*********************************************************************** 00200017
*                                                                     * 00400017
*  TITLE       IEFVMA - ASB READER INITIALIZATION                     * 00600019
*                                                                     * 00800017
*  FUNCTION    VALIDITY CHECK INPUT PARAMETERS AND INITIALIZE THE     * 01000017
*              SSWA (ASB READER WORKAREA)                             * 01200019
*                                                                     * 01400017
*  INPUT       REG 1 = PTR TO POINTER TO PARM FIELD FROM ASB RDR PROC * 01600019
*              REG 13 = PTR TO REGISTER SAVE AREA                     * 01800017
*                                                                     * 02000017
*  OUTPUT      REG 1 = ADDRESS OF SSWA                                * 02200017
*              REG 13 = ADDRESS OF REGISTER SAVE AREA                 * 02400017
*                                                                     * 02600017
*  EXIT        NORMAL - IEFVMB VIA XCTL                               * 02800017
*              ERROR - IEFVMD VIA XCTL                                * 03000017
*                                                                     * 03200017
*  TABLES      DCB, CVT, JFCB, SSWA, TIOT, TCB, UCB                   * 03400017
*                                                                     * 03600017
*  ATTRIBUTES  READ ONLY / REENTRANT                                  * 03800017
*                                                                     * 04000017
*********************************************************************** 04200017
         TITLE 'IEFVMA---MAPPING MACROS---IEFVMA'                       04400017
         IEFVSSWA                                                       04600017
         EJECT                                                          04800017
VMAJFCB  DSECT                                                          05000017
         IEFJFCBN                                                       05200017
         EJECT                                                          05600017
VMAUCB   DSECT                                                          05800017
         IEFUCBOB                                                       06000017
         EJECT                                                          06200017
VMATIOT  DSECT                                                          06400017
         IEFTIOT1                                                       06600017
         EJECT                                                          06800017
         DCBD  DSORG=(PS)                                               07000017
         EJECT                                                          07200017
         IEFQMNGR                                                       07900019
         EJECT                                                          08600017
*********************************************************************** 08700019
*                                                                     * 08800019
*  THE FOLLOWING IS A MAPPING OF THE SPOOL SPLITTER RELATED PARM      * 08900019
*  FIELD VALUES.  THE S/S PARM FIELD IS COMPOSED OF 2 SECTIONS--ONE   * 09000019
*  TO BE PASSED TO THE READER/INTERPRETER, THE OTHER FOR SPOOL        * 09100019
*  SPLITTER ITSELF.  THE TWO SECTIONS ARE SEPERATED BY A COMMA.  THIS * 09200019
*  COMMA IS USED TO REMOVE THE S/S DEPENDENCY UPON THE LENGTH OF THE  * 09300019
*  R/I PARM VALUES.                                                   * 09400019
*                                                                     * 09500019
*********************************************************************** 09600019
VMAPARM  DSECT                                                    19474 09700019
PCOMDISP DS    ZL1            VALU INDICATNG HOW COMMANDS FOUND IN19474 09800019
*                             THE INPUT STREAM ARE TO BE PROCESSED19474 09900019
*                                  0 -  EXECUTE ALL COMMANDS      19474 10000019
*                                  1 -  ISSUE WTO AND EXECUTE     19474 10100019
*                                  2 -  ISSUE WTOR REQUESTING     19474 10200019
*                                       DISPOSITION FROM OPERATOR 19474 10300019
*                                  3 -  IGNORE COMMAND            19474 10400019
PJOBCNT  DS    ZL2            NUMBER OF JOBS TO BE PROCESSED FROM 19474 10500019
*                             INPUT STREM BEFOR CALLING INTRPRTER 19474 10600019
PJCLTRKS DS    ZL2            MAXIMUM NUMBR OF LOGICAL TRCKS TO BE19474 10700019
*                             USED IN JOB QUEUE AT ANY ONE TIME   19474 10800019
PIREGION DS    ZL3            REGION SIZE TO BE USED REQUESTING A 19474 10900019
*                             REGION FOR THE  INTERPRETER         19474 11000019
PITRKBUF DS    ZL2            NUMBR OF LOGCAL JOB QUE TRCKS TO BE 19474 11100019
*                             REQUESTED IN THE TRACK STACK USED   19474 11200019
*                             WHEN INTERPRETING JCL               19474 11300019
PCMDAUTH DS    ZL4            COMAND AUTHORITY WHICH MUST BE PASED19474 11400019
*                             TO SVC 34 WHEN A COMMAND IS TO BE   19474 11500019
*                             EXECUTED--INDICATE WHICH COMANDS CAN19474 11600019
*                             BE VALIDLY SUMMITTED THRU THE INPUT 19474 11700019
*                             STREAM                              19474 11800019
PSPOOL   DS    CL8            DEVICE NAME TO BE PLACED ON THE     19474 11900019
*                             GENERATED DD STMT USED TO DESCRIBE  19474 12000019
*                             THE SPOOLED SYSIN DATA SETS         19474 12100019
PBINARY  DS    CL1            VALUE USED IN CONJUNCTION WITH THE  19474 12200019
*                             7090 MOD 85 INTEGRATED EMULATOR     19474 12300019
*                             0 - NO BINARY DATA SETS IN INPUT    19474 12400019
*                                  1 - BINARY SYSIN IN INPUT STREM19474 12500019
PHARCHY  DS    CL1            THIS BYTE CONTAINS THE HIERARCHY      LCS 12600019
*                             VALUE WHICH SPECIFIES WHICH         19474 12700019
*                             HIERARCHY THE R/I IS TO RUN IN.     19474 12800019
*                             THE DEFAULT VALUE IS ZERO. THIS     19474 12900019
*                             BYTE OF THE PARM FLD IS REPRESENTED 19474 13000019
*                             BY A SYMBOLIC PARAMETER AND MAY BE  19474 13100019
*                             OVERRIDDEN BY THE START COMMAND.    19474 13200019
PDATALEN EQU   *-PCOMDISP     LENGTH OF SPOOL SPLITTER RELATED    19474 13300019
*                             PARM VALUES                         19474 13400019
         EJECT                                                          13500019
VMACIB   DSECT                                                          17400018
         IEZCIB                                                         17800018
         EJECT                                                          17810019
*********************************************************************** 17811019
*                                                                     * 17820019
*     THE FOLLOWING DSECT WAS ADDED WITH THE FIX FOR APAR 27933       * 17830019
*      THIS WORK AREA IS ONLY MODIFIED BY MODULE IEFVMBC              * 17840019
*                                                                     * 18200019
*********************************************************************** 18201019
VMBCWORK DSECT                                                          18210019
VMBCSTRT DS    0D             USED TO SET LENGTH OF THIS WORK AREA      18220019
DCBHOLD  DS    A              USED TO SAVE PTR.TO IMAGE OF IEFRDER DCB  18230019
         DS    X              RESERVED                                  18240019
HEODAD   DS    AL3            SAVE EODAD ADDR.FOR IEFVMB                18250019
         DS    X              RESERVED                                  18260019
HSYNAD   DS    AL3        SAVE SYNAD ADDR.FOR IEFVMB                    18270019
SAVECARD DS    CL80       USED TO PASS CARD FROM IEFVMBC TO IEFVMB      18280019
VMBCEND  EQU   *          USED TO SET LENGTH OF THIS WORK AREA          18290019
VMBCAREA EQU   VMBCEND-VMBCSTRT    USED FOR GETMAIN AND FREEMAIN        18300019
*                                                                       18310019
*                                                                       18320019
*                                                                       18330019
         TITLE 'IEFVMA---SPOOL SPLITTER INITIALIZATION MODULE---IEFVMA' 18800017
IEFVMA   CSECT                                                          19000017
* 646000,678000-682000,690000-696000,704000,768000-796000,712000  P3731 19030019
* 682880,682960                                                   P3740 19060019
* 546000-552000,556000-634000,818000-856000,868000                18037 19100018
*********************************************************************** 19120019
*  SAVE INPUT REGISTER AND ESTABLISH MODULE ADDRESSIBILITY            * 19140019
*********************************************************************** 19160019
         SAVE  (14,12)             SAVE PASSED REGISTERS                19200017
         BALR  RB,R0               LOAD MODULE BASE REG                 19400017
         USING *,RB                TELL ASSEMBLER                       19600017
*********************************************************************** 20200019
*  GET CORE IN SUBPOOL 0 FOR SPOOL SPLITTER WORK AREA AND INITIALIZE  * 20800019
*********************************************************************** 21400019
VMA001   DS    0H                                                       22000017
         LR    R5,R1               SAVE POINTER TO PARM FIELD      I272 22200019
*                                   ADDRESS                        I272 22400019
         L     R4,SSWALEN          LOAD LENGTH AND SUBPOOL ID FOR 19474 22500019
*                                   SSWA GETMAIN                  19474 22600019
         LR    R0,R4               LOAD GETMAIN PARAMETER REGISTER19474 22700019
         GETMAIN R,LV=(0)          GET CORE FOR SWA                     22800017
         LR    RC,R1               SET UP ADDRESSIBILITY OF SWA         23000017
         USING SSWA,RC                                                  23200017
         SR    R3,R3               SET REG TO ZERO                      23400017
         BCTR  R4,0                                                     23800017
VMA002   DS    0H                                                       24000017
         STC   R3,0(R4,R1)         STORE ZEROES                         24200017
         BCT   R4,VMA002           CONTINUE TILL END OF SSWA            24400017
*                                  GET CORE FOR REGISTER SAVE AREA19474 24460019
*                                   WHOSE ADDRESS WILL BE KEPT IN 19474 24520019
*                                   REGISTER 13 ALL DURING ASB    19474 24580019
*                                   READER   EXECUTION            19474 24640019
         SPACE 2                                                        24643019
*********************************************************************** 24646019
*                                                                     * 24649019
*        ALLOCATE CORE IN SUBPOOL 252 FOR THE IN-LINE PROC            * 24652019
*        DIRECTORY, A 176 BYTE Q BUFFER AND A 176 BYTE JFCB           * 24655019
*        AND PLACE POINTERS TO THESE AREAS IN THE SSWA.               * 24658019
*                                                                     * 24661019
*********************************************************************** 24664019
         SPACE 2                                                        24667019
         L     R0,AMTCORE          GET CORE SIZE NND SUBPOOL ID   P3731 24670019
         GETMAIN R,LV=(0)                                               24673019
*                                                                       24676019
         ST    R1,PROCDIRC   SET THE FIRST AREA FOR THE DIRECTORY P3731 24679019
         ST    R1,NEXTPROC          AND POINT TO FIRST ENTRY      P3731 24682019
         LA    R1,DIRCLEN(R1)      ALLOCATE THE NEXT SECTION FOR  P3731 24685019
         ST    R1,DATAJFCB         THE JFCB BUFFER AND            P3731 24688019
         LA    R1,JFCBLGTH(R1)     ALLOCATE THE LAST SECTION FOR  P3731 24691019
         ST    R1,QBUFPTR          THE Q BUFFER                   P3731 24694019
         IEFSAVER                                                       24700019
*********************************************************************** 24750019
*  EXTRACT ADDRESSES OF THE TIOT AND COMMUNICATIONS PARAMETER LIST    * 24800019
*********************************************************************** 24850019
         GETMAIN R,LV=20           GET CORE FOR EXTRACT PARAMETER  I272 24900019
*                                   LIST (3 WORDS) AND FOR ANSWER  I272 24950019
*                                   AREA (2 WORDS)                 I272 25000019
         LR    R3,R1               SAVE ADDRESS OF GOTTEN CORE     I272 25050019
*                                  EXTRACT ADDRESSES OF TIOT AND   I272 25100019
*                                   COMMUNICATIONS PARAMETER LIST  I272 25150019
         EXTRACT 12(R3),'S',FIELDS=(COMM,TIOT),MF=(E,(1))          I272 25200019
*                                  ADDRESS OF TIOT IS AT 12(R3)    I272 25250019
*                                  ADDRESS OF CPL  IS AT 16(R3)    I272 25300019
         L     RA,12(R3)           LOAD POINTER TO TIOT            I272 25350019
         ST    RA,SSTIOT           SAVE TIOT ADDRESS IN SSWA       I272 25400019
         L     RA,16(R3)           LOAD POINTER TO CPL             I272 25450019
         ST    RA,COMMPL           STORE ADDRESS OF COMMUNICATIONS I272 25500019
*                                   PARAMETER LIST IN SSWA         I272 25550019
         LR    R1,R3               RESTORE PTR TO GOTTEN CORE      I272 25600019
         FREEMAIN R,LV=20,A=(1)    FREE EXTRACT  PARAMETER LIST    I272 25650019
*********************************************************************** 25700019
*  PROCESS THE COMMAND INPUT BUFFER (CIB) FROM THE START COMMAND      * 25750019
*              .  SAVE THE CONSOLE ID OF CONSOLE ISSUING START        * 25800019
*              .  IF THE IS A JOBNAME IN CIB SAVE IT IN THE SSWA AND  * 25850019
*                 SET SWITCH TO CAUSE IEFVMB TO SKIP ALL INPUT STREAM * 25900019
*                 RECORDS UNTIL A JOB STMT IS FOUND WITH A NAME       * 25950019
*                 MATCHING THE ONE IN THE SSWA                        * 26000019
*              .  UNCHAIN AND FREE THE CIB VIA THE QEDIT MACRO        * 26050019
*********************************************************************** 26100019
         L     RA,4(RA)            LOAD 2ND WORD OF THE CPL--THE   I272 26150019
*                                   ADDRESS OF THE CIB             I272 26200019
         LA    RA,0(RA)            CLEAR HIGH-ORDER BIT            I272 26250019
         USING VMACIB,RA           SET UP CIB ADDRESSIBILITY       I272 26300019
         MVC   CONSOLID,CIBCONID   SAVE CONSOLE ID FROM START COMD I272 26350019
         LA    RF,CONSOLID         LOAD PTR TO CONSOLE ID IN SSWA  I272 26400019
         ST    RF,CONSLIDP         STORE IN PARM LIST FOR IEFVME   I272 26450019
         LH    R9,CIBDATLN         LOAD LENGTH OF CIB DATA              26700018
         LTR   R9,R9               IS THERE A JOBNAME                   26900018
         BZ    VMA003              NO                                   27100018
         BCTR  R9,0                REDUCE LENGTH FOR EXECUTE            27300018
         CH    R9,SEVEN            IS JOBNAME TOO LONG                  27600017
         BNH   VMA0025             NO                                   27800017
         MVI   ERRMSG,MSG1         WRITE JOBNAME TOO LONG MESSAGE       28000017
         B     VMA025              TERMINATE                            28200017
VMA0025  DS    0H                                                       28400017
         OI    STATSWTA,STARTJOB   INDICATE USER GIVEN STATING JOBNAME  28600017
         MVC   SAVEJOB,BLANKS      PAD SAVE AREA WITH BLANKS            28800017
         EX    R9,MVCNAME          SAVE JOBNAME                         29000017
VMA003   DS    0H                                                  I272 29020019
         LR    R1,RA               LOAD CIB ARRD INTO REG 1             29050018
         L     RF,COMMPL           LOAD ADDRESS OF COMMUNICATIONS  I272 29070019
*                                   PARAMETER LIST                 I272 29090019
         LA    R0,4(RF)            LOAD PTR TO COMMAND INPUT BUFFERI272 29110019
         QEDIT BLOCK=(1),ORIGIN=(0)  FREE AND UNCHAIN CIB CORE          29150018
*********************************************************************** 29200019
*  PROCESS PARM FIELD BUFFER                                          * 29250019
*              .  SAVE PARM ADDRESS IN SSWA TO USE WHEN CALLING       * 29300019
*                 INTERPRETER                                         * 29350019
*              .  SCAN TO FIRST COMMA AND ESTABLISH ADDRESSIBILITY TO * 29400019
*                 SPOOL SPLITTER PARM VALUES                          * 29450019
*              .  VALIDITY CHECK ALL VALUES, CONVERT THEM AND STORE   * 29500019
*                 THEM IN SSWA FOR LATER USE                          * 29550019
*              .  IF VALIDITY CHECK FAILS, ISSUE 'INVALID PARM FIELD  * 29600019
*                 FORMAT' ERROR MSG                                   * 29650019
*              .  IF BINARY SYSIN WAS SPECIFIED, LOAD IEFVMBC--THE    * 29700019
*                 BINARY SYSIN SPOOL ROUTINE                          * 29750019
*********************************************************************** 29800019
         L     R8,0(R5)            LOAD ADDRESS OF PARM FIELD      I272 29850019
         ST    R8,PARMPTR          SAVE PARM ADDRESS IN SSWA       I272 29900019
         LH    R6,0(R8)            LOAD PARM FIELD LENGTH          I272 29950019
         LTR   R6,R6               TEST FOR A LENGTH OF ZERO--IF   I272 30000019
*                                   SO THE PARM FIELD IS INVALID   I272 30050019
         BNZ   VMA0042             NOT ZERO--CONTINUE CHECKING     I272 30100019
VMA004   DS    0H                                                       30200017
         MVI   ERRMSG,MSG2         PARM FIELD IS INVALID                30400017
         B     VMA025              TERMINATE                            30600017
VMA0042  DS    0H                                                       30800017
         LA    R8,2(R8)            POINT TO FIRST BYTE OF PARM DATA     31000017
VMA0044  DS    0H                                                       31200017
         CLI   0(R8),C','          SCAN TO START OF S/S VALUES          31400017
         BE    VMA005                                                   31600017
         LA    R8,1(R8)            MOVE TO NEXT CHARACTER               31800017
         BCT   R6,VMA0044          CONTINUE SEARCH FOR COMMA            32000017
         B     VMA004              AT END OF PARM DATA---FIELD INVALID  32200017
VMA005   DS    0H                                                  I272 32260019
         BCTR  R6,0                SUBTRACT ONE FROM LENGTH TO     I272 32320019
*                                   REMOVE BYTE TAKEN BY COMMA     I272 32380019
         LA    RF,PDATALEN         LOAD VALID LENGTH OF PARM VALUE I272 32440019
         CR    RF,R6               TEST FOR VALID LENGTH           I272 32500019
         BL    VMA004              NOT VALID                       I272 32560019
         LA    R8,1(R8)            POINT TO CHARACTER AFTER COMMA  I272 32620019
         USING VMAPARM,R8          SET PARM ADDRESSIBILITY         I272 32680019
*                                                                       32800017
*  PICK UP COMMAND DISP WHICH MUST BE A 0, 1, 2, OR 3                   33000017
*                                                                       33200017
         CLI   PCOMDISP,C'0'       LESS THAN A ZERO               19474 33400019
         BL    VMA004              YES--INVALID                   19474 33600019
         CLI   PCOMDISP,C'3'       GREATER THAN A THREE           19474 33800019
         BH    VMA004              YES--INVALID                   19474 34000019
         MVC   COMDISP,PCOMDISP    VALID--SAVE IN SSWA             I272 34200019
*                                                                       34400017
*  THE REST OF THE PARM FIELD IS FOR ASB READER OPTIONS.  THE           34500018
*  CHARACTERS FROM JOB COUNT TO COMMAND AUTHORITY MUST BE CHECKED       34600018
*  FOR NUMERICS.                                                        34700018
*                                                                       34800018
         LA    R7,PITRKBUF+1       LOAD ADDRESS OF LAST BYTE TO BE19474 35000019
*                                   TESTED                        19474 35200019
         LA    R6,PITRKBUF+2-PJOBCNT  NUMBER OF CHARACTERS TO TEST19474 35400019
VMA006   DS    0H                                                       35600017
         CLI   0(R7),C'0'          LESS THAN 0                          35800017
         BL    VMA004               YES                                 36000017
         CLI   0(R7),C'9'          GREATER THAN 9                       36200017
         BH    VMA004               YES                                 36400017
         BCTR  R7,R0               MOVE TO NEXT CHARACTER               36600017
         BCT   R6,VMA006           AT END                               36800017
*                                                                       37000017
*  CONVERT SPOOL VALUES AND STORE IN SSWA                               37200017
*                                                                       37400017
         PACK  WORKAREA,PJOBCNT    CONVERT JOB COUNT TO BINARY          37600017
         CVB   R6,WORKAREA          AND STORE IN THE SSWA               37800017
         STH   R6,JOBLIMIT                                              38000017
         PACK  WORKAREA,PJCLTRKS   CONVERT JCL QUEUE TRACKS TO BINARY   38200017
         CVB   R6,WORKAREA          AND STORE IN THE SSWA               38400017
         STH   R6,TRKLIMIT                                              38600017
         PACK  WORKAREA,PIREGION                                        38606018
         CVB   R6,WORKAREA         CONVERT R/I REGION SIZE TO BINARY    38612018
         SLL   R6,10               MULTIPLY BY 1024 TO GET CORE SIZE    38618018
         ST    R6,RDRREGON         SAVE IN SSWA FOR IEFVME              38624018
         MVI   RDRREGON,247        SET SUBPOOL NBR EQUAL 247*           38630018
*                                                                       38636018
*  PACK 4 BYTE EBCDIC COMMAND AUTHORITY INTO 2 BYTE BINARY              38642018
*                                                                       38648018
         LA    R3,WORKAREA         WORK SPACE                           38654018
         LA    R4,4                LENGTH COMMAND AUTH FIELD            38660018
         LA    R5,PCMDAUTH         POINT TO PARM BUFFER                 38666018
VMA0060  DS    0H                                                       38672018
         LA    R6,TABLE            COMPARISON TABLE                     38678018
         LA    R7,16               MAXIMUM NBR OF POSSIBILITIES         38684018
VMA00605 DS    0H                                                       38690018
         CLC   0(1,R5),0(R6)       BUFFER VS TABLE                      38696018
         BE    VMA0061             HIT                                  38702018
         BCTR  R6,0                DECREMENT INDEX                      38708018
         BCT   R7,VMA00605         TRY AGAIN                            38714018
         B     VMA004              NOT IN TABLE - ILLEGAL CHARACTER     38720018
VMA0061  DS    0H                                                       38726018
         BCTR  R7,0                SET TO BINARY OF NBR HIT             38732018
         STC   R7,0(R3)            STORE IN WORK AREA                   38738018
         LA    R3,1(R3)            INDEX TO NEXT STORE SLOT             38744018
         LA    R5,1(R5)            INDEX TO NEXT PARM CHARACTER         38750018
         BCT   R4,VMA0060          GO GET NEXT CHARACTER                38756018
         PACK  WORKAREA+5(3),WORKAREA(5)    GOT ALL FOUR - PACK THEM    38762018
         MVC   COMDAUTH(2),WORKAREA+5   MOVE TO SSWA SLOT               38768018
         MVC   UNITADDR,PSPOOL     SAVE SPOOL DEVICE NAME               38800017
         CLI   PBINARY,ONE              HAS BINARY SYSIN SUPPORT  18037 38810019
*                                         BEEN REQUESTED          18037 38820019
         BNE   VMA00615                 IF NOT IN PARM FIELD      18037 38840018
*                                           DO NOT LOAD IEFVMBC   18037 38860018
         LA    R0,VMBCAREA         SIZE OF WORK AREA              27933 38870019
         GETMAIN R,LV=(0)                                               38871019
         ST    R1,VMBCWA           SAVE FOR IEFVMBC TO USE        27933 38872019
         LOAD  EP=IEFVMBC                                         18037 38880018
         ST    R0,VMBCPTR               SAVE PTR.FOR IEFVMB       18037 38900018
VMA00615 DS    0H                                                 18037 38920018
         CLI   PHARCHY,ZERO             IF HIERARCHY = 0            LCS 38930019
         BE    VMA00617                    NO ACTION NECESSARY      LCS 38940019
         CLI   PHARCHY,ONE              IS HIERARCHY = 1            LCS 38950019
         BNE   VMA004                   IF NOT,ERROR                LCS 38960019
         OI    STATSWTD,RDRHRCHY        INDICATE HIERARCHY = 1      LCS 38970019
VMA00617 DS    0H                                                   LCS 38980019
         SPACE 3                                                        38990019
*********************************************************************** 39290019
*  SCAN TIOT FOR REQUIRED DATA SETS (IEFRDER, IEFPDSI, AND IEFDATA).  * 39590019
*********************************************************************** 39890019
         L     R5,SSTIOT           LOAD TIOT PTR                        40200017
         LA    R5,24(R5)           BYPASS JOB + STEPNAME IN TIOT        40400017
         USING TIOENTRY,R5         ESTABLISH TIOT ADDRESSIBILITY        40600017
         LR    R6,R5               SAVE POINTER TO FIRST ENTRY          40800017
         SR    R8,R8                                                    41000017
         LA    R3,RDCB             POINT TO IEFRDER DCB                 41200017
         BAL   RA,VMA0062          SCAN TIOT                            41400017
         LA    R3,PDCB             POINT TO IEFPDSI DCB                 41600017
         BAL   RA,VMA0062          SCAN TIOT                            41800017
         LA    R3,SDCB             POINT TO IEFDATA DCB                 42000017
         BAL   RA,VMA0062                                               42200017
         B     VMA007                                                   42400017
VMA0062  DS    0H                                                       42600017
         LR    R5,R6               POINT TO FIRST TIOT ENTRY            42800017
         USING IHADCB,R3           DCB ADDRESSIBILITY                   43000017
VMA0065  DS    0H                                                       43200017
         CLC   TIOEDDNM,DCBDDNAM   FOUND PROPER ENTRY                   43400017
         BCR   8,RA                YES, RETURN                          43600017
         IC    R8,TIOELNGH         NO, COMPUTE ADDR OF NEXT ENTRY       43800017
         AR    R5,R8                                                    44000017
         L     RF,0(R5)            END OF TIOT INDICATED BY WORD OF     44200017
*                                  ZEROES                               44400017
         LTR   RF,RF               AT END OF TIOT                       44600017
         BC    NOTZERO,VMA0065      NO                                  44800017
         MVI   ERRMSG,MSG3         MISSING DD ENTRY MSG                 45000017
         B     VMA025              TERMINATE                            45200017
VMA007   DS    0H                                                       45400017
*********************************************************************** 45410019
*  PROCESS THE IEFDATA TIOT ENTRY                                     * 45420019
*              .  SAVE IEFDATA TIOT ENTRY ADDRESS IN SSWA             * 45430019
*              .  SAVE TTR OF JFCB ASSIGNED TO THE IEFDATA SET.  THIS * 45440019
*                 TTR WILL BE RESTORED BY IEFVMD.  THIS SAVING AND    * 45450019
*                 RESTORING OF THE TTR IS REQUIRED SINCE THE TTR WILL * 45460019
*                 BE CHANGED DURING THE SPOOLING OF SYSIN DATA SETS   * 45470019
*              .  IF THE IEFDATA TIOT ENTRY INDICATES IT IS A DUMMY   * 45471019
*                 DATASET (INDICATED BY A ZERO UCB COUNT), THEN       * 45472019
*                 BYPASS THE SETTING OF THE UCB ATTRIBUTE BITS        * 45473019
*              .  MARK ALL UCB ALLOCATED TO THE IEFDATA SET WHICH ARE * 45480019
*                 NOT MARKED RESERVED OR PERMANENTLY RESIDENT AS      * 45490019
*                 RESERVED, PUBLIC, AND NOT PRIVATE.  THIS IS DONE TO * 45500019
*                 INSURE THE VOLUMES WITH SYSIN DATA SETS WILL NOT BE * 45510019
*                 DISMOUNTED WHEN THE READER CLOSES.                  * 45520019
*********************************************************************** 45530019
         ST    R5,SSTIOT           SAVE POINTER TO IEFDATA TIOT ENTRY   45600019
         MVC   JFCBTTR,TIOEJFCB    SAVE TTR OF ITS JFCB                 45800017
         LH    R6,TIOEFSRT+1       LOAD UCB POINTER                     46800017
         USING UCBOB,R6            UCB ADDRESSIBILITY                   47000017
         SR    R3,R3                                                    47200017
         IC    R3,TIOEWTCT         INSERT # OF UCB'S ALLOCATED          47400017
         LTR   R3,R3               IS THIS A DUMMY DATASET        28370 47410019
         BZ    VMA009              YES BYPASS ATTRIBUTE SETTING   28370 47420019
VMA0075  DS    0H                                                       47600017
         TM    SRTESTAT,SRTERESV+SRTEPRES RESERVED OR PERM. RESIDENT    47800017
         BC    NOTZERO,VMA008       YES                                 48000017
         NI    TIOESTTB,255-TIOSUSED   SET DATA SET ON DEVICE SWT OFF   48200017
         OI    SRTESTAT,SRTERESV   MARK UCB - RESERVED                  48400017
         OI    SRTESTAB,SRTEBPUB              PUBLIC                    48600017
         NI    SRTESTAB,255-SRTEBPRV          NOT PRIVATE               48800017
VMA008   DS    0H                                                       49000017
         LA    R5,4(R5)            POINT TO NEXT UCB POINTER            49200017
         LH    R6,TIOEFSRT+1       PICK UP UCB PTR                      49400017
         BCT   R3,VMA0075                                               49600017
*********************************************************************** 49640019
*  INITIALIZE DATA SET PROCESSING                                     * 49680019
*              .  RELOCATE DCB TO THE SSWA                            * 49720019
*              .  INSURE OPEN WILL NOT TRY TO GET BUFFERS FOR IEFPDSI * 49760019
*                 BY SETTING THE BUFFER CONTROL BLOCK POINTER TO ZERO.* 49800019
*                 REASON IS THIS MODULE GET THE ONE BUFFER FOR BOTH   * 49840019
*                 PROCLIB READING AND SPOOLING.  FOR THIS REASON A    * 49880019
*                 BUFFER CANNOT BE GOTTEN UNTIL THE LARGE BLKSIZE     * 49920019
*                 (IEFDATA OR IEFPDSI) IS DETERMINED                  * 49960019
*              .  OPEN IEFPDSI DATA SET                               * 50000019
*              .  READ THE JFCB FOR IEFDATA                           * 50040019
*              .  FIND LARGER BLKSIZE BETWEEN IEFDATA JFCB AND IEFPDSI* 50080019
*                 AND ISSUE GETMAIN FOR BUFFER                        * 50120019
*              .  SAVE THE BLKSIZE AND BUFNO VALUES FROM THE JFCB     * 50160019
*              .  SET UP BASE OF UNIQUE DATA SET NAME--AS FOLLOWS     * 50200019
*                        SYSDDDDD.TXXXXXX.IV000                       * 50240019
*                 WHERE  DDDDD = CURRENT DATE                         * 50280019
*                 AND    XXXXXX = CURRENT TIME                        * 50320019
*********************************************************************** 50360019
VMA009   DS    0H                                                 28370 50370019
         MVC   RDERDCB(96),RDCB    MOVE DCB'S TO SSWA                   50400017
         MVC   PROCDCB(96),PDCB                                         50600017
         MVC   SPOLDCB(96),SDCB                                         50800017
         SR    R1,R1               MAKE SURE NO BUFFERS ARE GOTTEN      50860017
         ST    R1,PROCDCB+DCBBUFCB-IHADCB  BY OPEN (ZERO BUFNO& BUFCB)  50920017
         LA    R1,PROCDCB          SET UP OPEN PARAMETER LIST FOR 19474 51420019
         ST    R1,WORKAREA          OPENING THE IEFPDSI DCB       19474 51920019
         MVI   WORKAREA,X'80'      INDICATE END OF PARAMETER LIST 19474 52420019
         OPEN  ,MF=(E,WORKAREA)    OPEN IEFPDSI DCB               19474 52920019
         TM    PROCDCB+DCBOFLGS-IHADCB,X'10' DID IEFPDSI DCB OPEN       53800017
         BO    VMA010              YES                                  54000017
         MVI   ERRMSG,MSG5         WRITE UNABLE TO OPEN MSG             54200017
         B     VMA025              TERMINATE                            54400017
VMA010   DS    0H                                                       55400017
         L     R4,DATAJFCB          ADDR.OF JFCB BUFFER           P3731 59400019
         ST    R4,RDJEXIT          STORE IN EXIT                        64800017
         MVI   RDJEXIT,X'87'                                            65000017
         LA    R4,DCBEXITS         ADDRESS OF DCB EXITS                 65200017
         ST    R4,WORKAREA                                              65400017
         MVC   SPOLDCB+DCBEXLST+1-IHADCB(3),WORKAREA+1 PUT INTO DCB     65600017
         LA    R1,SPOLDCB          SET UP RDJFCB PARAMETER LIST         66600017
         ST    R1,WORKAREA                                              66800017
         MVI   WORKAREA,X'80'      INDICATE END OF PARAMETER LIST 19474 67100019
         RDJFCB ,MF=(E,WORKAREA)   READ IEFDATA JFCB              19474 67400019
         L     R4,DATAJFCB          SET UP ADDRESSIBILITY TO      P3731 67500019
         USING VMAJFCB,R4             JFCB BUFFER                 P3731 67600019
         MVC   MAXBLKSI,JFCBLKSI     GET VALUES FROM PROC         P3731 67700019
         MVC   MAXBUFNO,JFCBUFNO      FOR MAX BLKSIZE AND BUFNO   P3731 67800019
         OI    JFCBIND2,X'04'        MARK DATA SET OLD            P3731 67900019
         DROP  R4                                                 P3731 68000019
         LH    R4,MAXBLKSI         LOAD IEFDATA MAXIMUM BLKSIZE   19474 68208019
         LH    R3,PROCDCB+DCBBLKSI-IHADCB GET IEFPDSI BLKSIZE     19474 68216019
         CR    R4,R3               FIND LARGER VALUE              19474 68224019
         BH    VMA011              IEFDATA GRATER                 19474 68232019
         LR    R4,R3               IEFPDSI GREATER                19474 68240019
VMA011   DS    0H                                                 19474 68248019
         LA    R4,8(R4)       ADD TO LEN THE LEN REQUIRED         19474 68256019
*                                   FOR THE BUFFER CONTROL BLOCK  19474 68264019
         LR    R0,R4               SET GETMAIN LENGTH PARAMETER   19474 68272019
         GETMAIN R,LV=(0)          GETCORE FOR I/O BUFFER         19474 68280019
         ST    R1,WORKAREA         ADDR OF BUFFER CONTROL BLOCK   P3740 68285019
         MVC   SPOLDCB+DCBBUFCB-IHADCB+1(3),WORKAREA+1 MOVE TO DCBP3740 68290019
         LA    R1,8(R1)            POINT TO 1ST BYTE OF BUFFER    P3740 68297019
         ST    R1,PROCBUF          STORE ADDRESS OF PROC BUFFER   19474 68304019
*                                   IN SSWA                       19474 68312019
         LA    R1,RDERDCB          LOAD ADDRESS OF IEFRDER DCB    19474 68320019
         ST    R1,WORKAREA         STORE FOR OPEN PARAMETER LIST  19474 68328019
         MVI   WORKAREA,X'80'      MARK END OF PARAMETER LIST     19474 68336019
         OPEN  ,MF=(E,WORKAREA)    OPEN IEFRDER DCB               19474 68344019
         TM    RDERDCB+DCBOFLGS-IHADCB,X'10' DID IEFRDER DCB OPEN 19474 68352019
         BO    VMA012              YES                            19474 68360019
         MVI   ERRMSG,MSG4         NO, SET MSG NUMBER FOR IEFVMD  19474 68368019
         B     VMA025              GO TO XCTL TO IEFVMD           19474 68376019
VMA012   DS    0H                                                 19474 68384019
*                                                                       68400017
*  DEVELOPE BASE OF UNIQUE DSNAME AND PLACE IN JFCB                     68600017
*                                                                       68800017
         TIME  DEC                 GET DATE AND TIME                    69800017
         ST    R1,WORKAREA         STORE PACKED DATE                    70000017
         OI    WORKAREA+3,X'0F'    SET RIGHT SIGN                       70200017
         USING VMAJFCB,R4           SET ADDRESSIBILITY FOR JFCB   P3731 70260019
         L     R4,DATAJFCB                                        P3731 70320019
         MVC   JFCBDSNM(24),UNQNAME  MOVE BASE OF UNIQUE DSNAME   P3731 70380019
         MVC   JFCBDSNM+24(20),JFCBDSNM+23  BLANK REST OF DSNAME  P3731 70440019
         UNPK  JFCBDSNM+3(5),WORKAREA+1(3)                        P3731 70500019
         SRL   R0,4                SHIFT OUT HUNDREDS OF SECONDS  26990 70600019
         ST    R0,WORKAREA         STORE TIME                           70800017
         OI    WORKAREA+3,X'0F'    STORE NUMERIC SIGN OVER TENTHS 26990 70900019
*                                  OF A SECOND POSITION           26990 71000019
         UNPK  JFCBDSNM+10(6),WORKAREA(4)   PUT TIME INTO NAME    P3731 71070019
         DROP  R4                                                 P3731 71140019
*********************************************************************** 71210019
*    .  INITIALIZE FLUSH SWITCH ON TO CAUSE ALL SYSIN DATA SET TO     * 71220019
*       BE FLUSHED UNTIL FIRST JOB STMT IS READ                       * 71230019
*    .  INITIALIZE POINTER IN QMPA TO EXTERNAL PARAMETER LIST         * 71240019
*********************************************************************** 71250019
         OI    STATSWTA,FLUSH      SET FLUSH SWITCH ON            19474 71260019
         LA    RF,QMPCA            SET UP POINTER IN QMPA TO THE  19474 71270019
         ST    RF,QMPA+QMPCL-IOPARAMS   EXTERNAL PARAMETER LIST   19474 71280019
*********************************************************************** 71290019
*      INITIALIZE POINTER TO IEZNCODE PARAMETER LIST AND              * 71300019
*      SET COMPRESSION CHARACTER IN PARAMETER LIST TO BLANK           * 71310019
*********************************************************************** 71320019
         LA    RF,INPUTREC         LOAD PTR TO NCODE LIST         19474 71330019
         ST    RF,NCODELST         STORE IN SSWA                  19474 71340019
         MVI   COMPCHAR,C' '       SET BLANK COMPRESSION          19474 71350019
*********************************************************************** 71360019
*  BUILD SPOOL FULL AND WAITING MSG WRITE TO OPERATOR BUFFER IN SSWA  * 71370019
*********************************************************************** 71380019
         MVC   SPOLMSG,MSGWTO      MOVE LIST FORM OF WTO FOR SPOOL19474 71390019
*                                   MESSAGE TO SSWA               19474 71400019
*********************************************************************** 71600019
*  ATTACH MODULE IEFVME THE LINK PACK AREA MODULE RESPONSIBLE FOR     * 71800019
*  INITIATION OF THE INTERPRETER.  SINCE IEFVME MUST BE ABLE TO GET   * 72000019
*  AND FREE THE REGION IN WHICH THE INTERPRETER WILL OPERATE, IT MUST * 72200019
*  NOT OWN OR SHARE ANY CORE WHEN THE GET AND FREE ARE ISSUED.  IT IS * 72400019
*  FOR THIS REASON THAT IT MUST BE RESIDENT IN LINK PACK AREA (ONLY   * 72600019
*  LPA MODULES DO NOT HAVE SPQE'S DESCRIBING THE STORAGE AREA IN      * 72800019
*  WHICH THEY RESIDE).  IN ADDITION TO PREVENT ANY WORK SPACE BEING   * 73000019
*  ALLOCATED TO IT, THE ATTACH PARAMETER LIST IS SET UP SO SUBPOOL    * 73200019
*  ZERO WILL NOT BE SHARED, NO REGISTER SAVE AREA WILL BE GENERATED   * 73400019
*  AND SUBPOOL 252 WILL NOT BE GIVEN.                                 * 73600019
*********************************************************************** 73800019
         GETMAIN R,LV=36           GET CORE FOR ATTACH PARAMETERS 19474 74000019
         LR    R4,R1               SAVE AREA GOTTEN               19474 74200019
         XC    0(36,R4),0(R4)      CLEAR ALL PARAMETERS           19474 74400019
         LA    R1,PARMPTR     POINT TO LIST TO PASS TO IEFVME      I272 74600019
         LR    RF,R4               POINT TO ATTACH PARAMETER LIST 19474 74800019
         ATTACH EP=IEFVME,ECB=RTNECB,SF=(E,(15)),SM=PROB,          I270X75000019
               SZERO=NO,SVAREA=NO,JSTCB=YES,KEY=ZERO,GIVEJPQ=NO    I270 75200019
         ST    R1,VMETCB           SAVE ADDRESS OF SUBTASK TCB          76200017
         FREEMAIN R,LV=36,A=(4)    FREE ATTACH PARAMETER LIST     19474 76300019
*********************************************************************** 79800019
*  RESTORE REGISTERS, INDICATE SWA AS PASSED PARM AND XCTL TO IEFVMB    80000017
*********************************************************************** 80200019
         LR    R1,RC                    PASS ADDR OF SSWA               80400017
         XCTL  ,EP=IEFVMB          PASS CONTROL TO MAIN MODULE          80600017
*********************************************************************** 80700019
*  ERROR HAS OCCURRED FREE SWA, WTO MSG, AND TERMINATE                  80800017
*********************************************************************** 81000019
VMA025   DS    0H                                                       81200017
         LR    R1,RC               PASS ADDRESS OF SSWA                 81400017
         XCTL  ,EP=IEFVMD          PASS CONTROL TO S-S TERMINATE MODULE 81600017
         TITLE 'IEFVMA---MODULE CONSTANTS-READ ONLY---IEFVMA'           85800017
RDCB     DCB   DDNAME=IEFRDER,                                         *86000017
               DSORG=PS,                                               *86200017
               MACRF=(GL),                                             *86400017
               LRECL=80,                                               *86600017
               EROPT=SKP                                                87000017
PDCB     DCB   DDNAME=IEFPDSI,                                         *87200017
               DSORG=PO,                                               *87400017
               MACRF=(R),                                              *87600017
               LRECL=80                                                 87900017
SDCB     DCB   DDNAME=IEFDATA,                                         *88200017
               DSORG=PS,                                               *88400017
               MACRF=(PM),                                             *88600017
               BUFNO=1,                                                *88800017
               LRECL=80                                                 89000017
UNQNAME  DC    C'SYS00000.T000000.IV000. '   UNIQUE DSNAME BASE   19474 89200019
NOTZERO  EQU   7                                                        89400017
         DS    0H                                                       89600017
FOUR     DC    H'4'                                                     89800017
SEVEN    DC    H'7'                                                     90000017
SSWALEN  DC    A(SSWAEND-SSWA)     LENGTH OF SSWA                 19474 90100019
         DS    0F                                                 P3731 90120019
AMTCORE  DC    AL1(252)                                           P3731 90140019
         DC    AL3(DIRCLEN+JFCBLGTH+QBUFLGTH)                     P3731 90160019
MVCNAME  MVC   SAVEJOB(0),CIBDATA                                       90200018
TESTMVC  MVC   WORKAREA(0),2(R2)                                        90400017
DATAEND  DC    C'/*'                                                    90600017
JCLSTMT  DC    C'//'                                                    90800017
JOBSTMT  DC    C'JOB '                                                  91000017
DDSTMT   DC    C'DD '                                                   91200017
DATA     DC    C'DATA'                                                  91400017
BLANKS   DC    8C' '                                                    91600017
         DC    C'0123456789ABCDEF' COMMAND AUTHORITY COMPARISON TABLE   91660018
TABLE    EQU   *-1                                                      91720018
MSG1     EQU   1         STARTING JOBNAME TOO LONG                      91800017
MSG2     EQU   2        PARM FIELD IS INVALID                           92000017
MSG3     EQU   3         REQUIRED DD NAME MISSING                       92200017
MSG4     EQU   4        UNABLE TO OPEN INPUT STREAM                     92400017
MSG5     EQU   5        UNABLE TO OPEN PROCLIB                          92600017
MSG6     EQU   6                   STARTING JOBNAME NOT FOUND           92800017
EQUAL    EQU   8                                                        93000017
NOTEQUAL EQU   7                                                        93200017
ZERO     EQU   X'F0'                                              19474 93260019
ONE      EQU   X'F1'                                              19474 93320019
MSGWTO   WTO   'IEF416I SPOOL FULL AND WAITING FOR JOB JJJJJJJJ', 19106*93410019
               ROUTCDE=(2,4),DESC=(4),MCSFLAG=(REG0),MF=L         1O106 93500019
         END                                                            93600017
