         TITLE  'REGION CONTROL TASK QUIESCE FUNCTION'                  00020020
IKJEAR02 START                                                          00030020
         SPACE 3                                                        00040020
         SPACE 3                                                        00150020
*********************************************************************** 00160020
*                                                                     * 00170020
*STATUS -- 0                                                          * 00180020
*A093920                                                         A43809 00182021
*A037640,037660,038920,038940                                    A43833 00184021
*A024820,024828,024829,095820,095840,102604,102608               A44369 00186021
*C047720                                                         A46413 00188000
*A028920-0289140                                               AJ M1704 00188400
*C029150                                                       AJ M1704 00188800
*A031620,031640,031604                                        AJ A50057 00189221
*C031600,031700                                               AJ A50057 00189621
*D031900,032000,032100                                        AJ A50057 00189721
*A035602,035604,035606                                           A67714 00189821
*C035962,037900,039200,041900,042000                             A67714 00189921
*                                                                     * 00190020
*FUNCTION -- LOAD MODULE NAME - IKJEAR01                              * 00200020
*    ROUTINE NAME - IKJEAR02                                          * 00210020
*    IKJEAR02 PERFORMS THE OPERATIONS NECESSARY TO TEMPORARILY DIS-   * 00220020
*    CONNECT A USER FROM THE SYSTEM SO THAT HE MAY BE SWAPPED OUT OF  * 00221020
*    CORE LEAVING THE REGION HE WAS OCCUPYING FREE FOR ANOTHER USER.  * 00222020
*    THE FOLLOWING PROCESSING IS REQUIRED:                            * 00223020
*                                                                     * 00260020
*    1)  THE USER'S TCB'S ARE SET NON-DISPATCHABLE.  IN A MULTI-      * 00265000
*        PROCESSING SYSTEM, INVOKE THE TASK REMOVE ROUTINE WHEN A     * 00270000
*        TASK IS SET NON-DISPATCHABLE.                          21008 * 00275000
*    2)  THE USER'S I/O THAT HAS BEEN SCHEDULED BUT NOT STARTED IS    * 00280020
*        QUIESCED BY ISSUING SVC 16                                   * 00290020
*    3)  THE TRANSIENT AREA USER QUEUES ARE PURGED OF ANY SVRB'S      * 00300020
*        BELONGING TO THE USER                                        * 00310020
*    4)  ANY CONTROL BLOCKS ASSOCIATED WITH THE USER'S WTORS ARE      * 00320020
*        FLAGGED AND THE USER'S TJID INSERTED                         * 00330020
*    5)  QEL'S ARE LOCATED AND THE USER'S TJID INSERTED               * 00340020
*    6)  THE USER'S TCB'S ARE REMOVED FROM THE READY QUEUE            * 00350020
*    7)  TQE'S AND RQE'S ARE FLAGGED WITH THE USER'S TJID             * 00360020
*    8)  IQE'S ARE REMOVED FROM THE ASYNCHRONOUS EXIT QUEUES          * 00370020
*    9)  A MAP OF THE USER'S REGION IS BUILT                          * 00380020
*                                                                     * 00390020
*ENTRY POINT  -- IKJEAR02                                               00400020
*                                                                     * 00420020
*INPUT -- REG11 - RCB ADDRESS                                         * 00430020
*         REG12 - TJB ADDRESS                                         * 00440020
*         REG13 - SAVE AREA ADDRESS                                   * 00450020
*         REG14 - RETURN ADDRESS                                      * 00460020
*         REG15 - ENTRY POINT ADDRESS                                 * 00470020
*                                                                     * 00480020
*OUTPUT -- NONE                                                       * 00490020
*                                                                     * 00500020
*EXTERNAL REFERENCES -- BR 12 TO IEAQTR02.  IKJEAR02 STORES ITS       * 00510020
*    REGISTERS IN ITS TCB AND SETS THE PSW IN ITS RB TO THE RETURN    * 00520020
*    POINT REQUIRED.  AT COMPLETION OF ITS PROCESSING, IEAQTR02       * 00530020
*    CAUSES A TASK SWITCH, AND IKJEAR02 IS REDISPATCHED AT THE RETURN * 00540020
*    ADDRESS SPECIFIED IN ITS RB.                                     * 00550020
*    BALR 14,15 TO TASK REMOVE ROUTINE WHEN A TASK IS SET       21008 * 00553000
*    NON-DISPATCHABLE IN A MULTIPROCESSING SYSTEM.              21008 * 00556000
*                                                                     * 00560020
*EXITS, NORMAL -- RETURNS TO CALLER WITH BR 14                        * 00570020
*EXITS, ERROR -- STAE FOR TASK GAINS CONTROL IF THIS MODULE ABENDS    * 00580020
*                                                                     * 00590020
*TABLES/WORKAREAS -- NONE                                             * 00600020
*                                                                     * 00610020
*ATTRIBUTES -- REENTRANT, REFRESHABLE,  DISABLES, SUPERVISOR STATE    * 00620020
*                                                                     * 00631020
*CHARACTER CODE DEPENDENCY - THE OPERATION OF THIS MODULE DOES NOT    * 00632020
*    DEPEND UPON A PARTICULAR INTERNAL REPRESENTATION OF THE EXTERNAL * 00633020
*    CHARACTER SET.                                                   * 00634020
*                                                                     * 00640020
*NOTES -- NONE                                                        * 00650020
*                                                                     * 00660020
*******************************************************************     00670020
         EJECT                                                          00680020
         IEAQFX 65,MCH,M65MP                                      21008 00683000
         EJECT                                                    21008 00686000
UCM      DSECT                                                          00690020
         IEECUCM                                                        00700020
SCVTSECT DSECT                                                          00710020
         SCVT                                                           00720020
         SPACE 4                                                        00730020
         IEZJSCB                                                        00740020
         SPACE  4                                                       00750020
         IKJWQE                                                         00760020
         SPACE 4                                                        00770020
         IKJRPQE                                                        00780020
         SPACE 4                                                        00790020
         IKJRB                                                          00800020
         SPACE 4                                                        00810020
         IKJPQE                                                         00820020
         SPACE 4                                                        00830020
         IKJFBQE                                                        00840020
         SPACE 4                                                        00850020
         IKJUMSM                                                        00860020
UMSMEND  DS    0F                      LABEL TO MARK END OF DSECT       00870020
         SPACE 4                                                        00880020
         IKJQEL                                                         00890020
         SPACE 4                                                        00900020
QPLSECT  DSECT                         QUIESCE I/O PARAMETER LIST       00910020
         DS    0F                                                       00920020
QPLCNT   DS    0C                      TOTAL COUNT FIELD                00930020
QPLNUM   DS    4C                      NUMBER OF EXTENTS                00940020
QPLIOB   DS    1F                      ADDRESS OF IOB CHAIN             00950020
QPLFLG   DS    0C                      FLAGS FIELD                      00960020
QPLTCB   DS    1F                      ADDRESS OF TCB                   00970020
OPTIONS  EQU   X'0E'                   PURGE I/O OPTIONS                00980020
LSTENTRY EQU   X'80'                   LAST GPL EXTENT FLAG             00990020
         SPACE 4                                                        01000020
         IKJECBS                                                        01010020
         EJECT                                                          01020020
         IKJTCB                                                         01030020
         SPACE 4                                                        01040020
         IKJTJB                                                         01050020
         SPACE 4                                                        01060020
         IKJTJBX                                                        01070020
         SPACE 4                                                        01090020
         IKJRCB                                                         01100020
         SPACE  4                                                       01110020
CVT      DSECT                         NAME FOR CVT DSECT               01120020
         CVT                                                            01130020
         SPACE  4                                                       01140020
         IKJTSCVT                                                       01150020
         SPACE 4                                                        01160020
         IKJTQE                                                         01170020
         SPACE 4                                                        01180020
         IKJRQE                                                         01190020
         EJECT                                                          01192021
         MPCVT                                                          01194021
         TITLE 'RCT QUIESCE ROUTINE'                                    01200020
         SPACE 5                                                        01210020
* MISCELLANEOUS EQUATES                                                 01220020
         SPACE 3                                                        01230020
CVTSECT  EQU   CVT                     NAME FOR CVT DSECT               01240020
NOLGWAIT EQU   X'F7'                   FLAG TO TURN OFF LONGWAIT        01250020
XEF      EQU   X'EF'                   MASK TO TEST TS TASK DISPATCH    01260020
MCSINSYS EQU   X'02'                   FLAG TO TEST FOR MCS             01262020
ABENDBIT EQU   X'40'                   BIT IN TCBFLGS5 FIELD IN TCB     01264020
*                                      TO INDICATE TCB WILL BE ABENDED  01266020
BYTE     EQU   1                       LENGTH EQUATE                    01270020
WORD     EQU   4                       LENGTH EQUATE                    01280020
*     NUMERIC EQUATES                                                   01290020
         SPACE 2                                                        01300020
ZERO     EQU   0                       *                                01310020
ONE      EQU   1                       *                                01320020
TWO      EQU   2                       *                                01330020
THREE    EQU   3                       *                                01340020
FOUR     EQU   4                       *                                01350020
SIX      EQU   6                       *                                01360020
EIGHT    EQU   8                       *                                01370020
TWELVE   EQU   12                      *                          21008 01380000
D1       EQU   1                       *                                01390020
D2       EQU   2                       *                                01400020
D3       EQU   3                       *                                01410020
D4       EQU   4                       *                                01420020
D8       EQU   8                       *                                01430020
D9       EQU   9                       *                                01440020
D12      EQU   12                      *                                01450020
D15      EQU   15                      *                                01460020
D25      EQU   25                      *                                01480020
D255     EQU   X'FF'                   *                                01500020
         SPACE 3                                                        01510020
         SPACE 4                                                        01650020
*      GENERAL REGISTER EQUATES                                         01660020
         SPACE 3                                                        01670020
PARMREG  EQU   1                       PARAMETER REGISTER               01680020
CVTREG   EQU   3                       CVT BASE REGISTER                01690020
TCBREG   EQU   6                       TCB BASE REGISTER                01700020
TJBXREG  EQU   9                       TJBX BASE REGISTER               01710020
BASEREG  EQU   10                      BASE REGISTER FOR MODULE         01720020
RCBREG   EQU   11                      RCB BASE REGISTER                01730020
TJBREG   EQU   12                      TJB BASE REGISTER                01740020
SAVEREG  EQU   13                      SAVE AREA.                 21008 01750000
RTNREG   EQU   14                      CONTAINS RETURN ADDRESS          01760020
BALREG   EQU   15                      BRANCH & LINK REG.         21008 01765000
         SPACE 2                                                        01770020
* EQUATES USED BY MAP ROUTINE                                           01780020
         SPACE 2                                                        01790020
ZEROREG  EQU   0                       WORK REGISTER                    01800020
SWORK1   EQU   1                       WORK REGISTER                    01810020
SWORK2   EQU   2                       WORK REGISTER                    01820020
SWORK3   EQU   3                       WORK REGISTER                    01830020
SWORK4   EQU   4                       WORK REGISTER                    01840020
SWORK6   EQU   6                       WORK REGISTER                    01842020
SFBQEREG EQU   5                       FBQE BASE REGISTER               01850020
SWORK5   EQU   5                       WORK REGISTER                    01860020
UMSMREG  EQU   7                       UMSM BASE REGISTER               01870020
SPQEREG  EQU   8                       PQE BASE REGISTER                01880020
CODEREG  EQU   15                      REGISTER FOR RETURN CODES        01890020
TWOK     EQU   2048                    CONSTANT USED BY SETKEY ROUTINE  01900020
         SPACE 4                                                        01910020
*    EQUATES USED BY T/A PURGE ROUTINE                                  01920020
         SPACE 2                                                        01930020
SCVTREG  EQU   3                       SECONDARY CVT BASE REGISTER      01940020
SVRBREG  EQU   4                       SVRB BASE REGISTER               01950020
ENTRYREG EQU   7                       ADDR TACT ENTRY ARE PROCESSING   01960020
TACTSREG EQU   8                       TACT BASE REGISTER               01970020
EXITEFRG EQU   12                      STG II EXIT EFF BRANCH ENTRY PT  01980020
         SPACE 2                                                        01990020
*    EQUATES USED BY WTOR PURGE                                         02000020
         SPACE  2                                                       02010020
SRQEREG  EQU   7                       RQE BASE REGISTER                02020020
RQEPURGE EQU   X'80'                   PURGE FLAG IN RQEXA FIELD OF RQE 02040020
RQERO    EQU   X'20'                   ROLLOUT FLG IN RQE'S RQEXA FIELD 02050020
         SPACE 4                                                        02060020
*    REGISTERS USED BY ENQUEUE,TCB READY QUEUE,TQE PURGE AND RESTORE    02070020
         SPACE 2                                                        02080020
TJBFSTRG EQU   1                       ADDR USER'S FIRST TCB            02100020
MIQCBREG EQU   2                       MINOR QCB BASE REGISTER          02110020
TQPLREG  EQU   2                       QPL BASE REGISTER                02120020
TRBREG   EQU   2                       RB BASE REGISTER                 02130020
TSCVTREG EQU   3                       TIME SHARING CVT BASE REG        02140020
MINQCBRG EQU   3                       MINOR QCB REG              M3864 02145020
TQEREG   EQU   4                       TQE BASE REGISTER                02150020
QELREG   EQU   4                       QEL BASE REGISTER                02160020
QCBREG   EQU   4                       MAJOR QCB REG              M3864 02165020
QELCTREG EQU   5                       QEL COUNT FROM TCB               02170020
TCBLSTRG EQU   5                       ADDR RCT'S TCB IN READY Q PURGE  02180020
TJBLSTRG EQU   7                       ADDR USER'S LAST TCB             02190020
TWKREG1  EQU   7                       WORK REGISTER                    02200020
XTSECB   EQU   8                       TSC ECB ADDR                     02210020
XQPL     EQU   8                       QPL BASE REG 1ST ENTRY I/O PURGE 02220020
TSIAREG  EQU   8                       TSIA BASE REGISTER               02230020
MJQCBREG EQU   8                       MAJOR QCB BASE REG               02240020
TWKREG4  EQU   8                       WORK REGISTER                    02250020
CNTREG   EQU   8                       TCB COUNT REG              M3864 02255020
XQPLW    EQU   15                      QPL BASE SAVE REGISTER           02260020
         SPACE 4                                                        02270020
*    REGISTERS USED BY RQE AND IQE QUIESCE AND RESTORE                  02280020
         SPACE                                                          02290020
*                                                                       02300020
TPREVREG EQU   2                       SAVE REG FOR ADDR PREVIOUS RQE   02310020
JSCBREG  EQU   3                       ADDR OF JSCB               M3864 02313020
TCBLSTR  EQU   1                       ADDR OF LAST TCB           M3864 02316020
TRQEREG  EQU   4                       ADDR RQE IN PROCESS              02320020
TIQEREG  EQU   4                       ADDR IQE IN PROCESS              02330020
TAEQJREG EQU   5                       ADDR IQE QUEUE                   02340020
TAEQAREG EQU   5                       ADDR RQE QUEUE                   02350020
TCBIQERG EQU   7                       ADDR TCB FOR IQE BEING PROCESSED 02360020
TCBRQERG EQU   7                       ADDR TCB FOR RQE BEING PROCESSED 02370020
TSAVIQEG EQU   8                       ADDR LAST IQE SAVED IN TJBX      02380020
TSAVRQEG EQU   8                       ADDR LAST RQE SAVED IN TJBX      02390020
RQEREG   EQU   4                       ADDR OF RQE                M3864 02395020
         SPACE  4                                                       02400020
*   EQUATES USED BY RQE AND IQE QUIESCE AND RESTORE                     02410020
         SPACE 2                                                        02420020
TAEQMT   EQU   X'FF'                   FLAG INDICATING AEQ EMPTY        02430020
TIQETCB  EQU   12                      DISP IN IQE TO TCB ADDRESS       02440020
IQELNK   EQU   0                       DISP IN IQE TO NEXT IQE          02450020
TSTCBSND EQU   X'01'                   MASK TO SET SECONDARY NON-DISP   02460020
TALLON   EQU   X'FF'                   MASK TO TURN ALL BITS ON         02470020
TRQETCB  EQU   12                      DISP IN RQE TO TCB ADDR          02480020
TRQEOUT  EQU   X'F0'                   INDICATES USER IS SWAPPED A44369 02482021
*                                      OUT AND RQE NOT TO BE     A44369 02482821
*                                      PURGED                    A44369 02482921
RBRQE1   EQU   X'08'                   RQE INDICATOR IN IRB       M3864 02483020
RBRQE2   EQU   X'04'                   RQE INDICATOR IN IRB       M3864 02486020
         SPACE 4                                                        02490020
*  EQUATES USED BY ENQUEUE,TCB READY QUEUE,TQE PURGE AND RESTORE        02500020
         SPACE 2                                                        02510020
TQENTONQ EQU   X'80'                   MASK TO CHECK IF TQE ON TIMER Q  02520020
HIBITON  EQU   X'80'                   MASK TO TURN ON HI BIT IN QEL    02530020
X00      EQU   X'00'                   MASK TO TURN OFF ALL BITS        02540020
NOTINUSE EQU   X'20'                   MASK TO SET TRANS AREA NOT USED  02550020
PRGFENT  EQU   X'80'                   PURGE ENTRY FLAG                 02560020
TCBNXT   EQU   116                     DISP TO ADDR NEXT TCB ON READY Q 02570020
TYP3OR4  EQU   X'D0'                   FLAG TO DETERMINE RB TYPE        02590020
         SPACE 4                                                        02620020
*  DISPLACEMENTS IN QCB'S                                               02640020
         SPACE 2                                                        02650020
NEXTMAJ  EQU   0                       ADDR OF NEXT MAJOR QCB           02660020
MINQCB   EQU   8                       ADDR OF MINOR QCB                02670020
MINQEL   EQU   0                       ADDR OF QEL                      02680020
MAJNAME  EQU   12                      ADDR OF MAJOR NAME         M3864 02685020
         EJECT                                                          02690020
         SPACE 2                                                        02700020
*    THE FOLLOWING REGISTERS CAN NOT BE ALTERED DURING THE RCT          02710020
*    QUIESCE ROUTINE.  ALL OTHERS ARE TRANSPARENT.                      02720020
         SPACE 1                                                        02730020
*        RCBREG    11     ADDR RCB                                      02740020
*        TJBREG    12     ADDR TJB                                      02750020
*        TJBXREG    9     ADDR TJBX                                     02760020
*        BASEREG   10     BASE REGISTER                                 02770020
         SPACE 3                                                        02780020
IKJEAR02 CSECT                                                          02790020
         BALR  BASEREG,ZEROREG         ESTABLISH ADDRESSABILITY         02800020
         USING *,BASEREG               BASE REG FOR THIS CSECT          02810020
         USING TJB,TJBREG              BASE FOR TJB                     02820020
         USING TJBX,TJBXREG            BASE FOR TJBX                    02830020
         USING  TCB,TCBREG             BASE FOR TCB                     02840020
         USING  RCB,RCBREG             BASE FOR RCB                     02850020
         SPACE 2                                                        02860020
*                                                                       02862020
*        QUIESCE PROLOGUE ROUTINE - GET THE PURGE RESOURCE              02864020
*        FIRST , THEN ISSUE TSEVENT TO SEE IF QUIESCE                   02866020
*        SHOULD CONTINUE.                                               02868020
*                                                                       02874020
         SPACE                                                          02882020
         TM    TJBSTAT,TJBNJB      THIS TJB UNASSIGNED         AJ M1704 02892000
         BZ    QUIOK               NO- SO CONTINUE PROCESS     AJ M1704 02902000
         NC    TJBTJID(TWO),TJBTJID TJID=0(LOGON IMAGE)        AJ M1704 02912000
         BCR   7,RTNREG            NO-RETURN TO R01 LOGED OFF  AJ M1704 02914000
QUIOK    OI    TJBSTAT2,TJBQUIS        TURN ON QUIESCE STARTED BITM4298 02915000
         MVI   RCBQUFLG,RCBQUSTR        INDICATE QUIESCE STARTED  M1374 02920020
         SPACE 1                                                  M3864 02920820
*        MARK ALL TASKS NONDISPATCHABLE                           M3864 02921620
SETNDSP  L     TJBXREG,TJBEXTNT        GET TJB EXTENSION          M3864 02922420
         L     SWORK5,TJBXLAST         GET LAST USER TCB          M3864 02923220
         L     TCBREG,TJBXFST          GET FIRST USER TCB         M3864 02924020
SETNDSP1 OI    TCBFLGS5,TCBPNDSP       MARK TASK NONDISPATCHABLE  M3864 02924820
         L     CVTREG,CVTPTR           ADDRESS OF CVT             21008 02924900
         USING CVTSECT,CVTREG                                     21008 02925000
         TM    CVTDCB,CVT4MS1+CVT4MPS  CHECK FOR MP SYSTEM        21008 02925100
         BNO   NOTMP                   NO - TAKE BRANCH           21008 02925200
         STM   RTNREG,BALREG,TWELVE(SAVEREG) SAVE REGS TEMPORARILY21008 02925300
         L     BALREG,MPCVTPTR         POINTER TO MP CVT          21008 02925400
         USING IEAMPCVT,BALREG                                    21008 02925500
         L     BALREG,CVTTKRM          ADDR TSK REMOVE            21008 02925621
         DROP  BALREG                                             21008 02927721
         BALR  RTNREG,BALREG           TO TASK REMOVE             21008 02930221
         LM    RTNREG,BALREG,TWELVE(SAVEREG) RESTORE REGISTERS.   21008 02932421
NOTMP    EQU   *                                                  21008 02934621
         OI    TCBNDSP2,TCBNDTS        INDCTE TASK TO BE SW'D OUT M3864 02936821
         CR    TCBREG,SWORK5           LAST USER TCB ?            M3864 02939021
         BE    INITIAL                 CHECK PURGE RESOURCE       M3864 02941221
         L     TCBREG,TCBTCB           GET NEXT USER TCB          M3864 02943421
         B     SETNDSP1                MARK IT NONDISPATCHABLE    M3864 02945621
         TITLE 'RCT PURGE I/O INTERFACE'                                02947821
*********************************************************************** 02950020
*        THIS ROUTINE WILL INSURE THAT THE PURGE RESOURCE IS AVAILABLE* 02970020
*        BEFORE ENQUEING ON IT. IT WILL PREVENT AN INTERLOCK BETWEEN  * 02990020
*        QUIESCE AND ITS SUBTASKS.                                    * 03010020
*********************************************************************** 03030020
INITIAL  L     TCBREG,TJBXFST          GET FIRST USER TCB         M3864 03050020
         SR    CNTREG,CNTREG           ZERO COUNT OF TCB'S REG    M3864 03070020
         L     CVTREG,CVTPTR           ADDR CVT                   M3864 03090020
         USING CVTSECT,CVTREG          BASE FOR CVT               M3864 03110020
         L     SCVTREG,CVTABEND        PTR TO SECONDATY CVT       M3864 03130020
         USING SCVTSECT,SCVTREG        BASE FOR SECONDARY CVT     M3864 03140020
         L     QCBREG,SCVTQCBO         GET IEAQQCB0:ADDR 1ST QCB  M3864 03150020
SRCHMAJ  L     QCBREG,ZERO(QCBREG)     GET FIRST MAJOR QCB      M3864   03160021
         LA    QCBREG,ZERO(QCBREG)    CLEAR HIGH ORDER BYTE   AJ A50057 03160421
         LTR   QCBREG,QCBREG       QCBS PRESENT?              AJ A50057 03162021
         BZ    SETFLG              NO BYPASS SEARCH           AJ A50057 03164021
         CLC   MAJNAME(EIGHT,QCBREG),QNAME DOES QNAME MATCH?    M3864   03174021
         BE    SRCHMIN                 YES, GET MINOR             M3864 03180020
         B     SRCHMAJ                                            M3864 03212020
         SPACE 2                                                  M3864 03214020
*        MATCH MINOR NAMES                                        M3864 03216020
SRCHMIN  L     MINQCBRG,MINQCB(QCBREG) LOAD FIRST MINOR QCB       M3864 03218020
SRCHMIN1 CLC   D12(THREE,MINQCBRG),PRERNAME DO RNAMES MATCH ?     M3864 03220020
         BE    SRCHQEL              NOW SEARCH QELS FOR TCB MATCH M3864 03222020
         L     MINQCBRG,EIGHT(MINQCBRG) GET NEXT MINOR QCB        M3864 03224020
         LA    MINQCBRG,ZERO(MINQCBRG) CLEAR HIGH ORDER BYTE      M3864 03226020
         LTR   MINQCBRG,MINQCBRG       ANY MORE MINORS ?          M3864 03228020
         BZ    SETFLG                  NO ENQ'S ON PURGE RESOURCE M3864 03230020
         B     SRCHMIN1                                           M3864 03232020
         SPACE  1                                                 M3864 03234020
*        SEARCH QELS                                              M3864 03236020
SRCHQEL  L     QELREG,ZERO(MINQCBRG)   GET FIRST QEL              M3864 03237020
         USING QELSECT,QELREG          ADDR. QEL                  M3864 03238020
SRCHQEL1 L     SWORK1,QELTCB           GET QEL'S TCB              M3864 03239020
         LA    SWORK1,ZERO(SWORK1)     CLEAR HI ORDER BYTE        M3864 03240020
         CR    SWORK1,TCBREG           RESOURCE OWNED BY USER TCB M3864 03241020
         BE    SETDISP                 YES, SET TASK DISPATCHABLE M3864 03242020
         L     QELREG,QELNQEL          GET NEXT QEL               M3864 03243020
         LTR   QELREG,QELREG           ANY MORE QELS ?            M3864 03244020
         BZ    LSTCBTST                NO, GET NEXT TCB           M3864 03245020
         B     SRCHQEL1                TEST TCB MATCH             M3864 03246020
         SPACE 1                                                  M3864 03247020
SETDISP  NI    TCBNDSP2,D255-TCBNDTS   SET 2ND DISPATCHABLE       M3864 03247820
         NC    TCBSCNDY(THREE),TCBSCNDY ANY 2ND BITS SET ?        M3864 03248620
         BNZ   YESPRIM                 YES, LEAVE NONDISP         M3864 03249420
         NI    TCBFLGS5,D255-TCBPNDSP  MARK PRIM DISPATCHABLE     M3864 03250220
YESPRIM  LA    CNTREG,ONE(CNTREG)      BUMP CNT OF TASKS TO DISP  M3864 03251020
LSTCBTST CR    TCBREG,SWORK5           IS THIS LAST TCB ?         M3864 03251820
         L     TCBREG,TCBTCB           GET NEXT TCB               M3864 03252620
         BNE   SRCHQEL                 NO, SEARCH QELS            M3864 03253420
         SPACE 1                                                  M3864 03254220
*        TEST FOR EXIT FROM THIS ROUTINE                          M3864 03255020
         LTR   CNTREG,CNTREG           ARE THERE ANY TCB'S TO RUN M3864 03255820
         BZ    DEQUEUE                 NO, DEQ AND EXIT           M3864 03256620
         ENQ   (QNAME,RNAME,E,1,SYSTEM),RET=HAVE  ENQ ON PURGE RESOURCE 03257421
         B     SETNDSP                 GO SET ALL TASKS NONDISP.  M3864 03259020
         SPACE 2                                                        03259421
DEQUEUE  DEQ   (QNAME,RNAME,1,SYSTEM),RET=HAVE DEQ PURGE RESOURCE M3864 03259820
         SPACE 2                                                        03260221
SETFLG   EQU   *                                                  M3864 03260620
*   INTERFACE TO TSIP-  QUIESCE BEGINNING                               03261420
         SPACE 2                                                        03262220
         LH    ZEROREG,RCBTJID         SET UP FOR SVC TO TSIP           03263020
         TSEVENT  QSCEST,TJID=(0)      TELL TSIP QUIESCE HAS STARTED    03263820
         SPACE                                                          03264620
         LTR   PARMREG,PARMREG         CAN QUIESCE CONTINUE ?     M3864 03265420
         BZ    PRGIO                   YES, GO AROUND             M3864 03266220
         NI    TJBSTAT2,D255-TJBQUIS   TURN OFF QUIESCE STARTED   M3864 03267020
         MVI   RCBQUFLG,X00            RESET QUIESCE STARTED      M3864 03267820
         L     TJBXREG,TJBEXTNT        GET TJB EXTENSION          M3864 03268620
         L     SWORK5,TJBXLAST         GET LAST USER TCB          M3864 03269220
         L     TCBREG,TJBXFST          GET FIRST USER TCB         M3864 03269820
MARKDISP NI    TCBNDSP2,D255-TCBNDTS   SET 2ND DISPATCHABLE       M3864 03270420
         NC    TCBSCNDY(THREE),TCBSCNDY ANY 2ND BITS SET ?        M3864 03271020
         BNZ   YESPRIM1                YES, LEAVE NONDISP         M3864 03271620
         NI    TCBFLGS5,D255-TCBPNDSP  MARK PRIM DISPATCHABLE     M3864 03272220
YESPRIM1 CR    TCBREG,SWORK5           LAST USER ?                M3864 03272820
         L     TCBREG,TCBTCB           GET NEXT USER              M3864 03273420
         BNE   MARKDISP                NO, MARK NEXT              M3864 03274020
         BR    RTNREG                  RETURN                           03274620
         EJECT                                                          03275021
*  INTERFACE TO PURGE ROUTINE -                                         03275820
         SPACE 2                                                        03276420
*  SET UP POINTER TO QUIESCE I/O PARAMETER LIST (QPL) AND INITIALIZE    03277020
*     LIST                                                              03277620
*                                                                       03278021
*   THE QPL ENTRY FOR EACH USER TCB WILL LOOK LIKE                      03278121
*       1ST WORD -- TCB ADDRESS                                         03279021
*       2ND WORD -- IOB ADDRESS-0 FOR INPUT TO PURGE                    03281021
*                                                                       03281421
*   THE PARM LIST TO PURGE WILL CONSIST OF FOUR WORDS                   03281821
*       1ST WORD -- 0E000000  PURGE OPTIONS AS FOLLOW                   03282221
*                              PURGE  BY TCB LIST                       03282621
*                              PURGE ONLY IOS LOGICAL CHANNEL Q AND AEQ 03282721
*                              PURGE BY TCB                             03282821
*       2ND AND 3RD WORDS- ZERO                                         03283521
*       4TH WORD -- ADDRESS OF QPL                                      03283621
*                                                                       03283721
         SPACE 2                                                        03283821
PRGIO    EQU   *                       START OF PURGE I/O ROUTINE       03283921
         NI    TJBSTAT,D255-TJBINCOR   TURN OFF USER IN CORE BIT  M3864 03284821
         USING QPLSECT,XQPL            BASE FOR QPL                     03285721
         L     TJBXREG,TJBEXTNT        GET ADDR OF TJB EXTENSION        03286621
         L     XQPLW,TJBXQPL           ADDR OF QPL                      03287521
         LR    XQPL,XQPLW              SAVE ADDR QPL                    03288421
         SR    ZEROREG,ZEROREG         CLEAR REGISTER                   03289321
         L     TCBREG,TJBXFST          TOP USER TCB ON READY Q          03290221
         L     SWORK4,TJBXLAST         LAST OF USER'S TCBS ON READY Q   03291121
         SPACE 2                                                        03292021
GETTCB   EQU   *                       START OF NONDISPATCH RTN         03292921
         ST    TCBREG,QPLTCB           INIT QPL WITH TCB ADDRESS        03293821
         ST    ZEROREG,QPLIOB          INITIALIZE IOB FIELD TO ZERO     03294721
         CR    TCBREG,SWORK4           LAST USER TCB?                   03295621
         BE    GOPRGE                  YES, DEQ PURGE RESOURCE    M3864 03296521
         L     TCBREG,TCBTCB           GET NEXT USER TCB                03297421
         LA    XQPL,D8(XQPL)           GET NEXT ENTRY IN QPL            03298321
         B     GETTCB                  BRANCH TO INIT. THIS ENTRY       03299221
         SPACE                                                          03300121
GOPRGE   EQU   *                                                  M3864 03301021
         OI    QPLFLG,LSTENTRY         SET LAST EXTENT FLAG IN QPL      03301921
         MVI   RCBPRG,ZERO             ZERO 1ST BYTE PARAM LIST         03302821
         MVC   RCBPRG+D1(D15),RCBPRG   ZERO REST OF LIST                03303721
         MVI   RCBPRG,OPTIONS          SET PURGE I/O OPTIONS            03304621
         ST    XQPLW,RCBQPL            STORE ADDR-QUIESCE I/O P.L.      03305521
         LA    PARMREG,RCBPRG          SET UP REG FOR PURGE RTN         03306421
         SVC   16                      PASS CONTROL TO PURGE            03307321
         MVI   RCBQUFLG,X'C0'          INDICATE FIRST ENTRY TO PURGE    03308221
         TITLE 'TRANSIENT AREA PURGE'                                   03310020
         SPACE 2                                                        03320020
*   TRANSIENT AREA PURGE                                                03330020
         SPACE 4                                                        03340020
*********************************************************************** 03360020
*THIS ROUTINE PURGES ANY SVRB'S FOR THE SWAPPED USER FROM THE         * 03370021
*T/A REQUEST AND USER QUEUES                                          * 03380020
*                                                                       03382021
*     EACH TACT ENTRY LOOKS LIKE                                        03384021
*       1ST WORD -- DEFERRED(REQUEST) QUEUE                             03386021
*       2ND WORD -- USER QUEUE                                          03388021
*                                                                       03388421
*     THE THIRD WORD OF EACH USER SVRB ON THE USER QUEUE POINTS TO      03388821
*            THE NEXT SVRB OFF THE TACT ENTRY FOR THE T/A               03389221
*                                                                       03389621
*     ANY SVRB FOUND ON THE USER QUEUE FOR THE USER WE ARE QUIESCING    03389721
*        ARE THEN QUEUED OFF THE TJBX AS IF IT WERE THE TACT USER QUEUE 03389821
*        IF ANY SVRBS WERE USING A T/A THE SVRBS ARE PLACED IN A WAIT   03389921
*        VIA X'FF' WAIT COUNT.                                          03393221
*                                                                       03395221
*     ANY SVRBS FOUND ON THE DEFERRED QUEUE ARE DEQUEUED AND THEIR WAIT 03395621
*        COUNT ZEROED.                                                  03396021
*                                                                       03396421
*     IF ANY SVRBS HAVE BEEN DEQUEUED FROM A USER QUEUE A BRANCH ENTRY  03396521
*        IS MADE TO TRANSIENT AREA REFRESH                              03396621
*                                                                       03402421
*********************************************************************** 03408421
         SPACE 4                                                        03414221
TAPURG   EQU   *                       START OF TA PURGE ROUTINE        03420020
         XC    TJBXSVRB(D4),TJBXSVRB   CLEAR FIELD                      03440020
*                                      PT TO PURGE CHAIN FIELD AND SET  03450020
         LA    SWORK5,TJBXSVRB-D12     SWORK5 UP FOR INDEXING           03460020
TAPRGRST L     CVTREG,CVTPTR           ADDR CVT                         03470020
         USING CVTSECT,CVTREG          BASE FOR CVT                     03480020
         L     SCVTREG,CVTABEND        PTR TO SECONDARY CVT             03500020
         USING SCVTSECT,SCVTREG        BASE FOR SCVT                    03510020
         L     TACTSREG,SCVTTACT       ADDRESS OF TACT                  03520020
         L     TJBXREG,TJBEXTNT        ADDR USER'S TJBX                 03530020
         USING  TJBX,TJBXREG           BASE FOR TJBX                    03540020
         L     TCBREG,TJBXFST          FIRST TCB ON Q FOR THIS USER     03550020
         USING  TCB,TCBREG             BASE FOR TCB                     03560020
         C     TCBREG,TCBRBP           TASK HAVE RB              A67714 03560221
         BNE   GETRB                   YES                       A67714 03560421
         XC    TCBRBP,TCBRBP                                     A67714 03560621
GETRB    L     SVRBREG,TCBRBP          GET FIRST RB                     03570020
         USING RBSECT,SVRBREG          BASE FOR RB                      03580020
         LTR   SVRBREG,SVRBREG         IS IT ZERO                 M3812 03580420
         BZ    TCBMORE                 IF YES - BEING ABENDED - GET     03580820
*                                      NEXT TCB                         03580920
TESTNRES TM    RBSTAB,RBTRSVRB         IS IT ON NON RES SVRB      67714 03596221
         BO    RESVRB                  YES,GO CHECK IF IN A USER Q      03600020
RBMORE   TM    RBSTAB+BYTE,RBTCBNXT    MORE RB'S ON THUS Q              03610020
         BO    TCBMORE                 NO,GO SEE IF MORE TCB'S          03620020
         L     SVRBREG,RBLINK          NEXT RB                          03630020
         LA    SVRBREG,ZERO(SVRBREG)   CLEAR OUT WAIT COUNT             03640020
         B     TESTNRES                GO TEST FOR NON-RES SVRB         03650020
TCBMORE  C     TCBREG,TJBXLAST         WAS LAST TCB FOR USER PROCESSED  03660020
         BE    REQPURGE                YES, PROCESS REQUEST QUEUE       03670020
         L     TCBREG,TCBTCB           GET NEXT TCB ON READY Q          03690020
         B     GETRB                   BRANCH TO PROCESS NEXT RB        03700020
RESVRB   LH    ENTRYREG,RBTABNO        GET TAB NO                       03710020
         LTR   ENTRYREG,ENTRYREG       IS SVRB ON USER Q                03730020
         BE    RBMORE                  NO, GET NEXT RB                  03740020
         AR    ENTRYREG,TACTSREG       YES GET THIS TACT ENTRY          03750020
         L     SWORK1,D4(ENTRYREG)     START OF USER Q                  03760020
         LTR   SWORK1,SWORK1           Q. IS THERE A USER QUEUE  A43833 03764021
         BZ    RBMORE                  NO, BRANCH                A43833 03766021
         CR    SWORK1,SVRBREG          IS THIS THE SVRB TO BE PURGED    03770020
         BNE   NOTPURGE                NO, NOT USER'S                   03780020
         MVC   D4(WORD,ENTRYREG),RBSVTQN TAKE SVRB OFF Q          67714 03790021
NOTFIRST ST    SVRBREG,D12(SWORK5)     QUEUE SVRB OFF TJBX              03800020
DECREMEN LR    SWORK5,SVRBREG          UPDATE POINTER                   03810020
         L     SWORK2,SCVTAUCT         PT TO TA USER COUNT              03820020
         L     CODEREG,ZERO(SWORK2)    GET NO. TRANS.AREA USERS         03830020
         BCTR  CODEREG,ZEROREG         DECREMENT COUNT                  03840020
         ST    CODEREG,ZERO(SWORK2)    SAVE NEW COUNT                   03850020
         B     TABUSE                  SEE IF TAB IN USE                03860020
NOTPURGE LR    CODEREG,SWORK1          SAVE PRIOR SVRB ON QUEUE         03870020
         L     SWORK1,D12(SWORK1)      GET ADDR NEXT SVRB ON USER Q     03890020
         LTR   SWORK1,SWORK1           Q.IS THIS THE END OF Q    A43833 03892021
         BZ    RBMORE                  YES, GO GET NEXT SVRB     A43833 03894021
         CR    SWORK1,SVRBREG          HIT                              03900020
         BNE   NOTPURGE                NO,UPDATE TO NEXT                03910020
         MVC   D12(D4,CODEREG),RBSVTQN YES DEQUEUE FROM USER Q    67714 03920021
         B     NOTFIRST                GO QUEUE SVRB OFF TJBX           03930020
TABUSE   CLI   ZERO(ENTRYREG),X00      IS TAB IN USE?                   03940020
         BNE   RBMORE                  NO, GET NEXT RB ON Q             03950020
         CLC   D9(D3,ENTRYREG),RBSVTTR YES, WAS THIS SVRB USING TAB     03970020
         BNE   ANYUSE                  NO, GO SEE IF MORE ON Q          03980020
         CLI   RBWCF,TALLON          Q.REAL WAIT COUNT PREV. SAVED      03982020
         BE    ANYUSE                   YES                             03984020
         MVC   RBTAWCSA(BYTE),RBWCF    SAVE WAIT COUNT                  03990020
         MVI   RBWCF,TALLON            PLACE IN WAIT STATE              04000020
ANYUSE   L     CODEREG,D4(ENTRYREG)    TEST USER Q FOR MORE SVRBS       04010020
LASTSVRB LTR   CODEREG,CODEREG         USING TAB                        04020020
         BE    SETFREE                 NONE USING TAB, SET FREE         04030020
         CLC   D9(D3,ENTRYREG),D25(CODEREG)  THIS SVRB USING TAB?       04040020
         BE    RBMORE                  YES, PROCESS NEXT RB             04050020
         L     CODEREG,D12(CODEREG)    GET NEXT ON USER Q               04060020
         B     LASTSVRB                GO SEE IF SVRB USING TAB         04070020
SETFREE  MVI   ZERO(ENTRYREG),NOTINUSE SET TAB NOT IN USE               04080020
         B     RBMORE                  CHECK NEXT RB                    04100020
         SPACE 3                                                        04102021
*                                                                       04104021
*  SEARCH DEFERRED QUEUE AND REMOVE ALL SVRBS AND ZERO WAIT COUNT       04106021
*                                                                       04108021
         SPACE 1                                                        04108421
REQPURGE SR    SWORK1,SWORK1           PURGE THE REQUEST                04110020
         ST    SWORK1,D12(SWORK5)      SAVE SVRB POINTER                04120020
         L     SVRBREG,ZERO(TACTSREG)  REQUEST Q PTR                    04140020
         LTR   SVRBREG,SVRBREG         ANY QUEUE                        04150020
         BE    CHECKPUR                NO                               04160020
         ST    SWORK1,ZERO(TACTSREG)   YES, ZERO TACT REQ Q PTR         04170020
PURGEIT  MVI   RBWCF,ZERO              ZERO WAIT COUNT                  04180020
         L     SWORK2,RBSVTQN          GET NEXT POINTER           67714 04190021
         ST    SWORK1,RBSVTQN          ZERO POINTER               67714 04200021
         LTR   SVRBREG,SWORK2          MORE ON QUEUE ?                  04210020
         BNE   PURGEIT                 YES                              04220020
CHECKPUR L     SWORK1,TJBXSVRB         HEAD OF PURGED SVRB QUEUE        04230020
         LTR   SWORK1,SWORK1           WERE ANY SVRBS PURGED FROM USER  04240020
         BE    EXIT                    NO, EXIT                         04250020
         SPACE 3                                                        04252021
*                                                                       04254021
*  TAKE BRANCH ENTRY TO T/A REFRESH IF ANY SVRBS ON USER QUEUE          04256021
*                                                                       04258021
         SPACE 1                                                        04258421
         L     TCBREG,RCBRCT           YES, SET UP TO CALL TRANSIENT    04260020
         L     SVRBREG,TCBRBP          AREA REFRESH ROUTINE             04270020
         MVC   RBOPSW(D8),RETPSW       SET OLD PSW TO RETURN POINT      04280020
         STM   ZERO,CODEREG,TCBGRS     SAVE REGISTERS                   04290020
         L     CVTREG,CVTPTR           GET CVTPTR                       04300020
         USING CVTSECT,CVTREG          BASE FOR CVT                     04310020
         L     CVTREG,CVTABEND         ADDR SECONDARY CVT               04320020
         USING  SCVTSECT,CVTREG        BASE FOR SCVT                    04330020
         L     EXITEFRG,SCVTTAR        ADDR TRANS AREA REFRESH RTN      04340020
         BR    EXITEFRG                GO TO TRANS AREA REFRESH RTN     04360020
REFRESHD L     CVTREG,CVTPTR           FIND TCB TO RESTORE REGS         04370020
         USING CVTSECT,CVTREG          BASE FOR CVT                     04390020
         L     SWORK1,CVTTCBP          ADDR NEW/OLD                     04400020
         L     TCBREG,D4(SWORK1)       ADDR CURRENT TCB                 04410020
         LM    ZERO,CODEREG,TCBGRS     RESTORE REGISTERS                04420020
EXIT     MVI   RCBQUFLG,X'E0'          TA QUIESCED                      04440020
         DROP  SVRBREG                 DROP RB BASE REGISTER            04441020
         TITLE 'PURGE WTOR REPLIES'                                     04450020
*********************************************************************** 04460020
* PURGE  WTOR REPLIES                                                 * 04470020
*                                                                     * 04480020
* THE FOLLOWING CODE MARKS REPLY QUEUE ELEMENTS FOR THE USER TO BE    * 04490020
* SWAPPED OUT . WHEN REPLIES ARE RECEIVED BEFORE THE TASK IS SWAPPED  * 04500020
* IN, A TEMPORARY BUFFER IS OBTAINED TO HOLD THE REPLY. THE RQE IS    * 04510020
* FLAGGED AS FOLLOWS :                                                * 04520020
*                                                                     * 04530020
* 1) FLAG  RQERO IS SET IN RQEXA                                      * 04540020
* 2) THE USER TJID IS MOVED INTO THE RQETJID FIELDS                   * 04550020
*                                                                     * 04560020
* INPUT- REGISTER 11 (RCBREG)       ADDRESS OF RCB                    * 04570020
*        REGISTER 12 (TJBREG)       ADDRESS OF TJB                    * 04571020
*                                                                     * 04580020
* OUTPUT - NONE                                                       * 04590020
*                                                                     * 04600020
*********************************************************************** 04610020
         SPACE 2                                                        04611020
WTORPRGE EQU   *                       START OF WTOR PURGE ROUTINE      04630020
         L     CVTREG,CVTPTR           CVT ADDR                         04650020
         USING CVTSECT,CVTREG          BASE FOR CVT                     04660020
*                                      GET ADDRESS OF TABLE TO CONSOLE  04670020
         L     SRQEREG,CVTCUCB         UNIT CONTROL BLOCKS              04680020
         USING UCM,SRQEREG             BASE FOR UCM                     04690000
         L     SWORK2,UCMWTOQ          PT TO WQE CHAIN                  04700020
         USING WQE,SWORK2              BASE FOR WQE                     04710020
         L     SRQEREG,UCMRPYQ         GET REPLY QUEUE ORIGIN           04720020
SWTOPRG1 LTR   SRQEREG,SRQEREG         ANY (MORE) RQES ON THE QUEUE     04730020
         BZ    OUT                     NO, BRANCH TO NEXT RTN           04740020
         DROP  SRQEREG                 DROP ADDRESSABILITY ON UCM       04750000
         USING  RPQESECT,SRQEREG       BASE FOR REPLY QUEUE ELEMENT     04760020
         TM    RPQEXA,RPQEPRGE+RPQECANM+RPQESWAP   IS RPQE TO  A46413   04772000
*                                 BE PURGED,SWAPED OR CANCELLED A46413  04774000
         BNZ   SWTOPRG2                YES, GO FIND NEXT RQE            04780020
         L     TCBREG,RPQETCB          ACCESS TCB ADDR IN RPQE          04800020
         USING  TCB,TCBREG             BASE FOR TCB                     04810020
         L     SWORK4,TCBJSCB          PTR TO JSCB                      04820020
         USING  IEZJSCB,SWORK4         BASE FOR JSCB                    04830020
*                                      DOES THIS TCB BELONG TO USER     04840020
         CLC   JSCBTJID(D2),RCBTJID    BEING QUIESCED?                  04850020
         BNE   SWTOPRG2                NO, FIND NEXT RQE                04860020
         CLC   JSCBTJID(D2),ZEROMASK   IS TJID 0                        04870020
         BNZ   SWTOPR1A                NOT ZERO, INSERT TJID            04880020
         TM    TCBTSFLG,TCBTSTSK       ZERO, IS THIS TS TASK            04890020
         BNO   SWTOPRG2                NO, GO GET NEXT ELEMENT          04900020
SWTOPR1A MVC   RPETJID1(D1),RCBTJID    MARK RPQE WITH                   04910020
         MVC   RPETJID2(D1),RCBTJID+BYTE  USER'S TJID                   04940020
         OI    RPQEXA,RQERO            SET ROLLED OUT FLAG              04950020
SWTOPRG2 L     SRQEREG,RPQELKP         GET NEXT RPQE ON QUEUE           04960020
         B     SWTOPRG1                GO TEST IF MORE                  04970020
         DROP  TCBREG                  DROP ADDRESSABILITY OF TCB       04970420
OUT      L     SWORK6,CVTCUCB          UNIT CONTROL BLOCKS              04970820
         USING UCM,SWORK6              ADDRESSABILITY OF UCB            04971220
         TM    UCMMODE,MCSINSYS        IS MCS IN SYSTEM                 04971620
         BO    OUT2                    YES BYPASS PUTTING TJID'S IN WQE 04971720
         DROP  SWORK6                  DROP ADDRESSABILITY ON UCB       04971820
         USING TCB,TCBREG              SET UP ADDRESSABILITY ON TCB     04971920
         LA    SWORK2,ZERO(SWORK2)     CLEAR MCS COUNT FIELD      M2202 04972020
         LTR   SWORK2,SWORK2           ANY WQE'S                        04980020
         BZ    OUT2                    NO                               04990020
         L     TCBREG,WQETCB           GET TCB ADDR IN WQE              05000020
         LTR   TCBREG,TCBREG           ANY TCB'S                        05010020
         BZ    NEXTWQE                 NO                               05020020
         CLC   WQETJID1(D2),ZEROMASK    THIS WQE QUIESCED?        M3877 05030020
         BNZ   NEXTWQE                 YES, GET NEXT WQE                05040020
         L     SWORK4,TCBJSCB          GET JSCB ADDR                    05050020
         USING IEZJSCB,SWORK4          BASE FOR JSCB                    05060020
         CLC   JSCBTJID(D2),RCBTJID    THIS TCB BELONG TO USER?         05070020
         BNE   NEXTWQE                 NO                               05080020
         CLC   JSCBTJID(D2),ZEROMASK   IS TJID 0                        05090020
         BNZ   WQEPRG1                 NOT ZERO, INSERT TJID            05100020
         TM    TCBTSFLG,TCBTSTSK       ZERO, IS THIS TS TASK            05110020
         BNO   NEXTWQE                 NO, GO GET NEXT ELEMENT          05120020
WQEPRG1  MVC   WQETJID1(D2),RCBTJID    MOVE IN USER'S TJID              05130020
NEXTWQE  L     SWORK2,WQELKP           PTR TO NEXT WQE                  05140020
         B     OUT                     CHECK FOR MORE WQE'S             05150020
OUT2     MVI   RCBQUFLG,X'F0'          WTOR PROCESSING DONE             05170020
         TITLE 'REENTRY TO I/O PURGE'                                   05170420
*********************************************************************** 05172020
*  TEST WHETHER REENTRY TO I/O PURGE IS NECESSARY AND IF SO,          * 05174020
*  ISSUE THE SVC.                                                     * 05176020
*********************************************************************** 05178020
         SPACE 2                                                        05178420
PRGEOVER TM    RCBQPL,PRGFENT          IS REENTRY TO PREAMBLE NECC.     05179220
         BZ    Q20FF                   NO, SKIP PURGE                   05179620
         LA    SWORK1,RCBPRG           GET PURGE PARAMETER LIST ADDR    05179720
         SPACE 2                                                        05179820
         SVC  16                       REENTER PURGE I/O RTN            05179920
         SPACE 2                                                        05189420
Q20FF    MVI   RCBQUFLG,X'F4'          INDICATE I/O PURGED              05189820
         TITLE 'ENQUEUE PURGE'                                          05201520
*********************************************************************** 05211020
*                                                                     * 05220520
*  TITLE- ENQUEUE PURGE                                               * 05230020
*                                                                     * 05239520
*  FUNCTION- THIS ROUTINE FLAGS TS USER'S REQUESTS FOR SYSTEM         * 05249020
*            RESOURCES (QEL'S) AS BELONGING TO A SWAPPED-OUT USER     * 05258520
*                                                                     * 05268020
*                                                                     * 05277520
*  ENTRY POINT- TENQPRGE                                              * 05287020
*                                                                     * 05296520
*  INPUT- ADDRESS OF RCB FOR THIS REGION IN REGISTER 11               * 05306020
*         ADDRESS OF TJB FOR THIS USER IN REGISTER 12                 * 05315520
*                                                                     * 05325020
*********************************************************************** 05334520
         SPACE                                                          05344020
TENQPRGE EQU   *                       START OF QEL PURGE               05363020
         USING QELSECT,QELREG          BASE FOR QEL                     05372520
*********************************************************************** 05382020
*                                                                       05391520
*  THIS ROUTINE DETERMINES IF USER HAS OUTSTANDING REQUESTS             05401020
*  BY SEARCHING MAJOR AND MINOR QCB'S FOR QEL'S BELONGING TO USER.      05410520
*                                                                       05420020
*********************************************************************** 05429520
         SPACE                                                          05439020
TQELSRCH L     TJBXREG,TJBEXTNT        GET ADDR TJBX                    05448520
         L     TCBREG,TJBXFST          ADDR USER'S FIRST TCB            05458020
         USING TCB,TCBREG              BASE FOR TCB                     05467520
TQELCTCK CLI   TCBQEL,ZERO             ANY QEL'S                        05477020
         BE    TNXTCB                  NO, CHECK NEXT TCB               05486520
         SPACE                                                          05496020
*  TCB HAS OUTSTANDING RESOURCE REQUESTS SO MUST FIND QEL'S             05505520
         SPACE                                                          05515020
         SR    QELCTREG,QELCTREG       CLEAR QEL COUNT REG              05524520
         IC    QELCTREG,TCBQEL         GET QEL COUNT                    05534020
         L     CVTREG,CVTPTR           ADDR CVT                         05543520
         L     SCVTREG,CVTABEND        ADDR OF SECONDARY CVT            05553020
         USING SCVTSECT,SCVTREG        BASE FOR SCVT                    05562520
         L     MJQCBREG,SCVTQCBO       ADDR OF DUMMY QCB                05572020
         L     MJQCBREG,ZERO(MJQCBREG) GET ADDR OF FIRST MAJOR QCB      05581520
TMNQBADR L     MIQCBREG,MINQCB(MJQCBREG)     ADDR OF MINOR QCB          05591020
TQELADDR L     QELREG,MINQEL(MIQCBREG) ADDR OF QEL                      05600520
TQELCHCK L     TWKREG1,QELTCB          GET QEL'S TCB ADDR         M3877 05609520
         CR    TWKREG1,TCBREG          THIS QEL BELONG TO USER          05620020
         BE    TESTPRGE                YES                              05630020
TNXTQEL  L     QELREG,QELSMC           ADDR OF NEXT QEL                 05640020
         LA    QELREG,ZERO(QELREG)     CLEAR QEL STATUS BYTE            05650020
         LTR   QELREG,QELREG           LAST QEL IN THIS CHAIN           05660020
         BNZ   TQELCHCK                NO                               05670020
         L     MIQCBREG,MINQCB(MIQCBREG)     GET ADDR OF NEXT MINOR QCB 05680020
         LA    MIQCBREG,ZERO(MIQCBREG) CLEAR HI ORDER BYTE         4640 05690020
         LTR   MIQCBREG,MIQCBREG       LAST MINOR QCB IN THIS CHAIN     05700020
         BNZ   TQELADDR                NO                               05710020
         L     MJQCBREG,NEXTMAJ(MJQCBREG)    NEXT MAJOR QCB ADDR        05720020
         LTR   MJQCBREG,MJQCBREG       LAST MAJOR QCB                   05740020
         BNZ   TMNQBADR                NO                               05750020
         B     TFINISH                 YES                              05760020
TNXTCB   L     TWKREG1,TJBXLAST        ADDR USER'S LAST TCB             05770020
         CR    TWKREG1,TCBREG          ARE ALL TCB'S CHECKED            05780020
         BE    TFINISH                 YES                              05790020
         L     TCBREG,TCBTCB           NEXT TCB ON READY QUEUE          05800020
         B     TQELCTCK                GO CHECK NEXT QEL                05820020
TESTPRGE MVC   QELTJID1(D1),RCBTJID    FLAG QEL WITH                    05830020
         MVC   QELTJID2(D1),RCBTJID+BYTE TJID OF USER                   05840020
         OI    QELTJID1,HIBITON        SET HI ORDER BIT ON              05850020
TQELDEC  BCT   QELCTREG,TNXTQEL        DECREMENT QEL COUNT              05870020
         B     TNXTCB                  GET NEXT TCB IF COUNT ZERO       05880020
TFINISH  MVI   RCBQUFLG,X'FC'          INDICATE QEL PROCESSING DONE     05900020
         SPACE 1                                                        05920020
         TITLE 'TCB READY QUEUE PURGE'                                  06060020
*********************************************************************** 06070020
*                                                                     * 06080020
*  TITLE- TS USER'S TCB READY QUEUE PURGE                             * 06090020
*                                                                     * 06100020
*  FUNCTION- DEQUEUE A TIME SHARING USER'S TCBS FROM THE READY QUEUE  * 06110020
*                                                                     * 06120020
*  ENTRY POINT- TRDYQPRG                                              * 06130020
*                                                                     * 06140020
*  INPUT- ADDRESS OF RCB FOR THIS REGION IN REGISTER 11               * 06150020
*         ADDRESS OF TJB FOR THIS USER IN REGISTER 12                   06160020
*                                                                     * 06170020
*********************************************************************** 06180020
         SPACE 2                                                        06190020
TRDYQPRG EQU   *                                                        06222020
         L     TJBXREG,TJBEXTNT        ADDR TJB EXTENT                  06230020
         L     TJBFSTRG,TJBXFST        ADDR USER'S FIRST TCB            06240020
         L     TJBLSTRG,TJBXLAST       ADDR USER'S LAST TCB             06250020
         SPACE 2                                                        06260020
*   THIS ROUTINE WILL SEARCH THE TCB READY QUEUE LOOKING FOR            06270020
*   THIS USER'S TCB                                                     06280020
         SPACE 2                                                        06290020
         DROP  TCBREG                  DROP TCB                         06300020
         USING TCB,TCBLSTRG            BASE FOR TCB                     06310020
*                                      ADDR OF RCT'S TCB - STARTING     06320020
         L     TCBLSTRG,RCBRCT         POINT FOR TCB SEARCH             06330020
         XC    TCBLTC(WORD),TCBLTC     CLEAR DAUGHTER POINTER           06340020
TONSRCH  L     TCBREG,TCBTCB           ADDR NEXT TCB                    06350020
         CR    TCBREG,TJBFSTRG         THIS TCB BELONG TO USER?         06360020
         BE    TFOUND                  YES                              06370020
         LTR   TCBLSTRG,TCBREG          SAVE PREV TCB ADDR.             06380020
         BZ    TNOTFOU                  MAY NOT BE ON RETRY             06390020
         B     TONSRCH                 CONTINUE SEARCH                  06400020
         SPACE 2                                                        06410020
*   USER'S TCB GROUP FOUND. DEQUEUE FROM READY QUEUE                    06420020
         SPACE 1                                                        06430020
TFOUND   MVC   TCBTCB(WORD),TCBNXT(TJBLSTRG)   TCBS DEQUEUED            06440020
TNOTFOU  EQU   *                                                        06450020
         DROP  TCBLSTRG          DROP BASE FOR TCB                      06470020
         TITLE 'STORAGE MAP BUILD'                                      06480020
*********************************************************************** 06500020
*THIS ROUTINE BUILDS THE STORAGE MAP REQUIRED BY SWAP TO ROLL OUT     * 06510020
*THE USED   PARTS OF THE REGION. AS THE MAP IS OF FIXED SIZE, IT IS   * 06520020
*DETERMINED IF ANY FBQES SHALL HAVE TO BE SWAPPED. THE NUMBER OF FBQES* 06530020
*NOT SWAPPED IS EQUAL TO THE NUMBER OF MAP ENTRIES MINUS ONE.  ANY    * 06540020
*FBQES SWAPPED OUT ARE QUEUED TO THE PQE FBQE POINTER (PQEFFBQE) AND  * 06550020
*THE FBQE FORWARD POINTER (FWDPTR)                                    * 06560020
*********************************************************************** 06580020
         SPACE 4                                                        06590020
*********************************************************************** 06600020
*THIS PART OF THE ROUTINE DETERMINES THE LARGEST FBQES OF THE REGION, * 06610020
*POINTS TO THEM BY USE OF THE MAP IF FBQE'S ARE TO BE SWAPPED.IF ONLY * 06620020
*ONE MAP ENTRY IS REQUIRED,THIS ROUTINE MAKES THE ENTRY               * 06630020
*********************************************************************** 06650020
         SPACE 4                                                        06660020
FBQEFIND EQU   *                                                        06700020
         L     UMSMREG,TJBUMSM         ADDR OF STORAGE MAP              06710020
         L     TCBREG,TJBXFST          GET JOB STEP TCB ADDR            06720020
         USING  TCB,TCBREG             BASE FOR TCB                     06730020
         USING UMSM,UMSMREG            BASE FOR UMSM                    06740020
         L     SPQEREG,TCBPQE          ADDRESS OF DUMMY PQE             06750020
         L     SPQEREG,D8(SPQEREG)     ADDR PQE FOR REGION              06760020
         LR    SWORK4,SPQEREG          SET UP PQE BASE REGISTER         06770020
         USING PQESECT,SWORK4          BASE FOR PQE                     06780020
         L     SWORK2,PQEREGN          GET ADDR USER REGION             06790020
         L     SWORK5,PQESIZE          GET SIZE USER REGION             06800020
         AR    SWORK5,SWORK2           GET ADDR 1ST 2K BLOCK PAST REG   06810020
         L     CODEREG,TJBXKEYA        GET ADDR STORAGE KEY SAVE AREA   06820020
         SR    SWORK1,SWORK1           INIT REGISTER                    06830020
SAVEKEY  ISK   SWORK1,SWORK2           GET STORAGE KEY THIS 2K BLOCK    06840020
         STC   SWORK1,ZERO(CODEREG)    SAVE KEY IN SAVE AREA            06850020
         LA    SWORK2,TWOK(SWORK2)     UPDATE TO NEXT 2K BLOCK          06860020
         CR    SWORK5,SWORK2           BEYOND REGION?                   06870020
         BE    MAPREGN                 CONTINUE REST OF QUIESCE         06880020
         LA    CODEREG,BYTE(CODEREG)   UPDATE SAVE AREA ADDRESS         06890020
         B     SAVEKEY                 CONTINUE TO SAVE KEYS            06900020
MAPREGN  SR    SWORK1,SWORK1           INIT FBQE COUNT REG              06910020
         CL    SPQEREG,PQEFFBQE        ARE THERE ANT FBQES              06920020
         BNE   SCOMPUTE                YES,GO FIND WHICH NOT TO SWAP    06930020
MAPONE   L     SWORK1,PQEREGN          BUILD ONE ENTRY IN MAP-REGION @  06940020
         SRL   SWORK1,D8               ELIMINATE LOW ORDER BYTE         06960020
         STH   SWORK1,UMSMBG           STORE INTO MAP                   06970020
         L     SWORK1,PQESIZE          SIZE OF REGION                   06980020
         SRL   SWORK1,D8               ELIMINATE LOW ORDER BYTE         06990020
         STH   SWORK1,UMSMLN           STORE INTO MAP                   07000020
MAPONEA  CLI   TJBUMSMN,ONE            MORE ENTRIES?                    07010020
         BE    ROUT                    NO, CONTINUE QUIESCE PROCESSING  07020020
         XC    D4(WORD,UMSMREG),D4(UMSMREG)  YES,ZERO NEXT ENTRY        07030020
         B     ROUT                    CONTINUE QUIESCE PROCESSING      07040020
SCOMPUTE LA    SWORK1,D1(SWORK1)       BEGIN FBQE COUNT                 07050020
         L     SFBQEREG,PQEFFBQE       ADDR OF FIRST FBQE               07060020
         USING FBQESECT,SFBQEREG       BASE FOR FBQE                    07070020
FBQLOOP  L     SFBQEREG,FWDPTR         GET NEXT POINTER                 07080020
         LA    SFBQEREG,ZERO(SFBQEREG) CLEAR HI ORDER BYTE              07090020
         CR    SPQEREG,SFBQEREG        WAS IT LAST ONE                  07100020
         BE    HIGHFREE                YES, CHECK TOP ALLOCATION        07110020
         LA    SWORK1,D1(SWORK1)       NO ADD ONE TO COUNT              07120020
         B     FBQLOOP                 GO GET NEXT                      07130020
HIGHFREE STC   SWORK1,RCBFBQE          SAVE NO. FBQES FOR REFERENCE     07140020
         L     SFBQEREG,4(SFBQEREG)    PT TO LAST FBQE                  07150020
         A     SFBQEREG,SIZE           ADDR LAST FREE BYTE              07160020
         L     SWORK2,PQEREGN          GET ADDR BEG REGION              07170020
         A     SWORK2,PQESIZE          ADDR LAST BYTE REGION            07180020
         CR    SWORK2,SFBQEREG         EQUAL?                           07190020
         BNE   ENDSEAR                 NO, TOP OF REGION ALLOCATED      07200020
         L     SPQEREG,D4(SPQEREG)     PT TO LAST FBQE TO USE AS STOP   07210020
         CLI   TJBUMSMN,ONE            ONE MAP ENTRY?                   07220020
         BNE   BEGSRCH                 NO, MUST SEARCH FBQE CHAIN       07230020
         L     SWORK1,PQEREGN          YES, DETERMINE HOW               07240020
         SRL   SWORK1,D8               MUCH OF REGION                   07250020
         STH   SWORK1,UMSMBG           TO SWAP                          07260020
         L     SWORK1,PQESIZE          GET REGION SIZE FROM PQE         07270020
         L     SFBQEREG,D8(SPQEREG)    SIZE OF TOP FBQE                 07280020
         SR    SWORK1,SFBQEREG         SWAP REGION EXCEPT FOR TOP       07290020
         SRL   SWORK1,D8               FREE AREA                        07300020
         STH   SWORK1,UMSMLN           STORE LENGTH IN MAP              07310020
         B     MAPONEA                 GO CHECK MAP ENTRIES             07320020
ENDSEAR  CLI   TJBUMSMN,ONE            IF ONLY ONE MAP ENTRY AVAILABLE  07330020
         BE    MAPONE                  GO BUILD ONE ENTRY               07340020
BEGSRCH  EQU   *                       *                                07341020
         SR    SWORK1,SWORK1           ELSE, FIND FBQES NOT TO SWAP     07360020
         IC    SWORK1,TJBUMSMN         NUMBER OF AVAILABLE ENTRIES      07370020
         BCTR  SWORK1,ZEROREG          NUMBER OF FBQES NOT SWAPPED      07380020
         L     SFBQEREG,PQEFFBQE       ADDDRESS OF FIRST FBQE           07390020
STOREFBQ ST    SFBQEREG,UMSMBG         INTO STORAGE MAP                 07400020
         CL    SPQEREG,FWDPTR          MORE FBQES ?                     07410020
         BNE   NEXTFBQE                GO GET NEXT FBQE                 07420020
         XC    D4(WORD,UMSMREG),D4(UMSMREG) ELSE ZERO NEXT ENTRY AND    07430020
*                                      ZERO FIRST WORD PQE FOR CHAIN    07440020
         XC    PQEFFBQE(WORD),PQEFFBQE TO SAVE ADDR SWAPPED FBQES       07450020
         B     MAPBUILD                GO TO BUILD MAP                  07460020
NEXTFBQE L     SFBQEREG,FWDPTR         NEXT FBQE                        07470020
         LA    UMSMREG,UMSMEND         ADDR NEXT MAP ENTRY              07490020
         BCT   SWORK1,STOREFBQ         MORE TO DO, GO STORE INTO MAP    07500020
         XC    ZERO(WORD,UMSMREG),ZERO(UMSMREG)  CLEAR NEXT MAP ENTRY   07510020
SEARCHLO L     UMSMREG,TJBUMSM         GET BEGINNING ADDR OF MAP        07520020
         L     SWORK1,UMSMBG           ADDRESS OF FBQE INTO REG         07530020
MAPNEXT  LA    SWORK3,UMSMEND          NEXT MAP ENTRY                   07540020
FBQENEXT L     SWORK2,ZERO(SWORK3)     ADDR OF FBQE                     07550020
         LTR   SWORK2,SWORK2           IS THERE AN FBQE                 07560020
         BE    INSERT                  NO, GO SEE IF NEW FBQE LARGER    07570020
         CLC   D9(D3,SWORK1),D9(SWORK2) WHICH FBQE SIZE IS SMALLER?     07580020
         BL    KEEPTHIS                FIRST ONE SMALLER                07590020
         LR    UMSMREG,SWORK3          EVEN OR 2ND SMALLER: KEEP        07600020
         LR    SWORK1,SWORK2           POINTERS TO THIS ONE:MAP + FBQE  07610020
         B     MAPNEXT                 GO GET NEXT FBQE                 07620020
KEEPTHIS LA    SWORK3,D4(SWORK3)       GET POINTER TO NEXT ENTRY        07650020
         B     FBQENEXT                CHECK FOR ANOTHER FBQE           07660020
INSERT   CLC   D9(D3,SFBQEREG),D9(SWORK1) NEW FBQE LARGER?              07670020
         BH    NEWHIGH                 YES,GO PUT INTO MAP              07680020
         CL    SPQEREG,FWDPTR          MORE FBQES                       07700020
         BE    SWAPQUE                 NO                               07710020
         L     SFBQEREG,FWDPTR         YES GET NEXT FBQE                07720020
         B     INSERT                  YES  COMPARE SIZE                07730020
NEWHIGH  L     SWORK2,D4(UMSMREG)      GET CONTENTS OF NEXT ENTRY       07740020
         LTR   SWORK2,SWORK2           IS IT ZERO                       07760020
*                                      YES,GO INSERT FBQE               07770020
         BE    NEWENTER                PRIOR TO LAST                    07780020
         MVC   ZERO(WORD,UMSMREG),D4(UMSMREG)  NO, MOVE ENTRY INTO MAP  07790020
         LA    UMSMREG,UMSMEND         UPDATE PTR TO NEXT ENTRY         07800020
         B     NEWHIGH                 GO GET CONTENTS OF NEXT ENTRY    07810020
NEWENTER ST    SFBQEREG,ZERO(UMSMREG)  STORE NEW ENTRY INTO MAP         07820020
         CL    SPQEREG,FWDPTR          ANOTHER FBQE                     07840020
         BE    SWAPQUE                 NO,GO TO REQUEUE FBQES           07850020
         L     SFBQEREG,FWDPTR         GET ADDR NEXT FBQE               07860020
         B     SEARCHLO                FIND SMALLEST FBQE IN MAP        07870020
         EJECT                                                          07880020
*********************************************************************** 07890020
*THIS PART OF THE ROUTINE QUEUES THE FBQES TO BE SWAPPED OUT AS       * 07900020
*FOLLOWS :                                                            * 07910020
*   HEAD OF QUEUE IS PQEFFPQE                                         * 07920020
*   CHAIN FIELD IN FBQE IS FWDPTR                                     * 07930020
*   LAST FBQE CHAIN FIELD = ADDRESS OF PQE                            * 07940020
*********************************************************************** 07950020
         SPACE 4                                                        07960020
SWAPQUE  L     UMSMREG,TJBUMSM         ADDR OF MAP                      07980020
         L     SWORK4,TCBPQE           MAKE SURE HAVE PQE ADDRESS       08000020
         L     SWORK4,D8(SWORK4)       GET FBQE LAST                    08010020
         LR    SWORK1,SWORK4           SAVE ADDRESS                     08020020
         L     SWORK2,PQEFFBQE         NEXT FBQE NOT SWAPPED            08030020
         L     SWORK3,ZERO(UMSMREG)    NEXT FBQE NOT TO BE SWAPPED      08040020
TESTQUEU CR    SWORK2,SWORK3           CHECK FOR LOW                    08050020
         BNL   UPDATE                  NOT LOW ADVANCE POINTER(S)       08060020
         ST    SWORK2,ZERO(SWORK1)     IF LOW ENTER INTO SWAP QUEUE     08070020
         LR    SWORK1,SWORK2           UPDATE QUEUING REG               08080020
         CL    SPQEREG,ZERO(SWORK2)    MORE FBQES?                      08090020
         BE    FINISHQU                NO, FINISH QUEUE                 08100020
         L     SWORK2,ZERO(SWORK2)     YES, GET NEXT FBQE               08110020
         B     TESTQUEU                GO CHECK FOR LOW                 08120020
UPDATE   CL    SPQEREG,ZERO(SWORK2)    MORE FBQES?                      08130020
         BE    FINISHQU                NO, FINISH QUEUE                 08140020
         L     SWORK2,ZERO(SWORK2)     GET NEXT FBQE                    08160020
         LA    UMSMREG,UMSMEND         GET NEXT MAP ENTRY               08170020
*                                      GET ADDR OF FBQE TEMP STORED     08180020
         L     SWORK3,ZERO(UMSMREG)    IN MAP                           08190020
         LTR   SWORK3,SWORK3           MAP ENTRY?                       08200020
         BNE   TESTQUEU                YES, GO BACK THRU COMPARE        08210020
SWAPLAST ST    SWORK2,ZERO(SWORK1)     REMAINING FBQES TO BE SWAPPED    08220020
         LR    SWORK1,SWORK2           QUEUED TO SWAP QUEUE             08230020
         CL    SPQEREG,ZERO(SWORK2)    MORE TO DO?                      08240020
         BE    FINISHQU                NO                               08250020
         L     SWORK2,ZERO(SWORK2)     YES GET NEXT ONE                 08260020
         B     SWAPLAST                BRANCH TO QUEUE                  08270020
DONTSWAP SR    SPQEREG,SWORK2          LENGTH REMAINING AREA TO SWAP    08280020
         SRL   SPQEREG,D8              SHAPE FOR MAP                    08290020
         STH   SPQEREG,UMSMLN          MOVE LENGTH INTO MAP             08300020
         B     LASTSTOR                GO STORE LAST ENTRY              08310020
FINISHQU ST    SWORK4,ZERO(SWORK1)     PTR TO PQE INTO LAST OF Q        08320020
      EJECT                                                             08340020
*********************************************************************** 08350020
*THIS PART OF THE ROUTINE BUILDS THE STORAGE MAP FOR THE SWAP ROUTINE * 08360020
*********************************************************************** 08380020
         SPACE 4                                                        08390020
MAPBUILD SR    SWORK1,SWORK1           INITIALIZE REGISTERS             08410020
         IC    SWORK1,TJBUMSMN         REG 1 = NO. MAP ENTRIES          08420020
         L     UMSMREG,TJBUMSM         REG 7 = ADDR OF MAP              08430020
*                                      REG6 = ADDRESS OF 1ST NON-SWAP   08440020
         L     SFBQEREG,UMSMBG         FBQE                             08450020
         L     SWORK2,PQEREGN          REG2 = START OF REGION           08460020
MAPENTRY LR    SWORK3,SFBQEREG         GET SIZE OF                      08470020
         SR    SWORK3,SWORK2           AREA TO BE                       08480020
         SRL   SWORK3,D8               SWAPPED AND                      08490020
         STH   SWORK3,UMSMLN           STORE INTO MAP                   08500020
         SRL   SWORK2,D8               ADDRESS OF SWAP AREA             08510020
         STH   SWORK2,UMSMBG           INTO MAP                         08520020
         BCTR  SWORK1,ZEROREG          REDUCE NUM.OF MAP ENTRIES LEFT   08530020
         LR    SWORK2,SFBQEREG         COMPUTE ADD OF NEXT SWAP AREA=   08540020
*                                      ADDRESS OF FBQE NOT SWAPPED +    08550020
         A     SWORK2,SIZE             SIZE                             08560020
         LA    UMSMREG,UMSMEND         POINT TO NEXT MAP ENTRY          08570020
         L     SFBQEREG,UMSMBG         GET NEW ENTRY                    08580020
         LTR   SFBQEREG,SFBQEREG       TEST FOR MORE FBQES              08590020
*                                      IF MORE FBQES, MAKE ANOTHER      08600020
         BNE   MAPENTRY                ENTRY                            08610020
*                                      IF EQUAL TOP OF REGION           08620020
         CR    SPQEREG,SWORK4          IS ALLOCATED                     08630020
         BNE   DONTSWAP                NOT EQUAL,SUBTRACT LAST FBQE SIZ 08640020
         L     SPQEREG,PQEREGN         LAST ENTRY.COMPUTE ENDING ADDR   08650020
         A     SPQEREG,PQESIZE         OF REGION. COMPUTE SIZE OF ENTRY 08660020
         SR    SPQEREG,SWORK2          STORE INTO MAP.                  08670020
         SRL   SPQEREG,D8              SET UP LENGTH FOR STORE          08680020
         STH   SPQEREG,UMSMLN          STORE LENGTH INTO MAP            08690020
LASTSTOR SRL   SWORK2,D8               SHAPE FOR MAP ENTRY              08700020
         STH   SWORK2,UMSMBG           INTO MAP                         08710020
         BCTR  SWORK1,ZEROREG          DECREMENT MAP ENTRY COUNTER      08720020
         LTR   SWORK1,SWORK1           MORE ENTRIES?                    08730020
         BE    ROUT                    NO, MAPPING COMPLETE             08740020
         XC    D4(WORD,UMSMREG),D4(UMSMREG)  ZERO OUT LAST ENTRY        08760020
ROUT      EQU   *                                                       08782020
         TITLE 'CONTROL BLOCK QUIESCE'                                  08790020
*********************************************************************** 08800020
*                                                                     * 08810020
*  TITLE- TIMER QUEUE ELEMENT PURGE                                   * 08820020
*                                                                     * 08830020
*  FUNCTION- THIS ROUTINE WILL FLAG TS USER'S TIMER QUEUE ELEMENTS    * 08840020
*            ON TIMER Q AS BELONGING TO A SWAPPED OUT USER            * 08850020
*                                                                     * 08860020
*  ENTRY POINT- TQEPURGE                                              * 08870020
*                                                                     * 08880020
*  INPUT- ADDRESS OF RCB FOR THIS REGION IN REGISTER 11               * 08890020
*         ADDRESS OF TJB FOR THIS USER IN REGISTER 12                 * 08900020
*                                                                     * 08910020
*********************************************************************** 08920020
         SPACE 2                                                        08921020
TQEPURGE L     TJBXREG,TJBEXTNT        ADDR TJB EXTENT                  08950020
         L     TJBFSTRG,TJBXFST        ADDR USER'S FIRST TCB            08960020
         LR    TCBREG,TJBFSTRG         SAVE TCB ADDR                    08970020
         USING TCB,TCBREG              BASE FOR TCB                     08980020
TQEON    L     TQEREG,TCBTME           ADDR OF TQE                      08990020
         USING TQE,TQEREG              BASE FOR TQE                     09000020
         LTR   TQEREG,TQEREG           DOES TQE EXIST FOR THIS TCB      09020020
         BZ    TNEXTCB                 NO,TEST LAST TCB                 09030020
         TM    TQEFLGS,TQENTONQ        IS TQE ON TIMER Q?               09040020
         BO    TNEXTCB                 NO,TEST LAST TCB                 09050020
         SPACE 2                                                        09060020
*  PUT USER'S TJID INTO TQE TO INDICATE THIS USER HAS BEEN SWAPPED-OUT  09070020
         SPACE 2                                                        09080020
         MVC   TQETJID1(BYTE),RCBTJID  INSERT 1ST HALF USER'S ID        09090020
         MVC   TQETJID2(BYTE),RCBTJID+BYTE   REST OF USER'S ID          09100020
TNEXTCB  C     TCBREG,TJBXLAST         USER'S LAST TCB PROCESSED?       09120020
         BE    TCTEND                  YES                              09130020
         L     TCBREG,TCBTCB           NO, GET NEXT TCB ADDR            09140020
         B     TQEON                   GO CHECK FOR MORE TQE'S          09160020
TCTEND   MVI   RCBQUFLG,X'FE'          TQE'S PURGED                     09180020
         EJECT                                                          09190021
*********************************************************************** 09191020
*  SEARCH ASYNCHRONOUS EXIT QUEUE FOR USER'S RQES. FLAG WITH USER'S   * 09200020
*  TJID AND PUT ON SAVE QUEUE IN TJB EXTENT                           * 09210020
*********************************************************************** 09211020
         SPACE 1                                                        09220020
TRQEPRGE EQU   *                       *                                09240020
         USING CVTSECT,CVTREG          BASE FOR CVT                     09250020
         L     TJBXREG,TJBEXTNT        ADDR TJBX                        09252020
         L     TJBFSTRG,TJBXFST        GET TOP USER TCB                 09260020
         XC    TJBXRQE(WORD),TJBXRQE   ZERO OUT RQE AND                 09270020
         XC    TJBXIQE(WORD),TJBXIQE   IQE SAVE CHAIN PTRS              09280020
RQEPRGEP L     CVTREG,CVTPTR           GET CVT ADDR                     09300020
         L     TAEQAREG,CVTIERLC       ADDR OF QUEUE OF RQE'S           09310020
         USING  RQESECT,TRQEREG        BASE FOR REQUEST QUEUE ELEMENT   09320020
         CLC   ZERO(D2,TAEQAREG),FOUR(TAEQAREG) IS QUEUE EMPTY?         09330020
         BE    TAEQPRGE                YES BRANCH                       09340020
         LR    TRQEREG,TAEQAREG        SAVE ERROR Q PTR                 09360020
TNEXTRQE LR    TPREVREG,TRQEREG        SAVE RQE ADDR                    09370020
         LH    TRQEREG,RQELNK          GET ADDR OF NEXT RQE             09380020
TESTLAST CH    TRQEREG,FOUR(TAEQAREG)  HAS LAST RQE BEEN PROCESSED      09380820
         BE    TAEQPRGE                YES BRANCH                       09381220
         LR    TCBREG,TJBFSTRG         NO - GET ADR FIRST USER TCB      09382020
         L     TCBRQERG,RQETCB         ADDR OF TCB FOR THIS RQE         09390020
         LA    TCBRQERG,0(TCBRQERG)    CLEAR HI-ORDER BYTE       A43809 09392021
TCOMRQE  CR    TCBRQERG,TCBREG         THIS RQE BELONG TO USER?         09400020
         BE    TCKOUT                  YES                              09410020
         C     TCBREG,TJBXLAST         USER'S LAST TCB?                 09420020
         BE    TNEXTRQE                YES,GET NEXT RQE                 09430020
         L     TCBREG,TCBTCB           GET ADDR USER'S NEXT TCB         09440020
         B     TCOMRQE                 SEE IF RQE ONE OF USER'S         09450020
         SPACE 2                                                        09490020
*  TEST IF RQE BELONGS TO SWAPPED OUT USER (TJID FIELDS NOT 00 OR FF)   09500020
         SPACE 2                                                        09510020
         USING RQESECT,TRQEREG         BASE FOR REQUEST QUEUE ELEMENT   09520020
TCKOUT   CLI   RQEIDT,ZERO             OTHER TS USER                    09530020
         BNE   TNEXTRQE                YES,GET NEXT RQE           M3877 09550020
TSTRTJID MVC   RQETJID1(BYTE),RCBTJID  PLACE USER'S ID                  09570020
         MVC   RQETJID2(BYTE),RCBTJID+BYTE   INTO RQE                   09580020
         MVI   RQEIDT,TRQEOUT          INDICATE RQE NOT TO BE    A44369 09582021
*                                      PURGED                    A44369 09584021
         SPACE 2                                                        09590020
* REMOVE  RQE FROM AEQA AND PUT ON SAVE QUEUE IN TJB EXTENT             09600020
         SPACE 2                                                        09610020
         MVC   ZERO(D2,TPREVREG),RQELNK RQE FROM AEQA                   09620020
         CH    TRQEREG,TWO(TAEQAREG)   WAS LAST RQE DEQUEUED            09630020
         BNE   TRQEONQ                 GO QUEUE RQE OFF TJBX            09640020
         STH   TPREVREG,TWO(TAEQAREG)  SET PTR TO LAST RQE              09650020
TRQEONQ  L     TSAVRQEG,TJBXRQE        ADDR 1ST RQE SAVED               09660020
         LTR   TSAVRQEG,TSAVRQEG       ANY RQE'S SAVED                  09670020
         BNZ   TSTRQE                  YES                              09680020
         ST    TRQEREG,TJBXRQE         PUT RQE ON SAVE QUEUE            09690020
         B     TZEROLNK                CHECK FOR LAST RQE               09700020
TSTRQE   LH    SWORK6,ZERO(TSAVRQEG)   ADDR OF NEXT RQE                 09710020
         LTR   SWORK6,SWORK6           LAST RQE ON QUEUE                09720020
         BZ    TRQECHN                 YES BRANCH                       09722020
         LR    TSAVRQEG,SWORK6         NO SET UP REG 8                  09724020
         B     TSTRQE                  CONTINUE SEARCH FOR END          09726020
TRQECHN  STH   TRQEREG,ZERO(TSAVRQEG)  PUT RQE AT END OF QUEUE          09740020
TZEROLNK LR    TSAVRQEG,TRQEREG        SAVE ADDR OF RQE DEQUEUED        09750020
         LH    TRQEREG,RQELNK          GET ADDR OF NEXT RQE             09760020
         XC    ZERO(D2,TSAVRQEG),ZERO(TSAVRQEG) ZERO LINK FIELD         09770020
*                                      OF RQE ON TJBX RQE QUEUE         09772020
         B     TESTLAST                BR TO PROCESS NEXT RQE           09774020
         EJECT                                                          09784021
*  SEARCH QUEUE FOR ANY USER IQES. DEQUEUE AND PUT ON SAVE              09810020
*  QUEUE IN TJB EXTENT                                                  09820020
         SPACE 2                                                        09830020
TAEQPRGE LA    TAEQJREG,SIX(TAEQAREG)  ADDR OF QUEUE OF IQE'S           09850020
         CLI   ZERO(TAEQJREG),TAEQMT    IS IQE QUEUE EMPTY              09860020
         BE    TON                      YES                             09870020
         LR    TIQEREG,TAEQJREG         PTR TO FIRST IQE                09880020
TNEXTIQE LR    TPREVREG,TIQEREG         SAVE ADDR THIS IQE              09890020
         L     TIQEREG,IQELNK(TPREVREG) GET ADDR NEXT IQE               09900020
         LTR   TIQEREG,TIQEREG          ANY (MORE) IQE'S                09910020
         BM    TON                     NO, CONTINUE                     09920020
TESTON   L     TCBIQERG,TIQETCB(TIQEREG) ADDR TCB FOR THIS IQE          09930020
         LR    TCBREG,TJBFSTRG          GET ADDR USER'S FIRST TCB       09940020
TCOMIQE  CR    TCBIQERG,TCBREG          THIS IQE BELONG TO USER         09950020
         BE    TSAVEQ                   YES, GO UNCHAIN IT              09960020
         C     TCBREG,TJBXLAST          USER'S LAST TCB                 09970020
         BE    TNEXTIQE                 YES, GET NEXT IQE               09990020
TONTCB   L     TCBREG,TCBTCB            ADDR NEXT TCB                   10000020
         B     TCOMIQE                  SEE IF IQE BELONGS TO USER      10010020
         SPACE                                                          10020020
*  REMOVE IQE FROM AEQJ AND PUT ON SAVE QUEUE IN TJB EXTENT             10030020
         SPACE                                                          10040020
TSAVEQ   EQU   *                                                        10050420
         C     TIQEREG,WORD(TAEQJREG) Q.LAST IQE DEQUEUED               10052020
         BNE   TONQ                     NO                              10054020
         CLC   ZERO(WORD,TAEQJREG),WORD(TAEQJREG) DEQUE ONLY IQE        10054420
         BE    TOMQ                      YES                            10054820
         ST    TPREVREG,WORD(TAEQJREG)  NO-UPDATE AEQ LAST PTR          10055220
         B     TONQ                                                     10055320
TOMQ     EQU   *                                                        10055620
         MVC   WORD(WORD,TAEQJREG),IQELNK(TIQEREG)    UPDATE AEQ LAST   10056020
TONQ     MVC   IQELNK(WORD,TPREVREG),IQELNK(TIQEREG) IQE FR.AEQJ  M3026 10058020
     L     TSAVIQEG,TJBXIQE         ADDR 1ST IQE IN SAVE                10060020
         LTR   TSAVIQEG,TSAVIQEG        IS QUEUE EMPTY                  10070020
         BNZ   TSTIQE                   NO, GO FIND LAST ELEMENT        10080020
         ST    TIQEREG,TJBXIQE          YES, STORE FIRST IQE IN FIELD   10090020
         B     TLASTQ                   GO UPDATE POINTERS              10100020
TSTIQE   LR    TCBIQERG,TSAVIQEG        SAVE PREVIOUS POINTER           10110020
         L     TSAVIQEG,IQELNK(TSAVIQEG)  GET POINTER NEXT ELEMENT      10120020
         LTR   TSAVIQEG,TSAVIQEG        LAST ELEMENT                    10130020
         BNZ   TSTIQE                   NO, GET NEXT                    10140020
         ST    TIQEREG,ZERO(TCBIQERG)   YES, QUEUE NEW ELEMENT          10150020
TLASTQ   L     TSAVIQEG,ZERO(TIQEREG)   GET ADDR NEXT IQE ON AEQJ       10160020
         XC    ZERO(WORD,TIQEREG),ZERO(TIQEREG) ZERO TJBXIQE CHAIN PTR  10170020
         LR    TIQEREG,TSAVIQEG         LOAD NEXT IQE ADDR ON AEQJ      10180020
         LTR   TIQEREG,TIQEREG          IS THERE ONE                    10190020
         BNM     TESTON                   YES, PROCESS THIS ELEMENT     10210020
         SPACE 2                                                        10212020
*********************************************************************** 10214020
*        ROUTINE TO FLAG RQES WITH TJID                               * 10216020
*********************************************************************** 10218020
TON      L     TJBXREG,TJBEXTNT        ADDRESS TJBX               M3864 10220020
         L     TCBREG,TJBXFST          GET FIRST USER TCB         M3864 10222020
         L     TCBLSTR,TJBXLAST        GET LAST USER TCB          M3864 10224020
         USING TCB,TCBREG              ADDR TCB                   M3864 10226020
GETTOPRB L     TRBREG,TCBRBP           GET TOP RB OFF TCB         M3864 10228020
         USING RBSECT,TRBREG           ADDR RB                    M3864 10230020
TESTIRB  TM    RBSTAB,RBFTIRB          IS THIS AN IRB ?           M3864 10232020
         BZ    GTNXTRB                 NO, GET NEXT RB            M3864 10234020
         TM    RBSTAB2,RBRQE1          ARE RQE'S QUEUED OFF IRB ? M3864 10236020
         BO    GTNXTRB                 NO, GET NEXT RB            M3864 10238020
         TM    RBSTAB2,RBRQE2          ARE RQE'S QUEUED OFF IRB ? M3864 10240020
         BZ    GTNXTRB                 NO, GET NEXT RB            M3864 10242020
         SPACE 1                                                  M3864 10244020
*        FLAG RQE'S                                               M3864 10246020
         SPACE 1                                                  M3864 10248020
         LH    RQEREG,RBIQE2+TWO       GET RQE                    M3864 10250020
         USING RQESECT,RQEREG          ADDR RQE                   M3864 10252020
         L     JSCBREG,TCBJSCB         GET TCB'S JSCB             M3864 10254020
         USING IEZJSCB,JSCBREG         ADDR JSCB                  M3864 10256020
RQEFLAG  MVC   RQETJID1(ONE),JSCBTJID  MOVE IN FIRST HALF OF TJID M3864 10258020
         MVC   RQETJID2(ONE),JSCBTJID+ONE MVE IN 2ND HALF OF TJID M3864 10260020
         MVI   RQEIDT,TRQEOUT          INDICATE RQE NOT TO BE    A44369 10260421
*                                      PURGED                    A44369 10260821
         LH    RQEREG,RQELNK           GET NEXT RQE               M3864 10262020
         LTR   RQEREG,RQEREG           ANY MORE RQES ?            M3864 10264020
         BNZ   RQEFLAG                 YES FLAG IT                M3864 10266020
         SPACE 1                                                  M3864 10268020
*        LOOP CONTROL                                             M3864 10269020
         SPACE 1                                                  M3864 10270020
GTNXTRB  L     TRBREG,RBLINK           GET NEXT RB                M3864 10271020
         LA    TRBREG,ZERO(TRBREG)     CLEAR HIGH ORDER BYTE      M3864 10272020
         CR    TRBREG,TCBREG           ARE WE BACK TO TCB ?       M3864 10273020
         BNE   TESTIRB                 NO, TEST FOR IRB           M3864 10274020
         CR    TCBREG,TCBLSTR          IS THIS LAST USER TCB ?    M3864 10275020
         L     TCBREG,TCBTCB           GET NEXT TCB               M3864 10276020
         BNE   GETTOPRB                NO, GO BACK AGAIN          M3864 10277020
         DROP  JSCBREG,RQEREG,TRBREG                              M3864 10278020
         MVI   RCBQUFLG,X'FF'          IQE PROCESSING DONE              10281020
         TITLE 'LONG WAIT TEST'                                         10284020
*********************************************************************** 10287020
*                                                                     * 10290020
* THIS ROUTINE IS PART OF THE LONG WAIT FUNCTION OF QUIESCE. IT TESTS * 10300020
* IF THE USER HAS ANY OUTSTANDING I/O. IF HE DOES, NO FURTHER LONG    * 10310020
* WAIT TESTING IS DONE. THIS CODE MUST BE EXECUTED AFTER THE I/O      * 10320020
* PURGE ROUTINE                                                       * 10330020
*                                                                     * 10340020
*********************************************************************** 10350020
         SPACE 2                                                        10360020
TWAITIO  CLI   TJBATTN,ZERO            ATTN COUNT ZERO                  10380020
         BNZ   RESETFAT                NO, RESET RCBFAT BIT             10381020
         USING  TCB,TCBREG             BASE FOR TCB                     10390020
         L     TJBXREG,TJBEXTNT        ADDR TJBX                        10400020
         USING TJBX,TJBXREG            ADDR TJB                         10405020
         L     TQPLREG,TJBXQPL         GET ADDR QUIESCE I/O PARAM LIST  10410020
         LA    TQPLREG,FOUR(TQPLREG)   ADDR OF TCB ENTRY                10420020
         SPACE 2                                                        10421020
*********************************************************************** 10430020
*                                                                     * 10430120
* IF THE LOW ORDER BYTE OF THE IOB ADDR IS X'FF', THEN THERE IS NO    * 10431020
* IOB FOR THIS TCB.  IF THERE IS AN IOB ADDR, THEN NO FURTHER LONG    * 10431120
* WAIT PROCESSING IS NECESSARY BECAUSE THERE IS OUTSTANDING I/O       * 10431220
*                                                                     * 10480020
*********************************************************************** 10490020
         SPACE 2                                                        10491020
TSTAGAIN CLI   THREE(TQPLREG),TALLON   IOB FOR THIS TCB                 10500020
         BNE   TNOLGWT                 YES,FURTHER PROCESS UNNECESSARY  10510020
         TM    FOUR(TQPLREG),LSTENTRY  MORE TCB ENTRIES                 10520020
         BO    TIODONE                 NO,FURTHER TESTING NECESSARY     10530020
         LA    TQPLREG,EIGHT(TQPLREG)  GET ADDR OF NEXT TCB ENTRY       10540020
         B     TSTAGAIN                CHECK NEXT IOB                   10550020
TIODONE  EQU   *                       *                                10560020
         SPACE  4                                                       10570020
*********************************************************************** 10580020
*                                                                     * 10590020
* THIS ROUTINE IS PART OF THE LONG WAIT FUNCTION OF QUIESCE. IT TESTS * 10600020
* TO SEE IF REQUEST QUEUE ELEMENTS(RQE) FOR SCHEDULING I/O EXITS HAVE * 10610020
* BEEN DEQUEUED FROM THE ASYNCHRONOUS EXIT QUEUE AND PUT ON A SAVE    * 10620020
* QUEUE IN THE TJB EXTENT. IF THEY HAVE, THE EXIT WILL BE HONORED WHEN* 10630020
* THE USER IS SWAPPED IN, SO THE USER IS NOT IN A LONG WAIT CONDITION * 10640020
* AND FURTHER TESTING IS UNNECESSARY.                                 * 10650020
*                                                                     * 10660020
*********************************************************************** 10670020
         SPACE 2                                                        10680020
TCHKRQE  L     TRQEREG,TJBXRQE         HEAD OF SAVE CHAIN FOR RQE'S     10690020
         LTR   TRQEREG,TRQEREG         RQE'S ON SAVE QUEUE              10700020
         BNZ   TNOLGWT                 YES,FURTHER PROCESS UNNESSARY    10710020
         EJECT                                                          10720020
*********************************************************************** 10730020
*                                                                     * 10740020
* THIS ROUTINE IS PART OF THE LONG WAIT FUNCTION OF QUIESCE. IT TESTS * 10750020
* IF ANY OF THIS USER'S TCBS OR RBS ARE IN READY STATUS. IF ANY ONE   * 10760020
* IS, THE USER IS NOT IN A LONG WAIT AND FURTHER TESTING IS UNNECES-  * 10770020
* SARY                                                                * 10780020
*********************************************************************** 10790020
         SPACE 2                                                        10791020
TTCBRDY  L     TCBREG,TJBXFST          ADDR USER'S FIRST TCB            10810020
         SPACE 1                                                        10820020
*  FIND CURRENT RB AND TEST FOR WAIT CONDITION                          10830020
         SPACE 1                                                        10840020
TRBCK    L     TRBREG,TCBRBP           GET ADDR OF CURRENT RB           10850020
         USING RBSECT,TRBREG           BASE FOR RB                      10860020
         CLI   RBWCF,ZERO              RB READY TO RUN?                 10870020
         BE    TESTTCB                 YES                              10880020
         SPACE 1                                                        10890020
* TEST CURRENT RB FOR TYPE 3 OR 4 SVRB. IF NOT,THIS TCB COULD           10900020
*      NOT BE TRANSIENT AREA USER                                       10910020
         SPACE 1                                                        10920020
         TM    RBSTAB,TYP3OR4          TRANSIENT AREA USER?             10930020
         BNO   TLASTTCB                NO,TEST TCB                      10940020
         SR    TWKREG4,TWKREG4         CLEAR REG                        10960020
         IC    TWKREG4,RBTAWCSA        GET SAVE WAIT COUNT FOR COMPARE  10990020
         LTR   TWKREG4,TWKREG4         IF POSITIVE, TCB                 11000020
         BP    TLASTTCB                IS IN LONG WAIT                  11010020
* A BRANCH IS TAKEN IF THE WAIT COUNT IS NOT ZERO                 M3877 11015020
         SPACE 1                                                        11020020
* TEST IF TCB IS READY                                                  11030020
         SPACE 1                                                        11040020
TESTTCB  LH    TWKREG1,TCBFLGS4        2 BYTES PRIMARY NON DISP FLAGS   11050020
         N     TWKREG1,DISPMASK        TURN OFF TSO NON DISP FLAG       11060020
         LTR   TWKREG1,TWKREG1         ANY FLAGS SET?                   11070020
         BNZ   TLASTTCB                YES, THIS TCB NON DISP           11080020
         TM    TCBNDSP1,TALLON         SECONDARY NON DISP BITS OFF?     11090020
         BM    TLASTTCB                NO, THIS TCB NOT READY           11100020
         TM    TCBNDSP3,TALLON         SECONDARY NON DISP BITS OFF      11110020
         BM    TLASTTCB                NO, THIS TCB NOT READY           11120020
         TM    TCBNDSP2,XEF            TS TASK DISPATCHABLE?            11130020
         BZ    TNOLGWT                 YES,TESTING FINISHED             11140020
TLASTTCB C     TCBREG,TJBXLAST         USER'S LAST TCB?                 11150020
         BE    TELLTSIP                TCB'S NOT READY                  11160020
         L     TCBREG,TCBTCB           GET ADDR NEXT TCB                11170020
         B     TRBCK                   CHECK NEXT RB                    11180020
         SPACE 1                                                        11220020
TELLTSIP EQU   *                                                  M4298 11230020
         TM    TJBSTAT2,TJBUSERR       Q.USER READY TO RUN        M4298 11240020
         BO    TNOLGWT                 YES,DO NOT ISSUE TSIP 3    M4298 11250020
* USER IN LONG WAIT-NOTIFY TSIP                                         11268820
         LH    ZEROREG,RCBTJID           GET TJID FOR TSIP              11269220
*                                      SET FLAG IN TJB TO INDICATE      11270020
         OI    TJBRSTOR,TJBLWAIT       QUIESCED USER WAS IN LONG WAIT   11280020
         TSEVENT  NIOWAIT,TJID=(0)     INFORM DRIVER USER IN LONG WAIT  11290020
         B     TLETSET                 BR AROUND TURNING OFF LONGWAIT   11300020
RESETFAT NI    RCBFLG,TALLON-RCBFAT    RESET ATTENTION FLAG IN RCB      11301020
TNOLGWT  NI    TJBRSTOR,NOLGWAIT       MAKE SURE LONG WAIT BIT OFF      11310020
TLETSET  EQU   *                       *                                11320020
         TITLE 'QUIESCE COMPLETED'                                      11330020
         SPACE 2                                                        11340020
         L     CVTREG,CVTPTR           GET CVT ADDR                     11360020
         USING CVTSECT,CVTREG          BASE FOR CVT                     11370020
         L     TSCVTREG,CVTTSCVT       GET ADDR TS CVT                  11380020
         USING TSCVT,TSCVTREG          BASE FOR TSCVT                   11390020
         L     XTSECB,TSCVTECB         GET ADDR OF ECB LIST             11400020
         SPACE 2                                                        11410020
*   RESET RCB QUIESCE FLAG                                              11420020
         SPACE 2                                                        11430020
*   INTERFACE TO TSIP-  QUIESCE COMPLETED                               11440020
         SPACE                                                          11441020
         LH    ZEROREG,RCBTJID         INSERT TJID                      11460020
         SR    SWORK1,SWORK1           INITIALIZE REG                   11470020
         IC    SWORK1,RCBFBQE          PASS NO. FBQES TO TSIP           11480020
         TSEVENT  QSCEMP,TJID=(0)      TELL DRIVER QUIESCE COMPLETE     11490020
         NI    TJBSTAT2,TALLON-TJBQUIS-TJBUSERR CLEAR QUIESCE FLAGM4298 11500020
         LTR   SWORK1,SWORK1           USER TO BE SWAPPED               11510020
         BZ    QUIESCEN                YES                              11520020
         NI    TJBRSTOR,NOLGWAIT       RESET LONGWAIT FLAG              11530020
         OI    RCBFLG,RCBFRS           TURN ON RESTORE FLAG             11540020
         B     QUIESCEX                RETURN TO CALLER                 11550020
         SPACE 2                                                        11560020
*   SET TSC SWITCH IN TSCVT FOR 'BEGIN SWAP OUT'                        11570020
         SPACE 2                                                        11580020
QUIESCEN OI    TSCVTFLG,TSCSWPBG       SET THE 'BEGIN SWAP' FLAG        11600020
         SPACE 2                                                        11610020
*   POST TSC SWAP ECB                                                   11620020
         SPACE 2                                                        11630020
         OI    RCBFLG,RCBFSO           SET SWAP OUT FLAG                11640020
         TM    RCBFLG2,RCBLOGPR                                  M4655  11642020
        BZ      QUIESCEP                                         M4655  11644020
         LA    XTSECB,D12(XTSECB)                                M4655  11646020
QUIESCEP   LA    XTSECB,ZERO(XTSECB)     CLEAR HI ORDER BYTE      M4655 11650020
         POST  (XTSECB)                POST THE TSC                     11660020
QUIESCEX XC    RCBQUFLG(BYTE),RCBQUFLG CLEAR RECOVERY FIELD             11670020
         BR    RTNREG                  RETURN TO CALLER                 11680020
         EJECT                                                          11690020
         DS    0D                                                       11700020
RETPSW   DC    X'00040000'             PSW TA REFRESH RTN USES TO RET   11710020
         DC    A(REFRESHD)             FROM IEAQTR02                    11720020
DISPMASK DC    X'0000FFFE'             FOR TURNING OFF TSO NON DISP FLG 11730020
ZEROMASK DC    X'0000'                 CHECK FOR TJID OF ZERO           11740020
QNAME    DC    C'SYSIEC16'             PURGE RESOURCE QNAME       M3864 11742020
PRERNAME DC    X'01FF'                 2 BYTES BEFORE RNAME       M3864 11744020
RNAME    DC    X'F0'                   PURGE RESOURCE RNAME       M3864 11746020
         END                                                            12130020
