         TITLE 'IHLMCIHP -- MONITOR CALL INTERRUPT HANDLER  (MP65)'     00200021
*********************************************************************** 00400021
*                                                                     * 00600021
* ROUTINE NAME --                                                     * 00800021
*    IHLMCIHP -- MONITOR CALL INTERRUPT HANDLER (MP65)                * 01000021
*                                                                     * 01200021
* STATUS --                                                           * 01400021
*    CHANGE LEVEL = 0                                                 * 01600021
*                                                                     * 01800021
* FUNCTION --                                                         * 02000021
*    THIS MODULE RECEIVES CONTROL FROM PFLIH ON ALL PROGRAM           * 02200021
*    INTERRUPTS AND ON ALL BRANCH TYPE HOOKS.                         * 02400021
*                                                                     * 02600021
*    FOR PROGRAM INTERRUPTS, IT FIRST DETERMINES IF THIS INTERRUPT    * 02800021
*    HAS OCCURRED DURING THE PROCESSING OF A HOOK BY EXAMINING THE    * 03000021
*    MONITOR IN CONTROL FLAG (CVTSTATE).  IF ON, THE MODULE SEARCHES  * 03200021
*    THE HCT QUEUE TO FIND THE HCT THAT WAS IN CONTROL WHEN THE       * 03400021
*    INTERRUPT OCCURRED.  THE ERROR RECOVERY MONITOR ASSOCIATED WITH  * 03600021
*    THAT HCT IS CALLED (LOCATED BY HCTRCOV FIELD).  THE ERROR        * 03800021
*    RECOVERY MONITOR WILL EVENTUALLY RETURN TO THE HOOK PROCESSING   * 04000021
*    THAT WAS INTERRUPTED.                                            * 04200021
*                                                                     * 04400021
*    IF THE MONITOR WAS NOT IN CONTROL, THIS ROUTINE DETERMINES WHAT  * 04600021
*    TYPE OF PROGRAM INTERRUPT HAS OCCURRED.  THERE ARE FOUR          * 04800021
*    POSSIBILITIES: REAL MC, EX-NOP, MC-NOP, AND OTHER PROGRAM        * 05000021
*    INTERRUPT.  THEY ARE IDENTIFIED BY THE FOLLOWING                 * 05200021
*    CHARACTERISTICS:                                                 * 05400021
*         REAL MC -- INTERRUPT CODE IN PIOPSW IS X'4000'.             * 05600021
*         EX-NOP -- INSTRUCTION LENGTH CODE IS 4 BYTES.               * 05800021
*              INTERRUPT CODE IS ILLEGAL OP CODE (X'0001').           * 06000021
*              INTERRUPTED INSTRUCTION IS EX OP CODE (X'44') WITH     * 06200021
*                  R1, X2, AND B2 FIELDS ZERO.                        * 06400021
*              TARGET OF EXECUTE IS MC OP CODE (X'AF').               * 06600021
*              EXECUTE IS FOLLOWED BY NOP (X'470XXXXX').              * 06800021
*         MC-NOP -- INSTRUCTION LENGTH CODE IS 4 BYTES.               * 07000021
*              INTERRUPT CODE IS ILLEGAL OP CODE (X'0001').           * 07200021
*              INTERRUPTED INSTRUCTION IS MC OP CODE (X'AF').         * 07400021
*              INTERRUPTED INSTRUCTION IS FOLLOWED                    * 07600021
*                  BY NOP (X'470XXXXX').                              * 07800021
*              THE LOW ORDER THREE BYTES OF THE MC INSTRUCTION ARE    * 08000021
*                  EQUAL TO THE LOW ORDER THREE BYTES OF THE NOP.     * 08200021
*         OTHER PROGRAM INTERRUPT -- NOT ONE OF THE ABOVE.            * 08400021
*                                                                     * 08600021
*    IF AN MC-NOP CONDITION IS DETECTED, THE CLASS DIGIT IS OBTAINED  * 08800021
*    FROM THE MC INSTRUCTION, MULTIPLIED BY 2, AND ADDED TO THE       * 09000021
*    SIMULATED CLASS MASK ADDRESS (CMTCMSK).  THIS IS THE ADDRESS     * 09200021
*    OF THE SIMULATED CLASS FOR THIS HOOK.  THIS VALUE IS THEN        * 09400021
*    STORED IN THE SECOND HALF OF THE MC INSTRUCTION AND THE FIRST    * 09600021
*    HALF IS CHANGED TO AN EXECUTE (X'4400').  IF THE ADDRESSED       * 09800021
*    CLASS WAS NOT ON IN THE CMT (I.E. IT CONTAINED A NOPR (X'0700'), * 10000021
*    EXIT IS TAKEN  FROM THIS ROUTINE (SEE BELOW).                    * 10200021
*                                                                     * 10400021
*    IF EITHER A REAL MC, AN EX-NOP OR AN MC-NOP WITH THE CLASS ON,   * 10600021
*    THE HCT QUEUE IS SEARCHED.  FOR EACH ACTIVE HCT (HIGH ORDER BIT  * 10800021
*    OF CHAIN FIELD THAT CONTAINS ITS ADDRESS IS ZERO), THE           * 11000021
*    CORRESPONDING ROUTER IS CALLED.  THIS IS LOCATED BY THE HCTROUT  * 11200021
*    FIELD OF THE HCT.                                                * 11400021
*                                                                     * 11600021
*    AFTER ALL ACTIVE HCT'S HAVE BEEN SEARCHED AND CALLED, RETURN     * 11800021
*    PROCESSING IS DONE.  IF THE CALLER IS NOT TOTALLY ENABLED,       * 12000021
*    RETURN IS MADE DIRECTLY BY A LPSW OF THE PIOPSW.  IF THE         * 12200021
*    NEW-OLD WORDS OF EITHER LOW CORE ARE NOT EQUAL, OR IF THE        * 12400021
*    FLIH-SPIN FLAG (FLRETFLG) IS ON, A TASK SWITCH IS REQUIRED AND   * 12600021
*    EXIT IS MADE THROUGH THE DISPATCHER (IEA0DS).  OTHERWISE,        * 12800021
*    THE AFFINITY AND LOCK BYTES (CVTAFFLK) ARE RESET AND RETURN IS   * 13000021
*    MADE BY A LPSW OF THE PIOPSW.                                    * 13200021
*                                                                     * 13400021
*    IF A HOOK INTERRUPT HAD NOT OCCURRED, RETURN IS MADE TO PFLIH.   * 13600021
*                                                                     * 13800021
*    WHEN A BRANCH TYPE HOOK OCCURS, THE OTHER ENTRY POINT IS GIVEN   * 14000021
*    CONTROL.  THE HCT QUEUE IS SEARCHED AND FOR EACH ACTIVE HCT, THE * 14200021
*    ROUTER ENTRY TO HANDLE BRANCH TYPE HOOKS IS CALLED.  THIS IS     * 14400021
*    LOCATED BY THE HCTROUTB FIELD.  WHEN CONTROL IS RETURNED FROM    * 14600021
*    THE ROUTER, THE RETURN CODE IS CHECKED.  A ZERO RETURN CODE      * 14800021
*    INDICATES THAT THE CLASS OF THE HOOK IS ON AND SO THE SEARCH     * 15000021
*    OF THE HCT QUEUE CONTINUES UNTIL THE END.  A CODE OF FOUR        * 15200021
*    INDICATES THAT THE CLASS WAS OFF AND SO THE SEARCHING IS         * 15400021
*    STOPPED AT THIS POINT AND RETURN IS MADE TO THE INSTRUCTION      * 15600021
*    FOLLOWING THE BRANCH HOOK.                                       * 15800021
*                                                                     * 16000021
* ENTRY POINTS --                                                     * 16200021
*         IHLMCIH -- PROGRAM INTERRUPT ENTRY POINT                    * 16400021
*                  PARAMETERS RECEIVED:                               * 16600021
*                      NONE                                           * 16800021
*                                                                     * 17000021
*         IHLBHOOK -- BRANCH TYPE HOOK ENTRY POINT                    * 17200021
*                  PARAMETERS RECEIVED:                               * 17400021
*                      R1 = ADDRESS OF NOP THAT CONTAINS HOOK ID.     * 17600021
*                           NOP HAS FORMAT X'470C0DDD' WHERE HOOK     * 17800021
*                           VALUE IS CDDD                             * 18000021
*                                                                     * 18200021
* INPUT --                                                            * 18400021
*    NONE                                                             * 18600021
*                                                                     * 18800021
* OUTPUT --                                                           * 19000021
*    NONE                                                             * 19200021
*                                                                     * 19400021
* EXTERNAL REFERENCES --                                              * 19600021
*         IHLROUTI -- HOOK INTERRUPT ENTRY POINT LOCATED BY           * 19800021
*              HCTROUT FIELD.                                         * 20000021
*                  PARAMETERS PASSED:                                 * 20200021
*                      R0  = ROUTER PARAMETER LIST ADDRESS            * 20400021
*                      R1  = HCT ADDRESS                              * 20600021
*                      R14 = RETURN ADDRESS                           * 20800021
*                                                                     * 21000021
*         IHLROUTB -- BRANCH HOOK ENTRY POINT LOCATED BY              * 21200021
*              HCTROUTB FIELD.                                        * 21400021
*                  PARAMETERS PASSED:                                 * 21600021
*                      R0  = HCT ADDRESS                              * 21800021
*                      R1  = ADDRESS OF NOP OF BRANCH TYPE HOOK       * 22000021
*                      R14 = RETURN ADDRESS                           * 22200021
*                                                                     * 22400021
*         IHLRCOV -- ERROR RECOVERY MONITOR LOCATED BY HCTRCOV        * 22600021
*              FIELD IN CURRENT HCT                                   * 22800021
*                  PARAMETERS PASSED:                                 * 23000021
*                      R1  = HCT ADDRESS                              * 23200021
*                                                                     * 23400021
*         IEA0DS -- DISPATCHER                                        * 23600021
*                  PARAMETERS PASSED:                                 * 23800021
*                      R0-R15 -- RESTORED TO VALUES AT INTERRUPT      * 24000021
*                                                                     * 24200021
* EXITS, NORMAL --                                                    * 24400021
*    FOR IHLMCIH:                                                     * 24600021
*         IF NO TASK SWITCH IS REQUIRED, RETURN TO INSTRUCTION AFTER  * 24800021
*              INTERRUPT.                                             * 25000021
*         IF TASK SWITCH IS REQUIRED, EXIT THROUGH DISPATCHER.        * 25200021
*                                                                     * 25400021
*    FOR IHLBHOOK:                                                    * 25600021
*         RETURN TO INSTRUCTION FOLLOWING BRANCH HOOK.                * 25800021
*                                                                     * 26000021
* EXITS, ERROR --                                                     * 26200021
*    NONE                                                             * 26400021
*                                                                     * 26600021
* TABLES / WORK AREAS --                                              * 26800021
*         ROUTER PARAMETER LIST                                       * 27000021
*              ****************************************************** * 27200021
*         +0   *   ADDRESS OF BRANCH ENTRY TO TIME RTN.  (IGC011A0) * * 27400021
*              ****************************************************** * 27600021
*         +4   *   ADDRESS OF SVC REGISTER SAVE AREA IN LOW CORE    * * 27800021
*              ****************************************************** * 28000021
*         +8   *   ADDRESS OF PI REGISTER SAVE AREA IN LOW CORE     * * 28200021
*              ****************************************************** * 28400021
*         +C   *   ADDRESS OF TNE CVT                               * * 28450021
*              ****************************************************** * 28500021
*                                                                     * 28600021
*    LOW CORE FIELDS:                                                 * 28800021
*         PIOPSW -- USED TO DETERMINE TYPE AND ADDRESS OF INTERRUPT   * 29000021
*         FLRETFLG -- FLIH-SPIN INTERRUPTED FLAG                      * 29200021
*         PREFIX2 -- USED TO FIND OTHER LOW CORE                      * 29400021
*         IEATCBP -- NEW-OLD WORDS (BOTH LOW CORES)                   * 29600021
*                                                                     * 29800021
*    CVT FIELDS:                                                      * 30000021
*         CVTSTATE -- USED TO DETERMINE IF MONITOR IS IN CONTROL      * 30200021
*         CVTGTF -- USED TO FIND CMT                                  * 30400021
*         CVTAFFLK -- AFFINITY AND LOCK BYTE                          * 30600021
*                                                                     * 30800021
*    CMT FIELDS:                                                      * 31000021
*         CMTCMSK -- USED TO CALCULATE CLASS ADDRESS FOR CHANGING     * 31200021
*              AF TO 44 (MC-NOP TO EX-NOP)                            * 31400021
*         CMTHCT -- USED TO FIND FIRST HCT ON QUEUE                   * 31600021
*         CMTHCTDA -- USED TO TEST IF FIRST HCT IS ACTIVE             * 31800021
*                                                                     * 32000021
*    HCT FIELDS:                                                      * 32200021
*         HCTNHCT -- USED TO FIND NEXT HCT ON QUEUE                   * 32400021
*         HCTNDAC -- USED TO TEST IF NEXT HCT IS ACTIVE               * 32600021
*         HCTROUT -- USED TO FIND IHLROUTI                            * 32800021
*         HCTROUTB -- USED TO FIND IHLROUTB                           * 33000021
*         HCTRCOV -- USED TO FIND IHLRCOV                             * 33200021
*         HCTNHCT -- USED TO FIND NEXT HCT ON QUEUE                   * 33400021
*         HCTINCTL -- USED TO TEST IF HCT IS IN CONTROL               * 33600021
*                                                                     * 33800021
* ATTRIBUTES --                                                       * 34000021
*    REFRESHABLE, DISABLED, PRIVILEGED, SERIALLY-REUSEABLE            * 34200021
*                                                                     * 34400021
* CHARACTER CODE DEPENDENCY --                                        * 34600021
*    NONE                                                             * 34800021
*                                                                     * 35000021
* NOTES --                                                            * 35200021
*    THIS MODULE IS FOR MP65 ONLY.                                    * 35400021
*                                                                     * 35600021
*********************************************************************** 36400021
         EJECT                                                          36600021
*********************************************************************** 36800021
*        MODULE THAT HANDLES REAL, SIMULATED AND BRANCH HOOKS (MP65)  * 37000021
*********************************************************************** 37200021
IHLMCIHP CSECT                                                          37400021
*A000000-999999                                                  S21014 37450021
*C844500,845600                                                   M0817 37460021
*C894000                                                          M0817 37470021
*D930500                                                          M1329 37500021
*A926500                                                          M1329 37550021
*********************************************************************** 37600021
*        CVT MAPPING                                                  * 37800021
*********************************************************************** 38000021
CVTSECT  DSECT                                                          38200021
         CVT                                                            38400021
         EJECT                                                          38600021
*********************************************************************** 38800021
*        HOOK CONTROL TABLE MAPPING  (HCT)                            * 39000021
*********************************************************************** 39200021
         HCT                                                            39400021
         EJECT                                                          39600021
*********************************************************************** 39800021
*        CLASS MASK TABLE MAPPING  (CMT)                              * 40000021
*********************************************************************** 40200021
         CMT                                                            40400021
         EJECT                                                          40600021
*********************************************************************** 40800021
*        LOW CORE MAPPING                                             * 41000021
*********************************************************************** 41200021
         IEAQFX  65,SERP,1                                              41400021
         EJECT                                                          41600021
*********************************************************************** 41800021
*        M65MP CVT MAPPING                                            * 42000021
*********************************************************************** 42200021
         MPCVT                                                          42400021
         EJECT                                                          42600021
*********************************************************************** 42800021
*        ENTRY POINT FOR ALL PROGRAM INTERRUPTS                       * 43000021
*********************************************************************** 43200021
IHLMCIHP CSECT                                                          43400021
         ENTRY IHLMCIH                  NORMAL HOOK EP (REAL & SIMULTD) 43600021
         ENTRY IHLBHOOK                 BRANCH TYPE HOOK EP             43800021
TCBGRS   EQU   48                       TCB REGISTER SAVE AREA          44000021
RBOPSW   EQU   16                       PGM OLD PSW SAVED IN RB         44200021
TCBRBP   EQU   0                        ADDRESS OF CURRENT RB IN TCB    44400021
IHLPARM  EQU   0                        PARAMETER FIELD ADDRESS.        44600021
IHLHCTR  EQU   1                        HOOK CONTROL TABLE              44800021
IHLCMTR  EQU   1                        CMT ADDR                        45000021
IHLNHK   EQU   2                        NOT HOOK ADDR                   45200021
IHLCVT   EQU   3                        CVT ADDR                        45400021
IHLWK1   EQU   4                        WORK REG                        45600021
IHLWK2   EQU   5                        WORK REG                        45800021
IHLWK3   EQU   6                        WORK REG                        46000021
IHLSAVE  EQU   7                        REG TO SAVE PFLIH RETURN ADDR   46200021
IHLBASE  EQU   8                        BASE REG FOR THIS PROGRAM       46400021
IHLSREG  EQU   9                        PFLIH SAVE AREA                 46600021
IHLRE    EQU   14                       LINKAGE REG RETURN              46800021
IHLRF    EQU   15                       LINKAGE REG BRANCH              47000021
IHLR0    EQU   0                        LINKAGE REG FOR BRANCH HOOK     47200021
IHLR1    EQU   1                        LINKAGE REG FOR BRANCH HOOK     47400021
IHLILINT EQU   X'01'                    ILLEGAL OP INTERRUPT CODE       47600021
IHLMCINT EQU   X'40'                    MONITOR CALL INTERRUPT CODE     47800021
IHLMCOP  EQU   X'AF'                    MONITOR CALL OP-CODE            48000021
IHLEXOP  EQU   X'44'                    EXECUTE OP-CODE                 48200021
IHLNOPOP EQU   X'47'                    NOP OP-CODE, IF ZERO MASK       48400021
IHLZBASE EQU   X'F0'                    TM MASK FOR ZERO BASE TEST      48600021
IHLZMASK EQU   X'F0'                    TM MASK FOR ZERO MASK TEST      48800021
IHLPILC1 EQU   X'80'                    ICL BIT 1 IN PIOPSW             49000021
IHLPILC2 EQU   X'40'                    ILC BIT 2 IN PIOPSW             49200021
ENABLED  EQU   X'FF'                    TOTALLY ENABLED MASK            49400021
IHLPIILC EQU   X'C0'                    INSTRUCTION LENGTH IN PIPSW     49450021
         EJECT                                                          49600021
*********************************************************************** 49800021
*        ENTRY FOR NORMAL HOOKS OR RECURSION                          * 50000021
*********************************************************************** 50200021
IHLMCIH  EQU   *                        NORMAL HOOK ENTRY POINT         50400021
         LR    IHLBASE,IHLRF            ADDRESSIBILITY                  50600021
         USING IHLMCIH,IHLBASE                                          50800021
         LR    IHLSAVE,IHLRE            SAVE PFLIH RETURN ADDR          51000021
         L     IHLCVT,CVTCON            CVT ADDR                        51200021
         USING CVTSECT,IHLCVT           CVT ADDRESSIBILITY              51400021
         L     IHLCMTR,CVTGTF           GET CMT ADDR                    51600021
         SPACE                                                          51800021
*********************************************************************** 52000021
*        CHECK FOR PGM CHECK DURING HOOK PROCESSING                   * 52200021
*********************************************************************** 52400021
         TM    CVTGTFST,CVTSTATE        IS THIS PGMCHK DURING HOOK      52600021
         BZ    IHLNOTRE                 NO, CONTINUE NORMALLY           52800021
         EJECT                                                          53000021
*********************************************************************** 53200021
*        RECURSION INTO PFLIH DURING HOOK PROCESSING                  * 53400021
*********************************************************************** 53600021
*        LR    IHLHCTR,IHLCMTR          MAKE CMTHCT LOOK LIKE HCTNHCT   53800021
IHLRCTST EQU   *                        LOOK AT HCT ADDR                54000021
         USING HCT,IHLHCTR              ADDRESSIBILITY FOR HCT          54200021
         L     IHLHCTR,HCTNHCT          GET NEXT HCT ADDR               54400021
         LTR   IHLHCTR,IHLHCTR          IS THIS HCT ACTIVE              54600021
         BM    IHLRCTST                 NO TRY NEXT HCT                 54800021
         TM    HCTFLG1,HCTINCTL         IS THIS HCT IN CONTROL          55000021
         BZ    IHLRCTST                 NO, TRY NEXT HCT                55200021
         L     IHLRF,HCTRCOV            GET ERROR RECOVERY ADDR         55400021
         BR    IHLRF                    GO TO ERROR RECOVERY MONTR      55600021
         DROP  IHLHCTR                                                  55800021
         EJECT                                                          56000021
*********************************************************************** 56200021
*        POTENTIAL HOOK MUST BE CHECKED TO SEE IF REALLY HOOK         * 56400021
*        FOUR CASES: REAL MC INTERRUPT, EX-NOP, AF-NOP, OTHER PGMCHK  * 56600021
*********************************************************************** 56800021
         USING CMT,IHLCMTR                                              57000021
IHLNOTRE EQU   *                        NOT RECURSION DURING HOOK       57200021
         L     IHLSREG,IHLCON1          GET POINTER TO PFLIH REGS       57400021
*********************************************************************** 57600021
*        CHECK FOR REAL MC INTERRUPT                                  * 57800021
*********************************************************************** 58000021
         LA    IHLNHK,IHLNOHOK          ADDR OF BRANCH IF NOT HOOK      58050021
         TM    PIOPSW+3,IHLMCINT        IS REAL MC INTERRUPT            58200021
         BZ    IHLNOTMC                 NO, CHECK FOR SIMULATED MC      58500021
         TM    PIOPSW+4,IHLPIILC        MAYBE, CHECK FOR ZERO LENGTH    58550021
         BC    7,IHLCALLR               NONZERO LEN, REAL MC            58560021
         BR    IHLNHK                   ZERO LEN, IMPRECISE INTERRUPT   58570021
         SPACE                                                          58600021
*********************************************************************** 58800021
*        CHECK FOR EX-NOP AND AF-NOP                                  * 59000021
*********************************************************************** 59200021
IHLNOTMC EQU   *                        INTERRUPT IS NOT A REAL MC      59250021
         TM    PIOPSW+4,IHLPILC1        IS ILC=2 OR 3                   59600021
         BCR   8,IHLNHK                 NO, NOT HOOK                    59800021
         TM    PIOPSW+4,IHLPILC2        IS ILC=2                        60000021
         BCR   1,IHLNHK                 NO, NOT HOOK                    60200021
         CLI   PIOPSW+3,IHLILINT        IS IT ILLEGAL OP                60400021
         BCR   7,IHLNHK                 NO, NOT HOOK                    60600021
         L     IHLWK1,PIOPSW+4          ADDR FROM PI OPSW               60800021
         SL    IHLWK1,IHLC4             YIELDS ADDR OF EX OR MC         61000021
         CLC   0(2,IHLWK1),IHLEX00      DOES IT POINT TO EXECUTE        61200021
         BE    IHLEXNOP                 YES, CHECK VALID EX             61400021
         SPACE                                                          61600021
*********************************************************************** 61800021
*        CHECK FOR AF-NOP, AND IF SO, CHANGE TO EX-NOP                * 62000021
*********************************************************************** 62200021
         CLI   0(IHLWK1),IHLMCOP        IS IT AF OP-CODE                62400021
         BCR   7,IHLNHK                 NO, NOT HOOK                    62600021
         CLI   4(IHLWK1),IHLNOPOP       FOLLOWED BY POTENTIAL NOP       62800021
         BCR   7,IHLNHK                 NO, NOT HOOK                    63000021
         TM    5(IHLWK1),IHLZMASK       IS PTENTIAL NOP REAL NOP        63200021
         BCR   7,IHLNHK                 NO, NOT HOOK                    63400021
         CLC   1(3,IHLWK1),5(IHLWK1)    AF HOOKID EQUAL NOP HOOKID      63600021
         BCR   7,IHLNHK                 NOT EQUAL. NOT A HOOK.          63800021
         SR    IHLWK2,IHLWK2            ZERO WORK REG                   64000021
         IC    IHLWK2,1(IHLWK1)         GET CLASS OF HOOK               64200021
         SLA   IHLWK2,1                 MULTIPLY CLASS BY 2             64400021
         LA    IHLWK2,CMTCMSK(IHLWK2)   CALCULATE CLASSMASK ADDR        64600021
         MVC   0(2,IHLWK1),IHLEX00      SET UP FIRST HALF OF EX INST    64800021
         STH   IHLWK2,2(IHLWK1)         PUT CLASSMASK ADDR IN EX        65000021
         CLI   0(IHLWK2),IHLMCOP        IS CLASS ON                     65200021
         BNE   IHLRETRN                 NO GO TO RETURN                 65400021
         B     IHLCALLR                 YES,GO TO CALL ROUTER           65600021
         SPACE                                                          65800021
*********************************************************************** 66000021
*        CHECK FOR EX-NOP                                             * 66200021
*********************************************************************** 66400021
IHLEXNOP EQU   *                        POTENTIAL EX-NOP                66600021
         TM    2(IHLWK1),IHLZBASE       IS BASE ZERO                    66800021
         BCR   7,IHLNHK                 NO, NOT HOOK                    67000021
         LH    IHLWK2,2(IHLWK1)         GET TARGET OF EXECUTE           67200021
         CLI   0(IHLWK2),IHLMCOP        IS IT AF OP-CODE                67400021
         BCR   7,IHLNHK                 NO, NOT HOOK                    67600021
         CLI   4(IHLWK1),IHLNOPOP       FOLLOWED BY POTENTIAL NOP       67800021
         BCR   7,IHLNHK                 NO, NOT HOOK                    68000021
         TM    5(IHLWK1),IHLZMASK       IS POTENTIAL NOP REAL NOP       68200021
         BCR   7,IHLNHK                 NO, NOT HOOK                    68400021
         EJECT                                                          68600021
*********************************************************************** 68800021
*        ALL HOOKS WILL CALL ROUTER ADDR OF ALL ACTIVE HCT'S          * 69000021
*********************************************************************** 69200021
         DROP  IHLCMTR                                                  69400021
IHLCALLR EQU   *                        SEARCH HCT CHAIN                69600021
*        LR    IHLHCTR,IHLCMTR          MAKE CMTHCT LOOK LIKE HCTNHCT   69800021
IHLTESTH EQU   *                        LOOK DOWN HCT CHAIN             70000021
         USING HCT,IHLHCTR              ADDRESSIBILITY FOR HCT          70200021
         L     IHLHCTR,HCTNHCT          GET NEXT HCT ADDR               70400021
         LTR   IHLHCTR,IHLHCTR          CHECK HCT ADDR                  70600021
         BZ    IHLRETRN                 ZERO, NO MORE HCT'S             70800021
         BM    IHLTESTH                 NEG, INACTIVE HCT TRY NEXT      71000021
         SPACE                                                          71200021
*********************************************************************** 71400021
*        ROUTER IS TO BE CALLED FOR AN HCT                            * 71600021
*********************************************************************** 71800021
         LA    IHLPARM,IHLPLIST         SET PARAMETER LIST POINTER.     72000021
         L     IHLRF,HCTROUT            GET ROUTER ADDR                 72200021
         BALR  IHLRE,IHLRF              GO TO PROCESS HOOK              72400021
         B     IHLTESTH                 GO TO CHECK NEXT HCT            72600021
         DROP  IHLHCTR                                                  72800021
         EJECT                                                          73000021
*********************************************************************** 73200021
*        RETURN AFTER HOOK DIRECTLY IF CALLER DISABLED,               * 73400021
*        CHECK FOR TASK SWITCH IF CALLER TOTALLY ENABLED              * 73600021
*********************************************************************** 73800021
IHLRETRN EQU   *                        HOOK PROCESSING FINISHED        74000021
         CLI   PIOPSW,ENABLED           IS PSW TOTALLY ENABLED          74200021
         BNE   IHLDIRCT                 NO, RETURN DIRECTLY TO PGM      74400021
         L     IHLWK1,IEATCBP+4         DETERMINE IF A TASK SWITCH      74600021
         C     IHLWK1,IEATCBP           IS REQUIRED                     74800021
         BNE   IHLTSWCH                 YES, BRANCH                     75000021
         L     IHLWK3,PREFIX2           GET PREFIX ADDR                 75200021
         L     IHLWK2,IEATCBP-IEAQFX00(IHLWK3)   CURRENT TCB2           75400021
         C     IHLWK2,IEATCBP+4-IEAQFX00(IHLWK3)   IS TASK SWITCH REQ   75600021
         BNE   IHLTSWCH                 YES, GO TO TASK SWITCH CODE     75800021
         TM    FLRETFLG,X'FF'           WAS FLIH-SPIN INTERRUPTED       76000021
         BNZ   IHLTSWCH                 YES, TASK SWITCH                76200021
         L     IHLWK3,MPCVTPTR          BASE FOR M65MP CVT              76400021
         USING IEAMPCVT,IHLWK3                                          76600021
         XC    CVTAFFLK(2),CVTAFFLK     CLEAR AFFIN & LOCK              76800021
         DROP  IHLWK3                                                   77000021
         SPACE                                                          77200021
*********************************************************************** 77400021
*        DIRECT RETURN WHEN NO TASK SWITCH IS REQUIRED                * 77600021
*********************************************************************** 77800021
IHLDIRCT EQU   *                        RETURN WHEN NO TASK SWITCH      78000021
         LM    0,15,0(IHLSREG)          RESTORE REGS FROM LOW CORE      78200021
         LPSW  PIOPSW                   RETURN AFTER HOOK               78400021
         SPACE                                                          78600021
*********************************************************************** 78800021
*        EXIT THROUGH DISPATCHER IF TASK SWITCH IS REQUIRED           * 79000021
*********************************************************************** 79200021
IHLTSWCH EQU   *                        DISP MUST BE CALLED             79400021
         L     IHLWK2,TCBRBP(0,IHLWK1)  GET CURRENT TCB                 79600021
         MVC   RBOPSW(8,IHLWK2),PIOPSW  MOVE PGM OLD PSW INTO RB        79800021
         MVC   TCBGRS(64,IHLWK1),0(IHLSREG)  SAVE REGS IN TCB           80000021
         LM    0,15,0(IHLSREG)          RESTORE REGS FROM LOW CORE      80200021
         BALR  14,0                     RE-ESTABLISH                    80400021
         USING *,14                     ADDRESSIBILITY                  80600021
         L     IHLRF,IHLCON2            GET DISPATCHER ADDRESS          80800021
         BR    IHLRF                    GO TO DISPATCHER                81000021
         DROP  14                                                       81200021
         DROP  IHLCVT                                                   81400021
         SPACE                                                          81600021
*********************************************************************** 81800021
*        NOT A HOOK, SO RETURN TO PFLIH AFTER RESTORING REGS          * 82000021
*********************************************************************** 82200021
IHLNOHOK EQU   *                        NOT A HOOK INTERRUPT            82400021
         LR    IHLRE,IHLSAVE            RESTORE PFLIH RETURN ADDR       82600021
         LM    0,9,0(IHLSREG)           RESTORE REGS THAT WERE USED     82800021
         BR    IHLRE                    RETURN TO PFLIH                 83000021
         EJECT                                                          83200021
*********************************************************************** 83400021
*        THIS SECTION HANDLES BRANCH HOOKS AND MUST NOT CHANGE        * 83600021
*        REGISTERS 2-13.  REGS 0,14,15 ARE VOLITLE AND REG 1 IS       * 83800021
*        THE RETURN ADDR (ALSO THE NOP ADDR THAT CARRIES HOOK ID)     * 84000021
*********************************************************************** 84200021
IHLBHOOK EQU   *                        BRANCH HOOK BRANCHES HERE       84400021
         SLL   IHLRE,24                 LOCK TO HI BYTE IF SSM   M0817  84450021
         LA    IHLR1,0(IHLR1)           CLEAR HI BYTE OF R1      M0817  84500021
         OR    IHLR1,IHLRE              LOCK TO HI BYTE IF SSM   M0817  84550021
IHLBHK   EQU   *                                                 M0817  84560021
         BALR  IHLRE,0                  SET UP ADDRESSIBILITY           84600021
         USING *,IHLRE                                                  84800021
         L     IHLRF,CVTCON             CVT BASE ADDR                   85000021
         USING CVTSECT,IHLRF            ADDRESSIBILITY FOR CVT          85200021
         L     IHLRF,CVTGTF             GET CMT ADDR                    85400021
         USING CMT,IHLRF                ADDRESSIBILITY FOR CMT          85600021
*        LR    IHLRF,IHLRF              MAKE CMTHCT LOOK LIKE HCTNHCT   85800021
IHLBRTST EQU   *                        LOOK AT HCT                     86000021
         USING HCT,IHLRF                ADDRESSIBILITY FOR HCT          86200021
         L     IHLRF,HCTNHCT            GET NEXT HCT ADDR               86400021
         LTR   IHLRF,IHLRF              TEST HCT ADDR                   86600021
         BCR   8,IHLR1                  IF ZERO, NO MONITOR             86800021
         BM    IHLBRTST                 IF NEGITIVE, INACTIVE HCT       87000021
         SPACE                                                          87200021
*********************************************************************** 87400021
*        ROUTER (BRANCH ENTRY) IS TO BE CALLED FOR THIS HCT           * 87600021
*********************************************************************** 87800021
         LR    IHLR0,IHLRF              SAVE HCT ADDR FOR ROUTER        88000021
         L     IHLRF,HCTROUTB           ROUTER ADDR FOR BRANCH MC       88200021
         DROP  IHLRF                                                    88400021
IHLBCALL EQU   *                                                        88600021
         BALR  IHLRE,IHLRF              GO TO ROUTER BRANCH EP          88800021
         LTR   IHLRF,IHLRF              WAS CLASS OFF                   89000021
         BCR   7,IHLR1                  YES, RETURN- DONT SEARCH MORE   89200021
         LA    IHLRF,IHLBCALL-IHLBHK    NO, RESTORE              M0817  89400021
         SR    IHLRE,IHLRF              ADDRESSIBILITY                  89600021
         LR    IHLRF,IHLR0              RESTORE HCT ADDR                89800021
         USING HCT,IHLRF                REESTABLISH HCT ADDRESSIBILITY  90000021
         B     IHLBRTST                 CONTINUE SEARCH                 90200021
         DROP  IHLRF                                                    90400021
         EJECT                                                          90600021
*********************************************************************** 90800021
*        CONSTANTS AND PARM LIST FOR ROUTER                           * 91000021
*********************************************************************** 91200021
IHLEX00  DC    X'4400'                  1ST HALF OF EXECUTE INSTR       91400021
IHLC4    DC    F'4'                     CONSTANT 4                      91600021
         SPACE                                                          91800021
IHLPLIST DS    0XL16                    PARM LIST TO ROUTER             92000021
IHLTIMBR DC    V(IGC011A0)              TIME ROUTINE BRANCH ADDR        92200021
         DC    V(IEASCSAV)              SVC SAVE AREA IN LOW CORE       92400021
IHLCON1  DC    V(IEAPKSAV)              PI SAVE AREA IN LOW CORE        92600021
CVTCON   DC    V(IEACVT)                CVT ADDRESS               M1329 92650021
         SPACE                                                          92800021
IHLCON2  DC    V(IEA0DS)                DISPATCHER ADDRESS              93000021
         END                                                            93200021
