          TITLE  'REGION CONTROL TASK INITIALIZATION'                   00020020
IKJEAR00 START                                                          00030020
         SPACE 3                                                        00040020
*********************************************************************** 00050020
*                                                                     * 00060020
*STATUS -- 0                                                          * 00070020
*                                                                     * 00080020
*FUNCTION -- LOAD MODULE NAME - IKJEAR00                              * 00090020
*    ROUTINE NAME - IKJEAR00                                          * 00100020
*    R00 IS ATTACHED BY THE TSC AT START TS.  AFTER ENQUING ON AND    * 00110020
*    OBTAINING A KEY FROM THE PROTECTION KEY TABLE, IT ISSUES THE     * 00120020
*    GETPART FOR THE REGION SIZE PASSED IN THE REGION CONTROL BLOCK   * 00130020
*    (RCB).  FOLLOWING INITIALIZATION OF THE REGION'S CONTROL BLOCKS, * 00140020
*    R00 ATTACHES IKJEFLA (LOGON).  WHEN CONTROL IS RETURNED TO R00,  * 00170020
*    THE RCT DETERMINES THE NEW TCB'S DISPATCHING PRIORITIES, STORES  * 00180020
*    THEM IN THE TSIA AND XCTL'S TO IKJEAR01.                         * 00190020
*  IKJEAR00 MUST BE ATTACHED WITH THE PARAMETER SM=SUPV               * 00200020
*                                                                     * 00210020
*ENTRY POINTS -- IKJEAR00                                             * 00220020
*                                                                     * 00230020
*INPUT -- REG 1 - ADDRESS OF RCB                                      * 00240020
*         REG13 - ADDRESS OF A SAVE AREA                              * 00250020
*         REG14 - RETURN ADDRESS                                      * 00260020
*         REG15 - ENTRY POINT ADDRESS                                 * 00270020
*OUTPUT -- NONE                                                       * 00280020
*                                                                     * 00290020
*EXTERNAL REFERENCES -- ATTACHES IKJEFLA PASSING THE ADDRESS OF THE   * 00300020
*    RCB AS A PARAMETER IN REGISTER 1                                 * 00310020
*                                                                     * 00320020
*EXITS,NORMAL -- XCTL'S TO IKJEAR01 PASSING THE RCB ADDRESS IN REG 1. * 00330020
*                                                                     * 00340020
*EXITS,ERROR -- NONE                                                  * 00350020
*                                                                     * 00360020
*TABLES/WORK AREAS -- IKJEAR00 ISSUES A GETMAIN FOR A WORK AREA OF    * 00370020
*    172 BYTES.  18 WORDS ARE USED FOR A SAVE AREA AND THE REST AS    * 00371020
*    A WORK AREA FOR MESSAGE PROCESSING.  BEFORE XCTL TO IKJEAR01,    * 00372020
*    THE WORK AREA IS FREED.                                          * 00372120
*                                                                     * 00380020
*ATTRIBUTES -- REENTRANT, REFRESHABLE, READ ONLY, ENABLED, SUPERVISOR * 00390020
*    STATE                                                            * 00400020
*                                                                     * 00410020
*CHARACTER CODE DEPENDENCY - THE OPERATION OF THIS MODULE DEPENDS     * 00411020
*    UPON AN INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET    * 00412020
*    WHICH IS EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME. THE CODING * 00412120
*    HAS BEEN ARRANGED SO THAT REDEFINITION OF 'CHARACTER' CONSTANTS  * 00412220
*    BY REASSEMBLY, WILL RESULT IN A CORRECT MODULE FOR THE NEW DEFI- * 00412320
*    NITIONS.                                                         * 00412420
*                                                                     * 00413020
*NOTES -- R00 WILL RETURN TO THE TSC BEFORE ISSUING THE GETPART IF    * 00420020
*    IT IS UNABLE TO OBTAIN A PROTECTION KEY. IF A REPLY OF CANCEL    * 00430020
*    IS RECEIVED FOR MESSAGE ISSUED WHEN NOT ENOUGH MAINSTORAGE IS    * 00431020
*    AVAILABLE TO START A REGION, R00 WILL RETURN TO THE TSC.         * 00431120
*                                                                     * 00440020
*********************************************************************** 00450020
         SPACE 5                                                        00451020
ATLASECT DSECT                         DSECT FOR REENTRANT ATTACH       00460020
ATLA     ATTACH  EPLOC=STRING,SF=L                                      00470020
         CNOP  0,8                                                      00480020
LATLA    EQU   *-ATLA                                                   00490020
     SPACE  2                                                           00500020
     IEEBASEA                                                           00510020
         SPACE 2                                                        00520020
         IKJPQE                                                         00530020
         SPACE 2                                                        00540020
SCVTSECT DSECT                                                          00550020
         SCVT                                                           00560020
         SPACE 2                                                        00570020
         IKJUMSM                                                        00640020
UMSMEND  DS    0F                      END OF DSECT                     00650020
         SPACE 2                                                        00660020
         IKJRB                                                          00670020
         SPACE 4                                                        00690020
         IKJFBQE                                                        00700020
         SPACE  4                                                       00710020
         IKJSPQE                                                        00720020
         SPACE  4                                                       00730020
         IKJDQE                                                         00740020
         SPACE 4                                                        00760020
         IKJTSCVT                                                       00770020
         SPACE 4                                                        00780020
         IKJTJB                                                         00790020
         SPACE 4                                                        00800020
         IKJTJBX                                                        00810020
         SPACE 4                                                        00830020
CVTSECT  DSECT                                                          00840020
         CVT                                                            00850020
         SPACE  4                                                       00860020
         IKJTCB                                                         00870020
         SPACE  4                                                       00880020
         IKJRCB                                                         00890020
         SPACE  4                                                       00900020
         IKJTSIA                                                        00910020
         SPACE 3                                                        00920020
         IKJRXL                                                         00930020
         SPACE 4                                                        00950020
         IKJRXLQE                                                       00960020
RXLQEND  EQU   *-RXLQE                                                  00970020
         EJECT                                                          00980020
         IEZJSCB                                                        00990020
         SPACE 2                                                        00991020
         IKJECBS                                                        00992020
         EJECT                                                          01000020
*        INITIAL FORMAT FOR LSQS AND REGION                             01010020
         SPACE 2                                                        01020020
LSQSINIT DSECT                                                          01030020
LSPQE    DC    A(0)                    SPQE FOR LSQS                    01040020
LSPQEDQE DC    A(LDQE)                 ADDRESS OF DQE                   01050020
LDQE     DS    0F                      DQE FOR LSQS                     01060020
LDQEFQE  DC    A(LFQE)                 ADDR OF FQE                      01070020
LDQEDQE  DC    A(0)                    ADDR OF DQE                      01080020
LDQEBLK  DS    A                       ADDR OF LSQS AREA = START OF     01090020
*                                      REGION                           01100020
LDQELNTH DS    A                       LENGTH OF LSQS                   01110020
LDMYPQE  EQU   LDQEBLK                 DUMMY PQE FOR REGION IN LSQS     01120020
LDPQEFWD DC    A(LPQE)                 FORWARD PTR                      01130020
LDPQEBWD DC    A(LPQE)                 BACKWARD PTR                     01140020
LPQE     DS    0F                      PQE FOR REGION IN LSQS           01150020
LPQEFFBQ DC    A(LFBQE)                ADDR OF FBQE                     01160020
LPQEBFBQ DC    A(LFBQE)                ADDR OF FBQE                     01170020
LPQEFPQE DC    A(0)                    ADDR OF PQE (=0)                 01180020
LPQEBPQE DC    A(0)                    ADDR OF PQE (=0)                 01190020
LPQETCB  DS    4F                      PQETCB,PQESIZE,PQEREGN,PQEFLGS   01200020
LFQE     DC    A(0)                    FQE FOR LSQS                     01210020
LFQESIZE DC    A(0)                    SIZE OF LSQS ARER - 112          01220020
LFBQE    EQU   0                       FBQE FOR REGION-AT END OF LSQS   01230020
LFBQEFWD EQU   0                       ADDR OF PQE                      01240020
LFBQEBWD EQU   4                       ADDR OF PQE                      01250020
LFBQESIZ EQU   8                       SIZE OF FREE AREA-REGION SIZE-2K 01260020
         SPACE 3                                                        01270020
RCTWORK  DSECT                         WORK AREA DSECT                  01280020
RCTSAVE  DS    18F                     SAVE AREA FOR RCT                01290020
RCTRPLY  DS    2F                      REPLY ADDR FOR WTOR              01300020
RCTECBAD DS    1F                      ECB FOR WTOR                     01310020
RCTPART  DS    1F                      ADDR FOR BEG REGION              01320020
         DS    0D                                                       01330020
RCTPACK  DS    2F                      AREA FOR CONVERTING REGION NO.   01340020
RCTWTO   DS    19F                     WORK AREA FOR WTO MANIPULATING   01350020
REGNO    EQU   RCTWTO+61               DISP TO REG NUMBER IN WORK AREA  01360020
REGNOKEY EQU   RCTWTO+38               DISP TO REG NUMBER FOR KEY MESS  01361020
RCTWKEND EQU   *-RCTWORK               GET LENGTH WORKAREA              01370020
         EJECT                                                          01380020
*        RANDOM EQUATES                                                 01390020
         SPACE 2                                                        01400020
WORD     EQU   4                       LENGTH EQUATE                    01430020
TJBXSIZE EQU   72                      SIZE IN BYTES OF TJBX            01440020
ALLOCSZE EQU   64                      SIZE ALLOCATED LSQS              01450020
QPLSIZE  EQU   84                      INITIALIZE SIZE QPL              01460020
TURNOFF  EQU   X'7F'                   MASK TO TURN OFF HI ORDER BIT    01470020
X0F      EQU   X'0F'                   INSURE CONVERSION TO DECIMAL     01480020
RXLQACUR EQU   X'90'                   USER REGION AND RXLQE ACTIVE     01490020
ALLON    EQU   X'FF'                   MASK TO TURN ALL BITS ON         01491020
TWO55    EQU   255                 LENGTH FOR CLEAR           AJ A44987 01494021
TWO56    EQU   256               UPDATE VALUE FOR CLEAR AREA  AJ A44987 01497021
         SPACE 3                                                        01500020
*        NUMERIC EQUATES                                                01510020
         SPACE 2                                                        01520020
ZERO     EQU   0                       *                                01530020
ONE      EQU   1                       *                                01540020
TWO      EQU   2                       *                                01550020
FOUR     EQU   4                       *                                01560020
FIVE     EQU   5                        *                        A44022 01565021
SIX      EQU   6                       *                                01570020
SEVEN    EQU   7                       *                                01580020
EIGHT    EQU   8                       *                                01590020
TEN      EQU   10                      *                                01600020
ELEVEN   EQU   11                      *                                01610020
TWELVE   EQU   12                      *                                01620020
FIFTEEN  EQU   15                      *                                01630020
SEVENTY2 EQU   72                      *                                01670020
          EJECT                                                         01680020
*        REGISTER EQUATES                                               01690020
ZEROREG  EQU   0                       WORK REGISTER                    01700020
PARMREG  EQU   1                       PARAMETER REGISTER               01710020
RB       EQU   2                       WORK REGISTER                    01730020
WORK2    EQU   2                       WORK REGISTER                    01740020
WORK3    EQU   3                       WORK REGISTER                    01750020
TSCVTREG EQU   3                       TSCVT BASE REGISTER              01760020
CVTREG   EQU   3                       CVT BASE REGISTER                01770020
SCVTREG  EQU   3                       SCVT BASE REGISTER               01780020
WORK4    EQU   4                       WORK REGISTER                    01790020
WORK5    EQU   5                       WORK REGISTER                    01800020
TCBREG   EQU   6                       TCB BASE REGISTER                01810020
WORK7    EQU   7                       WORK REGISTER                    01820020
TSECBREG EQU   8                       ADDR TSC'S ECB                   01830020
WORK8    EQU   8                       WORK REGISTER                    01840020
PQEREG   EQU   8                       PQE BASE REGISTER                01850020
TJBXREG  EQU   9                       TJBX BASE REGISTER               01860020
LSQSREG  EQU   9                       BASE REGISTER FOR LSQS DSECT     01870020
BASEREG  EQU   10                      PROGRAM BASE REGISTER            01880020
RCBREG   EQU   11                      RCB BASE REGISTER                01890020
TJBREG   EQU   12                      TJB BASE REGISTER                01900020
REG12    EQU   12                      WORK REGISTER                    01910020
SAVREG   EQU   13                      SAVE AREA ADDRESS                01920020
RTNREG   EQU   14                      RETURN REGISTER                  01930020
CODEREG  EQU   15                      CODE REGISTER                    01940020
          EJECT                                                         01960020
IKJEAR00 CSECT                                                          01970020
         SPACE 3                                                        01980020
*********************************************************************** 01980120
*    SAVE REGS;  GET WORK/SAVE AREA                                   * 01981020
*********************************************************************** 01981120
         SPACE 3                                                        01982020
         STM   RTNREG,REG12,TWELVE(SAVREG)   SAVE REGS                  01990020
         LR    RCBREG,PARMREG          SAVE RCB ADDRESS                 02000020
         USING RCB,RCBREG              BASE FOR REGION CONTROL BLOCK    02010020
         BALR  BASEREG,ZEROREG         ESTABLISH ADDRESSABILITY         02020020
         USING *,BASEREG               BASE FOR PROGRAM                 02030020
         USING TCB,TCBREG              BASE FOR TCB                     02040020
         L     CVTREG,CVTPTR           GET ADDR CVT                     02050020
         USING CVTSECT,CVTREG          BASE FOR CVT                     02060020
         LA    ZEROREG,RCTWKEND        LENGTH WORK AND SAVE AREA        02070020
         GETMAIN R,LV=(0)              GET WORK AREA                    02080020
         XC    ZERO(RCTWKEND,PARMREG),ZERO(PARMREG)  CLEAR CORE         02090020
         ST    SAVREG,FOUR(PARMREG)    SAVE ADDR SYSTEM SAVE AREA       02100020
         ST    PARMREG,EIGHT(SAVREG)   SAVE ADDR RCT WORK AREA          02110020
         LR    SAVREG,PARMREG          SET SAVE AREA ADDR FOR RCT       02120020
         USING RCTWORK,SAVREG          *                                02130020
         SPACE 3                                                        02131020
*********************************************************************** 02131120
*  ENQ ON MASTER SCHEDULE RESIDENT DATA AREA TO OBTAIN PROTECTION KEY * 02132020
*  FOR REGION                                                         * 02133020
*********************************************************************** 02133120
         SPACE 3                                                        02134020
GETPROKY ENQ   MF=(E,IEFSD60A)         ENQ ON PROTECTION KEY TABLE      02150020
         USING BASE,WORK5              BASE FOR MS RESIDENT DATA AREA   02160020
         L     WORK5,CVTMSER           ADDR MS RESIDENT DATA AREA       02170020
         LA    TCBREG,FIFTEEN          NUMBER OF KEYS INITIALLY         02180020
         LA    WORK8,ONE               LOAD COUNTER                     02190020
         SLA   WORK8,ZERO(TCBREG)      SHIFT LEFT NO. SPECIFIED         02200020
         LH    PARMREG,BAPKES          MASK OF INIT PROTECT KEYS        02210020
         N     PARMREG,SD6000FF        TURN OFF ANY PROPOGATED BITS     02220020
TESTAGIN NR    WORK8,PARMREG           TEST BIT FOR KEY ALREADY ASSIGN  02240020
         BZ    FOUNDKEY                BR IF A 0 BIT FOUND (KEY AVAIL)  02250020
         SRL   WORK8,ONE               SHIFT RIGHT 1 TO TEST NEXT KEY   02260020
         BCT   TCBREG,TESTAGIN         CHECK NEXT KEY                   02270020
         DEQ   MF=(E,IEFSD60A)         DEQ FROM PROTECT KEY TABLE       02280020
         MVC   RCTWTO(KEYMSGLN),KEYMSG MOVE MESSAGE TO WORK AREA        02281020
         SR    WORK2,WORK2             INIT REG                         02290020
         IC    WORK2,RCBNMBR           GET THIS REGION'S NUMBER         02300020
         LA    WORK4,RCTPACK           ADDR WORK AREA FOR CVD           02310020
         CVD   WORK2,ZERO(WORK4)       CONVERT REGION NUMBER TO DEC     02320020
         OI    SEVEN(WORK4),X0F        INSURE REGION NO. IN DECIMAL     02330020
         UNPK  REGNOKEY(TWO),RCTPACK+FOUR MOVE NUMBER TO MSG            02340020
         SR    ZEROREG,ZEROREG         INIT REG                         02341020
         IC    ZEROREG,RCBCONID        GET CONSOLE ID FOR WTOR          02342020
         LA    PARMREG,RCTWTO          SET UP FOR EXECUTE FORM WTO      02350020
         WTO   MF=(E,(1))              WRITE MSG                        02360020
CANCLTS1 EQU   *                                                 A44022 02361021
         L     CVTREG,CVTPTR           ADDR OF CVT               A44022 02362021
         L     TCBREG,CVTTCBP          ACCESS PTR FOR TCB        A44022 02363021
         L     TCBREG,FOUR(TCBREG)     CURRENT TCB=OWN           A44022 02364021
         XC    TCBLTC(FOUR),TCBLTC     CLEAR DAUGHTER TASK       A44022 02365021
*                                      BEFORE EXIT SINCE ATTACHED LOGON 02366021
*                                      TASK RC=UNSUCCESSFUL.            02367021
         L     TSCVTREG,CVTTSCVT       PTR TO TS CVT                    02368021
         USING TSCVT,TSCVTREG          ESTABLISH ADDRESSABILITY         02369021
CANCELTS LR    PARMREG,SAVREG          SET UP TO FREE SAVE AREA         02370020
         L     SAVREG,FOUR(PARMREG)    RELOAD SAVREG                    02380020
         LA    ZEROREG,RCTWKEND        LENGTH WORK AREA                 02390020
         FREEMAIN R,LV=(0),A=(1)       FREE AREA                        02400020
         NI    RCBFLG2,ALLON-RCBSTR2   RESET START FLAG IF ON           02401020
CANCLTS2 XC    RCBRSIZE(FOUR),RCBRSIZE CLEAR REGION SIZE AND LSQS SIZE  02403020
*                                      TO INDICATE NOT ACTIVE           02403420
         L     WORK2,TSCVTECB          PTR TO TSC ECBS                  02404020
         USING TSECB,WORK2             BASE FOR ECB TABLE               02405020
         POST  TSCECB                  POST ECB TSC WAITING ON          02406020
         LM    RTNREG,REG12,TWELVE(SAVREG)  RESTORE REGS                02410020
         BR    RTNREG                  RETURN TO CALLER                 02420020
         DROP  TSCVTREG                DROP BASE FOR TSCVT              02421020
         USING CVTSECT,CVTREG          BASE FOR CVT                     02422020
FOUNDKEY EQU   *                       *                                02430020
*                                      SET UP TO SHIFT TO CORRECT       02440020
         LA    WORK8,ONE               POSITION OF KEY JUST ASSIGNED    02450020
         SLA   WORK8,ZERO(TCBREG)      SHIFT LEFT NO. SPECIFIED         02460020
         OR    PARMREG,WORK8           SET KEY BIT TO USED              02470020
         STH   PARMREG,BAPKES          STORE NEW KEY STATUS MASK        02480020
*                                      ZERO BOTTOM 4 BITS OF LOW ORDER  02490020
         SLL   TCBREG,FOUR             BYTE WITH KEY IN UPPER 4 BITS    02500020
         STC   TCBREG,RCBPKEY          SAVE PROTECT KEY IN RCB          02510020
DEQRTN   DEQ   MF=(E,IEFSD60A)         DEQ FROM PROTECT KEY TABLE       02520020
CONTINUE L     WORK5,CVTTCBP           PT TO NEW                        02530020
         L     TSCVTREG,CVTTSCVT       PT TO TSCVT                      02540020
         DROP  CVTREG                  DROP CVT BASE                    02550020
         USING TSCVT,TSCVTREG          BASE FOR TSCVT                   02560020
         L     TCBREG,FOUR(WORK5)      FETCH OUR TCB FROM OLD           02570020
GETPART  L     WORK4,TCBPQE            SAVE PQE PTR FOR RCT             02580020
         XC    TCBPQE(WORD),TCBPQE     ZERO PQE PTR BEFORE GETPART      02590020
         L     WORK5,TCBMSS            SAVE TCBMSS PTR OVER GETPART     02600020
         XC    TCBMSS(WORD),TCBMSS     ZERO PTR BEFORE GETPART          02610020
         ST    TCBREG,TCBJSTCB         GET JSTCB POINTED RIGHT          02620020
         SPACE 5                                                        02630020
*********************************************************************** 02631020
*        GET THE REGION OF SIZE REQUESTED.                            * 02640020
*                                                                     * 02641020
* REGION SIZE IS PASSED TO THE RCT IN A HALFWORD IN THE RCB CALLED    * 02650020
* RCBRSIZE.  ANOTHER HALFWORD CONTAINS THE LSQS SIZE.  THESE TWO      * 02660020
* FIELDS ARE USED TO COMPUTE THE SIZE OF THE ENTIRE REGION.           * 02660120
*********************************************************************** 02661020
         SPACE 3                                                        02680020
         LA    WORK7,RCTPART           WORD TO HOLD PARTITION ADDR      02681020
*                                      GET REGION SIZE SPEC IN 2K       02690020
         LH    ZEROREG,RCBRSIZE        SIZE REGION IN 2 K BLOCKS        02700020
*                                      ADD LSQS SIZE TO GET TOTAL SIZE  02710020
         AH    ZEROREG,RCBLSQSZ        OF REGION NEEDED                 02720020
         SLL   ZEROREG,ELEVEN          CONVERT TO BYTES                 02730020
         LA    PARMREG,TWELVE(SAVREG)  SET UP LIST ADDRESS              02740020
         GETMAIN EC,LV=(0),A=(WORK7),SP=247,MF=(E,(1))  GET REGION      02750020
         LTR   CODEREG,CODEREG         ENOUGH MAINSTORAGE AVAILABLE?    02760020
         BZ    GOTPART                 YES, CONTINUE PROCESSING         02770020
         ST    WORK4,TCBPQE            RESTORE PQE POINTER AND          02770120
         ST    WORK5,TCBMSS            MSS POINTER FOR WTOR PROCESSING  02770220
         MVC   TCBJSTCB(WORD),TSCVTTSC MOVE IN JOBSTEP PTR AGAIN        02770320
         SR    ZEROREG,ZEROREG         INIT REG                         02771020
         IC    ZEROREG,RCBCONID        GET CONSOLE ID FOR MSG           02772020
         MVC   RCTWTO(PARTMSLN),PARTMSG  MOVE MESSAGE TO WORK AREA      02772120
         SR    WORK2,WORK2             INIT REGISTER                    02772220
         IC    WORK2,RCBNMBR           GET REGION NUMBER                02772320
         LA    WORK7,RCTPACK           ADDR WORK AREA FOR CVD           02772420
         CVD   WORK2,ZERO(WORK7)       CONVERT REGION NUMBER FOR MSG    02772520
         OI    SEVEN(WORK7),X0F        INSURE READABLE                  02772620
         UNPK  REGNO(TWO),RCTPACK+FOUR MOVE INTO MESSAGE                02772720
         LA    PARMREG,RCTWTO          ADDR MESSAGE ABOUT REGION        02773020
         WTO   MF=(E,(1))              TELL OPERATOR CORE NOT AVAILABLE 02773120
GETPART2 EQU   *                                                 A44022 02776121
         LA    WORK8,RCTRPLY           LOAD REPLY ADDRESS               02780020
        MVC    ZERO(SIX,WORK8),BLANKS   BLANK OUT REPLY BUFFER   A44022 02783021
         XC    EIGHT(FOUR,WORK8),EIGHT(WORK8) RESET ECB          A44022 02786021
         SR    ZEROREG,ZEROREG         INIT REG                         02791020
         IC    ZEROREG,RCBCONID        GET CONSOLE ID FOR MESSAGE       02792020
         LA    PARMREG,REPLYMSG        SET UP FOR WTOR                  02800020
         WTOR  ,RCTRPLY,SIX,RCTECBAD,MF=(E,(1))                  A44022 02810021
         WAIT  1,ECB=RCTECBAD          WAIT FOR REPLY                   02820020
         OC    ZERO(SIX,WORK8),BLANKS  CHANGE TO UPPER CASE      A44022 02830021
         CLC   RCTRPLY(SIX),CANCEL     OPERATOR WANT TO CANCEL TS?      02840020
         BE    CANCELTS                YES, RETURN TO CALLER            02850020
         CLC   RCTRPLY(SIX),RETRY      OPERATOR WANTS TO RETRY?  A44022 02855021
         BNE   GETPART2                IF INVALID REPLY TRY AGAINA44022 02860021
         B     GETPART                  TRY TO GET PARTITION AGAIN      02865021
         SPACE 3                                                        02870020
*     BUILD GETMAIN ELEMENTS FOR LSQS SUPPORT AND INIT RXLQE            02880020
         SPACE 2                                                        02890020
GOTPART  L     PQEREG,TCBPQE           ADDR PQE THIS REGION             02900020
         USING PQESECT,PQEREG          BASE FOR PQE                     02910020
         L     PQEREG,PQEFPQE          ADDR FIRST PQE                   02920020
         L     WORK7,PQESIZE GET REGION SIZE IN BYTES            A44022 02921021
         SRL   WORK7,ELEVEN  CONVERT REGION SIZE TO #2K BLOCKS   A44022 02922021
         SR    WORK3,WORK3   SET PROTECT KEY REGISTER TO KEY ZEROA44022 02923021
         L     LSQSREG,PQEREGN         GET START OF REGION ADDRESA44022 02924021
         AH    LSQSREG,ONEK  GET ADDRESS OF CENTER OF BLOCK      A44022 02925021
SETKEYZ  SSK   WORK3,LSQSREG SET STORAGE KEY OF 2K BLOCK TO ZERO A44022 02926021
         AH    LSQSREG,TWOK  BUMP TO CENTER OF NEXT 2K BLOCK     A44022 02927021
         BCT   WORK7,SETKEYZ BRANCH UNTIL ALL 2K BLOCKS OF REGIONA44022 02928021
         L     LSQSREG,PQEREGN         ADDR START OF REGION (@ LSQS)    02930020
         USING LSQSINIT,LSQSREG        BASE FOR LSQS                    02940020
         L     CVTREG,CVTPTR           GET ADDR CVT                     02950020
         USING CVTSECT,CVTREG          BASE FOR CVT                     02960020
         L     CVTREG,CVTABEND         ADDR SECONDARY CVT               02970020
         USING SCVTSECT,CVTREG         BASE FOR SCVT                    02980020
         L     PARMREG,SCVTRXLQ        PTR TO RECOVERY BLOCKS           02990020
         LTR   PARMREG,PARMREG         ARE THERE ANY                    03000020
         BZ    REGBUILD                NO, CONTINUE                     03010020
         USING RXL,PARMREG             BASE FOR RXL                     03020020
         L     PARMREG,RXLRXLQ         PTR FIRST REGION RXLQE           03030020
         USING RXLQE,PARMREG           BASE FOR RXLQE                   03040020
         LA    WORK3,ONE               DISP IN RXLQE'S TO USER RXLQE'S  03050020
         SR    WORK7,WORK7             INIT REG                         03060020
         IC    WORK7,RCBNMBR           REGION NUMBER                    03070020
         AR    WORK7,WORK3             GET DISP FOR THIS USER REGION    03080020
         LA    WORK3,RXLQEND           LENGTH OF RXLQE                  03090020
         SR    WORK2,WORK2             INIT LEFT HALF REGISTER PAIR     03091020
         MR    WORK2,WORK7             MULTIPLY DISP BY LENGTH          03100020
         AR    PARMREG,WORK3           ADDR RXLQE THIS REGION           03110020
         ST    RCBREG,RXLQFLG1         INIT RXLQE                       03120020
         OI    RXLQFLG1,RXLQACUR       SET REGION BIT & ACTIVE FLAG     03130020
         ST    LSQSREG,RXLQRGLO        STORE START OF REGION IN BLOCK   03140020
         LH    WORK7,RCBLSQSZ          SIZE OF LSQS IN 2K BLOCKS        03141020
         SLL   WORK7,ELEVEN            CONVERT TO BYTES                 03142020
         AR    WORK7,LSQSREG           ADDR END OF LSQS                 03143020
         ST    WORK7,RXLQLSHI          SAVE ADDR IN RXLQE               03144020
         A     LSQSREG,PQESIZE         GET ADDR END OF REGION           03150020
         ST    LSQSREG,RXLQRGHI        END OF USER'S REGION             03160020
         S     LSQSREG,PQESIZE         RESET LSQSREG                    03170020
REGBUILD XC    LSPQE(SEVENTY2),LSPQE   CLEAR SPACE FOR GETMAIN ELEMENT  03180020
         SPACE 2                                                        03190020
*        BUILD LSQS SPQE                                                03200020
         SPACE                                                          03210020
         LA    WORK7,LDQE              GET ADDR OF DQE TO               03220020
         ST    WORK7,LSPQEDQE          STORE IN SPQE                    03230020
         SPACE 2                                                        03240020
*         BUILD LSQS DQE                                                03250020
         SPACE                                                          03260020
         LA    WORK7,LFQE              GET ADDR OF FQE TO               03270020
         ST    WORK7,LDQEFQE           STORE IN DQE                     03280020
*                                      STORE REGION ADDR WHICH ALSO     03290020
         ST    LSQSREG,LDQEBLK         EQUALS START OF LSQS             03300020
         LH    RB,RCBLSQSZ             GET LSQS SIZE FROM RCB           03310020
         SLL   RB,ELEVEN               CONVERT TO BYTES                 03320020
         ST    RB,LDQELNTH             PLACE LSQS SIZE IN DQE           03330020
         SPACE 2                                                        03340020
*        BUILD LSQS FQE                                                 03350020
         SPACE                                                          03360020
*                                      UNALLOCATED LSQS EQUAL TO LSQS   03370020
         LA    WORK7,ALLOCSZE          SIZE MINUS 64                    03380020
         LCR   WORK7,WORK7             COMPLEMENT TO ADD                03390020
         AR    WORK7,RB                GET SIZE FREE AREA               03400020
         ST    WORK7,LFQESIZE          STORE SIZE IN FQE                03410020
         SPACE 2                                                        03420020
*        BUILD DUMMY PQE AND FBQE FOR REGION                            03430020
         SPACE                                                          03440020
         LA    WORK7,LPQE              PQE ADDR                         03450020
         ST    WORK7,LDPQEFWD          STORE IN DUMMY PQE FORWARD       03460020
         ST    WORK7,LDPQEBWD          AND BACKWARD POINTERS            03470020
*                                      GET ADDR FBQE - REGION ADDR      03480020
         LA    RB,ZERO(RB,LSQSREG)     PLUS LSQS SIZE                   03490020
         ST    WORK7,LFBQEFWD(RB)      STORE PQE IN FBQE FWD PTR        03500020
         ST    WORK7,LFBQEBWD(RB)      AND BACK PTR                     03510020
         LH    WORK7,RCBRSIZE          GET REGION SIZE                  03520020
         SLL   WORK7,ELEVEN            CONVERT TO BYTES                 03530020
         ST    WORK7,LFBQESIZ(RB)      STORE SIZE IN FBQE               03540020
         SPACE 2                                                        03550020
*        BUILD PQE FOR REGION                                           03560020
         SPACE                                                          03570020
*                                      STORE FBQE IN PQE'S PTR TO 1ST   03580020
         ST    RB,LPQEFFBQ             FBQE & IN PQE'S PTR TO LAST      03590020
         ST    RB,LPQEBFBQ             FBQE                             03600020
*                                      MOVE REMAINDER OF PQE FROM PQE   03610020
         MVC   LPQETCB(FIFTEEN),PQETCB CREATED BY GETPART               03620020
         L     WORK7,TCBMSS            GET ADDR SPQE BUILT BY GETPART   03630020
         L     RB,FOUR(WORK7)          ADDR DQE                         03640020
         LA    WORK7,ZERO(WORK7)       CLEAR SPQE FLGS FROM REG         03650020
         LA    RB,ZERO(RB)             CLEAR SUBPOOL ID FROM REG        03660020
         FREEMAIN R,LV=8,SP=255,A=(WORK7)    FREE SPQE                  03670020
         FREEMAIN R,LV=16,SP=255,A=(RB)      FREE DQE                   03680020
         L     WORK7,TCBPQE            GET DUMMY PQE FROM TCB           03690020
*                                      SAVE PQE ADDR IN RCB FOR         03700020
         ST    WORK7,RCBPQE            FREEPART                         03710020
         XC    TCBMSS(WORD),TCBMSS     ZERO FIELD                       03720020
         LA    WORK7,LDMYPQE           GET ADDR DUMMY PQE               03730020
         ST    WORK7,TCBPQE            PT TCBPQE FIELD TO DUMMY PQE     03740020
         SPACE  6                                                       03760020
*        LOGON INTERFACE TO CREATE LOGON IMAGE                          03770020
         SPACE 2                                                        03780020
READY2GO MVI   RCBECB,ZERO             CLEAR POST INDICATION            03790020
         SPACE 2                                                        03820020
         OI    TCBTSFLG,TCBTSTSK       MAKE RCT TCB LOOK LIKE TS TASK   03830020
         LH    WORK2,RCBRSIZE          SIZE REGION IN 2K BLOCKS         03840020
         AH    WORK2,RCBLSQSZ          ADD SIZE LSQS IN 2K BLOCKS       03850020
         LA    ZEROREG,TJBXSIZE        SIZE TJBX INTO REG               03860020
         AR    WORK2,ZEROREG           SIZE TJBX PLUS KEY SAVE AREA     03870020
         GETMAIN R,LV=(WORK2),SP=255   GET CORE FOR TJBX AND KEY SA     03880020
         LR    CODEREG,PARMREG     AREA TO BE CLEARED         AJ A44987 03883021
         LA    RTNREG,TWO55        LENGTH OF 255 FOR EX       AJ A44987 03886021
CLEARMRE BCTR  WORK2,ZERO          DEC LEN BY ONE FOR EX      AJ A44987 03889021
         CR    WORK2,RTNREG        LARGER THAN 255            AJ A44987 03892021
         BNH   CLEARIT             NO-GO CLEAR FOR LEN        AJ A44987 03895021
         EX    RTNREG,CLEARCRE     YES-CLEAR FOR 256          AJ A44987 03898021
         SR    WORK2,RTNREG        DEC LEN BY 255             AJ A44987 03901021
         LA    CODEREG,TWO56(CODEREG)  UPDT AREA TO CLEAR     AJ A44987 03904021
         B     CLEARMRE            CONTINUE CORE CLEAR        AJ A44987 03907021
CLEARIT EX     WORK2,CLEARCRE      CLEAR FOR LEN IN WORK2     AJ A44987 03910021
         ST    PARMREG,RCBEXTNT    SAVE GETMAIN ADR FOR TSC   AJ A44987 03913021
         L     CVTREG,CVTPTR           GET CVT ADDRESS                  03920020
         USING CVTSECT,CVTREG          BASE FOR CVT                     03930020
         L     TSCVTREG,CVTTSCVT       ADDR TSCVT                       03940020
         USING TSCVT,TSCVTREG          BASE FOR TSCVT                   03950020
         L     TJBREG,TSCVTTJB         ADDRESS DUMMY TJB                03960020
         USING TJB,TJBREG              BASE FOR TJB                     03970020
         ST    PARMREG,TJBEXTNT        SAVE PTR TO TJBX IN TJB ALSO     03980020
         LR    TJBXREG,PARMREG         SET UP TJBX REG                  03990020
         USING TJBX,TJBXREG            ESTABLISH BASE REG FOR TJBX      04000020
         LA    WORK2,TJBXSIZE          SIZE TJBX                        04010020
         AR    PARMREG,WORK2           GET ADDR KEY SAVE AREA           04020020
         ST    PARMREG,TJBXKEYA        SAVE ADDRESS IN TJBX             04030020
         GETMAIN  R,LV=QPLSIZE,SP=255  GET QPL                          04040020
         XC    ZERO(QPLSIZE,PARMREG),ZERO(PARMREG)  CLEAR GOTTEN CORE   04050020
         LA    ZEROREG,TEN             INITIAL NUMBER ENTRIES IN QPL    04060020
         STH   ZEROREG,TJBXNQPE        SAVE IN TJBX                     04070020
         LA    ZEROREG,QPLSIZE         INITIAL SIZE QPL                 04080020
         STH   ZEROREG,TJBXLQPL        SAVE IN TJBX                     04090020
         ST    PARMREG,TJBXQPL         SAVE IN TJBX                     04100020
         LA    ZEROREG,TJBXLECB        GET ADDRESS LOGON ECB            04110020
         ST    ZEROREG,TJBXAECB        SAVE ADDR ECB FOR LOGON/LOGOFF   04120020
         GETJSCB  SYSTEM=MVT           GET JSCB FOR LOGON TASK          04130020
         LA    ZEROREG,LATLA           SIZE OF ATTACH LIST              04140020
         O     ZEROREG,SP245           GET CORE FROM SQS                04150020
         LR    REG12,PARMREG           SAVE PTR TO NEW JSCB             04160020
         GETMAIN R,LV=(0)              FOR ATTACH LIST                  04170020
         SPACE                                                          04180020
         LR    WORK7,PARMREG           SAVE ADDR OF GOTTEN CORE         04190020
         LR    CODEREG,PARMREG         FOR L FORM ATTACH                04200020
         USING ATLASECT,CODEREG        BASE FOR ATTACH LIST             04210020
         MVC   ATLA(LATLA),ATLAA       MOVE LIST INTO GOTTEN CORE       04220020
         L     WORK8,TCBJSCB           ADDR RCT JSCB                    04230020
         USING  IEZJSCB,WORK8          BASE FOR JSCB                    04240020
         MVC   JSCBDISP(JSCBMVTL,REG12),JSCBSEC1  INITIALIZE LOGON JSCB 04250020
         LR    PARMREG,RCBREG          PASS ADDR RCB TO LOGON           04260020
         SPACE                                                          04270020
*        ATTACH LOGON TASK                                              04271020
         SPACE                                                          04272020
     ATTACH  SF=(E,(15)),JSTCB=YES,ECB=RCBECB,                         X04280020
               JSCB=(REG12),TSLOGON=YES,SVAREA=NO                       04290020
         LR    PARMREG,WORK7           ADDR CORE TO FREE                04300020
         LA    ZEROREG,LATLA           LENGTH TO FREE                   04310020
         O     ZEROREG,SP245           MOVE IN SUBPOOL NUMBER           04320020
         FREEMAIN  R,LV=(0),A=(1)      FREE THE CORE                    04330020
         L     TCBREG,RCBRCT           RCT'S TCB ADDRESS         A44022 04331021
         NI    TCBTSFLG,TURNOFF        REMOVE FLAG MAKING RCT TCBA44022 04332021
*                                      LOOK LIKE TSC TASK               04333021
         ST    WORK4,TCBPQE            RESTORE PQE PTR AND       A44022 04334021
         ST    WORK5,TCBMSS            RESTORE MSS PTR           A44022 04335021
*                                      REMOVE ANY TRACES OF LSQS.       04336021
         XC    TCBAQE(WORD),TCBAQE     CLEAR AQE POINTER.        A44022 04337021
         MVC   TCBJSTCB(WORD),TSCVTTSC  MOVE TSC TCB PTR TO JS   A44022 04338021
*                                      FIELD OF RCT TCB.                04339021
         LA    WORK7,RCBECB            ECB RCT WAITS ON                 04340020
         N     WORK7,POSTMASK          TURN OFF ANY HI ORDER BITS       04350020
         WAIT  ECB=(WORK7)             WAIT FOR LOGON INIT TO COMPLETE  04360020
         DROP TSCVTREG                 DROP BASE SO CAN USE ANOTHER REG 04380020
         L     CVTREG,CVTPTR           GET ADDR CVT                     04390020
         USING CVTSECT,CVTREG          BASE FOR CVT                     04400020
         L     WORK8,RCBECB            GET ECB FIELD RCT WAITS ON       04402020
*                                      LOGON WILL RETURN A CODE EQ 0    04402420
*                                      IF IT WAS ABLE TO INITIALIZE     04402820
         SLL   WORK8,TWO               GET RID OF POST BITS             04404020
         XC    RCBECB,RCBECB           CLEAR FOR NEXT PASS              04406020
         LTR   WORK8,WORK8             TEST RETURN CODE FROM LOGON      04408020
         BNZ   CANCLTS1                NOT ZERO -REGION CANNOT START    04408420
         L     WORK8,CVTTSCVT          ADDR TSCVT                       04410020
         USING TSCVT,WORK8             BASE FOR TSCVT                   04420020
         L     WORK2,TSCVTSIA          ADDR TSIA                        04430020
         USING TSIA,WORK2              BASE FOR TSIA                    04440020
         L     TCBREG,TJBXFST          GET FIRST USER TCB(LOGON)        04442020
         SPACE 5                                                        04442421
*********************************************************************** 04442821
*****         APAR 44022- THE FOLLOWING PROSE APPLIES            A44022 04443221
*        PLEASE NOTE THAT END OF TASK HAS A DEPENDENCY UPON THE LOGON * 04443621
*        TCB HAVING A NONZERO TCBECB FIELD AND BEING A JOB STEP TCB.  * 04444021
*        THE FOLLOWING CODE MAKES THAT FIELD BOTH NONZERO AND         * 04444421
*        UNIMPORTANT AS FAR AS CAUSING USELESS TASK SWITCHES TO THE   * 04444821
*        RCT TASK IF THAT FIELD WAS LEFT WITH THE ADDRESS OF THE RCT  * 04445221
*        COMMUNICATION ECB (RCBECB).  THE LOGON TCB MUST BE A JOB STEP* 04445621
*        TCB IN ORDER TO BYPASS THE ECB - RB VALIDITY CHECKS DONE BY  * 04446021
*        END OF TASK BEFORE POSTING THE ATTACH ECB.                   * 04446421
*********************************************************************** 04446821
         SPACE 2                                                        04447221
         LA    WORK7,RCBSTECB          ADDRESS UNUSED ECB        A44022 04447621
         ST    WORK7,TCBECB  SAVE FOR EOT PROCESSING IN THE      A44022 04448021
*                                      LOGON TCB.                A44022 04448421
         SPACE 5                                                        04448821
         TM    CVTTSFLG,CVTTSRDY       IS TS RUNNING                    04450020
         BZ    CHECKDP                 NO, FILL IN TSIA                 04460020
         CLI   TSIAASGN,ZERO           YES, IS THERE AN ACTIVE REGION   04470020
         BNZ   PQERSTOR                YES, SKIP TSIA INIT - IS DONE    04480020
CHECKDP  IC    WORK7,TCBDSP            TCB DISP PRIORITY                04500020
         STC   WORK7,TSIACURR          INIT FIELD IN TSIA               04510020
         STC   WORK7,TSIAASGN          INIT TS DISP PRIORITY            04520020
PQERSTOR EQU   *                                                 A44022 04560021
         LA    ZEROREG,RCTWKEND        LENGTH RCT WORK AREA             04600020
         LR    PARMREG,SAVREG          SET UP TO FREE IT                04610020
         L     SAVREG,FOUR(PARMREG)    RELOAD SAVREG                    04620020
         FREEMAIN  R,LV=(0),A=(1)      FREE WORK AREA                   04630020
         LR    PARMREG,RCBREG          PASS ADDR RCB                    04640020
         XCTL  (2,12),EP=IKJEAR01      XCTL TO MAIN GO FOR RCT          04650020
         SPACE 3                                                        04660020
CLEARCRE XC    ZERO(ZERO,CODEREG),ZERO(CODEREG) CLEAR CORE    AJ A44987 04670021
         SPACE  4                                                       04680020
         TITLE 'STORAGE FOR RCT (READ-ONLY)'                            04690020
STRING   DC    CL8'IKJEFLA'            FOR USE IN ATTACH                04700020
ATLAA    ATTACH    EPLOC=STRING,ROLL=(NO,NO),SF=L   LIST FORM ATTACH    04710020
         DS    0F                      ALIGN TO FULL WORD               04720020
SP245    DC    X'F5000000'             MASK FOR SUBPOOL 245             04730020
POSTMASK DC    X'00FFFFFF'             MASK TO ZERO HI BYTE OF REG      04750020
*                                      MASK USED TO TURN OFF ANY BITS   04770020
SD6000FF DC    X'0000FFFF'             PROPOGATED WHEN GETTING KEY      04780020
TWOK     DC    H'2048'       SIZE OF A HARDWARE STOREAGE BLOCK   A44022 04780321
ONEK     DC    H'1024'       USED TO OBTAIN CENTER OF BLOCK ADDREA44022 04780621
BLANKS   DC    CL8' '                  CONSTANT TO CHANGE TO UPPERCASE  04781020
CANCEL   DC    C'CANCEL'               CONSTANT FOR COMPARE             04782020
RETRY    DC    C'RETRY '                                         A44022 04784021
         DS    0F                       FULL WORD BOUNDARY              04786021
IEFSD60A ENQ   (IEFSQCBS,IEFQ6QCB,E,2,SYSTEM),MF=L  ENQ/DEQ PARM LIST   04790020
IEFSQCBS DC    C'SYSIEFSD'             MAJOR NAME                       04800020
IEFQ6QCB DC    C'Q6'                   MINOR NAME ASGN-DEL Q MNGR       04810020
         DS    0F                                                       04820020
TDISABLE DC    X'00'                   MASK TO DISABLE INTERRUPTS       04830020
         DS    0F                                                       04840020
KEYMSG   WTO   'IKJ050I UNABLE TO START TS REGION   - PROTECTION KEY UNX04850020
               AVAILABLE',MF=L,MCSFLAG=REG0,DESC=5                      04851020
KEYMSGLN EQU   *-KEYMSG                LENGTH MESSAGE                   04870020
PARTMSG  WTO   'IKJ053I INSUFFICIENT MAINSTORAGE AVAILABLE FOR TS REGIOX04880020
               N   ',MCSFLAG=REG0,MF=L,DESC=5                           04890020
PARTMSLN EQU   *-PARTMSG               LENGTH OF MESSAGE                04900020
REPLYMSG WTOR  'IKJ054D REPLY ''RETRY'' OR ''CANCEL''',MCSFLAG=REG0,   X04910020
               MF=L,DESC=2                                              04920020
         END                                                            04950020
