         TITLE 'IKJEAM00-TSO/RECOVERY MANAGEMENT INTERFACE ROUTINE'     00020020
IKJEAM00 START                                                          00030020
*                                                                       00040020
*********************************************************************** 00050020
* THE FOLLOWING CODE IS THE TSO/RECOVERY MANAGEMENT INTERFACE           00060020
* PROGRAM AND IS A PORTION OF THE TSO PACKAGE. IT PROVIDES AN INTERFACE 00070020
* BETWEEN THE MVT RECOVERY MANAGEMENT ROUTINES AND THE TSO SUBSYSTEM.   00080020
* THIS ALLOWS TSO AND TCAM SUBSYSTEM RECOVERY TO BE ISOLATED FROM THE   00090020
* INTERNALS OF THE MVT RECOVERY MANAGEMENT ROUTINES.                    00100020
*                                                                       00110020
*                                                                       00120020
* ROUTINE NAME - TSO/RMS INTERFACE ROUTINE                              00130020
*                                                                       00140020
* THE ROUTINES CONTAINED IN THIS MODULE ARE-                            00150020
*                                                                       00160020
*        TSO/RMS INTERFACE-ENTERED BY SUBBROUTINE LINKAGE FROM          00170021
*                          THE MVT RECOVERY MANAGEMENT ROUTINES.        00180020
*                                                                       00190020
* FUNCTION-                                                             00200020
*                                                                       00210020
*        THE TSO/RMS INTERFACE ROUTINE IS ENTERED AFTER RMS HAS         00220020
*        RECOGNIZED A STORAGE FAILURE COULD BE IN THE TSO SUBSYSTEM     00230021
*        OR IN THE TCAM SUBSYSTEM THAT CANNOT BE REFRESHED.             00240021
*                                                                       00250020
*        RMS WILL HAVE SEARCHED ALL MODULES IN THE SYSTEM LOOKING FOR   00260020
*        POSSIBLE REFRESH PRIOR TO INVOKING THE TSO/RMS INTERFACE RTN.  00270020
*                                                                       00280020
*        RMS WILL DETERMINE IF THE STORAGE FAILURE RESIDES IN THE TSO   00290020
*        LSQA AREAS BY SEARCHING THE TSO/RMS RECOVERY EXTENT            00300021
*        LIST QUEUES WHICH WILL DESCRIBE THE BOUNDS OF THE LSQA.        00310021
*                                                                       00330020
*        UPON DETERMINATION THAT THE STORAGE FAILURE THAT CANNOT BE     00340020
*        REFRESHED MAY RESIDE IN THE TSO OR TCAM SUBSYSTEMS, RMS WILL   00350021
*        PLACE THE ADDRESS OF THE STORAGE FAILURE IN THE TSO/RMS        00360020
*        RECOVERY EXTENT LIST AND INDICATE WHETHER THE STORAGE          00370020
*        FAILURE WAS SOLID OR INTERMITTENT.                             00380020
*                                                                       00390020
*        THE TSO/RMS INTERFACE ROUTINE WILL TAKE THE FOLLOWING KINDS    00400020
*        OF ACTION:                                                     00410020
*                                                                       00420020
*        1.  FOR SOLID OR INTERMITTENT STORAGE FAILURES                 00430021
*            IN THE TIME SHARING CONTROL REGION, THE TSO/RMS INTER-     00440020
*            FACE ROUTINE WILL SET ALL TASKS IN THE TSO SUBSYSTEM       00450020
*            NON-DISPATCHABLE, RESET ALL INDICATORS THAT THE TSO        00460020
*            SUBSYSTEM IS READY, INFORM ALL TERMINAL USERS OF THE LOSS  00470020
*            OF THE TSO SUBSYSTEM, AND RETURN TO RMS WITH A MESSAGE     00480020
*            CODE TO INFORM THE OPERATOR OF THE LOSS OF THE TSO         00490020
*            SUBSYSTEM.                                                 00500020
*                                                                       00510020
*                                                                       00520020
*        2.  FOR SOLID STORAGE FAILURE IN THE TCAM SUBSYSTEM,           00530021
*            THE TSO/RMS INTERFACE ROUTINE WILL SET ALL TASKS IN THE    00540020
*            TCAM SUBSYSTEM NON-DISPATCHABLE, RESET ALL INDICATORS      00550020
*            THAT THE TCAM SUBSYSTEM IS READY, INFORM THE TSO           00560020
*            SUBSYSTEM TO SHUTDOWN, AND RETURN TO RMS WITH A MESSAGE    00570020
*            CODE TO INFORM THE OPERATOR OF THE LOSS OF THE TCAM        00580020
*            SUBSYSTEM.                                                 00590020
*                                                                       00600020
*        3.  FOR INTERMITTENT STORAGE FAILURES IN THE TCAM              00610021
*            SUBSYSTEM, THE TSO/RMS INTERFACE ROUTINE WILL SCHEDULE     00620020
*            THE TCAM SUBSYSTEM FOR ABEND, RESET ALL INDICATORS THAT    00630020
*            THE TCAM SUBSYSTEM IS READY,                               00640020
*             AND RETURN TO RMS WITH A MESSAGE CODE TO                  00650020
*            INFORM THE OPERATOR OF THE LOSS OF THE TCAM SUBSYSTEM.     00660020
*                                                                       00670020
*                                                                       00680020
*        4.  FOR INTERMITTENT STORAGE FAILURES IN A TSO USER REGION'S   00690020
*            DYNAMIC AREA, THE TSO/RMS INTERFACE ROUTINE WILL ABEND     00700020
*            RCT TO PURGE THIS USER FROM                                00710020
*            THE SYSTEM, WRITE A MESSAGE TO THE TERMINAL USER, AND      00720020
*            RETURN TO RMS WITH A MESSAGE CODE TO INFORM THE OPERATOR   00730020
*            OF THE LOSS OF THIS USER.                                  00740020
*                                                                       00750020
*        5.  FOR SOLID STORAGE FAILURES IN THE TSO USER REGION'S        00760020
*            DYNAMIC AREA, THE TSO/RMS INTERFACE ROUTINE WILL PURGE     00770020
*            ALL USERS FROM THIS REGION BY ABENDING THE RCT             00780020
*            AND RETURN TO RMS WITH A MESSAGE CODE TO INFORM            00820020
*            THE OPERATOR OF THE LOSS OF THIS REGION AND ALL ITS USERS  00830020
*                                                                       00840020
* ENTRY POINT-     IGFSUBA1    TSO/RMS INTERFACE ENTRY.                 00850021
*                                                                       00860020
*                                                                       00870020
* ATTRIBUTES-      DISABLED,SUPERVISOR STATE,SERIALLY REUSABLE,RESIDENT 00880020
*                  WHEN THE TIME SHARING SUBSYSTEM IS STARTED.          00890020
*                                                                       00900020
* APPLICABILITY-   MVT ITH TSO OPTION                                   00910021
*                                                                       00920020
         EJECT                                                          00930020
* EXTERNAL REFERENCES                                                   00940020
*                                                                       00950020
*        1.  POST ROUTINE VIA A BALR 14,15                              01100020
*              REG 10=POST CODE                                         01110020
*              REG 11=ECB ADDRESS                                       01120020
*              REG 12=WAITING TCB ADDRESS                               01130020
*                                                                       01140020
*        2.  ABTERM ROUTINE VIA A BALR 14,15                            01150020
*              REG0=TCB ADDRESS OF TASK TO BE TERMINATED                01160020
*              REG1=SYSTEM ERROR CODE(X'0F3') IN HIGH-ORDER 12 BITS     01170020
*                   OF LOW-ORDER 24 BITS                                01180020
*                                                                       01190020
*                                                                       01200020
* INPUT- RMS TO TSO INTERFACE                                           01210020
*  MODEL 65 MCH  (IGFASR30)                                             01220021
*                                                                       01230020
*                  REGISTER 2 MUST CONTAIN THE ADDRESS IN THE MCH       01240020
*                  COMM AREA WHERE THE TTR IS TO BE MOVED               01250020
*                                                                       01260020
*                  REGISTER 9 MUST CONTAIN THE ADDRESS OF THE           01270020
*                  SUB-SYSTEM COMMUNICATIONS AREA                       01280020
*                                                                       01290020
*                  REGISTER 13 MUST CONTAIN THE RETURN ADDRESS          01300020
*                                                                       01310020
*                  REGISTER 15 MUST CONTAIN THE ENTRY POINT ADDRESS     01320020
*                                                                       01330020
*                                                                       01340020
*   MODEL 85 AND NS MCH   (IGFMCHF6)                                    01350021
*                                                                       01360020
*                                                                       01370020
*                  REGISTERS 2 AND 3 MUST CONTAIN THE ADDRESSES FOR     01380020
*                  THE SSPATH AND SSLEVEL VALUES TO BE MOVED            01390020
*                                                                       01400020
*                  REGISTER 9 MUST CONTAIN THE ADDRESS OF               01410020
*                  THE MCH  SUB-SYSTEM COMM AREA                        01420021
*                                                                       01430020
*                  REGISTER 14 MUST CONTAIN THE RETURN ADDRESS          01440020
*                                                                       01450020
*                  REGISTER 15 MUST CONTAIN THE ENTRY POINT ADDRESS     01460020
*                                                                       01470020
* OUTPUT- TSO TO RMS INTERFACE                                          01480020
*                                                                       01490020
*        OUTPUT FROM THE TSO SUB-SYSTEM RMS ROUTINE TO THE RMS          01500021
*        ROUTINE WILL THE SETTING OF APPROPRIATE FLAGS IN THE           01510020
*        SUB-SYSTEM COMMUNICATIONS AREA                                 01520021
*        DEFINED BY THE MCHSUB DSECT.  THE FLAGS ARE AS FOLLOWS:        01530020
*                                                                       01540020
*                                                                       01570021
*             BIT 0 = MCH IS TO TAKE ACTION                             01620021
*             BIT 1 = TSC IS AFFECTED                                   01630021
*             BIT 2 = TCAM IS AFFECTED                                  01640021
*             BIT 3 = USER IS AFFECTED                                  01642021
*             BIT 4 = SUBSYTEM MODULE(IKJEAM00) IN CONTROL              01642421
*             BITS 5-7 = RESERVED                                       01644021
*                                                                       01650020
**        THE ABOVE FLAGS ARE THE SAME FOR EITHER THE AFFECTED TCB      01652021
**         OR THE CURRENT JOBSTEP TCB.                                  01654021
*                                                                       01660020
*IN ADDITION TO THE ABOVE PARAMETER THE FOLLOWING INFORMATION IS        01670020
*RETURNED TO RMS TO SPECIFY THAT A MESSAGE OR MESSAGES IS TO BE         01680020
*PUT OUT TO DESCRIBE THE FAILURE.  THIS INFORMATION IS PLACED IN        01690020
*THE MCHSSCDE FIELD OF THE SUB-SYSTEM COMMUNICATIONS AREA IN THE        01700020
*FOLLOWING FORMAT.                                                      01710020
*                                                                       01760021
*          BYTE 0                                                       01770021
*             BIT 0 = TSC NON-DISPATCH MESSAGE                          01780021
*             BIT 1 = TCAM NON-DISPATCH MESSAGE                         01790021
*             BIT 2 = TCAM ABEND MESSAGE                                01792021
*             BIT 3 = USER NON-DISPATCH MESSAGE                         01794021
*             BIT 4 = USER ABEND MESSAGE                                01796021
*             BITS 5-7= RESERVED                                        01798021
*                                                                       01800020
* EXIT-  TSO TO RMS INTERFACE                                           01810020
*        RESTORE REGS.   0,15                                           01820020
*                                                                       01830020
* EXIT-  ERROR                                                          01840020
*        NONE                                                           01850020
*                                                                       01860020
* TABLES AND CONTROL BLOCKS REFERENCED                                  01870020
*        CVT                                                            01880020
*        RCB                                                            01890020
*        RXL                                                            01900020
*        RXLQE                                                          01910020
*        SCVT                                                           01920020
*        TCB                                                            01930020
*        TSCVT                                                          01940020
*        MCHSUB                                                         01940421
***  NOTE   NOTE   ****  NOTE  NOTE   ******                     A44022 01942021
*  THIS MODULE DEPENDS UPON THE FORMAT OF THE SVC TABLE          A44022 01944021
**   ***  * * * * * * ** * * * * * * * * * * * * * * * * * **    A44022 01946021
*  THIS MODULE DOES NOT SUPPORT TCAM WITHOUT TSO IN THE SYSTEM          01948021
         EJECT                                                          01950020
         IEAQFX 65,MCH,M65MP                                      21008 01955000
*                                                                       01960020
CVTSECT  DSECT                                                          01970020
         CVT                                                            01980020
         EJECT                                                          01990020
SCVTSECT DSECT                                                          02000020
         SCVT                                                           02010020
         EJECT                                                          02020020
         IKJRXL                                                         02030020
         IKJRXLQE                                                       02040020
         IKJRCB                                                         02050020
         IKJTCB                                                         02060020
         IKJTSCVT                                                       02070020
         IKJSPQE                                                        02080020
         IKJDQE                                                         02090020
         EJECT                                                          02100020
         MCHSUB                                                         02110020
         EJECT                                                          02120020
         TAVTD                                                          02130020
         TTSID                                                          02140020
         EJECT                                                          02150020
         MPCVT                                                          02152021
         EJECT                                                          02154021
IGFSUBA1 CSECT                                                          02160020
*                                                                       02170020
*        REGISTER ASSIGNMENTS                                           02180020
*                                                                       02190020
XR0      EQU   0        REGISTER 0 INPUT                                02200020
XPAR0    EQU   0        PARAMETER REGISTER                              02210020
XPAR1    EQU   1        PARAMETER REGISTER                              02220020
XR2      EQU   2        REGISTER 2 AT ENTRY                             02230020
XR3      EQU   3        REGISTER 3 AT ENTRY                             02240020
XCVT     EQU   3        ADDRESS OF CVT                                  02260020
XTCB     EQU   4        ADDRESS OF TCB                                  02270020
XSCVT    EQU   5        ADDRESS OF SCVT                                 02280020
XRCB     EQU   6        ADDRESS OF RCB                                  02290020
XTSCVT   EQU   7        ADDRESS OF TSCVT                                02300020
XAVT     EQU   8        ADDRESS OF TCAM AVT                             02310020
XRXL     EQU   8        ADDRESS OF RECOVERY EXTENT LIST                 02320020
WKR8     EQU   8        WORK REGISTER                                   02340021
XCOMM    EQU   9        ADDRESS OF SUBSYSTEM COMM. AREA                 02350020
XPOS1    EQU   10       INPUT REGISTER TO POST WITH COMPLETION CODE     02360020
XTTSID   EQU   10       ADDRESS OF TCAM TTSID                           02370020
XRXLQ    EQU   10       ADDRESS OF RECOVERY EXTENT LIST QUEUE ELEM      02380020
XFAIL    EQU   11       ADDRESS OF STORAGE FAILURE                      02410020
XPECB    EQU   11       INPUT ECB ADDRESS TO POST                       02420020
XWK3     EQU   12       WORK REGISTER                                   02430020
XPTCB    EQU   12       INPUT TCB ADDRESS TO POST                       02450020
XSELECT  EQU   12       ADDR OF CURRENT TCB FOR TASK SELECTION ROUTINE  02460020
XR13     EQU   13       REGISTER 13 AT ENTRY                            02470020
XR14     EQU   14       REGISTER 14 AT ENTRY                            02510020
X14      EQU   14       RETURN REGISTER                                 02520020
XR15     EQU   15       REGISTER 15 INPUT                               02540020
X15      EQU   15       BRANCH TO REGISTER                              02550020
XBASE    EQU   15       BASE REGISTER                                   02560020
E4       EQU   4                                                 A44022 02562021
E0       EQU   0                                                 A44022 02564021
X40      EQU   X'40'                                             A44022 02566021
AQCTLSVC EQU   (4*102)                                           A44022 02568021
*                                                                       02570020
*                                                                       02580020
*        REGISTER DSECT ASSIGNMENTS                                     02590020
*                                                                       02600020
         USING CVTSECT,XCVT     CVT ADDRESSABILITY REGISTER             02610020
         USING SCVTSECT,XSCVT   SCVT ADDRESSABILITY REGISTER            02620020
         USING TCB,XTCB         TCB ADDRESSABILITY REGISTER             02630020
         USING RCB,XRCB         RCB ADDRESSABILITY REGISTER             02640020
         USING RXL,XRXL         RXL ADDRESSABILITY REGISTER             02650020
         USING RXLQE,XRXLQ      RXLQE ADDRESSABILITY REGISTER           02660020
         USING TSCVT,XTSCVT     TSCVT ADDRESSABILITY REGISTER           02670020
*                                                                       02680020
*                                                                       02700020
* MISCELLANEOUS CONSTANTS AND EQUATES                                   02710020
*                                                                       02720020
CODE0F3  EQU   X'F3'     ABEND ERROR CODE FOR TCAM STORAGE FAILURE      02730020
TSIPSVC  EQU   380       DISPLACEMENT OF SVC 95 IN SVC TABLE            02750020
QTIPSVC  EQU   404       DISPLACEMENT OF SVC 101 IN SVC TABLE           02760020
ZERO     EQU   0         CONSTANT                                       02770020
ONE      EQU   1         CONSTANT                                       02780020
TWO      EQU   2         CONSTANT                                       02790020
THREE    EQU   3                   CONSTANT                             02792021
FOUR     EQU   4         CONSTANT                                       02800020
SIX      EQU   6         DISP FROM CVT TO MOD NO.                       02810021
EIGHT    EQU   8         CONSTANT                                       02820020
X10      EQU   X'10'                                                    02822021
SOLID    EQU   X'40'     SOLID STORAGE FAILURE FLAG                     02830020
*                                                                       02840021
*                SUBSYSTEM  MACRO(MCHSUB) FLAGS                         02850021
*                                                                       02850421
MCHTOACT EQU   X'80'               MCH TO TAKE ACTION                   02852021
TSOFLAG  EQU   X'40'  TSC FAILURE FLAG                                  02860021
TCAMFLAG EQU   X'20'               TCAM  FAILURE FLAG                   02862021
TCAMOFF  EQU   X'DF'               ZERO TCAM INDICATOR                  02864021
USERFLAG EQU   X'10'     TSO USER REGION FAILURE FLAG                   02870021
MCHSSCON EQU   X'08'               SS IN CONTROL                        02872021
*                                                                       02874021
*         MCHSUB MESSAGE FLAGS                                          02876021
*                                                                       02878021
TSONDMGE EQU   X'80'             TSO NON DISPATCH MESSAGE               02880021
TCMNDMGE EQU   X'40'               TCAM NON-DISPATCH MESSAGE            02882021
TCMABMGE EQU   X'20'               TCAM ABEND MESSAGE                   02884021
USRNDMGE EQU   X'10'               USER NON-DISPATCH MESSAGE            02886021
USRABMGE EQU   X'08'               USER ABEND MESSAGE                   02888021
SSLEVEL  EQU   X'01'     FUNCTIONAL PATH INDICATOR                      02890020
SSPATH   EQU   X'01'     FUNCTIONAL PATH INDICATOR                      02900020
R0       EQU   0                                                 A44022 02931021
R1       EQU   1                                                 A44022 02932021
R3       EQU   3                                                 A44022 02933021
R4       EQU   4                                                 A44022 02934021
R5       EQU   5                                                 A44022 02935021
R14      EQU   14                                                A44022 02936021
R15      EQU   15                                                A44022 02937021
         EJECT                                                          02940020
*********************************************************************** 02950020
*              ENTRY FROM RECOVERY MANAGEMENT                           02960020
*********************************************************************** 02970020
         USING *,XBASE        EP = BASE = REGISTER 15                   02980021
         USING MCHSUB,XCOMM       ADDRESSABILITY FOR SUB-SYSTEM         02990020
*                                 COMMUNICATIONS AREA                   03000020
         STM   XR0,XR15,SAVE      SAVE INPUT REGISTERS                  03010020
         B     START              BRANCH AROUND TTR                     03020020
*   SPECIAL MODEL 65 INTERFACE TABLE                                    03022021
         ORG   IGFSUBA1+8                                               03030020
TTRTAB   DC    C'20'              PDAR TERMINATOR ID FOR USE BY         03040020
*                                 IEHIOSUP                              03050020
         DC    4X'0'              TTR SET IN HERE BY IEHIOSUP           03060020
         DC    2X'0'              END OF TTR TABLE                      03070020
*  END OF MODEL 65 INTERFACE TABLE                                      03072021
START    EQU   *                                                        03082021
         OI    MCHSSYS1,MCHSSCON   SS IS IN CONTROL                     03092021
         L     XCVT,CVTPTR        ADDRESS OF CVT                        03100020
         L     XSCVT,CVTABEND     ADDRESS OF SECONDARY CVT              03110020
         L     XTSCVT,CVTTSCVT    ADDRESS OF TIME SHARING CVT           03120020
         L     XRXL,SCVTRXLQ      ADDRESS OF RECOVERY EXTENT LIST       03130020
         LTR   XRXL,XRXL           IS THERE A RXLQE CHAIN               03132021
         BZ    EXIT                NO -EXIT TO NEXT MODULE              03134021
         EJECT                                                          03140020
*********************************************************************** 03150020
*              THE FOLLOWING ROUTINE SCANS THE RECOVERY EXTENT LIST     03160020
*              QUEUES LOOKING FOR THE REGION IN WHICH THE STORAGE       03170020
*              FAILURE HAS OCCURRED. I.E. THE TIME SHARING CONTROL      03180020
*              REGION, THE TCAM REGION, OR A TSO USER REGION.           03190020
*********************************************************************** 03200020
         L     XFAIL,MCHIN1        OBTAIN ADDRESS OF STORAGE FAILURE    03210020
         LA    XFAIL,ZERO(XFAIL)  CLEAR TYPE FAILURE INDICATOR          03220020
         L     XRXLQ,RXLRXLQ      OBTAIN FIRST QUEUE ELEMENT            03230020
RXLQSCAN TM    RXLQFLG1,RXLQFACV  IS THIS QUEUE ELEMENT ACTIVE?         03240020
         BZ    RXLQNEXT           NO. GET NXT RCVRY XTNT QUEUE EL.      03250020
         C     XFAIL,RXLQRGLO     IS FAILING STORAGE ADDRESS BELOW THIS 03260020
*                                 REGION'S LOWER BOUND?                 03270020
         BL    RXLQNEXT           YES. GET NXT RCVRY XTNT QUEUE EL.     03280020
         C     XFAIL,RXLQRGHI     IS FAILING STORAGE ADDRESS ABOVE THIS 03290020
*                                 REGION'S UPPER BOUND?                 03300020
         BNL   RXLQNEXT           YES. GET NXT RCVRY XTNT QUEUE EL.     03310020
         TM    RXLQFLG1,RXLQFRCT  DOES THIS RCVRY XTNT LIST QUEUE       03320020
*                                 DESCRIBE A TSO USER 'S REGION?        03330020
         BZ    NOTTSUSR           NO. BYPASS LOADING RCB ADDRESS.       03340020
         L     XRCB,RXLQCBLK      LOAD REGION CONTROL BLOCK ADDRESS.    03370020
         LA    XRCB,0(XRCB)       CLEAR HI-ORDER FLAG BYTE.             03380020
         L     XTCB,RCBRCT         GET TCB ADDRESS FOR ABTERM           03380421
         MVC   MCHSSFL1(THREE),RCBRCT+ONE  AFFECTTED RCT TCB            03382021
         OI    MCHSSYS1,USERFLAG    INDICATE USER REGION FAILURE        03392021
         LA    XR2,USERFAIL          USER HANDLER                       03394021
         B     AFFRET           PROCESS STORAGE FAILURE IN TSO USER'S   03400021
*                                 REGION.                               03410020
NOTTSUSR MVC   MCHSSFL1(THREE),RXLQCBLK+ONE   AFFECTTED TCB             03412021
         L     XTCB,RXLQCBLK       GET TCB ADDRESS                      03422021
         LA    XTCB,ZERO(XTCB)     CLEAR HI-BYTE                        03432021
         OI    MCHSSYS1,TCAMFLAG      INDICATE  TCAM FAILURE            03434021
         LA    XR2,TCAMFAIL           TCAM HANDLER                      03436021
         TM    RXLQFLG1,RXLQFTCM      THIS RXLQE = TCAM                 03438021
         BO    AFFRET           YES-PROCESS STORAGE FAILURE IN TCAM'S   03438421
*                                 REGION.                               03438821
*  ERROR WAS LOCATED WITHIN A SUB-SYSTEM REGION  BUT IF A  USER         03440021
*  OR TCAM WAS NOT INDICATED, TSC WILL BE ASSUMED THE REGION'S OWNER.   03450021
         NI    MCHSSYS1,TCAMOFF           ZERO THE TCAM BIT             03452021
         OI    MCHSSYS1,TSOFLAG        SET TSC INDICATOR                03454021
         OI    MCHSSCDE,TSONDMGE  TSO NON-DISPATCH MESSAGE INDICATOR    03456021
         LA    XR2,TSCFAIL         TSC  HANDLER                         03458021
         B     AFFRET             YES. PROCESS STORAGE FAILURE IN THE   03460021
*                                 TIME SHARING CONTROL REGION.          03470020
RXLQNEXT L     XRXLQ,RXLQRXLQ     ADDR OF NEXT RCVRY XTNT LIST QUEUE EL 03520020
         LTR   XRXLQ,XRXLQ        HAS LAST ELEMENT BEEN PROCESSED?      03530020
         BNZ   RXLQSCAN           NO. TEST REGION FOR STORAGE FAILURE.  03540020
**  AFFECTED STORAGE FAILURE WAS NOT LOCATED WITHIN A SUB-SYSTEM REGION 03590021
         B     CURRTCB             CHECK CURRENT TCB                    03592021
AFFRET   EQU   *                                                        03594021
         BALR  XFAIL,XR2           GO TO THE CORRECT HANDLER            03598021
         EJECT                                                          03598121
**  THIS ROUTINE DETERMINES IF THE CURRENT TCB IS LOCATED WITHIN        03598221
*    THE TSO OR TCAM SUBSYSTEM REGION.  THE ISOLATION OF THE FAILING    03598321
*     STORAGE ADDRESS(FINDING THE AFFECTED TCB) TO A TSO OR TCAM        03598421
*     SUBSYSTEM REGION IS NOT REQUIRED BEFORE ENTERING THIS ROUTINE.    03598821
CURRTCB  EQU   *                                                        03599421
         CLC   MCHSSFL1(THREE),MCHSSFL3  AFFECTED=CURRENT JOBSTEP       03599521
         BE    EXIT2              YES-CURRENT TCB IS HANDLED            03599621
         L     XRXL,SCVTRXLQ       RELOAD RXL BASE                      03599721
         L     XRXLQ,RXLRXLQ       GET FIRST RXLQE                      03599821
         L     XR13,MCHIN4         LOAD CURRENT TCB                     03599921
CURRSCAN EQU   *                                                        03600021
         TM    RXLQFLG1,RXLQFACV      IS RXLQE ACTIVE                   03603221
         BZ    NEXTRXLQ           NO. GET NEXT ENTRY                    03605221
         TM    RXLQFLG1,RXLQFTSC   IS THIS ENTRY TSC ?                  03605621
         BO    TSC                 YES HANDLE AS TSC ENTRY              03606021
NOTSC    EQU   *                                                        03606421
         TM    RXLQFLG1,RXLQFTCM   IS THIS ENTRY TCAM ?                 03606521
         BO    TCAM                YES  HANDLE TCAM ENTRY               03606621
NOTCAM   EQU   *                                                        03609921
         TM    RXLQFLG1,RXLQFRCT   IS THIS ENTRY RCT ?                  03611921
         BZ    NEXTRXLQ            NO  GET NEXT RXLQE                   03612321
         L     XRCB,RXLQCBLK       LOAD POINTER TO RCB                  03612721
         LA    XRCB,ZERO(XRCB)     CLEAR HI-BYTE                        03613121
         L     XTCB,RCBRCT         LOAD RCT ADDRESS                     03613221
         LA    XTCB,ZERO(XTCB)     CLEAR HI-BYTE                        03613321
         CR    XR13,XTCB           DOES CURRENT = RCT ?                 03616621
         BE    CURRUSR             HANDLE AS RCT CURRENT                03618621
         C     XR13,TCBLTC         CURRENT TCB=LOGON TCB                03618721
         BE    CURRUSR             YES                                  03618821
         L     XFAIL,TCBLTC        NO-GET DAUGHTER TCB                  03618921
         LTR   XFAIL,XFAIL         VALID ADDRESS                        03619321
         BZ    NEXTRXLQ            NO-GET NEXT RXLQE                    03619421
         USING TCB,XFAIL                                                03619821
         CLC   MCHSSFL3(THREE),TCBLTC  CURRENT JOBSTEP=2ND DAUGHTER     03622021
         BNE   NEXTRXLQ           NO- GET NEXT RXLQ ENTRY               03622521
         DROP  XFAIL                                                    03622921
CURRUSR  EQU   *                                                        03623021
*  THE CURRENT HAS BEEN ISOLATED TO THE USER REGION.                    03623521
         LA    XR2,USERFAIL        ADDRESS OF COMMON USERFAIL RTN       03624021
         OI    MCHSSYS3,USERFLAG   SET USER FLAG BIT                    03624521
         B     CURRRET             SET UP BRANCH ROUTINE                03625021
TSC      L     XTCB,RXLQCBLK       PICK UP TCB ADDRESS                  03625521
         LA    XTCB,ZERO(XTCB)     CLEAR HI-BYTE                        03626021
         CR    XR13,XTCB           DOES CURRENT = TSC                   03626521
         BNE   NOTSC               NO. CHECK TCAM                       03627021
STOPMOD  EQU   *                                                        03627521
         OI    MCHSSYS3,TSOFLAG    SET TSO INDICATION FLAG              03628021
         OI    MCHSSCDE,TSONDMGE   SET TSO NON-DIS MSG FLAG             03628521
*  THE CURRENT HAS BEEN ISOLATED TO THE TSC REGION.                     03629021
         LA    XR2,TSCFAIL         ADDRESS OF COMMON TSCFAIL RTN        03629821
         B     CURRRET             SET UP BRANCH ROUTINE                03630021
TCAM     L     XTCB,RXLQCBLK       LOAD CURRENT TCB                     03632721
         LA    XTCB,ZERO(XTCB)     ZERO HI-BYTE                         03634721
         CLC   MCHSSFL3(THREE),RXLQCBLK+ONE CURRENT JOBSTEP=TCAM TCB    03635121
         BNE   NOTCAM            NO-  GO CHECK RCT                      03635921
*  THE CURRENT HAS BEEN ISOLATED TO THE TCAM REGION                     03636021
         OI    MCHSSYS3,TCAMFLAG   SET TCAM INDICATION FLAG             03636121
         LA    XR2,TCAMFAIL        LOAD COMMON TCAMFAIL RTN             03636521
         B     CURRRET             SET UP BRANCH ROUTINE                03636621
NEXTRXLQ EQU   *                                                        03637421
         L     XRXLQ,RXLQRXLQ      LOAD NEXT RXLQ ENTRY                 03638921
         LTR   XRXLQ,XRXLQ         IS THE QUEUE EMPTY                   03639021
         BNZ   CURRSCAN            NO.  GO CHECK THIS ENTRY             03639121
         L     WKR8,TSCVTT06       LOAD STOP/MODIFY                     03641721
         CR    WKR8,XR13           COMPARE CURRENT TO STOP/MOD TASK     03643721
         BE    STOPMOD             GO TO THE TSC HANDLER                03644121
*       NO CURRENT FOUND                                                03644221
         B     EXIT                                                     03644321
         EJECT                                                          03645021
CURRRET  EQU   *                                                        03645421
         TM    MCHSSYS1,TSOFLAG    THE AFFECTED TSC                     03645821
         BZ    TCAMAFF             NO-GO TO TCAM                        03646221
         TM    MCHSSYS3,TCAMFLAG   IS CURRENT TCAM                      03646321
         BO    CURRBALR            YES-GO TO ROUTINE                    03646421
         B     EXIT2               NO- SKIP CURRENT WHICH WAS HANDLED   03646621
TCAMAFF  EQU   *                                                        03646721
         TM    MCHSSYS1,TCAMFLAG    IS AFFECTED TCAM                    03646821
         BZ    CURRBALR            NO-AFFECTED WAS USER                 03646921
         TM    MCHSSYS3,TCAMFLAG   IS CURRENT TCAM                      03647521
         BO    EXIT2               YES-SKIP CURRENT WHICH WAS HANDLED   03647921
*** AFFECTED WAS A USER REGION                                          03648321
         SPACE 5                                                        03648421
CURRBALR EQU   *                                                        03648721
**THIS ROUTINE IS ENTERED;                                              03648921
*            AFFECTED=USER REGION                                       03649321
*            AFFECTED=TSC AND CURRENT=TCAM                              03651621
*            AFFECTED=TCAM AND CURRENT=TSC/USER                         03653621
         MVC   MCHRSPSW(EIGHT),MCHINPSW       RESTORE ORIGINAL PSW      03653821
** IF THE CURRENT IS NOT HANDLED BY THIS MODULE, THE PSW REMAINS        03654221
**  CORRECT FOR MCH.                                                    03654321
         BALR  XFAIL,XR2           GO TO THE HANDLERS                   03654421
         B     EXIT2               MODULE TERMINATION                   03654621
         EJECT                                                          03654821
*********************************************************************** 03656221
*              THE FOLLOWING ROUTINE PROCESSES STORAGE FAILURES IN THE  03658521
*              TIME SHARING CONTROL REGION                              03660821
*********************************************************************** 03663121
*              THE FOLLOWING SUBROUTINE PROCESSES 1ST TIME SOLID OR     03665421
*              INTERMITTENT STORAGE FAILURES IN THE TIME SHARING CTL    03667721
*              REGION.  IT WILL SET ALL TASKS IN THE TSO SUBSYSTEM      03670020
*              NON-DISPATCHABLE, RESET ALL INDICATORS THAT THE TSO      03680020
*              SUBSYSTEM IS READY,INFORM ALL TERMINAL USERS OF THE      03690020
*              LOSS OF THE TSO SUBSYSTEM, AND RETURN TO RMS WITH A      03700020
*              MESSAGE CODE TO INFORM THE OPERATOR OF THE LOSS OF THE   03710020
*              TSO SUBSYSTEM.                                           03720020
*********************************************************************** 03730020
TSCFAIL  EQU   *                                                        03740021
         BAL   X14,TASKSTOP       SET ALL TASKS IN THE TSO SUBSYSTEM    03760020
*                                 NON-DISPATCHABLE.                     03770020
         NI    CVTTSFLG,255-CVTTSRDY  RESET TSO READY BIT IN CVT        03780020
         L     WKR8,SCVTSVCT      OBTAIN ADDR OF SVC TABLE.             03790021
         MVC   TSIPSVC(4,WKR8),TSCVTSVT RESTORE TIME-SHARING INTERFACE  03800021
*                                 PROGRAM (SVC 95) TO PRE-START STATUS  03810020
         MVC   QTIPSVC(4,WKR8),TSCVTSVQ RESTORE QTAM INTERFACE PGM      03820021
*                                 (SVC 101) TO PRE-START STATUS.        03830020
********************                                                    03840020
********************                                                    03850020
********************                                                    03860020
*                                 POST TIOC                             03870020
         L     WKR8,CVTAQAVT      GET ADDR.OF TCAM DISPATCHER           03880021
         USING IEDQAVTD,XAVT      SET UP ADDRESSABILITY FOR TCAM AVT    03890020
         L     XAVT,ZERO(WKR8)    GET ADDRESS OF TCAM AVT               03900021
         USING IEDQTSI,XTTSID     SET UP ADDRESSABILITY FOR TTSID DSECT 03910020
         L     XTTSID,AVTTSOPT    GET ADDRESS OF TTSID                  03920020
         STM   R0,R15,NEWSAV           SAVE REGS ACROSS SVC 102  A44022 03922021
         LA    R1,X40(XTTSID)          GET PARMS                 A44022 03924021
*  NOTE  NOTE   NOTE   NOTE                                      A44022 03926021
*  THIS CODE DEPENDS UPON THE FORMAT OF THE SVC TABLE            A44022 03928021
***********    *********    *********      *********      *******A44022 03930021
         L     R15,SCVTSVCT            GET ADRS OF SVCTABLE      A44022 03932021
         L     R15,AQCTLSVC(R15)       GET ADRS OF SVC 102       A44022 03934021
         L     R3,CVTPTR     ADRS OF CVT                         A44022 03936021
        L     R4,CVTTCBP    FADRS OF NEW   OLD                   A44022 03938021
         L     R4,E4(R4)     ADRS OF CURRENT TCB                 A44022 03940021
         L     R5,E0(R4)     ADRS OF CURRENT TCBS  RB            A44022 03942021
         BALR  R14,R15       GO TO SVC 102                       A44022 03944021
         USING *,R14                                             A44022 03946021
         LM    R0,R15,NEWSAV           RESTORE REGS              A44022 03948021
         DROP  R14                                               A44022 03950021
         DROP  XAVT               RELEASE AVT REGISTER                  03960020
         DROP  XTTSID             RELEASE TTSID REGISTER                03970020
         BR    XFAIL               RETURN                               04060021
         EJECT                                                          04070020
*********************************************************************** 04080020
*              THE FOLLOWING CODE PROCESSES STROAGE FAILURES IN THE     04090020
*              TCAM REGION.                                             04100020
**********************************************************************  04110020
TCAMFAIL EQU   *                                                        04160021
         TM    MCHIN1,SOLID            SOLID STORAGE FAILURE            04260021
         BO    TCMSOLID            YES,PROCESS SOLID                    04270021
         LR    XPAR0,XTCB          PASS TCAM'S TCB ADDR TO ABTERM       04272021
         BAL   XWK3,USERABND       SCHEDULE FOR ABEND                   04274021
         OI    MCHSSCDE,TCMABMGE  TCAM ABENDED MESSAGE                  04276021
         BR    XFAIL               PREPARE FOR RETURN                   04278021
TCMSOLID EQU   *                                                        04278421
         BAL   X14,TASKSTOP    SET TCAM AND ALL ITS SUBTASKS            04278821
*                                 NON-DISPATCHABLE.                     04280020
TCAMSTOP NI    CVTTCMFG,255-CVTTCRDY RESET TCAM READY BIT.              04290020
         TM    CVTTSFLG,CVTTSRDY  IS TSO SUBSYSTEM READY?               04300020
         BZ    TCAMSCND           NO. BYPASS POST OF TSC TO STOP TS     04310020
         OI    TSCVTFL1,TSCASTOP  SET INDICATOR TO TELL TSC TO STOP     04320020
         LR    WKR8,XBASE      SAVE BASE REGISTER ACROSS POST           04350021
         LR    XTCB,XFAIL          SAVE RETURN REG                      04352021
         L     XPTCB,TSCVTTSC     PASS TSC'S TCB ADDR. TO POST.         04360020
         L     XPECB,TSCVTECB     PTR TO TSC'S ECB ADDR.                04370020
         SR    XPOS1,XPOS1        CLEAR COMPLETION CODE REGISTER.       04380020
         L     X15,CVT0PT01       ADDR. OF BRANCH ENTRY TO POST.        04390020
         BALR  X14,X15            GO TO POST TSC TO STOP TIME SHARING.  04400020
         LR    XBASE,WKR8        RESTORE BASE REGISTER                  04420021
         LR    XFAIL,XTCB          RESTORE RETURN REG                   04422021
         OI    MCHSSCDE,TCMNDMGE INDICATE TO RMS TCAM NON-DISP.         04430021
TCAMSCND EQU   *                                                        04440021
         BR    XFAIL               RETURN                               04442021
*********************************************************************** 04450020
*              THE FOLLOWING CODE PROCESSES STORAGE FAILURES IN A       04460020
*              TIME-SHARING USER'S REGION.                              04470020
*********************************************************************** 04480020
USERFAIL EQU   *                                                        04490021
         LR    XPAR0,XTCB          PASS TCB ADDRESS TO ABTERM           04505020
         TM    MCHIN1,SOLID        Q IS STORAGE FAILURE SOLID ?         04512020
         BZ    USERNSLD           NO. GO PROCESS INTERMITTENT FAILURE.  04520020
         OI    RCBFLG,RCBFND   TELL RCT TO DELETE ALL                   04530021
*                                  USERS FROM THIS REGION               04540020
         BAL   XWK3,USERABND      SCHEDULE RCT ABEND                    04570020
         OI   MCHSSCDE,USRNDMGE INDICATE TO RMS USER RGN NON-DISP.      04572021
         BR    XFAIL               RETURN                               04582021
USERNSLD EQU   *                                                        04600020
         OI    RCBSWTCH,RCBRMS1U   TELL RCT TO DELETE                   04610020
*                                  CURRENT USER IN FAILING REGION       04620020
         BAL   XWK3,USERABND      SCHEDULE RCT FOR ABEND TO             04630020
*                                 DELETE CURRENT USER FROM REGION.      04640020
         OI    MCHSSCDE,USRABMGE   USER REGION ABEND MESSAGE            04690021
         BR    XFAIL               RETURN                               04700021
*********************************************************************   04710020
*              THE FOLLOWING ROUTINE PROVIDES THE INTERFACE FROM THE    04720020
*              TSO RMS INTERFACE ROUTINE TO THE ABTERM ABEND RTN.       04820020
*********************************************************************** 04830020
USERABND LA    XPAR1,CODE0F3       PASS X'0F3' COMPLETION CODE          04838020
*                                  TO ABTERM                            04846020
         SLL   XPAR1,12            POSITION CC FOR ABTERM               04854020
         LR    WKR8,XBASE           SAVE BASE ACROSS ABTERM             04862021
         L     X15,CVTBTERM        GET ADDRESS OF ABTERM                04870020
         BALR  X14,X15            GO TO THE ABTERM RTN                  04880020
         LR    X15,WKR8           RESTORE BASE REGISTER                 04890021
         L     XTCB,ZERO(XTCB)     GET RB ADDRESS                       04890421
         MVC   MCHRSPSW(EIGHT),X10(XTCB)   NEW RESUME PSW               04892021
**                              FROM THE ABTERMED RB                    04894021
         BR    XWK3               RETURN TO MAINLINE CODE               04900020
*********************************************************************** 04910020
*              THE FOLLOWING ROUTINE SETS THE ADDRESS OF THE TASK       04920020
*              PASSED IN XTCB(REGISTER 4) AND ALL OF ITS' SUBTASKS      04930020
*              NON-DISPATCHABLE.                                        04940020
*********************************************************************** 04950020
TASKSTOP OI    TCBNDSP1,TCBRSPND  SET CURRENT TASK NON-DISPATCHABLE     04960020
         OI    TCBFLGS5,TCBPNDSP  SET PRIMARY ND BIT                    04970020
         LR    XSELECT,XTCB       SET TCB REGISTER FOR SCAN             04980020
         USING TCB,XSELECT        ADDRESSABILITY REGISTER               05000020
         B     TASKSEL            SELECT SUBTASK TO SET NON-DISP.       05010020
TASKFND  OI    TCBNDSP1,TCBRSPND  SET SELECTED TASK NON-DISP.           05020020
         OI    TCBFLGS5,TCBPNDSP  SET PRIMARY ND BIT                    05030020
         B     TASKSEL            LOOK FOR ANOTHER TASK.                05040020
ALLSTOP  BR    X14                ALL TASKS HAVE BEEN SET NON-DISP.     05050020
*                                 RETURN TO CALLER.                     05060020
TASKSEL  EQU   *                  SELECT A TASK                         05061020
         DROP  XSELECT            CHANGE  TCB                           05070020
         USING TCB,WKR8          ADDRESSABILITY REGISTER                05080021
         LR    WKR8,XSELECT      SAVE TCB ADDRESS                       05090021
         L     XSELECT,TCBLTC     ADDR OF DAUGHTER TASK                 05100020
TASKSEL2 LTR   XSELECT,XSELECT    ANY DAUGHTERS?                        05110020
         BNZ   TASKFND            YES. SET TASK NON-DISPATCHABLE.       05120020
         L     XSELECT,TCBNTC     ADDR OF SISTER TASK                   05130020
         CR    WKR8,XTCB         FINISHED?                              05140021
         BE    ALLSTOP            YES. RETURN.                          05150020
         L     WKR8,TCBOTC       ADDR OF MOTHER TASK.                   05160021
         B     TASKSEL2           TEST AGAIN.                           05170020
         DROP  WKR8              RELEASE TCB REGISTER                   05180021
         EJECT                                                          05530020
*                                                                       05540020
*        STORAGE CONSTANTS                                              05550020
*                                                                       05560020
SAVE     DC    16F'0'             SAVE AREA FOR REGISTERS ON ENTRY      05570021
NEWSAV   DC    16F'0'        SAVE REGS ACROSS BRANCH ENTRY TO SVCA44022 05585021
MOD65    DC    X'0065'             MODEL 65 CONSTANT                    05635021
*********************************************************************** 05650020
*              THE FOLLOWING ROUTINE IS THE COMMON EXIT POINT FROM THE  05660020
*              TSO/RMS INTERFACE ROUTINE TO THE RMS ROUTINE.            05670020
*********************************************************************** 05680020
EXIT     EQU   *                                                        05690021
         OI    MCHSSYS3,MCHTOACT   MCH IS TO TAKE ACTION                05700021
EXIT2    EQU   *                                                        05740021
         LA    WKR8,SIX           GET DISP. FROM CVT TO MOD. NUMBER     05760021
         SR    XCVT,WKR8          GET ADDRESS OF MODEL NUMBER           05770021
         CLC   ZERO(TWO,XCVT),MOD65    ENTERED FROM MOD. 65 NUC. ?      05780021
         BE    SIXTY5             YES - TAKE BRANCH                     05790020
         LM    XR0,XR15,SAVE      RESTORE ENTRY REGISTERS               05800020
         MVI   ZERO(XR2),SSLEVEL  MOVE IN SS LEVEL INDICATOR            05810020
         MVI   ZERO(XR3),SSPATH   SET UP FUNCTIONAL PATH FOR SUCCESSOR  05820020
         BR    XR14               RETURN TO MOD. 85/370 MCH NUCLEUS     05830021
SIXTY5   L     XR2,SAVE+EIGHT     GET CONTENTS OF REG. 2 AT ENTRY       05840020
         MVC   ZERO(FOUR,XR2),TTRTAB+TWO SET IN TTR OF PDAR TERMINATOR  05850020
         LM    XR0,XR15,SAVE      RESTORE ENTRY REGISTERS               05870020
         LH    XPAR1,TTRTAB       GET TTR                               05872020
         BR    XR13               RETURN TO MOD. 65 MCH NUCLEUS         05880020
***  MAINTENANCE AREA                                                   05882021
MAINTID  DC    CL8'IKJEAM00'       CORE IDENTIFIER                      05884021
MAINT    DC    S(*)                MODULE DISPLACEMENT                  05886021
         DC    10F'0'           ADDITIONAL SPACE                        05888021
         CNOP  4,8                                                      05890020
         DC    C'ASR'             MCH MODULE PREFIX                     05900020
         DC    AL1((TTRTAB-IGFSUBA1)/EIGHT)     ADCON WHICH             05910020
*                                 RESOLVES INTO NUMBER OF DOUBLE WORDS  05920020
*                                 FROM BEGINNING TO 1ST ID IN TTR TABLE 05930020
         END                                                            05940020
