         TITLE 'IKJEAI00-TIME SHARING INTERFACE PROGRAM (TSIP)'         00020020
IKJEAI00 START  0                                                       00030020
          ENTRY IKJEAI01                                                00040020
          ENTRY IKJEAI02                                                00050020
          ENTRY IKJEAI03                                                00060020
         SPACE                                                          00070020
*********************************************************************** 00073021
*                                                                     * 00076021
*STATUS=0                                                         20023 00080020
*                                                                       00081021
*A108320-108360                                               AE A49262 00082021
*C019200,040600,056200                                            21008 00092021
*A030530,030560,040730,056110-056160,056180-056240,097300-099300  21008 00094021
*D097200-100300                                                   21008 00096021
*D097100-097300                                                   M1683 00098021
*A096920-100388                                                   M1683 00098421
*A089250                                                      CC A62272 00098521
*C089600                                                      CC A62272 00098621
*A060720-060760                                               CC A67880 00098721
*C055918,055920                                               CC A64471 00098821
*                                                                     * 00098921
*                                                                     * 00099021
*********************************************************************** 00099121
         SPACE 4                                                        00099221
*********************************************************************** 00100020
* THE FOLLOWING CODE IS THE TIME SHARING INTERFACE PROGRAM (TSIP) AND   00110020
* IS A PORTION OF THE TSO   PACKAGE. IT PROVIDES AN INTERFACE BETWEEN   00120020
* THE TIME SHARING DRIVER AND THE REST OF THE SYSTEM, THEREBY ISOLATING 00130020
* THE TS DRIVER FROM THE INTERNALS OF THE SYSTEM AND MAKING IT EASILY   00140020
* REPLACED BY AN INSTALLATION-PROVIDED ROUTINE.                         00150020
**********************************************************************  00160020
*                                                                       00170020
*                                                                       00180021
*                                                                       00190020
* ROUTINE NAME - TSIP                                                   00200020
*                                                                       00210020
* THE ROUTINES CONTAINED IN THIS MODULE ARE-                            00220020
*                                                                       00230020
*        TS INTERFACE-ENTERED BY AN SVC OR A BRANCH INSTRUCTION         00240020
*        TS DISPATCHER-ENTERED FROM THE TOP OF THE OS DISPATCHER AND    00250020
*                      AFTER A TASK SWITCH OCCURS IN THE OS DISPATCHER  00260020
*                                                                       00270020
* FUNCTION -                                                            00280020
*                                                                       00290020
*        A. TS INTERFACE                                                00300020
*              ENTERED BY MANY SYSTEM OR TS ROUTINES AND                00310020
*              USED TO PASS INFORMATION PERTAINING TO TIME-SHARING TO   00320020
*              AND FROM THE TIME SHARING DRIVER. REASONS FOR ENTRY CAN  00330020
*              BE CATAGORIZED AS FOLLOWS-                               00340020
*                                                                       00350020
*                  1. SWAPPING ENTRIES- A REGION SWAP MAY BE DESIRED AS 00360020
*                     A TIME SLICE EXPIRED, ALL A USER'S TASKS ARE IN A 00370020
*                     NON-I/O WAIT, ETC.                                00380020
*                                                                       00390020
*                  2. TASK SWITCH ENTRIES- CONVEY INFO ABOUT THE TYPE   00400020
*                     OF TASK BEING DISPATCHED, I.E. SYSTEM TASK, USER  00410020
*                     TASK, SYSTEM WAIT TASK, BACKGROUND, ETC.          00420020
*                                                                       00430020
*                  3. SWAPPING STATISTICS- INDICATE WHEN A TS FUNCTION  00440020
*                     BEGINS OR ENDS, I.E. QUIESCE HAS STARTED, SWAP IN 00450020
*                     HAS ENDED, ETC.                                   00460020
*                                                                       00470020
*                  4. TERMINAL I/O STATISTICS- INDICATE BEGINNING AND   00480020
*                     END OF TERMINAL READS AND WRITES, ENABLING SYSTEM 00490020
*                     TO GATHER STATISTICS ABOUT TERMINAL USE SUCH AS   00500020
*                     THINK TIME, ETC.                                  00510020
*                                                                       00520020
*                  5. ACCOUNTING INFORMATION- CONVEY OR REQUEST LOGON   00530020
*                     AND LOGOFF ACCOUNTING INFO.                       00540020
*                                                                       00550020
*                  6. REGION ALLOCATION- REQUEST ASSIGNMENT OR          00560020
*                     REASSIGNMENT OF A USER IN A REGION OR FREE UP     00570020
*                     REGIONS, THUS ENABLING THE TS DRIVER TO BALANCE   00580020
*                     THE SYSTEM.                                       00590020
*                                                                       00600021
*              AN ENTRY CODE IS PASSED TO THE INTERFACE SVC, IDENTIFY-  00610020
*              ING THE REASON FOR EACH ENTRY. THE INTERFACE ROUTINE     00620020
*              ASSEMBLES THIS AND OTHER PARAMETER INFORMATION FOR THE   00630020
*              TS DRIVER AS FOLLOWS-                                    00640020
*                                                                       00650020
*                  1. STORES INPUT REGISTERS 0-1 IN THE FIRST TWO WORDS 00660020
*                     OF THE DRIVER PARAMETER AREA (DPA).               00670020
*                                                                       00680020
*                  2. TESTS THE TERMINAL JOB IDENTIFICATION (TJID)      00690020
*                     FIELD OF THE INPUT INFO, AND IF IT CONTAINS ZERO, 00700020
*                     STORES THE TJID ASSOCIATED WITH THE CURRENTLY     00710020
*                     DISPATCHED TASK (IF IT IS A SWAPPABLE TS USER)    00720020
*                     INTO THE TJID FIELD OF THE DPA CTRL. BLOCK.       00730020
*                                                                       00740020
*                  3. DETERMINES THE CURRENT TIME OF DAY AND STORES IT  00750020
*                     IN THE THIRD WORD OF THE DPA.                     00760020
*                                                                       00770020
*              A CHECK IS MADE(SEE ECODETAB) TO DETERMINE IF THE        00771020
*              DRIVER CAN HANDLE THE ENTRY CODE IF NO TJID IS TO BE     00772020
*              PASSED.  IF NOT, TSIP RETURNS TO ITS CALLER.             00773020
*                                                                       00774021
*              THE INTERFACE ROUTINE CHECKS TO SEE IF TSTRACE HAS BEEN  00780020
*              STARTED. IF IT HAS, THE RESIDENT STATISTICS COLLECTION   00790020
*              ROUTINE MOVES THE FIRST THREE WORDS OF THE DPA INTO      00800020
*              BUFFERING SPACE PROVIDED BY THE STATISTICS WRITER. ENTRY 00810020
*              CODE 0,25,+44 ALSO CAUSE ADDITIONAL BUFFER ENTRIES TO BE 00820020
*              MADE CONTAINING 'COMMAND' INFO, USERID, OR SERVICEABIL-  00830020
*              ITY TYPE INFORMATION RESPECTIVE-                         00840020
*              LY. IF BUFFER SPACE IS NOT AVAILABLE, APPROPRIATE        00850020
*              INDICATIONS ARE PLACED IN THE LAST BUFFER. AFTER         00860020
*              THE RESIDENT STATISTICS COLLECTION CHORE IS COMPLETED,   00870020
*              OR IF TSTRACE IS NOT ACTIVE (TSCVTTRB SLOT CONTAINS 0),  00880020
*              THE INTERFACE ROUTINE THEN BRANCHES TO THE TIME SHARING  00890020
*              DRIVER WITH THE PARAMETER INFORMATION. UPON RETURN FROM  00900020
*              THE DRIVER A CHECK IS MADE TO DETERMINE IF A             00950020
*              NEW TIME SLICE HAS BEEN REQUESTED. IF SO, THE TIME SHAR- 00960020
*              ING TQE IS DEQUEUED FROM THE TIMER QUEUE AND RE-ENQUEUED 00970020
*              WITH THE NEW TIME SLICE VALUE. THE INTERFACE ROUTINE     00980020
*              THEN RETURNS TO ITS CALLER.                              00990020
*                                                                       01000020
*        B. TS DISPATCHER                                               01010020
*              THE TIME SHARING DISPATCHER IS AN EXTENSION OF THE OS    01020020
*              DISPATCHER WHEN TIME SHARING IS ACTIVE IN THE SYSTEM. IT 01030020
*              CONTROLS THE DISPATCHING OF TIME SHARING TASKS, BASED ON 01040020
*              INDICATORS SET BY THE TS DRIVER, BY REORDERING TS TASKS  01050020
*              ON THE TCB READY QUEUE. THE TIME SHARING SYSTEM CAN THUS 01060020
*              DETERMINE THE PRIORITY OF TIME SHARING TASKS WITHOUT     01070020
*              ALTERING THE LOGIC OF THE OS DISPATCHER. THE TS DIS-     01080020
*              PATCHER IS ENTERED FROM THE BEGINNING OF THE OS DIS-     01090020
*              PATCHER AND AGAIN, AT A DIFFERENT ENTRY, AFTER THE NEXT  01100020
*              TASK TO BE DISPATCHED HAS BEEN DETERMINED. THIS SECOND   01110020
*              ENTRY IS TO PASS ACCOUNTING INFO TO THE TS DRIVER.       01120020
*                                                                       01130020
*                  1. WHEN ENTERED FROM THE BEGINNING OF THE OS DIS-    01140020
*                     PATCHER, THE TIME SHARING DISPATCHER DETERMINES   01150020
*                     WHETHER ANY STATUS MODIFICATIONS HAVE BEEN RE-    01160020
*                     QUESTED BY THE TS DRIVER. IF THE STATUS FIELD IS  01170020
*                     ZERO, THE TS DISPATCHER RETURNS TO THE OS DIS-    01180020
*                     PATCHER.  OTHERWISE, EACH INDICATOR IS TESTED.    01190020
*                     THE TIME SHARING DISPATCHER TESTS THE SYSTEM      01200020
*                     STATUS FIELD TO DETERMINE WHETHER ANY REGION      01210020
*                     STATUS MODIFICATIONS ARE REQUIRED. IF SO, THE     01220020
*                     STATUS FIELD IN EACH REGION ENTRY IS TESTED AND   01230020
*                     THE FUNCTION INDICATED FOR EACH REGION IS PER-    01240020
*                     FORMED. THIS INVOLVES SETTING APPROPRIATE FLAGS   01250020
*                     IN THE RCB'S AND POSTING VIA THE POST ROUTINE     01260020
*                     FOR QUIESCE OR RESTORE, WHICHEVER IS              01270020
*                     INDICATED IN THE STATUS FIELD OF EACH REGION      01280020
*                     ENTRY. AFTER PERFORMING THE TEST FOR THE SYSTEM   01290020
*                     AND REGION STATUS CHANGES, THE TIME SHARING       01300020
*                     DISPATCHER TESTS TO DETERMINE IF                  01310020
*                     A CHANGE IN PRIORITY IS INDICATED, THE REGION NO. 01320020
*                     SPECIFIED IS CHECKED. IF NOT ZERO,THIS REGION NO. 01330020
*                     IS TO BE OF HIGHEST PRIORITY. THE TCB'S ASSOCIAT- 01340020
*                     ED WITH THIS REG. ARE REQUEUED, IF NECESSARY, SO  01350020
*                     AS TO BE THE FIRST TIME SHARING TASKS ON THE TCB  01360020
*                     READY QUEUE. IF ZERO, BACKGROUND IS TO RUN AT     01370020
*                     HIGHEST PRIORITY. THEREFORE, TIME SHARING USER    01380020
*                     TASKS ARE MOVED TO THE END OF THE TCB READY QUEUE 01390020
*                     AND THEIR DISPATCHING PRIORITY IS SET TO ZERO.    01400020
*                     AFTER THE REORDERING OF THE TCB READY QUEUE IS    01410020
*                     COMPLETE, THE TS DISPATCHER CHECKS TO ENSURE THIS 01420020
*                     REORDERING IS REFLECTED IN THE TCB NEW POINTER.   01430020
*                     IF NOT, THIS POINTER IS UPDATED. THE TS DISP.     01440020
*                     THEN RETURNS TO THE OS DISPATCHER.                01450020
*                                                                       01460020
*                  2. WHEN ENTERED FROM THE OS DISPATCHER AFTER THE     01470020
*                     NEXT TASK TO BE DISPATCHED HAS BEEN DETERMINED, A 01480020
*                     TEST IS MADE TO SEE WHETHER A TASK SWITCH HAS     01490020
*                     OCCURRED. IF NOT, THE TS DISPATCHER RETURNS TO    01500020
*                     THE OS DISPATCHER BECAUSE A CHANGE OF ACCOUNTING  01510020
*                     INFORMATION IS NOT NEEDED. IF SO, THE TS DIS-     01520020
*                     PATCHER DETERMINES THE TYPE OF TASK TO BE DIS-    01530020
*                     PATCHED. THESE ARE:                               01540020
*                                                                       01550020
*                       1. TS USER TASK- HAS TS DISPATCHING PRIORITY    01560020
*                                                                       01570020
*                       2. SYSTEM TASK- HAS DISPATCHING PRIORITY HIGHER 01580020
*                          THAN TS DISPATCHING PRIORITY                 01590020
*                                                                       01600020
*                       3. BACKGROUND TASK- HAS DISPATCHING PRIORITY    01610020
*                          LOWER THAN TS DISPATCHING PRIORITY           01620020
*                                                                       01630020
*                       4. SYSTEM WAIT TASK- DISPATCHED WHEN NO OTHER   01640020
*                          TASK IS READY                                01650020
*                                                                       01660020
*                     IF THE NEW TASK IS A DIFFERENT TS USER, THE TS    01670020
*                     DISPATCHER BRANCHES TO THE INTERFACE ROUTINE WITH 01680020
*                     THE TJID OF THE USER TASK- AND THE APPROPRIATE    01690020
*                     ENTRY CODE. IF THE NEW TASK IS NOT THE SAME TYPE  01700020
*                     OF TASK AS THE OLD TASK, THE TS DISPATCHER        01710020
*                     BRANCHES TO THE INTERFACE ROUTINE WITH THE AP-    01720020
*                     PROPRIATE ENTRY CODE. ENTRY TO THE INTERFACE      01730020
*                     ROUTINE WILL ENABLE THE TS DRIVER TO ALLOCATE     01740020
*                     TIME BETWEEN BACKGROUND AND TIME SHARING USERS    01750020
*                     PROPERLY. IF THE NEW TASK IS THE SAME TYPE OF     01760020
*                     TASK AS THE OLD TASK, BUT NOT A TIME SHARING USER 01770020
*                     TASK, THE TS DISPATCHER RETURNS TO THE OS DIS-    01780020
*                     PATCHER.                                          01790020
         EJECT                                                          01800020
* ENTRY POINT  . IKJEAI00    TS INTERFACE SVC 95 ENTRY                  01810020
* NAMES        . IKJEAI01    TS INTERFACE  BRANCH ENTRY                 01820020
*              . IKJEAI02    ENTRY FROM BEGINNING OF OS DISPATCHER      01830020
*              . IKJEAI03    ENTRY FROM OS DISP. AFTER TASK SWITCH      01840020
*                                                                       01850020
* CONTAINED    . IKJEAI00                                               01860020
* IN MODULE                                                             01870020
*                                                                       01880020
* ATTRIBUTES-DISABLED,SUPERVISOR STATE,                                 01890020
*              RESIDENT WHEN THE TIME SHARING SUBSYSTEM IS OPERATING    01900020
*                                                                       01910020
* APPLICABILITY- MVT AND M65MP SYSTEMS WITH TSO OPTION            21008 01920021
*                                                                       01930020
*EXTERNAL REFERENCES                                                    01940020
*                                                                       01950020
*        1. TS DRIVER VIA A BALR 14,15                                  01960020
*              REG 1= PTR TO DRIVER PARAMETER AREA                      01970020
*              REG 13= PTR TO DRIVER SAVE REGISTERS AREA-18 WORDS       01980020
*                                                                       01990020
*        2. TIMER DEQUE ROUTINE VIA A BALR 2,15                         02000020
*              REG 1= PTR TO TQE                                        02010020
*              REG 10=PTR TO TIMER PSEUDO CLOCKS                        02020020
*                                                                       02030020
*        3. TIMER ENQUE ROUTINE VIA A BALR 2,15                         02040020
*              REG 1= PTR TO TQE                                        02050020
*                                                                       02060020
*        4. POST ROUTINE VIA A BALR 14,15                               02070020
*              REG 10= POST CODE                                        02080020
*              REG 11= ECB FLAG ADDRESS                                 02090020
*              REG 12= WAITING TCB ADDRESS                              02100020
*                                                                       02110020
         EJECT                                                          02120020
*                                                                       02130020
* INPUT- TS INTERFACE                                                   02140020
*                                                                       02150020
*        REGISTERS 0 AND 1 CONTAIN INPUT PARAMETERS AS FOLLOWS          02160020
*                                                                       02170020
*              REGISTER 0     BYTE                                      02180020
*                             0-1  TJID- IF THIS HALFWORD IS ZERO, THE  02190020
*                                  TJID ASSOCIATED WITH THE CURRENTLY   02200020
*                                  DISPATCHED TASK IS PASSED TO THE     02210020
*                                  TIME SHARING DRIVER                  02220020
*                                                                       02230020
*                             2    RESERVED                             02240020
*                                                                       02250020
*                             3    ENTRY CODE- IDENTIFIES THE REASON    02260020
*                                  FOR THE ENTRY                        02270020
*                                                                       02280020
*              REGISTER 1 APPLIES ONLY TO ENTRY CODES 6,14,25,26,27,30, 02290020
*              31,32,33,40,+44 AS FOLLOWS-                              02300020
*                                                                       02310020
*              ENTRY CODE     CONTENTS OF REGISTER 1                    02320020
*                                                                       02330020
*                    6        EST. MUST COMPLETE TIME                   02340020
*                   14        SWAP SIZE                                 02350020
*                   25        ADDRESS OF ACCOUNTING INFORMATION         02360020
*                   26        TOD CHG. VALUE IN 52.08 USEC. TIMER UNITS 02370020
*                   27        REGION ID (BYTE 0&1)                      02380020
*                             SPECIFIED REGION SIZE (BYTE 2+3)          02390020
*                   30        REGION ID                                 02400020
*                   31        REGION SIZE REQUIRED                      02410020
*                   32        SIGN BIT=0-NOT LOGON IMAGE                02420020
*                   33        TJID OF FAILED USER                       02430020
*                   40        REGION ID                                 02440020
*                   44        MOVE FACTOR + MOVE FROM ADDR.             02450020
*                                                                       02460020
*        REGISTER 14 CONTAINS RETURN ADDRESS                            02470020
*                                                                       02480020
* OUTPUT- TS INTERFACE                                                  02490020
*                                                                       02500020
*        REGISTER 1 CONTAINS RETURN INFORMATION FOR THOSE ENTRY CODES   02510020
*        WHICH REQUIRE IT AS FOLLOWS-                                   02520020
*                                                                       02530020
*              ENTRY CODE     CONTENTS OF REGISTER 1                    02540020
*                   12        0=QUIESCE USER                            02562020
*                             8=DO NOT QUIESCE USER                     02564020
*                   13        8=RUN QUIESCED USER                       02570020
*                   30        ALL FF'S IF REG. SELECTED BY ECODE31 HAS  02580020
*                             BECOME UNUSABLE.                          02590020
*                   31        REGION ID OR ALL FF'S IF NO BIG           02600020
*                             ENOUGH REGIONS                            02610020
*                                                                       02620020
* EXIT- TS INTERFACE                                                    02630020
*        RESTORE REGS. 2-14, ZERO 15, RETURN TO CALLER VIA BR 14        02640020
*        REGISTER 0 WILL BE RESTORED IF TSIP WAS NOT ENTERED VIA AN SVC 02650020
*                                                                       02660020
*                                                                       02670020
* EXIT- ERROR- TS INTERFACE                                             02680020
*                                                                       02690020
*        REGISTER 15 CONTAINS 4 IF THE CALLER OF THE INTERFACE SVC DOES 02700020
*        NOT HAVE A ZERO PROTECT KEY.                                   02710020
*        REGISTER 15 CONTAINS 0 ON A NORMAL RETURN                      02720020
*                                                                       02730020
* INPUT- TS DISPATCHER-                                                 02740020
*        REGISTER 14 CONTAINS RETURN ADDRESS                            02750020
*                                                                       02760020
*        ENTRY  IKJEAI03  ONLY  AFTER TASK SWITCH-OS DISPATCHER         02770020
*        REGISTER 11 CONTAINS CURRENT NEW UPON ENTRY                    02780020
*                                                                       02790020
* OUTPUT- TS DISPATCHER-                                                02800020
*        NONE                                                           02810020
*                                                                       02820020
* EXIT- TS DISPATCHER                                                   02830020
*        RESTORE REGS. 2-14, AND RETURN TO OS DISP. VIA BR14            02840020
* EXIT- ERROR- TS DISPATCHER                                            02850020
*        NONE                                                           02860020
*                                                                       02870020
*                                                                       02880020
* TABLES AND   .CVT                                                     02890020
* CONTROL BLKS .TSCVT                                                   02900020
*              .TCB                                                     02910020
*              .TQE                                                     02920020
* REFERENCED   .RCB                                                     02930020
*              .ECB                                                     02940020
*              .TJB                                                     02950020
*              .TJBX                                                    02960020
*              .TSICB                                                   02970020
*              .DPA                                                     02980020
*              .TSSAVE                                                  02990020
*              .TSIA                                                    03000020
*              .JSCB                                                    03010020
*              .TRCB                                                    03020020
*              .TRACE (A LOCAL DSECT-BUFFER FOR TSTRACE RESIDENT CODE)  03030020
*                                                                       03032020
* NOTE-  A ZERO VALUE TJID CANNOT BE HANDLED BY THE TIME SHARING        03034020
* DRIVER IN CERTAIN CASES.  A TABLE LABLED ECODETAB IS USED TO          03036020
* CHECK THIS CONDITION PRIOR TO TSIP GOING TO THW DRIVER.  TSIP         03038020
* RETURNS TO THE CALLER, RATHER THAN GO TO THE DRIVER, IN THESE CASES.  03038420
         EJECT                                                          03040020
*                                                                       03050020
         IEAQFX 65,MCH,M65MP                                      21008 03053021
         EJECT                                                    21008 03056021
CVTSECT  DSECT                                                          03060020
         CVT   SYS=VMS                                                  03070021
         SPACE  4                                                 21008 03070421
SCVTSECT DSECT                                                    21008 03072021
         SCVT                                                     21008 03074021
         SPACE  2                                                 21008 03080021
         MPCVT                                                    21008 03082021
         SPACE 4                                                  21008 03084021
         IKJTSCVT                                                       03090020
         EJECT                                                          03100020
         IKJTCB                                                         03110020
         SPACE                                                          03120020
         IKJTQE                                                         03130020
         SPACE 2                                                        03140020
         IKJRCB                                                         03150020
         SPACE                                                          03160020
         IKJTJB                                                         03170020
         SPACE                                                          03180020
         IKJTJBX                                                        03190020
         SPACE                                                          03200020
         IKJECBS                                                        03211020
         SPACE                                                          03220020
         SPACE                                                          03230020
         IEZJSCB                                                        03240020
         EJECT                                                          03250020
         IKJDPA                                                         03260020
         SPACE                                                          03270020
         IKJSAVED                                                       03280020
         SPACE 2                                                        03290020
         IKJTSIA                                                        03300020
         SPACE                                                          03310020
         IKJTSICB                                                       03320020
         EJECT                                                          03330020
         IKJTRCB                                                        03340020
TRACE    DSECT                                                          03350020
TRCEDATA DS    CL12       NORMAL ENTRY=1ST 3 WORDS OF DPA...TYPE D OR G 03360020
TRCETYIN EQU   TRCEDATA   TYPE OF ENTRY INDICATOR-FOUR BYTS TYPE A+B+C  03370020
TRCECMNA EQU   TRCEDATA   COMMAND NAME-EIGHT BYTES          TYPE E      03380020
TRCEUSID EQU   TRCEDATA   USERID      -SEVEN BYTES          TYPE F      03390020
TRCEELCT EQU   TRCEDATA+4 NUMBER OF ENTRIES LOST-FOUR BYTES TYPE C      03400020
TRCETOFD EQU   TRCEDATA+8 TOD OF 1ST  LOST ENTRY-FOUR BYTES TYPE C      03410020
TRACEND  EQU   *                                                        03420020
         EJECT                                                          03430020
IKJEAI00 CSECT                                                          03440020
*                                                                       03450020
*              REGISTER ASSIGNMENTS                                     03460020
*                                                                       03470020
XPAR0    EQU   0         INPUT PARAMETER REGISTER                       03480020
XPAR1    EQU   1         INPUT PARAMETER REG.+ADDRESS OF JSCB+TQE       03490020
XWK1     EQU   2         WORK REGISTER                                  03500020
XCVT     EQU   3         ADDRESS OF CVT                                 03510020
XTCB     EQU   4         ADDRESS OF TCB                                 03520020
XDPA     EQU   5         ADDRESS OF DRIVER PAR. AREA                    03530020
XTCVT    EQU   6         ADDRESS OF TSCVT                               03540020
XTSIA    EQU   7         ADDRESS OF TSIA                                03550020
XRCB     EQU   8         ADDRESS OF RCB AND MISCELLANEOUS               03560020
XECB     EQU   9         ADDRESS OF ECB AND MISCELLANEOUS               03570020
XPOS1    EQU   10        POST ROUTINE INPUT REG                         03580020
XWK2     EQU   11        WORK REGISTER                                  03590020
XPOS2    EQU   11        POST ROUTINE INPUT REG                         03600020
XBASE    EQU   12        BASE REGISTER                                  03610020
XSAVE    EQU   13        ADDRESS OF SAVE AREA                           03620020
X14      EQU   14        RETURN REGISTER                                03630020
X15      EQU   15        BRANCH TO ADDRESS                              03640020
         EJECT                                                          03720020
**                                                                      03730020
*              REGISTER DSECT ASSIGNMENTS                               03740020
**                                                                      03750020
         USING CVTSECT,XCVT                                             03760020
         USING TSCVT,XTCVT                                              03770020
         USING TSIA,XTSIA                                               03780020
         USING TSECB,XECB                                               03790020
         USING DPA,XDPA                                                 03800020
         USING TSSAVE,XSAVE                                             03810020
         USING TCB,XTCB                                                 03820020
         USING RCB,XRCB                                                 03830020
*                                                                       03840020
*                  CONSTANTS AND CONSTANT EQUATES                     * 03850020
*                                                                     * 03860020
ZERO     EQU   0                        USED FOR COMPARE                03870020
ONE      EQU   1                        INSTRUCTION DISPLACEMENT ETC.   03880020
TWO      EQU   2                        GENERAL PURPOSE NUMBER          03890020
FOUR     EQU   4                        ERROR RETURN-PROT.KEY NOT 0-SVC 03900020
EIGHT    EQU   8                        SHIFT FACTOR                    03910020
TWELVE   EQU   12                       GENERAL PURPOSE NUMBER          03920020
TWENTYFO EQU   24                       INSTRUCTION DISPLACEMENT        03930020
TWENTY5  EQU   25                       GENERAL PURPOSE NUMBER          03940020
TWENTYEI EQU   28                       INSTRUCTION DISPLACEMENT        03950020
THIRTYTO EQU   32                       INSTRUCTION DISPLACEMENT        03960020
FORTY4   EQU   44                       USED TO CHECK ECODE44           03970020
RBWAITCT EQU   28                       DISPLACEMENT OF WAIT COUNT-R.B. 03980020
SVCOLD   EQU   32                       ABSOLUTE ADDR. OF SVC OLD PSW   03990020
SVCOLD4  EQU   SVCOLD+4                 SVC OLD PSW                     04000020
ZTCBDSPD EQU   TCBDSP-TCBRBP            DISPLACEMENT OF DISP. PRIORITY  04010020
ZTCBTCBD EQU   TCBTCB-TCBRBP            DISPLACEMENT OF TCBTCB IN TCB   04020020
DRVSAVRG EQU   TSICBRSV-TSICBDPA        DRIVER SAVE REG SLOT            04030020
DPAVAR3  EQU   DPAVAR+3                 DRIVER RETURN CODE              04040020
ALLFLAGS EQU   255                      USED TO CLEAR FLAGS             04050020
TIMERR   EQU   80                       ADDR. OF TIMER ENTRY      21008 04056021
MIDELM   EQU   40                       MIDNITE ELEM. EXT. IN PSEUDOCL. 04063020
TQEWORK  EQU   32                       OFFSET OF MIDNITE TOD EXP.      04066020
NEW2     EQU   IEATCBP-IEAQFX00         NEW2 TCB IN MP.           21008 04073021
IKJCPUA  EQU   C'A'                     TEST FOR CPU A IN MP      21008 04075021
         SPACE                                                          04080020
**       POST CODES                                                     04090020
RCTCODE  EQU   X'01'                    REGION CONTROL TASK POST CODE   04100020
TSCECODE EQU   X'02'                    TIME SHARING CONTROL POST CODE  04110020
         SPACE                                                          04120020
*                                                                       04130020
*                                                                       04140020
         EJECT                                                          04150020
*********************************************************************** 04160020
*                                                                       04170020
*              TYPE 1 SVC ENTRY                                         04180020
*                                                                       04190020
         BALR  X15,ZERO                 TEMPORARY ADDRESSABILITY        04200020
         USING *,X15                                                    04210020
         TM    CVTTSFLG,CVTTSRDY     Q.IS TIME SHARING ACTIVE.          04220020
         BNZ   IGCBEGIN                YES  CONTINUE                    04230020
         SR    XPAR1,XPAR1             NO CLEAR VAR. PARAM  INFO REG.   04240020
         SR    X15,X15                 CLEAR RETURN CODE REG.           04250020
         BR    X14                     RETURN TO CALLER                 04260020
*                                                                       04270020
*      Q PROTECT KEY = ZERO                                             04280020
*                                                                       04290020
* THIS ROUTINE CHECKS TO INSURE A ZERO PROTECT KEY WHEN ENTERED VIA A   04300020
* TYPE 1 SVC -  IF NOT, AN IMMEDIATE RETURN IS MADE WITH AN ERROR       04310020
* INDICATION TO THE CALLER                                              04320020
         SPACE                                                          04330020
*********************************************************************** 04340020
IGCBEGIN EQU   *                                                        04350020
*                                                                       04360020
* FIRST-CHECK FOR SPECIAL CASE OF ENTRY CODEZERO(USED FOR PERF. EVAL.   04370020
* AND DATA GATHERING). IF ENTRY CODE IS 0, SKIP ZERO PROTECT KEY TEST.  04380020
*                                                                       04390020
         L     XBASE,BASEADCO          PERMANENT BASE REGISTER          04400020
         USING IGCBEGIN,XBASE                                           04410020
         DROP  X15                                                      04420020
         CH    XPAR0,VALCHECK         Q ENTRY CODE ZERO                 04430020
         BNE   IGCOMMZ                 NO                               04431020
         SR    XPAR0,XPAR0             YES-CLEAR TJID                   04432020
         B     IGCOMMON                AND IGNORE PROT. KEY TEST        04433020
IGCOMMZ  EQU   *                                                        04434020
         LH    XWK1,SVCOLD              SVC OLD PSW                     04450020
         N     XWK1,VALCHECK          Q PROTECT KEY ZERO                04460020
         BZ    IGCOMMON                 YES                             04470020
         LA    X15,FOUR                 NO-ERROR  RETURN TO CALLER      04480020
         BR    X14                                                      04490020
         EJECT                                                          04500020
*********************************************************************** 04510020
* THIS ROUTINE IS ENTERED VIA A BRANCH                                  04520020
*                                                                       04530020
IKJEAI01 EQU   *                                                        04540020
         L     X15,CVTPTR               LOCATION OF THE CVT POINTER     04550020
         USING CVTSECT,X15                                              04560020
         TM    CVTTSFLG,CVTTSRDY     Q.IS TIME SHARING ACTIVE.          04570020
         BALR  X15,ZERO                 TEMPORARY ADDRESSABILITY        04580020
         USING *,X15                                                    04590020
*                                                                       04600020
*-NOTE- PLACE NO INSTRUCTIONS BETWEEN TM+BNZ THAT CHG. COND. CODE       04610020
*                                                                       04620020
         BNZ   IKJCONTI                 YES-CONTINUE                    04630020
         SR    XPAR1,XPAR1             NO CLEAR VAR. PARAM  INFO REG.   04640020
         SR    X15,X15                 CLEAR RETURN CODE REG.           04650020
         BR    X14                     RETURN TO CALLER                 04660020
IKJCONTI EQU   *                                                        04670020
         L     X15,CVTPTR              LOCATION OF THE CVT PTR          04680020
         USING CVTSECT,X15                                              04690020
         L     X15,CVTTSCVT             ADDRESS OF THE TSCVTABLE        04700020
         USING TSCVT,X15                                                04710020
         L     X15,TSCVTSAV             ADDRESS OF TSSAVE AREA          04720020
         USING TSSAVE,X15                                               04730020
         STM   XWK1,X14,TSIPSAVE        SAVE REGISTERS                  04740020
         BALR  X15,ZERO                TEMPORARY ADDRESSABILITY         04750020
         USING *,X15                                                    04760020
         L     XBASE,BASEADCO           RESTORE BASE REGISTER           04770020
         DROP  X15                                                      04780020
*                                                                       05150020
         BAL   X14,IGCOMMON                                             05160020
         LM    XWK1,X14,TSIPSAVE        RESTORE REGISTERS               05170020
         BR    X14                      RETURN TO CALLER                05180020
         EJECT                                                          05190020
*********************************************************************** 05200020
* THIS ROUTINE IS THE MAIN LINE OF THE INTERFACE PORTION OF TSIP        05210020
*                                                                       05220020
IGCOMMON EQU   *                                                        05230020
         BAL   XWK1,IGCLPTRG            LOAD DSECT PTR REGS             05240020
         STM   XPAR0,XPAR1,DPATJID      INPUT REGS FOR DRIVER           05380020
         L     XTCB,CVTTCBP            PTR TO NEW OLD PTR               05390020
         L     XTCB,FOUR(,XTCB)         PTR.TO OLD TCB                  05400020
         CLC   DPATJID,VALCHECK       Q TJID=0                          05410020
         BNE   IGCONTIN                                                 05420020
         C     XTCB,ZERO(XTCB)       Q.RB POINTING TO TCB               05430020
         BE    IGCONTIZ                YES-IT IS PSUEDO WAIT TCB  M6145 05440020
         TM    TCBTSFLG,TCBTSTSK     Q.TIME SHARING USER TASK           05450020
         BZ    IGCONTIZ                 NO-THEREFORE NO TJID AVAIL.     05460020
         L     XPAR1,TCBJSCB            LOCATE THE JSCB                 05470020
         USING IEZJSCB,XPAR1                                            05480020
         MVC   DPATJID,JSCBTJID         TJID FROM OLD TCB FOR DRIVER    05490020
         DROP  XPAR1                                                    05500020
IGCONTIZ EQU   *                                                        05501020
         CLC   DPATJID,VALCHECK        Q.ANY TJID FOUND                 05502020
         BNE   IGCONTIN                 YES-CONTINUE                    05503020
* NO-CHECK FOR ECODES DRIVER CANNOT HANDLE WITH TJID ZERO               05504020
         SR    XWK1,XWK1                                                05505020
         SR    XWK2,XWK2                                                05506020
         IC    XWK1,DPAENT              ENTRY CODE FOR TABLE INDEX      05507020
         IC    XWK2,ECODETAB(XWK1)      PICK UP VALUE IN TABLE          05508020
         LTR   XWK2,XWK2                ZERO IN TBLE-DRV CANNOT HDLE    05509020
         BNZ   IGCONTIN                 PROCEED                         05509120
         XC    DPAVAR,DPAVAR            CLEAR RETURN REGISTER SLOT      05509220
          B    IGCBACK                  RETURN                          05509320
         EJECT                                                          05510020
*********************************************************************** 05520020
* THIS ROUTINE WILL CALCULATE THE TIME OF DAY IN TU'S BY USING THE      05530020
* TIMER, THE LOCAL PSUEDO CLOCK, THE 6 HR PSUEDO CLOCK, AND THE 24HR    05540020
* PSUEDO CLOCK AND STORE THE RESULT IN THE THIRD WORD OF THE DRIVER     05550020
* PARAMETER AREA                                                        05560020
*                                                                       05570020
IGCONTIN EQU   *                                                        05580020
         L     XWK1,CVTTPC              ADDRESS OF PSUEDO CLOCKS        05590020
      TM    CVTOPTB,CVTTOD           Q. TIMER VALUE AT LOC. 80          05590320
         BZ    IGCONTX                  YES                             05590420
         LM    XPAR0,XPAR1,DPA          SAVE DPA DATA SO FIRST TWO      05590620
*                                       WORDS OF DPA CAN BE WORKAREA    05590820
         DC    X'B2055000'              STORE CLOCK IN WORKAREA         05591020
         L     XWK1,MIDELM(XWK1)        PTR. TO MIDNIGHT ELEM. EXT.     05591220
         L     XWK1,TQEWORK(XWK1)       EXPECTED MIDNIGHT TOD EXP.      05591420
         SL    XWK1,DPA                 TIME REMAINING IN DAY           05591620
         LM    XPOS1,XWK2,MICSECS  NUMBER OF USEC IN DAY      CC A64471 05591821
         BC    4,MAKEPOS           BR IF NEG-IND. PAST MIDNITE   A64471 05592021
         AL    XWK2,DPAVAR              ADD MICROSECOND PORTION         05592220
         BC    12,CARRY1                BRANCH IF NO CARRY              05592420
         LA    XPOS1,ONE(XPOS1)         ADD BECAUSE OF CARRY            05592620
CARRY1   EQU   *                                                        05592820
         SLR   XPOS1,XWK1               TOD IN USECS.-CLOCK FORMAT      05593020
TUCONV   EQU   *                                                        05593220
         SR    XWK1,XWK1                INDICATE VALUE LESS THAN 12HRS  05593420
         C     XPOS1,HALFDAY          Q.TOD EXCEED 12 HRS.              05593620
         BNH   LESSHALF                 NO                              05593820
         SL    XWK2,HALFDAY4            HALF DAY OF MICS                05594020
         BC    11,CARRY2                BRANCH IF RESULTS POSITIVE      05594220
         BCTR  XPOS1,ZERO               SUBTRACT ONE                    05594420
CARRY2   EQU   *                                                        05594620
         SL    XPOS1,HALFDAY            SUBTRACT HALFDAY                05594820
         L     XWK1,TUHALF              HALF DAY IN TIMER UNITS         05595020
LESSHALF EQU   *                                                        05595220
         SLDL  XPOS1,TWELVE             TOD HAS ALREADY BEEN SHIFTED    05595420
* 12 BITS DUE TO CLOCK FORMAT. SHIFT ADDITIONAL 12 BITS DUE TO DIVISOR  05595620
* HAVING 6 DIGITS TO RIGHT OF HEXIDECIMAL POINT                         05595820
         D     XPOS1,MICPERTU           TOD IN USECS. BY NO. OF USECS.  05596020
* IN ONE UNIT TO GET NUMBER OF TIMER UNITS.                             05596220
         ALR   XWK1,XWK2                ADD ANY 12 HOUR FACTOR          05596420
         STM   XPAR0,XWK1,DPA           SAVED DPA DATA PLUS TOD         05596620
         B     IGCONTY                                                  05596820
MAKEPOS  EQU   *                                                        05597020
         LPR   XPOS1,XWK1               TIME ELAPSED IN NEW DAY         05597220
         B     TUCONV                   CONVERT TO 26.04 USEC. TU'S     05597420
IGCONTX  EQU   *                                                        05597620
         L     XPAR0,ZERO(,XWK1)        CALL 24 HR TIME                 05600020
         AL    XPAR0,FOUR(,XWK1)        6 HR + 24 HR PSUEDO CLOCKS      05610020
         TM    CVTDCB,CVT4MS1+CVT4MPS   IS THIS AN MP SYSTEM      21008 05611021
         BNO   NOTMP                    NO, BRANCH                21008 05612021
         L     XWK2,PREFTMRA            PSA CONTAINING ACT TIMER. 21008 05613021
         USING IEAQFX00,XWK2                                      21008 05614021
         L     XWK2,TIMERR(XWK2)        PICK UP TIMER VALUE       21008 05615021
         DROP  XWK2                                               21008 05616021
         B     IGCONTX1                 CONTINUE CALCULATION.     21008 05618021
NOTMP    EQU   *                                                  21008 05620021
         L     XWK2,TIMERR(ZERO)        PICK UP TIMER VALUE       21008 05622021
IGCONTX1 EQU   *                                                  21008 05624021
         SRA   XWK2,ONE(ZERO)           SHIFT                           05630020
         SLR   XPAR0,XWK2               SUBTRACT TIMER VALUE            05640020
         CL    XPAR0,ZTD24HRS         Q RESULT EXCEED 24 HRS            05650020
         BL    IGCONTI1                 BRANCH IF NOT                   05660020
         AL    XPAR0,ZTDADJ             ADD MODULO ADJUSTMENT           05670020
IGCONTI1 EQU   *                                                        05680020
         AL    XPAR0,EIGHT(,XWK1)       ADD LOCAL PSUEDO CLOCK          05690020
         BO    ZTADJUST                 CHECK FOR OVERFLOW              05700020
         CL    XPAR0,ZTD24HRS           CHECK FOR OVER 24 HRS           05710020
         BL    ZTADJUS1                 NO                              05720020
ZTADJUST AL    XPAR0,ZTDADJ                                             05730020
ZTADJUS1 EQU   *                                                        05740020
         ST    XPAR0,DPATOD             TOD IN 26.04 USEC. T.U. FOR DRV 05750020
IGCONTY  EQU   *                                                        05755020
         EJECT                                                          05760020
*********************************************************************** 05770020
* THIS ROUTINE IS THE RESIDENT STATISTICS COLLECTION ROUTINE            05780020
*                                                                       05790020
         L     XWK1,TSCVTTRB            ADDR. OF TRCB CTRL. BLOCK       05800020
         LTR   XWK1,XWK1              Q. ARE THERE ANY                  05801020
         BZ    RSTACXIT                NO                               05802020
         L     XWK1,ZERO(,XWK1)        YES-PTR. TO CTRL. BLOCK          05803020
         LA    XPAR1,DPATJID            PTR. TO DRIVER PARAMETERS       05810020
         BAL   X15,TRACEIT              TRACE THIS ONE                  05820020
         CLI   DPAENT,FORTY4            ENTRY CODE = 44                 05830020
         BNE   TRCN044                  NO                              05840020
*                                       YES-SET UP CONTROL REGS         05850020
         L     XPAR1,DPAVAR                PTR. TO DATA TO BE MOVED     05860020
         IC    XPOS1,DPAVAR             QUANTIFY FACTOR TO MOVE-N       05870020
         N     XPOS1,QUANMOVE           CLEAR UNWANTED BITS             05880020
         LA    XECB,TWO                 DEVELOP TWO TO THE N+1          05890020
         SLL   XECB,ZERO(XPOS1)         QUANTITY OF 12 BYTE MOVES       05900020
TRCEC44  EQU   *                                                        05910020
         BAL   X15,TRACNEXT             MOVE TWELVE BYTES OF DATA       05920020
         LA    XPAR1,TWELVE(XPAR1)      STEP TO NEXT DATA               05930020
         BCT   XECB,TRCEC44             DATA ALL MOVED-NO-LOOP          05940020
         B     RSTACXIT                 YES-DONE                        05950020
TRCN044  EQU   *                                                        05960020
         CLI   DPAENT,ZERO              ENTRY CODE = 0                  05970020
         BE    TRCCALL                  YES-PUT OUT EXTRA RECORD        05980020
         CLI   DPAENT,TWENTY5           ENTRY CODE = 25                 05990020
         BNE   RSTACXIT                 NO-DONE                         06000020
TRCCALL  EQU   *                                                        06010020
         L     XPAR1,DPAVAR             ADDRESS OF COMMAND              06020020
         BAL   X15,TRACNEXT             MAKE SECOND ENTRY               06030020
         B     RSTACXIT                 DONE                            06040020
TRACEIT  EQU   *                                                        06050020
         LTR   XWK1,XWK1              Q.ANY TRCB                        06060020
         BZ    RSTACXIT                 NO-CONTINUE WITH TSIP           06070020
         CLI   DPAENT,ONE             Q.ECODE 1               CC A67880 06072021
         BNE   TRCTRY                   NO - CONTINUE W/TRACE CC A67880 06074021
         MVI   DPATJID+ONE,ZERO         ZERO TJID ON ECODE 1  CC A67880 06076021
         USING TRCB,XWK1                                                06080020
TRCTRY   EQU   *                                                        06090020
         L     XWK2,TRCNEXT             ADDR. OF NEXT TRACE             06100020
TRACNEXT EQU   *                                                        06110020
         C     XWK2,TRCLAST           Q.LAST ENTRY                      06120020
         BH    STATSUPR                 YES-GO TO SUPPRESS              06130020
         USING TRACE,XWK2                                               06140020
         MVC   TRCEDATA,ZERO(XPAR1)     COPY DATA TO BE TRACED          06150020
         LA    XWK2,TRACEND             PTR. TO NEXT                    06160020
         ST    XWK2,TRCNEXT             UPDATE NEXT PTR.                06170020
         BR    X15                      END OF SUBROUTINE               06180020
STATSUPR EQU   *                                                        06190020
         L     XPAR0,TRCLINK            LINK POINTER                    06200020
         LTR   XPAR0,XPAR0            Q.ANY LEFT                        06210020
         BZ    SUPRNTRY                 NO-SUPPRESS ENTRY               06220020
         LR    XWK1,XPAR0               YES-NEW TRCB DSECT PTR.         06230020
         B     TRCTRY                   RETRY                           06240020
SUPRNTRY EQU   *                                                        06250020
         SR    XPAR0,XPAR0                                              06270020
         BCTR  XPAR0,ZERO               NEGATIVE ONE IN REGISTER        06280020
         C     XPAR0,TRCETYIN         Q.SUPPRESS ALREADY DONE           06290020
         BE    STATCTR1                 YES-LOST DATA ALREADY HAPPENED  06300020
         ST    XPAR0,TRCETYIN           STORE MARKER                    06310020
         MVC   TRCETOFD(FOUR),EIGHT(XPAR1) TOD FIRST DATA LOST          06320020
         SR    XWK1,XWK1                SET COUNTER TO ZERO             06330020
         B     STATCTRO                 FINISHED FIRST TIME             06340020
STATCTR1 EQU   *                                                        06350020
         L     XWK1,TRCEELCT            GET COUNTER CONTENTS            06360020
STATCTRO EQU   *                                                        06370020
         LA    XWK1,ONE(,XWK1)          STEP CTR                        06380020
         ST    XWK1,TRCEELCT            AND STORE BACK                  06390020
         DROP  XWK1                                                     06400020
         DROP  XWK2                                                     06410020
RSTACXIT EQU   *                                                        06420020
         EJECT                                                          06421020
* TEST FOR ECODE 4-IF YES-TEST TO SEE IF USER IS IN PROCESS OF    M4298 06422020
* QUIESCE. IF YES-SET BIT SO RCT WILL NOT ISSUE ECODE 3 FOR THIS        06423020
* USER-AS DRIVER MIGHT LOSE THE READY                                   06424020
         CLI   DPAENT,FOUR               ENTRY CODE 4             M4298 06425020
         BNE   TODRIVER                  NO                       M4298 06426020
         LH    XPAR1,DPATJID             YES-GET PTR              M4298 06427020
         MH    XPAR1,TSCVTSZU            TO USER TJB              M4298 06428020
         A     XPAR1,TSCVTTJB                                     M4298 06429020
         USING TJB,XPAR1                                          M4298 06430020
         TM    TJBSTAT,TJBNJB            TJB ACTIVE               M4544 06430420
         BO    IGCBACK                                      M4544       06430820
         TM    TJBSTAT2,TJBQUIS          USER BEING QUIESCED      M4298 06431020
         BZ    TODRIVER                  NO                       M4298 06432020
         OI    TJBSTAT2,TJBUSERR         YES-SET BIT FOR RCT QUIE M4298 06433020
         DROP  XPAR1                                              M4298 06434020
TODRIVER EQU   *                                                  M4298 06435020
* THIS ROUTINE LOADS REGISTERS IN ACCORDANCE WITH THE TS DRIVERS RE-    06450020
* QUIREMENTS AND THEN GOES TO THE DRIVER                                06460020
*                                                                       06470020
         SR    XPAR1,XPAR1              INDICATE UNI-PROCESSING   21008 06472021
*                                       OR CPU A                  21008 06474021
         TM    CVTDCB,CVT4MS1+CVT4MPS   IS THIS AN MP SYSTEM      21008 06478021
         BNO   NOTMP3                   NO, SET UP FOR THE DRIVER 21008 06478421
         CLI   CPUID,IKJCPUA            YES, IS THIS CPU A        21008 06478821
         BE    NOTMP3                   YES,THE INDEX FACTOR IS 0 21008 06479221
         LA    XPAR1,EIGHT              CPU B - THE INDEX IS 8    21008 06479621
*  THE 2 WORDS IN THE DCA FOR CPU B WILL BE USED.                 21008 06482221
NOTMP3   EQU   *                                                  21008 06484821
         STC   XPAR1,DPAINDEX           SET UP THE CPU INDEX      21008 06486821
         LR    XPAR1,XDPA               PTR TO PARAMETERS               06487421
         LA    XSAVE,DRVSAVRG(XDPA)     PTR. TO DRIVER SAVE REG SLOT    06490020
         L     X15,TSCVTD02             ADDR. OF TSDRIVER               06500020
         LR    XWK1,X14                                                 06520020
         BALR  X14,X15                  TO TS DRIVER                    06530020
         LR    X14,XWK1                 SAVED RETURN REG ACROSS DRIVER  06540020
         L     XSAVE,TSCVTSAV           ADDRESS OF TS SAVE AREA         06550020
         EJECT                                                          06760020
*********************************************************************** 06770020
* THIS ROUTINE TESTS WHETHER A NEW TIME SLICE HAS BEEN REQUESTED. IF    06780020
* SO, THE TIME SHARING TQE IS DEQUEUED FROM THE TIMER QUEUE AND RE-     06790020
* ENQUEUED WITH THE NEW TIME SLICE VALUE. RETURN IS THEN MADE, VIA REG  06800020
* 14, TO THE CALLER                                                     06810020
*                                                                       06820020
IGCONTIM EQU   *                                                        06830020
         TM    TSIASTAT,TSIATMS      Q NEW TIME SLICE REQUESTED         06840020
         BO    IGCTIEDQ                 YES                             06850020
         B     IGCBACK                  PREPARE TO RETURN               06860020
IGCTIEDQ EQU   *                                                        06870020
         NI    TSIASTAT,ALLFLAGS-TSIATMS CLEAR REQUEST BIT              06880020
         L     XPAR1,TSCVTTQE          PTR. TO TQE                      06890020
         USING TQE,XPAR1                                                06900020
         TM    TQEFLGS,TQEOFF        QTIME SLICE TQE ON QUEUE           06910020
         BO    IGCTIED0                NO  DEQUE NOT REQUIRED           06920020
         L     X15,CVTQTD00       ADDR OF TIMER DEQUEUE ROUTINE         06940020
         L     XPOS1,CVTTPC            REQUIRED BY DEQUE ROUTINE        06950020
         BALR  XWK1,X15                DEQUE TS TQE                     06960020
         BAL   XWK1,IGCLPTRG      RESTORE REGS                          06970020
         L     XPAR1,TSCVTTQE          PTR. TO TQE                      06980020
         USING TQE,XPAR1                                                06990020
IGCTIED0 EQU   *                                                        07000020
         L     XWK1,TSIATOD            TIME VALUE FROM DRIVER           07010020
         ST    XWK1,TQEVAL        INTO TQE TIME VALUE FIELD             07020020
         DROP  XPAR1                                                    07030020
         L     X15,CVTQTE00       ADDR OF TIMER ENQUE ROUTINE           07040020
         BALR  XWK1,X15           ENQUE TS TQE                          07050020
         BAL   XWK1,IGCLPTRG      RESTORE REGS                          07060020
IGCBACK  EQU   *                                                        07070020
         SR    X15,X15                  NORMAL RETURN COND. NO ERROR    07080020
         LM    XPAR0,XPAR1,DPATJID      RESTORE 0,MAYBE DR. INPUT FOR 1 07090020
         BR    X14                      RETURN TO CALLER                07100020
*                                                                       07110020
         EJECT                                                          07120020
*********************************************************************** 07130020
*              TSIP-TS DISPATCHER                                       07140020
* THIS ROUTINE IS ENTERED FROM THE BEGINNING OF THE O/S DISPATCHER. IT  07150020
* TESTS THE TSIA TO DETERMINE WHETHER ANY STATUS MODIFICATIONS HAVE     07160020
* BEEN REQUESTED BY THE TS DRIVER. IF SO, THE REQUESTED FUNCTION IS     07170020
* PERFORMED. RETURN IS MADE TO THE OS DISPATCHER VIA REG 14.            07180020
*                                                                       07190020
IKJEAI02 EQU   *                                                        07200020
         L     X15,CVTPTR               LOCATION OF CVT POINTER         07210020
         USING CVTSECT,X15                                              07220020
         L     X15,CVTTSCVT             ADDRESS OF THE TSCVTABLE        07230020
         USING TSCVT,X15                                                07240020
         L     X15,TSCVTSAV             ADDRESS OF TSSAVE AREA          07250020
         USING TSSAVE,X15                                               07260020
         STM   XWK1,X14,TSDSPSAV        SAVE OS DISPATCHER REGS.        07270020
         BALR  X15,ZERO                 TEMPORARY ADDRESSABILITY        07280020
         USING *,X15                                                    07290020
         L     XBASE,BASEADCO           RESTORE BASE REGISTER           07300020
         DROP  X15                                                      07310020
         BAL   XWK1,IGCLPTRG            LOAD DSECT PTR REGS             07320020
         CLI   TSIASTAT,ZERO          Q TS SYS STATUS MODIF. REQUIRED   07330020
         BNE   IKJTSD10                YES                              07340020
IKJRETUR EQU   *                                                        07350020
         LM    XWK1,X14,TSDSPSAV        RESTORE OS DISPATCHER REGS.     07360020
         BR    X14                      RETURN TO OS DISPATCHER         07370020
IKJTSD10 EQU   *                                                        07380020
         TM    TSIASTAT,TSIAMOD      Q MODIFICATION REQ. TO REGION ST   07390020
         BZ    IKJTSD02                 NO                              07400020
         NI    TSIASTAT,ALLFLAGS-TSIAMOD CLEAR REQUEST BIT              07410020
         LH    XWK1,TSCVTCTR           NO. OF TS REGIONS                07420020
         L     XRCB,TSCVTRCB            ADDRESS OF TABLE OF RCBS        07450020
         L     XECB,TSCVTECB            ADDRESS OF LIST OF INTFACE ECBS 07460020
         LR    XPAR0,XBASE             SAVE BASE REG ACROSS POST ROUT.  07470020
         LA    XWK1,ONE(XWK1)           ADD ONE REGION                  07480020
IKJNXTRG EQU   *                                                        07490020
         BCT   XWK1,IKJTSD03            HANDLE STATUS CHANGES           07500020
         L     XTSIA,TSCVTSIA           RESTORE POINTER                 07510020
         B     IKJTSD02                 ALL REGION STATUS CHANGES DONE  07520020
IKJTSD03 EQU   *                                                        07530020
         CLI   TSIARST,ZERO           Q STATUS CHANGE FOR THIS REGION   07540020
         BE    IKJTSD07                NO  CHECK NEXT REGIOM            07550020
         L     X15,CVT0PT01             POST ROUTINE ADDRESS            07560020
         TM    TSIARST,TSIAQUI       Q QUIESCE REQUESTED                07570020
         BZ    IKJTSD05                 NO                              07580020
         NI    TSIARST,ALLFLAGS-TSIAQUI  CLEAR QUIESCE BIT              07590020
         OI    RCBFLG,RCBFQU            QUIESCE                         07600021
         LA    XPOS1,RCTCODE            RCT POST CODE                   07623421
         LA    XPOS2,RCBECB             RCT ECB FLAG                    07626721
         B     IKJTSD04                                                 07630020
IKJTSD05 EQU   *                                                        07640020
         TM    TSIARST,TSIARES       Q RESTORE REQUESTED                07650020
         BZ    IKJTSD07                 NO                              07660020
         NI    TSIARST,ALLFLAGS-TSIARES  CLEAR RESTORE BIT              07670020
         OI    RCBFLG,RCBFSI           SWAP IN                          07680020
         OI    TSCVTFLG,TSCSWPBG       SET SWAP BIT IN TSCVT            07690020
         MVC   RCBTJID,TSIATJD          CURRENT USER TJID FOR RCT       07700020
         LA    XPOS1,TSCECODE           TSCE POST CODE                  07710020
         LA    XPOS2,TSCECB            POST ADDRESS                     07720020
         L     XBASE,TSCVTTSC          POST NEEDS WAITING TCB ADDR.-12  07730020
         BALR  X14,X15                 GO TO POST                       07740020
         LR    XBASE,XPAR0             RESTORE BASE REG                 07750020
         B     IKJTSD99                                                 07760020
IKJTSD04 EQU   *                                                        07770020
         L     XBASE,RCBRCT            POST NEEDS WAITING TCB PTR IN12  07780020
         BALR  X14,X15                 GO TO POST                       07790020
         LR    XBASE,XPAR0             RESTORE REGS REQUIRED AFTER POST 07800020
IKJTSD99 EQU   *                                                        07810020
         L     XSAVE,TSCVTSAV          AFTER POST                       07820020
IKJTSD07 EQU   *                                                        07830020
         LA    XTSIA,FOUR(XTSIA)        TO ACCESS NEXT TSIA REGION SLOT 07840020
         LA    XRCB,RCBEND             STEP TO NEXT RCB                 07850020
         B     IKJNXTRG                 CONTINUE FOR NEXT REGION        07860020
IKJTSD02 EQU   *                                                        07870020
         TM    TSIASTAT,TSIABKL      Q MAKE BACKGROUND LAST             07880020
         BO    IKJNETCA                YES                              07890020
         TM    TSIASTAT,TSIAPRI      Q REGION PRIORITY CHANGE           07900020
         BZ    IKJRETUR                 NO RETURN TO OS DISP            07910020
         NI    TSIASTAT,ALLFLAGS-TSIAPRI CLEAR REGION PRIORITY BIT      07920020
         EJECT                                                          07930020
*********************************************************************** 07940020
* THE FOLLOWING CODE WILL SEARCH THE TCB READY QUEUE TO DETERMINE WHICH 07950020
* TCB'S ARE TIME SHARING AND WHICH ARE BACKGROUND PRIOR TO MANIPULATION 07960020
* OF THE QUEUE. TCB ADDRESSES WILL BE PLACED IN REGS. AS FOLLOWS:       07970020
*        XECB = LAST SYSTEM TCB                                         07980020
*        XPOS1 = FIRST TIME SHARING TCB                                 07990020
*        XPAR1 = FIRST BACKGROUND TCB (ZERO IF NO BACKGROUND TASKS)     08000020
*        XWK1  = LAST  TIME SHARING TCB                                 08010020
*        XWK2  = LAST  BACKGROUND TCB                                   08020020
*                                                                       08030020
IKJNETCA EQU   *                                                        08040020
         L     XRCB,TSCVTRCB            INITIALIZE RCB POINTER          08050020
         L     XTCB,TSCVTTSC            TCB FOR START READY Q SEARCH    08060020
IKJNETCB EQU   *                                                        08070020
         TM    TCBTSFLG,TCBTSTSK      Q TIME SHARING TASK               08080020
         BO    IKJTCBFD                 YES- FOUND                      08090020
IKJTCBS6 LR    XECB,XTCB               MAY BE LAST SYSTEM TCB           08100020
         L     XTCB,TCBTCB              STEP TO NEXT TCB                08110020
         LTR   XTCB,XTCB              Q ANY TS TASKS IN SYSTEM          08120020
         BZ    IKJRETUR                 NO-RETURN TO OS DISP.           08130020
         B     IKJNETCB                                                 08140020
IKJTCBFD EQU   *                                                        08150020
         CLC   TCBDSP(ONE),TSIAASGN    RCT ACROSS ATTACH OF LOGON HAS   08152020
         BH    IKJTCBS6                BIT SET INDICATING IT IS A TS    08154020
*                                      TASK.THEREFORE ANOTHER TEST MUST 08156020
*                                      BE MADE TO FIND THE FIRST REAL   08158020
*                                      TS TASK. FOR RCT THE REAL DP PRI 08158420
*                                      IN TCB WILL ALWAYS BE GR TH THE  08159620
*                                      ASSIGNED VALUE IN THE TSIA. FOR  08159720
*                                      ALL OTHER TS TASKS THE REAL DP   08159820
*                                      PRI IN TCB WILL BE LESS TH OR EQ 08159920
*                                     TO THE ASSIGNED VALUE IN TSIA     08163220
         SR    XPAR1,XPAR1                                              08166720
         SR    X15,X15                                                  08170020
         SR    XPAR0,XPAR0                                              08180020
         IC    XPAR0,TCBLMP             PICK UP TCB LIMIT PRIORITY      08190020
         LR    XPOS1,XTCB               FIRST TS TCB                    08200020
IKJTCBS0 EQU   *                                                        08210020
         LR    XWK1,XTCB                MAY BE LAST TS TCB              08220020
         C     X15,TCBTCB               0 MEANS LAST TASK               08230020
         BE    IKJTCBS1                                                 08240020
         L     XTCB,TCBTCB             STEP TO NEXT TCB                 08250020
         TM    TCBTSFLG,TCBTSTSK      Q NEXT TASK TS TASK               08260020
         BO    IKJTCBS0                 YES-GO AGAIN.NO-HAVE LAST       08270020
IKJTCBS1 EQU   *                                                        08280020
         L     XTCB,TSCVTTSC            TCB FOR START READY Q SEARCH    08290020
IKJTCBS3 EQU   *                                                        08300020
         IC    XPAR1,TCBDSP                                             08310020
         CR    XPAR1,XPAR0              DISP PRIO HI THAN TS LIMIT PRIO 08320020
         BH    IKJTCBS2                                                 08330020
         TM    TCBTSFLG,TCBTSTSK      Q TS TASK                         08340020
         BZ    IKJTCBS4                 NO THEREFORE BACKGROUND         08350020
IKJTCBS2 EQU   *                                                        08360020
         C     X15,TCBTCB               0 MEANS LAST TASK               08370020
         BE    IKJTCBS7                 THEREFORE NO BACKGROUND         08380020
         LR    X14,XTCB                MAY BE LAST SYSTEM TCB           08390020
         L     XTCB,TCBTCB             STEP TO NEXT TCB                 08400020
         B     IKJTCBS3                 CONTINUE SEARCH                 08410020
IKJTCBS4 EQU   *                                                        08420020
         LR    XPAR1,XTCB               FIRST BACKGROUND TCB            08430020
IKJTCBS5 EQU   *                                                        08440020
         LR    XWK2,XTCB               MAY BE LAST BACKGROUND TCB       08450020
         C     X15,TCBTCB               0 MEANS LAST BACKGROUND         08460020
         BE    IKJTCBQ0                FOUND                            08470020
         L     XTCB,TCBTCB             STEP TO NEXT TCB                 08480020
         TM    TCBTSFLG,TCBTSTSK      Q IS IT TS                        08490020
         BZ    IKJTCBS5                 NO CONTINUE SEARCH              08500020
IKJTCBQ1 EQU   *                                                        08510020
         LR    XECB,X14                CORRECT LAST SYS TASK PTR        08520020
         B     IKJTCBQ0                GO RESTRING TCB QUEUE            08530020
IKJTCBS7 EQU   *                                                        08540020
         SR    XPAR1,XPAR1              CLEAR BACKGROUND TASK PTR       08550020
*                                                                       08560020
* SEARCH COMPLETE                                                       08570020
*                                                                       08580020
         EJECT                                                          08590020
*********************************************************************** 08600020
* THE FOLLOWING CODE WILL RESTRING THE TCB READY QUEUE AS SPECIFIED BY  08610020
* THE TIME SHARING DRIVER                                               08620020
IKJTCBQ0 EQU   *                                                        08630020
         TM    TSIASTAT,TSIABKL      Q MAKE BACKGROUND LAST             08640020
         BZ    IKJTCBQ2                NO                               08650020
         LTR   XPAR1,XPAR1           Q ANY BACKGROUND                   08660020
         BZ    IKJRETUZ                NO  RETURN AFTER CLEAR BKGD FL   08670020
         LR    XTCB,XECB               LAST SYSTEM TASK                 08680020
         L     XTCB,TCBTCB             FIRST TASK AFTER SYS TASK        08690020
         TM    TCBTSFLG,TCBTSTSK      Q IS IT BACKGROUND                08700020
         BO    IKJRETUZ                 NO- NOTHING TO RESTRING         08710020
         B     IKJTCBQ3                                                 08720020
IKJTCBQ2 EQU   *                                                        08730020
         IC    X15,TSIARGN             REGION NO. OF HIGHEST PRIORITY   08740020
         LTR   X15,X15                  0 MEANS BACKGROUND HI PRIORITY  08750020
         BZ    IKJTSD08                 GO MOVE TS TASKS TO BOTTOM      08760020
IKJTCBQ3 EQU   *                                                        08770020
         LR    XTCB,XPOS1               FIRST TIME SHARING TASK         08780020
         IC    X15,TCBDSP               DISPATCHING PRIORITY            08790020
         LTR   X15,X15                Q IS IT ZERO                      08800020
         BNZ   IKJTSD12                NO-BRANCH AROUND RESTRING        08810020
         STC   XPAR0,TSIACURR          UPDATE DISP PRIORITY IN TSIA     08820020
IKJTSD11 EQU   *                                                        08830020
         STC   XPAR0,TCBDSP             PUT DISP PRIORITY IN EACH TCB   08840020
         CR    XPOS1,XWK1             Q FIRST = LAST                    08850020
         BE    IKJTSD20                 YES                             08860020
         L     XTCB,TCBTCB              STEP TO NEXT TCB                08870020
         CR    XTCB,XWK1              Q LAST TIME SHARING TASK          08880020
         BNE   IKJTSD11                 NO  CONTINUE LOOPING            08890020
         STC   XPAR0,TCBDSP             LAST TS TCB                     08900020
IKJTSD20 EQU   *                                                        08910020
         ST    XPOS1,ZTCBTCBD(,XECB)    CHAIN 1ST TS TASK TO LAST SYS   08920020
         L     X15,ZTCBTCBD(,XWK1)  SAVE TCBTCB OF LAST TS TASK  A62272 08925021
         ST    XPAR1,ZTCBTCBD(,XWK1)    CHAIN 1ST-BKGD TO LAST TS TASK  08930020
         LTR   XPAR1,XPAR1              ZERO MEANS NO BACK GROUND       08940020
         BZ    IKJTSD12                                                 08950020
         ST    X15,ZTCBTCBD(,XWK2)   CHAIN 1ST BKGD TO LAST TS   A62272 08960021
         TM    TSIASTAT,TSIABKL      Q MAKE BACKGROUND LAST             08970020
         BZ    IKJTSD12                NO                               08980020
         NI    TSIASTAT,ALLFLAGS-TSIABKL CLEAR BKGD LAST INDICATOR      08990020
         B     IKJTSD09                YES                              09000020
IKJRETUZ EQU   *                                                        09010020
         NI    TSIASTAT,ALLFLAGS-TSIABKL CLEAR BKGD LAST INDICATOR      09020020
         B     IKJRETUR                AND RETURN                       09030020
IKJTSD12 EQU   *                                                        09040020
         CLC   TSIARGN,RCBNMBR          REG. NO. HIPRIORITY=THIS RCB    09050020
         BE    IKJTSD14                 YES                             09060020
         LA    XRCB,RCBEND             STEP TO NEXT RCB                 09070020
         B     IKJTSD12                 CONTINUE SEARCH                 09080020
IKJTSD14 EQU   *                                                        09090020
         LH    X15,RCBTJID              USER TJID                       09100020
         MH    X15,TSCVTSZU             SIZE OF TJB                     09110020
         L     XRCB,TSCVTTJB            PTR. TO TJB TABLE               09120020
         AR    XRCB,X15                 ADDRESS OF THIS TJB             09130020
         USING TJB,XRCB                                                 09140020
         L     XRCB,TJBEXTNT            ADDRESS OF TJBX                 09150020
         USING TJBX,XRCB                                                09160020
         L     X15,TJBXLAST             LAST TS TCB-THIS REGION         09170020
         L     XPAR0,TJBXFST           FIRST TS TCB-THIS REGION         09180020
         DROP  XRCB                                                     09190020
         CR    XPAR0,XPOS1              THIS REG 1ST ALREADY THERE      09200020
         BE    IKJTSD09                 YES                             09210020
         LR    XTCB,XECB               TO START TCB SEARCH              09220020
IKJTSD15 EQU   *                                                        09230020
         C     XPAR0,TCBTCB             FOR TCB PRECEDING IN CHAIN      09240020
         BE    IKJTSD16                 FOUND                           09250020
         L     XTCB,TCBTCB             STEP TO NEXT TCB                 09260020
         B     IKJTSD15                 CONTINUE SEARCH                 09300020
IKJTSD16 EQU   *                                                        09310020
         L     XRCB,ZTCBTCBD(,X15)      SAVE NEXT TCB AFTER THIS REG.   09320020
         LTR   XRCB,XRCB              Q NONE                            09330020
         BZ    IKJTSD18                 YES-GO ZERO FORWARD PTR         09340020
         ST    XRCB,TCBTCB             INTO PRECEDING IN CHAIN          09350020
IKJTSD17 EQU   *                                                        09360020
         ST    XPAR0,ZTCBTCBD(,XECB)    CHAIN THIS REG.TCB TO LAST SYST 09370020
         ST    XPOS1,ZTCBTCBD(,X15)     CHAIN FIRST TSTCB TO THIS RLAST 09380020
         B     IKJTSD09                 GO HANDLE OLD+NEW TCB PTRS      09390020
IKJTSD18 EQU   *                                                        09400020
         XC    TCBTCB,TCBTCB            ZERO FORWARD PTR                09410020
         B     IKJTSD17                 FINISH RESTRINGING QUEUE        09420020
IKJTSD08 EQU   *                                                        09430020
         LTR   XPAR1,XPAR1            Q IS THERE ANY BKGD               09440020
         BZ    IKJTSD09                 NO-SKIP RESTRINGING             09450020
         STC   X15,TSIACURR            SET CURRENT DISP PRIORIYY TO 0   09460020
         LR    XTCB,XPOS1               FIRST TS TASK                   09470020
         IC    XPAR0,TCBDSP             TS DISPATCHING PRIORITY         09480020
         CR    XPAR0,X15              Q IS IT ZERO                      09490020
         BE    IKJTSD09                 YES  NO RESTRINGING REQUIRED    09500020
IKJTSD19 EQU   *                                                        09510020
         STC   X15,TCBDSP               ZERO DISPATCHING PRIORITY       09520020
         CR    XPOS1,XWK1               FIRST=LAST                      09530020
         BE    IKJTSD21                 YES                             09540020
         L     XTCB,TCBTCB              STEP TO NEXT TCB                09550020
         CR    XTCB,XWK1                LAST TS TCB                     09560020
         BNE   IKJTSD19                 NO   CONTINUE LOOPING           09570020
         STC   X15,TCBDSP               LAST TS TCB DONE                09580020
IKJTSD21 EQU   *                                                        09590020
         ST    XPAR1,ZTCBTCBD(,XECB)    CHAIN 1ST BKGD TO LAST SYS. TCB 09600020
         ST    XPOS1,ZTCBTCBD(,XWK2)    CHAIN 1ST TS TO LAST BKGD. TCB  09610020
         ST    X15,ZTCBTCBD(,XWK1)      ZERO CHAIN-LAST TS TASK         09620020
*                                                                       09630020
* RESTRINGING THE TCB READY QUEUE COMPLETE                              09640020
         EJECT                                                          09650020
**********************************************************************  09660020
* THE FOLLOWING CODE WILL ENSURE THAT THE TCB PTRS-OLD+NEW-REFLECT THE  09670020
* RESTRINGING OF THE TCB READY QUEUE, SO THAT THE CORRECT TASK WILL BE  09680020
* DISPATCHED                                                            09690020
*                                                                       09690421
* THIS IS DONE BY SUPPLYING THE TASK SWITCH ROUTINE WITH THE      M1683 09692021
* FIRST DISPATCHABLE TASK AFTER THE LAST SYSTEM TASK. IN AN MP    M1683 09694021
* SYSTEM, THE TASK SWITCH ROUTINE IS USED TWICE TO CHANGE THE     M1683 09696021
* POINTERS ON THE OTHER CPU, IF NECESSARY.                        M1683 09698021
         SPACE                                                          09700020
IKJTSD09 EQU   *                                                        09710021
         LA    XWK1,ONE                 SET LOOP COUNTER          M1683 09712021
         TM    CVTDCB,CVT4MS1+CVT4MPS   IS THIS AN MP SYSTEM.     M1683 09720021
         BNO   NOTMP2                   NO, BRANCH                M1683 09722021
         LA    XWK1,TWO                 SET LOOP COUNTER FOR MP   M1683 09724021
NOTMP2   L     XTCB,ZTCBTCBD(,XECB)     TASK AFTER SYS TASK NOW   M1683 09730021
*AT THAT POSITION ON READY Q AFTER RESTRINGING(EITHER TS OR BKGD) M1683 09740021
         B     IKJTSD43                                           M1683 09742021
IKJTSD42 L     XTCB,TCBTCB              NEXT TCB ON QUEUE.        M1683 09742421
         LTR   XTCB,XTCB                IS THIS THE END OF THE Q  M1683 09744021
         BZ    IKJRETUR                 YES, RETURN TO OS DISP.   M1683 09746021
IKJTSD43 LH    XECB,TCBFLGS4            TCB DISPATCHABILITY FLAGS M1683 09750021
         LTR   XECB,XECB                IS TASK DISPATACHABLE     M1683 09770021
         BNZ   IKJTSD42                 NO,GET ANOTHER TCB        M1683 09820021
         L     XECB,TCBRBP              GET REQUEST BLOCK PTR.    M1683 09870021
         CLI   RBWAITCT(XECB),ZERO      IS THE RB WAITING         M1683 09920021
         BNE   IKJTSD42                 YES, GET NEXT TCB ON Q.   M1683 09970021
         L     XWK2,CVTABEND            PTR TO THE MVT CVT        M1683 10020021
         USING SCVTSECT,XWK2            MVT CVT ADDRESSABILITY    M1683 10030021
         L     XWK2,SCVTTASW            ADR OF TASK SWITCH RTN.   M1683 10032021
         DROP  XWK2                                               M1683 10034021
         LR    XPOS1,XTCB               SET UP TASK SWITCH INPUT  M1683 10036021
         BALR  X14,XWK2                 TO THE TASK SWITCH ROUTINEM1683 10038021
         BCT   XWK1,IKJTSD42            WE HAVE TO GO TO THE TASK M1683 10038421
*SWITCH ROUTINE TWICE IF THIS IS AN MP SYSTEM.                    M1683 10038821
         B     IKJRETUR                 RETURN TO OS DISP.              10040020
*                                                                       10050020
* TCB PTR-NEW- ADJUSTMENT NOW COMPLETE                                  10060020
*                                                                       10070020
         EJECT                                                          10080020
*********************************************************************** 10090020
* THIS ROUTINE IS ENTERED FROM THE END OF THE OS DISPATCHER, AFTER IT   10100020
* HAS DETERMINED THE NEXT TASK TO BE DISPATCHED AND A TASK SWITCH HAS   10110020
* OCCURED. IF THE NEW TASK IS EITHER A DIFF. TS USER TASK OR NOT        10120020
* THE SAME TYPE OF TASK AS THE OLD TASK, THE TS INTERFACE ROUTINE IS    10130020
* ENTERED VIA A BRANCH. OTHERWISE, A RETURN IS MADE TO THE OS DISPATCH- 10140020
* ER VIA REG 14.                                                        10150020
*                                                                       10160020
IKJEAI03 EQU   *                                                        10170020
         L     X15,CVTPTR               CVT PTR                         10180020
         USING CVTSECT,X15                                              10190020
         L     X15,CVTTSCVT             TSCVT PTR                       10200020
         USING TSCVT,X15                                                10210020
         L     X15,TSCVTSAV             TS SAVE REGS PTR                10220020
         USING TSSAVE,X15                                               10230020
         STM   XWK1,X14,TSDSPSAV        SAVE OS DISP REGS               10240020
         BALR  X15,ZERO                 TEMPORARY ADDRESSABILITY        10250020
         USING *,15                                                     10260020
         L     XBASE,BASEADCO           FOR BASE ADDRESSABILITY         10270020
         DROP  X15                                                      10280020
         BAL   XWK1,IGCLPTRG            LOAD DSECT PTR REGS             10290020
         L     XWK1,CVTTCBP            PTR TO TCB NEW OLD               10300020
         L     XWK1,FOUR(XWK1)          TCB OLD                         10310020
* XWK2 CONTAINS CURRENT NEW UPON ENTRY FROM OS DISPATCHER               10320020
*                                                                       10330020
         CR    XWK1,XWK2              Q REDISPATCH SAME TASK            10340020
         BE    IKJTRETN                YES  RETURN TO OS DISP           10350020
         SR    XPAR1,XPAR1             CLEAR FOR TS DRIVER              10360020
         LA    X15,IKJEAI01            FOR TSEVENT-TSIP BR ENTRY        10370020
         L     XPAR0,ZERO(XWK2)         PICK UP RB                      10380020
         CR    XWK2,XPAR0              EQ. TO TCB MEANS WAIT TASK       10390020
         BNE   IKSTREBG                 NO PROCEED                      10400020
         TSEVENT   DISPWAIT,ENTRY=BRANCH                                10410020
         LM    XWK1,X14,TSDSPSAV       RESTORE OS DISP. REGS.           10420020
         BR    X14                     RETURN TO OS DISPATCHER          10430020
IKSTREBG EQU   *                                                        10440020
         LR    XTCB,XWK2               ADDRESS OF TCB TO DSECT REG      10450020
         CLC   TCBDSP,TSIAASGN            Q THIS TASK HIGHER THAN TS    10460020
         BH    IKJTREBY                YES SYSTEM TAS,                  10470020
         TM    TCBTSFLG,TCBTSTSK      Q TS TASK                         10480020
         BZ    IKJTREBZ                 NO-GO HANDLE BKGD               10490020
         L     XPAR1,TCBJSCB            LOCATE THE JSCB                 10500020
         USING IEZJSCB,XPAR1                                            10510020
         LH    XPAR0,JSCBTJID           TJID INTO REG 0                 10520020
         DROP  XPAR1                                                    10530020
         SR    XPAR1,XPAR1             CLEAR FOR TS DRIVER              10540020
         L     XTCB,ZERO(XWK1)    PICK UP RB                  AE A49262 10542021
         CR    XTCB,XWK1     Q. IS THIS WAIT TCB              AE A49262 10544021
         BE    IKSTREBH      YES. PREVIOUS TASK WAS WAIT TCB  AE A49262 10546021
         LR    XTCB,XWK1                ADDRESS OF OLD TCB              10550020
         TM    TCBTSFLG,TCBTSTSK      Q OLD A TS TASK                   10560020
         BZ    IKSTREBH                 NO                              10570020
         L     XPAR1,TCBJSCB            ACCESS JSCB                     10580020
         USING IEZJSCB,XPAR1                                            10590020
         LH    XPAR1,JSCBTJID           TJID OF OLD TCB                 10600020
         DROP  XPAR1                                                    10610020
         CR    XPAR0,XPAR1            Q NEW TJID=OLD TJID               10620020
         BE    IKJTRETN                 YES-NO NEED TO GO TO TSIP       10630020
         SR    XPAR1,XPAR1              CLEAR FOR TS DRIVER             10640020
IKSTREBH EQU   *                                                        10650020
         TSEVENT   DISPTS,ENTRY=BRANCH,TJID=(0)                         10660020
         LM    XWK1,X14,TSDSPSAV       RESTORE OS DISP. REGS.           10670020
         BR    X14                     RETURN TO OS DISPATCHER          10680020
IKJTREBY EQU   *                                                        10690020
         LR    XTCB,XWK1               ADDR OF OLD TCB TO DSECT REG     10700020
         L     XWK1,ZERO(XTCB)          RB ADDRESS                      10710020
         LA    XWK1,ZERO(XWK1)          CLEAR HI ORDER BYTE             10720020
         CR    XWK1,XTCB               = MEANS OLD TCB IS PSUEDO TCB WA 10730020
         BE    IKJTRET2                THRREFORE HAVE TASK SW           10740020
         CLC   TCBDSP,TSIAASGN        Q THIS TASK HIGHER THAN TS PRIOR. 10750020
         BH    IKJTRETN                YES YSTEM TASK NO TASK SWITCH    10760020
*                                      TYPE CHANGE AS A RESULT OF       10770020
*                                      TASK SWITCH RETURN TO OS DISP    10780020
IKJTRET2 EQU   *                                                        10790020
         TSEVENT   DISPSYS,ENTRY=BRANCH                                 10800020
         LM    XWK1,X14,TSDSPSAV       RESTORE OS DISP. REGS.           10810020
         BR    X14                     RETURN TO OS DISPATCHER          10820020
IKJTREBZ EQU   *                                                        10830020
         L     XTCB,ZERO(XWK1)    PICK UP RB                  AE A49262 10832021
         CR    XTCB,XWK1     Q. IS THIS WAIT TCB              AE A49262 10834021
         BE    IKJTREBX      YES. PREVIOUS TASK WAS WAIT TCB  AE A49262 10836021
         LR    XTCB,XWK1               ADDR OF OLD TCB DSECT REG        10840020
         CLC   TCBDSP,TSIAASGN        Q THIS TASK HIGHER THAN TS PRIOR  10850020
         BNH   IKJTREBW                NO CHECK FOR TS OR BACKGROUND    10860020
IKJTREBX EQU   *                                                        10870020
         TSEVENT   DISPBAC,ENTRY=BRANCH                                 10880020
         LM    XWK1,X14,TSDSPSAV       RESTORE OS DISP. REGS.           10890020
         BR    X14                     RETURN TO OS DISPATCHER          10900020
IKJTREBW EQU   *                                                        10910020
         TM    TCBTSFLG,TCBTSTSK      Q TS TASK                         10920020
         BO    IKJTREBX                 YES-TASK SWITCH OCCURRED        10930020
IKJTRETN EQU   *                                                        10940020
         LM    XWK1,X14,TSDSPSAV        RESTORE REGS                    10950020
         BR    X14                     RETURN TO OS DISPATCHER          10960020
         SPACE                                                          10970020
*                                                                       10980020
         EJECT                                                          10990020
* THIS ROUTINE LOADS DSECT PTR REGISTERS-                               11000020
*                                                                       11010020
IGCLPTRG EQU   *                                                        11020020
         L     XCVT,CVTPTR              CVT PTR                         11030020
         L     XTCVT,CVTTSCVT           ADDR OF TSCVT                   11040020
         L     XTSIA,TSCVTSIA           ADDRESS OF TSIA                 11050020
         L     XDPA,TSCVTICB            ADDRESS OF TSICB TABLE          11060020
         L     XSAVE,TSCVTSAV                                           11070020
         BR    XWK1                                                     11080020
         EJECT                                                          11090020
BASEADCO DC    A(IGCBEGIN)              FOR BASE ADDRESSABILITY         11150020
ZTDADJ   DC    X'3A3F0000'              MODULO ADJUSTMENT               11160020
ZTD24HRS DC    X'C5C10000'              24HR VALUE IN 26.04 USEC. TU'S  11170020
MICPERTU DC    X'1A0AAAAB' 1A.0AAAAB IS NO. OF USECS. PER TU            11171020
TUHALF   DC    X'62E08000'              NO. OF TU'S IN HALF DAY         11172020
MICSECS  DC    X'000141DD76000000'      NO. OF USECS.-1 DAY-CLOCK FORM. 11173020
HALFDAY  DC    X'0000A0EEBB000000'      NO. OF USECS.-HALF DAY-LEFT ADJ 11174020
HALFDAY4 EQU   HALFDAY+4                USED IN TOD CODE                11175020
         DS    0F                                                       11220020
QUANMOVE DC    X'FFFFFF87'              CLEAR UNWANTED BITS-ECODE44     11230020
VALCHECK DC    F'240'                   CHECK FOR 0-HI HALF-PROTECT KEY 11240020
EC1      DC    H'1'                    COMPARE FOR ENTRY CODE ONE       11250020
* THIS TABLE IS USED TO CHECK ECODES TO THE DRIVER TO LEARN IF          11290020
* IT IS A CODE THE DRIVER CAN HANDLE EVEN THOUGH THE TJID IS ZERO       11300020
ECODETAB DC   X'0001000000000000010100010000000000000000000000000000'   11310020
         DC    X'0101000000000000010000000000010000000100'              11311020
         END                                                            11320020
