          TITLE  'RCT WAIT AND FUNCTION TESTING'                        00050020
IKJEAR01 START                                                          00100020
*********************************************************************** 00150020
*A149100,153100                                        MP/TSO AJ M1705  00160021
*A190980-192060                                        MP/TSO AJ A53356 00170021
*C192064                                               MP/TSO AJ A53356 00180021
*STATUS  =0                                                      20021* 00200020
*                                                                     * 00250020
*FUNCTION-TSO/REGION REGION CONTROL TASK                              * 00300020
*                                                                       00350020
*    THIS ROUTINE'S MAIN PURPOSE IS TO DETERMINE WHICH FUNCTIONS -    * 00400020
*    QUIESCE, RESTORE, ATTENTION HANDLING - ARE TO BE PERFORMED BY    * 00450020
*    TESTINE THE RCB FUNCTION FLAGS AND THEN ISSUENG A BALR TO THE    * 00500020
*    APPROPRIATE ROUTINE. WHEN NONE OF THE FLAGS ARE SET, R01         * 00550020
*    ISSUES A WAIT ON THE RCBECB.                                     * 00600020
*       THE STAE RETRY ROUTINES ARE ALSO CONTAINED IN THIS CONTROL    * 00650020
*    SECTION AND GAIN CONTROL WHEN A USER CAUSED THE RCT TO ABEND.    * 00700020
*    THE STAE RETRY ROUTINES HAVE TWO FIRST TIME ENTRY POINTS AND SIX * 00750020
*    RECURSION ENTRY POINTS. EACH ENTRY POINT IS DESCRIBED AS FOLLOWS:* 00800020
*                                                                     * 00850020
*    RETRY 5:  IS ENTERED IF AN  ABEND OCCURED WHILE THE RCT WAS IN   * 00900020
*              PROCESS OF TERMINATING A USER USING OOCA BECAUSE THE   * 00950020
*              USER COULD NOT BE SWAPPED IN. IT WILL DISCONNECT USER  * 01000020
*              VIA OOCA AND RETURN                                    * 01050020
*                                                                     * 01100020
*    RETRY 6:  IS ENTERED WHEN RETRY 5 FAILS  IT CALLS OOCA TO        * 01150020
*              COMPLETE USER DISCONNECT.                              * 01200020
*                                                                     * 01250020
*    RETRY 7:  IS ENTERED WHEN RETRY 6 FAILS. RCBSTAE0 IS SPECIFIED   * 01300020
*              AND RCT MAINLINE ENTERED                               * 01350020
*                                                                     * 01400020
*    RETRY 0:  IS ENTERED FOR ALL ERRORS OTHER THAN RETRY 5. IT       * 01450020
*               ATTEMPTS TO TAKE A DUMP                               * 01500020
*                                                                     * 01550020
*    RETRY 1:  IS ENTERED VIA RETRY 0 OR AN ABEND IN RETRY 0. IT DE-  * 01600020
*              TERMINES WHERE THE FAILURE OCCURRED IN RCT PROCESSING  * 01650020
*                                                                     * 01700020
*    RETRY 2:  IS ENTERED VIA RETRY 1 OR ABEND IN RETRY 1. IT INFORMS * 01750020
*              TS DRIVER THAT REGION IS LOST.                         * 01800020
*                                                                     * 01850020
*    RETRY 3:  IS ENTERED VIA RETRY 2 OR ABEND IN RETRY 2. IT WILL    * 01900020
*              TERMINATE WLL USERS OF REGION BY OOCA AND ISSUE A WTO. * 01950020
*              IT IS REENTERED IF OOCA FAILS AND REISSUES OOCA FOR    * 02000020
*              THE REMAINING USERS                                    * 02050020
*                                                                     * 02100020
*    RETRY 4:  IS ENTERED WHEN RETRY 3 OR FAILURE IN WTO. IT SETS     * 02150020
*              THE RCT PERMANENTLY NON-DISPATCHABLE AND ISSUES A      * 02200020
*              WAIT                                                   * 02250020
*                                                                     * 02260000
*    RETRY 8:  IS ENTERED WHEN FSTOP IS SPECIFIED AT STOP TSO TIME AND* 02270000
*              USERS ARE STILL LOGGED ON IN THE REGION(S). OOCA IS    * 02280000
*              INVOKED TO LOG THEM OFF                                * 02290000
*                                                                     * 02292000
*    RETRY 9:  IS ENTERED WHEN FSTOP IS SPECIFIED AT STOP TSO TIME    * 02294000
*              AND NO USERS ARE LOGGED ON OR IF OOCA HAS ABENDED      * 02296000
*              WHILE PROCESSING FOR RETRY 8                           * 02298000
*                                                                     * 02300020
*ROUTINES CONTAINED IN THIS MODULE ARE:                               * 02350020
*        IKJEAR01 - ENTRY POINT AND INITIALIZATION                    * 02400020
*        R01MNL01 - MAINWAIT, TEST, AND BRANCH                        * 02450020
*        R01STE0  - STAE EXIT                                         * 02500020
*        R01RTR0  - STAE RETRY 0                                      * 02550020
*        R01RTR1  - STAE RETRY 1                                      * 02600020
*        R01RTR2  - STAE RETRY 2                                      * 02650020
*        R01RTR3  - STAE RETRY 3                                      * 02700020
*        R01RTR4  - STAE RETRY 4                                      * 02750020
*        R01RTR5  - STAE RETRY 5                                      * 02800020
*        R01RTR6  - STAE RETRY 6                                      * 02850020
*        R01RTR7  - STAE RETRY 7                                      * 02900020
*        R01RTR8  --STAE RETRY 8                                      * 02910000
*        R01RTR9  - STAE RETRY 9                                      * 02920000
*                                                                     * 02950020
*ENTRY POINTS/INPUT-                                                  * 03000020
*                                                                     * 03050020
*        IKJEAR01                                                     * 03100020
*        REG   1  - RCB ADDRESS                                       * 03150020
*        REG   13 - SAVE AREA ADDR.                                   * 03200020
*        REG   14 - RETURN ADDRESS                                    * 03250020
*        REG   15 - ENTRY POINT ADDRESS                               * 03300020
*                                                                     * 03350020
*        R01SET0                                                      * 03400020
*        REG   0  - CODE                                              * 03450020
*        REG   14 - RETURN ADDRESS                                    * 03500020
*        REG   15 - ENTRY POINT ADDRESS                               * 03550020
*        WHEN THE CODE IS 0, 4, OR 8                                  * 03600020
*        REG   1  - ADDR. OF STAE WORK AREA                           * 03650020
*        REG   13 - SAVE AREA ADDR.                                   * 03700020
*        PLUS ZERO WORK AREA - ADDR. STAE EXIT PARM LIST              * 03750020
*        WHEN THE CODE IS 12                                          * 03800020
*        REG   1  - ABEND COMPLETION CODE                             * 03850020
*        REG   2  - ADDR. OF STAE EXIT PARAMETER LIST                 * 03900020
*                                                                     * 03950020
*        R01RTR0, 1, 2, 3, 4, 5, 6, OR 7                              * 04000020
*        REG   0  - CODE                                              * 04050020
*        REG   14 - RETURN ADDRESS                                    * 04100020
*        REG   15 - ENTRY POINT ADDRESS                               * 04150020
*        WHEN THE CODE IS 0                                           * 04200020
*        REG   1  - ADDR. OF STAE WORK AREA                           * 04250020
*        WHEN THE CODE IS 12                                          * 04300020
*        REG   1  - ABEND COMPLETION CODE                             * 04350020
*                                                                     * 04400020
*OUTPUT- NONE                                                         * 04450020
*                                                                     * 04500020
*EXTERNAL REFERENCES-                                                 * 04550020
*        IKJEAR02 - RCT QUIESCE                                       * 04600020
*        ENTERED DISABLED AND RETURN DISABLED.                        * 04650020
*        REG   11  RCB ADDRESS                                        * 04700020
*        REG   12  TJB ADDRESS                                        * 04750020
*        REG   13  SAVE AREA ADDRESS                                  * 04800020
*        REG   14  RETURN ADDRESS                                     * 04850020
*        REG   15  ENTRY POINT ADDRESS                                * 04900020
*                                                                     * 04950020
*        IKJEAR03 - RCT RESTORE                                       * 05000020
*        ENTERED DISABLED AND RETURN DISABLED.                        * 05050020
*        REG   11  RCB ADDRESS                                        * 05100020
*        REG   12  TJB ADDRESS                                        * 05150020
*        REG   13  SAVE AREA ADDRESS                                  * 05200020
*        REG   14  RETURN ADDRESS                                     * 05250020
*        REG   15  ENTRY POINT ADDRESS                                * 05300020
*                                                                     * 05350020
*        IKJEAR04 - RCT ATTENTION HANDLER                             * 05400020
*        ENTERED DISABLED AND RETURN DISABLED.                        * 05450020
*        REG   11  RCB ADDRESS                                        * 05500020
*        REG   12  TJB ADDRESS                                        * 05550020
*        REG   13  SAVE AREA ADDRESS                                  * 05600020
*        REG   14  RETURN ADDRESS                                     * 05650020
*        REG   15  ENTRY POINT ADDRESS                                * 05700020
*                                                                     * 05750020
*        IKJEAT07 - OUT OF CORE ABEND                                 * 05800020
*        ENTERED DISABLED AND RETURN DISABLED.                        * 05850020
*        REG    1  TJID - SINGLE TSO USER                             * 05900020
*        REG    1  ADDR. RCB - FOR ALL TSO USERS                      * 05950020
*        REG   13  SAVE AREA ADDRESS                                  * 06000020
*        REG   14  RETURN ADDRESS                                     * 06050020
*        REG   15  ENTRY POINT ADDRESS                                * 06100020
*                                                                     * 06150020
*        IKJEAT08 - TSO DUMP                                          * 06200020
*        REG    1 ADDR. OF RCB                                        * 06250020
*        REG   13  SAVE AREA ADDRESS                                  * 06300020
*        REG   14  RETURN ADDRESS                                     * 06350020
*        REG   15  ENTRY POINT ADDRESS                                * 06400020
*                                                                     * 06450020
*        TSEVENT                                                      * 06500020
*              SWINERR - RESTORE LOGON IMAGE HAS FAILED.              * 06550020
*              RGNFAIL - IKJEAT07 ABENDS                              * 06600020
*                                                                     * 06650020
*EXIT-   RETURN TO CALLER WHEN RCBFND IS SET.                         * 06700020
*                                                                     * 06750020
*EXIT ERROR- SETS OWN TCB NON DISPATCHABLE                            * 06800020
*                                                                     * 06850020
*TABLES/WORKAREAS- SAVE/WORK OBTAINED FROM SUBPOOL 253                * 06900020
*                                                                     * 06950020
*ATTRIBUTES- REENTRANT, REFRESHABLE, SUPERVISOR STATE, DISABLES       * 07000020
*                                                                     * 07050020
*CHARACTER CODE DEPENDENCY - THE OPERATION OF THIS MODULE DEPENDS     * 07100020
*    UPON AN INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET    * 07150020
*    WHICH IS EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME.  THE       * 07200020
*    CODING HAS BEEN ARRANGED SO THAT REDEFINITION OF 'CHARACTER'     * 07250020
*    CONSTANTS, BY REASSEMBLY, WILL RESULT IN A CORRECT MODULE FOR    * 07300020
*    THE NEW DEFINITIONS.                                             * 07350020
*                                                                     * 07400020
*NOTES-NONE                                                           * 07450020
*                                                                     * 07500020
*********************************************************************** 07550020
         EJECT                                                          07600020
CVTDSECT DSECT                                                          07650020
         CVT                                                            07700020
         EJECT                                                          07750000
         IKJTCB                                                         07800020
         SPACE 5                                                        07810000
         IKJPQE                                                         07820021
         EJECT                                                          07850020
         IKJTSCVT                                                       07900020
         SPACE 5                                                        07950000
         IKJRCB                                                         08000020
         SPACE 5                                                        08050000
         IKJTJB                                                         08100020
         SPACE 5                                                        08150000
         IKJTJBX                                                        08200020
         SPACE 5                                                        08250000
         IKJECBS                                                        08300020
         EJECT                                                          08350020
          SPACE 3                                                       08360000
*                                                                       08370000
*     RCT INITIALIZATION WORKAREA DSECT                                 08380000
*                                                                       08390000
          SPACE 3                                                       08392000
R01WORK  DSECT                         WORK AREA FOR RCT                08400020
R01SAVE  DS    18F                     SAVE AREA FOR RCT                08450020
         ORG   R01SAVE+16              ORG INTO SAVE AREA               08500020
R01PACK  DS    D                       AREA FOR CONVERTING REGION NO    08550020
R01WTO   DS    19F                     WORK AREA FOR WTO MANIPULATING   08600020
R01OCAWK DS    57F                     WORKAREA FOR OOCA                08650020
R01WKEND EQU   *-R01WORK               LENGTH R01WORK AREA              08700020
         EJECT                                                          08750020
*********************************************************************** 08800020
*IKJEAR01 EQUATES.                                                    * 08850020
*********************************************************************** 08900020
         SPACE 3                                                        08910000
*                                                                       08920000
*        REGISTERS                                                      08950020
*                                                                       08960000
         SPACE 2                                                        09000020
WORK0    EQU   0                       WORK REGISTER                    09050020
WORK1    EQU   1                       *                                09100020
WORK2    EQU   2                       *                                09150020
WORK3    EQU   3                       *                                09200020
WORK4    EQU   4                       *                                09250020
WORK5    EQU   5                       *                                09300020
BALREG   EQU   6                       INTERNAL RETURN REGISTER         09350020
DSECTREG EQU   7                       ANY DSECT BASE REGISTER          09400020
TCBREG   EQU   8                       TCB BASE REGISTER                09450020
TSCVTREG EQU   9                       TSCVT BASE REGISTER              09500020
BASEREG  EQU   10                      IKJEAR01 BASE ADDRESS            09550020
*DO NOT CHANGE ANY OF THE BELOW.  EXTERNAL ROUTINE DEPENDENCIES         09600020
RCBREG   EQU   11                      RCB BASE REGISTER                09650020
TJBREG   EQU   12                      TJB BASE REGISTER                09700020
SAVREG   EQU   13                      SAVE AREA ADDRESS                09750020
RTNREG   EQU   14                      RETURN REGISTER                  09800020
CODEREG  EQU   15                      CODE REGISTER                    09850020
BNCHREG  EQU   15                      BRANCHING REGISTER               09900020
         SPACE 2                                                        09950020
*                                                                       09960000
*        MASKS                                                          10000020
*                                                                       10010000
         SPACE 2                                                        10050020
SET      EQU   X'FF'                   MASK TO TURN ALL BITS ON         10100020
X0F      EQU   X'0F'                   *                                10150020
WAITBIT  EQU   X'80'                   ECB IN WAIT BIT                  10200020
POSTBIT  EQU   X'40'                   ECB IS POSTED                    10250020
         EJECT                                                          10300020
         SPACE 3                                                        10310000
*                                                                       10320000
*        NUMBERS                                                        10350020
*                                                                       10360000
         SPACE 2                                                        10400020
ZERO     EQU   0                       *                                10450020
ONE      EQU   1                       *                                10500020
TWO      EQU   2                       *                                10550020
FOUR     EQU   4                       *                                10600020
SEVEN    EQU   7                       *                                10650020
EIGHT    EQU   8                       *                                10700020
TWELVE   EQU   12                      *                                10750020
THIRTEEN EQU   13                      *                                10800020
SIXTEEN  EQU   16                      *                                10850020
TWENTY   EQU   20                      *                                10900020
TWENTY4  EQU   24                      *                                10950020
THIRTY6  EQU   36                      *                                11000020
SIXTY8   EQU   68                      *                                11050020
SEVENTY6 EQU   76                      *                                11100020
NINETY2  EQU   92                      *                                11150020
HUNDRED4 EQU   104                     *                                11200020
TWO55    EQU   255                     *                                11250020
E8       EQU   8                                                        11260021
E11      EQU   11                                                       11270021
         EJECT                                                          11300020
IKJEAR01 CSECT                                                          11350020
         SPACE 3                                                        11360000
*********************************************************************** 11400020
         USING RCB,RCBREG              BASE FOR RCB                     11450020
         USING TCB,TCBREG              BASE FOR TCB                     11500020
         USING TJB,TJBREG              BASE FOR TJB                     11550020
         USING TSCVT,TSCVTREG          BASE FOR TSCVT                   11600020
         USING R01WORK,SAVREG          BASE FOR WORK AREA               11650020
*********************************************************************** 11700020
         SPACE 3                                                        11710000
         SAVE  (14,12)                 SAVE CALLER'S REGISTERS          11750020
         BALR  BASEREG,0               ESTABLISH ADDRESSABILITY         11800020
         USING R01BASE,BASEREG         *                                11850020
R01BASE  EQU   *                       BASE ADDR. FOR IKJEAR01          11900020
         LR    RCBREG,WORK1            SAVE RCB ADDRESS                 11950020
         LA    WORK0,R01WKEND          LENGTH OF AREA TO GETMAIN        12000020
         O     WORK0,WSP253            AND SET SUBPOOL ID               12050020
         GETMAIN  R,LV=(0)             SAVE/WORK AREA                   12100020
         SPACE 2                                                        12110000
         XC    ZERO(TWO55,WORK1),ZERO(WORK1)  CLEAR SAVE AREA           12150020
         XC    TWO55(R01WKEND-TWO55,WORK1),TWO55(WORK1)                 12200020
         ST    SAVREG,FOUR(WORK1)      SAVE PTR TO HSA                  12250020
         ST    WORK1,EIGHT(SAVREG)     SAVE PTR TO LSA                  12300020
         LR    SAVREG,WORK1            LOAD SAVE REG WITH ADDR SA       12350020
         MVI   RCBRCOVR,RCBRCOV0       SET 'IN INIT'                    12400020
         MVI   RCBSTAEN,RCBSTAE0       SET 'STAE EXIT 0'                12450020
         BAL   BALREG,R01SUBA          SUBROUTINE/ISSUE STAE/           12500020
          SPACE 1                                                       12510000
*********************************************************************** 12550020
*IKJ052I TIME SHARING REGION NN HAS STARTED                           * 12600020
*********************************************************************** 12650020
         SPACE 2                                                        12660000
         MVC   R01WTO(MSG3LNTH),MSG3   MOVE MESSAGE TO WORK AREA        12700020
         LA    WORK2,R01WTO+MSG3NUM    ADDR. VARIABLE IN MSG 3          12750020
         BAL   BALREG,R01SUBC          SUBROUTINE/REGION NUMBER EDCBIC/ 12800020
         SR    WORK0,WORK0             ZERO                             12850020
         IC    WORK0,RCBCONID          GET CONSOLE ID FOR MESSAGE       12900020
         WTO   MF=(E,R01WTO)           WRITE MESSAGE                    12950020
         EJECT                                                          13000020
*********************************************************************** 13050020
*POST TSCECB, IKJEAR01 IS UP AND READY.                               * 13100020
*********************************************************************** 13150020
         SPACE 1                                                        13152020
         OI    RCBFLG2,RCBACTV         INDICATE REGION ACTIVE     M6580 13160020
         USING CVTDSECT,DSECTREG       BASE FOR CVT                     13200020
         L     DSECTREG,CVTPTR         ADDR. OS CVT                     13250020
         L     TSCVTREG,CVTTSCVT       ADDR. OF TSCVT                   13300020
         DROP  DSECTREG                CVT                              13350020
         USING TSECB,DSECTREG          BASE FOR TSC ECB'S               13400020
         L     DSECTREG,TSCVTECB       ADDR. OF TSC ECB'S               13450020
         POST  TSCECB                  TELL TSC INIT COMPLETE           13500020
         SPACE 2                                                        13510000
         DROP  DSECTREG                TSO ECB'S                        13550020
         B     R01MNL02                GO TEST FUNCTION FLAGS           13650020
         EJECT                                                          13700020
*********************************************************************** 13750020
*REGION CONTROL TASK'S (RCT'S) MAIN WAIT FOR WORK. WHEN RCBECB IS     * 13800020
*POSTED, TEST RCBFLG TO DETERMINE THE FUNCTION TO PERFORM.            * 13850020
*********************************************************************** 13900020
         SPACE 2                                                        13950000
R01MNL00 EQU   *             A MOVEABLE LABLE DEFINITION                14000021
         WAIT  ECB=RCBECB              WAIT FOR FUNCTION TO BE REQ      14250020
         SPACE 2                                                        14260000
R01MNL02 MVI   RCBECB,ZERO   CLEAR WAIT/POST BITS                       14300021
         MVI   RCBSTAEN,RCBSTAE0       SET 'STAE EXIT 0'                14350021
         MVI   RCBRCOVR,RCBRCOV1       SET 'IN MAIN LINE'               14400020
         TM    RCBFLG,SET              RCT FUNCTION FLAGS SET           14450020
         BZ    R01MNL00                NO                               14500020
         USING CVTDSECT,DSECTREG       BASE FOR CVT                     14550020
         L     DSECTREG,CVTPTR         ADDR. OS CVT                     14600020
         L     TSCVTREG,CVTTSCVT       ADDR. OF TSCVT                   14650020
         DROP  DSECTREG                CVT                              14700020
         LH    TJBREG,RCBTJID          GET TJID                         14750020
         MH    TJBREG,TSCVTSZU         DISP IN TJB'S TO TJB THIS TJID   14800020
         L     WORK2,TSCVTTJB          ADDR. FIRST TJB                  14850020
         AR    TJBREG,WORK2            ADDR. TJB THIS TJID              14900020
         SSM   DISABLE             SERIALIZE RCB FUNCTION FLG  AJ M1705 14910000
         TM    RCBFLG,RCBOCAB   1      IS USER TO BE OUT OF CORE ABEND  14950020
         BO    T07BRNCH                YES, BR TO OUT OF CORE ABEND     15000020
         TM    RCBFLG,RCBFRS    2      IS USER TO BE RESTORED           15050020
         BO    R03BRNCH                YES, BR TO RESTORE RTN           15100020
         TM    RCBFLG,RCBFAT    3      USER ATTENTION EXIT              15150020
         BO    R04BRNCH                YES, BR TO ATTENTION RTN         15200020
         TM    RCBFLG,RCBFQU    4      IS USER TO BE QUIESCED           15250020
         BO    R02BRNCH                YES, BR TO QUIESCE RTN           15300020
         SSM   ENABLE              ENABLE FOR RCT END          AJ M1705 15310000
         TM    RCBFLG,RCBFND    5      IS RCT TO END                    15350020
         BO    R01END                  YES, BR TO R01 END               15400020
         B     R01MNL00                TO TOP                           15450020
         EJECT                                                          15500020
*********************************************************************** 15550020
*RCBOCAB IS SET.  ISSUE TSEVENT(SWINERR), INVOKE IKJEAT07 BY TJID,    * 15600020
*AND SET 'STAE EXIT 5' - IKJEAT07 BY TJID.                            * 15650020
*********************************************************************** 15700020
         SPACE 1                                                        15710000
T07BRNCH MVI   RCBRCOVR,RCBRCOV2       SET 'RCBOCAB IS SET'             15750020
         MVI   RCBSTAEN,RCBSTAE5       SET 'STAE EXIT 5'                15800020
         NI    RCBFLG,SET-RCBOCAB      RESET FUNCTION FLAG              15850020
         LH    WORK1,RCBTJID           REG 1 CONTAINS TJID              16050020
         BAL   BALREG,R01SUBD          SUBROUTINE/INVOKE IKJEAT07/      16100020
         B     R01MNL02                CHECK FLAGS FOR MORE WORK        16150020
         SPACE 3                                                        16160000
*********************************************************************** 16200020
*RCBFRS IS SET, INVOKE RESTORE/IKJEAR03/                              * 16250020
*********************************************************************** 16300020
         SPACE 1                                                        16310000
R03BRNCH MVI   RCBRCOVR,RCBRCOV3       SET 'IN RESTORE'                 16350020
         NI    RCBFLG,SET-RCBFRS       RESET RESTORE FUNCTION FLAG      16400020
         L     BNCHREG,AR03EP          ADDR. RESTORE/IKJEAR03/          16450020
         B     R01MNL03                CARRY OUT BALR                   16500020
         SPACE 3                                                        16510000
*********************************************************************** 16550020
*RCBFAT IS SET, INVOKE ATTENTION HANDLING/IKJEAR04/                   * 16600020
*********************************************************************** 16650020
         SPACE 1                                                        16660000
R04BRNCH MVI   RCBRCOVR,RCBRCOV4       SET 'IN ATTENTION'               16700020
         NI    RCBFLG,SET-RCBFAT       RESET ATTENTION FUNCTION FLAG    16750020
         L     BNCHREG,AR04EP          ADDR. ATTENTION/IKJEAR04/        16800020
         B     R01MNL03                CARRY OUT BALR                   16850020
         SPACE 3                                                        16860000
*********************************************************************** 16900020
*RCBFQU IS SET, INVOKE QUIESCE/IKJEAR02/                              * 16950020
*********************************************************************** 17000020
         SPACE 1                                                        17010000
R02BRNCH MVI   RCBRCOVR,RCBRCOV5       SET 'IN QUIESCE'                 17050020
         NI    RCBFLG,SET-RCBFQU       RESET QUIESCE FUNCTION FLAG      17100020
         L     BNCHREG,AR02EP          ADDR. QUIESCE/IKJEAR02/          17150020
         SPACE 1                                                        17160000
*********************************************************************** 17200020
*COMMON BALR TO QUIESCE, RESTORE, ATTN. HANDLING.                     * 17250020
*********************************************************************** 17300020
         SPACE 1                                                        17310000
R01MNL03 SSM   DISABLE                 INVOKED DISABLED                 17350020
         BALR  RTNREG,BNCHREG          GO TO ROUTINE INDICATED          17400020
         USING R01MNL04,RTNREG         TEMPORARY BASE                   17450020
R01MNL04 L     BASEREG,AR01BASE        LOAD BASE R01 BASE ADDR.         17500020
         DROP  RTNREG                  DROP TEMPORARY BASE              17550020
         SSM   ENABLE                  AND ENABLE                       17600020
         B     R01MNL02                GO CHECK RCB FLAGS               17650020
         EJECT                                                          17700020
*********************************************************************** 17750020
*RCBFND IS SET, IF RCBCUSE NE ZERO, INVOKE OUT OF CORE ABEND TO       * 17800020
*TERMINATE ALL USERS.  RETURN TO CALLER.                              * 17850020
*********************************************************************** 17900020
         SPACE 2                                                        17902000
*                                                                       17904000
*   STAE  RETRY 9  AND NORMAL RCT END PROCESSING ROUTINE                17906000
*                                                                       17908000
         SPACE 2                                                        17908400
         USING R01RTR9,BNCHREG                                          17910021
R01RTR9  L     BASEREG,AR01BASE        EST ADRSBLTY                     17920021
         DROP  BNCHREG                                                  17930021
         BAL   BALREG,R01SUBE          GET RCB ADRSBLTY                 17940021
R01END   MVI   RCBRCOVR,RCBRCOV6       SET 'RCBFND, RCBCUSE EQ 0'       17950020
         NI    RCBFLG,SET-RCBFND       RESET RCT END FUNCTION FLAG      18000020
         LH    WORK2,RCBCUSE           COUNT CURRENT USER THIS REGION   18050020
         LTR   WORK2,WORK2             ZERO                             18100020
         BNZ   R01END04                NO                               18150020
R01END05 L     TCBREG,RCBRCT GET RCT'S TCB ADDRESS                      18180021
         XR    WORK2,WORK2         CLEAR FOR DAUGHTER TCB               18210021
         C     WORK2,TCBLTC            IS THERE A DAUGHTER              18250020
         BZ    R01END02                NO - EXIT                        18300020
         SSM   DISABLE                 NO INTERRUPTS             A42839 18320021
         ST    WORK2,TCBLTC            YES - ZERO DAUGHTER TCB          18350020
         L     WORK2,RCBEXTNT          GET TJBX ADR FROM RCB            18400020
         USING TJBX,WORK2              TJBX BASE                        18450020
         L     WORK1,TJBXFST           GET FIRST TCB TO BE REMOVED      18500020
R01END01 C     WORK1,TCBTCB            DOES NEXT TCB POINT TO THIS TCB  18550020
         BNE   R01END03                NO GET NEXT TCB                  18600020
         L     WORK1,TJBXLAST          GET LAST TCB ON USER RDY Q       18650020
         DROP  WORK2                   RELEASE TJBX BASE                18700020
         DROP  TCBREG                  DROP TEMPORARILY                 18750020
         USING TCB,WORK1               USE TCB TO BE REMOVED            18800020
         L     WORK2,TCBTCB            YES- GET NEXT TCB ADDR           18850020
         DROP  WORK1                   DROP TO USE PERMANENT BASE AGAIN 18900020
         USING TCB,TCBREG              RESUME WITH REGULAR BASE         18950020
         ST    WORK2,TCBTCB            PLACE NEXT IN PREVIOS TCB        19000020
         SSM   ENABLE                  ALLOW INTERRUPTS          A42839 19020021
R01END02 SR    WORK0,WORK0   SET KEY EQ 0                               19024021
         USING PQESECT,WORK1                                            19028021
         L     WORK1,RCBPQE  GET DUMMY POINTER                          19032021
         L     WORK1,E8(WORK1)         GET PQE ADRS                     19036021
         L     WORK2,PQEREGN GET REGN ADRS                              19040021
         L     WORK3,PQESIZE GET SIZE OF REGION                         19044021
         SRL   WORK3,E11     GET NUMBER OF 2K BLOCKS                    19048021
BACK     SSK   WORK0,WORK2   SET STRG KEY=0                             19052021
         AH    WORK2,TWOK    ADRS NEXT POTENTIAL BLOCK                  19056021
         BCT   WORK3,BACK    CONTINUE                                   19060021
         DROP  WORK1                                                    19064021
         LR    WORK1,SAVREG  GET SAVE AREA ADRS                         19068021
         L     SAVREG,FOUR(SAVREG)     REST ADR CALLER'S SAVE AR A42839 19072021
         LA    WORK0,R01WKEND          GET LENGTH OF WK AR     R A42839 19076021
         O     WORK0,WSP253            INDICATE SUBPOOL 253      A42839 19080021
         FREEMAIN R,LV=(0),A=(1)       FREE R01 WK AREA          A42839 19084021
         SPACE 2                                                        19086021
**********************************************************************  19094021
         EJECT                                                          19096021
**********************************************************************  19096121
         SPACE 3                                                        19096421
************          *******          *****       *********            19098021
****                                                       *****        19098421
****      THIS IS THE BEGINNING OF THE SECTION MOVED FROM  *****        19098821
****          T05 TO R01 FOR MP/TSO CHANGES                *****        19099221
****                APAR 53356                             *****        19099621
***********      ********        **********      ************           19099721
         SPACE 3                                                        19099821
*********************************************************************** 19099921
*GET ADDR. OF DUMMY PQE FROM RCB FOR THIS RCT.                        * 19103221
*********************************************************************** 19105221
T05SR01A L     PQER,RCBPQE             ADDR DUMMY PQE FOR USER REGION   19105621
         LTR   PQER,PQER               IS THERE A PQE IN THE RCB        19106021
         BZ    EXIT             NO, RETURN TO SYSTEM TERMINATION        19106421
          SPACE 3                                                       19106521
*********************************************************************** 19106621
*BUILD AN FBQE FOR ENTIRE REGION FOR THIS PQE AT START OF REGION      * 19117421
*********************************************************************** 19127421
         USING PQESECT,PQER            PQE                              19127821
T05SR02  L     PQER,PQEFPQE            ADDR. OF PQE                     19128221
         L     WR1,PQEREGN             ADDR. OF START OF REGION         19128321
         ST    PQER,E0(WR1)            ADDR. OF PQE IN FBQE             19131921
         ST    PQER,E4(WR1)            ADDR. OF PQE IN FBQE             19133921
         MVC   E8(E4,WR1),PQESIZE      SIZE OF REGION IN FBQE           19134321
         ST    WR1,PQEFFBQE            ADDR. OF FBQE IN PQE             19134721
         ST    WR1,PQEBFBQE            ADDR. OF FBQE IN PQE             19135121
         L     RCBTCB,RCBRCT           GET RCT ADDRESS           MP/TSO 19135521
         ST    RCBTCB,PQETCB           STORE IN PQE FOR FREEPART MP/TSO 19139121
         L     PQER,PQEFPQE            ADDR. OF NEXT PQE                19141121
         LTR   PQER,PQER               ANOTHER PQE?                     19141521
         BNZ   T05SR02                 YES, TO TOP                      19141921
*                                      NO                               19142321
         EJECT                                                          19142721
         DROP  TCBREG                                                   19154121
WR1      EQU  1                   WORK REGISTER 1               MP/TSO  19164121
WR5      EQU  5                   RCTS TCBPQE SAVE REGISTER     MP/TSO  19164521
WR4      EQU  4                   RCTS TCBMSS SAVE REGISTER     MP/TSO  19164921
E0       EQU  0                   CONSTANT ZERO FOR DSPLCMENT   MP/TSO  19165321
E4       EQU  4                   CONSTANT FOR DISPLACEMENT     MP/TSO  19165721
PQER     EQU  6                   BASE FOR REGION PQE           MP/TSO  19169521
RCBTCB   EQU  7                   THIS RCTS TCB ADDRESS         MP/TSO  19171521
ALLFLAG  EQU  X'FF'               CONSTANT FOR ALLFLAGS ON      MP/TSO  19171921
TSCTCB   EQU   3                  TSCS TCB ADDRESS              MP/TSO  19172321
         SPACE 3                                                        19172721
*********************************************************************** 19173121
*ISSUE FREEPART FOR THIS REGION BEFORE TERMINATING             MP/TSO * 19173221
*********************************************************************** 19173321
         SPACE 2                                                        19177121
         SSM   DISABLE             DISABLE FOR TCB MSS,PQE MANIPULATION 19179121
         USING TCB,RCBTCB           TCB                                 19179521
         L     WR5,TCBPQE              PQE ADDR FOR RCT CONTROL REGION  19179921
         L     WR4,TCBMSS              ADDR RCT'S SPQE CHAIN            19180321
         L     TSCTCB,TCBJSTCB       SAVE JOB STEP POINTER       MP/TSO 19180721
         ST    RCBTCB,TCBJSTCB        MAKE RCT LOOK LIKE JS      MP/TSO 19180821
         NI    TCBJPQ,ALLFLAG-TCBJPQF  CLEAR JPQ PURGE FLAG             19180921
         L     PQER,RCBPQE             ADDR PQE FOR USER REGION         19184721
         ST    PQER,TCBPQE             TO RCT'S TCB                     19186721
         XC    TCBMSSB,TCBMSSB         ZERO PTR TO RCT'S SPQE CHAIN     19187121
         SPACE 2                                                        19187521
         GETMAIN R,LV=8,SP=252         SUBPOOL 252 FOR FREEPART         19187921
         SPACE 2                                                        19188321
         FREEMAIN  R,SP=247            FREEPART                         19188421
         SPACE 2                                                        19188521
         L     WR1,TCBMSS              GET SPQE PTR FROM RCT TCB  M1412 19194321
         FREEMAIN R,LV=8,SP=255,A=(1)  FREE SPQE                  M1412 19196321
         SPACE 2                                                        19198321
         ST    WR5,TCBPQE              RESTORE RCT PQE IN RCT TCB       19200321
         ST    WR4,TCBMSS              RESTORE SPQE PTR  IN RCT TCB     19200721
         ST    TSCTCB,TCBJSTCB     RESTORE JOB STEP POINTER      MP/TSO 19201121
         SSM   ENABLE              LET INTERRUPTS COME IN FINISHED WITH 19201221
*                                    TCB MANIPULATION            MP/TSO 19201321
         DROP  RCBTCB                 TO RCT TCB                        19201521
*********************************************************************** 19201921
         SPACE 3                                                        19202621
************          **********        ********      ********          19203021
*****                                                       *****       19203421
*****          THIS IS THE END OF THE SECTION OF CODE MOVED *****       19203821
*****               FROM T05 TO R01 FOR MP/TSO CHANGES      *****       19203921
*****                APAR 53356                            *****        19204621
**************         *********       ********     **********          19205021
         SPACE 3                                                        19205421
**********************************************************************  19205821
         EJECT                                                          19205921
         USING TCB,TCBREG   RESTORE TCB BASE                            19206021
EXIT     RETURN (14,12),RC=0           RETURN TO CALLER    MPTSO A53356 19206421
         SPACE 3                                                        19207221
R01END03 L     TCBREG,TCBTCB           GET NEXT TCB                     19213021
         B     R01END01                BRANCH BACK FOR CHECK            19218821
         SPACE 3                                                        19224621
*                                                                       19230421
*    STAE RETRY ROUTINE 8                                               19236221
*                                                                       19242021
         SPACE 2                                                        19247821
         USING R01RTR8,BNCHREG                                          19253621
R01RTR8  L     BASEREG,AR01BASE        ESTABLISH ADRSBLTY               19259421
         DROP  BNCHREG                                                  19265221
         BAL   BALREG,R01SUBE          GET ADRSBLTY TO RCB              19271021
         MVI   RCBSTAEN,RCBSTAE2       SET FOR RETRY 2                  19276821
         BAL   BALREG,R01SUBA          RE ISSUE STAE                    19282621
         SPACE 2                                                        19288421
*********************************************************************** 19294221
*INVOKE OUT OF CORE ABEND - IKJEAT07 BY RCB ADDR.                     * 19300020
*********************************************************************** 19350020
         SPACE 2                                                        19360000
R01END04 MVI   RCBRCOVR,RCBRCOV7       SET 'RCBFND RCBCUSE NE 0'        19400020
         MVI   RCBFLG,ZERO   ZERO FUNCTION FLAGS                        19410021
         SR    WORK1,WORK1   GET REGION NUMBER                          19420021
         IC    WORK1,RCBNMBR     FROM RCB                               19430021
         TSEVENT RGNFAIL     TELL DRIVER                                19440021
         SPACE 2                                                        19442000
         MVI   RCBSTAEN,RCBSTAE2       SET 'STAE EXIT 2'                19450020
         LR    WORK1,RCBREG            REG1 ADDR. RCB                   19500020
         O     WORK1,WMBIT0            TURN BIT 0 REG 1 ON              19550020
         BAL   BALREG,R01SUBD          SUBROUTINE/INVOKE IKJEAT07/      19600020
         SPACE                                                          19650020
*                                                                       19660000
* FROM THIS POINT ON TREAT AS A NORMAL RETURN                           19700020
*                                                                       19710000
         SPACE                                                          19750020
         MVI   RCBRCOVR,RCBRCOV6       SET'RCBFND, RCBCUSE EQ 0'        19800020
         MVI   RCBSTAEN,RCBSTAE0       SET 'STAE EXIT 0'                19850020
         B     R01END05      AND RETURN TO CALLER                       19900021
         EJECT                                                          19950020
*********************************************************************** 20000020
*STAE EXIT ROUTINE.  USE RCBSATEN AS INDEX TO ADDR. RETRY ROUTINE.    * 20050020
*********************************************************************** 20100020
         SPACE 3                                                        20110000
         USING R01STE0,BNCHREG         TEMPORARY BASE                   20150020
R01STE0  L     BASEREG,AR01BASE        PERMANENT BASE ADDR.             20200020
         DROP  BNCHREG                 DROP TEMPORARY BASE              20250020
         CH    WORK0,STAEC12           STAE EXIT CODE EQUAL 12??        20300020
         BE    R01STE01                ADDR. RCB IN WORK2               20350020
         L     WORK2,ZERO(WORK1)       RCB ADDR. +0 STAE WORK AREA      20400020
R01STE01 LR    RCBREG,WORK2            ADDR. RCB IN REGISTER 2          20450020
         TM    RCBFLG,RCBFND WAS THE END FUNCTION REQESTED              20455021
         BZ    R01STE02      NO, USE RCBSTEAN                           20460021
         OC    RCBCUSE,RCBCUSE         ANY USERS THIS REGION            20465021
         BZ    R01STE03      NO, USE RETRY 9                            20470021
         LA    WORK0,R01RTR8 YES, USE RETRY 8                           20475021
         B     R01STE04      RETURN                                     20480021
R01STE03 LA    WORK0,R01RTR9 USE RETRY 9                                20485021
         B     R01STE04      RETURN                                     20490021
R01STE02 EQU   *             USE RCBSTEAN                               20495021
         SR    WORK3,WORK3             ZERO                             20500020
         IC    WORK3,RCBSTAEN          RCBSTAEN IS INDEX TO             20550020
         L     WORK0,AR01RTRT(WORK3)   ADDR. RETRY ROUTINE              20600020
R01STE04 EQU   *             SET FOR RETURN                             20620021
         LA    CODEREG,FOUR            RETURN CODE EQ 4 /RETRY/         20650020
         BR    RTNREG                  RETURN                           20700020
         EJECT                                                          20750020
*********************************************************************** 20800020
*RETRY 0 - PROTECTS THE RCT'S NORMAL PROCESSING.                      * 20850020
*INVOKE'S TSO DUMP - IKJEAT08, BRANCHS INTO RETRY 1.                  * 20900020
*********************************************************************** 20950020
         SPACE 3                                                        20960000
         USING R01RTR0,BNCHREG         TEMPORARY BASE                   21000020
R01RTR0  L     BASEREG,AR01BASE        PERMANENT BASE ADDR.             21050020
         DROP  BNCHREG                 DROP TEMP                        21100020
         BAL   BALREG,R01SUBE          SUBROUTINE/LOAD RCBREG/          21150020
         MVI   RCBSTAEN,RCBSTAE1       SET 'STAE EXIT 1'                21200020
         BAL   BALREG,R01SUBA          SUBROUTINE/ISSUE STAE/           21250020
         CLI   RCBRCOVR,RCBRCOV6       'RCBFND, RCBCUSE EQ O'           21300020
         BE    R01END05      (BE) YES, RETURN                           21350021
R01RTR01 LR    WORK1,RCBREG            REG1 ADDR. RCB                   21400020
         L     BNCHREG,TSCVTT08        ADDR. OF IKJEAT08                21450020
         BALR  RTNREG,BNCHREG          GO TO IKJEAT08                   21500020
         CLI   RCBRCOVR,RCBRCOV0       'IN INIT'                        21550020
         BE    R01END05      (BE) YES, RETURN                           21600021
R01RTR02 MVI   RCBSTAEN,RCBSTAE2       SET 'STAE EXIT 2'                21650020
         B     R01RTR11                INTO RETRY 1                     21700020
         EJECT                                                          21750020
*********************************************************************** 21800020
*RETRY 1 - PROTECTS RETRY 0'S INVOKING OF IKJEAT08. RETRY 0 BRANCHES  * 21850020
*INTO RETRY 1 TO HANDLE FAILURE IN RCT'S NORMAL PROCESSING.           * 21900020
*********************************************************************** 21950020
         SPACE 3                                                        21960000
         USING R01RTR1,BNCHREG         TEMPORARY BASE                   22000020
R01RTR1  L     BASEREG,AR01BASE        PERMANENT BASE ADDR.             22050020
         DROP  BNCHREG                 DROP TEMP                        22100020
         BAL   BALREG,R01SUBE          SUBROUTINE/LOAD RCBREG/          22150020
         MVI   RCBSTAEN,RCBSTAE2       SET 'STAE EXIT 2'                22200020
         BAL   BALREG,R01SUBA          SUBROUTINE/ISSUE STAE/           22250020
         CLI   RCBRCOVR,RCBRCOV0       'IN INIT'                        22300020
         BE    R01END05      (BE) YES, RETURN                           22350021
R01RTR11 TM    RCBSWTCH,RCBRMSAL       MACHINE CHECK - ALL USERS        22400020
         BO    R01RTR13                YES                              22450020
R01RTR12 TM    RCBSWTCH,RCBRMS1U       MACHINE CHECK - ONE USER         22500020
         BO    R01RTR15                YES, INVOKE IKJEAT07             22550020
         TM    RCBFLG2,RCBLOGPR        IS THIS QUIESCE OF LOGON IMG     22557021
         BZ    R01RTR1N      NO, CONTINUE                               22564021
         NI    RCBFLG2,TWO55-RCBLOGPR  TURN OFF LOGIN PROC FLAG         22571021
         OI    RCBFLG,RCBFND           SET END FUNCTION FLAG ON         22578021
         B     R01MNL02      PERFORM THE END FUNCTION                   22585021
R01RTR1N EQU   *                                                        22592021
         SR    WORK2,WORK2             ZERO                             22600020
         IC    WORK2,RCBRCOVR          USE RCBRCOVR AS INDEX            22650020
         B     R01RTR1T(WORK2)         AND BRANCH ON IT                 22700020
R01RTR1T NOP   *                       RCBRCOV0                         22750020
         B     R01RTR13                RCBRCOV1                         22800020
         NOP   *                       RCBRCOV2                         22850020
         B     R01RTR14                RCBRCOV3                         22900020
         B     R01RTR16                RCBRCOV4                         22950020
         B     R01RTR15                RCBRCOV5                         23000020
*        NOP   *                       RCBRCOV6                         23050020
*        NOP   *                       RCBRCOV7                         23100020
R01RTR13 MVI   RCBSTAEN,RCBSTAE3       SET 'STAE EXIT 3'                23150020
         NI    RCBSWTCH,SET-RCBRMSAL   TURN OFF BIT                     23200020
         B     R01RTR21                INTO RETRY 2                     23250020
         SPACE 3                                                        23260000
*********************************************************************** 23300020
*RESTORE FAILURE, IF LOGON IMAGE TSEVENT AND WTO IKJ062I              * 23350020
*********************************************************************** 23400020
         SPACE 3                                                        23410000
R01RTR14 NI    RCBFLG,SET-RCBFAT       RESET FAT IN RCB                 23450020
         LH    TJBREG,RCBTJID          GET TJID                         23500020
         MH    TJBREG,TSCVTSZU         DISP IN TJB'S TO TJB THIS TJID   23550020
         L     WORK2,TSCVTTJB          ADDR. FIRST TJB                  23600020
         AR    TJBREG,WORK2            ADDR. TJB THIS TJID              23650020
         TM    TJBRSTOR,TJBLOGP        RESTORE LOGON IMAGE              23700020
         BZ    R01RTR15                NO                               23750020
         SR    WORK1,WORK1   ZERO REG FOR IC                            23790021
         IC    WORK1,RCBNMBR GET REGION NUMBER                          23830021
         O     WORK1,WMBIT0            SET BIT 0 TO ONE                 23870021
         TSEVENT RGNFAIL     TELL  DRIVER REGION FAILED                 23910021
         SPACE 2                                                        23920000
*********************************************************************** 23950020
*IKJ062I TS REGION NO LONGER AVAILABLE FOR LOGONS                     * 24000020
*********************************************************************** 24050020
         SPACE 3                                                        24060000
         MVC   R01WTO(MSG2LNTH),MSG2   MOVE MESSAGE TO WORK AREA        24100020
         LA    WORK2,R01WTO+MSG2NUM    ADDR. VARIABLE IN MSG 4          24150020
         BAL   BALREG,R01SUBC          SUBROUTINE/REGION NUMBER EBCDIC/ 24200020
         SR    WORK0,WORK0             ZERO                             24250020
         IC    WORK0,RCBCONID          GET CONSOLE ID FOR MESSAGE       24300020
         WTO   MF=(E,R01WTO)           WRITE MESSAGE                    24350020
         EJECT                                                          24400020
         SPACE 2                                                        24410000
*********************************************************************** 24450020
*MACHINE CHECK, QUIESCE, RESTORE FAILURE, INVOKE OUT OF CORE ABEND    * 24500020
*********************************************************************** 24550020
         SPACE 2                                                        24560000
R01RTR15 LH    WORK1,RCBTJID           REG 1 TJID                       24600020
         NI    RCBSWTCH,SET-RCBRMS1U   TURN OFF BIT                     24650020
         BAL   BALREG,R01SUBD          SUBROUTINE/INVOKE IKJEAT07/      24700020
         B     R01MNL02                RETURN TO MAINLINE               24750020
         SPACE 2                                                        24760000
*********************************************************************** 24800020
* ATTENTION FAILURE, ABTERM THE FIRST DAUGHTER AFTER TJBXFST THAT IS    24850020
* A JOB STEP TCB WITH 160 COMPLETION CODE          *                    24900020
*********************************************************************** 24950020
         SPACE 2                                                        24960000
R01RTR16 MVI   RCBRCOVR,RCBRCOV3       SET 'IN RESTORE'                 25000020
         MVI   RCBSTAEN,RCBSTAE1       SET 'STAE EXIT 1'                25050020
         LH    TJBREG,RCBTJID          GET TJID                         25100020
         MH    TJBREG,TSCVTSZU         DISP IN TJB'S TO TJB THIS TJID   25150020
         L     WORK2,TSCVTTJB          ADDR. FIRST TJB                  25200020
         AR    TJBREG,WORK2            ADDR. TJB THIS TJID              25250020
         SSM   DISABLE                 DISABLE                          25300020
         MVI   TJBSTAX,ZERO            ZERO STAX COUNT                  25350020
         MVI   TJBATTN,ZERO            ZERO ATTENTION COUNT             25400020
         USING TJBX,DSECTREG           TJBX                             25450020
         L     DSECTREG,TJBEXTNT       ADDR. OF TJBX                    25500020
         XC    TJBXTAXE(FOUR),TJBXTAXE ZERO ADDR. TAXE QUEUE            25550020
         L     WORK0,TJBXFST           PUT FST IN WORK0                 25600020
         CL    WORK0,TJBXLAST          IS THIS ALSO LAST ?              25650020
         BE    R01RTR19                YES, ABEND FST                   25700020
         LR    TCBREG,WORK0            GET FST TCB                      25750020
         L     TCBREG,TCBLTC           GET DAUGHTER TCB                 25800020
R01RTR17 CL    TCBREG,TCBJSTCB         IS THIS THE JOB STEP TASK        25850020
         BE    R01RTR18                YES, ABEND DAUGHTER              25900020
         L     TCBREG,TCBNTC           GET DAUGHTER'S SISTER TCB        25950020
         LTR   TCBREG,TCBREG           LAST ONE ON QUEUE?               26000020
         BZ    R01RTR19                YES, ABEND FST                   26050020
         B     R01RTR17                NO, CHECK THIS SISTER            26100020
R01RTR18 LR    WORK0,TCBREG            MOVE TCB ADDR TO ABEND           26150020
R01RTR19 L     WORK1,ABCC160           ABEND COMPLETION CODE X'160'     26200020
         USING CVTDSECT,DSECTREG       CVT                              26250020
         L     DSECTREG,CVTPTR         ADDR. CVT                        26300020
         L     BNCHREG,CVTBTERM        ADDR. OF IEA0AB00/ABTERM/        26350020
         DROP  DSECTREG                CVT                              26400020
         BALR  RTNREG,BNCHREG          GO TO ABTERM                     26450020
         SSM   ENABLE                  ENABLE                           26500020
         B     R01MNL02                RETURN TO MAINLINE               26550020
         EJECT                                                          26600020
         SPACE 2                                                        26610000
*********************************************************************** 26650020
*RETRY 2 - PROTECTS RETRY 1                                           * 26700020
*********************************************************************** 26750020
         SPACE 3                                                        26760000
         USING R01RTR2,BNCHREG         TEMPORARY BASE                   26800020
R01RTR2  L     BASEREG,AR01BASE        PERMANENT BASE ADDR.             26850020
         DROP  BNCHREG                 DROP TEMP                        26900020
         BAL   BALREG,R01SUBE          SUBROUTINE/LOAD RCBREG/          26950020
         MVI   RCBSTAEN,RCBSTAE3       SET 'STAE EXIT 3'                27000020
         BAL   BALREG,R01SUBA          SUBROUTINE/ISSUE STAE/           27050020
R01RTR21 SR    WORK1,WORK1             ZERO                             27100020
         IC    WORK1,RCBNMBR           REGION NUMBER                    27150020
         TSEVENT RGNFAIL               REGION HAS FAILED                27200020
         SPACE 2                                                        27210000
         MVI   RCBSTAEN,RCBSTAE3       SET 'STAE EXIT 3'                27250020
         B     R01RTR31                INTO RETRY 3                     27300020
         EJECT                                                          27350020
         SPACE 2                                                        27360000
*********************************************************************** 27400020
*RETRY 3 - PROTECTS RETRY ACROSS TSEVENT                              * 27450020
*********************************************************************** 27500020
         SPACE 2                                                        27510000
         USING R01RTR3,BNCHREG         TEMPORARY BASE                   27550020
R01RTR3  L     BASEREG,AR01BASE        PERMANENT BASE ADDR.             27600020
         DROP  BNCHREG                 DROP TEMP                        27650020
         BAL   BALREG,R01SUBE          SUBROUTINE/LOAD RCBREG/          27700020
         MVI   RCBSTAEN,RCBSTAE3       SET 'STAE EXIT 3'                27750020
         BAL   BALREG,R01SUBA          SUBROUTINE/ISSUE STAE/           27800020
R01RTR31 LR    WORK1,RCBREG            ADDR. RCB                        27850020
         O     WORK1,WMBIT0            TURN ON BIT 0                    27900020
         BAL   BALREG,R01SUBD          SUBROUTINE/INVOKE IKJEAT07/      27950020
         MVI   RCBSTAEN,RCBSTAE4       SET 'STAE EXIT 4'                28000020
         SPACE 2                                                        28010000
*********************************************************************** 28050020
*IKJ055I TIME SHARING REGION NN HAS FAILED                            * 28100020
*********************************************************************** 28150020
         SPACE 2                                                        28160000
         MVC   R01WTO(MSG4LNTH),MSG4   MOVE MESSAGE TO WORK AREA        28200020
         LA    WORK2,R01WTO+MSG4NUM    ADDR. VARIABLE IN MSG 4          28250020
         BAL   BALREG,R01SUBC          SUBROUTINE/REGION NUMBER EDCBIC/ 28300020
         SR    WORK0,WORK0             ZERO                             28350020
         IC    WORK0,RCBCONID          GET CONSOLE ID FOR MESSAGE       28400020
         WTO   MF=(E,R01WTO)           WRITE MESSAGE                    28450020
         B     R01RTR41                BRANCH INTO RETRY 4              28500020
         EJECT                                                          28550020
         SPACE 3                                                        28560000
*********************************************************************** 28600020
*RETRY 4 PROTECTS WTO IKJ055I                                         * 28650020
*HANGS RCT TCB                                                        * 28700020
*********************************************************************** 28750020
         SPACE 2                                                        28760000
         USING R01RTR4,BNCHREG         TEMPORARY BASE                   28800020
R01RTR4  L     BASEREG,AR01BASE        PERMANENT BASE ADDR.             28850020
         DROP  BNCHREG                 DROP TEMP                        28900020
         BAL   BALREG,R01SUBE          SUBROUTINE/LOAD RCBREG/          28950020
R01RTR41 SSM   DISABLE                 NO INTERRUPTS             A42839 28960021
         L     WORK3,TSCVTECB          GET ADRS OF ECBS                 28970021
         TM    RCBFLG2,RCBMODFY        IS MODIFY FOR A REGION    A42839 28980021
         MVI   RCBFLG2,RCBDEAD         SET RCBDEAD               A42839 28990021
         BZ    NT06POST                NO MODIFY FOR A REGION    A42839 29000021
         USING TSECB,WORK3                                              29010021
         POST  TSCECB4       POST MODIFY (T06)                          29020021
         SPACE 2                                                        29022000
NT06POST POST  TSCECB        POST THE TSC (T03)                         29030021
         SPACE 2                                                        29032000
         LA    WORK0,FOUR    SET CODE OF FOUR                           29040021
         POST RCBDIECB,(0)   POST FOR T03 QUIESCE OF 6. I.              29050021
         SPACE 2                                                        29060000
*                                                                       29070000
*SET TCB NON DISPATCH                                                   29100020
*                                                                       29110000
         MVI   RCBFLG,ZERO             RESET ALL FUNCTION FLAGS         29150020
         OI    TCBFLGS5,TCBPNDSP       SET RCT PERM NON-DISP            29200020
         OI    TCBNDSP1,TCBDARPN       SET PERM NON-DISP FOR DAR        29250020
         XC    RCBECB(FOUR),RCBECB     ZERO OUT RCB ECB                 29300020
         WAIT  ECB=RCBECB              FORCE TASK SWITCH                29350020
         SPACE 3                                                        29360000
*********************************************************************** 29400020
*RETRY 5                                                              * 29450020
*********************************************************************** 29500020
         SPACE 2                                                        29510000
         USING R01RTR5,BNCHREG         TEMPORARY BASE                   29550020
R01RTR5  L     BASEREG,AR01BASE        PERMANENT BASE ADDR.             29600020
         DROP  BNCHREG                 DROP TEMP                        29650020
         BAL   BALREG,R01SUBE          SUBROUTINE/LOAD RCBREG/          29700020
         MVI   RCBSTAEN,RCBSTAE6       SET 'STAE EXIT 6'                29750020
         BAL   BALREG,R01SUBA          SUBROUTINE/ISSUE STAE/           29800020
         L     BNCHREG,TSCVTT08        ADDR. OF IKJEAT08                29850020
         BALR  RTNREG,BNCHREG          GO TO IKJEAT08                   29900020
         MVI   RCBSTAEN,RCBSTAE7       SET 'STAE EXIT 7'                29950020
         B     R01RTR61                BRANCH INTO RETRY 6              30000020
         SPACE 3                                                        30010000
*********************************************************************** 30050020
*RETRY 6 - PROTECTS T07BRNCH INVOKING IKJEAT07 WHEN RCBOCAB IS SET.   * 30100020
*INVOKES IKJEAT07 BY TJID TO ALLOW T07 TO FINISH DISCONNECT.          * 30150020
*********************************************************************** 30200020
         SPACE 2                                                        30210000
         USING R01RTR6,BNCHREG         TEMPORARY BASE                   30250020
R01RTR6  L     BASEREG,AR01BASE        PERMANENT BASE ADDR.             30300020
         DROP  BNCHREG                 DROP TEMP                        30350020
         BAL   BALREG,R01SUBE          SUBROUTINE/LOAD RCBREG/          30400020
         MVI   RCBSTAEN,RCBSTAE7       SET 'STAE EXIT 7'                30450020
         BAL   BALREG,R01SUBA          SUBROUTINE/ISSUE STAE/           30500020
R01RTR61 LH    WORK1,RCBTJID           REG1 IS TJID                     30550020
         BAL   BALREG,R01SUBD          SUBROUTINE/INVOKE IKJEAT07/      30600020
         B     R01MNL02                RETURN TO MAINLINE               30650020
         SPACE 3                                                        30660000
*********************************************************************** 30700020
*RETRY 7 - PROTECTS RETRY 6 INVOKING IKJEAT07 SECOND TIME BY TJID.    * 30750020
*********************************************************************** 30800020
         SPACE 2                                                        30810000
         USING R01RTR7,BNCHREG         TEMPORARY BASE                   30850020
R01RTR7  L     BASEREG,AR01BASE        PERMANENT BASE ADDR.             30900020
         DROP  BNCHREG                 DROP TEMP                        30950020
         BAL   BALREG,R01SUBE          SUBROUTINE/LOAD RCBREG/          31000020
         MVI   RCBSTAEN,RCBSTAE0       SET 'STAE EXIT 0'                31050020
         BAL   BALREG,R01SUBA          SUBROUTINE/ISSUE STAE/           31100020
         B     R01MNL02                RETURN TO MAINLINE               31150020
         EJECT                                                          31200020
*********************************************************************** 31250020
*R01SUBA IS A CLOSED SUBROUTINE THAT ISSUES THE STAE SVC.             * 31300020
*IT ASSUMES THAT RCBSTAEN HAS BEEN SET BY THE CALLER.                 * 31350020
*********************************************************************** 31400020
         SPACE 2                                                        31410000
R01SUBA  LA    WORK1,R01WTO            ADDR. MACRO E LIST               31450020
         MVC   ZERO(STAELL,WORK1),STAEL  MOVE STAE MACRO LIST           31500020
         STAE  ,CT,PARAM=(RCBREG),MF=(E,(1)) ISSUE STAE                 31550020
         BR    BALREG                  RETURN                           31600020
         SPACE 3                                                        31650020
*********************************************************************** 31700020
*R01SUBC IS A CLOSED SUBROUTINE CONVERTS REGION NUMBER TO EBCDIC.     * 31750020
*********************************************************************** 31800020
         SPACE 2                                                        31810000
R01SUBC  SR    WORK3,WORK3             ZERO                             31850020
         IC    WORK3,RCBNMBR           REGION NUMBER                    31900020
         CVD   WORK3,R01PACK           CONVERT TO DECIMAL               31950020
         OI    R01PACK+SEVEN,X0F       SIGN F FOR PRINT                 32000020
         UNPK  ZERO(TWO,WORK2),R01PACK+FOUR(FOUR) MOVE NUMBER TO MESG   32050020
         BR    BALREG                  RETURN                           32100020
         EJECT                                                          32150020
*********************************************************************** 32200020
*R01SUBD IS A CLOSED SUBROUTINE THAT INVOKES IKJEAT07.                * 32250020
*********************************************************************** 32300020
         SPACE 2                                                        32310000
R01SUBD  SSM   DISABLE                 DISABLE                          32350020
         NI    RCBFLG,SET-RCBFRS-RCBFAT-RCBFQU RESET THEM         M5936 32360020
         L     BNCHREG,TSCVTABN        ADDR. OF IKJEAT07                32400020
         BALR  RTNREG,BNCHREG          GO TO IT                         32450020
         SSM   ENABLE                  ENABLE                           32550020
         BR    BALREG                  RETURN                           32600020
         SPACE 3                                                        32650020
*********************************************************************** 32700020
*R01SUBE IS A CLOSED SUBROUTINE FOR THR RETRY ROUTINES ONLY.          * 32750020
*FREE'S STAE WORK AREA, LOADS TCBREG, SAVREG, TSCVTREG, AND RCBREG.   * 32800020
*********************************************************************** 32850020
         SPACE 2                                                        32860000
R01SUBE  CH    WORK0,STAEC12           STAE WORK AREA ?                 32900020
         BE    R01SUBE1                NO DONT FREEMAIN                 32950020
         LA    WORK0,HUNDRED4          LENGTH WORK AREA                 33000020
         O     WORK0,WSP250            AND SUBPOOL 250                  33050020
         FREEMAIN R,LV=(0),A=(1)       AND RELEASE IT                   33100020
         SPACE 2                                                        33110000
         USING CVTDSECT,DSECTREG       BASE FOR CVT                     33150020
R01SUBE1 L     DSECTREG,CVTPTR         ADDR. CVT                        33200020
         L     TCBREG,CVTTCBP          ADDR. NEW/OLD                    33250020
         L     TCBREG,FOUR(TCBREG)     ADDR. CURRENT TCB                33300020
         L     SAVREG,TCBFSA           ADDR. OF CALLER'S SAVE           33350020
         L     SAVREG,EIGHT(SAVREG)    ADDR. OF R01'SAVE AREA           33400020
         L     TSCVTREG,CVTTSCVT       ADDR. OF TSCVT                   33450020
         DROP  DSECTREG                CVT                              33500020
         L     RCBREG,TSCVTRCB         ADDR. OF FIRST RCB               33550020
R01SUBE2 C     TCBREG,RCBRCT           CURRENT TCB ADDR. TO RCBRCT      33600020
         BCR   8,BALREG           (BE) HIT, RETURN                      33650020
         LA    RCBREG,RCBEND           ADDR. NEXT RCB                   33700020
         B     R01SUBE2                TO TOP                           33750020
         EJECT                                                          33800020
*********************************************************************** 33850020
*CONSTANTS                                                            * 33900020
*********************************************************************** 33950020
         SPACE 2                                                        33960000
AR01BASE DC    A(R01BASE)              IKJEAR01 BASE ADDR.              34000020
AR02EP   DC    V(IKJEAR02)             QUIESCE ENTRY POINT/IKJEAR02/    34050020
AR03EP   DC    V(IKJEAR03)             RESTORE ENTRY POINT/IKJEAR03/    34100020
AR04EP   DC    V(IKJEAR04)             ATTENTION ENTRY POINT/IKJEAR04/  34150020
AR01RTRT DS    0F                      TABLE OF RETRY ROUTINE ADDR.     34200020
         DC    A(R01RTR0)              RETRY ROUTINE 0                  34250020
         DC    A(R01RTR1)              RETRY ROUTINE 1                  34300020
         DC    A(R01RTR2)              RETRY ROUTINE 2                  34350020
         DC    A(R01RTR3)              RETRY ROUTINE 3                  34400020
         DC    A(R01RTR4)              RETRY ROUTINE 4                  34450020
         DC    A(R01RTR5)              RETRY ROUTINE 5                  34500020
         DC    A(R01RTR6)              RETRY ROUTINE 6                  34550020
         DC    A(R01RTR7)              RETRY ROUTINE 7                  34600020
         SPACE 3                                                        34650020
         DS    0F                      WORK BOUNDARY FOR MASKS          34700020
WMBIT0   DC    X'80000000'             BIT 0 MASK                       34750020
WSP250   DC    X'FA000000'             SUBPOOL ID FOR STAE WORK AREA    34800020
WSP253   DC    X'FD000000'             SUBPOOL ID FOR R01 WORK AREA     34850020
WLOGOFFC DC    X'00006220'             FORCE LOGOFF POST CODE           34900020
ABCC160  DC    X'C0160000'             ABEND CODE 160                   34950020
WSP25372 DC    X'FD',AL3(72)           SUBPOOL 253, 72 BYTES            35000020
STAEC12  DC    H'12'                   STAE EXIT CODE 12                35050020
TWOK     DC    H'2048'                                                  35070021
DISABLE DC     X'00'                   MASK TO DISABLE INTERRUPTS       35100020
ENABLE  DC     X'FF'                   MASK TO ENABLE INTERRUPTS        35150020
         SPACE 3                                                        35200020
STAEL    STAE  R01STE0,PURGE=NONE,MF=L  LIST FORM STAE                  35250020
STAELL   EQU   *-STAEL                 LENGTH LSIT FORM STAE            35300020
          EJECT                                                         35350020
         SPACE 3                                                        35360000
MSG2     WTO   'IKJ062I TS REGION    NO LONGER AVAILABLE FOR LOGONS',  X35400020
               MF=L,MCSFLAG=REG0,DESC=4,ROUTCDE=(2,10)                  35450020
MSG2LNTH EQU   *-MSG2                  LENGTH OF MESSAGE                35500020
MSG2NUM  EQU   22                      DISP TO NUMBER IN MESSAGE 2      35550020
         SPACE 3                                                        35560000
MSG3     WTO   'IKJ052I TIME SHARING REGION    HAS STARTED',MF=L,      X35600020
               MCSFLAG=REG0,ROUTCDE=2,DESC=5                            35650020
MSG3LNTH EQU   *-MSG3                  LENGTH OF MESSAGE                35700020
MSG3NUM  EQU   32                      DISP TO NUMBER IN MESSAGE 3      35750020
         SPACE 3                                                        35760000
MSG4     WTO   'IKJ055I TIME SHARING REGION    HAS FAILED - TSO CANNOT X35800021
               BE TERMINATED',MF=L,MCSFLAG=REG0,ROUTCDE=2,DESC=5        35850021
MSG4LNTH EQU   *-MSG4                  LENGTH OF MESSAGE 4              35900020
MSG4NUM  EQU   32                      DISP TO NUMBER IN MESSAGE 4      35950020
         SPACE 3                                                        35960000
         END                                                            36000020
