         TITLE 'IKJEAD03-TIME SHARING DRIVER-MODIFY BACKGROUND %'       00020020
IKJEAD03 START                                                          00030020
         SPACE                                                          00040020
* STATUS=0                                                        20023 00050020
         SPACE                                                          00060020
* FUNCTION                                                              00070020
*   THE TIME SHARING DRIVER MODIFY MODULE ALLOWS THE SYSTEM OPERATOR    00080020
*   TO CHANGE THE PERCENTAGE OF TIME GUARANTEED TO THE BACKGROUND.      00090020
*   THIS CAN BE DONE AFTER THE TS SUBSYSTEM HAS BEEN STARTED BY ISSUING 00100020
*   THE MODIFY TS COMMAND AND SPECIFYING A KEYWORD AND THE DESIRED      00110020
*   PERCENTAGE. THE KEYWORD (BACKGROUND=NN) IS TESTED FOR VALIDITY AND  00120020
*   ITS VALUE FOR AN ACCEPTABLE RANGE (0 THRU 99).                      00130020
         SPACE                                                          00140020
*   A WTOR IS ISSUED IF THE MODIFY CAME FROM THE OPERATOR'S CONSOLE AND 00150020
*   THE KEYWORD OR VALUE IS IN ERROR. THE REPLY IS THEN USED, IF VALID. 00160020
*   AN INVALID REPLY CAUSES A WTOR TO AGAIN ASK FOR PROPER INPUT. AN    00170020
*   OPERATOR REPLY OF CANCEL CAUSES THE MODIFY COMMAND TO BE IGNORED.   00180020
*   A VALID KEYWORD WITH AN ACCEPTABLE VALUE UPDATES THE GUARANTEED     00190020
*   BACKGROUND PERCENTAGE (DCABKGD) BYTE IN THE DCA CONTROL BLOCK WITH  00200020
*   THE NEW VALUE.                                                      00210020
         SPACE                                                          00220020
*   A TPUT IS ISSUED IF THE MODIFY CAME FROM A TSO TERMINAL AND THE     00230020
*   KEYWORD OR VALUE IS IN ERROR. THIS TPUT TELLS THE USER THAT THE     00240020
*   MODIFY COMMAND IS INVALID.                                          00250020
         SPACE                                                          00260020
*   THE BACKGROUND PERCENTAGE VALUE IS ALSO UPDATED IN THE TS DRIVER    00270020
*   MODIFY SMF RECORD (33) IF SMF IS ACTIVE BY BUILDING AND WRITING A   00280020
*   NEW RECORD.  THE SMF WRITER MACRO (SMFWTM) IS USED TO WRITE THE     00290020
*   SMF RECORD.                                                         00300020
         SPACE                                                          00310020
* ENTRY POINT-IKJEAD03                                                  00320020
         SPACE                                                          00330020
* INPUT                                                                 00340020
*   REGISTER  1     ADDRESS OF A PARAMETER LIST                         00350020
*            13     ADDRESS OF SAVE AREA FOR TSC'S REGISTERS            00360020
*            14     RETURN ADDRESS                                      00370020
*            15     ENTRY POINT ADDRESS                                 00380020
*   PARAMETER LIST FORMAT                                               00390020
*            +0     SWITCH                                              00400020
*                   BIT 0=1 IF SMF IS ACTIVE                            00410020
*                   BIT 1=1 IF MODIFY FROM TSO TERMINAL                 00420020
*            +1     CONSOLE ID IF MESSAGE FROM CONSOLE                  00430020
*            +2     TJID IF MODIFY FROM TERMINAL                        00440020
*            +4     ADDRESS OF DCA                                      00450020
*            +8     TOTAL LENGTH OF DRIVER KEYWORD AND ASSOC. INPUT     00460020
*            +12    ADDRESS OF DRIVER KEYWORD IN CIB                    00470020
         SPACE                                                          00480020
* OUTPUT- NEW BACKGROUND PERCENTAGE VALUE IN DCA CONTROL BLOCK          00490020
         SPACE                                                          00500020
* EXIT,NORMAL-RESTORE TSC'S REGS.(EXCEPT 15) AND RETURN TO TSC.         00510020
* REG. 15 CONTAINS A FOUR IF MODIFICATION NOT DONE,OTHERWISE ZERO.      00520020
*                                                                       00530020
* EXIT,ERROR-NONE                                                       00540020
         SPACE                                                          00550020
* TABLES/WORK AREAS                                                     00560020
*   1. DRIVER CONTROL AREA (DCA) CONTROL BLOCK.                         00570020
*   2. A WORK AREA FOR WTOR + OPER. REPLIES (SEE ERRORMSG DSECT).       00580020
*   3. A WORK AREA FOR REQUIRED SMF RECORDS.                            00590020
*   4. A DOUBLE WORD FOR CONVERTING EBEDIC BKGD % TO BINARY.            00600020
         SPACE                                                          00610020
* ATTRIBUTES-REFRESHABLE,REENTRANT,READ-ONLY,ENABLED                    00620020
         SPACE                                                          00630020
*                                                                       00640020
         IKJDCA                                                         00650020
ERRORMSG DSECT                                                          00660020
ZLERPLY  DS    A                        LENGTH AND ADDRESS OF REPLY     00670020
ZWTORECB DS    A                        ECB ADDRESS                     00680020
         DS    A                                                        00690020
ZMESSAGE DS    CL46                     MESSAGE                         00700020
ZMSGECB  DS    F                        WTOR ECB                        00710020
ZREPLY   DS    CL16                     WTOR REPLY SPACE                00720020
ZREPLY1  EQU   ZREPLY+1                                                 00730020
* END OF DSECT                                                          00740020
         SPACE                                                          00750020
         IFASMFR 33                                                     00760020
         EJECT                                                          00770020
IKJEAD03 CSECT                                                          00780020
*                                                                       00790020
*              REGISTER ASSIGNMENTS                                     00800020
*                                                                       00810020
X0       EQU   0                        SCRATCH                         00820020
X1       EQU   1                        ADDRESS OF COMMAND INPUT BUFFER 00830020
XWK1     EQU   2                        MISC                            00840020
XRETC    EQU   3                        RETURN CODE                     00845020
XGETMAIN EQU   8                        ADDRESS OF SPACE                00850020
XDATA    EQU   9                        PTR. TO MODIFY DATA             00860020
XPLIST   EQU   10                       PARAMETER LIST ADDRESS          00870020
XDCA     EQU   11                       DSECT BASE REGISTER FOR DCA     00880020
XBASE    EQU   12                       BASE REGISTER                   00890020
XSAVE    EQU   13                       SAVE AREA ADDRESS               00900020
X14      EQU   14                       RETURN ADDRESS                  00910020
X15      EQU   15                       ENTRY POINT ADDRESS             00920020
         EJECT                                                          00930020
*              GENERAL EQUATES                                          00940020
*                                                                       00950020
ZERO     EQU   0                        GENERAL PURPOSE NUMBER          00960020
ONE      EQU   1                        GENERAL PURPOSE NUMBER          00970020
TWO      EQU   2                        GENERAL PURPOSE NUMBER          00980020
FOUR     EQU    4                       GENERAL PURPOSE NUMBER          00990020
SIX      EQU   6                        GENERAL PURPOSE NUMBER          01000020
SEVEN    EQU   7                        GENERAL PURPOSE NUMBER          01010020
EIGHT    EQU   8                        GENERAL PURPOSE NUMBER          01020020
TEN      EQU   10                       GENERAL PURPOSE NUMBER          01030020
ELEVEN   EQU   11                       GENERAL PURPOSE NUMBER          01040020
TWELVE   EQU   12                       GENERAL PURPOSE NUMBER          01050020
FIFTEEN  EQU   15                       GENERAL PURPOSE NUMBER          01060020
SIXTEEN  EQU   16                       GENERAL PURPOSE NUMBER          01070020
TWENTY   EQU   20                       GENERAL PURPOSE NUMBER          01080020
THIRTY3  EQU   33                       GENERAL PURPOSE NUMBER          01090020
THIRTY8  EQU   38                       GENERAL PURPOSE NUMBER          01100020
FIFTY8   EQU   58                       GENERAL PURPOSE NUMBER          01110020
CZERO    EQU   X'F0'                    CHARACTER COMPARE               01120020
CNINE    EQU   X'F9'                    CHARACTER COMPARE               01130020
SMFACT   EQU   X'80'                    SMF ACTIVE INDICATOR            01140020
INPUTTER EQU   X'40'                    INPUT FROM TERMINAL INDICATOR   01150020
ALLFLAGS EQU   X'FF'                    USED TO CLEAR FLAGS             01160020
ENABLE   EQU   X'00'                    USED WITH SSM INSTRUCTION       01170020
DISABLE  EQU   X'FF'                    USED WITH SSM INSTRUCTION       01180020
PARENL   EQU   X'4D'                    USED FOR CIRB INPUT COMPARE     01186020
PARENR   EQU   X'5D'                                                    01192020
BLANK    EQU   X'40'                    FOR PARAMETER EDIT              01200020
TDMSMFLE EQU   TDMTIMB+ONE-TDMSMF       LENGTH OF SMF RECORD            01210020
         EJECT                                                          01220020
         STM   X14,XBASE,TWELVE(XSAVE)  SAVE TSC REGISTERS              01230020
         LR    XBASE,X15                LOAD BASE REGISTER              01240020
         LA    XRETC,FOUR               RETURN CODE IF NO MODIF. DONE   01250020
         USING IKJEAD03,XBASE                                           01260020
         SR    XGETMAIN,XGETMAIN        CLEAR FOR LATER CHECK           01270020
         LR    XPLIST,X1                PARAMETER LIST ADDRESS          01280020
         L     XDATA,TWELVE(,XPLIST)    DRIVER MODIFY DATA PTR.         01290020
         L     XDCA,FOUR(,XPLIST)       PTR. TO DR. CTRL DLOCK-DCA      01300020
         USING DCA,XDCA                                                 01310020
         LA    XDATA,SEVEN(,XDATA)      STEP OVER DRIVER=               01320020
         CLI   ZERO(XDATA),PARENL       Q. PARENTHESIS PRECEDE KEYWORD  01330020
         BNE   IKJD3ERR                 NO-ERROR                        01340020
         LA    XDATA,ONE(,XDATA)        YES-STEP OVER                   01350020
IKJD3000 EQU   *                                                        01370020
         CLC   ZERO(ELEVEN,XDATA),BACKGREQ  Q.KEYWORD VALID             01380020
         BNE   IKJD3ERR                       NO-ERROR                  01390020
         LA    XDATA,ELEVEN(,XDATA)     YES-STEP OVER IT                01400020
         L     XWK1,PACKDOUB            LOAD EXECUTE VALUE LENGTH       01410020
         CLI   ZERO(XDATA),CZERO     Q.BKGD % DIGIT TOO LOW             01420020
         BL    IKJD3ERR                 YES ERROR                       01430020
         CLI   ZERO(XDATA),CNINE     Q.BKGD % DIGIT TOO HIGH            01440020
         BH    IKJD3ERR                 YES ERROR                       01450020
         CLI   ONE(XDATA),PARENR        Q.DELIMITER AFTER 1 CHAR.       01460020
         BE    IKJD3020                 YES                             01470020
         CLI   ONE(XDATA),BLANK         DELIMITER IF WTOR REPLY         01480020
         BE    IKJD3020                 YES-ONE CHARACTER               01490020
         LA    XWK1,ONE(,XWK1)          NO STEP EXECUTE VALUE           01500020
         CLI   ONE(XDATA),CZERO      Q.BKGD % DIGIT TOO LOW             01510020
         BL    IKJD3ERR                 YES ERROR                       01520020
         CLI   ONE(XDATA),CNINE      Q.BKGD % DIGIT TOO HIGH            01530020
         BH    IKJD3ERR                 YES ERROR                       01540020
         CLI   TWO(XDATA),BLANK         DELIMITER IF WTOR REPLY         01550020
         BE    IKJD3020                 YES-TWO CHARACTER               01560020
         CLI   TWO(XDATA),PARENR        Q.DELIMITER REACHED             01570020
         BNE   IKJD3ERR                 NO CHAR. EXCEED TWO             01580020
IKJD3020 EQU   *                                                        01590020
         GETMAIN   R,LV=8               WORKSPACE FOR UNPACK+CVB        01600020
         XC    ZERO(EIGHT,X1),ZERO(X1)  CLEAR WORK SPACE                01610020
         EX    XWK1,IKJD3PAC                                            01620020
         CVB   XWK1,ZERO(X1)                                            01630020
         FREEMAIN  R,LV=8,A=(1)                                         01640020
         LTR   XWK1,XWK1              Q.BKGD % NEGATIVE                 01650020
         BM    IKJD3ERR                 YES-KEYWORD INVALID ERROR       01660020
         CH    XWK1,HNINTY9           Q.VALUE GREATER THAN 99           01670020
         BH    IKJD3ERR                 YES-KEYWORD INVALID ERROR       01680020
         STC   XWK1,DCABKGD             PLACE VALUE IN CONTROL BLOCK    01690020
         SR    XRETC,XRETC              MODIFY DONE-ZERO RETURN CODE    01700020
         NI    DCAIFLGS,ALLFLAGS-DCAIBKGD  CLEAR IGNORE BKGD. IND.      01710020
         CLI   DCABKGD,ZERO          Q.ANY BKGD. GUARANTEED TIME        01720020
         BNE   IKJD3021                YES-TAKE BRANCH                  01730020
         OI    DCAIFLGS,DCAIBKGD       NO-SET IGNORE BKGD. IND.         01740020
IKJD3021 EQU   *                                                        01750020
         LTR   XGETMAIN,XGETMAIN      Q.GETMAIN BEEN ISSUED             01760020
         BZ    IKJD3030                 NO                              01770020
IKJD3025 EQU   *                                                        01780020
         LR    X1,XGETMAIN              ADDRESS OF MAIN TO FREE         01790020
         FREEMAIN  R,LV=80,A=(1)                                        01800020
IKJD3030 EQU   *                                                        01810020
         TM    ZERO(XPLIST),SMFACT    Q.SMF ACTIVE                      01820020
         BZ    IKJD3RET                 NO-RETURN                       01830020
         LA    X1,TDMSMFLE              LENGTH OF SMF                   01840020
         GETMAIN R,LV=(1)               FORSMF RECORD                   01850020
         USING TDMSMF,X1                                                01860020
         XC    ZERO(TDMSMFLE,X1),ZERO(X1)    CLEAR SMF RECORD           01870020
         LA    X0,TDMSMFLE              RECORD LENGTH                   01880020
         STH   X0,TDMRLEN               FOR SMF RECORD                  01890020
         MVI   TDMRCDCY,THIRTY3         RECORD TYPE                     01900020
         MVC   TDMSCHED(ONE),DCAIFLGS   CONTROL INFORMATION             01910020
         STC   XWK1,TDMTIMB             NEW BACKGROUND EXEC PERCENTAGE  01920020
         LR    XWK1,X1                  SAVE FOR FREEMAIN               01923020
         LR    XDATA,X0                 SAVE FOR FREEMAIN               01926020
         SMFWTM  (1)                   WRITE SMF RECORD                 01930020
         FREEMAIN R,LV=(9),A=(2)        FREE SMF WORKSPACE              01940020
IKJD3RET EQU   *                                                        01950020
         L     X14,TWELVE(XSAVE)         RESTORE REGISTERS              01960020
         LR    X15,XRETC                RETURN CODE                     01965020
         LM    X0,XBASE,TWENTY(XSAVE)    EXCEPT X15, WHICH IS RET. CODE 01970020
         BR    X14                      RETURN TO TSC                   01980020
IKJD3ERR EQU   *                                                        01990020
         TM    ZERO(XPLIST),INPUTTER  Q.INPUT FROM TERMINAL             02000020
         BZ    IKJD3R2                  NO                              02010020
         LH    XWK1,TWO(,XPLIST)        TJID NUMBER                     02020020
         TPUT  IKJD3TMS,THIRTY8,TJID=(XWK1) MAKE INV. MSG. TO TSO TERM. 02030020
         B     IKJD3RET                 RETURN TO TSC                   02040020
IKJD3R2  EQU   *                                                        02050020
         LTR   XGETMAIN,XGETMAIN      Q.ERRORMSG SPACE ALREADY OBTAINED 02060020
         BNZ   IKJD3ER1                 YES-BRANCH AROUND GETMAIN       02070020
         GETMAIN   R,LV=80                                              02080020
         LR    XGETMAIN,X1              DSECT PTR                       02090020
         USING ERRORMSG,XGETMAIN                                        02100020
         MVC   ERRORMSG(FIFTY8),MSGDWTOR  WTOR PARM LIST                02110020
         LA    XWK1,ZMSGECB             ADDRESS OF ECB TO               02120020
         ST    XWK1,ZWTORECB            WTOR PARM LIST                  02130020
IKJD3ER1 EQU   *                                                        02140020
         SR    X0,X0                                                    02142020
         IC    X0,ONE(,XPLIST)          CONSOLE ID FOR WTO              02144020
         LA    X1,WTOMSG                ADDR. OF WTO LIST               02146020
         WTO   MF=(E,(1))               ISSUE WTO                       02148020
         XC    ZMSGECB,ZMSGECB          CLEAR ECB                       02150020
         MVI   ZREPLY,BLANK             BLANK                           02160020
         MVC   ZREPLY1(FIFTEEN),ZREPLY  MSG. REPLY AREA                 02170020
         LR    X1,XGETMAIN              PTR. TO WTOR PARMS              02180020
         L     XWK1,ZWTORECB            ECB PTR.                        02190020
         LA    XDATA,ZREPLY             REPLY AREA PTR.                 02200020
         SR    X0,X0                                                    02203020
         IC    X0,ONE(,XPLIST)          GET CONSOLE ID FOR WTOR         02206020
         WTOR  ,(XDATA),SIXTEEN,(XWK1),MF=(E,(1))                       02210020
         WAIT  1,ECB=(XWK1)                                             02220020
         OC    ZERO(TEN,XDATA),CBLANKS  TO HANDLE LOWER CASE ANSWER     02230020
         CLC   ZERO(SIX,XDATA),ZCANCEL  OPERATOR REPLY EQUAL CANCEL     02240020
         BNE   IKJD3000                 NO-GO HANDLE                    02250020
         NI    ZERO(XPLIST),ALLFLAGS-SMFACT  YES-CLEAR SMF INDICATOR    02260020
         B     IKJD3025                 GO FREEMAIN AND RETURN          02270020
HNINTY9  DC    H'99'                    USED FOR COMPARE                02280020
PACKDOUB DC    F'112'                   CREATE EXECUTE VALUE FACTOR     02290020
MSGDWTOR WTOR  'IKJ040D  RESPECIFY ''BACKGROUND=NN'' OR ''CANCEL''',   X02300020
               DESC=2,MCSFLAG=REG0,MF=L                                 02310020
IKJD3PAC PACK  ZERO(ZERO,X1),ZERO(ZERO,XDATA)  CONV. EBEDIC TO BIN      02330020
BACKGREQ DC    C'BACKGROUND='           USED TO COMPARE KEYWORD         02340020
ZCANCEL  DC    C'CANCEL'                WTOR REPLY COMPARE              02350020
CBLANKS  DC    10C' '                   CONSTANT BLANK CHARACTERS       02360020
WTOMSG   WTO   'IKJ041I  BACKGROUND PERCENTAGE INVALID',MCSFLAG=REG0,  X02362020
               MF=L,DESC=5                                              02364020
IKJD3TMS EQU   WTOMSG+FOUR         TPUT MESSAGE                         02368020
         END                                                            02370020
