         TITLE 'IGG0196S - TS OPEN EXECUTOR'                            00100020
*                                                                       00200020
IGG0196S CSECT                                                          00300020
*                                                                       00400020
* RELEASE 23 DELETIONS/CHANGES                                        * 00430020
* RELEASE 22 DELETIONS/CHANGES                                        * 00460020
* RELEASE 21 DELETIONS/CHANGES                                        * 00490020
*                                                                     * 00520020
*0000215016,215044                                               TS2495 00530020
*                                                                M3415  00540020
*                                                                M3504  00545020
*                                                                M4324  00547020
*                                                                M1565  00547520
*                                                                M2307  00548020
*                                                                 M5005 00549020
*                                                                M5457  00549520
*STATUS CHANGE LEVEL 001                                                00550020
*                                                                     * 00580020
* NAME - IGG0196S, TS OPEN EXECUTOR                                   * 00610020
*                                                                     * 00640020
* FUNCTION - THIS ROUTINE OBTAINS CONTROL WHEN THE DCB BEING OPENED   * 00670020
*            IS A TERMINAL DEVICE AND THE TASK IS UNDER TIME SHARING. * 00700020
*            THE EXECUTOR PERFORMS THE FOLLOWING FUNCTIONS.           * 00730020
*                                                                     * 00760020
*          * FOR PUT LOCATE MODE, IT SET ON BIT 0 IN BYTE 0 IN BUFFER * 00790020
*            POOL CONTROL BLOCK TO SIGNAL IGG019T4 (TS PUT ROUTINE)   * 00820020
*            THAT THIS IS THE FIRST PUT                               * 00850020
*                                                                     * 00880020
*          * IT LOADS PROPER INTERFACE ROUTINE(S) FOR SAM AND TERMINAL* 00910020
*            I/O SVC                                                  * 00940020
*                                                                     * 00970020
* ENTRY POINTS - IGG0196S, BEGINNG OF ROUTINE. CONTROL IS RECEIVED    * 01000020
*                FROM IGG0196B OR IGG0191I VIA XCTL                   * 01030020
*                                                                     * 01060020
* INPUT - SEE DESCRIPTION OF REGISTERS                                * 01090020
*                                                                     * 01120020
* OUTPUT - PROPER INTERFACE ROUTINES LOADED                           * 01150020
*                                                                     * 01180020
* EXTERNAL REFERENCE - NONE                                           * 01210020
*                                                                     * 01240020
* EXIT, NORMAL - TO OPEN MODULE, IGG0190S VIA XCTL                    * 01270020
*                                                                     * 01300020
* EXIT, ERROR - NONE                                                  * 01330020
*                                                                     * 01360020
* TABLE/WORK AREAS - WHERE-TO-GO TABLE (WTG)                          * 01390020
*                                                                     * 01420020
*      BYTE  0-7  NAME                                                * 01450020
*      BYTE  8-10 RELATIVE DISK ADDRESS(TTR) OF FIRST RECORD          * 01480020
*      BYTE 11    CONCATENATION NUMBER                                * 01510020
*      BYTE 12    ZERO                                                * 01540020
*      BYTE 13    ALIAS INDICATOR AND USER DATA FIELD DESCRIPTOR      * 01570020
*                        ALIAS 1 BIT                                  * 01600020
*                        NUMBER OF TTRS IN USERS DATA FIELD 2 BITS    * 01630020
*      BYTE 14-16 TTR OF FIRST TEXT RECORD                            * 01660020
*      BYTE 17    ZERO                                                * 01690020
*      BYTE 18-19 TTR OF NOTE LIST OR SCATTER LIST                    * 01720020
*      BYTE 20    TRANSLATION TABLE                                   * 01750020
*      BYTE 21    ZERO NUMBER OF ENTRIES IN THE NOTE LIST             * 01780020
*      BYTE 22-23 ATTRIBUTES                                          * 01810020
*      BYTE 24-26 TOTAL CONTIGIOUS MAIN STORAGE REQUIRED FOR MODULE   * 01840020
*      BYTE 27-28 LENGTH OF FIRST TEXT RECORD                         * 01870020
*      BYTE 29    LENGTH OF WHERE-TO-GO TABLE (IN DOUBLE WORDS)       * 01900020
*      BYTE 30-31 PATH THROUGH LOADS OF ROUTINES                      * 01930020
*      BYTE 32-34 IDTTR OF EXECUTOR FOR FIRST DCB                     * 01960020
*      BYTE 35    ADDRESS OF STORAGE FOR DCB                          * 01990020
*      BYTE 36-39 TABLE OF IDTTR'S                                    * 02020020
*      BYTE 32+N(8) IDTTR OF EXECUTOR FOR NEXT DCB (3 BYTES)          * 02050020
*                   ADDRESS OF STORAGE FOR DCB     (1 BYTE)           * 02080020
*                   IDTTR OF LAST ROUTINE LOADED   (3 BYTES)          * 02110020
*                   NOT USED                       (1 BYTE)           * 02140020
*                                                                     * 02170020
*      OPEN WORK AREA - SEE IECDSECT IN THIS LISTING                  * 02200020
*                                                                     * 02230020
* ATTRIBUTES - REENTRANT, REUSABLE, SUPERVISOR MODE                   * 02260020
*                                                                     * 02290020
* CHARACTER CODE DEPENDENCY -                                         * 02320020
*                                                                     * 02350020
* NOTES -                                                             * 02380020
*                                                                     * 02410020
*********************************************************************** 03200020
*                                                                       03300020
*                                                                       03400020
*********************************************************************** 03500020
*                                                                       03600020
*   REGISTER CONVENTIONS USED THROUGH OUT OPEN EXECUTORS                03700020
*                                                                       03800020
*********************************************************************** 03900020
*                                                                       04000020
RE       EQU   0                        WORK/PARAMETER REGISTER         04100020
RF       EQU   1                        WORK/PARAMETER REGISTER         04200020
RDCB     EQU   2                        ADDR OF USERS DCB               04300020
RBASE    EQU   3                        BASE REGISTER                   04400020
RCORE    EQU   4                        ADDR OF OPEN WORK AREA          04500020
RPAR     EQU   5                        PARAMTER LIST                   04600020
RWTG     EQU   6                        START OF WTG                    04700020
RPARC    EQU   7                        CURRENT ENTRY IN PARAMETER LIST 04800020
RWTGC    EQU   8                        CURRENT ENTRY IN WTG TABLE      04900020
RTIOT    EQU   9                        TIOT ADDR/WORK REGISTER         05000020
RUCB     EQU   10                       UCB ADDR                        05100020
RDEB     EQU   11                       DEB ADDR                        05200020
RA       EQU   11                       WORK REGISTER                   05250020
RB       EQU   12                       WORK AREA BASE REGISTER         05300020
RC       EQU   13                       WORK REGISTER                   05400020
RD       EQU   14                       WORK/PARAMETER REGISTER         05500020
RJ       EQU   15                       WORK/PARAMETER REGISTER         05600020
*                                                                       05700020
*********************************************************************** 05800020
*                                                                       05900020
*                                                                       06000020
*********************************************************************** 06100020
*                                                                       06200020
*   EQUATES                                                             06300020
*                                                                       06400020
*********************************************************************** 06500020
*                                                                       06600020
NULL     EQU   0                        CONSTANT='0'                    06700020
ONE      EQU   1                        CONSTANT='1'                    06800020
TWO      EQU   2                        CONSTANT='2'                    06900020
THREE    EQU   3                        CONSTANT=3                      07000020
FOUR     EQU   4                        CONSTANT='4'                    07100020
FIVE     EQU   5                        CONSTANT='5'                    07150020
SIX      EQU   6                        CONSTANT=6                      07200020
MSK08    EQU   X'08'                    MASK FOR QSAM/LOCATE            07300020
MSK14    EQU   14                       CONSTANT =14                    07400020
MSK24    EQU   24                       CONSTANT=24                     07500020
MSK25    EQU   25                       CONSTANT=25                     07600020
MSK27    EQU   27                       CONSTANT=27                     07650020
PARMLNGH EQU   16                       LENGTH OF PARM LIST=16          07700020
MSK48    EQU   X'48'                    MASK FOR V/S RECORD             07800020
QSAMLOCT EQU   X'48'                    MACRF=PL OR GL                  07900020
NOTONES  EQU   14                       'BC 14' FOR TEST UNDER MASK     08000020
SETLOCAT EQU   X'01'                    LOCATE MODE                     08100020
QSAMODE  EQU   X'01'                    MACRF=WSAM                      08200020
GETREAD  EQU   X'60'                    MACRF=INPUT                     08300020
INPUTEDT EQU   X'09'                    TGET AND IEDIT                  08400020
OUTPTEDT EQU   X'12'                    TPUT AND OEDIT                  08500020
READMODE EQU   X'20'                    READ OR WRITE                   08600020
POINTMD  EQU   X'04'                    NOTE/POINT IS SPECIFIED         08700020
CNTRLMD  EQU   X'02'                    CNTRL IS SPECIFIED              08800020
GETMODE  EQU   X'40'                    QSAM/GET                        08900020
UNDEFINE EQU   X'C0'                    RECFM=U                         09000020
FIXED    EQU   X'80'                    DCBRECFM=F                      09100020
BLKSIMRG EQU   X'10'                    BLKSI HAS BEEN MERGED           09110020
LRECLMRG EQU   X'80'                    LRECL HAS BEEN MERGED           09120020
RECFMMRG EQU   X'04'                    RECFM HAS BEEM MERGED           09150020
FIRSTPT  EQU   X'80'                    FIRST PUT IN PUT LOCATE MODE    09200020
MSK7     EQU   7                        CONSTANT = 7                    09300020
MSK22    EQU   22                       CONSTANT = 22                   09400020
WGOFF    EQU   8                        OFFSET TO CURRENT WTG ENTRIES   09500020
PLOFF    EQU   4                        OFFSET TO CURRENT DCB ENTRIES   09600020
WAOFF    EQU   32                       OFFSET TO 1ST ENTRY IN WTG TBL  09700020
DEBPRFX  EQU   16                       SIZE OF DEB PREFIX              09750020
NMXD     EQU   X'09'                                                    09800020
MSK04    EQU   X'04'                                                    09900020
MSK0E    EQU   X'0E'                                                    10000020
*                                                                       10100020
*********************************************************************** 10200020
*                                                                       10300020
*   REGISTER INITIALIZATION                                             10400020
*                                                                       10500020
*********************************************************************** 10600020
*                                                                       10700020
         BALR  RBASE,NULL               ESTABLISH BASE REGISTER         10800020
         USING GOGOGOGO,RBASE           START AT 'GOGOGOGO'             10900020
         USING IHADCB,RDCB              ESTABLISH DCB REG.              11000020
         USING FORCORE,RCORE            ESTABLISH OPEN WORK AREA        11100020
         USING DEB,RDEB                 ESTABLISH DEB REG.              11200020
         USING CVT,RTIOT                ESTABLISH CVT REG.              11300020
         USING TCB,RD                                                   11350020
*                                                                       11400020
*********************************************************************** 11500020
*                                                                       11600020
*                                                                       11700020
*********************************************************************** 11800020
*                                                                       11900020
GOGOGOGO EQU   *                                                        12000020
*                                                                       12100020
*********************************************************************** 12200020
*                                                                       12300020
         L     RDCB,NULL(RPARC)         GET DCB ADDR                    12400020
         L     RCORE,FOUR(RWTGC)        GET WORK AREA                   12500020
         L     RTIOT,CVTPTR             LOAD CVT ADDR                   12650020
*                                                                       12652020
*  CHECK IF DCBBLKSI AND DCBLRECL ARE SPECIFIED. IF BOTH ARE            12654020
*  NOT THERE, DEFAULT WITH TERMINAL LINE SIZE WHEN IT IS SMALLER THAN   12656020
*  BUFFER LENGTH. WHEN DCBBUFL IS SMALLER THAN TERMINAL LINE SIZE,      12658020
*  THE FORMER WILL BE USED AS BLOCK SIZE AND LRECL                      12660020
*                                                                       12662020
         LH    RA,DCBBLKSI              GET BLOCK SIZE                  12664020
         LTR   RA,RA                    IS IT SPECIFIED                 12666020
         BNZ   OP6050                   BRANCH IF YES                   12668020
         LH    RA,DCBLRECL              GET LRECL                       12670020
         LTR   RA,RA                    IS IT SPECIFIED                 12672020
         BZ    OP6060                   BRANCH IF NO                    12674020
         STH   RA,DCBBLKSI              USE LRECL AS BLOCK SIZE         12676020
         OI    JFCBMASK+TWO,BLKSIMRG    INDICATE BLKSI MERGED           12678020
         B     OP5666                   GO TO CHECK RECFM               12680020
OP6050   EQU   *                                                        12682020
         LH    RF,DCBLRECL              GET LRECL                       12684020
         LTR   RF,RF                    IS IT SPECIFIED                 12686020
         BNZ   OP5666                   BRANCH IF YES                   12688020
         STH   RA,DCBLRECL              USE BLOCK SIZE AS LRECL         12690020
         OI    JFCBMASK+TWO,LRECLMRG    INDICATE LRECL MERGED           12692020
         B     OP5666                   GO TO CHECK RECFM               12694020
*                                                                       12696020
*  GET TERMINAL LINE SIZE FROM TSB                                      12698020
*                                                                       12700020
OP6060   EQU   *                                                        12702020
         L     RD,CVTTCBP               GET ADDR OF TCB WORD            12704020
         L     RD,FOUR(,RD)             GET ADDR OF CURRENT TCB         12706020
         L     RF,TCBJSCB               GET JSCB ADDRESS                12708020
         USING IEZJSCB,RF                                               12710020
         LH    RF,JSCBTJID              GET TJID                        12712020
         BCTR  RF,RE                    DECREMENT TJID BY 1             12714020
         L     RB,CVTTSCVT              GET TSCVT ADDR                  12716020
         USING TSCVT,RB                                                 12718020
         L     RB,TSCVTRPT              GET TIOCRPT ADDR                12720020
         DROP  RB                                                       12722020
         USING TIOCRPT,RB                                               12724020
         SR    RE,RE                    CLEAR REGISTER                  12726020
         IC    RE,TIOCTSBS              GET TSB SIZE                    12728020
         MR    RE,RE                    GET OFFSET TO TSB TABLE         12730020
         L     RE,TIOCTSB-ONE           LOAD TSB TABLE ADDR             12732020
         AR    RF,RE                    GET TSB ADDRESS                 12734020
         USING TSB,RF                                                   12736020
         IC    RA,TSBLNSZ               GET TERMINAL LINE SIZE          12738020
         LH    RF,DCBBUFL               GET BUFFER LENGTH               12740020
         LTR   RF,RF                    IS IT SPECIFIED                 12742020
         BZ    OP6070                   BRANCH IF NO                    12744020
         CR    RA,RF                    IS TERMINAL LINE SIZE           12746020
*                                       LARGER THAN BUFFER LENGTH       12748020
*                                                                       12750020
*  IF BUFFER LENGTH IS LARGER THAN TERMINAL LINE SIZE, DEFAULT WITH     12752020
*  THE LATTER, OTHERWISE, DEFAULT WITH THE FORMER.                      12754020
*                                                                       12756020
         BH    OP6080                   BRANCH IF YES                   12758020
OP6070   EQU   *                                                        12760020
         STH   RA,DCBBLKSI              DEFAULT BLOCK SIZE              12762020
         STH   RA,DCBLRECL              DEFAULT LRECL                   12764020
         OI    JFCBMASK+TWO,BLKSIMRG+LRECLMRG                           12766020
*                                       SET MERGE MASK                  12768020
         B     OP5666                   GO TO CHECK RECFM               12770020
OP6080   EQU   *                                                        12772020
         LR    RA,RF                    GET BUFFER LENGTH               12774020
         B     OP6070                   DEFAULT BLOCK SIZE              12776020
OP5666   EQU   *                                                        12778020
*                                                                       12788020
*  CHECK WHETHER DCBRECFM IS SPECIFIED, IF NOT, DEFAULT TO FIXED        12800020
*                                                                       12900020
         L     RDEB,DCBDEBAD            GET DEB ADDR                    12920020
         MVC   DEBBLKSI,DCBBLKSI        SAVE BLKSI IN DEB               12940020
         MVC   DEBLRECL,DCBLRECL        SAVE LRECL IN DEB               12960020
         CLI   DCBRECFM,NULL            CHECK RECFM IS SPECIFIED        13000020
         BNE   TSEX010                  BRANCH IF YES                   13100020
         MVI   DCBRECFM,FIXED           DEFAULT TO FIXED                13200020
         OI    JFCBMASK+TWO,RECFMMRG    SET MERGE MASK                  13300020
*                                                                       13900020
*********************************************************************** 14000020
*                                                                       14100020
*   LOAD APPROPRIATE SAM ACCESS METHOD ROUTINE AND INITIALIZE FIELDS    14200020
*   IN THE DCB                                                          14300020
*                                                                       14400020
*********************************************************************** 14500020
*                                                                       14600020
*   DETERMINE ACCESS MODE AND LOAD PROPER ROUTINE                       14700020
*                                                                       14800020
TSEX010  EQU   *                                                        14850020
         SR    RJ,RJ                    RESET RJ TO '0'                 14900020
         IC    RJ,DEBAMLNG              INSERT A.M. LENGTH              15000020
         LA    RUCB,32(RJ,RDEB)         LOAD DEB OFFSET                 15100020
         IC    RJ,DEBNMEXT              INSERT NO. OF EXTENT            15200020
         SLL   RJ,2                     MULTIPLY EXTENT BY '4'          15300020
         AR    RUCB,RJ                  NOW RUCB POINT TO DEBSUBID      15400020
*                                                                       15500020
*                                                                       16100020
         TM    DCBCIND2,QSAMODE         TEST IF BSAM OR QSAM            16200020
         BO    TSEX050                  QSAM,GOTO CHECK PUT OR GET      16300020
*                                                                       16400020
*                                                                       16500020
*                                                                       17300020
*   TEST OPEN FOR INOUT,OUTIN OR UPDAT                                  17400020
*                                                                       17500020
TSEX042  EQU   *                                                        17550020
         TM    DEBOPATB,MSK0E           TEST FOR INOUT,OUTIN,UPDAT      17600020
         BC    NMXD,TSEX041             NO,GOTO CHECK READ OR WRITE     17700020
*                                                                       17800020
*   WHEN OPEN FOR INOUT,OUTIN OR UPDAT LOAD COMBINED READ/WRITE ROUTINE 17900020
*                                                                       18000020
         LA    RJ,RDWRRTN                LOAD ADDR OF READ/WRITE RTN ID 18100020
*                                                                       18200020
         B     TSEX070                   GOTO LOAD SUB RTN              18300020
*                                                                       18400020
TSEX041  EQU   *                                                        18500020
*                                                                       18600020
         TM    DEBOPATB,MSK0E           TEST IF READ IS SPECIFIED       18700020
         BNZ   TSEX060                  NO,GOTO LOAD WRITE ROUTINE      18800020
*                                                                       18900020
         LA    RJ,READRTN               LOAD ADDR OF READ RTN ID        19000020
         B     TSEX070                  GOTO,BRANCH TO LOAD ROUTINE     19100020
*                                                                       19200020
TSEX060  EQU   *                                                        19300020
*                                                                       19400020
         LA    RJ,WRITERTN              LOAD ADDR OF WRITE RTN ID       19500020
*                                                                       19600020
TSEX070  EQU   *                                                        19700020
*                                                                       19800020
         BAL   RD,TSEX900               GOTO LOAD ROUTINE               19900020
         MVC   DCBRTNAD(THREE),MSK25(RWTG)   STORE RTN ADDR IN DCB      20000020
*                                                                       20100020
TSEX080  EQU   *                                                        20200020
*                                                                       20300020
         TM    DCBMACRF,CNTRLMD         IS CONTROL SPECIFIED FOR INPUT  20310020
         BO    TSEX020                  BRANCH IF YES                   20320020
         TM    DCBMACRF+1,CNTRLMD       IS CONTROL SPECIFIED FOR OUTPUT 20330020
         BNO   TSEX025                  BRANCH IF NO                    20340020
TSEX020  EQU   *                                                        20350020
*                                                                       20360020
*   LOAD CONTROL ROUTINE                                                20370020
*                                                                       20380020
         LA    RJ,CNTRLRTN              LOAD ADDR OF CNTRL ROUTINE ID   20390020
         BAL   RD,TSEX900               GO TO LOAD ROUTINE              20400020
         MVC   DCBCNTRL+1(THREE),MSK25(RWTG)                            20410020
*                                       STORE CNTRL ROUTINE ADDR IN DCB 20420020
         B     TSEX030                  GO TO LOAD CHECK ROUTINE        20430020
TSEX025  EQU   *                                                        20440020
         TM    DCBMACRF,POINTMD         IS NOTE/POINT SPECIFIED         20446020
*                                       FOR INPUT                       20452020
         BO    TSEX035                  BRANCH IF YES                   20460020
         TM    DCBMACRF+1,POINTMD       IS NOTE/POINT SPECIFIED FOR     20466020
*                                       OUTPUT                          20472020
         BNO   TSEX030                  GO TO LOAD CHECK ROUTINE        20480020
TSEX035  EQU   *                                                        20490020
*                                                                       20500020
*   LOAD NOTE/POINT ROUTINE                                             20510020
*                                                                       20520020
         LA    RJ,NTPTRTN               LOAD ADDR OF NOTE-POINT RTN ID  20530020
         BAL   RD,TSEX900               GO TO LOAD ROUTINE              20540020
         MVC   DCBPOINT+1(THREE),MSK25(RWTG)                            20550020
*                                       STORE NOTE-POINT RTN ADDR       20560020
TSEX030  EQU   *                                                        20570020
*                                                                       20580020
*   LOAD CHECK ROUTINE                                                  20590020
*                                                                       20600020
         LA    RJ,CHECKRTN              LOAD ADDR OF CHECK RTN ID       20610020
         BAL   RD,TSEX900               GO TO LOAD ROUTINE              20620020
         MVC   DCBCKADR(THREE),MSK25(RWTG)                              20630020
*                                       STORE CHECK RTN ADDRESS         20640020
*                                                                       20700020
         B     TSEX090                  GOTO CHECK WTG TABLE ROUTINE    20800020
*                                                                       20900020
*********************************************************************** 21000020
*                                                                       21100020
TSEX050  EQU   *                                                        21200020
*                                                                       21300020
*   QSAM IS SPECIFIED                                                   21400020
*                                                                       21500020
*********************************************************************** 21500420
*                                                                     * 21500820
*  TEST FOR LOCATE MODE, IF SO PUT BUFFER ADRESS IN DCBRECAD, PUT     * 21501020
*  BUFFER ADDRESS PLUS LOGICAL RECORD LENGTH IN DCBEOBAD. IF          * 21501220
*  PUT/LOCATE IS SPECIFIED, TURN ON BIT 0 OF BYTE 0 IN BUFFER POOL    * 21501420
*  CONTROL BLOCK TO INDICATE FIRST PUT.                               * 21501620
*                                                                     * 21502020
*********************************************************************** 21502420
*                                                                       21502820
         TM    DCBMACRF,QSAMLOCT        TEST FOR GET/LOCATE             21510820
         BO    TSEX001                  BRANCH IF YES                   21518820
         TM    DCBMACRF+1,QSAMLOCT      TEST FOR PUT/LOCATE             21526820
         BNO   TSEX040                  BRANCH IF NOT                   21534820
TSEX001  EQU   *                                                        21542820
         L     RD,DCBBUFNO              GET ADDR OF BUFCB               21550820
         L     RD,NULL(RD)              GET ADDR OF FIRST BUFFER        21558820
         ST    RD,DCBRECAD              PUT ADDR OF BUFFER IN DCB       21566820
         AH    RD,DCBLRECL              ADD LENGTH OF RECORD            21574820
         ST    RD,DCBEOBAD              PUT EOB ADDRESS IN DCB          21582820
         TM    DCBMACRF+1,QSAMLOCT      TEST FOR PUT/LOCATE             21590820
         BNO   TSEX040                  BRANCH IF NOT                   21598820
         L     RD,DCBBUFNO              GET ADDR OF BUFCB               21606820
         OI    NULL(RD),FIRSTPT         TURN ON FLAG FOR FIRST PUT      21614820
         SPACE 3                                                        21624920
TSEX040  EQU   *                                                        21644920
*                                                                       21664920
*   TEST IF DCB IS OPEND FOR UPDATE                                     21700020
*                                                                       21800020
         TM    DEBOPATB,MSK0E           TEST IF DCB IS OPENED FOR UPDAT 21900020
         BC    NMXD,TSEX051             NO,GOTO CHECK PUT OR GET        22000020
*                                                                       22100020
         LA    RJ,GTPTRTN                LOAD ADDR OF GET/PUT RTN ID    22200020
         B     TSEX110                  GO TO LOAD ROUTINE              22300020
*                                                                       22400020
TSEX051  EQU   *                                                        22500020
*                                                                       22600020
         TM    DEBOPATB,MSK0E           TEST IF GET IS SPECIFIED        22700020
         BNZ   TSEX100                  NO, GO TO LOAD PUT RTN          22800020
*                                                                       22900020
         LA    RJ,GETRTN                LOAD ADDR OF GET RTN ID         23000020
*                                                                       23020020
*   FOR VARIABLE SPANNED RECORD, SAVE BLOCK SIZE IN DEB IF IT           23040020
*   IS SMALLER THAN LRGCL                                               23060020
*                                                                       23080020
TSEX057  EQU   *                                                        23100020
         TM    DCBRECFM,MSK48           TEST FOR V/S TYPE RECORD        23300020
         BNO   TSEX110                  BRANCH IF NO                    23400020
         TM    DCBMACRF,MSK08           TEST FOR GET/LOCATE MODE        23500020
         BNO   TSEX110                  BRANCH IF NO                    23600020
         LH    RC,DCBBLKSI              LOAD BLOCK SIZE                 23700020
         DROP  RD                                                       23900020
         USING BUFCB,RD                                                 24100020
         CH    RC,BUFL                  BLOCK SIZE BIGGER THAN BFR      24300020
*                                       LENGTH                          24400020
         BNH   TSEX056                  BRANCH IF NOT                   24500020
         LH    RC,BUFL                  GET BFR ELNGTH                  24600020
TSEX056  EQU   *                                                        24700020
         CH    RC,DEBLRECL              IS BLOCK SIZE BIGGER THAN LRECL 24800020
         BNL   TSEX110                  BRANCH IF YES                   24900020
         STH   RC,DEBLRECL              SAVE BLOCK SIZE IN DEB          25000020
         B     TSEX110                  GOTO,BRANCH TO LOAD ROUTINE     25200020
*                                                                       25300020
TSEX100  EQU   *                                                        25400020
*                                                                       25500020
         LA    RJ,PUTRTN                LOAD ADDR OF PUT RTN ID         25600020
*                                                                       25700020
TSEX110  EQU   *                                                        25800020
*                                                                       25900020
         BAL   RD,TSEX900               GOTO LOAD ROUTINE               26000020
         MVC   DCBRTNAD(THREE),MSK25(RWTG)   STORE RTN ADDR IN DCB      26100020
*                                                                       26200020
*                                                                       26240020
*   TEST CNTRL IS SPECIFIED, IF YES, LOAD CONTROL ROUTINE               26280020
*                                                                       26320020
         TM    DCBMACRF,CNTRLMD         IS CONTROL SPECIFIED FOR INPUT  26360020
         BO    TSEX054                  BRANCH IF YES                   26400020
         TM    DCBMACRF+1,CNTRLMD       IS CONTROL SPECIFIED FOR OUTPUT 26440020
         BNO   TSEX090                  BRANCH IF NO                    26480020
*                                                                       26520020
TSEX054  EQU   *                                                        26560020
         LA    RJ,CNTRLRTN              LOAD ADDR OF CNTRL RTN ID       26600020
         BAL   RD,TSEX900               GO TO LOAD ROUTINE              26640020
         MVC   DCBCNTRL+1(THREE),MSK25(RWTG)                            26680020
*                                       STORE CNTRL RTN ADDR IN DCB     26720020
*                                                                       26760020
         B     TSEX090                  GOTO CHECK WTG TABLE ROUTINE    26800020
*                                                                       26900020
*                                                                       27000020
*********************************************************************** 27100020
*                                                                       27200020
TSEX900  EQU   *                                                        27300020
*                                                                       27400020
*********************************************************************** 27500020
*                                                                       27600020
*   LOAD SAM SUBROUTINE ROUTINE                                         27700020
*                                                                       27800020
*********************************************************************** 27900020
*                                                                       28000020
         MVC   NULL(TWO,RUCB),NULL(RJ)  STORE ROUTINE ID IN DEB         28100020
         LA    RUCB,TWO(RUCB)           INCREMENT RUCB BY '2'           28200020
         MVC   MSK14(THREE,RWTG),TWO(RJ)                                28208020
*                                       MOVE TTR TO DE                  28216020
         MVC   SIX(TWO,RWTG),NULL(RJ)   MOVE 2 BYTE ID TO DE            28224020
         SR    RF,RF                    CLEAR REGISTER                  28232020
         IC    RF,FIVE(RJ)              LOAD DOUBLE WORD LENGTH         28240020
         SLL   RF,THREE                 MUPY BY 8 FOR BYTE LENGTH       28248020
         ST    RF,MSK24(RWTG)           TEMP STORE FOR LENGTH           28256020
         MVC   MSK24(THREE,RWTG),MSK25(RWTG)                            28264020
*                                       STORE 3 BYTE TOTAL LENGTH       28272020
         MVC   MSK27(TWO,RWTG),MSK25(RWTG)                              28280020
*                                       STORE 2 BYTE TEXT LENGTH        28288020
*                                                                       28300020
*   OBTAIN DCB FOR SYS1.SVCLIB                                          28400020
*                                                                       28500020
         L     RF,CVTSVDCB              LOAD ADDR OF SYS1.SVCLIB DCB    28600020
*                                                                       28700020
         LOAD  DE=(RWTG),DCB=(1)        LOAD THE ROUTINE                28800020
*                                                                       28900020
         ST    RE,MSK24(RWTG)           SAVE ADDR OF ROUTINE TEMPORARLY 29000020
*                                                                       29100020
         SR    RJ,RJ                                                    29200020
         IC    RJ,DEBNMSUB              LOAD NO. OF SUBROUTINE          29300020
         LA    RJ,ONE(RJ)               INCREMENT NO. BY '1'            29400020
         STC   RJ,DEBNMSUB              UPDATE NO. OF SUBROUTINE        29500020
*                                                                       29600020
         BR    RD                       GO BACK TO ENTRY POINT          29700020
*                                                                       29800020
*                                                                       29900020
*********************************************************************** 30000020
*                                                                       30100020
*********************************************************************** 30200020
*                                                                       30300020
*                                                                       30400020
TSEX090  EQU   *                                                        30500020
*                                                                       30700020
         MVI   NULL(RWTGC),NULL         SET TO GO OUT FROM SAM EXECUTOR 30800020
*                                                                       30900020
*********************************************************************** 31000020
*                                                                       31100020
RELOOP   EQU   *                                                        31200020
*                                                                       31300020
*********************************************************************** 31400020
*                                                                       31500020
*   UPDATES WHERE-TO-GO TABLE AND XCTL TO NEXT MODULE                   31600020
*                                                                       31700020
*********************************************************************** 31800020
*                                                                       31900020
         LA    RWTGC,WGOFF(NULL,RWTGC)  INCREMENT CURRENT WTG ENTRY     32000020
         LA    RPARC,PLOFF(NULL,RPARC)  INCREMENT CURRENT DCB ENTRY     32100020
         CLC   NULL(TWO,RWTGC),AMIDCNST IS THE RTN NEEDED AGAIN         32200020
         BE    GOGOGOGO                 YES,RETURN TO THE BEGINNING     32300020
*                                                                       32400020
         CLC   NULL(TWO,RWTGC),OPIDCNST TEST END OF WTG TABLE           32500020
         BNE   RELOOP                   NO,CHECK NEXT ENTRY             32600020
*                                                                       32700020
         LR    RPARC,RPAR               RESET REG. TO '0'               32800020
         LA    RWTGC,WAOFF(NULL,RWTG)   RESET WTG REG TO PT +32(WTG)    32900020
*                                                                       33000020
ZCHECK   EQU   *                                                        33100020
*                                                                       33200020
         CLI   NULL(RWTGC),NULL         TEST IF THIS ENTRY IS COMPLETE  33300020
         BNE   TCTLRTN                  NO,GOTO XCTL                    33400020
*                                                                       33500020
         LA    RWTGC,WGOFF(NULL,RWTGC)  GET NEXT ENTRY OF WTG TABLE     33600020
         LA    RPARC,PLOFF(NULL,RPARC)  GET NEXT ENTRY OF DCB           33700020
         B     ZCHECK                   GOTO TEST COMPLETION            33800020
*                                                                       33900020
TCTLRTN  EQU   *                                                        34000020
*                                                                       34100020
         MVC   SIX(TWO,RWTG),NULL(RWTGC)     STORE ID IN WTG TABLE      34200020
         MVC   MSK14(THREE,RWTG),TWO(RWTGC)  MOVE TTR INTO TABLE        34300020
         MVC   MSK22(MSK7,RWTG),RESTCON RESET WTG AFTER LOAD            34400020
*                                                                       34500020
         LA    RJ,DXCCW12                                               34600020
*                                                                       34700020
         XCTL  DE=(RWTG),SF=(E,(15))    XCTL TO NEXT MODULE             34800020
*                                                                       34900020
*                                                                       35000020
*                                                                       35100020
*********************************************************************** 35200020
*                                                                       35300020
*********************************************************************** 35400020
*                                                                       35500020
*   CONSTANTS                                                           35600020
*                                                                       35700020
*********************************************************************** 35800020
*                                                                       36800020
*   FOR WTG TABLE                                                       36900020
*                                                                       37000020
OPIDCNST DC    C'0S'                    LAST MODULE OF OPEN             37100020
AMIDCNST DC    C'6S'                    THIS MODULE                     37200020
WTGCNST  DC    C'IGG019  '              OPEN ROUTINE ID                 37300020
RESTCON  DC    X'C3780004000400'        LOAD ATTRIBUTES                 37400020
*                                                                       37500020
*                                                                       37600020
*********************************************************************** 37700020
*                                                                       37800020
*   XCTL TABLE                                                          37900020
*                                                                       38000020
*********************************************************************** 38100020
*                                                                       38200020
XCTLTABL DS    0D                       START OF XCTL TABLE             38230020
GETRTN   DC    C'T3',4X'0'              ID, TTRL                        38260020
PUTRTN   DC    C'T4',4X'0'              ID, TTRL                        38290020
RDWRRTN  DC    C'T5',4X'0'              ID, TTRL                        38320020
GTPTRTN  DC    C'T6',4X'0'              ID, TTRL                        38350020
READRTN  DC    C'T7',4X'0'              ID, TTRL                        38380020
WRITERTN DC    C'T8',4X'0'              ID, TTRL                        38410020
CHECKRTN DC    C'TX',4X'0'              ID, TTRL                        38440020
NTPTRTN  DC    C'TY',4X'0'              ID, TTRL                        38470020
CNTRLRTN DC    C'TZ',4X'0'              ID, TTRL                        38500020
END      DC    2X'0'                    END OF TABLE                    38530020
LAST     EQU   *                                                        38560020
         ORG   IGG0196S+1020            ALIGN MODULE TO 1 K             38590020
UNUSED   EQU   *-LAST                                                   38620020
         DC    C'019'                   SVC ID                          38650020
         DC    AL1((XCTLTABL-IGG0196S)/8)                               38680020
*                                       XCTL TABLE LOCATION ON DOUBLE   38720020
*                                       WORD                            38760020
*                                                                       38800020
*                                                                       38900020
*********************************************************************** 39000020
*                                                                       39100020
*   DCB DSECT                                                           39200020
*                                                                       39300020
*********************************************************************** 39400020
*                                                                       39500020
         DCBD  DSORG=PS                                                 39600020
*                                                                       39700020
DCBRTNAD EQU   DCBREAD+1                SAM RTN ADDR                    39800020
DCBPTADR EQU   DCBPOINT+1               ADDR OF DCB POINT/CNTRL RTN     39900020
DCBCKADR EQU   DCBCHECK+1               ADDR OF DCB CHECK RTN           40000020
DCBBLKSZ EQU   DCBBLKSI+1               DCB BLKSIZE                     40100020
DCBLRCL2 EQU   DCBLRECL+1               DCB LRECL+1                     40200020
*                                                                       40300020
*********************************************************************** 40400020
*                                                                       40500020
*   OPEN WORK AREA DSECT                                                40600020
*                                                                       40700020
*********************************************************************** 40800020
*                                                                       40900020
FORCORE  DSECT                                                          41000020
*                                                                       41100020
         IECDSECT                                                       41200020
*                                                                       41300020
*                                                                       41306020
*                                                                       41390020
*********************************************************************** 41400020
*                                                                       41500020
*   DEB DSECT                                                           41600020
*                                                                       41700020
*********************************************************************** 41800020
*                                                                       41900020
*                                                                       42000020
DEB      DSECT                          THIS DSECT DESCRIBES A DEB      42100020
DEBNMSUB DS    0CL1                    NO. OF SUB RTNS                  42200020
DEBTCBAD DS    CL4                     TASK CONTROL BLOCK ADDR          42300020
DEBAMLNG DS    0CL1                    LENGTH OF ACCESS METHOD SEC      42400020
DEBDEBAD DS    CL4                     ADDR OF NEXT DEB IN DEB CHAIN    42500020
DEBOFLGS DS    0CL1                    DEB OPEN FLAGS                   42600020
DEBIRBAD DS    CL4                     ADDR OF THE IRB CONTROL BLOCK    42700020
DEBOPATB DS    0CL1                    OPEN ATRIBUTES                   42800020
DEBSYSPG DS    CL4                     SYSTEM PURGE FIELD               42900020
DEBNMEXT DS    0CL1                    NUMBER OF EXTENTS IN DEB         43000020
DEBUSRPG DS    CL4                     USER PURGE FIELD                 43100020
DEBPRIOR DS    0CL1                    INFO BYTE                        43200020
DEBECBAD DS    CL4                     EVENT CONTROL BLOCK ADDR         43300020
DEBPROTG DS    0CL1                    INFO BYTE                        43400020
DEBDEBID DS    0CL1                    INFO BYTE                        43500020
DEBDCBAD DS    CL4                     ADDR OF DCB                      43600020
DEBEXSCL DS    0CL1                    SCALING FACTOR OF DEB EXTENT     43700020
DEBAPPAD DS    CL4                     APPENDAGE TABLE ADDR             43800020
DEBDVMOD DS    0CL1                    DEVICE MODIFIER BYTE             43900020
DEBUCBAD DS    CL4                     UNIT CTL BLOCK ADDR              44000020
DEBVOLSQ DS    CL2                      VOLUME SEQUENCE NUMBER          44010020
DEBVOLNM DS    CL2                      NUMBER OF VOLUME                44020020
         DS    CL8                                                      44030020
DEBBLKSI DS    CL2                      BLOCK SIZE SAVE AREA            44040020
DEBLRECL DS    CL2                      LRECL SAVE AREA                 44050020
*  FOR EACH SUBROUTINE LOADED BUMP THIS OFFSET BY 2                     44100020
DEBSUBID DS    H                       SUBROUTINE ID ( 2 BYTES )        44200020
*                                                                       44300020
*                                                                       44400020
*********************************************************************** 48500020
*                                                                       48600020
*   CVT DUMMY SECTION                                                   48700020
*                                                                       48800020
*********************************************************************** 48900020
*                                                                       49000020
CVT      DSECT                                                          49100020
*                                                                       49200020
         CVT                                                            49300020
**********************************************************************  49400020
*                                                                     * 49500020
*                  BUFFER POOL CONTROL BLOCK DSECT                    * 49600020
*                                                                     * 49700020
**********************************************************************  49800020
         DS    0F                                                       49900020
BUFCB    DSECT                                                          50000020
BUFAD    DS    CL4                                                      50100020
BUFNO    DS    CL2                                                      50200020
BUFL     DS    CL2                                                      50300020
         SPACE 3                                                        50309020
         IKJTCB                                                         50318020
         SPACE 3                                                        50327020
         IEZJSCB                                                        50336020
         SPACE 3                                                        50345020
         IKJTIOCP                                                       50354020
         SPACE 3                                                        50363020
         IKJTSCVT                                                       50372020
         SPACE 3                                                        50381020
         IKJTSB                                                         50390020
         END                                                            50400020
