IEEVGPSD CSECT                                                          00900020
         TITLE  'IEEVGPSD - GET PARTITION FOR OPER SEND/ DISPLAY USER'  00902020
*/*IEEVGPSD:  CHART */                                                  00910020
*/* HEADER                                                              00920020
*/*GET PARTITION FOR OPERATOR SEND AND/OR DISPLAY USER   */             00940020
*/*              E IEEVGPSD */                                          00950020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 01800020
*                                                                     * 02700020
*                       P  R  O  L  O  G  U  E                        * 03600020
*                                                                     * 04500020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 05400020
*                                                                     * 06300020
*   STATUS: CHANGE LEVEL 000                                          * 06310020
*           PTM INCLUDED: 4801, 1586, 5759                            * 06360020
*                                                                     * 07200020
*   FUNCTION:                                                         * 09900020
*        THIS ROUTINE PROVIDES AN INTERFACE BETWEEN THE 'SEND'        * 10800020
*        AND THE 'DISPLAY USER'                                       * 10810020
*        PROCESSING MODULES AND THE MASTER SCHEDULER.                 * 11700020
*        ITS FUNCTION IS TO GET AND FREE A PARTITION .                * 12600020
*        THIS ROUTINE WILL GET A PARTITION AND ATTACH  THE            * 12650020
*        APPROPRIATE PROCESSING MODULE.  IF THE PROCESSING MODULE     * 12700020
*        COMPLETES SUCCESSFULLY CONTROL IS RETURNED, THE CSCB IS FREED* 12750020
*        AND DELETED, THE WORKAREA IS FREED, AND FINALLY THE          * 12760020
*        PARTITION IS FREED.                                          * 12800020
*                                                                     * 12850020
*       IF THE PROCESSING MODULE FAILS TO COMPLETE SUCCESSFULLY,      * 12900020
*       A STAI ROUTINE WILL FREE SUBPOOL 252 AND ABEND WILL CLEAN UP. * 12950020
*       ON RETURN TO THIS MODULE, THE ECB COMPLETION CODE IS CHECKED  * 13000020
*       AND AN ERROR MESSAGE IS PUT OUT INDICATING THE ABEND          * 13050020
*       COMPLETION CODE AND THE FAILING PROCESSOR.  THEN THE CSCB IS  * 13100020
*       FREED AND DELETED, THE WORKAREA IS FREED, AND FINALLY THE     * 13110020
*       PARTITION IS FREED.                                           * 13150020
*                                                                     * 16200020
*        AND CONTROL RETURNS TO THE MASTER SCHEDULER WHICH ATTACHED   * 25200020
*        THIS ROUTINE.                                                * 26100020
*                                                                     * 27000020
*   ENTRY POINTS:  IEEVGPSD                                           * 27900020
*                                                                     * 28800020
*   INPUT:  REGISTER 1 CONTAINS THE ADDRESS OF THE CSCB.              * 29700020
*                                                                     * 30600020
*   OUTPUT: TO IEEVSEND - REGISTER  1- CSCB ADDRESS                   * 31500020
*                         REGISTER 13- REGISTER SAVE AREA ADDRESS     * 32400020
*                                                                     * 33300020
*   EXTERNAL REFERENCES:  GETMAIN, ATTACH, SVC34, FREEMAIN, DETACH    * 34200020
*                         LINK                                        * 34250020
*                                                                     * 35100020
*   EXIT:  CONTROL RETURNS TO THE MASTER SCHEDULER                    * 36000020
*                                                                     * 36050020
*                                                                     * 36900020
*                                                                     * 36950020
*   EXITS, ERROR:                                                     * 37000020
*                NONE                                                 * 37002020
*                                                                     * 37010020
*                                                                     * 37050020
*   ATTRIBUTES:  REENTRANT, READ ONLY                                 * 37800020
*                                                                     * 38700020
*   CHARACTER CODE DEPENDENCY:                                        * 38750020
*          NONE                                                       * 38760020
*                                                                     * 38800020
*   NOTES: SUPPORT CODE IS 20034                                      * 39600020
*                                                                     * 40500020
*                                                                     * 40550020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 41400020
         EJECT                                                          42300020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 43200020
*                                                                     * 44100020
*                   R E G I S T E R     E Q U A T E S                 * 45000020
*                                                                     * 45900020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 46800020
*                                                                     * 47700020
*                                                                     * 48600020
R0       EQU   0                                                        49500020
R1       EQU   1                   PARAM                                50400020
R2       EQU   2                   ADDRESS OF THE XSA                   51300020
R3       EQU   3                   PARM SAVE, CSCB ADDRESS              52200020
R4       EQU   4                   RETURN SAVE                          53100020
R5       EQU   5                   ADDR OF DOUBLE WORD NEEDED           54000020
*                                  BY GETMAIN                     M5759 54050020
R6       EQU   6                   CONTAINS LENGTH OF GETMAIN     M5759 54900020
R7       EQU   7                   ADDRESS OF THE ATTACH ECB            55800020
R8       EQU   8                   CONTAINS MSG CODE IF DAUGHTER ABENDS 56700020
R9       EQU   9                   E P NAME FOR THE ATTACH              57600020
RA       EQU   10                  BASE REGISTER                        58500020
RB       EQU   11                  UNUSED                               59400020
RC       EQU   12                  UNUSED                               60300020
RD       EQU   13                  SAVE AREA REGISTER                   61200020
RE       EQU   14                  RETURN                               62100020
RF       EQU   15                  ADDRESS OF THE LIST FORM OF ATTACH   63000020
N0       EQU   0                                                        63002020
N1       EQU   1                                                        63010020
N3       EQU   3                                                        63020020
N4       EQU   4                                                        63030020
N7       EQU   7                                                        63032020
N8       EQU   8                                                        63034020
N9       EQU   9                                                        63040020
N12      EQU   12                                                       63042020
N24      EQU   24                                                       63042420
LTHXSA   EQU   44                  LENGTH OF THE XSA              M4801 63044020
SUPERST  EQU   X'01'               INDICATE SUPERVISOR STATE      M4801 63050020
*        CODES FOR MESSAGE MODULE (IEE2103D)                     M4801* 63060020
SNDCODE  EQU   55                  ONE-BYTE CODE FOR 'SEND' ABEND MSG   63100020
*                                                                 M4801 63110020
DCODE    EQU   56                  ONE-BYTE CODE FOR 'DUSER' ABEND      63150020
*                                                                 M4801 63200020
         EJECT                                                          63900020
*/*              P SAVE CSCB ADDRESS */                                 63910020
         LR    R3,R1               SAVE THE PARAMETE (CSCB ADDR)        64800020
         LR    R4,RE               SAVE RETURN ADDRESS                  65700020
*/*              P SET ADDRESSIBILITY FOR CSECT */                      65710020
         BALR  RA,0                SET BASE                             66600020
         USING *,RA                ESTABLISH ADDRESSABILITY             67500020
         USING CSCB,R3                                                  67501020
*/*              D (NO,,YES,GETSMPRT) IS THIS DISPLAY USER CMD */       67501120
         CLI   CHVCD,DUVBCD        DISPLAY USER COMMAND                 67502020
         BE    GETSMPRT            YES, GO TO CHANGE GETMAIN PARAMETERS 67503020
*/*              P SET REGION SIZE FOR OPERATOR SEND CMD */             67504020
         L     R0,REGSIZE          SET UP PARAMETERS TO                 67510020
*/*GETPART:   P  SET UP PARAMETERS FOR GET PARTITION */                 67511020
GETPART  EQU   *                                                        67520020
         O     R0,SUBPOOL               GET A PARTITION                 69300020
*/*           P  GET A REGION */                                        69350020
         GETMAIN  R,LV=(0)         UNCONDITIONAL REQUEST                70200020
         LA    R0,RSA              LOAD LENGTH INTO REGISTER            71120020
*/*           P  GETMAIN FOR DYNAMIC CORE */                            71150020
         GETMAIN  R,LV=(0)         REGISTER SAVE AREA                   72000020
         LR    RD,R1               SET UP SAVE AREA REGISTER            72900020
*/*           P  SET ADDRESSIBILITY FOR DYNAMIC AREA */                 72950020
         USING SAVE,RD             SET ADDRESSIBILITY FOR SAVE DSECT    73810020
*/*           P  INITIALIZE PARMS FOR ATTACH */                         73820020
         MVC   ATCH(ATHLGTH),LSTATCH  MOVE LIST FORM OF ATTACH TO       73860020
*                                     DYNAMIC CORE                      73910020
         XC    ECB1,ECB1           ZERO OUT ECB                         73920020
         LA    R7,ECB1             LOAD ADDRESS OF THE ECB              73960020
         LA    RF,ATCH             LOAD ADDRESS OF THE LIST ATTACH      74010020
         LR    R1,R3               RELOAD ADDRESS OF THE CSCB           74060020
         LA    R9,VSEND            LOAD E P NAME FOR SEND ATTACH        74110020
         CLI   CHVCD,DUVBCD        DISPLAY USER COMMAND?          20030 75600020
         BNE   DOATTCH             NO BRANCH TO ATTACH IEEVSEND         76500020
         LA    R9,DUSER            YES, LOAD E P NAME FOR DISPLAY       76510020
*                                  USER ATTACH                          76520020
*********************************************************************** 76522420
*        THE FOLLOWING OI INSTRUCTION TURNS ON A BIT IN THE ATTACH    * 76524020
*        LIST FORM IN DYNAMIC AREA AND INDICATES THAT THE SUBTASK WILL* 76526020
*        BE IN SUPERVISOR STATE.THIS IS DONE IN ORDER THAT ONE ATTACH * 76528020
*        FORM CAN BE USED FOR BOTH SEND AND DISPLAY USER.   IF THE    * 76528420
*        EXPANSION OF THE LIST FORM OF THE ATTACH MACRO CHANGES THEN  * 76528520
*        THE OFFSET FROM RF WILL HAVE TO BE CHANGED.                  * 76528620
*********************************************************************** 76528820
         OI    N27(RF),SUPERST     INDICATE IN ATTACH LIST FORM         76530020
*                                  THAT THE ATTACHED SUBTASK WILL BE IN 76540020
*                                  SUPERVISOR STATE                     76550020
*/*           P  ATTACH EITHER SEND OR D USER */                        76552020
DOATTCH  EQU   *                                                        76560020
         ATTACH  EPLOC=(9),ECB=(7),MF=(E,(1)),SF=(E,(15))               76610020
         ST    R1,TCBADR           SAVE TCB ADDRESS OF THE SUBTASK      76660020
         LA    R1,ECB1             LOAD ADDRESS OF THE ECB              76662020
         WAIT  ECB=(1)             WAIT FOR COMPLETION OF DAUGHTER      76670020
         LA    R1,TCBADR           LOAD ADDRESS OF THE SUBTASK TCB      76672020
*/*           P  DETACH */                                              76672420
         DETACH  (1)               DO THE DETACH                        76674020
*********************************************************************** 76680020
*       THE FOLLOWING CODE CHECKS FOR THE SUCCESSFUL COMPLETION OF THE* 76692520
*       COMMAND AND IF SUCCESSFUL, THE CSCB IS DELETED, SUBPOOL 0     * 76702520
*       AND THE PARTITION ARE FREED.  IF THE COMMAND                  * 76704520
*       (EITHER  'SEND' OR 'D USER') DOES NOT COMPLETE SUCCESSFULLY,  * 76704920
*       THE ABEND COMPLETION CODE IS CONVERTED TO HEX, THE SOURCE OF  * 76709120
*       THE COMMAND IS DETERMINED, AND AN APPROPRIATE MSG IS ISSUED   * 76711120
*       USING THE MESSAGE MODULE IEE2103D TO THE APPROPRIATE CONSOLE  * 76713120
*       OR TERMINAL, AND THEN PROCESSING COMPLETES AS NORMAL.         * 76713220
*                                                                     * 76713320
*********************************************************************** 76717520
         L     R8,ECB1             LOAD ECB INTO REGISTER         M4801 76730020
         LA    R8,N0(R8)           CLEAR HIGH ORDER BYTE          M4801 76780020
         SRL   R8,N12              SHIFT COMPLETION CODE TO LOW-ORDER   76830020
*                                  12 BITS OF REGISTER            M4801 76840020
*/*           D  (YES,UNCHAIN,NO,) WAS COMPLETION SUCCESSFUL? */        76850020
         LTR   R8,R8               WAS THERE A SUCCESSFUL COMPLETION?   76880020
*                                                                 M4801 76930020
         BZ    UNCHAIN             YES, BRANCH TO FREE CSCB       M4801 77330020
*/*           P  CONVERT COMPLETION CODE TO PRINTABLE HEX */            77332020
         XC    XSA(LTHXSA),XSA     CLEAR XSA                      M4801 77340020
         STH   R8,COMCDE           SAVE COMPLETION CODE           M4801 77380020
         UNPK  XAV+N4(N4),COMCDE(N3)  UNPACK COMPLETION CODE      M4801 77430020
         TR    XAV+N4(N3),TRTABLE-C'0' TRANSLATE COMPLETION CODE  M4801 77480020
         MVI   XAV,C' '            INSERT BLANK CHARACTER         M4801 77530020
         MVC   XAV+N1(N3),XAV      PAD WITH BLANKS                M4801 77580020
         MVI   XAV+N7,C' '                                        M4801 77582020
*/*           P  INITIALIZE XSA FOR ERROR MSG */                        77590020
         CLI   CHVCD,DUVBCD        IS THIS DISPLAY USER COMMAND?  M4801 77630020
         BNE   SEND                NO, BRANCH TO SET 'SEND' MSG CODE    77680020
*                                                                 M4801 77690020
         LA    R8,DCODE            SET ONE-BYTE MSG CODE FOR DISPLAY    77730020
*                                  USER                           M4801 77780020
         STC   R8,XAE                                             M4801 77830020
         B     FORMAT              BRANCH TO CHECK SOURCE OF COMMAND    77880020
*                                  WHETHER OP CONSOLE OR A TERMINAL     77930020
*                                                                 M4801 77940020
SEND     EQU   *                   SET MSG CODE FOR SEND          M4801 77980020
         LA    R8,SNDCODE          GET MSG CODE                   M4801 78030020
         STC   R8,XAE              SAVE MSG CODE                  M4801 78080020
FORMAT   EQU   *                   CHECK SOURCE OF THE COMMAND    M4801 78130020
         MVC   XAU(N1),CHUCMP      GET CONSOLE ID                 M4801 78290020
         LH    R8,CHTJID           GET TWO-BYTE TERMINAL ID       M4801 78300820
         STH   R8,XAJ              STORE IN XSA                   M4801 78300920
         LA    R2,XSA              SET R2 TO THE ADDRESS OF THE XSA     78352920
*                                                                 M4801 78353320
         STM   0,15,SAREA          SAVE IEEVGPSD REGISTER CONTENTS      78354920
*                                                                 M4801 78355020
*/*           S  IEE2103D: ISSUE ERROR MSG */                           78356920
         LINK  EP=IEE2103D         LINK TO MESSAGE MODULE         M4801 78360920
         LM    0,15,SAREA          RESTORE IEEVGPSD REGISTER CONTENTS   78362920
*                                                                 M4801 78364920
UNCHAIN  EQU   *                                                        78370920
         LR    R1,R3               RESTORE REG 1 TO CSCB ADDR           78400920
*/*UNCHAIN:   P  FREE CSCB */                                           78450920
         OI    CHSTS,CHFC          INDICATE FREE CSCB'S CORE      M1586 78600920
         MGCR  (1),CHAIN           FREE CORE FOR CSCB                   80100020
         LA    R1,GETL            LOAD GETMAIN LIST FORM          M5759 80150020
         L     R6,REGSIZE         LOAD LENGTH TO BE GOTTEN        M5759 80200020
         LA    R5,UNPCK           LOAD ADDR OF DOUBLE WORD TO BE        80250020
*                                 USED BY GETMAIN FOR ADDR OF           80300020
*                                 AREA GOTTEN                     M5759 80350020
*********************************************************************** 80352020
*        DO A CONDITIONAL GETMAIN FOR AN AMOUNT OF CORE THAT COULD    * 80360020
*        NEVER BE SATISFIED IN ORDER TO FORCE GETMAIN TO PURGE ANY    * 80370020
*        MODULES IN SP 252 WHICH ARE NO LONGER NEEDED                 * 80372020
*********************************************************************** 80380020
*/*           P  PURGE ALL UNUSED MODULES IN SP 252 */                  80392020
         GETMAIN EC,LV=(6),A=(5),MF=(E,(1))                       M5759 80400020
         L     R0,SP252           LOAD THE SUBPOOL ID             M5759 80450020
         SR    R1,R1              INITIALIZE REG 1 TO ZERO        M5759 80500020
*********************************************************************** 80520020
*        FREEMAIN ALL OF SUBPOOL 252 TO CLEAN UP ANY CORE             * 80522020
*        (SUCH AS WORKAREAS) THAT COULD NOT BE PURGED BY              * 80524020
*        THE ABOVE GETMAIN.                                           * 80526020
*********************************************************************** 80530020
*/*           P  FREE SUBPOOL 252 */                                    80540020
         FREEMAIN R,LV=(0),A=(1)  FREE SUBPOOL 252                M5759 80550020
         L     R0,SP252           LOAD SUBPOOL ID                 M5759 80600020
         LA    R1,N8              LOAD LENGTH TO BE GOTTEN        M5759 80650020
         OR    R0,R1              R0 CONTAINS SUBPOOL ID IN             80700020
*                                 HI-ODER BYTE AND LENGTH IN            80750020
*                                 LOW ORDER                       M5759 80800020
*********************************************************************** 80810020
*        FREEPART EXPECTS TO FIND 8 BYTES IN SP 252 WHICH             * 80812020
*        HAVE NOT BEEN FREED, THEREFORE A GETMAIN IS                  * 80814020
*        DONE FOR 8 BYTES.                                            * 80816020
*********************************************************************** 80820020
*/*           P  GETMAIN FOR 8 BYTES FROM SP 252(FREEPART EXPECTS IT)   80830020
*/**/                                                                   80840020
         GETMAIN R,LV=(0)         GETMAIN FOR 8 BYTES OF SP 252   M5759 80850020
*********************************************************************** 80900020
*        FREE THE PARTITION                                           * 80910020
*********************************************************************** 80950020
*/*           P  FREE THE PARTITION(REGION) */                          81000020
         FREEMAIN  R,SP=247        FREE REGION                          83700020
         LR    RE,R4               SET RETURN ADDRESS                   84600020
*/*              R RETURN TO MASTER SCHEDULER */                        84610020
         BR    RE                  RETURN TO MASTER SCHEDULER           85500020
*/*GETSMPRT: P   SET SMALL REGION SIZE FOR DISPLAY USER CMD */          88201020
GETSMPRT EQU   *                                                        88210020
         L     R0,SMREGSZE         GET SMALL REGION FOR D U COMMAND     88220020
*/*              P (,GETPART) BRANCH TO GET REGION */                   88221020
         B     GETPART             RETURN TO GETMAIN FOR REGION         88230020
         EJECT                                                          89100020
TRTABLE  DC    C'0123456789ABCDEF' TRANSLATE TABLE FOR HEX CONVERSION   89110020
*                                                                 M4801 89120020
GETL     GETMAIN EC,SP=0,MF=L      LIST FORM OF GETMAIN           M5759 89130020
VSEND    DC    CL8'IEEVSEND'       ENTRY POINT NAME FOR SEND ATTACH     89150020
DUSER    DC    CL8'IEEVDUS1'       E P NAME FOR DISPLAY USER ATTACH     89200020
LSTATCH  ATTACH  HIARCHY=0,SVAREA=NO,SZERO=NO,SF=L                      89250020
REGSIZE  DC    F'12288'            REGION SIZE FOR SEND COMMAND =12K    90000020
SMREGSZE DC    F'6144'            REGION SIZE FOR D USER COMMAND        90010020
SP252    DC    AL1(252)           WORD FOR GETMAIN (SUBPOOL ID)   M5759 90060020
         DC    AL3(0)              WORD FOR GETMAIN (LENGTH)      M5759 90110020
SUBPOOL  DC    AL1(247)            SUBPOOL NUMBER FOR                   90900020
         DC    AL3(0)                   GET AND FREE PART               91800020
N27      EQU   27                 DISPLACEMENT INTO ATTACH EXPANSION    91850020
DUVBCD   EQU   164                VERB CODE FOR D USER           20030  92710020
ATHLGTH  EQU   52                 LENGTH OF LIST FORM OF ATTACH         92760020
SAVE     DSECT                                                          92810020
SAREA    DS    18F                SAVE AREA                       M4801 92860020
TCBADR   DS     1F                ADDRESS OF THE SUBTASK TCB            92870020
ECB1     DS     1F                EVENT CONTROL BLOCK FOR ATTACH        92910020
COMCDE   DS     H                 ABEND COMPLETION CODE FROM ECB  M4801 92920020
UNPCK    DS     D                 WORD FOR CONVERSION             M4801 92930020
ATCH     DS    13F                LIST FORM OF THE ATTACH MACRO         92960020
         IEEXSA                   EXTENDED SAVE AREA(XSA)         M4801 92970020
END1     DS    0H                                                       92980020
RSA      EQU   END1-SAREA        SIZE FOR GETMAIN                M4801  92990020
CSCB     DSECT                                                          93010020
         IEECHAIN                                                       93060020
*/*IEEVGPSD:  END END OF IEEVGPSD */                                    94510020
         END                                                            95400020
