         TITLE 'IEDAYII - QTIP CODE FOR TSINPUT'                        00100020
         GBLC  &LIB                                                     00130000
&LIB     SETC  'LIB1'                                                   00160022
IEDAYII  CSECT                                                          00200020
         SPACE 1                                                        00500020
         DC    CL7'IEDAYII'             IDENTIFIER                      00800020
         DC    X'2038'                  DATE - 2/7/72            S22028 00810001
PATCHREA DC    10F'0'                   PATCH AREA               Y01018 00850000
         DS    0H                       FILLER                          00900020
         SPACE 1                                                        01108020
*********************************************************************** 01116020
*                                                                     * 01124020
*                                                                M2688  01126020
*                                                                TS1628 01128020
*                                                                M0030  01130020
*                                                                 M3660 01131020
*                                                                 M6361 01131520
*          RELEASE 23 DELETIONS                                       * 01132020
*          RELEASE 22 DELETIONS                                       * 01140020
*          RELEASE 21 DELETIONS                                       * 01148020
*D747011                                                        SA59536 01155201
*1332137210,311000,335000,339600,412320,453000-453200,455100,    S22028 01165801
*1332455400,455600,456600,530080,530380,684000,747000            S22028 01173001
*1332                                                            A45625 01180201
*1332139370-139400                                               A43888 01187401
*1332535000-542000,548500-600000,663080-663920                   S21008 01194601
*                                                                 M2673 01201801
*                                                                     * 01209001
* STATUS -                                                            * 01216201
*STATUS CHANGE LEVEL 001                                                01223401
*                                                                     * 01230601
* FUNCTION -                                                          * 01237801
*    THIS ROUTINE PROVIDES AN INTERFACE FOR TSINPUT (IEDAYI) BETWEEN  * 01245001
*    THE TCAM AND TSO REGIONS.                                        * 01252201
*                                                                     * 01259401
* ENTRY POINTS -                                                      * 01266601
*    QTIP0050,QTIP0060,QTIP0070,QTIP0080,QTIP0090, AND QTIP0280.      * 01273801
*                                                                     * 01281001
* INPUT -                                                             * 01288201
*    REFER TO THE PREFACE OF THE APPLICABLE ENTRY POINT.              * 01295401
*                                                                     * 01302601
* OUTPUT -                                                            * 01309801
*    FOR QTIP ENTRY CODE 9, REGISTER 15 WILL CONTAIN A RETURN CODE IN * 01317001
*    THE HI ORDER BYTE INDICATING WEITHER OR NOT SUFFICIENT TS        * 01324201
*    BUFFERS WERE AVAILABLE TO PROCESS THE TS MESSAGE.  THE LOW ORDER * 01331401
*    3 BYTES WILL CONTAIN THE ADDRESS OF THE LAST TS HEADER BUFFER ON * 01338601
*    THE INPUT HEADER QUEUE.  THE RETURN CODES ARE AS FOLLOWS.        * 01345801
*        00 - SUFFICIENT TS BUFFERS WERE AVAILABLE.                   * 01353001
*        04 - NO TS BUFFERS WERE AVAILABLE.                           * 01360201
*                                                                     * 01367401
* EXTERNAL REFERENCES -                                               * 01374601
*    THIS ROUTINE CALLS THE TIME SHARING INTERFACE PROGRAM (TSIP)     * 01381801
*    WITH AN ENTRY CODE OF 4, VIA A BRANCH AND LINK, TO BRING THE     * 01389001
*    USER INTO CORE FOLLOWING THE REMOVAL OF AN IWAIT CONDITION.      * 01396201
*                                                                     * 01403401
* EXITS, NORMAL -                                                     * 01410601
*    RETURN IS ALWAYS TO TSINPUT (IEDAYI) VIA A BRANCH ON REGISTER 14.* 01417801
*                                                                     * 01425001
* EXITS, ERROR -                                                      * 01432201
*    NONE                                                             * 01439401
*                                                                     * 01446601
* TABLES/WORK AREAS -                                                 * 01453801
*    NONE                                                             * 01461001
*                                                                     * 01468201
* ATTRIBUTES -                                                        * 01475401
*    SERIALLY-REUSABLE,REFRESHABLE,DISABLED                           * 01482601
*                                                                     * 01489801
* CHARACTER CODE DEPENDENCY -                                         * 01497001
*    THIS ROUTINE IS DEPENDENT ON THE FOLLOWING EBCDIC CHARACTERS.    * 01504201
*        X'0D' - EBCDIC CARRIAGE RETURN CHARACTER.  EQUATED TO        * 01511401
*        'CARRTRN' WITHIN THIS ROUTINE.                               * 01518601
*                                                                     * 01525801
*        X'15' - EBCDIC NEW LINE CHARACTER.  EQUATED TO 'NEWLINE'     * 01533001
*        WITHIN THIS ROUTINE.                                         * 01540201
*                                                                     * 01547401
* NOTES -                                                             * 01554601
*    EACH ENTRY POINT INTO THIS ROUTINE IS PREFACED WITH DESCRIPTION  * 01561801
*    WHICH DEFINES THE FUNCTION AND INPUT PARAMETERS OF THE ASSOCI-   * 01569001
*    ATED ENTRY.                                                      * 01576201
*                                                                     * 01583401
*********************************************************************** 01590601
         EJECT                                                          01597801
*********************************************************************** 01605020
********                                                       ******** 01610020
******** ENTRY POINTS                                          ******** 01615020
********                                                       ******** 01620020
*********************************************************************** 01625020
         SPACE 1                                                        01630020
         ENTRY QTIP0050,QTIP0060,QTIP0070,QTIP0080,QTIP0090             01650020
         ENTRY QTIP0280                                                 01660020
         SPACE 3                                                        01670020
*********************************************************************** 01700020
********                                                       ******** 01800020
******** REGISTER EQUATES                                      ******** 01900020
********                                                       ******** 02000020
*********************************************************************** 02100020
         SPACE 1                                                        02200020
R0       EQU   0                        INDEX REGISTER                  02300020
RMVSZ1   EQU   R0                       SIZE OF DATA IN THE BASIC UNIT  02400020
RMVSZ2   EQU   1                        UNFILLED SPACE SIZE IN TS BFR   02600020
RWRK1    EQU   RMVSZ2                   WORK/PARAMETER REGISTER         02800020
RSCANF   EQU   2                        POINTER TO BEGIN OF DATA SCANED 02900020
RWRK2    EQU   RSCANF                   WORK/PARAMETER REGISTER         03000020
RSCANL   EQU   3                        POINTER TO END OF DATA SCANNED  03100020
RWRK3    EQU   RSCANL                   WORK/PARAMETER REGISTER         03200020
RWRK4    EQU   4                        WORK/PARAMETER REGISTER         03300020
RLCB     EQU   RWRK4                    LCB ADDRESS                     03350020
RTSBFR   EQU   5                        TIME SHARING BUFFER ADDRESS     03400020
RTCBFR   EQU   6                        TCAM BUFFER ADDRESS             03700020
RQCB     EQU   7                        DESTINATION QCB ADDRESS         03900020
RFILL    EQU   RQCB                     ADDR OF BEGIN FILL IN TS BFR    04000020
RWRK7    EQU   RFILL                    WORK/PARAMETER REGISTER         04100020
RDSZE    EQU   8                        SIZE OF DATA IN BUFFER          04200020
RWRK8    EQU   RDSZE                    WORK/PARAMETER REGISTER         04300020
RTSB     EQU   9                        TSB ADDRESS                     04400020
RTIOC    EQU   10                       TIOCRPT ADDRESS                 04500020
RWK11    EQU   11                       WORK/PARAMETER REGISTER         04600020
RBASE    EQU   12                       BASE REGISTER                   04700020
RAVT     EQU   13                       ADDRESS OF AVTSAVE2             04800020
RETRN    EQU   14                       RETURN ADDRESS                  05000020
RNTRY    EQU   15                       ENTRY POINT                     05200020
RTRNCD   EQU   RNTRY                    RETURN CODE TO TSINPUT          05300020
RWK15    EQU   RTRNCD                   WORK/PARAMETER REGISTER         05400020
         EJECT                                                          05500020
*********************************************************************** 05600020
********                                                       ******** 05700020
******** MASKS AND DISPLACEMENTS                               ******** 05800020
********                                                       ******** 05900020
*********************************************************************** 06000020
         SPACE 1                                                        06100020
K0       EQU   0                        NULL DISPLACEMENT               06200020
K1       EQU   1                        CONSTANT 1                      06300020
CC3270ND EQU   1                        3270 AID CONTROL CHAR    S22028 06310001
*                                       LENGTH                   S22028 06320001
K2       EQU   2                        LENGTH FIELD                    06330020
K3       EQU   3                        LENGTH FIELD                    06360020
CC3270R  EQU   3                        LENGTH OF EXTRA CONTROL  S22028 06368001
*                                       CONCHARACTERS FOR 3270 REMOTE   06376001
CC3270D3 EQU   3                        CONTROL CHAR LNG FOR     S22028 06384001
*                                       3270                     S22028 06392001
K4       EQU   4                        LENGTH FIELD                    06400020
CC3270D6 EQU   6                        MAXIMUM NO. OF CONTROL   S22028 06420001
*                                       CHARACTERS FOR 3270             06440001
ZEROS    EQU   8                        MASK FOR A CONDITION CODE OF 8  06460020
K8       EQU   8                        LENGTH FIELD                    06500020
K12      EQU   12                       LENGTH FIELD                    06600020
K16      EQU   16                       LENGTH FIELD                    06700020
LCBDELAY EQU   X'02'                    LCB IS ON THE DELAY QUEUE       06900020
CARRRTRN EQU   X'0D'                    CARRIAGE RETURN CHARACTER       07110020
SBA      EQU   X'11'                    SBA CHARACTER            S22028 07120001
WAITQBFR EQU   X'10'                    USED TO INDICATE TCAM BFR HAS   07130020
*                                       BEEN ON TCAM BFR WAIT QUEUE     07160020
NEWLINE  EQU   X'15'                    NEW LINE CHARACTER              07190020
NOTMOVED EQU   X'20'                    IND NOT ALL OF SCANNED DATA IN  07210020
*                                       TCAM BFR WAS MOVED TO TS BFR(S) 07230020
TIMEOUT  EQU   X'40'                    TIME OUT OCCURED IN THIS BFR    07260020
WRITEBRK EQU   X'80'                    WRITE BREAK IN PROGRESS         07300020
CC32706  EQU   X'08'                    MORE THAN 1 3270 CONTROL S22028 07330001
*                                       CHARACTER IN BUFFER             07360001
OFF      EQU   X'FF'                    USED TO TURN OFF BITS           07400020
CLRSCREN EQU   X'FF'                    USED TO IND DISPLAY SCREEN MUST 07430020
*                                       BE CLEARED BEFORE CONTINUING    07460020
         EJECT                                                          07500020
*********************************************************************** 07600020
********                                                       ******** 07700020
******** THE FOLLOWING SECTION OF CODE IS USED BY TSINPUT TO   ******** 07800020
******** TERMINATE TCLEARQ PROCESSING.  THE ENTRY POINT INTO   ******** 07900020
******** THIS CODE IS QTIP0050.                                ******** 08000020
********                                                       ******** 08200020
******** INPUT REGISTERS -                                     ******** 08300020
********                                                       ******** 08400020
********       REG 9 - ADDRESS OF THE CURRENT TSB.             ******** 08500020
********                                                       ******** 08600020
*********************************************************************** 08700020
QTIP0050 EQU   *                                                        08800020
         USING *,RBASE                  ESTABLISH ADDRESSABILITY        08900020
         USING TSB,RTSB                 USE RTSB AS TSB BASE REGISTER   09000020
         NI    TSBFLG1,OFF-TSBIFLSH     TERMINATE TCLEARQ PROCESSING    09060020
         NI    TSBFLG2,OFF-TSBBIPI      TERMINATE BREAK-IN PROCESSING   09200020
         NI    TSBFLG3,OFF-TSBSPIT      PROMPTING OK NOW         YM2814 09250000
         BR    RETRN                    RETURN TO CALLER                09300020
         DROP  RTSB                     DROP CONTROL BLOCK BASE REGS    09400020
         EJECT                                                          10400020
*********************************************************************** 12300020
********                                                       ******** 12400020
******** THE FOLLOWING SECTION OF CODE IS USED BY TSINPUT TO   ******** 12500020
******** REMOVE THE SYSTEM FROM AN LWAIT CONDITION AND CHECK   ******** 12540020
******** THE LINE STATUS OF EACH TERMINAL WHOSE KEYBOARD WAS   ******** 12580020
******** LOCKED TO INPUT DUE TO THE SYSTEM LWAIT CONDITION.    ******** 12620020
******** IF IT IS NECESSARY TO ACTIVATE THE TERMINAL, THE LINE ******** 12660020
******** WILL BE TPOSTED TO ITSELF.  THE ENTRY POINT INTO THIS ******** 12700020
******** CODE IS QTIP0060.                                     ******** 12740020
********                                                       ******** 12800020
******** INPUT REGISTERS -                                     ******** 12900020
********                                                       ******** 13000020
********       REG 10 - ADDRESS OF THE TIOCRPT.                ******** 13100020
********       REG 13 - ADDRESS OF AVTSAVE2.                   ******** 13150020
********                                                       ******** 13200020
*********************************************************************** 13300020
QTIP0060 EQU   *                                                        13400020
         USING TIOCRPT,RTIOC            USE RTIOC AS TIOCRPT BASE REG   13600020
         USING AVTSAVE2,RAVT            USE RAVT AS AVT BASE REGISTER   13650020
         NI    TIOCFLG,OFF-TIOCSYLW     REMOVE SYSTEM FROM LWAIT        13700020
         USING CVT,RWK11                USE RWK11 AS CVT BASE REGISTER  13703020
         L     RWK11,CVTPTR             GET CVT ADDRESS                 13706020
         L     RWK11,CVTTSCVT           GET ADDRESS OF TSCVT            13709020
         DROP  RWK11                    DROP RWK11 AS CVT BASE REGISTER 13712020
         USING TSCVT,RWK11              USE RWK11 AS TSCVT BASE REG     13715020
         LH    RWK11,TSCVTCUS           GET CURRENT NO. OF USERS IN SYS 13718020
         DROP  RWK11                    DROP RWK11 AS TSCVT BASE REG    13724020
         USING TSB,RTSB                 USE RTSB AS TSB BASE REGISTER   13727020
         L     RTSB,TIOCTSB-K1          GET ADDR OF FIRST TSB IN TABLE  13730020
         SR    RWRK8,RWRK8              CLEAR REGISTER                  13733020
         IC    RWRK8,TIOCTSBS           GET SIZE OF A TSB               13736020
         SPACE 2                                                        13739020
********                                                                13742020
******** CHECK EVERY TSB IN USE TO DETERMINE IF THE ASSOCIATED TERMINAL 13745020
******** KEYBOARD WAS LOCKED TO INPUT DUE TO THE SYSTEM LWAIT           13748020
******** CONDITION.  IF THE ASSOCIATED TERMINAL IS NOT ALSO IN A USER   13751020
******** LWAIT CONDITION, UNLOCK THE TERMINAL KEYBOARD TO ALLOW ANOTHER 13754020
******** READ TO BE ISSUED.  OTHERWISE, LEAVE THE KEYBOARD LOCKED.      13757020
********                                                                13760020
TSIN6000 EQU   *                                                        13763020
         LTR   RWK11,RWK11              ARE ANY USERS LEFT       A43888 13764021
         BCR   ZEROS,RETRN              NO, STOP CHECKING        A43888 13765021
         TM    TSBSTAT,TSBINUSE         IS THIS TSB IN USE              13766020
         BZ    TSIN6070                 BRANCH IF NOT TO GET NEXT TSB   13769020
         BCTR  RWK11,R0                 DECR COUNT OF TSBS LEFT TO SCAN 13772020
         TM    TSBSTAT,TSBLWAIT         IS THE TERMINAL IN A USER LWAIT 13775020
         BO    TSIN6070                 BRANCH IF YES TO GET NEXT TSB   13778020
         USING IEDQQCB,RQCB             USE RQCB AS QCB BASE REGISTER   13781020
         L     RQCB,TSBQCB-K1           GET ASSOCIATED QCB ADDRESS      13784020
         TM    QCBFLAG,QCBTSSES         IS A TSO SESSION IN PROGRESS    13787020
         BZ    TSIN6070                 BRANCH IF NOT TO GET NEXT TSB   13790020
         NI    QCBTSOF1,OFF-QCBNOBUF    UNLOCK THE TERMINAL KEYBOARD    13793020
         SPACE 2                                                        13796020
********                                                                13799020
******** POST THE LINE, IF NECESSARY, TO ACTIVATE THE TERMINAL.         13802020
********                                                                13805020
         USING IHADCB,RWRK3             USE RWRK3 AS DCB BASE REGISTER  13808020
         L     RWRK3,QCBDCBAD-K1        GET DCB ADDRESS                 13811020
         L     RLCB,DCBIOBAD            GET IOB ADDRESS                 13814020
         LA    RWRK2,LCBFLAG1-IEDQLCB   GET OFFSET OF IOB FROM LCB      13817020
         SR    RLCB,RWRK2               POINT TO BEGINNING OF FIRST LCB 13820020
         SR    RWRK2,RWRK2              CLEAR REGISTER                  13823020
         IC    RWRK2,DCBEIOBX           GET SIZE OF AN LCB ENTRY        13826020
         DROP  RWRK3                    DROP RWRK3 AS DCB BASE REGISTER 13829020
         SR    RWRK3,RWRK3              CLEAR REGISTER                  13832020
         IC    RWRK3,QCBRELLN           RELATIVE POSITION OF LCB IN TBL 13835020
         MR    RWRK2,RWRK2              CALC OFFSET OF LCB IN TABLE     13838020
         AR    RLCB,RWRK3               ADDRESS OF THE DESIRED LCB      13841020
         USING IEDQLCB,RLCB             USE RLCB AS LCB BASE REGISTER   13844020
         TM    LCBINSRC+K2,LCBDELAY     IS LCB ON THE DELAY QUEUE       13847020
         BO    TSIN6070                 BRANCH IF YES TO GET NEXT TSB   13850020
         CLI   LCBSTAT1,LCBFREEN        IS THIS LINE FREE               13853020
         BE    TSIN6030                 BRANCH IF YES                   13856020
         NI    LCBTSOB,OFF-LCBSOPL      REMOVE LCB FROM POLLING LIST    13859020
         B     TSIN6070                 BRANCH TO GET NEXT TSB          13862020
         SPACE 1                                                        13865020
TSIN6030 EQU   *                                                        13868020
         TM    QCBTSOF1,QCBPARTO        ANY OUTPUT IN PROGRESS          13871020
         BO    TSIN6070                 BRANCH IF YES TO GET NEXT TSB   13874020
         TM    QCBFLAG,QCBNOBRK         DOES TERM HAVE REVERSE BREAK    13877020
         BZ    TSIN6050                 BRANCH IF YES                   13880020
         TM    QCBFLAG,QCBREAD          DOES READ HAVE PRIORITY         13883020
         BO    TSIN6050                 BRANCH IF YES                   13886020
         TM    QCBTSOF1,QCBTGET         HAS TGET BEEN REQUESTED         13889020
         BZ    TSIN6070                 BRANCH IF NOT TO GET NEXT TSB   13892020
         SPACE 1                                                        13895020
TSIN6050 EQU   *                                                        13898020
         MVI   LCBSTAT1,LCBSENDN        INDICATE LINE IS SENDING        13901020
         ST    RLCB,LCBQCBA-K1          TPOST THE LINE TO ITSELF        13904020
         MVC   LCBLINK,AVTDOUBL+K1      CHAIN LCB TO FIRST ELEMENT ON   13907020
*                                       THE RETURN QUEUE                13910020
         ST    RLCB,AVTDOUBL            PLACE THIS LCB ON RETURN QUEUE  13913020
         MVI   LCBPRI,PRILNFRE          PRIORITY TO FREE A LINE         13916020
         SPACE 2                                                        13919020
********                                                                13922020
******** IF THERE ARE ANY MORE TSB'S WHICH ARE IN USE CONTINUE          13925020
******** SCANNING, OTHERWISE RETURN TO TSINPUT.                         13928020
********                                                                13931020
TSIN6070 EQU   *                                                        13934020
         AR    RTSB,RWRK8               POINT TO NEXT TSB IN THE TABLE  13943020
         B     TSIN6000                 BRANCH TO CONTINUE SCAN         13946020
         DROP  RLCB,RQCB,RTSB,RTIOC,RAVT  DROP CONTROL BLOCK BASE REGS  13949020
         EJECT                                                          14000020
*********************************************************************** 14100020
********                                                       ******** 14200020
******** THE FOLLOWING SECTION OF CODE IS USED BY TSINPUT TO   ******** 14300020
******** PUT THE SYSTEM IN AN LWAIT CONDITION.  THE ENTRY      ******** 14400020
******** POINT INTO THIS CODE IS QTIP0070.                     ******** 14500020
********                                                       ******** 14800020
******** INPUT REGISTERS -                                     ******** 14900020
********                                                       ******** 15000020
********       REG 10 - ADDRESS OF THE TIOCRPT.                ******** 15250020
********                                                       ******** 15300020
*********************************************************************** 15400020
QTIP0070 EQU   *                                                        15500020
         USING TIOCRPT,RTIOC            USE RTIOC AS TIOCRPT BASE REG   15840020
         OI    TIOCFLG,TIOCSYLW         PLACE THE SYSTEM IN LWAIT       16180020
         BR    RETRN                    RETURN TO TSINPUT               16200020
         DROP  RTIOC                    DROP CONTROL BLOCK BASE REGS    16300020
         EJECT                                                          16400020
*********************************************************************** 16500020
********                                                       ******** 16600020
******** THE FOLLOWING SECTION OF CODE IS USED BY CHARACTER    ******** 16700020
******** LINE DELETE AND CANCEL MESSAGE ROUTINES WITHIN        ******** 16800020
******** TSINPUT TO REMOVE TIME SHARING BUFFERS FROM THE INPUT ******** 16900020
******** QUEUE AND RETURN THEM TO THE FREE QUEUE.  THE ENTRY   ******** 17000020
******** POINT INTO THIS CODE IS QTIP0080.                     ******** 17100020
********                                                       ******** 17200020
******** INPUT REGISTERS -                                     ******** 17300020
********                                                       ******** 17400020
********       REG 6 -  ADDR OF TCAM BFR CURRENTLY PROCESSING. ******** 17500020
********       REG 9 -  ADDR OF THE CURRENT TSB.               ******** 17600020
********       REG 10 - ADDRESS OF THE TIOCRPT.                ******** 17700020
********       REG 13 - ADDRESS OF AVTSAVE2.                   ******** 17800020
********                                                       ******** 17900020
*********************************************************************** 18000020
QTIP0080 EQU   *                                                        18100020
         USING IEDQPRF,RTCBFR           USE RTCBFR AS TCAM BFR BASE REG 18300020
         USING TSB,RTSB                 USE RTSB AS TSB BASE REG        18400020
         USING AVTSAVE2,RAVT            USE RAVT AS AVT BASE REG        18500020
         USING TIOCRPT,RTIOC            USE RTIOC AS TIOCRPT BASE REG   18600020
         USING TIOCBUF,RTSBFR           USE RTSBFR AS TS BFR BASE REG   18700020
         SPACE 2                                                        18900020
********                                                                19000020
******** IF CANCEL MESSAGE IS IN PROGRESS, SEARCH FOR THE BEGINNING OF  19100020
******** THE FRAGMENT MESSAGE ON THE INPUT QUEUE.  IF CHARACTER LINE    19200020
******** DELETE HAS OCCURED, SEARCH FOR THE LAST BUFFER (WHICH WILL BE  19300020
******** A PARTIAL LINE) ON THE INPUT QUEUE.                            19400020
********                                                                19500020
         CLC   TSBIBFP,AVTFZERO         ANY TS BFRS ON INPUT HDR QUEUE  19550020
         BE    TSIN0800                 BRANCH IF NONE                  19600020
         L     RTSBFR,TSBIBFP-K1        GET FIRST TS BFR ON INPUT QUEUE 19660020
         LR    RWRK4,RTSBFR             SAVE ADDR OF CURRENT HDR BFR    19700020
         SPACE 1                                                        19800020
TSIN0620 EQU   *                                                        19900020
         TM    BUFFFL2,BUFFFRAG         IS THIS TS BFR PART OF FRAG MSG 20000020
         BZ    TSIN0640                 BRANCH IF NOT                   20100020
         TM    PRFSTAT1,PRFCNCLN        IS CANCEL MESSAGE IN PROGRESS   20200020
         BO    TSIN0660                 BRANCH IF YES                   20300020
         SPACE 1                                                        20400020
TSIN0640 EQU   *                                                        20500020
         CLC   BUFFHEAD,AVTFZERO        MORE HDR BFRS ON INPUT QUEUE    20600020
         BE    TSIN0650                 BRANCH IF NO MORE               20700020
         LR    RWRK4,RTSBFR             SAVE ADDR OF CURRENT HDR BFR    20800020
         L     RTSBFR,BUFFHEAD-K1       GET ADDR OF NEXT HDR BFR ON Q   20900020
         B     TSIN0620                 CONTINUE SEARCH                 21000020
         SPACE 1                                                        21020020
TSIN0650 EQU   *                                                        21040020
         TM    BUFFFL1,BUFFNLCR         IS LAST TS MSG COMPLETE         21060020
         BO    TSIN0800                 BRANCH IF YES                   21080020
         NI    BUFFFL1,BUFFHDR          RESET FIRST FLAG BYTE           21080620
         NI    BUFFFL2,BUFFFRAG         RESET SECOND FLAG BYTE          21081220
         XC    BUFFLNTH,BUFFLNTH        RESET AMOUNT OF DATA TO ZERO    21082020
         XC    BUFFWORK,BUFFWORK        RESET CHAR COUNT TO ZERO        21122020
         L     RWRK1,BUFFTRLR-K1        GET TRAILER BFR PTR             21163020
         LA    RWRK1,K0(R0,RWRK1)       CLEAR HI ORDER BYTE OF REG      21243020
         LTR   RWRK1,RWRK1              ANY TRAILER BFRS ON THIS HEADER 21323020
         BZ    TSIN0800                 BRANCH IF NONE                  21403020
         XC    BUFFTRLR,BUFFTRLR        CLEAR TRAILER BUFFER POINTER    21483020
         LR    RWK11,RTSBFR             SAVE PTR TO LAST HEADER BFR     21563020
         LR    RTSBFR,RWRK1             INITIALIZE LAST BFR POINTER     21643020
         B     TSIN0690                 BRANCH TO RETURN TRAILER BFRS   21723020
         DROP  RTSBFR                   DROP RTSBFR AS  TS BFR BASE REG 21803020
         SPACE 1                                                        21883020
TSIN0660 EQU   *                                                        21963020
         USING TIOCBUF,RWRK4            USE RWRK4 AS TS BFR BASE REG    22043020
         CR    RTSBFR,RWRK4             IS FIRST BFR TO BE DROPPED ALSO 22123020
*                                       FIRST ON INPUT QUEUE            22203020
         BNE   TSIN0670                 BRANCH IF NO                    22363020
         XC    TSBIBFP,TSBIBFP          CLEAR INPUT QUEUE POINTER       22443020
         B     TSIN0680                 BRANCH TO RETURN BUFFERS        22523020
         SPACE 1                                                        22603020
TSIN0670 EQU   *                                                        22683020
         XC    BUFFHEAD,BUFFHEAD        ZERO LINK FIELD OF PREVIOUS HDR 22763020
         DROP  RWRK4                    DROP RWRK4 AS TS BFR BASE REG   22843020
         SPACE 2                                                        22923020
********                                                                23003020
******** DETERMINE HOW MANY TS BUFFERS ARE TO BE RETURNED AND LINK THEM 23083020
******** TOGETHER FOR PLACEMENT ON THE FREE QUEUE.  IF AUTOMATIC LINE   23163020
******** NUMBERING IS IN PROGRESS, DECREMENT THE LINE COUNT FOR EACH    23243020
******** TS HEADER BUFFER RETURNED.                                     23323020
********                                                                23403020
TSIN0680 EQU   *                                                        23483020
         USING TIOCBUF,RTSBFR           USE RTSBFR AS TS BFR BASE REG   23563020
         LR    RWK11,RTSBFR             INITIALIZE NEXT HDR BFR POINTER 23643020
         LR    RWRK1,RTSBFR             INITIALIZE NEXT TRLR BFR PTR    23723020
         SPACE 1                                                        23803020
TSIN0690 EQU   *                                                        23883020
         SR    RWRK4,RWRK4              INIT NO. OF TS BFRS RETURNING   23963020
         SPACE 1                                                        24043020
TSIN0700 EQU   *                                                        24123020
         LA    RWRK4,K1(R0,RWRK4)       INCR NO. OF TS BFRS RETURNING   24203020
         CLC   BUFFTRLR,AVTFZERO        ANY TRLR BFRS ON LAST HDR BFR   24283020
         BE    TSIN0720                 BRANCH IF NO MORE               24363020
         L     RTSBFR,BUFFTRLR-K1       GET ADDR OF NEXT TRLR BFR       24443020
         B     TSIN0700                 CONT COUNT OF TRLR BFRS         24523020
         SPACE 1                                                        24603020
TSIN0720 EQU   *                                                        24683020
         TM    TSBFLG2,TSBAUTON+TSBAULST  IS AUTO LINE NO. IN PROGRESS  24763020
         BNO   TSIN0740                 BRANCH IF NO                    24843020
         DROP  RTSBFR                   DROP RTSBFR AS TS BFR BASE REG  24923020
         USING TIOCBUF,RWK11            USE RWK11 AS TS BFR BASE REG    25003020
         TM    BUFFFL1,BUFFNLCR         IS THE LAST TS MSG COMPLETE     25083020
         BZ    TSIN0740                 BRANCH IF NOT                   25163020
         L     RWK15,TSBAUTOS           GET CURRENT VALUE OF LINE NO.   25243020
         S     RWK15,TSBAUTOI           DECR LINE NO. BY INCR VALUE     25323020
         ST    RWK15,TSBAUTOS           UPDATE LINE NUMBER              25403020
         SPACE 1                                                        25483020
TSIN0740 EQU   *                                                        25563020
         CLC   BUFFHEAD,AVTFZERO        MORE HDR BFRS ON INPUT QUEUE    25643020
         BE    TSIN0760                 BRANCH IF NO MORE               25723020
         L     RWK11,BUFFHEAD-K1        GET NEXT HDR BFR ON INPUT QUEUE 25803020
         DROP  RWK11                    DROP RWK11 AS TS BFR BASE REG   25883020
         USING TIOCBUF,RTSBFR           USE RTSBFR AS TS BFR BASE REG   25963020
         ST    RWK11,BUFFTRLR-K1        LINK BFRS FOR RETURN TO FREE Q  26043020
         LR    RTSBFR,RWK11             SET LAST BFR PTR TO THIS HDR    26123020
         B     TSIN0700                 CONT COUNT OF HDR BFRS          26203020
         SPACE 2                                                        26283020
********                                                                26363020
******** REMOVE THE AFOREMENTIONED BUFFERS FROM THE INPUT QUEUE AND     26443020
******** RETURN THEM TO THE FREE QUEUE.  ALSO UPDATE THE BUFFER COUNT   26523020
******** FIELDS FOR BOTH QUEUES.                                        26603020
********                                                                26683020
TSIN0760 EQU   *                                                        26763020
         MVC   BUFFTRLR,TIOCFBFF+K1     RETURN BFRS TO FREE QUEUE USING 26843020
         ST    RWRK1,TIOCFBFF           PUSH DOWN METHOD                26923020
         SR    RWRK1,RWRK1              CLEAR REGISTER                  27023020
         IC    RWRK1,TSBNIBF            GET NO. OF BFRS ORIG ON FREE Q  27123020
         SR    RWRK1,RWRK4              DECR THIS VALUE BY NO. RETURNED 27223020
         STC   RWRK1,TSBNIBF            STORE UPDATED INPUT BFR COUNT   27323020
         AH    RWRK4,TIOCNFBF           UPDATE NO. OF BFRS ON FREE Q    27800020
         STH   RWRK4,TIOCNFBF           STORE UPDATED VALUE             27900020
         SPACE 2                                                        27902020
********                                                                27904020
******** IF ENTRY INTO THIS ROUTINE WAS TO CANCEL A TCAM MESSAGE,       27906020
******** RETURN TO THE CALLER AT THIS TIME.                             27908020
********                                                                27912020
TSIN0800 EQU   *                                                        27920020
         TM    PRFSTAT1,PRFCNCLN        IS CANCEL MESSAGE IN PROGRESS   27930020
         BZ    TSIN0900                 BRANCH IF NOT                   27933020
         NI    TSBFLG2,OFF-TSBBIPI-TSBBRKIN  TERM BREAKIN PROCESSING    27939020
         BR    RETRN                    RETURN TO TSINPUT               27942020
         SPACE 2                                                        27949620
********                                                                27950420
******** IF THIS IS THE LAST TCAM BUFFER OF THE MESSAGE AND NO DATA     27951220
******** REMAINS TO BE SCANNED, OR IF THE NEXT CHARACTER IN THE TCAM    27952020
******** BUFFER IS A NEW LINE OR CARRIAGE RETURN CHARACTER, BRANCH TO   27952820
******** COMPLETE THE TCAM AND/OR TS MESSAGE.  OTHERWISE, RETURN TO     27953620
******** TSINPUT.                                                       27954420
********                                                                27955220
TSIN0900 EQU   *                                                        27959220
         CLR   RSCANF,RSCANL            CR OR NL CHAR NEXT IN TCAM BFR  27964020
         BNE   TSIN0170                 BRANCH IF YES                   27972020
         TM    PRFSTAT1,PRFNLSTN        IS THIS LAST TCAM BFR OF MSG    27980020
         BCR   ZEROS,RETRN              RETURN TO TSINPUT IF NOT        27990020
         LTR   RDSZE,RDSZE              ANY DATA LEFT TO SCAN           28000020
         BZ    TSIN0170                 BR IF NONE TO EOM PROCESSING    28009020
         BR    RETRN                    RETURN TO TSINPUT               28018020
         DROP  RTCBFR,RTSB,RTIOC,RTSBFR,RAVT  DROP CONTROL BLOCK REGS   28029020
         EJECT                                                          28038020
*********************************************************************** 28300020
********                                                       ******** 28400020
******** THE FOLLOWING SECTION OF CODE IS USED BY TSINPUT TO   ******** 28500020
******** ALLOCATE TS BUFFERS AND MOVE THE SCANED DATA IN THE   ******** 28600020
******** TCAM BUFFER INTO TS BUFFER(S), AND/OR PERFORM END OF  ******** 28700020
******** TRANSMISSION PROCESSING WHENEVER APPLICABLE.  THE     ******** 28800020
******** ENTRY POINT INTO THIS CODE IS QTIP0090.               ******** 28900020
********                                                       ******** 29000020
******** INPUT REGISTERS -                                     ******** 29100020
********                                                       ******** 29200020
********       REG 2 -  POINTER TO BEGINNING OF DATA SCANNED.  ******** 29260020
********       REG 3 -  POINTER TO END OF DATA SCANNED.        ******** 29320020
********       REG 6 -  ADDR OF TCAM BFR CURRENTLY PROCESSING. ******** 29400020
********       REG 9 -  ADDRESS OF THE CURRENT TSB.            ******** 29500020
********       REG 10 - ADDRESS OF THE TIOCRPT.                ******** 29600020
********       REG 13 - ADDRESS OF AVTSAVE2.                   ******** 29700020
********                                                       ******** 29800020
*********************************************************************** 29900020
QTIP0090 EQU   *                                                        30000020
         USING AVTSAVE2,RAVT            USE RAVT AS AVT BASE REGISTER   30200020
         USING TIOCRPT,RTIOC            USE RTIOC AS TIOCRPT BASE REG   30300020
         USING TSB,RTSB                 USE RTSB AS TSB BASE REGISTER   30400020
         SPACE 3                                                 A45625 30407021
********                                                                30414021
******** CHECK FOR TCLEARQ INPUT ISSUED, IF SO, RETURN TO TSINPUT       30421021
********                                                                30428021
         TM    TSBFLG1,TSBIFLSH         IS INPUT FLUSH IN        A45625 30435021
*                                       PROGRESS                 A45625 30442021
         BZ    TSIN0150                 NO, CHECK SIZE OF DATA   A45625 30449021
         NI    TSBFLG1,OFF-TSBIFLSH     TURN OFF INPUT FLUSH     A45625 30456021
*                                       FLAG                     A45625 30463021
         NI    TSBFLG2,OFF-(TSBBIPI+TSBBRKIN) TURN OFF BREAKIN-  A45625 30470021
*                                       FLASHBACK FLAGS                 30477021
         BR    RETRN                    RETURN TO TSINPUT        A45625 30484021
         SPACE 2                                                        30500020
********                                                                30600020
******** GET SIZE OF DATA IN THE TCAM BUFFER.                           30700020
********                                                                30800020
TSIN0150 EQU   *                                                 A45625 30850021
         USING IEDQPRF,RTCBFR           USE RTCBFR AS TCAM BFR BASE REG 30900020
         LH    RDSZE,PRFSIZE            GET SIZE OF DATA IN TCAM BFR    31000020
         SPACE 2                                                        31200020
********                                                                31300020
******** DETERMINE IF A PARTIALLY FILLED TS BUFFER EXISTS ON THE INPUT  31400020
******** QUEUE.  IF SO, CONTINUE MOVING DATA INTO THIS TS BUFFER BEGIN- 31500020
******** ING AT THE POINT WHERE THE LAST MOVE LEFT OFF.                 31600020
********                                                                31700020
TSIN0170 EQU   *                                                        31750020
         CLC   TSBIBFP,AVTFZERO         ANY TS BFRS ON INPUT HDR QUEUE  31800020
         BE    TSIN0242                 BRANCH IF NONE                  31900020
         USING TIOCBUF,RTSBFR           USE RTSBFR AS TS BFR BASE REG   32000020
         L     RTSBFR,TSBIBFP-K1        GET FIRST TS BFR ON INPUT QUEUE 32010020
         SPACE 1                                                        32020020
TSIN0190 EQU   *                                                        32030020
         CLC   BUFFHEAD,AVTFZERO        MORE HDR BFRS ON INPUT QUEUE    32040020
         BE    TSIN0210                 BRANCH IF NO MORE               32050020
         L     RTSBFR,BUFFHEAD-K1       GET NEXT HDR BFR ON INPUT QUEUE 32060020
         B     TSIN0190                 CONT SEARCH FOR LAST HDR BFR    32070020
         SPACE 1                                                        32080020
TSIN0210 EQU   *                                                        32090020
         LR    RWK11,RTSBFR             SAVE POINTER TO LAST HDR BFR    32100020
         TM    BUFFFL1,BUFFNLCR         IS HDR MARKED AS COMPL TS MSG   32200020
         BZ    TSIN0230                 BRANCH IF NO                    32230020
         LTR   RDSZE,RDSZE              ANY DATA IN TCAM BFR TO MOVE    32260020
         BNZ   TSIN0242                 BRANCH IF YES                   32290020
         TM    BUFFFL2,BUFFFRAG         IS LAST TCAM MSG COMPLETE       32320020
         BZ    TSIN0242                 BRANCH IF YES                   32350020
         SPACE 1                                                        32400020
TSIN0230 EQU   *                                                        32500020
         CLC   BUFFTRLR,AVTFZERO        ANY TRLR BFRS LINKED TO LST BFR 32600020
         BE    TSIN0240                 BRANCH IF NO                    32700020
         L     RTSBFR,BUFFTRLR-K1       GET ADDR OF NEXT TRAILER BFR    32800020
         B     TSIN0230                 CONT SEARCH FOR LAST BFR IN Q   32900020
         SPACE 1                                                        33000020
TSIN0240 EQU   *                                                        33100020
         LTR   RDSZE,RDSZE              ANY DATA IN TCAM BFR TO MOVE    33200020
         BZ    TSIN0352                 BRANCH IF NONE                  33300020
         TM    BUFFFL1,BUFFFULL         IS THE LAST BFR IN QUEUE FULL   33400020
         BZ    TSIN0249                 BRANCH IF NO             S22028 33500001
         SPACE 1                                                        33600020
TSIN0242 EQU   *                                                        33700020
         LR    R0,RWRK7                 SAVE CURRENT CHARACTER COUNT    33720020
         BAL   RWK15,TSIN0500           BR TO BFR ALLOCATION ROUTINE    33750020
         SPACE 2                                                 S22028 33751001
********                                                                33752001
******** FOR 3270, IF THIS IS BEGINNING OF A TCAM MSG, MOVE CONTROL     33753001
******** CHARACTERS INTO TS BUFFERS                                     33754001
********                                                                33755001
         TM    TSBSTAT,TSB3270          TEST FOR 3270 TERMINAL   S22028 33756001
         BZ    TSIN0248                 BR AROUND IF NOT         S22028 33757001
         TM    PRFSTAT1,PRFNHDRN        IS THIS FIRST TCAM BFR   S22028 33758001
*                                       OF MSG                   S22028 33759001
         BO    TSIN0248                 BR IF NO                 S22028 33760001
         TM    BUFFFL1,BUFFHDR          IS THIS A TS HDR BFR     S22028 33761001
         BZ    TSIN0248                 BR IF NO                 S22028 33762001
         LA    RWRK7,AVTUMALN+AVTHDRSZ(RTCBFR)                   S22028 33763001
*                                       POINTS AT FIRST CHAR IN BFR     33764001
         SPACE 1                                                 S22028 33765001
TSIN0244 EQU   *                                                 S22028 33766001
         CLI   K0(RWRK7),AVTEZERO       CHECK FOR ZEROS          S22028 33767001
         BNE   TSIN0245                 BRANCH IF NO             S22028 33768001
         LA    RWRK7,K1(R0,RWRK7)       POINT PASS ZERO          S22028 33769001
         B     TSIN0244                 CHECK NEXT BYTE          S22028 33770001
         SPACE 1                                                 S22028 33771001
TSIN0245 EQU   *                                                 S22028 33772001
         LA    RMVSZ2,CC3270ND          ASSUME MSG HAS NO DATA   S22028 33773001
*                                       (ONLY 1 AID CHAR)               33774001
         TM    PRFTIC,CC32706           DOES MSG HAVE MORE THAN  S22028 33775001
*                                       1 CONTROL CHARS                 33776001
         BZ    TSIN0246                 NO, BRANCH AROUND        S22028 33777001
         LA    RMVSZ2,CC3270D3          ASSUME 3 CONTROL CHARS   S22028 33778001
         CLI   CC3270D3(RWRK7),SBA      CHECK FOR SBA CHAR       S22028 33779001
         BNE   TSIN0246                 BRANCH IF NO             S22028 33780001
         LA    RMVSZ2,CC3270D6          THERE ARE 6 CONTROL      S22028 33781001
*                                       CHARS                    S22028 33782001
         SPACE 1                                                 S22028 33783001
TSIN0246 EQU   *                                                 S22028 33784001
         STC   RMVSZ2,BUFFLNTH          UPDATE DATA LENGTH IN    S22028 33785001
*                                       BFR                      S22028 33786001
         BCTR  RMVSZ2,R0                DECREMENT FOR EX         S22028 33787001
*                                       INSTRUCTION              S22028 33788001
         SPACE 1                                                 S22028 33789001
TSIN0247 EQU   *                                                 S22028 33790001
         EX    RMVSZ2,TSIN0345          MOVE 3270 CONTROL CHARS  S22028 33791001
*                                       INTO TS BUFFER                  33792001
         OI    BUFFFL2,BUFF3270         TELL TGET THIS BFR HAS   S22028 33793001
*                                       3270                     S22028 33794001
*                                       CONTROL CHARS                   33795001
         SPACE 1                                                 S22028 33796001
TSIN0248 EQU   *                                                 S22028 33797001
         LTR   RDSZE,RDSZE              ANY DATA IN TCAM BFR TO MOVE    33800020
         BZ    TSIN0352                 BRANCH IF NONE                  33900020
         LR    RWRK7,R0                 RESTORE CURRENT CHARACTER COUNT 33903020
         SPACE 2                                                        33906020
********                                                                33912020
******** IF THERE IS ANY DATA IN THIS TCAM BUFFER WHICH IS REMAINING    33918020
******** FROM A PREVIOUS INCOMPLETE MOVE, THE CURRENT CHARACTER COUNT   33924020
******** IN THE LAST TS HEADER BUFFER REFLECTS THE ACTUAL NUMBER OF     33930020
******** CHARACTERS NOT DELETED.  IF THIS IS THE FIRST ATTEMPT TO MOVE  33936020
******** THE SCANNED DATA, PLACE THE CURRENT CHARACTER COUNT INTO THE   33942020
******** LAST TS HEADER BUFFER ON THE INPUT QUEUE.                      33948020
********                                                                33954020
TSIN0249 EQU   *                                                 S22028 33960001
         TM    PRFTIC,NOTMOVED          ANY UNMOVED DATA IN TCAM BUFFER 33966020
*                                       FROM A PREVIOUS SCAN            33972020
         BO    TSIN0250                 BRANCH IF YES                   33978020
         STH   RWRK7,BUFFWORK-TIOCBUF(R0,RWK11) STORE CHARACTER COUNT   34038020
         SPACE 2                                                        34100020
********                                                                34200020
******** DETERMINE IN WHICH BASIC UNIT OF THE TCAM BUFFER THE DATA TO   34300020
******** BE MOVED BEGINS.                                               34400020
********                                                                34500020
TSIN0250 EQU   *                                                        34600020
         DROP  RTCBFR                   DROP RTCBFR AS TCAM BFR BASE    34700020
         USING IEDQPRF,RWRK4            USE RWRK4 AS TCAM BFR BASE REG  34800020
         LR    RWRK4,RTCBFR             GET ADDR OF FIRST BASIC UNIT    34900020
         SPACE 1                                                        35000020
TSIN0260 EQU   *                                                        35100020
         LH    RWK15,AVTKEYLE           GET BASIC UNIT SIZE             35200020
         SPACE 1                                                        35300020
TSIN0270 EQU   *                                                        35400020
         LA    RMVSZ1,K12(RWK15,RWRK4)  POINT TO END OF THIS BASIC UNIT 35500020
         LA    RWRK4,K0(R0,RWRK4)       CLEAR HI ORDER BYTE OF REGISTER 35600020
         CLR   RSCANF,RWRK4             COULD DATA BEGIN IN THIS B.U.   35700020
         BL    TSIN0280                 BRANCH IF NO TO CONT SEARCH     35800020
         CLR   RSCANF,RMVSZ1            DOES DATA BEGIN IN THIS B.U.    35900020
         BE    TSIN0290                 NO, IT BEGINS IN THE NEXT B.U.  36000020
         BNH   TSIN0300                 BRANCH IF YES                   36100020
         SPACE 1                                                        36200020
TSIN0280 EQU   *                                                        36300020
         L     RWRK4,PRFTIC             GET ADDR OF NEXT BASIC UNIT     36400020
         B     TSIN0270                 CONT SEARCH FOR BEGIN OF MOVE   36500020
         SPACE 1                                                        36600020
TSIN0290 EQU   *                                                        36700020
         L     RWRK4,PRFTIC             GET ADDR OF NEXT BASIC UNIT     36800020
         LA    RSCANF,K12(R0,RWRK4)     RESET BEGIN DATA PTR TO THIS BU 36900020
         LA    RMVSZ1,K12(RWK15,RWRK4)  POINT OT END OF THIS BASIC UNIT 37000020
         SPACE 2                                                        37100020
********                                                                37200020
******** DETERMINE HOW MUCH DATA IS TO BE MOVED AT THIS TIME.  THIS     37300020
******** AMOUNT WILL BE THE SMALLER OF EITHER THE NUMBER OF UNFILLED    37400020
******** BYTES IN THE CURRENT TS BUFFER, OR THE AMOUNT OF UNMOVED DATA  37500020
******** IN THE CURRENT BASIC UNIT.                                     37600020
********                                                                37700020
TSIN0300 EQU   *                                                        37800020
         CLR   RSCANL,RMVSZ1            COULD END OF DATA BE IN THIS BU 37900020
         BH    TSIN0310                 BRANCH IF NO                    38000020
         CLR   RSCANL,RSCANF            IS END OF DATA IN THIS B.U.     38100020
         BNH   TSIN0310                 BRANCH IF NO                    38200020
         LR    RMVSZ1,RSCANL            END OF DATA IS IN THIS B.U.     38300020
         SPACE 1                                                        38400020
TSIN0310 EQU   *                                                        38500020
         SR    RMVSZ1,RSCANF            CALC AMOUNT OF DATA IN THIS BU  38600020
         LR    RFILL,RTSBFR             INIT TS BFR BEGIN DATA MOVE PT  38700020
         SR    RWK15,RWK15              CLEAR REGISTER                  38800020
         IC    RWK15,BUFFOFST           GET HDR OR TRLR OFFSET          38900020
         AR    RFILL,RWK15              ADD OFFSET TO TS BFR ADDRESS    39000020
         IC    RWK15,BUFFLNTH           GET LENGTH OF DATA IN TS BFR    39100020
         AR    RFILL,RWK15              CALC BEGIN ADDR OF NEXT MOVE    39200020
         LH    RMVSZ2,TIOCBFSZ          GET TS BUFFER SIZE              39300020
         AR    RMVSZ2,RTSBFR            POINT TO END OF THIS TS BUFFER  39400020
         SR    RMVSZ2,RFILL             CALC UNFILLED SPACE IN TS BFR   39500020
         CLR   RMVSZ2,RMVSZ1            IS UNFILLED SPACE LESS OR EQUAL 39600020
*                                       TO AMOUNT OF DATA IN TCAM B.U.  39700020
         BNH   TSIN0320                 BRANCH IF YES                   39800020
         LR    RMVSZ2,RMVSZ1            MOVE AMOUNT OF DATA IN B.U.     39900020
         B     TSIN0330                 BRANCH TO CONTINUE MOVE         40000020
         SPACE 1                                                        40100020
TSIN0320 EQU   *                                                        40200020
         OI    BUFFFL1,BUFFFULL         MARK TS BUFFER AS FULL          40300020
         SPACE 2                                                        40400020
********                                                                40500020
******** MOVE DATA FROM THE TCAM BASIC UNIT INTO THE TS BUFFER AND      40600020
******** CALCULATE THE AMOUNT OF UNMOVED DATA LEFT IN THE TCAM BUFFER.  40700020
********                                                                40800020
TSIN0330 EQU   *                                                        40900020
         SR    RDSZE,RMVSZ2             DECR AMOUNT OF DATA IN TCAM BFR 41000020
         AR    RWK15,RMVSZ2             INCR AMOUNT OF DATA IN TS BFR   41100020
         STC   RWK15,BUFFLNTH           STORE UPDATED TS BFR DATA COUNT 41200020
         DROP  RWRK4                    DROP RWRK4 AS TCAM BFR BASE REG 41210020
         USING IEDQPRF,RTCBFR           USE RTCBFR AS TCAM BFR BASE REG 41220020
         LH    RWK15,PRFSRCE            GET OLD DATA OFFSET             41226020
         AR    RWK15,RMVSZ2             UPDATE DATA OFFSET              41240020
         STH   RWK15,PRFSRCE            STORE UPDATED OFFSET            41270020
         BCTR  RMVSZ2,R0                DECR MOVE AMOUNT FOR EXECUTE    41300020
         EX    RMVSZ2,TSIN0340          MOVE DATA INTO TS BUFFER        41400020
         LA    RSCANF,K1(RMVSZ2,RSCANF) INCR TCAM BFR BEGIN DATA PTR    41500020
         SPACE 2                                                        41600020
********                                                                41700020
******** DETERMINE IF ALL THE DATA HAS BEEN MOVED FROM THE TCAM BUFFER  41800020
******** INTO TS BUFFER(S).  IF NOT, DETERMINE IF ANOTHER TS BUFFER IS  41900020
******** NEEDED TO PERFORM THE NEXT MOVE.                               42000020
********                                                                42100020
         CLR   RSCANF,RSCANL            ALL OF SCANED DATA MOVED        42200020
         BE    TSIN0350                 BRANCH IF YES                   42300020
         TM    BUFFFL1,BUFFFULL         IS THE LAST TS BUFFER FULL      42400020
         BZ    TSIN0260                 BRANCH IF NO                    42500020
         OI    PRFTIC,NOTMOVED          IND NOT ALL OF SCANNED DATA     42530020
*                                       MOVED FROM TCAM BUFFER          42560020
         LA    RWK15,TSIN0260           RETURN PT FROM BFR ALLOCATION   42600020
         B     TSIN0500                 BR TO BFR ALLOCATION ROUTINE    42700020
         SPACE 1                                                        42800020
TSIN0340 EQU   *                                                        42900020
         MVC   K0(RMVSZ2,RFILL),K0(RSCANF)  MOVE DATA FR TCAM TO TS BFR 43000020
         SPACE 1                                                 S22028 43020001
TSIN0345 EQU   *                                                 S22028 43040001
         MVC   BUFFHDLN(RMVSZ2,RTSBFR),K0(RWRK7) MOVE 3270       S22028 43060001
*                                       CONTROL CHA              S22028 43080001
         SPACE 2                                                        43100020
********                                                                43200020
******** IF A COMPLETE LINE (ENDS IN CARRIAGE RETURN AND/OR EOT) HAS    43300020
******** BEEN MOVED INTO THE TS BUFFER, MARK THE BUFFER AS FULL AND     43400020
******** INCREMENT THE LINE COUNT IF AUTOMATIC LINE NUMBERING IS IN     43500020
******** PROGRESS.  IF EOT OCCURED, TURN OFF THE FRAGMENT INDICATORS    43600020
******** IN ALL THE HEADER BUFFERS WHICH ARE IN THIS TSBS INPUT QUEUE.  43700020
********                                                                43800020
TSIN0350 EQU   *                                                        43900020
         NI    PRFTIC,OFF-NOTMOVED      IND ALL OF SCANNED DATA MOVED   43950020
         BCTR  RSCANL,R0                BACK UP TO LAST CHAR SCANED     44000020
         LTR   RDSZE,RDSZE              ANY UNMOVED DATA IN TCAM BUFFER 44100020
         BNZ   TSIN0362                 BRANCH IF YES                   44160020
         SPACE 1                                                        44280020
TSIN0352 EQU   *                                                        44340020
         USING IEDQQCB,RQCB             USE RQCB AS QCB BASE REGISTER   44420020
         L     RQCB,TSBQCB-K1           GET QCB ADDRESS                 44440020
         TM    PRFSTAT1,PRFNLSTN        IS THIS LAST TCAM BFR OF MSG    44460020
         BO    TSIN0360                 BRANCH IF NO                    44480020
         TM    PRFTIC,WRITEBRK          DID WR BREAK OCCUR IN THIS BFR  44540020
         BO    TSIN0420                 BRANCH IF YES                   44600020
         TM    PRFTIC,TIMEOUT           DID TIMEOUT OCCUR IN THIS BFR   44650020
         BZ    TSIN0370                 BRANCH IF NO                    44700020
         TM    PRFTIC,WAITQBFR          WAS THIS BFR ON THE WAIT QUEUE  44750020
         BO    TSIN0420                 BRANCH IF YES                   44800020
         OI    QCBFLAG,QCBREAD          IND READ STILL HAS PRIORITY     44850020
         SPACE 1                                                        44900020
TSIN0360 EQU   *                                                        45000020
         CLC   PRFSIZE,AVTFZERO         ANY DATA MOVED FROM TCAM BFR    45006020
         BE    TSIN0490                 BRANCH IF NONE                  45012020
         TM    PRFSTAT1,PRFEOFN         WAS SET EOF EXECUTED            45020020
         BO    TSIN0370                 YES, TREAT AS END OF MESSAGE    45040020
         SPACE 1                                                        45060020
TSIN0362 EQU   *                                                        45080020
         CLI   K0(RSCANL),NEWLINE       WAS LAST CHAR SCANNED NEW LINE  45086020
         BE    TSIN0364                 BRANCH IF YES                   45093020
         CLI   K0(RSCANL),CARRRTRN      WAS LAST CHAR SCANED CARR RETRN 45100020
         BNE   TSIN0490                 RETURN TO TSINPUT IF NOT        45120020
         SPACE 2                                                        45140020
********                                                                45160020
******** IF THIS TS MESSAGE IS A NULL LINE (NO DATA OR THE ONLY         45180020
******** CHARACTER IN THE TS BUFFER IS NEW LINE OR CARRIAGE RETURN),    45200020
******** TERMINATE AUTOMATIC PROMPTING.                                 45220020
********                                                                45240020
TSIN0364 EQU   *                                                        45260020
         DROP  RTSBFR                   DROP RTSBFR AS TS BFR BASE REG  45280020
         BAL   RWK15,TSIN9010           CALCULATE ACTUAL DATA    S22028 45300001
*                                       SIZE                     S22028 45310001
         CH    R0,ONE                   IS ONLY CHAR NL OR CR    S22028 45320001
         BH    TSIN0390                 BRANCH IF NO                    45340020
         NI    TSBFLG2,OFF-TSBAUTON     TERMINATE AUTO PROMPTING        45360020
         B     TSIN0390                 CONTINUE                        45380020
         SPACE 1                                                        45400020
TSIN0370 EQU   *                                                        45500020
         BAL   RWK15,TSIN9010           CALCULATE ACTUAL DATA    S22028 45510001
*                                       SIZE                     S22028 45512001
         CH    R0,ONE                   IS DATA LENGTH IN TS BFR S22028 45514001
*                                       1                        S22028 45516001
         BH    TSIN0374                 BR IF MORE THAN ONE CHAR IN BFR 45520020
         BL    TSIN0372                 BR IF NO DATA IN TS BFR         45530020
         LA    RWRK1,BUFFHDLN(RWRK1,RWK11) POINTS AT ONLY DATA   S22028 45540001
*                                       CHAR                     S22028 45542001
         CLI   K0(RWRK1),NEWLINE        IS THE ONLY CHAR IN TS   S22028 45544001
*                                       BFR NL                   S22028 45546001
         BE    TSIN0372                 BRANCH IF YES                   45550020
         CLI   K0(RWRK1),CARRRTRN       IS THE ONLY CHAR IN TS   S22028 45560001
*                                       BFR CR                   S22028 45565001
         BNE   TSIN0374                 BRANCH IF NO                    45570020
         SPACE 1                                                        45580020
TSIN0372 EQU   *                                                        45590020
         NI    TSBFLG2,OFF-TSBAUTON     TERMINATE AUTO PROMPTING        45600020
         SPACE 2                                                        45610020
********                                                                45620020
******** INDICATE THIS TCAM MESSAGE IS COMPLETE.                        45630020
********                                                                45640020
TSIN0374 EQU   *                                                        45650020
         USING TIOCBUF,RWRK4            USE RWRK4 AS TS BFR BASE REG    45700020
         CLC   TSBIBFP,AVTFZERO         ANY TS BFRS ON INPUT HDR QUEUE  45800020
         BE    TSIN0392                 BRANCH IF NONE                  45900020
         L     RWRK4,TSBIBFP-K1         GET FIRST TS HDR ON INPUT QUEUE 46000020
         SPACE 1                                                        46100020
TSIN0380 EQU   *                                                        46200020
         NI    BUFFFL2,OFF-BUFFFRAG     TURN OFF MSG FRAG INDR IN BFR   46300020
         L     RWRK4,BUFFHEAD-K1        GET NEXT HDR BFR ON INPUT QUEUE 46400020
         LA    RWRK4,K0(R0,RWRK4)       CLEAR HI-ORDER BYTE OF REG      46500020
         LTR   RWRK4,RWRK4              IS THIS END OF INPUT BFR QUEUE  46600020
         BNZ   TSIN0380                 BRANCH IF NO                    46700020
         TM    K0(RWK11),BUFFNLCR       IS LAST TS MESSAGE COMPLETE     46800020
         BO    TSIN0393                 BRANCH IF YES                   46900020
         SPACE 2                                                        46940020
********                                                                46980020
******** INDICATE THIS TS MESSAGE IS COMPLETE.                          47020020
********                                                                47060020
TSIN0390 EQU   *                                                        47100020
         DROP  RWRK4                    DROP RWRK4 AS TS BFR BASE REG   47200020
         USING TIOCBUF,RTSBFR           USE RTSBFR AS TS BFR BASE REG   47300020
         OI    BUFFFL1,BUFFFULL         MARK LAST TS BFR AS FULL        47400020
         DROP  RTSBFR                   DROP RTSBFR AS TS BFR BASE REG  47460020
         USING TIOCBUF,RWK11            USE RWK11 AS TS BFR BASE REG    47520020
         OI    BUFFFL1,BUFFNLCR         MARK LAST TS MSG AS COMPLETE    47580020
         NI    BUFFFL2,OFF-BUFFPART     TURN OFF PART LINE INDR IF ON   47640020
         NI    TSBFLG2,OFF-TSBBRKIN-TSBBIPI  IND PARTIAL LINE COMPLETE  47670020
         SPACE 2                                                        47700020
********                                                                47800020
******** INCREMENT AUTOMATIC LINE NUMBER                                47900020
********                                                                48000020
         TM    TSBFLG2,TSBAUTON+TSBAULST  IS AUTO LINE NO. IN PROGRESS  48100020
         BNO   TSIN0392                 BRANCH IF NO                    48200020
         L     RWK15,TSBAUTOS           GET CURRENT AUTO LINE NUMBER    48500020
         A     RWK15,TSBAUTOI           ADD INCR VALUE TO AUTO LINE NO. 48600020
         ST    RWK15,TSBAUTOS           STORE UPDATED AUTO LINE NUMBER  48700020
         SPACE 2                                                        48800020
********                                                                48900020
******** WHEN END OF MESSAGE IS DETECTED AND THERE IS NO MORE DATA LEFT 49000020
******** IN THE TCAM BUFFER TO BE MOVED INTO TS BUFFERS, PERFORM THE    49100020
******** FOLLOWING FUNCTIONS.                                           49200020
********                                                                49300020
TSIN0392 EQU   *                                                        49400020
         TM    PRFSTAT1,PRFNLSTN        IS THIS LAST TCAM BFR OF MSG    49500020
         BO    TSIN0490                 BRANCH IF NO                    49600020
         LTR   RDSZE,RDSZE              ANY UNMOVED DATA IN TCAM BFR    49700020
         BNZ   TSIN0490                 BRANCH IF YES                   49800020
         SPACE 1                                                        49900020
TSIN0393 EQU   *                                                        50000020
         NI    TSBFLG2,OFF-TSBBIPI-TSBBRKIN  IND PARTIAL LINE COMPLETE  50160020
         NI    QCBTSOF1,OFF-QCBTGET     IND READ NO LONGER HAS PRIORITY 50300020
         SPACE 2                                                        50404020
********                                                                50408020
******** IF THE USER HAS EXCEEDED THE MAXIMUM NUMBER OF TIME SHARING    50412020
******** BUFFERS ALLOWED HIS TERMINAL FOR INPUT, PLACE HIM IN LWAIT.    50416020
******** IF THE AMOUNT OF TIME SHARING BUFFERS ON THE FREE QUEUE HAS    50420020
******** FALLEN BELOW THE RESERVE MINIMUM, PLACE THE SYSTEM IN LWAIT.   50424020
******** IN EITHER CASE, LOCK THE USERS KEYBOARD TO FURTHER INPUT.      50428020
********                                                                50432020
         CLC   TSBNIBF,TIOCAIMX+K1      MAX NO. OF INPUT BFRS EXCEEDED  50436020
         BL    TSIN0394                 BRANCH IF NO                    50440020
         OI    TSBSTAT,TSBLWAIT         PLACE USER IN LWAIT             50444020
         OI    QCBTSOF1,QCBNOBUF        LOCK USERS KEYBOARD TO INPUT    50448020
         SPACE 1                                                        50452020
TSIN0394 EQU   *                                                        50456020
         CLC   TIOCNFBF,AVTFZERO        ANY TS BFRS ON FREE QUEUE       50460020
         BE    TSIN0395                 BRANCH IF NONE                  50464020
         CLC   TIOCNFBF,TIOCUSLW        NO. FREE BFRS BELOW MINIMUM     50468020
         BNL   TSIN0396                 BRANCH IF NO                    50472020
         SPACE 1                                                        50476020
TSIN0395 EQU   *                                                        50480020
         OI    TIOCFLG,TIOCSYLW         PLACE THE SYSTEM IN LWAIT       50484020
         OI    QCBTSOF1,QCBNOBUF        LOCK USERS KEYBOARD TO INPUT    50488020
         SPACE 1                                                        50988020
TSIN0396 EQU   *                                                        51488020
         CLI   TSBNIBF,AVTEZERO         ANY TS BFRS ON THE INPUT QUEUE  51988020
         BE    TSIN0410                 BRANCH IF NONE                  52488020
         TM    TSBSTAT,TSBDSPLY         IS THIS A DISPLAY SCREEN        52538020
         BZ    TSIN0398                 BRANCH IF NO                    52588020
         SR    R0,R0                    CLEAR REGISTER                  52638020
         SR    RWRK1,RWRK1              CLEAR REGISTER                  52688020
         IC    R0,QCBSATCT              GET NO. OF LINES ENTERED        52738020
         IC    RWRK1,TSBLNNO            GET NO. OF LINES ON SCREEN (N)  52788020
         BCTR  RWRK1,R0                 DECR BY 1 NO. OF SCREEN LINES   52838020
         CLR   R0,RWRK1                 IS NO. OF LINES ENTERED LESS    52888020
*                                       THAN (N-1)                      52938020
         BL    TSIN0398                 BRANCH IF YES                   52948020
         MVI   QCBSATCT,AVTEZERO        RESET NO. LINES ENTERED TO ZERO 52958020
         BH    TSIN0397                 BR IF LINES ENTERED IS GT (N-1) 52968020
         MVI   QCBSATCT,CLRSCREN        INDICATE SCREEN MUST BE CLEARED 52978020
         SPACE 1                                                        52988020
TSIN0397 EQU   *                                                        52998020
         BAL   RWK15,TSIN9010           CALCULATE ACTUAL DATA    S22028 53008001
*                                       SIZE                     S22028 53010001
         CH    R0,ONE                   IS DATA LENGTH IN TS BFR S22028 53012001
*                                       1                        S22028 53014001
         BH    FLASHBAK                 BR IF MORE THAT ONE CHAR IN BFR 53018020
         BL    TSIN0398                 IF NO DATA, DON'T FLASH BACK    53028020
         LA    RWRK1,BUFFHDLN(RWRK1,RWK11) POINTS AT ONLY DATA   S22028 53038001
*                                       CHAR                     S22028 53040001
         CLI   K0(RWRK1),NEWLINE        IS ONLY CHAR IN BFR NEW  S22028 53042001
*                                       LINE                     S22028 53044001
         BE    TSIN0398                 IF CHAR IS NL, DON'T FLASH BACK 53048020
         SPACE 1                                                        53058020
FLASHBAK EQU   *                                                        53068020
         OI    BUFFFL2,BUFFPART         MARK TS BFR FOR FLASH BACK      53088020
         OI    TSBFLG2,TSBBRKIN         TELL TSOUTPUT TO FLASH BACK     53138020
         B     TSIN0440                 GO TO CHK IF ANY OUTPUT IN PROG 53188020
         SPACE 2                                                        53300020
********                                                                53400020
******** IF THE USER IS IN IWAIT, CALL THE IKJGGQIO ROUTINE             53700021
******** IN IEDAYOO TO REMOVE IWAIT.                                    54000021
********                                                                54300020
TSIN0398 EQU   *                                                        54400020
         USING TJB,RWRK2                USE RWRK2 AS TJB BASE REG       54500020
         L     RWRK2,TSBTJB-K1          GET TJB ADDRESS                 54600020
         TM    TJBSTAT,TJBIWAIT         IS THE USER IN AN IWAIT         54700020
         BZ    TSIN0410                 BRANCH IF NO                    54800020
         STM   RTSBFR,RETRN,TIOCSAVE    SAVE REG.S 5-14 ACROSS   S21008 55100021
*                                       CALL                     S21008 55400021
         LR    RTSBFR,RWRK2             LD 5 WITH TJB ADDR       S21008 55700021
         LA    RWRK8,AVTEZERO(,RTSB)    LD TSB ADDR & CLEAR BYTE S21008 56000021
*                                       0                        S21008 56300021
         IC    RWK11,TSBFLG2            SAVE TSBBIPI SETTING     S21008 56600021
         OI    TSBFLG2,TSBBIPI          REQUEST IWAIT REMOVAL    S21008 56900021
         L     RNTRY,QIOEPA             GET REMOVAL RTN'S EPA    S21008 57200021
         L     RBASE,QIOBASE            GET REMOVAL RTN'S BASE   S21008 57500021
*                                       ADDR                     S21008 57800021
         BALR  RWRK4,RNTRY              GO REMOVE IWAIT          S21008 58100021
         STC   RWK11,TSBFLG2            RESTORE TSBBIPI SETTING  S21008 58400021
         LM    RTSBFR,RETRN,TIOCSAVE    RESTORE REGISTERS        S21008 58700021
         SPACE 2                                                        60004020
********                                                                60008020
******** IF AUTOMATIC PROMPTING IS IN PROGRESS, TELL TCAM OR TSOUTPUT   60011020
******** TO PROMPT THE USER WITH THE PROMPT CHARACTER OR THE NEXT LINE  60014020
******** NUMBER.                                                        60017020
********                                                                60020020
TSIN0410 EQU   *                                                        60024020
         TM    TSBFLG2,TSBAUTON         IS AUTO PROMPTING IN PROGRESS   60029020
         BNO   TSIN0490                 BRANCH IF NO                    60034020
         TM    PRFSRCE,WAITQBFR         WAS THIS BFR ON WAIT QUEUE      60044020
         BZ    TSIN0412                 BRANCH IF NO                    60048020
         OI    TSBFLG2,TSBSTAUT         TELL TSOUTPUT TO PROMPT USER    60049020
         B     TSIN0440                 BRANCH TO POST TSOUTPUT         60052020
         SPACE 1                                                        60056020
TSIN0412 EQU   *                                                        60060020
         USING IEDQLCB,RWRK2            USE RWRK2 AS LCB BASE REG       60064020
         L     RWRK2,PRFLCB-K1          GET LCB ADDRESS                 60068020
         L     RWRK2,LCBSCBA-K1         GET SCB ADDRESS                 60072020
         DROP  RWRK2                    DROP RWRK2 AS LCB BASE REG      60076020
         USING IEDQSCB,RWRK2            USE RWRK2 AS SCB BASE REG       60080020
         OI    SCBERR2,SCBALN           TELL TCAM TO PROMPT THE USER    60084020
         B     TSIN0490                 BRANCH TO RETURN TO TSINPUT     60088020
         DROP  RWRK2                    DROP RWRK2 AS SCB BASE REG      60092020
         SPACE 2                                                        60100020
********                                                                60200020
******** IF A PARTIAL LINE CAUSED BY BREAK-IN EXISTS, MARK THE LAST TS  60300020
******** HEADER BUFFER ON THE INPUT QUEUE AS A PARTIAL LINE.  ALSO      60400020
******** DETERMINE IF THE PARTIAL LINE CAN BE PROCESSED BY TSOUTPUT AT  60500020
******** THIS TIME.                                                     60600020
********                                                                60700020
TSIN0420 EQU   *                                                        60800020
         CLC   PRFSIZE,AVTFZERO         ANY DATA MOVED FROM TCAM BFR    60803020
         BNE   TSIN0430                 BRANCH IF YES                   60806020
         TM    BUFFFL1,BUFFNLCR         WAS LAST CHAR MOVED NL OR CR    60809020
         BO    TSIN0370                 BRANCH IF YES - NO PARTIAL LINE 60812020
         B     TSIN0434                 BR TO INDICATE A PARTIAL LINE   60815020
         SPACE 1                                                        60818020
TSIN0430 EQU   *                                                        60821020
         CLI   K0(RSCANL),NEWLINE       WAS LAST CHAR SCANNED NEW LINE  60830020
         BE    TSIN0370                 BRANCH IF YES - NO PARTIAL LINE 60860020
         CLI   K0(RSCANL),CARRRTRN      WAS LAST CHAR SCANED CARR RETRN 60900020
         BE    TSIN0370                 BRANCH IF YES - NO PARTIAL LINE 61000020
         SPACE 1                                                        61100020
TSIN0434 EQU   *                                                        61200020
         OI    TSBFLG2,TSBBRKIN         IND PARTL LINE DUE TO BREAK-IN  61300020
         OI    BUFFFL2,BUFFPART         IND PARTIAL LINE IN THIS TS BFR 61700020
         NI    QCBTSOF1,OFF-QCBNOBUF    TURN OFF TCAM NO BFRS INDICATOR 62200020
         DROP  RWK11                    DROP RWK11 AS TS BFR BASE REG   62600020
         SPACE 1                                                        63040020
TSIN0440 EQU   *                                                        63080020
         TM    QCBTSOF1,QCBTPUT+QCBPARTO  ANY OUTPUT IN PROGRESS        63120020
         BNZ   TSIN0490                 BRANCH IF YES                   63160020
         OI    QCBTSOF1,QCBTPUT         REQUEST A TPUT OPERATION        63180020
         TM    QCBTSOF1,QCBDELAY        IS THIS QCB ON THE DELAY QUEUE  63200020
         BZ    TSIN0450                 BRANCH IF NO                    63240020
         SPACE 2                                                        63300020
********                                                                63400020
******** QPOST THE DELAY QUEUE QCB TO ITSELF TO REMOVE THE TERMINAL     63460020
******** DESTINATION QCB FROM THE DELAY QUEUE.                          63520020
********                                                                63600020
         DROP  RQCB                     DROP RQCB AS QCB BASE REGISTER  63620020
         L     RQCB,AVTTSOPT            GET ADDR OF TSINPUT'S QCB       63640020
         USING IEDQTSI,RQCB             USE RQCB AS TSINPUT'S QCB BASE  63660020
         TM    TSIDYQFG,TSIDYPOS        HAS DELAY QUEUE QCB BEEN POSTED 63680020
         BO    TSIN0490                 BR IF YES, NOTHING MORE TO DO   63700020
         OI    TSIDYQFG,TSIDYPOS        IND DELAY QUEUE QCB IS POSTED   63720020
         LA    RQCB,TSIDYQFG            PT TO DELAY QUEUE QCB           63740020
         B     TSIN0470                 BR TO POST DELAY QUEUE QCB      63760020
         DROP  RQCB                     DROP RQCB AS TSINPUT'S QCB BASE 63780020
         SPACE 2                                                        63800020
********                                                                63900020
******** QPOST THE TERMINAL QCB TO ITSELF TO ACTIVATE A SEND            64000020
******** OPERATION FOR THIS TERMINAL.                                   64100020
********                                                                64200020
TSIN0450 EQU   *                                                        64300020
         USING IEDQQCB,RQCB             USE RQCB AS QCB BASE REGISTER   64320020
         TM    QCBTSOF2,QCBPOSTO        IS QCB POSTED TO ITSELF         64326020
         BO    TSIN0490                 BRANCH IF YES                   64332020
         OI    QCBTSOF2,QCBPOSTO        IND QCB IS POSTED TO ITSELF     64340020
         MVI   QCBPRI,PRIDESTQ          SET QCB PRIORITY                64360020
         SPACE 2                                                        64380020
********                                                                64400020
******** THIS IS A COMMON ROUTINE USED TO QPOST A QCB TO ITSELF AND     64420020
******** ADD THAT QCB TO THE QUEUE OF ELEMENTS BEING PASSED TO THE TCAM 64440020
******** DISPATCHER FOR POSTING.                                        64460020
********                                                                64480020
TSIN0470 EQU   *                                                        64500020
         IC    RWRK2,QCBELCHN-K1        SAVE FLAG BYTE                  64520020
         ST    RQCB,QCBELCHN-K1         QPOST QCB TO ITSELF             64540020
         STC   RWRK2,QCBELCHN-K1        RESTORE FLAG BYTE               64560020
         MVC   QCBLINK,AVTDOUBL+K1      CHAIN FIRST ELEMENT ALREADY IN  64600020
*                                       QUEUE TO THIS QCB               64700020
         ST    RQCB,AVTDOUBL            CHAIN QCB TO RETURN QUEUE       64800020
         SPACE 2                                                        65100020
********                                                                65200020
******** STORE UPDATED DATA SIZE IN TCAM BUFFER AND RETURN TO TSINPUT   65300020
********                                                                65400020
TSIN0490 EQU   *                                                        65500020
         SR    RTIOC,RTIOC              SET RETURN CODE EQUAL TO ZERO   65600020
         SPACE 1                                                        65700020
TSIN0492 EQU   *                                                        65800020
         SLL   RWK11,K8                 LEFT ADJ LAST TS HDR BFR ADDR   65900020
         SRDL  RTIOC,K8                 ADJ RETURN CODE AND BUFFER ADDR 66000020
         LR    RTRNCD,RWK11             RETRN CODE AND LAST TS HDR ADDR 66100020
         STH   RDSZE,PRFSIZE            STORE UPDATED COUNT IN TCAM BFR 66200020
         BR    RETRN                    RETURN TO TSINPUT               66300020
         SPACE 2                                                        66304020
         SPACE 2                                                        66400020
********                                                                66500020
******** THE FOLLOWING SUBROUTINE OBTAINS A FREE TS BUFFER, IF ANY ARE  66600020
******** AVAILABLE, AND BUILDS A HEADER OR TRAILER BUFFER DEPENDING ON  66700020
******** WHICH IS REQUIRED.  THE BUFFER IS THEN CHAINED TO THE LAST     66800020
******** HEADER OR TRAILER AS REQUIRED.                                 66900020
********                                                                67000020
TSIN0500 EQU   *                                                        67100020
         NC    TIOCNFBF,TIOCNFBF        ANY FREE TS BUFFERS             67200020
         BNZ   TSIN0510                 BRANCH IF YES                   67300020
         LA    RTIOC,K4                 RETURN CODE FOR NO FREE TS BFRS 67400020
         B     TSIN0492                 BRANCH TO RETURN TO TSINPUT     67500020
         SPACE 1                                                        67600020
TSIN0510 EQU   *                                                        67700020
         USING TIOCBUF,RWRK7            USE RWRK7 AS TS BFR BASE REG    67800020
         L     RWRK7,TIOCFBFF           GET A TS BFR FROM FREE QUEUE    67900020
         LA    RWRK7,K0(R0,RWRK7)       CLEAR HI ORDER BYTE OF BFR ADDR 68000020
         L     RWRK1,BUFFTRLR-K1        GET ADDR NEXT BFR IN FREE QUEUE 68100020
         ST    RWRK1,TIOCFBFF           RE-CHAIN FREE QUEUE BFRS        68200020
         LH    RWRK1,TIOCNFBF           GET NO. OF BFRS ON FREE QUEUE   68300020
         BCTR  RWRK1,R0                 DECR NO. OF BFRS ON FREE QUEUE  68500020
         STH   RWRK1,TIOCNFBF           STORE UPDATED BFR COUNT         68600020
         XC    BUFFFL1(BUFFHDLN),BUFFFL1  CLEAR PREFIX OF NEW BUFFER    68700020
         CLC   TSBIBFP,AVTFZERO         ANY TS BFRS ON INPUT HDR QUEUE  68800020
         BE    TSIN0530                 BRANCH IF NONE                  68900020
         DROP  RWRK7                    DROP RWRK7 AS TS BFR BASE REG   69000020
         USING TIOCBUF,RTSBFR           USE RTSBFR AS TS BFR BASE REG   69100020
         TM    BUFFFL1,BUFFHDR          IS LAST BFR POINTED TO A HDR    69200020
         BZ    TSIN0520                 BR IF NO TO BUILD A TRAILER BFR 69300020
         TM    BUFFFL1,BUFFNLCR         DOES HDR CONTAIN CARRIAGE RETRN 69400020
         BO    TSIN0540                 BR IF YES TO BUILD A HDR BFR    69500020
         SPACE 2                                                        69600020
********                                                                69700020
******** BUILD A TRAILER BUFFER AND CHAIN IT TO THE LAST BUFFER ON THE  69800020
******** INPUT QUEUE                                                    69900020
********                                                                70000020
TSIN0520 EQU   *                                                        70100020
         O     RWRK7,BUFFFL1            RESTORE FLAGS TO BFR ADDR       70200020
         ST    RWRK7,BUFFFL1            CHAIN NEW TRLR BFR TO LAST BFR  70300020
         DROP  RTSBFR                   DROP RTSBFR AS TS BFR BASE REG  70400020
         USING TIOCBUF,RWRK7            USE RWRK7 AS TS BFR BASE REG    70500020
         MVI   BUFFOFST,BUFFTRLN        OFFSET TO BEGIN DATA IN TRLR    70600020
         B     TSIN0560                 BR TO UPDATE INPUT BFR COUNT    70700020
         SPACE 2                                                        70800020
********                                                                70900020
******** BUILD A HEADER BUFFER AND CHAIN IT TO THE LAST HEADER BUFFER   71000020
******** IN THE INPUT QUEUE OR TO THE QUEUE ITSELF IF THE QUEUE IS      71100020
******** EMPTY                                                          71200020
********                                                                71300020
TSIN0530 EQU   *                                                        71400020
         O     RWRK7,TSBNIBF            RESTORE NO. BFRS TO BFR ADDR    71500020
         ST    RWRK7,TSBNIBF            CHAIN NEW HDR BFR TO QUEUE      71600020
         B     TSIN0550                 BR TO BUILD A HDR BFR           71700020
         SPACE 1                                                        71800020
TSIN0540 EQU   *                                                        71900020
         DROP  RWRK7                    DROP RWRK7 AS TS BFR BASE REG   72000020
         USING TIOCBUF,RTSBFR           USE RTSBFR AS TS BFR BASE REG   72100020
         O     RWRK7,BUFFFL2            RESTORE FLAGS TO BFR ADDR       72200020
         ST    RWRK7,BUFFFL2            CHAIN NEW HDR BFR TO LAST HDR   72300020
         DROP  RTSBFR                   DROP RTSBFR AS TS BFR BASE REG  72400020
         USING TIOCBUF,RWRK7            USE RWRK7 AS TS BFR BASE REG    72500020
         SPACE 1                                                        72600020
TSIN0550 EQU   *                                                        72700020
         OI    BUFFFL1,BUFFHDR          IND THIS IS A HEADER BFR        72800020
         OI    BUFFFL2,BUFFFRAG         IND THIS BFR CONTAINS FRAG MSG  72900020
         MVI   BUFFOFST,BUFFHDLN        OFFSET TO BEGIN DATA IN HDR BFR 73000020
         LR    RWK11,RWRK7              UPDATE LAST HEADER POINTER      73100020
         DROP  RWRK7                    DROP RWRK7 AS TS BFR BASE REG   73200020
         SPACE 2                                                        73300020
********                                                                73400020
******** UPDATE INPUT QUEUE BUFFER COUNT AND RETURN TO CALLER           73500020
********                                                                73600020
TSIN0560 EQU   *                                                        73700020
         SR    RWRK1,RWRK1              CLEAR REGISTER                  73800020
         IC    RWRK1,TSBNIBF            GET NO. OF BFRS ON INPUT QUEUE  73900020
         LA    RWRK1,K1(R0,RWRK1)       INCR NO. OF BFRS ON INPUT QUEUE 74000020
         STC   RWRK1,TSBNIBF            ST UPDATED BFR COUNT            74100020
         LR    RTSBFR,RWRK7             POINT TO NEXT BFR TO BE FILLED  74200020
         BR    RWK15                    RETURN TO CALLING ROUTINE       74300020
         DROP  RAVT,RTCBFR,RTIOC        DROP CONTROL BLOCK BASE  S22028 74700001
*                                       REGS                     S22028 74700101
         SPACE 3                                                 S22028 74700201
********                                                                74700301
******** FOR 3270 THERE WILL BE CONTROL CHARACTERS RANGING FROM 1 TO    74700401
******** 6 BYTES IN LENGTH. SUBTRACT THIS LENGTH FROM DATA SIZE TO      74700501
******** GET THE ACTUAL DATA LENGTH.                                    74700601
********                                                                74700701
TSIN9010 EQU   *                                                 S22028 74700801
         USING TIOCBUF,RWK11            USE RWK11 AS TS BFR BASE S22028 74700901
*                                       REG                      S22028 74701001
         SR    R0,R0                    CLEAR LENGTH REGISTER   SA59536 74701101
         SR    RWRK1,RWRK1              CLEAR OFFSET REGISTER   SA59536 74710001
         IC    R0,BUFFLNTH              GET DATA LENGTH          S22028 74710401
         TM    TSBSTAT,TSB3270          TEST FOR 3270            S22028 74713801
         BZ    TSIN9050                 BRANCH IF NOT            S22028 74717201
         CH    R0,CC3270L               IS DATA LENGTH LESS THAN S22028 74720601
*                                       3                        S22028 74724001
         BNL   TSIN9020                 BRANCH IF NO             S22028 74727401
         BCTR  R0,R0                    SUBTRACT 1 FROM DATA     S22028 74730801
*                                       SIZE                     S22028 74734201
         LA    RWRK1,K1                 REMEMBER OFFSET          S22028 74737601
         B     TSIN9050                 GO BACK                  S22028 74741001
         SPACE 1                                                 S22028 74744401
TSIN9020 EQU   *                                                 S22028 74747801
         SH    R0,CC3270L               SUBTRACT 3 FROM DATA     S22028 74751201
*                                       SIZE                     S22028 74754601
         LA    RWRK1,K3                 REMEMBER OFFSET          S22028 74758001
         CLI   BUFFHDLN+K3(RWK11),SBA   IS FOURTH CHAR SBA       S22028 74761401
         BNE   TSIN9050                 BRANCH IF NOT            S22028 74764801
         SH    R0,CC3270L               SUBTRACT 3 MORE FROM     S22028 74768201
*                                       DATA SIZE                S22028 74771601
         LA    RWRK1,K3(R0,RWRK1)       REMEMBER OFFSET          S22028 74775001
         SPACE 1                                                 S22028 74778401
TSIN9050 EQU   *                                                 S22028 74781801
         BR    RWK15                    RETURN TO CHECK DATA     S22028 74785201
*                                       LENGTH                   S22028 74788601
         DROP  RTSB,RWK11               DROP BASE REGS           S22028 74792001
         EJECT                                                          74795401
*********************************************************************** 74798801
********                                                       ******** 74802201
******** THE FOLLOWING SECTION CODE IS USED BY THE LOGOFF AND  ******** 74805601
******** HANGUP ROUTINES (IEDAYOO AND IEDAYHH) TO REMOVE THE   ******** 74809001
******** USERS TERMINAL FROM THE SYSTEM LWAIT CONDITION AND    ******** 74812401
******** RETURN ANY TCAM BUFFERS WHICH ARE ASSOCIATED WITH     ******** 74815801
******** THIS TERMINAL AND ARE ON THE TCAM BUFFER WAIT QUEUE.  ******** 74819201
******** THE ENTRY POINT INTO THIS CODE IS QTIP0280.           ******** 74822601
********                                                       ******** 74826001
******** INPUT REGISTERS -                                     ******** 74829401
********                                                       ******** 74832801
********       REG 7 -  ADDR OF THE TERMINAL DESTINATION QCB.  ******** 74836201
********       REG 9 -  ADDRESS OF THE CURRENT TSB.            ******** 74839601
********       REG 13 - ADDRESS OF AVTSAVE2.                   ******** 74843001
********                                                       ******** 74846401
*********************************************************************** 74849801
QTIP0280 EQU   *                                                        74853201
         USING IEDQQCB,RQCB             USE RQCB AS TERM QCB BASE REG   74856601
         USING TSB,RTSB                 USE RTSB AS TSB BASE REGISTER   74860001
         USING AVTSAVE2,RAVT            USE RAVT AS AVT BASE REGISTER   74863401
         TM    QCBTSOF2,QCBBUFQ         HOLDING TCAM BFRS FOR THIS TERM 74866801
         BCR   ZEROS,RETRN              RETURN TO CALLER IF NOT         74870201
         L     RWK15,CVTPTR             GET CVT ADDRESS                 74873601
         L     RWK15,CVTTSCVT-CVT(R0,RWK15)    GET ADDRESS OF TSCVT     74877001
         L     RWK15,TSCVTRPT-TSCVT(R0,RWK15)  GET ADDRESS OF TIOCRPT   74880401
         USING TIOCRPT,RWK15            USE RWK15 AS TIOCRPT BASE REG   74883801
         STM   RWRK1,RWRK3,TIOCSAVE     SAVE CALLER'S REGISTERS 1-3     74887201
         STM   RTCBFR,RETRN,TIOCSAVE+K12  SAVE CALLER'S REGISTERS 6-14  74890601
         LA    RTSB,K0(R0,RTSB)         CLEAR HI-ORDER BYTE OF REG      74894001
         USING IEDQTSI,RWRK8            USE RWRK8 AS TSINPUT'S QCB BASE 74897401
         L     RWRK8,AVTTSOPT           GET ADDR OF TSINPUT'S QCB       74900801
         LA    RWRK8,TSIBUFQ            GET ADDR OF TCAM BFR WAIT QUEUE 74904201
         DROP  RWRK8                    DROP RWRK8 AS TSINPUT QCB BASE  74907601
         SPACE 2                                                        74911001
********                                                                74914401
******** REMOVE ALL TCAM BUFFERS FROM THE BUFFER WAIT QUEUE WHICH ARE   74917801
******** ASSOCIATED WITH THIS TERMINAL AND RETURN THEM TO TCAM.         74921201
********                                                                74924601
TSIN7000 EQU   *                                                        74928001
         USING IEDQPRF,RTCBFR           USE RTCBFR AS TCAM BFR BASE REG 74931401
         L     RTCBFR,K0(R0,RWRK8)      GET NEXT TCAM BFR ON WAIT QUEUE 74934801
         LA    RTCBFR,K0(R0,RTCBFR)     CLEAR HI-ORDER BYTE OF REGISTER 74938201
         LTR   RTCBFR,RTCBFR            ANY MORE TCAM BFR ON WAIT QUEUE 74941601
         BZ    TSIN7050                 RETURN TO CALLER IF NOT         74945001
         L     RWRK2,PRFQCBA-K1         GET TSB ASSOCIATED WITH BFR     74948401
         LA    RWRK2,K0(R0,RWRK2)       CLEAR HI-ORDER BYTE OF REGISTER 74951801
         CR    RTSB,RWRK2               DOES BFR BELONG TO CURRENT TSB  74955201
         BE    TSIN7030                 BRANCH IF YES TO RETURN BUFFER  74958601
         LA    RWRK8,PRFLINK-K1         PT TO ADDR OF NEXT BFR ON QUEUE 74962001
         B     TSIN7000                 BR TO CONT SCAN OF WAIT QUEUE   74965401
         SPACE 2                                                        74968801
********                                                                74972201
******** TPOST TCAM BUFFER TO THE BUFFER RETURN QCB VIA THE TCAM        74975601
******** DISPATCHER.                                                    74979001
********                                                                74982401
TSIN7030 EQU   *                                                        74985801
         MVC   K1(K3,RWRK8),PRFLINK     REMOVE BFR FROM WAIT QUEUE      74989201
         XC    PRFLINK,PRFLINK          CLEAR LINK FIELD OF BFR         74992601
         AIF   ('&LIB' NE 'LIB4').LIB4BD                                74996001
*                                                                       74999401
*        CALL IKJGGTPQ TO TPOST TCAM BUFFER TO BUFFER RETURN            75002801
*        REG.  00 - RETURN ADDR                                         75006201
*              01 - ELEMENT ADDR, PRIORITY IN BYTE ZERO                 75009601
*              02 - QCB ADDR                                            75013001
*              13 - 6 WORD SAVE AREA - BYTE 0=0 FOR NO TIME DELAY CHK   75016401
*              15 - ENTRY ADDR                                          75019801
*                                                                       75023201
         LR    RWRK3,RWRK2              SAVE REGISTER CONTENTS          75026601
         LR    RWK11,RWK15              SAVE REGISTER CONTENTS          75030001
         LR    RWRK1,RTCBFR             ELEMENT TO BE TPOSTED           75033401
         ICM   RWRK1,8,TPPRI            INSERT TPOST PRIORITY           75036801
         LA    RWRK2,AVTBFRTB           QCB TO BE TPOSTED TO            75040201
         LA    RAVT,0(,RAVT)            CLEAR BYTE ZERO                 75043601
         L     RNTRY,TPQADDR            ADDR OF IKJEGTPQ                75047001
         BALR  R0,RNTRY                 GO TPOST BFR TO BFR RET         75050401
         LR    RWRK2,RWRK3              RESTORE REGISTER                75053801
         LR    RWK15,RWK11              RESTORE REGISTER                75057201
         AGO   .LIB4BE                                                  75060601
.LIB4BD  ANOP                                                           75064001
         LA    RWRK3,AVTBFRTB           GET ADDR OF BFR RETURN QCB      75067401
         ST    RWRK3,PRFQCBA-K1         TPOST BFR TO BFR RETURN QCB     75070801
         MVI   PRFPRI,PRIBFRTB          PRIORITY TO RETURN TCAM BFR     75074201
         USING IEDQDISP,RWK11           USE RWK11 AS TCAM DISP BASE REG 75077601
         L     RWK11,AVTEA              GET ADDR OF TCAM DISPATCHER     75081001
         LR    RWRK1,RTCBFR             PT TO TCAM BFR TO BE RETURNED   75084401
         BAL   RETRN,DSPPOSTR           RETURN BFR VIA TCAM DISPATCHER  75087801
         L     RQCB,TSBQCB-K1           RESTORE QCB ADDRESS             75091201
.LIB4BE  ANOP                                                           75094601
         B     TSIN7000                 BR TO CONT SCAN OF WAIT QUEUE   75098001
         SPACE 2                                                        75101401
********                                                                75104801
******** INDICATE ALL TCAM BUFFERS HAVE BEEN REMOVED FROM THE BUFFER    75108201
******** WAIT QUEUE WHICH ARE ASSOCIATED WITH THE CURRENT TSB, AND      75111601
******** RETURN TO THE CALLER.                                          75115001
********                                                                75118401
TSIN7050 EQU   *                                                        75121801
         NI    QCBTSOF2,OFF-QCBBUFQ     NO MORE BFRS IN Q FOR THIS TSB  75125201
         LM    RWRK1,RWRK3,TIOCSAVE     RESTORE CALLER'S REGISTERS 1-3  75128601
         LM    RTCBFR,RETRN,TIOCSAVE+K12  RESTORE CALLER'S REGS 6-14    75132001
         BR    RETRN                    RETURN TO CALLER                75135401
         DROP  RTCBFR,RQCB,RTSB,RAVT,RWK15  DROP CONTROL BLK BASE REGS  75138801
         SPACE 2                                                 S21008 75142201
**********************************************************************  75145601
********                                                                75149001
******** CONSTANTS                                                      75152401
********                                                                75155801
**********************************************************************  75159201
QIOEPA   DC    V(IKJGGQIO)              IWAIT REMOVAL RTN'S EPA  S21008 75162601
QIOBASE  DC    V(QTIP0110)              IWAIT REMOVAL RTN'S BASE S21008 75166001
ONE      DC    H'1'                     USED TO DETERMINE DATA   S22028 75169401
*                                       SIZE                     S22028 75172801
CC3270L  DC    H'3'                     USED TO SKIP 3270        S22028 75176201
*                                       CONTROL CHAR             S22028 75179601
         AIF   ('&LIB' NE 'LIB4').LIB4BF                                75183001
TPQADDR  DC    V(IKJGGTPQ)              TPOST ROUTINE                   75186401
TPPRI    DC    AL1(PRIBFRTB)            TPOST PRIORITY                  75189801
.LIB4BF  ANOP                                                           75193201
         SPACE 1                                                        75196601
         EJECT                                                          75200020
*********************************************************************** 75300020
********                                                       ******** 75400020
******** DSECTS                                                ******** 75500020
********                                                       ******** 75600020
*********************************************************************** 75700020
         SPACE 1                                                        75800020
********                                                                75900020
******** AVT - ADDRESS VECTOR TABLE                                     76000020
********                                                                76100020
         SPACE 1                                                        76200020
         TAVTD                                                          76300020
         EJECT                                                          76400020
********                                                                76500020
******** TIOCBUF - TIOC BUFFER FORMAT                                   76600020
********                                                                76700020
         SPACE 1                                                        76800020
         IKJTIOCB                                                       76900020
         EJECT                                                          77000020
********                                                                77100020
******** CVT - COMMUNICATIONS VECTOR TABLE                              77200020
********                                                                77300020
         SPACE 1                                                        77400020
CVT      DSECT                                                          77500020
         CVT                                                            77600020
         EJECT                                                          77700020
********                                                                77707020
******** DCB - DATA CONTROL BLOCK                                       77714020
********                                                                77721020
         SPACE 1                                                        77728020
         DCBD  DSORG=TX                                                 77735020
         EJECT                                                          77742020
********                                                                77749020
******** TCAM DISPATCHER                                                77756020
********                                                                77763020
         SPACE 1                                                        77770020
         TDISPD                                                         77777020
         EJECT                                                          77784020
********                                                                77800020
******** LCB - LINE CONTROL BLOCK                                       77900020
********                                                                78000020
         SPACE 1                                                        78100020
         TLCBD                                                          78200020
         EJECT                                                          78300020
********                                                                78400020
******** TCAM BUFFER PREFIX                                             78500020
********                                                                78600020
         SPACE 1                                                        78700020
         TPRFD                                                          78800020
         EJECT                                                          78900020
********                                                                79000020
******** TCAM BUFFER PRIORITIES                                         79100020
********                                                                79200020
         SPACE 1                                                        79300020
         TPRIOR                                                         79400020
         EJECT                                                          79500020
********                                                                79600020
******** QCB - DESTINATION QUEUE ELEMENT CONTROL BLOCK                  79700020
********                                                                79800020
         SPACE 1                                                        79900020
         TQCBD                                                          80000020
         EJECT                                                          80100020
********                                                                80200020
******** SCB - STATION CONTROL BLOCK                                    80300020
********                                                                80400020
         SPACE 1                                                        80500020
         TSCBD                                                          80600020
         EJECT                                                          80700020
********                                                                80800020
******** TCB - TASK CONTROL BLOCK                                       80900020
********                                                                81000020
         SPACE 1                                                        81100020
         IKJTCB                                                         81200020
         EJECT                                                          81300020
********                                                                81400020
******** TIOCRPT - TIOC REFERENCE POINTER TABLE                         81500020
********                                                                81600020
         SPACE 1                                                        81700020
         IKJTIOCP                                                       81800020
         EJECT                                                          81900020
********                                                                82000020
******** TJB - TIME SHARING JOB BLOCK                                   82100020
********                                                                82200020
         SPACE 1                                                        82300020
         IKJTJB                                                         82400020
         EJECT                                                          82500020
********                                                                82600020
******** TJBX - TIME SHARING JOB BLOCK EXTENSION                        82700020
********                                                                82800020
         SPACE 1                                                        82900020
         IKJTJBX                                                        83000020
         EJECT                                                          83100020
********                                                                83200020
******** TERMINAL ENTRY TABLE                                           83300020
********                                                                83400020
         SPACE 1                                                        83500020
         TTRMD                                                          83600020
         EJECT                                                          83700020
********                                                                83800020
******** TSB - TERMINAL STATUS BLOCK                                    83900020
********                                                                84000020
         SPACE 1                                                        84100020
         IKJTSB                                                         84200020
         EJECT                                                          84300020
********                                                                84400020
******** TSCVT - TIME SHARING COMMUNICATIONS VECTOR TABLE               84500020
********                                                                84600020
         SPACE 1                                                        84700020
         IKJTSCVT                                                       84800020
         EJECT                                                          84900020
********                                                                85000020
******** DESTINATION QCB FOR TSINPUT                                    85100020
********                                                                85200020
         SPACE 1                                                        85300020
         TTSID                                                          85400020
         END                                                            85500020
