         TITLE 'IGG09408 - STATTN ROUTINE'                              00400020
IGG09408 CSECT                                                          00800020
*                                                                       00900020
*0000                                                            M5712  00950020
*                                                                M0252  01000020
*                                                                M4283  01020020
*                                                                 M4040 01050020
*                                                                 M5113 01070020
*                                                                 M4283 01080020
*                                                                 M5467 01090020
*                                                                       01100020
*********************************************************************** 01200020
*    RELEASE 23 DELETIONS/CHANGES                                     * 01300020
*    RELEASE 22 DELETIONS/CHANGES                                     * 01400020
*    RELEASE 21 DELETIONS/CHANGES                                     * 01500020
*                                                                     * 01600020
* STATUS -                                                            * 01700020
*    CHANGE LEVEL 0                                                   * 01800020
*                                                                     * 01900020
* FUNCTION -                                                          * 02000020
*    THIS ROUTINE IS TO SERVE THE MACRO 'STATTN'. IT IS TO PREPARE    * 02100020
*    DIFFERENT FIELDS IN TSB AND QCB TO REFLECT CONDITIONS WHICH THE  * 02800020
*    USER SPECIFIES WHEN SETTING ATTENTION SIMULATION.                * 03200020
*                                                                     * 03600020
*    THE VALUE SPECIFIED IN OPERANDS 'LINES' AND 'TENS' ARE MOVED INTO* 04000020
*    'TSBATNLC' AND 'TSBATNTC' LEFT JUSTIFIED. THE 2ND BYTE IN BOTH   * 04400020
*    FIELDS ARE NOT USED. 'INPUT CHARACTERS' IF SPECIFIED BY USER, IS * 04800020
*    MOVED INTO 'TSBATNCC'.                                           * 05200020
*                                                                     * 05600020
*    IF A FUNCTION IS CANCELLED, THAT IS, '0' IS SPECIFIED IN ANY     * 06000020
*    OF THE OPERAND, THE APPROPRIATE FIELD IN TSB IS ZEROED.          * 06400020
*                                                                     * 06800020
*    THE ATTENTION SIMULATION REQUESTED SWITCHES, 'TSBANR' IN THE TSB * 07200020
*    AND 'QCBSATCH', 'QCBSATTI', AND 'QCBSATLC' IN THE QCB ARE SET.   * 07600020
*                                                                     * 08000020
*    A RETURN CODE OF '00' INDICATES SUCCESSFUL COMPLETION OF THE     * 08400020
*    FUNCTION.                                                        * 08800020
*                                                                     * 09200020
* ENTRY POINTS -                                                      * 09500020
*         IGG09408 - CONTROL IS RECEIVED FROM MODULE IGC0009D VIA     * 09800020
*         XCTL ACCORDING TO THE ENTRY CODE 8                          * 10100020
*                                                                     * 10400020
* INPUT -                                                             * 10600020
*    REGISTER  3 HAS CVT ADDRESS                                      * 10800020
*    REGISTER  4 HAS TCB ADDRESS                                      * 11000020
*    REGISTER  5 HAS SVRB EXTENDED SAVE AREA ADDRESS                  * 11200020
*                                                                     * 11600020
*    REGISTER 2                                                       * 12000020
*    ****************************************************             * 12400020
*    * ENTRY CODE = 08 *             * LINES *   * TENS *               12800020
*    ****************************************************             * 13200020
*                                                                     * 13600020
*    REGISTER 11                                                      * 14000020
*    ****************************************************             * 14400020
*    *                      * INPUT CHARACTER ADDRESS   *             * 14800020
*    ****************************************************             * 15200020
*                                                                     * 16400020
* OUTPUT -                                                            * 16700020
*    REGISTER 15 HAS RETURN CODE:                                     * 17000020
*           0 - SUCCESSFUL                                            * 17300020
*                                                                     * 17600020
* EXTERNAL REFERENCES -                                               * 17800020
*         NONE                                                        * 18000020
*                                                                     * 18400020
* EXITS, NORMAL -                                                     * 18500020
*         SVC 3 WITH 0 IN REGISTER 15                                 * 18600020
*                                                                     * 18700020
* EXITS, ERROR -                                                      * 18800020
*         NONE                                                        * 18900020
*                                                                     * 19000020
* TABLES/WORK AREAS -                                                 * 19100020
*    CONTROL BLOCKS ARE DESCRIBED IN THE DSECTS AT END OF LISTING     * 19200020
*    XCTL TABLE PRECEDES SAID DSECTS                                  * 19300020
*                                                                     * 19400020
* ATTRIBUTES -                                                        * 19500020
*    REENTRANT, REFRESHABLE, SUPERVISOR MODE, DISABLED AND ENABLED    * 19600020
*                                                                     * 19700020
* CHARACTER CODE DEPENDENCY -                                         * 19800020
*    THIS MODULE IS ASSEMBLED IN EBCDIC AND MUST BE REASSEMBLED IF    * 19900020
*    A DIFFERENT CHARACTER SET IS TO BE USED DURING EXECUTION         * 20000020
* NOTES -                                                             * 20100020
*    NONE                                                             * 20200020
*                                                                     * 21600020
*********************************************************************** 22000020
RZERO    EQU   0                        GENERAL PURPOSE REG             22400020
RTJID    EQU   0                        CONTAINS TJID                   22800020
RONE     EQU   1                        GENERAL PURPOSE REG             23200020
RPARM1   EQU   2                        SAVE PARAMETERS                 23600020
RCVT     EQU   3                        POINTS AT CVT                   24000020
RTSCVT   EQU   3                        POINTS AT TSCVT                 24400020
RRPT     EQU   3                        POINTS AT TIOCRPT               24800020
RTCB     EQU   4                        POINTS AT TCB                   25200020
RAVT     EQU   5                        POINTS AT AVT                   25600020
RQCB     EQU   6                        POINTS AT QCB                   26000020
RTSB     EQU   7                        POINTS AT TSB                   26400020
RWORK    EQU   8                        WORK REGISTER                   26800020
RTSBSIZE EQU   9                        CONTAINS TSB SIZE               27200020
RTJB     EQU   9                        POINTS AT TJB                   27400020
RJSCB    EQU   10                       POINTS AT JSCB                  27600020
RTT      EQU   11                       POINTS AT TERMINAL TABLE        28000020
RWORK1   EQU   11                       PARAMETER REGISTER              28200020
RBASE    EQU   12                       BASE REG                        28400020
RPARM2   EQU   13                       SAVE PARAMETERS                 28800020
R14      EQU   14                       CONTAINS RETURN ADDR            29200020
RCODE    EQU   15                       FOR RETURN CODE                 29600020
R15      EQU   15                       CONTAINS ADDR TO BRANCH TO      30000020
         SPACE 3                                                        30400020
********                                                                30800020
******** EQUATES FOR LENGTH, MASKS, DISPLACEMENTS                       31200020
********                                                                31600020
D0       EQU   0                        DISPLACEMENT                    32000020
D1       EQU   1                        DISPLACEMENT                    32400020
D2       EQU   2                        DISPLACEMENT                    32800020
D3       EQU   3                        DISPLACEMENT                    33200020
D96      EQU   96                       DISPLACEMENT                    33400020
L2       EQU   2                        LENGTH OF 2                     33600020
L4       EQU   4                        LENGTH OF 4                     34000020
M1       EQU   1                        MASK                            34400020
M2       EQU   2                        MASK                            34800020
M3       EQU   3                        MASK                            35200020
M8       EQU   8                        MASK                            35600020
M16      EQU   16                       MASK                            36000020
M24      EQU   24                       MASK                            36400020
M31      EQU   31                       MASK                            36800020
NOT      EQU   X'FF'                    MASK FOR TURNING BITS OFF       37200020
BLANK    EQU   X'40'                    MASK FOR BLANK                  37400020
IDLE     EQU   X'17'                    IDLE CHAR. FOR TPUT             37500020
         SPACE 3                                                        37600020
********                                                                38000020
******** EQUATES FOR RETURN CODES                                       38400020
********                                                                38800020
EXIT     EQU   3                        EQUATE TO RETURN TO CALLER      39000020
CODEGOOD EQU   X'00'                    CODE FOR SUCCESSFUL COMPLETION  39200020
         SPACE 3                                                        40000020
********                                                                40400020
******** SET UP BASE REGISTER AND ADDRESSABILITY                        40800020
********                                                                41200020
         BALR  RBASE,RZERO              ESTABLISH ADDRESSABILITY        41600020
         USING *,RBASE                                                  42000020
         USING CVT,RCVT                                                 42400020
         USING IEDQAVTD,RAVT                                            42800020
         USING TCB,RTCB                                                 43200020
         USING IEZJSCB,RJSCB                                            43600020
         USING TSB,RTSB                                                 44000020
         USING IEDQTRM,RTT                                              44400020
         USING IEDQQCB,RQCB                                             44800020
         SPACE 3                                                        45200020
********                                                                45600020
******** GET POINTER TO NECESSARY CONTROL BLOCKS                        46000020
********                                                                46400020
         LR    R14,RAVT                 GET SVRB EXTENDED SAVE AREA     46600020
         LR    RPARM2,RWORK1            SAVE PARAMETER                  46800020
         L     RCVT,CVTTSCVT            GET ADDR OF TSCVT               48000020
         DROP  RCVT                                                     48400020
         USING TSCVT,RTSCVT                                             48800020
         L     RTSCVT,TSCVTRPT          GET ADDR OF TIOCRPT             49200020
         DROP  RTSCVT                                                   49600020
         USING TIOCRPT,RRPT                                             50000020
         L     RTSB,TIOCTSB-1           GET ADDR OF TSB TABLE           50400020
         SR    RTSBSIZE,RTSBSIZE        CLEAR REGISTER                  50800020
         IC    RTSBSIZE,TIOCTSBS        GET TSB SIZE                    51200020
         L     RJSCB,TCBJSCB            GET ADDR OF JSCB                51600020
         LH    RTJID,JSCBTJID           GET TJID                        52000020
         BCTR  RTJID,0                  DECREMENT TJID BY 1             52400020
         MR    RWORK,RTJID              GET OFFSET TO TSB TABLE         52800020
         AR    RTSB,RTSBSIZE            GET ADDR OF DESIRED TSB         53200020
         L     RCVT,CVTPTR              GET CVT ADDRESS                 53230020
         DROP  RRPT                                                     53260020
         USING CVT,RCVT                                                 53290020
         SSM   DISABLE                  DISABLE ALL INTERRUPT           53320020
         TM    CVTTCMFG,CVTTCRDY        IS TCAM RUNNING                 53350020
         BNO   RETURN                   BRANCH IF TCAM NOT UP           53360020
         L     RAVT,CVTAQAVT            LOAD ADDR OF TCAM DISPATCHER    53370020
         L     RAVT,0(RAVT)             LOAD ADDR OF AVT                53380020
         L     RTJB,TSBTJB-1            GET ADDR OF TJB                 53410020
         USING TJB,RTJB                                                 53440020
         TM    TJBSTAT2,TJBHUNG         DID USER HANG UP                53470020
         BO    RETURN                   BRANCH IF USER HANG UP          53530020
         L     RQCB,TSBQCB-1            GET ADDR OF DESTINATION QCB     53600020
         SPACE 3                                                        54000020
********                                                                54400020
******** CHECK LINES                                                    54800020
********                                                                55200020
         LR    RWORK,RPARM2             GET PARAMETER                   55600020
         SRL   RWORK,M31                GET RID ALL BITS BUT 1ST        56000020
         LTR   RWORK,RWORK              LINES SPECIFIED                 56400020
         BZ    CKTENS                   NO, GO TO CKTENS                56800020
         TM    TSBSTAT,TSBDSPLY         IS TERMINAL A 2260/2265  M5712  56900020
         BO    CKTENS                   YES, DISREGARD & BR TO   M5712  57000020
*                                       CKTENS                   M5712  57100020
         LR    RWORK,RPARM1             GET PARAMETERS                  57200020
         SLL   RWORK,M16                GET RID OF HIGH ORDER 2 BYTES   57600020
         SRL   RWORK,M24                GET RID OF ALL BUT LINES        58000020
         LTR   RWORK,RWORK              LINES = NO                      58400020
         BZ    NOLINES                  YES, GO TO NOLINES              58800020
LINESYES EQU   *                                                        59200020
         STC   RWORK,TSBATNLC+1         MOVE LINES TO TSBATNLC          59600020
         OI    TSBFLG1,TSBANSR          TURN ON TSBANSR BIT             60000020
         OI    QCBTSOF2,QCBSATLC        TURN ON QCBSATLC BIT IN QCB     60400020
         B     CKTENS                   GO TO CKTENS                    60800020
NOLINES  EQU   *                                                        61200020
         XC    TSBATNLC(L2),TSBATNLC    ZERO OUT TSBATNLC FIELD         61600020
         NI    QCBTSOF2,NOT-QCBSATLC    TURN OFF QCBSATLC BIT           62000020
         SPACE 3                                                        62400020
********                                                                62800020
******** CHECK TENS                                                     63200020
********                                                                63600020
CKTENS   EQU   *                                                        64000020
         LR    RWORK,RPARM2             GET PARAMETERS                  64400020
         SLL   RWORK,M1                 GET RID OF 1ST BIT              64800020
         SRL   RWORK,M31                GET RID OF ALL BUT 2ND BIT      65200020
         LTR   RWORK,RWORK              TENS SPECIFIED                  65600020
         BZ    CKADDR                   NO, GO TO CHECK ADDRESS         66000020
         LR    RWORK,RPARM1             GET PARAMETERS                  66400020
         SLL   RWORK,M24                GET RID OF ALL BUT TENS         66800020
         SRL   RWORK,M24                PUT TENS IN LOW ORDER BYTE      67200020
         LTR   RWORK,RWORK              TENS SPECIFIED                  67600020
         BZ    NOTENS                   NO, GO TO NOTENS                68000020
TENSYES  EQU   *                                                        68400020
         MH    RWORK,TEN                MULTIPLY TIME INTERVAL BY 10    68600020
         STH   RWORK,TSBATNTC           MOVE TIME INTERVAL TO TSBATNTC  68800020
         OI    TSBFLG1,TSBANSR          TURN ON TSBANSR BIT             69200020
         OI    QCBTSOF2,QCBSATTI        TURN ON QCBSATTI BIT            69600020
         OI    TSBFLG3,TSBSPIT          TSOUTPUT NO AUTOPROMPT          69640020
         MVI   D0(R14),IDLE             MOVE IN IDLE CHAR               69680020
         LH    RZERO,JSCBTJID           GET TJID                        69720020
         SLL   RZERO,M16                SHIFT TO HIGH ORDER             69760020
         LA    RONE,M1                  SET BUFFER LENGTH               69800020
         OR    RZERO,RONE                                               69840020
         LA    RONE,D0(,R14)            SET BUFFER ADDRESS              69880020
         O     RONE,TPUTOPTN            LOAD TPUT OPTIONS               69920020
         TPUT  (1),(0),R                ISSUE TPUT TO GET ON DELAY Q    69960020
         NI    TSBFLG3,NOT-TSBSPIT      ALLOW AUTOPROMPT                69980020
         TM    CVTTCMFG,CVTTCRDY        IS TCAM RUNNING                 69986020
         BNO   RETURN                   BRANCH IF TCAM NOT UP           69989020
         TM    TJBSTAT2,TJBHUNG         DID USER HANG UP                69992020
         BO    RETURN                   BRANCH IF USER HANG UP          69996020
         B     CKADDR                   GO TO CKADDR                    70000020
NOTENS   EQU   *                                                        70400020
         XC    TSBATNTC(L2),TSBATNTC    ZERO OUT TSBATNTC FIELD         70800020
         NI    QCBTSOF2,NOT-QCBSATTI    TURN OFF QCBSATTI BIT           71200020
         SPACE 3                                                        71600020
********                                                                72000020
******** CHECK INPUT ADDR                                               72400020
********                                                                72800020
CKADDR   EQU   *                                                        73200020
         LR    RWORK,RPARM2            GET PARAMTER                     73600020
         SLL   RWORK,M2                 GET RID OF HIGH ORDER 2 BITS    74000020
         SRL   RWORK,M31                GET RID OF ALL BITS BUT 3RD     74400020
         LTR   RWORK,RWORK              INPUT SPECIFIED                 74800020
         BZ    RETURN                   NO, GO TO RETURN                75200020
         LR    RWORK,RPARM2             GET PARAMETER                   75600020
         LA    RWORK,D0(RWORK)          GET RID OF FLAG BYTE            76000020
         LTR   RWORK,RWORK              ADDRESS SPECIFIED               76300020
         BZ    NOINPUT                  BRANCH IF NONE                  76600020
CHARYES  EQU   *                                                        76800020
         NI    TSBFLG2,NOT-TSBSATN1-TSBSATN2                            77100020
*                                       ZERO OUT BITS 6, 7 (SET CHAR    77400020
*                                       COUNT TO 1)                     77700020
         CLI   D1(RWORK),BLANK          TEST FOR BLANK                  78000020
         BE    MOVE                     IT IS BLANK, GO TO MOVE         78400020
         OI    TSBFLG2,TSBSATN2         SET CHAR COUNT TO 2             78800020
         CLI   D2(RWORK),BLANK          TEST FOR BLANK                  79200020
         BE    MOVE                     IT IS BLANK, GO TO MOVE         79600020
         NI    TSBFLG2,NOT-TSBSATN2     TURN OFF LOW ORDER BIT          80000020
         OI    TSBFLG2,TSBSATN1         SET CHAR COUNT TO 3             80400020
         CLI   D3(RWORK),BLANK          TEST FOR BLANK                  80800020
         BE    MOVE                     IT IS BLANK, GO TO MOVE         81200020
         OI    TSBFLG2,TSBSATN2         SET CHAR COUNT TO 4             81600020
MOVE     EQU   *                                                        82000020
         MVC   TSBATNCC,D0(RWORK)       MOVE CHARS TO TSBATNCC FIELD    82400020
         OI    TSBFLG1,TSBANSR          TURN ON TSBANSR BIT             82800020
         OI    QCBTSOF2,QCBSATCH        TURN ON QCBSATCH BIT            83200020
         B     RETURN                   GO TO RETURN                    83600020
NOINPUT  EQU   *                                                        84000020
         XC    TSBATNCC(L4),TSBATNCC    ZERO OUT TSBATNCC FIELD         84400020
         NI    QCBTSOF2,NOT-QCBSATCH    TURN OFF QCBSATCH BIT           84800020
RETURN   EQU   *                                                        85200020
         LA    RCODE,CODEGOOD                                           85600020
         SVC   EXIT                     RETURN CONTROL TO CALLER        85800020
         SPACE 3                                                        86060020
********                                                                86120020
******** CONSTANT                                                       86180020
********                                                                86240020
TEN      DC    H'10'                    CONSTANT OF 10                  86300020
TPUTOPTN DS    0F                                                       86303020
         DC    XL4'0A000000'            TPUT CONTROL/HOLD               86306020
DISABLE  DC    X'00'                    MASK FOR RUNNING DISABLED       86307020
         ORG   IGG09408+1008            MAKE MODULE 1K                  86310020
         DC    C'08    '                INFORMATION FOR FIRST LOAD SVC  86320020
         DC    H'0'                     FILLER HALFWORD                 86330020
         DC    F'0'                     DUMMY BYTE                      86340020
         DC    C'094'                   INFORMATION FOR FIRST LOAD SVC  86350020
         DC    AL1(126)                 POINTS TO START OF TABLE        86360020
         EJECT                                                          86400020
CVT      DSECT                                                          86800020
         CVT                                                            87200020
         IKJTSCVT                                                       87600020
         IKJTIOCP                                                       88000020
         SPACE 3                                                        88100020
         IKJTJB                                                         88200020
         IKJTSB                                                         88400020
         TAVTD                                                          88800020
         IKJTCB                                                         89200020
         IEZJSCB                                                        89600020
         TTRMD                                                          90000020
         TQCBD                                                          90400020
         END                                                            90800020
