         TITLE 'IGG09405 - STCOM ROUTINE'                               00700020
IGG09405 CSECT                                                          01400020
*********************************************************************** 02100020
*                                                                M5113  02400020
*                                                                     * 02800020
*                                                                 M5113 03000020
*    RELEASE 23 DELETIONS/CHANGES                                     * 03200020
*    RELEASE 22 DELETIONS/CHANGES                                     * 03400020
*    RELEASE 21 DELETIONS/CHANGES                                     * 03600020
*                                                                     * 03800020
* STATUS -                                                            * 04000020
*    CHANGE LEVEL 0                                                   * 04200020
*                                                                     * 04400020
* FUNCTION -                                                          * 04600020
*    THIS ROUTINE IS TO SERVE THE MACRO STCOM', WHICH IS USED         * 04800020
*    BY PROFILE COMMAND AND OTHER PROBLEM PROGRAMS TO SPECIFY WHETHER * 05600020
*    OR NOT THE USER WISHES TO RECEIVE INTER-TERMINAL COMMUNICATIONS. * 06300020
*    ONCE THE USER STOPS INTER-TERMINAL COMMUNICATIONS VIA ISSUANCE   * 07000020
*    OF THIS MACRO, ANY SUBSEQUENT TPUTS WITH TJID TO THIS TERMINAL   * 07700020
*    WILL BE IGNORED AND A RETURN CODE OF '0C' WILL BE PASSED BACK TO * 08400020
*    THE CALLER.                                                      * 09100020
*                                                                     * 09800020
*    INTERNALLY, THIS ROUTINE WILL SET ON BITS IN TSB (TSBJTOFF,      * 10500020
*    TSBNOMSG) IF THE USER SPECIFIES NO INTER-TERMINAL COMMUNICATIONS.* 11200020
*    OTHERWISE, THE ABOVE MENTIONED BITS IN TSB WILL BE ON.  THE      * 11900020
*    TSBJTOFF BIT WILL BE CHECKED BY TPUT IF THE TJID OPTION IS       * 12600020
*    SPECIFIED.                                                       * 13300020
*                                                                     * 14000020
* ENTRY POINTS -                                                      * 14500020
*         IGG09405 - CONTROL IS RECEIVED FROM MODULE IGC0009D VIA     * 15000020
*         XCTL ACCORDING TO THE ENTRY CODE 5                          * 15500020
*                                                                     * 16100020
* INPUT -                                                             * 16300020
*    REGISTER  3 HAS CVT ADDRESS                                      * 16500020
*    REGISTER  4 HAS TCB ADDRESS                                      * 16700020
*    REGISTER  5 HAS SVRB EXTENDED SAVE AREA ADDRESS                  * 16900020
*    REGISTER 11 HAS THE PARAMETERS                                   * 17100020
*                                                                     * 17500020
* OUTPUT -                                                            * 17900020
*    REGISTER 15 HAS RETURN CODE:                                     * 18300020
*           0 - SUCCESSFUL                                            * 18700020
*           4 - INVALID PARAMETER                                     * 19100020
*                                                                     * 19600020
* EXTERNAL REFERENCES -                                               * 20000020
*         NONE                                                        * 20400020
*                                                                     * 21000020
* EXITS, NORMAL -                                                     * 21100020
*         SVC 3 WITH 0 IN REGISTER 15                                 * 21200020
*                                                                     * 21300020
* EXITS, ERROR -                                                      * 21400020
*         SVC 3 WITH 4 IN REGISTER 15                                 * 21500020
*                                                                     * 21600020
* TABLES/WORK AREAS -                                                 * 21700020
*    CONTROL BLOCKS ARE DESCRIBED IN THE DSECTS AT END OF LISTING     * 21800020
*    XCTL TABLE PRECEDES SAID DSECTS                                  * 21900020
*                                                                     * 22000020
* ATTRIBUTES -                                                        * 22100020
*    REENTRANT, REFRESHABLE, SUPERVISOR MODE, ENABLED                 * 22200020
*                                                                     * 22300020
* CHARACTER CODE DEPENDENCY -                                         * 22400020
*    THIS MODULE IS NOT CHARACTER DEPENDENT                           * 22500020
* NOTES -                                                             * 22600020
*    NONE                                                             * 22700020
*                                                                     * 24500020
*********************************************************************** 25200020
         SPACE 3                                                        25900020
********                                                                26600020
******** REGISTER EQUATES                                               27300020
********                                                                28000020
RZERO    EQU   0                        WORK REGISTER                   28700020
RONE     EQU   1                        CONTAINS PARAMETER              29400020
RPARM    EQU   2                        PARAMETER SAVE                  30100020
RCVT     EQU   3                        POINTS AT CVT                   30800020
RTCB     EQU   4                        POINTS AT TCB                   31500020
RTJID    EQU   5                        CONTAINS TJID                   32200020
RTSB     EQU   7                        POINTS AT TSB                   33600020
RWORK    EQU   8                        WORK REGISTER                   34300020
RTSBSIZE EQU   9                        CONTAINS TSB SIZE               35000020
RRPT     EQU   10                       POINTS AT TIOCRPT               35700020
RJSCB    EQU   11                       POINTS AT JSCB                  36400020
RWORK1   EQU   11                       PARAMETER REGISTER              36700020
RBASE    EQU   12                       BASE REGISTER                   37100020
RTSCVT   EQU   13                       POINTS AT TSCVT                 37800020
RCODE    EQU   15                       CONTAINS RETURN CODE            38500020
         SPACE 3                                                        39200020
********                                                                39900020
******** EQUATES FOR MASK, DISPLACEMENT AND LENGTH                      40600020
********                                                                41300020
M24      EQU   24                       FOR SHIFTING REGISTER           42000020
NOT      EQU   X'FF'                    FOR TURNING BITS OFF            42700020
         SPACE 3                                                        43400020
********                                                                44100020
******** EQUATES FOR RETURN CODES                                       44800020
********                                                                45500020
EXIT     EQU   3                        EQUATE FOR RETURN TO CALLER     45800020
SUCCESS  EQU   X'00'                    CODE FOR SUCCESSFUL COMPLETION  46200020
INVALID  EQU   X'04'                    CODE FOR INVALID PARM           46900020
         SPACE 3                                                        47600020
********                                                                48300020
******** SET UP BASE REGISTER AND ADDRESSABILITY                        49000020
********                                                                49700020
         BALR  RBASE,RZERO              ESTABLISH ADDRESSABILITY        50400020
         USING *,RBASE                                                  51100020
         USING CVT,RCVT                                                 51800020
         USING TSCVT,RTSCVT                                             52500020
         USING TIOCRPT,RRPT                                             53200020
         USING TCB,RTCB                                                 53900020
         USING IEZJSCB,RJSCB                                            54600020
         USING TSB,RTSB                                                 55300020
         SPACE 3                                                        56700020
********                                                                57400020
******** CHECK PARAMETERS                                               58100020
********                                                                58800020
         LR    RONE,RWORK1              RESTORE PARAMETERS              59100020
         LR    RPARM,RONE               SAVE PARAMETERS                 59500020
         N     RONE,KEY                 TURN OFF PARM BIT               60200020
         LTR   RONE,RONE                ANY BIT ON                      60900020
         BNZ   PARMBAD                  BRANCH IF YES                   61600020
PARMOK   EQU   *                                                        62300020
         SPACE 3                                                        63000020
********                                                                63700020
******** GET POINTER TO NECESSARY CONTROL BLOCKS                        64400020
********                                                                65100020
         L     RTSCVT,CVTTSCVT          REG HAS ADDR OF TSCVT           65800020
         L     RRPT,TSCVTRPT            GET ADDR OF TIOCRPT             66500020
         L     RTSBSIZE,TIOCTSBS        HIGH ORDER BYTE OF REG HAS TS   67200020
*                                       SIZE, REST OF REG HAS ADDR OF   67900020
*                                       TSB TABLE                       68600020
         LR    RTSB,RTSBSIZE            REG HAS SAME AS ABOVE           69300020
         SRL   RTSBSIZE,M24             LOW ORDER BYTE OF REG HAS TSB   70000020
*                                       SIZE                            70700020
         L     RJSCB,TCBJSCB            GET ADDR OF JSCB                71400020
         LH    RTJID,JSCBTJID           GET TJID                        72100020
         BCTR  RTJID,0                  DECREMENT TJID BY 1             72800020
         MR    RWORK,RTJID              GET OFFSET TO TSB TABLE         73500020
         AR    RTSB,RTSBSIZE            GET ADDR OF PARTICULAR TSB      74200020
         SPACE 3                                                        75600020
********                                                                76300020
******** PERFORM MAIN FUNCTION OF ROUTINE                               77000020
********                                                                77700020
         LTR   RPARM,RPARM              INTERCOM WANTED                 78400020
         BZ    NOCOM                    NO, BRANCH TO NOCOM             79100020
COM      EQU   *                                                        79800020
         NI    TSBSTAT,NOT-TSBITOFF     TURN OFF TSBITOFF BIT           80500020
         B     RETURN                   GO TO RETURN                    81900020
NOCOM    EQU   *                                                        82600020
         OI    TSBSTAT,TSBITOFF         TURN ON TSBITOFF BIT            83300020
RETURN   EQU   *                                                        84700020
         LA    RCODE,SUCCESS            LOAD RETURN CODE                85400020
         SVC   EXIT                     RETURN CONTROL TO CALLER        86100020
PARMBAD  EQU   *                                                        86800020
         LA    RCODE,INVALID            LOAD RETURN CODE                87500020
         SVC   EXIT                     RETURN CONTROL TO CALLER        88300020
KEY      DS    0F                       FORCE NEXT FIELD ON WORD        89100020
*                                       BOUNDARY                        90000020
         DC    X'7FFFFFFF'              CONDITION FOR TESTING PARM      91000020
         ORG   IGG09405+1008            MAKE MODULE 1K                  91100020
         DC    C'05    '                INFORMATION FOR FIRST LOAD SVC  91200020
         DC    H'0'                     FILLER HALFWORD                 91300020
         DC    F'0'                     DUMMY WORD                      91400020
         DC    C'094'                   INFORMATION FOR FIRST LOAD SVC  91500020
         DC    AL1(126)                 POINTS TO START OF TABLE        91600020
         EJECT                                                          91700020
         IKJTSB                                                         92700020
CVT      DSECT                                                          93800020
         CVT                                                            94500020
         IKJTSCVT                                                       95200020
         IKJTIOCP                                                       95900020
         IKJTCB                                                         96600020
         IEZJSCB                                                        97300020
         END                                                            98000020
