*********************************************************************** 00030017
*                                                                     * 00060017
*  TITLE       IEFVME -- ASB READER R/I REGION CONTROLLER            *  00090018
*                                                                     * 00120017
*  FUNCTION    TO DYNAMICALLY ACQUIRE AND FREE A REGION FOR THE      *  00150018
*              INTERPRETATION OF ASB READER BATCHED JCL              *  00180018
*                                                                     * 00210017
*  ENTRY POINT IEFVME (ATTACHED BY IEFVMA)                            * 00240017
*                                                                     * 00270017
*  INPUT       REG1 POINTS TO FOLLOWING FOUR WORD PARAMETER LIST      * 00279019
*               . ADDRESS OF PARM FIELD TO BE PASSED TO INTERPRETER   * 00288019
*               . ADDRESS OF CONSOLE ID FROM START COMMAND            * 00297019
*               . SUBPOOL AND AMOUNT OF STORAGE FOR INTERPRETER REGION* 00306019
*               . START ECB WHICH IS POSTED TO CAUSE IEFVME TO COME   * 00315019
*                 OUT OF WAIT                                         * 00324019
*               . RETURN ECB WHICH IS POSTED BY IEFVME TO INDICATE    * 00333019
*                 PROCESSING IS COMPLETE                              * 00342019
*    5.  THE 'RDRHRCHY' BIT IN THE 'STATSWTD' FIELD OF THE SSWA       * 00351019
*        INDICATES THE HIERARCHY IN WHICH THE INTERPRETER             * 00360019
*        IS TO RUN.(BIT = 1 MEANS HIERARCHY = 1)                      * 00369019
*                                                                     * 00378019
*  OPERATION   INITIALIZATION                                         * 00387019
*               . ACCESS ADDRESS OF INPUT PARAMETER LIST              * 00396019
*               . CLEARS START ECB                                    * 00405019
*               . WAITS ON START ECB                                  * 00414019
*              START ECB POSTED WITH A NON-ZERO POST CODE             * 00423019
*               . TERMINATES PROCESSING BY BRANCHING TO RETURN POINT  * 00432019
*              START ECB POSTED WITH A ZERO POST CODE                 * 00441019
*               . ISSUES A GETPART (GETMAIN IN SUBPOOL 247) FOR THE   * 00450019
*                 AMOUNT SPECIFIED IN INPUT PARAMETER LIST            * 00459019
*               . POINTS REGISTER 1 TO FIRST 2 WORDS OF INPUT         * 00468019
*                 PARAMETER LIST TO PASS TO IEFVMF                    * 00477019
*               . LINKS TO INTERPRETER INTERFACE ROUTINE IEFVMF       * 00486019
*               . ON RETURN, FREES ALL SUBPOOL 0 TO INSURE NO CORE IS * 00495019
*                 ALLOCATED WHEN FREEPART IS ISSUED                   * 00504019
*               . ISSUES FREEPART FOR REGION                          * 00513019
*               . TESTS RETURN CODE FOR A QUEUE FULL CONDITION        * 00522019
*               . IF NOT QUEUE FULL RETURN CODE, THE RETURN ECB IS    * 00531019
*                 POSTED WITH THE RETURN CODE RECEIVED                * 00540019
*               . THE START ECB IS THEN WAITED ON AGAIN               * 00549019
*               . IF A QUEUE FULL RETURN CODE, THE ADDRESS OF THE     * 00558019
*                 QUEUE MANAGER RESIDENT DATA AREA IS ACCESSED        * 00567019
*               . AND ENQ MACRO IS ISSUED TO GAIN EXCLUSIVE CONTROL OF* 00576019
*                 THE NO-SPACE ECB                                    * 00585019
*               . THE NO-SPACE ECB IS CLEARED TO REMOVE POST THAT     * 00594019
*                 OCCURRED WHEN INTERPRETER RELEASED THE INPUT QUEUE  * 00603019
*                 SPACE IT HAD USED FOR THE JOB BEING INTERPRETED     * 00612019
*                 WHEN THE QUEUE FULL CONDITION OCCURRED              * 00621019
*               . THE NO-SPACE ECB IS WAITED ON                       * 00630019
*               . AFTER THE NO-SPACE ECB IS POSTED, A DEQ IS ISSUED   * 00639019
*                 TO RELEASE CONTROL OF THE NO-SPACE ECB              * 00648019
*               . THE PROCESSING IS THEN REPEATED AS IF THE ORIGIONAL * 00657019
*                 POST OF THE START ECB HAD OCCURRED                  * 00666019
*                                                                     * 00675019
*  OUTPUT      NONE                                                   * 00684019
*                                                                     * 00693019
*  EXIT        RETURN                                                 * 00702019
*                                                                     * 00711019
*  TABLES      CVT, QMRCAR                                            * 00720019
*                                                                     * 00729019
*  ATTRIBUTES  READ-ONLY / REENTRANT                                  * 00738019
*                                                                     * 00747019
*  NOTE--------THIS MODULE MUST BE RESIDENT IN THE LINK PACK AREA     * 00756019
*              SINCE IT MUST BE ABLE TO ISSUE BOTH A GET & FREE       * 00765019
*              REGION SVC.                                            * 00774019
*                                                                     * 00810017
*********************************************************************** 00840017
         EJECT                                                          00860017
VMECVT   DSECT                                                          00880017
         CVT   SYS=VMS                                                  00900017
         EJECT                                                          00920017
QMRCAR   DSECT                                                          00940017
         IEFQMRES                                                       00960017
         EJECT                                                          00970018
         IEFVSSWA                                                       00980018
         TITLE 'IEFVME---GET A REGION FOR THE INTERPRETER---IEFVME'     01000017
IEFVME   CSECT                                                          02000017
*                                                                       03000017
*                                                                       10000017
         BALR  RB,0                ESTABLISH MODULE ADDRESSIBILITY      27000017
         USING *,RB                                                     28000017
         LR    R2,R1               SAVE INPUT POINTER                   29000017
         USING SSWA,R2             IEFVSSWA ADDRESSING                  29500018
         LR    R3,RE               SAVE RETURN TO ADDRESS               30000017
VME001   DS    0H                                                       31000017
         LA    R1,STARTECB         POINT TO START ECB                   32000018
         WAIT  1,ECB=(1)           WAIT FOR POST                        34000017
         LH    R4,STARTECB+2       LOAD POST CODE                19474  35000019
         XC    STARTECB,STARTECB   ZERO START  ECB                P3672 35010019
         LTR   R4,R4               A 0 PSOT CODE                        36000017
         BCR   7,R3                NO TERMINATE                  19474  37000019
VME002   DS    0H                                                       38000017
*                                                                       40000017
*  GET REGION FOR INTERPRETER                                           41000017
*                                                                       42000017
         L     R0,RDRREGON              R/I REG.SIZE AND SP ID   19474  42200019
         TM    STATSWTD,RDRHRCHY        IF HIERARCHY = 1           LCS  42400019
         BO    VME003                       ISSUE SPECIAL GETMAIN  LCS  42600019
*                                                                       42800019
* HIERARCHY 0 GETMAIN EXPANSION                                         43000019
*                                                                       43200019
         GETMAIN R,LV=(0),HIARCHY=0                                LCS  43400019
         B     VME004                                              LCS  43600019
VME003   DS    0H                                                  LCS  43800019
*                                                                       44000019
* HIERARCHY 1 GETMAIN EXPANSION                                         44200019
         GETMAIN R,LV=(0),HIARCHY=1                                LCS  44400019
VME004   DS    0H                                                  LCS  44600019
         LR    R4,R1                    SAVE REGION POINTER             44800019
         LR    R1,R2               POINT TO PARMS TO BE PASSED   19474  48800019
*                                  **NOTE THIS ROUTINE DOES NOT PROVIDE 49800019
*                                  A REGISTER SAVE AREA TO IEFVMF.  SO  50800019
*                                  IEFVMF MUST DESTROY REGISTERS 7,8,9  51800019
*                                  TO SAVE ITS INPUT VALUES BEFORE IT   52800019
*                                  CAN ISSUED A GETMAIN FOR A SAVE AREA 53800019
*                                  THEREFORE, THIS MODULE MUST NEVER    54800019
*                                  THESE REGISTERS TO BE SAVED OVER     55800019
*                                  THE LINK MACRO                       56800019
         LINK  EP=IEFVMF           LINK TO INTERPRETER MODULE    19474  57800019
         LR    R6,RF               SAVE RETURN CODE              19474  58800019
         FREEMAIN R,SP=0           FREE ALL OF SUBPOOL ZERO             61000017
         LR    R1,R4               POINT TO REGION                      62000017
         LA    R1,0(R1)            SET HIGH ORDER BIT OFF               63000017
         L     R0,RDRREGON         R/I REGION SIZE AND SUBPOOL ID (247) 64000018
         FREEMAIN R,LV=(0),A=(1)   FREE INTERPRETER REGION              65000017
         LA    R0,QFULRTN          TEST RETURN CODE FOR QUEUE FULL      67000017
         CR    R6,R0               A QUEUE FULL                         68000017
         BE    VME005              YES                                  69000017
         LR    R0,R6               SET POST CODE                 19474  70000019
         POST  RTNECB,(0)          POST IEFVMB * R/I IS DONE     19474  71000019
         B     VME001                                                   73000017
VME005   DS    0H                                                       74000017
*                                                                       75000017
*  A QUEUE FULL CONDITION OCCURRED WHEN THE INTERPRETER WAS MAKING      76000017
*  AN ENTRY INTO THE JOB QUEUE.  NOW ENTER A WAIT ON THE SPACE ECB      76400017
*  WHICH WILL BE POSTED WHEB QUEUE SPACE BECOMES FREE.                  76800017
*                                                                       77200017
         ENQ   MF=(E,IEFQASGB)         GET EXCLUSIVE CONTROL FF ECB     77600017
         L     R1,CVTPTR               FIND CVT POINTER                 78000017
         USING VMECVT,R1               CVT ADDRESSIBILITY               78400017
         L     R1,CVTJOB               ACCESS  MASTER QUEUE DATA AREA   78800017
         USING QMRCAR,R1                                                79200017
         XC    QMECBA,QMECBA       SET ECB TO WAIT FOR NEXT POST        79400017
         LA    R1,QMECBA                                                79600017
         DROP  R1                                                       80000017
         WAIT  1,ECB=(1)                                                80400017
         DEQ   MF=(E,IEFQASGB)         FREE RECSOURCE                   80800017
         B     VME002                                                   82000017
*                                                                       85000017
QFULRTN  EQU   12                                                       86000017
         DS    0D                                                       87000017
*  E N Q  -  D E Q   P A R A M E T E R   L I S T                        91000017
IEFQASGB ENQ   (IEFSQCBS,IEFQ3QCB,E,2,SYSTEM),MF=L                      94200017
IEFSQCBS DC    C'SYSIEFSD'                                              94300017
IEFQ3QCB DC    C'Q3'                                                    94400017
*                                                                       94500017
         END                                                            95000017
