          TITLE  'RCT ATTENTION PROLOGUE'                               00310020
*********************************************************************** 00320020
*                                                                     * 00600020
*  NAME  -  REGION CONTROL TASK ATTENTION PROLOGUE (IKJEAR05)         * 00900020
*                                                                     * 01200020
*  STATUS - 0                                                         * 01500020
*C637500                                                      AJ A60017 01550021
*                                                                     * 01800020
*  FUNCTION  -  THIS MODULE ESTABLISHES THE NECESSARY INTERFACES FOR  * 02100020
*               THE USER ATTENTION EXIT ROUTINE AND THEN PASSES       * 02400020
*               CONTROL TO THE EXIT ROUTINE WHOSE ADDRESS IS SPECIFIED* 02700020
*               IN THE STAX MACRO.                                    * 03000020
*                                                                     * 03300020
*  ENTRY POINT  -  IKJEAR05                                           * 03600020
*                                                                     * 03900020
*  INPUT  -  REGISTER 0 - ADDRESS OF IQE                              * 04200020
*            REGISTER 1 - ADDRESS OF TAXE (IRB PLUS AN EXTENSION)     * 04500020
*            REGISTER 14 - RETURN ADDRESS (ADDRESS OF SVC 3)          * 04800020
*            REGISTER 15 - ENTRY POINT                                * 05100020
*                                                                     * 05400020
*  OUTPUT  -  REGISTER 1 - ADDRESS OF PARAMETER LIST                  * 05700020
*             REGISTER 13 - SAVE AREA ADDRESS                         * 06000020
*             REGISTER 14 - RETURN ADDRESS (SVC 3)                    * 06300020
*             REGISTER 15 - ENTRY POINT ADDRESS                       * 06600020
*             PARAMETER LIST:                                         * 06900020
*              DISPLACEMENT          DESCRIPTION                      * 07200020
*                   0                 ADDRESS OF TAIE (TERMINAL       * 07500020
*                                     ATTENTION INTERRUPT ELEMENT)    * 07800020
*                   4                 ADDRESS OF INPUT BUFFER         * 08100020
*                   8                 ADDRESS OF USER PARAMETER       * 08400020
*                                     (SPECIFIED IN THE STAX MACRO    * 08700020
*                                     INSTRUCTION)                    * 09000020
*                                                                     * 09300020
*             TAIE:                                                   * 09600020
*                  ********************************                   * 09900020
*                  * MESSAGE      *RTCODE * RES.  *                   * 10200020
*                  * LENGTH       * TGET  *       *                   * 10500020
*                  ********************************                   * 10800020
*                  *   RIGHT HALF PSW OF THE      *                   * 11100020
*                  *      INTERRUPTED RB          *                   * 11400020
*                  ********************************                   * 11700020
*                  *                              *                   * 12000020
*                  *                              *                   * 12300020
*                  *   INTERRUPTED REGISTERS      *                   * 12600020
*                  *                              *                   * 12900020
*                  *        0-15                  *                   * 13200020
*                  *                              *                   * 13500020
*                  *                              *                   * 13800020
*                  ********************************                   * 14100020
         EJECT                                                          14400020
*                                                                     * 14700020
*  EXTERNAL REFERENCES  -  (1) TPUT                                   * 15000020
*                              A.  REQUESTED IN STAX PARAMETER LIST   * 15300020
*                              B.  USE BUFFER ADDRESS AND SIZE IN     * 15600020
*                                  STAX PARAMETER LIST TO ISSUE MACRO * 15900020
*                          (2) TGET                                   * 16200020
*                              A.  REQUESTED IN STAX PARAMETER LIST   * 16500020
*                              B.  USE BUFFER ADDRESS AND SIZE IN     * 16800020
*                                  STAX PARAMETER LIST TO ISSUE MACRO * 17100020
*                                                                     * 17400020
*  EXITS,NORMAL - THE USER ATTENTION ROUTINE WITH PROBLEM PROGRAM     * 17700020
*                 KEY IS PASSED CONTROL VIA LPSW                      * 18000020
*                                                                     * 18300020
*  EXITS,ERROR - NONE                                                 * 18600020
*                                                                     * 18900020
*  TABLES/WORK AREAS - NONE                                           * 19200020
*                                                                     * 19500020
*  ATTRIBUTES  -  REFRESHABLE, REENTRANT, READ ONLY, SUPERVISOR       * 19800020
*                 STATE, RESIDENT WHILE TS IS OPERATING.              * 20100020
*                 RUNS BOTH ENABLED AND DISABLED                      * 20400020
*                                                                     * 20700020
*  NOTES  -  BEFORE PASSING CONTROL TO THE SPECIFIED TERMINAL         * 21000020
*            ATTENTION EXIT ROUTINE, THE FOLLOWING FUNCTIONS          * 21300020
*            ARE PERFORMED:                                           * 21600020
*                (1)  WHEN OUTPUT BUFFER ADDRESS IS SPECIFIED IN THE  * 21900020
*                     STAX PARAMETER LIST, A TPUT IS ISSUED USING     * 22200020
*                     BUFFER SIZE AND ADDRESS IN THE STAX PARAMETER   * 22500020
*                     LIST.  SIMILARLY A TGET MACRO IS ISSUED IF SO   * 22800020
*                     REQUESTED AS INDICATED IN THE STAX PARAMETER    * 23100020
*                     LIST.                                           * 23400020
*                (2)  AN AREA FOR THE TERMAINAL ATTENTION INTERRUPT   * 23700020
*                     ELEMENT IS OBTAINED AND INITIALIZED.            * 24000020
*                (4)  THE IQE ADDRESS IN THE TJBX IS ZEROED TO        * 24300020
*                     INDICATE THAT CONTROL HAS BEEN PASSED TO THE    * 24600020
*                     EXIT ROUTINE.                                   * 24900020
*                                                                     * 25200020
*********************************************************************** 25500020
*                                                                       26100020
*  STAX PARAMETER LIST                                                  26400020
*                                                                       26700020
STAXPARM DSECT                                                          27000020
STXEXIT  DS    F                  ADDR USER EXIT RTN                    27300020
STXISIZ  DS    H                  SIZE OF INPUT BUFFER                  27600020
STXOSIZ  DS    H                  SIZE OF OUTPUT BUFFER                 27900020
STXOBUF  DS    F                  ADDR OF OUTPUT BUFFER                 28200020
STXIBUF  DS    F                  ADDR OF INPUT BUFFER                  28500020
STXOPTS  DS    0X                 OPTIONS FLAGS                         28800020
STXRPLNO EQU   X'40'              INDICATES CREATE NEW TAXE FOR TCB     29400020
STXUSER  DS    F                  ADDR USER PARAMETER FOR USER RTN      29700020
         EJECT                                                          30000020
CVTSECT  DSECT                                                          30300020
         CVT                                                            30600020
         EJECT                                                          30900020
         IKJTSCVT            TSCVT                                      31200020
         EJECT                                                          31500020
         IEZJSCB             JSCB                                       31800020
         EJECT                                                          32100020
         IKJTJB              TJB                                        32400020
         EJECT                                                          32700020
         IKJTAXE             TAXE                                       33000020
         EJECT                                                          33300020
         IKJTJBX             TJBX                                       33600020
         EJECT                                                          33900020
         IKJTCB              TCB                                        34200020
         EJECT                                                          34500020
         IKJRB               RB                                         34800020
         EJECT                                                          35100020
         IKJTAIE             TAIE                                       35400020
         EJECT                                                          35700020
*                                                                       35710020
*  DISPLACEMENT FOR STATUS FLAGS IN PSW                                 35720020
*                                                                       35730020
PMODE    EQU   TAXEXPSW+1    PROBLEM MODE                               35740020
PKEY     EQU   PMODE         PROBLEM KEY                                35750020
MCHCK    EQU   PMODE         MACHINE CHECK MASK                         35760020
         SPACE 5                                                        36900020
*                                                                       37200020
*  REGISTERS EQUATES                                                    37500020
*                                                                       37800020
X0       EQU   0             REGISTER 0                                 37810020
XBUFLNGT EQU   0             LENGHT OF BUFFER FOR TGER/TPUT             37820020
X1       EQU   1             REGISTER 1                                 37830020
XBUFADR  EQU   1             ADDRESS OF BUFFER FOR TGET/TPUT            37840020
XTCB     EQU   1             ADDRESS OF TCB FROM TAXE                   37850020
XIQE     EQU   2             ADDRESS OF IQE                             37860020
XTAXE    EQU   3             ADDRESS OF TAXE                            37870020
XCVT     EQU   4             ADDRESS OF CVT                             37880020
XTSCVT   EQU   4             ADDRESS OF TSCVT                           37890020
XJSCB    EQU   4             ADDRESS OF JSCB                            37900020
XLNGTH   EQU   5             LENGTH OF MESSAGE FROM TGET                37910020
XTJID    EQU   5             TJID                                       37920020
XTJBX    EQU   5             ADRESS OF TJBX                             37930020
XRB      EQU   6             ADDRESS OF RB                              37940020
XTAIE    EQU   7             ADDRESS OF TERMINAL ATTETION EXIT ELEMENT  37950020
XSTXPARM EQU   8             ADDRESS OF STAX PARAMETER LIST FROM TAXE   37960020
XCODESAV EQU   9             SAVE REG FOR RETURN CODE FROM TGET         37970020
XSAVE    EQU   10            SAVE REG FOR RB SCAN                       37980020
XBASE    EQU   12            BASE REGISTER                              37990020
XRTCODE  EQU   15            REG FOR RETURN CODE FROM TGET              38000020
XENTRY   EQU   15            ENTRY POINT                                38010020
         SPACE 5                                                        44700020
*                                                                       45000020
*  MISCELLANEOUS EQUATES                                                45300020
*                                                                       45600020
TAIELNGT EQU   72            LENGTH OF TAIE = 72 BYTES                  45900020
WORD     EQU   4             DISPLACEMENT OF 1 WORD = 4 BYTES           46200020
WORD16   EQU   64            DISPLACEMENT OF 16 WORDS = 64 BYTES        46500020
ZERO     EQU   0             DISPLACEMENT OF ZERO                       46800020
HW       EQU   2             DISPLACEMENT OF HALF WORD = 2 BYTES        46810020
BYTE     EQU   1             DISPLACEMENT OF 1 BYTE                     46820020
RBPRB    EQU   X'00'         MASK FOR RB TYPE = PRB                     47100020
MCKMASK  EQU   X'04'         MASK FOR MACHINE CHECK                     48000020
PROBMODE EQU   X'01'         MASK FOR PROBLEM MODE                      48600020
         EJECT                                                          49200020
         DS    0H            ALIGN TO HALF BOUNDARY                     49500020
IKJEAR05 CSECT                                                          49800020
         USING *,XBASE             ESTABLISH ADDRESSABILITY             50100020
         LR    XBASE,XENTRY        LOAD BASE REGISTER WITH ENTRY POINT  50400020
         LR    XTAXE,X1            ADDR OF TAXE SCHEDULED               50700020
         USING TAXE,XTAXE          ADDRESSABILITY FOR TAXE              51000020
         LR    XIQE,X0             ADDR OF IQE                          51300020
         L     XSTXPARM,TAXEPARM   ADDR OF STAX PARAMETER LIST          51600020
         LA    XSTXPARM,ZERO(XSTXPARM) ZERO HIGH ORDER BYTE             51900020
         USING STAXPARM,XSTXPARM   ADDRESSABILITY FOR STAX PARM LIST    52200020
         SPACE 5                                                        52210020
*                                                                       52500020
*  SEND MESSAGES TO TERMINAL IF REQUESTED                               52800020
*                                                                       53100020
         L     XBUFADR,STXOBUF     ADDR OF OUTPUT BUFFER                53400020
         LTR   XBUFADR,XBUFADR     ANY MESSAGE TO SENT TO TERMINAL      53700020
         BZ    NOMSG               NO, BYPASS MESSAGE PROCESSING        54000020
         LH    XBUFLNGT,STXOSIZ    LENGTH OUTPUT MESSAGE                54300020
         TPUT  (1),(0),,,HOLD      SEND MESSAGE TO TERMINAL             54600020
         L     XBUFADR,STXIBUF     ADDR OF INPUT BUFFER                 54900020
         LTR   XBUFADR,XBUFADR     TGET REQUESTED                       55200020
         BZ    NOMSG               NO, MSG PROCESSING COMPLETED         55500020
         LH    XBUFLNGT,STXISIZ    LENGTH INPUT BUFFER                  55800020
         TGET  (1),(0)             GET INPUT FROM TERMINAL              56100020
         LR    XCODESAV,XRTCODE    SAVE RETURN CODE TO PUT IN TAIE      56400020
         LR    XLNGTH,X1           LENGTH OF BUFFER FROM TGET           56700020
NOMSG    EQU   *                                                        56710020
          EJECT                                                         57000020
*                                                                       57300020
*  OBTAIN TERMINAL ATTENTION INTERRUPT ELLEMENT (TAIE)                  57600020
*                                                                       57900020
         SSM   DISABLE             DISABLE ACROSS GETMAIN        A45510 57950021
         GETMAIN R,LV=TAIELNGT,SP=250  GET CORE FOR TAIE                58200020
         ST    X1,TAXETAIE         ADDR OF TAIE CORE INTO TAXE          58500020
         SSM   ENABLE              ALLOW FOR INTERRUPTS          A45510 58550021
         XC    ZERO(TAIELNGT,X1),ZERO(X1) ZERO GOTTEN CORE              58800020
         LR    XTAIE,X1            ADDR TAIE                            59100020
         USING TAIE,XTAIE          ADDRESSABILITY FOR TAIE              59400020
         STC   XCODESAV,TAIETGET   RETURN FROM TGET INTO TAIE           59700020
         STH   XLNGTH,TAIEMSGL     LENGTH OF MESSAGE FROM TGET          60000020
         SR    XCODESAV,XCODESAV   ZERO REGISTER                        60300020
         SPACE 5                                                        60310020
*                                                                       60600020
*  FIND INTERUPTED RB                                                   60900020
*                                                                       61200020
         L     XTCB,TAXETCB        TCB ADDR FROM TAXE                   61500020
         USING TCB,XTCB            ADDRESSABILITY FOR TCB               61800020
         LR    XRB,XTAXE           ADDR TOP RB ON TCB QUEUE             62100020
         DROP  XTAXE               DROP ADDRESSABILITY FOR TAXE         62400020
         USING RBSECT,XRB          ADDRESSABILITY FOR RB                62700020
NXRB     EQU   *                                                        63000020
         LR    XSAVE,XRB           SAVE ADDRESS OF PREVIOUS IRB         63050020
         DROP  XRB                 DROP ADDRESSABILITY OF RB            63100020
         USING RBSECT,XSAVE        ADDRESSABILITY FOR PREVIOUS IRB      63150020
         L     XRB,RBLINK          ADDR NEXT RB ON QUEUE                63600020
         DROP  XSAVE               DROP ADDRESSABILITY ON PREVIOUS IRB  63650020
         USING RBSECT,XRB          ADDRESSABILITY CURRENT RB            63700020
         TM    RBSTAB,RBFTP        IS RB A PRB                AJ A60017 63750021
         BZ    PRBFND              YES INTERRUPTED RB FOUND             63800020
         TM    RBSTAB2,RBATTN      IS IT AN ATTENTION IRB               63850020
         BZ    NXRB                NO- BRANCH TO GET NEXT RB            63900020
PRBFND   EQU   *                                                        63950020
*                                                                       65400020
*  INITIALIZE TAIE                                                      65700020
*                                                                       66000020
         MVC   TAIEIAD(WORD),RBOPSW+4 MOVE RIGHT HALF INTERRUPTED       66300020
*                                  PSW TO TAIE                          66600020
         DROP  XRB                 DROP ADDRESSABILITY FOR RB           66900020
         USING RBSECT,XSAVE        ADDRESSABILITY FOR PREVIOUS IRB      67200020
         MVC   TAIERSAV(WORD16),RBGRSAVE    MOVE INTERRUPTED            67500020
*                                   REGS TO TAIE                        67800020
         DROP  XSAVE                DROP ADDRESSABILITY ON PREVIOUS IRB 68100020
         USING TAXE,XTAXE           ADDRESSABILITY FOR TAXE             68102020
         LA    XSAVE,ZERO(XSAVE)    CLEAR HI ORDER BYTE OF RB ADR       68102420
         ST    XSAVE,TIQEPARM       SAVE ADR OF RB WHERE REGS           68104020
*                                   MOVED FROM FOR EXIT                 68106020
         EJECT                                                          68110020
*                                                                       68700020
*  INITIALIZE POINTER TO PARAMETER FOR USER                             69000020
*                                                                       69300020
         XC    TAXEXPSW,TAXEXPSW   ZERO AREA TO BUILD PSW               69900020
         MVC   TAXEXPSW(BYTE),ENABLE SET SYSTEM MASK ENABLE IN PSW      70200020
         L     XENTRY,TAXEEXIT     ETNRY POINT ADDR EXIT RTN            70500020
         TM    TAXESTAT,TAXEFKEY   CALLER IN PROGRAM PROTECT KEY        70800020
         BZ    SKPKEY              NO, SKIP SETTING PROTECT KEY         71100020
         OC    PKEY(BYTE),TCBPKF   PUT USER PROTECT KEY IN PSW          71400020
SKPKEY   EQU   *                                                        71700020
         TM    TAXESTAT,TAXEFMOD   CALLER IN PROBLEM MODE               72000020
         BZ    SKPMOD              NO, SKIP SETTING MODE                72300020
         OI    PMODE,PROBMODE      YES, SET PROBLEM STATE               72600020
SKPMOD   EQU   *                                                        72900020
         OI    MCHCK,MCKMASK       SET MACHINE CHECK MASK               73200020
          SPACE 5                                                       73210020
*                                                                       73500020
*  OBTAIN ADDRESS OF TJB AND TJBX                                       73800020
*                                                                       74100020
         L     XJSCB,TCBJSCB      ADDRESS OF JSCB FROM TCB              74400020
         USING IEZJSCB,XJSCB      ADDRESSABILITY FOR JSCB               74700020
         LH    XTJID,JSCBTJID     TJID FOR THIS TCB FROM JSCB           75000020
         L     XCVT,CVTPTR        POINTER TO CVT                        75300020
         USING CVTSECT,XCVT       ADDRESSABILITY FOR CVT                75600020
         L     XTSCVT,CVTTSCVT    ADDR OF TS CVT                        75900020
         USING TSCVT,XTSCVT       ADDRESSABILITY FOR TSCVT              76200020
         MH    XTJID,TSCVTSZU     MULTIPLY TJID BY TJB SIZE             76500020
         A     XTJID,TSCVTTJB     ADD PRODUCT TO ADDR TJB TABLE         76800020
         USING TJB,XTJID          ADDRESSABILITY FOR TJB                77100020
         L     XTJBX,TJBEXTNT     ADDR OF TJBX                          77400020
         LA    X1,TAXETAIE        POINTER TO PARAMETER LIST             77700020
         USING TJBX,XTJBX         ADDRESSABILITY FOR TJBX               78000020
         XC    TJBXAIQE,TJBXAIQE  ZERO AIQE FLD IN TJBX TO INDICATE     78900020
*                                  USER RTN PASSED CONTROL              79200020
         LPSW  TAXEXPSW            LOAD PSW TO ATTN EXIT RTN            79500020
         EJECT                                                          79550020
**********                    CONSTANTS                    **********   79600020
         SPACE 2                                                        79650020
DISABLE  DC    X'00'               MASK FOR DISABLING INTERRUPTS        79750020
ENABLE   DC    X'FF'               MASK FOR ENABLING INTERRUPTS         79760020
         END                                                            79800020
