IEEVSIPL CSECT                                                          00050020
         TITLE  'IEEVSIPL - SYS1.BROADCAST TIOT INITIALIZATION MODULE'  00060020
*/*IEEVSIPL:  CHART */                                                  00100020
*/*           E  IEEVSIPL */                                            00350020
**********************************************************************  00400020
*                                                                    *  00450020
* STATUS:    CHANGE LEVEL 000                                        *  00500020
*                                                                    *  00550020
*                                                               M2531*  00560020
* TITLE:      IEEVSIPL        SYS1.BROADCAST TIOT INITIALIZATION     *  00600020
*                                                                    *  00650020
* FUNCTION:  ADD THE SYS1.BROADCAST TIOT TO THE MASTER SCHEDULER TIOT*  00700020
*                                                                    *  00750020
* ENTRY POINTS:      IEEVSIPL-LINK FROM IEEVIPL.                     *  00800020
*                                                                    *  00850020
* INPUT:     1. REG14 CONTAINS THE ADDRESS OF THE RETURN POINT IN    *  00900020
*                   IEEVIPL.                                         *  00950020
*            2. R3 CONTAINS PARMLIB UCB POINTER.                     *  01000020
*            3. R12 CONTAINS THE POINTER TO THE CVT.                 *  01050020
*                                                                    *  01100020
* OUTPUT:     SYS1.BROADCAST TIOT ADDED TO THE MASTER TIOT.          *  01150020
*                                                                    *  01200020
* EXTERNAL REFERENCES: NONE                                          *  01210020
*                                                                    *  01220020
* EXITS:  IEEVIPL-RETURNED TO NEXT SEQUENTIAL INSTRUCTION AFTER LINK *  01250020
*                                                                    *  01300020
* TABLES/WORK AREAS: CVT TCB TIOT                                    *  01310020
*                                                                    *  01320020
* ATTRIBUTES: NOT REENTRANT                                          *  01330020
*                                                                    *  01340020
* CHARACTER CODE DEPENDENCY:                                         *  01342020
*             THIS MODULE IS NOT CHARACTER CODE DEPENDENT.           *  01344020
*                                                                    *  01346020
* NOTES: SUPPORT CODE IS 20034                                       *  01350020
*        THIS MODULE DOES NOT PROVIDE A REGISTER SAVE AREA. THEREFORE*  01400020
*        IF THIS MODULE MUST CALL ANOTHER MODULE A SAVE AREA MUST BE *  01410020
*        GOTTEN                                                      *  01420020
**********************************************************************  01450020
         EJECT                                                          01500020
**********************************************************************  01550020
*              REGISTER EQUATES                                      *  01600020
**********************************************************************  01650020
R0       EQU   0                       UNUSED                           01700020
R1       EQU   1                       UNUSED                           01750020
R2       EQU   2                       BASE REGISTER FOR CVT            01800020
R3       EQU   3                       UNUSED                           01850020
R4       EQU   4                       UNUSED                           01900020
R5       EQU   5                       UNUSED                           01950020
R6       EQU   6                       UNUSED                           02000020
R7       EQU   7                       ADDR OF DD ENTRY IN MASTER TIOT  02050020
R8       EQU   8                       UNUSED                           02100020
R9       EQU   9                       UNUSED                           02150020
R10      EQU   10                      UNUSED                           02200020
R11      EQU   11                      BASE REG FOR MASTER TIOT         02250020
R12      EQU   12                      BASE REG FOR TCB                 02300020
R13      EQU   13                      UNUSED                           02350020
R14      EQU   14                      FOR LOOP CONTROL                 02400020
R15      EQU   15                      UNUSED                           02450020
N0       EQU   0                                                        02500020
N4       EQU   4                       DISPLACEMENT FOR TCB(CURRENT)    02550020
N6       EQU   6                                                        02600020
N12      EQU   12                      DISPLACEMENT INTO TCB FOR TIOT   02650020
         EJECT                                                          02700020
**********************************************************************  02750020
*              MODULE IDENTIFICATION                                 *  02800020
**********************************************************************  02850020
         B     22(R15)                 BRANCH AROUND MODULE ID    M2531 02900020
         DC    AL1(8)                  LENGTH OF MODULE NAME            02950020
         DC    CL8'IEEVSIPL'           INITIALIZATION MODULE FOR        03000020
*                                      SYS1.BROADCAST TIOT              03050020
         DC    CL8'3411970'            JULIAN DATE                      03100020
         EJECT                                                          03150020
*/*           P  SAVE REGISTER CONTENTS */                              03200020
         SAVE  (14,12)                 SAVE CONTENTS OF REGISTERS       03250020
*/*           P  SET ADDRESSIBILITY FOR CSECT */                        03300020
         BALR  R10,N0                  SET BASE FOR ADDRESSIBILITY      03350020
         USING *,R10                                                    03400020
*/*           P  GET ADDRESS OF TCB */                                  03450020
*              SET MASTER SCHEDULER TIOT FOR SEND                    *  03500020
         L     R2,CVTPTR               GET PTR TO THE CVT               03550020
         USING SENDCVT,R2              SET CVT BASE FOR ADDRESSIBILITY  03600020
         L     R12,CVTTCBP             GET THE ADDRESS OF A DOUBLE      03650020
*                                      WORD, THE FIRST CONTAINING THE   03700020
*                                      NEXT-TO-BE DISPATCHED TCB ADDR,  03750020
*                                      THE SECOND CONTAINING THE LAST   03800020
*                                      (CURRENT TCB ADDRESS.            03850020
         L     R12,N4(R0,R12)          GET THE ADDRESS OF THE CURRENT   03900020
*                                      TCB                              03950020
         USING TCB,R12                 SET TCB ADDRESSIBILITY           03960020
         L     R11,TCBTIO              GET THE ADDRESS OF THE MASTER    03970020
*                                      SCHEDULER TIOT.                  04050020
*/*           P  ACCESS MASTER'S TIOT */                                04100020
         USING TIOT,R11                SET TIOT BASE FOR ADDRESSIBILITY 04150020
         LA    R7,TIOELNGH             GET THE ADDRESS OF THE LENGTH OF 04200020
*                                      THE FIRST DD ENTRY IN MASTER     04250020
*                                      SCHEDULER TIOT.                  04300020
         SR    R14,R14                 ZERO OUT REGISTER 14. TO BE      04350020
*                                      USED TO TEST TIOT END .          04400020
**********************************************************************  04450020
*              TEST FOR THE END OF THE TIOT                          *  04500020
**********************************************************************  04550020
*/*TIOTEND:   D  (NO,,YES,INITIOT) IS THIS END OF TIOT */               04600020
TIOTEND  EQU   *                                                        04650020
         IC    R14,N0(R0,R7)           GET ACTUAL LENGTH OF THIS TIOT   04700020
*                                      ENTRY                            04750020
         LTR   R14,R14                 IS THIS THE END OF THE TIOT?     04800020
         BZ    INITIOT                 YES, BRANCH TO ADD               04850020
*                                      SYS1.BROADCAST TIOT TO THE       04900020
*                                      MASTER TIOT.                     04950020
*/*              P (,TIOTEND) POINT TO NEXT DD ENTRY */                 05000020
         AR    R7,R14                  NO, POINT TO NEXT DD ENTRY       05050020
         B     TIOTEND                 BRANCH TO CHECK FOR END OF TIOT  05100020
*/*INITIOT:   P  MOVE 'SYS1.BRODCAST' INTO TIOT EXTENSION */            05150020
INITIOT  EQU   *                                                        05200020
         MVC   N0(SENDTIOL,R7),SENDTIOT  ADD SYS1.BROADCAST TIOT TO     05250020
*                                        MASTER TIOT                    05300020
**********************************************************************  05350020
*              RETURN TO IEEVIPL                                     *  05400020
**********************************************************************  05450020
*/*              P RESTORE REGISTER CONTENTS */                         05500020
*/*              R RETURN TO IEEVIPL */                                 05550020
         RETURN (14,12)                RETURN TO IEEVIPL                05600020
**********************************************************************  05650020
*        SYS1.BROADCAST TIOT ADDITION TO MASTER SCHEDULER TIOT       *  05700020
**********************************************************************  05750020
         DS    0F                                                       05800020
SENDTIOT EQU   *                                                        05850020
         DC    XL1'14'                 LENGTH OF THIS DD ENTRY          05900020
         DC    XL1'00'                 STATUS BYTE A                    05950020
         DC    XL2'0000'               REL. LOC FOR POOL                06000020
         DC    CL8'SYSLBC'             DDNAME FOR SYS1.BROADCAST        06050020
*                                      DD ENTRY.                        06100020
         DC    F'0'                    DISK ADDR OF JFCB AND STATUS C   06150020
         DC    X'80000000'             STATUS B AND UCB POINTER         06200020
         DC    F'0'                    FULL WORD ZERO INDICATE END      06250020
SENTIOTD EQU   *                       TIOT END                         06300020
SENDTIOL EQU   SENTIOTD-SENDTIOT       LENGTH OF SYS1.BROADCAST TIOT    06350020
SENDCVT  DSECT                                                          06400020
         CVT                                                            06450020
TIOT     DSECT                                                          06500020
         IEFTIOT1                                                       06550020
         IKJTCB                                                         06570020
*/*IEEVSIPL:  END END OF IEEVSIPL */                                    06600020
         END                                                            06650020
