         TITLE 'IKJEAS01  TSO/SWAP INITIALIZATION'                      00050020
IKJEAS01 START                                                          00100020
*********************************************************************** 00150020
*                                                                       00152021
* STATUS -- 0                                                         * 00152421
*C139800-140400,154200-154600,203200-203600                  SSM A44022 00154021
*C124500                                                      AE A54052 00156021
*A125100,384344-384370,385257-385270,429514,429518            AE A54053 00160021
*                                                                     * 00200021
*FUNCTION-TSO SWAP INITIALIZATION                                     * 00250020
*        INITIALIZATION FOR SWAP DATA SETS.  CALLED AT START TSO:     * 00300020
*        FOR EACH SWAP DATA SET, OBTAINS MAIN STORAGE FOR AND         * 00350020
*        INITIALIZES:                                                 * 00400020
*        1)    SWAP CONTROL BLOCK(SWAPCB)                             * 00450020
*        2)    SWAP UNIT ALLOCATION TABLE                             * 00500020
*        3)    SWAP CHANNEL PROGRAM AREAS 'A' AND 'B'                 * 00550020
*        4)    SWAP REQUEST TABLE ENTRIES                             * 00600020
*                                                                     * 00650020
*        AFTER THE INITIALIZATION FOR ALL SWAP DATA SETS IS COMPLETE  * 00700020
*        BUILDS A CHAINED LIST OF SWAPCB'S FOR USE BY SWAP MAINLINE   * 00750020
*                                                                     * 00800020
*        ALL SWAP DATA SETS HAVE DD NAME OF 'SYSWAPLN' WHERE 'L'      * 00850020
*        IS THE LEVEL OF THE DATA SET(0, 1, 2, ETC.). THIS IS THE     * 00900020
*        SERIAL STRUCTURE OF THE DATA SETS.  AND WHERE 'N' IS THE     * 00950020
*        NUMBER OF DATA SETS AT THAT LEVEL.  THERE MAY BE ONLY        * 01000020
*        TWO DATA SETS AT A PARALLEL LEVEL(N=0, N=1) AND THEY MUST BE * 01050020
*        ALLOCATED ON THE SAME TYPE OF DASD DEVICE.                   * 01100020
*                                                                     * 01150020
*        IKJEAS01 ASSUMES THAT:                                       * 01200020
*                                                                     * 01250020
*        IKJEAS00 - SWAP PRE/INITIALIZATION HAS:                      * 01300020
*        1)   DETERMINED THE VALIDITY OF THE DEVICES THAT SWAP DATA   * 01350020
*        SETS ARE ALLOCATED TO.                                       * 01400020
*        2)   DETERMINED THE VALIDITY OF SERIAL/PARALLEL DATA         * 01450020
*        SET STRUCTURE.                                               * 01500020
*                                                                     * 01550020
*        IKJEAS01:                                                    * 01600020
*        SEARCHES THE TIOT TO COUNT THE NUMBER OF SWAP DATA SETS.     * 01650020
*        COMPUTES SIZE OF AND OBTAINS A DD NAME TABLE(LOCAL WORK      * 01700020
*        AREA).  SEARCHES THE TIOT A SECOND TIME AND ENTERS 'LN' OF   * 01750020
*        'SWSWAPLN' OF SWAP DATA SET DD NAME IN DD TABLE.             * 01800020
*                                                                     * 01850020
*        SCANS DD TABLE FOR 'LN'. FOR EACH 'LN' INVOKES S01MAIN.      * 01900020
*        S01MAIN WILL BUILD THE SWAPCB FOR ONE SWAP DATA SET.         * 01950020
*        S01MAIN  GETS MAIN STORAGE FOR THE SWAPCB. BUILDS A DCB AND  * 02000020
*        OPENS THE DATA SET.  INITIALIZES THE SWAPCB PER DEVICE       * 02050020
*        TYPE.  GETS MAIN STORAGE FOR CHANNEL PROGRAM AREAS AND THE   * 02100020
*        SWAP REQUEST TABLE.  TESTS THE PARAMETER LIST TO DETERMINE   * 02150020
*        IF THE SWAP DATA SET IS TO BE FORMATED.  IF FORMAT IS NOT    * 02200020
*        REQUIRED OR IS OPTIONAL, SETS UP A CHANNEL PROGRAM TO READ   * 02250020
*        CHECK AND DETERMINE IF THE DATA SET IS FORMATTED.            * 02300020
*        FOR AN UNFORMATTED DATA SET OR IF FORMAT IS REQUIRED, LINK   * 02350020
*        TO IKJEAS03 TO HAVE THE DATA SET FORMATED.                   * 02400020
         EJECT                                                          02450020
*        AFTER EACH SWAPCB IS BUILT, THE ADDR. OF THE SWAPCB IS       * 02500020
*        PLACED IN THE DD TABLE. AFTER ALL THE SWAPCB'S ARE BUILT     * 02550020
*        THE DD TABLE IS SCANNED AND THE CHAINED LIST OF SWAPCB'S IS  * 02600020
*        IS BUILT. THE ADDR. OF THE LIST IS AT TSCVTSDC.              * 02650020
*                                                                     * 02700020
*        THE HOME RECORD IS CHECKED TO SEE IF ALTERNATE TRACKS    M5430 02710020
*        ARE BEING USED FOR EACH SWAP UNIT.  IF SO, THE SWAP UNIT M5430 02720020
*        IS MARKED NOT AVAILABLE AND THE SWAP UNIT GROSS COUNT IS M5430 02730020
*        DECREMENTED ACCORDINGLY.                                 M5430 02740020
*        THE DD TABLE IS RELEASED BEFORE IKJEAS01 TERMINATES          * 02750020
*                                                                     * 02800020
*ENTRY POINTS-IKJEAS01                                                * 02850020
*                                                                     * 02900020
*INPUT-  REG   1    ADDR. OF PARM LIST                                * 02950020
*        REG   13   ADDR. OF SAVE AREA                                * 03000020
*        REG   14   RETURN ADDR.                                      * 03050020
*        REG   15   ENTRY POINT ADDR.     IKJEAS01                    * 03100020
*                                                                     * 03150020
*        PARM LIST                                                    * 03200020
*        +   0  NUMBER OF USERS-NOT EXAMINED                          * 03250020
*        +   4  L' OF PARM DATA-NOT EXAMINED                          * 03300020
*        +   8  ADDR. OF PARM DATA-NOT EXAMINED                       * 03350020
*        +  12  SWAP SWITCH-EXAMINED                                  * 03400020
*              X'FF'    FORMAT ALL SWAP DATA SETS                     * 03450020
*              X'0F'    FORMAT PER OPERATOR REQUIREMENTS              * 03500020
*              X'00'    DO NOT FORMAT                                 * 03550020
*        + 13  CONSOLE ID FOR WTO/WTOR MESSAGES                       * 03600020
*        + 14  NUMBER OF REGIONS-EXAMINED                             * 03650020
*        + 16  0(ZERO)                                                * 03700020
*                                                                     * 03750020
*OUTPUT- CHAINED LIST OF SWAPCB'S. ADDR. OF LIST AT TSCVTSDC.         * 03800020
*                                                                     * 03850020
*EXTERNAL REFERENCES-                                                 * 03900020
*        IKJEAS03                  SWAP FORMAT                        * 03950020
*        REG   1    ADDR. OF PARM LIST                                * 04000020
*        REG   13   ADDR. OF SAVE AREA                                * 04050020
*        REG   14   RETURN ADDR.                                      * 04100020
*        REG   15   ENTRY POINT ADDR.  IKJEAS03                       * 04150020
*                                                                     * 04200020
*        PARM LIST                                                    * 04250020
*        +   0 ADDR. OF SWAP CB                                       * 04300020
*        +   4 CONSOLE ID                                             * 04350020
*                                                                     * 04400020
*        IECPCNVT                  TTRN TO MBBCCHHR CONVERT           * 04450020
*        REG   0     TTRN                                             * 04500020
*        REG   1     ADDR. OF DEB                                     * 04550020
*        REG   2     ADDR. OF DW FOR MBBCCHHR                         * 04600020
*        REG   3-8   TRANSPARENT                                      * 04650020
*        REG   9-13  LOST                                             * 04700020
*        REG   14    RETURN ADDR.                                     * 04750020
*        REG   15    ENTRY POINT ADDR.  IECPCNVT                      * 04800020
         EJECT                                                          04850020
*        GETMAIN/FREEMAIN/OPEN/EXCP/WAIT/WTO/WTOR/LINK                * 04900020
*        EXTRACT  (FOR ADDR. OF TIOT)                                 * 04950020
*        SMFWTM FOR SMF RECORD 38 IF SMF IS ACTIVE                    * 05000020
*                                                                    -  05050020
*EXIT-   RETURN TO CALLER. REG 15 CONTAINS RETURN CODE.               * 05100020
*        RC=0  SWAP INITIALIZATION COMPLETE                           * 05150020
*        RC=4  NOT USED                                               * 05200020
*        RC=8  ERROR, SWAP INITIALIZATION FAILED                      * 05250020
*                                                                     * 05300020
*EXIT ERROR-NONE                                                      * 05350020
*                                                                     * 05400020
*TABLES/CONTROL BLOCKS/WORK AREAS                                     * 05450020
*                                                                     * 05500020
*        CVT, TIOT, UCB, DCB, DEB, IOB                                * 05550020
*                                                                     * 05600020
*        TSCVT, SWAPCB                                                * 05650020
*                                                                     * 05700020
*        LOCAL:  DDNAME TABLE. USE TO DETERMINE SERIAL/PARALLEL       * 05750020
*        OF SWAP DATA SETS.  DDNAMES ARE 'SYSWAPLN' WHERE L IS LEVEL, * 05800020
*        AND N IS THE NUMBER ON THE LEVEL.                            * 05850020
*                                                                     * 05900020
*        AFTER TIOT SEARCH FOR SWAP DATA SETS                         * 05950020
*                    N=0           N=1                                * 06000020
*              ******************************                         * 06050020
*    L=0   +0  *  'LN'*  0   *  'LN'*  0    *                         * 06100020
*              ******************************                         * 06150020
*    L=1   +8  *  'LN'*  0   *  'LN'*  0    *                         * 06200020
*              ******************************                         * 06250020
*              ETC.                                                   * 06300020
*                                                                     * 06350020
*        AFTER SWAPCB'S ARE BUILT                                     * 06400020
*                    N=0           N=1                                * 06450020
*              ******************************                         * 06500020
*    L=0   +0  *ADDR. SWAPCB *ADDR. SWAPCB  *                         * 06550020
*              ******************************                         * 06600020
*    L=1   +8  *ADDR. SWAPCB *ADDR. SWAPCB  *                         * 06650020
*              ******************************                         * 06700020
*              ETC.                                                   * 06750020
         EJECT                                                       -  06800020
*NOTES-  TSO CONTROL BLOCKS EXIST                                     * 06850020
*                                                                     * 06900020
*        FOR DIRECT ACCESS STORAGE DEVICES                            * 06950020
*        IBM   2311    DISK WITH RECORD OVERFLOW FEATURE              * 07000020
*        IBM   2314    DISK                                           * 07050020
*        IBM   2301    DRUM                                           * 07100020
*        IBM   2303    DRUM WITH RECORD OVERFLOW FEATURE              * 07150020
*        IBM   3330    DISK                                      20201* 07160020
*        IBM   2305    MOD 1 DRUM WITH RECORD OVERFLOW FEATURE   20201* 07170020
*        IBM   2305    MOD 2 DRUM WITH RECORD OVERFLOW FEATURE   20201* 07180020
*                                                                     * 07200020
*        GETMAIN SUBPOOL USAGE:                                       * 07250020
*              0 - TEMPORARY STORAGE(SAVE AND WORK AREAS)             * 07300020
*            252 - PERMANENT STORAGE(SWAP CONTROL BLOCKS)             * 07350020
*********************************************************************** 07400020
         EJECT                                                          07450020
CVTDSECT DSECT                                                          07500020
         CVT                                                            07550020
         SPACE                                                          07600020
         IKJTSCVT                                                       07650020
         SPACE                                                          07700020
         IKJSWAPD  INIT=YES                                             07750020
         EJECT                                                          07800020
*********************************************************************** 07850020
*WORK AREA USED BY SWAP INITIALIZATION(IKJEAS01). CONTAINS            * 07900020
*SAVE AREA, WTO/WTOR BUFFERS, EXTRACT PARM LIST, OPEN PARM LIST       * 07950020
*********************************************************************** 08000020
S01WORKD DSECT                                                          08050020
S01WSAVE DS    18F                 SAVE AREA                            08100020
S01WEXPL EQU   S01WSAVE+12         USE SAVE FOR EXTRACT PARM LIST       08150020
S01WOLST EQU   S01WSAVE+12         USE SAVE FOR OPEN PARM LIST          08200020
S01WWTO  EQU   S01WSAVE+12         USE SAVE AREA FOR WTO BUFFER         08250020
         ORG   S01WSAVE+96         ORG TO END WTO BUFFER                08300020
S01WPACK DS    D                   BUFFER FOR PACK,CVB                  08350020
S01W3PL  EQU   S01WPACK            PARM LIST TO IKJEAS03                08400020
S01W3PL1 EQU   S01W3PL             PARM 1 TO IKJEAS03                   08450020
S01W3PL2 EQU   S01W3PL+4           PARM 2 TO IKJEAS03                   08500020
S01WDDCS DS    D                   DD TABLE SCAN CURRENT/STOPPER        08550020
S01WRPLY DS    F                   REPLY BUFFER                         08600020
S01WECB  DS    F                   REPLY ECB                            08650020
S01WTIOT DS    F                   ADDR. OF FIRST DD ENTRY IN TIOT      08700020
S01WDDTL DS    F                   L'OF DDNAME TABLE       1/2          08750020
S01WDDTA DS    F                   ADDR. OF DDNAME TABLE   2/2          08800020
S01WL    EQU   *-S01WORKD          L'S01 SAVE WORK AREA                 08850020
         SPACE                                                          08900020
*********************************************************************** 08950020
*DSECT FOR SMF RECORD TYPE 38( START TSO SWAP DEVICES).               * 09000020
*********************************************************************** 09050020
SMFRD    DSECT                     DSECT FOR SMF RECORD 38              09100020
SMFRL    DS    H                   RECORD LENGTH                        09150020
         DS    H                   RESERVED                             09200020
         DS    XL1                 RESERVED                             09250020
SMFRT    DS    XL1                 RECORD TYPE                          09300020
SMFRT38  EQU   38                  RECORD TYPE 38                       09350020
SMFTOD   DS    XL8                 DATE AND TIME OF DAY                 09400020
SMFCPU   DS    XL4                 CPU IDENTIFICATION                   09450020
         DS    XL2                 RESERVED                             09500020
         DS    XL20                RESERVED                             09550020
SMFLV    DS    H                   LENGTH OF VARIABLE                   09600020
SMFNV    DS    XL1                 NUMBER OF SWAP DS ENTRIES            09650020
SMF38END DS    0X                  ADDR. OF FIRST SWAP DS ENTRY         09700020
SMF38L   EQU   *-SMFRD             LENGTH OF FIXED PART                 09750020
         SPACE                                                          09800020
SMF38ED  DSECT                     DSECT FOR SWAP DS ENTRY              09850020
SMF38EC  DS    XL1                 DEVICE CLASS                         09900020
SMF38ET  DS    XL1                 DEVICE TYPE                          09950020
SMF38EA  DS    XL2                 DEVICE ADDRESS                       10000020
SMF38EAN DS    0X                  ADDR. OF NEXT SWAP DS ENTRY          10050020
SMF38EL  EQU   *-SMF38ED           LENGTH OF SWAP DS ENTRY              10100020
         EJECT                                                          10150020
****************REGISTER EQUATES                                        10200020
*                                  WORK REGISTERS                       10250020
WR0      EQU   0                   *                                    10300020
WR1      EQU   1                   *                                    10350020
WR2      EQU   2                   *                                    10400020
WR3      EQU   3                   *                                    10450020
WR4      EQU   4                   *                                    10500020
WR5      EQU   5                   *                                    10550020
WR14     EQU   14                  *                                    10600020
WR15     EQU   15                  *                                    10650020
*                                                                       10700020
UCBR     EQU   6                   ADDR. OF UCB                         10750020
DDR      EQU   7                   ADDR. OF CURRENT DDNAME IN DD TABLE  10800020
TIOTR    EQU   7                   ADDR. OF TIOT                        10850020
TRANR    EQU   8                   ADDR. OF INTERNAL RETURN             10900020
CTR      EQU   9                   COUNT REG                            10950020
SWAPCBR  EQU   10                  ADDR. OF SWAP CONTROL BLOCK          11000020
PARMR    EQU   11                  ADDR. OF PARM LIST                   11050020
BASER    EQU   12                  ADDR. OF BASE                        11100020
SAVER    EQU   13                  ADDR. OF SAVE AREA                   11150020
RTNR     EQU   14                  RETURN ADDR.                         11200020
EPR      EQU   15                  ENTRY POINT ADDR.                    11250020
***************NUMERIC EQUATES                                          11300020
E0       EQU   0                   *                                    11350020
E1       EQU   1                   *                                    11400020
E2       EQU   2                   *                                    11450020
E3       EQU   3                   *                                    11500020
E4       EQU   4                   *                                    11550020
E5       EQU   5                   *                                    11600020
E6       EQU   6                   *                                    11650020
E7       EQU   7                   *                                    11700020
E8       EQU   8                   *                                    11750020
E12      EQU   12                  *                                    11800020
E16      EQU   16                  *                                    11850020
E32      EQU   32                  *                                    11900020
E255     EQU   255                 *                                    11950020
E256     EQU   256                 *                                    12000020
***************CHARACTER EQUATES                                        12050020
C0       EQU   C'0'                TWO                                  12100020
C1       EQU   C'1'                ONE                                  12150020
         EJECT                                                          12200020
****************GENERAL EQUATES                                         12250020
ALLFLAG  EQU   X'FF'               ALL BITS SET                         12300020
OPENFLAG EQU   X'10'               DCB OPEN FLAG                        12350020
CYLBOUND EQU   X'08'                    ALLOC. MASK FOR CYLINDER M0049  12360020
DEVFALL  EQU   X'C0'    M-2-3046   FILE MASK(WRITE/READ/SEEK FULL)      12400020
DEVF2303 EQU   X'C0'       FILE MASK(WRITE/READ/SEEK HEAD)    AE A54052 12450021
ALTTRACK EQU   X'08'          TURN OFF SWAP UNIT AVAIL. FLAG AND  M5430 12460020
*                             MARK-INDICATING ALTERNATE TRACK SITUATION 12470020
ECB7F    EQU   X'7F'               ECB POST CODE                        12500020
TRACK10  EQU   X'0A'     TRACK TEN WHICH IS INVALID FOR 2303 AE A54053  12510021
S2048    EQU   11                  SHIFT TO MUL-DIVIDE BY 2048          12550020
*                                  CHANNEL COMMAND WORDS                12600020
*                                  COMMAND CODES                        12650020
SIDEQ    EQU   X'31'               SEARCH ID EQUAL                      12700020
TIC      EQU   X'08'               TRANSFER IN CHANNEL                  12750020
READD    EQU   X'06'               READ DATA                            12800020
RHA      EQU   X'1A'               READ HOME ADDRESS CCW OP CODE        12810020
SEEKHD   EQU   X'1B'               SEEEK HEAD                           12820020
NOP      EQU   X'03'               NO OPERATION                         12850020
MT       EQU   X'80'               MULTI TRACK BIT                      12900020
*                                  FLAGS                                12950020
CC       EQU   X'40'               CHAIN COMMANDS                       13000020
CCR      EQU   X'82'               CC, IOB RELATED FLAAG                13020020
SLI      EQU   X'20'               SUPPRESS INCORRECT LENGTH            13050020
SKIP     EQU   X'10'               SKIP DATA TRANSFER                   13100020
NF       EQU   X'00'               NO FLAGS SET                         13150020
*                                  DISPLACMENTS IN THE PARMS LIST       13200020
PSWITCH  EQU   12                  SWAP SWITCH                          13250020
PSCONID  EQU   13                  CONSOLE ID FOR WTO/WTOR              13300020
PSWALL   EQU   X'FF'               FORMAT ALL SWAP DATA SETS            13350020
PRIMOPER EQU   X'02'               K  RHA FLAG FOR PRIMARY OPERATIME    13360020
*                                  TRACK                                13370020
PSWSOME  EQU   X'0F'               FORMAT PER OPERATOR                  13400020
PSWNONE  EQU   X'00'               DO NOT FORMAT                        13450020
PREGION  EQU   14                  TO NUMBER OF REGIONS                 13500020
* REMOVE FOLLOWING EQUATE   AFTER COMMAND RETRY IS FIXED FOR ZEUS M5388 13510020
CMDRETRY EQU   X'02'  MASK FOR INHIBIT COMM. RETRY-DEB-2305       M5388 13520020
         EJECT                                                          13550020
IKJEAS01 CSECT                                                          13600020
*********************************************************************** 13650020
*IKJEAS01 INITIALIZATION:  OBTAIN SAVE/WORK AREA.                     * 13700020
*********************************************************************** 13750020
         SAVE  (14,12)             SAVE THE CALLER'S REGISTERS          13800020
         BALR  BASER,0             EST. ADDRESSABILITY                  13850020
         USING *,BASER             *                                    13900020
         LR    PARMR,WR1           LOAD PARM LIST REGISTER              13950020
         LA    WR0,S01WL     L'S01 SAVE/WORK AREA.               A44022 13980021
         O     WR0,SP251     SUBPOOL 251.                        A44022 14010021
         GETMAIN R,LV=(0)                                        A44022 14040021
         ST    WR1,E8(SAVER)       CHAIN                                14100020
         ST    SAVER,E4(WR1)       SAVE                                 14150020
         USING S01WORKD,SAVER      SAVE/WROK AREA                       14200020
         LR    SAVER,WR1           AREAS                                14250020
         XC    S01WDDTA(E4),S01WDDTA  CLEAR ADDR. OF DDNAME TABLE       14300020
*********************************************************************** 14310020
*USE EXTRACT MACRO TO GET THE ADDR. OF TIOT                           * 14320020
*********************************************************************** 14330020
         LA    WR1,S01WEXPL        EXTRACT MACRO PARM LIST              14340020
         LA    WR2,S01WTIOT        ADDR. OF TIOT HERE                   14350020
         EXTRACT (WR2),'S',FIELDS=(TIOT),MF=(E,(1)) EXTRACT TIOT ADDR.  14360020
*********************************************************************** 14370020
*SEARCH TIOT FOR SWAP DATA SET DDNAMES(SYSWAPXX). COUNT THEM.         * 14380020
*********************************************************************** 14390020
         L     TIOTR,S01WTIOT      ADDR. OF TIOT                        14400020
         LA    TIOTR,TIOCLNGH(TIOTR) PLUS FIXED LEN. OF TIOT            14450020
         SR    CTR,CTR             ZERO COUNT REG.                      14500020
         SR    WR15,WR15           ZERO REGISTER FOR INDEXING           14550020
         USING TIOTD,TIOTR         TIOT                                 14600020
S1ML00   CLI   TIOELNGH,E0         END OF TIOT                          14650020
         BE    S1ML02              YES                                  14700020
         CLC   TIOEDDNM(E6),NSYSWAP  SWAP DATA SET??  'SYSWAP'          14750020
         BNE   S1ML01              NO                                   14800020
         LA    CTR,E1(CTR)         COUNT PLUS ONE                       14850020
S1ML01   IC    WR15,TIOELNGH       L' OF DD ENTRY                       14900020
         LA    TIOTR,E0(WR15,TIOTR)  ADDR. OF NEXT DD ENTRY IN TIOT     14950020
         B     S1ML00              TO TOP                               15000020
         EJECT                                                          15050020
*********************************************************************** 15100020
*COMPUTE THE SIZE OF AND OBTAIN THE DD TABLE.  COMPUTE SIZE FROM THE  * 15150020
*COUNT OF SWAP DATA SETS.                                             * 15200020
*********************************************************************** 15250020
S1ML02   LR    WR2,CTR             LOAD COUNT OF DATA SETS              15300020
         SLL   WR2,E3              TIMES EIGHT                          15350020
         ST    WR2,S01WDDTL        SAVE LENGTH IN S01 SAVE/WORK AREA    15400020
         LR    WR0,WR2       R0=LENGTH OF DD NAME TABLE.         A44022 15420021
         O     WR0,SP251     SUBPOOL 251.                        A44022 15440021
         GETMAIN R,LV=(0)                                        A44022 15460021
         ST    WR1,S01WDDTA        SAVE ADDR. IN S01 SAVE/WORK AREA     15500020
         BAL   TRANR,S1MSCLR       ZERO MAIN STORAGE WR1-ADDR. WR2-LEN. 15550020
         LR    WR14,WR1            ADDR. OF DD TABLE FOR S1DD200        15600020
*********************************************************************** 15650020
*DETERMINE THE SERIAL/PARALLEL STRUCTURE OF SWAP DATA SETS.  SCAN TIOT* 15700020
*FOR SWAP DATA SETS. ENTER 'LN' IN THE DD TABLE FOR EACH DATA SET     * 15750020
*********************************************************************** 15800020
         L     TIOTR,S01WTIOT      ADDR. OF FIRST DD ENTRY IN TIOT      15850020
         LA    TIOTR,TIOCLNGH(TIOTR)  PLUS LEN. FIXED PART TIOT         15900020
         SR    WR15,WR15           ZERO REGISTER FOR INDEXING           15950020
         LA    TRANR,S1ML04        SET RETURN                           16000020
         USING TIOTD,TIOTR         TIOT                                 16050020
S1ML03   CLI   TIOELNGH,E0         END OF TIOT                          16100020
         BE    S1ML05              YES                                  16150020
         CLC   TIOEDDNM(E6),NSYSWAP SWAP DATA SET  'SYSWAP'             16200020
         BE    S1DD100             YES                                  16250020
S1ML04   IC    WR15,TIOELNGH       L'DD ENTRY                           16300020
         LA    TIOTR,E0(WR15,TIOTR) ADDR. OF NEXT ENTRY                 16350020
         B     S1ML03              TO TOP                               16400020
         EJECT                                                          16450020
*********************************************************************** 16500020
*DDNAME TABLE CONTAINS 'LN' OF 'SYSWAPLN' FOR EACH SWAP DATA SET      * 16550020
*SCAN TABLE FOR ENTRIES. INVOKE S01MAIN TO INIT ONE SWAP DATA. RETURNS* 16600020
*ADDR. OF SWAPCB IN SWAPCBR. STORED OVER 'LN' IN DD TABLE.            * 16650020
*S01MAIN RETURNS TO S01MDONE                                          * 16700020
*********************************************************************** 16750020
S1ML05   LM    WR1,WR2,S01WDDTL    L' AND ADDR. OF DDNAME TABLE         16800020
         AR    WR1,WR2             WR1-STOPPER, WR2-ADDR. CURRENT       16850020
         STM   WR1,WR2,S01WDDCS    SAVE DD TABLE STOPPER AND CURRENT    16900020
         B     S1ML061             TO FIRST TIME SCAN                   16950020
*********************************************************************** 17000020
*SCAN DD TABLE FOR 'LN' OF SYSWAPLN                                   * 17050020
*********************************************************************** 17100020
S1ML06   LM    WR1,WR2,S01WDDCS    LOAD DD TABLE STOPPER AND CURRENT    17150020
S1ML061  CR    WR2,WR1             CURRENT EQ STOPPER                   17200020
         BE    S1ML10              END OF SCAN                          17250020
         LA    EPR,S1ML06          SET UP BRANCH TO TOP LOOP            17300020
         SR    WR0,WR0             ZERO                                 17350020
         C     WR0,E0(WR2)         ENTRY IN TABLE(LN00)                 17400020
         BE    S1ML07              NO, 'LN' ENTRY NOT IN TABLE          17450020
         LR    DDR,WR2             SET INPUT TO S01MAIN                 17500020
         LA    EPR,S01MAIN         SET UP BRANCH TO S01MAIN             17550020
S1ML07   LA    WR2,E4(WR2)         BUMP CURRENT TO NEXT ENTRY           17600020
         STM   WR1,WR2,S01WDDCS    SAVE DD TABLE STOPPER AND CURRENT    17650020
         BR    EPR                 TO S01MAIN  OR S1ML06                17700020
*********************************************************************** 17750020
*S01MAIN RETURNS HERE. STORE ADDR. SWAPCB(SWAPCBR) OVER 'LN'(DDR)     * 17800020
*********************************************************************** 17850020
S01MDONE EQU   *                   RETURN FROM S01MAIN                  17900020
S1ML09   ST    SWAPCBR,E0(DDR)     SAVE ADDR. OF SWAPCB IN DD TABLE     17950020
         B     S1ML06              TO TOP                               18000020
         EJECT                                                          18050020
*********************************************************************** 18100020
*DD TABLE CONTAINS THE ADDR. OF SWAPCB'S FOR ALL SWAP DATA SETS.      * 18150020
*SCAN THE DD TABLE AND BUILD THE CHAINED LIST OF SWAPCB'S.            * 18200020
*ADDR. OF NEXT LEVEL OR NEXT SERIAL SWAPCB AT SWAPCB -8               * 18250020
*ADDR. OF PARALLEL SWAPCB AT SWAPCB -4                                * 18300020
*********************************************************************** 18350020
S1ML10   LM    WR0,WR1,S01WDDTL    L' AND ADDR. OF DD TABLE             18400020
         AR    WR0,WR1             WR0-STOPPER, WR1-ADDR. OF CURRENT    18450020
         L     WR15,CVTPTR         ADDR. OF CVT                         18500020
         USING CVTDSECT,WR15       CVT                                  18550020
         L     WR15,CVTTSCVT       ADDR. OF TSCVT                       18600020
         USING TSCVT,WR15          TSCVT                                18650020
         L     WR3,E0(WR1)         ADDR. SWAPCB(L N = 0 0 )             18700020
         ST    WR3,TSCVTSDC        ADDR. OF LIST IS SWAPCB(L N = 0 0)   18750020
         DROP  WR15                TSCVT                                18800020
*                                  ADDR. OF SWAPCB'S                    18850020
S1ML11   LM    WR2,WR3,E0(WR1)     ADDR. SWAP CB(S) THIS LEVEL          18900020
         LTR   WR3,WR3             THIS LEVEL IN PARALLEL               18950020
         BP    S1ML12              YES, IT IS                           19000020
         LA    WR1,E8(WR1)         BUMP ADDR. DD TABLE TO NEXT LEVEL    19050020
         CR    WR0,WR1             STOPPER EQ CURRENT                   19100020
         BE    S1SMF               DONE, END OF TABLE                   19150020
         L     WR4,E0(WR1)         SERIAL SWAPCB THIS LEVEL             19200020
         S     WR2,NF8             LAST LEVEL ADDR. S AND P  POINTERS   19250020
         ST    WR4,E0(WR2)         THIS LEVEL TO LAST S POINTER         19300020
         B     S1ML11              TO TOP                               19350020
S1ML12   S     WR2,NF8             N = 0 ADDR. OF S AND P POINTERS      19400020
         S     WR3,NF8             N = 1 ADDR. OF S AND P POINTERS      19450020
         LM    WR4,WR5,E0(WR1)     ADDR. OF N = 0 AND N = 1 SWAPCB      19500020
         ST    WR4,E4(WR3)         N = 1 SWAPCB TO P OF N = 0           19550020
         ST    WR5,E4(WR2)         N = 0 SWAPCB TO P OF N = 1           19600020
         EJECT                                                          19650020
*********************************************************************** 19700020
*IF SMF IS ACTIVE, BUILD RECORD 38 AND ISSUE SMFWTM.                  * 19750020
*********************************************************************** 19800020
S1SMF    L     WR15,CVTPTR         ADDR. OF CVT                         19850020
         USING CVTDSECT,WR15       CVT                                  19900020
         L     WR1,CVTSMCA         ADDR. OF SMF CONTROL AREA            19950020
         DROP  WR15                CVT                                  20000020
         LTR   WR1,WR1             IS IT ZERO                           20050020
         BZ    S1RC                NO SMF                               20100020
         LA    WR5,SMF38EL         LENGTH SWAP DS ENTRY                 20150020
         MR    WR4,CTR             TIME NUMBER OF SWAP DS               20200020
         LA    WR4,SMF38L          LENGTH FIXED PART                    20250020
         AR    WR4,WR5             LENGTH OF RECORD                     20300020
         LR    WR0,WR4       R0=SMF RECORD LENGTH.               A44022 20320021
         O     WR0,SP251     SUBPOOL 251.                        A44022 20340021
         GETMAIN R,LV=(0)                                        A44022 20360021
         LR    WR2,WR1             SAVE ADDR. OF RECORD                 20400020
         USING SMFRD,WR2           SMF RECORD                           20450020
         XC    E0(SMF38L,WR2),E0(WR2)  ZERO FIXED PART                  20500020
         STH   WR4,SMFRL           RECORD LENGTH TO RECORD              20550020
         MVI   SMFRT,SMFRT38       RECORD TYPE TO RECORD                20600020
         AR    WR4,WR2             ADDR. END OF RECORD                  20650020
         LA    WR3,SMFLV           ADDR. OF VARIABLE LENGTH FIELD       20700020
         SR    WR4,WR3             LENGTH OF VARIABLE                   20750020
         STH   WR4,SMFLV           TO VARIABLE LENGTH FIELD             20800020
         STC   CTR,SMFNV           NUMBER OF SWAP DATA SETS             20850020
         LA    WR3,SMF38END        ADDR. OF FIRST SWAP DS ENTRY         20900020
         USING SMF38ED,WR3         SWAP DS ENTRY ENTRY                  20950020
         LM    WR4,WR5,S01WDDTL    L' AND ADDR. OF DD TABLE             21000020
         AR    WR4,WR5             WR4-STOPPER, WR5-ADDR. OF CURRENT    21050020
S1SMF00  CR    WR4,WR5             END OF DD TABLE                      21100020
         BE    S1SMF03             YES, DD TABLE SCAN IS DONE           21150020
         L     SWAPCBR,E0(WR5)     ADDR. OF SWAP CB                     21200020
         LTR   SWAPCBR,SWAPCBR     SWAP CB EXIST                        21250020
         BP    S1SMF02             YES, DATA TO SMF RECORD              21300020
S1SMF01  LA    WR5,E4(WR5)         NEXT ENTRY DD TABLE                  21350020
         B     S1SMF00             TO TOP OF DD SCAN                    21400020
         EJECT                                                          21450020
         USING SWAPCBD,SWAPCBR     SWAP CONTROL BLOCK                   21500020
S1SMF02  L     WR15,SB1DEBA        ADDR. OF DEB                         21550020
         DROP  SWAPCBR             SWAP CB                              21600020
         LA    WR15,DEBLNGH(WR15)  ADDR. DASD SECTION                   21650020
         USING DEBD,WR15           DEB                                  21700020
         L     UCBR,DEBUCBAD       ADDR OF UCB                          21750020
         DROP  WR15                DEB                                  21800020
         USING UCBD,UCBR           UCB                                  21850020
         MVC   SMF38EC(E1),UCBTDEVC  DEVICE CLASS(DASD)                 21900020
         MVC   SMF38ET(E1),UCBTDTYP  DEVICE TYPE(2311)                  21950020
         MVC   SMF38EA(E2),UCBCHA  DEVICE ADDRESS(190)                  22000020
         DROP  UCBR                UCB                                  22050020
         LA    WR3,SMF38EAN        ADDR. NEXT ENTRY SMF RECORD          22100020
         B     S1SMF01             NEXT ENTRY DD TABLE                  22150020
S1SMF03  SMFWTM  (WR2)             SMF WRITER(IGNORE RC'S)              22200020
         LH    WR0,SMFRL           LENGTH OF RECORD                     22250020
         O     WR0,SP251     SUBPOOL 251.                        A44022 22270021
         FREEMAIN  R,LV=(0),A=(WR2) FREE SMF RECORD                     22300020
         B     S1RC                RETURN ROUTINE                       22350020
         DROP  WR2,WR3             SMF RECORD FIXED, VARIABLE           22400020
*********************************************************************** 22450020
*S01 RETURN. RELEASE SAVE AREA AND RETURNS TO CALLER. RC WAS SET.    .* 22500020
*********************************************************************** 22550020
S1RC     SR    EPR,EPR             SET RC=0                             22600020
S1RTN    LR    WR2,EPR             SAVE RC ACROSS FREEMAIN              22650020
         LM    WR0,WR1,S01WDDTL    L' AND ADDR. OF DDNAME TABLE         22700020
         LTR   WR1,WR1             ADDR. EQ. ZERO                       22750020
         BZ    S1RTN01             YES, NEVER GOT THE TABLE             22800020
         O     WR0,SP251     SUBPOOL 251.                        A44022 22820021
         FREEMAIN R,LV=(0),A=(1)   FREE THE DDNAME TABLE                22850020
S1RTN01  LR    WR1,SAVER           ADDR. OF S00 SAVE                    22900020
         L     SAVER,E4(WR1)       RESTORE CALLER SAVE                  22950020
         LA    WR0,S01WL           L'S00 SAVE/WORK AREA                 23000020
         O     WR0,SP251     SUBPOOL 251.                        A44022 23020021
         FREEMAIN R,LV=(0),A=(1)   SAVE/WORK AREA                       23050020
         LR    EPR,WR2             RESTORE RETURN CODE                  23100020
         RETURN (14,12),RC=(15)    RESTORE CALLER'S REGISTERS           23150020
         EJECT                                                          23200020
*********************************************************************** 23250020
*SWAP DATA SET DDNAME  IS 'SYSWAPLN',  L IS LEVEL, N IS NUM. ON LEVEL.* 23300020
*********************************************************************** 23350020
S1DD100  SR    WR1,WR1             SET DISP IN DD TABLE FOR N=0         23400020
         CLI   TIOEDDN,C1          N=1, A PARALLEL DATA SET             23450020
         BNE   S1DD101             NO                                   23500020
         LA    WR1,E4              SET DISP IN DD TABLE FOR N=1         23550020
S1DD101  PACK  S01WPACK(E8),TIOEDDL(E1) PACK  L                         23600020
         CVB   WR2,S01WPACK        AND CONVERT TO BINARY                23650020
         SLL   WR2,E3              L TIMES EIGHT(TO LEVEL IN DD TABLE)  23700020
         AR    WR2,WR1             PLUS DISP AT L FOR N                 23750020
         LA    WR2,E0(WR2,WR14)    COMPUTE ADDR. IN TABLE               23800020
         MVC   E0(E2,WR2),TIOEDDL  MOVE 'LN' TO TABLE(LN00)             23850020
         BR    TRANR               DONE                                 23900020
         EJECT                                                          23950020
*********************************************************************** 24000020
*S01MAIN FOR ONE SWAP DATA SET.  COMPUTES SIZE OF AND GETMAIN FOR     * 24050020
*SWAPCB, SWAP UNIT ALLOCATION TABLE, CHANNEL PGM AREAS 'A' AND 'B',   * 24100020
*AND SWAP REQUEST TABLE.  TEST SWAP SWITCH IN PARM LIST TO DETERMINE  * 24150020
*FORMAT.  INPUT IS  DDR-ADDR. OF HALFWORD WITH 'LN' OF 'SYSWAPLN'.    * 24200020
*DESTROYS:  WR0  WR1  WR2  WR3  WR4  WR5  WR15  UCBR  TRANR           * 24250020
*WHEN DONE, BRANCHES TO S01MDONE WITH ADDR. OF SWAPCB IN SWAPCBR.     * 24300020
*IF ERROR, BRANCHES TO  S1MERR1.                                      * 24350020
*********************************************************************** 24400020
*COMPUTE SIZE OF AND GETMAIN STORAGE FOR SWAPCB.                      * 24450020
*********************************************************************** 24500020
S01MAIN  LH    WR2,S01SCBL         LEN. SWAP CONTROL BLOCK              24550020
         LA    WR2,E8(WR2)         PLUS SERIAL/PARALLEL POINTERS        24600020
         GETMAIN   R,LV=(WR2),SP=252 SWAPCB                             24650020
         BAL   TRANR,S1MSCLR       ZERO MAIN STORE  WR1-ADDR. WR2-LEN.  24700020
         LR    SWAPCBR,WR1         LOAD SWAPCB REG.                     24750020
         LA    SWAPCBR,E8(SWAPCBR) BUMP PAST  S/P POINTERS              24800020
         USING SWAPCBD,SWAPCBR     SWAPCB                               24850020
*********************************************************************** 24900020
*BUILD DCB AND OPEN THE SWAP DATA SET. OPEN FAILS WTO AND RTN, RC EQ 8* 24950020
*********************************************************************** 25000020
         MVC   SB1DCB(S01DCBL),S01DCB MOVE MODEL DCB TO SWAPCB          25050020
         MVC   SB1DDNM+E6(E2),E0(DDR) MOVE 'LN' TO DDNAME IN DCB        25100020
         MVC   SB3DDN(E8),SB1DDNM  SAVE DD NAME FOR LATER               25150020
         LA    WR1,S01WOLST        OPEN MACRO DYNAMIC PARM LIST         25200020
         MVC   E0(E4,WR1),S01OPLST MODEL OPEN PARM LIST TO DYNAMIC      25250020
         OPEN  ((SWAPCBR),OUTPUT),MF=(E,(1))  OPEN DCB                  25300020
         TM    SB1DCBOF,OPENFLAG   IS DCB OPEN                          25350020
         BZ    S1MERR1             TO S01 MAIN ERROR ONE                25400020
         EJECT                                                          25450020
*********************************************************************** 25500020
*USE DEB TO FIND UCB                                                  * 25550020
*********************************************************************** 25600020
         L     WR15,SB1DEBA        ADDR. OF DEB                         25650020
         LA    WR15,DEBLNGH(WR15)  PLUS LEN. BASIC SECTION              25700020
         USING DEBD,WR15           DEB                                  25750020
         SPACE 2                                                        25850020
         L     UCBR,DEBUCBAD       ADDR. OF UCB                         25900020
         USING UCBD,UCBR           UCB                                  25950020
         CLI   UCBTDTYP,DEV2311    SWAP DS ON 2311                      26000020
         BE    S1M2311             YES                                  26050020
         CLI   UCBTDTYP,DEV2314    SWAP DS ON 2314                      26100020
         BE    S1M2314             YES                                  26150020
         CLI   UCBTDTYP,DEV2301    SWAP DS ON 2301                      26200020
         BE    S1M2301             YES                                  26250020
         CLI   UCBTDTYP,DEV2303    SWAP DS ON 2303                      26300020
         BE    S1M2303             YES                                  26350020
         CLI   UCBTDTYP,DEV23051   DEVICE 2305 MODEL 1            20201 26357020
         BE    S1M23051            YES                            20201 26364020
         CLI   UCBTDTYP,DEV23052   DEVICE 2305 MODEL 2            20201 26371020
         BE    S1M23052            YES                            20201 26378020
         CLI   UCBTDTYP,DEV3330    DEVICE 3330                    20201 26385020
         BE    S1M3330             YES                            20201 26392020
*                                  IKJEAS00 ALLOWED INVALID DEVICE      26400020
         LA    EPR,E8              SET RETURN CODE TO 8                 26450020
         B     S1RTN               TO RETURN                            26500020
         EJECT                                                          26520020
*********************************************************************** 26550020
*PER DEVICE TYPE ASSOCIATED WITH SWAP DATA SET.                       * 26600020
*MOVE SWAP UNIT CPACITY(BYTES) AND DEVICE INDEX TO SWAPCB             * 26650020
*COMPUTE SIZE AND OBTAIN CHANNEL PROGRAM AREAS 'A' AND 'B' AND        * 26700020
*INITIALIZE SWAPCB FOR CHANNEL PROGRAM AREAS.                         * 26750020
*COMPUTE SIZE OF SWAP UNIT ALLOCATION TABLE.  HALF WORD PER SWAP UNIT * 26800020
*FOR     2311  UNIT IS CYLINER(10 TRKS)                               * 26850020
*        2314  UNIT IS HALF-CYLINDER(10 TRKS)                         * 26900020
*        2301  UNIT IS TRACK                                          * 26950020
*        2303  UNIT IS FOUR TRACKS                                    * 27000020
*        2305  MODEL 1  UNIT IS FOUR TRACKS                      20201* 27010020
*        2305  MODEL 2  UNIT IS FOUR TRACKS                      20201* 27020020
*        3330  UNIT IS THREE TRACKS                              20201* 27030020
*OBTAIN AND INITIALIZE SWAP UNIT ALLOCATION TABLE.                    * 27050020
*********************************************************************** 27100020
         EJECT                                                          27150020
         USING CHANPGM,WR1         CHANNEL PROGRAM AREAS                27200020
S1M2311  MVC   SB3CAPB(E4),CAP2311B UNIT CAPACITY(BYTES) TO SWAPCB      27250020
         TM    DEBDVMOD,CYLBOUND        ALLOC. IN CYLINDERS      M0049  27260020
         BO    S1MERR1                  NO-ERROR                 M0049  27270020
         MVI   DEBDVMOD,DEVFALL         SET FILE MASK           2-M3046 27280020
         MVI   SB3DEVI+E3,SB32311  DEVICE INDEX TO SWAPCB               27300020
         LH    WR5,DEBENDCC        CYL END                              27350020
         SH    WR5,DEBSTRCC        MINUS CYL START  PLUS ONE            27400020
         LA    WR5,E1(WR5)         EQUALS CYLS ALLOCATED(SWAP UNIT)     27450020
         ST    WR5,SB3GRCT         AND IS GROSS COUNT SWAP UNITS        27500020
         LH    WR2,CP2311L         SIZE ONE 2311 CHANNEL PROGRAM        27550020
         GETMAIN  R,LV=(WR2),SP=252  CHANNEL PROGRAM AREA               27600020
*                                  PROGRAM AREA 'A'                     27650020
         BAL   TRANR,S1MCPA        TO SET UP CP 'A' COMMON              27700020
         LA    WR2,CPSBUF11        MBBCCHHR BUFFERS                     27750020
         ST    WR2,SB5ABUFF        TO SWAPCB                            27800020
         LH    WR2,CP2311L         SIZE ONE 2311 CHANNEL PROGRAM        27850020
         GETMAIN  R,LV=(WR2),SP=252  CHANNEL PROGRAM AREA               27900020
*                                  PROGRAM AREA 'B'                     27950020
         BAL   TRANR,S1MCPB        TO SET UP CP 'B' COMMON              28000020
         LA    WR2,CPSBUF11        MBBCCHHR BUFFERS                     28050020
         ST    WR2,SB5BBUFF        TO SWAP CB                           28100020
         B     S1M01               TO NEXT                              28150020
         EJECT                                                          28200020
S1M2314  MVC   SB3CAPB(E4),CAP2314B UNIT CAPACITY(BYTES) TO SWAPCB      28250020
         TM     DEBDVMOD,CYLBOUND       ALLOC. IN CYLINDERS      M0049  28260020
         BO    S1MERR1                  N0-ERROR                 M0049  28270020
         MVI   DEBDVMOD,DEVFALL         SET FILE MASK           2-M3046 28280020
         MVI   SB3DEVI+E3,SB32314  DEVICE INDEX TO SWAPCB               28300020
         LH    WR5,DEBENDCC        CYL END                              28350020
         SH    WR5,DEBSTRCC        MINUS CYL START PLUS ONE             28400020
         LA    WR5,E1(WR5)         EQUALS CYLS ALLOCATED                28450020
         SLL   WR5,E1              CONVERT CYLS TO HALF CYLS(SWAP UNIT) 28500020
         ST    WR5,SB3GRCT         AND IS GROSS COUNT SWAP UNITS        28550020
         LH    WR2,CP2314L         SIZE ONE 2314 CHANNEL PROGRAM        28600020
         GETMAIN  R,LV=(WR2),SP=252  CHANNEL PROGRAM AREA               28650020
*                                  PROGRAM AREA 'A'                     28700020
         BAL   TRANR,S1MCPA        TO SET UP CP 'A' COMMON              28750020
         LA    WR2,CPSBUF14        MBBCCHHR BUFFERS                     28800020
         ST    WR2,SB5ABUFF        TO SWAPCB                            28850020
         LH    WR2,CP2314L         SIZE ONE 2314 CHANNEL PROGRAM        28900020
         GETMAIN  R,LV=(WR2),SP=252  CHANNEL PROGRAM AREA               28950020
*                                  PROGRAM AREA 'B'                     29000020
         BAL   TRANR,S1MCPB        TO SET UP CP 'B' COMMON              29050020
         LA    WR2,CPSBUF14        MBBCCHHR BUFFERS                     29100020
         ST    WR2,SB5BBUFF        TO SWAP CB                           29150020
         B     S1M01               TO NEXT                              29200020
         EJECT                                                       -  29250020
S1M2301  MVC   SB3CAPB(E4),CAP2301B UNIT CAPACITY(BYTES) TO SWAPCB      29300020
         MVI   SB3DEVI+E3,SB32301  DEVICE INDEX TO SWAPCB               29350020
         MVI   DEBDVMOD,DEVFALL         SET FILE MASK           2-M3046 29370020
         LH    WR5,DEBTRKS         NUMBER OF ALLOCATED TRACKS           29400020
         ST    WR5,SB3GRCT         AND IS GROSS COUNT SWAP UNITS        29450020
         LH    WR2,CP2301L         SIZE ONE 2301 CHANNEL PROGRAM        29500020
         GETMAIN  R,LV=(WR2),SP=252  CHANNEL PROGRAM AREA               29550020
*                                  PROGRAM AREA 'A'                     29600020
         BAL   TRANR,S1MCPA        TO SET UP CP 'A' COMMON              29650020
         LA    WR2,CPSBUF01        MBBCCHHR BUFFERS                     29700020
         ST    WR2,SB5ABUFF        TO SWAPCB                            29750020
         LH    WR2,CP2301L         SIZE ONE 2301 CHANNEL PROGRAM        29800020
         GETMAIN  R,LV=(WR2),SP=252  CHANNEL PROGRAM AREA               29850020
*                                  PROGRAM AREA 'B'                     29900020
         BAL   TRANR,S1MCPB        TO SET UP CP 'B' COMMON              29950020
         LA    WR2,CPSBUF01        MBBCCHHR BUFFERS                     30000020
         ST    WR2,SB5BBUFF        TO SWAP CB                           30050020
         B     S1M01               TO NEXT                              30100020
         EJECT                                                          30150020
S1M2303  MVC   SB3CAPB(E4),CAP2303B UNIT CAPACITY(BYTES) TO SWAPCB      30200020
         MVI   SB3DEVI+E3,SB32303  DEVICE INDEX TO SWAPCB               30250020
         TM    DEBDVMOD,CYLBOUND        ALLOC. IN CYLINDERS     2-M0049 30260020
         BO    S1MERR1                  NO-ERROR                2-M0049 30270020
         MVI   DEBDVMOD,DEVF2303   SET FILE MASK 2303           2-M3046 30300020
         LH    WR5,DEBTRKS         NUMBER OF ALLOCATED TRACKS           30350020
         SRL   WR5,E2              DIV BY FOUR(SWAP UNITS)              30400020
         ST    WR5,SB3GRCT         AND IS GROSS COUNT SWAP UNITS        30450020
         LH    WR2,CP2303L         SIZE ONE 2303 CHANNEL PROGRAM        30500020
         GETMAIN  R,LV=(WR2),SP=252  CHANNEL PROGRAM AREA               30550020
*                                  PROGRAM AREA 'A'                     30600020
         BAL   TRANR,S1MCPA        TO SET UP CP 'A' COMMON              30650020
         LA    WR2,CPSBUF03        MBBCCHHR BUFFERS                     30700020
         ST    WR2,SB5ABUFF        TO SWAPCB                            30750020
         LH    WR2,CP2303L         SIZE ONE 2303 CHANNEL PROGRAM AREA   30800020
         GETMAIN  R,LV=(WR2),SP=252  CHANNEL PROGRAM AREA               30850020
*                                  PROGRAM AREA 'B'                     30900020
         BAL   TRANR,S1MCPB        TO SET UP CP 'B' COMMON              30950020
         LA    WR2,CPSBUF03        MBBCCHHR BUFFERS                     31000020
         ST    WR2,SB5BBUFF        TO SWAP CB                           31050020
         B     S1M01               TO NEXT                              31100020
*                                  2305 MODEL 1                   20201 31103020
S1M23051 MVC   SB3CAPB(E4),CAP23051 UNIT CAPACTY(BYTES) TO SWAPCB 20201 31106020
         TM    DEBDVMOD,CYLBOUND        ALLOC. IN CYLINDERS     2-M0049 31106220
         BO    S1MERR1                  NO-ERROR                2-M0049 31106420
         MVI   DEBDVMOD,DEVFALL         SET FILE MASK           2-M3046 31106620
         MVI   SB3DEVI+E3,SB323051 DEVICE INDEX TO SWAPCB         20201 31109020
         LH    WR5,DEBTRKS         NUMBER OF ALLOCATED TRACKS     20201 31112020
         SRL   WR5,E2              DIV BY FOUR(SWAP UNITS)        20201 31115020
         ST    WR5,SB3GRCT         AND IS GROSS COUNT SWAP UNITS  20201 31118020
         LH    WR2,CP23051L    SIZE ONE 2305 CHANNEL PROGRAM AREA 20201 31121020
         GETMAIN  R,LV=(WR2),SP=252 CHANNEL PROGRAM AREAS         20201 31124020
*                                  PROGRAM AREA 'A'               20201 31127020
         BAL   TRANR,S1MCPA        TO SET UP CP 'A' COMMON        20201 31130020
         LA    WR2,CPSBF051        MBBCCHHR BUFFERS               20201 31133020
         ST    WR2,SB5ABUFF        TO SWAPCB                      20201 31136020
         LH    WR2,CP23051L    SIZE ONE 2305 CHANNEL PROGRAM AREA 20201 31139020
         GETMAIN  R,LV=(WR2),SP=252 CHANNEL PROGRAM AREAS         20201 31141020
*                                  PROGRAM AREA 'B'               20201 31143020
         BAL   TRANR,S1MCPB        TO SET UP CP 'B' COMMON        20201 31145020
         LA    WR2,CPSBF051        MBBCCHHR BUFFERS               20201 31147020
         ST    WR2,SB5BBUFF        TO SWAP CB                     20201 31149020
         B     S1M01               TO NEXT                        20201 31151020
*                                  2305 MODEL 2                   20201 31153020
S1M23052 MVC   SB3CAPB(E4),CAP23052 UNIT CAPACTY(BYTES) TO SWAPCB 20201 31155020
         TM    DEBDVMOD,CYLBOUND        ALLOC. IN CYLINDERS     2-M0049 31155120
         BO    S1MERR1                  NO-ERROR                2-M0049 31155220
         MVI   DEBDVMOD,DEVFALL         SET FILE MASK           2-M3046 31155320
         MVI   SB3DEVI+E3,SB323052 DEVICE INDEX TO SWAPCB         20201 31157020
         LH    WR5,DEBTRKS         NUMBER OF ALLOCATED TRACKS     20201 31159020
         SRL   WR5,E2              DIV BY FOUR(SWAP UNITS)        20201 31161020
         ST    WR5,SB3GRCT         AND IS GROSS COUNT SWAP UNITS  20201 31163020
         LH    WR2,CP23052L    SIZE ONE 2305 CHANNEL PROGRAM AREA 20201 31165020
         GETMAIN  R,LV=(WR2),SP=252 CHANNEL PROGRAM AREAS         20201 31167020
*                                  PROGRAM AREA 'A'               20201 31169020
         BAL   TRANR,S1MCPA        TO SET UP CP 'A' COMMON        20201 31171020
         LA    WR2,CPSBF052        MBBCCHHR BUFFERS               20201 31173020
         ST    WR2,SB5ABUFF        TO SWAPCB                      20201 31175020
         LH    WR2,CP23052L  SIZE ONE 2305 CHAN. PGM. AREA M5498  20201 31177420
         GETMAIN  R,LV=(WR2),SP=252 CHANNEL PROGRAM AREAS         20201 31179020
*                                  PROGRAM AREA 'B'               20201 31181020
         BAL   TRANR,S1MCPB        TO SET UP CP 'B' COMMON        20201 31183020
         LA    WR2,CPSBF052        MBBCCHHR BUFFERS               20201 31185020
         ST    WR2,SB5BBUFF        TO SWAP CB                     20201 31187020
         B     S1M01               TO NEXT                        20201 31189020
*                                  3330                           20201 31191020
S1M3330  MVC   SB3CAPB(E4),CAP3330B UNIT CAPACTY(BYTES) TO SWAPCB 20201 31193020
         TM    DEBDVMOD,CYLBOUND        ALLOC. IN CYLINDERS      M0049  31193420
         BO    S1MERR1                  NO-ERROR                 M0049  31193820
         MVI   DEBDVMOD,DEVFALL         SET FILE MASK           2-M3046 31194420
         MVI   SB3DEVI+E3,SB33330  DEVICE INDEX TO SWAPCB         20201 31195020
         LH    WR5,DEBTRKS         NUMBER OF ALLOCATED TRACKS     20201 31197020
         SR    WR4,WR4             CLEAR REG 4                    20201 31199020
         D     WR4,NF3             DIV BY THREE(SWAP UNITS)       20201 31201020
         LR    WR2,WR5       SAVE FIRST CALCULATION              A44022 31201621
         SR    WR4,WR4       ZERO FOR DIVIDE                     A44022 31202221
         D     WR4,NF19      CALCULATE NO. OF EXTRA SWAP UNITS   A44022 31202821
         SR    WR2,WR5       SUBTRACT UNUSABLE FROM TOTAL        A44022 31203421
         ST    WR2,SB3GRCT   STORE IN GROSS COUNT SWAP UNITS     A44022 31204021
         LH    WR2,CP3330L     SIZE ONE 3330 CHANNEL PROGRAM AREA 20201 31205020
         GETMAIN  R,LV=(WR2),SP=252 CHANNEL PROGRAM AREAS         20201 31207020
*                                  PROGRAM AREA 'A'               20201 31209020
         BAL   TRANR,S1MCPA        TO SET UP CP 'A' COMMON        20201 31211020
         LA    WR2,CPSBF30         MBBCCHHR BUFFERS               20201 31213020
         ST    WR2,SB5ABUFF        TO SWAPCB                      20201 31215020
         LH    WR2,CP3330L     SIZE ONE 3330 CHANNEL PROGRAM AREA 20201 31217020
         GETMAIN  R,LV=(WR2),SP=252 CHANNEL PROGRAM AREAS         20201 31219020
*                                  PROGRAM AREA 'B'               20201 31221020
         BAL   TRANR,S1MCPB        TO SET UP CP 'B' COMMON        20201 31223020
         LA    WR2,CPSBF30         MBBCCHHR BUFFERS               20201 31225020
         ST    WR2,SB5BBUFF        TO SWAP CB                     20201 31227020
         B     S1M01               TO NEXT                        20201 31229020
         EJECT                                                          31231020
*********************************************************************** 31233020
*COMMON ROUTINES TO SET UP CP 'A' AND 'B' FOR ALL SWAP DEVICES        * 31250020
*********************************************************************** 31300020
S1MCPA   ST    WR1,SB5ASEEK        ADDR. OF 'A'                         31350020
         LA    WR3,SB5ASEEK        ADDR. OF CP 'A' ADDRESS              31400020
         ST    WR3,SB5NEXT         AND MAKE IT 'NEXT                    31450020
         LA    WR2,CPRCCW          START READ CCW'S                     31500020
         ST    WR2,SB5AREAD        TO SWAPCB                            31550020
         LA    WR2,CPWCCW          START WRITE CCW'S                    31600020
         ST    WR2,SB5AWRIT        TO SWAPCB                            31650020
         BR    TRANR               RETURN                               31700020
S1MCPB   ST    WR1,SB5BSEEK        ADDR. OF 'B'                         31750020
         LA    WR3,SB5BSEEK        ADDR. OF CP 'B' ADDRESS              31800020
         ST    WR3,SB5INUSE        AND MAKE IT 'IN USE'                 31850020
         LA    WR2,CPRCCW          START READ CCW'S                     31900020
         ST    WR2,SB5BREAD        TO SWAPCB                            31950020
         LA    WR2,CPWCCW          START WRITE CCW'S                    32000020
         ST    WR2,SB5BWRIT        TO SWAPCB                            32050020
         BR    TRANR               RETURN                               32100020
         DROP  WR1,WR15            CHANPGM  DEB                         32150020
         EJECT                                                          32200020
*********************************************************************** 32250020
*GETMAIN FOR UNIT ALLOCATION TABLE                                    * 32300020
*********************************************************************** 32350020
S1M01    L     WR2,SB3GRCT         GROSS COUNT OF UNITS                 32400020
         SLL   WR2,E1              UNITS TIME HALFWORD PER UNIT         32450020
         GETMAIN R,LV=(WR2),SP=252 ALLOCATION TABLE                     32500020
         BAL   TRANR,S1MSCLR       ZERO MAIN STORE  WR1-ADDR. WR2-LEN.  32550020
         ST    WR1,SB3UTSTR        START TABLE                          32600020
         ST    WR1,SB3UTCUR        SET TABLE CURRENT TO START TABLE     32650020
         LA    WR2,E0(WR2,WR1)     START PLUS LEN. EQ END               32700020
         ST    WR2,SB3UTSTP        END   TABLE                          32750020
*********************************************************************** 32800020
*LOOP SWAP ALLOCATION TABLE TO MARK UNITS AS AVAILABLE                * 32850020
*********************************************************************** 32900020
S1M02    CR    WR1,WR2             START TO END                         32950020
         BNL   S1M03               OUT                                  33000020
         MVI   E0(WR1),SB3UTAV     UNIT AVAILABLE                       33050020
         LA    WR1,E2(WR1)         BUMP ADDR. BY TWO PER UNIT           33100020
         B     S1M02               TO TOP                               33150020
*********************************************************************** 33200020
*COMPUTE SIZE OF AND GET MAIN STORAGE FOR SWAP REQUEST TABLE          * 33250020
*********************************************************************** 33300020
S1M03    LH    WR2,PREGION(PARMR)  NUMBER OF REGIONS                    33350020
         MH    WR2,S01SRQEL        TIMES LENGTH OF ONE REQUEST          33400020
         GETMAIN R,LV=(WR2),SP=252 REQUEST TABLE                        33450020
         BAL   TRANR,S1MSCLR       ZERO MAIN STORE WR1-ADDR. WR2-LEN.   33500020
         ST    WR1,SB4RSTR         ADDR. OF FIRST  ENTRY                33550020
         AR    WR2,WR1             START PLUS LENGTH EQUAL              33600020
         ST    WR2,SB4REND         ADDR. OF END OF THE TABLE            33650020
*********************************************************************** 33700020
*TEST SWAP SWITCH IN PARM LIST TO DETERMINE IF FORMAT IS REQUIRED     * 33750020
*IF  X'FF' FORMAT ALL SWAP DATA SETS, LINK TO IKJEAS03                * 33800020
*********************************************************************** 33850020
         CLI   PSWITCH(PARMR),PSWALL  FORMAT ALL                        33900020
         BE    S1M05               YES                                  33950020
         EJECT                                                          34000020
*********************************************************************** 34050020
*BEFORE CHECKING OTHER SETTINGS, READ CHECK A SWAP UNIT TO DETERMINE  * 34100020
*IF DATA SET IS FORMATTED.  USE CHAN PGM AREA 'A' TO SET UP READ WITH * 34150020
*DATA TRANSFER SUPPRESSED.  SET UP SEARCH TIC*-8                      * 34200020
*********************************************************************** 34250020
         L     WR1,SB5ASEEK        ADDR. OF CHAN. PGM AREA              34300020
         L     WR3,SB3CAPB         CAPACITY UNIT IN BYTES               34350020
         SRL   WR3,S2048           DIV BY 2048 EQ NUM. OF RECORDS       34400020
         MVC   E0(E8,WR1),SIDEQCCW MOVE SEARCH                          34450020
         LA    WR2,SB2SEEK+E3      ADDR. OF CCHHR                       34500020
         ST    WR2,E0(WR1)         TO CCW                               34550020
         MVI   E0(WR1),SIDEQ       RESET OP CODE                        34600020
         LR    WR2,WR1             SAVE ADDR. OF SIDEQ                  34650020
         LA    WR1,E8(WR1)         BUMP TO ADDR. OF TIC                 34700020
         MVC   E0(E8,WR1),TICCCW   MOVE TIC                             34750020
         ST    WR2,E0(WR1)         ADDR. OF SEARCH TO TIC               34800020
         MVI   E0(WR1),TIC         RESET OP CODE                        34850020
         LA    WR1,E8(WR1)         BUMP TO FIRST READ                   34900020
*********************************************************************** 34950020
*SET UP READ WITH SKIP                                                  35000020
*WR1-ADDR. OF CCW WR2-ADDR. OF READ BUFFER  WR3-COUNT OF READ CCW'S  *  35050020
*********************************************************************** 35100020
         L     WR2,SB5ABUFF        USE MBBCCHHR BUFFER ADDR. IN READS   35150020
S1M04    MVC   E0(E8,WR1),READCCW  MOVE SKELTON                         35200020
         ST    WR2,E0(WR1)         DATA ADDR.                           35250020
         MVI   E0(WR1),READD+MT    RESET OP CODE                        35300020
         LA    WR1,E8(WR1)         BUMP TO NEXT CCW ADDR                35350020
         BCT   WR3,S1M04           TO TOP                               35400020
         MVC   E0(E8,WR1),NOPCCW   NOP CCW TO END CHANNEL PGM           35450020
*********************************************************************** 35500020
*SET UP THE IOB                                                       * 35550020
*********************************************************************** 35600020
         XC    SB2IOB(E32),SB2IOB  ZERO IOB                             35650020
         ST    SWAPCBR,SB2DCBA     ADDR. OF DCB TO IOB                  35700020
         LA    WR1,SB2ECB          ADDR. OF ECB                         35750020
         ST    WR1,SB2ECBA         TO IOB                               35800020
         MVI   SB2ECB,E0           CLEAR ECB WAIT/POST                  35850020
         L     WR1,SB5ASEEK        ADDR. OF CHAN PGM                    35900020
         ST    WR1,SB2STRA         TO IOB                               35950020
         MVI   SB2FLG1,SB2CCUR     SET FLAG 1 CC, UNRELATED             36000020
         EJECT                                                          36050020
*********************************************************************** 36100020
*DERIVE MBBCCHHR FOR FIRST SWAP UNIT                                  * 36150020
*IISUE EXCP AND WAIT FOR I/O TO COMPLETE                              * 36200020
*********************************************************************** 36250020
         L     WR0,CTTRN           SET TTRN TO 00 00 01 00              36300020
         L     WR1,SB1DEBA         ADDR. OF DEB                         36350020
         LA    WR2,SB2SEEK         ADDR. OF MBBCCHHR(SEEK BUFFER)       36400020
         BAL   TRANR,S1MCONV       TO TO TTRN TO MBBCCHHR CONVERT RTN   36450020
         LA    WR1,SB2IOB          ADDR. OF IOB                         36500020
         EXCP  (1)                 EXECUTE CHANNEL PROGRAM              36550020
         LA    WR1,SB2ECB          ADDR. OF ECB                         36600020
         WAIT  1,ECB=(1)           WAIT FOR CHANNEL PGM                 36650020
         CLI   SB2ECB,ECB7F        I/O COMPLETE NORMALLY                36700020
         BNE   S1M05               TO FORMAT, I/O IS UNSUCCESSFUL       36750020
*********************************************************************** 36800020
*TEST SWAP SWITCH NO FORMAT,  FORMAT PER OPERATOR                       36850020
*********************************************************************** 36900020
         CLI   PSWITCH(PARMR),PSWNONE   NO FORMAT                       36950020
         BE    S1M06                                                    37000020
*********************************************************************** 37050020
*ISSUE FORMAT SWAP DATA SET WTOR                                      * 37100020
*********************************************************************** 37150020
ZWTOR    EQU   *                                                  M4980 37160020
         LA    WR1,S01WWTO         ADDR. OF WTO/WTOR BUFFER             37200020
         MVC   E0(S1MSG2L,WR1),S1MSG2  MOVE MESSAGE TO BUFFER           37250020
         MVC   S1MSG2X(E8,WR1),SB3DDN  MOVE DD NAME TO MESSAGE          37300020
         LA    WR2,E4              LENGTH OF REPLY                      37350020
         LA    WR3,S01WRPLY        ADDR. OF REPLY                       37400020
         MVC   E0(E4,WR3),FBLANK   BLANK REPLY BUFFER                   37450020
         LA    WR4,S01WECB         ADDR. OF ECB                         37500020
         MVI   E0(WR4),E0          CLEAR ECB                            37550020
         SR    WR0,WR0             ZERO                                 37600020
         IC    WR0,PSCONID(PARMR)  CONSOLE ID FROM PARM LIST            37650020
         WTOR  ,(WR3),(WR2),(WR4),MF=(E,(1))  ISSUE WTOR                37700020
         WAIT  1,ECB=(WR4)         WAIT FOR REPLY                       37750020
         OC    E0(E4,WR3),FBLANK   UPPER CASE REPLY                     37800020
         CLC   E0(E3,WR3),RYES     REPLY IS YES                         37850020
         BE    S1M05                     YES-BR TO SWAP FORMAT    M4980 37900020
         CLC   E0(E2,WR3),RNO            NOT YES=CHECK FOR NO     M4980 37910020
         BE    S1M06                    NO-GO TO             M4980,5430 37920020
          B    ZWTOR                     INVALID REPLY-REISSUE WTOR     37930020
         EJECT                                                          37950020
*********************************************************************** 38000020
*TO SWAP FORMAT(IKJEAS03).  WR1 - ADDR. OF PARM LIST.                 * 38050020
*********************************************************************** 38100020
S1M05    LA    WR1,S01W3PL         ADDR. OF PARM LIST TO IKJEAS03       38150020
         ST    SWAPCBR,S01W3PL1    ADDR SWAP CB TO PARM LIST            38200020
         SR    WR0,WR0             ZERO                                 38250020
         IC    WR0,PSCONID(PARMR)  CONSOLE ID FROM PARM LIST            38300020
         ST    WR0,S01W3PL2        CONSOLE ID TO PARM LIST              38350020
         LINK  EPLOC=S03NAME       TO SWAP FORMAT(IKJEAS03)             38400020
**********************************************************************  38400620
*TO CHECK FOR ALTERNARE TRACK-MARK SWAP UNIT NOT AVAIL. IF FOUND  M5430 38401220
**********************************************************************  38401820
S1M06    EQU   *                                                  M5430 38402420
         SR    WR3,WR3                  CLEAR TTRN REG                  38403020
         SR    RTNR,RTNR           CLEAR COUNTER REG                    38403620
         XC    SB2IOB(E32),SB2IOB  CLEAR IOB                            38404220
         ST    SWAPCBR,SB2DCBA     ADDR OF DCB TO ION                   38404820
         LA    WR1,SB2ECB          ADDR OF ECB                          38405420
         ST    WR1,SB2ECBA         TO IOB                               38406020
         L     WR1,SB5ASEEK        ADDR OF CHAN PGM (PGM 'A' AREA)      38406620
         ST    WR1,SB2STRA         TO IOB                               38407220
         MVI   SB2FLG1,CCR         SET LAG 1 CC, RELATED                38407820
         L      WR1,SB3UTCUR             CURRENT UNIT PTR. FIRST PASS   38408220
S1MRHA03 LR    WR0,WR3             TTRN TO REG 0                        38408420
         CLI   SB3DEVI+E3,SB33330 Q. SWAP DEVICE= 3330           A44022 38408521
         BE    S1MRHA33            YES                           A44022 38408621
S1MRHA99 TM    E0(WR1),MT    Q. SWAP UNIT ALREADY NOT AVAIL      A44022 38408721
         BZ    S1MCHA04                   YES-TO NEXT SWAP UNIT         38408920
S1MRHA34 LA    WR2,SB2SEEK              ADDR OF MBBCCHHR (SEEK BUFFER)  38419620
         L     WR1,SB1DEBA         ADDR OF DEB                          38420820
         BAL   TRANR,S1MCONV       TO TTRN CONVERT ROUTINE              38422020
SIMRHA01 L     WR1,SB5ASEEK             ADDR OF CHANNEL PROG            38423220
         L     UCBR,SB3DEVI        DEVICE INDEX                         38424420
         L     UCBR,S01TRKTZ(UCBR) PICKUP NO. OF TRACKS PER UNIT        38425620
         L     WR2,SB5ABUFF        ADDR OF AREA TO READ HOME ADDR INTO  38426820
         L     TRANR,SB5BSEEK      CP 'B' AREA FOR SEEK  HEAD BUFFERS   38428020
         L     WR15,SB2SEEK+E4     'CHHR' PORTION OF SEEK ADDR          38429220
S1MRHA02 MVC   E0(E8,WR1),SEEKCCW  SEEK HEAD CCW FOR ORIENTATION        38430420
         MVC   E0(E4,TRANR),SB2SEEK MOVE FIRST HALF OF SEEK ADDR FROM   38431620
*                                  IOB TO BUFFER AREA                   38432820
         ST    WR15,E4(TRANR)      SECOND HALF OF SEEK ADDR TO BUFFER   38434020
         CLI   SB3DEVI+3,SB32303  Q IS DEVICE 2303           AE A54053  38434421
         BNE   S1MRHA04      NO BRANCH AROUND 2303 TEST      AE A54053  38434821
         CLI   E6(TRANR),TRACK10 Q TRACK 10 WHICH IS INVALID AE A54053  38434921
         BE    UPCYL         YES INVALID TRACK GO UP CYL     AE A54053  38435021
S1MRHA04 EQU   *   THIS EQUATE AND ENDUPCYL MUST BE TOGETHER AE A54053  38435121
ENDUPCYL EQU   *   THIS EQUATE AND S1MRHA04 MUST BE TOGETHER AE A54053  38437021
         AL    WR15,CTTRN          USE CTTRN '00 00 01 00' TO INCREMENT 38441721
*                                  HEAD NO. BY ONE                      38443621
         LA    TRANR,E1(TRANR)     ADDR OF SEEK ADDR                    38445521
         ST    TRANR,E0(WR1)       TO SEEK HEAD CCW                     38447421
         OI    E0(WR1),SEEKHD      RESET OP CODE                        38449321
         LA    TRANR,E7(TRANR)          TO NEXT BUFFER FOR SEEK HEAD    38451221
         LA    WR1,E8(WR1)         TO NEXT CCW                          38453121
         MVC   E0(E8,WR1),RHACCW   MOVE READ HOME ADDRESS CCW TO CP     38455021
         ST    WR2,E0(WR1)         TO READ HOME ADDRESS CCW             38456921
         OI    E0(WR1),RHA         RESTT OP CODE                        38458821
         LA    WR1,E8(WR1)         BUMP TO NEXT CCW                     38460721
         LA    WR2,E4(WR2)         BUMP TO NEXT DATA AREA               38462621
         BCT   UCBR,S1MRHA02       MORE TRACKS THIS UNIT, TO TOP        38464521
         MVC   E0(E8,WR1),NOPCCW   NO-NOP CHANNEL PROG                  38466421
         ST    WR2,E0(WR1)         ADDR TO NOOP CCW                     38468321
         OI    E0(WR1),NOP         RESET OP CODE                        38470221
         LA    WR1,SB2IOB          ADDR OF IOB                          38472121
         MVI   SB2ECB,E0           CLEAR ECB WAIT/POST                  38474021
         EXCP  (1)                 EXECUTE CHANNTL PROGRAN              38475921
         LA    WR1,SB2ECB          ADDR OF ECB                          38477821
         WAIT  1,ECB=(1)           WAIT FRO CHANNEL PROG TO COMPLETE    38479721
         CLI   SB2ECB,ECB7F        I/O COMPLETE NORMALLY                38481621
         BNE   S1MCHA01            NO MARK UNIT NOT AVAILABLE           38483521
         L     UCBR,SB3DEVI        DEVICE INDEX                         38485421
         L     UCBR,S01TRKTZ(UCBR) PICKUP NO. OF TRACKS PER UNIT        38487321
         L     WR2,SB5ABUFF             ADDR. OF HOME ADDRESS           38489221
S1MCHA03 TM    E0(WR2),PRIMOPER    IS TRACK PRIMARY OPERATIME           38491121
         BZ    S1MCHA02            YES                                  38493021
S1MCHA01 L     WR1,SB3UTCUR             CURRENT TNIT POINTER            38494921
         MVI   E0(WR1),ALTTRACK   TURN OFF AVAIL. FLAG AND MARK         38496821
*                                  AS ALTERNATE TRACK SITUATION         38498721
         L     WR15,SB3GRCT        GROSS COUNT OF AVAIL SWAP UNITS      38500621
         BCTR  WR15,WR0            MINUS ONE                            38502521
         ST    WR15,SB3GRCT        EQUALS NEW GROSS COUNT OF  UNITS     38504421
S1MCHA04 LA    WR1,E2(WR1)         TO NEXT UNIT                         38506321
         C     WR1,SB3UTSTP        PAST END OF TABLE                    38508221
         BNL   S01MDONE                 YES DONE                        38510121
         ST    WR1,SB3UTCUR       UPDATE CURRENT POINTER         A44022 38512021
         L     UCBR,SB3DEVI        DEVICE INDEX                         38513921
         A     WR3,S01TRKTB(UCBR)  NEXT SWAP UNTI                       38515821
         B     S1MRHA03            TO READ HOME ADDRESS OF NEXT UNIT    38517721
S1MCHA02 LA    WR2,E4(WR2)         TO NEXT HOME ADDRESS                 38519621
         BCT   UCBR,S1MCHA03       CHECK NEXT TRACK IN UNIT             38521521
         L     WR1,SB3UTCUR        ALL TRACKS THIS UNIT CHECKED         38523421
         B     S1MCHA04            TO MAIN                              38525321
UPCYL    EQU   *    RESET TRACK TO ZERO AND ADD ONE TO CYL   AE A54053  38525721
         N     WR15,C000MASK MASK CHHR TO C000-ZERO TK & RCD AE A54053  38526121
         AL    WR15,ONECYL   INCREMENT CYLINDER BY ONE       AE A54053  38526521
         ST    WR15,E4(TRANR) 2ND HALF SEEK ADDR IN BUFFER   AE A54053  38526921
         B     ENDUPCYL      RETURN TO MAINLINE CHECK RTN    AE A54053  38527021
S1MRHA33 LA    RTNR,E1(RTNR)       3330 SWAP UNIT COUNT PER CYL         38527221
         C     RTNR,NF6            MORE THAN SIX OR NEW CYLINDER        38529121
         BH    S01SIX              YES-BR                               38531021
         B     S1MRHA99      NO RETURN                           A44022 38532921
S01SIX   LA    RTNR,E1             ONE                                  38534821
         SLL   RTNR,E16            TO TTRN FOR 3330                     38536721
         AR    WR0,RTNR            TO FIRST TTRN FOR NEW CYL            38538621
         AR    WR3,RTNR                                          A44022 38540521
         SR    RTNR,RTNR                CLEAR CTR                       38542421
         LA    RTNR,E1       SET UP FOR COUNER INIT VALUE OF ONE A44022 38544321
         B     S1MRHA99      TO MAINLINELLLLL                    A44022 38546221
*********************************************************************** 38548121
*S1MERR1 ISSUES OPEN FAILED MESSAGE, SET RC TO 8 AND RETURNS          * 38550020
*********************************************************************** 38600020
S1MERR1  LA    WR1,S01WWTO         ADDR. OF WTO BUFFER                  38650020
         MVC   E0(S1MSG1L,WR1),S1MSG1 MOVE MSG TO BUFFER                38700020
         MVC   S1MSG1X(E8,WR1),SB3DDN   DDNAME TO MSG                   38750020
         SR    WR0,WR0             ZERO REGISTER                        38800020
         IC    WR0,PSCONID(PARMR)  CONSOLE ID FROM PARM LIST            38850020
         WTO   MF=(E,(1))          ISSUE WTO                            38900020
         LA    EPR,E8              SET RETURN CODE TO 8                 38950020
         B     S1RTN               TO RETURN(NOT S01MDONE) ERROR        39000020
*********************************************************************** 39050020
*INTERFACE TO TTRN TO  MBBCCHHR CONVERT ROUTINE(IECPCNVT).  WR0-TTRN, * 39100020
*WR1-ADDR. OF DEB,  WR2-ADDR. OF DW FOR MBBCCHHR.  LOADED BY CALLER.  * 39150020
*REGISTER 3-8 TRANSPARENT, 9-13 LOST, 14-15 RETURN AND EP ADDR.       * 39200020
*********************************************************************** 39250020
S1MCONV  STM   RTNR,BASER,E12(SAVER) SAVE THE REGISTERS                 39300020
         LR    WR3,SAVER           SAVE THE SAVE                        39350020
         L     WR15,CVTPTR         ADDR. OF OS CVT                      39400020
         USING CVTDSECT,WR15       CVT                                  39450020
         L     WR15,CVTPCNVT       ADDR. OF IECPCNVT ROUTINE            39500020
         DROP  WR15                CVT                                  39550020
         BALR  RTNR,EPR            GO TO IT                             39600020
         LR    SAVER,WR3           UN SAVE THE SAVE                     39650020
         LM    RTNR,BASER,E12(SAVER) RELOAD THE REGISTERS               39700020
         BR    TRANR               RETURN                               39750020
         EJECT                                                          39800020
*********************************************************************** 39850020
*ZERO MAIN STORAGE ROUTINE.   WR1-ADDR. OF MS  WR2-LENGTH             * 39900020
*********************************************************************** 39950020
S1MSCLR  LR    WR3,WR1             LOAD ADDR.                           40000020
         LR    WR4,WR2             LOAD LENGTH AS  XXXXXXNN WHERE       40050020
*                                  XXXXXX IS NUMBER OF 256 BYTE BLOCKS  40100020
*                                  NN IS LESS THAN 256                  40150020
         N     WR4,BYT3MASK        ZERO XXXXXX                          40200020
         LTR   WR4,WR4             NN EQ ZERO                           40250020
         BZ    S1MSCLR1            YES                                  40300020
         BCTR  WR4,0               MINUS ONE                            40350020
         EX    WR4,S1MSCXC         EXECUTE ZERO MAIN STORE              40400020
         LA    WR3,E1(WR4,WR3)     BUMP PAST NN                         40450020
S1MSCLR1 LR    WR4,WR2             LOAD LENGTH                          40500020
         SRL   WR4,E8              ISOLATE XXXXXX TO CONTROL LOOP       40550020
         LTR   WR4,WR4             XXXXXX EQ ZERO                       40600020
         BCR   8,TRANR             BZ  YES, RETURN                      40650020
         LA    WR5,E255            SET ZERO MAIN STORE LEN. TO 256      40700020
S1MSCLR2 EX    WR5,S1MSCXC         EXECUTE ZERO MAIN STORAGE            40750020
         LA    WR3,E256(WR3)       BUMP MAIN STORE ADDR.                40800020
         BCT   WR4,S1MSCLR2        TO TOP                               40850020
         BR    TRANR               DONE                                 40900020
S1MSCXC  XC    E0(E0,WR3),E0(WR3)  ZERO MAIN STORAGE                    40950020
         EJECT                                                          41000020
*********************************************************************** 41050020
S01OPLST OPEN  (,(OUTPUT)),MF=L    MODEL OPEN MACRO PARM LIST           41100020
         SPACE                                                          41150020
S01DCB   DCB   MACRF=E,DSORG=DA,DDNAME=SYSWAPLN  MODEL DCB  1/2         41200020
S01DCBL  EQU   *-S01DCB            LENGTH MODEL DCB         2/2         41250020
*********************************************************************** 41300020
         EJECT                                                          41350020
*********************************************************************** 41400020
*SWAP UNIT CPACITY IN BYTES                                             41450020
CAP2311B DC    F'32768'            2311  16X2048                        41500020
CAP2314B DC    F'65536'            2314  32X2048                        41550020
CAP2301B DC    F'18432'            2301   9X2048                        41600020
CAP2303B DC    F'18432'            2303   9X2048                        41650020
CAP23051 DC    F'45056'            2305 MOD 1 22X2048             20201 41660020
CAP23052 DC    F'53248'            2305 MOD 2 26X2048 M5503       20201 41670020
CAP3330B DC    F'36864'            3330 18X2048                   20201 41680020
         SPACE                                                          41700020
*LENGTH OF SWAP CONTROL BLOCK                                           41750020
S01SRQEL DC    AL2(SB4END-SB4SW0)  L'SWAP REQUEST TABLE ENTRY           41800020
S01SCBL  DC    AL2(SB5END-SB1DCB)  L'SWAP CONTROL BLOCK                 41850020
         SPACE                                                          41900020
*LENGTH OF CHANNEL PROGRAM AREAS                                        41950020
CP2311L  DC    AL2(CPEND11-CPSEEK) 2311 CHANNEL PROGRAM AREA LENGTH     42000020
CP2314L  DC    AL2(CPEND14-CPSEEK) 2314 CHANNEL PROGRAM AREA LENGTH     42050020
CP2301L  DC    AL2(CPEND01-CPSEEK) 2301 CHANNEL PROGRAM AREA LENGTH     42100020
CP2303L  DC    AL2(CPEND03-CPSEEK) 2303 CHANNEL PROGRAM AREA LENGTH     42150020
CP23051L DC    AL2(CPEND051-CPSEEK) 2305 MOD 1 CHNL PGM AREA LNTH 20201 42160020
CP23052L DC    AL2(CPEND052-CPSEEK) 2305 MOD 2 CHNL PGM AREA LNTH 20201 42170020
CP3330L  DC    AL2(CPEND30-CPSEEK) 3330 CHANEL PROGRAM AREA LNGTH 20201 42180020
         SPACE                                                          42200020
*CHANNEL COMMAND WORDS                                                  42250020
SIDEQCCW CCW   SIDEQ,0,CC,5        SEARCH ID EQUAL                      42300020
TICCCW   CCW   TIC,0,CC,1          TIC                                  42350020
READCCW  CCW   READD+MT,0,CC+SKIP,2048  READ 2048 BYTES WITH SKIP       42400020
NOPCCW   CCW   NOP,0,SLI,1         NOP WITH SUPPRESS INCORRECT LENGTH   42450020
SEEKCCW  CCW   SEEKHD,0,CC,6       SEEK HEAD                            42460020
RHACCW   CCW   RHA,0,CC+SLI,5                                           42470020
         SPACE                                                          42500020
*MISC. CONSTANTS                                                        42550020
NF3      DC    F'3'                THREE                          20201 42570020
NF6      DC    F'6'                     SIX                             42580020
NF8      DC    F'8'                EIGHT                                42600020
NF19     DC    F'19'         NUMBER OF 3330 TRKS PER CYL         A44022 42620021
RYES     DC    C'YES'              YES FOR REPLY                        42650020
RNO      DC    CL2'NO'                   NO FOR REPLY             M4980 42660020
FBLANK   DC    4C' '               FULL WORD BLANKS                     42700020
S03NAME  DC    C'IKJEAS03'         SWAP FORMAT                          42750020
NSYSWAP  DC    C'SYSWAP'           SWAP DATA SET DD NAME IS SYSWAPLN    42800020
         DS    0F                  FULL WORD BOUNDARY                   42850020
BYT3MASK DC    X'000000FF'         MASK TO SET BYTE 0,1,2 TO ZERO       42900020
CTTRN    DC    X'00000100'         TTRN FIRST SWAP UNIT IS 00 00 01 00  42950020
SP251    DC    X'FB000000'   SUBPOOL 251 MASK.                   A44022 42951021
C000MASK DC    X'FF000000'   MASK TO ZERO TRACK AND RECORD   AE A54053  42951421
ONECYL   DC    X'01000000'   ONE CYLINDER CHHR               AE A54053  42951821
*DEVICE TABLE                                                           42952020
S01TRKTB DS    0F                  TABLE OF TRACKS PER/SWAP UNIT/DEVICE 42954020
S01TRK11 DC    H'10',H'0'     2311   10 TRKS PER SWAP UNIT              42956020
S01TRK14 DC    H'10',H'0'     2314   10 TRKS PER SWAP UNIT              42958020
S01TRK01 DC    H'1',H'0'      2301 1  TRK  PER SWAP UNIT                42960020
S01TRK03 DC    H'4',H'0'      2303 4  TRKS PER SWAP UNIT                42962020
S01TRK30 DC    H'3',H'0'      3330 3  TRKS PER SWAP UNIT                42964020
S01TRK51 DC    H'4',H'0'      2305 M1 4 TRKS PER SWAP UNIT              42966020
S01TRK52 DC    H'4',H'0'      2305 M2 4 TRKS PER SWAP UNIT              42968020
S01TRKTZ DS    0F            TABLE OF TRACKS PER SWAP UNIT PER DEVICE   42970020
         DC    F'10'          2311  10 TRACKS PER UNIT                  42972020
         DC    F'10'          2314  10 TRACKS PER UNIT                  42974020
         DC    F'1'           2301  1 TRACK PER UNIT                    42976020
         DC    F'4'           2303  4 TRACKS PER UNIT                   42978020
         DC    F'3'           3330  3 TRACKS PER UNIT                   42980020
         DC    F'4'           2305 M1 4 TRACKS PER UNIT                 42982020
         DC    F'4'           2305 M2 4 TRACKS PER UNIT                 42984020
S01TRKND DS    0F                  END OF TRACK TABEL                   42986020
*********************************************************************** 43000020
         EJECT                                                          43050020
*********************************************************************** 43100020
*               IKJ033I DDNAME   SWAP DATA SET OPEN FAILED              43150020
S1MSG1   WTO   'IKJ033I          SWAP DATA SET OPEN FAILED',           *43200020
               MCSFLAG=REG0,MF=L,ROUTCDE=(10),DESC=5                    43250020
S1MSG1L  EQU   *-S1MSG1            LEN.MSG                              43300020
S1MSG1X  EQU   12                  DISP TO DD NAME                      43350020
*********************************************************************** 43400020
*               IKJ034D FORMAT DDNAME   SWAP DATA SET                   43450020
S1MSG2   WTOR  'IKJ034D FORMAT          SWAP DATA SET, REPLY ''YES'' OR*43500020
                ''NO''',MCSFLAG=REG0,MF=L,DESC=2                        43550020
S1MSG2L  EQU   *-S1MSG2            LENGTH OF MESSAGE TWO                43600020
S1MSG2X  EQU   27                  DISP TO DDNAME                       43650020
*********************************************************************** 43700020
         EJECT                                                          43710021
*********************************************************************** 43712021
***** THE FOLLOWING ARE THE FL/1 STATEMENTS FOR RELEASE 21.0     *****  43714021
*********************************************************************** 43716021
*/*IKJEAS01: CHART */                                                   43720021
*/*HEADER                                                               43730021
*/*IKJEAS01  TSO/SWAP  INITIALIZATION RELEASE 21.0 */                   43740021
*/*IKJEAS01: E ENTRY */                                                 43742021
*/*         P     SAVE CALLER'S REGISTERS */                            43744021
*/*         S     GETMAIN: GET WORK AREA CORE */                        43746021
*/*         S     EXTRACT: GET ADDRESS OF TIOT */                       43748021
*/*         P     ZERO OUT COUNTER REG */                               43748421
*/*         P     ZERO OUT INDEX REG */                                 43748821
*/*S1ML00:  D     (YES,S1ML02,NO,) END OF TIOT ? */                     43749221
*/*         D     (NO,S1ML01,YES,) SWAP DATA SET ? */                   43749621
*/*         P     ADD ONE TO SWAP DATA SET COUNTER */                   43749721
*/*S1ML01:  P     (,S1ML00) INCREMENT DD ENTRY POINTER IN TIOT */       43749821
*/*S1ML02:  P     NO. DATA SETS * 8 = STORAGE REQUIRED */               43749921
*/*         S     GETMAIN: GET CORE FOR DD TABLE */                     43799921
*/*         S     S1MSCLR: CLEAR OUT DD GOTTEN CORE */                  43809921
*/*         P     SET UP POINTER TO FIRST DD ENTRY IN TIOT */           43819921
*/*         P     SET UP TRANR WITH ADDRESS OF S1ML04 */                43829921
*/*S1ML03:  D     (YES,S1ML05,NO,) END OF TIOT ? */                     43839921
*/*         D     (YES,S1DD100,NO,) SWAP DATA SET ? */                  43841921
*/*S1ML05:  P     (,S1ML061) UPDATE DD TABLE STOPPER */                 43843921
*/*S1ML06:  P     PICK UP DD TABLE STOPPER & CURRENT */                 43845921
*/*S1ML061: D     (YES,S1ML10,NO,) CURRENT = STOPPER ? */               43847921
*/*         D     (YES,S1ML07,NO,) CURRENT = ZERO ? */                  43848321
*/*         P     (,S01MAIN) UP CURRENT TO NEXT & SAVE CURRENT &        43848721
*/*STOPPER */                                                           43849121
*/*S1ML07:  P     (,S1ML06) UP CURRENT TO NEXT & SAVE CURRENT AND       43849521
*/*STOPPER */                                                           43849621
*/*S01MDONE: P   (,S1ML06) SAVE ADDR OF SWAPCW IN  DD TABLE */          43849721
*/*S1ML10:  P     PUT ADDR OF FIRST SWAPCB IN TSCVTSDC */               43899821
*/*S1ML11:  D     (YES,S1ML12,NO,) PARALLEL SWAP CB */                  43909821
*/*         P     UP POINTER TO NEXT DD TABLE LEVEL */                  43919821
*/*         D     (YES,S1SMF,NO,) END OF TABLE ? */                     43929821
*/*         P     (,S1ML11) UPDATE S & P POINTERS */                    43939821
*/*S1ML12:  P     UPDATE S & P POINTERS */                              43941821
*/*S1SMF:   D     (NO,S1RC,YES,) SMF IN SYSTEM ? */                     43943821
*/*         S     GETMAIN: GET CORE FOR SMF RECORD 38 */                43945821
*/*         P     BUILD SMF RECORD */                                   43947821
*/*S1SMF00: D     (YES,S1SMF03,NO,) END OF DD TABLE ? */                43948221
*/*         D     (YES,S1SMF02,NO,) IS THERE A SWAP CB ? */             43948621
*/*S1SMF01: P     (,S1SMF00) UPDATE ADDRESS TO NEXT DD ENTRY */         43949021
*/*S1SMF02: P     (,S1SMF01) MOVE DEVICE INFO INTO SMF RECORD */        43949421
*/*S1SMF03: S     SVC83: SMF WRITER */                                  43949521
*/*         S     FREEMAIN: FREE SMF RECORD */                          43949621
*/*S1RC:    P     SET RETURN CODE + 0 */                                43949721
*/*S1RTN:   S     FREEMAIN: DD TABLE CORE */                            43999721
*/*S1RTN01: S     FREEMAIN: SAVE AREA CORE */                           44009721
*/*         R     RETURN TO CALLER */                                   44019721
*/*S1DD100: D     (NO,S1DD101,YES,) PARALLEL DATA SET ? */              44029721
*/*         P     SET DISPLACEMENT IN DD TABLE FOR N=1 */               44039721
*/*S1DD101: P     MOVE 'LN' TO TABLE */                                 44041721
*/*         R     RETURN ON TRANR */                                    44043721
*/*S01MAIN: S     GETMAIN: GET CORE  FOR SWAPCB */                      44045721
*/*         S     S1MSCLR: CLEAR GOTTEN CORE */                         44047721
*/*         P     MOVE MODEL DCB INTO SWAPCB */                         44048121
*/*         S     OPEN: OPEN DDNAME */                                  44048521
*/*         D     (NO,S1MERR1,YES,) IS DCB OPEN ? */                    44048921
*/*         P     FIND UCB FROM DEB */                                  44049321
*/*         D     (YES,S1M2311,NO,) SWAP DS ON 2311 ? */                44049421
*/*         D     (YES,S1M2314,NO,) SWAP DS ON 2314 ? */                44049521
*/*         D     (YES,S1M2301,NO,) SWAP DS ON 2301 ? */                44049621
*/*         D     (YES,S1M2303,NO,) SWAP DS ON 2303 ? */                44099621
*/*         D     (YES,S1M23051,NO,) SWAP DS ON 2305 MOD 1 ? */         44109621
*/*         D     (YES,S1M23052,NO,) SWAP DS ON 2305 MOD 2 ? */         44119621
*/*         D     (YES,S1M3330,NO,) SWAP DS ON 3330 ? */                44129621
*/*         P     (,S1RTN) SET RETURN CODE OF 8 */                      44139621
*/*S1M2311: D     (YES,,NO,S1MERR1) ALLOC IN CYL ? */                   44141621
*/*         P     CYL END - CYL START + 1 = CYL ALLOC (SWAP UNITS)*/    44143621
*/*         S     GETMAIN: GET CORE FOR CHANNEL PGM AREA */             44145621
*/*         S     S1MCPA: SET UP CHANNEL PGM 'A' */                     44147621
*/*         S     GETMAIN: GET CORE FOR CHANNEL PGM AREA */             44148021
*/*         S     S1MCPB: SET UP CHANNEL PGM 'B' */                     44148421
*/*         P     (,S1M01) PUT ADDRESS OF MBBCCHHR BUFFERS IN SWAPCB */ 44148821
*/*S1M2314: D     (YES,,NO,S1MERR1) ALLOC IN CYL ? */                   44149221
*/*         P     CYL END - CYL START + 1 = CYL ALLOC */                44149321
*/*         P     CONVERT CYLS TO HALF CYLS (SWAP UNITS) */             44149421
*/*         S     GETMAIN: GET CORE FOR CHANNEL PGM AREA */             44149521
*/*         S     S1MCPA: SET UP CHANNEL PGM 'A' */                     44149621
*/*         S     GETMAIN: GET CORE FOR CHANNEL PGM AREA */             44199521
*/*         S     S1MCPB: SET UP CHANNEL PGM 'B' */                     44209521
*/*         P     (,S1M01) PUT ADDRESS OF MBBCCHHR BUFFERS IN SWAPCB */ 44219521
*/*S1M2301: P     NO. OF ALLOC TRACKS = GROSS SWAP UNITS */             44219921
*/*         S     GETMAIN: GET CORE FOR CHANNEL PGM AREA */             44221521
*/*         S     S1MCPA: SET UP CHANNEL PGM 'A' */                     44223521
*/*         S     GETMAIN: GET CORE FOR CHANNEL PGM AREA */             44225521
*/*         S     S1MCPB: SET UP CHANNEL PGM 'B' */                     44227521
*/*         P     (,S1M01) PUT ADDRESS OF MBBCCHHR BUFFERS IN SWAPCB */ 44227921
*/*S1M2303: D     (YES,,NO,S1MERR1) ALLOC IN CYL ? */                   44228321
*/*         P     NUMBER TRACKS / 4 = SWAP UNITS */                     44228421
*/*         S     GETMAIN: GET CORE FOR CHANNEL PGM AREA */             44229121
*/*         S     S1MCPA: SET UP CHANNEL PGM 'A' */                     44229221
*/*         S     GETMAIN: GET CORE FOR CHANNEL PGM AREA */             44229321
*/*         S     S1MCPB: SET UP CHANNEL PGM 'B' */                     44229421
*/*         P     (,S1M01) PUT ADDRESS OF MBBCCHHR BUFFERS IN SWAPCB */ 44232721
*/*S1M23051: D     (YES,,NO,S1MERR1) ALLOC IN CYL ? */                  44233121
*/*         P     NUMBER TRACKS / 4 = SWAP UNITS */                     44233521
*/*         S     GETMAIN: GET CORE FOR CHANNEL PGM AREA */             44233921
*/*         S     S1MCPA: SET UP CHANNEL PGM 'A' */                     44234321
*/*         S     GETMAIN: GET CORE FOR CHANNEL PGM AREA */             44234421
*/*         S     S1MCPB: SET UP CHANNEL PGM 'B' */                     44234521
*/*         P     (,S1M01) PUT ADDRESS OF MBBCCHHR BUFFERS IN SWAPCB */ 44234621
*/*S1M23052: D     (YES,,NO,S1MERR1) ALLOC IN CYL ? */                  44234721
*/*         P     NUMBER TRACKS / 4 = SWAP UNITS */                     44235121
*/*         S     GETMAIN: GET CORE FOR CHANNEL PGM AREA */             44235521
*/*         S     S1MCPA: SET UP CHANNEL PGM 'A' */                     44235921
*/*         S     GETMAIN: GET CORE FOR CHANNEL PGM AREA */             44236021
*/*         S     S1MCPB: SET UP CHANNEL PGM 'B' */                     44236121
*/*         P     (,S1M01) PUT ADDRESS OF MBBCCHHR BUFFERS IN SWAPCB */ 44236921
*/*S1M3330: D     (YES,,NO,S1MERR1) ALLOC IN CYL ? */                   44238721
*/*         P     NUMBER TRACKS / 3 = SWAP UNITS */                     44239121
*/*         S     GETMAIN: GET CORE FOR CHANNEL PGM AREA */             44241521
*/*         S     S1MCPA: SET UP CHANNEL PGM 'A' */                     44243521
*/*         S     GETMAIN: GET CORE FOR CHANNEL PGM AREA */             44245521
*/*         S     S1MCPB: SET UP CHANNEL PGM 'B' */                     44247521
*/*         P     (,S1M01) PUT ADDRESS OF MBBCCHHR BUFFERS IN SWAPCB */ 44247921
*/*S1MCPA:  P     PUT ADDR OF SEEK, READ,& WRITE CCW IN SWAPCB FOR CP   44248721
*/*'A' */                                                               44298721
*/*         R     RETURN TO CALLER */                                   44299121
*/*S1MCPB:  P     PUT ADDR OF SEEK, READ, & WRITE CCW IN SWAPCB FOR CP  44349121
*/*'B' */                                                               44399121
*/*         R     RETURN TO CALLER */                                   44449121
*/*S1M01:   S     GETMAIN: GET CORE FOR ALLOCATION TABLE */             44451121
*/*         S     S1MSCLR: CLEAR OUT GOTTEN CORE */                     44453121
*/*         P     SET UP CURRENT, START, & END POINTERS TO ALLOC TABLE  44455121
*/**/                                                                   44457121
*/*S1M02:   D     (YES,S1M03,NO,) CURRENT POINTER OUT OF TABLE ? */     44457521
*/*         P     (,S1M02) MARK SWAP UNIT AVALIABLE, UP CURRENT POINTER 44457921
*/* BY TWO*/                                                            44458321
*/*S1M03:   S     GETMAIN: GET CORE FOR SWAP REQUEST TABLE */           44458721
*/*         S     S1MSCLR: CLEAR OUT GOTTEN CORE */                     44458821
*/*         P     SET UP ADDRESS OF FIRST POINTER & LAST POINTER */     44458921
*/*         D     (YES,S1M05,NO,) FORMAT REQUESTED ? */                 44459021
*/*         P     SET UP CHANNEL PGM 'A' TO READ A SWAP UNIT */         44472321
*/*         P     SET UP IOB & ECB FOR READ I/O */                      44484321
*/*         S     S1MCONV: CONVERT TTRN TO MBBCCHHR */                  44484721
*/*         S     EXCP: DO I/O */                                       44485121
*/*         S     WAIT: WAIT FOR COMPLETION */                          44485521
*/*         D     (NO,S1M05,YES,) I/O SUCCESSFUL ? */                   44485621
*/*         D     (YES,S1M06,NO,) SWAP SWITCH = NO FORMAT ? */          44485721
*/*ZWTOR:   P     SET UP FOR WTOR 'SWAP DATA SET YES OR NO' */          44490121
*/*         S     WTOR: SEND MESSAGE WITH REPLY */                      44492121
*/*         S     WAIT: WAIT FOR REPLY */                               44494121
*/*         D     (YES,S1M05,NO,) IS REPLY = 'YES' ? */                 44494521
*/*         D     (YES,S1M06,NO,ZWTOR) IS REPLY = 'NO' ? */             44594521
*/*S1M05:   P     SET UP PARMETER LIST FOR IKJEAS03 */                  44604521
*/*         S     IKJEAS03: LINK TO FORMAT ROUTINE */                   44614521
*/*S1M06:   P     CLEAR OUT IOB AND SET UP FOR CHANNEL PGM 'A' */       44624521
*/*S1MRHA03: D    (YES,S1MCHA04,NO,) IS SWAP UNIT NOT AVAL ? */         44634521
*/*         P     *************** NOTE BLOCK HAS BEEN                   44638521
*/*CHANGED *************** */                                           44640521
*/*         D     (YES,S01MDONE,NO,) DEVICE = 3330 ? */                 44642521
*/*S1MRHA34: P    PUT ADDRESS OF MBBCCHHR IN DEB */                     44642921
*/*         S     S1MCONV: CONVERT MBBCCHHR TO TTRN */                  44643321
*/*SIMRHA01: P    SET CHANNEL PGM 'B' TO READ */                        44643721
*/*S1MRHA02: P    ******** ******** ******** ******** ******** */       44644121
*/*S1MERR1: P     SET UP FOR WTO MSG 'SWAP DATA SET OPEN FAILED' */     44644321
*/*         S     WTO: WRITE MESSAGE */                                 44644421
*/*         P     (,S1RTN) SET RETURN CODE = 8 */                       44661121
*/*S1MCONV: P     SAVE CALLER'S REGS */                                 44671121
*/*         S     IECPCNVT: CONVERT TTRN TO MBBCCHHR */                 44673121
*/*         P     RESTORE CALLER'S REGS */                              44675121
*/*         R     RETURN ON TRANR */                                    44677121
*/*END */                                                               44677821
         END                                                            44694521
