         TITLE 'IHLMCIHV -- MONITOR CALL INTERRUPT HANDLER  (MVT)'      00200021
*********************************************************************** 00729521
*                                                                     * 00746221
* ROUTINE NAME --                                                     * 00800021
*    IHLMCIHV -- MONITOR CALL INTERRUPT HANDLER (MVT)                 * 01000021
*                                                                     * 01200021
* STATUS --                                                           * 01400021
*    CHANGE LEVEL = 0                                                 * 01600021
*                                                                     * 01800021
* FUNCTION --                                                         * 02000021
*    THIS MODULE RECEIVES CONTROL FROM PFLIH ON ALL PROGRAM           * 02200021
*    INTERRUPTS AND ON ALL BRANCH TYPE HOOKS.                         * 02400021
*                                                                     * 02600021
*    FOR PROGRAM INTERRUPTS, IT FIRST DETERMINES IF THIS INTERRUPT    * 02800021
*    HAS OCCURRED DURING THE PROCESSING OF A HOOK BY EXAMINING THE    * 03000021
*    MONITOR IN CONTROL FLAG (CVTSTATE).  IF ON, THE MODULE SEARCHES  * 03200021
*    THE HCT QUEUE TO FIND THE HCT THAT WAS IN CONTROL WHEN THE       * 03400021
*    INTERRUPT OCCURRED.  THE ERROR RECOVERY MONITOR ASSOCIATED WITH  * 03600021
*    THAT HCT IS CALLED (LOCATED BY HCTRCOV FIELD).  THE ERROR        * 03800021
*    RECOVERY MONITOR WILL EVENTUALLY RETURN TO THE HOOK PROCESSING   * 04000021
*    THAT WAS INTERRUPTED.                                            * 04200021
*                                                                     * 04400021
*    IF THE MONITOR WAS NOT IN CONTROL, THIS ROUTINE DETERMINES WHAT  * 04600021
*    TYPE OF PROGRAM INTERRUPT HAS OCCURRED.  THERE ARE FOUR          * 04800021
*    POSSIBILITIES: REAL MC, EX-NOP, MC-NOP, AND OTHER PROGRAM        * 05000021
*    INTERRUPT.  THEY ARE IDENTIFIED BY THE FOLLOWING                 * 05200021
*    CHARACTERISTICS:                                                 * 05400021
*         REAL MC -- INTERRUPT CODE IN PIOPSW IS X'4000'.             * 05600021
*         EX-NOP -- INSTRUCTION LENGTH CODE IS 4 BYTES.               * 05800021
*              INTERRUPT CODE IS ILLEGAL OP CODE (X'0001').           * 06000021
*              INTERRUPTED INSTRUCTION IS EX OP CODE (X'44') WITH     * 06200021
*                  R1, X2, AND B2 FIELDS ZERO.                        * 06400021
*              TARGET OF EXECUTE IS MC OP CODE (X'AF').               * 06600021
*              EXECUTE IS FOLLOWED BY NOP (X'470XXXXX').              * 06800021
*         MC-NOP -- INSTRUCTION LENGTH CODE IS 4 BYTES.               * 07000021
*              INTERRUPT CODE IS ILLEGAL OP CODE (X'0001').           * 07200021
*              INTERRUPTED INSTRUCTION IS MC OP CODE (X'AF').         * 07400021
*              INTERRUPTED INSTRUCTION IS FOLLOWED                    * 07600021
*                  BY NOP (X'470XXXXX').                              * 07800021
*              THE LOW ORDER THREE BYTES OF THE MC INSTRUCTION ARE    * 08000021
*                  EQUAL TO THE LOW ORDER THREE BYTES OF THE NOP.     * 08200021
*         OTHER PROGRAM INTERRUPT -- NOT ONE OF THE ABOVE.            * 08400021
*                                                                     * 08600021
*    IF AN MC-NOP CONDITION IS DETECTED, THE CLASS DIGIT IS OBTAINED  * 08800021
*    FROM THE MC INSTRUCTION, MULTIPLIED BY 2, AND ADDED TO THE       * 09000021
*    SIMULATED CLASS MASK ADDRESS (CMTCMSK).  THIS IS THE ADDRESS     * 09200021
*    OF THE SIMULATED CLASS FOR THIS HOOK.  THIS VALUE IS THEN        * 09400021
*    STORED IN THE SECOND HALF OF THE MC INSTRUCTION AND THE FIRST    * 09600021
*    HALF IS CHANGED TO AN EXECUTE (X'4400').  IF THE ADDRESSED       * 09800021
*    CLASS WAS NOT ON IN THE CMT (I.E. IT CONTAINED A NOPR (X'0700'), * 10000021
*    EXIT IS TAKEN  FROM THIS ROUTINE (SEE BELOW) ).                  * 10200021
*                                                                     * 10400021
*    IF EITHER A REAL MC, AN EX-NOP OR AN MC-NOP WITH THE CLASS ON,   * 10600021
*    THE HCT QUEUE IS SEARCHED.  FOR EACH ACTIVE HCT (HIGH ORDER BIT  * 10800021
*    OF CHAIN FIELD THAT CONTAINS ITS ADDRESS IS ZERO), THE           * 11000021
*    CORRESPONDING ROUTER IS CALLED.  THIS IS LOCATED BY THE HCTROUT  * 11200021
*    FIELD OF THE HCT.                                                * 11400021
*                                                                     * 11600021
*    AFTER ALL ACTIVE HCT'S HAVE BEEN SEARCHED AND CALLED, RETURN     * 11800021
*    PROCESSING IS DONE.  IF THE CALLER IS NOT TOTALLY ENABLED,       * 12000021
*    RETURN IS MADE DIRECTLY BY A LPSW OF THE PIOPSW.  IF THE         * 12200021
*    NEW-OLD WORDS POINTED TO BY THE CVT ARE NOT EQUAL, A TASK        * 12400021
*    SWITCH IS REQUIRED AND EXIT IS MADE THROUGH THE DISPATCHER       * 12600021
*    (IEA0DS).  OTHERWISE, CONTROL IS RETURNED DIRECTLY AS ABOVE.     * 12800021
*                                                                     * 13000021
*    IF A HOOK INTERRUPT HAD NOT OCCURRED, RETURN IS MADE TO PFLIH.   * 13200021
*                                                                     * 13400021
*    WHEN A BRANCH TYPE HOOK OCCURS, THE OTHER ENTRY POINT IS GIVEN   * 13600021
*    CONTROL.  THE HCT QUEUE IS SEARCHED AND FOR EACH ACTIVE HCT, THE * 13800021
*    ROUTER ENTRY TO HANDLE BRANCH TYPE HOOKS IS CALLED.  THIS IS     * 14000021
*    LOCATED BY THE HCTROUTB FIELD.  WHEN CONTROL IS RETURNED FROM    * 14200021
*    THE ROUTER, THE RETURN CODE IS CHECKED.  A ZERO RETURN CODE      * 14400021
*    INDICATES THAT THE CLASS OF THE HOOK IS ON AND SO THE SEARCH     * 14600021
*    OF THE HCT QUEUE CONTINUES UNTIL THE END.  A CODE OF FOUR        * 14800021
*    INDICATES THAT THE CLASS WAS OFF AND SO THE SEARCHING IS         * 15000021
*    STOPPED AT THIS POINT AND RETURN IS MADE TO THE INSTRUCTION      * 15200021
*    FOLLOWING THE BRANCH HOOK.                                       * 15400021
*                                                                     * 15600021
* ENTRY POINTS --                                                     * 15800021
*         IHLMCIH -- PROGRAM INTERRUPT ENTRY POINT                    * 16000021
*                  PARAMETERS RECEIVED:                               * 16200021
*                      NONE                                           * 16400021
*                                                                     * 16600021
*         IHLBHOOK -- BRANCH TYPE HOOK ENTRY POINT                    * 16800021
*                  PARAMETERS RECEIVED:                               * 17000021
*                      R1 = ADDRESS OF NOP THAT CONTAINS HOOK ID.     * 17200021
*                           NOP HAS FORMAT X'470C0DDD' WHERE HOOK     * 17400021
*                           VALUE IS CDDD                             * 17600021
*                                                                     * 17800021
* INPUT --                                                            * 18000021
*    NONE                                                             * 18200021
*                                                                     * 18400021
* OUTPUT --                                                           * 18600021
*    NONE                                                             * 18800021
*                                                                     * 19000021
* EXTERNAL REFERENCES --                                              * 19200021
*         IHLROUTI -- HOOK INTERRUPT ENTRY POINT LOCATED BY           * 19400021
*              HCTROUT FIELD.                                         * 19600021
*                  PARAMETERS PASSED:                                 * 19800021
*                      R0  = ROUTER PARAMETER LIST ADDRESS            * 20000021
*                      R1  = HCT ADDRESS                              * 20200021
*                      R14 = RETURN ADDRESS                           * 20400021
*                                                                     * 20600021
*         IHLROUTB -- BRANCH HOOK ENTRY POINT LOCATED BY              * 20800021
*              HCTROUTB FIELD.                                        * 21000021
*                  PARAMETERS PASSED:                                 * 21200021
*                      R0  = HCT ADDRESS                              * 21400021
*                      R1  = ADDRESS OF NOP OF BRANCH TYPE HOOK       * 21600021
*                      R14 = RETURN ADDRESS                           * 21800021
*                                                                     * 22000021
*         IHLRCOV -- ERROR RECOVERY MONITOR LOCATED BY HCTRCOV        * 22200021
*              FIELD IN CURRENT HCT                                   * 22400021
*                  PARAMETERS PASSED:                                 * 22600021
*                      R1  = HCT ADDRESS                              * 22800021
*                                                                     * 23000021
*         IEA0DS -- DISPATCHER                                        * 23200021
*                  PARAMETERS PASSED:                                 * 23400021
*                      R0-R15 -- RESTORED TO VALUES AT INTERRUPT      * 23600021
*                                                                     * 23800021
* EXITS, NORMAL --                                                    * 24000021
*    FOR IHLMCIH:                                                     * 24200021
*         IF NO TASK SWITCH IS REQUIRED, RETURN TO INSTRUCTION AFTER  * 24400021
*              INTERRUPT.                                             * 24600021
*         IF TASK SWITCH IS REQUIRED, EXIT THROUGH DISPATCHER.        * 24800021
*                                                                     * 25000021
*    FOR IHLBHOOK:                                                    * 25200021
*         RETURN TO INSTRUCTION FOLLOWING BRANCH HOOK.                * 25400021
*                                                                     * 25600021
* EXITS, ERROR --                                                     * 25800021
*    NONE                                                             * 26000021
*                                                                     * 26200021
* TABLES / WORK AREAS --                                              * 26400021
*         ROUTER PARAMETER LIST                                       * 26600021
*              ****************************************************** * 26800021
*         +0   *   ADDRESS OF BRANCH ENTRY TO TIME RTN.  (IGC011A0) * * 27000021
*              ****************************************************** * 27200021
*         +4   *   ADDRESS OF SVC REGISTER SAVE AREA IN LOW CORE    * * 27400021
*              ****************************************************** * 27600021
*         +8   *   ADDRESS OF PI REGISTER SAVE AREA IN LOW CORE     * * 27800021
*              ****************************************************** * 28000021
*         +C   *   ADDRESS OF THE CVT                               * * 28050021
*              ****************************************************** * 28100021
*                                                                     * 28200021
*    LOW CORE FIELDS:                                                 * 28400021
*         PIOPSW -- USED TO DETERMINE TYPE AND ADDRESS OF INTERRUPT   * 28600021
*                                                                     * 28800021
*    CVT FIELDS:                                                      * 29000021
*         CVTSTATE -- USED TO DETERMINE IF MONITOR IS IN CONTROL      * 29200021
*         CVTGTF -- USED TO FIND CMT                                  * 29400021
*         CVTTCBP -- USED TO FIND NEW-OLD WORDS FOR TASK SWITCH TEST  * 29600021
*                                                                     * 29800021
*    CMT FIELDS:                                                      * 30000021
*         CMTCMSK -- USED TO CALCULATE CLASS ADDRESS FOR CHANGING     * 30200021
*              AF TO 44 (MC-NOP TO EX-NOP)                            * 30400021
*         CMTHCT -- USED TO FIND FIRST HCT ON QUEUE                   * 30600021
*         CMTHCTDA -- USED TO TEST IF FIRST HCT IS ACTIVE             * 30800021
*                                                                     * 31000021
*    HCT FIELDS:                                                      * 31200021
*         HCTNHCT -- USED TO FIND HCT QUEUE                           * 31400021
*         HCTNDAC -- USED TO TEST IF NEXT HCT IS ACTIVE               * 31600021
*         HCTROUT -- USED TO FIND IHLROUTI                            * 31800021
*         HCTROUTB -- USED TO FIND IHLROUTB                           * 32000021
*         HCTRCOV -- USED TO FIND IHLRCOV                             * 32200021
*         HCTINCTL -- USED TO TEST IF HCT IS IN CONTROL               * 32400021
*                                                                     * 32600021
* ATTRIBUTES --                                                       * 32800021
*    REFRESHABLE, DISABLED, PRIVILEGED, SERIALLY-REUSEABLE            * 33000021
*                                                                     * 33200021
* CHARACTER CODE DEPENDENCY --                                        * 33400021
*    NONE                                                             * 33600021
*                                                                     * 33800021
* NOTES --                                                            * 34000021
*    THIS MODULE IS FOR MVT ONLY.                                     * 34200021
*                                                                     * 34400021
*********************************************************************** 35200021
        AGO    .SKIPFL1                                                 35250021
*/*IHLMCIH: CHART (SEQ) */                                              35300021
*/* HEADER                                                              35350021
*/*IHLMCIH   --   MC INTERRUPT HANDLER: RESIDENT IN PFLIH               35360021
*/*                                        B13.#      */                35370021
*/*IHLMCIHV: E IHLMCIHV */                                              35380021
*/* N ENTERED FROM PFLIH FOLLOWING ALL PROGRAM INTERRUPTS */            35390021
*/* P SAVE PFLIH BASE REG AND RETURN REG */                             35392021
*/* D (YES,RECURS,NO,) PROG CK IN GTF ? */                              35394021
*/* D (NO,,MAYBE,%T77) REAL MC ? */                                     35394421
*/* P TEST LENGTH OF INTERRUPTED INSTRUCTION */                         35396021
*/* D (NO,%T2,YES,) 4 BYTES ? */                                        35398021
*/* P TEST PROG OPSW INTERRUPT CODE */                                  35398421
*/* D (NO,%T2,YES,) ILLEGAL OP CODE ? */                                35398821
*/* P TEST INSTRUCTION THAT CAUSED INTERRUPT */                         35399221
*/* D (NO,%T4,YES,%Z) EXECUTE INSTR ? */                                35399621
*/*%Z: P TEST BASE OF EXECUTE INSTR */                                  35399721
*/* D (YES,,NO,%T2) ZERO? */                                            35399821
*/* P TEST TARGET OF EXECUTE */                                         35399921
*/* D (NO,%T2,YES,) X'AF' OP CODE ? */                                  35449921
*/*%T3: P TEST INSTRUCTION FOLLOWING EXECUTE */                         35459921
*/* D (NO,%T2,YES,%T7) RX TYPE NOP ? */                                 35469921
*/*RECURS: P EXAMINE HCT */                                             35479921
*/* D (NO,%T5,YES,) ACTIVE & IN CONTROL ? */                            35489921
*/* P CALL IHLERRM TO ATTEMPT ERROR RECOVERY */                         35491921
*/* R IHLERRM */                                                        35493921
*/*%T5: P (,RECURS) SET UP TO EXAMINE NEXT HCT IN CHAIN */              35495921
*/*%T77: D (YES,%T2,NO,%T7) IS PIOPSW ILC =0 ? */                       35497921
*/*%T4: D (NO,%T2,YES,) IS OP CODE AF ? */                              35498321
*/* D (NO,%T2,YES,) IS NEXT OP CODE RX NOP ? */                         35498721
*/* P COMPARE HOOK IDS IN ABOVE INSTRUCTIONS */                         35499121
*/* D (NO,%T2,YES,) EQUAL? */                                           35499521
*/* P CHANGE AF OP CODE TO 44 */                                        35499621
*/* P INSERT CLASS MASK ADDR INTO THIS INSTR */                         35499721
*/* D (NO,%T6,YES,%T7) THIS CLASS ON ? */                               35499821
*/*%T7: P CHECK HCT CHAIN */                                            35543221
*/*%T8: D (NO,%T6,YES,) IS THERE AN HCT ? */                            35553221
*/* D (NO,%T9,YES,) HCT ACTIVE ? */                                     35563221
*/* P SET UP PARM LIST PTR */                                           35566421
*/* L IHLROUT: LET APPLICATION PROCESS HOOK */                          35587621
*/*%T9: P (,%T8) SET UP TO CHECK NEXT HCT IN CHAIN */                   35588021
*/*%T6: P TEST PROG OPSW */                                             35588421
*/* D (NO,%T12,YES,) TOTALLY ENABLED ? */                               35588821
*/* P CHECK IF TASK SWITCH REQUIRED */                                  35592521
*/* D (NO,%T12,YES,) REQUIRED? */                                       35594521
*/* P SAVE PROG OPSW IN CURRENT RB */                                   35594921
*/* P MOVE REGS FROM SAVE AREA TO CURRENT RB */                         35595321
*/* P GO TO DISPATCH A NEW TASK */                                      35595721
*/* R IEA0D5 */                                                         35596121
*/*%T12: P RESTORE REGS FROM PFLIH SAVE AREA */                         35596221
*/* R RETURN: LPSW PROG OPSW */                                         35646221
*/*%T2: P RESTORE REGS USED BY THIS ROUTINE */                          35656221
*/* R RETURN: VIA REG 14 */                                             35666221
*/*IHLBHOOK: E IHLBHOOK */                                              35676221
*/* N ENTRY FROM PFLIH VIA BRANCH TYPE HOOK */                          35686221
*/* P SAVE PFLIH BASE REG */                                            35688221
*/* P SET UP TO CHECK HCT CHAIN */                                      35692221
*/*%T13: D (NO,%T15,YES,) IS THERE AN HCT ? */                          35694221
*/* D (NO,%T14,YES,) IS IT ACTIVE ? */                                  35694621
*/* P PUT PTR TO HCT IN REGISTER */                                     35694721
*/* P GET BRANCH HOOK EP OF IHLROUT */                                  35695021
*/* L IHLROUT: GIVE APPLICATION CONTROL */                              35695821
*/* P TEST RETURN CODE */                                               35695921
*/* D (NO,%T15,YES,%T14) ZERO? */                                       35696021
*/*%T15: P RESET PFLIH BASE REG */                                      35696121
*/* R RETURN */                                                         35712821
*/*%T14: P (,%T13) SET UP TO CHECK NEXT HCT IN CHAIN */                 35722821
*/*IHLMCIH: END */                                                      35724821
.SKIPFL1 ANOP                                                           35726821
         EJECT                                                          35729521
*********************************************************************** 35746221
*        MODULE THAT HANDLES REAL, SIMULATED AND BRANCH HOOKS (MVT)   * 35800021
*********************************************************************** 36000021
IHLMCIHV CSECT                                                          36200021
*A000000-999999                                                  S21014 36250021
*D892500                                                          M1329 36300021
*A888500                                                          M1329 36350021
*********************************************************************** 36400021
*        CVT MAPPING                                                  * 36600021
*********************************************************************** 36800021
CVTSECT  DSECT                                                          37000021
         CVT                                                            37200021
         EJECT                                                          37400021
*********************************************************************** 37600021
*        HOOK CONTROL TABLE MAPPING  (HCT)                            * 37800021
*********************************************************************** 38000021
         HCT                                                            38200021
         EJECT                                                          38400021
         CMT                                                            39200021
         EJECT                                                          39400021
*********************************************************************** 39600021
*        LOW CORE MAPPING                                             * 39800021
*********************************************************************** 40000021
         IEAQFX  65,SERP,0                                              40200021
         EJECT                                                          40400021
*********************************************************************** 40600021
*        ENTRY POINT FOR ALL PROGRAM INTERRUPTS                       * 40800021
*********************************************************************** 41000021
IHLMCIHV CSECT                                                          41200021
         ENTRY IHLMCIH                  NORMAL HOOK EP (REAL & SIMULTD) 41400021
         ENTRY IHLBHOOK                 BRANCH TYPE HOOK EP             41600021
TCBGRS   EQU   48                       TCB REGISTER SAVE AREA          41800021
RBOPSW   EQU   16                       PGM OLD PSW SAVED IN RB         42000021
TCBRBP   EQU   0                        ADDRESS OF CURRENT RB IN TCB    42200021
IHLPARM  EQU   0                        PARAMETER FIELD ADDRESS.        42400021
IHLHCTR  EQU   1                        HOOK CONTROL TABLE              42600021
IHLCMTR  EQU   1                        CMT ADDR                        42800021
IHLNHK   EQU   2                        NOT HOOK ADDR                   43000021
IHLCVT   EQU   3                        CVT ADDR                        43200021
IHLWK1   EQU   4                        WORK REG                        43400021
IHLWK2   EQU   5                        WORK REG                        43600021
IHLWK3   EQU   6                        WORK REG                        43800021
IHLSAVE  EQU   7                        REG TO SAVE PFLIH RETURN ADDR   44000021
IHLBASE  EQU   8                        BASE REG FOR THIS PROGRAM       44200021
IHLSREG  EQU   9                        PFLIH SAVE AREA                 44400021
IHLRE    EQU   14                       LINKAGE REG RETURN              44600021
IHLRF    EQU   15                       LINKAGE REG BRANCH              44800021
IHLR0    EQU   0                        LINKAGE REG FOR BRANCH HOOK     45000021
IHLR1    EQU   1                        LINKAGE REG FOR BRANCH HOOK     45200021
IHLILINT EQU   X'01'                    ILLEGAL OP INTERRUPT CODE       45400021
IHLMCINT EQU   X'40'                    MONITOR CALL INTERRUPT CODE     45600021
IHLMCOP  EQU   X'AF'                    MONITOR CALL OP-CODE            45800021
IHLNOPOP EQU   X'47'                    NOP OP-CODE, IF ZERO MASK       46000021
IHLZBASE EQU   X'F0'                    TM MASK FOR ZERO BASE TEST      46200021
IHLZMASK EQU   X'F0'                    TM MASK FOR ZERO MASK TEST      46400021
IHLPILC1 EQU   X'80'                    ICL BIT 1 IN PIOPSW             46600021
IHLPILC2 EQU   X'40'                    ILC BIT 2 IN PIOPSW             46800021
ENABLED  EQU   X'FF'                    TOTALLY ENABLED MASK            47000021
IHLPIILC EQU   X'C0'                    INSTRUCTION LENGTH IN PIPSW     47050021
         EJECT                                                          47200021
*********************************************************************** 47400021
*        ENTRY FOR NORMAL HOOKS OR RECURSION                          * 47600021
*********************************************************************** 47800021
IHLMCIH  EQU   *                        NORMAL HOOK ENTRY POINT         48000021
         LR    IHLBASE,IHLRF            ADDRESSIBILITY                  48200021
         USING IHLMCIH,IHLBASE                                          48400021
         LR    IHLSAVE,IHLRE            SAVE PFLIH RETURN ADDR          48600021
         L     IHLCVT,CVTCON            CVT ADDR                        48800021
         USING CVTSECT,IHLCVT           CVT ADDRESSIBILITY              49000021
         L     IHLCMTR,CVTGTF           GET CMT ADDR                    49200021
         SPACE                                                          49400021
*********************************************************************** 49600021
*        CHECK FOR PGM CHECK DURING HOOK PROCESSING                   * 49800021
*********************************************************************** 50000021
         TM    CVTGTFST,CVTSTATE        IS THIS PGMCHK DURING HOOK      50200021
         BZ    IHLNOTRE                 NO, CONTINUE NORMALLY           50400021
         EJECT                                                          50600021
*********************************************************************** 50800021
*        RECURSION INTO PFLIH DURING HOOK PROCESSING                  * 51000021
*********************************************************************** 51200021
IHLRCTST EQU   *                        LOOK AT HCT ADDR                51600021
         USING HCT,IHLHCTR              ADDRESSIBILITY FOR HCT          51800021
         L     IHLHCTR,HCTNHCT          GET NEXT HCT ADDR               52000021
         LTR   IHLHCTR,IHLHCTR          IS THIS HCT ACTIVE              52200021
         BM    IHLRCTST                 NO TRY NEXT HCT                 52400021
         TM    HCTFLG1,HCTINCTL         IS THIS HCT IN CONTROL          52600021
         BZ    IHLRCTST                 NO, TRY NEXT HCT                52800021
         L     IHLRF,HCTRCOV            GET ERROR RECOVERY ADDR         53000021
         BR    IHLRF                    GO TO ERROR RECOVERY MONTR      53200021
         DROP  IHLHCTR                                                  53400021
*                          DEBUGGING AID                                53450021
* TO BE TRAPPED IN THE ABOVE LOOP MEANS THAT SOME HCT IS CHAINED TO     53500021
* ITSELF OR TO ANOTHER HCT THAT IS AHEAD OF IT ON THE QUEUE             53550021
* TO PROGRAM CHECK IN THIS LOOP OR TO TAKE A WILD BRANCH OUT OF THIS    53560021
* LOOP MEANS THAT THE CVT INDICATED GTF WAS PROCESSING BUT NO HCT       53570021
* WAS MARKED AS IN CONTROL. ONE OF THEM IS PROBABLY WRONG               53580021
*                                                                       53590021
         EJECT                                                          53600021
*********************************************************************** 53800021
*        POTENTIAL HOOK MUST BE CHECKED TO SEE IF REALLY HOOK         * 54000021
*        FOUR CASES: REAL MC INTERRUPT, EX-NOP, AF-NOP, OTHER PGMCHK  * 54200021
*********************************************************************** 54400021
         USING CMT,IHLCMTR                                              54600021
IHLNOTRE EQU   *                        NOT RECURSION DURING HOOK       54800021
         L     IHLSREG,IHLCON1          GET POINTER TO PFLIH REGS       55000021
*********************************************************************** 55200021
*        CHECK FOR REAL MC INTERRUPT                                  * 55400021
*********************************************************************** 55600021
         LA    IHLNHK,IHLNOHOK          ADDR OF BRANCH IF NOT HOOK      55650021
         TM    PIOPSW+3,IHLMCINT        IS REAL MC INTERRUPT            55800021
         BZ    IHLNOTMC                 NO, CHECK FOR SIMULATED MC      56050021
         TM    PIOPSW+4,IHLPIILC        MAYBE, CHECK FOR ZERO LENGTH    56100021
         BC    7,IHLCALLR               NONZERO LEN, REAL MC            56150021
         BR    IHLNHK                   ZERO LEN, IMPRECISE INTERRUPT   56160021
         SPACE                                                          56200021
*********************************************************************** 56400021
*        CHECK FOR EX-NOP AND AF-NOP                                  * 56600021
*********************************************************************** 56800021
IHLNOTMC EQU   *                        INTERRUPT IS NOT A REAL MC      56850021
         TM    PIOPSW+4,IHLPILC1        IS ILC=2 OR 3                   57200021
         BCR   8,IHLNHK                 NO, NOT HOOK                    57400021
         TM    PIOPSW+4,IHLPILC2        IS ILC=2                        57600021
         BCR   1,IHLNHK                 NO, NOT HOOK                    57800021
         CLI   PIOPSW+3,IHLILINT        IS IT ILLEGAL OP                58000021
         BCR   7,IHLNHK                 NO, NOT HOOK                    58200021
         L     IHLWK1,PIOPSW+4          ADDR FROM PI OPSW               58400021
         SL    IHLWK1,IHLC4             YIELDS ADDR OF EX OR MC         58600021
         CLC   0(2,IHLWK1),IHLEX00      DOES IT POINT TO EXECUTE        58800021
         BE    IHLEXNOP                 YES, CHECK VALID EX             59000021
         SPACE                                                          59200021
*********************************************************************** 59400021
*        CHECK FOR AF-NOP, AND IF SO, CHANGE TO EX-NOP                * 59600021
*********************************************************************** 59800021
         CLI   0(IHLWK1),IHLMCOP        IS IT AF OP-CODE                60000021
         BCR   7,IHLNHK                 NO, NOT HOOK                    60200021
         CLI   4(IHLWK1),IHLNOPOP       FOLLOWED BY POTENTIAL NOP       60400021
         BCR   7,IHLNHK                 NO, NOT HOOK                    60600021
         TM    5(IHLWK1),IHLZMASK       IS PTENTIAL NOP REAL NOP        60800021
         BCR   7,IHLNHK                 NO, NOT HOOK                    61000021
         CLC   1(3,IHLWK1),5(IHLWK1)    AF HOOKID EQUAL NOP HOOKID      61200021
         BCR   7,IHLNHK                 NOT EQUAL. NOT A HOOK.          61400021
         SR    IHLWK2,IHLWK2            ZERO WORK REG                   61600021
         IC    IHLWK2,1(IHLWK1)         GET CLASS OF HOOK               61800021
         SLA   IHLWK2,1                 MULTIPLY CLASS BY 2             62000021
         LA    IHLWK2,CMTCMSK(IHLWK2)   CALCULATE CLASSMASK ADDR        62200021
         MVC   0(2,IHLWK1),IHLEX00      SET UP FIRST HALF OF EX INST    62400021
         STH   IHLWK2,2(IHLWK1)         PUT CLASSMASK ADDR IN EX        62600021
         CLI   0(IHLWK2),IHLMCOP        IS CLASS ON                     62800021
         BNE   IHLRETRN                 NO GO TO RETURN                 63000021
         B     IHLCALLR                 YES,GO TO CALL ROUTER           63200021
         SPACE                                                          63400021
*********************************************************************** 63600021
*        CHECK FOR EX-NOP                                             * 63800021
*********************************************************************** 64000021
IHLEXNOP EQU   *                        POTENTIAL EX-NOP                64200021
         TM    2(IHLWK1),IHLZBASE       IS BASE ZERO                    64400021
         BCR   7,IHLNHK                 NO, NOT HOOK                    64600021
         LH    IHLWK2,2(IHLWK1)         GET TARGET OF EXECUTE           64800021
         CLI   0(IHLWK2),IHLMCOP        IS IT AF OP-CODE                65000021
         BCR   7,IHLNHK                 NO, NOT HOOK                    65200021
         CLI   4(IHLWK1),IHLNOPOP       FOLLOWED BY POTENTIAL NOP       65400021
         BCR   7,IHLNHK                 NO, NOT HOOK                    65600021
         TM    5(IHLWK1),IHLZMASK       IS POTENTIAL NOP REAL NOP       65800021
         BCR   7,IHLNHK                 NO, NOT HOOK                    66000021
         EJECT                                                          66200021
*********************************************************************** 66400021
*        ALL HOOKS WILL CALL ROUTER ADDR OF ALL ACTIVE HCT'S          * 66600021
*********************************************************************** 66800021
         DROP  IHLCMTR                                                  67000021
IHLCALLR EQU   *                        SEARCH HCT CHAIN                67200021
IHLTESTH EQU   *                        LOOK DOWN HCT CHAIN             67600021
         USING HCT,IHLHCTR              ADDRESSIBILITY FOR HCT          67800021
         L     IHLHCTR,HCTNHCT          GET NEXT HCT ADDR               68000021
         LTR   IHLHCTR,IHLHCTR          CHECK HCT ADDR                  68200021
         BZ    IHLRETRN                 ZERO, NO MORE HCT'S             68400021
         BM    IHLTESTH                 NEG, INACTIVE HCT TRY NEXT      68600021
         SPACE                                                          68800021
*********************************************************************** 69000021
*        ROUTER IS TO BE CALLED FOR AN HCT                            * 69200021
*********************************************************************** 69400021
         LA    IHLPARM,IHLPLIST         SET PARAMETER LIST POINTER.     69600021
         L     IHLRF,HCTROUT            GET ROUTER ADDR                 69800021
         BALR  IHLRE,IHLRF              GO TO PROCESS HOOK              70000021
         B     IHLTESTH                 GO TO CHECK NEXT HCT            70200021
         DROP  IHLHCTR                                                  70400021
         EJECT                                                          70600021
*********************************************************************** 70800021
*        RETURN AFTER HOOK DIRECTLY IF CALLER DISABLED,               * 71000021
*        CHECK FOR TASK SWITCH IF CALLER TOTALLY ENABLED              * 71200021
*********************************************************************** 71400021
IHLRETRN EQU   *                        HOOK PROCESSING FINISHED        71600021
         CLI   PIOPSW,ENABLED           IS PSW TOTALLY ENABLED          71800021
         BNE   IHLDIRCT                 NO, RETURN DIRECTLY TO PGM      72000021
         L     IHLWK3,CVTTCBP           POINTER TO TASK CTL DBL WORD    72200021
         L     IHLWK1,4(IHLWK3)         DETERMINE IF A TASK SWITCH      72400021
         C     IHLWK1,0(IHLWK3)         IS REQUIRED                     72600021
         BNE   IHLTSWCH                 YES, BRANCH                     72800021
         SPACE                                                          73000021
*********************************************************************** 73200021
*        DIRECT RETURN WHEN NO TASK SWITCH IS REQUIRED                * 73400021
*********************************************************************** 73600021
IHLDIRCT EQU   *                        RETURN WHEN NO TASK SWITCH      73800021
         LM    0,15,0(IHLSREG)          RESTORE REGS FROM LOW CORE      74000021
         LPSW  PIOPSW                   RETURN AFTER HOOK               74200021
         SPACE                                                          74400021
*********************************************************************** 74600021
*        EXIT THROUGH DISPATCHER IF TASK SWITCH IS REQUIRED           * 74800021
*********************************************************************** 75000021
IHLTSWCH EQU   *                        DISP MUST BE CALLED             75200021
         L     IHLWK2,TCBRBP(0,IHLWK1)  GET CURRENT TCB                 75400021
         MVC   RBOPSW(8,IHLWK2),PIOPSW  MOVE PGM OLD PSW INTO RB        75600021
         MVC   TCBGRS(64,IHLWK1),0(IHLSREG)  SAVE REGS IN TCB           75800021
         LM    0,15,0(IHLSREG)          RESTORE REGS FROM LOW CORE      76000021
         BALR  14,0                     RE-ESTABLISH                    76200021
         USING *,14                     ADDRESSIBILITY                  76400021
         L     IHLRF,IHLCON2            GET DISPATCHER ADDRESS          76600021
         BR    IHLRF                    GO TO DISPATCHER                76800021
         DROP  14                                                       77000021
         DROP  IHLCVT                                                   77200021
         DROP  IHLBASE                                                  77400021
         SPACE                                                          77600021
*********************************************************************** 77800021
*        NOT A HOOK, SO RETURN TO PFLIH AFTER RESTORING REGS          * 78000021
*********************************************************************** 78200021
IHLNOHOK EQU   *                        NOT A HOOK INTERRUPT            78400021
         LR    IHLRE,IHLSAVE            RESTORE PFLIH RETURN ADDR       78600021
         LM    0,9,0(IHLSREG)           RESTORE REGS THAT WERE USED     78800021
         BR    IHLRE                    RETURN TO PFLIH                 79000021
         EJECT                                                          79200021
*********************************************************************** 79400021
*        THIS SECTION HANDLES BRANCH HOOKS AND MUST NOT CHANGE        * 79600021
*        REGISTERS 2-13.  REGS 0,14,15 ARE VOLITLE AND REG 1 IS       * 79800021
*        THE RETURN ADDR (ALSO THE NOP ADDR THAT CARRIES HOOK ID)     * 80000021
*********************************************************************** 80200021
IHLBHOOK EQU   *                        BRANCH HOOK BRANCHES HERE       80400021
         BALR  IHLRE,0                  SET UP ADDRESSIBILITY           80600021
         USING *,IHLRE                                                  80800021
         L     IHLRF,CVTCON             CVT BASE ADDR                   81000021
         USING CVTSECT,IHLRF            ADDRESSIBILITY FOR CVT          81200021
         L     IHLRF,CVTGTF             GET CMT ADDR                    81400021
         USING CMT,IHLRF                ADDRESSIBILITY FOR CMT          81600021
IHLBRTST EQU   *                        LOOK AT HCT                     82000021
         USING HCT,IHLRF                ADDRESSIBILITY FOR HCT          82200021
         L     IHLRF,HCTNHCT            GET NEXT HCT ADDR               82400021
         LTR   IHLRF,IHLRF              TEST HCT ADDR                   82600021
         BCR   8,IHLR1                  IF ZERO, NO MONITOR             82800021
         BM    IHLBRTST                 IF NEGITIVE, INACTIVE HCT       83000021
         SPACE                                                          83200021
*********************************************************************** 83400021
*        ROUTER (BRANCH ENTRY) IS TO BE CALLED FOR THIS HCT           * 83600021
*********************************************************************** 83800021
         LR    IHLR0,IHLRF              SAVE HCT ADDR FOR ROUTER        84000021
         L     IHLRF,HCTROUTB           ROUTER ADDR FOR BRANCH MC       84200021
         DROP  IHLRF                                                    84400021
IHLBCALL EQU   *                                                        84600021
         BALR  IHLRE,IHLRF              GO TO ROUTER BRANCH EP          84800021
         LTR   IHLRF,IHLRF              WAS CLASS OFF                   85000021
         BCR   7,IHLR1                  YES, RETURN- DONT SEARCH MORE   85200021
         LA    IHLRF,IHLBCALL-IHLBHOOK  NO, RESTORE                     85400021
         SR    IHLRE,IHLRF              ADDRESSIBILITY                  85600021
         LR    IHLRF,IHLR0              RESTORE HCT ADDR                85800021
         USING HCT,IHLRF                REESTABLISH HCT ADDRESSIBILITY  86000021
         B     IHLBRTST                 CONTINUE SEARCH                 86200021
         DROP  IHLRF                                                    86400021
         DROP  IHLRE                                                    86600021
         EJECT                                                          86800021
*********************************************************************** 87000021
*        CONSTANTS AND PARM LIST FOR ROUTER                           * 87200021
*********************************************************************** 87400021
IHLEX00  DC    X'4400'                  1ST HALF OF EXECUTE INSTR       87600021
IHLC4    DC    F'4'                     CONSTANT 4                      87800021
         SPACE                                                          88000021
IHLPLIST DS    0XL16                    PARM LIST TO ROUTER             88200021
         DC    V(IGC011A0)              TIME ROUTINE BRANCH ADDR        88400021
         DC    V(IEASCSAV)              SVC SAVE AREA IN LOW CORE       88600021
IHLCON1  DC    V(IEAPKSAV)              PI SAVE AREA IN LOW CORE        88800021
CVTCON   DC    V(IEACVT)                CVT ADDRESS               M1329 88850021
         SPACE                                                          89000021
IHLCON2  DC    V(IEA0DS)                DISPATCHER ADDRESS              89200021
         END                                                            89400021
