         TITLE 'IKJEAS00  TSO/SWAP PRE-INITIALIZATION'                  00200020
IKJEAS00 START                                                          00400020
*********************************************************************** 00600020
*STATUS  =0                                                      20021* 00800020
*FUNCTION-TSO/SWAP PRE INITIALIZATION                                 * 01000020
*        PRE-INITIALIZATION FOR SWAP DATA SETS. CALLED AT START TSO:  * 01200020
*        COMPUTE THE MAIN STORAGE REQUIREMENTS FOR SWAP DATA SETS,    * 01400020
*        DETERMINE IF SWAP DATA SETS ARE ALLOCATED TO VALID DEVICE    * 01600020
*        TYPES,                                                       * 01800020
*        DETERMINE THE VALIDITY OF SWAP DATA SET SERIAL/PARALLEL      * 02000020
*        STRUCTURE.                                                   * 02200020
*                                                                     * 02400020
*        ALL SWAP DATA SETS HAVE THE DD NAME OF 'SYSWAPLN' WHERE 'L'  * 02600020
*        IS THE LEVEL OF THE DATA SET(0, 1, 2, ETC.). THIS IS THE     * 02800020
*        SERIAL STRUCTURE. AND WHERE 'N' IS THE                       * 03000020
*        NUMBER OF DATA SETS AT THAT LEVEL. THERE MAY BE ONLY         * 03200020
*        TWO DATA SETS AT A PARALLEL LEVEL(N=0, N=1) AND THEY MUST    * 03400020
*        BE ALLOCATED ON THE SAME TYPE OF DASD DEVICE.                * 03600020
*                                                                     * 03800020
*        IKJEAS00:                                                    * 04000020
*        SEARCHES THE TIOT TO COUNT THE NUMBER OF SWAP DATA SETS.     * 04200020
*        IF NO SWAP DATA SETS ARE FOUND, ERROR CONDITION(RC=8).       * 04400020
*        COMPUTE THE SIZE OF AND OBTAINS A DD NAME TABLE(LOCAL WORK   * 04600020
*        AREA).                                                       * 04800020
*                                                                     * 05000020
*        SEARCHES THE TIOT A SECOND TIME. WHEN A SWAP DATA SET IS     * 05200020
*        FOUND, DETERMINE THE VALIDITY OF THE DEVICE THE DATA SET     * 05400020
*        IS ALLOCATED ON.  COMPUTE THE MAIN STORAGE REQUIREMENTS.     * 05600020
*        THE ADDR. OF THE UCB IS ENTERED IN THE DD TABLE.             * 05800020
*                                                                     * 06000020
*        SCANS THE DD TABLE TO CHECK THE SERIAL/PARALLEL STRUCTURE    * 06200020
*        OF THE SWAP DATA SETS.  USE THE DEVICE TYPE FIELD IN THE UCB * 06400020
*        TO CHECK IF PARALLEL DATA SETS ARE ON THE SAME TYPE DEVICE   * 06600020
*                                                                     * 06800020
*        THE DD TABLE IS RELEASED BEFORE IKJEAS00 TERMINATES.         * 07000020
*                                                                     * 07200020
*ENTRY POINTS- IKJEAS00                                               * 07400020
*                                                                     * 07600020
*INPUT-  REG   1    ADDR. OF PARM. LIST                               * 07800020
*        REG   13   ADDR. OF SAVE AREA                                * 08000020
*        REG   14   RETURN ADDR.                                      * 08200020
*        REG   15   ENTRY POINT ADDR.  -  IKJEAS00                    * 08400020
*                                                                     * 08600020
*        PARM LIST                                                    * 08800020
*        +  0  NUMBER OF USERS-NOT EXAMINED                           * 09000020
*        +  4  LENGTH OF PARM DATA-NOT EXAMINED                       * 09200020
*        +  8  ADDR. OF PARM DATA-NOT EXAMINED                        * 09400020
*        + 12  SWAP SWITCH-NOT EXAMINED BY THIS LOAD                  * 09600020
*        + 13  CONSOLE ID FOR WTO/WTOR MESSAGES                       * 09610020
*        + 14  NUMBER OF REGIONS-EXAMINED                             * 09800020
*        + 16   0 (ZERO)                                              * 10000020
         EJECT                                                          10200020
*OUTPUT- PARM. LIST + 16 AMOUNT OF MAIN STORAGE REQUIRED BY SWAP      * 10400020
*                                                                     * 10600020
*EXTERNAL REFERENCES-                                                 * 10800020
*        GETMAIN/FREEMAIN/WTO                                         * 11000020
*        EXTRACT  (FOR ADDR. OF TIOT)                                 * 11200020
*                                                                     * 11400020
*EXIT-   RETURN TO CALLER. REG 15 CONTAINS RETURN CODE.               * 11600020
*        RC=0  MAIN STORAGE REQUIREMENTS RETURNED                     * 11800020
*        RC=4  NOT USED                                               * 12000020
*        RC=8  ERROR, MAIN STORAGE REQUIREMENTS NOT RETURNED          * 12200020
*                                                                     * 12400020
*EXIT ERROR-NONE                                                      * 12600020
*                                                                     * 12800020
*TABLES/CONTROL BLOCKS/WORK AREAS                                     * 13000020
*        TIOT, UCB                                                    * 13200020
*                                                                     * 13400020
*        LOCAL:  DDNAME TABLE. USE TO DETERMINE SERIAL/PARALLEL       * 13600020
*        OF SWAP DATA SETS.  DDNAMES ARE 'SYSWAPLN' WHERE L IS LEVEL, * 13800020
*        AND N IS THE NUMBER ON THE LEVEL.                            * 14000020
*                                                                     * 14200020
*                    N=0           N=1                                * 14400020
*              ******************************                         * 14600020
*    L=0   +0  *  ADDR. UCB  *  ADDR. UCB   *                         * 14800020
*              ******************************                         * 15000020
*    L=1   +8  *  ADDR. UCB  *  ADDR. UCB   *                         * 15200020
*              ******************************                         * 15400020
*              ETC.                                                   * 15600020
*                                                                     * 15800020
*NOTES-  THE TSO CONTROL BLOCKS DO NOT EXIST AND MAY NOT BE ACCESSED. * 16000020
*                                                                     * 16200020
*        FOR DIRECT ACCESS STORAGE DEVICES                            * 16400020
*        IBM   2311    DISK WITH RECORD OVERFLOW FEATURE              * 16600020
*        IBM   2314    DISK                                           * 16800020
*        IBM   2301    DRUM                                           * 17000020
*        IBM   2303    DRUM WITH RECORD OVERFLOW FEATURE              * 17200020
*        IBM   2305    DRUM  MODEL 1                             20201* 17250020
*        IBM   2305    DRUM  MODEL 2                             20201* 17300020
*        IBM   3330    DISK                                      20201* 17350020
*********************************************************************** 17400020
         EJECT                                                          17600020
CVTDSECT DSECT                                                          17800020
         CVT                                                            18000020
         EJECT                                                          18200020
         IKJSWAPD  INIT=YES                                             18400020
         EJECT                                                          18600020
*********************************************************************** 18800020
*WORK AREA USED BY SWAP PRE-INITIALIZATION(IKJEAS00).  CONTAINS       * 19000020
*SAVE AREA, WTO BUFFER,  AND SVC PARM LISTS                           * 19200020
*********************************************************************** 19400020
S00WORKD DSECT                                                          19600020
S00WSAVE DS    18F                 SAVE AREA                            19800020
S00WWTO  EQU   S00WSAVE+12         USE SAVE AREA FOR WTO BUFFER         20000020
S00WEXPL EQU   S00WSAVE+12         USE SAVE FOR EXTRAC PARM LIST        20200020
S00OPLS  EQU   S00WSAVE+12         USE SAVE FOR DYNAMIC OPEN PARM 20201 20300020
S00WPACK DS    D                   BUFFER FOR PACK,CVB                  20400020
S00WTIOT DS    F                   ADDR. OF TIOT                        20600020
S00WDDTL DS    F                   L'OF DDNAME TABLE       1/2          20800020
S00WDDTA DS    F                   ADDR. OF DDNAME TABLE   2/2          21000020
S00WSV1  DS   5F                                               AE P1677 21100021
S00WL    EQU   *-S00WORKD          L'S00 SAVE WORK AREA                 21200020
         EJECT                                                          21400020
****************REGISTER EQUATES                                        21600020
*                                  WORK REGISTERS                       21800020
WR0      EQU   0                   *                                    22000020
WR1      EQU   1                   *                                    22200020
WR2      EQU   2                   *                                    22400020
WR3      EQU   3                   *                                    22600020
WR4      EQU   4                   *                                    22800020
WR5      EQU   5                   *                                    23000020
WR14     EQU   14                  *                                    23200020
WR15     EQU   15                  *                                    23400020
*                                                                       23600020
UCBR     EQU   6                   ADDR. OF UCB                         23800020
TIOTR    EQU   7                   ADDR. OF TIOT                        24000020
TRANR    EQU   8                   INTERNAL RETURN ADDR.                24200020
CTR      EQU   9                   COUNT REG                            24400020
MSR      EQU   10                  SUM OF MAIN STORAGE REG              24600020
PARMR    EQU   11                  PARAMETER REGISTER                   24800020
BASER    EQU   12                  BASE ADDR                            25000020
SAVER    EQU   13                  SAVE AREA ADDR.                      25200020
RTNR     EQU   14                  RETURN ADDR.                         25400020
EPR      EQU   15                  ENTRY POINT ADDR.                    25600020
***************NUMERIC EQUATES                                          25800020
E0       EQU   0                   *                                    26000020
E1       EQU   1                   *                                    26200020
E2       EQU   2                   *                                    26400020
E3       EQU   3                   *                                    26600020
E4       EQU   4                   *                                    26800020
E5       EQU   5                   *                                    27000020
E6       EQU   6                   *                                    27200020
E7       EQU   7                   *                                    27400020
E8       EQU   8                   *                                    27600020
E16      EQU   16                  *                                    27800020
***************CHARACTER EQUATES                                        28000020
C0       EQU   C'0'                ZERO                                 28200020
C1       EQU   C'1'                ONE                                  28400020
****************GENERAL EQUATES                                         28600020
*                                  DISPLACMENTS IN THE PARMS LIST       28800020
PCONID   EQU   13                  TO CONSOLE ID FOR WTO/WTOR           29000020
PREG     EQU   14                  TO NUMBER OF REGIONS                 29200020
PMS      EQU   16                  TO MAIN STORAGE REQUIREMENTS         29400020
****************FLAG EQUATES                                      20201 29460020
OPENFLAG EQU   X'10'               DCB OPEN FLAG MASK             20201 29520020
         EJECT                                                          29600020
IKJEAS00 CSECT                                                          29800020
*********************************************************************** 30000020
*IKJEAS00 INITIALIZATION:  OBTAIN SAVE/WORK AREA.                     * 30200020
*********************************************************************** 30400020
         SAVE  (14,12)             SAVE THE CALLER'S REGISTERS          30600020
         BALR  BASER,0             EST. ADDRESSABILITY                  30800020
         USING *,BASER             *                                    31000020
         LR    PARMR,WR1           LOAD PARM LIST REGISTER              31200020
         LA    WR0,S00WL           L'S00 SAVE/WORK AREA                 31400020
         GETMAIN R,LV=(0)          SAVE/WORK AREA                       31600020
         ST    WR1,E8(SAVER)       CHAIN                                31800020
         ST    SAVER,E4(WR1)       SAVE                                 32000020
         USING S00WORKD,SAVER      SAVE/WORK AREA                       32200020
         LR    SAVER,WR1           AREAS                                32400020
         XC    S00WDDTA(E4),S00WDDTA  CLEAR ADDR. OF DDNAME TABLE       32600020
*********************************************************************** 32800020
*USE EXTRACT MACRO TO GET ADDR. OF TIOT.                              * 33000020
*********************************************************************** 33200020
         LA    WR1,S00WEXPL        EXTRACT MACRO PARM LIST              33400020
         LA    WR2,S00WTIOT        TIOT ADDR. HERE                      33600020
         EXTRACT  (WR2),'S',FIELDS=(TIOT),MF=(E,(1)) EXTRACT ADDR. TIOT 33800020
*********************************************************************** 34000020
*SEARCH TIOT FOR SWAP DATA  SET DDNAMES(SYSWAPXX).  DETERMINE         * 34200020
*DEVICE VALID.  COMPUTE FIXED MAIN STORAGE  REQUIREMENTS.             * 34400020
*********************************************************************** 34600020
         L     TIOTR,S00WTIOT      ADDR. OF TIOT                        34800020
         LA    TIOTR,TIOCLNGH(TIOTR) PLUS FIXED LEN. OF TIOT            35000020
         SR    MSR,MSR             ZERO MAIN STORAGE REG.               35200020
         SR    CTR,CTR             ZERO COUNT REG.                      35400020
         SR    WR15,WR15           ZERO REGISTER FOR INDEXING           35600020
         LA    TRANR,S0ML01        SET RETURN ADDR.                     35800020
         USING TIOTD,TIOTR         TIOT                                 36000020
S0ML00   CLI   TIOELNGH,E0         END OF TIOT                          36200020
         BE    S0ML02              YES                                  36400020
         CLC   TIOEDDNM(E6),NSYSWAP  SWAP DATA SET??  'SYSWAP'          36600020
         BE    S0DD100             YES                                  36800020
S0ML01   IC    WR15,TIOELNGH       L' OF DD ENTRY                       37000020
         LA    TIOTR,E0(WR15,TIOTR)  ADDR. OF NEXT DD ENTRY IN TIOT     37200020
         B     S0ML00              TO TOP                               37400020
         EJECT                                                          37600020
*********************************************************************** 37800020
*ANY SWAP DATA SETS. CHECK COUNT. CTR CONTAINS COUNT.                 * 38000020
*********************************************************************** 38200020
S0ML02   LTR   CTR,CTR             ANY SWAP DATA SETS?                  38400020
         BZ    S0ERR2              NO, TO ERROR TWO                     38600020
*********************************************************************** 38800020
*COMPUTE MAIN STORAGE FOR SWAP REQUEST TABLE ENTRIES.                 * 39000020
*********************************************************************** 39200020
         LR    WR2,CTR             COUNT OF DEVICES                     39400020
         MH    WR2,PREG(PARMR)     TIMES NUM. OF REGIONS                39600020
         MH    WR2,S00SRQEL        TIMES L'SWAP REQUEST TABLE ENTRY     39800020
         BAL  WR14,S00SUM0   SUM NEEDED CORE FOR SWAP          AE P1677 40000021
*********************************************************************** 40200020
*COMPUTE STORAGE FOR SERIAL/PARALLEL POINTERS FOR EACH SWAPCB         * 40400020
*********************************************************************** 40600020
         LR    WR2,CTR             COUNT OF DEVICES                     40800020
         SLL   WR2,E3              TIMES EIGHT PER SWAPCB               41000020
         BAL  WR14,S00SUM0   SUM NEEDED CORE FOR SWAP          AE P1677 41200021
         ST    MSR,PMS(PARMR)      TOTAL TO PARM LIST                   41400020
*********************************************************************** 41600020
*COMPUTE THE SIZE OF AND OBTAIN THE DD TABLE.  COMPUTE SIZE FROM THE  * 41800020
*COUNT OF SWAP DATA SETS.                                             * 42000020
*********************************************************************** 42200020
         LR    WR2,CTR             SAVE COUNT OF DATA SETS              42400020
         SLL   WR2,E3              TIMES EIGHT PER POSSIBLE LEVEL       42600020
         ST    WR2,S00WDDTL        SAVE LENGTH IN S00 SAVE/WORK AREA    42800020
         GETMAIN  R,LV=(WR2)       MAIN STORAGE FOR DD TABLE            43000020
         ST    WR1,S00WDDTA        SAVE ADDR. IN S00 SAVE/WORK AREA     43200020
         ST   WR1,ADDTABL SAVE ADDRESS OF DD TABLE FOR S0DD200 AE P1677 43400021
         AR    WR2,WR1             SIZE PLUS START EQ END               43600020
S0ML030  XC    E0(E8,WR1),E0(WR1)  ZERO DD TABLE                        43800020
         LA    WR1,E8(WR1)         BUMP TO NEXT LEVEL                   44000020
         CR    WR1,WR2             CURRENT EQ END                       44200020
         BL    S0ML030             NO TO TOP                            44400020
         EJECT                                                          44500020
*********************************************************************** 44600020
*DETERMINE THE VALIDITY OF SWAP DATA SET SERIAL/PARALLEL STRUCTURE.   * 44800020
*SEARCH TIOT FOR SWAP DATA SETS.  ENTER ADDR. OF UCB IN DD TABLE      * 45000020
*********************************************************************** 45200020
         L     TIOTR,S00WTIOT      ADDR. OF TIOT                        45400020
         LA    TIOTR,TIOCLNGH(TIOTR) PLUS FIXED LENGTH OF TIOT          45600020
         SR    WR15,WR15           ZERO REGISTER FOR INDEXING           45800020
         LA    TRANR,S0ML04        SET RETURN                           46000020
         USING TIOTD,TIOTR         TIOT                                 46200020
S0ML03   CLI   TIOELNGH,E0         END OF TIOT                          46400020
         BE    S0ML05              YES                                  46600020
         CLC   TIOEDDNM(E6),NSYSWAP SWAP DATA SET  'SYSWAP'             46800020
         BE    S0DD200             YES                                  47000020
S0ML04   IC    WR15,TIOELNGH       L'DD ENTRY                           47200020
         LA    TIOTR,E0(WR15,TIOTR) ADDR. OF NEXT ENTRY                 47400020
         B     S0ML03              TO TOP                               47600020
*********************************************************************** 48000020
*DD NAME TABLE IS BUILT. CONTAIN  ADDR. OF UCB FOR EACH SWAP DATA SET.* 48200020
*SCAN TABLE FOR VALID SERIAL/PARALLEL.  FOR PARALLEL, USE UCB ADDR. TO* 48400020
*CHECK PARALLEL ON SAME LEVEL.                                        * 48600020
*********************************************************************** 48800020
S0ML05   LM    WR1,WR2,S00WDDTL    L' AND ADDR. OF DD TABLE             49000020
         AR    WR1,WR2             L' PLUS START=END, WR2=ADDR. OF L=0  49200020
         SR    WR5,WR5             ZERO SWAP DS COUNT FOR DD SCAN       49400020
S0ML06   LM    WR3,WR4,E0(WR2)     ENTRIES FOR N=0, N=1 ADDR. UCB'S     49600020
         LTR   WR3,WR3             ENTRY FOR N=0                        49800020
         BZ    S0ML08              NO                                   50000020
         LA    WR5,E1(WR5)         PLUS ONE                             50200020
         LTR   WR4,WR4             ENTRY FOR N=1                        50400020
         BNZ   S0ML07              YES, CHECK DATA SETS IN PARALLEL     50600020
         LA    WR2,E8(WR2)         BUMP POINTER IN DD TABLE             50800020
         CR    WR2,WR1             CURRENT POSITION TO DD TABLE TO END  51000020
         BL    S0ML06              NOT DONE, TO TOP FOR NEXT LEVEL      51200020
         B     S0ML08              CHECK COUNTS                         51400020
S0ML07   LA    WR5,E1(WR5)         PLUS ONE                             51600020
*                                  CHECK DEVICE CLASS OF PARALLEL       51800020
         USING UCBD,WR3            UCB                                  52000020
         LA    WR3,UCBTDTYP        ADDR. OF UCB DEVICE TYPE N=0         52200020
         DROP  WR3                 UCB                                  52400020
         USING UCBD,WR4            UCB                                  52600020
         LA    WR4,UCBTDTYP        ADDR. OF UCB DEVICE TYPE N=1         52800020
         DROP  WR4                 UCB                                  53000020
         CLC   E0(E1,WR3),E0(WR4)  SAME DEVICES IN PARALLEL             53200020
         BNE   S0ERR2              NO                                   53400020
*                                  PARALLEL AT GREATEST 'L' ONLY        53600020
S0ML08   CR    WR5,CTR             COUNTS EQUAL                         53800020
         BNE   S0ERR2              NO                                   54000020
         SR    WR15,WR15           RETURN CODE=0                        54200020
         B     S0RTN               DONE, RETURN                         54400020
         EJECT                                                          54600020
*********************************************************************** 54800020
*FOUND 'SYSWAPXX'. VALIDITY CHECK DEVICE  CLASS, FEATURE, AND TYPE    * 55000020
*********************************************************************** 55200020
S0DD100  LA    CTR,E1(CTR)         COUNT OF SWAP DS PLUS ONE            55400020
         USING UCBD,UCBR           UCB                                  55600020
         L     UCBR,TIOEFSRT       ADDR. OF UCB                         55800020
*                                  TEST DEVICE CLASS                    56000020
         CLI   UCBTDEVC,DEVDASD    DEVICE TYPE IS DASD                  56200020
         BNE   S0ERR1              NO                                   56400020
*                                  TEST FEATURE                         56600020
         TM    UCBTOFEA,DEVROFW    RECORD OVERFLOW                      56800020
         BZ    S0ERR1              NO                                   57000020
*                                  TEST DEVICE TYPE                     57200020
         CLI   UCBTDTYP,DEV2311    DEVICE  2311                         57400020
         BE    S0D12311            YES                                  57600020
         CLI   UCBTDTYP,DEV2314    DEVICE  2314                         57800020
         BE    S0D12314            YES                                  58000020
         CLI   UCBTDTYP,DEV2301    DEVICE  2301                         58200020
         BE    S0D12301            YES                                  58400020
         CLI   UCBTDTYP,DEV2303    DEVICE  2303                         58600020
         BE    S0D12303            YES                                  58800020
         CLI   UCBTDTYP,DEV23051   DEVICE 2305 MODEL 1            20201 58820020
         BE    S0D23051            YES                            20201 58840020
         CLI   UCBTDTYP,DEV23052   DEVICE 2305 MODEL 2            20201 58860020
         BE    S0D23052            YES                            20201 58880020
         CLI   UCBTDTYP,DEV3330    DEVICE 3330                    20201 58900020
         BE    S0D13330            YES                            20201 58920020
         B     S0ERR1              NO, DEVICE NOT VALID                 59000020
         EJECT                                                          59200020
*********************************************************************** 59400020
*DEVICE IS VALID.  COMPUTE MAIN STORAGE REQUIREMENTS                  * 59600020
*********************************************************************** 59800020
         USING DEBD,WR4            ADDRESSABILITY ON DEB          20201 59860020
         USING SWAPCBD,WR3         ADDRESSABILITY ON DCB          20201 59920020
S0D12311 EQU   *                   2311 COMPUTATION                     60000020
         BAL  WR14,S00SUM1   SUM NEEDED CORE FOR SWAP CB       AE P1677 60100021
         BAL   WR5,S0DD300         TO DCB BUILD AND OPEN SUBRTN   20201 60220020
         LH    WR1,DEBENDCC        CYL END MINUS CYL START        20201 60240020
         SH    WR1,DEBSTRCC        PLUS ONE IS NUMBER OF UNITS    20201 60260020
         LA    WR1,E1(WR1)         ALLOCATED                      20201 60280020
         SLL   WR1,E1              TIMES 2 (HALFWORD PER SWP UNIT)20201 60300020
         BAL  WR14,S00SUM2   SUM NEEDED CORE FOR UNIT TABLE    AE P1677 60350021
         LH    WR5,CP2311L         LENGTH CHANNEL PROGRAM AREA    20201 60410020
         B     S0DD101             TO COMPUTE CHANNEL PROGRM AREA 20201 60500020
S0D12314 EQU   *                   2314 COMPUTATION                     61000020
         BAL  WR14,S00SUM1   SUM NEEDED CORE FOR SWAP CB       AE P1677 61100021
         BAL   WR5,S0DD300         TO DCB BUILD AND OPEN SUBRTN   20201 61220020
         LH    WR1,DEBENDCC        CYL END MINUS CYL START        20201 61240020
         SH    WR1,DEBSTRCC        PLUS ONE IS NUMBER OF UNITS    20201 61260020
         LA    WR1,E1(WR1)         ALLOCATED                      20201 61280020
         SLL   WR1,E1              CONVERT CYLS TO 1/2 CYLS (S.U.)20201 61300020
         SLL   WR1,E1              TIMES 2 (HALFWORD PER SWP UNIT)20201 61320020
         BAL  WR14,S00SUM2   SUM NEEDED CORE FOR UNIT TABLE    AE P1677 61380021
         LH    WR5,CP2314L         LENGTH CHANNEL PROGRAM AREA    20201 61440020
         B     S0DD101             TO COMPUTE CHANNEL PROGRM AREA 20201 61640020
S0D12301 EQU   *                   2301 COMPUTATION                     62000020
         BAL  WR14,S00SUM1   SUM NEEDED CORE FOR SWAP CB       AE P1677 62100021
         BAL   WR5,S0DD300         TO DCB BUILD AND OPEN SUBRTN   20201 62240020
         LH    WR1,DEBTRKS         NUMBER OF TRACKS EQ # OF UNITS 20201 62280020
         SLL   WR1,E1              TIMES 2 (HALFWORD PER SWP UNIT)20201 62320020
         BAL  WR14,S00SUM2   SUM NEEDED CORE FOR UNIT TABLE    AE P1677 62390021
         LH    WR5,CP2301L         LENGTH CHANNEL PROGRAM AREA    20201 62460020
         B     S0DD101             TO COMPUTE CHANNEL PROGRM AREA 20201 62660020
S0D12303 EQU   *                   2303 COMPUTATION                     63000020
         BAL  WR14,S00SUM1   SUM NEEDED CORE FOR SWAP CB       AE P1677 63100021
         BAL   WR5,S0DD300         TO DCB BUILD AND OPEN SUBRTN   20201 63230020
         LH    WR1,DEBTRKS         NUMBER OF TRACKS               20201 63260020
         SRL   WR1,E2              DIVIDED BY FOUR(SWAP UNITS)    20201 63290020
         SLL   WR1,E1              TIMES 2 (HALFWORD PER SWP UNIT)20201 63320020
         BAL  WR14,S00SUM2   SUM NEEDED CORE FOR UNIT TABLE    AE P1677 63370021
         LH    WR5,CP2303L         LENGTH CHANNEL PROGRAM AREA    20201 63430020
         B     S0DD101             TO COMPUTE CHANNEL PROGRM AREA 20201 63510020
S0D23051 EQU   *                   2305 MODEL 1 COMPUTATION       20201 63520020
         BAL  WR14,S00SUM1   SUM NEEDED CORE FOR SWAP CB       AE P1677 63530021
         BAL   WR5,S0DD300         TO DCB BUILD AND OPEN SUBRTN   20201 63540020
         LH    WR1,DEBTRKS         NUMBER OF TRACKS               20201 63550020
         SRL   WR1,E2              DIVIDED BY FOUR(SWAP UNITS)    20201 63560020
         SLL   WR1,E1              TIMES 2 (HALFWORD PER SWP UNIT)20201 63570020
         BAL  WR14,S00SUM2   SUM NEEDED CORE FOR UNIT TABLE    AE P1677 63580021
         LH    WR5,CP23051L        LENGTH CHANNEL PROGRAM AREA    20201 63590020
         B     S0DD101             TO COMPUTE CHANNEL PROGRM AREA 20201 63600020
S0D23052 EQU   *                   2305 MODEL 2 COMPUTATION       20201 63610020
         BAL  WR14,S00SUM1   SUM NEEDED CORE FOR SWAP CB       AE P1677 63620021
         BAL   WR5,S0DD300         TO DCB BUILD AND OPEN SUBRTN   20201 63630020
         LH    WR1,DEBTRKS         NUMBER OF TRACKS               20201 63640020
         SRL   WR1,E2              DIVIDED BY FOUR(SWAP UNITS)    20201 63650020
         SLL   WR1,E1              TIMES 2 (HALFWORD PER SWP UNIT)20201 63660020
         BAL  WR14,S00SUM2   SUM NEEDED CORE FOR UNIT TABLE    AE P1677 63670021
         LH    WR5,CP23052L        LENGTH CHANNEL PROGRAM AREA    20201 63680020
         B     S0DD101             TO COMPUTE CHANNEL PROGRM AREA 20201 63690020
S0D13330 EQU   *                   3330 COMPUTATION               20201 63700020
         BAL  WR14,S00SUM1   SUM NEEDED CORE FOR SWAP CB       AE P1677 63710021
         BAL   WR5,S0DD300         TO DCB BUILD AND OPEN SUBRTN   20201 63720020
         LH    WR1,DEBTRKS         NUMBER OF TRACKS               20201 63750020
         SR    WR0,WR0             CLEAR REG 0                    20201 63780020
         D     WR0,NF3             DIVIDED BY THREE(SWAP UNITS)   20201 63810020
         LR    WR5,WR1       SAVE FIRST CALCULATION                     63820021
         SR    WR0,WR0       ZERO OUT FOR THE DIVIDE                    63830021
         D     WR0,NF19      CALCULATE THE NO. OF EXTRA TRKS            63840021
         SR    WR5,WR1       SUBTRACT UNUSED FROM TOTAL                 63850021
         SLL   WR5,E1        TIMES 2 (HALFWORD PER SWAP UNIT)           63860021
         BAL  WR14,S00SUM3   SUM NEEDED CORE FOR UNIT TABLE    AE P1677 63880021
         LH    WR5,CP3330L         LENGTH CHANNEL PROGRAM AREA    20201 63900020
*********************************************************************** 63930020
*COMPUTE TOTAL CHANNEL PROGRAM AREA REQUIREMENTS AND ADD TO TOTAL     * 64000020
*********************************************************************** 64200020
S0DD101  AR    WR5,WR5             TWO CHANNEL PROGRAM AREAS      20201 64400020
*                            SUM NEEDED CORE FOR               AE P1677 64500021
         BAL  WR14,S00SUM3   CHANNEL PGM AREAS                 AE P1677 64600021
         B     S0DD400             GO CLOSE AND FREE THE DCB      20201 64800020
         EJECT                                                          65000020
*********************************************************************** 65200020
*SWAP DATA SET DDNAME  IS 'SYSWAPLN',  L IS LEVEL, N IS NUM. ON LEVEL.* 65400020
*********************************************************************** 65600020
S0DD200  SR    WR1,WR1             SET DISP IN DD TABLE FOR N=0         65800020
         CLI   TIOEDDN,C1          N=1, A PARALLEL DATA SET             66000020
         BE    S0DD201             YES                                  66200020
         CLI   TIOEDDN,C0          NOT N=1, MUST BE N=0                 66400020
         BNE   S0ERR2              ERROR                                66600020
         B     S0DD202             TO HASH 'L'                          66800020
S0DD201  LA    WR1,E4              SET DISP IN DD TABLE FOR N=1         67000020
S0DD202  TM    TIOEDDL,C0          IS L NUMERIC                         67200020
         BNO   S0ERR2              NO, L IS INVALID              M5367  67400020
         PACK  S00WPACK(E8),TIOEDDL(E1)  PACK 'L'                       67600020
         CVB   WR2,S00WPACK        AND BINARY                           67800020
         SLL   WR2,E3              L TIMES EIGHT TO LEVEL IN DD TABLE   68000020
         AR    WR2,WR1             PLUS DISP FOR N                      68200020
         C     WR2,S00WDDTL        HASH LN GT DD TABLE SIZE             68400020
         BH    S0ERR2              ERROR                                68600020
         L    WR14,ADDTABL   RESTORE ADDR OF DD TABLE POINTER  AE P1677 68700021
         LA    WR2,E0(WR2,WR14)    COMPUTE ADDR. OF TABLE               68800020
         MVC   E0(E4,WR2),TIOEFSRT ADDR. OF UCB TO TABLE FOR THIS 'LN'  69000020
         BR    TRANR               DONE                                 69200020
         EJECT                                                    20201 69209020
*********************************************************************** 69218020
*               GETMAIN, BUILD AND OPEN THE DCB                       * 69227020
*********************************************************************** 69236020
S0DD300  EQU   *                   GETMAIN FOR DCB                20201 69245020
         LR    WR2,WR15            SAVE REG 15 ACROSS GETMAIN/    20201 69254020
*                                  FREEMAIN/OPEN/CLOSE            20201 69263020
         LA    WR4,S00DCBL         SCBLENGTH                      20201 69272020
         GETMAIN R,LV=(WR4)        GET DCB                        20201 69281020
         LR    WR3,WR1             SAVE ADDR                      20201 69290020
         MVC   SB1DCB(S00DCBL),S00DCB MOVE MODEL DCB              20201 69299020
         MVC   SB1DDNM(E8),TIOEDDNM MOVE DDNAME TO DCB            20201 69308020
         LA    WR1,S00OPLS         ADDR OF OPEN DYNAMIC PARM LIST 20201 69317020
         MVC   E0(E4,WR1),S00OPLST MOVE OPEN MACRO LIST TO DYNAMIC20201 69326020
         OPEN  ((WR3),INPUT),MF=(E,(1)) PLIST AND OPEN THE DCB    20201 69335020
         TM    SB1DCBOF,OPENFLAG  IS DCB OPEN                     20201 69344020
         BZ    S0ERR4              NO-BR                          20201 69353020
         L     WR4,SB1DEBA         GET DEB ADDR                   20201 69362020
         LA    WR4,DEBLNGH(WR4)    FIXED PART OF DEB              20201 69371020
         BR    WR5                 RETURN                         20201 69380020
*********************************************************************** 69389020
*                            CLOSE AND FREE THE DCB                   * 69399020
*********************************************************************** 69409020
S0DD400  EQU   *                   CLOSE DCB AND FREE IT          20201 69419020
         MVC   S00OPLS(S00CLSL),S00CLSLS MOVE CLOSE MACRO LIST    20201 69429020
*                                  TO DYNAMIC AREA                20201 69439020
         LA    WR1,S00OPLS         ADDR FOR CLOSE PARM LIST       20201 69449020
         CLOSE ((WR3)),MF=(E,(1))  CLOSE DCB                      20201 69459020
         LA    WR4,S00DCBL         DCB LENGTH FOR FREEMAIN        20201 69469020
         FREEMAIN R,LV=(WR4),A=(WR3)  FREE DCB                    20201 69479020
         LR    WR15,WR2            RESTORE REG 15                 20201 69489020
         BR     TRANR            TO MAIN LINE RTN                 20201 69499020
         EJECT                                                          69509020
*********************************************************************** 69600020
*S00 ERROR ROUTINE.  ISSUES WTO AND SETS RETURN CODE TO 8.            * 69800020
*UCBR - ADDR. OF UCB.  TIOTR - ADDR. TIOT ENTRY WITH SYSWAPLN         * 70000020
*********************************************************************** 70200020
S0ERR1   LA    WR1,S00WWTO         ADDR. OF WTO BUFFER                  70400020
         MVC   E0(S0MSG1L,WR1),S0MSG1   MOVE MSG TO BUFFER              70600020
         MVC   S0MSG1X(E3,WR1),UCBNAME  MOVE DEVICE ADDR. TO MSG        70800020
         MVC   S0MSG1Y(E8,WR1),TIOEDDNM MOVE DDNAME TO MSG              71000020
         B     S0ERR3              TO ISSUE WTO                         71200020
*                                                                 20201 71230020
S0ERR4   LA    WR1,S00WWTO         ADDR. OF WTO BUFFER            20201 71260020
         MVC   E0(S0MSG3L,WR1),S0MSG3   MOVE MSG TO BUFFER        20201 71290020
         MVC   S0MSG3Y(E8,WR1),TIOEDDNM MOVE DDNAME TO MSG        20201 71320020
         B     S0ERR3              TO ISSUE WTO                   20201 71350020
*                                                                       71400020
S0ERR2   LA    WR1,S0MSG2          ADDR. OF MSG2                        71600020
*                                                                       71800020
S0ERR3   SR    WR0,WR0             ZERO                                 72000020
         IC    WR0,PCONID(PARMR)   CONSOLE ID FROM PARM LIST            72200020
         WTO   MF=(E,(1))          ISSUE WTO                            72400020
         SR    WR1,WR1             ZERO                                 72600020
         ST    WR1,PMS(PARMR)      ZERO TOTAL MAIN STORAGE NEEDED       72800020
         LA    EPR,E8              SET RETURN CODE TO '8'               73000020
*********************************************************************** 73200020
*S00 RETURN. RELEASE SAVE AREA AND RETURNS TO CALLER. RC WAS SET.    .* 73400020
*********************************************************************** 73600020
S0RTN    LR    WR2,EPR             SAVE RC ACROSS FREEMAIN              73800020
         LM    WR0,WR1,S00WDDTL    LH AND ADDR OF DDNAME TABLE          74000020
         LTR   WR1,WR1             ADDR. EQ. ZERO                       74200020
         BZ    S0RTN01             YES, NEVER GOT THE TABLE             74400020
         FREEMAIN R,LV=(0),A=(1)   FREE THE DDNAME TABLE                74600020
S0RTN01  LR    WR1,SAVER           ADDR. OF S00 SAVE                    74800020
         L     SAVER,E4(WR1)       RESTORE CALLER SAVE                  75000020
         LA    WR0,S00WL           L'S00 SAVE/WORK AREA                 75200020
         FREEMAIN R,LV=(0),A=(1)   SAVE/WORK AREA                       75400020
         LR    EPR,WR2             RESTORE RETURN CODE                  75600020
         RETURN (14,12),RC=(15)    RESTORE CALLER'S REGISTERS           75800020
         EJECT                                                          75840021
S00SUM2  EQU  *                                                         75880021
         STM  WR1,WR5,S00WSV1  SAVE REGS NEEDED FOR SUBROUTINE AE P1677 75920021
S00SUM   EQU  *                                                         75960021
         LR   WR3,MSR GET WORKING COPY OF TOTAL STORAGE NEEDED AE P1677 76000021
         AR   WR3,WR1   ADD CALCULATE NEEDED TO TOTAL          AE P1677 76040021
         C    WR3,TWOKMULT   COMPARE TOTAL TO 2K MULTIPLE      AE P1677 76080021
         BL   S00DONE   TOTAL NOT EXCEEDING A 2K MULTIPLE      AE P1677 76120021
         L    WR4,TWOK     LOAD UP 2K VALUE FOR INCREMENT      AE P1677 76160021
         A    WR4,TWOKMULT INCREMENT 2K MULTIPLE COUNTER BY 2K AE P1677 76200021
         ST   WR4,TWOKMULT  SAVE NEXT 2K HIGHER MULTIPLE VALUE AE P1677 76240021
         SR   WR3,WR1   SUBTRACT NEEDED FROM TOTAL             AE P1677 76280021
         A    WR3,PLUS2K     ROUND UP TOTAL STORAGE NEEDED     AE P1677 76320021
         N    WR3,TWKMASK    TO NEXT 2K-FOR GETMAIN 2K BLOCKS  AE P1677 76360021
         AR   WR3,WR1  ADD NEEDED CORE TO TOTAL AFTER ROUND UP AE P1677 76400021
S00DONE  EQU  *                                                AE P1677 76440021
         LR   MSR,WR3   PUT TOTAL CORE NEEDED IN COUNTER       AE P1677 76480021
         LM   WR1,WR5,S00WSV1     RESTORE REGS                 AE P1677 76520021
         BR   WR14                 RETURN                      AE P1677 76560021
         SPACE     2                                           AE P1677 76600021
S00SUM0  EQU  *                                                AE P1677 76640021
         STM  WR1,WR5,S00WSV1     SAVE REGS                    AE P1677 76680021
         LR   WR1,WR2   SET UP CORE NEEDED IN REG WR1          AE P1677 76720021
         B    S00SUM    GO CALCULATE ACTUAL CORE NEEDED        AE P1677 76760021
         SPACE     2                                           AE P1677 76800021
S00SUM1  EQU  *                                                AE P1677 76840021
         STM  WR1,WR5,S00WSV1     SAVE REGS                    AE P1677 76880021
         LH   WR1,S00SCBL   SET UP CORE NEEDED IN REG WR1      AE P1677 76920021
         B    S00SUM    GO CALCULATE ACTUAL CORE NEEDED        AE P1677 76960021
         SPACE     2                                                    77000021
S00SUM3  EQU  *                                                AE P1677 77040021
         STM  WR1,WR5,S00WSV1     SAVE REGS                    AE P1677 77080021
         LR   WR1,WR5   SET UP CORE NEEDED IN REG WR1          AE P1677 77120021
         B    S00SUM    GO CALCULATE ACTUAL CORE NEEDED        AE P1677 77160021
         SPACE 2                                                        77200021
PLUS2K   DC   F'2047'      ROUND UP INCREMENTOR FOR 2K         AE P1677 77240021
TWKMASK  DC   X'FFFFF800'  ROUND UP MASK TO 2K                 AE P1677 77280021
TWOKMULT DC   F'2048'      ACCUMULATOR OF 2K CORE NEEDED       AE P1677 77320021
TWOK     DC   F'2048'      TW0 K INCREMENTOR FOR GETMAIN ALGO  AE P1677 77360021
ADDTABL  DC   F'0'         REGISTER SAVE AREA                  AE P1677 77400021
         EJECT                                                          77440021
*LENGTH OF SWAP CONTROL BLOCK                                           77800020
S00SRQEL DC    AL2(SB4END-SB4SW0)  SWAP REQUEST TABLE ENTRY             78000020
S00SCBL  DC    AL2(SB5END-SB1DCB)  SWAP CONTROL BLOCK                   78200020
         SPACE                                                          78400020
*LENGTH OF ONE CHANNEL PROGRAM AREA                                     78600020
CP2311L  DC    AL2(CPEND11-CPSEEK) 2311 CHANNEL PROGRAM AREA            78800020
CP2314L  DC    AL2(CPEND14-CPSEEK) 2314 CHANNEL PROGRAM AREA            79000020
CP2301L  DC    AL2(CPEND01-CPSEEK) 2301 CHANNEL PROGRAM AREA            79200020
CP2303L  DC    AL2(CPEND03-CPSEEK) 2303 CHANNEL PROGRAM AREA            79400020
CP23051L DC    AL2(CPEND051-CPSEEK) 2305 MOD 1 CHANEL PRGRAM AREA 20201 79450020
CP23052L DC    AL2(CPEND052-CPSEEK) 2305 MOD 2 CHANEL PRGRAM AREA 20201 79500020
CP3330L  DC    AL2(CPEND30-CPSEEK) 3330 CHANNEL PROGRAM AREA      20201 79550020
         SPACE                                                          79600020
*MODEL DD NAME FOR SWAP DATA SETS                                       79800020
NSYSWAP  DC    C'SYSWAP'           SWAP DATA SETS DDNAME IS 'SYSWAPLN'  80000020
* CONSTANTS                                                       20201 80060020
NF3      DC    F'3'                WORD OF THREE                  20201 80120020
NF19     DC    F'19'         NUMBER OF 3330 TRKS PER CYL                80160021
*********************************************************************** 80200020
*               IKJ035I DDD INVALID SWAP DEVICE, SYSWAPLN               80400020
S0MSG1   WTO   'IKJ035I     INVALID SWAP DEVICE,         ',            *80600020
               MCSFLAG=REG0,MF=L,DESC=5                                 80800020
S0MSG1L  EQU   *-S0MSG1            LENGTH OF MESSAGE                    81000020
S0MSG1X  EQU   12                  DISP TO DDD                          81200020
S0MSG1Y  EQU   37                  DISP TO DDNAME                       81400020
*********************************************************************** 81600020
S0MSG2   WTO   'IKJ036I SWAP DATA SET STRUCTURE INVALID',              *81800020
               MCSFLAG=REG0,MF=L,DESC=5                                 82000020
*               IKJ033I          SWAP DATA SET OPEN FAILED        20201 82030020
S0MSG3   WTO   'IKJ033I          SWAP DATA SET OPEN FAILED',      20201*82060020
               MCSFLAG=REG0,MF=L                                  20201 82090020
S0MSG3L  EQU   *-S0MSG3            LENGTH OF MESSAGE              20201 82120020
S0MSG3Y  EQU   12                  DISP TO DDNAME                 20201 82150020
*********************************************************************** 82200020
         EJECT                                                    20201 82220020
S00OPLST OPEN  (,(INPUT)),MF=L     MODEL OPEN MACRO PARM LIST     20201 82240020
         SPACE 3                                                  20201 82260020
S00DCB   DCB   MACRF=E,DSORG=DA,DDNAME=SYSWAPLN MODEL DCB 1/2     20201 82280020
S00DCBL  EQU   *-S00DCB                                   2/2     20201 82300020
S00CLSLS CLOSE (S00DCB),MF=L                                      20201 82320020
S00CLSL  EQU   *-S00CLSLS                                         20201 82340020
         EJECT                                                          82350021
*/*IKJEAS00: CHART */                                                   82390021
*/*HEADER                                                               82392021
*/*IKJEAS00   TSO/SWAP PRE INITIALIZATION */                            82394021
*/*IKJEAS00: E ENTRY */                                                 82396021
*/*         P     SAVE CALLER'S REGISTERS */                            82398021
*/*         P     SET UP GETMAIN PARMETERS */                           82398421
*/*         S     GETMAIN: GET CORE FOR S00WORKD */                     82398821
*/*         P     CHAIN SAVE ARAES */                                   82399221
*/*         P     CLEAR OUT ADDR OF DDNAME IN GOTTEN CORE */            82399621
*/*         P     SET UP FOR EXTRACT CALL FOR TIOT */                   82399721
*/*         S     EXTRACT: EXTRACT ADDRESS OF TIOT */                   82399821
*/*         P     SET UP ADDRESS OF TIOT */                             82399921
*/*         P     ZERO OUT MAIN STORAGE COUNTER */                      82449921
*/*         P     ZERO OUT COUNTER */                                   82459921
*/*         P     ZERO OUT INDEX REG */                                 82469921
*/*         P     SET TRANR RETURN ADDRESS TO SOML01 */                 82479921
*/*%ML00:   D     (YES,%ML02,NO,) END OF TIOT ? */                      82489921
*/*         D     (YES,%DD100,NO,) SWAP DATA SET ? */                   82491921
*/*%ML01:   P (,%ML00) UP POINTER TO NEXT DD ENTRY */                   82493921
*/*%ML02:   D     (YES,,NO,%ERR2) ANY SWAP DATA SETS ? */               82495921
*/*         P     # DEVICES * # REGIONS * SWAP REQ TBL = MAIN STORAGE   82497921
*/*REQ */                                                               82498321
*/*         P     # DEVICES * 8 + MAIN STORAGE REQ + --> PARM LIST */   82498721
*/*         P     COMPUTE MAIN STORAGE FOR SWAP REQUEST TABLE ENTRIES   82499121
*/**/                                                                   82499521
*/*         P     COMPUTE STORAGE FOR SERIAL/ PARALLEL POINTERS FOR     82499621
*/*EACH SWAPCB */                                                       82499721
*/*         S     GETMAIN: GET STORAGE FOR DD TABLE */                  82499821
*/*         P     ZERO DD TABLE */                                      82549821
*/*         P     SET UP ADDRESSABILITY FOR TIOT */                     82559821
*/*%ML03:     D     (YES,%ML05,NO,) END OF TIOT ? */                    82569821
*/*         D     (YES,%DD200,NO,) SWAP DATA SET ? */                   82579821
*/*%ML04:   P (,%ML03) UP POINTER TO NEXT DD ENTRY */                   82589821
*/*%ML05:   P     CALCULATE LENGTH OF DDNAME TABLE & ZERO SWAP DS CNT   82591821
*/**/                                                                   82593821
*/*%ML06:   P     PICK UP FIRST TWO DDNAMES ENTRIES */                  82595821
*/*         D     (YES,%ML08,NO,) FIRST ENTRY ZERO ? */                 82597821
*/*         P     ADD ONE TO SWAP DS COUNTER */                         82598221
*/*         D     (YES,%ML07,NO,) IS THERE A 2ND ENTRY ? */             82598621
*/*         P     UP POINTER TO NEXT ENTRY IN TABLE */                  82599021
*/*         D     (YES,%ML06,NO,%ML08) MORE ENTRIES TO CHECK ? */       82599421
*/*%ML07:   P     ADD ONE TO SWAP DS COUNTER */                         82599521
*/*         D     (NO,%ERR2,YES,) ARE PARALLEL DEVICES SAME TYPE ? */   82599621
*/*%ML08:   D     (NO,%ERR2,YES,) ARE DS COUNTERS EQUAL WR5 & CTR ? */  82599721
*/*         P     (,%RTN) SET ZERO RETURN CODE */                       82649721
*/*%DD100:  P     ADD ONE TO SWAP DATA SET COUNTER */                   82659721
*/*         P     GET THE ADDRESS OF THE UCB */                         82669721
*/*         D     (NO,%ERR1,YES,) IS DEVICE TYPE DASDI ? */             82679721
*/*         D     (NO,%ERR1,YES,) RECORD OVERFLOW OPTION ? */           82689721
*/*         D     (YES,%D12311,NO,) 2311? */                            82691721
*/*         D     (YES,%D12314,NO,) 2314 ? */                           82693721
*/*         D     (YES,%D12301,NO,) 2301 ? */                           82695721
*/*         D     (YES,%D12303,NO,) 2303 ? */                           82697721
*/*         D     (YES,%D23051,NO,) 2305 MODEL 1 ? */                   82698121
*/*         D     (YES,%D23052,NO,) 2305 MODEL 2 ? */                   82698521
*/*         D     (YES,%D13330,NO,%ERR1) 3330 ? */                      82698921
*/*%D12311: P     ADD SWAPCB SIZE TO STORAGE REQUIED COUNTER */         82699321
*/*         S     S0DD300: BUILD DCB AND OPEN SUBROUTINE */             82699421
*/*         P     REQ STORAGE = ((CYL END - CYL START) + 1) * 2 */      82699521
*/*         P     ADD 2311 REQ STORAGE TO TOTAL STORAGE REQUIRED */     82699621
*/*         P     (,%DD101) PUT LENGTH OF CHANNEL PGM IN PARM REG */    82749621
*/*%D12314: P     ADD SWAPCB SIZE TO STORAGE REQUIED COUNTER */         82759621
*/*         S     S0DD300: BUILD DCB AND OPEN SUBROUTINE */             82769621
*/*         P     REQ STORAGE = ((CYL END - CYL START) + 1) * 2 * 2 */  82779621
*/*         P     ADD 2314 REQ STORAGE TO TOTAL STORAGE REQUIRED */     82789621
*/*         P     (,%DD101) PUT LENGTH OF CHANNEL PGM IN PARM REG */    82791621
*/*%D12301: P     ADD SWAPCB SIZE TO STORAGE REQUIED COUNTER */         82793621
*/*         S     S0DD300: BUILD DCB AND OPEN SUBROUTINE */             82795621
*/*         P     REQ STORAGE = NUMBER OF TRACKS * 2 */                 82797621
*/*         P     ADD 2301 REQ STORAGE TO TOTAL STORAGE REQUIRED */     82798021
*/*         P     (,%DD101) PUT LENGTH OF CHANNEL PGM IN PARM REG */    82798421
*/*%D12303: P     ADD SWAPCB SIZE TO STORAGE REQUIED COUNTER */         82798821
*/*         S     S0DD300: BUILD DCB AND OPEN SUBROUTINE */             82799221
*/*         P     REQ STORAGE = (NUMBER OF TRACKS) / 4 * 2 */           82799321
*/*         P     ADD 2303 REQ STORAGE TO TOTAL STORAGE REQUIRED */     82799421
*/*         P     (,%DD101) PUT LENGTH OF CHANNEL PGM IN PARM REG */    82799521
*/*%D23051: P     ADD SWAPCB SIZE TO STORAGE REQUIED COUNTER */         82849521
*/*         S     S0DD300: BUILD DCB AND OPEN SUBROUTINE */             82859521
*/*         P     REQ STORAGE = (NUMBER OF TRACKS) / 4 * 2 */           82869521
*/*         P  ADD 2305 MOD 1 REQ STORAGE TO TOTAL STORAGE REQUIRED */  82879521
*/*         P     (,%DD101) PUT LENGTH OF CHANNEL PGM IN PARM REG */    82889521
*/*%D23052: P     ADD SWAPCB SIZE TO STORAGE REQUIED COUNTER */         82891521
*/*         S     S0DD300: BUILD DCB AND OPEN SUBROUTINE */             82893521
*/*         P     REQ STORAGE = (NUMBER OF TRACKS) / 4 * 2 */           82895521
*/*         P  ADD 2305 MOD 2 REQ STORAGE TO TOTAL STORAGE REQUIRED */  82897521
*/*         P     (,%DD101) PUT LENGTH OF CHANNEL PGM IN PARM REG */    82897921
*/*%D13330: P     ADD SWAPCB SIZE TO STORAGE REQUIED COUNTER */         82898321
*/*         S     S0DD300: BUILD DCB AND OPEN SUBROUTINE */             82898721
*/*         P     REQ STORAGE = (NUMBER OF TRACKS) / 3 * 2 */           82899121
*/*         P     ADD 3330 REQ STORAGE TO TOTAL STORAGE REQUIRED */     82899221
*/*         P     PUT LENGTH OF CHANNEL PGM IN PARM REG */              82899321
*/*%DD101:  P     (,%DD400) STORAGE REQ = 2 * CHANNEL PGM + STORAGE REQ 82899421
*/* */                                                                  82949421
*/*%DD200:  D     (YES,%DD201,NO,) PARALLEL DS ? */                     82959421
*/*         D     (NO,%ERR2,YES,%DD202) SERIAL DS ? */                  82969421
*/*%DD201:  P     SET DISPLACEMENT IN DD TABLE FOR N=1 */               82979421
*/*%DD202:  D     (NO,%ERR2,YES,) IS L NUMERIC ? */                     82989421
*/*         P     COMPUTE ADDRESS WITHIN TABLE & PUT UCB ADDR IN */     82991421
*/*         R     RETURN  */                                            82993421
*/*%DD300:  S     GETMAIN: GET CORE FOR DCB */                          82995421
*/*         S     OPEN: OPEN DCB */                                     82997421
*/*         D     (NO,%ERR4,YES,) IS DCB OPEN ? */                      82997821
*/*         P     GET DEB ADDRESS */                                    82998221
*/*         R     RETURN  */                                            82998621
*/*%DD400:  S     CLOSE: CLOSE DCB */                                   82999021
*/*         S     FREEMAIN: FREE DCB CORE */                            82999121
*/*         R     RETURN */                                             82999221
*/*%ERR1:   P     (,%ERR3) SET UP MESSAGE 'INVALID SWAP DEVICE' */      82999321
*/*%ERR4:   P     (,%ERR3) SET UP MESSAGE ' SWAP DATA SET OPEN FAILED'  83049321
*/**/                                                                   83059321
*/*%ERR2:   P     PUT ADDR OF 'SWAP DATA SET STRUCTURE INVALID' IN REG  83069321
*/**/                                                                   83079321
*/*%ERR3:   S     WTO: PUT OUT MESSAGE */                               83089321
*/*         P     SET RETURN CODE TO 8 */                               83091321
*/*%RTN:    S     FREEMAIN: FREE THE DDNAME TABLE */                    83093321
*/*%RTN01:  S     FREEMAIN: FREE THE SAVE AREA S00 */                   83095321
*/*         R     RETURN TO CALLER */                                   83097321
*/*END */                                                               83097721
         END                                                            83099321
