         TITLE ' RCT  ATTENTION HANDLER '                               00200020
*********************************************************************** 00400020
*                                                                     * 00600020
*  NAME  -  REGION CONTROL TASK ATTENTION HANDLER (IKJEAR04)          * 00800020
*  STATUS - 0                                                         * 01000020
*  FUNCTION  -  THIS MODULE SCHEDULES AN IRB, CONTAINED IN THE        * 01200020
*               TERMINAL ATTENTION ELEMENT (TAXE), UNDER WHICH        * 01400020
*               THE USER'S ATTENTION EXIT ROUTINE WILL RUN.           * 01600020
*                                                                     * 01800020
*  ENTRY POINT  -  IKJEAR04                                           * 02000020
*                                                                     * 02200020
*  INPUT  -  REGISTER 11  -  ADDRESS OF THE RCB                       * 02400020
*            REGISTER 13  -  SAVE AREA ADDRESS                        * 02600020
*            REGISTER 14  -  RETURN ADDRESS                           * 02800020
*            REGISTER 15  -  ENTRY POINT ADDRESS                      * 03000020
*                                                                     * 03200020
*  OUTPUT  -  REGISTERS SAME AS UPON ENTRY                            * 03400020
*                                                                     * 03600020
*  EXTERNAL REFERENCES  -  (1)  STAGE 2 EXIT EFFECTOR                 * 03800020
*                               A.  TO SCHEDULE THE IRB FOR THE USER  * 04000020
*                                   ATTENTION EXIT ROUTINE            * 04200020
*                               B.  BALR 14,10                        * 04400020
*                               C.  REGISTER 1 - COMPLEMENTED ADDRESS * 04600020
*                                                 OF THE IQE          * 04800020
*                                   REGISTER 10 - ENTRY POINT ADDRESS * 05000020
*                                   REGISTER 14 - RETURN ADDRESS      * 05200020
*                                                                     * 05400020
*                          (2)  STATUS                                * 05600020
*                               A.  TO SET NONDISPATCHABLE ALL SUBTASK* 05800020
*                                   OF THE TASK REQUESTING THE ATTEN- * 06000020
*                                   TION EXIT                         * 06200020
*                               B.  ISSUE STATUS MACRO INSTRUCTION    * 06400020
*                                   SPECIFING STOP AND THE TCB ADDRESS* 06600020
*                                                                     * 06800020
*  EXITS,NORMAL - BRANCH ON RETURN ADDRESS TO CALLER                  * 07000020
*                                                                     * 07200020
*  EXITS,ERROR - NONE                                                 * 07400020
*                                                                     * 07600020
*  TABLES/WORK AREAS - NONE                                           * 07800020
*                                                                     * 08000020
*  ATTRIBUTES  -  REFRESHLE, REENTRANT, READ ONLY, SUPERVISOR STATE,  * 08200020
*                 DISABLED, RESIDENT WHILE TS IS OPERATING.           * 08400020
*                                                                     * 08600020
*  NOTES  -  BEFORE THE IRB IS SCHEDULED THE FOLLOWING FUNCTIONS      * 08800020
*            MUST BE PERFORMED:                                       * 09000020
*               (1)  SET A FLAG IN THE TCB (TCBTIOTG) OF ANY USER     * 09200020
*                    TASK WITH AN OUTSTANDING TGET/TPUT SVRB.  THIS   * 09400020
*                    FLAG COMMUNICATES THE OCCURRENCE OF AN ATTENTION * 09600020
*                    TO THE TGET/TPUT SVC SERVICE ROUTINE WHEN THE    * 09800020
*                    SVRB GAINS CONTROL.                              * 10000020
*               (2)  ANY EXISTING IWAIT/OWAIT CONDITIONS FOR THIS     * 10200020
*                    USER, INDICATED BY FLAGS IN THE TJB, MUST BE     * 10400020
*                    SATISFIED.  THE TASK(S) IN THE WAIT CONDITION    * 10600020
*                    ARE SET DISPATCHABLE, IN ORDER TO ALLOW THE      * 10800020
*                    SVC ROUTINE FOR TPUT/TGET TO TAKE THE REQUIRED   * 11000020
*                    ACTION CAUSED BY AN ATTENTION INTERRUPT.         * 11200020
*               (3)  IF ANOTHER ATTENTION EXIT IS IN THE PROCESS OF   * 11400020
*                    BEING SCHEDULED, IT IS MADE TO RETURN AND IS     * 11600020
*                    TAKEN OFF THE AEQ.                               * 11800020
*               (4)  THE ATTENTION LEVEL REQUESTED IS DETERMINED,     * 12000020
*                    WITH ALL LOWER LEVELS MARKED UNAVAILABLE.        * 12200020
*               (5)  ALL TASKS BELOW THE ONE REQUESTING THE ATTENTION * 12400020
*                    EXIT ARE SET NONDISPATCHABLE VIA THE STATUS      * 12600020
*                    MACRO.                                           * 12800020
*               (6)  THE STAX COUNT IN THE TJB INDICATING THE NUMBER  * 13000020
*                    OF AVAILABLE ATTENTION LEVELS IS DECREMENTED.    * 13200020
*                    THE ATTENTION COUNT IN THE TJB IS SET TO ZERO    * 13400020
*                                                                     * 13600020
*                THEN STAGE 2 EXIT EFFECTOR IS PASSED THE COMPLEMENTED* 13800020
*                ADDRESS OF THE IQE AND THE EXIT ROUTINE IS SCHEDULED.* 14000020
*                                                                     * 14200020
*********************************************************************** 14400020
         EJECT                                                          14600020
CVTSECT  DSECT                                                          14800020
         CVT                                                            15000020
         EJECT                                                          15200020
         IKJTCB                TCB                                      15400020
         EJECT                                                          15600020
         IKJRB                 RB                                       15800020
         EJECT                                                          16000020
         IKJTAXE               TAXE                                     16200020
         EJECT                                                          16400020
         IKJTJB                TJB                                      16600020
         EJECT                                                          16800020
         IKJTJBX               TJBX                                     17000020
         EJECT                                                          17200020
         IKJTSCVT              TSCVT                                    17400020
         EJECT                                                          17600020
IQE      DSECT                 IQE                                      17800020
IQELNK   DS    A                  ADDR OF NEXT IQE                      18000020
IQEIRB   DS    A                  ADDR IRB ON WHICH IQE SCHEDULED       18200020
IQETAXE  DS    A                  ADDR OF TAXE INPUT TO ATTN PTOLOG     18400020
IQETCB   DS    A                  ADDR TCB                              18600020
         SPACE   5                                                      18800020
         IKJRCB                    RCB                                  19000020
         EJECT                                                          19200020
*  REGISTER EQUATES                                                     19600020
*                                                                       19800020
         SPACE                                                          20000020
X0       EQU   0                  REGISTER ZERO                         20010020
XRB      EQU   1                  ADDRESS OF RB                         20020020
X1       EQU   1                  REGISTER 1                            20030020
XSTAX    EQU   2                  STAX COUNT FOR TJB                    20040020
XCVT     EQU   3                  ADDRESS OF CVT                        20050020
XTAXE    EQU   4                  ADDRESS OF TAXE                       20060020
XAIQE    EQU   4                  ADDRESS OF IQE IN TAXE                20070020
XRET     EQU   4                  RETURN REGISTER                       20080020
XTCB     EQU   5                  ADDRESS OF TCB                        20090020
XIRB     EQU   5                  ADDRESS OF IRB                        20100020
XAEQ     EQU   5                  ADDRESS OF ASYNCHRONOUS EXIT QUEUE    20110020
XTJB     EQU   6                  ADDRESS OF TJB                        20120020
XTJBX    EQU   7                  ADDRESS OF TJBX                       20130020
XTJID    EQU   8                  TJID                                  20150020
XPREV    EQU   8                  ADDRESS OF PREVIOUS TAXE              20160020
XWK1     EQU   8                  WORK REGISTER TREE SCAN               20170020
XWK      EQU   9                  WORK REGISTER                         20171020
XWK2     EQU   9                  WORK REGISTER TREE SCAN               20180020
XCURR    EQU   9                  ADDRESS OF CURRENT TAXE               20182020
XODS     EQU   9                  ADDRESS OF DISPATCHER FOR OS          20182420
XTSCVT   EQU   9                  ADDRESS OF TSCVT                      20190020
XATTN    EQU   10                 ATTN COUNT IN TJB                     20191020
XWK3     EQU   10                 WORK REGISTER FOR TREE SCAN           20192020
XRCB     EQU   11                 ADDRESS OF RCB                        20193020
XBASE    EQU   12                 BASE REGISTER                         20194020
X12      EQU   12                 REG 12                                20194420
XSAVEREG EQU   13                 ADDRESS OF SAVE AREA                  20195020
XRETURN  EQU   14                 RETURN ADDRESS                        20196020
X14      EQU   14                 REG 14                                20196420
XENTRY   EQU   15                 ENTRY POINT ADDRESS                   20197020
X15      EQU   15                 REGISTER 15                           20200020
         SPACE   2                                                      25800020
*                                                                       26000020
*  DISPLACEMANT EQUATES                                                 26200020
*                                                                       26400020
HWORD    EQU   2                  DISPLACEMENT FOR A BYTE               26450020
IQELNKE  EQU   0                  DISPLACEMENT FOR LINK FLD IN IQE      26810020
ONE      EQU   1                  DISPLACEMENT OF ONE BYTE              26860020
AEQB     EQU   2                  POINTER TO RQE QUEUE                  26910020
AEQJ     EQU   6                  POINTER TO LAST IQE ON AEQ            27000020
AEQK     EQU   10                 POINTER TO FIRST IQE ON AEQ           27200020
WORD     EQU   4                  WORD = 4 BYTES                        27600020
SVCNUM   EQU   RBOPSW+3           DISPLAC IN OLD RBPSW FOR SVC NUMBER   27800020
THREE    EQU   3                  DISPLACEMTENT OF THREE                28000020
CLEAR    EQU   0                  USED FOR CLEARING HI ORDER BYTE       28010020
TWELVE   EQU   12                 DISPLACEMENT OF TWELVE                28060020
         EJECT                                                          28400020
*                                                                       28600020
*  MISC EQUATES                                                         28800020
*                                                                       29000020
TGETPUT  EQU   X'5D'              SVC NUMBER FOR TGET/TPUT              29200020
ZERO     EQU   X'00'              CONSTANT USED TO ZERO TJBATTN FLD     29600020
WAITPOST EQU   X'F3'              MASK FOR 'POSTING' TERMINAL I/O WAIT  29800020
WAITOFF  EQU   X'E7'              MASK FOR RESETTING TJB WAIT FLGS      30020020
REQOFF   EQU   255-TAXEFREQ      MASK FOR RESETTING REQUEST FLG IN TAXE 30030020
PNDSPOFF EQU   255-TCBPNDSP      MASK FOR RESETTING 2ND NONDISPATCH BIT 30400020
ATTNOFF  EQU   255-RCBFAT         MASK FOR RESETTING ATTN BIT IN RCB    30420020
COND0    EQU   8                  CONDITION FOR ZERO AFTER TM           30800020
CONDNZ   EQU   7                  CONDITION FOR NONZERO AFTER NC        31000020
KEYZERO  EQU   X'0E'                                                    31200020
         EJECT                                                          31400020
IKJEAR04 CSECT                                                          31600020
         DS    0H                  ALIGN TO HALF WORD BOUNDARY          31800020
         USING *,XBASE             ESTABLISH ADDRESSABILITY             32000020
         STM   X14,X12,TWELVE(XSAVEREG) SAVE CALLER REGISTERS           32050020
         LR    XBASE,XENTRY        INITIALIZE BASE REG                  32200020
         USING RCB,XRCB            ADDRESSABILITY FOR RCB               32800020
         NI    RCBFLG,ATTNOFF      TURN ATTENTION FLAG IN RCB           33000020
         SPACE 5                                                        33010020
*                                                                       33200020
*  COMPUTE ADDRESS OF TJB                                               33400020
*                                                                       33600020
         LH    XTJID,RCBTJID       TJID FOR USER                        33800020
         L     XCVT,CVTPTR         ADDRESS OF CVT                       34000020
         USING CVTSECT,XCVT        ESTABLISH FOR CVT                    34200020
         L     XTSCVT,CVTTSCVT     ADDRESS OF TS CVT                    34400020
         LA    XTSCVT,CLEAR(XTSCVT) CLEAR HIGH ORDER BYTE               34600020
         USING TSCVT,XTSCVT       ESTABLISH ADDRESSABILITY FOR TSCVT    34800020
         LR    XTJB,XTJID         COMPUTE ADDR OF TJB FOR THIS TJID     35000020
         MH    XTJB,TSCVTSZU      BY ADDING THE PRODUCT OF TJID AND     35200020
         A     XTJB,TSCVTTJB      TJB SIZE TO ADDR OF TJB INDEX TABLE   35400020
         USING TJB,XTJB           ESTABLISH ADDRESSABILITY FOR TJB      35600020
         L     XTJBX,TJBEXTNT     ADDR TJB EXTENSION                    35800020
         USING TJBX,XTJBX         ESTABLISH ADDRESSABILITY FOR TJBX     36000020
         L     XTCB,TJBXFST       ADDR FIRST TCB FOR USER               36200020
         SR    XATTN,XATTN        ZERO ATTN COUNT REG                   36400020
         IC    XATTN,TJBATTN      ATTN COUNT FROM TJB                   36600020
         SR    XSTAX,XSTAX        ZERO STAX COUNT REG                   36800020
         IC    XSTAX,TJBSTAX      STAX COUNT FROM TJB                   37000020
         USING TCB,XTCB           ESTABLISH ADDRESSABILITY FOR TCB      37200020
         EJECT                                                          37210020
*                                                                       37400020
*  SEARCH FOR ANY OUTSTANDING TPUT/TGET REQUESTS FOR THIS USER          37600020
*                                                                       37800020
         C     XTCB,TJBXLAST      DOES FIRST EQUAL LAST                 37850020
         BE    TCBCK1             YES SET UP RETURN REG TO ONLY         37900020
*                                 PROCESS ONE TCB                       37950020
         BAL   XRET,TCBCK         BRANCH TO CHECK FIRST TCB             38000020
NXTCB    EQU   *                                                        38200020
         L     XTCB,TCBTCB        ADDR NEXT TCB ON QUEUE                38400020
         C     XTCB,TJBXLAST      LAST TCB FOR USER                     38600020
         BNE   TCBCK              NO, SCAN RB QUEUE FOR THIS TCB        38800020
TCBCK1   LA    XRET,TJBWTOFF      RETURN ADDR SET UP - NOW CHECK LAST   39000020
TCBCK    EQU   *                                                        39200020
         TM    TCBTSFLG,TCBATT     ANY SVRBS ON THIS TCB RB QUEUE       39400020
         BCR   COND0,XRET          NO,GET NEXT TCB                      39600020
         L     XRB,TCBRBP          ADDR TOP RB ON QUEUE                 39800020
         LTR   XRB,XRB             IS THERE AN RB                       39850020
         BCR   COND0,XRET          NO GET NEXT TCB                      39900020
         USING RBSECT,XRB          ADDRESSABILITY FOR RB                40000020
SVRBCK   EQU   *                                                        40200020
         TM    RBSTAB1,RBFTSVRB    IS RB AN SVRB                        40400020
         BZ    NXRB                NO, GET NEXT RB ADDR                 40600020
         TM    RBSTAB2,RBTCBNXT    DOES SVRB POINT TO A TCB             40650020
         BO    ZERO(XRET)          YES BRANCH TO GET NEXT TCB           40700020
         L     XRB,RBLINK          ADDRESS RB AFTER SVRB                40800020
         LA    XRB,CLEAR(XRB)      CLEAR HIGH ORDER BYTE                41000020
         CLI   SVCNUM,TGETPUT      IS SVRB FOR TGET/TPUT                41200020
         BNE   SVRBCK              NO, CHECK CURRENT RB                 41400020
         OI    TCBTSFLG,TCBTIOTG   SET FLAG INDICATE ATTN TO TGET/TPUT  41800020
         NI    TCBNDSP2,WAITPOST   RESET NONDISPATCH FLAG FOR I/OWAIT   42000020
         NC    TCBSCNDY(THREE),TCBSCNDY  ANY SECONDARY DISPATCH FLGS ON 42200020
         BCR   CONDNZ,XRET         YES, SKIP RESET OF FLAG              42400020
         NI    TCBFLGS5,PNDSPOFF   TURN OFF FLAG INDICATING             42600020
*                                  SECONDARY DISPATCH BITS OFF          42800020
         BR    XRET                BRANCH TO GET NEXT TCB               43000020
NXRB     EQU   *                                                        43200020
         L     XRB,RBLINK          ADDR NEXT TCB ON QUEUE               43400020
         LA    XRB,CLEAR(XRB)      CLEAR HIGH ORDER BYTE                43600020
         CR    XTCB,XRB            LAST RB ON QUEUE                     43800020
         BNE   SVRBCK              NO, CHECK FOR SVRB FOR TGET/TPUT     44000020
         BR    XRET                RETURN TO CALLER                     44200020
TJBWTOFF EQU   *                                                        44400020
        EJECT                                                           44610020
*                                                                       44800020
*  IS ATTENTION BEING SCHEDULED                                         45000020
*                                                                       45200020
         L     XAIQE,TJBXAIQE      ADDR IQE FROM TJBX                   45400020
         LTR   XAIQE,XAIQE         ATTENTION PROLOG ACTIVE              45600020
         BZ    FNDTAXE             NO, BRANCH TO FIND TAXE REQUESTED    45800020
         USING IQE,XAIQE           ADDRESSABILITY FOR IQE               46000020
         L     XIRB,IQEIRB         YES, ADDR OF ACTIVE IRB              46200020
         USING RBSECT,XIRB         ADDRESSABILITY FOR IRB               46400020
         TM    RBSTAB2,RBFACTV     IS IRB ON RB QUEUE (ACTIVE)          46600020
         BNZ   ACTVRB              YES, BRANCH TO MAKE RETURN           46800020
         SPACE 5                                                        47010020
*                                                                       47200020
* DEQUEUE IQE                                                           47400020
*                                                                       47600020
         L     XAEQ,CVTIERLC       ADDRESS ERROR LOGICAL CHANNEL QUEUE  47800020
         LA    XAEQ,AEQJ(XAEQ)     ADDRESS OF AEQJ                      48000020
         LR    XCURR,XAEQ          SAVE ADR OF QUEUE                    48050020
AEQLOOP  EQU   *                                                        48200020
         LR    XPREV,XCURR         SAVE ADDR OF PREVIOUS                48400020
         L     XCURR,IQELNKE(XPREV) GET NEXT IQE                        48600020
         LTR   XCURR,XCURR         LAST IQE                             48650020
         BM    QMTY                YES, CHECK IF QUEUE IS EMPTY         48700020
         CR    XCURR,XAIQE         IS THIS IQE TO BE DEQUEUED           51000020
         BNE   AEQLOOP             NO, LOOK FOR NEXT IQE                51200020
         C     XCURR,WORD(XAEQ)    IS LAST IQE BEING DEQUEUED           51210020
         BNE   AEQ2                NO BRANCH                            51220020
         CLC   ZERO(WORD,XAEQ),WORD(XAEQ) YES- IS FIRST EQ TO LAST      51240020
         BNE   AEQ1                NO BRANCH                            51242020
         MVC   WORD(WORD,XAEQ),IQELNKE(XCURR)  UPDATE LAST PTR WITH     51244020
*                                  LINK OF IQE BEING DEQUEUED           51246020
         B     AEQ2                CONTINUE DEQUEUING                   51248020
AEQ1     ST    XPREV,WORD(XAEQ)    UPDATE LAST PTR WITH PREVIOUS IQE    51248420
AEQ2     MVC   IQELNKE(WORD,XPREV),IQELNKE(XCURR) YES, DEQUEUE IQE      51250020
         XC    TJBXAIQE,TJBXAIQE   ZERO ATTN IQE FLD IN TJBX            52400020
         B     FNDTAXE             BRANCH TO FIND REQUESTED TAXE        52600020
ACTVRB   EQU   *                                                        52800020
          EJECT                                                         52810020
*                                                                       53000020
*  FORCE IRB TO EXIT                                                    53200020
*                                                                       53400020
         LA    XWK,CVTEXIT         ADDR OF SVC 3                        53600020
         ST    XWK,RBOPSW+WORD     STORE SVC 3 ADDR IN IRBS PSW         53800020
QMTY     EQU   *                                                        53850020
FNDTAXE  EQU   *                                                        54000020
         DROP  XIRB                DROP XIRB REG                        54010020
*                                                                       54200020
*  DETERMINE FIRST TAXE OR ATTENTION LEVEL AVAILABLE                    54400020
*                                                                       54600020
         L     XTAXE,TJBXTAXE      ADDR FIRST TAXE ON QUEUE             54800020
         USING TAXE,XTAXE          ADDRESSABILITY FOR TAXE              55000020
TESTAXE  TM    TAXESTAT,TAXEFREQ   TAXE AVAILABLE FOR SCHEDULING        55200020
         BZ    REQLEVEL            YES,BRANCH TO DETERMINE ATTN         55400020
*                                  LEVEL REQUESTED                      55600020
         L     XTAXE,TAXELNK       ADDR NEXT TAXE                       55800020
         B     TESTAXE             BRANCH TO DETERMINE ATTN             55811020
*                                  LEVEL REQUESTED                      55820020
         EJECT                                                          55830020
*                                                                       57600020
*  DETERMINE REQUESTED ATTENTION LEVEL TO SCHEDULE                      57800020
*                                                                       58000020
REQLEVEL EQU   *                                                        58200020
         BCTR  XATTN,X0            DECREMENT ATTN COUNT BY ONE          58400020
         LTR   XATTN,XATTN         ATTN COUNT ZERO                      58600020
         BNZ   CKNXLEVL            NO, CHECK IF NEXT LEVEL              58800020
         BCTR  XSTAX,X0            DECREMENT STAX COUNT BY 1            59000020
         B     SCHED               SCHEDULE CURRENT AVAILABLE TAXE      59200020
CKNXLEVL EQU   *                                                        59400020
         OI    TAXESTAT,TAXEFREQ   MAKE TAXE UNAVAILABLE                59450020
         BCTR  XSTAX,X0            DECREMENT STAX COUNT                 59800020
         LTR   XSTAX,XSTAX         STAX COUNT ZERO                      60000020
         BZ    SCHED               YES, BRANCH TO SCHED                 60050020
         L     XTAXE,TAXELNK       ADDRESS OF NEXT TAXE                 60100020
         B     TESTAXE             TEST THIS NEXT TAXE                  60150020
SCHED    EQU   *                                                        60400020
         SPACE 5                                                        60410020
*                                                                       60600020
*  SCHEDULE CURRENT AVAILABLE TAXE                                      60800020
*                                                                       61000020
         MVI   TJBATTN,ZERO       ZERO ATTENTION COUNT IN TJB           61200020
         STC   XSTAX,TJBSTAX      UPDATE STAX COUNT IN TJB              61400020
         USING RBSECT,XTAXE       ADDRESSABILITY FOR TAXE(IRB)          61600020
         MVC   RBEP,PROLOGUE      MOVE ADDRESS ATTENTION PROLOGUE       61800020
         NI    RBOPSW+1,KEYZERO   PSW FOR ATTN PROLOGUE IN KEY ZERO     62000020
*                                 INTO IRB TO BE SCHEDULED              62200020
         DROP  XTAXE              DROP ADDRESSABILITY FOR TAXE(IRB)     62400020
         USING TAXE,XTAXE         ADDRESSABILITY FOR TAXE               62600020
         OI    TAXESTAT,TAXEFREQ  TURN ON REQUESTED FLAG IN TAXE        62800020
         L     XTCB,TAXETCB       ADDR TCB THIS TAXE                    63000020
        EJECT                                                           63010020
*                                                                       63200020
*  STOP ALL SUBTASKS OF TASK REQUESTING ATTENTION EXIT                  63400020
*                                                                       63600020
         LR    XWK1,XTCB          INITIALIZE REGISTERS FOR SCAN         63800020
         LR    XWK2,XTCB          INITALIZE WORK REGISTER 2             64000020
         USING TCB,XWK2           ADDRESSABILITY FOR TCB                64200020
SCAN     EQU   *                                                        64400020
         L     XWK3,TCBLTC        ADDRESS OF DESCENDENT                 64600020
         LTR   XWK3,XWK3          ANY DESCENDENTS FOUND                 64800020
         BNZ   STOPIT             YES, SO STOP IT                       65000020
OUTCK    EQU   *                                                        65200020
         CR    XWK1,XWK2          IS THIS THE REQUESTING TASK           65400020
         BE    SCHEDIQE           YES, STOP PROCESSING COMPLETE         65600020
         L     XWK3,TCBNTC        ADDRESS OF SISTER TASK                65800020
         LTR   XWK3,XWK3          ANY SISTER TASKS                      66000020
         BNZ   STOPIT             YES, STOP IT                          66200020
         L     XWK2,TCBOTC        GO BACK TO MOTHER                     66400020
         B     OUTCK              CHECK IF AT TOP                       66600020
         SPACE 5                                                        66610020
*                                                                       66800020
*  STATUS MACRO TO SET SUBTASKS NONDISPATCHABLE                         67000020
*                                                                       67200020
STOPIT   EQU   *                                                        67400020
         STATUS STOP,TCB=(XWK3)   STATUS MACRO TO STOP SUBTASK          67600020
         LR    XWK2,XWK3          UPDATE TCB BASE REG                   67800020
         B     SCAN               CONTINUE SUBSTASK SCAN                68000020
SCHEDIQE EQU   *                                                        68200020
         EJECT                                                          68210020
*                                                                       68400020
*  BRANCH TO STAGE 2 OF EXIT EFFECTOR TO SCHEDULE IRB                   68600020
*                                                                       68800020
         L     XENTRY,CVT0EF00     ADDR STAGE 2 EXIT EFFECTOR           69000020
         LA    X1,TIQELNK          ADDR IQE FROM TAXE                   69200020
         LCR   X1,X1               COMPLIMENT IQE ADDRESS               69400020
         BALR  XRETURN,XENTRY      BRANCH TO SCHEDULE IRB               69600020
*  REGISTER 10 IS DESTROYED BY STAGE 2 EXIT EFFECTOR                    69800020
         LA    XWK,TIQELNK         IQE ADDR INTO TJBX INDICATES         70000020
         ST    XWK,TJBXAIQE        ATTN EXIT BEING SCHEDULED            70200020
         LM    X14,X12,TWELVE(XSAVEREG) RESTORE CALLER REGISTERS        70400020
         BR    XRETURN             RETURN TO CALLER                     70800020
         EJECT                                                          70810020
*                                                                       71000020
*  CONSTANTS                                                            71200020
*                                                                       71400020
DISABLE  DC    X'00'         MASK TO DISABLE FOR INTERRUPTS             71600020
PROLOGUE DC    V(IKJEAR05)   ADDRESS OF ATTENTION PROLOGUE (IKJEAR05)   72000020
         END                                                            72400020
