         TITLE 'REGION CONTROL TASK RESTORE FUNCTION'                   00020020
IKJEAR03 START                                                          00030020
         SPACE 3                                                        00040020
         EJECT                                                          00160020
*********************************************************************** 00170020
*                                                                     * 00175021
*STATUS -- 0                                                          * 00180020
*A088808,088832-088872,088896-088904,088920-088976               A41399 00180421
*A065720,065740,069044,069048                                    A44369 00182021
*A088973,088996                                                   M1430 00184021
*CO88872                                                          M1433 00186021
*A078220,078240                                                   M1562 00188000
*A074104,074108                                              AJ  A52532 00188421
*A089320,089340                                              AJ   M4903 00188821
*C085300,085400                                                       * 00189221
*A063000                                                      CC A68775 00189421
*                                                                     * 00189621
*FUNCTION -- CONTROL SECTION NAME - IKJEAR03                          * 00190020
*            LOAD MODULE NAME - IKJEAR01                              * 00200020
*    IKJEAR03 (RESTORE) PERFORMS THE FUNCTIONS NECESSARY TO RECONNECT * 00210020
*    THE USER TO THE SYSTEM SO THAT HE MAY CONTINUE HIS PROCESSING    * 00220020
*    IN THE REGION.  TO RESTORE THE USER THE FOLLOWING IS DONE:       * 00230020
*    1)  THE USER'S REGION IS RECONSTRUCTED USING THE MAIN STORAGE    * 00240020
*        MAP BUILT DURING QUIESCE                                     * 00250020
*    2)  THE USER'S TCB'S ARE REQUEUED ON THE READY QUEUE             * 00260020
*    3)  THE USER'S QEL'S ARE REACTIVATED                             * 00270020
*    4)  RQE'S, IQE'S AND TQE'S ARE REQUEUED ON THE PROPER QUEUES     * 00280020
*    5)  I/O IS RESCHEDULED                                           * 00290020
*    6)  WTOR ELEMENTS ARE RESTORED                                   * 00300020
*    7)  SVRB'S ON TRANSIENT AREA QUEUES WHEN THE USER WAS QUIESCED   * 00310020
*        ARE REQUEUED AND MADE READY                                  * 00320020
*    8)  INTERPARTITION POSTS ARE PROCESSED                           * 00330020
*    9)  ATTENTION EXITS ARE NOTED BY SETTING THE RCB ATTENTION       * 00340020
*        FUNCTION FLAG (RCBFAT)                                       * 00350020
*   10)  USER'S TCB'S ARE SET DISPATCHABLE                            * 00360020
*                                                                     * 00370020
*ENTRY POINTS -- MAIN ENTRY POINT - IKJEAR03                          * 00380020
*                                                                     * 00420020
*INPUT -- REG11 - RCB ADDRESS                                         * 00430020
*         REG12 - TJB ADDRESS                                         * 00440020
*         REG13 - SAVE AREA ADDR                                      * 00450020
*         REG14 - RETURN ADDRESS                                      * 00460020
*         REG15 - ENTRY POINT ADDRESS                                 * 00470020
*                                                                     * 00480020
*OUTPUT -- NONE                                                       * 00490020
*                                                                     * 00500020
*EXTERNAL REFERENCES -- BALR 14,15 TO STAGE II EXIT EFFECTOR          * 00510020
*    (IEAOEF00) TO SCHEDULE TIMER EXITS ON THE ASYNCHRONOUS EXIT      * 00520020
*    QUEUE WITH THE ADDRESS OF EITHER THE RQE OR IQE TO BE            * 00530020
*    SCHEDULED IN REG 1 DEPENDING ON WHICH QUEUE THE ELEMENT          * 00540020
*    IS TO BE PLACED.                                                 * 00550020
*       BR 12 TO TRANSIENT AREA REFRESH ROUTINE (IEAQTR02)            * 00560020
*    IKJEAR03 STORES ITS REGISTERS IN ITS TCB AND SETS THE PSW IN ITS * 00570020
*    RB TO THE RETURN POINT REQUIRED.  AT COMPLETION OF ITS PRO-      * 00580020
*    CESSING, IEAQTR02 INDICATES A TASK SWITCH IS NECESSARY, AND      * 00590020
*    IKJEAR03 IS REDISPATCHED AT THE RETURN ADDRESS SPECIFIED IN ITS  * 00600020
*    RB.                                                              * 00610020
*       BALR 14,15 TO POST RTN (IEAOPT01)                             * 00620020
*    PROCESS ANY INTERPARTITION POSTS RECEIVED WHILE USER WAS OUT OF  * 00630020
*    CORE.  REG 13 - TJID, REG 11 - ADDRESS ECB TO BE POSTED,         * 00640020
*    REG 10 - POST CODE                                               * 00650020
*                                                                     * 00660020
*EXITS, NORMAL -- RETURN TO CALLER WITH BR 14                         * 00670020
*EXITS, ERROR -- STAE FOR TASK GAINS CONTROL IF THIS MODULE ABENDS    * 00680020
*                                                                     * 00690020
*TABLES/WORK AREAS -- NONE                                            * 00700020
*                                                                     * 00710020
*ATTRIBUTES--REENTRANT,REFRESHABLE,DISABLES,SUPERVISOR STATE          * 00710420
*                                                                     * 00710820
*CHARACTER CODE DEPENDENCY - THE OPERATION OF THIS MODULE DOES NOT    * 00711020
*    DEPEND UPON A PARTICULAR INTERNAL REPRESENTATION OF THE EXTERNAL * 00712020
*    CHARACTER SET.                                                   * 00713020
*                                                                     * 00714020
*NOTES -- NONE                                                        * 00720020
*                                                                     * 00730020
*********************************************************************** 00740020
         EJECT                                                          00750021
UCM      DSECT                                                          00760020
         IEECUCM                                                        00770020
         SPACE 5                                                        00772021
SCVTSECT DSECT                                                          00780020
         SCVT                                                           00790020
         SPACE 5                                                        00800021
         IKJPQE                                                         00810020
         SPACE 5                                                        00820021
         IKJRPQE                                                        00830020
         SPACE 5                                                        00840021
         IKJFBQE                                                        00850020
         SPACE 5                                                        00860021
         IKJRB                                                          00870020
         SPACE 5                                                        00880021
         IKJUMSM                                                        00890020
UMSMEND  DS    0F                       LABEL TO MARK END OF DSECT      00900020
         SPACE 5                                                        00910021
         IKJQEL                                                         00920020
          EJECT                                                         00930021
         IEZJSCB                                                        00940020
         EJECT                                                          00950020
         IKJRCB                                                         00960020
          EJECT                                                         00970021
         IKJTJB                                                         00980020
         SPACE  5                                                       00990021
         IKJTJBX                                                        01000020
         EJECT                                                          01020021
         IKJTSCVT                                                       01030020
         EJECT                                                          01040021
CVT      DSECT                                                          01050020
         CVT                                                            01060020
         SPACE 5                                                        01070021
         IKJTCB                                                         01080020
         SPACE 5                                                        01090021
         IKJTQE                                                         01100020
         SPACE 5                                                        01110021
         IKJWQE                                                         01120020
         SPACE 5                                                        01130021
         IKJRQE                                                         01140020
         SPACE 5                                                        01150021
         IKJIPPB                                                        01160020
         SPACE 5                                                        01210021
         IKJTSIA                                                        01220020
         SPACE 5                                                        01222021
         IGFIORMS                                                A41399 01225021
         EJECT                                                          01230020
*                                                                       01232021
*     EQUATES USED BY IKJEAR03                                          01240020
*                                                                       01242021
         SPACE  2                                                       01250020
BYTE     EQU   1                       LENGTH EQUATE                    01260020
BYTE3    EQU   3                       LENGTH EQUATE                    01280020
TALLON   EQU   X'FF'                   MASK TO TURN ALL BITS ON         01290020
MCSINSYS EQU   X'02'                   FLAG TO TEST FOR MCS             01300020
IPPBREG  EQU   6                       IPPB BASE REGISTER               01310020
SWORK8   EQU   8                       WORK REGISTER                    01320020
RECBREG  EQU   11                      REG TO PASS ECB ADDR TO POST     01330020
SAVEREG  EQU   13                      SAVE AREA ADDR REG               01340020
CVTSECT  EQU   CVT                     NAME FOR CVT DSECT               01350020
TCBSECT  EQU   TCB                     NAME FOR TCB DSECT               01360020
         SPACE  3                                                       01370020
*                                                                       01372021
*    NUMERIC EQUATES                                                    01380020
*                                                                       01382021
         SPACE 2                                                        01390020
ONE      EQU   1                       *                                01391020
TWO      EQU   2                       *                                01395020
D4       EQU   4                       *                                01400020
D8       EQU   8                       *                                01410020
D9       EQU   9                       *                                01420020
TWELVE   EQU   12                      *                                01470020
SIXTEEN  EQU   16                      *                                01480020
SIXTY4   EQU   64                      *                                01500020
         SPACE 3                                                        01502021
*                                                                       01504021
*                   EQUATES USED BY MAP ROUTINE                       * 01510020
*                                                                       01512021
         SPACE 2                                                        01520020
ZEROREG  EQU   0                       WORK REGISTER                    01530020
SWORK1   EQU   1                       WORK REGISTER                    01540020
SWORK2   EQU   2                       WORK REGISTER                    01550020
SWORK3   EQU   3                       WORK REGISTER                    01560020
SWORK4   EQU   4                       WORK REGISTER                    01570020
SCOMPREG EQU   4                       WORK REGISTER                    01580020
SWORK5   EQU   5                       WORK REGISTER                    01590020
SFBQEREG EQU   5                       FBQE BASE REGISTER               01600020
BACKREG  EQU   6                       TCB REGISTER                     01610020
UMSMREG  EQU   7                       UMSM BASE REGISTER               01620020
SPQEREG  EQU   8                       PQE BASE REGISTER                01630020
TJBXREG  EQU   9                       TJBX BASE REGISTER               01640020
RCBREG   EQU   11                      RCB BASE REGISTER                01650020
TJBREG   EQU   12                      TJB BASE REGISTER                01660020
COUNTREG EQU   14                      REG WITH NO. MAP ENTRIES         01670020
CODEREG  EQU   15                      RETURN CODE REGISTER             01680020
         SPACE 2                                                        01690020
TWOK     EQU   2048                    CONSTANT USED BY SETKEY ROUTINE  01700020
         SPACE 3                                                        01850020
*                                                                       01852021
*    EQUATES USED BY T/A PURGE ROUTINE                                  01860020
*                                                                       01862021
         SPACE 2                                                        01870020
SCVTREG  EQU   3                       SCVT BASE REGISTER               01880020
SVRBREG  EQU   4                       SVRB BASE REGISTER               01890020
ENTRYREG EQU   7                       TACT ENTRY POINTER               01900020
TACTSREG EQU   8                       TACT BASE REGISTER               01910020
         SPACE 3                                                        01920020
*                                                                       01922021
*   WTOR PURGE                                                          01930020
*                                                                       01932021
         SPACE 2                                                        01940020
SPARMREG EQU   1                       PARAMETER REGISTER               01950020
SRQEREG  EQU   7                       RQE POINTER                      01960020
SRQEORIG EQU   24                      REPLY QUEUE ORIGIN IN UCM        01970020
MCSDISP  EQU   140                     DISP FOR TEMP BUFF WHEN MCS IN   01980020
RQERO    EQU   X'20'                   RO FLAG IN RQEXA FIELD OF RQE    01990020
         SPACE 3                                                        02000020
*                                                                       02000421
*MISCELLANEOUS EQUATES USED BY ENQUEUE RESTORE ROUTINE                  02001020
*                                                                       02001421
         SPACE 3                                                        02002020
RESERVED EQU   X'40'                   TEST FOR DEVICE RESERVED         02003020
CURPRG   EQU   80                      PARM PTR IN TCB SET BY ENQ       02005020
UCBRSCT  EQU   40                      RESERVE COUNT FIELD IN UCB       02006020
         SPACE 3                                                        02007020
*                                                                       02009021
*REGISTERS USED BY ENQUEUE,TCB READY QUEUE,TQE PURGE AND RESTORE        02010020
*                                                                       02012021
         SPACE 2                                                        02020020
ZERO     EQU   0                       WORK REGISTER                    02030020
PARMREG  EQU   1                       PARAMETER REGISTER               02040020
TADIQERG EQU   1                       IQE ADDR FOR EXIT EFFECTOR       02050020
TJBFSTRG EQU   1                       USER'S FIRST TCB                 02060020
TCBLSTRG EQU   2                       RCT TCB ADDR IN READY Q RESTORE  02070020
MIQCBREG EQU   2                       MINOR QCB BASE REGISTER          02080020
TRBREG   EQU   2                       RB BASE REGISTER                 02090020
TSCVTREG EQU   3                       TSCVT BASE REGISTER              02100020
CVTREG   EQU   3                       CVT BASE REGISTER                02110020
QELCMPRG EQU   4                       WORK REGISTER IN QEL RESTORE     02120020
TJIDREG  EQU   5                       USER'S TJID                      02140020
QELREG   EQU   5                       QEL BASE REGISTER                02150020
TQEREG   EQU   5                       TQE BASE REGISTER                02160020
TCBREG   EQU   6                       TCB BASE REGISTER                02170020
TJBLSTRG EQU   7                       ADDR USER'S LAST TCB             02180020
TWKREG1  EQU   7                       WORK REGISTER                    02190020
TSIAREG  EQU   8                       TSIA BASE REGISTER               02200020
MJQCBREG EQU   8                       MAJOR QCB BASE REG               02210020
BASEREG  EQU   10                      BASE ADDR FOR RTN                02220020
TARFRREG EQU   12                      REG FOR BRANCH TO TA REFRESH RTN 02230020
RTNREG   EQU   14                      RETURN REGISTER                  02240020
         SPACE  3                                                       02250020
*                                                                       02252021
* REGISTERS USED BY RQE AND IQE QUIESCE AND RESTORE                     02260020
*                                                                       02262021
         SPACE 2                                                        02270020
TBLKREG  EQU   1                       IQE ADDR FOR EXIT EFFECTOR       02280020
JSCBREG  EQU   3                       ADDR OF JSCB               M3864 02285020
TSAVIQEG EQU   8                       IQE ADDR                         02290020
TSAVRQEG EQU   8                       TEMP SAVE FOR RQE                02300020
TCBLSTR  EQU   4                       ADDR OF LAST TCB           M3864 02303020
RQEREG   EQU   7                       ADDR OF RQE                M3864 02306020
         SPACE 3                                                        02310020
*                                                                       02312021
*   EQUATES USED BY RQE AND IQE QUIESCE AND RESTORE                     02320020
*                                                                       02322021
         SPACE 2                                                        02330020
HALFWORD EQU   2                       LENGTH EQUATE                    02340020
DBLEWORD EQU   8                       LENGTH EQUATE                    02350020
TCOMP    EQU   X'08'                   TQE FLG MARK TQE PROCESSING DONE 02360020
TCBADR   EQU   108                     DISP IN IQE TO TCB ADDR          02370020
IQELNK   EQU   0                       DISP IN IQE TO ADDR NEXT         02380020
IQEADR   EQU   104                     DISP IN TQE TO IRB ADDR FOR IQE  02390020
RBRQE1   EQU   X'08'                   RQE INDICATOR IN IRB       M3864 02393020
RBRQE2   EQU   X'04'                   RQE INDICATOR IN IRB       M3864 02396020
         SPACE 3                                                        02400020
*                                                                       02402021
*  EQUATES USED BY ENQUEUE,TCB READY QUEUE,TQE PURGE AND RESTORE        02410020
*                                                                       02412021
         SPACE 2                                                        02420020
TABLOAD  EQU   X'40'                   FLAG TO INDICATE TAB LOADING     02430020
TCBFTSND EQU   X'04'                   TIME SHARING NONDISP. FLAG       02440020
TCBDISPR EQU   35                      DISP TO TCB DISPATCHING PRIORITY 02450020
THREBYTE EQU   3                       LENGTH EQUATE                    02470020
WORD     EQU   4                       LENGTH EQUATE                    02480020
TCBNXT   EQU   116                     DISP IN TCB TO NEXT TCB          02490020
TNTLGWT  EQU   X'F7'                   FLAG TO TURN OFF LONGWAIT        02500020
TQESAADR EQU   25                      DISP IN TQE TO SAVE AREA ADDR    02510020
TQEXITAD EQU   28                      DISP TO EXIT ADDR IN TQE         02520020
RBWTOFF  EQU   X'DF'                   MASK TO TURN OFF QELRBWT         02530020
QELRBWT  EQU   X'20'                   FLG INDICATE SVRB PROCESSING     02540020
         SPACE 3                                                        02550020
*                                                                       02552021
*  DISPLACEMENTS IN QCB'S                                               02560020
*                                                                       02562021
         SPACE 2                                                        02570020
NEXTMAJ  EQU   0                       ADDR OF NEXT MAJOR QCB           02580020
MINQCB   EQU   8                       ADDR OF MINOR QCB                02590020
MINQEL   EQU   0                       ADDR OF QEL                      02600020
         SPACE 3                                                        02610020
*                                                                       02612021
*    FLAGS IN TQE                                                       02620020
*                                                                       02622021
         SPACE 2                                                        02630020
TQEXIT   EQU   X'04'                   EXIT MASK                        02640020
TQEWAIT  EQU   X'01'                   WAIT MASK                        02650020
TQENTONQ EQU   X'80'                   FLAG TO DETERMINE IF TQE ON Q    02660020
TQEREAL  EQU   X'02'                   FLAG TO DETERMINE IF REAL REQST  02670020
         EJECT                                                          02680020
IKJEAR03 CSECT                                                          02690020
         SPACE 3                                                        02692021
         BALR  BASEREG,ZEROREG         ESTABLISH ADDRESSABILITY         02700020
         USING *,BASEREG               BASE FOR MODULE                  02710020
         USING RCB,RCBREG              BASE FOR RCB                     02720020
         USING TJB,TJBREG              BASE FOR TJB                     02730020
         USING TCBSECT,TCBREG          BASE FOR TCB                     02740020
         L     TJBXREG,TJBEXTNT        GET TJB EXTENT                   02750020
         USING TJBX,TJBXREG            BASE FOR TJBX                    02760020
         L     TCBREG,RCBRCT           GET RCT TCB ADDRESS              02770020
         TM    TJBRSTOR,TJBLOGP        IS LOGON IMAGE BEING RESTORED?   02790020
         BZ    NOTON                   NO, CONTINUE PROCESSING          02800020
         L     TCBREG,TJBXFST          GET ADDR LOGON IMAGE TCB         02810020
         L     TCBREG,TCBJSCB          GET ADDR JSCB SO CAN PUT ID IN   02820020
         USING  IEZJSCB,TCBREG                                          02830020
         MVC   JSCBTJID(HALFWORD),RCBTJID  FLAG JSCB WITH USER'S TJID   02840020
NOTON     EQU  *                                                  M3873 02862020
         SPACE 2                                                        02870020
*                                                                       02872021
*   INTERFACE TO TSIP-  RESTORE BEGINNING                               02880020
*                                                                       02882021
         SPACE 2                                                        02890020
         LH    ZEROREG,RCBTJID         INDICATE TJID TO TSIP            02910020
         TSEVENT  RSTORST,TJID=(0)     TELL TSIP RESTORE STARTED        02920020
         SPACE 2                                                        02922021
          MVI   RCBRSFLG,RCBRSTRT        INDICATE RESTORE STARTED M1374 02930020
         TITLE 'RESTORE STORAGE KEYS'                                   02940020
         SPACE 3                                                        02942021
*********************************************************************** 02950020
* THIS ROUTINE SERVES THE FOLLOWING FUNCTIONS:                        * 02960020
*   A) SETS KEY FOR EACH 2K BLOCK IN REGION USING KEYS SAVED DURING   * 02970020
*      QUIESCE                                                        * 02971020
*   B) REQUEUES ALL FBQE'S AS THEY WERE PRIOR TO QUIESCE              * 02990020
*                                                                     * 03000020
*********************************************************************** 03010020
         SPACE 4                                                        03020020
         STM   RTNREG,TJBREG,TWELVE(SAVEREG)   SAVE REGS                03030020
RESTKEY  EQU   *                       START OF MAPPING                 03050020
         L     TJBXREG,TJBEXTNT        ADDR TJB EXTENSION               03070020
         USING TJBX,TJBXREG            BASE FOR TJBX                    03080020
         L     UMSMREG,TJBUMSM         ADDR USER'S MAIN STORAGE MAP     03090020
         L     TCBREG,TJBXFST          ADDR JSTCB                       03100020
         USING TCBSECT,TCBREG          BASE FOR TCB                     03110020
         L     SPQEREG,TCBPQE          ADD OF PQE                       03120020
         L     SPQEREG,D8(SPQEREG)     ADDR PQE FOR REGION              03130020
         USING PQESECT,SPQEREG         BASE FOR PQE                     03140020
         USING UMSM,UMSMREG            BASE FOR USER MAIN STORAGE MAP   03150020
         L     SWORK2,PQEREGN          GET ADDR USER REGION             03160020
         L     SWORK5,PQESIZE          GET SIZE USER REGION             03170020
         AR    SWORK5,SWORK2           GET ADDR 1ST 2K BLOCK PAST REG   03180020
         L     CODEREG,TJBXKEYA        GET ADDR STORAGE KEY SAVE AREA   03190020
         SR    SWORK1,SWORK1           INIT REGISTER                    03200020
RESETKEY IC    SWORK1,ZERO(CODEREG)    GET KEY FOR THIS 2K BLOCK        03210020
         SSK   SWORK1,SWORK2           SET KEY                          03220020
         LA    SWORK2,TWOK(SWORK2)     UPDATE PTR TO NEXT 2K BLOCK      03230020
         CR    SWORK5,SWORK2           BEYOND REGION                    03240020
         BE    REBUILD                 YES, REBUILD                     03250020
         LA    CODEREG,BYTE(CODEREG)   UPDATE SAVE AREA ADDRESS         03260020
         B     RESETKEY                CONTINUE RESTORING KEYS          03270020
         SPACE 3                                                        03272021
REBUILD  SR    COUNTREG,COUNTREG       INIT REGISTERS                   03280020
         IC    COUNTREG,TJBUMSMN       NO. MAP ENTRIES FOR LOOP CONTRL  03290020
SREQFBQ  SR    ZEROREG,ZEROREG         INITIALIZE WORK REG              03300020
         L     UMSMREG,TJBUMSM         REINITIALIZE MAP POINTER         03310020
         LH    SWORK1,UMSMBG           COMPUTE ADDRESS ONE BYTE HIGHER  03320020
         SLL   SWORK1,D8               THAN AREA SWAPPED OUT            03330020
         LH    SWORK2,UMSMLN           GET LENGTH AREA FROM MAP         03340020
         SLL   SWORK2,D8               GET LENGTH OF AREA SWAPPED OUT   03350020
         AR    SWORK1,SWORK2           GPR1 POINTS PAST SWAPPED AREA    03360020
         LR    BACKREG,SPQEREG         SET UP GPR 9 FOR CHAINING        03370020
         L     SFBQEREG,PQEFFBQE       GET ADDR FIRST FBQE SWAPPED      03380020
         LTR   SFBQEREG,SFBQEREG       ANY SWAPPED?                     03390020
         BE    SNONOUT                 NO                               03400020
         CLR   SFBQEREG,SPQEREG        YES, ANY FBQE'S?                 03420020
         BE    ALLDONE                 NONE IN REGION                   03430020
SLOWFBQE CLR   SFBQEREG,SWORK1         SWAPPED FBQE BEFORE NON-SWAP.?   03440020
         BL    SINSWAP                 YES,GO QUEUE & SET KEY           03450020
         LA    CODEREG,SLOWFBQE        SET UP BRANCH REG                03470020
SBUILDFB ST    BACKREG,D4(SWORK1)      NO, CONSTRUCT THIS FBQE          03480020
         ST    SWORK1,ZERO(BACKREG)    POINTER AND SIZE                 03490020
         BCTR  COUNTREG,ZEROREG        KEEP TRACK OF ENTRIES PROCESSED  03500020
         LTR   COUNTREG,COUNTREG       IF ZERO, NO MORE ENTRIES         03510020
         BZ    LASTFBQE                TOP REGION UNALLOCATED           03520020
         LH    SWORK2,D4(UMSMREG)      ADDR NEXT NON-SWAPPED FBQE       03530020
         SLA   SWORK2,D8               SET UP PROPER ADDR               03540020
         BZ    LASTFBQE                TOP OF REGION UNALLOCATED        03550020
         SR    SWORK2,SWORK1           SIZE OF THIS FBQE                03560020
         ST    SWORK2,D8(SWORK1)       INTO FBQE                        03570020
         LR    BACKREG,SWORK1          NEW BACK POINTER                 03590020
         LA    UMSMREG,UMSMEND         PT TO NEXT MAP ENTRY             03600020
         LH    SWORK1,UMSMBG           GET ADDR AREA FROM THIS ENTRY    03610020
         SLL   SWORK1,D8               RESET ADDR                       03620020
         LH    SWORK2,UMSMLN           GET LENGTH FROM MAP              03630020
         SLL   SWORK2,D8               GET REAL LENGTH                  03640020
         AR    SWORK1,SWORK2           GET TO END OF MAPPED ENTRY       03650020
         BR    CODEREG                 GO TO RTN INDICATED IN REG       03660020
SINSWAP  ST    BACKREG,D4(SFBQEREG)    FORWARD AND                      03670020
         ST    SFBQEREG,ZERO(BACKREG)  BACKWARD CHAIN                   03680020
         LR    BACKREG,SFBQEREG        UPDATE CHAIN POINTER             03700020
         L     SFBQEREG,ZERO(SFBQEREG) GET NEXT PTR                     03710020
         CLR   SFBQEREG,SPQEREG        MORE FBQES SWAPPED               03720020
         BNE   SLOWFBQE                YES, FIND NEXT TO QUEUE          03730020
SNONOUT  L     SCOMPREG,PQEREGN        COMPUTE @ OF BYTE PAST REGION    03740020
         A     SCOMPREG,PQESIZE        PT TO BYTE BEYOND REGION         03760020
SREGEND  CLR   SCOMPREG,SWORK1         PAST REGION ?                    03770020
         BE    SQEND                   YES, LAST FBQE BUILT             03780020
         LA    CODEREG,SREGEND         ADDR WHERE CHECK FOR LAST FBQE   03790020
         B     SBUILDFB                GO BUILD NEXT FBQE               03800020
LASTFBQE SR    SCOMPREG,SWORK1         FIND SIZE OF FBQE                03810020
         ST    SCOMPREG,D8(SWORK1)     STORE SIZE IN FBQE               03820020
         ST    SPQEREG,ZERO(SWORK1)    CHAIN TO PQE                     03830020
         B     ALLDONE                 REGION MAPPED, CONTINUE          03840020
SQEND    ST    SPQEREG,ZERO(BACKREG)   QUEUE LAST FBQE TO PQE           03850020
ALLDONE  LM    RTNREG,TJBREG,TWELVE(SAVEREG)   RESTORE REGS             03880020
         TITLE 'TCB READY QUEUE RESTORE'                                03890020
         SPACE 3                                                        03892021
*********************************************************************** 03900020
*                                                                     * 03910020
*  TITLE- TS USER'S TCB READY QUEUE RESTORE                           * 03920020
*                                                                     * 03930020
*  FUNCTION- TO RESTORE A TIME SHARING USER'S TCB TO THE READY QUEUE  * 03940020
*                                                                     * 03950020
*  ENTRY POINT- TRDYRSTR                                              * 03960020
*                                                                     * 03970020
*  INPUT- ADDRESS OF RCB FOR THIS REGION IN REGISTER 11               * 03980020
*         ADDRESS OF TJB FOR THIS USER IS IN REGISTER 12              * 03990020
*                                                                     * 04000020
*********************************************************************** 04010020
         SPACE 2                                                        04011020
TRDYRSTR  EQU  *                                                        04030020
         L     TJBXREG,TJBEXTNT        ADDR TJB EXTENT                  04050020
         L     TJBFSTRG,TJBXFST        ADDR USER'S FIRST TCB            04060020
         L     TJBLSTRG,TJBXLAST       ADDR USER'S LAST TCB             04070020
         L     TCBREG,RCBRCT           GET RCT ADDRESS                  04072020
         MVC   TCBLTC(WORD),TJBXFST    MAKE RCT LOOK LIKE MOTHER        04074020
         SPACE 3                                                        04080020
*                                                                       04082021
*   SET USER'S  DISPATCHING PRIORITY TO TS PRIORITY (VALUE IN TSIA)     04090020
*                                                                       04092021
         SPACE 2                                                        04100020
         L     CVTREG,CVTPTR           ADDR CVT                         04110020
         USING CVTSECT,CVTREG          BASE FOR CVT                     04120020
         L     TSCVTREG,CVTTSCVT       ADDR OF TIME SHARING CVT         04130020
         USING TSCVT,TSCVTREG          BASE FOR TSCVT                   04140020
         L     TSIAREG,TSCVTSIA        ADDR OF TSIA                     04150020
         USING TSIA,TSIAREG            BASE FOR TSIA                    04160020
*                                      IS PRIORITY EQUAL TO USER        04170020
         CLC   TSIACURR,TCBDISPR(TJBFSTRG)    PRIORITY                  04180020
         BE    TLOCATE                 YES                              04190020
         SPACE 3                                                        04200020
*                                                                       04202021
*  SET EACH USER PRIORITY TO TS PRIORITY                                04210020
*                                                                       04212021
         SPACE 2                                                        04220020
TFURTHER MVC   TCBDISPR(BYTE,TJBFSTRG),TSIACURR    CHANGE PRIORITY      04240020
         CR    TJBFSTRG,TJBLSTRG       ALL USER'S TCB'S CHANGED?        04250020
         BE    TLOCATE                 YES                              04260020
         L     TJBFSTRG,TCBNXT(TJBFSTRG)  ADDR USER'S NEXT TCB          04270020
         B     TFURTHER                CHANGE PRIORITY NEXT TCB         04280020
         SPACE 3                                                        04290021
*********************************************************************** 04292020
*  SEARCH TCB READY QUEUE FOR DISPATCHING PRIORITY EQUAL TO TS        * 04300020
*  PRIORITY TO PUT  USER TCB'S ON READY QUEUE. TS USER'S TCBS WILL    * 04310020
*  GO TO HIGHEST LOCATION WITHIN THIER PRIORITY                       * 04320020
*********************************************************************** 04321020
         SPACE 2                                                        04330020
*                                      RCT'S TCB ADDR - STARTING POINT  04340020
TLOCATE  L     TCBLSTRG,RCBRCT         FOR TCB SEARCH                   04350020
TGOON    L     TCBREG,TCBNXT(TCBLSTRG) ADDR NEXT TCB                    04370020
         LTR   TCBREG,TCBREG           IS THERE ANOTHER TCB?            04380020
         BZ    TOEND                   NO                               04390020
*                                      IS READY Q PRIORITY EQUAL        04410020
         CLC   TCBDISPR(BYTE,TCBREG),TSIACURR    TO TS PRIORITY?        04420020
         BNH    TPLACE                 YES                              04430020
SAVETCB  LR    TCBLSTRG,TCBREG         SAVE PREVIOUS TCB ADDR           04450020
         B     TGOON                   GET ADDR NEXT TCB                04460020
         SPACE 3                                                        04470020
*                                                                       04472021
*  PUT TS USER'S TCBS ON READY QUEUE                                    04480020
*                                                                       04482021
         SPACE 2                                                        04490020
TPLACE   CLI    TSIACURR,ZERO          IS TS DISP PRIORITY ZERO         04491020
         BNZ   TPLACE1                 NO, GO MOVE IN TS TCB'S          04492020
         TM    TCBTSFLG,TCBTSTSK       IS THIS TASK A TS TASK           04493020
         BNO   SAVETCB                 NO, GO TEST NEXT TCB             04494020
TPLACE1  MVC   TCBNXT(WORD,TJBLSTRG),TCBNXT(TCBLSTRG)  PLACE TCBS ON    04500020
TLSTSTEP MVC   TCBNXT(WORD,TCBLSTRG),TJBXFST            READY Q         04510020
         B     TEND                    END OF RTN                       04530020
         SPACE 3                                                        04540020
*                                                                       04542021
*  THIS PLACES TS USER TCBS ON END OF TCB READY QUEUE                   04550020
*                                                                       04552021
         SPACE 2                                                        04560020
TOEND    ST    TCBREG,TCBNXT(TJBLSTRG) CHAIN LAST TCB                   04570020
         MVC   TCBNXT(WORD,TCBLSTRG),TJBXFST   TCB ON END OF Q          04580020
TEND     MVI   RCBRSFLG,X'C0'          INDICATE TCB'S PROCESSED         04610020
         TITLE 'ENQUEUE RESTORE'                                        04620020
         SPACE 3                                                        04622021
*********************************************************************** 04630020
* TITLE- ENQUEUE RESTORE                                              * 04640020
*                                                                     * 04650020
* FUNCTION- THIS ROUTINE CHECKS TS USER'S REQUESTS FOR SYSTEM         * 04660020
*           RESOURCES (QEL'S) AND RESTORES THEM TO ACTIVE STATUS.     * 04670020
*           IF THE USER'S REQUEST IS READY TO BE SERVICED THE WAIT    * 04680020
*           COUNT IN THE USER'S SVRB IS DECREMENTED.                  * 04690020
*                                                                     * 04700020
* ENTRY POINT- TENQRSTR                                               * 04710020
*                                                                     * 04720020
* INPUT- ADDRESS OF RCB FOR THIS REGION IN REGISTER 11                * 04730020
*        ADDRESS OF TJB FOR THIS USER IN REGISTER 12                  * 04740020
*                                                                     * 04750020
*********************************************************************** 04760020
         SPACE 3                                                        04770021
TENQRSTR EQU   *                       START OF ENQ RESTORE             04790020
         USING QELSECT,QELREG          BASE FOR QEL                     04800020
         USING CVTSECT,CVTREG          BASE FOR CVT                     04810020
         SPACE 3                                                        04811021
*********************************************************************** 04820020
*                                                                       04830020
*  THIS ROUTINE DETERMINES IF USER HAS OUTSTANDING REQUESTS             04840020
*  BY SEARCHING MAJOR AND MINOR QCB'S FOR QEL'S BELONGING TO USER.      04850020
*                                                                       04860020
*********************************************************************** 04870020
         SPACE 2                                                        04871021
TQELSRCH L     TJBXREG,TJBEXTNT        GET TJB EXTENT ADDR              04880020
         L     TCBREG,TJBXFST          ADDR USER'S FIRST TCB            04890020
TQELCTCK CLI   TCBQEL,ZERO             IS QEL COUNT ZERO?               04900020
         BE    TNXTCB                  YES                              04910020
         SPACE 3                                                        04920020
*                                                                       04922021
*  TCB HAS OUTSTANDING RESOURCE REQUESTS SO MUST FIND QEL'S             04930020
*                                                                       04932021
         SPACE 2                                                        04940020
         L     CVTREG,CVTPTR           ADDR CVT                         04950020
         L     SCVTREG,CVTABEND        ADDR SECONDARY CVT               04960020
         USING SCVTSECT,SCVTREG        BASE FOR SCVT                    04970020
         L     MJQCBREG,SCVTQCBO       ADDR OF DUMMY QCB                04980020
         L     MJQCBREG,ZERO(MJQCBREG) GET ADDR OF FIRST MAJOR QCB      04990020
TMNQBADR L     MIQCBREG,MINQCB(MJQCBREG)     ADDR OF MINOR QCB          05000020
TQELADDR L     QELREG,MINQEL(MIQCBREG) ADDR OF QEL                      05010020
TQELCHCK LH    QELCMPRG,QELTJID1       LOAD REG FOR COMPARE             05030020
         IC    QELCMPRG,QELTJID2       OF TJIDS                         05040020
         N     QELCMPRG,QELIDMSK       TURN OFF HI ORDER BIT QELTJID1   05050020
         CH    QELCMPRG,RCBTJID        ARE TJID'S THE SAME?             05060020
         BE    TESTRSTR                YES                              05070020
TNXTQEL  L     QELREG,QELSMC           ADDR OF NEXT QEL                 05080020
         LA    QELREG,ZERO(QELREG)     CLEAR STATUS BYTE FOR COMPARE    05090020
         LTR   QELREG,QELREG           LAST QEL IN THIS CHAIN           05100020
         BNZ   TQELCHCK                NO                               05110020
         L     MIQCBREG,MINQCB(MIQCBREG)     GET ADDR OF NEXT MINOR QCB 05120020
         LA    MIQCBREG,ZERO(MIQCBREG) CLEAR HI ORDER BYTE         4640 05130020
         LTR   MIQCBREG,MIQCBREG       LAST MINOR QCB IN THIS CHAIN     05140020
         BNZ   TQELADDR                NO                               05150020
         L     MJQCBREG,NEXTMAJ(MJQCBREG)    NEXT MAJOR QCB ADDR        05160020
         LTR   MJQCBREG,MJQCBREG       LAST MAJOR QCB                   05180020
         BNZ   TMNQBADR                NO                               05190020
         B     TDONE                   YES                              05200020
TNXTCB   L     TWKREG1,TJBXLAST        ADDR USER'S LAST TCB             05210020
         CR    TWKREG1,TCBREG          ARE ALL TCB'S CHECKED            05220020
         BE    TDONE                   YES                              05230020
         L     TCBREG,TCBTCB           NEXT TCB ON READY QUEUE          05240020
         B     TQELCTCK                GO CHECK NEXT TCB FOR QELS       05260020
TESTRSTR TM    QELCODE,QELRBWT         THIS QEL TO BE PROCESSED         05270020
         BNO   TCLEAR                  NO, REMOVE TJID AND GET NEXT     05280020
         L     TWKREG1,QELSVRB         ADDR SVRB FOR THIS QEL           05290020
         LA    TWKREG1,ZERO(TWKREG1)   CLEAR TJID OUT                   05300020
         USING RBSECT,TWKREG1          BASE FOR RB                      05320020
         CLI   RBWCF,ZERO              IS SVRB WAIT COUNT ZERO?         05330020
         BE    TCLEAR                  YES                              05340020
         SR    SWORK3,SWORK3           INITIALIZE REG                   05360020
         IC    SWORK3,RBWCF            GET SVRB WAIT COUNT              05370020
         BCTR  SWORK3,ZEROREG          DECREMENT COUNT                  05380020
         STC   SWORK3,RBWCF            STORE NEW COUNT                  05390020
         TM    QELCODE,RESERVED        QEL TO RESERVE SHARED DASD       05431020
         BZ    TCLEAR                 NO, GET NEXT                M5410 05432020
         L     SWORK3,QELTCB           TCB PTR                          05433020
         L     SWORK3,CURPRG(SWORK3)   UCB PTR FOR QEL                  05434020
         ST    SWORK3,QELSVRB          SET UCB PTR IN QEL               05435020
         SR    PARMREG,PARMREG         INIT REGISTER                    05436020
         IC    PARMREG,UCBRSCT(SWORK3) GET UCB RESERVE COUNT            05437020
         LA    PARMREG,ONE(PARMREG)    UPDATE COUNT                     05438020
         STC   PARMREG,UCBRSCT(SWORK3) REPLACE COUNT                    05439020
TCLEAR  MVI   QELTJID1,ZERO             CLEAR TJID FROM QEL TO   M5410  05449020
        MVI   QELTJID2,ZERO             IND. USER BACK IN CORE   M5410  05449420
        NI    QELCODE,RBWTOFF           TURN OFF PROCESS BIT     M5410  05449820
         B     TNXTQEL                 GET NEXT QEL                     05450020
TDONE    MVI   RCBRSFLG,X'E0'          INDICATE QEL'S RESTORED          05470020
         DROP  TWKREG1                 DROP RB BASE                     05471020
         TITLE 'CONTROL BLOCK RESTORE'                                  05480020
         SPACE 3                                                        05482021
*********************************************************************** 05490020
*  TITLE- TIMER QUEUE ELEMENT RESTORE                                 * 05500020
*                                                                     * 05510020
*  FUNCTION- THIS ROUTINE WILL RESTORE A TS USER'S TIMER QUEUE ELEMENT* 05520020
*            TO ACTIVE STATUS AND IF TIME HAS EXPIRED IT WILL COMPLETE* 05530020
*            THE TIMER EXPIRATION FUNCTIONS                           * 05540020
*                                                                     * 05550020
*  ENTRY POINT- TQERSTR                                               * 05560020
*                                                                     * 05570020
*  INPUT- ADDRESS OF RCB FOR THIS REGION IN REGISTER 11               * 05580020
*         ADDRESS OF TJB FOR THIS USER IN REGISTER 12                 * 05590020
*                                                                     * 05600020
*********************************************************************** 05610020
         SPACE 2                                                        05611020
TQERSTR  L     TJBXREG,TJBEXTNT        ADDR TJB EXTENT                  05640020
         L     TJBFSTRG,TJBXFST        ADDR USER'S FIRST TCB            05650020
         LR    TCBREG,TJBFSTRG         GET ADDR USER'S FIRST TCB        05660020
TNXTQE   L     TQEREG,TCBTME           ADDR TIMER Q ELEMENT             05670020
         USING TQE,TQEREG              BASE FOR TQE                     05680020
         LTR   TQEREG,TQEREG           TQE FOR THIS TCB                 05690020
         BZ    TESTNEXT                NO,TEST NEXT TCB                 05700020
         LH    SWORK3,TQETJID1         WAS TQE FLAGGED BY QUIESCE?      05720020
         IC    SWORK3,TQETJID2         LOAD ID INTO REG FOR COMPARE     05730020
         CH    SWORK3,RCBTJID          TJIDS EQUAL?                     05740020
         BNE   TESTNEXT                NO, CONTINUE CHECKING TCBS       05750020
         XC    TQETJID1(BYTE),TQETJID1 ZERO TJID                        05760020
         XC    TQETJID2(BYTE),TQETJID2 FIELDS                           05770020
         SPACE 3                                                        05790020
*                                                                       05792021
*   TQE IS NOW CHECKED TO SEE IF TIME INTERVAL HAS EXPIRED              05800020
*                                                                       05802021
         SPACE 2                                                        05810020
         TM    TQEFLGS,TQENTONQ        IS TQE ON TIMER QUEUE            05820020
         BZ    TESTNEXT                YES, SEE IF EXIT SPECIFIED       05830020
         SPACE 3                                                        05850020
*                                                                       05852021
*   TIME INTERVAL EXPIRED. TQE MUST NOW BE TESTED FOR TYPE OF INTERVAL  05860020
*                                                                       05862021
         SPACE 2                                                        05870020
         TM    TQEFLGS,TQEWAIT         WAIT INTERVAL SPECIFIED          05880020
         BZ    TESTEXIT                NO                               05890020
         TM    TQEFLGS,TQEREAL         IS IT REAL REAUEST               05900020
         BNZ   TESTEXIT                YES, TEST IF EXIT SPECIFIED      05910020
         SPACE 3                                                        05920020
*                                                                       05922021
*    WAIT SPECIFIED, MUST POST ECB                                      05930020
*                                                                       05932021
         SPACE 2                                                        05940020
         LA    SWORK2,TQEECB           GET ECB ADDRESS                  05960020
         SR    ZEROREG,ZEROREG         INIT REG                         05970020
         POST  (SWORK2),(0)            SERVICE TIMER WAIT               05980020
         B     TSETCOMP                GO MARK TQE PROCESSING COMPLETE  06000020
         SPACE 3                                                        06010020
TESTEXIT TM    TQEFLGS,TQEXIT          EXIT SPECIFIED?                  06020020
         BZ    TSETCOMP                NO                               06030020
         SPACE 3                                                        06050020
*                                                                       06052021
*  EXIT SPECIFIED. INITIALIZE TQE AS IRB AND GO TO EXIT EFFECTOR(STG 2) 06060020
*                                                                       06062021
         SPACE 2                                                        06070020
         USING RBSECT,TQEREG           NEW BASE FOR RB                  06080020
         MVC   RBWCSA(WORD),TSZSTAB    RB SIZE AND FLAGS FIELDS         06090020
         MVC   RBEP(WORD),TQEXITAD(TQEREG)  ENTRYP PT TO EXIT RTN       06100020
         MVC   RBPPSAV+BYTE(BYTE3),TQESAADR(TQEREG)  SAVE AREA ADDR     06110020
         ST    TQEREG,IQEADR(TQEREG)   ADDR IRB TO IQE                  06120020
         ST    TCBREG,TCBADR(TQEREG)   TCB ADDR TO IQE                  06130020
         SR    SWORK2,SWORK2           INIT REG                         06140020
         ST    SWORK2,TCBTME           CLEAR TQE ADDR IN TCB            06150020
         ST    SWORK2,RBTAWCSA         ZERO RB TA WAIT COUNT SAVE AREA  06160020
         LR    SWORK2,BASEREG          SAVE REGS                        06170020
         LR    TWKREG1,RTNREG          SAVE REG 14                      06180020
         USING TQE,TQEREG              BASE FOR TQE                     06190020
         LA    TADIQERG,TQEIQE         IQE ADDR FOR EXIT EFF            06210020
         LCR   TADIQERG,TADIQERG       SET UP INPUT TO EXIT EFFECTOR    06220020
         L     CVTREG,CVTPTR           GET CVT PTR                      06230020
         USING CVTSECT,CVTREG          BASE FOR CVT                     06240020
         L     CODEREG,CVT0EF00        ADDR EXIT EFFECTOR               06250020
*                                      GO TO EXIT EFFECTOR TO           06260020
*                                      SCHEDULE EXIT                    06262020
         BALR  RTNREG,CODEREG          SCHEDULE EXIT                    06270020
         LR    BASEREG,SWORK2          RESTORE REGS                     06280020
         LR    RTNREG,TWKREG1          RESTORE RETURN REG               06290020
         NI    TJBRSTOR,TNTLGWT    CLEAR LONGWAIT FLG IN TJBX CC A68775 06300021
TSETCOMP OI    TQEFLGS,TCOMP           MARK TQE PROCESSING COMPLETE     06310020
TESTNEXT C     TCBREG,TJBXLAST         USER'S LAST TCB PROCESSED?       06320020
         BE    TQEDONE                 YES, TQE PROCESSING COMPLETE     06330020
         L     TCBREG,TCBTCB           NO, GET ADDR NEXT TCB            06340020
         B     TNXTQE                  GO PROCESS NEXT TQE              06360020
TQEDONE  MVI   RCBRSFLG,X'F0'          TQE PROCESSING COMPLETE          06380020
         DROP  TQEREG                  DROP TQE AND RB BASE             06381020
         EJECT                                                          06390020
         SPACE 3                                                        06392021
*********************************************************************   06400020
*                                                                       06410020
*  GET RQE'S FROM SAVE QUEUE IN TJBX(IF ANY) AND QUEUE THEM ON AEQA.    06420020
*  ALSO CLEAR TJID AS USER IS RESTORED                                  06430020
*                                                                       06440020
*********************************************************************   06450020
         SPACE 2                                                        06451021
TRQERSTR LH    TJIDREG,RCBTJID         PLACE TJID IN REG FOR COMPARES   06480020
         L     TSAVRQEG,TJBXRQE        ADDR RQE'S ON SAVE Q             06490020
         USING RQESECT,TSAVRQEG        BASE FOR REQUEST QUEUE ELEMENTS  06500020
TONLAST  LTR   TSAVRQEG,TSAVRQEG       RQE'S ON QUEUE                   06510020
         BZ    TIQERSTR                NO                               06520020
         SPACE 3                                                        06530020
*                                                                       06532021
*   CLEAR TJID FIELDS IN EACH RQE PUT BACK ON QUEUE                     06540020
*                                                                       06542021
         SPACE 2                                                        06550020
TONCLEAR XC    RQETJID1(BYTE),RQETJID1 CLEAR TJID                       06560020
         XC    RQETJID2(BYTE),RQETJID2 FROM RQES                        06570020
         MVI   RQEIDT,ZERO        CLEAR FIELD TO INDICATE       A44369  06572021
*                                 TO IOS THAT RQE CAN BE PURGED         06574021
         SPACE 3                                                        06580020
*                                                                       06582021
*  PUT RQE ON AEQA                                                      06590020
*                                                                       06592021
         SPACE 2                                                        06600020
         L     CVTREG,CVTPTR           GET CVT ADDR                     06610020
         USING CVTSECT,CVTREG          BASE FOR CVT                     06620020
         L     CODEREG,CVT0EF00        ADDR STAGE 2 EXIT EFFECTOR       06630020
         LR    TBLKREG,TSAVRQEG        RQE ADDR FOR EXIT EFFECTOR       06640020
         LH    TSAVRQEG,RQELNK         GET NEXT RQE                     06650020
         LR    SWORK2,BASEREG          SAVE REGS                        06660020
         LR    TWKREG1,RTNREG          SAVE RETURN REG ADDR             06670020
         BALR  RTNREG,CODEREG          GO TO EXIT EFFECTOR              06680020
         LR    BASEREG,SWORK2          RESTORE REGS                     06690020
         LR    RTNREG,TWKREG1          RESTORE RETURN REG               06700020
         B     TONLAST                 MORE RQE'S?                      06710020
         SPACE 3                                                        06720020
*                                                                       06722021
*  GET IQE'S FROM SAVE QUEUE IN TJBX IF ANY AND QUEUE THEM ON AEQJ      06730020
*                                                                       06732021
         SPACE 2                                                        06740020
TIQERSTR L     TSAVIQEG,TJBXIQE        ADDR IGE'S ON SAVE Q             06760020
TCKIQE   LTR   TSAVIQEG,TSAVIQEG       IQE ON QUEUE                     06770020
         BZ    TON                     NO, FINISHED IQE PROCESSING      06780020
         L     CVTREG,CVTPTR           GET CVT ADDR                     06790020
         L     CODEREG,CVT0EF00        ADDR STAGE 2 EXIT EFFECTOR       06800020
         LCR   TBLKREG,TSAVIQEG        COMPLEMENT IQE ADDR FOR EX EFF   06810020
         L     TSAVIQEG,IQELNK(TSAVIQEG) GET ADDR OF NEXT IQE           06820020
         LR    SWORK2,BASEREG          SAVE REGS                        06830020
         LR    TWKREG1,RTNREG          SAVE RETURN REG ADDR             06840020
         BALR  RTNREG,CODEREG          GO TO EXIT EFFECTOR              06850020
         LR    BASEREG,SWORK2          RESTORE REGS                     06860020
         LR    RTNREG,TWKREG1          RESTORE RETURN REG ADDR          06870020
         B     TCKIQE                  GO CHECK FOR ANOTHER IQE         06880020
         DROP  TSAVRQEG                                                 06881020
         SPACE 3                                                        06882021
*********************************************************************** 06883020
*        ROUTINE TO REMOVE TJID FROM RQES                             * 06884020
*********************************************************************** 06885020
         SPACE 2                                                        06885421
TON      L     TJBXREG,TJBEXTNT        ADDRESS TJBX               M3864 06886020
         L     TCBREG,TJBXFST          GET FIRST USER TCB         M3864 06887020
         L     TCBLSTR,TJBXLAST        GET LAST USER TCB          M3864 06888020
         USING TCB,TCBREG              ADDR TCB                   M3864 06889020
GETTOPRB L     TRBREG,TCBRBP           GET TOP RB OFF TCB         M3864 06890020
         USING RBSECT,TRBREG           ADDR RB                    M3864 06891020
TESTIRB  TM    RBSTAB,RBFTIRB          IS THIS AN IRB ?           M3864 06892020
         BZ    GTNXTRB                 NO, GET NEXT RB            M3864 06893020
         TM    RBSTAB2,RBRQE1          ARE RQE'S QUEUED OFF IRB ? M3864 06894020
         BO    GTNXTRB                 NO, GET NEXT RB            M3864 06895020
         TM    RBSTAB2,RBRQE2          ARE RQE'S QUEUED OFF IRB ? M3864 06896020
         BZ    GTNXTRB                 NO, GET NEXT RB            M3864 06897020
         SPACE 2                                                  M3864 06898021
*                                                                       06898421
*        DEFLAG RQE'S                                             M3864 06899020
*                                                                       06899421
         SPACE 2                                                  M3864 06900021
         LH    RQEREG,RBIQE2+TWO       GET RQE                    M3864 06901020
         USING RQESECT,RQEREG          ADDR RQE                   M3864 06902020
RQEFLAG  XC    RQETJID1(ONE),RQETJID1  CLEAR FIRST HALF OF TJID   M3864 06903020
         XC    RQETJID2(ONE),RQETJID2  CLEAR SECOND HALF OF TJID  M3864 06904020
         MVI   RQEIDT,ZERO             CLEAR FIELD TO INDICATE TOA44369 06904421
*                                      IOS RQE CAN BE PURGED     A44369 06904821
         LH    RQEREG,RQELNK           GET NEXT RQE               M3864 06905020
         LTR   RQEREG,RQEREG           ANY MORE RQES ?            M3864 06906020
         BNZ   RQEFLAG                 YES CLEAR FLAG             M3864 06907020
         SPACE 2                                                  M3864 06908021
*                                                                       06908421
*        LOOP CONTROL                                             M3864 06909020
*                                                                       06909421
         SPACE 2                                                  M3864 06910021
GTNXTRB  L     TRBREG,RBLINK           GET NEXT RB                M3864 06911020
         LA    TRBREG,ZERO(TRBREG)     CLEAR HIGH ORDER BYTE      M3864 06912020
         CR    TRBREG,TCBREG           ARE WE BACK TO TCB ?       M3864 06913020
         BNE   TESTIRB                 NO, TEST FOR IRB           M3864 06914020
         CR    TCBREG,TCBLSTR          IS THIS LAST USER TCB ?    M3864 06917020
         L     TCBREG,TCBTCB           GET NEXT TCB               M3864 06920020
         BNE   GETTOPRB                NO, GO BACK AGAIN          M3864 06923020
         DROP  RQEREG,TRBREG                                      M3864 06926020
         MVI   RCBRSFLG,X'F8'          IQE AND RQE PROCESSING DONE      06929020
         TITLE 'RESTORE USERS I/O'                                      06932020
         SPACE 3                                                        06934021
*                                                                       06934421
*    RESTORE THE USER'S I/O                                             06935020
*                                                                       06937021
         SPACE 2                                                        06942020
RSTORIO  L     SWORK1,TJBXQPL          GET QPL ADDR FOR IOS             06950020
          STM   RTNREG,TJBREG,TWELVE(SAVEREG) REGS ACROSS IOSGEN  M1187 06952020
         SPACE 3                                                        06960021
         IOSGEN  RESTORE,AUTH=IKJEAR03 RESTORE USER'S I/O               06970020
         SPACE 3                                                        06980021
         LM    RTNREG,TJBREG,TWELVE(SAVEREG) REGS AFTER IOSGEN    M1187 06982020
         MVI   RCBRSFLG,X'FC'          I/O RESTORE COMPLETE             06990020
         TITLE 'WTOR RESTORE'                                           07000020
         SPACE 3                                                        07010021
*********************************************************************** 07040020
* RESTORE WTOR REPLIES                                                * 07050020
*                                                                     * 07060020
* THIS ROUTINE RESTARTS REPLY PROCESSING FOR REPLIES RECEIVED WHILE   * 07070020
* THE USER WAS SWAPPED OUT. IF REPLY WAS NOT RECEIVED THE RQE SHALL   * 07080020
* BE MARKED READY BY TURNING OFF THE ROLLED OUT FLAG AND ZEROING THE  * 07090020
* RQETJID FIELDS                                                      * 07100020
*                                                                     * 07110020
* INPUT- REG 11(RCBREG)                ADDRESS OF RCB                 * 07120020
*        REG 12(TJBREG)                ADDRESS OF TJB                 * 07121020
*                                                                     * 07130020
* OUTPUT- NONE                                                        * 07140020
*                                                                     * 07150020
*********************************************************************** 07160020
         SPACE 2                                                        07162021
WTORREST EQU   *                                                        07165020
SRESTOR1 EQU   *                                                        07180020
         L     CVTREG,CVTPTR           GET CVT ADDR                     07190020
         USING CVTSECT,CVTREG          BASE FOR CVT                     07200020
*                                      ADDR TABLE TO CONSOLE            07220020
         L     SRQEREG,CVTCUCB         UNIT CONTROL BLOCKS              07230020
         USING UCM,SRQEREG             BASE FOR UCM                     07240020
         L     SWORK2,UCMWTOQ          ADDR WQE CHAIN                   07250020
         L     SWORK3,UCMRPYQ          ADDR RQE CHAIN                   07270020
SRESTOR2 LTR   SWORK3,SWORK3           ANY (MORE) RQE'S?                07280020
         BZ    WQESEARC                NO, SEARCH WQE QUEUE             07290020
         USING  RPQESECT,SWORK3        BASE FOR REPLY QUEUE ELEMENT     07310020
         LH    SWORK4,RPETJID1         GET TJID FOR COMPARE AGAINST     07320020
         IC    SWORK4,RPETJID2         THIS USER'S TJID?                07330020
         CR    SWORK4,TJIDREG          TJIDS EQUAL?                     07340020
         BNE   SRESTOR3                NO,FIND NEXT RQE                 07350020
         NI    RPQEXA,TALLON-RQERO     YES, ZER ROLLOUT FLAG IN RQE     07360020
         XC    RPETJID1(BYTE),RPETJID1 REMOVE TJID                      07370020
         XC    RPETJID2(BYTE),RPETJID2 FROM REPLY QUEUE ELEMENT         07380020
         TM    UCMMODE,MCSINSYS        MCS PRESENT IN SYSTEM?           07390020
         BZ    SRESTOR4                NO, CONTINUE REGULAR PROCESSING  07400020
         L     SPARMREG,RPQEXB       YES,FIND  WQE ASSOCIATED           07410021
         LTR   SPARMREG,SPARMREG    IS THERE A WQE PRESENT   AJ  A52532 07410421
         BZ    SRESTOR3             GET NEXT RPQE IF NO      AJ  A52532 07410821
         USING WQE,SPARMREG                                             07412020
         L    SPARMREG,WQETCB          TEMP MCS BUFFER AREA       M2202 07414020
         DROP SPARMREG                                            M2202 07416020
         USING      WQE,SWORK2          BASE FOR WRITER QUEUE ELE M2202 07418020
         B     SRESTOR5                SEE IF REPLY RECEIVED            07420020
SRESTOR4 L     SPARMREG,RPQEXB         ADDR RPQE TEMPORARY BUFFER       07430020
         TM    RPQEXA,X'10'                                       M4525 07432021
         BO    SRESTOR3                                           M4525 07434020
SRESTOR5 LTR   SPARMREG,SPARMREG       WAS REPLY RECEIVED?              07440020
         BZ    SRESTOR3                GET NEXT REPLY QUEUE ELEMENT     07450020
         SR    ZEROREG,ZEROREG          FOR SVC34 SERVICE ROUT    M2277 07452020
         SVC   34   (MGCR SPARMREG)    RESTART REPLY PROCESSING         07460020
         B     SRESTOR1                CHECK FOR MORE RQES ON QUEUE.    07470020
*                                      START AT BEGINNING OF QUEUE AS   07480020
*                                      IT MAY HAVE BEEN REORDERED       07490020
SRESTOR3 L     SWORK3,RPQELKP          GET NEXT RPQE ON QUEUE           07500020
         B     SRESTOR2                AND GO TO PROCESS IT             07510020
WQESEARC TM    UCMMODE,MCSINSYS        IS MCS IN SYSTEM           M2769 07510420
         BO    NEXTROUT                YES BYPASS CLEARING TJID'S M2769 07510820
*                                      IF MCS THEN NO TJID'S WERE PUT   07511620
*                                      INTO THE WQE'S             M2769 07511720
         LA    SWORK2,ZERO(SWORK2)     CLEAR MCS COUNT FIELD      M2202 07512020
         LTR   SWORK2,SWORK2           ANY WQE'S                        07520020
         BZ    NEXTROUT                NO                               07530020
         SR    SWORK4,SWORK4           CLEAR REG SO CAN INSERT TJID     07540020
         IC    SWORK4,WQETJID1         1ST HALF USER TJID               07550020
         SLL   SWORK4,D8               MOVE IT TO MAKE ROOM FOR 2ND     07560020
         IC    SWORK4,WQETJID2         INSERT 2ND HALF                  07570020
         CR    SWORK4,TJIDREG          TJID'S EQUAL - USER'S WQE?       07580020
         BNE   NEXTWQE                 NO, GET NEXT TO PROCESS          07590020
         XC    WQETJID1(HALFWORD),WQETJID1  CLEAR TJID FIELDS           07600020
NEXTWQE  L     SWORK2,WQELKP           ADDR NEXT WQE                    07610020
         B     WQESEARC                CHECK NEXT WQE                   07620020
NEXTROUT MVI   RCBRSFLG,X'FE'          WTOR PROCESSING COMPLETE         07640020
         TITLE  'INTERPARTITION POST BLOCK SERVICING'                   07650020
         SPACE 3                                                        07650421
*********************************************************************** 07651020
*    IPPB RESTORE                                                     * 07660020
*********************************************************************** 07661020
         SPACE  2                                                       07670020
IPPBSTOR EQU   *                       START OF IPPB RESTORE            07690020
         USING  TJB,TJBREG             BASE FOR TJB                     07700020
         L     IPPBREG,TJBIPPB         ADDR IPPB                        07710020
         LTR   IPPBREG,IPPBREG         ARE THERE ANY IPPBS              07720020
         BZ    CONTINUE                NO, GO ON                        07730020
         L     CVTREG,CVTPTR           GET CVT PTR                      07740020
         USING CVTSECT,CVTREG          BASE FOR CVT                     07750020
         USING IPPB,IPPBREG            BASE FOR IPPB                    07760020
         L     SWORK4,RCBRCT           SET UP TCB ADDRESS TO PASS POST  07761020
         STM   RCBREG,TJBREG,SIXTY4(SAVEREG)   SAVE RCB & TJB ADDRESS   07770020
         ST    RTNREG,TWELVE(SAVEREG)  SAVE RETURN REG                  07772020
         LR    SWORK2,SAVEREG          SAVE ADDR SAVE AREA              07780020
POSTANOT L     CODEREG,CVT0PT01        BR ENTRY ADDR FOR POST RTN       07790020
         LR    SWORK1,BASEREG          SAVE BASE TEMPORARILY            07800020
         L     RECBREG,IPPBECB         ADDR ECB TO BE POSTED            07820020
          LA    RECBREG,ZERO(RECBREG)  CLEAR HI ORDER BIT SO NOT M1562  07822000
*                                   RECOGNIZED AS INT. PART.POST M1562  07824000
         LR    TJBREG,SWORK4           SET UP TCB REG FOR POST          07830020
POSTON   L     BASEREG,IPPBCODE        GET POST CODE                    07860020
         BALR  RTNREG,CODEREG          GO TO POST RTN                   07870020
         LR    BASEREG,SWORK1          RESTORE BASE                     07880020
         LR    SWORK1,IPPBREG          SET UP REGS TO FREEMAIN IPPB     07890020
         L     IPPBREG,IPPBTJQ         GET PTR TO NEXT IPPB             07900020
         LA    ZEROREG,SIXTEEN         LENGTH OF IPPB                   07910020
         O     ZEROREG,SP245           INDICATE SUBPOOL TO FREEMAIN     07920020
         FREEMAIN  R,LV=(0),A=(1)      FREE UP THE IPPB                 07930020
         SPACE 2                                                        07932021
         LTR   IPPBREG,IPPBREG         ANY MORE IPPB'S?                 07940020
         BNZ   POSTANOT                YES, PROCESS THEM                07950020
         LR    SAVEREG,SWORK2          RELOAD SAVEREG                   07960020
         LM    RCBREG,TJBREG,SIXTY4(SAVEREG)    RESTORE OTHER REGS      07970020
         L     RTNREG,TWELVE(SAVEREG)                                   07972020
         XC    TJBIPPB(WORD),TJBIPPB   CLEAR FIELD IN TJB               07980020
CONTINUE EQU   *                       *                                07990020
         CLI   TJBATTN,ZERO        ANY ATTENTION EXITS REQUESTED        07991020
         BE    NOATTN              NO, CONTINUE PROCESSING              07992020
         OI    RCBFLG,RCBFAT     SET ATTENTION FLAG FOR R01             07993020
         NI    TJBRSTOR,TNTLGWT  CLEAR LONG WAIT FLAG                   07995020
NOATTN   EQU   *                                                        07998020
         TITLE 'TERMINAL IWAIT/OWAIT RESTORE'                           08000020
         SPACE 3                                                        08002021
*                                                                       08004021
*             HANDLE IWAIT AND OWAIT RESTORE                            08010020
*                                                                       08012021
         SPACE 3                                                        08020020
         USING TCBSECT,TCBREG          BASE REG FOR TCB                 08030020
         L     TJBLSTRG,TJBXLAST       ADDR TS USER'S LAST TCB          08040020
         L     TCBREG,TJBXFST          ADDR TS USER'S FIRST TCB         08050020
         TM    TJBRSTOR,TJBOWP         END OF OUTPUT WAIT CONDITION?    08060020
         BZ    TESTINWT                NO, CHECK INPUT WAIT             08070020
         NI    TJBRSTOR,TALLON-TJBOWP  YES, RESET OUTPUT WAIT FLAG      08080020
OUTWTOFF NI    TCBNDSP2,TALLON-TCBOWAIT  RESET OUTPUT WAIT FLAG         08090020
         CR    TCBREG,TJBLSTRG         LAST TCB?                        08100020
         BE    TESTINWT                YES, CHECK FOR INPUT WAIT        08110020
         L     TCBREG,TCBTCB           NO, RESET NEXT TCB DISPATCHABLE  08120020
         B     OUTWTOFF                CHECK NEXT TCB FOR OUTPUT WAIT   08130020
         SPACE 2                                                        08132021
TESTINWT TM    TJBRSTOR,TJBIWP         END OF INPUT WAIT CONDITION?     08140020
         BZ    RCTIWOW9                NO FLAG SET, CONTINUE PROCESS    08150020
         NI    TJBRSTOR,TALLON-TJBIWP  YES, RESET INPUT WAIT FLAG       08160020
         L     TCBREG,TJBXFST          RESET TCB REG                    08170020
INWTOFF  NI    TCBNDSP2,TALLON-TCBIWAIT SET TCB DISPATCHABLE            08180020
         CR    TCBREG,TJBLSTRG         LAST TCB?                        08190020
         BE    RCTIWOW9                CONTINUE PROCESSING              08200020
         L     TCBREG,TCBTCB           GET ADDR NEXT TCB                08210020
         B     INWTOFF                 CHECK NEXT TCB FOR INPUT WAIT    08220020
RCTIWOW9 EQU   *                       *                                08230020
         TITLE 'TRANSIENT AREA RESTORE'                                 08241020
         SPACE 3                                                        08243021
*********************************************************************** 08250020
*   TRANSIENT AREA HANDLER RESTORE                                      08260020
* THIS ROUTINE CHECKS IF ANY SVRBS WERE PURGED FROM THE USER QUEUES   * 08270020
* IF NO - EXIT . IF YES , REQUEU ON CORRECT USER QUEUE AND CALL       * 08280020
* TRANSIENT AREA REFRESH ROUTINE.                                     * 08290020
*                                                                     * 08300020
*********************************************************************** 08310020
         SPACE  2                                                       08320020
TARESTOR EQU   *                       *                                08340020
         L     CVTREG,CVTPTR           GET CVT PTR                      08360020
         USING CVTSECT,CVTREG          BASE FOR CVT                     08370020
         USING  TCBSECT,TCBREG         BASE FOR TCB                     08380020
         USING  RCB,RCBREG             BASE FOR RCB                     08390020
         USING  TJB,TJBREG             BASE FOR TJB                     08400020
         USING  TJBX,TJBXREG           BASE FOR TJBX                    08410020
         L     SCVTREG,CVTABEND        GET ADDR SCVT                    08420020
         USING SCVTSECT,SCVTREG        BASE FOR SCVT                    08430020
         USING RBSECT,SVRBREG          NEW BASE FOR RB                  08440020
         L     TACTSREG,SCVTTACT       ADDR OF TACT                     08450020
         L     TJBXREG,TJBEXTNT        GET ADDR TJBX                    08460020
         L     SVRBREG,TJBXSVRB        ADDR 1ST SVRB PURGED             08470020
         LTR   SVRBREG,SVRBREG         IF ANY                           08480020
         BE    SETDISP                 NONE PURGED, CONTINUE            08490020
SVRBENQ  LH    ENTRYREG,RBTABNO        GET DISPLACEMENT OF TACT ENTRY   08500020
         AR    ENTRYREG,TACTSREG       POINTER TO TACT ENTRY            08520020
         L     SWORK1,RBSVTQN          SAVE POINTER TO NXT US.PURGED    08530021
         MVC   RBSVTQN(WORD),D4(ENTRYREG)  MOVE PTR FROM TACT TO SVRB   08540021
         ST    SVRBREG,D4(ENTRYREG)    POINT TACT TO THIS SVRB          08550020
         L     CVTREG,CVTPTR           GET CVT PTR                      08560020
         USING CVTSECT,CVTREG          BASE FOR CVT                     08570020
         L     SCVTREG,CVTABEND        GET ADDR SCVT                    08580020
         USING SCVTSECT,SCVTREG        BASE FOR SCVT                    08590020
         L     SWORK3,SCVTAUCT         GET TRANSIENT AREA USER COUNT    08600020
         L     SWORK2,ZERO(SWORK3)     GET CURRENT COUNT                08610020
         LA    SWORK2,ONE(SWORK2)      INCREMENT                        08620020
         ST    SWORK2,ZERO(SWORK3)     RESET SCVTAUCT                   08630020
         CLI   ZERO(ENTRYREG),TABLOAD  IS TAB BEING LOADED              08640020
         BE    TESTSVRB                GO ON TO NEXT SVRB               08650020
         CLC   D9(THREBYTE,ENTRYREG),RBSVTTR  NO, RTN IN TAB?           08670020
         BNE   TESTSVRB                NO,GO TO NEXT                    08680020
         MVC   RBWCF(BYTE),RBTAWCSA    RESTORE WAIT COUNT               08760020
         MVI   RBTAWCSA,ZERO            CLEAR SAVE WAIT COUNT FIELD     08810020
         MVI   ZERO(ENTRYREG),ZERO     SET TAB IN USE                   08820020
TESTSVRB LTR   SVRBREG,SWORK1          TEST SAVED ADDRESS,MORE SVRBS    08830020
         BNE   SVRBENQ                 YES, GO PROCESS                  08840020
         TITLE 'RESET TS NONDISPATCHABILITY FLAG'                       08860020
         SPACE 3                                                        08862021
*                                                                       08864021
*    RESET THE TIME SHARING NONDISPATCHABILITY FLAG                     08870020
*                                                                       08872021
         SPACE 2                                                        08880020
SETDISP  EQU   *                                                 A41399 08880821
         L     CVTREG,CVTPTR            GET CVT ADDRESS                 08881600
         USING CVTSECT,CVTREG           BASE FOR CVT                    08882400
         TM    CVTOPTA,CVTDDR           Q. DDR IN SYSTEM         A41399 08883221
         BZ    SETDISP1                 NO                       A41399 08884021
         L     TCBREG,CVTDCB            LOGREG DCB PTR.          A41399 08884821
         L     TCBREG,ZERO(TCBREG)      IORMSCOM PTR.            A41399 08885621
         USING IGFIORMS,TCBREG                                   A41399 08886421
         L     TCBREG,ALLOCTCB          DDR TCB                AF M1433 08887221
         DROP  TCBREG                                                   08888000
         USING TCBSECT,TCBREG                                           08888800
         TM    TJBRSTOR,TJBDDRD         DDR NON-DISP FLAG RESET  A41399 08889621
         BZ    SETDISPA                 NO                       A41399 08890421
         NI    TCBNDSP1,TALLON-TCBDDRND YES-CLEAR NON-DISP FLAG-FIX EQ. 08891221
         B     SETDISPB                                          A41399 08892021
SETDISPA EQU   *                                                 A41399 08892821
         TM    TJBRSTOR,TJBDDRND        Q. TJB NON-DISP BIT SET  A41399 08893621
         BZ    SETDISP1                 NO                       A41399 08894421
         OI    TCBNDSP1,TCBDDRND        SET DDR TCB NON-DISP     A41399 08895221
SETDISPB EQU   *                                                 A41399 08896021
         NI    TJBRSTOR,TALLON-TJBDDRD-TJBDDRND CLEAR TJB FLAGS  A41399 08896821
         B     DISPOFF             BRANCH                    AF   M1430 08897321
SETDISP1 EQU   *                                                 A41399 08897621
         L     TCBREG,TJBXFST          INITIALIZE TCB REG    AF   M1430 08899621
DISPOFF  NI    TCBNDSP2,TALLON-TCBNDTS BITS TO INDICATE DISPATCHABLE    08900020
         CLC   TCBSCNDY(THREBYTE),ZEROMASK  SECONDARY NONDISP BITS OFF  08910020
         BNZ   DISPCHK                 NO, DON'T RESET PRIMARY BIT      08920020
         NI    TCBFLGS5,TALLON-TCBPNDSP YES, RESET PRIMARY BIT ALSO     08930021
         NI    TCBFLGS4,TALLON-TCBRQENA  RESET RQE NOT AVAIL  AJ M4903  08932021
*                                        MIGHT NOW BE ONE     AJ M4903  08934021
DISPCHK  C     TCBREG,TJBXLAST         ALL TCBS MARKED?                 08940020
         BE    CALLTAR                 YES, GO TO TA REFRESH PROC       08950020
         L     TCBREG,TCBTCB           GET ADDR NEXT TCB                08960020
         B     DISPOFF                 NO, GO CHECK NEXT TCB            08970020
         SPACE 2                                                        08980020
CALLTAR  L     SWORK1,TJBXSVRB         ANY ENQUEUED?                    08990020
         LTR   SWORK1,SWORK1           IF ZERO NO SVRBS QUEUED          09010020
         BE    OUTTARES                NO, FINISHED                     09020020
         L     TCBREG,RCBRCT           ADDR RCT'S TCB                   09040020
         L     SVRBREG,TCBRBP          CALL T/A REFRESH ROUTINE         09050020
         MVC   RBOPSW(DBLEWORD),NEWPSW SET OPSW TO RETURN POINT         09060020
         STM   ZEROREG,CODEREG,TCBGRS  SAVE REGS                        09070020
         L     CVTREG,CVTABEND         ADDR SECONDARY CVT               09100020
         USING SCVTSECT,CVTREG         BASE FOR SCVT                    09110020
         L     TARFRREG,SCVTTAR        ADDR TRANS. AREA REFRESH RTN     09120020
         BR    TARFRREG                GO TO TA REFRESH ROUTINE         09130020
TABACK   L     CVTREG,CVTPTR           GET CVT ADDR                     09140020
         USING CVTSECT,CVTREG          BASE FOR CVT                     09150020
         L     SWORK1,CVTTCBP          PTR TO NEW/OLD                   09160020
         L     TCBREG,WORD(SWORK1)     ADDR OLD                         09170020
         LM    ZEROREG,CODEREG,TCBGRS  RESTORE REGS                     09180020
OUTTARES EQU   *                       *                                09190020
         MVI   RCBRSFLG,X'FF'          TA PROCESSING COMPLETE           09200020
         DROP  SVRBREG                 DROP BASE FOR RB                 09201020
         TITLE 'POST LOGON IMAGE'                                       09210020
         SPACE 3                                                        09212021
*                                                                       09214021
*        POST  LOGON IMAGE IF THIS IS A LOGON RESTORE                   09220020
*                                                                       09222021
         SPACE 3                                                        09230020
LOGPOST  EQU   *                                                        09252020
         TM    TJBRSTOR,TJBLOGP        LOGON IMAGE RESTORE?             09260020
         BZ    NOTLOGON                NO-BYPASS POST                   09270020
         NI    TJBRSTOR,TALLON-TJBLOGP TURN OFF TJB LOGON FLAG          09280020
         L     PARMREG,TJBXAECB        GET ECB ADDR FROM TJBX           09290020
         POST  (1)                     POST LOGON                       09300020
         SPACE 2                                                        09302021
NOTLOGON EQU   *                       *                                09310020
         TITLE ' MARK USERS TJB FOR INCORE'                             09320021
         SPACE 3                                                        09330020
         OI    TJBSTAT,TJBINCOR        TURN ON INCORE BIT               09340020
         TITLE 'LONG WAIT TEST RESTORE'                                 09390020
         SPACE 3                                                        09392021
*********************************************************************** 09400020
* THIS ROUTINE  IS THE LONG WAIT FUNCTION OF RESTORE. THE ROUTINE TESTS 09410020
* FOR ANY OF THE TS USER'S TCB'S OR RB'S THAT CAN BE DISPATCHED.IF NONE 09420020
* ARE FOUND,THEN THE TS DRIVER IS NOTIFIED THAT THIS USER IS STILL IN   09430020
* A LONG WAIT AND CAN BE SWAPPED OUT IMMEDIATELY                        09440020
*                                                                       09450020
*********************************************************************** 09460020
         SPACE 2                                                        09461020
TSTLWAIT L     TJBXREG,TJBEXTNT        GET ADDR TJB EXTENT              09480020
         TM    TJBRSTOR,TJBLWAIT       USER IN LONGWAIT WHEN QUIESCED?  09490020
         BNO   TCONRSTR                NO,CONTINUE RESTORE              09500020
         L     TCBREG,TJBXFST          ADDR TS USER'S FIRST TCB         09510020
         USING TCBSECT,TCBREG          BASE FOR TCB                     09520020
         SPACE 3                                                        09530020
*                                                                       09532021
* FIND CURRENT  RB AND TEST FOR WAIT CONDITION                          09540020
*                                                                       09542021
         SPACE 2                                                        09550020
TCURRB   L     TRBREG,TCBRBP           GET ADDR OF CURRENT RB           09560020
         USING RBSECT,TRBREG           NEW BASE FOR RB                  09570020
         CLI   RBWCF,ZERO              WAIT COUNT ZERO?                 09580020
         BNE   TESTTCB                 NO                               09590020
         SPACE 3                                                        09600020
*                                                                       09602021
* TEST IF TCB IS READY                                                  09610020
*                                                                       09612021
         SPACE 2                                                        09620020
         LH    TWKREG1,TCBFLGS+3       TCB DISPATCHABILITY FLAGS        09640020
         LTR   TWKREG1,TWKREG1         IS TCB READY                     09650020
         BZ    TCLRLGWT                YES                              09660020
TESTTCB  C     TCBREG,TJBXLAST         USER'S LAST TCB?                 09670020
         BE    TGOTSIP                 YES,STILL IN LONG WAIT           09680020
         L     TCBREG,TCBTCB           ADDR NEXT TCB                    09690020
         B     TCURRB                  TEST NEXT RB                     09700020
         SPACE 3                                                        09710020
*                                                                       09712021
* USER IS STILL IN LONG WAIT. NOTIFY TSIP SO USER CAN BE SWAPPED- OUT   09720020
*                                                                       09722021
         SPACE 2                                                        09730020
TGOTSIP  TSEVENT RUSRTRMW,TJID=(5)     TELL TSIP USER IN NON I/O WAIT   09740020
         SPACE 2                                                        09742021
TCLRLGWT NI    TJBRSTOR,TNTLGWT        CLEAR LONGWAIT FLAG IN TJBX      09750020
TCONRSTR EQU   *                       *                                09760020
         TITLE  'TERMINAL LINE DROP TEST'                               09770020
         SPACE 2                                                        09780021
TLINDROP TM    TJBSTAT,TJBSILF         HAS LINE TO TERMINAL DROPPED?    09790020
         BNO   TLINEXIT                NO                               09800020
         NI    TJBSTAT,TALLON-TJBSILF  TURN OFF LOGOFF BIT              09810020
         L     TJBXREG,TJBEXTNT        GET TJB EXTENT ADDR              09850020
         L    ZEROREG,LGOFFCOD        POST CODE FOR LOGOFF              09860020
         L     PARMREG,TJBXAECB        ECB ADDR FOR LOGON               09870020
         POST  (1),(0)                 POST LOGON                       09880020
         SPACE 2                                                        09882021
TLINEXIT EQU   *                       *                                09890020
         TITLE 'RESTORE COMPLETE'                                       09900020
         SPACE 3                                                        09902021
*                                                                       09904021
*   INTERFACE TO TSIP-  RESTORE COMPLETE                                09910020
*                                                                       09912021
         SPACE 2                                                        09920020
RESCMP   TSEVENT  RSTORCMP,TJID=(5)     INDICATE USER RESTORED          09940020
         SPACE 2                                                        09950020
         XC    RCBRSFLG(BYTE),RCBRSFLG  CLEAR RECOVERY INDICATOR        09960020
         BR    RTNREG                   RETURN TO R01                   09970020
         EJECT                                                          09980020
          SPACE 3                                                       09982021
*                                                                       09984021
*  CONSTANTS FOR TQE RESTORE                                            09990020
*                                                                       09992021
         SPACE 2                                                        10000020
TSZSTAB  DC    X'000E'                 RB SIZE                          10010020
         DC    X'400E'                 IQE AND DYNAMIC FLAGS SET IN IRB 10020020
         SPACE 2                                                        10022021
         DS    0D                                                       10030020
NEWPSW   DC    X'00040000'             FIRST HALF PSW                   10040020
         DC    A(TABACK)               ADDR IN R03 AFTER TA REFRESH     10050020
         SPACE 2                                                        10052021
QELIDMSK DC    X'00007FFF'             MASK TO TURN OFF HI BIT IN QEL   10060020
         DS    0F                                                       10110020
POSTMASK DC    X'00000001'             MASK TO TURN ON HI ORDER BIT     10130020
LGOFFCOD DC    X'00006220'             POST CODE FOR LOGOFF             10140020
SP245    DC    X'F5000000'             SUBPOOL ID FOR IPPB'S            10150020
ZEROMASK DC    X'00000000'             MASK OF ZEROS FOR CLC'S          10160020
         SPACE 3                                                        10210021
         END                                                            10520020
