IEEVSND9 CSECT                                                          00050020
         TITLE  'IEEVSND9 - OPERATOR SEND COMMAND OPEN ROUTINE'         00100020
*/*IEEVSND9:  CHART */                                                  00150020
*/* HEADER                                                              00200020
*/*OPERATOR SEND OPEN MODULE                                     */     00300020
*/*           E  IEEVSND9 */                                            00350020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 00400020
*                                                                     * 00450020
*    STATUS: CHANGE LEVEL 000                                         * 00500020
*                                                                     * 00550020
*    FUNCTION:                                                        * 00750020
*            THIS ROUTINE PERFORMS     I/O OPERATIONS FOR THE SEND    * 00800020
*            COMMAND.  FUNCTIONS PROVIDED ARE:                        * 00850020
*                   OPEN                READ                          * 00950020
*                                                                     * 01100020
*            NECESSARY INFORMATION FOR THE OPERATIONS DESIRED IS      * 01150020
*            SPECIFIED IN THE PARAMETER LIST POINTED TO BY REGISTER1. * 01200020
*            THE ORDER OF OPERATION IS:                               * 01210020
*            1. 'LOCATE' AND ALLOCATE THE BROADCAST D.S.              * 01220020
*            2. READ THE FIRST RECORD                                 * 01230020
*            3. CHECK FIRST RECORD TO SEE IF D.S. IS FORMATTED        * 01240020
*            4. IF NOT FORMATTED (1ST SEND AFTER SYSGEN):             * 01242020
*               A. CLOSE D.S. FOR BDAM                                * 01244020
*               B. OPEN D.S. FOR BSAM                                 * 01246020
*               C. INITIALIZE D.S. USING BSAM WRITE'S                 * 01248020
*               D. CLOSE D.S. FOR BSAM                                * 01248420
*               E. REOPEN D.S. FOR BDAM                               * 01248820
*               F. DO INITIAL FORMATTING OF NOTICE DIRECTORY          * 01249220
*               G. RESERVE SPACE FOR NOTICE MSG RECORDS               * 01249620
*               H. WRITE FIRST USER MAIL DIRECTORY RCD OF 0           * 01249720
*               I. WRITE RECORD 1 TO PT TO USER AND NOTICE DIRECTRY   * 01249820
*               J. CLOSE D.S. TO FREE CORE GOTTEN BY BDAM FORMAT      * 01249920
*               K. OPEN D.S.                                          * 01299920
*            5. XCTL TO NEXT MODULE                                   * 01309920
*                                                                     * 01349920
*    ENTRY POINTS: IEEVSND9                                           * 02070020
*                                                                    *  02150020
*                                                                    *  02200020
*    INPUT:  REGISTER 1 - ADDRESS OF COMMON DATA AREA                *  02250020
*            REGISTER 14- RETURN ADDRESS                             *  02300020
*                                                                    *  02400020
*                                                                    *  02450020
*    OUTPUT:                                                         *  02500020
*            REGISTER 1 - ADDRESS OF COMMON DATA AREA                *  02550020
*            SDIORC IN COMMON DATA AREA IS SET WITH RETURN CODE      *  02600020
*                                                                    *  02650020
*    EXTERNAL REFERENCES:                                            *  02700020
*             GETMAIN, FREEMAIN,                                     *  02750020
*            READ, WRITE, CHECK,OPEN,CLOSE,                          *  02800020
*            LOCATE                                                  *  02850020
*            EXTRACT - TO GET TIOT ADDRESS FROM TCB                  *  02900020
*                                                                    *  02950020
*                                                                    *  03000020
*    EXITS, NORMAL: XCTL TO ENTRY POINT NAME IN COMMON DATA AREA -   *  03050020
*            IEEVSND2 OR IEEVSND3 OR IEEVSND8.                       *  03100020
*                                                                    *  03110020
*    EXITS, ERROR:                                                   *  03150020
*            ABEND WILL POST THE MOTHER, IEEVGPSD.                   *  03170020
*                                                                    *  03200020
*    TABLES/WORK AREAS:                                              *  03250020
*            CVT - TO GET PTR TO UCB LOOKUP TABLE                    *  03300020
*            DCB - DATA CONTROL BLOCK - FOR BROADCAST DATA SET       *  03350020
*            DECB - DATA EVENT CONTROL BLOCK                         *  03400020
*            ECB - EVENT CONTROL BLOCK - TO TEST EXCEPTION CODE      *  03450020
*                    BIT SETTINGS AFTER I/O OPERATION                *  03500020
*            JFCB - JOB FILE CONTROL BLOCK                           *  03550020
*            TCB - TASK CONTROL BLOCK - TO GET ADDRESS OF TIOT       *  03600020
*            TIOT - ENTRY FOR BROADCAST DATA SET IN MASTER'S TIOT    *  03650020
*            UCB - UNIT CONTROL BLOCK - ADDR IS PUT INTO TIOT ENTRY  *  03700020
*                                                                    *  03750020
*                                                                    *  03800020
*    ATTRIBUTES: REUSABLE                                             * 03850020
*                                                                     * 03900020
*    CHARACTER DEPENDENCY CODE: NONE.                                 * 03902020
*                                                                     * 03910020
*    NOTES:                                                           * 03950020
*         1. STANDARD LINKAGE CONVENTIONS USED.                       * 04000020
*            HOWEVER, THIS ROUTINE DOES NOT SAVE OR STORE REGISTERS.  * 04010020
*         2. THIS ROUTINE IS XCTL'ED TO BY OPERATOR SEND -  IEEVSEND  * 04050020
*         3. SUPPORT CODE FOR THIS MODULE IS 20034, TSO SCHEDULER     * 04150020
*                                                                     * 04250020
*                                                                     * 04260020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 04300020
         EJECT                                                          04350020
*********************************************************************** 04400020
*                                                                     * 04450020
*                   R E G I S T E R    E Q U A T E S                  * 04500020
*                                                                     * 04550020
*********************************************************************** 04600020
*                                                                     * 04650020
R0       EQU   0                   REGISTER USED IN GETMAIN, FREEMAIN   04700020
R1       EQU   1                   WORK REGISTER                        04750020
R2       EQU   2                   WORK REGISTER                        04800020
R3       EQU   3                   ADDRESS OF 129 BYTE READ/WRITE AREA  04850020
R4       EQU   4                   ADDRESS OF RBA (RELATIVE BLOCK       04900020
*                                     ADDRESS) OF DESIRED BLOCK         04950020
R5       EQU   5                   WORK REGISTER                        05000020
R6       EQU   6                   BASE FOR COMMON DATA AREA            05050020
R7       EQU   7                   LOOP CONTROL TO INITIALIZE           05100020
*                                     BROADCAST DATA SET                05110020
R8       EQU   8                   WORK REGISTER                        05150020
R9       EQU   9                   BASE REG FOR VARIOUS CONTROL BLOCKS  05200020
R10      EQU   10                  BASE REGISTER FOR DSECT FOR DCB      05250020
R11      EQU   11                  BASE REGISTER FOR CSECT              05300020
R12      EQU   12                  BASE REGISTER FOR DATA AREA DSECT    05350020
R13      EQU   13                  ADDRESS OF THIS ROUTINE'S SAVE AREA  05400020
R14      EQU   14                  ADDRESS OF CALLING ROUTINE RETURN    05450020
R15      EQU   15                  RETURN CODE                        * 05500020
         EJECT                                                          05550020
         LR    R6,R1               SAVE ADDRESS OF COMMON IN REG6       05800020
         BALR  R11,0                                                    05850020
*/*           P  ESTABLISH ADDRESSIBILITY FOR CSECT */                  05900020
         USING *,R11               SET ADDRESSABILITY FOR CSECT         05950020
         B     *+20                BRANCH AROUND MODULE ID              06000020
         DC    AL1(8)              LENGTH OF MOD NAME                   06050020
         DC    CL8'IEEVSND9'       MODULE IDENTIFICATION                06100020
         DC    CL3'111'            JULIAN DATE OF LAST UPDATE           06150020
         DC    CL4'1971'           YEAR                                 06200020
         LA    R5,DATAEND-DATABEG  R5 = LENGTH OF DATA AREA FOR GETMAIN 06250020
         SLL   R5,LENG8            SHIFT GETMAIN LENGTH                 06300020
         LA    R4,SP0              REG4 = SUBPOOL INDICATOR = 0         06350020
         SRDL  R4,LENG8            GET SUBPOOL IN HI ORDER BYTE         06400020
*                                  OF REG5.   LENGTH IN LO ORDER BYTES  06450020
         LR    R0,R5               SET R0 FOR GETMAIN                   06500020
         GETMAIN  R,LV=(0)         GET CORE FOR WORK AREA               06550020
         LR    R12,R1              MOVE ADDR OF GOTTEN CORE TO REG 12   06600020
         USING DATABEG,R12         SET ADDRESSABILITY FOR DATA AREA     06650020
         ST    R13,SAVER+OFFCALLR  SAVE ADDRESS OF CALLER'S SAVE AREA   06700020
         LR    R5,R13              GET ADDRESS CALLERS SAVE AREA        06750020
         LA    R13,SAVER           R13 = ADDR THIS RTN'S SAVE AREA      06800020
         ST    R13,OFFCALLD(R5)    SAVE ADDRESS OF THIS RTN'S SAVE AREA 06850020
         MVC   DECB1(LISTSL),DEC01 MOVE LISTS FOR MACRO INSTRUCTIONS    06900020
*                                  INTO GOTTEN CORE (DSECT)             06950020
         USING IHADCB,R10          ESTABLISH ADDRESSABILITY FOR IHADCB  07000020
         USING COMMON,R6           SET ADDRESSABILITY FOR COMMON        07050020
         LA    R5,DCBLNG           R5 = LENGTH OF DCB FOR GETMAIN       07250020
*/*           P  GET CORE FOR DCB  */                                   07300020
         LA    R2,SP0              SET SUBPOOL INDICATOR FOR 0          07350020
*                                  GET CORE FOR DCB                     07400020
         GETMAIN  EC,LV=(R5),A=DCBADD,SP=(R2),MF=(E,GETML)              07450020
*/*           D  (YES,,NO,BADGM) IS GETMAIN SUCCESSFUL */               07500020
         LTR  R15,R15              TEST GETMAIN RETURN CODE IN REG 15   07550020
         BNZ  BADGM                IF NOT SUCCESSFUL (0), RETURN TO     07600020
*                                  CALLER WITH ERROR INDICATION         07650020
         L    R10,DCBADD           MOVE ADDR OF GOTTEN CORE TO REG 10   07700020
*        R10 HAS ADDRESS OF CORE GOTTEN FOR DCB VIA GETMAIN             07750020
*/*           P  MOVE DCB INTO GOTTEN CORE */                           07800020
         MVC   ZER(BDDCBL,R10),BDAMDCB  MOVE BDAM DCB TO GOTTEN CORE    07850020
*                                  DATA SET MUST BE 'LOCATE'D AND       08100020
*                                  ALLOCATED BEFORE OPENING             08150020
         EJECT                                                          08450020
*/*FINDDS:    P  ISSUE 'LOCATE' TO READ CATLG & GET VOL SER */          08452020
FINDDS   DS    0H                  FIND THE BROADCAST DATA SET          08454020
         SPACE 2                                                        08456020
*********************************************************************** 08458020
*                                                                     * 08458420
* ISSUE LOCATE INSTRUCTION TO READ CATALOG AND GET VOLUME SERIAL      * 08458820
* NUMBER OF SYS1.BRODCAST DATA SET                                    * 08459220
*                                                                     * 08459620
*********************************************************************** 08459720
         LOCATE INDAB                                                   08459820
         C     R15,MOUNT           CHECK RET CODE FOR'VOLUME NOT MOUNT' 08459920
*/*           D  (NO,,YES,NOTUP) IS VOLUME MOUNTED */                   08473220
         BE    NOTUP               IF NOT MOUNTED, GIVE WARNING         08483220
*/*           P  GET PTR TO UCB LOOK UP TABLE FROM CVT */               08485220
         L     R9,CVTPTR           R9 = ADDRESS OF CVT FROM LOC X'10'   08485620
         USING CVTD,R9                                                  08486020
         MVC   UCBLKADD(PTRL),CVTILK2  PTR TO UCB LOOKUP TABLE          08486420
         EJECT                                                          08486520
*/*           P  GET PTR TO TIOT FROM TCB */                            08486620
         EXTRACT  TIOTADD,FIELDS=TIOT,MF=(E,EXTRACTL)                   08491020
*                                  USE EXTRACT TO GET ADDRESS OF TIOT   08493020
*                                  FROM TCB                             08495020
         L     R9,TIOTADD          R9 = ADDRESS OF TIOT FOR MAST SCHED  08495420
         LA    R9,DDENTOFF(R9)     R9 = ADDR OF FIRST DD ENTRY IN TIOT  08495520
         USING TIOENTRY,R9         SET ADDRESSABILITY FOR TIOT DSECT    08509120
         SPACE 2                                                        08519120
*                                                                     * 08521120
*        THE FOLLOWING CODE SEARCHES THE ENTIRE TIOT FOR THE DD       * 08521520
*        ENTRY FOR THE BROADCAST DATA SET.                            * 08521920
*                                                                     * 08522320
TIOTLOOP DS    0H                  SEARCH DD ENTRIES OF TIOT            08522720
*/*TIOTLOOP:  P  SEARCH TIOT FOR DD ENTRY FOR BROADCAST D S */          08527220
*/*           D  (YES,TIOTLEND,NO,) IS THIS TIOT END */                 08529220
         CLC   0(L'ENDTIOT,R9),ENDTIOT    IS IT END OF TIOT, FULL WORD  08531220
*                                           OF ZERO                     08531620
         BE    TIOTLEND            YES, BRANCH                          08531720
*/*           D  (YES,TIOTFND,NO,) IS THIS DD FOR BROADCAST D S */      08531820
         CLC   TIOEDDNM(L'BCDDNM),BCDDNM  IS DD NAME EQUAL TO THAT FOR  08536320
*                                         BROADCAST DATA SET            08536420
         BE    TIOTFND             YES, DD ENTRY FOUND, BRANCH          08538420
         SPACE 2                                                        08540420
*/*TIOTL2:    P  (,TIOTLOOP) BUMP PTR TO NEXT DD ENTRY */               08540820
TIOTL2   DS    0H                  INCREMENT R9 PTR AND LOOP AGAIN      08540920
         SR    R5,R5               CLEAR R5                             08552720
         IC    R5,TIOELNGH         R5 = LENGTH OF THIS DD ENTRY         08562720
         AR    R9,R5               BUMP R9 TO NEXT DD ENTRY             08563120
         B     TIOTLOOP            BRANCH TO CONTINUE SEARCH OF TIOT    08563520
         SPACE 4                                                        08563920
*/*TIOTLEND:  P  (,BADOPEN) END OF TIOT: NO ENTRY FOR BROADCAST D S */  08564320
TIOTLEND DS    0H                  END OF TIOT REACHED WITHOUT FINDING  08564420
*                                  DD ENTRY FOR BROADCAST DATA SET      08564520
         B     BADOPEN             HANDLE AS IF AN OPEN ERROR.          08568420
*                                  MASTER SCHEDULER TIOT IS BAD BECAUSE 08570420
*                                  NO ENTRY IS FOUND FOR BROADCAST D S  08572420
         SPACE 2                                                        08576320
*/*TIOTFND:   P  FOUND DD ENTRY FOR BROADCAST D S */                    08576420
TIOTFND  DS    0H                  DD ENTRY FOR BC DATA SET FOUND       08578420
         ST    R9,BCDDENTP         SAVE ADDR OF DD ENTRY                08578820
         EJECT                                                          08579220
*/*TIOTF1:    P  SEARCH UCB TABLE FOR VOL SER GOTTEN WITH LOCATE */     08579620
TIOTF1   DS    0H                  CONTINUE PROCESSING                  08580020
*********************************************************************** 08580120
*                                                                     * 08580220
* THE UCB TABLE IS SEARCHED FOR VOLUME SERIAL NO. GOTTEN THRU THE       08580320
* LOCATE INSTRUCTION.  WHEN A MATCH IS FOUND, THE DEVICE TYPE IS        08584220
* CHECKED FOR DIRECT ACCESS. THIS UCB ADDRESS IS THEN PLACED IN THE     08584320
* TIOT ENTRY THAT WAS COPIED FROM THE MASTER SCHEDULER.                 08586320
*                                                                     * 08586720
*********************************************************************** 08587120
         SR    R8,R8               SET R8 = 0 FOR INDEX TO LOOKUP TABLE 08587520
         USING UCBD,R9             SET ADDRESSABILITY FOR UCB DSECT     08587920
         L     R9,UCBLKADD         R9 = ADDR UCB LOOKUP TABLE           08588020
         LR    R8,R9               R8 = ADDR UCB LOOKUP TABLE           08588120
*/*UCBLOOP:   D  (NO,,YES,UCBL2) IS UCB ENTRY 0 */                      08588220
UCBLOOP  DS    0H                                                       08598520
         LH    R9,0(R8)            R9 = ADDRESS OF A UCB                08598920
         LTR   R9,R9               CHECK FOR ZERO UCB ENTRY             08599320
         BZ    UCBL2               ZERO ENTRY, SKIP THE COMPARE         08599720
*/*           D  (NO,,YES,NOTUP) END OF UCB TABLE? */                   08599820
         CH    R9,ENDUCBN          IS IT END OF UCB LOOKUP TABLE        08599920
         BE    NOTUP               YES, NO UCB FOR SYS1.BRODCAST,VOLUME 08600020
*                                      IS NOT MOUNTED, GIVE WARNING     08602020
*/*           D  (NO,,YES,CKDEVT) VOL SER= LOCATE BROADCAST DS VOL SER  08604020
*/**/                                                                   08606020
         CLC   VOLSER(VOLSERL),SRTEVOLI   IS VOLUME SERIAL NUMBER FROM  08608020
*                                  UCB EQUAL TO THAT OF SYS1.BRODCAST   08608420
*                                  GOTTEN VIA 'LOCATE'                  08608520
         BE    CKDEVT              YES, BRANCH TO CHECK DEVICE TYPE     08608620
*/*UCBL2:     P  (,UCBLOOP) BUMP PTR TO NEXT UCB ENTRY */               08608720
UCBL2    DS    0H                                                       08612120
         LA    R8,2(R8)            NO, BUMP  R8  , INDEX TO TABLE       08614120
         B     UCBLOOP                                                  08614520
CKDEVT   DS    0H                                                       08614920
*/*CKDEVT:    D  (YES,,NO,UCBL2) IS TYPE= DIRECT ACCESS */              08615320
         CLI   UCBTYP+2,TYPEDA     CHECK UCBTYP FIELD FOR DIRECT ACCESS 08615420
         BNE   UCBL2               IF NOT EQUAL, CONTINUE SEARCH OF     08615520
*                                  UCBS THROUGH THE LOOKUP TABLE        08615620
         SPACE 2                                                        08619020
*                                                                     * 08619120
*                                                                       08621120
**       SET ADDRESSABILITY FOR TIOT DSECT                              08621520
*        PLACE ADDRESS OF UCB INTO TIOT ENTRY.                          08621920
*                                                                     * 08622320
*/*           P  PUT BROADCAST D S DD ENTRY INTO TIOT */                08622420
         L     R5,BCDDENTP         R5 = ADDR DD ENTRY IN TIOT FOR       08622520
*                                  BROADCAST DATA SET                   08625920
         USING TIOENTRY,R5         SET ADDRESSABILITY FOR TIOT DSECT    08626020
         STH   R9,TIOEFSRT+1       PUT UCB ADDR INTO TIOT               08628020
         XC    TIOEFSRT(ONE),TIOEFSRT   CLEAR FIRST BYTE OF UCB ADDRESS 08628420
         MVI   TIOESTTB,STTB80     SET STATUS BYTE B FOR 'ON DEVICE'    08628820
         SPACE 2                                                        08629220
*                                                                     * 08629320
*/*           P  GETMAIN FOR JFCB */                                    08629420
* GET CORE FOR JFCB                                                     08632820
*                                                                       08632920
         LA    R9,JFCBADD          R9 = ADDR OF AREA FOR GETMAIN TO PUT 08634920
*                                  THE ADDRESS OF CORE GOTTEN FOR JFCB  08635320
         LA    R2,SP0              SET SUBPOOL INDICATOR FOR 0          08635720
*                                  GET CORE FOR JFCB                    08636120
         GETMAIN  EC,LV=JFCBLNG,A=(R9),SP=(R2),MF=(E,GETML)             08636220
*/*           D  (YES,,NO,BADGM) IS GETMAIN SUCCESSFUL */               08636320
         LTR   R15,R15             TEST GETMAIN RETURN CODE             08637420
         BNZ   BADGM               IF NOT SUCCESSFUL, BRANCH            08639420
         L     R9,JFCBADD          R9 = ADDR OF CORE GOTTEN FOR JFCB    08639520
         ST    R9,PARMJFCB         SAVE JFCB ADDR IN PARM LIST FOR      08639620
*                                  FREEMAIN AFTER CLOSE OF DATA SET     08642520
         USING JFCBD,R9            SET ADDRESSABILITY FOR JFCB DSECT    08642920
*/*           P  MOVE BROADCAST DS JFCB INTO CORE */                    08643020
         MVC   INFMJFCB(JFCBLNG),JFCBDUM   MOVE THE JFCB FOR BROADCAST  08643120
*                                  DATA SET INTO GOTTEN CORE            08643220
*/*           P  MOVE VOL SER INTO JFCB */                              08645220
         MVC   JFCBVOLS(VOLSERL),VOLSER  PUT VOLUME SERIAL NO. IN JFCB  08645320
         ST    R9,EXITLST          SET JFCB ADDR IN EXIT LIST           08645420
         MVC   EXIT1,EXITJFCB      SET EXIT LIST CODE FOR JFCB          08645820
         LA    R5,EXITLST          GET ADDRESS OF EXIT LIST             08646220
         ST    R5,WORK4                                                 08646320
         MVC   DCBDDNAM(L'DCBDDNAM),BCDDNM  MOVE DDNAME INTO DCB        08646420
         MVC   PARMDDNM(L'PARMDDNM),BCDDNM  SET DDNAME IN PARM LIST     08646520
         MVC   DCBEXLST+1(RBAL),WORK4+NEXT  SET DCB EXIT LIST ADDRESS   08647320
*                                         BEFORE OPEN                   08647720
*/*           I  (,OPEN2) OPEN TYPE=J BROADCAST DS */                   08648120
         OPEN   ((R10),OUTPUT),TYPE=J,MF=(E,OPENL)  OPEN FOR UPDATE     08648220
         EJECT                                                          08648320
*/*OPEN2:     D  (YES,,NO,BADOPEN) IS OPEN SUCCESSFUL */                08651320
         TM    DCBOFLGS,GOODOPEN   TEST OPEN FLAGS OF DCB               08654220
         BZ    BADOPEN             IF NOT SUCCESSFUL OPEN, BRANCH       08657120
         OI    FLAG1,FOPEN         INDICATE BROADCAST DATA SET IS OPEN  08660020
         LA    R5,SYNAD0           CHANGE SYNAD ADDRESS FOR FIRST READ  08700020
         ST    R5,WORK4            PUT SYNAD ADDR INTO WORK4 FOR 'MVC'  08750020
         MVC   DCBSYNAD+ONE(RBAL),WORK4+ONE  PUT SYNAD ADDR IN DCB      08760020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   08770020
*                                                                       08800020
*        READ FIRST RECORD OF SYS1.BRODCAST DATA SET TO DETERMINE IF    08850020
*        DATA SET HAS BEEN INITIALIZED.  THIS IS DONE BY CHECKING       08850420
*        FOR THE EBCDIC CHARACTERS ' SYS1.BRODCAST DATA SET ' AT        08910020
*        OFFSET 15 IN THE FIRST RECORD.                                 08920020
*        THE BROADCAST DATA SET WILL BE FORMATTED ONCE AFTER EACH       08930020
*        SYSGEN.                                                        08940020
*                                                                       08950020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *   08960020
*/*           I  READ RECORD 1 OF BROADCAST DATA SET */                 09000020
         READ  DECB1,DI,(R10),RECORD1,'S',0,R1RBA,MF=E  READ RECORD 1   09050020
         CHECK DECB1                                                    09100020
         LA    R5,SYNAD1           RESTORE SYNAD ADDRESS TO DCB         09150020
         ST    R5,WORK4            PUT SYNAD ADDR INTO WORK4 FOR 'MVC'  09170020
         MVC   DCBSYNAD+ONE(RBAL),WORK4+ONE  PUT SYNAD ADDR IN DCB      09180020
*/*           D  (YES,,NO,INITDS) IS BROADCAST DS INITIALI -ZED */      09250020
         CLC   R1DSN(L'DSNAME),DSNAME  DATE SET NAME IN RECORD 1 THUS   09300020
*                                       INDICATING INITIALIZATION DONE  09350020
         BNE   INITDS              NO, BRANCH TO DO INITIAL FORMATTING  09400020
*/*           P  SAVE DCB PTR IN PARM LIST */                           09450020
         ST    R10,PARMDCB         SAVE DCB ADDR IN PARM LIST           09500020
         MVC   PARMLMCT(PTRL),R1RECNUM  SAVE LIMIT CNT IN PARM LIST     09550020
*/*           P  (,ENDIO) RETURN CODE=0 SUCCESSFUL PROCESSING */        09600020
         XC    RETCODE,RETCODE     SET RETCODE = 0 FOR OPERATION DONE   09650020
         B     ENDIO               END OF PROCESSING                    09700020
         EJECT                                                          14950020
INITDS   DS    0H                                                       15020020
*/*INITDS:    I  CLOSE DCB FOR BDAM */                                  15030020
*********************************************************************** 15032520
*                                                                     * 15035120
*   ENQUEUE ON RECORD1 FOR THE BROADCAST DIRECTORY FOR EXCLUSIVE      * 15037220
*********************************************************************** 15039220
         ENQ   (QNAME,R1RBA,E,3,SYSTEM),RET=HAVE,MF=(E,ENQEL)           15039320
         CLOSE  ((R10)),MF=(E,CLOSEL)  CLOSE DCB FOR BDAM               15041420
*        R10 HAS ADDRESS OF CORE GOTTEN FOR DCB VIA GETMAIN             15043520
*/*           P  MOVE BSAM DCB TO CORE */                               15045620
         MVC   ZER(BSDCBL,R10),BSAMDCB  MOVE BSAM DCB TO GOTTEN CORE    15047720
         MVC   DCBDDNAM(L'DCBDDNAM),PARMDDNM  MOVE DDNAME INTO DCB      15049820
*/*           I  ISSUE OPEN 'J' */                                      15051920
         LA    R5,EXITLST          R5 = ADDR OF EXIT LIST               15054020
         ST    R5,WORK4                                                 15056020
         MVC   DCBEXLST+NEXT(RBAL),WORK4+NEXT    SET EXIT LIST ADDR     15056120
*                                                    IN DCB             15058120
         OPEN  ((10),OUTPUT),TYPE=J,MF=(E,OPENL)  OPEN TO CREATE BDAM   15058220
*/*           D  (YES,CREATE,NO,BADOPEN) WAS OPEN SUCCESSFUL? */        15064420
         TM    DCBOFLGS,GOODOPEN   WAS OPEN SUCCESSFUL                  15076620
         BZ    BADOPEN             NO, BRANCH                           15078620
         EJECT                                                          15093220
*********************************************************************** 15093620
*                                                                     * 15094020
* THE FOLLOWING CODE CREATES A BDAM DATA SET BY ISSUING BSAM WRITE    * 15094120
* INSTRUCTIONS TO WRITE DUMMY RECORDS WITH KEY = X'FF'                * 15094220
* AND FIRST BYTE OF DATA = POSITION OF RECORD ON TRACK                * 15094320
* THE BROADCAST DATA SET MUST HAVE ONLY 1 EXTENT.                     * 15108220
* RECORDS ARE WRITTEN UNTIL THE RETURN CODE INDICATES THAT THE NEXT   * 15118220
* BLOCK REQUIRES SECONDARY SPACE ALLOCATION.                          * 15120220
*                                                                     * 15120620
*********************************************************************** 15121020
*/*CREATE:    P  CREATE A BDAM DATA SET USING BSAM WRITE */             15121120
CREATE   DS    0H                  CREATE BDAM USING BSAM               15121420
         SR    R8,R8               R8 = 0 = NO. RECORDS WRITTEN         15121820
         XC    BCD,BCD             SET RECORD TO BE WRITTEN TO ZERO     15121920
*                                                                     * 15122020
WRITESD  DS    0H                                                       15122120
*/*WRITESD:   I  WRITE DUMMY RECORD */                                  15126720
         WRITE DECB4,SD,(R10),DUMREC,'S',,,MF=E  WRITE DUMMY RECORD     15128720
*/*           P  INCREMENT NUMBER OF RECORDS WRITTEN BY 1 */            15130720
         LA    R8,NEXT(R8)         BUMP COUNT OF RECORDS WRITTEN        15131120
         LR    R5,R15              R15 = RETURN CODE AFTER WRITE        15131220
         CHECK DECB4               CHECK THE WRITE FOR COMPLETION       15131320
*/*           D  (0,WRITESD,4,WRITESD,8,) CHECK RETURN CODE */          15131420
         B     BTABLE(R5)          TEST RETURN CODE FROM WRITE          15136020
BTABLE   EQU   *                   BRANCH TABLE FOR RETURN CODE FROM    15136120
*                                  WRITE MACRO                          15138120
         B     WRITESD             RET CODE = 00, WRITE ANOTHER BLOCK   15140120
         B     WRITESD             RET CODE = 04, WRITE ANOTHER BLOCK   15140520
         DS    0H                  RET CODE = 08, STOP WRITING. THIS    15140620
*                                  BLOCK WILL BE WRITTEN. NEXT BLOCK    15140720
*                                  REQUIRES SECONDARY SPACE ALLOCATION  15152520
*/*           P  PRIMARY SPACE ALLOCATION ALL USED */                   15162520
         ST    R8,RECCNT           SET NO. RECORDS IN DATA SET          15164520
         EJECT                                                          15168420
*                                                                     * 15170420
* CLOSE DATA AND REPOSITION TO CONTINUE FORMATTING                    * 15172420
*                                                                     * 15176320
*/*           I  CLOSE BROADCAST D S */                                 15176420
         CLOSE ((R10),REREAD),MF=(E,CLOSEL)  CLOSE FOR REREAD           15178420
*/*           P  MOVE BDAM DCB INTO CORE */                             15178820
         MVC   ZER(BDDCBL,R10),BDAMDCB  MOVE BDAM DCB TO GOTTEN CORE    15179220
         MVC   DCBLIMCT(RBAL),RECCNT+NEXT                               15179620
*                                         SET LIMCT FIELD IN DCB TO     15180020
*                                         NO. RECORDS IN DATA SET       15180120
         MVC   DCBDDNAM(L'DCBDDNAM),PARMDDNM  MOVE DDNAME INTO DCB      15180220
*/*           I   OPEN 'J' BROADCAST D S */                             15182720
         LA    R5,EXITLST          R5 = ADDR EXIT LIST FOR OPEN'J'      15183120
         ST    R5,WORK4                                                 15183520
         MVC   DCBEXLST+NEXT(RBAL),WORK4+NEXT  EXIT LIST ADDR IN DCB    15183920
         OPEN  ((10),OUTPUT),TYPE=J,MF=(E,OPENL)  OPEN FOR UPDATE       15184020
*/*           D  (YES,,NO,BADOPEN) WAS OPEN SUCCESSFUL */               15187920
         TM    DCBOFLGS,GOODOPEN   WAS OPEN SUCCESSFUL                  15188020
         BZ    BADOPEN             NO, BRANCH                           15188120
         EJECT                                                          15202020
*********************************************************************** 15204020
*                                                                     * 15206020
*  FIND MAXIMUM NO. OF BRODCAST 'NOTICES' MESSAGES FROM MASTER SCHED  * 15208020
*  BASE A                                                             * 15208420
*                                                                     * 15208520
*********************************************************************** 15208620
FINDMAX  DS    0H                  FIND MAX NO. NOTICE MSGS             15208720
*/*FINDMAX:   P  FIND THE MAX NO. OF NOTICE MSGS FROM MS BASE A */      15212120
         L     R9,CVTPTR           R9 = ADDRESS CVT IN MAIN STORAGE     15214120
         USING CVTD,R9             SET ADDRESSABILITY FOR CVT DSECT     15214520
         L     R9,CVTMSER          R9 = ADDRESS MASTER SCHED BASEA      15214920
         USING BASE,R9             SET ADDRESSABILITY FOR M.S. BASEA    15215320
         MVC   BCMAX(HALF),BABCMAX BCMAX = MAXIMUM NO. BROADCAST MSGS   15215420
*                                  SPEC'D AT SYSGEN & KEPT IN           15215520
*                                  MASTER SCHEDULER BASE A              15215620
         LH    R5,BCMAX                                                 15219020
*/*           D  (YES,,NO,BCMAXSET) IS MAX NO. OF BC MSGS =0? */        15220120
         LTR   R5,R5               TEST BCMAX FOR ZERO, INVALID VALUE   15224520
         BNZ   BCMAXSET            IF NOT ZERO, BRANCH AROUND SETTING   15225620
*                                  IF ZERO, SET BCMAX TO 1              15226720
         LA    R5,NEXT             R5 = 1                               15227820
         STH   R5,BCMAX            SET BCMAX = 1 TO REPLACE ZERO        15228920
BCMAXSET DS    0H                  BCMAX CONTAINS NONZERO VALUE         15230020
*                                                                     * 15231120
* THE FOLLOWING CALCULATES THE RBA OF THE FIRST BRODCAST NOTICES      * 15232220
* MESSAGE RECORD.  THIS VALUE IS THEN USED IN FORMATTING THE BRODCAST * 15233320
* DIRECTORY RECORDS.  A UNIQUE MSG RBA IS PUT INTO THE DIRECTORY FOR  * 15234420
* EACH POSSIBLE BRODCAST MSG NUMBER.                                  * 15235520
* THE FORMULA USED IS:                                                * 15236620
*                                                                     * 15237720
*   RBA OF FIRST     RBA OF FIRST     NUMBER OF                       * 15238820
*   BRODCAST MSG  =  BRODCAST DIR  +  BRODCAST                        * 15239920
*    RECORD           RECORD          DIR RECORDS                     * 15241020
*                                                                     * 15242120
*                                                                     * 15243220
*/*           P  CALCULATE RBA OF FIRST NOTICE MSG RECORD */            15244320
         SR    R8,R8               CLEAR R8                             15245420
         LH    R9,BCMAX            R9 = MAXIMUM NUMBER OF BC MSG        15246520
*                                  R9 = DIVIDEND                        15247620
         D     R8,NUMENT           DIVIDE BY NUMBER OF MSG ENTRIES      15248720
*                                  PER BC DIRECTORY RECORD              15249820
*                                  R9 = QUOTIENT = NO. BC DIRECTORY REC 15250920
         LTR   R8,R8               R8 = REMAINDER                       15252020
         BZ    NOREM               IF NO REMAINDER, BYPASS BUMP         15253120
         LA    R9,NEXT(R9)         BUMP R9 BY 1                         15254220
NOREM    DS    0H                                                       15255320
*/*NOREM:     P  CALCULATE RBA OF FIRST BC MSG */                       15256420
         LA   R9,BD1RBA(R9)        BUMP R9 BY RBA OF FIRST BC DIR. REC  15257520
         ST    R9,BMRBA            BMRBA = RBA OF FIRST BC MSG RECORD   15258620
         MVC   R1BCMAX(L'BCMAX),BCMAX  SET MAXIMUM NO.BROADCAST MSGS    15259720
         MVC   BCMNUM(MSGNOL),BCMNUM1  INITIALIZE BRODCAST MSG NO.      15260820
*/*           P  MOVE CALCULATED RBA INTO NOTICE DIR ENTRY */           15261920
         MVC   BDRBA(PTRL),BDRBA1  INITIALIZE BRODCAST DIR RBA          15263020
         SPACE 4                                                        15264120
BCDL1    DS    0H             FORMAT 1 BRODCAST DIRECTORY RECORD        15265220
*/*BCDL1:     P  SET BC MSGNO */                                        15266320
         L     R8,BMRBA            R8 = RBA OF BRODCAST MESSAGE RECORD  15267420
         LA    R2,BCD              R2 = ADDRESS BRODCAST DIRECTORY REC  15268520
         LH    R1,BCMNUM           R1 = BRODCAST MESSAGE NUMBER         15270520
         CH    R1,BCMAX            TEST FOR MAXIMUM NOTICE MSG NUMBER   15270920
         BH    DIREND              YES, GO TO WRITE NOTICE MSG RECORDS  15271320
*/*           P  SET LOOP CONTROL INDEX TO 25 ENTRIES PER RCD */        15272520
         L     R7,NUMENT           R7 = 25 FOR LOOP CONTROL             15272920
         SPACE 4                                                        15273320
*/*BCDLOOP:   P  FORMAT 1 BROADCAST DIRECTORY ENTRY */                  15273720
BCDLOOP  DS    0H            FORMAT 25 BRODCAST DIRECTORY RECORD ENTRY  15274120
*/*           D  (YES,ENDBCD,NO,) HAVE 25 ENTRIES BEEN FORMATED */      15274220
         CH    R1,BCMAX            IS IT MAXIMUM BRODCAST MSG NUM       15276220
         BH    ENDBCD              YES, BRANCH                          15278220
*/*           P  MOVE MSGNO INTO RECORD ENTRY */                        15280220
         MVC   BCMSGNO(MSGNOL,R2),BCMNUM SET BRODCAST MESSAGE NUMBER    15280320
*/*           P  SET FLAG TO INDICATE NO MSG FOR THIS MSGNO */          15281120
         OI    BCMSGNO(R2),NOMSG   SET BIT0 = 1 TO SAY NO MSG FOR THIS  15281520
*                                  BRODCAST MESSAGE NUMBER              15281920
         MVC   BCMRBA(RBAL,R2),BMRBA+NEXT  SET BROADCAST MSG RBA        15282320
*/*           P  MSGNO=MSGNO+1 */                                       15282720
         LA    R1,NEXT(R1)         BUMP BRODCAST MESSAGE NUMBER         15285620
         STH   R1,BCMNUM                                                15287620
         LA    R8,NEXT(R8)         BUMP BRODCAST MESSAGE RECORD RBA     15289620
         ST    R8,BMRBA                                                 15290020
*/*           P  BUMP PTR TO NEXT NOTICE DIR ENTRY */                   15290420
         LA    R2,BCDENTL(R2)      BUMP BCD PTR TO NEXT ENTRY           15290820
*/*           D  (NO,BCDLOOP,YES,) HAVE 25 ENTRIES BEEN DONE */         15291220
         BCT   R7,BCDLOOP          EXECUTE LOOP 25 TIMES                15291320
         LA    R4,BDRBA+NEXT       SET R4 = ADDR THIS DIRECTORY REC     15293420
*/*           P  SET END OF RECORD INDICATOR X'7F' */                   15295420
         MVI   ZER(R2),ENDREC      SET END OF RECORD INDICATOR          15297420
         L     R5,BDRBA            BUMP BC DIRECTORY POINTER            15297820
         LA    R5,NEXT(R5)                                              15301220
         ST    R5,WORK4                                                 15303220
         CH    R1,BCMAX            CHECK FOR MAXIMUM BROADCAST MSGNO    15303620
         BH    NOPTR               LAST REC, SET CHAIN PTR TO ZERO      15304020
*/*           P  GET PTR TO NEXT BC DIRECTORY RCD */                    15304420
         MVC   NEXT(RBAL,R2),WORK4+NEXT  SET PTR TO NEXT BC DIRECT. REC 15304820
WRITBCD  DS    0H                  WRITE NOTICE DIRECTORY RECORD        15304920
         LA    R3,BCD              SET AREA ADDRESS                     15308520
         MVI   KEY,BDKEY           SET KEY = X'0                        15310520
*/*           I  WRITE DIRECTORY RCD */                                 15310920
         WRITE DECB2,DI,(R10),(R3),'S',KEY,(R4),MF=E  WRITE DIR. RECORD 15311320
         CHECK DECB2                                                    15311720
         ST    R5,BDRBA             SET RBA NEXT DIRECTORY REC          15311820
*/*           P  (,BCDL1) BRANCH TO FORMAT NEXT RECORD */               15312220
         B     BCDL1               BRANCH TO FORMAT ANOTHER RECORD      15312320
NOPTR    DS    0H                  LAST NOTICE DIRECTORY RECORD         15313220
         XC    NEXT(RBAL,R2),NEXT(R2)  ZERO OUT CHAIN PTR               15313620
         B     WRITBCD             GO TO WRITE DIRECTORY RECORD         15314020
         EJECT                                                          15314120
DIREND   DS    0H                  END OF DIRECTORY, DO NOT BUMP BDRBA  15314220
*                                  TO GET FIRST NOTICE MSG RECORD RBA   15314320
         L     R5,BDRBA            R5 = RBA OF LAST DIRECTORY RECORD    15314420
         B     WRITBCM2            GO TO WRITE NOTICE MSG RECORDS       15316320
         SPACE 4                                                        15318320
*/*ENDBCD:    P  WRITE ZEROES FOR REST OF DIRECTORY */                  15328020
ENDBCD   DS    0H                  WRITE ZEROES FOR REST OF DIRECT. REC 15330020
*/*           P  ZERO OUT ENTRY */                                      15332020
         XC    ZER(BCDENTL,R2),ZER(R2)  ZERO OUT BCD ENTRY              15334020
*/*           P  BUMP PTR IN BC DIR TO NEXT ENTRY */                    15336020
         LA    R2,BCDENTL(R2)      BUMP PTR IN BC DIRECTORY RECORD TO   15338020
*                                  NEXT ENTRY                           15340020
*/*           D  (YES,,NO,ENDBCD) HAVE 25 ENTRIES BEEN MADE? */         15342020
         BCT   R7,ENDBCD           LOOP TILL 25 ENTRIES ARE MADE        15344020
*/*           P  SET END OF RECORD FLAG='7F' */                         15346020
         MVI   ZER(R2),ENDREC      SET END OF RECORD INDICATOR          15348020
*/*           P  SET PTR TO NEXT DIRECTORY RCD=0, LAST DIR RCD */       15350020
         XC    NEXT(RBAL,R2),NEXT(R2)  PTR TO NEXT BC DIRECT. REC = 0   15352020
*********************************************************************** 15354020
*                                                                     * 15356020
* WRITE BRODCAST DIRECTORY RECORD                                     * 15358020
*                                                                     * 15360020
*********************************************************************** 15362020
         LA    R4,BDRBA+NEXT       SET ADDRESS OF BLOCK ID (RBA)        15364020
         LA    R3,BCD              SET AREA ADDRESS                     15366020
         MVI   KEY,BDKEY           SET KEY                              15368020
*/*           I  WRITE LAST BROADCAST DIR RCD */                        15370020
         WRITE DECB2,DI,(R10),(R3),'S',KEY,(R4),MF=E WRITE              15372020
         CHECK DECB2               CHECK THE WRITE FOR COMPLETION       15374020
         SPACE 4                                                        15376020
*********************************************************************** 15378020
*        WRITE BROADCAST NOTICE MSG RECORDS TO RESERVE MAXIMUM SPACE  * 15380020
*********************************************************************** 15382020
WRITBCM  DS    0H                  WRITE NOTICE MSG RECORDS OF ALL 0'S  15384020
         L     R5,BDRBA            R5= RBA OF LAST DIRECTORY RCD        15392020
*                                  WRITTEN                              15394020
         LA    R5,NEXT(R5)         BUMP R5 TO RBA OF FIRST MSG RCD      15396020
WRITBCM2 DS    0H                  BRANCH PT ON DIRECTORY END.          15396420
*                                  REG 5 ALREADY SET                    15396520
         XC    BCD(L'BCD),BCD      CLEAR AREA FOR NOTICE MSG RECORD     15396820
         LH    R7,BCMAX            INIT LOOP CONTROL REG TO NO. OF      15397220
*                                  BC NOTICE MSG RECORDS TO WRITE       15397620
         ST    R5,BMRBAS           SAVE R5                              15398020
         LA    R4,BMRBAS+NEXT      R4=ADDR OF RBA OF RECORD TO WRITE    15400020
         LA    R3,BCD              SET AREA ADDRES                      15402020
         MVI   KEY,BMKEY           SET KEY FOR BROADCAST NOTICE MSG     15404020
*                                  RECORD                               15406020
BCMLOOP  DS    0H                  WRITE A NULL BC NOTICE MSG RECORD    15408020
         WRITE DECB2,DI,(R10),(R3),'S',KEY,(R4),MF=E                    15410020
*                                  WRITE NOTICE RECORD                  15412020
         CHECK DECB2                                                    15414020
         L     R5,BMRBAS                                                15416020
         LA    R5,NEXT(R5)         BUMP RBA OF NEXT NOTICE MSG TO       15418020
*                                  WRITE                                15420020
         ST    R5,BMRBAS                                                15422020
         BCT   R7,BCMLOOP          LOOP UNTIL ALL NOTICES MSGS          15424020
*                                  ARE WRITTEN                          15426020
         EJECT                                                          15428020
*********************************************************************** 15430020
*                                                                     * 15432020
* SET UP RECORD 1 FOR SYS1.BRODCAST DATA SET                          * 15434020
*                                                                     * 15436020
*********************************************************************** 15438020
*/*           P  CLEAR AREA FOR RECORD 1 */                             15440020
         XC    RECORD1(L'RECORD1),RECORD1  CLEAR AREA FOR RECORD 1      15442020
*/*           P  FORMAT RECORD 1 */                                     15444020
         MVC   R1BCPTR(RBAL),BDRBA1+1   PTR TO BROADCAST NOTICES DIR.   15446020
         MVC   R1USPTR(RBAL),BMRBA+1    PTR TO USER MAIL DIRECTORY.     15448020
*                                       FIRST RECORD                    15450020
         MVC   R1BCMAX(HALF),BCMAX MAXIMUM NO. BROADCAST MSGS           15452020
*                                  SET NO. RECORDS IN DATA SET          15454020
         MVC   R1RECNUM(L'R1RECNUM),RECCNT                              15456020
*                                                                     * 15458020
         MVC   R1DSN(L'DSNAME),DSNAME   DATA SET NAME                   15460020
         L     R5,RECCNT                R5 = NO. RECORDS IN D S         15462020
         S     R5,BMRBA                 R5 = NO. RECORDS IN D S MINUS   15464020
*                                       RBA OF FIRST USER DIR REC       15466020
         ST    R5,PARMLMCT              SAVE LIMIT CNT IN PARM LIST =   15468020
*                                       NO. RECORDS IN USER SECTION     15470020
         EJECT                                                          15472020
*********************************************************************** 15474020
*                                                                     * 15476020
* WRITE RECORD 1 OF SYS1.BRODCAST DATA SET                            * 15478020
*                                                                     * 15480020
*********************************************************************** 15482020
         LA    R3,RECORD1          SET AREA ADDRESS                     15484020
         LA    R4,R1RBA            SET ADDRESS OF BLOCK ID (RBA)        15486020
         MVI   KEY,R1KEY           SET KEY                              15488020
*/*           I  WRITE RECORD 1 */                                      15490020
         WRITE  DECB2,DI,(R10),(R3),'S',KEY,(R4),MF=E  WRITE RECIRD 1   15492020
         CHECK DECB2                                                    15494020
*********************************************************************** 15496020
*                                                                     * 15498020
* WRITE FIRST USER MAIL DIRECTORY RECORD OF ALL ZEROES                * 15500020
*                                                                     * 15502020
*********************************************************************** 15504020
*/*           P  SET UP TO WRITE FIRST USER MAIL DIR RCD */             15506020
         XC    BCD,BCD             SET RECORD TO BE WRITTEN TO ZERO     15508020
         LA    R3,BCD              SET AREA ADDR TO BE WRITTEN          15510020
         MVI   ENDRECFF(R3),ENDREC  SET END OF RECORD INDICATOR IN      15512020
*                                  USER MAIL DIRECTORY RECORD           15514020
         LA    R4,R1USPTR          R4 = ADDR OF RBA FOR USER DIR. REC1  15516020
         MVI   KEY,USDKEY          SET KEY FOR USER DIRECTORY           15518020
*/*           I  WRITE FIRST USER MAIL DIR RCD OF ALL ZERO */           15520020
         WRITE DECB2,DI,(R10),(R3),'S',KEY,(R4),MF=E  WRITE USER DIR    15522020
         CHECK DECB2               CHECK THE WRITE                      15524020
*/*           P  PUT DCB PTR IN PARM LIST */                            15526020
         ST    R10,PARMDCB         PUT DCB ADDRESS IN PARM LIST         15528020
*                                                                       15528120
*        THE FOLLOWING CODE CLOSES AND REOPENS THE BROADCAST D.S.       15528220
*        THIS IS DONE TO FREE AS MUCH CORE AS POSSIBLE                  15528320
*        BEFORE XCTL'ING TO THE NEXT LOAD WHICH IS LARGER THAN THIS.    15528420
*                                                                       15532520
         CLOSE  ((R10)),MF=(E,CLOSEL)  CLOSE DCB TO FREE CORE           15537020
*/*           I   OPEN 'J' BROADCAST D S */                             15540420
         LA    R5,EXITLST          R5 = ADDR EXIT LIST FOR OPEN'J'      15540820
         ST    R5,WORK4                                                 15540920
         MVC   DCBEXLST+NEXT(RBAL),WORK4+NEXT  EXIT LIST ADDR IN DCB    15541020
         OPEN  ((R10),OUTPUT),TYPE=J,MF=(E,OPENL)  OPEN FOR UPDATE      15541120
*        NO I/O OPERATIONS ARE DONE TO KEEP AMT OF BDAM CODE TO MINIMUM 15541220
         TM    DCBOFLGS,GOODOPEN   TEST FOR GOOD OPEN                   15545420
         BZ    BADOPEN             OPEN NOT SUCCESSFUL, BRANCH          15549620
*/*           P  (,ENDIO) RETURN CODE=0 SUCCESSFUL OPERATION */         15553820
         XC    RETCODE,RETCODE     SET RETCODE = 0 FOR OPERATION DONE   15558020
         EJECT                                                          22700020
*/*ENDIO:     P  RELOAD CALLER REGISTERS */                             22750020
ENDIO    DS    0H                  EXIT CODE                            22800020
*********************************************************************** 22802020
*     DEQUEUE FROM RECORD1 FOR THE BROADCAST DIRECTORY                * 22804020
*********************************************************************** 22806020
         DEQ   (QNAME,R1RBA,3,SYSTEM),RET=HAVE,MF=(E,DEQL)              22810020
         L     R13,SAVER+OFFCALLR  RELOAD R13 WITH CALLER SAVE AREA ADD 22850020
         SR    R14,R14             CLEAR REG 14                         22900020
         IC    R14,RETCODE         SAVE RETURN CODE IN REG 14           22950020
*                                  BEFORE ISSUING FREEMAIN              23000020
         LA    R8,DATAEND-DATABEG  SET R8 FOR FREEMAIN FOR WORK AREA    23050020
*        R12 HAS ADDRESS OF WORK AREA GOTTEN VIA GETMAIN                23100020
*/*           P  FREEMAIN CORE FOR WORK DSECT */                        23150020
         FREEMAIN  R,LV=(R8),A=(R12),SP=0   FREE CORE FOR WORK AREA     23200020
*/*           P  PUT RETURN CODE IN COMMON */                           23300020
         STC   R14,SDIORC          PUT RETURN CODE IN COMMON AREA       23350020
         L     R14,OFF14(R13)      RELOAD REG 14 FROM SAVEAREA          23350420
         LA    R5,EPXCTL2          R5 = ENTRY POINT ADDR FOR XCTL       23352020
         LR    R1,R6               R1 = ADDR OF COMMON FOR XCTL         23354020
*                                                                       23354420
*       PASS CONTROL TO NEXT ROUTINE ACCORDING TO ENTRY POINT           23354820
*       NAME IN COMMON DATA AREA, EPXCTL2.                              23355220
*       CONTROL WILL PASS TO IEEVSND2 OR IEEVSND3 OR IEEVSND8 AS        23355620
*       DETERMINED BY IEEVSEND, WHICH SET EPXCTL2.                      23355720
*       REGISTERS ARE NOT RELOADED BECAUSE THEY WERE NOT SAVED.         23404220
*                                                                       23453020
         XCTL    ,EPLOC=(R5),MF=(E,(1)),SF=(E,XCTLL)                    23501520
         SPACE 4                                                        23550020
*/*NOTUP:     P  (,ENDIO) SET RET CODE FOR VOLUME NOT MOUNT */          23600020
NOTUP    DS    0H                  BROADCAST DATA SET NOT MOUNTED       23650020
         OI    RETCODE,NOTMNT      SET RETURN CODE                      23700020
         B     ENDIO               GO TO EXIT CODE                      23750020
*/*BADOPEN:   P  (,ENDIO) SET RETURN CODE FOR OPEN ERROR */             23800020
BADOPEN  DS    0H                  OPEN WAS NOT SUCCESSFUL              23850020
         OI    RETCODE,OPENERR     SET RETURN CODE FOR OPEN ERROR       23900020
         LA    R0,DCBEND-IHADCB    SET R0 FOR FREEMAIN                  23950020
         FREEMAIN  R,LV=(0),A=(R10) FREE CORE FOR DCB                   23960020
*                                                                       23962020
         L     R5,PARMJFCB         R5 = ADDR OF JFCB TO FREE            23964020
         LA    R0,JFCBLNG          R0 = LENGTH OF JFCB TO FREE          23966020
         FREEMAIN   R,LV=(0),A=(R5)   FREE CORE FOR JFCB                23968020
         B     ENDIO               END OF PROCESSING                    23970020
         SPACE 4                                                        24600020
*/*SYNAD0:    P  SYNAD FOR OPEN REQUEST ON FIRST READ  */               24650020
SYNAD0   DS    0H                  SYNAD USED ON FIRST READ WHEN OPEN   24700020
*                                  IS REQUESTED                         24750020
         B     INITDS              DATA SET HAS NOT BEEN FORMATD        24900020
*                                                                     * 24950020
         SPACE 4                                                        24960020
*/*SYNAD1:    D  (YES,,NO,SYNA) I/O ERROR? */                           25000020
SYNAD1   DS    0H                  SYNAD ROUTINE                        25050020
         LR    R5,R0               REG0 = ADDRESS OF DECB               25100020
*/*           P  (,ENDIO) SET RETURN CODE FOR IO ERROR */               25250020
         OI    RETCODE,IOERR       SET RETURN CODE TO IO ERROR          25300020
         B     ENDIO               END OF PROCESSING                    25350020
*                                                                     * 25400020
*                                                                     * 25650020
         SPACE 2                                                        25700020
*/*BADGM:     P  (,ENDIO) SET RETURN CODE FOR 'NO CORE' */              25750020
BADGM    DS    0H                  GETMAIN FOR JFCB OR DCB UNSUCCESSFUL 25800020
         OI    RETCODE,NOCORE      SET RETURN CODE FOR NOT ENOUGH CORE  25850020
         B     ENDIO               BRANCH TO EXIT                       25900020
         EJECT                                                          26300020
AB       DC    CL44'SYS1.BRODCAST' DATA SET NAME                        26350020
BCDDNM   DC    CL8'SYSLBC'         DDNAME FOR BROADCAST DATA SET        26400020
QNAME    DC    CL8'SYSIKJBC'       QNAME FOR ENQUE ON RECORD 1          26410020
DDENTOFF EQU   24                  OFFSET TO FIRST DD ENTRY IN TIOT     26450020
ENDTIOT  DC    F'0'                END-OF-TIOT INDICATOR                26500020
JFCBLNG  EQU   176                 LENGTH OF JFCB                       26550020
SP0      EQU   0                   INDICATOR FOR SUBPOOL 0              26600020
SP252    EQU   252                 INDICATOR FOR SUBPOOL 252            26650020
ENDUCBN  DC    2X'FF'              END OF UCB LOOKUP TABLE INDICATOR    26700020
LOCAREA  DS    0D                                                       26750020
         DS    2C                  NO. OF VOLUME POINTERS               26800020
         DS    4C                  DEVICE CODE                          26850020
VOLSER   DS    6C                  VOLUME SERIAL NUMBER - SYS1.BRODCAST 26900020
*                                  - GOTTEN FROM LOCATE INSTR.          26950020
         DS    2C                  DATA SET SEQUENCE NO.                27000020
         DS    242C                VOLUME LIST BLOCK                    27050020
         DS    3C                  TTR OF NEXT BLOCK                    27100020
         DS    6C                  VOL SERIAL NO. OF CATALOG BLOCK      27150020
EXITJFCB DC    X'87'               EXIT LIST CODE FOR JFCB              27200020
MOUNT    DC    F'4'                VOLUME NOT MOUNTED CODE IN REG 15    27250020
ONE      EQU   1                                                        27300020
VOLSERL  EQU   6                   VOLUME SERIAL NUMBER LENGTH          27350020
TYPEDA   EQU   X'20'               CODE FOR DIRECT ACCESS IN UCBTYP FLD 27400020
BDRBA1   DC    F'1'                RBA FIRST BROADCAST DIR RECORD       27410020
BCMNUM1  DC    H'1'                FIRST BROADCAST MESSAGE NUMBER       27420020
DSNAME   DC   C' SYS1.BRODCAST DATA SET '                               27450020
R1RBA    DC    X'000000'           RELATIVE BLOCK ADDR OF FIRST RECORD  27500020
NUMENT   DC    F'25'               NUMBER OF MSG ENTRIES PER BROADCAST  27510020
*                                  NOTICE DIRECTORY RECORD              27520020
         EJECT                                                          27550020
GOODOPEN EQU   X'10'               USED TO TEST DCBOFLGS FOR GOOD OPEN  27600020
ENDREC   EQU   X'7F'               END OF RECORD INDICATOR              27610020
ENDRECFF EQU   125                 OFFSET TO END OF RECORD INDICATOR    27620020
NOMSG    EQU   X'80'                                                    27650020
ZER      EQU   0                   USED FOR OFFSET OF ZERO              27700020
BCMSGNO  EQU   0                   OFFSET TO MSG NO. IN BC DIR ENTRY    27710020
STTB80   EQU   X'80'               DATA SET IS ON DEVICE                27750020
*                                  TIOT STATUS BYTE B                   27800020
NEXT     EQU   1                   USED AS INCREMENT VALUE              27850020
BD1RBA   EQU   1                   RBA OF FIRST BROADCAST DIR RECORD    27860020
BCMRBA   EQU   2                   OFFSET TO RBA IN BC DIR ENTRY        27870020
HALF     EQU   2                   USED TO GET TO HALF WORD BDY         27900020
MSGNOL   EQU   2                   LENGTH OF MSG NO. FIELD              27950020
RBAL     EQU   3                   RELATIVE BLOCK ADDRESS LENGTH        28000020
PTRL     EQU   4                   POINTER LENGTH - FULL WORD           28050020
OFFCALLR EQU   4                   OFFSET IN MY SAVE AREA TO ADDR OF    28100020
*                                  CALLER'S SAVE AREA                   28150020
BCDENTL  EQU   5                   LENGTH OF BRODCAST DIRECTORY ENTRY   28200020
RECPOS   EQU   7                   POSITION OF RECORD BYTE IN           28250020
*                                  2-WORD FEEDBACK AREA AFTER READ      28300020
OFFCALLD EQU   8                   OFFSET IN SAVE AREA TO CALLED ADDR   28350020
LENG8    EQU   8                   LENGTH OF 8 BYTES FOR REG SHIFT      28400020
OFF0     EQU   20                  OFFSET TO REG0 IN SAVE AREA          28450020
OFF14    EQU   12                  OFFSET TO REG14 IN SAVE AREA         28500020
         EJECT                                                          28600020
*********************************************************************** 28650020
*                                                                     * 28700020
*  THE FOLLOWING ARE EXCEPTION CODE BIT SETTINGS IN ECB+1 WHICH ARE     28750020
*  TESTED IN THE SYNAD ROUTINES.                                        28800020
*                                                                     * 28850020
*********************************************************************** 28900020
*                                                                     * 28950020
ECBRECL  EQU   X'40'               RECORD LENGTH CHECK                  29000020
ECBSPAC  EQU   X'20'               SPACE NOT FOUND TO WRITE REC         29050020
ECBIOERR EQU   X'08'               UNCORRECTABLE I/O ERROR              29100020
         SPACE 2                                                        29150020
*********************************************************************** 29200020
*                                                                     * 29250020
*        THE FOLLOWING ARE USED TO SET THE RETURN CODE FOR CALLER     * 29300020
*                                                                     * 29350020
*********************************************************************** 29400020
SDERR    EQU   X'80'               ERROR IN 'SEND' PROCESSOR            29450020
NOCORE   EQU   X'40'               NOT ENOUGH CORE FOR IO RTN           29500020
RINITDS  EQU   X'10'               BROADCAST D S IS NOT INITIALIZED     29550020
IOERR    EQU   X'08'               I/O ERROR - SYNAD ENTERED            29600020
NOTMNT   EQU   X'04'               BROADCAST VOLUME NOT MOUNTED         29650020
OPENERR  EQU   X'02'               ERROR OCCURRED DURING OPEN           29700020
DSFULL   EQU   X'01'               DATA SET FULL  ON   WRITE 'DA'       29750020
BDKEY    EQU   X'00'               KEY FOR BROADCAST DIRECTORY REC      29760020
USDKEY   EQU   X'01'               KEY FOR USER MAIL DIRECTORY REC      29770020
BMKEY    EQU   X'02'               KEY FOR BROADCAST NOTICE MSG REC     29780020
R1KEY    EQU   X'04'               KEY FOR RECORD 1                     29790020
*                                                                     * 29800020
*                                                                     * 29850020
*                                                                     * 29900020
         EJECT                                                          29950020
*                                                                     * 30000020
*        THE FOLLOWING ARE LIST FORMS OF MACROS WHICH ARE MOVED TO    * 30050020
*        GOTTEN CORE AT EXECUTION TIME.                               * 30100020
*        THE ORDER OF THE MACROS MUST, MUST NOT BE CHANGED            * 30150020
*                                                                     * 30200020
         READ  DEC01,DIF,,,,,,MF=L  READ BY BLOCK ID (RBA) LIST         30250020
         WRITE DEC02,DI,,,,,,MF=L  WRITE BY BLOCK ID (REL. BLOCK ADDR)  30300020
         WRITE DEC03,DAF,,,,,,MF=L WRITE TO ADD A RECORD W/FEEDBACK     30350020
         WRITE DEC04,SD,,,,,,MF=L                                       30360020
         OPEN  0,MF=L              OPEN LIST FORM                       30400020
         CLOSE 0,MF=L              CLOSE LIST FORM                      30450020
         GETMAIN  EC,MF=L          GETMAIN LIST FORM                    30500020
         CAMLST NAME,AB,,LOCAREA   LIST FOR LOCATE INSTRUCTION          30550020
         EXTRACT   ,MF=L           LIST FOR EXTRACT INSTRUCTION         30600020
         ENQ   (QNAME,R1RBA,E,3,SYSTEM),RET=HAVE,MF=L   ENQ LIST FORM   30610020
         DEQ   (QNAME,R1RBA,3,SYSTEM),RET=HAVE,MF=L     DEQ LIST FORM   30620020
         XCTL  ,SF=L                                                    30630020
LISTSEND EQU   *                   END OF LISTS FOR MACRO INSTRUCTIONS  30650020
*                                  TO BE USED TO MOVE INTO DSECT        30700020
LISTSL   EQU   LISTSEND-DEC01      LENGTH OF LISTS FOR MACRO INSTRUCT.  30750020
         EJECT                                                          30800020
*        THE FOLLOWING IS THE JFCB WHICH WILL BE USED TO OPEN 'J'     * 30850020
*        THE BROADCAST DATA SET.                                      * 30900020
*        THE VOLUME SERIAL NUMBER WILL BE GOTTEN FROM THE CATALOG     * 30950020
*        USING THE 'LOCATE' MACRO.                                    * 31000020
*                                                                     * 31050020
*                                                                     * 31100020
*                                                                     * 31150020
JFCBDUM  DS    0F                  DUMMY JOB FILE CONTROL BLOCK         31200020
         DC    C'SYS1.BRODCAST'    DATA SET NAME FIELD                  31250020
         DC    CL31' '             DATA SET NAME FIELD                  31300020
         DC    8C' '               ELEMENT NAME OR GENERATION NO.       31350020
         DC    AL1(8)              INTERFACE BYTE = '08' =              31400020
*                                  DO NOT WRITE BACK THE JFCB DURING    31450020
*                                  OPEN PROCESSING                      31500020
         DC    XL13'00'            SYSTEM CODE                          31550020
         DC    AL1(1)              LABEL TYPE = '01' = NO LABEL         31600020
         DC    AL1(0)              RESERVED                             31650020
         DC    H'0'                FILE SEQUENCE NUMBER                 31700020
         DC    H'0'                VOLUME SEQUENCE NUMBER               31750020
         DC    8X'00'              DATA MANAGEMENT MASK                 31800020
         DC    XL3'00'             CREATION DATE                        31850020
         DC    3X'00'              EXPIRATION DATE                      31900020
         DC    AL1(0)              INDICATOR BYTE 1                     31950020
         DC    X'40'               INDICATOR BYTE 2 ='40' = OLD DATASET 32000020
         DC    XL19'00'            DCB OPTIONS                          32050020
         DC    X'000000'                                                32100020
         DC    7X'00'                                                   32150020
         DC    X'01'               NO. OF SERIAL NUMBERS                32200020
         SPACE 2                                                        32250020
JFCBVSN  DC    30C' '              VOLUME SERIAL NUMBERS - SPACE FOR 5  32300020
         DC    X'00'               RESERVED                             32350020
         DC    3X'00'              TTR OF FIRST JFCB EXTENSION          32400020
         DC    3X'00'              PRIMARY DIRECT ACCESS SPACE          32450020
         DC    X'00'               SPACE PARAMETERS                     32500020
         DC    4X'00'              DECONDARY DIRECT ACCESS SPACE        32550020
         DC    3X'00'              DIRECTORY SPACE                      32600020
         DC    3X'00'              CORE ADDR. OF JFCB SPLIT CYL         32650020
         DC    2X'00'              REL. ADDR. 1ST TRACK TO ALLOCATE     32700020
         DC    3X'00'              CORE ADDR. OF JFCB SUBALLOC. SPACE   32750020
         DC    3X'00'              AVERAGE DATA BLOCK LENGTH            32800020
         DC    X'01'               VOLUME COUNT                         32850020
         DC    X'00'               TRKS/CYL TO BE USED - SPLIT CYL      32900020
JFCBDEND EQU   *                   END OF JFCB                          32950020
         EJECT                                                          33000020
*********************************************************************** 33050020
*                                                                     * 33100020
* BDAM DCB - USED TO ACCESS SYS1.BRODCAST DATA SET                    * 33150020
*                                                                     * 33200020
*********************************************************************** 33250020
BDAMDCB  DCB   BLKSIZE=129,                                            X33300020
               BUFL=129,                                               X33350020
               DDNAME=SYSLBC,      DDNAME FOR BROADCAST DATA SET       X33400020
               DSORG=DA,           DIRECT ACCESS                       X33450020
               KEYLEN=1,           KEY LENGTH = 1 BYTE                 X33500020
               LIMCT=5,            SET AT EXECUTION TIME, NEVER ZERO   X33550020
               MACRF=(RIC,WAIC),   READ, ID, CHECK, WRITE              X33600020
               OPTCD=WEFR,         RELATIVE BLOCK ADDRESSING           X33650020
               RECFM=F,            FIXED                               X33700020
               SYNAD=SYNAD1                                             33750020
BDAMEND  EQU   *                   END OF BDAM DCB                      33760020
BDDCBL   EQU   BDAMEND-BDAMDCB     LENGTH OF BDAM DCB                   33770020
         EJECT                                                          33800020
*********************************************************************** 33830020
*                                                                     * 33840020
* BSAM DCB - USED TO CREATE SYS1.BRODCAST DATA SET                    * 33842020
*                                                                     * 33844020
*********************************************************************** 33846020
BSAMDCB  DCB   BLKSIZE=129,                                            X33848020
               BUFL=129,                                               X33848420
               DEVD=DA,            DIRECT ACCESS                       X33848820
               DDNAME=SYSLBC,      DDNAME FOR BROADCAST DATA SET       X33849220
               DSORG=PS,           PHYSICAL SEQUENTIEL                 X33849620
               KEYLEN=1,           KEY LENGTH = 1 BYTE                 X33849720
               MACRF=(WL),         CREATE DIRECT DATA SET              X33849820
               OPTCD=W,            WRITE                               X33849920
               RECFM=F,            FIXED                               X33866620
               SYNAD=SYNAD1                                             33876620
BSAMEND  EQU   *                   END OF BSAM DCB                      33877020
BSDCBL   EQU   BSAMEND-BSAMDCB     LENGTH OF BSAM DCB                   33877420
         EJECT                                                          33878620
*********************************************************************** 33883320
*                                                                     * 33900020
*        DSECT FOR PARAMETER LIST FROM CALLER                         * 33950020
*                                                                     * 34000020
*********************************************************************** 34050020
*                                                                     * 34100020
COMMON   DSECT                     COMMON DATA AREA FOR OPERATOR SEND   34102020
         DS    1C                  RESERVED                             34104020
TPUTRC   DS    1C                  NONZERO RETURN CODE FROM BAD TPUT    34106020
VALCNT   DS    1C                  NO. VALID USERIDS SPEC'D             34120020
MSGFLAGS DS    1C                  WARNING MESSAGE INDICATORS           34122020
FMSG2    EQU   X'80'               WARNING MSG2 TO BE ISSUED            34122420
FMSG3    EQU   X'40'               WARNING MSG3 TO BE ISSUED            34122520
FMSG4    EQU   X'20'               WARNING MSG4 TO BE ISSUED            34122620
FMSG5    EQU   X'10'               WARNING MSG5 TO BE ISSUED            34122720
FMSG6    EQU   X'08'               WARNING MSG6 TO BE ISSUED            34128120
FMSG8    EQU   X'04'               WARNING MSG8 TO BE ISSUED            34128520
FMSG9    EQU   X'02'               WARNING MSG9 TO BE ISSUED            34128920
FMSGA    EQU   X'01'               WARNING MSGA TO BE ISSUED            34133820
*                                                                       34133920
FLAG1    DS    1C                  FLAG AREA                            34134220
FOPEN    EQU   X'80'               SYS1.BRODCAST DATA SET IS OPEN       34135820
FANYINV  EQU   X'40'               ROUTE CONTROL TO ANYINV IN IEEVSND4  34137820
FBADSEND EQU   X'20'               SEND ERROR HAS BEEN ENCOUNTERED      34138220
FCHNMSG  EQU   X'10'               USER MAIL MSGS IN CHAIN              34138620
FUPUSD   EQU   X'08'               USER DIRECTORY REC HAS BEEN UPDATED  34139020
FENDUSL  EQU   X'04'               FLAG FOR END OF USER LIST            34139120
FENDTJB  EQU   X'02'               FLAG FOR END OF TJB SCAN             34151220
FLISTING EQU   X'01'               LISTING NOTICE MSGS BEING DONE       34161220
*                                                                       34161320
FLAG2    DS    1C                  FLAG AREA                            34161620
FNOMSG   EQU   X'80'               NOTICE DIRECTORY SHOWS DELETION      34163220
FYESBCM  EQU   X'40'               AT LEAST 1 NOTICE MSG IN DATA SET    34163620
FADDBC   EQU   X'20'               ADDING NOTICE MSG TO DATA SET        34167620
FMN      EQU   X'10'               MESSAGE NO. FORMAT OF SEND CMD       34169620
*        EQU   X'08'               RESERVED                             34171620
FUSER    EQU   X'04'               SEND COMMAND SPEC'D 'USER'           34171720
FMAILFL  EQU   X'02'               USER MAIL SECTION FULL               34175720
*        EQU   X'01'               RESERVED                             34175820
*                                                                       34176220
FLAG3    DS    1C                  FLAG AREA                            34177820
FDEL     EQU   X'80'               DELETE SPEC'D NOTICE MSG             34179820
FLISTALL EQU   X'40'               LIST ALL BROADCAST NOTICE MSGS       34183820
FLIST    EQU   X'20'               LIST SPEC'D NOTICE MSG NO.           34183920
FNOW     EQU   X'10'               SEND MSG NOW                         34185920
FLOGON   EQU   X'08'               SEND MSG AT LOGON                    34187920
FALL     EQU   X'04'               SEND MSG TO ALL USERS                34198220
FSTAE    EQU   X'02'               STAE EXIT ROUTINE ENTERED            34198620
FERRID   EQU   X'01'               SYNTAX ERROR IN THIS USERID          34199020
*                                                                       34199120
FLAG4    DS    1C                  FLAG AREA                            34199420
FTERM    EQU   X'80'               JOB INITIATED BY OPERATOR TERMINAL   34199820
FCONSOL  EQU   X'40'               JOB INITIATED BY OPERATOR CONSOLE    34199920
FERRSYN  EQU   X'20'               PROCESSING SYNTAX ERROR              34200020
FWTO2    EQU   X'10'               SECOND WTO MUST BE ISSUED            34202020
FMSG1    EQU   X'08'               MSG 1 INSERT INDEX HAS BEEN SET      34204020
FBADIO   EQU   X'04'               I/O ERROR FOUND                      34206020
FBADRITA EQU   X'02'               UNSUCCESSFUL WRITE 'DA'              34208020
FBADTPUT EQU   X'01'               TPUT ERROR FOUND                     34208420
*                                                                       34208520
M1IND    DS    1C                  INDEX TO MSG1 USERID EXTENSION       34208820
MSG1EXTP DS    3C                  PTR TO MSG1 USERID EXTENSION         34218820
IDCNT    DS    1C                  TOTAL NO. OF USERIDS SPEC'D          34218920
IDTBL    DS    3C                  PTR TO USERID TABLE                  34219020
SDIORC   DS    1C                  RETURN CODE FROM I/O ROUTINE -       34222420
*                                     IEEVSND5 OR IEEVSND9              34222820
RETVATT1 DS    3C                  RETURN POINT IN IEEVGPSD             34224420
         DS    1C                  UNUSED                               34224520
CSCBPTR  DS    3C                  ADDR OF CSCB FOR SEND CMD            34224620
COMI     DS    1C                  INDEX TO COMBUF = I                  34224720
COMBUFP  DS    3C                  PTR TO COMBUF                        34227720
TBEG     DS    1C                  INDEX IN COMBUF TO MSG TEXT BEGIN    34228120
TEXTLENG DS    1C                  LENGTH OF TEXT IN SEND CMD           34228520
CBCMSGNO DS    2C                  MESSAGE NO. SPEC'D IN SEND CMD       34228920
EPXCTL   DS    8C                  ENTRY POINT NAME USED IN XCTL        34229320
EPXCTL2  DS    8C                  ENTRY POINT NAME USED IN XCTL        34229720
MSG1EXT  DS    112C                INVALID USERIDS FOR MSG1             34230720
COMBUF   DS    124C                COMMAND IMAGE FROM CSCB              34231120
IDUSRID  DS    140C                TABLE OF USERIDS SPEC'D              34231520
*                                                                     * 34233720
SDIOPARM DS    0F                  INFORMATION FOR I/O OPERATIONS       34236720
*                                                                       34239720
PARM1    DS    1C                  FLAG1 FOR OPERATIONS TO BE PERFORMED 34250020
P1OPEN   EQU   X'80'               OPEN - INITIAL FORMATTING IF FIRST   34300020
*                                       TIME DATA SET HAS BEEN USED     34350020
P1READ   EQU   X'40'               READ SPECIFIED RECORD                34400020
P1OPENIN EQU   X'20'               OPEN DATA SET FOR INPUT              34450020
*                                                                     * 34500020
*                                                                     * 34550020
PARM2    DS    1C                  FLAG2 FOR OPERATIONS TO BE PERFORMED 34600020
P2WRDI   EQU   X'80'               WRITE SPECIFIED RECORD BY BLOCK ID   34650020
P2WRDAF  EQU   X'40'               WRITE SPECIFIED RECORD IN NEXT       34700020
*                                       AVAILABLE SPACE WITH FEEDBACK   34750020
P2CLOSE  EQU   X'20'               CLOSE                                34800020
P2DEL    EQU   X'10'               DELETION OF THIS RECORD.             34850020
*                                  PUT PARMFDBK INTO FIRST BYTE OF DATA 34900020
P2JFCB   EQU   X'08'               FREE CORE FOR JFCB                   34950020
PARMKEY  DS    C                   KEY FOR READ/WRITE INSTRUCTION       35000020
PARMFDBK DS    C                   FEEDBACK FROM READ - POSITION        35050020
*                                  OF RECORD ON TRACK.  PUT INTO        35100020
*                                  FIRST BYTE OF DATA FOR DELETE        35150020
PARMRBA  DS    F                   ADDRESS OF RBA FOR READ/WRITE        35200020
PARMIOAD DS    F                   ADDRESS OF BUFFER FOR IO INSTRUCTION 35250020
PARMDDNM DS    CL8                 DDNAME FOR BROADCAST DATA SET        35300020
*        THE FOLLOWING FIELDS ARE NEVER CLEARED FROM PARM LIST          35350020
PARMLMCT DS    F                   LIMIT COUNT FOR EXTENDED SEARCH      35400020
PARMDCB  DS    F                   ADDRESS OF DCB                       35450020
PARMJFCB DS    F                   ADDRESS OF JFCB                      35500020
         EJECT                                                          35550020
*********************************************************************** 35600020
*                                                                     * 35650020
DATABEG  DSECT                     DSECT FOR    WORK DATA AREA          35700020
         READ  DECB1,DIF,,,,,,MF=L  READ BY BLOCK ID (RBA) LIST         35750020
         WRITE DECB2,DI,,,,,,MF=L  WRITE BY BLOCK ID (REL. BLOCK ADDR)  35800020
         WRITE DECB3,DAF,,,,,,MF=L WRITE TO ADD A RECORD W/FEEDBACK     35850020
         WRITE DECB4,SD,,,,,,MF=L  WRITE DUMMY RECORD LIST              35860020
OPENL    OPEN  (BDAMDCB),MF=L      OPEN LIST FORM                       35900020
CLOSEL   CLOSE (BDAMDCB),MF=L      CLOSE LIST FORM                      35950020
GETML    GETMAIN  EC,MF=L          GETMAIN LIST FORM                    36000020
INDAB    CAMLST NAME,AB,,LOCAREA                                        36050020
EXTRACTL EXTRACT  ,MF=L                                                 36100020
ENQEL    ENQ    (QNAME,R1RBA,E,3,SYSTEM),MF=L                           36110020
DEQL     DEQ    (QNAME,R1RBA,3,SYSTEM),RET=HAVE,MF=L                    36120020
XCTLL    XCTL   ,SF=L                                                   36130020
         EJECT                                                          36150020
SAVER    DS    18F                 REGISTER SAVE AREA                   36200020
DCBADD   DS    F                   ADDR OF CORE FOR DCB FROM GETMAIN    36250020
JFCBADD  DS    F                   ADDR OF CORE FOR JFCB FROM GETMAIN   36300020
EXITLST  DS    0H                                                       36350020
EXIT1    DC    X'87'               EXIT  LIST CODE FOR JFCB             36400020
         DS    AL3                 ADDRESS JFCB                         36450020
WORK4    DS    F                   FULL WORD WORK AREA                  36500020
KEY      DS    C                   KEY FOR READ / WRITE OPERATIONS      36550020
BCDDENTP DS    F                   ADDR OF DD ENTRY IN TIOT FOR BROAD-  36600020
*                                  CAST DATA SET                        36650020
TIOTADD  DS    F                   ADDR OF TIOT FROM TCB                36700020
UCBNO    DS    H                   INDEX TO UCB LOOKUP TABLE            36750020
UCBLKADD DS    F                   ADDR UCB ADDRESS LIST PORTION IN     36800020
*                                  UCB LOOKUP TABLE, FROM CVTILK2       36850020
         EJECT                                                          36900020
*                  R    E    C    O    R    D       1                   36950020
*                                                                       37000020
         DS    0F                  FULL WORD BDY                        37050020
RECORD1  DS    0CL129              RECORD 1 AREA                        37100020
         DS    C                                                        37150020
R1BCPTR  DS    AL3                 RBA OF FIRST BRODCAST DIRECTORY REC  37200020
         DS    C                                                        37250020
R1USPTR  DS    AL3                 RBA OF FIRST USER DIRECTORY RECORD   37300020
R1RECNUM DS    CL4                 NO. OF RECORDS IN BROADCAST DATA SET 37350020
*                                  INITIALIZED AFTER FIRST FORMATTING   37400020
R1BCMAX  DS    H                   MAXIMUM NUMBER OF BRODCAST MSGS      37450020
*                                  SET BY SYSTEM AT SYSGEN              37500020
R1DSN    DS    CL24                DATA SET NAME IN EBCDIC              37550020
R1RES    DS    CL93                UNUSED PORTION OF RECORD 1           37600020
         SPACE 4                                                        37650020
*                                                                     * 37700020
* THE FOLLOWING ARE USED FOR INITIAL FORMATTING OF DATA SET           * 37750020
*                                                                     * 37800020
DUMREC   DS    H                   KEY PLUS 1 BYTE FOR RECORD NUMBER    37810020
         DS    0F                  BROADCAST DIRECTORY RECORD           37820020
BCD      DS    CL129               AREA FOR BROADCAST DIR RECORD        37830020
BCMAX    DS    H                   MAXIMUM NUMBER BRODCAST MSGS ALLOWED 37840020
BMRBA    DS    F                   BROADCAST MSG RBA                    37842020
BMRBAS   DS    F                   RBA OF BROADCAST NOTICE MSG RECORD   37844020
*                                  TO BE WRITTEN WITH KEY '02'X TO      37846020
*                                  RESERVE IT AS UNAVAILABLE TO BDAM    37848020
BDRBA    DS    F                   BROADCAST DIRECTORY RBA              37848420
BCMNUM   DS    H                   BROADCAST MESSAGE NUMBER             37848820
RETCODE  DS    C                   RETURN CODE TO BE PLACE IN REG15     37850020
RECCNT   DS    F                   NUMBER OF RECORDS IN DATA SET        37860020
         DS    0D                  ROUND UP TO A DOUBLE WORD BOUNDARY   37870020
DATAEND  DS    0H                  END OF WORK DATA AREA                37900020
*                                                                     * 37950020
*********************************************************************** 38000020
         EJECT                                                          38050020
CVTD     DSECT                DSECT TO MAP COMMUNICATIONS VECTOR TABLE. 38100020
         CVT                                                            38150020
         EJECT                                                          38200020
UCBD     DSECT                DSECT TO MAP UNIT CONTROL BLOCK           38250020
         IEFUCBOB                                                       38300020
         EJECT                                                          38350020
JFCBD    DSECT                DSECT TO MAP JOB FILE CONTROL BLOCK       38400020
         IEFJFCBN                                                       38450020
         EJECT                                                          38500020
TIOTD    DSECT                DSECT FOR MAPPING TIOT ENTRY              38550020
         IEFTIOT1                                                       38600020
TIOTEND  EQU   *              END OF TIOT                               38650020
         EJECT                                                          38700020
         IEEBASEA                                                       38710020
         EJECT                                                          38720020
         DCBD  DSORG=DA,DEVD=DA                                         38750020
DCBEND   EQU   *                   END OF DCB                           38800020
DCBLNG   EQU   DCBEND-IHADCB       LENGTH OF DCB TO USE IN GETMAIN      38850020
*                                                                     * 38900020
*/*IEEVSND9:  END END OF IEEVSND9 */                                    38950020
         END                                                            39000020
