         TITLE 'IKJEAD00-INITIALIZATION MODULE FOR TSO DRIVER'          00050020
IKJEAD00 START                                                          00100020
*                                                                       00150020
*STATUS=0                                                         20023 00200020
*D138700,139300,460500,461000,490500,775500                      A44022 00202021
*A138400-139300,336700,460300-460900,488700,490200-490800,494200 A44022 00204021
*A775200-775600,784600,784700                                    A44022 00206021
*A062600,487600                                                  A45527 00210021
*D487000,487500,488500                                           A45527 00220021
*C490200,490400                                                  A45527 00230021
*C796500                                                         A44413 00240021
*A811600,814060-814072,828600                                    A44413 00242021
*C115500-117500,222500,231500,312500,314000,314500,368000,378500, M1683 00244021
*C388500,398500,407500,440700,446000,457000,499500,722000,722500,749000 00246021
*C770500,771000,783500,784000,793000,793500                       M1683 00248021
         SPACE                                                          00250020
*FUNCTION                                                               00300020
*   A. THE PRE-INITIALIZATION ROUTINE (EP-IKJEAD00) COMPUTES THE AMOUNT 00350020
*   OF MAIN STORAGE REQUIRED BY THE  TS DRIVER CTRL. BLKS. AND RETURNS  00400020
*   THE RESULT AS A PARAMETER TO THE TIME SHARING CONTROL (TSC) INIT.   00450020
*   THE DR. CTRL. BLOCKS ARE 1. DCA     ONE FOR THE TS SYSTEM.          00500020
*                            2. DCARE   ONE PER REGION.                 00550020
*                            3. RQEL    INSTALLATION SPECIFIED QUANTITY 00600020
*                                       PER REGION.                     00650020
*                            4. UQEL    MAXIMUM NUMBER OF TS USERS.     00700020
*   B. THE INITIALIZATION ROUTINE (EP-IKJEAD01) AGAIN COMPUTES THE AMT. 00750020
*   OF MAIN STORAGE AND THEN OBTAINS THE MAIN STORAGE FOR THE DRIVER    00800020
*   CTRL. BLKS. THESE BLOCKS ARE THEN INITIALIZED WITH POINTERS, BLOCK  00850020
*   TYPE INDICATORS, VALUES PASSED IN A PARAMETER LIST FROM TSC, AND    00900020
*   VALUES FROM THE PARM. DATA FIELDS. REQUIRED PARAMETERS THAT ARE     00950020
*   MISSING FROM THE PARM. DATA CAUSE A WTOR TO BE WRITTEN. OPERATOR    01000020
*   SUPPLIED VALUES ARE THEN USED  IF VALID. INVALID OPER. SUPPLIED     01050020
*   VALUES CAUSE A WTOR TO AGAIN ASK FOR A PROPER VALUE. THE ADDRESS OF 01100020
*   THE CONTROL BLOCKS IS RETURNED TO THE TSC INITIALIZATION ROUTINE IN 01150020
*   THE DESIGNATED WORD OF THE ENTRY PARAMETER LIST.                    01200020
    EJECT                                                               01250020
* ENTRY POINTS                                                          01300020
*   IKJEAD00   PRE-INITIALIZATION ROUTINE-LINKED TO BY TSC INIT. TO GET 01350020
*              AMT. OF MAIN STORAGE NEEDED FOR TS DRIVER CONTROL BLKS.  01400020
*   IKJEAD01   INITIALIZATION ROUTINE-LINKED TO BY TSC INIT. TO GET     01450020
*              TS DRIVER CTRL. BLKS. STORAGE + INITIALIZE THEM.         01500020
         SPACE                                                          01550020
* INPUT                                                                 01600020
*   REGISTER  1    ADDRESS OF A PARAMETER LIST                          01650020
*            13    ADDRESS OF SAVE AREA FOR TSC'S REGISTERS             01700020
*            14    RETURN ADDRESS                                       01750020
*            15    ENTRY POINT ADDRESS                                  01800020
*   PARAMETER LIST FORMAT                                               01850020
*            +0    MAXIMUM NUMBER OF TS USERS                           01900020
*            +4    LENGTH OF PARAMETER DATA                             01950020
*            +8    ADDRESS OF PARAMETER DATA                            02000020
*           +12    SWITCH-NOT USED BY TS DRIVER                         02050020
*           +13    CONSOLE ID                                           02100020
*           +14    MAXIMUM NUMBER OF TS REGIONS                         02150020
*           +16    FULL WORD OF ZEROS                                   02200020
*           +20    FULL WORD OF ZEROS OR-IF ANY-PTR TO START PARM OVERR 02250020
* HI ORDER BIT ON AT +20 INDICATES DRIVER SMF RECORD REQ'D              02260020
         SPACE                                                          02300020
* OUTPUT                                                                02350020
*   IKJEAD00-MAIN STORAGE REQUIREMENT RETURNED IN 5TH. WD. OF PARM LIST 02400020
*   IKJEAD01-DCA CONTROL BLOCK ADDR.  RETURNED IN 5TH. WD. OF PARM LIST 02450020
         SPACE                                                          02500020
* EXTERNAL REFERENCES - NONE                                            02550020
         SPACE                                                          02600020
* EXITS,NORMAL                                                          02650020
*   RETURN TO TSC WITH RETURN CODE OF ZERO IN REGISTER 15.              02700020
         SPACE                                                          02750020
* EXITS,OPERATOR SPECIFIES CANCEL                                       02800020
*   RETURN TO TSC WITH RETURN CODE OF EIGHT IN REGISTER 15.             02850020
         SPACE                                                          02900020
* EXITS,ERROR                                                           02950020
*   RETURN TO TSC WITH RETURN CODE OF EIGHT IN REGISTER 15.             03000020
         SPACE                                                          03050020
* TABLES/WORK AREAS                                                     03100020
*   1. A CONTIGUOUS AREA CONTAINING A WORKING COPY OF THE DCA AND A     03150020
*   WORD FOR EACH TS REGION                                             03200020
*   2. A WORK AREA FOR WTOR + OPER. REPLIES (SEE ERRORMSG DSECT)        03250020
*   3. A WORK AREA FOR TSDRIVER SMF RECORD#32 (SEE TDRSMF DSECT)        03300020
         SPACE                                                          03350020
* ATTRIBUTES-REFRESHABLE, REENTRANT, ENABLED, READ-ONLY, SUPER. STATE   03400020
         SPACE                                                          03450020
* NOTES - MVT SYSTEM WITH TSO OPTION                                    03500020
*   PARAMETER DATA IS HANDLED SO THAT A REPETION OF A KEYWORD CAUSES    03550020
*   THE SECOND OCCURRENCE TO OVERRIDE THE FIRST. FOR THIS REASON,       03600020
*   'INVALID' KEYWORDS ARE SKIPPED OVER. AT THE END OF A PARM DATA      03650020
*   PASS,A CHECK IS MADE FOR ALL REQUIRED VALUES. A 'MISSING' VALUE     03700020
*   CAUSES A PROMPTING WTOR TO THE OPERATOR.                            03750020
         SPACE                                                          03800020
* SCALED NUMBERS AS USED IN THIS MODULE MEANS THE HIGH ORDER BITS       03850020
* (QUANTITY VARIES) REPRESENT WHOLE NUMBERS. THE REMAINING LOW ORDER    03900020
* BITS (TO THE RIGHT OF THE BINARY POINT) REPRESENTS A FRACTION. THIS   03950020
* FRACTION IS EXPRESSED BY THE BITS AS 2 TO THE MINUS 1 POWER, 2 TO     04000020
* THE MINUS 2 POWER, 2 TO THE MINUS 3 POWER ETC.                        04050020
       SPACE                                                            04100020
         SPACE                                                          04150020
* TSO CONTROL BLOCK DIAGRAM - ALL BLOCKS IN CONTIGUOUS MAIN STORAGE     04200020
*                             IN TIME SHARING CONTROL REGION            04250020
*    DCA ***************                                                04300020
*        *             *                                                04350020
*        *             *                                                04400020
*        *             *                                                04450020
*  DCARE ***************                                                04500020
*        *             *                                                04550020
*  DCARE ***************                                                04600020
*        *             *                                                04650020
*   RQEL ***************      RQELS ARE CONTIGUOUS PER ASCENDING REGION 04700020
*        *             *      AND THE LAST RQEL FOR EACH REGION IS      04750020
*   RQEL ***************      MARKED BY A FLAG. RQELS ARE DIFFERENTIAT- 04800020
*        *             *      ED FROM UQELS BY THE STATUS OF AN         04850020
*   RQEL ***************      IDENTIFIER FLAG.                          04900020
*        *             *                                                04950020
*   UQEL ***************      UQELS ARE CONTIGUOUS PER ASCENDING        05000020
*        *             *      TERMINAL USER IDENTIFIER (TJID)           05050020
*   UQEL ***************                                                05100020
*        *             *                                                05150020
*        ***************                                                05200020
         SPACE 2                                                        05210020
* GETMAIN SUBPOOL USAGE                                                 05220020
*     0 - TEMPORARY STORAGE(SAVE AND WORK AREAS)                        05230020
*   252 - PERMANENT STORAGE(DRIVER CONTROL BLOCKS)                      05240020
         EJECT                                                          05250020
*                                                                       05300020
         IKJDCA                                                         05350020
         IKJDCARE                                                       05400020
         IKJRQEL                                                        05450020
         IKJUQEL                                                        05500020
         SPACE                                                          05550020
ERRORMSG DSECT                                                          05600020
ZWTOST   DS    F                        WTO MSG LENGTH + FLAGS          05650020
ZWTOMSG  DS    CL68                     WTO MSG+DESC+ROUTING CODES      05700020
*                                       WTOR PARM LIST                  05750020
ZFSTRPLY DS    A                        LEN.+ADDR. OF FIRST REPLY       05800020
ZWTORECB DS    A                        ECB ADDRESS                     05850020
         DS    F                        WTOR MSG. LENGTH + FLAGS        05900020
ZMESSAGE DS    CL68                     WTOR MSG + DESC+ROUTING CODES   05950020
*                                       END OF PARM LIST                06000020
*                                                                       06050020
ZMSGECB  DS    F                        WTOR ECB                        06100020
*                                                                       06150020
ZRPLYAD  DS    A                        ADDR. OF REPLY TO HANDLE        06200020
ZMSGAREA DS    A                        ADDR.OF REPLY SPACE             06250021
ZMSGLENG DS    1F                       LENGTH OF REPLY SPACE    A45527 06260021
ZSAVEREG DS    A                        SAVE AREA PASSED BY TSC         06300020
* END OF DSECT                                                          06350020
         IFASMFR 32                     DRIVER SMF RECORD               06400020
DSMFRQE  DSECT                                                          06450020
*********************************************************************** 06500020
*  THIS IS AN 'INTERNAL' DSECT (WITHIN THE FULL SMF RECORD 32) FOR    * 06550020
*  INSERTING IN THE TS DRIVER SMF RECORD-ON A PER RQEL BASIS- THE     * 06600020
*  REQUIRED RQEL DATA AT START TS TIME.                               * 06650020
*********************************************************************** 06700020
         DC    BL1'0'                   RESERVED                        06750020
DSMFRQE# DC    BL1'0'                   REGION NO.                      06800020
DSMF#CYC DC    2BL1'0'                  NO. OF SERVICE CYCLES           06850020
DSMFSIZE DC    2BL1'0'                  SWAPLOAD THRESHOLD              06900020
DSMFTCO  DC    4BL1'0'                  TOTAL CORE OCCUPANCY THRESHOLD  06950020
DSMFAQST DC    4BL1'0'                  DESIRED AVE. SERVICE TIME       07000020
DSMFMSLC DC    4BL1'0'                  MIN. MAJOR SLICE                07050020
         DC    2BL1'0'                  RESERVED                        07100020
DSMFEND  EQU   *                                                        07150020
         EJECT                                                          07200020
IKJEAD00 CSECT                                                          07250020
*                                                                       07300020
         ENTRY IKJEAD01                                                 07350020
*                                                                       07400020
*              REGISTER ASSIGNMENTS                                     07450020
*                                                                       07500020
X0       EQU   0                        SCRATCH                         07550020
X1       EQU   1                        SCRATCH                         07600020
XWK1     EQU   2                        WORK REG.                       07650020
XWK2     EQU   3                        WORK REG.                       07700020
XWKSP    EQU   4                        WORKSPACE PTR. + DCA PTR.       07750020
XLINK    EQU   5                        SUBROUTINE LINKAGE REG.         07800020
XPARM    EQU   6                        PARM DATA PTR.                  07850020
XSMF     EQU   6                        SMF RECORD DSECT PTR.           07900020
XSCEND   EQU   7                        END OF SCAN PTR.                07950020
XRETC    EQU   7                        RETURN CODE PRIOR TO RETURN     08000020
XMSGL    EQU   7                        WTOR REPLY MSG. LENGTH          08050020
XRECD    EQU   8                        RECORD PTR.                     08100020
XRQEL    EQU   8                        RQEL DSECT PTR.                 08150020
XDAEND   EQU   9                        END OF PARM DATA PTR.           08200020
X2LINK   EQU   9                        SECONDARY LINKAGE REG. + MISC.  08250020
XSMFRQ   EQU   9                        DSMFRQE DSECT PTR.              08300020
XSCAN    EQU   10                       SCAN PTR.+MISC. AFTER SCAN DONE 08350020
XSW      EQU   11                       TYPE OF ENTRY SWITCH            08400020
XDCARE   EQU   11                       DCARE DSECT PTR.                08450020
XBASE    EQU   12                       BASE REG.                       08500020
XSAVE    EQU   13                       SAVE AREA PTR.                  08550020
XERMSG   EQU   13                       ERROR MSG. PTR.                 08600020
X14      EQU   14                      RETURN REG. + SCRATCH            08650020
X15      EQU   15                      ENTRY PTR.+RETURN CODE+SCRATCH   08700020
         EJECT                                                          08750020
*              GENERAL EQUATES                                          08800020
*                                                                       08850020
ZERO     EQU   0                        GENERAL PURPOSE NUMBER          08900020
ONE      EQU   1                        GENERAL PURPOSE NUMBER          08950020
TWO      EQU   2                        GENERAL PURPOSE NUMBER          09000020
FOUR     EQU   4                        GENERAL PURPOSE NUMBER          09050020
FIVE     EQU   5                        GENERAL PURPOSE NUMBER          09100020
SIX      EQU   6                        GENERAL PURPOSE NUMBER          09150020
SEVEN    EQU   7                        GENERAL PURPOSE NUMBER          09200020
EIGHT    EQU   8                        GENERAL PURPOSE NUMBER          09250020
NINE     EQU   9                        GENERAL PURPOSE NUMBER          09300020
TEN      EQU   10                       GENERAL PURPOSE NUMBER          09350020
ELEVEN   EQU   11                       GENERAL PURPOSE NUMBER          09400020
TWELVE   EQU   12                       GENERAL PURPOSE NUMBER          09450020
THIRTEEN EQU   13                       GENERAL PURPOSE NUMBER          09500020
FOURTN   EQU   14                       GENERAL PURPOSE NUMBER          09550020
FIFTN    EQU   15                       GENERAL PURPOSE NUMBER          09600020
SIXTEEN  EQU   16                       GENERAL PURPOSE NUMBER          09650020
SEVENTEN EQU   17                       GENERAL PURPOSE NUMBER          09700020
EIGHTEEN EQU   18                       GENERAL PURPOSE NUMBER          09750020
TWENTY   EQU   20                       GENERAL PURPOSE NUMBER          09800020
TWENTY2  EQU   22                       GENERAL PURPOSE NUMBER          09850020
TWENTY3  EQU   23                       GENERAL PURPOSE NUMBER          09900020
TWENTY4  EQU   24                      GENERAL PURPOSE NUMBER           09950020
TWENTY8  EQU   28                       GENERAL PURPOSE NUMBER          10000020
TWENTY9  EQU   29                       GENERAL PURPOSE NUMBER          10050020
THIRTY1  EQU   31                       GENERAL PURPOSE NUMBER          10100020
THIRTY2  EQU   32                       GENERAL PURPOSE NUMBER          10150020
THIRTY3  EQU   33                       GENERAL PURPOSE NUMBER          10200020
THIRTY4  EQU   34                       GENERAL PURPOSE NUMBER          10250020
FORTY6   EQU   46                       GENERAL PURPOSE NUMBER          10300020
FORTY2   EQU   42                       GENERAL PURPOSE NUMBER          10350020
FORTY7   EQU   47                       GENERAL PURPOSE NUMBER          10400020
FIFTY    EQU   50                       GENERAL PURPOSE NUMBER          10450020
FIFTY7   EQU   57                       GENERAL PURPOSE NUMBER          10500020
SIXTYFO  EQU   64                       GENERAL PURPOSE NUMBER          10550020
SVTYONE  EQU   71                       GENERAL PURPOSE NUMBER          10600020
SEVENTY2 EQU   72                       WTO PARM LIST LENGTH            10650020
EIGHTY   EQU   80                       WTOR PARM LIST LENGTH           10700020
ONEH63   EQU   163                      AMT. OF CORE TO CLEAR-MSG.AREA  10750020
TWOHU55  EQU   255                      GENERAL PURPOSE NUMBER          10800020
TWOHU56  EQU   256                      GENERAL PURPOSE NUMBER          10850020
DCATSTM1 EQU   DCATSTME+1               WORKSPACE FOR UNPACK            10900020
DCATSTM6 EQU   DCATSTME+6               WORKSPACE FOR UNPACK            10950020
DCARHTM2 EQU   DCARHTME+2               FOR UPDATING DCARE-RQEL OFFSET  11000020
CZERO    EQU   X'F0'                    CHARACTER COMPARE               11050020
CNINE    EQU   X'F9'                    CHARACTER COMPARE               11100020
BLANK    EQU   X'40'                    USED TO BLANK AND SCAN          11150020
COMMA    EQU   X'6B'                    USED TO SCAN PARM LIST          11200020
RIGHTPAR EQU   X'5D'                    USED TO SCAN PARM LIST          11250020
EQUALSGN EQU   X'7E'                    USED TO SCAN PARM LIST          11300020
DEFAULT  EQU   X'E4'                    DEFAULT OPER. ANS.-U-           11350020
DEFFLGS  EQU   X'FE'                    INITIALIZE DEFAULT-DCA FLAGS    11400020
ALLFLAGS EQU   X'FF'                    USED TO CLEAR FLAGS             11450020
ERRORSW  EQU   DCA#HPT                  SWITCH=SET=PARM. ERROR          11500020
SUBQSW   EQU   DCAFLAGS+DCACPU1 X'01'   SW-SET=SUBQ PARMS HANDLED M1683 11550021
ERSPSW   EQU   DCAFLAGS+DCACPU1 X'02'   SW-SET=ERR.MSG.SP.OBTAINEDM1683 11600021
BADKWD   EQU   DCAFLAGS+DCACPU1 X'04'   SW-SET=HDLE BAD KEYWORD   M1683 11650021
PAOVWTSW EQU   DCAFLAGS+DCACPU1 X'08'   SW-SET-WTOR FOR PARM OVER.M1683 11700021
MS46SW   EQU   DCAFLAGS+DCACPU1 X'10'   SW-SET-WTO KEYWD AT MS46  M1683 11720021
EOJSW    EQU   DCA#RUNR+DCACPU1         SW-SET=END OF JOB CHCKING M1683 11750021
RCYCDONE EQU   RQELFLGS                SW.-SET=RQEL CYCLE PARM HDLED    11800020
DCALEN   EQU   DCAEND-DCA               LENGTH OF DCA CTRL. BLOCK       11850020
DCARELEN EQU   DCAREND-DCARE           LENGTH OF DCARE CONTROL BLOCK    11900020
RQELLEN  EQU   RQELEND-RQEL             LENGTH OF RQEL CONTROL BLOCK    11950020
UQELLEN  EQU   UQELEND-UQEL            LENGTH OF UQEL CONTROL BLOCK     12000020
ZWTOMS33 EQU   ZWTOMSG+33               WTO AREA TO CLEAR               12050020
ZMESSA42 EQU   ZMESSAGE+42              WTOR AREA TO CLEAR              12100020
ZMSG42   EQU   ZMESSAGE+42             REGION NUMBER                    12150020
ZMSG43   EQU   ZMESSAGE+43              SLOTS IN MSG.                   12200020
ZWTOMS46 EQU   ZWTOMSG+46               WTO AREA                        12250020
ZWTOMS50 EQU   ZWTOMSG+50               KEYWORD SLOT IN WTO MSG.        12300020
ZMSG50   EQU   ZMESSAGE+50              UNUSED MSG SLOTS FOR KEYWORDS   12350020
SMFDCAEN EQU   TDRRGNQ+2                END OF DCA SECTION OF SMF DSECT 12400020
SMFDCALE EQU   SMFDCAEN-TDRRLEN+20      LENGTH OF NON-RQEL SMF RECORD   12450020
SMFRQLEN EQU   DSMFEND-DSMFRQE          LENGTH PER RQEL OF SMF RECORD   12500020
SMFDCALN EQU   TDRRGNQ-TDRSMF           LENGTH OF DCA INFO              12550020
DSMFTCO2 EQU   DSMFTCO+2                FOR SMF RECORD ALIGNMENT        12600020
DSMFAQS2 EQU   DSMFAQST+2               FOR SMF RECORD ALIGNMENT        12650020
DSMFMSL2 EQU   DSMFMSLC+2               FOR SMF RECORD ALIGNMENT        12700020
DSMFPRE   EQU   X'80'                   SMF RECORD REQ'D FOR DRIV M3870 12720020
         EJECT                                                          12750020
* SAVE TSC REGISTERS, SET SWITCH FOR PRE-INITIALIZATION OR INITIALIZA-  12800020
* TION, AND ESTABLISH ADDRESSABILITY.                                   12850020
         STM   X14,XBASE,TWELVE(XSAVE)  SAVE TSC REGS.                  12900020
         SR    XSW,XSW                  PRE-INIT. ENTRY SW.             12950020
         LR    XBASE,X15                LOAD BASE REGISTER              13000020
         USING IKJEAD00,XBASE                                           13050020
         B     IKJINIT1                                                 13100020
IKJEAD01 EQU   *                                                        13150020
         STM   X14,XBASE,TWELVE(XSAVE)  SAVE TSC REGS.                  13200020
         LA    XSW,ONE                  INIT. ENTRY SW.                 13250020
         BALR  X15,ZERO                TEMPORARY ADDRESSABILITY         13300020
         USING *,X15                                                    13350020
         L     XBASE,BASEADCO          LOAD BASE REGISTER               13400020
         DROP  X15                                                      13450020
* OBTAIN AND CLEAR INITIAL WORK SPACE                                   13500020
*                                                                       13550020
IKJINIT1 EQU   *                                                        13600020
         LR    XPARM,X1                 LOAD PTR. TO PARAM. LIST        13650020
         LH    X0,FOURTN(XPARM)         NO. OF REGIONS                  13700020
         MH    X0,HFOUR                 WORKSPACE FOR REGIONS           13750020
         LA    XWK1,DCALEN              PLUS LENGTH OF DCA              13810020
         AR    X0,XWK1       TOTAL CORE REQUIRED.                A44022 13840021
         LR    XWK1,X0       SAVE SIZE IN XWK1 FOR SUBSEQUENT CLEA44022 13870021
         O     X0,SP251      SUBPOOL 251.                        A44022 13900021
         GETMAIN R,LV=(0)                                        A44022 13930021
         LR    XWKSP,X1                 PTR. TO WORKSPACE               14000020
         USING DCA,XWKSP                                                14050020
         BCTR  XWK1,ZERO                DECREMENT LENGTH BY ONE         14100020
         EX    XWK1,IKJCLEAR            CLEAR WORKSPACE                 14150020
* THIS ROUTINE SCANS THE PARM DATA FOR DRIVER RECORDS AND BRANCHES TO   14200020
* APPROPRIATE ROUTINES TO HANDLE THE KEYWORDS FOUND ON THE DR. RECORDS  14250020
IKJRECIN EQU   *                                                        14300020
         L     XDAEND,EIGHT(,XPARM)     BEGINNING OF PARM DATA          14350020
         A     XDAEND,FOUR(,XPARM)      PLUS LENGTH EQ. STOPPER         14400020
         L     XRECD,EIGHT(,XPARM)      BEGINNING OF PARM DATA          14450020
         S     XRECD,FEIGHTY            FOR FIRST PASS                  14500020
IKJREC00 EQU   *                        NEXT RECORD HANDLER             14550020
         A     XRECD,FEIGHTY            STEP TO NEXT RECORD             14600020
         CR    XRECD,XDAEND           Q.AT END OF RECORDS               14650020
         BNL   IKJENDRC                 YES                             14700020
         LR    XSCAN,XRECD              SET UP TO SCAN RECORD           14750020
         LA    XSCEND,SVTYONE(XSCAN)    END OF SCAN PTR                 14800020
IKJREC10 EQU   *                        CHECK CHARACTER                 14850020
         CLI   ZERO(XSCAN),BLANK      Q.CHARACTER A BLANK               14900020
         BNE   IKJREC20                 NO                              14950020
         LA    XSCAN,ONE(XSCAN)         STEP TO NEXT CHARACTER          15000020
         CR    XSCAN,XSCEND             AT END OF RECORD                15050020
         BH    IKJREC00                 YES-GET NEXT RECORD             15100020
         B     IKJREC10                 NO-SEARCH FOR NON BLANK         15150020
IKJREC20 EQU   *                        WHAT TYPE OF RECORD             15200020
         CLC   RECNAME(SEVEN),ZERO(XSCAN) Q.IS IT DRIVER RECORD         15250020
         BNE   IKJREC00                 NO-GET NEXT RECORD              15300020
         LA    XSCAN,SIX(XSCAN)         YES-STEP SCAN PTR               15350020
         CR    XSCAN,XSCEND           Q AT END OF RECORD                15400020
         BH    IKJREC00                 YES-GET NEXT RECORD             15450020
         CLI   ERRORSW,ONE            Q.ERROR SWITCH SET                15500020
         BE    PARMUPDT                 YES- UPDATE PARM DATA           15550020
IKJREC30 EQU   *                                                        15600020
         LA    XSCAN,ONE(XSCAN)         STEP SCAN PTR                   15650020
IKJREC31 EQU   *                                                        15700020
         CR    XSCAN,XSCEND           Q.AT END OF RECORD                15750020
         BH    IKJREC00                 YES-GET NEXT RECORD             15800020
         CLI   ZERO(XSCAN),BLANK      Q.CHARACTER A BLANK               15850020
         BE    IKJREC30                 YES-STEP TO NEXT CHARACTER      15900020
         TM    SUBQSW,ONE            Q.SUBQUEUE SEAECH DONE             15950020
         BZ    HDLSUBQ0                 NO-HANDLE IT                    16000020
IKJREC32 EQU   *                                                        16050020
         LA    X1,KEYWORDS              PTR. TO KEYWORD TABLE           16100020
         SR    XWK1,XWK1                CLEAR FOR IC                    16150020
         SR    XWK2,XWK2                CLEAR FOR IC                    16200020
IKJREC40 EQU   *                                                        16250020
         IC    XWK1,ZERO(,X1)           LENGTH ATTRIBUTE OF KEYWORD     16300020
         IC    XWK2,ONE(,X1)            BRANCH FACTOR                   16350020
         EX    XWK1,COMPKYWD          Q.WHAT IS THE KEYWORD             16400020
         BE    BRTBKEND(XWK2)           FOUND                           16450020
         LA    X1,SIXTEEN(X1)           STEP TO NEXT KEYWORD TBLE SLOT  16500020
         CLC   ZERO(FOUR,X1),KEYWSTOP Q.AT END OF TABLE                 16550020
         BNE   IKJREC40                NO-STEP THRU TABLE               16600020
         TM    SUBQSW,ONE            Q.SUBQUE PARMS HANDLES             16650020
         BZ    IKJREC50                 NO                              16700020
         OI    BADKWD,FOUR              YES-SET BAD KEYWORD SWITCH      16750020
         TM    EOJSW,ONE              Q.EOJ FLAG SET                    16800020
         BZ    STEPOVR0                 NO-STEP TO NEXT PARAMETER       16850020
         USING ERRORMSG,XERMSG                                          16900020
         L     XSCAN,ZMSGAREA           RESET SCAN PTR.                 16950020
         MVC   ZWTOMS33(THIRTY1),CBLANKS CLEAR WTO VARIABLE AREA        17000020
         MVC   ZWTOMSG(THIRTY3),MSGZINVK WTO KEYWORD INVALID MSG.       17050020
         MVC   ZWTOMS33(TWENTY),ZERO(XSCAN)  KEYWORD IN WTOR MSG.       17100020
         MVC   ZMESSA42(TWENTY2),CBLANKS CLEAR UNUSED WTOR MSG AREA     17150020
         MVC   ZMESSAGE(FORTY2),MSGZKEYV WTOR MSG.                      17200020
         DROP  XERMSG                                                   17250020
         B     IKJEOJ                   MAKE INVALID KEYWORD MSG.       17300020
IKJREC50 EQU   *                                                        17350020
         TM    EOJSW,ONE              Q.EOJ FLAG SET                    17400020
         BZ    STEPOVR0                 NO-STEP TO NEXT PARAMETER       17450020
         USING ERRORMSG,XERMSG                                          17500020
         L     XSCAN,ZMSGAREA           RESET SCAN PTR.                 17550020
         DROP  XERMSG                                                   17600020
         B     IKJINV00                 YES-GET PROPER DATA FROM OPER.  17650020
         EJECT                                                          17700020
* THE FOLLOWING ARE THE KEYWORD HANDLING ROUTINES FOR 'FLAG TYPE'       17750020
* KEYWORDS                                                              17800020
*                                                                       17850020
HDWAIT   EQU   *                                                        17900020
         NI    DCAIFLGS,ALLFLAGS-DCAIWAIT    CLEAR FLAG                 17950020
         LA    XSCAN,FIVE(XSCAN)             STEP SCAN PTR. PAST KEYWD. 18000020
         B     IKJREC31                      CONTINUE SCAN OF RECORD    18050020
HDNOWAIT EQU   *                                                        18100020
         OI    DCAIFLGS,DCAIWAIT             SET FLAG                   18150020
         LA    XSCAN,SEVEN(XSCAN)            STEP SCAN PTR. PAST KEYWD. 18200020
         B     IKJREC31                      CONTINUE SCAN OF RECORD    18250020
HDACTIVI EQU   *                                                        18300020
         NI    DCAIFLGS,ALLFLAGS-DCAIRACT    CLEAR FLAG                 18350020
         LA    XSCAN,NINE(XSCAN)             STEP SCAN PTR. PAST KEYWD. 18400020
         B     IKJREC31                      CONTINUE SCAN OF RECORD    18450020
HDNOACTI EQU   *                                                        18500020
         OI    DCAIFLGS,DCAIRACT             SET FLAG                   18550020
         LA    XSCAN,ELEVEN(XSCAN)           STEP SCAN PTR. PAST KEYWD. 18600020
         B     IKJREC31                      CONTINUE SCAN OF RECORD    18650020
HDOCCUPA EQU   *                                                        18700020
         NI    DCAIFLGS,ALLFLAGS-DCAICORE    CLEAR FLAG                 18750020
         LA    XSCAN,TEN(XSCAN)              STEP SCAN PTR. PAST KEYWD. 18800020
         B     IKJREC31                      CONTINUE SCAN OF RECORD    18850020
HDNOOCCU EQU   *                                                        18900020
         OI    DCAIFLGS,DCAICORE             SET FLAG                   18950020
         LA    XSCAN,TWELVE(XSCAN)           STEP SCAN PTR. PAST KEYWD. 19000020
         B     IKJREC31                      CONTINUE SCAN OF RECORD    19050020
HDSWAPLO EQU   *                                                        19100020
         NI    DCAIFLGS,ALLFLAGS-DCAISWPL    CLEAR FLAG                 19150020
         LA    XSCAN,NINE(XSCAN)             STEP SCAN PTR. PAST KEYWD. 19200020
         B     IKJREC31                      CONTINUE SCAN OF RECORD    19250020
HDNOSWAP EQU   *                                                        19300020
         OI    DCAIFLGS,DCAISWPL             SET FLAG                   19350020
         LA    XSCAN,ELEVEN(XSCAN)           STEP SCAN PTR. PAST KEYWD. 19400020
         B     IKJREC31                      CONTINUE SCAN OF RECORD    19450020
HDAVGSER EQU   *                                                        19500020
         NI    DCAIFLGS,ALLFLAGS-DCAIAQST    CLEAR FLAG                 19550020
         LA    XSCAN,ELEVEN(XSCAN)           STEP SCAN PTR. PAST KEYWD. 19600020
         B     IKJREC31                      CONTINUE SCAN OF RECORD    19650020
HDNOAVGS EQU   *                                                        19700020
         OI    DCAIFLGS,DCAIAQST             SET FLAG                   19750020
         LA    XSCAN,THIRTEEN(XSCAN)         STEP SCAN PTR. PAST KEYWD. 19800020
         B     IKJREC31                      CONTINUE SCAN OF RECORD    19850020
HDNOBACK EQU   *                                                        19900020
         OI    DCAIFLGS,DCAIBKGD             SET FLAG                   19950020
         LA    XSCAN,THIRTEEN(XSCAN)         STEP SCAN PTR. PAST KEYWD. 20000020
         B     IKJREC31                      CONTINUE SCAN OF RECORD    20050020
HDPRIORI EQU   *                                                        20100020
         NI    DCAIFLGS,ALLFLAGS-DCAIPRTY    CLEAR FLAG                 20150020
         LA    XSCAN,NINE(XSCAN)             STEP SCAN PTR. PAST KEYWD. 20200020
         B     IKJREC31                      CONTINUE SCAN OF RECORD    20250020
HDNOPRIO EQU   *                                                        20300020
         OI    DCAIFLGS,DCAIPRTY             SET  FLAG                  20350020
         LA    XSCAN,ELEVEN(XSCAN)           STEP SCAN PTR. PAST KEYWD. 20400020
         B     IKJREC31                      CONTINUE SCAN OF RECORD    20450020
HDPREEMP EQU   *                                                        20500020
         OI    DCAIFLGS,DCAICRQL             SET FLAG                   20550020
         LA    XSCAN,EIGHT(XSCAN)            STEP SCAN PTR. PAST KEYWD. 20600020
         B     IKJREC31                      CONTINUE SCAN OF RECORD    20650020
HDNOPREE EQU   *                                                        20700020
         NI    DCAIFLGS,ALLFLAGS-DCAICRQL    CLEAR FLAG                 20750020
         LA    XSCAN,TEN(XSCAN)              STEP SCAN PTR. PAST KEYWD. 20800020
         B     IKJREC31                      CONTINUE SCAN OF RECORD    20850020
         EJECT                                                          20900020
* THE FOLLOWING ARE THE KEYWORD HANDLING ROUTINES FOR PLACING KEYWORD   20950020
* VALUES INTO THE DRIVER CONTROL AREA (DCA) CONTROL BLOCK.              21000020
*                                                                       21050020
HDBACKGR EQU   *                                                        21100020
         NI    DCAIFLGS,ALLFLAGS-DCAIBKGD    CLEAR FLAG                 21150020
         LA    XSCAN,ELEVEN(XSCAN)           STEP SCAN PTR. PAST KEYWD. 21200020
         BAL   XLINK,IKJHDV00           CONVERT PARM VALUE              21250020
         C     XWK2,FZERO             Q.VALUE LESS THAN ZERO            21300020
         BL    IKJREC50                 YES-ERROR                       21350020
         C     XWK2,FNINTY9           Q.VALUE GREATER THAN 99           21400020
         BH    IKJREC50                 YES-ERROR                       21450020
         STC   XWK2,DCABKGD             INTO CONTROL BLOCK SLOT         21500020
         CLI   DCABKGD,ZERO             BACKGROUND PERCENTAGE ZERO      21550020
         BNE   IKJEOJSS                 NO                              21600020
         OI    DCAIFLGS,DCAIBKGD        YES-SET IGNORE FLAG             21650020
         B     IKJEOJSS                 CHECK END OF JOB SWITCH         21700020
*                                                                       21750020
HDDECAYW EQU   *                                                        21800020
         LA    XSCAN,TEN(XSCAN)         STEP SCAN PTR. PAST KEYWD.      21850020
         BAL   XLINK,IKJHDV00           CONVERT PARM VALUE              21900020
         LTR   XWK2,XWK2              Q.VALUE ZERO OR NEGATIVE          21950020
         BNP   IKJREC50                 YES-ERROR                       22000020
         C     XWK2,FONETW8T         Q.VALUE EXCEED UPPER LIMIT         22050020
         BNL   IKJREC50                 YES-ERROR                       22100020
         L     X15,SMFADCO               SUBROUTINES ADDRESS            22150020
         LA    X15,EIGHT(,X15)          BRANCHING TABLE FACTOR          22200020
         ST    XBASE,DCALTOD+DCACPU1    SAVE MAINLINE BASE REG    M1683 22250021
         L     XBASE,SMFADCO            SUBROUTINES BASE REG.           22300020
         BALR  XLINK,X15                CONVERT DECAY CONSTANT-WAIT EST 22350020
* SPECIFIED IN 100TH'S TO SCALED VALUE.                                 22400020
         ST    X1,DCAKWAIT             PLACE IN PROPER DCA SLOT         22450020
         A     X1,SCALONE              INCREMENT SCALED VALUE BY        22500020
         ST    X1,DCAKWAI2             SCALED ONE                       22550020
         B     IKJEOJSS                 CHECK END OF JOB SWITCH         22600020
*                                                                       22650020
HDDECAYA EQU   *                                                        22700020
         LA    XSCAN,NINE(XSCAN)        STEP SCAN PTR. PAST KEYWD.      22750020
         BAL   XLINK,IKJHDV00           CONVERT PARM                    22800020
         LTR   XWK2,XWK2              Q.VALUE ZERO OR NEGATIVE          22850020
         BNP   IKJREC50                 YES-ERROR                       22900020
         C     XWK2,FONETW8T         Q.VALUE EXCEED UPPER LIMIT         22950020
         BNL   IKJREC50                 YES-ERROR                       23000020
         L     X15,SMFADCO              ADDR, OF SUBROUTINE             23050020
         LA    X15,EIGHT(,X15)          BRANCHING TABLE FACTOR          23100020
         ST    XBASE,DCALTOD+DCACPU1    SAVE MAINLINE BASE REG    M1683 23150021
         L     XBASE,SMFADCO            SUBROUTINES BASE REG.           23200020
         BALR  XLINK,X15                 CONVERT DECAY CONSTANT-REGION  23250020
* ACTIVITY-SPECIFIED IN 100TH'S TO SCALED VALUE                         23300020
         ST    X1,DCAKRACT             PLACE IN PROPER DCA SLOT         23350020
         A     X1,SCALONE              INCREMENT SCALED VALUE BY        23400020
         ST    X1,DCAKRAC2             SCALED ONE                       23450020
*                                                                       23500020
* THE FOLLOWING CODE DETERMINES IF END OF JOB PROCESSING IS BEING DONE. 23550020
* IF NOT,RECORD SCAN IS CONTINUED. IF SO,RETURN IS MADE TO THE CALLER.  23600020
*                                                                       23650020
IKJEOJSS EQU   *                                                        23700020
         TM    EOJSW,ONE              Q.EOJ SWITCH SET                  23750020
         BZ    IKJREC31                 NO-CONTINUE RECORD SCAN         23800020
         B     ZERO(X2LINK)             YES-RETURN TO CALLING ROUTINE   23850020
         EJECT                                                          23900020
* THIS ROUTINE WILL CONVERT THE SUBQUEUES PARAMETERS TO BINARY AND      23950020
* 'SAVE' THE RESULTANT QUANTITY IN THE CORRESPONDING REGION SLOT OF     24000020
* THE DCA WORKSPACE.                                                    24050020
*                                                                       24100020
HDLSUBQ0 EQU   *                                                        24150020
         CLC   ZERO(TEN,XSCAN),COMPSUBQ   Q.THIS A SUBQUEUES PARM       24200020
         BNE   STEPOVR0                 NO-STEP OVER IT                 24250020
         LA    XLINK,HDLSUBQ9           FOR LATER BR                    24300020
         LA    XSCAN,TEN(XSCAN)         STEP PAST KEYWORD               24350020
         LR    XWK1,XSCAN               FOR PACK EXECUTE                24400020
         SR    XWK2,XWK2               CLEAR FOR LENGTH CTR             24450020
HDLSUBQ3 EQU   *                                                        24500020
         CLI   ZERO(XSCAN),CZERO       Q.PROPER DIGIT                   24550020
         BL    IKJPARER                 NO                              24600020
         CLI   ZERO(XSCAN),CNINE       Q.PROPER DIGIT                   24650020
         BH    IKJPARER                 NO                              24700020
         LA    XSCAN,ONE(XSCAN)        STEP SCAN PTR                    24750020
         LA    XWK2,ONE(XWK2)          STEP LENGTH CTR                  24800020
         CLI   ZERO(XSCAN),RIGHTPAR    REGION DELIMITER REACHED         24850020
         BNE   HDLSUBQ3                NO-STEP TO NEXT SCAN CHARACTER   24900020
         LA    XSCAN,ONE(XSCAN)        YES-STEP OVER IT                 24950020
         CH    XWK2,HTWO               LENGTH VALUE TO LONG             25000020
         BH    IKJPARER                YES-  ERROR                      25050020
         BCTR  XWK2,ZERO               LENGTH FOR EXECUTE-LO 4 BITS     25100020
         O     XWK2,PACKDOUB           LENGTH FOR EXECUTE-HI 4 BITS     25150020
         EX    XWK2,IKJPACK             DO PACK                         25200020
         CVB   XWK2,DCATSTME            YIELDS REGION NUMBER            25250020
         XC    DCATSTME(EIGHT),DCATSTME CLEAR WORKSPACE AFTER PACK      25300020
HDLSUBQ8 EQU   *                                                        25350020
         CLI   ZERO(XSCAN),EQUALSGN   Q.NEXT CHARACTER EQUAL SIGN       25400020
         BNE   IKJPARER                 NO   ERROR                      25450020
         LA    XSCAN,ONE(XSCAN)         YES-STEP OVER IT                25500020
         LR    XWK1,XSCAN               FOR PACK EXECUTE                25550020
         SR    X1,X1                   CLEAR FOR LENGTH CTR             25600020
HDLSUBQ4 EQU   *                                                        25650020
         CLI   ZERO(XSCAN),CZERO       Q.PROPER DIGIT                   25700020
         BL    IKJPARER                 NO                              25750020
         CLI   ZERO(XSCAN),CNINE       Q.PROPER DIGIT                   25800020
         BH    IKJPARER                 NO                              25850020
         LA    XSCAN,ONE(XSCAN)        STEP SCAN PTR                    25900020
         LA    X1,ONE(X1)              STEP LENGTH CTR                  25950020
         CLI   ZERO(XSCAN),BLANK       RQEL   DELIMITER REACHED         26000020
         BNE   HDLSUBQ4                NO-STEP TO NEXT SCAN CHARACTER   26050020
         CH    X1,HTWO                 LENGTH VALUE TO LONG             26100020
         BH    IKJPARER                YES-  ERROR                      26150020
         BCTR  X1,ZERO                 LENGTH FOR EXECUTE-LO 4 BITS     26200020
         O     X1,PACKDOUB             LENGTH FOR EXECUTE-HI 4 BITS     26250020
         EX    X1,IKJPACK               DO PACK                         26300020
         CVB   X1,DCATSTME              YIELDS NO. OF RQELS             26350020
         XC    DCATSTME(EIGHT),DCATSTME CLEAR WORKSPACE AFTER PACK      26400020
         BR    XLINK                    IF ERROR-BACK TO ERROR ROUTINE  26450020
HDLSUBQ9 EQU   *                                                        26500020
         LTR   XWK2,XWK2             Q.REGION NO. ZERO OR NEG.          26550020
         BNP   IKJPARER                 YES-ERROR                       26600020
         CH    XWK2,FOURTN(XPARM)    Q.REGION NO. EXCEED PARM SPECIF.   26650020
         BH    IKJPARER                YES  ERROR                       26700020
         BCTR  XWK2,ZERO                DECREMENT FOR INDEXING          26750020
         AR    XWK2,XWK2                AND MULTIPLY                    26800020
         AR    XWK2,XWK2                BY FOUR                         26850020
         ST    X1,DCAEND(XWK2)          KEEP IN DCA REGION SLOT         26900020
         B     IKJREC30                 CONTINUE SEARCH                 26950020
IKJPARER EQU   *                                                        27000020
         CLI   ERRORSW,ONE            Q.ENTRY FROM ERROR ROUTINE        27050020
         BE    RQELER2                  YES-ASK AGAIN                   27100020
         B     STEPOVR1                 NO-STEP OVER THIS PARM          27150020
STEPOVR0 EQU   *                                                        27200020
         LA    XSCAN,ONE(XSCAN)                                         27250020
STEPOVR1 EQU   *                                                        27300020
         CR    XSCAN,XSCEND           Q.AT END OF RECORD                27350020
         BH    IKJREC00                 YES-GET NEXT RECORD             27400020
         CLI   ZERO(XSCAN),BLANK        DELIMETER REACHED               27450020
         BNE   STEPOVR0                 NO-CONTINUE STEPPING SCAN PTR   27500020
         B     IKJREC30                 YES-CONTINUE SEARCH FOR NON BL. 27550020
*                                                                       27600020
* THIS ROUTINE IS USED ON THE SECOND PASS TO BYPASS SUBQUEUE KEYWORDS.  27650020
*                                                                       27700020
HDSUBQUE EQU   *                                                        27750020
         LA    XSCAN,NINE(XSCAN)        STEP OVER THIS KEYWORD          27800020
         B     STEPOVR0                 AND STEP TILL BLANK FOUND       27850020
         EJECT                                                          27900020
*                                                                       27950020
* THE FOLLOWING ARE THE KEYWORD HANDLING ROUTINES FOR PLACING KEYWORD   28000020
* VALUES INTO THE SPECIFIED REGION QUEUE ELEMENT (RQEL) CONTROL BLOCK.  28050020
HDCYCLES EQU   *                                                        28100020
         LA    XSCAN,SEVEN(XSCAN)       STEP SCAN PTR. PAST KEYWD.      28150020
         BAL   XLINK,IKJHDRCY           GET RQEL PTR.                   28200020
         BAL   XLINK,IKJHDV00           CONV. PARM. VALUE               28250020
         LTR   XWK2,XWK2              Q.VALUE NEGATIVE                  28300020
         BM    IKJREC50                 YES-ERROR                       28350020
         USING RQEL,X15                                                 28400020
         STH   XWK2,RQEL#CYC            STORE IN PROPER RQEL            28450020
         STH   XWK2,RQELCYC#            INITIALIZE CYCLE COUNT          28500020
         OI    RCYCDONE,ONE            MARK RQEL CYCLE VALUE RECEIVED   28550020
         DROP  X15                                                      28600020
         B     IKJEOJSS                 CONTINUE TO NEXT                28650020
HDMAXSWA EQU   *                                                        28700020
         LA    XSCAN,EIGHT(XSCAN)       STEP SCAN PTR. PAST KEYWD.      28750020
         BAL   XLINK,IKJHDRCY           GET RQEL PTR                    28800020
         BAL   XLINK,IKJHDV00           CONV. PARM. VALUE               28850020
         LTR   XWK2,XWK2              Q.PARM VALUE ZERO OR NEGATIVE     28900020
         BNP   IKJREC50                 YES-ERROR                       28950020
         USING RQEL,X15                                                 29000020
         SRL   XWK2,ONE                MAKE 2K VALUE                    29050020
         STH   XWK2,RQELSIZE            STORE IN PROPER RQEL            29100020
         DROP  X15                                                      29150020
         B     IKJEOJSS                 CONTINUE TO NEXT                29200020
HDMAXOCC EQU   *                                                        29250020
         LA    XSCAN,THIRTEEN(XSCAN)    STEP SCAN PTR. PAST KEYWD.      29300020
         BAL   XLINK,IKJHDRCY           GET RQEL PTR.                   29350020
         BAL   XLINK,IKJHDV00           CONV. PARM. VALUE               29400020
         LTR   XWK2,XWK2              Q.PARM VALUE ZERO OR NEGATIVE     29450020
         BNP   IKJREC50                 YES-ERROR                       29500020
         USING RQEL,X15                                                 29550020
         MH    XWK2,HTHREE             CONV.TIME DATA TO 3.3MSEC TU'S   29600020
         ST    XWK2,RQELTCO             STORE IN PROPER RQEL            29650020
         DROP  X15                                                      29700020
         B     IKJEOJSS                 CONTINUE TO NEXT                29750020
HDSERVIC EQU   *                                                        29800020
         LA    XSCAN,EIGHT(XSCAN)       STEP SCAN PTR. PAST KEYWD.      29850020
         BAL   XLINK,IKJHDRCY           GET RQEL PTR.                   29900020
         BAL   XLINK,IKJHDV00           CONV. PARM VALUE                29950020
         LTR   XWK2,XWK2              Q.VALUE ZERO OR NEGATIVE          30000020
         BNP   IKJREC50                 YES-ERROR                       30050020
         USING RQEL,X15                                                 30100020
         MH    XWK2,HTHREE             CONV.TIME DATA TO 3.3MSEC TU'S   30150020
         ST    XWK2,RQELAQST            STORE IN PROPER RQEL            30200020
         DROP  X15                                                      30250020
         B     IKJEOJSS                 CONTINUE TO NEXT                30300020
HDMINSLI EQU   *                                                        30350020
         LA    XSCAN,NINE(XSCAN)        STEP SCAN PTR. PAST KEYWD.      30400020
         BAL   XLINK,IKJHDRCY           GET RQEL PTR.                   30450020
         BAL   XLINK,IKJHDV00           CONV. PARM. VALUE               30500020
         LTR   XWK2,XWK2              Q.VALUE ZERO OR NEGATIVE          30550020
         BNP   IKJREC50                 YES-ERROR                       30600020
         USING RQEL,X15                                                 30650020
         MH    XWK2,HTHREE             CONV.TIME DATA TO 3.3MSEC TU'S   30700020
         ST    XWK2,RQELMSLC            STORE IN PROPER RQEL            30750020
         DROP  X15                                                      30800020
         B     IKJEOJSS                 CONTINUE TO NEXT                30850020
         EJECT                                                          30900020
* THIS ROUTINE IS ENTERED DURING THE INITIALIZATION PHASE AFTER THE     30950020
* FIRST  PASS THRU THE PARAMETER LIST HAS BEEN COMPLETED.               31000020
* X1 - MAIN STORAGE REQUIRED FOR DRIVER CONTROL BLOCKS                  31010020
*                                                                       31050020
IKJENDD0 EQU   *                                                        31100020
         O     X1,SUBP252               OR SUBPOOL ID IN HI BYTE        31110020
         L     X15,SMFADCO                                              31150020
         LA    X15,FOUR(,X15)           FOR SUBROUTINE BRANCH TABLE     31200020
         ST    XBASE,DCALTOD+DCACPU1    SAVE MAINLINE BASE REG.   M1683 31250021
         L     XBASE,SMFADCO            SUBROUTINES BASE REG.           31300020
         BALR  X2LINK,X15              GET AND CLEAR TOTAL CORE REQ.    31350020
         L     XBASE,DCALTOD+DCACPU1    RESTORE MAINLINE BASEREG  M1683 31400021
         XC    DCALTOD+DCACPU1(FOUR),DCALTOD+DCACPU1              M4909 31450000
*                                              CLEAR WORKAREA SLOTM1683 31460000
         LA    XWK1,DCAEND              PTR TO FIRST RQEL QUANTITY      31500020
         LA    XDCARE,DCALEN            LENGTH OF DCA CTRL. BLOCK       31550020
         AR    XDCARE,X0                PTR. TO DCARE SLOT              31600020
         USING DCARE,XDCARE                                             31650020
         LR    XRQEL,XDCARE                                             31700020
         LH    X14,FOURTN(XPARM)        NO. OF REGIONS                  31750020
IKJENDD1 EQU   *                                                        31800020
         LA    XRQEL,DCARELEN(XRQEL)    STEP TO END OF DCARE            31850020
         BCT   X14,IKJENDD1             STEP TO END OF ALL DCARES       31900020
         LH    X14,FOURTN(XPARM)        NO. OF REGIONS FOR STOPPER      31950020
         LR    X2LINK,XRQEL             SAVE TOP OF RQEL AREA           32000020
         USING RQEL,XRQEL                                               32050020
         SR    X15,X15                  TOP RQEL OFFSET PER DCARE       32100020
IKJENDD4 EQU   *                                                        32150020
         STH   X15,DCARTRQ              OFFSET IN DCARE FOR TOP         32200020
         STH   X15,DCARCRQ              AND CURRENT RQEL                32250020
         L     XSCEND,ZERO(,XWK1)       NO. OF RQELS FOR REGION         32300020
         ST    XSCEND,DCARHTME          SAVED FOR PARM HANDLING         32350020
         ST    XRQEL,DCARTMIN           PTR. TO TOP RQEL FOR REGION     32400020
         LA    XWK2,RQELLEN             LENGTH OF RQEL                  32450020
         MH    XWK2,DCARHTM2            TIMES NO. PER REGION YIELDS     32500020
         AR    X15,XWK2                 TOTAL OFFSET FROM FIRST RQEL    32550020
*                                       FOR NEXT REGION DCARE           32600020
         BCTR  XSCEND,ZERO             DECREMENT FOR LATER BCT          32650020
         CH    XSCEND,FZERO           Q.ONLY ONE RQEL FOR REGION        32700020
         BE    IKJENDD3                 YES-GO AROUND BCT               32750020
IKJENDD2 EQU   *                                                        32800020
         OI    RQELFLGS,RQLIND         MARK RQEL AS SUCH                32850020
         LA    XRQEL,RQELLEN(XRQEL)     STEP TO NEXT                    32900020
         BCT   XSCEND,IKJENDD2         NOT LAST RQEL FOR REG.-LOOP      32950020
IKJENDD3 EQU   *                                                        33000020
         OI    RQELFLGS,RQLIND+RQLLAST  MARK RQEL LAST FOR REGION       33050020
         LA    XRQEL,RQELLEN(XRQEL)     STEP TO NEXT RQEL OR 1ST UQEL   33100020
         LA    XWK1,FOUR(XWK1)          STEP TO NEXT WORK SLOT          33150020
         LA    XDCARE,DCARELEN(XDCARE)  STEP TO NEXT DCARE              33200020
         BCT   X14,IKJENDD4           Q.END OF REGION WORK SLOTS        33250020
         DROP  XRQEL                                                    33300020
         DROP  XDCARE                                                   33350020
         IC    XWK2,SUBQSW              SAVE SWITCH SETTING             33400020
         LR    XWK1,X0                 SAVE PTR. TO PERM. SPACE         33450020
         LH    X0,FOURTN(,XPARM)        NO. OF REGIONS                  33500020
         MH    X0,HFOUR                 WORKSPACE FOR REGIONS           33550020
         LA    X1,DCALEN                LENGTH OF DCA CTRL. BLOCK       33600020
         AR    X0,X1                    TOTAL CORE TO FREE              33650020
         O     X0,SP251      SUBPOOL 251.                        A44022 33670021
         LR    X1,XWKSP                 PTR. TO AREA TO FREEMAIN        33700020
         LR    XWKSP,XWK1               PTR. TO PERM DCA AREA           33750020
         STC   XWK2,SUBQSW              RESTORE SWITCH SETTING          33800020
         FREEMAIN   R,LV=(0),A=(1)      WORKSPACE GONE                  33850020
         ST    X2LINK,DCAQELS           INITIALIZE TOP RQEL PTE.        33900020
         LA    X1,UQELLEN               LENGTH OF UQEL                  33950020
         LR    XWK2,XRQEL               KEEP UQEL PTR                   34000020
         USING UQEL,XWK2                                                34050020
        ST    XRQEL,DCAUQEL0           INITIALIZE ADDR. OF VIR. UQEL    34100020
         LR    XRQEL,X2LINK             TOP RQEL PTR.                   34150020
         USING RQEL,XRQEL                                               34200020
         SR    X15,X15                  RELATIVE RQEL/UQEL OFFSET       34250020
         MH    X1,TWO(XPARM)            LENGTH TIMES NO. OF UQELS       34300020
         LA    X1,UQELLEN(,X1)          ADD LENGTH OF DUMMY UQEL        34350020
         AR    X1,XWK2                  END OF UQELS PTR.               34400020
IKJENDD5 EQU   *                                                        34450020
         STH   X15,RQELTUQL             RELATIVE RQEL OFFSET IN RQEL    34500020
         STH   X15,RQELBUQL             SLOTS                           34550020
         STH   X15,RQELCUQL                                             34560020
         LA    X15,RQELLEN(,X15)        STEP TO NEXT RELATIVE OFFSET    34600020
         LA    XRQEL,RQELEND            STEP TO NEXT RQEL               34650020
         CR    XRQEL,XWK2             Q.AT UQELS YET                    34700020
         BL    IKJENDD5                 NO-CONTINUE WITH RQELS          34750020
IKJENDD6 EQU   *                                                        34800020
         STH   X15,UQELNUQL             UPDATE UQEL SLOTS FOR           34850020
         STH   X15,UQELPUQL             RELATIVE OFFSET                 34900020
         LA    X15,UQELLEN(,X15)        STEP TO NEXT RELATIVE OFFSET    34950020
         LA    XWK2,UQELEND             STEP TO NEXT UQEL               35000020
         CR    XWK2,X1               Q.AT END OF UQELS                  35050020
         BL    IKJENDD6                 NO CONTINUE UPDATING UQELS      35100020
         DROP  XRQEL                                                    35150020
         DROP  XWK2                                                     35200020
         MVI   DCAIFLGS,DEFFLGS         INITIALIZE FLAGS-DEFAULT        35250020
         LH    X1,FOURTN(,XPARM)                                        35300020
         STC   X1,DCA#RGNS              INITIALIZE NO. OF REGIONS       35350020
         MVC   DCA#UQEL,TWO(XPARM)      INITIALIZE MAX. NO. OF USERS    35400020
         ST    XWKSP,SIXTEEN(,XPARM)    RETURN ANCHOR TO TSC            35450020
         B     IKJRECIN                 MAKE NEXT PASS AT PARMS         35500020
         EJECT                                                          35550020
* THIS ROUTINE IS ENTERED TO COMPLETE INITIALIZATION CLEAN UP AND       35600020
* TO CHECK IF ALL REQUIRED PARAMETER VALUES HAVE BEEN RECEIVED PRIOR    35650020
* TO THE RETURN TO TSC.                                                 35700020
IKJENDE0 EQU   *                                                        35750020
         OI    EOJSW,ONE                SET EOJ SWITCH                  35800020
         LA    XDCARE,DCAEND            PTR. TO 1ST DCARE               35850020
         USING DCARE,XDCARE                                             35900020
         USING ERRORMSG,XERMSG          DSECT PTR LOADER AT IKJENDR1    35950020
IKJENDE1 EQU   *                                                        36000020
         L     XRQEL,DCARTMIN           PTR. TO 1ST RQEL FOR REGION     36050020
         USING RQEL,XRQEL                                               36100020
IKJENDEA EQU   *                                                        36150020
         TM    RCYCDONE,ONE           Q.RQEL CYCLE VALUE SUPPLIED       36200020
         BNZ   IKJENDIA                 YES-PROCEED                     36250020
         MVC   ZWTOMS33(THIRTY1),CBLANKS     CLEAR WTO VARIABLE AREA    36300020
         MVC   ZWTOMSG(THIRTY3),MSGZMISS     WTO KEYWORD MISSING MSG    36350020
         MVC   ZWTOMS33(SEVEN),KCYCLES       MISSING KEYWORD NAME       36400020
         MVC   ZMESSA42(TWENTY2),CBLANKS      CLEAR UNUSED WTOR MSG ARA 36450020
         MVC   ZMESSAGE(FORTY2),MSGZKEYV     WTOR MSG                   36500020
         LA    X1,ZWTOMS33                                              36550020
         LA    X1,SEVEN(X1)             PTR. TO MSG. PARM SLOT          36600020
         LA    XMSGL,EIGHTEEN           WTOR REPLY MSG. LENGTH          36650020
         L     X15,SMFADCO              SUBROUTINES ADDRESS             36700020
         LA    X15,TWELVE(,X15)         BRANCH TABLE FACTOR             36750020
         ST    XBASE,DCALTOD+DCACPU1    SAVE BASE REG-MAINLINE    M1683 36800021
         L     XBASE,SMFADCO            SUBROUTINE BASE ADDRESS         36850020
         BALR    X2LINK,X15             TO SUBROUTINE                   36900020
         BAL   X2LINK,IKJEOJ            MAKE ERROR MESSAGE              36950020
IKJENDIA EQU   *                                                        37000020
         NI    RCYCDONE,ALLFLAGS-ONE    YES-CLEAR IT                    37050020
         TM    DCAIFLGS,DCAICORE      Q.IGNORE CORE OCCUPANCY BIT SET   37100020
         BO    IKJENDE2                 YES- DO NOT CHECK FOR VALUE     37150020
         L     XWK1,RQELTCO                                             37200020
         LTR   XWK1,XWK1              Q.CORE OCCUPANCY VALUE SUPPLIED   37250020
         BP    IKJENDE2                 YES-OK                          37300020
         MVC   ZWTOMS33(THIRTY1),CBLANKS     CLEAR WTO VARIABLE AREA    37350020
         MVC   ZWTOMSG(THIRTY3),MSGZMISS     WTO KEYWORD MISSING MSG    37400020
         MVC   ZWTOMS33(THIRTEEN),KMAXOCCU   MISSING KEYWORD NAME       37450020
         MVC   ZMESSA42(TWENTY2),CBLANKS      CLEAR UNUSED WTOR MSG ARA 37500020
         MVC   ZMESSAGE(FORTY2),MSGZKEYV     WTOR MSG                   37550020
         LA    X1,ZWTOMS33                                              37600020
         LA    X1,THIRTEEN(X1)          PTR. TO MSG. PARM SLOT          37650020
         LA    XMSGL,TWENTY8            WTOR REPLY MSG. LENGTH          37700020
         L     X15,SMFADCO              SUBROUTINE ADDRESS              37750020
         LA    X15,TWELVE(,X15)         BRANCH TABLE FACTOR             37800020
         ST    XBASE,DCALTOD+DCACPU1    SAVE MAINLINE BASE REG.   M1683 37850021
         L     XBASE,SMFADCO            SUBROUTINE BASE REGISTER        37900020
         BALR  X2LINK,X15               TO SUBROUTINE                   37950020
         BAL   X2LINK,IKJEOJ            MAKE ERROR MESSAGE              38000020
IKJENDE2 EQU   *                                                        38050020
         TM    DCAIFLGS,DCAISWPL     Q.IGNORE SWAP LOAD BIT SET         38100020
         BO    IKJENDE3                 YES- DO NOT  CHECK FOR VALUE    38150020
         LH    XWK1,RQELSIZE                                            38200020
         LTR   XWK1,XWK1              Q.SWAP LOAD SIZE VALUE SUPPLIED   38250020
         BP    IKJENDE3                 YES-OK                          38300020
         MVC   ZWTOMS33(THIRTY1),CBLANKS     CLEAR WTO VARIABLE AREA    38350020
         MVC   ZWTOMSG(THIRTY3),MSGZMISS     WTO KEYWORD MISSING MSG    38400020
         MVC   ZWTOMS33(EIGHT),KMAXSWAP      MISSING KEYWORD NAME       38450020
         MVC   ZMESSA42(TWENTY2),CBLANKS      CLEAR UNUSED WTOR MSG ARA 38500020
         MVC   ZMESSAGE(FORTY2),MSGZKEYV     WTOR MSG                   38550020
         LA    X1,ZWTOMS33                                              38600020
         LA    X1,EIGHT(X1)             PTR. TO MSG. PARM SLOT          38650020
         LA    XMSGL,TWENTY3            WTOR REPLY MESSAGE LENGTH       38700020
         L     X15,SMFADCO              SUBROUTINES ADDRESS             38750020
         LA    X15,TWELVE(,X15)         BRANCH TABL FACTOR              38800020
         ST    XBASE,DCALTOD+DCACPU1    SAVE MAINLINE BASE REG.   M1683 38850021
          L    XBASE,SMFADCO            SUBROUTINES BASE REG.           38900020
         BALR  X2LINK,X15               TO SUBROUTINE                   38950020
         BAL   X2LINK,IKJEOJ            MAKE ERROR MESSAGE              39000020
IKJENDE3 EQU   *                                                        39050020
         TM    DCAIFLGS,DCAIAQST      Q.IGNORE AVE. Q SERV. BIT SET     39100020
         BO    IKJENDE4                 YES- DO NOT CHECK FOR VALUE     39150020
         L     XWK1,RQELAQST          Q.AVE. Q.SERVICE VALUE SUPPLIED   39200020
         LTR   XWK1,XWK1                                                39250020
         BP    IKJENDE4                 YES-OK                          39300020
         MVC   ZWTOMS33(THIRTY1),CBLANKS    CLEAR WTO VARIABLE AREA     39350020
         MVC   ZWTOMSG(THIRTY3),MSGZMISS     WTO KEYWORD MISSING MSG    39400020
         MVC   ZWTOMS33(EIGHT),KSERVICE     MISSING KEYWORD NAME        39450020
         MVC   ZMESSA42(TWENTY2),CBLANKS      CLEAR UNUSED WTOR MSG ARA 39500020
         MVC   ZMESSAGE(FORTY2),MSGZKEYV     WTOR MSG                   39550020
         LA    X1,ZWTOMS33                                              39600020
         LA    X1,EIGHT(X1)             PTR. TO MSG. PARM SLOT          39650020
         LA    XMSGL,TWENTY3            WTOR REPLY MESSAGE LENGTH       39700020
         L     X15,SMFADCO              SUBROUTINES ADDRESS             39750020
         LA    X15,TWELVE(,X15)         BRANCH TABLE FACTOR             39800020
         ST    XBASE,DCALTOD+DCACPU1    SAVE MAINLINE BASE REG.   M1683 39850021
         L     XBASE,SMFADCO            SUBROUTINE BASE ADDRESS         39900020
         BALR  X2LINK,X15               TO SUBROUTINE                   39950020
         BAL   X2LINK,IKJEOJ            MAKE ERROR MESSAGE              40000020
IKJENDE4 EQU   *                                                        40050020
         L     XWK1,RQELMSLC                                            40100020
         LTR   XWK1,XWK1              Q.MIN. SLICE VALUE SUPPLIED       40150020
         BP    IKJENDE5                 YES-OK                          40200020
         MVC   ZWTOMS33(THIRTY1),CBLANKS    CLEAR WTO VARIABLE AREA     40250020
         MVC   ZWTOMSG(THIRTY3),MSGZMISS     WTO KEYWORD MISSING MSG    40300020
         MVC   ZWTOMS33(NINE),KMINSLIC      MISSING KEYWORD NAME        40350020
         MVC   ZMESSA42(TWENTY2),CBLANKS      CLEAR UNUSED WTOR MSG ARA 40400020
         MVC   ZMESSAGE(FORTY2),MSGZKEYV     WTOR MSG                   40450020
         LA    X1,ZWTOMS33                                              40500020
         LA    X1,NINE(X1)              PTR. TO MSG. PARM SLOT          40550020
         LA    XMSGL,TWENTY3            WTOR REPLY MESSAGE LENGTH       40600020
          L    X15,SMFADCO                                              40650020
         LA    X15,TWELVE(,X15)          FOR BRANCH TABLE               40700020
         ST    XBASE,DCALTOD+DCACPU1    SAVE MAINLINE BASE REG    M1683 40750021
         L     XBASE,SMFADCO            BASE REG FOR SUBROUTINES        40800020
         BALR  X2LINK,X15               MOVE PARAMETERS INTO MESSAGE    40850020
         BAL   X2LINK,IKJEOJ            MAKE ERROR MESSAGE              40900020
IKJENDE5 EQU   *                                                        40950020
         TM    RQELFLGS,RQLLAST       Q.LAST RQEL FOR REGION            41000020
         BO    IKJENDEB                 YES-STEP TO NEXT REGION         41050020
         LA    XRQEL,RQELEND            NO-STEP TO NEXT RQEL            41100020
         B     IKJENDEA                 AND GO AGAIN                    41150020
IKJENDEB EQU   *                                                        41200020
         XC    DCARHTME,DCARHTME        CLEAR WORKSPACE IN DCARE        41250020
         XC    DCARTMIN,DCARTMIN                                        41300020
         LA    XDCARE,DCAREND           STEP TO NEXT REGION             41350020
         C     XDCARE,DCAQELS         Q.ALL REGIONS CHECKED             41400020
         BNE   IKJENDE1                 NO-GO AGAIN-YES-CHECK DCA VALUE 41450020
         DROP  XDCARE                                                   41500020
         TM    DCAIFLGS,DCAIWAIT      Q.IGNORE WAIT EST. FLAG SET       41550020
         BO    IKJENDES                 YES  DO NOT CHECK FOR VALUE     41600020
         L     XWK1,DCAKWAIT            WAIT ESTIMATE VALUE SUPPLIED    41650020
         LTR   XWK1,XWK1                                                41700020
         BP    IKJENDES                 YES-OK                          41750020
         MVC   ZWTOMS33(THIRTY1),CBLANKS    CLEAR WTO VARIABLE AREA     41800020
         MVC   ZWTOMSG(THIRTY3),MSGZMISS     WTO KEYWORD MISSING MSG    41850020
         MVC   ZWTOMS33(NINE),KDECAYWA      MISSING KEYWORD NAME        41900020
         MVC   ZMESSA42(TWENTY2),CBLANKS      CLEAR UNUSED WTOR MSG ARA 41950020
         MVC   ZMESSAGE(FORTY7),MSGZKEYU     WTOR MESSAGE               42000020
         LA    XMSGL,FIFTN              WTOR REPLY MESSAGE LENGTH       42050020
         BAL   X2LINK,IKJEOJ            MAKE ERROR MESSAGE              42100020
IKJENDES EQU   *                                                        42150020
         TM    DCAIFLGS,DCAIRACT      Q.IGNORE REGION ACT. BIT SET      42200020
         BO    IKJENDE6                 YES- DO NOT CHECK VALUE         42250020
         L     XWK1,DCAKRACT          Q.REGION ACTIVITY VALUE SUPPLIED  42300020
         LTR   XWK1,XWK1                                                42350020
         BP    IKJENDE6                 YES-OK                          42400020
         MVC   ZWTOMS33(THIRTY1),CBLANKS     CLEAR WTO VARIABLE AREA    42450020
         MVC   ZWTOMSG(THIRTY3),MSGZMISS     WTO KEYWORD MISSING MSG    42500020
         MVC   ZWTOMS33(EIGHT),KDECAYAC      MISSING KEYWORD NAME       42550020
         MVC   ZMESSA42(TWENTY2),CBLANKS      CLEAR UNUSED WTOR MSG ARA 42600020
         MVC   ZMESSAGE(FORTY7),MSGZKEYU     WTOR MESSAGE               42650020
         LA    XMSGL,FOURTN             WTOR REPLY MESSAGE LENGTH       42700020
         BAL   X2LINK,IKJEOJ            MAKE ERROR MESSAGE              42750020
IKJENDE6 EQU   *                                                        42800020
         TM    DCAIFLGS,DCAIBKGD      Q.IGNORE BACKGROUND BIT SET       42850020
         BO    IKJENDE7                 YES-DO NOT CHECK VALUE          42900020
         SR    XWK1,XWK1                                                42950020
         IC    XWK1,DCABKGD          Q.BACKGROUND VALUE SUPPLIED        43000020
         LTR   XWK1,XWK1                                                43050020
         BP    IKJENDE7                 YES-OK                          43100020
         MVC   ZWTOMS33(THIRTY1),CBLANKS     CLEAR WTO VARIABLE AREA    43150020
         MVC   ZWTOMSG(THIRTY3),MSGZMISS     WTO KEYWORD MISSING MSG    43200020
         MVC   ZWTOMS33(TEN),KBACKGRO        MISSING KEYWORD NAME       43250020
         MVC   ZMESSA42(TWENTY2),CBLANKS      CLEAR UNUSED WTOR MSG ARA 43300020
         MVC   ZMESSAGE(FORTY7),MSGZKEYU     WTOR MESSAGE               43350020
         LA    XMSGL,THIRTEEN           WTOR REPLY MESSAGE LENGTH       43400020
         BAL   X2LINK,IKJEOJ            MAKE ERROR MESSAGE              43450020
IKJENDE7 EQU   *                                                        43500020
         SR    XRETC,XRETC              RETURN CODE-ALL IS WELL         43550020
         B     IKJCKMOD                 CHECK FOR START DRIVER OVERRIDE 43600020
*                                                                       43650020
* THIS ROUTINE WILL SET UP THE KEYWORD INVALID MESSAGE AND THEN GO TO   43700020
* THE WRITE ERROR MESSAGES ROUTINE.                                     43750020
IKJINV00 EQU   *                                                        43800020
         MVC   ZMESSAGE(FORTY2),MSGZKEYV WTOR MSG.                      43850020
         MVC   ZMSG42(TWENTY2),CBLANKS       CLEAR WTOR MSG. AREA       43900020
         MVC   ZWTOMS33(THIRTY1),CBLANKS CLEAR WTO MSG AREA             43950020
         MVC   ZWTOMSG(FORTY6),MSGZINVV INVALID KEYWORD WTO             44000020
         MVC   ZWTOMS46(EIGHTEEN),ZERO(XSCAN) INVALID OPER REPLY        44050020
         OI    DCAFLAGS+DCACPU1,SIXTEEN SET MS46 KEYWORD SW.      M1683 44070021
         B     IKJEOJ                   MAKE MSSSAGE AGAIN              44100020
         SPACE                                                          44150020
* THIS ROUTINE WILL CHECK TO SEE IF THE START TSO COMMAND HAS SPECIFIED 44200020
* A GUARANTEED BACKGROUND PERCENTAGE VALUE                              44250020
IKJCKMOD EQU   *                                                        44300020
         L     XSCAN,TWENTY(,XPARM)   Q.ANY START OVERRIDES             44350020
         LA    XSCAN,ZERO(XSCAN)        CLEAR SMF IND.-HI ORDER BIM3870 44360020
         LTR   XSCAN,XSCAN                                              44400020
         BZ    IKJRETUR                 NO-RETURN TO TSC MAINLINE       44450020
         L     X15,SMFADCO              YES-GO TO SUBROUYINE TO HDLE    44500020
         LA    X15,TWENTY(,X15)         FOR SUBROUTINW BR. TBLE.        44550020
         ST    XBASE,DCALTOD+DCACPU1    SAVE MAINLINE BASE REG.   M1683 44600021
         L     XBASE,SMFADCO            SUBROUTINE BASE REG.            44650020
          BALR XLINK,X15                HANDLE START PARM. OVERRIDES    44700020
         B     IKJRETUR                 RETURN TO TSC                   44750020
         EJECT                                                          44800020
* THIS ROUTINE IS ENTERED WHENEVER A PASS THROUGH THE PARAMETER LIST    44850020
* HAS BEEN COMPLETED.                                                   44900020
IKJENDRC EQU   *                        END OF RECORDS                  44950020
         CLI   ERRORSW,ZERO           Q.ERROR SWITCH SET                45000020
         BE    IKJENDR0                 NO-OK                           45050020
         LA    XRETC,EIGHT              YES-UNRECOVERABLE ERROR         45100020
         SR    XSW,XSW                  CLEAR SO WKSPACE FREED PROPER   45150020
         B     IKJRETUR                 RETURN TO TSC                   45200020
IKJENDR0 EQU   *                                                        45250020
         LTR   XSW,XSW               Q.PRE-INITIALIZATION PHASE         45300020
         BZ    IKJENDR1                YES-FIND TOTAL SPACE             45350020
         TM    SUBQSW,ONE            Q.ONLY SUBQUEUE PASS DONE          45400020
         BO    IKJENDE0                 NO-BOTH PASSES COMPLETE         45450020
         OI    SUBQSW,ONE               YES-SET SUBQUEUES PASS DONE SW. 45500020
IKJENDR1 EQU   *                                                        45550020
         L     X15,SMFADCO              SUBROUTINES BASE ADDRESS        45600020
         LA    X15,SIXTEEN(X15)         BRANCH TABLE ENTRY              45650020
         ST    XBASE,DCALTOD+DCACPU1    SAVE BASE REGISTER        21008 45700021
         L     XBASE,SMFADCO            BASE REG FOR SUBROUTINE         45750020
          BALR XLINK,X15                SET UP ERROR MSG. SETUP         45800020
         CH    X0,HTHIRTY4           Q.SIZE EXCEED MINIMUM              45850020
         BH    IKJENDR5                 YES-CONTINUE                    45900020
         LA    X0,THIRTY4               MINIMUM SIZE                    45950020
IKJENDR5 EQU   *                                                        46000020
         LR    XWK1,X0       SAVE LENGTH IN XWK1.                A44022 46030021
         O     X0,SP251      SUBPOOL 251.                        A44022 46060021
         GETMAIN R,LV=(0)                                        A44022 46090021
         ST    X1,ZMSGAREA              SAVE PTR.                       46150020
         ST    XWK1,ZMSGLENG            + LENGTH                        46200021
         BCTR  XWK1,ZERO                LESS ONE FOR EX                 46250020
         BCTR  XWK1,ZERO                AND ONE FOR MVI BLANK           46300020
         MVI   ZERO(X1),BLANK                                           46350020
         EX    XWK1,IKJBLANK                                            46400020
         SH    X1,HEIGHTEN              PREPARE FOR LATER               46450020
         ST    X1,ZRPLYAD               WTOR ROUTINE                    46500020
         BCTR  XWK1,ZERO                DECREMENT LENGTH BY TWO MORE    46550020
         BCTR  XWK1,ZERO                FOR 4 TOTAL                     46600020
         AH    X1,HEIGHTEN              PUT BACK PREV, SUB              46650020
         AR    X1,XWK1                  AND ADD TO BEGINNING FOR STOP   46700020
         MVC   ZERO(FOUR,X1),KEYWSTOP   MARK STOPPER                    46750020
IKJENDR2 EQU   *                                                        46800020
         L     X1,ZERO(,XWK2)           RQEL QUANTITY FOR REGION        46850020
         LTR   X1,X1                  Q.QUANTITY POSITVE                46900020
         BNP   RQELER1                  NO-ERROR                        46950020
IKJENDR3 EQU   *                                                        47000020
         AR    XDAEND,X1                ADD TO TOTAL                    47050020
         LA    XWK2,FOUR(XWK2)          STEP TO NEXT RQEL SLOT          47100020
         BCT   XSCEND,IKJENDR2        Q.ALL RQEL SLOTS CHECKED          47150020
         CLI   ERRORSW,ONE            Q.YES-ANY ERRORS                  47200020
         BNE   IKJENDR4                 NO-CONTINUE                     47250020
         L     XWK1,ZMSGAREA            YES-LOAD PTR. TO DATA AND       47300020
         LR    X0,XDAEND                SAVE TOTAL SPACE ACCUMULATOR    47400020
         B     IKJRECIN                 GET RECORDS FOR PARM DATA UPDAT 47450020
IKJENDR4 EQU   *                                                        47500020
         LR    X1,XDAEND                ACCUMULATED SO FAR TO ACCUM REG 47550020
         LA    X0,RQELLEN              LENGTH OF RQEL                   47600020
         MR    X0,X0                   TIMES NO. OF RQELS YIELDS SPACE  47650020
         LA    X0,UQELLEN              LENGTH OF UQEL                   47700020
         MH    X0,TWO(XPARM)           TIMES NO. OF UQELS EQ. SPACE     47750020
         LA    X1,UQELLEN(,X1)          ADD LENGTH OF DUMMY UQEL        47800020
         AR    X1,X0                   ADDED TO SPACE TOTAL             47850020
         LA    X1,DCALEN(X1)           ADD LENGTH OF DCA CB TO TOTAL    47900020
         LA    XWK2,DCARELEN           LENGTH OF DCARE CB               47950020
         MH    XWK2,FOURTN(XPARM)      TIMES NO. OF REGIONS EQ. SPACE   48000020
         AR    X1,XWK2                 ADD TO TOTAL SPACE REQUIRED      48050020
         LTR   XSW,XSW               Q.PRE-INITIALIZATION PHASE         48100020
         BNZ   IKJENDD0                NO HANDLE REST OF PARMS          48150020
         ST    X1,SIXTEEN(XPARM)       TOATAL SPACE -PASSED BACK TO TSC 48200020
         SR    XRETC,XRETC              RETURN CODE-ALL IS WELL         48250020
IKJRETUR EQU   *                                                        48300020
         TM    ERSPSW,TWO             Q.ERROR MSG. GETMAIN ISSUED       48600020
         BZ    IKJRETU0                 NO                              48650020
         L     X0,ZMSGLENG              LENG OF OPER REPLY SPACE A45527 48760021
         L     X1,ZMSGAREA              PTR. TO OPER. REPLY SPACE       48800020
         O     X0,SP251      SUBPOOL 251.                        A44022 48870021
         FREEMAIN R,LV=(0),A=(1)                                        48900020
         LR    X1,XERMSG               ADDR. OF ERROR MESSAGE SPACE     48950020
         L     XSAVE,ZSAVEREG           RESTORE SAVE PTR.               49000020
         LA    X0,N172       LENGTH TO FREE.                     A45527 49020021
N172     EQU   172           LENGTH TO FREE.                     A45527 49040021
         O     X0,SP251      SUBPOOL 251.                        A44022 49060021
         FREEMAIN R,LV=(0),A=(1)                                 A44022 49080021
IKJRETU0 EQU   *                                                        49100020
         LTR   XSW,XSW                  PREINIT                         49150020
         BNZ   IKJRETU9                 NO                              49200020
         LH    X0,FOURTN(,XPARM)        NO. OF REGIONS                  49250020
         MH    X0,HFOUR                 WORKSPACE FOR REGIONS           49300020
         LA    X1,DCALEN                LENGTH OF DCA CTRL. BLOCK       49350020
         AR    X0,X1                    TOTAL CORE TO FREE              49400020
         O     X0,SP251      SUBPOOL 251.                        A44022 49420021
         LR    X1,XWKSP                 PTR. TO WORKSPACE               49450020
         FREEMAIN R,LV=(0),A=(1)                                        49500020
IKJRETU9 EQU   *                                                        49550020
         LTR   XSW,XSW                 Q.PRE INIT. PHASE                49600020
         BZ    IKJRETU1                YES                              49650020
         XC    SUBQSW,SUBQSW           WORKSPACES                       49700020
         XC    ERRORSW,ERRORSW          AND                             49750020
         XC    EOJSW,EOJSW              SWITCHES                        49800020
         LTR   XRETC,XRETC            Q.RETURN CODE EQUAL 0             49850020
         BNZ   IKJRETU1                 NO-DO NOT MAKE SMF RECORD       49900020
         TM    TWENTY(XPARM),DSMFPRE    SMF RECORD REQ'D          M3870 49910020
         BZ    IKJRETU1                 NO                        M3870 49920020
         ST    XBASE,DCALTOD+DCACPU1    SAVE MAINLINE BASE REG.   M1683 49950021
         L     XBASE,SMFADCO            SUBROUTINE BASE REGISTER        50000020
         BALR  XLINK,XBASE              HANDLE SMF RECORD               50050020
IKJRETU1 EQU   *                                                        50100020
         LR    X15,XRETC                RETURN CODE                     50150020
         L     X14,TWELVE(XSAVE)        RESTORE TSC                     50200020
         LM    X0,XBASE,TWENTY(XSAVE)   REGISTERS                       50250020
         BR    X14                      TO TSC                          50300020
         EJECT                                                          50350020
* THIS ROUTINE IS ENTERED AFTER 'SUBQUEUES' PARM DATA ERRORS HAVE BEEN  50400020
* ENCOUNTERED AND CORRECT DATA OBTAINED FROM THE OPERATOR. ITS PURPOSE  50450020
* IS TO PUT THE CORRECT DATA IN EMPTY SLOTS IN THE PARM LIBRARY AND     50500020
* SUBSEQUENT CLEANUP.                                                   50550020
PARMUPDT EQU   *                                                        50600020
         SR    X15,X15                  CLEAR BLANK COUNTER             50650020
PARMUPD1 EQU   *                                                        50700020
         LA    XSCAN,ONE(XSCAN)         STEP SCAN PTR                   50750020
         CR    XSCAN,XSCEND           Q.AT END OF RECORDS               50800020
         BH    IKJREC00                 YES-GET NEXT RECORD             50850020
         CLI   ZERO(XSCAN),BLANK        NEXT CHARACTER A BLANK          50900020
         BNE   PARMUPDT                 NO- START OVER                  50950020
         LA    X15,ONE(X15)             YES-STEP BLANK COUNTER          51000020
         CH    X15,HEIGHTEN           Q.COUNTER EQUAL EIGHTEEN          51050020
         BNE   PARMUPD1                 NO-CONTINUE BLANK SEARCH        51100020
         SH    XSCAN,HSIXTEEN           SUBTRACT SIXTEEN                51150020
         MVC   ZERO(SIXTEEN,XSCAN),ZERO(XWK1) FROM REPLY AREA TO PARM   51200020
         LA    XSCAN,SIXTEEN(XSCAN)     STEP OVER SUBQUEUE LENGTH       51250020
         LA    XWK1,EIGHTEEN(XWK1)      STEP TO NEXT REPLY AREA         51300020
         CLC   ZERO(FOUR,XWK1),KEYWSTOP Q.AT STOPPER                    51350020
         BE    PARMUPD2                 YES ALL UPDATES HDLED           51400020
         CLC   ZERO(TWELVE,XWK1),CBLANKS Q.IF NO-ANY MORE REPLIES       51450020
         BNE   PARMUPDT                 YES-LOOP                        51500020
PARMUPD2 EQU   *                                                        51550020
         NI    ERRORSW,ALLFLAGS-ONE    NO CLEAR ERROR SWITCH            51600020
         LR    XDAEND,X0                RESTORE TOT. SP. ACC.           51650020
         B     IKJENDR4                 BACK TO MAIN LINE               51700020
         EJECT                                                          51750020
*                                                                       51800020
* THIS SUBROUTINE WRITES ERROR MESSAGES TO THE OPERATOR AND ROUTES      51850020
* CONTROL TO THE PROPER ROUTINE AFTER THE REPLY IS RECEIVED.            51900020
IKJEOJ   EQU   *                                                        51950020
         LA    X1,ZWTOST                                                52000020
         SR    X0,X0                                                    52050020
         IC    X0,THIRTEEN(XPARM)       CONSOLE ID FOR WTO              52100020
         WTO   MF=(E,(1))                                               52150020
IKJEOJ00 EQU   *                                                        52200020
         L     XSCAN,ZMSGAREA           PTR. TO REPLY AREA              52250020
         MVI   ZERO(XSCAN),BLANK        CLEAR REPLY AREA                52300020
         MVC   ONE(TWENTY9,XSCAN),ZERO(XSCAN)                           52350020
         LA    X1,ZFSTRPLY              WTOR PARMS PTR                  52400020
         L     XWK1,ZWTORECB            ECB PTR.                        52450020
         SR    X0,X0                                                    52500020
         IC    X0,THIRTEEN(XPARM)       CONSOLE ID FOR WTOR             52550020
         WTOR  ,(XSCAN),(XMSGL),(XWK1),MF=(E,(1))                       52600020
         WAIT  1,ECB=(XWK1)                                             52650020
         XC    ZMSGECB,ZMSGECB          CLEAR ECB FOR NEXT PASS         52700020
         OC    ZERO(TWELVE,XSCAN),CBLANKS  FOR LOWER CASE ANSWER        52750020
         CLC   ZERO(SIX,XSCAN),ZCANCEL  OPER. REPLY EQUAL CANCEL        52800020
         BNE   IKJEOJ01                 NO                              52850020
         LA    XRETC,EIGHT              YES-RETURN CODE FOR TSC         52900020
         B     IKJRETUR                 TO RETURN TO TSC AFTER CLEAN UP 52950020
IKJEOJ01 EQU   *                                                        53000020
         CLI   ZERO(XSCAN),DEFAULT      OPER. REPLY EQUAL DEFAULT       53050020
         BE    IKJEOJ04                 YES-CHECK WHAT KEYWD+HANDLE     53100020
         TM    BADKWD,FOUR           Q.BAD KEYWORD FLAG SET             53150020
         BO    IKJEOJ05                 YES-DO NOT COMPARE TO LAST      53200020
         TM    MS46SW,SIXTEEN           MS46 SW SET                     53207020
         BZ    IKJEOJA                  NO                              53214020
         CLC   ZWTOMS46(SEVEN),ZERO(XSCAN) YES-KEYWD ENTER= ASKED       53221020
         BNE   IKJEOJ                   NO-SEND MESSAGE AGAIN           53228020
         B     IKJEOJ05                                                 53235020
IKJEOJA  EQU   *                                                        53242020
         CLC   ZWTOMS33(SEVEN),ZERO(XSCAN) NO-KEYWD WNTER=ASKED FOR     53262020
         BNE   IKJEOJ                   NO-SEND MESSAGE AGAIN           53300020
IKJEOJ05 EQU   *                                                        53350020
         NI    BADKWD,ALLFLAGS-FOUR     CLEAR BAD KEYWORD FLAG          53400020
         NI    MS46SW,ALLFLAGS-SIXTEEN  CLEAR IN CASE ON                53420020
         B     IKJREC32                 YES-HANDLE KEYWORD              53450020
IKJEOJ04 EQU   *                                                        53500020
         TM    MS46SW,SIXTEEN           MS46 SW SET                     53508020
         BZ    IKJEOJB                  NO                              53516020
         CLC   ZWTOMS46(NINE),KDECAYWA Q.DEFAULT ALLOWED                53524020
         BNE   IKJEOJ02                 NOT DECAYWAIT                   53532020
         B     IKJEOJE                                                  53536020
IKJEOJB  EQU   *                                                        53540020
         CLC   ZWTOMS33(NINE),KDECAYWA Q.DEFAULT ALLOWED                53550020
         BNE   IKJEOJ02                 NOT DECAYWAIT                   53600020
IKJEOJE  EQU   *                                                        53620020
         OI    DCAIFLGS,DCAIWAIT        SET DECAYWAIT IGNORED FLAG      53650020
         NI    MS46SW,ALLFLAGS-SIXTEEN  CLEAR IN CASE ON                53670020
         BR    X2LINK                   RETURN TO CALLER                53700020
IKJEOJ02 EQU   *                                                        53750020
         TM    MS46SW,SIXTEEN           MS46 SW SET                     53758020
         BZ    IKJEOJC                                                  53766020
         CLC   ZWTOMS46(EIGHT),KDECAYAC   Q.DEFAULY ALLOWED             53774020
         BNE   IKJEOJ03                 NOT REGION ACTIVITY             53782020
         B     IKJEOJF                                                  53786020
IKJEOJC  EQU   *                                                        53790020
         CLC   ZWTOMS33(EIGHT),KDECAYAC Q.DEFAULT ALLOWED               53800020
         BNE   IKJEOJ03                 NOT REGION ACTIVITY             53850020
IKJEOJF  EQU   *                                                        53870020
         OI    DCAIFLGS,DCAIRACT        SET REGION ACT. IGNORED FLAG    53900020
         NI    MS46SW,ALLFLAGS-SIXTEEN  CLEAR IN CASE ON                53920020
         BR    X2LINK                   RETURN TO CALLER                53950020
IKJEOJ03 EQU   *                                                        54000020
         TM    MS46SW,SIXTEEN           MS46 SW SET                     54008020
         BZ    IKJEOJD                                                  54016020
         CLC   ZWTOMS46(TEN),KBACKGRO                                   54024020
         BE    IKJEOJG                                                  54029020
         B     IKJEOJ                   NOT BACKGROUND-NOT DEFAULT      54034020
IKJEOJD  EQU   *                                                        54040020
         CLC   ZWTOMS33(TEN),KBACKGRO  Q.DEFAULT ALLOWED                54050020
         BNE   IKJEOJ                   NOT BACKGROUND-DEFAULT NOT OK   54100020
IKJEOJG  EQU   *                                                        54120020
         OI    DCAIFLGS,DCAIBKGD        SET IGNORE BACKGROUND FLAG      54150020
         NI    MS46SW,ALLFLAGS-SIXTEEN  CLEAR IN CASE ON                54170020
         BR    X2LINK                   RETURN TO CALLER                54200020
         EJECT                                                          54250020
* THIS SUBROUTINE STEPS THE SCAN PTR. TO THE END OF A KEYWORD AND       54300020
* CONVERTS THE KEYWORD VALUE TO BINARY. THIS VALUE IS RETURNED TO THE   54350020
* CALLING ROUTINE IN XWK2.                                              54400020
*                                                                       54450020
IKJHDV00 EQU   *                                                        54500020
         CLI   ZERO(XSCAN),BLANK      Q. FIRST CHARACTER BLANK          54550020
         BE    IKJREC50                 YES-ERROR                       54600020
         LR    XWK1,XSCAN               SAVE BEGIN OF PARM. VALUE PTR.  54650020
         SR    XWK2,XWK2                CLEAR FOR LENGTH COUNT          54700020
IKJHDV01 EQU   *                                                        54750020
         CLI   ZERO(XSCAN),CZERO       Q.PROPER DIGIT                   54800020
         BL    IKJREC50                 NO                              54850020
         CLI   ZERO(XSCAN),CNINE       Q.PROPER DIGIT                   54900020
         BH    IKJREC50                 NO                              54950020
         LA    XSCAN,ONE(XSCAN)         STEP SCAN PTR                   55000020
         LA    XWK2,ONE(XWK2)           STEP LENGTH COUNTER             55050020
         CLI   ZERO(XSCAN),BLANK        DELIMITER=BLANK REACHED         55100020
         BNE   IKJHDV01                 NO-STEP TO NEXT SCAN CHAR.      55150020
         CH    XWK2,HEIGHT              LENGTH VALUE RIDICULOUSLY LONG  55200020
         BH    IKJREC50                 YES-ERROR                       55250020
         BCTR  XWK2,ZERO                LENGTH FOR EXECUTE-LO 4 BITS    55300020
         O     XWK2,PACKDOUB            LENGTH FOR EXECUTE-HI 4 BITS    55350020
         EX    XWK2,IKJPACK             PACK VALUE                      55400020
         CVB   XWK2,DCATSTME            MAKE VALUE BINARY               55450020
         XC    DCATSTME(EIGHT),DCATSTME CLEAR WORKSPACE AFTER PACK      55500020
         BR    XLINK                    BACK TO CALLING ROUTINE         55550020
*                                                                       55600020
* THIS SUBROUTINE STEPS THE SCAN PTR PAST THE REGION NUMBER AND CYCLE   55650020
* NUMBER IN THE KEYWORD AND CONVERTS THESE TWO NUMBERS TO BINARY. THE   55700020
* REGION NUMBER IS RETURNED IN X1 AND THE CYCLE NUMBER IN XWK2.         55750020
* THE RQEL PTR. OR DSECT BASE REGISTER IS RETURNED IN X15.              55800020
*                                                                       55850020
IKJHDRCY EQU   *                                                        55900020
         LR    XWK1,XSCAN               PARM. VALUE PTR.                55950020
         SR    XWK2,XWK2               CLEAR FOR LENGTH COUNTER         56000020
IKJHDRC1 EQU   *                                                        56050020
         CLI   ZERO(XSCAN),CZERO       Q.PROPER DIGIT                   56100020
         BL    IKJREC50                 NO                              56150020
         CLI   ZERO(XSCAN),CNINE       Q.PROPER DIGIT                   56200020
         BH    IKJREC50                 NO                              56250020
         LA    XSCAN,ONE(XSCAN)        STEP SCAN PTR                    56300020
         LA    XWK2,ONE(XWK2)          STEP LENGTH CTR                  56350020
         CLI   ZERO(XSCAN),COMMA       REGION DELIMITER REACHED         56400020
         BNE   IKJHDRC1                NO-STEP TO NEXT SCAN CHARACTER   56450020
         LA    XSCAN,ONE(XSCAN)        YES-STEP PAST COMMA              56500020
         CH    XWK2,HTWO               LENGTH VALUE TO LONG             56550020
         BH    IKJREC50                 YES  ERROR                      56600020
         BCTR  XWK2,ZERO               LENGTH FOR EXECUTE-LO 4 BITS     56650020
         O     XWK2,PACKDOUB           LENGTH FOR EXECUTE-HI 4 BITS     56700020
         EX    XWK2,IKJPACK             PACK VALUE                      56750020
         CVB   XWK2,DCATSTME            MAKE BINARY                     56800020
         XC    DCATSTME(EIGHT),DCATSTME CLEAR WORKSPACE AFTER PACK      56850020
         LR    X1,XWK2                  SAVE REGION NUMBER              56900020
         LTR   X1,X1                  Q.REGION VALUE ZERO OR NEGATIVE   56950020
         BNP   IKJREC50                 YES-ERROR                       57000020
         CH    X1,FOURTN(XPARM)      Q.REGION MAX EXCEEDED              57050020
         BH    IKJREC50                 YES-ERROR                       57100020
         LR    XWK1,XSCAN               PARM. VALUE PTR.                57150020
         SR    XWK2,XWK2               CLEAR FOR LENGTH COUNTER         57200020
IKJHDRC2 EQU   *                                                        57250020
         CLI   ZERO(XSCAN),CZERO       Q.PROPER DIGIT                   57300020
         BL    IKJREC50                 NO                              57350020
         CLI   ZERO(XSCAN),CNINE       Q.PROPER DIGIT                   57400020
         BH    IKJREC50                 NO                              57450020
         LA    XSCAN,ONE(XSCAN)        STEP SCAN PTR                    57500020
         LA    XWK2,ONE(XWK2)          STEP LENGTH CTR                  57550020
         CLI   ZERO(XSCAN),RIGHTPAR   Q.RQEL DELIMITER REACHED          57600020
         BNE   IKJHDRC2                NO-STEP TO NEXT SCAN CHARACTER   57650020
         LA    XSCAN,ONE(XSCAN)        YES-STEP PAST IT                 57700020
         CH    XWK2,HTWO               LENGTH VALUE TO LONG             57750020
         BH    IKJREC50                 YES  ERROR                      57800020
         BCTR  XWK2,ZERO               LENGTH FOR EXECUTE-LO 4 BITS     57850020
         O     XWK2,PACKDOUB           LENGTH FOR EXECUTE-HI 4 BITS     57900020
         EX    XWK2,IKJPACK             PACK VALUE                      57950020
         CVB   XWK2,DCATSTME            MAKE BINARY                     58000020
         XC    DCATSTME(EIGHT),DCATSTME CLEAR WORKSPACE AFTER PACK      58050020
         LTR   XWK2,XWK2              Q.RQEL VALUE ZERO OR NEGATIVE     58100020
         BNP   IKJREC50                 YES-ERROR                       58150020
         CLI   ZERO(XSCAN),EQUALSGN   Q.NEXT CHARACTER EQUAL SIGN       58200020
         BNE   IKJREC50                 NO ERROR                        58250020
         LA    XSCAN,ONE(XSCAN)         YES-STEP PAST IT                58300020
         LA    XWK1,DCAEND              PTR TO FIRST DCARE              58350020
         LA    X15,DCARELEN             LENGTH OF DCARE CTRL BLOCK      58400020
         LR    X14,X1                   REGION NO.                      58450020
         BCTR  X14,ZERO                 DECREMENT FOR INDEXING          58500020
         MR    X14,X14                  TOTAL LENGTH OF DCARES          58550020
         AR    XWK1,X15                 ADD BEGINNING                   58600020
         USING DCARE,XWK1                                               58650020
         C     XWK2,DCARHTME          Q.RQEL VALUE EXCEED MAX FOR REG.  58700020
         BH    IKJREC50                 YES-ERROR                       58750020
         L     XWK1,DCARTMIN            PTR. TO FIRST RQEL FOR REGION   58800020
         DROP  XWK1                                                     58850020
         LA    X15,RQELLEN              LENGTH OF RQEL CTRL BLOCK       58900020
         LR    X14,XWK2                 RQEL NO.                        58950020
         BCTR  X14,ZERO                 DECREMENT FOR INDEXING          59000020
         MR    X14,X14                  TOTAL LENGTH OF RQEL            59050020
         AR    X15,XWK1                 ADD BEGINNING EQ. RQEL PTR.     59100020
         BR    XLINK                    BACK TO CALLING ROUTINE         59150020
         EJECT                                                          59200020
* THIS ROUTINE WILL PLACE THE REGION NUMBER IN THE 'RQEL PARM NOT       59250020
* SUPPLIED' MESSAGE, WTOR THE MESSAGE, CHECK THE REPLY FOR ACCURACY,    59300020
* AND THEN PLACE THE RQEL VALUE IN ITS WORKAREA SLOT.                   59350020
RQELER1  EQU   *                                                        59400020
         OI    ERRORSW,ONE              SET ERROR SWITCH                59450020
         LH    X15,FOURTN(,XPARM)       MAX. NO. OF REGIONS             59500020
         LA    X15,ONE(X15)             STEP BY ONE                     59550020
         SR    X15,XSCEND               YIELDS REGION REQUIRING RQEL NO 59600020
         CH    X15,HTEN               Q.REGION NO. LESS THAN 10         59650020
         BNL   RQELCVD                  NO                              59700020
         STC   X15,ZMSG43                                               59750020
         MVZ   ZMSG43(ONE),ZONES       CONVERT TO PRINTABLE             59800020
         B     RQELER2                                                  59850020
RQELCVD  EQU   *                                                        59900020
         CVD   X15,DCATSTME             CONVERT TO DECIMAL              59950020
         UNPK  DCATSTME(TWO),DCATSTM6(TWO)   CHANGE TO ZONED            60000020
         MVZ   DCATSTM1(ONE),ZONES      MAKE PRINTABLE                  60050020
         MVC   ZMSG42(TWO),DCATSTME    REGION NUMBER IN WTOR            60100020
         XC    DCATSTME(EIGHT),DCATSTME CLEAR WORKSPACE                 60150020
RQELER2  EQU   *                                                        60200020
         L     XSCAN,ZRPLYAD            ADDRESS OF LAST REPLY           60250020
         AH    XSCAN,HEIGHTEN           ADDRESS FOR THIS REPLY          60300020
RQELER3  EQU   *                                                        60350020
         MVI   ZERO(XSCAN),BLANK                  REPLY AREA            60400020
         MVC   ONE(SEVENTEN,XSCAN),ZERO(XSCAN)    BLANKED               60450020
         LA    X1,ZFSTRPLY              WTOR PARMS PTR                  60500020
         L     XWK1,ZWTORECB           ECB PTR.                         60550020
         SR    X0,X0                                                    60600020
         IC    X0,THIRTEEN(,XPARM)      CONSOLE ID FOR WTOR             60650020
         WTOR  ,(XSCAN),EIGHTEEN,(XWK1),MF=(E,(1))                      60700020
         WAIT  1,ECB=(XWK1)                                             60750020
         OC    ZERO(TEN,XSCAN),CBLANKS  TO HDLE LOWER CASE ANS.         60800020
         XC    ZMSGECB,ZMSGECB          CLEAR ECB FOR NEXT PASS         60850020
         CLC   ZERO(SIX,XSCAN),ZCANCEL  OPER. REPLY EQUAL CANCEL        60900020
         BNE   RQELER7                  NO- HANDLE OPERATOR REPLY       60950020
         LA    XRETC,EIGHT              RETURN CODE FOR TSC             61000020
         B     IKJRETUR                 TO RETURN TO TSC ROUTINE        61050020
RQELER7  EQU   *                                                        61100020
         CLC   ZERO(TEN,XSCAN),COMPSUBQ Q.SUBQUEUES PARAMETER           61150020
         BNE   RQELER3                  NO-ASK AGAIN                    61200020
         CLI   ELEVEN(XSCAN),RIGHTPAR Q.REGION NO. GREATER THAN 9       61250020
         BNE   RQELER8                  YES                             61300020
         CLC   TEN(ONE,XSCAN),ZMSG43  Q.REG. NO. VS. NO. IN MSG.        61350020
         BNE   RQELER3                  NOT EQUAL-ASK AGAIN             61400020
         LA    XSCAN,TWELVE(XSCAN)      STEP OVER REGION NO.            61450020
         B     RQELER5                                                  61500020
RQELER8  EQU   *                                                        61550020
         CLC   TEN(TWO,XSCAN),ZMSG42  Q.REG. NO. VS. NO. IN MSG.        61600020
         BNE   RQELER3                  NOT EQUAL-ASK AGAIN             61650020
         LA    XSCAN,THIRTEEN(XSCAN)    STEP OVER REGION NO.            61700020
RQELER5  EQU   *                                                        61750020
         BAL   XLINK,HDLSUBQ8           PROCESS RQEL QUAN               61800020
         LTR   X1,X1                  Q.RQEL VALUE 0 OR NEG.            61850020
         BNP   RQELER2                  YES-ASK AGAIN                   61900020
         ST    X1,ZERO(XWK2)            NO-STORE IN RQEL SLOT           61950020
         L     XSCAN,ZRPLYAD            UPDATE REPLY AREA PTR.          62000020
         AH    XSCAN,HEIGHTEN           TO NEXT                         62050020
         ST    XSCAN,ZRPLYAD            REPLY                           62100020
         B     IKJENDR3                 ADD TO TOTAL                    62150020
         EJECT                                                          62200020
* THIS KEYWORD TABLE CONTAINS A LENGTH ATTRIBUTE, A BRANCH FACTOR,      62250020
* AND THE ACTUAL KEYWORD. IT IS USED TO DETERMINE, VIA AN EXECUTE ON    62300020
* A CLC INSTRUCTION, THE PARTICULAR KEYWORD INVOLVED AND IS USED IN     62350020
* CONJUNCTION WITH BRTBKEWD (A BRANCH TABLE) TO GET TO A DIFFERENT      62400020
* HANDLING ROUTINE FOR EACH KEYWORD.                                    62450020
*                                                                       62500020
KEYWORDS DC    X'0400'                                                  62550020
KWAIT    DC    C'WAIT          '                                        62600020
         DC    X'0604'                                                  62650020
         DC    C'NOWAIT        '                                        62700020
         DC    X'0808'                                                  62750020
KACTIVIT DC    C'ACTIVITY      '                                        62800020
         DC    X'0A0C'                                                  62850020
         DC    C'NOACTIVITY    '                                        62900020
         DC    X'0910'                                                  62950020
KOCCUPAN DC    C'OCCUPANCY     '                                        63000020
         DC    X'0B14'                                                  63050020
         DC    C'NOOCCUPANCY   '                                        63100020
         DC    X'0818'                                                  63150020
KSWAPLOA DC    C'SWAPLOAD      '                                        63200020
         DC    X'0A1C'                                                  63250020
         DC    C'NOSWAPLOAD    '                                        63300020
         DC    X'0A20'                                                  63350020
KAVGSERV DC    C'AVGSERVICE    '                                        63400020
         DC    X'0C24'                                                  63450020
         DC    C'NOAVGSERVICE  '                                        63500020
         DC    X'0A28'                                                  63550020
KBACKGRO DC    C'BACKGROUND=   '                                        63600020
         DC    X'0C2C'                                                  63650020
         DC    C'NOBACKGROUND  '                                        63700020
         DC    X'0830'                                                  63750020
KPRIORIT DC    C'PRIORITY      '                                        63800020
         DC    X'0A34'                                                  63850020
         DC    C'NOPRIORITY    '                                        63900020
         DC    X'0738'                                                  63950020
         DC    C'PREEMPT       '                                        64000020
         DC    X'093C'                                                  64050020
         DC    C'NOPREEMPT     '                                        64100020
         DC    X'0940'                                                  64150020
KDECAYWA DC    C'DECAYWAIT=    '                                        64200020
         DC    X'0844'                                                  64250020
KDECAYAC DC    C'DECAYACT=     '                                        64300020
         DC    X'0648'                                                  64350020
KCYCLES  DC    C'CYCLES(       '                                        64400020
         DC    X'074C'                                                  64450020
KMAXSWAP DC    C'MAXSWAP(      '                                        64500020
         DC    X'0C50'                                                  64550020
KMAXOCCU DC    C'MAXOCCUPANCY( '                                        64600020
         DC    X'0754'                                                  64650020
KSERVICE DC    C'SERVICE(      '                                        64700020
         DC    X'0858'                                                  64750020
KMINSLIC DC    C'MINSLICE(     '                                        64800020
         DC    X'095C'                                                  64850020
COMPSUBQ DC    C'SUBQUEUES(    '                                        64900020
KEYWSTOP DC    X'FFFFFFFF'              STOPPER                         64950020
*                                                                       65000020
* THIS BRANCHING TABLE IS USED WITH A KEYWORD TABLE (KEYWORDS) TO       65050020
* BRANCH TO THE PROPER KEYWORD HANDLING ROUTINE.                        65100020
*                                                                       65150020
BRTBKEND EQU   *                                                        65200020
         B     HDWAIT                                                   65250020
         B     HDNOWAIT                                                 65300020
         B     HDACTIVI                                                 65350020
         B     HDNOACTI                                                 65400020
         B     HDOCCUPA                                                 65450020
         B     HDNOOCCU                                                 65500020
         B     HDSWAPLO                                                 65550020
         B     HDNOSWAP                                                 65600020
         B     HDAVGSER                                                 65650020
         B     HDNOAVGS                                                 65700020
         B     HDBACKGR                                                 65750020
         B     HDNOBACK                                                 65800020
         B     HDPRIORI                                                 65850020
         B     HDNOPRIO                                                 65900020
         B     HDPREEMP                                                 65950020
         B     HDNOPREE                                                 66000020
         B     HDDECAYW                                                 66050020
         B     HDDECAYA                                                 66100020
         B     HDCYCLES                                                 66150020
         B     HDMAXSWA                                                 66200020
         B     HDMAXOCC                                                 66250020
         B     HDSERVIC                                                 66300020
         B     HDMINSLI                                                 66350020
         B     HDSUBQUE                                                 66400020
         EJECT                                                          66450020
ZONES    DC    X'FF'                    USED TO MAKE CHAR. PRINTABLE    66500020
HTWO     DC    H'2'                    TO COMPARE LENGTH FIELD OF PARMS 66550020
HTHREE   DC    H'3'                    TO CONV, TIME PARMS.             66600020
HFOUR    DC    H'4'                     TO MULTIPLY # OF REGIONS BY     66650020
HEIGHT   DC    H'8'                     LENGTH COUNT-VALUE CHECK        66700020
HTEN     DC    H'10'                    REGION NUMBER COMPARE           66750020
HSIXTEEN DC    H'16'                    GENERAL PURPOSE NUMBER          66800020
HEIGHTEN DC    H'18'                    SPACE PER REGION FOR OPER.REPLY 66850020
HTHIRTY4 DC    H'34'                    MIN. OPER. REPLY SPACE          66900020
FZERO    DC    F'0'                     BKGD PERCENT LIMIT COMPARE      66950020
FEIGHTY  DC    F'80'                    TO ADVANCE RECORD PTR.          67000020
FNINTY9  DC    F'99'                    BKGD. PERCENT LIMIT COMPARE     67050020
FONETW8T DC    F'12800'                UPPPER LIMIT FOR DECAY CONSTANT  67100020
PACKDOUB DC    F'112'                   CREATE EXECUTE VALUE FACTOR     67150020
SP251    DC    X'FB000000'   MASK FOR SUBPOOL 251.               A44022 67160021
SUBP252   DC    X'FC000000'             MASK FOR SUBPOOL 252            67170020
BASEADCO DC    A(IKJEAD00)             FOR BASE ADDRESSABILITY          67200020
SCALONE  DC    X'01000000'              SCALER ONE                      67250020
*                                                                       67300020
*-NOTE-TEMPORARY WORK AREA USED IN CONTROL BLOCK MUST BE ON A DOUBLE    67350020
* WORD BOUNDARY AND IS LATER CLEARED.                                   67400020
*                                                                       67450020
IKJPACK  PACK  DCATSTME(ZERO),ZERO(ZERO,XWK1) CONV. EBEDIC TO NBINARY   67500020
COMPKYWD CLC   ZERO(ZERO,XSCAN),TWO(X1) PARAMETER LIST KEYWD VS. TABLE  67550020
IKJCLEAR XC    ZERO(ZERO,X1),ZERO(X1)   CLEAR WORKSPACE                 67600020
IKJBLANK MVC   ONE(ZERO,X1),ZERO(X1)    BLANK AREA                      67650020
RECNAME  DC    C'DRIVER '                                               67700020
ZCANCEL  DC    C'CANCEL'                COMPARE OPERATOR ANS. TO WTOR   67750020
MSGZINVK DC    C'IKJ061I  THIS KEYWORD IS INVALID-'                     67800020
MSGZMISS DC    C'IKJ063I  THIS KEYWORD IS MISSING-'                     67850020
MSGZINVV DC    C'IKJ064I  THE VALUE OF THIS KEYWORD IS INVALID-'        67900020
MSGZKEYU DC    C'IKJ066D  REPLY ''KEYWORD=VALUE'', ''U'',OR ''CANCEL''' 67950020
MSGZKEYV DC    C'IKJ066D  REPLY ''KEYWORD=VALUE'' OR ''CANCEL'''        68000020
CBLANKS  DC    32C' '                   USED AS BLANKS                  68050020
SMFADCO  DC    A(IKJSMF)                SUBROUTINES BASE ADDRESS        68100020
         EJECT                                                          68150020
IKJSMF    EQU  *                                                        68200020
         USING IKJSMF,XBASE                                             68250020
* SUBROUTINE ENTRY POINT AND BRANCHING TABLE                            68300020
         B     IKJSMF1                  HANDLE SMF RECORD               68350020
         B     IKJGETCL                 GETMAIN SUBROUTINE              68400020
         B     IKJBTOSC                 CONVERT BINARY NO. TO SCALED VA 68450020
         B     IKJFXMSG                 REGION + RQEL NO. IN MSG.       68500020
         B     IKJENDMG                HANDLE MESSAGE SETUP             68550020
         B     IKJPAROV                 HANDLE PARM. OVERIDES ON START  68600020
* THIS ROUTINE IS ENTERED DURING THE INITIALIZATION PHASE, JUST PRIOR   68650020
* TO THE RETURN TO TSC, TO WRITE THE TSO DRIVER SMF RECORD-NO. 32.      68700020
IKJSMF1  EQU   *                                                        68850020
         L     X1,DCAUQEL0              VIRTUAL UQEL PTR.               68900020
         S     X1,DCAQELS               LESS RQEL BEGINNING             68950020
         SR    X0,X0                                                    69000020
         LA    X15,RQELLEN              LENGTH OF RQEL                  69050020
         DR    X0,X15                   YIELDS NO. OF RQELS             69100020
         LR    XSCAN,X1                 SAVE FOR LATER BCT              69150020
         LA    X15,SMFRQLEN             LENGTH OF RQELSMF RECORD        69200020
         MR    X0,X15                   YIELDS SPACE REQUIRED FOR RQEL  69250020
         LA    X1,SMFDCALE(X1)          PLUS SPACE FOR DCASMF INFO      69300020
         LR    XSMF,XLINK              TEMP, SAVE LINK REG.             69350020
         BAL   X2LINK,IKJGETCL          GET+CLEAR TOTAL CORE REQUIRED   69400020
         LR    XWK1,XSMF                                                69450020
         LR    XSMF,X0                  DSECT PTR                       69500020
         USING TDRSMF,XSMF                                              69550020
         STH   XLINK,TDRRLEN            RECORD LENGTH                   69600020
         MVI   TDRRCDTY,THIRTY2         SMF RECORD ID                   69650020
         MVC   TDRSCHED(ONE),DCAIFLGS   CONTROL INFORMATION             69700020
         MVC   TDRTIMB(ONE),DCABKGD     PERCENTAGE OF BKGD TIME REQUEST 69750020
         MVC   TDRDCWT(FOUR),DCAKWAIT   DECAY CONSTANT FOR WAIT ESTIMAT 69800020
         MVC   TDRDCRGN(FOUR),DCAKRACT  DECAY CONSTANT FOR REG. ACTIV.  69850020
         LA    X0,SMFDCALN              LENGTH OF COMPLETED PORTION     69900020
         SR    XLINK,X0                 LENGTH OF REST OF RECORD        69950020
         STH   XLINK,TDRRGNQ            INTO SLOT-RECORD DONE EXCEPT    70000020
*                                       FOR CONTIGUOUS RQEL DATA        70050020
         LR    XLINK,XWK1              RESTORE RETURN PTR.              70100020
         LA    XSMFRQ,SMFDCAEN          STEP TO FIRST RQEL              70150020
         USING DSMFRQE,XSMFRQ                                           70200020
         L     XRQEL,DCAQELS            RQEL PTR.                       70250020
         USING RQEL,XRQEL                                               70300020
         LA    XWK1,ONE                 REGION NUMBER                   70350020
IKJSMRQE EQU   *                                                        70400020
         STC   XWK1,DSMFRQE#            REGION NUMBER                   70450020
         MVC   DSMF#CYC(TWO),RQEL#CYC   NO. OF SERVICE CYCLES THIS Q    70500020
         MVC   DSMFSIZE(TWO),RQELSIZE   SWAPLOAD THRESHOLD              70550020
* CONVERT TIME DATA TO 100THS OF A SEC. FOR SMF RECORD                  70600020
         LH    X15,HTHREEE               DIVISOR                        70650020
         L     X1,RQELTCO               CORE OCCUPANCY THRESHOLD        70700020
         SR    X0,X0                                                    70750020
         DR    X0,X15                    3.3 MSEC. CONVERTED            70800020
         STH   X1,DSMFTCO2              HANDLE                          70850020
         SRL   X1,SIXTEEN               SMF RECORD ALIGNMENT            70900020
         STH   X1,DSMFTCO                                               70950020
         L     X1,RQELAQST                AVE. SERVICE TIME             71000020
         SR    X0,X0                                                    71050020
         DR    X0,X15                                                   71100020
         STH   X1,DSMFAQS2                                              71150020
         SRL   X1,SIXTEEN                                               71200020
         STH   X1,DSMFAQST                                              71250020
         L     X1,RQELMSLC              MINSLICE                        71300020
         SR    X0,X0                                                    71350020
         DR    X0,X15                                                   71400020
         STH   X1,DSMFMSL2                                              71450020
         SRL   X1,SIXTEEN               ALIGNMENT                       71500020
         STH   X1,DSMFMSLC                                              71550020
         TM    RQELFLGS,RQLLAST       Q.THIS LAST RQEL FOR THIS REGION  71600020
         BZ    IKJSMRQ1                 NO                              71650020
         LA    XWK1,ONE(XWK1)           YES-STEP TO NEXT REGION NUMBER  71700020
IKJSMRQ1 EQU   *                                                        71750020
         LA    XRQEL,RQELEND            STEP TO NEXT RQEL               71800020
         LA    XSMFRQ,DSMFEND           STEP TO NEXT SMF RQEL SLOT      71850020
         BCT   XSCAN,IKJSMRQE           AND HANDLE NEXT                 71900020
         LR    X1,XSMF                  WORKSPACE FOR RECORD PTR        71950020
         SMFWTM (1) WRITE SMF RECORD                                    72000020
         LH    X0,TDRRLEN               RECORD LENGTH                   72050020
         LR    X1,XSMF                  WORKSPACE FOR RECORD PTR.       72100020
         FREEMAIN R,LV=(0),A=(1)        FREE WORKSPACE                  72150020
         L     XBASE,DCALTOD+DCACPU1    RESTORE MAINLINE BASE REG.M1683 72200021
         XC    DCALTOD+DCACPU1(FOUR),DCALTOD+DCACPU1              M4909 72250000
*                                               CLEAR SAVE AREA   M1683 72260000
         BR    XLINK                                                    72300020
         EJECT                                                          72350020
*                                                                       72400020
* THIS SUBROUTINE PLACES THE APPROPRIATE REGION AND RQEL NUMBERS IN     72450020
* THE 'KEYWORD MISSING' ERROR MESSAGE. X1 POINTS TO MSG. SLOT.          72500020
*                                                                       72550020
IKJFXMSG EQU   *                                                        72600020
         SR    X14,X14                  FOR DIVIDE                      72650020
         LA    X0,DCAEND                PTR. TO FIRST DCARE             72700020
         LR    X15,XDCARE               CURRENT DCARE                   72750020
         SR    X15,X0                   DIFFERENCE                      72800020
         LA    X0,DCARELEN              DCARE LENGTH                    72850020
         DR    X14,X0                   DEVELOP REGION                  72900020
         LA    X15,ONE(X15)             NUMBER                          72950020
         CH    X15,HTENN              Q.RESULT LESS THAN TEN            73000020
         BL    IKJFXMS1                 YES                             73050020
         CVD   X15,DCATSTME             CONVERT TO DECIMAL              73100020
         UNPK  DCATSTME(TWO),DCATSTM6(TWO)   CHG TO ZONED               73150020
         MVZ   DCATSTM1(ONE),YONES      MAKE PRINTABLE                  73200020
         MVC   ZERO(TWO,X1),DCATSTME    REGION NO. IN WTOR              73250020
         XC    DCATSTME(EIGHT),DCATSTME CLEAR WORKSPACE                 73300020
         LA    X1,ONE(X1)               STEP MSG PTR                    73350020
         B     IKJFXMS2                                                 73400020
IKJFXMS1 EQU   *                                                        73450020
         STC   X15,ZERO(,X1)            REGION NO. IN MSG.              73500020
         MVZ   ZERO(ONE,X1),YONES       MAKE REGION NUMBER PRINTABLE    73550020
IKJFXMS2 EQU   *                                                        73600020
         MVI   ONE(X1),COMMA            AFTER REGION NO.                73650020
         LA    X1,TWO(X1)               STEP MSG PTR. AFTER REG. NO.    73700020
         SR    X14,X14                  FOR  DIVIDE                     73750020
         USING DCARE,XDCARE                                             73800020
         L     X0,DCARTMIN              PTR. TO FIRST RQEL              73850020
         DROP  XDCARE                                                   73900020
         LR    X15,XRQEL                CURRENT RQEL                    73950020
         SR    X15,X0                   DIFFERENCE                      74000020
         LA    X0,RQELLEN               RQEL LENGTH                     74050020
         DR    X14,X0                   DEVELOP RQEL                    74100020
         LA    X15,ONE(X15)             NUMBER                          74150020
         CH    X15,HTENN              Q.RESULT LESS THAN TEN            74200020
         BL    IKJFXMS3                 YES                             74250020
         CVD   X15,DCATSTME             CONVERT TO DECIMAL              74300020
         UNPK  DCATSTME(TWO),DCATSTM6(TWO)   CHG. TO ZONED              74350020
         MVZ   DCATSTM1(ONE),YONES           MAKE PRINTABLE             74400020
         MVC   ZERO(TWO,X1),DCATSTME    RQEL NO. IN WTOR                74450020
         XC    DCATSTME(EIGHT),DCATSTME      CLEAR WORKSPACE            74500020
         LA    X1,ONE(X1)                    STEP MSG PTR               74550020
         B     IKJFXMS4                                                 74600020
IKJFXMS3 EQU   *                                                        74650020
         STC   X15,ZERO(,X1)            RQEL NO. IN MSG.                74700020
         MVZ   ZERO(ONE,X1),YONES       MAKE PRINTABLE                  74750020
IKJFXMS4 EQU   *                                                        74800020
         MVI   ONE(X1),RIGHTPAR         RIGHT PAREN AFTER RQEL NO.      74850020
         L     XBASE,DCALTOD+DCACPU1    RESTORE MAINLINE BASE ADR.M1683 74900021
         XC    DCALTOD+DCACPU1,DCALTOD+DCACPU1 CLEAR SAVE AREA    M1683 74950021
         BR    X2LINK                   RETURN TO CALLER                75000020
         EJECT                                                          75050020
*                                                                       75100020
* THIS SUBROUTINE GETMAINS FOR AND ZEROS THE AMOUNT OF STORAGE          75140020
* SPECIFIED IN X1.  X1 CONTAINS THE SUBPOOL ID IN THE HIGH BYTE.        75180020
* THE LENGTH IS SAVED IN XLINK.  ADDR. OF STORAGE RETURNED IN X0        75220020
* RETURN IS VIA X2LINK.                                                 75260020
IKJGETCL EQU   *                                                        75300020
         LR    X0,X1                    TOTAL CORE REQUIRED-GETMAIN     75350020
         LA    X1,ZERO(X1)               CLEAR SUBPOOL ID               75360020
         LR    XLINK,X1                 SAVE FOR LATER                  75400020
         LR    XWK1,X1                  TOTAL CORE TO CLEAR             75450020
         GETMAIN R,LV=(0)                                               75500020
         LA    XWK2,TWOHU55             CONSTANT FOR CLEAR 256 BYTES    75550020
         LR    X0,X1                    SAVE GETMAIN PTR.               75600020
IKJCLEA0 EQU   *                                                        75650020
         CH    XWK1,HTWOHU56          Q.LENGTH EXCEED 255               75700020
         BH    IKJCLEA1                 YES                             75750020
         BCTR  XWK1,ZERO                NO-DECREMENT FOR EXECUTE        75800020
         EX    XWK1,IKJCLEAX            CLEAR SPACE                     75850020
         BR    X2LINK                   ALL DONE                        75900020
IKJCLEA1 EQU   *                                                        75950020
         EX    XWK2,IKJCLEAX            CLEAR 256 BYTES                 76000020
         SH    XWK1,HTWOHU56            DECREMENT LENGTH TO BE DONE     76050020
         LA    X1,TWOHU56(X1)           STEP CLEAR AREA PTR             76100020
         B     IKJCLEA0                 GO AGAIN                        76150020
IKJCLEAX XC    ZERO(ZERO,X1),ZERO(X1)         CLEAR WORKSPACE           76200020
         EJECT                                                          76250020
*                                                                       76300020
* THIS SUBROUTINE CONVERTS A BINARY NUMBER-PASSED IN XWK2-              76350020
* TO A 31:24 SCALED NO.-RETURNED IN X1.                                 76400020
*                                                                       76450020
IKJBTOSC EQU   *                                                        76500020
         LR    X15,XWK2                SET EVEN ODD                     76550020
         SR    X14,X14                 REGS FOR DIVIDE                  76600020
         D     X14,FONEHUND            PARM. SUPPLIED IN HUNDREDS       76650020
         SLA   X15,TWENTY4             MAKE SCALED                      76700020
         LR    X1,X15                  HOLD QUOTIENT                    76750020
         SLA   X14,TWENTY4             MAKE REMAINDER SCALED            76800020
         LR    X15,X14                  SET UP FOR DIVIDE               76850020
         SR    X14,X14                                                  76900020
         D     X14,FONEHUND            CONVERT REMAINDER                76950020
         OR    X1,X15                  REMAINDER INTO RESULT            77000020
         L     XBASE,DCALTOD+DCACPU1    RESTORE MAINLINE BASE REG.M1683 77050021
         XC    DCALTOD+DCACPU1(FOUR),DCALTOD+DCACPU1              M4909 77100000
*                                               CLEAR SAVE AREA   M1683 77110000
         BR    XLINK                   RETURN TO CALLER                 77150020
*                                                                       77200020
* THIS SUBROUTINE DOES A GETMAIN FOR A WTO AND A WTOR AREA. THE BASIC   77250020
* SETUP FOR THE MESSAGES IS DONE HERE                                   77300020
*                                                                       77350020
IKJENDMG EQU   *                                                        77400020
         OI    ERSPSW,TWO               SET ERRORMSG GETMAIN SW.        77450020
         LR    XWK2,XSAVE               SAVE THE SAVE REG               77500020
         LA    X0,N172                 LENGTH TO GET.             M7636 77520021
         O     X0,SP251B               SUBPOOL 251.              A44022 77540021
         GETMAIN R,LV=(0)                                        A44022 77560021
         LR    XERMSG,X1                DSECT PTR                       77600020
         LA    XWK1,ONEH63                                              77650020
         EX    XWK1,IKJCLEAX           CLEAR WTOR AREA                  77700020
         ST    XWK2,ZSAVEREG                                            77750020
         MVC   ZWTOST(SEVENTY2),ZWTO    WTO PARMS                       77800020
         MVC   ZFSTRPLY(EIGHTY),MSGWTOR  WTOR PARM LIST                 77850020
         LA    X15,ZMSGECB              ADDR. OF ECB TO                 77900020
         ST    X15,ZWTORECB             WTOR PARM LIST                  77950020
         LA    XWK2,DCAEND              RQEL WORKAREA PTR.              78000020
         SR    XDAEND,XDAEND            TOTAL SPACE ACCUMULATOR         78050020
         LH    XSCEND,FOURTN(,XPARM)    NO. OF REGIONS FOR LOOPING      78100020
         MVC   ZMESSAGE(SIXTYFO),MSGRQEL  RQEL ERROR MSG.               78150020
         LR    X0,XSCEND                NO. OF REGIONS                  78200020
         MH    X0,HEIGHTNN              TIMES SPACE PER REGION          78250020
         AH    X0,HFOURR                 PLUS SPACE FOR STOPPER         78300020
         L     XBASE,DCALTOD+DCACPU1    RESTORE MAINLINE BASEREG  M1683 78350021
         XC    DCALTOD+DCACPU1(FOUR),DCALTOD+DCACPU1              M4909 78400000
*                                               CLEAR SAVE AREA   M1683 78410000
         BR    XLINK                    RETURN TO MAINLINE              78450020
         DS    0F                                                A44022 78460021
SP251B   DC    X'FB000000'             MASK FOR SUBPOOL 251.     A44022 78470021
         EJECT                                                          78500020
* THIS SUBROUTINE WILL HANDLE THE DRIVER OVERRIDES SPECIFIED ON         78550020
* THE START TSO OPERATOR COMMAND.                                       78600020
*                                                                       78650020
IKJPAROV EQU   *                                                        78700020
         L     XDAEND,EIGHT(,XPARM)     BEGINNING OF PARM DATA          78750020
         A     XDAEND,FOUR(,XPARM)      PLUS LENGTH EQUAL END OF PARM   78800020
IKJCKMD1 EQU   *                                                        78850020
         TM    PAOVWTSW,EIGHT           Q.VALUE SUPPLIED BY WTOR        78900020
         BO    IKJCKMD4                 YES-RETURN TO MAINLINE          78950020
         CLC   ZERO(EIGHT,XSCAN),MODRVBK MODIFY DRIVER BKGD KEYWD       79000020
         BE    IKJCKMD2                 YES                             79050020
         LA    XSCAN,ONE(,XSCAN)        STEP SCAN PTR.                  79100020
         CR    XSCAN,XDAEND             AT END OF PARM DATA             79150020
         BL   IKJCKMD1                 NO-CONTINUE SCAN                 79200020
IKJCKMD4 EQU   *                                                        79250020
         SR    XRETC,XRETC              CLEAR RETURN CODE REGISTER      79260020
IKJCKMD8 EQU   *                                                        79270020
         L     XBASE,DCALTOD+DCACPU1    RESTORE MAINLINE BASE REG M1683 79300021
         XC    DCALTOD+DCACPU1(FOUR),DCALTOD+DCACPU1              M4909 79350000
*                                               CLEAR SAVE AREA   M1683 79360000
         BR    XLINK                    RETURN TO MAINLINE              79400020
IKJCKMD2 EQU   *                                                        79450020
         LA    XSCAN,EIGHT(,XSCAN)      STEP OVER DRIVER KEYWORD        79500020
IKJCKMD7 EQU   *                                                        79550020
         CLC   ZERO(ELEVEN,XSCAN),KZACKGRO   KEYWORD PROPER             79600020
         BNE   IKJCKMDC                 NO-CHECK NOBKGD SPEC  AF A44413 79650021
         LR    XMSGL,XSCAN              KEYWD PTR FOR ERROR MSG         79700020
         LA    XSCAN,ELEVEN(,XSCAN)     YES-STEP OVER KEYWORD           79750020
         LR    XWK1,XSCAN               SAVE BEGINNING OF PARM VALUE    79800020
         SR    XWK2,XWK2                LCEAR LENGTH COUNT              79850020
         CLI   ZERO(XSCAN),CZERO       Q.PROPER DIGIT                   79900020
         BL    IKJCKMD6                 NO                              79950020
         CLI   ZERO(XSCAN),CNINE       Q.PROPER DIGIT                   80000020
         BH    IKJCKMD6                 NO                              80050020
         LA    XSCAN,ONE(,XSCAN)        STEP SCAN PTR                   80100020
         LA    XWK2,ONE(,XWK2)          STEP LENGTH COUNTER             80150020
         TM    PAOVWTSW,EIGHT        Q.VALUE FROM WTOR                  80158020
         BZ    IKJCKMD9                 NO                              80166020
         CLI   ZERO(XSCAN),BLANK          DELIMITER REACHED             80174020
         BE    IKJCKMD3                 YES                             80182020
IKJCKMD9 EQU   *                                                        80190020
         CLI   ZERO(XSCAN),RIGHTPAR     DELIMITER REACHED               80200020
         BE    IKJCKMD3                 YES                             80250020
         CLI   ZERO(XSCAN),CZERO       Q.PROPER DIGIT                   80300020
         BL    IKJCKMD6                 NO                              80350020
         CLI   ZERO(XSCAN),CNINE       Q.PROPER DIGIT                   80400020
         BH    IKJCKMD6                 NO                              80450020
         LA    XSCAN,ONE(,XSCAN)                                        80500020
         LA    XWK2,ONE(,XWK2)                                          80550020
         TM    PAOVWTSW,EIGHT        Q.VALUE FROM WTOR                  80558020
         BZ    IKJCKMDA                 NO                              80566020
         CLI   ZERO(XSCAN),BLANK          DELIMITER REACHED             80574020
         BE    IKJCKMD3                 YES                             80582020
IKJCKMDA EQU   *                                                        80590020
         CLI   ZERO(XSCAN),RIGHTPAR     DELIMITER REACHED               80600020
         BNE   IKJCKMD6                 NO-ERROR                        80650020
IKJCKMD3 EQU   *                                                        80700020
         BCTR  XWK2,ZERO                LENGTH FOR EXECUTE-LO 4 BITS    80750020
         O     XWK2,PACKDOUZ            LENGTH FOR EXECUTE-HI 4         80800020
         EX     XWK2,IKJPACZ            PACK VALUE                      80850020
         CVB   XWK2,DCATSTME            MAKE VALUE BINARY               80900020
         XC    DCATSTME(EIGHT),DCATSTME   CL. WKSP. AFTER PACK          80950020
         C     XWK2,FZEZO             Q.VALUE LESS THAN ZERO            81000020
         BL    IKJCKMD6                 YES  ERROR                      81050020
         C     XWK2,FNINTZ9           Q.VALUE GREATER THAN 99           81100020
         BH    IKJCKMD6                 YES  ERROR                      81150020
IKJCKMDB EQU   *                                              AF A44413 81160021
         STC   XWK2,DCABKGD             INTO CONTROL BLOCK SLOT         81200020
         NI    DCAIFLGS,ALLFLAGS-DCAIBKGD    CLEAR FLAG                 81250020
         CLI   DCABKGD,ZERO             BDGD PERCENTAGE ZERO            81300020
         BNE   IKJCKMD1                 NO                              81350020
         OI    DCAIFLGS,DCAIBKGD             YES-SET THE FLAG           81400020
         B     IKJCKMD1                 CONTINUE CHECKING CIB DATA      81404020
IKJCKMDC CLC   ZERO(TWELVE,XSCAN),KZNOBKGD  Q. NOBACKGROUND SPEC A44413 81406021
         BNE   IKJCKMD5                 NO-ERROR              AF A44413 81406421
         XR    XWK2,XWK2                YES, ZERO WK REG      AF A44413 81406821
         B     IKJCKMDB                 CONTINUE PROCESSING   AF A44413 81407221
IKJCKMD5 EQU   *                                                        81409221
         MVC   ZWTOMS33(THIRTY1),ZBLANKS                                81412020
         MVC   ZWTOMSG(THIRTY3),MSGZZNVK     KEYWORD INVALID            81416020
         MVC   ZWTOMS33(THIRTEEN),ZERO(XSCAN) BAD KEYWORD               81420020
         LA    X1,ZWTOST                                                81424020
         SR    X0,X0                                                    81428020
         IC    X0,THIRTEEN(XPARM)       CONSOLE ID                      81432020
         WTO   MF=(E,(1))                                               81436020
         MVC   ZWTOMSG(FIFTY7),MSGZIGN  IGNORE KEYWORD MESSAGE          81440020
         LA    X1,ZWTOST                                                81444020
         SR    X0,X0                                                    81448020
         IC    X0,THIRTEEN(XPARM)       CONSOLE ID                      81452020
         WTO   MF=(E,(1))                                               81456020
         B     IKJCKMD4                                                 81460020
IKJCKMD6 EQU   *                                                        81464020
         OI    PAOVWTSW,EIGHT           SET WTOR SUPPLIED VALUE SW.     81468020
         MVC   ZWTOMS33(THIRTY1),ZBLANKS                                81472020
         MVC   ZWTOMSG(FORTY6),MSGZIZVV INVALID KEYWORD WTO             81476020
         MVC   ZWTOMS46(FOURTN),ZERO(XMSGL)   VALUE OF KEYWORD          81480020
         MVC   ZMESSA42(TWENTY2),ZBLANKS                                81484020
         MVC   ZMESSAGE(FORTY7),MSGZKZYU     WTOR MESSAGE               81488020
         LA    XMSGL,THIRTEEN           WTOR REPLY MESSAGE LENGTH       81492020
         LA    X1,ZWTOST                                                81496020
         SR    X0,X0                                                    81500020
         IC    X0,THIRTEEN(XPARM)       CONSOLE ID                      81504020
         WTO   MF=(E,(1))                                               81508020
         L     XSCAN,ZMSGAREA           PTR. TO REPLY AREA              81512020
         MVI   ZERO(XSCAN),BLANK                                        81516020
         MVC   ONE(TWENTY9,XSCAN),ZERO(XSCAN) CLEAR REPLY AREA          81520020
         LA    X1,ZFSTRPLY              WTOR PARMS PTR                  81524020
         L     XWK1,ZWTORECB            ECB PTR.                        81528020
         SR    X0,X0                                                    81532020
         IC    X0,THIRTEEN(XPARM)       CONSOLE ID FOR WTOR             81536020
         WTOR  ,(XSCAN),(XMSGL),(XWK1),MF=(E,(1))                       81540020
         WAIT  1,ECB=(XWK1)                                             81544020
         XC    ZMSGECB,ZMSGECB          CLEAR ECB FOR NEXT PASS         81548020
         OC    ZERO(TWELVE,XSCAN),ZBLANKS LOWER CASE ANS.               81552020
         CLI   ZERO(XSCAN),DEFAULT      OPER. REPLY EQUAL DEFAULT       81556020
         BE    IKJCKMD4                 YES  RETURN TO MAIN LINE        81560020
         CLC   ZERO(SIX,XSCAN),ZCANCELZ OPER. REPLY EQUAL CANCEL        81564020
         BNE   IKJCKMD7                 NO-CHECK REPLY                  81568020
         LA    XRETC,EIGHT              YES-RETURN CODE FOR TSC         81572020
         B     IKJCKMD8                 RETURN TO MAIN LINE             81576020
IKJPACZ  PACK  DCATSTME(ZERO),ZERO(ZERO,XWK1) CONV. EBEDIC TO BINARY    81600020
         EJECT                                                          81650020
ZWTO     WTO   '                                                       X81700020
                        ',MF=L,DESC=5,MCSFLAG=REG0                      81770020
MSGWTOR  WTOR  '                                                       +81850020
                         ',MF=L,DESC=2,MCSFLAG=REG0                     81900020
HFOURR   DC    H'4'                     GENERAL PURPOSE NO.             81950020
HEIGHTNN DC    H'18'                    GENERAL PURPOSE NO.             82000020
FZEZO    DC    F'0'                     GENERAL PURPOSE NUMBER          82050020
FNINTZ9  DC    F'99'                    GENERAL PURPOSE NUMBER          82100020
FONEHUND  DC   F'100'                   FOR DIDIDE-CONV. TO SCALED      82150020
PACKDOUZ DC    F'112'                  CREATE EXECUTE VALUE FACTOR      82200020
HTWOHU56 DC    H'256'                   USED TO CLEAR CTRL. BLOCK AREA  82250020
HTHREEE  DC    H'3'                     FOR DIVIDE-CONV. ROUTINE        82300020
HTENN    DC    H'10'                    REGION NUMBER COMPARE           82350020
MSGZIGN  DC    C'IKJ067I  THE ABOVE KEYWORD AND IT''S VALUE WILL BE '   82400020
         DC    C'IGNORED'                                               82450020
MSGRQEL  DC     C'IKJ043D RQEL PARM NOT SUPPLIED FOR REGION 0N-SPECIFY' 82510020
         DC    C' OR ''CANCEL'''                                        82550020
MSGZKZYU DC    C'IKJ066D  REPLY ''KEYWORD=VALUE'', ''U'',OR ''CANCEL''' 82600020
MSGZIZVV DC    C'IKJ064I  THE VALUE OF THIS KEYWORD IS INVALID-'        82650020
ZCANCELZ DC    C'CANCEL'                FOR WTOR REPLY COMPARE          82700020
MSGZZNVK DC    C'IKJ061I  THIS KEYWORD IS INVALID-'                     82750020
MODRVBK  DC    C'DRIVER=('              CHECK START PARM KEYWORD        82800020
KZACKGRO DC    C'BACKGROUND='                                           82850020
KZNOBKGD DC    C'NOBACKGROUND'                                AF A44413 82860021
YONES    DC    X'FF'                    USEE TO MAKE CHARACTERS PRINTAB 82900020
ZBLANKS  DC    32C' '                   USED AS BLANKS                  82920020
         END                                                            82950020
