IEEVSDIO CSECT                                                          00050020
          TITLE  'IEEVSDIO - I/O ROUTINE FOR USER SEND CMD FOR TSO'     00060020
*/*IEEVSDIO:  CHART */                                                  00100020
*/* HEADER                                                              00150020
*/*NOVEMBER 1970                                                        00200020
*/*SEND I/O MODULE                                                   */ 00250020
*/*           E  IEEVSDIO */                                            00350020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 00400020
*                                                                     * 00450020
*    STATUS: CHANGE LEVEL 000                                         * 00500020
*                                                                     * 00550020
*    FUNCTION:                                                        * 00750020
*            THIS ROUTINE PERFORMS     I/O OPERATIONS FOR THE SEND    * 00800020
*            COMMAND.  FUNCTIONS PROVIDED ARE:                        * 00850020
*                   OPEN                READ                          * 00900020
*                   CLOSE               WRITE 'DI'                    * 00950020
*                                       WRITE 'DAF'                   * 01000020
*                                                                     * 01050020
*            NECESSARY INFORMATION FOR THE OPERATIONS DESIRED IS      * 01100020
*            SPECIFIED IN THE PARAMETER LIST POINTED TO BY REGISTER1: * 01150020
*                                                                     * 01200020
*                   ---------------------------                       * 01250020
*                   - FLAGS(2) KEY(1) FDBK(1) -                       * 01300020
*                   ---------------------------                       * 01350020
*                   -   RBA FOR READ/WRITE    -                       * 01400020
*                   -    RBA FOR FEEDBACK     -                       * 01450020
*                   ---------------------------                       * 01500020
*                   -      AREA ADDRESS       -                       * 01550020
*                   ---------------------------                       * 01600020
*                   -   DDNAME  (8 BYTES)     -                       * 01650020
*                   -                         -                       * 01700020
*                   ---------------------------                       * 01750020
*                   -      LIMIT COUNT        -                       * 01800020
*                   ---------------------------                       * 01850020
*                   -      DCB ADDRESS        -                       * 01900020
*                   ---------------------------                       * 01950020
*                                                                     * 02000020
*                                                                     * 02050020
*    ENTRY POINTS: IEEVSDIO                                           * 02100020
*                                                                     * 02150020
*                                                                     * 02200020
*    INPUT:  REGISTER 1 - ADDRESS OF PARAMETER LIST                   * 02250020
*            REGISTER 14- RETURN ADDRESS                              * 02300020
*            REGISTER 15- ENTRY POINT ADDRESS                         * 02350020
*                                                                     * 02400020
*                                                                     * 02450020
*    OUTPUT:                                                          * 02500020
*            REGISTER 1 - ADDRESS OF PARAMETER LIST                   * 02550020
*            REGISTER15 - RETURN CODE                                 * 02600020
*                                                                     * 02650020
*    EXTERNAL REFERENCES:                                             * 02700020
*             GETMAIN, FREEMAIN,                                      * 02750020
*            READ, WRITE, CHECK,OPEN,CLOSE,                           * 02800020
*                                                                     * 02950020
*                                                                     * 03000020
*    EXITS,NORMAL: CONTROL RETURNS TO CALLER                          * 03050020
*                                                                     * 03100020
*    EXITS,ERROR: NONE.                                               * 03150020
*                                                                     * 03200020
*    TABLES/WORK AREAS:                                               * 03250020
*            CVT - TO GET PTR TO UCB LOOKUP TABLE                     * 03300020
*            DCB - FOR BROADCAST DATA SET                             * 03350020
*            DECB - DATA EVENT CONTROL BLOCK                          * 03400020
*            ECB - EVENT CONTROL BLOCK - TO TEST EXCEPTION CODE       * 03450020
*                    BIT SETTINGS AFTER I/O OPERATION                 * 03500020
*                                                                     * 03700020
*    ATTRIBUTES: REENTRANT                                            * 03800020
*                                                                     * 03850020
*    CHARACTER DEPENDENCY CODE:  NONE.                                * 03860020
*                                                                     * 03870020
*    NOTES:                                                           * 03900020
*         1. STANDARD LINKAGE CONVENTIONS USED.                       * 03950020
*         2. THIS ROUTINE IS CALLED BY USER SEND CP - IKJEES10,       * 04000020
*                                      ACCT/SEND INTERFACE - IKJEES40 * 04100020
*                                                                     * 04150020
*         3. SUPPORT CODE FOR THIS MODULE IS 20034, TSO SCHEDULER     * 04160020
*                                                                     * 04260020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 04300020
         EJECT                                                          04350020
*********************************************************************** 04400020
*                                                                     * 04450020
*                   R E G I S T E R    E Q U A T E S                  * 04500020
*                                                                     * 04550020
*********************************************************************** 04600020
*                                                                     * 04650020
R0       EQU   0                   REGISTER USED IN GETMAIN, FREEMAIN   04700020
R1       EQU   1                   TEMPORARY WORK REG                   04750020
R2       EQU   2                   TEMPORARY USE                        04800020
R3       EQU   3                   ADDRESS OF 129 BYTE READ/WRITE AREA  04850020
R4       EQU   4                   ADDRESS OF RBA (RELATIVE BLOCK       04900020
*                                  ADDRESS) OF DESIRED BLOCK            04950020
R5       EQU   5                   WORK REGISTER                        05000020
R6       EQU   6                   COUNTER FOR LOOP CONTROL             05050020
R7       EQU   7                   ADDRESS OF PARAMETER LIST            05100020
R8       EQU   8                   WORK REGISTER                        05150020
R9       EQU   9                   BASE REGISTER FOR CONTROL BLOCKS     05200020
R10      EQU   10                  BASE REGISTER FOR DSECT FOR DCB      05250020
R11      EQU   11                  BASE REGISTER FOR CSECT              05300020
R12      EQU   12                  BASE REGISTER FOR DATA AREA DSECT    05350020
R13      EQU   13                  ADDRESS OF THIS ROUTINE'S SAVE AREA  05400020
R14      EQU   14                  ADDRESS OF CALLING ROUTINE RETURN    05450020
R15      EQU   15                  RETURN CODE                        * 05500020
         EJECT                                                          05550020
*                                                                     * 05600020
*                                                                     * 05650020
*/*           P  SAVE REGISTER CONTENTS */                              05700020
         SAVE  (14,12)             SAVE ALL REGISTERS                   05750020
         LR    R7,R1               SAVE ADDRESS OF PARMLIST IN REG7     05800020
         LR    R11,R15             R11 = ADDRESS IEEVSDIO CSECT         05850020
*/*           P  ESTABLISH ADDRESSIBILITY FOR CSECT */                  05900020
         USING IEEVSDIO,R11        SET ADDRESSABILITY FOR CSECT         05950020
         B     *+20                BRANCH AROUND MODULE ID              06000020
         DC    AL1(8)              LENGTH OF MOD NAME                   06050020
         DC    CL8'IEEVSDIO'       MODULE IDENTIFICATION                06100020
         DC    CL3'341'            JULIAN DATE                          06150020
         DC    CL4'1970'           YEAR                                 06160020
         LA    R0,DATAEND-DATABEG  SET R0 FOR GETMAIN FOR WORK AREA     06200020
         GETMAIN  R,LV=(0)         GET CORE FOR WORK AREA               06250020
         LR    R12,R1              MOVE ADDR OF GOTTEN CORE TO REG 12   06300020
         USING DATABEG,R12         SET ADDRESSABILITY FOR DATA AREA     06350020
         ST    R13,SAVER+OFFCALLR  SAVE ADDRESS OF CALLER'S SAVE AREA   06400020
         LR    R5,R13              GET ADDRESS CALLERS SAVE AREA        06450020
         LA    R13,SAVER                                                06500020
         ST    R13,OFFCALLD(R5)    SAVE ADDRESS OF THIS RTN'S SAVE AREA 06550020
*                                                                       06600020
*                                                                     * 06650020
*                                                                       06700020
         MVC   DECB1(LISTSL),DEC01 MOVE LISTS FOR MACRO INSTRUCTIONS    06750020
*                                  INTO GOTTEN CORE (DSECT)             06800020
         USING IHADCB,R10          ESTABLISH ADDRESSABILITY FOR IHADCB  06850020
         USING SDIOPARM,R7         SET ADDRESSABILITY FOR PARMLIST DSEC 06900020
*/*           D  (YES,,NO,TESTREAD) IS OPEN REQUESTED */                06950020
         TM    PARM1,P1OPEN        IS OPEN REQUESTED                    07000020
         BZ    TESTREAD            NO, BRANCH                           07050020
         LA    R5,DCBLNG           R5 = LENGTH OF DCB FOR GETMAIN       07100020
*/*           P  GET CORE FOR DCB  */                                   07150020
         GETMAIN  EC,LV=(R5),A=DCBADD,MF=(E,GETML)   GET CORE FOR DCB   07200020
         LTR  R15,R15              TEST GETMAIN RETURN CODE IN REG 15   07250020
         BNZ  BADGM                IF NOT SUCCESSFUL (0), RETURN TO     07300020
*                                  CALLER WITH ERROR INDICATION         07350020
         L    R10,DCBADD           MOVE ADDR OF GOTTEN CORE TO REG 10   07400020
*        R10 HAS ADDRESS OF CORE GOTTEN FOR DCB VIA GETMAIN             07450020
*/*           D  (YES,MOVEDCB,NO,) DEVICE ADDR FEEDBACK REQ'D? */       07502020
         TM    PARM2,P2ACCT        TEST IF THIS OPEN IS FOR SPECIAL DCB 07510020
*                                  TO GET ACTUAL DEVICE ADDR FEEDBACK   07520020
*/*           P  MOVE IN DCB FOR RBA FEEDBACK */                        07522020
         BO    MOVEDCB             YES, MOVE IN SPECIAL DCB             07530020
         MVC   ZER(BDDCBL,R10),BDAMDCB  MOVE BDAM DCB TO GOTTEN CORE    07550020
OPEN1    DS    0H                  DCB HAS BEEN MOVED INTO GOTTEN CORE  07600020
*/*OPEN1:    P  PUT DDNAME IN DCB */                                    07650020
         MVC   DCBDDNAM(L'DCBDDNAM),PARMDDNM  MOVE DDNAME INTO DCB      07900020
         LA    R5,SYNAD0           CHANGE SYNAD ADDRESS FOR FIRST READ  07910020
         ST    R5,WORK4            PUT SYNAD ADDR INTO WORK4 FOR 'MVC'  07920020
         MVC   DCBSYNAD+ONE(RBAL),WORK4+ONE  PUT SYNAD ADDR IN DCB      07930020
*/*           I  OPEN BROADCAST DATA SET */                             07950020
         OPEN  ((R10),(OUTPUT)),MF=(E,OPENL) OPEN DATA SET FOR UPDATE   08000020
*/*OPEN2:     D  (YES,,NO,BADOPEN) IS OPEN SUCCESSFUL */                08100020
         TM    DCBOFLGS,GOODOPEN   TEST OPEN FLAGS OF DCB               08150020
         BZ    BADOPEN             IF NOT SUCCESSFUL OPEN, BRANCH       08200020
*                                                                       08350020
* READ RECORD 1 OF SYS1.BRODCAST DATA SET TO DETERMINE IF DATA SET HAS* 08400020
* BEEN INITIALIZED.                                                   * 08450020
*                                                                     * 08500020
*/*           I  READ RECORD 1 OF BROADCAST DS */                       08550020
         READ  DECB1,DI,(R10),RECORD1,'S',0,R1RBA,MF=E  READ RECORD 1   08600020
         CHECK DECB1                                                    08650020
         LA    R5,SYNAD1           RESTORE SYNAD ADDRESS TO DCB         08700020
         ST    R5,WORK4            PUT SYNAD ADDR INTO WORK4 FOR 'MVC'  08770020
         MVC   DCBSYNAD+ONE(RBAL),WORK4+ONE  PUT SYNAD ADDR IN DCB      08780020
*/*           D  (YES,,NO,INITDS) IS BROADCAST DS INITIALI -ZED */      08800020
         CLC   R1DSN(L'DSNAME),DSNAME  DATE SET NAME IN RECORD 1 THUS   08850020
*                                       INDICATING INITIALIZATION DONE  08900020
         BNE   INITDS              NO, BRANCH TO DO INITIAL FORMATTING  08950020
*/*           P  SAVE DCB PTR IN PARM LIST */                           09000020
         ST    R10,PARMDCB         SAVE DCB ADDR IN PARM LIST           09050020
         MVC   PARMLMCT(PTRL),R1RECNUM  SAVE LIMIT CNT IN PARM LIST     09100020
*/*           P  (,ENDIO) RETURN CODE=0 SUCCESSFUL PROCESSING */        09150020
         XC    RETCODE,RETCODE     SET RETCODE = 0 FOR OPERATION DONE   09200020
         B     ENDIO               END OF PROCESSING                    09250020
*                                                                       09260020
*                                                                       09270020
MOVEDCB  DS    0H                  MOVE IN DCB FOR ACTUAL DEVICE        09280020
*                                  ADDRESS FEEDBACK                     09280120
*/*MOVEDCB:   P  (,OPEN1) MOVE IN DCB FOR DEVICE ADDR FDBK */           09280420
*                                  R10 = ADDR OF DCB CORE               09282020
         MVC   ZER(BDDCBL,R10),ACCTDCB   MOVE DCB TO GOTTEN CORE        09290020
         B     OPEN1               BRANCH BACK TO OPEN DCB              09292020
         EJECT                                                          09300020
TESTREAD DS    0H                  READ BY BLOCK ID                     09350020
*/*TESTREAD:  D  (YES,,NO,TESTWRDI) IS READ REQUESTED */                09400020
         TM    PARM1,P1READ        IS READ REQUESTED                    09450020
         BZ    TESTWRDI            NO, BRANCH                           09500020
*/*           P  GET DCB PTR FROM PARM LIST */                          09550020
         L     R10,PARMDCB         R10 = ADDRESS OF DCB FROM PARM       09600020
         L     R3,PARMIOAD         SET AREA ADDRESS FROM PARM LIST      09650020
         L     R4,PARMRBA          SET BLOCK ID (RBA) FROM PARM LIST    09700020
*/*           I  READ REQ'D RECORD */                                   09750020
         READ  DECB1,DIF,(R10),(R3),'S',0,(R4),MF=E  READ A RECORD      09800020
         CHECK DECB1               CHECK THE READ                       09850020
         MVC   PARMFDBK(L'PARMFDBK),RECPOS(R4)   PUT FEEDBACK OF RECORD 09900020
*                                  POSITION ON TRACK INTO PARM LIST     09950020
*/*           P  (,ENDIO) RETURN CODE= 0 SUCCESSFUL PROCESSING */       10000020
         XC    RETCODE,RETCODE     SET RETCODE = 0 FOR OPERATION DONE   10050020
         B     ENDIO               END OF PROCESSING                    10100020
         EJECT                                                          10150020
TESTWRDI DS    0H                  WRITE BY BLOCK ID                    10200020
*/*TESTWRDI:  D  (YES,,NO,TESTWRDA) IS WRITE 'DI' REQUESTED */          10250020
         TM    PARM2,P2WRDI        IS WRITE 'DI' REQUESTED              10300020
         BZ    TESTWRDA            NO, BRANCH                           10350020
*/*           P  GET DCB PTR FROM PARM LIST */                          10400020
         L     R10,PARMDCB         R10 = ADDRESS OF DCB FROM PARM       10450020
         L     R3,PARMIOAD         SET AREA ADDRESS FROM PARMLIST       10500020
         L     R4,PARMRBA          SET BLOCK ID (RBA) FROM PARMLIST     10550020
         MVC   KEY(L'PARMKEY),PARMKEY   SET KEY FROM PARMLIST           10600020
*/*           D  (NO,,YES,NOTDEL) IS WRITE A DELETION */                10650020
         TM    PARM2,P2DEL         TEST IF THIS WRITE IS A DELETION     10700020
         BNO   NOTDEL              NO, BRANCH AROUND FIRST BYTE SETTING 10750020
*/*           P  PUT DELETION INDICATOR ON IN RECORD TO BE DELETED */   10800020
         MVC   0(L'PARMFDBK,R3),PARMFDBK  PUT POSITION OF RECORD ON     10850020
*                                  TRACK INTO FIRST BYTE OF DATA RECORD 10900020
*                                  TO SHOW 'AVAILABLE' TO BDAM          10950020
NOTDEL   DS    0H                  THIS WRITE IS NOT FOR A DELETION     11000020
*/*NOTDEL:    I  WRITE REQ'D RECORD */                                  11050020
         WRITE DECB2,DI,(R10),(R3),'S',KEY,(R4),MF=E  WRITE A RECORD    11100020
*                                                     BY BLOCK ID (RBA) 11150020
         CHECK DECB2               CHECK WRITE                          11200020
*/*           P  (,ENDIO) RETURN CODE= 0 SUCCESSFUL PROCESSING */       11250020
         XC    RETCODE,RETCODE     SET RETCODE = 0 FOR OPERATION DONE   11300020
         B     ENDIO               END OF PROCESSING                    11350020
         SPACE 4                                                        11400020
TESTWRDA DS    0H                  WRITE 'DA'                           11450020
*/*TESTWRDA:  D  (YES,,NO,TESTCLOS) IS WRITE 'DA' REQUESTED */          11500020
         TM    PARM2,P2WRDAF       IS WRITE 'DA' REQUESTED              11550020
         BZ    TESTCLOS            NO, BRANCH                           11600020
*/*           P  GET DCB PTR FROM PARM LIST */                          11650020
         L     R10,PARMDCB         R10 = ADDRESS OF DCB FROM PARM       11700020
         LA    R5,SYNWRDA          CHANGE SYNAD ADDR IN DCB             11750020
         ST    R5,WORK4            PUT SYNAD ADDR INTO WORK4 FOR 'MVC'  11820020
         MVC   DCBSYNAD+ONE(RBAL),WORK4+ONE  PUT SYNAD ADDR IN DCB      11830020
*/*           P  SET LIMIT OF RECORDS TO BE SEARCHED TO FIND AVAILABLE  11850020
*/*SPACE */                                                             11900020
         MVC   DCBLIMCT+NEXT(HALF),PARMLMCT+HALF  SET LIMIT COUNT IN    11950020
*                                  DCB FOR EXTENDED SEARCH              12000020
*                                  TO NO. RECORDS IN DAT SET FROM REC 1 12050020
         L     R3,PARMIOAD         SET AREA ADDR FROM PARMLIST          12100020
         L     R4,PARMRBA          SET BLOCK ID FROM PARMLIST           12150020
         MVC   KEY(L'PARMKEY),PARMKEY   SET KEY FROM PARMLIST           12200020
*/*           I  WRITE REQ'D RECORD */                                  12250020
         WRITE DECB3,DAF,(R10),(R3),'S',KEY,(R4),MF=E WRITE RECORD      12300020
         CHECK DECB3               CHECK THE WRITE                      12350020
*                                  R4 = ADDRESS OF FEEDBACK RBA         12400020
         MVC   PARMRBA+ONE(RBAL),ZER(R4)                                12450020
         LA    R5,SYNAD1           CHANGE SYNAD ADDR AFTER WRITE 'DA'   12500020
         ST    R5,WORK4            PUT SYNAD ADDR INTO WORK4 FOR 'MVC'  12570020
         MVC   DCBSYNAD+ONE(RBAL),WORK4+ONE  PUT SYNAD ADDR IN DCB      12580020
*/*           P  (,ENDIO) RETURN CODE= 0 SUCCESSFUL PROCESSING */       12600020
         XC    RETCODE,RETCODE     SET RETCODE = 0 FOR OPERATION DONE   12650020
         B     ENDIO               END OF PROCESSING                    12700020
         EJECT                                                          12750020
TESTCLOS DS    0H                  CLOSE                                12800020
*/*TESTCLOS:  D  (YES,,NO,ENDIO) IS CLOSE REQUESTED */                  12850020
         TM    PARM2,P2CLOSE       IS CLOSE REQUESTED                   12900020
         BZ    ENDIO               NO, BRANCH                           12950020
*                                  CLOSE SYS1.BRODCAST DATA SET         13000020
*/*           P  GET DCB PTR FROM PARM LIST */                          13050020
         L     R10,PARMDCB         R10 = ADDRESS OF DCB FROM PARM       13100020
*/*           I  CLOSE BROADCAST DATA SET */                            13150020
         CLOSE  ((R10)),MF=(E,CLOSEL)  CLOSE DATA SET                   13200020
*/*           P  (,ENDIO) RETURN CODE= 0 SUCCESSFUL PROCESSING */       13210020
         XC    RETCODE,RETCODE     SET RETCODE = 0 FOR OPERATION DONE   13220020
FREEDCB  DS    0H                  FREE CORE GOTTEN FOR DCB             13230020
         LA    R0,DCBEND-IHADCB    SET R0 FOR FREEMAIN                  13250020
*/*           P  FREEMAIN CORE FOR DCB */                               13300020
         FREEMAIN  R,LV=(0),A=(R10)  FREE CORE FOR DCB                  13350020
         B     ENDIO               END OF PROCESSING                    14000020
         EJECT                                                          14050020
INITDS   DS    0H                                                       14100020
*/*INITDS:    I  CLOSE DCB FOR BDAM */                                  14150020
         CLOSE  ((R10)),MF=(E,CLOSEL)  CLOSE DCB FOR BDAM               14200020
*        R10 HAS ADDRESS OF CORE GOTTEN FOR DCB VIA GETMAIN             14250020
*/*           P  MOVE BSAM DCB TO CORE */                               14300020
         MVC   ZER(BSDCBL,R10),BSAMDCB  MOVE BSAM DCB TO GOTTEN CORE    14350020
         MVC   DCBDDNAM(L'DCBDDNAM),PARMDDNM  MOVE DDNAME INTO DCB      14400020
*/*           I  OPEN TO CREATE BDAM DS USING BSAM */                   14650020
         OPEN   ((10),(OUTPUT)),MF=(E,OPENL)  OPEN TO CREATE BDAM       14700020
*/*           D  (YES,,NO,BADOPEN) WAS OPEN SUCCESSFUL */               14800020
         TM    DCBOFLGS,GOODOPEN   WAS OPEN SUCCESSFUL                  14850020
         BZ    BADOPEN             NO, BRANCH                           14900020
         EJECT                                                          15350020
*********************************************************************** 15400020
*                                                                     * 15450020
* THE FOLLOWING CODE CREATES A BDAM DATA SET BY ISSUING BSAM WRITE    * 15500020
* INSTRUCTIONS TO WRITE DUMMY RECORDS WITH KEY = X'FF'                * 15550020
* AND FIRST BYTE OF DATA = POSITION OF RECORD ON TRACK                * 15600020
* THE BROADCAST DATA SET MUST HAVE ONLY 1 EXTENT.                     * 15650020
* RECORDS ARE WRITTEN UNTIL THE RETURN CODE INDICATES THAT THE NEXT   * 15700020
* BLOCK REQUIRES SECONDARY SPACE ALLOCATION.                          * 15750020
*                                                                     * 15800020
*********************************************************************** 15850020
CREATE   DS    0H                  CREATE BDAM USING BSAM               15900020
         SR    R8,R8               R8 = 0 = NO. RECORDS WRITTEN         15950020
         XC    BCD,BCD             SET RECORD TO BE WRITTEN TO ZERO     16000020
*                                                                     * 16050020
WRITESD  DS    0H                                                       16100020
*/*WRITESD:   I  WRITE DUMMY RECORD */                                  16150020
         WRITE DECB4,SD,(R10),BCD,'S',,,MF=E  WRITE DUMMY RECORD        16200020
*/*           P  INCREMENT NUMBER OF RECORDS WRITTEN BY 1 */            16250020
         LA    R8,NEXT(R8)         BUMP COUNT OF RECORDS WRITTEN        16300020
         LR    R5,R15              R15 = RETURN CODE AFTER WRITE        16350020
         CHECK DECB4               CHECK THE WRITE FOR COMPLETION       16400020
*/*           D  (0,WRITESD,4,WRITESD,8,) CHECK RETURN CODE */          16450020
         B     BTABLE(R5)          TEST RETURN CODE FROM WRITE          16500020
BTABLE   EQU   *                   BRANCH TABLE FOR RETURN CODE FROM    16550020
*                                  WRITE MACRO                          16600020
         B     WRITESD             RET CODE = 00, WRITE ANOTHER BLOCK   16650020
         B     WRITESD             RET CODE = 04, WRITE ANOTHER BLOCK   16700020
         DS    0H                  RET CODE = 08, STOP WRITING.         16750020
*                                  BLOCK WILL BE WRITTEN. NEXT BLOCK    16800020
*                                  REQUIRES SECONDARY SPACE ALLOCATION  16850020
*/*           P  SECONDARY SPACE ALLOCATION NEEDED */                   16900020
         ST    R8,RECCNT           SET NO. RECORDS IN DATA SET          16950020
         EJECT                                                          17000020
*                                                                     * 17050020
* CLOSE DATA AND REPOSITION TO CONTINUE FORMATTING                    * 17100020
*                                                                     * 17150020
*/*           I  CLOSE BROADCAST D S */                                 17200020
         CLOSE ((R10),REREAD),MF=(E,CLOSEL)  CLOSE FOR REREAD           17250020
*/*           P  MOVE BDAM DCB INTO CORE */                             17300020
         MVC   ZER(BDDCBL,R10),BDAMDCB  MOVE BDAM DCB TO GOTTEN CORE    17350020
         MVC   DCBLIMCT(RBAL),RECCNT+NEXT                               17400020
*                                         SET LIMCT FIELD IN DCB TO     17450020
*                                         NO. RECORDS IN DATA SET       17500020
         MVC   DCBDDNAM(L'DCBDDNAM),PARMDDNM  MOVE DDNAME INTO DCB      17550020
*/*           I  OPEN BROADCAST D S FOR BDAM */                         17750020
         OPEN  ((R10),(OUTPUT)),MF=(E,OPENL) OPEN DATA SET FOR UPDATE   17800020
*/*           D  (YES,,NO,BADOPEN) WAS OPEN SUCCESSFUL */               17900020
         TM    DCBOFLGS,GOODOPEN   WAS OPEN SUCCESSFUL                  17950020
         BZ    BADOPEN             NO, BRANCH                           18000020
         EJECT                                                          18400020
*********************************************************************** 18450020
*                                                                     * 18500020
*  FIND MAXIMUM NO. OF BRODCAST 'NOTICES' MESSAGES FROM MASTER SCHED  * 18550020
*  BASE A                                                             * 18600020
*                                                                     * 18650020
*********************************************************************** 18700020
FINDMAX  DS    0H                  FIND MAX NO. NOTICE MSGS             18750020
*/*           P  FIND THE MAX NO. OF NOTICE MSGS FROM MS BASE A */      18800020
         L     R9,CVTPTR           R9 = ADDRESS CVT IN MAIN STORAGE     18850020
         USING CVTD,R9             SET ADDRESSABILITY FOR CVT DSECT     18900020
         L     R9,CVTMSER          R9 = ADDRESS MASTER SCHED BASEA      18950020
         USING BASE,R9             SET ADDRESSABILITY FOR M.S. BASEA    19000020
         MVC   BCMAX(HALF),BABCMAX BCMAX = MAXIMUM NO. BROADCAST MSGS   19050020
*                                  SPEC'D AT SYSGEN & KEPT IN           19100020
*                                  MASTER SCHEDULER BASE A              19150020
         LH    R5,BCMAX                                                 19200020
         LTR   R5,R5               TEST BCMAX FOR ZERO, INVALID VALUE   19250020
         BNZ   BCMAXSET            IF NOT ZERO, BRANCH AROUND SETTING   19300020
*                                  IF ZERO, SET BCMAX TO 1              19350020
         LA    R5,NEXT             R5 = 1                               19400020
         STH   R5,BCMAX            SET BCMAX = 1 TO REPLACE ZERO        19450020
BCMAXSET DS    0H                  BCMAX CONTAINS NONZERO VALUE         19500020
*                                                                     * 19550020
* THE FOLLOWING CALCULATES THE RBA OF THE FIRST BRODCAST NOTICES      * 19600020
* MESSAGE RECORD.  THIS VALUE IS THEN USED IN FORMATTING THE BRODCAST * 19650020
* DIRECTORY RECORDS.  A UNIQUE MSG RBA IS PUT INTO THE DIRECTORY FOR  * 19700020
* EACH POSSIBLE BRODCAST MSG NUMBER.                                  * 19750020
* THE FORMULA USED IS:                                                * 19800020
*                                                                     * 19850020
*   RBA OF FIRST     RBA OF FIRST     NUMBER OF                       * 19900020
*   BRODCAST MSG  =  BRODCAST DIR  +  BRODCAST                        * 19950020
*    RECORD           RECORD          DIR RECORDS                     * 20000020
*                                                                     * 20050020
*                                                                     * 20100020
*/*           P  CALCULATE RBA OF FIRST NOTICE MSG RECORD */            20150020
         SR    R8,R8               CLEAR R8                             20200020
         LH    R9,BCMAX            R9 = MAXIMUM NUMBER OF BC MSG        20250020
*                                  R9 = DIVIDEND                        20300020
         D     R8,NUMENT           DIVIDE BY NUMBER OF MSG ENTRIES      20350020
*                                  PER BC DIRECTORY RECORD              20400020
*                                  R9 = QUOTIENT = NO. BC DIRECTORY REC 20450020
*/*           D  (YES,NOREM,NO,) IS RBA EVEN NUMBER */                  20500020
         LTR   R8,R8               R8 = REMAINDER                       20550020
         BZ    NOREM               IF NO REMAINDER, BYPASS BUMP         20600020
*/*           P  INCREMENT NUMBER BY 1 TO MAKE IT EVEN */               20650020
         LA    R9,NEXT(R9)         BUMP R9 BY 1                         20700020
NOREM    DS    0H                                                       20750020
*/*NOREM:     P  CALCULATE RBA OF FIRST BC MSG */                       20800020
         LA   R9,BD1RBA(R9)        BUMP R9 BY RBA OF FIRST BC DIR. REC  20850020
         ST    R9,BMRBA            BMRBA = RBA OF FIRST BC MSG RECORD   20900020
         MVC   R1BCMAX(L'BCMAX),BCMAX  SET MAXIMUM NO.BROADCAST MSGS    20950020
         MVC   BCMNUM(MSGNOL),BCMNUM1  INITIALIZE BRODCAST MSG NO.      21000020
*/*           P  MOVE CALCULATED RBA INTO NOTICE DIR ENTRY */           21050020
         MVC   BDRBA(PTRL),BDRBA1  INITIALIZE BRODCAST DIR RBA          21100020
         SPACE 4                                                        21150020
BCDL1    DS    0H             FORMAT 1 BRODCAST DIRECTORY RECORD        21200020
*/*BCDL1:     P  SET BC MSGNO */                                        21250020
         L     R8,BMRBA            R8 = RBA OF BRODCAST MESSAGE RECORD  21300020
         LA    R2,BCD              R2 = ADDRESS BRODCAST DIRECTORY REC  21350020
         LH    R1,BCMNUM           R1 = BRODCAST MESSAGE NUMBER         21400020
         CH    R1,BCMAX            TEST FOR MAXIMUM BRODCAST MSG NUM    21410020
         BH    DIREND              YES, END OF NOTICE DIRECTORY,        21420020
*                                  GO TO WRITE NOTICE MSG RECORDS       21430020
*/*           P  SET LOOP CONTROL INDEX TO 25 ENTRIES PER RCD */        21450020
         L     R6,NUMENT           R6 = 25 FOR LOOP CONTROL             21500020
         SPACE 4                                                        21550020
*/*BCDLOOP:   P  FORMAT 25 BC DIR ENTRIES */                            21600020
BCDLOOP  DS    0H            FORMAT 25 BRODCAST DIRECTORY RECORD ENTRY  21650020
*/*           D  (YES,ENDBCD,NO,) HAVE 25 ENTRIES BEEN FORMATED */      21700020
         CH    R1,BCMAX            IS IT MAXIMUM BRODCAST MSG NUM       21750020
         BH    ENDBCD              YES, BRANCH                          21800020
*/*           P  MOVE MSGNO INTO RECORD ENTRY */                        21850020
         MVC   BCMSGNO(MSGNOL,R2),BCMNUM SET BRODCAST MESSAGE NUMBER    21900020
*/*           P  SET FLAG TO INDICATE NO MSG FOR THIS MSGNO */          21950020
         OI    BCMSGNO(R2),NOMSG   SET BIT0 = 1 TO SAY NO MSG FOR THIS  22000020
*                                  BRODCAST MESSAGE NUMBER              22050020
         MVC   BCMRBA(RBAL,R2),BMRBA+NEXT  SET BROADCAST MSG RBA        22100020
*/*           P  MSGNO=MSGNO+1 */                                       22150020
         LA    R1,NEXT(R1)         BUMP BRODCAST MESSAGE NUMBER         22200020
         STH   R1,BCMNUM                                                22250020
         LA    R8,NEXT(R8)         BUMP BRODCAST MESSAGE RECORD RBA     22300020
         ST    R8,BMRBA                                                 22350020
*/*           P  BUMP PTR TO NEXT NOTICE DIR ENTRY */                   22400020
         LA    R2,BCDENTL(R2)      BUMP BCD PTR TO NEXT ENTRY           22450020
*/*           D  (NO,BCDLOOP,YES,) HAVE 25 ENTRIES BEEN DONE */         22500020
         BCT   R6,BCDLOOP          EXECUTE LOOP 25 TIMES                22550020
         LA    R4,BDRBA+NEXT       SET R4 = ADDR THIS DIRECTORY REC     22600020
*/*           P  SET END OF RECORD INDICATOR */                         22650020
         MVI   ZER(R2),ENDREC      SET END OF RECORD INDICATOR          22700020
         L     R5,BDRBA            BUMP BC DIRECTORY POINTER            22750020
         LA    R5,NEXT(R5)                                              22800020
         ST    R5,WORK4                                                 22850020
         CH    R1,BCMAX            CHECK FOR MAXIMUM BROADCAST MSGNO    22900020
         BH    NOPTR               LAST REC, SET CHAIN PTR TO ZERO      22950020
*/*           P  GET PTR TO NEXT BC DIRECTORY RCD */                    23000020
         MVC   NEXT(RBAL,R2),WORK4+NEXT  SET PTR TO NEXT BC DIRECT. REC 23050020
WRITBCD  DS    0H                  WRITE NOTICE DIRECTORY RECORD        23100020
         LA    R3,BCD              SET AREA ADDRESS                     23150020
         MVI   KEY,BDKEY           SET KEY = X'0                        23200020
*/*           I  WRITE DIRECTORY RCD */                                 23250020
         WRITE DECB2,DI,(R10),(R3),'S',KEY,(R4),MF=E  WRITE DIR. RECORD 23300020
         CHECK DECB2                                                    23350020
         ST    R5,BDRBA             SET RBA NEXT DIRECTORY REC          23400020
*/*           P  (,BCDL1) BRANCH TO FORMAT NEXT RECORD */               23450020
         B     BCDL1               BRANCH TO FORMAT ANOTHER RECORD      23500020
NOPTR    DS    0H                  LAST NOTICE DIRECTORY RECORD         23550020
         XC    NEXT(RBAL,R2),NEXT(R2)  ZERO OUT CHAIN PTR               23600020
         B     WRITBCD             GO TO WRITE DIRECTORY RECORD         23650020
         EJECT                                                          23660020
DIREND   DS    0H                  END OF DIRECTORY, DO NOT BUMP BDRBA  23662020
*                                  TO GET FIRST NOTICE MSG RBA          23664020
         L     R5,BDRBA            R5 = RBA OF LAST DIRECTORY RECORD    23666020
         B     WRITBCM2            GO TO WRITE NOTICE MSG RECORDS       23668020
         SPACE    4                                                     23670020
*/*ENDBCD:    P  WRITE ZEROES FOR REST OF DIRECTORY */                  23700020
ENDBCD   DS    0H                  WRITE ZEROES FOR REST OF DIRECT. REC 23750020
*/*           P  ZERO OUT ENTRY */                                      23800020
         XC    ZER(BCDENTL,R2),ZER(R2)  ZERO OUT BCD ENTRY              23850020
*/*           P  BUMP PTR IN BC DIR TO NEXT ENTRY */                    23900020
         LA    R2,BCDENTL(R2)      BUMP PTR IN BC DIRECTORY RECORD TO   23950020
*                                  NEXT ENTRY                           24000020
*/*           D  (YES,,NO,ENDBCD) HAVE 25 ENTRIES BEEN MADE? */         24050020
         BCT   R6,ENDBCD           LOOP TILL 25 ENTRIES ARE MADE        24100020
*/*           P  SET END OF RECORD FLAG='7F' */                         24150020
         MVI   ZER(R2),ENDREC      SET END OF RECORD INDICATOR          24200020
*/*           P  SET PTR TO NEXT DIRECTORY RCD=0, LAST DIR RCD */       24250020
         XC    NEXT(RBAL,R2),NEXT(R2)  PTR TO NEXT BC DIRECT. REC = 0   24300020
*********************************************************************** 24350020
*                                                                     * 24400020
* WRITE BRODCAST DIRECTORY RECORD                                     * 24450020
*                                                                     * 24500020
*********************************************************************** 24550020
         LA    R4,BDRBA+NEXT       SET ADDRESS OF BLOCK ID (RBA)        24600020
         LA    R3,BCD              SET AREA ADDRESS                     24650020
         MVI   KEY,BDKEY           SET KEY                              24700020
*/*           I  WRITE LAST BROADCAST DIR RCD */                        24750020
         WRITE DECB2,DI,(R10),(R3),'S',KEY,(R4),MF=E WRITE              24800020
         CHECK DECB2               CHECK THE WRITE FOR COMPLETION       24850020
         SPACE 4                                                        24900020
*********************************************************************** 24950020
*        WRITE BROADCAST NOTICE MSG RECORDS TO RESERVE MAXIMUM SPACE  * 25000020
*********************************************************************** 25050020
WRITBCM  DS    0H                  WRITE NOTICE MESSAGE RECORDS OF 0'S  25060020
         L     R5,BDRBA            R5= RBA OF LAST DIRECTORY RCD        25250020
*                                  WRITTEN                              25300020
         LA    R5,NEXT(R5)         BUMP R5 TO RBA OF FIRST MSG RCD      25350020
WRITBCM2 DS    0H                  BRANCH PT ON DIRECTORY END           25360020
         ST    R5,BMRBAS           SAVE R5                              25400020
         XC    BCD(L'BCD),BCD      CLEAR AREA FOR NOTICE MSG RECORD     25410020
         LH    R6,BCMAX            INIT LOOP CONTROL REG TO NO. OF      25420020
*                                  BC NOTICE MSG RECORDS TO WRITE       25430020
         LA    R4,BMRBAS+NEXT      R4=ADDR OF RBA OF RECORD TO WRITE    25450020
         LA    R3,BCD              SET AREA ADDRES                      25500020
         MVI   KEY,BMKEY           SET KEY FOR BROADCAST NOTICE MSG     25550020
*                                  RECORD                               25600020
BCMLOOP  DS    0H                  WRITE A NULL BC NOTICE MSG RECORD    25650020
         WRITE DECB2,DI,(R10),(R3),'S',KEY,(R4),MF=E                    25700020
*                                  WRITE NOTICE RECORD                  25750020
         CHECK DECB2                                                    25800020
         L     R5,BMRBAS                                                25850020
         LA    R5,NEXT(R5)         BUMP RBA OF NEXT NOTICE MSG TO       25900020
*                                  WRITE                                25950020
         ST    R5,BMRBAS                                                26000020
         BCT   R6,BCMLOOP          LOOP UNTIL ALL NOTICES MSG           26050020
*                                  ARE WRITTEN                          26100020
         EJECT                                                          26150020
*********************************************************************** 26200020
*                                                                     * 26250020
* SET UP RECORD 1 FOR SYS1.BRODCAST DATA SET                          * 26300020
*                                                                     * 26350020
*********************************************************************** 26400020
*/*           P  CLEAR AREA FOR RECORD 1 */                             26450020
         XC    RECORD1(L'RECORD1),RECORD1  CLEAR AREA FOR RECORD 1      26500020
*/*           P  FORMAT RECORD 1 */                                     26550020
         MVC   R1BCPTR(RBAL),BDRBA1+1   PTR TO BROADCAST NOTICES DIR.   26600020
         MVC   R1USPTR(RBAL),BMRBA+1    PTR TO USER MAIL DIRECTORY.     26650020
*                                       FIRST RECORD                    26700020
         MVC   R1BCMAX(HALF),BCMAX MAXIMUM NO. BROADCAST MSGS           26750020
*                                  SET NO. RECORDS IN DATA SET          26800020
         MVC   R1RECNUM(L'R1RECNUM),RECCNT                              26850020
*                                                                     * 26900020
         MVC   R1DSN(L'DSNAME),DSNAME   DATA SET NAME                   26950020
         L     R5,RECCNT                R5 = NO. RECORDS IN D S         27000020
         S     R5,BMRBA                 R5 = NO. RECORDS IN D S MINUS   27050020
*                                       RBA OF FIRST USER DIR REC       27100020
         ST    R5,PARMLMCT              SAVE LIMIT CNT IN PARM LIST =   27150020
*                                       NO. RECORDS IN USER SECTION     27200020
         EJECT                                                          27250020
*********************************************************************** 27300020
*                                                                     * 27350020
* WRITE RECORD 1 OF SYS1.BRODCAST DATA SET                            * 27400020
*                                                                     * 27450020
*********************************************************************** 27500020
         LA    R3,RECORD1          SET AREA ADDRESS                     27550020
         LA    R4,R1RBA            SET ADDRESS OF BLOCK ID (RBA)        27600020
         MVI   KEY,R1KEY           SET KEY                              27650020
*/*           I  WRITE RECORD 1 */                                      27700020
         WRITE  DECB2,DI,(R10),(R3),'S',KEY,(R4),MF=E  WRITE RECIRD 1   27750020
         CHECK DECB2                                                    27800020
*********************************************************************** 27850020
*                                                                     * 27900020
* WRITE FIRST USER MAIL DIRECTORY RECORD OF ALL ZEROES                * 27950020
*                                                                     * 28000020
*********************************************************************** 28050020
*/*           P  SET UP TO WRITE FIRST USER MAIL DIR RCD */             28100020
         XC    BCD,BCD             SET RECORD TO BE WRITTEN TO ZERO     28150020
         LA    R3,BCD              SET AREA ADDR TO BE WRITTEN          28200020
         MVI   ENDRECFF(R3),ENDREC  SET END OF RECORD INDICATOR IN      28250020
*                                  USER MAIL DIRECTORY RECORD           28300020
         LA    R4,R1USPTR          R4 = ADDR OF RBA FOR USER DIR. REC1  28350020
         MVI   KEY,USDKEY          SET KEY FOR USER DIRECTORY           28400020
*/*           I  WRITE FIRST USER MAIL DIR RCD */                       28450020
         WRITE DECB2,DI,(R10),(R3),'S',KEY,(R4),MF=E  WRITE USER DIR    28500020
         CHECK DECB2               CHECK THE WRITE                      28550020
*/*           P  PUT DCB PTR IN PARM LIST */                            28600020
         ST    R10,PARMDCB         PUT DCB ADDRESS IN PARM LIST         28650020
*/*           P  (,ENDIO) RETURN CODE=0 SUCCESSFUL OPERATION */         28700020
         XC    RETCODE,RETCODE     SET RETCODE = 0 FOR OPERATION DONE   28750020
         B     ENDIO               END OF PROCESSING                    28800020
         EJECT                                                          28850020
*/*ENDIO:     P  RELOAD CALLER REGISTERS */                             36000020
ENDIO    DS    0H                  EXIT CODE                            36050020
         L     R13,SAVER+OFFCALLR  RELOAD R13 WITH CALLER SAVE AREA ADD 36100020
         SR    R14,R14             CLEAR REG 14                         36150020
         IC    R14,RETCODE         SAVE RETURN CODE IN REG 14           36200020
*                                  BEFORE ISSUING FREEMAIN              36250020
         LA    R0,DATAEND-DATABEG  SET R0 FOR FREEMAIN FOR WORK AREA    36300020
*        R12 HAS ADDRESS OF WORK AREA GOTTEN VIA GETMAIN                36350020
*/*           P  FREEMAIN CORE FOR WORK DSECT */                        36400020
         FREEMAIN  R,LV=(0),A=(R12)  FREE CORE FOR WORK AREA DSECT      36450020
         LM    R0,R12,OFF0(R13)    RELOAD REGS ZERO THRU 12             36500020
*/*           P  PUT RETURN CODE IN REG 15 */                           36550020
         LR    R15,R14             PUT RETURN CODE INTO REG 15          36600020
                    L     R14,OFF14(R13)      RELOAD REG 14             36650020
*/*           R  RETURN TO CALLER */                                    36700020
         BR    R14                 RETURN TO CALLER                     36750020
         SPACE 4                                                        36800020
*                                                                     * 37250020
*/*SYNWRDA:   P  SET PTR TO SYNAD RTN */                                37300020
SYNWRDA  DS    0H                  SYNAD ROUTINE FOR WRITE 'DAF' TYPE   37350020
         LA    R5,SYNAD1           R5 = SYNAD ROUTINE ADDR              37400020
         ST    R5,WORK4            PUT SYNAD ADDR INTO WORK4 FOR 'MVC'  37470020
         MVC   DCBSYNAD+ONE(RBAL),WORK4+ONE  PUT SYNAD ADDR IN DCB      37480020
         LR    R5,R0               REG0 = ADDRESS OF DECB               37500020
*/*           D  (YES,SYNAD1,NO,) IS ECB = 'SPACE NOT FOUND' */         37550020
         TM    NEXT(R5),ECBSPAC    TEST ECB FOR 'SPACE NOT FOUND'       37600020
         BNO   SYNAD1              IF OFF, BRANCH                       37650020
*/*           P  (,ENDIO) SET RETURN CODE FOR 'DATA SET FULL' */        37700020
         OI    RETCODE,DSFULL      SET RETURN FOR DATA SET FULL         37750020
         B     ENDIO               END OF PROCESSING                    37800020
         SPACE 4                                                        37850020
*/*SYNAD0:    P  SYNAD FOR OPEN REQUEST AND FIRST READ  */              37900020
SYNAD0   DS    0H                  SYNAD USED ON FIRST READ WHEN OPEN   37950020
*                                  IS REQUESTED                         38000020
         B     INITDS              GO TO DO INITIAL FORMATTING OF       38150020
*                                  SYS1.BRODCAST DATA SET               38152020
*/*BADOPEN:   P  (,ENDIO) SET RETURN CODE FOR OPEN ERROR */             38160020
BADOPEN  DS    0H                  OPEN WAS NOT SUCCESSFUL              38170020
         OI    RETCODE,OPENERR     SET RETURN CODE FOR OPEN ERROR       38180020
         B     FREEDCB             GO TO FREE CORE GOTTEN FOR DCB       38190020
*                                                                     * 38200020
*/*SYNAD1:    D  (YES,,NO,SYNA) I/O ERROR? */                           38250020
SYNAD1   DS    0H                  SYNAD ROUTINE                        38300020
         LR    R5,R0               REG0 = ADDRESS OF DECB               38350020
         TM    NEXT(R5),ECBIOERR   TEST ECB FOR IO ERROR                38400020
*/*           P  (,ENDIO) SET RETURN CODE FOR IO ERROR */               38500020
         OI    RETCODE,IOERR       SET RETURN CODE TO IO ERROR          38550020
         B     ENDIO               END OF PROCESSING                    38600020
*                                                                     * 38650020
*                                                                     * 38900020
         SPACE 2                                                        38950020
*/*BADGM:     P  (,ENDIO) SET RETURN CODE FOR 'NO CORE' */              39000020
BADGM    DS    0H                  GETMAIN FOR JFCB UNSUCCESSFUL        39050020
         OI    RETCODE,NOCORE      SET RETURN CODE FOR NOT ENOUGH CORE  39100020
         B     ENDIO               BRANCH TO EXIT                       39150020
         SPACE 2                                                        39200020
*/*BADGETM:   P  RELOAD REGISTER CONTENTS */                            39250020
BADGETM  DS    0H                  UNSUCCESSFUL GETMAIN                 39300020
         LM    R14,R12,OFF14(R13)  RELOAD REGS                          39350020
*/*           R  RETURN TO CALLER */                                    39400020
         LA    R15,NOCORE          SET RETURN CODE                      39450020
         BR    R14                 RETURN TO CALLER                     39500020
         EJECT                                                          39550020
BCDDNM   DC    CL8'SYSLBC'         DDNAME FOR BROADCAST DATA SET        39650020
ONE      EQU   1                                                        40450020
BCMNUM1  DC    H'1'                FIRST BRODCAST MSG NUMBER            40600020
BDRBA1   DC    F'1'                RBA FIRST BRODCAST DIR. RECORD       40650020
DSNAME   DC   C' SYS1.BRODCAST DATA SET '                               40700020
R1RBA    DC    X'000000'           RELATIVE BLOCK ADDR OF FIRST RECORD  40750020
NUMENT   DC    F'25'               NUMBER OF MSG ENTRIES PER BORDCAST   40800020
*                                  NOTICES DIRECTORY RECORD             40850020
         EJECT                                                          40900020
GOODOPEN EQU   X'10'               USED TO TEST DCBOFLGS FOR GOOD OPEN  40950020
ENDREC   EQU   X'7F'               END OF RECORD INDICATOR              41000020
ENDRECFF EQU  125                  OFFSET TO END OF RECORD INDICATOR    41050020
NOMSG    EQU   X'80'                                                    41100020
ZER      EQU   0                   USED FOR OFFSET OF ZERO              41150020
BCMSGNO  EQU   0                   OFFSET TO MSG NO. IN BC DIR ENTRY    41200020
STTB80   EQU   X'80'               DATA SET IS ON DEVICE                41250020
*                                  TIOT STATUS BYTE B                   41300020
NEXT     EQU   1                   USED AS INCREMENT VALUE              41350020
BD1RBA   EQU   1                   RBA OF FIRST BRODCAST DIRECTORY REC  41400020
BCMRBA   EQU   2                   OFFSET TO RBA IN BC DIR ENTRY        41450020
HALF     EQU   2                   USED TO GET TO HALF WORD BDY         41500020
MSGNOL   EQU   2                   LENGTH OF MSG NO. FIELD              41550020
RBAL     EQU   3                   RELATIVE BLOCK ADDRESS LENGTH        41600020
PTRL     EQU   4                   POINTER LENGTH - FULL WORD           41650020
OFFCALLR EQU   4                   OFFSET IN MY SAVE AREA TO ADDR OF    41700020
*                                  CALLER'S SAVE AREA                   41750020
BCDENTL  EQU   5                   LENGTH OF BRODCAST DIRECTORY ENTRY   41800020
RECPOS   EQU   7                   POSITION OF RECORD BYTE IN           41850020
*                                  2-WORD FEEDBACK AREA AFTER READ      41900020
OFFCALLD EQU   8                   OFFSET IN SAVE AREA TO CALLED ADDR   41950020
OFF0     EQU   20                  OFFSET TO REG0 IN SAVE AREA          42000020
OFF14    EQU   12                  OFFSET TO REG14 IN SAVE AREA         42050020
BSDCBL   EQU   X'54'               LENGTH OF BSAM DCB                   42100020
BDDCBL   EQU   X'68'               LENGTH OF BDAM DCB                   42150020
RECLNG   EQU   129                 RECORD LENGTH FOR SYS1.BRODCAST      42200020
         EJECT                                                          42250020
*********************************************************************** 42300020
*                                                                     * 42350020
*  THE FOLLOWING ARE EXCEPTION CODE BIT SETTINGS IN ECB+1 WHICH ARE     42400020
*  TESTED IN THE SYNAD ROUTINES.                                        42450020
*                                                                     * 42500020
*********************************************************************** 42550020
*                                                                     * 42600020
ECBRECL  EQU   X'40'               RECORD LENGTH CHECK                  42650020
ECBSPAC  EQU   X'20'               SPACE NOT FOUND TO WRITE REC         42700020
ECBIOERR EQU   X'08'               UNCORRECTABLE I/O ERROR              42750020
         SPACE 2                                                        42800020
*********************************************************************** 42850020
*                                                                     * 42900020
*        THE FOLLOWING ARE USED TO SET THE RETURN CODE FOR CALLER     * 42950020
*                                                                     * 43000020
*********************************************************************** 43050020
SDERR    EQU   X'80'               ERROR IN 'SEND' PROCESSOR            43100020
NOCORE   EQU   X'40'               NOT ENOUGH CORE FOR IO RTN           43150020
IOERR    EQU   X'08'               I/O ERROR - SYNAD ENTERED            43200020
NOTMNT   EQU   X'04'               BROADCAST VOLUME NOT MOUNTED         43250020
OPENERR  EQU   X'02'               ERROR OCCURRED DURING OPEN           43300020
DSFULL   EQU   X'01'               DATA SET FULL  ON   WRITE 'DA'       43350020
*                                                                     * 43400020
*                                                                     * 43450020
*                                                                     * 43500020
         EJECT                                                          43550020
BDKEY    EQU   X'00'               KEY FOR BROADCAST DIRECTORY REC      43600020
USDKEY   EQU   X'01'               KEY FOR USER MAIL DIRECTORY RECS     43650020
BMKEY    EQU   X'02'               KEY FOR BROADCAST NOTICE MSG REC     43700020
R1KEY    EQU   X'04'               KEY FOR RECORD1                      43750020
*                                                                     * 43800020
*        THE FOLLOWING ARE LIST FORMS OF MACROS WHICH ARE MOVED TO    * 43850020
*        GOTTEN CORE AT EXECUTION TIME.                               * 43900020
*        THE ORDER OF THE MACROS MUST, MUST NOT BE CHANGED            * 43950020
*                                                                     * 44000020
         READ  DEC01,DIF,,,,,,MF=L  READ BY BLOCK ID (RBA) LIST         44050020
         WRITE DEC02,DI,,,,,,MF=L  WRITE BY BLOCK ID (REL. BLOCK ADDR)  44100020
         WRITE DEC03,DAF,,,,,,MF=L WRITE TO ADD A RECORD W/FEEDBACK     44150020
         WRITE DEC04,SD,,,,,,MF=L  WRITE DUMMY RECORD LIST              44200020
         OPEN  0,MF=L              OPEN LIST FORM                       44250020
         CLOSE 0,MF=L              CLOSE LIST FORM                      44300020
         GETMAIN  EC,MF=L          GETMAIN LIST FORM                    44350020
LISTSEND EQU   *                   END OF LISTS FOR MACRO INSTRUCTIONS  44500020
*                                  TO BE USED TO MOVE INTO DSECT        44550020
LISTSL   EQU   LISTSEND-DEC01      LENGTH OF LISTS FOR MACRO INSTRUCT.  44600020
         EJECT                                                          46850020
*                                                                     * 46900020
*                                                                     * 46950020
*                                                                     * 47000020
*********************************************************************** 47050020
*                                                                     * 47100020
* BSAM DCB - USED TO CREATE SYS1.BRODCAST DATA SET                    * 47150020
*                                                                     * 47200020
*********************************************************************** 47250020
BSAMDCB  DCB   BLKSIZE=129,                                            X47300020
               BUFL=129,                                               X47350020
               DEVD=DA,            DIRECT ACCESS                       X47400020
               DDNAME=SYSLBC,      DDNAME FOR BROADCAST DATA SET       X47450020
               DSORG=PS,           PHYSICAL SEQUENTIEL                 X47500020
               KEYLEN=1,           KEY LENGTH = 1 BYTE                 X47550020
               MACRF=(WL),         CREATE DIRECT DATA SET              X47600020
               OPTCD=W,                                                X47650020
               RECFM=F,            FIXED                               X47700020
               SYNAD=SYNAD1                                             47750020
         EJECT                                                          47800020
*********************************************************************** 47850020
*                                                                     * 47900020
* BDAM DCB - USED TO ACCESS SYS1.BRODCAST DATA SET                    * 47950020
*   OPTCD='FR' CAUSES FEEDBACK TO BE IN RELATIVE BLOCK ADDRESS FORM.  * 48000020
*                                                                     * 48010020
*********************************************************************** 48050020
BDAMDCB  DCB   BLKSIZE=129,                                            X48100020
               BUFL=129,                                               X48150020
               DDNAME=SYSLBC,      DDNAME FOR BROADCAST DATA SET       X48200020
               DSORG=DA,           DIRECT ACCESS                       X48250020
               KEYLEN=1,           KEY LENGTH = 1 BYTE                 X48300020
               LIMCT=5,            SET AT EXECUTION TIME, NEVER ZERO   X48350020
               MACRF=(RIC,WAIC),   READ, ID, CHECK, WRITE              X48400020
               OPTCD=WEFR,         RELATIVE BLOCK ADDRESSING           X48450020
               RECFM=F,            FIXED                               X48500020
               SYNAD=SYNAD1                                             48550020
         EJECT                                                          48560020
*********************************************************************** 48570020
*                                                                     * 48580020
* DCB FOR USE BY IKJEES40, ACCOUNT / BROADCAST DATA SET INTERFACE RTN * 48590020
*     OPTCD DOES NOT SPECIFY 'F',  FEEDBACK WILL BE IN ACTUAL DEVICE  * 48592020
*     ADDRESS FORM.                                                   * 48594520
*                                                                     * 48595020
*********************************************************************** 48595520
ACCTDCB  DCB   BLKSIZE=129,                                            X48596020
               BUFL=129,                                               X48598020
               DDNAME=SYSLBC,      DDNAME FOR BROADCAST DATA SET       X48598420
               DSORG=DA,           DIRECT ACCESS                       X48598820
               KEYLEN=1,           KEY LENGTH = 1 BYTE                 X48599220
               LIMCT=5,            SET AT EXECUTION TIME, NEVER ZERO   X48599620
               MACRF=(RIC,WAIC),   READ, ID, CHECK, WRITE              X48599720
               OPTCD=WER,          RELATIVE BLOCK ADDRESSING           X48599820
               RECFM=F,            FIXED                               X48600020
               SYNAD=SYNAD1                                             48616620
         EJECT                                                          48633320
*********************************************************************** 48650020
*                                                                     * 48700020
*        DSECT FOR PARAMETER LIST FROM CALLER                         * 48750020
*                                                                     * 48800020
*********************************************************************** 48850020
*                                                                     * 48900020
SDIOPARM DSECT                     DSECT FOR PARM LIST FROM IEEVSEND    48950020
*                                                                       49000020
PARM1    DS    1C                  FLAG1 FOR OPERATIONS TO BE PERFORMED 49050020
P1OPEN   EQU   X'80'               OPEN - INITIAL FORMATTING IF FIRST   49100020
*                                       TIME DATA SET HAS BEEN USED     49150020
P1READ   EQU   X'40'               READ SPECIFIED RECORD                49200020
*                                                                     * 49250020
*                                                                     * 49300020
PARM2    DS    1C                  FLAG2 FOR OPERATIONS TO BE PERFORMED 49350020
P2WRDI   EQU   X'80'               WRITE SPECIFIED RECORD BY BLOCK ID   49400020
P2WRDAF  EQU   X'40'               WRITE SPECIFIED RECORD IN NEXT       49450020
*                                       AVAILABLE SPACE WITH FEEDBACK   49500020
P2CLOSE  EQU   X'20'               CLOSE                                49550020
P2DEL    EQU   X'10'               DELETION OF THIS RECORD.             49600020
*                                  PUT PARMFDBK INTO FIRST BYTE OF DATA 49650020
P2JFCB   EQU   X'08'               FREE CORE FOR JFCB                   49700020
P2ACCT   EQU   X'04'               CALLER IS ACCT / BROADCAST DATA SET  49710020
*                                  INTERFACE ROUTINE, IKJEES40          49720020
PARMKEY  DS    C                   KEY FOR READ/WRITE INSTRUCTION       49750020
PARMFDBK DS    C                   FEEDBACK FROM READ - POSITION        49800020
*                                  OF RECORD ON TRACK.  PUT INTO        49850020
*                                  FIRST BYTE OF DATA FOR DELETE        49900020
PARMRBA  DS    F                   ADDRESS OF RBA FOR READ/WRITE        49950020
PARMIOAD DS    F                   ADDRESS OF BUFFER FOR IO INSTRUCTION 50000020
PARMDDNM DS    CL8                 DDNAME FOR BROADCAST DATA SET        50050020
*        THE FOLLOWING FIELDS ARE NEVER CLEARED FROM PARM LIST          50100020
PARMLMCT DS    F                   LIMIT COUNT FOR EXTENDED SEARCH      50150020
PARMDCB  DS    F                   ADDRESS OF DCB                       50200020
         EJECT                                                          50300020
*********************************************************************** 50350020
*                                                                     * 50400020
DATABEG  DSECT                     DSECT FOR    WORK DATA AREA          50450020
         READ  DECB1,DIF,,,,,,MF=L  READ BY BLOCK ID (RBA) LIST         50500020
         WRITE DECB2,DI,,,,,,MF=L  WRITE BY BLOCK ID (REL. BLOCK ADDR)  50550020
         WRITE DECB3,DAF,,,,,,MF=L WRITE TO ADD A RECORD W/FEEDBACK     50600020
         WRITE DECB4,SD,,,,,,MF=L  WRITE DUMMY RECORD LIST              50650020
OPENL    OPEN  0,MF=L              OPEN LIST FORM                       50700020
CLOSEL   CLOSE 0,MF=L              CLOSE LIST FORM                      50750020
GETML    GETMAIN  EC,MF=L          GETMAIN LIST FORM                    50800020
         EJECT                                                          50950020
SAVER    DS    18F                 REGISTER SAVE AREA                   51000020
DCBADD   DS    F                   ADDR OF CORE FOR DCB FROM GETMAIN    51050020
WORK4    DS    F                   FULL WORD WORK AREA                  51300020
KEY      DS    C                   KEY FOR READ / WRITE OPERATIONS      51350020
         EJECT                                                          51700020
*********************************************************************** 51710020
*                                                                     * 51720020
*                  R    E    C    O    R    D       1                 * 51750020
*                                                                     * 51800020
*********************************************************************** 51810020
         DS    0F                  FULL WORD BDY                        51850020
RECORD1  DS    0CL129              RECORD 1 AREA                        51900020
         DS    C                                                        51950020
R1BCPTR  DS    AL3                 RBA OF FIRST BRODCAST DIRECTORY REC  52000020
         DS    C                                                        52050020
R1USPTR  DS    AL3                 RBA OF FIRST USER DIRECTORY RECORD   52100020
R1RECNUM DS    CL4                 NO. OF RECORDS IN BROADCAST DATA SET 52150020
*                                  INITIALIZED AFTER FIRST FORMATTING   52200020
R1BCMAX  DS    H                   MAXIMUM NUMBER OF BRODCAST MSGS      52250020
*                                  SET BY SYSTEM AT SYSGEN              52300020
R1DSN    DS    CL24                DATA SET NAME IN EBCDIC              52350020
R1RES    DS    CL93                UNUSED PORTION OF RECORD 1           52400020
         SPACE 4                                                        52450020
*                                                                     * 52500020
* THE FOLLOWING ARE USED FOR INITIAL FORMATTING OF DATA SET           * 52550020
*                                                                     * 52600020
DUMREC   DS    H                   KEY PLUS 1 BYTE FOR RECORD NUMBER    52650020
         DS    0F                  BROADCAST DIRECTORY RECORD           52700020
BCD      DS    CL129               AREA FOR BROADCAST DIRECTORY REC     52750020
BCMAX    DS    H                   MAXIMUM NUMBER BRODCAST MSGS ALLOWED 52800020
BCMSG1   DS    F                   ADDR FIRST BRODCAST MESSAGE RECORD   52850020
BMRBA    DS    F                   BRODCAST MESSAGE RBA                 52900020
BMRBAS   DS    F                   RBA OF BROADCAST NOTICE MSG RECORD   52950020
*                                  TO BE WRITTEN WITH KEY '02'X TO      53000020
*                                  RESERVE IT AS UNAVAILABLE TO BDAM    53050020
BDRBA    DS    F                   BRODCAST DIRECTORY RBA               53100020
BCMNUM   DS    H                   BRODCAST MESSAGE NUMBER              53150020
RETCODE  DS    C                   RETURN CODE TO BE PLACE IN REG15     53200020
RECCNT   DS    F                   NUMBER OF RECORDS IN DATA SET        53250020
DATAEND  DS    0H                  END OF WORK DATA AREA                53300020
*                                                                     * 53350020
*********************************************************************** 53400020
         EJECT                                                          53450020
CVTD     DSECT                DSECT TO MAP COMMUNICATIONS VECTOR TABLE. 53500020
         CVT                                                            53550020
         EJECT                                                          53600020
         IEEBASEA                                                       53610020
         EJECT                                                          53650020
         DCBD  DSORG=DA,DEVD=DA                                         54300020
DCBEND   EQU   *                   END OF DCB                           54350020
DCBLNG   EQU   DCBEND-IHADCB       LENGTH OF DCB TO USE IN GETMAIN      54400020
*                                                                     * 54450020
*/*IEEVSDIO:  END END OF IEEVSDIO */                                    54500020
         END                                                            54550020
