IKJEAT00 START                                                          00030021
**********************************************************************  00060021
*                                                                       00090021
* STATUS/CHANGE LEVEL=0                                                 00120021
*                                                                       00150021
*A511000                                                      CC A67733 00160021
*C511800                                                      CC A67733 00162021
*A325600,325900                                               CC A68643 00164021
*C176400-177300                                               CC A70433 00166021
*C518400                                                      CC A70793 00168021
*                                                                       00170021
*                                                                       00172021
*                                                                       00174021
* ROUTINE NAME - TSC'S INITILIZATION ROUTINE LOAD ONE                   00180021
*                                                                       00210021
* FUNCTION - THE FIRST LOAD OF TSC RECEIVES CONTROL WHEN THE            00240021
*          L-SHAPED PROGRAM ATTACHES IT. THIS LOAD PERFORMS THE         00270021
*          FOLLOWING FUNCTIONS:                                         00300021
*          1) OBTAINS AND INTERPRETS THE PARAMETERS FROM THE            00330021
*             START PARAMETER LIST ASSOCIATED WITH THE START TS         00360021
*             COMMAND.                                                  00390021
*          2) READS THE MEMBER OF SYS1.PARMLIB THAT CONTAINS TS         00420021
*             PARAMETERS.                                               00450021
*          3) MODIFYS THE TS PARAMETERS AS SPECIFIED IN THE CIB.        00480021
*          4) COMPUTES THE SIZE OF THE TIME SHARING CONTROL REGION      00510021
*             BASED UPON:                                               00540021
*             A) SUBSYSTEM DATA SETS - MAIN STORAGE FOR SWAP DATA SETS  00570021
*             B) TS CONTROL BLOCKS.                                     00600021
*             C) TERMINAL I/O BUFFERS                                   00630021
*             D) MAIN STORAGE FOR LOAD MODULES USED AS SUBSYSTEM        00660021
*                TASKS,NUCLEUS EXTENSION, AND THE LINK PACK AREA        00690021
*                EXTENSION.                                             00720021
*                                                                       00750021
* ENTRY POINT - IKJEAT00                                                00780021
*                                                                       00810021
* ATTRIBUTES - SERIALLY REUSEABLE, KEY ZERO                             00840021
*                                                                       00870021
* APPLICABILITY - MVT SYSTEMS WITH TSO.                                 00900021
*                                                                       00930021
*EXTERNAL REFERENCES -                                                  00960021
*                                                                       00990021
* SVC'S BLDL                  LINK                                      01020021
*       CHECK                 LOAD                                      01050021
*       CLOSE                 READ                                      01080021
*       EXTRACT               WAIT                                      01110021
*       FIND                  WTO                                       01140021
*       FREEMAIN              WTOR                                      01170021
*       GETMAIN               XCTL                                      01200021
*                                                                       01230021
* INPUT - REGISTER 1: ADDRESS OF PARM OR ZERO                           01260021
*         REGISTER 13: ADDRESS OF SAVE AREA                             01290021
*         REGISTER 14: RETURN ADDRESS                                   01320021
*         REGISTER 15: ENTRY POINT ADDRESS                              01350021
*                                                                       01380021
* OUTPUT - NONE                                                         01410021
*                                                                       01440021
* EXITS - NORMAL - XCTL TO TSC INITIALIZATION LOAD TWO - IKJEAT01       01470021
*           REGISTER 1 CONTAINS THE ADDRESS OF THE PARAMETER LIST       01500021
*                                                                       01530021
*          ERROR EXIT - RETURN TO SYSTEM CONTROL TASK IF UNABLE TO      01560021
*           INITIALIZE THE SYSTEM.                                      01590021
*                                                                       01620021
* TABLES/CONTROL BLOCKS/WORK AREAS -                                    01650021
*          A. TSC PARAMETER LIST                                        01680021
*              +0 NUMBER MAX USERS (TERMAX= PARAMETER)                  01710021
*              +4 LENGTH PARM DATA                                      01740021
*              +8 ADDRESS OF PARM DATA                                  01770021
*              +12 SWITCH FOR FORM OPTION                               01800021
*                  X'FF'- FORMAT ALL SWAP DATA SETS                     01830021
*                  X'0F'- FORMAT DATA SETS PER OP REQUIREMENTS          01860021
*                  X'00'- DO NOT FORMAT SWAP DATA SETS.                 01890021
*              +13 CONSOLE ID FOR THE START COMMAND                     01920021
*              +14 MAXIMUM NUMBER OF REGIONS (REGNMAX= PARAMETER)       01950021
*              +16 USED TO RETURN AMT MAIN STORAGE NEEDED               01980021
*                  BY SWAP,TIOC, AND DRIVER.                            02010021
*                                                                       02040021
*                  THIS WORD ALSO USED TO SAVE THE ADDRESS OF START     02070021
*                  COMMAND OVERRIDES IN THE PARM AREA ACROSS THE        02100021
*                  XCTL TO IKJEAT01. THE ADR IS NEEDED IN IKJEAT02      02130021
*                  WHEN IT LINKS TO THE DRIVER.                         02160021
*                                                                       02190021
*              +20 SIZE NEW REGION IF NEEDED                            02220021
*                                                                       02250021
*                  THIS WORD ALSO USED TO PASS THE DRIVER THE ADDRESS   02280021
*                  OF THE START COMMAND OVERRIDES IN THE PARM AREA.THE  02310021
*                  DRIVER CAN THEN EDIT HIS OVERRIDES.                  02340021
*                                                                       02370021
*              +24 ADDRESS COMMUNICATIONS PARAMETER LIST (CPL)          02400021
*              +28 SWITCH FOR TSO DUMP                                  02430021
*                  X'FF'  DUMP =DUMP - SAVE SWAPPED USER                02460021
*                  X'00'  DUMP=NODUMP - DO NOT SAVE SWAPPED USER        02490021
*              +29 ADDRESS TSC TABLE                                    02520021
*          B. TSC TABLE                                                 02550021
*              +0 LENGTH TSC TABLE                                      02580021
*              +4 NUMBER MAPS  (MAP= PARAMETER)                         02610021
*              +6 LIMIT NUMBER OF USERS (USERS= PARAMETER)              02640021
*              +8 DRIVER NAME  (DSPCH= PARAMETER)                       02670021
*              +16 SUBMIT PARAMETER                                     02700021
*              +18 SMF PARAMETER                                        02730021
*              +20 MEMBER NAME IN SYS1.PARMLIB                          02760021
*              +28 ADDRESS OF SRE CHAIN                                 02770021
*              +32 REGSIZE AND LSQS SIZE FOR REGION 1                   02790021
*              +36 REGSIZE AND LSQS SIZE FOR REGION 2                   02820021
*                  ETC.                                                 02850021
*          C. PARM DATA AREA                                            02880021
*              CARDS ARE READ FROM A MEMBER IN SYS1.PARMLIB INTO THIS   02910021
*              AREA. THE DEFAULT MEMBER IS IKJPRM00. A DIFFERENT        02940021
*              MEMBER MAY BE SPECIFIED ON THE START COMMAND. THE        02970021
*              CARD MUST BEGIN WITH AN ID WHICH IS TS OR DRIVER         02980021
*              OR TIOC FOLLOWED BY BLANK(S). THE ID DOES NOT            02990021
*              NECESSARILY HAVE TO START IN COL 1.                      02994021
*              NEXT ON THE CARD ARE THE PARAMETERS FOR THAT             03060021
*              ID SEPARATED BY BLANK(S).                                03090021
*                                                                       03140021
*              VALID TS PARAMETERS ARE:                                 03180021
*                  USERS=XX  - WHERE XX IS A VALID NUMBER GR TH 0.      03210021
*                    IF OMITTED IT DEFAULTS TO TERMAX VALUE             03240021
*                    FOR USERS= PARAM ONLY 0 IS VALID                   03250021
*                  TERMAX=XX                                            03270021
*                  MAP=XX                                               03300021
*                  REGNMAX=XX  ( THIS NO. CANNOT BE GR TH 14)           03330021
*                  SUBMIT=XX                                            03360021
*                  REGSIZE(N)=(XXK,XXK) -N=NUMBER OF THE REGION         03390021
*  WITHIN PARENTHESIS IS REGION SIZE AND LSQS SIZE                      03420021
*   - REGION SIZE MUST BE GREATER THAN LSQS SIZE                        03450021
*   - REGION SIZE MUST BE GREATER THAN MINPART                          03480021
*                  SMF=(AA,BB) - AA=OFF,OR OPT=1,OR OPT=2               03510021
*                                BB=EXT=YES,OR EXT=NO                   03540021
*  IF OMITTED SMF FOREGROUND DEFAULTS TO BACKGROUND OPTIONS             03570021
*                                                                       03600021
*  IF THE OPERATOR INTERVENTION BIT IS SET, THEN SMF= MAY NOT BE        03630021
*  PUT ON THE START COMMAND.                                            03660021
*                                                                       03690021
*  IF THE SMF DATSET ACCOUNTING BIT IS SET THEN SMF OPTION OPT=2        03720021
*  MUST BE USED. IF ANYTHING DIFFERENT WAS SPECIFIED IN THE PARMLIB     03750021
*  OR ON THE START COMMAND IT WILL BE IGNORED.                          03780021
*                                                                       03810021
*                  LPA=(CC,CCCC,ETC) , CC IS NAME(UP TO 8 CHAR) OF      03840021
*                                      MODULE TO BE LOADED INTO TSLPA.  03870021
*                  DSPCH=CCCCCC - THIS IS A 6 CHAR DRIVER NAME-DEFAULT  03900021
*                                 NAME IS IKJEAD.                       03930021
*                  DUMP=DUMP OR DUMP=NODUMP                             03960021
*                  DRIVER=(   )  - INSIDE PARENTHESIS ARE ANY VALID     03990021
*                                 DRIVER PARAMETERS SEPARATED BY COMMAS 04020021
*                                                                       04050021
*  THERE ARE TWO PARAMETERS WHICH CANNOT BE PUT ON THE START            04080021
*  COMMAND. THESE ARE DUMP= AND LPA=.                                   04110021
*                                                                       04140021
*  IF THERE IS AN ERROR ON THE START COMMAND A MESSAGE WILL APPEAR      04170021
*  EXPLAINING THE ERROR, AND ANOTHER MESSAGE WILL APPEAR ASKING YOU     04200021
*  TO REPLY AGAIN.                                                      04230021
*                                                                       04240021
*  IF THERE IS AN ERROR IN THE PARMLIB IT WILL BE IGNORED               04250021
*                                                                       04260021
*  THERE ARE THREE PARAMETERS NECESSARY FOR START TS. THEY ARE MAP=,    04290021
*  REGNMAX=, AND TERMAX=. WITHOUT THESE INITIALIZATION CANNOT           04320021
*  BE COMPLETED. IF ANY OF THESE PARAMETERS ARE OMITTED A               04350021
*  MESSAGE PROMPTING FOR THE INFO WILL APPEAR                           04360021
*                                                                       04380021
*          D. COMMUNICATIONS PARAMETER LIST (CPL)                       04410021
*              +0 ADDRESS ECB                                           04440021
*              +4 ADDRESS COMMAND INPUT BUFFER (CIB)                    04470021
         SPACE                                                          04500021
*              THE ADDRESS OF THE CPL IS OBTAINED BY ISSUING THE        04530021
*              EXTRACT MACRO.                                           04560021
         SPACE                                                          04590021
*              FORMAT OF CIB-                                           04620021
         SPACE                                                          04650021
*    **********************************************                     04680021
*    * ADDR *    *    *  * L OF *                 *                     04710021
*    * NEXT *    *    *  * CIB  * CIBDATA....     *                     04740021
*    *  CIB *    *    *  * DATA *                 *                     04770021
*    **********************************************                     04800021
*    +0     +4   +8   +16+18    +20                                     04830021
         SPACE                                                          04860021
*              CIB DATA ARE THE OVERRIDE PARAMETERS ON THE START        04890021
*              COMMAND                                                  04920021
         SPACE                                                          04950021
*          E. OS CONTROL BLOCKS REFERENCED                              04980021
*              CVT                                                      05010021
*              DCB                                                      05040021
*              TCB                                                      05070021
*              IEZCIB                                                   05100021
*              IEEBASEA                                                 05130021
*              IEFQMRES                                                 05160021
*              IEESMCA                                                  05190021
*          F. TS CONTROL BLOCKS REFERENCED                              05220021
*              IKJTSCVT                                                 05250021
*              IKJRCB                                                   05280021
*              IKJTJB                                                   05310021
*              IKJSAVED                                                 05340021
*              IKJPQE                                                   05370021
*              IKJECBS                                                  05400021
*              IKJDPA                                                   05430021
*              IKJTSIA                                                  05460021
*              IKJTSDMP                                                 05490021
*                                                                       05520021
*********************************************************************** 05550021
         EJECT                                                          05580021
*********************************************************************** 05610021
*                                                                     * 05640021
*                            DSECTS                                   * 05670021
*                                                                     * 05700021
*********************************************************************** 05730021
         SPACE                                                          05760021
TCB      DSECT                                                          05790021
         DS    28F                                                      05820021
TCBFSA   DS    1F                                                       05850021
         DS    9F                                                       05880021
TCBPQE   DS    1F                                                       05910021
         SPACE 5                                                        05940021
CVTSECT  DSECT                                                          05970021
         CVT                                                            06000021
         SPACE 6                                                        06030021
         IEEBASEA                                                       06060021
         EJECT                                                          06090021
         IKJTSCVT                                                       06120021
ENDTSCVT EQU   *                                                        06150021
LTSCVT   EQU   ENDTSCVT-TSCVT                                           06180021
         SPACE 3                                                        06210021
CIBD     DSECT                                                          06240021
         IEZCIB                                                         06270021
         EJECT                                                          06300021
         IKJRCB                                                         06330021
ENDRCB   EQU   *                                                        06360021
LRCB     EQU   ENDRCB-RCB                                               06390021
         EJECT                                                          06420021
         IKJTJB                                                         06450021
ENDTJB   EQU   *                                                        06480021
LTJB     EQU   ENDTJB-TJB                                               06510021
         SPACE 6                                                        06540021
         IKJSAVED                                                       06570021
ENDSAVE  EQU   *                                                        06600021
LTSSAVE  EQU   ENDSAVE-TSSAVE                                           06630021
         EJECT                                                          06660021
         IKJPQE                                                         06690021
         SPACE 4                                                        06720021
         IKJECBS                                                        06750021
ENDECB   EQU   *                                                        06780021
LECBTAB  EQU   ENDECB-TSECB                                             06810021
         EJECT                                                          06840021
         IKJDPA                                                         06870021
ENDDPA   EQU   *                                                        06900021
LDPA     EQU   ENDDPA-DPA                                               06930021
         SPACE 4                                                        06960021
         IKJTSIA                                                        06990021
LTSIA    EQU   TSIARST-TSIA                                             07020021
         EJECT                                                          07050021
IEFQM    DSECT                                                          07080021
         IEFQMRES                                                       07110021
         EJECT                                                          07140021
         IEESMCA                                                        07170021
         SPACE 5                                                        07200021
         IKJTSDMP                                                       07230021
ENDTSDMP EQU   *                                                        07260021
LTSDMP   EQU   ENDTSDMP-IKJTSDMP                                        07290021
         EJECT                                                          07320021
WKAREA   DSECT                                                          07350021
SAVEAR   DS    18F                                                      07380021
SAVE1    DS    16F                                                      07410021
SAVE2    DS    15F                                                      07440021
LISTMAC  DS    25F                                                      07470021
LISTWTO  EQU   LISTMAC+4                                                07500021
KYWD5    EQU   LISTMAC+12                                               07530021
KYWD3    EQU   LISTMAC+20                                               07560021
KYWD6    EQU   LISTMAC+36                                               07590021
KYWD1    EQU   LISTMAC+38                                               07620021
KYWD2    EQU   LISTMAC+42                                               07650021
KYWD4    EQU   LISTMAC+51                                               07680021
REPLYAD  DS    18F                                                      07740021
ECBAD    DS    1F                                                       07770021
EXTREPLY DS    1F                                                       07800021
EXTINPUT DS    3F                                                       07830021
CPLADR   DS    1F                                                       07860021
MODFYADR DS    1F                                                       07890021
DRVRCIB  DS    1F                                                       07920021
CIBENDAD DS    1F                                                       07950021
CIBPTR   DS    1F                                                       07980021
CIBPTR1  DS    1F                                                       08010021
         DS    0D                                                       08040021
CVBDWD   DS    2F                                                       08070021
CVBDWD1  EQU   CVBDWD+1                                                 08100021
CVBDWD6  EQU   CVBDWD+6                                                 08130021
PARMEND  DS    1F                                                       08160021
DRVCRDAD DS    1F                                                       08190021
SZECNBLK DS    1F                                                       08220021
TSCRGSZE DS    1F                       TSC REG SIZE FIELD-USED WHEN    08280021
*                                       TSCREGSZ KEYWORD SPECIFIED ON   08310021
*                                       START TSO OR TS PARM LIST       08340021
REGWTOFL DS    CL1                                                      08370021
REGWTOM  EQU   X'80'                                                    08400021
DCBPARM  DS    24F                                                      08430021
DCBFLAG  EQU   DCBPARM+48                                               08460021
         DS    0H                                                       08490021
RDSAVE   DS    18F                                                      08520021
EDITSW   DS    CL1                                                      08550021
LISTSW   DS    CL1                                                      08580021
MODIFYSW DS    CL1                                                      08610021
IOERRSW  DS    CL1                                                      08640021
DMPSW    DS    CL1                                                      08670021
USERSW   DS    CL1                                                      08700021
MODSW    DS    CL1                                                      08730021
DRVSW    DS    CL1                                                      08760021
SMFSW    DS    CL1                                                      08790021
SMF1SW   DS    CL1                 SWITCH TO INDICATE IF DSA BIT IS SET 08820021
*                                  AND OPT=2 MUST BE USED FRO SMF       08850021
REJSW    DS    CL1                                                      08880021
MAXUSER  DS    1F                                                       08910021
MAXNUSER EQU   MAXUSER+2                                                08940021
PARMLEN  DS    1F                                                       08970021
PARMADR  DS    1F                                                       09000021
FORMSW   DS    CL1                                                      09030021
CONSLID  DS    CL1                                                      09060021
REGNUM   DS    1H                                                       09090021
TSCTAB   DS    0F                                                       09120021
MAPENT   DS    1H                                                       09150021
LIMUSER  DS    1H                                                       09180021
DRVR     DS    CL8' '                                                   09210021
DRVCDE   EQU   DRVR+6                                                   09240021
SUBMTMAX DS    1H                                                       09270021
SMFPARM1 DS    X                                                        09300021
         DS    X                   RESERVED                             09330021
PARMNAME DC    CL8' '                                                   09360021
SRECHAIN DS    1F             POINTER TO 1ST SRE ON CHAIN.              09390021
REGDISP  EQU   *-4                                                      09420021
TABEND   EQU   *+4                                                      09450021
REGN1    DS    1F                                                       09480021
REGN2    DS    1F                                                       09510021
REGN3    DS    1F                                                       09540021
REGN4    DS    1F                                                       09570021
REGN5    DS    1F                                                       09600021
REGN6    DS    1F                                                       09630021
REGN7    DS    1F                                                       09660021
REGN8    DS    1F                                                       09690021
REGN9    DS    1F                                                       09720021
REGN10   DS    1F                                                       09750021
REGN11   DS    1F                                                       09780021
REGN12   DS    1F                                                       09810021
REGN13   DS    1F                                                       09840021
REGN14   DS    1F                                                       09870021
BLDLLIST DS    0F                                                       09900021
LPALIST  DS    1F                                                       09930021
LPANAME  DS    14F                                                      09960021
LPANM    EQU   LPANAME+1                                                09990021
DRVLST   DS    29F           TWO 56 BYTE ENTRIES.                       10020021
DRVR2    EQU   DRVLST+4                                                 10050021
DRVR3    EQU   DRVLST+60                                                10080021
WKAREND  EQU   *                                                        10110021
LWKAREA  EQU   WKAREND-WKAREA                                           10140021
LTSCTAB  EQU   TABEND-TSCTAB                                            10170021
LCLRAREA EQU   WKAREND-LISTMAC                                          10200021
         EJECT                                                          10230021
SRE      DSECT                STORAGE REQUEST ELEMENT.                  10260021
         SPACE 1                                                        10290021
SRELINK  DS    1F             CHAIN FIELD ('NEXT' POINTER).             10320021
SRESIZE  DS    1F             AMOUNT OF STORAGE REQUESTED.              10350021
SRENAME  DS    CL8            NAME FIELD (ZERO IF NOT A MODULE).        10380021
SRETNAME DS    CL8            TRUE NAME FIELD FOR LOAD MODULES.         10410021
SRELNGTH EQU   *-SRE          SRE LENGTH.                               10440021
         EJECT                                                          10470021
IKJEAT00 CSECT                                                          10500021
*********************************************************************** 10530021
*                                                                     * 10560021
*                            EQUATES                                  * 10590021
*                                                                     * 10620021
*********************************************************************** 10650021
         SPACE 1                                                        10680021
*                            REGISTER EQUATES                           10710021
         SPACE 1                                                        10740021
R0       EQU   0    REGISTER EQUATES                                    10770021
R1       EQU   1                                                        10800021
USEREG   EQU   1                                                        10830021
TSCSVE   EQU   1                                                        10860021
R2       EQU   2                                                        10890021
CARDPTR  EQU   2                                                        10920021
PARMREG  EQU   2                                                        10950021
CPLREG   EQU   2                                                        10980021
R3       EQU   3                                                        11010021
PARMLST  EQU   3                                                        11040021
CVTREG   EQU   3                                                        11070021
R4       EQU   4                                                        11100021
CARDSTOP EQU   4                                                        11130021
NBLDLREG EQU   4                                                        11160021
PARMAD   EQU   4                                                        11190021
TSCVTREG EQU   4                                                        11220021
R5       EQU   5                                                        11250021
MSTOREG  EQU   5                                                        11280021
R6       EQU   6                                                        11310021
PARMBUF  EQU   6                                                        11340021
CIBBUF   EQU   6                                                        11370021
R7       EQU   7                                                        11400021
CIBREG   EQU   7                                                        11430021
RTNREG   EQU   7                                                        11460021
R8       EQU   8                                                        11490021
LCIBREG  EQU   8                                                        11520021
R9       EQU   9                                                        11550021
LKYWDREG EQU   9                                                        11580021
PARMSTOP EQU   9                                                        11610021
R10      EQU   10                                                       11640021
DCBREG   EQU   10                                                       11670021
KYWDREG  EQU   10                                                       11700021
R11      EQU   11                                                       11730021
LDSCTREG EQU   11                                                       11760021
KWDENREG EQU   11                                                       11790021
R12      EQU   12                                                       11820021
BASEREG  EQU   12                                                       11850021
R13      EQU   13                                                       11880021
R14      EQU   14                                                       11910021
RETREG   EQU   14                                                       11940021
R15      EQU   15                                                       11970021
CODEREG  EQU   15                                                       12000021
         SPACE 3                                                        12030021
*                            NUMBER EQUATES                             12060021
         SPACE 2                                                        12090021
ZERO     EQU   0                                                        12120021
ONE      EQU   1                                                        12150021
TWO      EQU   2                                                        12180021
THREE    EQU   3                                                        12210021
FOUR     EQU   4                                                        12240021
FIVE     EQU   5                                                        12270021
SIX      EQU   6                                                        12300021
SEVEN    EQU   7                                                        12330021
EIGHT    EQU   8                                                        12360021
NINE     EQU   9                                                        12390021
TEN      EQU   10                                                       12420021
RFLD     EQU   10                                                       12450021
TWELVE   EQU   12                                                       12510021
SXTN     EQU   16                                                       12520021
TWTY     EQU   20                                                       12530021
TWTYFOUR EQU   24                                                       12532021
TWTYSIX  EQU   26                                                       12750021
TWTYEIGT EQU   28                                                       12810021
THTYTW   EQU   32                                                       12840021
THTYSX   EQU   36                                                       12870021
THTYEIGT EQU   38                                                       12900021
FIFTYONE EQU   51                                                       13050021
FIFTYFIV EQU   55                  LENGTH OF LPA DIR ENTRY              13080021
N56      EQU   56                                                       13110021
SVNTY    EQU   70                                                       13140021
SVNTYONE EQU   71                                                       13170021
SVNTYTW  EQU   72                                                       13200021
N76      EQU   76                                                A44413 13224021
N79      EQU   79                                                 M1574 13226021
EIGHTY   EQU   80                                                       13230021
ONESXTY  EQU   160                                                      13260021
TWFTYFIV EQU   255                                                      13290021
TWFTYSIX EQU   256                                                      13320021
N13      EQU   13                                                       13350021
N22      EQU   22                                                       13380021
N38      EQU   38                                                       13410021
N46      EQU   46                                                       13440021
         EJECT                                                          13470021
*                            GENERAL EQUATES                            13500021
         SPACE 3                                                        13530021
ALIASBIT EQU   X'80'               BIT IN DIRECT ENTRY INDICATING       13560021
*                                  MODULE IS AN ALIAS                   13590021
REENTBIT EQU   X'80'               BIT INDICATING MODULE IS REENTRANT   13620021
REUSBIT  EQU   X'40'               BIT INDICATING MODULE IS REUSEABLE   13650021
SCATTBIT EQU   X'04'               BIT INDICATING SCATTER LOAD          13680021
GOODREAD EQU   X'00'                                                    13710021
BADREAD  EQU   X'FF'                                                    13740021
COMMA    EQU   X'6B'                                                    13770021
LFPAREN  EQU   X'4D'                                                    13800021
BLANK    EQU   X'40'                                                    13830021
CONSTK   EQU   X'D2'                                                    13860021
RTPAREN  EQU   X'5D'                                                    13890021
DCBOPEN  EQU   X'10'                                                    13920021
MODIFY   EQU   X'20'                                                    13950021
NOMODFY  EQU   X'40'                                                    13980021
FORMABIT EQU   X'FF'                                                    14010021
NOFORM   EQU   X'00'                                                    14040021
FORMBIT  EQU   X'0F'                                                    14070021
FRMERBIT EQU   X'10'                                                    14100021
NOLIST   EQU   X'40'                                                    14130021
LISTBIT  EQU   X'20'                                                    14160021
LSTERBIT EQU   X'10'                                                    14190021
BLDGD    EQU   X'FF'                                                    14220021
DUMPYES  EQU   X'FF'                                                    14250021
OFFBIT   EQU   X'00'                                                    14280021
ONBIT    EQU   X'FF'                                                    14310021
SMFBIT   EQU   X'1E'               USED TO RESET SMF FOREGROUND         14340021
*                                  BITS - OPT1,OPT2,EXT,& FOREGRND      14370021
CZERO    EQU   X'F0'               CHARACTER COMPARE                    14400021
CNINE    EQU   X'F9'               CHARACTER COMPARE                    14430021
HIBIT    EQU   X'80'                                                    14460021
MASKF    EQU   X'7F'                                                    14490021
         EJECT                                                          14520021
         STM   R14,R12,TWELVE(R13) SAVE SYSTEM REGISTERS                14550021
         BALR  BASEREG,ZERO                                             14580021
         USING *,BASEREG                                                14610021
         SPACE 3                                                        14640021
********************************************************************    14670021
*                                                                  *    14700021
*  SAVE THE ADDRESS PASSED IN REG1 FROM THE L SHAPED PROGRAM. GET  *    14730021
*  A TSC SAVE AREA AND WORK AREA AND CLEAR THE WORK AREA. MOVE THE *    14760021
*  BLDL LIST OF TSO MODULES INTO THE WORK AREA.                    *    14790021
*                                                                  *    14820021
********************************************************************    14850021
         SPACE 3                                                        14880021
         LR    PARMREG,R1          SAVE REG1                            14910021
         SPACE                                                          14940021
         LOAD  EP=IKJEAT09         TSC STAE EXIT ROUTINE                14970021
         LR    R6,R0               SAVE ADDRESS OF IKJEAT09             15000021
         STAE  (R6),CT,XCTL=YES    ISSUE STAE                           15030021
         LTR   R15,R15             TEST RETURN CODE FROM STAE           15060021
         BZ    STAEGOOD            0 RETURN CODE MEANS STAE ESTABLISHED 15090021
*                                  CONTINUE TSC INITIALIZATION          15120021
         WTO   'IKJ060I START REJECTED - UNABLE TO ESTABLISH A STAE ENVX15150021
               IRONMENT',ROUTCDE=(2),DESC=4                             15180021
         B     REJST9              STAE COULD NOT BE ESTABLISHED-       15210021
*                                  CANNOT START TSO                     15240021
STAEGOOD EQU   *                                                        15270021
         LA    R0,LWKAREA          GET LENGTH OF SAVE AND WORKAREA      15300021
         GETMAIN R,LV=(0)          GET AREA IN SUBPOOL=0                15330021
         ST    R13,FOUR(TSCSVE)    SAVE ADR CALLING RTNS SVE AREA       15360021
         ST    TSCSVE,EIGHT(R13)   SAVE ADR TSC SAVE AREA               15390021
         LR    R13,TSCSVE          SET UP REG13 WITH TSC SAVE AREA      15420021
         USING WKAREA,R13          SET UP ADDRESSABILITY OF WORK AREA   15450021
         LA    R6,LCLRAREA         GET LENGTH OF WK AREA TO CLEAR       15480021
         LA    R1,SVNTYTW(R1)      UPDATE ADR AREA PASS SAVE AREA       15510021
EXLOOP4  CH    R6,N256             IS LENGTH GR TH 256 BYTES            15540021
         BH    MOVE4               YES BRANCH                           15570021
         BCTR  R6,ZERO             DECREMENT LENGTH BY ONE              15600021
         EX    R6,CLEAR1           ZERO OUT AREA                        15630021
         LA    R1,BLDLS1           GET ADR BLDL LIST                    15660021
         LA    R3,BLDLLIST         GET ADR AREA FOR BLDL LIST           15690021
         LA    R6,LBLDL            GET LENGTH OF BLDL LIST              15720021
EXLOOP5  CH    R6,N256             IS LENGTH GR TH 256                  15750021
         BH    MOVE5               YES BRANCH                           15780021
         BCTR  R6,ZERO             DECREMENT LENGTH BY ONE              15810021
         EX    R6,MOVEBLDL         MOVE LIST INTO AREA                  15840021
         EJECT                                                          15870021
*********************************************************************   15900021
*                                                                   *   15930021
*  TEST IF TIME SHARING IS IN PROGRESS. IF IT IS IN PROGRESS THEN   *   15960021
*  WRITE OP THAT START TS IS REJECTED, FREE TSC SAVE AREA           *   15990021
*  AND WORK AREA AND RETURN TO THE CALLING PROGRAM. IF TIME SHARING *   16020021
*  IS NOT IN PROGRESS THEN CONTINUE.                                *   16050021
*                                                                   *   16080021
*********************************************************************   16110021
         SPACE 2                                                        16140021
         L     CVTREG,CVTPTR       GET ADDR CVT                         16170021
         USING CVTSECT,CVTREG      SET UP ADDRESSABILITY OF CVT         16200021
         LA    R5,CVTTSCVT         GET PTR TO ADR TSCVT                 16230021
         L     TSCVTREG,ZERO(R5)   GET ADDR TSCVT                       16260021
         LTR   TSCVTREG,TSCVTREG   DOES TSCVT EXIST                     16290021
         BZ    PROCPARM            NO CONTINUE                          16320021
         SPACE                                                          16350021
         MVI   REJSW,ONBIT         SET REJECT START TS SW               16380021
         B     PROCCIB             BR TO GET ADR CIB                    16410021
         DROP  CVTREG              DROP CVT                             16440021
REJSTTS  MVC   LISTMAC(WTO3L),WTO3 MOVE LIST FORM OF MACRO TO           16470021
         LA    R1,LISTMAC          WK AREA -GET ADR WK AREA             16500021
         USING CIBD,R7             SET UP CIB DSECT                     16530021
         SR    R0,R0               CLEAR REGISTER                       16560021
         IC    R0,CIBCONID         PUT CONSOLE ID INTO REG 0            16590021
         DROP  R7                  DROP CIB DSECT                       16620021
         WTO   MF=(E,(1))          WRITE TO OP- START REJECTED.         16650021
REJST1   LR    R1,R13              GET ADR TSC SAVE AND WK AREA         16680021
         L     R13,FOUR(R13)       RESTORE REG13                        16710021
         LA    R0,LWKAREA          GET LENGTH SVE AND WORK AREA         16740021
         FREEMAIN R,LV=(0),A=(1)   FREE TSC SVE AND WORK AREA           16770021
REJST9   LM    R14,R12,TWELVE(R13) RESTORE REGISTERS                    16800021
         BR    RETREG              RETURN TO CALLER                     16830021
         SPACE                                                          16860021
MOVE4    LA    R15,TWFTYFIV        GET NUMBER 255                       16890021
         EX    R15,CLEAR1          CLEAR 256 BYTES OF AREA              16920021
         SH    R6,N256             SUBTRACT 256 FROM LENGTH             16950021
         LA    R1,TWFTYSIX(R1)     UPDATE PTR TO AREA BY 256            16980021
         B     EXLOOP4             BR TO CONTINUE CLEARING AREA         17010021
         SPACE                                                          17040021
MOVE5    LA    R15,TWFTYFIV        GET NUMBER 255                       17070021
         EX    R15,MOVEBLDL        MOVE 256 BYTES                       17100021
         SH    R6,N256             SUBTRACT 256 FROM LENGTH             17130021
         LA    R1,TWFTYSIX(R1)     UPDATE PTR TO BLDL LIST BY 256       17160021
         LA    R3,TWFTYSIX(R3)     UPDATE PTR TO AREA BY 256            17190021
         B     EXLOOP5             BR TO CONTINUE MOVING BLDL LIST      17220021
*                                  TO WORK AREA                         17250021
         EJECT                                                          17280021
         SPACE 2                                                        17310021
********************************************************************    17340021
*                                                                  *    17370021
*  TEST IF AN ADR OF THE PARM WAS PASSED IN REG 1 FROM THE L       *    17400021
*  SHAPED PROGRAM. IF IT WAS THEN FREE THAT PARM. ALSO PUT AN ADR  *    17430021
*  IN THE CVTTSCVT WHICH MEANS TIME SHARING IS IN PROGRESS.        *    17460021
*                                                                  *    17490021
********************************************************************    17520021
         SPACE 3                                                        17550021
PROCPARM LTR   PARMREG,PARMREG     WAS ADDR PARM PASSED IN REG1         17580021
         BZ    PROCSPL             NO-BRANCH                            17610021
         LR    R1,PARMREG          YES, SET REG1 WITH ADR PARM   A70433 17640021
         L     PARMREG,ZERO(,PARMREG)  GET ADR PARM           CC A70433 17670021
         LH    PARMREG,ZERO(,PARMREG)   GET LENGTH PARM       CC A70433 17700021
         LA    R0,EIGHT(,PARMREG)  ADD EIGHT TO LENGTH        CC A70433 17730021
         FREEMAIN R,LV=(0),A=(1)   FREE PARM                            17760021
PROCSPL  ST    R5,ZERO(R5)         LET ADR TSCVT POINT TO ITSELF        17790021
         SPACE 5                                                        17820021
*********************************************************************** 17850021
*                                                                     * 17880021
*  THIS SECTION BRANCHES AND LINKS TO THE CIB ROUTINE, WHICH          * 17910021
*  SCANS THE CIB FOR THE FORM OPTION,THE LIST OPTION,AND THE MEMBER   * 17940021
*  NME WHICH CONTAINS THE PARM DATA. IF EITHER OF THESE ARE NOT GIVEN * 17970021
*  IN THE CIB, THEN DEFAULT VALUES ARE USED. THE DEFAULT FOR THE FORM * 18000021
*  AND LIST OPTION IS NO FORM AND NO LIST. THE DEFAULT FOR THE        * 18030021
*  MEMBER NME IS IKJPRM00. IF THERE IS AN ERROR IN THE CIB FOR EITHER * 18060021
*  OF THESE OPTIONS THEN A SWITCH IS SET. UPON RETURN FROM THE CIB    * 18090021
*    ROUTINE A WTOR IS ISSUED FOR THE CORRECT OPTION. THE OP CAN      * 18120021
*  CHOSE TO REPLY A SPECIFIC OPTION, OR HE CAN REPLY A U WHICH MEANS  * 18150021
*  TO USE THE DEFAULT VALUE, OR HE CAN REPLY CANCEL WHICH MEANS TO    * 18180021
*  REJECT START TS.                                                   * 18210021
*                                                                     * 18240021
*********************************************************************** 18270021
         SPACE 3                                                        18300021
PROCCIB  LA    R7,EXTREPLY         GET ADDR REPLY FIELD FOR EXTRACT     18330021
         LA    R1,EXTINPUT         GET ADDR INPUT FIELD FOR EXTRACT     18360021
         EXTRACT (R7),'S',FIELDS=(COMM),MF=(E,(1))                      18390021
         L     CPLREG,EXTREPLY     GET ADR CPL RETURNED FR EXTRACT      18420021
         ST    CPLREG,CPLADR       SAVE ADR CPL IN WK AREA              18450021
         L     CIBREG,FOUR(CPLREG) GET ADR CIB                          18480021
         TM    REJSW,ONBIT         IS REJECT START TS SW ON             18510021
         BO    REJSTTS             YES BRANCH                           18540021
         L     R15,CIBRTNME        GET ADR CIB RTN                      18570021
         BALR  R14,R15             BRANCH                               18600021
         TM    LISTSW,LSTERBIT     WAS LIST PARAM IN ERROR              18630021
         BO    PROCLTER            YES BR AND ISSUE WTOR                18660021
PROCFORM TM    FORMSW,FORMABIT     IS FORM=ALL OPTION SET               18690021
         BO    PROCNAME            YES BRANCH AND CONTINUE              18720021
         TM    FORMSW,FRMERBIT     WAS FORM PARAM IN ERROR              18750021
         BZ    PROCNAME            NO CONTINUE                          18780021
         SPACE 2                                                        18810021
WTOR3LP  MVC   LISTMAC(WTOR3L),WTOR3 MOVE WTOR LIST TO WK AREA          18840021
         BAL   R6,WTORRTN          BR TO WTOR RTN                       18870021
         B     REJST7              REJECT START TS                      18900021
         CLC   REPLYAD(EIGHT),FORMALL DOES REPLY EQ FORM=ALL OPTION     18930021
         BE    PROCFRMA            YES BRANCH                           18960021
         CLC   REPLYAD(FOUR),FORM  DOES REPLY EQ FORM OPTION            18990021
         BE    PROCFRM             YES BRANCH                           19020021
         CLC   REPLYAD(ONE),U      DOES REPLY EQ DEFLT OPTION           19050021
         BNE   WTOR3LP             NO-BR AND RE ISSUE WTOR              19080021
         MVI   FORMSW,NOFORM       YES- SET FORM SW TO NO FORM          19110021
         B     PROCNAME            CONTINUE                             19140021
PROCFRMA MVI   FORMSW,FORMABIT     SET FRM SW TO FORM=ALL               19170021
         B     PROCNAME            CONTINUE                             19200021
PROCFRM  MVI   FORMSW,FORMBIT      SET FRM SW TO FORM OPTION            19230021
         B     PROCNAME            CONTINUE                             19260021
PROCLTER MVC   LISTMAC(WTOR2L),WTOR2 MOVE WTOR LIST TO WK AREA          19290021
         BAL   R6,WTORRTN          BR TO ISSUE WTOR                     19320021
         B     REJST7              REJECT START TS                      19350021
         CLC   REPLYAD(FOUR),LIST  DOES REPLY EQ LIST OPTION            19380021
         BE    PROCLIST            YES BRANCH                           19410021
         CLC   REPLYAD(ONE),U      DOES REPLY EQ DFLT OPTION            19440021
         BNE   PROCLTER            NO BR AND RE ISSUE WTOR              19470021
         MVI   LISTSW,NOLIST       SET LIST SW TO NO LIST OPTION        19500021
         B     PROCFORM            BR TO TEST FORM SWITCH               19530021
PROCLIST MVI   LISTSW,LISTBIT      SET LIST SW TO LIST OPTION           19560021
         B     PROCFORM            BR AND TEST FORM SW                  19590021
         EJECT                                                          19620021
         SPACE 3                                                        19650021
********************************************************************    19680021
*                                                                  *    19710021
*  THIS SECTION OPENS THE DATA SET.IF THE OPEN IS NOT SUCESSFUL    *    19740021
* A WTO IS ISSUED TELLING THE OPERATOR THE OPEN FAILED AND START   *    19770021
*  TS IS REJECTED. IF THE DATA SET IS OPENED WE CONTINUE.          *    19800021
*                                                                  *    19830021
********************************************************************    19860021
         SPACE 4                                                        19890021
PROCNAME MVC   DCBPARM(DCBEND-SYS1PARM),SYS1PARM MVE DCB INTO WK AREA   19920021
         MVC   LISTMAC(OPENEND-OPENDCB),OPENDCB MVE OPEN LIST TO WK AR  19950021
         LA    R6,DCBPARM          GET ADR DCB IN WK AREA               19980021
         LA    R1,LISTMAC          GET ADR OPEN LIST IN WK AREA         20010021
         OPEN  ((6)),MF=(E,(1))    OPEN SYS1.PARMLIB                    20040021
         SPACE                                                          20070021
         TM    DCBFLAG,DCBOPEN     HAS IT BEEN SUCCESSFULLY OPENED      20100021
         BO    FINDMEMB            YES- BRANCH TO FIND MEMBER           20130021
         SPACE 2                                                        20160021
         MVC   LISTMAC(WTO1L),WTO1 NO- MOVE LIST FORM OF WTO            20190021
         LA    R1,LISTMAC          GET ADR  WTO LIST IN WK AREA         20220021
         SR    R0,R0               CLEAR REGISTER                       20250021
         IC    R0,CONSLID          PUT CONSOLE ID INTO REG 0            20280021
         WTO   MF=(E,(1))          ISSUE WTO OPENED FAILED              20310021
         SPACE                                                          20340021
REJST7   EQU   *                                                        20370021
         TM    DCBFLAG,DCBOPEN         WAS DCB OPENED?                  20400021
         BNO   REJST7A                 IF SO, PARMLIB MUST BE           20430021
*                                      CLOSED BEFORE TERM.              20460021
         MVC   LISTMAC(DCBLEND-DCBCLOSE),DCBCLOSE    LIST FORM          20490021
         LA    R1,LISTMAC                                               20520021
         LA    R6,DCBPARM              PTR TO DCB IN WORK AREA          20550021
         CLOSE ((R6)),MF=(E,(1))                                        20580021
REJST7A   EQU  *                                                        20610021
         L     CVTREG,CVTPTR           GET ADDR CVT                     20640021
         USING CVTSECT,CVTREG      SET UP ADDRESSABILITY OF CVT         20670021
         XC    CVTTSCVT(FOUR),CVTTSCVT  CLEAR ADR TSCVT                 20700021
         DROP  CVTREG              DROP CVT                             20730021
         B     REJST1              REJECT START TS                      20760021
         EJECT                                                          20790021
*********************************************************************** 20820021
*                                                                     * 20850021
*  THIS SECTION ISSUES A FIND ON THE MEMBER NAME.IF THE MEMBER        * 20880021
*  CANNOT BE FOUND THEN A WTO IS ISSUED AND ALSO A WTOR ASKING THE    * 20910021
*  OPERATOR FOR THE CORRECT MEMBER NAME. THE OP CAN REPLY A MEMBER    * 20940021
*  NAME OR A U WHICH MEANS USE THE DEFAULT MEMBER NAME, AFTER         * 20970021
*  WHICH THE FIND IS REISSUED. HE CAN ALSO REPLY CANCEL WHICH REJECTS * 21000021
*  START TS. IF AN IO ERROR OCCURS DURING THE FIND A WTO IS ISSUED    * 21030021
*  AND START TS IS REJECTED.IF THE MEMBER IS FOUND WE CONTINUE.       * 21060021
*                                                                     * 21090021
*********************************************************************** 21120021
         SPACE 2                                                        21150021
FINDMEMB FIND  DCBPARM,PARMNAME,D  FIND SPECIFIED MEMBER                21180021
         B     *+FOUR(CODEREG)     BRANCHING TABLE DEPENDING            21210021
*                                  ON RETURN CODE IN REG 15             21240021
         B     FINDGOOD            IF CODE=0- SUCCESSFUL FIND           21270021
         B     FINDNOGD            IF CODE=4- MEMBER NOT FOUND          21300021
         B     IOERROR             IF CODE=8- IO ERROR                  21330021
         SPACE 2                                                        21360021
FINDNOGD MVC   LISTMAC(WTO2L),WTO2 ISSUE WTO FOR MEMBER NT FOUND        21390021
         LA    R1,LISTMAC          GET ADR WTO LIST IN WK AREA          21420021
         SR    R0,R0               CLEAR REGISTER                       21450021
         IC    R0,CONSLID          PUT CONSOLE ID INTO REG 0            21480021
         WTO   MF=(E,(1))          ISSUE WTO                            21510021
         MVC   LISTMAC(WTOR1L),WTOR1 MVE LIST OF WTOR INTO WK AREA      21540021
         BAL   R6,WTORRTN          BR AND WTOR FOR MEMBER NAME          21570021
         B     REJST7              REJECT START TS                      21600021
         SPACE                                                          21630021
         CLC   REPLYAD(ONE),U      DOES REPLY EQ DEFAULT OPTION         21660021
         BE    DFLTNME             YES BRANCH                           21690021
         MVC   PARMNAME(EIGHT),REPLYAD MVC NAME INTO WK AREA            21720021
         B     FINDMEMB            TRY TO FIND MEMBER AGAIN             21750021
         SPACE                                                          21780021
DFLTNME  MVC   PARMNAME(EIGHT),DFNAME   MVE DF NAME TO WK AREA          21810021
         B     FINDMEMB            BR TO FIND MEMBER AGAIN              21840021
         SPACE 2                                                        21870021
IOERROR  MVC   LISTMAC(WTO4L),WTO4 MVE WTO LIST TO WK AREA              21900021
         LA    R1,LISTMAC          GET ADR WTO LIST IN WK AREA          21930021
         SR    R0,R0               CLEAR REGISTER                       21960021
         IC    R0,CONSLID          PUT CONSOLE ID INTO REG 0            21990021
         WTO   MF=(E,(1))          TELL OP THERE IS AN IO ERROR         22020021
         B     REJST7              BR AND REJECT START TS               22050021
         SPACE 2                                                        22080021
**********************************************************************  22110021
*                                                                    *  22140021
*  THIS SECTION BRANCHES AND LINKS TO THE PARM ROUTINE WHICH         *  22170021
*  READS THE PARM DATA INTO A BUFFER AND THEN CLOSES THE DATA SET.   *  22200021
*  IT ALSO MOVES THE CIB MODIFYS INTO THE BUFFER. IT MOVES FIVE      *  22230021
*  BLANK DRIVER CARDS INTO THE BUFFER WHICH ARE NEEDED BY THE        *  22260021
*  DRIVER. IF AN IO ERROR OCCURS WHILE READING THE PARM DATA, A      *  22290021
*  WTO IS ISSUED AND START TS IS REJECTED.                           *  22320021
*                                                                    *  22350021
**********************************************************************  22380021
         SPACE 2                                                        22410021
FINDGOOD L     R15,PRMRTNME        GET ADR PARM RTN                     22440021
         BALR  R14,R15             BR AND LINK TO PARM ROUTINE          22470021
         B     TESTLIST            GOOD READ SO CONTINUE                22500021
         SPACE                                                          22530021
         MVC   LISTMAC(WTO4L),WTO4 YES WRITE MSG TO OP                  22560021
         LA    R1,LISTMAC          GET ADR LIST WTO                     22590021
         SR    R0,R0               CLEAR REGISTER                       22620021
         IC    R0,CONSLID          PUT CONSOLE ID INTO REG 0            22650021
         WTO   MF=(E,(1))          ISSUE WTO  FOR BAD READ              22680021
         B     REJST7              REJECT START TS                      22710021
         SPACE 2                                                        22740021
**********************************************************************  22770021
*                                                                    *  22800021
*  THIS SECTION TESTS WHETHER THE LIST OPTION WAS SPECIFIED IN THE   *  22830021
*  CIB. IF THE LIST OPTION WAS SPECIFIED THE ENTIRE PARM BUFFER IS   *  22860021
*  PRINTED OUT TO THE CONSOLE. THIS INCLUDES THE MEMBER PLUS ANY     *  22890021
*  START OVERRIDES. IF NO LIST WAS SPECIF WE BR AROUND THIS SECTION  *  22920021
*                                                                    *  22950021
**********************************************************************  22980021
         SPACE 2                                                        23010021
TESTLIST TM    LISTSW,LISTBIT      IS LIST OPTION SPECIFIED             23040021
         BZ    NOLSTPRM            NO BRANCH                            23070021
         SPACE                                                          23100021
         L     R2,PARMADR          GET ADR OF BEG PARM DATA             23130021
         L     R9,PARMEND          GET END ADDR OF PARM DATA            23160021
         MVC   LISTMAC(FOUR),WTO8  MOVE IN WTO FLAGS                    23190021
LPRMLOOP MVC   LISTWTO(EIGHTY),ZERO(R2) MOVE FIRST CARD IN WTO BUF      23220021
         LA    R1,LISTMAC          GET ADR WTO BUF                      23250021
         SR    R0,R0               CLEAR REGISTER                       23280021
         IC    R0,CONSLID          PUT CONSOLE ID INTO REG 0            23310021
         WTO   MF=(E,(1))          LIST CARD FR PARM TO OP              23340021
         SPACE 3                                                        23370021
         LA    R2,EIGHTY(R2)       UPDATE PTR TO PARM DATA              23400021
         CR    R2,R9               IS IT END PARM DATA                  23430021
         BNE   LPRMLOOP            NO-CONTINUE LISTING PARM DATA        23460021
         TM    MODIFYSW,MODIFY     ARE THERE ANY OVERRIDES              23490021
         BZ    NOLSTPRM            NO BRANCH                            23520021
         L     R9,MODFYADR         GET BEG ADDRESS OF CIB MODIFYS       23550021
         L     R2,CIBENDAD         GET END ADDRESS OF CIB MODIFYS       23580021
         SR    R2,R9               GET LENGTH OF OVERRIDES              23610021
         LA    R1,LISTMAC          GET ADR OF LIST FORM OF WTO          23640021
EXLOOP6  MVC   LISTMAC(WTO8L),WTO8 MVE WTO INTO WK AREA                 23670021
         CH    R2,N71              IS LENGTH GR TH 71                   23700021
         BH    MOVE6               YES- BRANCH                          23730021
         BCTR  R2,ZERO             NO-DECREMENT LENGTH BY ONE           23760021
         EX    R2,MOVEMODS         MOVE OVERRIDES INTO WK AREA          23790021
         SR    R0,R0               CLEAR REGISTER                       23820021
         IC    R0,CONSLID          PUT CONSOLE ID INTO REG 0            23850021
         WTO   MF=(E,(1))          PUT OUT TO CONSOLE                   23880021
         B     NOLSTPRM            CONTINUE                             23910021
         SPACE                                                          23940021
MOVE6    LA    R15,SVNTY           GET NUMBER 70                        23970021
         EX    R15,MOVEMODS        MVE 71 BYTES OF OVERRIDES TO AREA    24000021
         SH    R2,N71              DECREMENT LENGTH OF OVERRIS          24030021
         LA    R9,SVNTYONE(R9)     UPDTE PT TO OVERRIDES BY 71          24060021
         B     EXLOOP6             BR TO CONTINUE LISTING               24090021
         EJECT                                                          24120021
*********************************************************************   24150021
*                                                                       24180021
*  THIS CODE BRANCHES TO THE EDIT RTN.THE TSC PARAMETERS AND VALUES *   24210021
*  IN THE PARM BUFFER ARE EDITED. IF THEY ARE VALID THEN THEY ARE   *   24240021
*  SAVED IN THE WORK AREA. IF THEY ARE NOT VALID THEY ARE IGNORED   *   24270021
*                                                                   *   24300021
*********************************************************************   24330021
         SPACE 2                                                        24360021
NOLSTPRM L     R15,EDRTNME         GET ADR EDIT RTN                     24390021
         BALR  R14,R15                                                  24420021
         B     REJST8              REJECT START TS                      24450021
         SPACE 6                                                        24480021
*********************************************************************   24510021
*                                                                   *   24540021
*  THIS CODE BRANCHES TO THE PARM TEST RTN WHERE A TEST IS MADE TO  *   24570021
*  MAKE SURE NECESSARY PARAMETERS WERE GIVEN IN THE PARM BUFFER. IF *   24600021
*  ANY NECESSARY VALUES ARE MISSING A WTOR IS ISSUED. IF THE OP     *   24630021
*  RETURNS A GOOD VALUE IT IS SAVED. IF IT IS A BAD VALUE THE WTOR  *   24660021
*  IS REISSUED. IF THE OP CANCELS THEN START TS IS REJECTED.        *   24690021
*                                                                   *   24720021
*********************************************************************   24750021
         SPACE 2                                                        24780021
         L     R15,PRMTNME         GET ADR PARM TEST RTN                24810021
         BALR  R14,R15                                                  24840021
         B     REJST8              REJECT START TS                      24870021
         EJECT                                                          24900021
         SPACE 4                                                        24930021
*********************************************************************   24960021
*                                                                   *   24990021
*  THIS SECTION GETMAINS AN AREA FOR THE TSC PARAMETER LIST AND     *   25020021
*  THE TSC TABLE. IT INITIALIZES THEM WITH THE VALUES RECEIVED      *   25050021
*  FROM THE PARM DATA OR OVERRIDES ON THE START COMMAND OR REPLYS   *   25080021
*  TO WTORS.                                                        *   25110021
*                                                                   *   25140021
*********************************************************************   25170021
         SPACE 5                                                        25200021
T00PARM  EQU   *                                                        25230021
         LA    R1,FOUR                                                  25260021
         MH    R1,REGNUM           GET LENGTH  = 1 WRD FOR EACH REGION  25290021
         LA    R0,LTSCTAB          GET LENGTH FIXED TSC TABLE           25320021
         AR    R0,R1               ADD TWO LENGTHS=L OF TABLE           25350021
         LR    R11,R0              SAVE LENGTH TSC TABLE                25380021
         AH    R0,N32              ADD LENGTH PARM LST                  25410021
         SPACE                                                          25440021
         GETMAIN R,LV=(0)          GETMAIN AN AREA FOR THAT LENGTH      25470021
         SPACE                                                          25500021
         LR    PARMLST,R1          SAVE ADR OF AREA                     25530021
         MVC   ZERO(SXTN,PARMLST),MAXUSER  INITIALIZE PARM LIST         25560021
         XC    SXTN(EIGHT,PARMLST),SXTN(PARMLST)  ZERO TWO WDS IN LIST  25590021
         MVC   TWTYFOUR(FOUR,PARMLST),CPLADR  PUT ADR CPL IN PRMLST     25620021
         LA    R1,THTYTW(PARMLST)  GET ADR TSC TABLE                    25650021
         ST    R1,TWTYEIGT(PARMLST) PUT ADR IN PARM LIST                25680021
         MVC   TWTYEIGT(ONE,PARMLST),DMPSW SET DUMP SW IN PARM LIST     25710021
         ST    R11,THTYTW(PARMLST) PUT LENGTH OF TSC TAB IN PARM LIST   25740021
         LA    R1,FOUR             GET NUMBER=4                         25770021
         SR    R11,R1              DECREMENT L OF TSC TABLE BY FOUR     25800021
         BCTR  R11,ZERO            DECREMENT LENGTH BY ONE              25830021
         EX    R11,MOVETAB         INITIALIZE TSC TABLE                 25860021
         EJECT                                                          25890021
*********************************************************************   25920021
*                                                                   *   25950021
*  THIS SECTION LINKS TO SWAP,TIOC, AND DRIVER. THE ADDRESS OF THE  *   25980021
*  PARM LIST IS PASSED IN REG1. THE MODULES ARE TO COMPUTE THE      *   26010021
*  AMOUNT OP MAIN STORAGE THEY NEED AND RETURN THE AMOUNT IN +16 OF *   26040021
*  THE PARM LIST AND ALSO A RETURN CODE=0. IF THEY ARE NOT ABLE TO  *   26070021
*  COMPUTE THE MAIN STORAGE NEEDED THE RETURN CODE=8. IN THIS CASE  *   26100021
*  START TS IS REJECTED.                                            *   26130021
*                                                                   *   26160021
*********************************************************************   26190021
         SPACE 3                                                        26220021
*                             LINK TO SWAP                          *   26250021
         SPACE                                                          26280021
T00LINK  EQU   *                                                        26310021
         MVC   LISTMAC(LINKEND-LINKLIST),LINKLIST MVE LST FRM LINK      26340021
*                                  TO WORK AREA                         26370021
         LA    R15,LISTMAC                                              26400021
         LR    R1,PARMLST          PUT ADR PARM LIST IN REG 1           26430021
         LA    R11,SWAP                                                 26460021
         LINK  EPLOC=(R11),SF=(E,(15))  LINK TO SWAP ROUTINE            26490021
         B     TAB1(R15)           IS RETURN CODE ZERO                  26520021
TAB1     B     LINKGD1                                                  26550021
         B     LINKGD1             NO-BRANCH AND REJECT START TS        26580021
         B     REJST2                                                   26610021
         SPACE 3                                                        26640021
*                             LINK TO TIOC                          *   26670021
         SPACE                                                          26700021
LINKGD1  EQU   *                                                        26730021
         L     R2,SXTN(PARMLST) R2=AMT.OF STORAGE RETURNED.             26760021
         SR    R5,R5         INDICATE NO NAME.                          26790021
         BAL   R14,SREBUILD  BUILD SRE FOR STOARAGE.                    26820021
         XC    SXTN(FOUR,PARMLST),SXTN(PARMLST)  CLEAR WORD IN          26850021
*                                  PARM LST FOR MAIN STOR NEEDED        26880021
         MVC   LISTMAC(LINKEND-LINKLIST),LINKLIST  PUT LINK LST IN      26910021
         LA    R15,LISTMAC         WORK AREA                            26940021
         LR    R1,PARMLST          PUT ADR PARM LIST IN REG1            26970021
         LA    R11,TIOC                                                 27000021
         LINK  EPLOC=(R11),SF=(E,(15))  LINK TO TIOC AND GET AMT OF MS  27030021
         B     TAB2(R15)           IS RETURN CODE=0                     27060021
TAB2     B     LINKGD2                                                  27090021
         B     LINKGD2             NO-BRANCH AND REJECT START TS        27120021
         B     REJST2                                                   27150021
         EJECT                                                          27180021
         SPACE 3                                                        27210021
*                             LINK TO DRIVER                        *   27240021
         SPACE                                                          27270021
LINKGD2  EQU   *                                                        27300021
         L     R2,SXTN(PARMLST) R2=AMT.OF STORAGE RETURNED.             27330021
         SR    R5,R5         INDICATE NO NAME.                          27360021
         BAL   R14,SREBUILD  BUILD SRE FOR STOARAGE.                    27390021
         XC    SXTN(FOUR,PARMLST),SXTN(PARMLST)  CLEAR WORD IN          27420021
*                                  PARM LIST FOR MAIN ST NEEDED         27450021
         MVC   LISTMAC(LINKEND-LINKLIST),LINKLIST  PUT LINK LST         27480021
         LA    R15,LISTMAC         IN WORK AREA                         27510021
         MVC   TWTY(FOUR,PARMLST),DRVRCIB PUT ADR OVERRIDES IN PARMLST  27540021
         LR    R1,PARMLST          PUT ADR OF PARM LIST IN REG1         27570021
         MVC   DRVCDE(TWO),DRVCD1  PUT DRVR CODE IN DRVR NME            27600021
         LA    R11,DRVR            GET ADDR DRIVER RTN                  27630021
         LINK  EPLOC=(R11),SF=(E,(15))  LINK TO DRIVER                  27660021
         B     TAB3(R15)           IS RETURN CODE=0                     27690021
TAB3     B     LINKGD3                                                  27720021
         B     LINKGD3             NO-BRANCH AND REJECT START TS        27750021
         B     REJST2                                                   27780021
         SPACE 4                                                        27810021
*********************************************************************   27840021
*                                                                   *   27870021
*  THIS SECTION BRANCHES TO THE CONTROL BLOCK ROUTINE WHICH COMPUTES    27900021
*  THE AMOUNT OF MAIN STORAGE NEEDED FOR ALL THE TSO CONTROL BLOCKS.*   27930021
*  THE AMOUNT IS ADDED TO THE TOTAL AMOUNT OF MAIN STORAGE NEEDED.  *   27960021
*                                                                   *   27990021
*********************************************************************   28020021
         SPACE 2                                                        28050021
LINKGD3  EQU   *                                                        28080021
         L     R2,SXTN(PARMLST) R2=AMT.OF STORAGE RETURNED.             28110021
         SR    R5,R5         INDICATE NO NAME.                          28140021
         BAL   R14,SREBUILD  BUILD SRE FOR STOARAGE.                    28170021
         MVC   SXTN(FOUR,PARMLST),DRVRCIB  SAVE PTR TO OVERRIDES FOR    28200021
*                                 DRIVER  TO BE USED IN IKJEAT02        28230021
         L     R15,CNBRTNME       GET ADR CONTRL BLK RTN                28260021
         BALR  R14,R15                                                  28290021
*                                  STORAGE FOR CONTROL BLOCKS           28320021
         L     R2,SZECNBLK   R2=AMT.OF CNTRL BLOCK STORAGE REQUIRED.    28350021
         LA    R5,ONE        SET R5 NEGATIVE.                           28380021
         LCR   R5,R5         *                                          28410021
         BAL   R14,SREBUILD  BUILD SRE FOR STOARAGE.                    28440021
         EJECT                                                          28470021
*********************************************************************   28500021
*                                                                   *   28530021
*  THIS SECTION ISSUES BLDL'S FOR TSO MODULES AND DRIVER MODULES,   *   28560021
*  AND THE AMOUNT OF MAIN STORAGE NEEDED FOR EACH OF THESE MODULES  *   28590021
*  IS ADDED TO THE TOTAL AMOUNT OF MAIN STORAGE NEEDED. IF A BLDL   *   28620021
*  FAILS FOR ANY MODULE A WTO IS ISSUED AND START TS IS REJECTED.   *   28650021
*                                                                   *   28680021
*********************************************************************   28710021
         SPACE 4                                                        28740021
T00BLDL  EQU   *                                                        28770021
         SR    R1,R1                                                    28800021
         LA    R0,BLDLS            GET ADR OF LIST FOR TSO MODULES      28830021
         SR    R15,R15             CLEAR RETURN CODE REGISTER           28860021
         BLDL  (1),(0)             DO A BLDL TO GET SIZE TSO MODULES    28890021
         B     TAB4(R15)           BRANCH TO TAB4 INDEXED BY RET CODE   28920021
TAB4     B     BLDGD1             BLDL GOOD                             28950021
         B     REJST3              BLDL FAILED FOR SOME MODULE          28980021
         B     REJST4              I/O ERROR DURING DIRECTORY SEARCH    29010021
         SPACE                                                          29040021
BLDGD1   LA    R2,BLDLS            GET ADR OF LIST                      29070021
         BAL   R14,BLDRTN          COMPUTE MS FOR MODULES               29100021
         SPACE                                                          29130021
         SR    R1,R1                                                    29160021
         LA    R0,DRVLST           GET ADR BLD LIST FOR DRIVER MODS     29190021
         SR    R15,R15             CLEAR RET CODE REG.                  29220021
         BLDL  (1),(0)             ISSUE BLDL                           29250021
         B     TAB5(R15)           BR TO TAB5 INDEXED BY RET CODE       29280021
TAB5     B     BLDGD2              BLDL GOOD                            29310021
         B     BLDNG2              BLDL FAILED FOR SOME DRVR MODULE     29340021
         B     REJST4              I/O ERROR DURING DIRECTORY SEARCH    29370021
         SPACE                                                          29400021
BLDGD2   LA    R2,DRVLST           GET ADR DRVR MODULE LIST             29430021
         BAL   R14,BLDRTN          BR AND COMPUTE MS NEEDED FOR MODS    29460021
         EJECT                                                          29490021
*  ADD TO TOTAL AMT MAIN STORAGE NEEDED THE AMT NEEDED FOR LPA MODULES  29520021
         SPACE 2                                                        29550021
         SPACE 3                                                        29580021
*****    THE FOLLOWING SECTION OF CODE WAS ADDED FOR APAR 44022 *****   29610021
**********************************************************************  29640021
*  THIS SECTION USES THE CHAIN OF STORAGE REQUEST ELEMENTS CONSTRUCT- * 29670021
*  ED DURING THE PRECEDING PROCESSING TO CALCULATE THE STORAGE RE-    * 29700021
*  QUIRED FOR THE TSC REGION. IF A 'TSCREGSZ' PARAMETER IS SPECIFIED, * 29730021
*  HOWEVER,THAT VALUE IS USED AND THE CALCULATION IS SKIPPED.         * 29760021
*                                                                     * 29790021
         SPACE 3                                                        29820021
REGSIZE  EQU   *                                                        29850021
*        REPLACE WITH INSTRUCTIONS TO TEST TSCREGSZ,IF NON-ZERO,STORE   29880021
*        BINARY VALUE IN TWTY(PARMLST) AND BRANCH TO T00END.            29910021
         SPACE                                                          29940021
         L     R2,SRECHAIN       R2=BEGINNING OF SRE CHAIN.             29970021
RSZLOOP1 EQU   *                 R2=ENTRY POINTER.                      30000021
         LTR   R2,R2             Q.END OF CHAIN.                        30030021
         BZ    ADD               YES,GO THRU AGAIN AND ADD IT UP.       30060021
         USING SRE,R2            *                                      30090021
         L     R4,SRESIZE        R4=SIZE FOR THIS ENTRY.                30120021
         XC    SRESIZE,SRESIZE         SET ENTRY SIZE FIELD TO ZERO.    30150021
         L     R5,SRECHAIN       R5=CURRENT POINTER.                    30180021
HOLECHK  EQU   *                                                        30210021
         L     R9,SRESIZE-SRE(R5) R9=CURRENT SRE SIZE FIELD.            30240021
         A     R9,PLUS2K         ADD ROUNDING 2K                        30270021
         N     R9,TWKMASK        ROUND UP TO 2K                         30300021
         S     R9,SRESIZE-SRE(R5) R9='HOLE' SIZE                        30330021
         CR    R9,R4             Q.DOES SAVED SIZE FIT THE 'HOLE'       30360021
         BNL   SQUEEZE           YES,ADD SAVED SIZE TO CURRENT SRESIZE. 30390021
         NC    SRESIZE-SRE(FOUR,R5),SRESIZE-SRE(R5) Q. IS CURRENT       30420021
*                                SRESIZE ZERO.                          30450021
         BZ    SQUEEZE           YES,ADD SAVED SIZE TO CURRENT SRESIZE. 30480021
         L     R5,SRELINK-SRE(R5) NO,R5=NEXT SRE ADDRESS.               30510021
         B     HOLECHK           KEEP GOING TIL A SQUEEZE WORKS OR WE   30540021
*                                CATCH UP TO 'ENTRY' SRE.               30570021
SQUEEZE  EQU   *                                                        30600021
         A     R4,SRESIZE-SRE(R5) ADD SAVED SIZE TO CURRENT SRESIZE.    30630021
         ST    R4,SRESIZE-SRE(R5) *                                     30660021
         L     R2,SRELINK        POINT TO NEXT SRE.                     30690021
         B     RSZLOOP1                                                 30720021
ADD      EQU   *                                                        30750021
*        ACCUMULATE ADJUSTED SIZES,ROUNDING UP TO 2K FOR EACH SRESIZE.  30780021
         SPACE                                                          30810021
         L     R2,SRECHAIN       R2=1ST SRE ADDR.                       30840021
         SR    R9,R9             ZERO ACCUMULATOR                       30870021
RSZLOOP2 EQU   *                                                        30900021
         LTR   R2,R2             Q.ANY MORE SRE'S.                      30930021
         BZ    T00END            NO,FINISH UP.                          30960021
         NC    SRESIZE,SRESIZE Q. SRESIZE FOR THIS ENTRY ZERO.          30990021
         BZ    T00END            YES,FINISH UP.                         31020021
         A     R9,SRESIZE        YES,ADD SIZE TO ACCUMULATOR.           31050021
         A     R9,PLUS2K         ROUND ACCUMULATOR UP TO                31080021
         N     R9,TWKMASK        NEXT 2K MULTIPLE AND                   31110021
         L     R2,SRELINK        GET NEXT SRE.                          31140021
         B     RSZLOOP2          DO IT AGAIN TIL SRE'S ARE ALL CHECKED  31170021
*                                OR TIL WE FALL INTO ONE WITH A SIZE    31200021
*                                FIELD OF ZERO.                         31230021
         SPACE 2                                                        31260021
*********************************************************************   31290021
*  THE PRE-INITIALIZATION IS COMPLETE.  PREPARE TO XCTL TO IKJEAT01 *   31320021
*  MOVE THE PARM DATA, PARM LIST AND THE TSC TABLE TO SUBPOOL 254   *   31350021
*  ADDR. OF PARM LIST IN REG. 1 WHEN XCTL'ING TO IKJEAT01           *   31380021
*********************************************************************   31410021
         SPACE 2                                                        31440021
T00END   EQU   *                                                        31470021
         CLC   TSCRGSZE(FOUR),EMPTY     TEST FOR TSC REG SIZE ALREADY   31500021
         MVC   TWTY(FOUR,PARMLST),TSCRGSZE LIST VIA TSCREGSZ KEYWORD.   31530021
         BNE    NEWREGN1               SPECIFIED ON START TSO OR PARM   31560021
         A     R9,SIXK       BUMP R9 TO ALLOW FOR T02 & ATTACH RCT      31590021
*                            SPACE REQUIREMENTS.                        31620021
         ST    R9,TWTY(PARMLST)        STORE TSC RESIZE IN PARM LIST.   31650021
NEWREGN1 EQU   *                        WILL USE CALCULATED SIZE.       31680021
*****             THIS ENDS THE SECTION OF CODE ADDED FOR APAR 44022 ** 31710021
         L     R2,CVTPTR           GET ADDRESS OF CVT                   31740021
         USING CVTSECT,R2          SET UP ADDRESSABILITY FOR CVT        31770021
         L     R11,CVTTCBP         GET ADR OF PTR TO TCB                31800021
         L     R11,FOUR(R11)       GET ADR CURRENT TCB                  31830021
         DROP  R2                  DROP CVT                             31860021
         USING TCB,R11             SET UP ADDRESSABILITY FOR TCB        31890021
         L     R0,FOUR(PARMLST)    GET LENGTH OF PARM DATA              31920021
         L     R4,TWTYEIGT(PARMLST) GET ADR TSC TABLE                   31950021
         A     R0,ZERO(R4)         ADD LENGTH TSC TABLE                 31980021
         AH    R0,N32              ADD LENGTH PARM LIST                 32010021
         O     R0,SP254            INDICATE SUBPOOL=254                 32040021
         GETMAIN R,LV=(0)          GET AREA FOR LIST,TABLE AND PARM     32070021
         LR    R9,R1               SAVE ADR OF AREA                     32100021
         LH    R6,N32              GET LENGTH PARM LIST                 32130021
         A     R6,ZERO(R4)         ADD LENGTH TSC TABLE                 32160021
         BCTR  R6,ZERO             DECREMENT LENGTH BY ONE              32190021
         EX    R6,MOVELIST         MOVE LIST AND TABLE TO SP254         32220021
         LA    R6,ONE(R6)          INCREMENT LENGTH BY ONE              32250021
         AR    R1,R6               ADD LENGTH TO ADR NEW AREA AND GET   32280021
         LM    R6,R7,FOUR(PARMLST) GET LENGTH AND ADR PARM IN SP0       32310021
*                                  ADR PARM DATA IN SP=254              32340021
EXLOOP2  CH    R6,N256             IS LENGTH GR TH 256 BYTES            32370021
         BH    MOVE2               YES-BRANCH                           32400021
         BCTR  R6,ZERO             NO- DECREMENT LENGTH BY ONE          32430021
         EX    R6,MOVEDATA         MOVE PARM FR SP0 TO SP254            32460021
         BAL   R8,FREERTN          FREE LIST,TABLE AND PARM IN SP0      32490021
         LR    PARMLST,R9          GET ADR PARM LIST SP 254             32520021
         AH    R9,N32              ADD LENGTH 32BYTES AND GET ADR TABLE 32550021
         IC    R8,TWTYEIGT(PARMLST) SAVE DUMP SWITCH BYTE     CC A68643 32560021
         ST    R9,TWTYEIGT(PARMLST) PUT ADR IN PARM LIST                32580021
         STC   R8,TWTYEIGT(PARMLST) RESTORE DUMP SWITCH BYTE  CC A68643 32590021
         L     R8,ZERO(R9)         GET LENGTH TSC TABLE                 32610021
         AR    R9,R8               ADD LENGTH AND GET ADR PARM DATA     32640021
         L     R0,EIGHT(PARMLST)   GET ADR OLD PARM IN SP 0             32670021
         ST    R9,EIGHT(PARMLST)   PUT ADR OF NEW PARM IN PARM LIST     32700021
         L     R1,SXTN(PARMLST)    GET ADR OVERRIDES IN PARM AREA       32730021
         LTR   R1,R1               IS THERE AN ADDRESS                  32760021
         BZ    NODRVMOD            NO DRIVER MODIFYS -BRANCH            32790021
         SR    R1,R0               GET DIFF BETWEEN TWO ADRESSES        32820021
         AR    R9,R1               GET ADR OVERRIDES IN NEW PARM        32850021
         ST    R9,SXTN(PARMLST)    ST ADR NEW OVERRIDES IN LIST         32880021
NODRVMOD LA    R0,SVNTYTW          GET LENGTH OF 72 BYTESVE AR          32910021
         O     R0,SP254            INDICATE SUBPOOL=254                 32940021
         SPACE                                                          32970021
         GETMAIN R,LV=(0)          GET AREA FOR SYSTEM SAVE AREA IN 254 33000021
         L     R6,FOUR(R13)        GET ADR SYS SVE AREA IN SP0          33030021
         MVC   ZERO(SVNTYTW,R1),ZERO(R6) MOVE SVE AREA INTO SP254       33060021
         ST    R1,FOUR(R13)        PUT ADR IN TSC SVE AREA              33090021
         IC    R6,TCBFSA           SAVE HI ORDER BYTE IN SAVE AR        33120021
*                                  ADR IN TCB                           33150021
         SR    R1,R1               ZERO REG                             33180021
         ST    R1,TCBFSA           ZERO ADR SAVE AREA IN TCB            33210021
         STC   R6,TCBFSA           RESTORE HI ORDER BYTE                33240021
         DROP  R11                 DROP TCB                             33270021
         LR    R1,R13              GET ADR TSC SAVE AND WK AREA         33300021
         L     R13,FOUR(R13)       RESTORE REG13 WITH SYS SVE AREA ADR  33330021
         LA    R0,LWKAREA          GET LENGTH WORK AND SAVE AREA        33360021
         SPACE                                                          33390021
         FREEMAIN R,LV=(0),A=(1)   FREE SAVE AND WORK AREA              33420021
         SPACE 1                                                        33450021
         LR    R1,PARMLST          PUT ADDR PARMLST IN REG1             33480021
         XCTL  (2,12),EP=IKJEAT01  RESTORE REGS AND XCTL                33510021
         SPACE 2                                                        33540021
MOVE2    LA    R5,TWFTYFIV         GET NO. 255                          33570021
         EX    R5,MOVEDATA         MOVE 256 BYTES OF PARM INTO NEW AREA 33600021
         SH    R6,N256             SUBTRACT BYTES FR LENGTH             33630021
         LA    R7,TWFTYSIX(R7)     UPDATE PTR PARM DATA BY 256          33660021
         LA    R1,TWFTYSIX(R1)     UPDTE PTR TO NEW AR BY 256 BYTES     33690021
         B     EXLOOP2             BR TO MOVE REST OF PARM              33720021
         SPACE                                                          33750021
REJST2   LA    R1,LISTMAC          GET ADR OF BUFFER                    33780021
         MVC   ZERO(WTO6L,R1),WTO6 MOVE WTO LIST INTO BUFFER            33810021
         MVC   WTO6X(EIGHT,R1),ZERO(R11) MOVE MODULE NAME INTO BUFFER   33840021
         SR    R0,R0               CLEAR REGISTER                       33870021
         IC    R0,CONSLID          PUT CONSOLE ID INTO REG 0            33900021
         WTO   MF=(E,(1))          ISSUE WTO                            33930021
         SPACE                                                          33960021
REJST5   BAL   R8,FREERTN          BR TO FREE LIST,TABLE AND PARM       33990021
         B     REJST7              BR TO REJECT START TS                34020021
         SPACE                                                          34050021
REJST3   LA    R1,LISTMAC          GET ADDR OF LIST                     34080021
         MVC   ZERO(WTO5L,R1),WTO5 MVE WTO LIST INTO WK AREA            34110021
         SR    R0,R0               CLEAR REGISTER                       34140021
         IC    R0,CONSLID          PUT CONSOLE ID INTO REG 0            34170021
         WTO   MF=(E,(1))          ISSUE WTO                            34200021
         B     REJST5              BR TO RETURN                         34230021
         SPACE                                                          34260021
REJST4   LA    R1,LISTMAC          GET ADDR OF LIST                     34290021
         MVC   ZERO(WTO11L,R1),WTO11 MVE WTO LIST INTO WK AREA          34320021
         SR    R0,R0               CLEAR REGISTER                       34350021
         IC    R0,CONSLID          PUT CONSOLE ID INTO REG 0            34380021
         WTO   MF=(E,(1))          ISSUE WTO                            34410021
         B     REJST5              BR TO RETURN                         34440021
         SPACE                                                          34470021
REJST6   LA    R1,LISTMAC          GET ADR OF BUFFER                    34500021
         MVC   ZERO(WTO7L,R1),WTO7 MOVE WTO LIST TO BUFFER              34530021
         MVC   WTO7X(EIGHT,R1),ZERO(R2) MOVE MODULE NAME TO BUFFER      34560021
         SR    R0,R0               CLEAR REGISTER                       34590021
         IC    R0,CONSLID          PUT CONSOLE ID INTO REG 0            34620021
         WTO   MF=(E,(1))          ISSUE WTO                            34650021
         B     REJST5              BR TO RETURN                         34680021
         SPACE                                                          34710021
REJST8   LM    R0,R1,PARMLEN       GET LENGTH AND ADR PARM BUF          34740021
         FREEMAIN R,LV=(0),A=(1)   FREE PARM BUFFER                     34770021
         B     REJST7              BR TO REJECT START TS                34800021
         SPACE                                                          34830021
BLDNG2   LA    R2,DRVLST           GET ADR DRVER BLDL LIST              34860021
         LA    R2,FOUR(R2)         UPDTE PTR TO LIST TO ENTRY           34890021
RFLDLOOP TM    RFLD(R2),BLDGD      TEST R FIELD FOR ZERO                34920021
         BZ    REJST6              YES- BLDL FAILED                     34950021
         LA    R2,TWTYEIGT(R2)     NO UPDATE PTR TO NEXT MODULE ON LIST 34980021
         B     RFLDLOOP            BR TO TEST R FIELD                   35010021
WTORRTN  LA    R1,LISTMAC          GET ADR OF LIST IN WK AREA           35040021
         LA    R5,REPLYAD          GET ADR REPLY FIELD                  35070021
         XC    ZERO(N76,R5),ZERO(R5)  CLEAR ANS FIELD AND  ECB   A51701 35100021
         SR    R0,R0               CLEAR REGISTER                       35130021
         IC    R0,CONSLID          PUT CONSOLE ID INTO REG 0            35160021
         WTOR  ,REPLYAD,EIGHT,ECBAD,MF=(E,(1))  ISSUE WTOR              35190021
         WAIT  1,ECB=ECBAD         WAIT FOR REPLY                       35220021
         OC    ZERO(EIGHT,R5),WBLANKB DO FOLDING ON REPLY               35250021
         CLC   REPLYAD(SIX),CNCELB DOES REPLY EQ CANCEL START TS        35280021
         BE    ZERO(R6)            RETURN TO REJECT START TS            35310021
         B     FOUR(R6)            RETURN TO CONTINUE                   35340021
         EJECT                                                          35370021
*********************************************************************   35400021
*                                                                   *   35430021
*                                  CONSTANTS                        *   35460021
*                                                                   *   35490021
*********************************************************************   35520021
         SPACE 3                                                        35550021
         DS    0F                                                       35580021
CIBRTNME DC    A(CIBRTN)           ADDR OF CIB ROUTINE                  35610021
PRMRTNME DC    A(PARMRTN)          ADDR OF PARM ROUTINE                 35640021
EDRTNME  DC    A(EDITRTN)          ADDR OF EDIT ROUTINE                 35670021
PRMTNME  DC    A(PARMTEST)         ADDR OF PARM TEST ROUTINE            35700021
CNBRTNME DC    A(CNBLKRTN)         ADDR OF CONTROL BLOCK ROUTINE        35730021
WBLANKB  DC    CL8' '                                                   35760021
CNCELB   DC    C'CANCEL'                                                35790021
PLUS2K   DC    F'2047'                                                  35880021
SP254    DC    X'FE000000'         SUBPOOL 254 IN HI ORDER BYTE         35910021
EMPTY    DC    F'0'                    ZERO CONSTANT                    35940021
TWKMASK  DC    X'FFFFF800'                                              35970021
SIXK     DC    X'00002000'                                              36000021
N32      DC    H'32'                                                    36060021
N71      DC    H'71'                                                    36090021
U        DC    C'U'                                                     36150021
DRVCD1   DC    X'F0F0'                                                  36180021
TIOC     DC    C'IKJGGE00'                                              36210021
SWAP     DC    C'IKJEAS00'                                              36240021
N256     DC    H'256'                                                   36270021
DFNAME   DC    C'IKJPRM00'                                              36300021
LIST     DC    C'LIST'                                                  36330021
FORM     DC    C'FORM'                                                  36360021
FORMALL  DC    C'FORM=ALL'                                              36390021
BLDLS    DS    0F                                                       36420021
*****               CHANGE TO IKJEAT00 FOR APAR 44022            *****  36450021
         DC    H'14'         FOURTEEN ENTRIES.                          36480021
         DC    H'56'         56 BYTES PER ENTRY.                        36510021
         DC    CL8'IKJEAI00'                                            36540021
         DC    CL48' '                                                  36570021
         DC    CL8'IKJEAI01'                                            36600021
         DC    CL48' '                                                  36630021
         DC    CL8'IKJEAI02'                                            36660021
         DC    CL48' '                                                  36690021
         DC    CL8'IKJEAI03'                                            36720021
         DC    CL48' '                                                  36750021
         DC    CL8'IKJEAL00'                                            36780021
         DC    CL48' '                                                  36810021
         DC    CL8'IKJEAR00'                                            36840021
         DC    CL48' '                                                  36870021
         DC    CL8'IKJEAR01'                                            36900021
         DC    CL48' '                                                  36930021
         DC    CL8'IKJEAT03'                                            36960021
         DC    CL48' '                                                  36990021
         DC    CL8'IKJEAT05'                                            37020021
         DC    CL48' '                                                  37050021
         DC    CL8'IKJEAT06'                                            37080021
         DC    CL48' '                                                  37110021
         DC    CL8'IKJEAT07'                                            37140021
         DC    CL48' '                                                  37170021
         DC    CL8'IKJEFLM'                                             37200021
         DC    CL48' '                                                  37230021
         DC    CL8'IKJGGQT0'                                            37260021
         DC    CL48' '                                                  37290021
         DC    CL8'IKJGGQT1'                                            37320021
         DC    CL48' '                                                  37350021
*****             THIS ENDS THE SECTION OF CODE CHANGED FOR APAR44022*  37380021
BLDLS1   EQU   *                   LPA AND DRIVER BLDS LIST             37410021
         DC    H'1'                                                     37440021
         DC    H'56'                                                    37470021
         DC    CL8' '                                                   37500021
         DC    CL48' '                                                  37530021
         DC    H'2'                                                     37560021
         DC    H'56'         56 BYTE ENTRIES.                           37590021
         DC    CL8'      02'                                            37620021
         DC    CL48' '                                                  37650021
         DC    CL8'      03'                                            37680021
         DC    CL48' '                                                  37710021
BLDLEND  EQU   *                                                        37740021
LBLDL    EQU   BLDLEND-BLDLS1                                           37770021
         SPACE 3                                                        37800021
MOVEBLDL MVC   ZERO(ZERO,R3),ZERO(R1)                                   37830021
MOVEDATA MVC   ZERO(ZERO,R1),ZERO(R7)                                   37860021
MOVELIST MVC   ZERO(ZERO,R1),ZERO(PARMLST)                              37890021
MOVETAB  MVC   THTYSX(ZERO,PARMLST),MAPENT                              37920021
MOVEMODS MVC   LISTWTO(ZERO),ZERO(R9)                                   37950021
CLEAR1   XC    ZERO(ZERO,R1),ZERO(R1)                                   37980021
         SPACE 3                                                        38010021
LINKLIST LINK  SF=L                                                     38040021
LINKEND  EQU   *                                                        38070021
         SPACE 3                                                        38100021
OPENDCB  OPEN  (SYS1PARM),MF=L                                          38130021
OPENEND  EQU   *                                                        38160021
         SPACE 2                                                        38190021
*****    THE FOLLOWING SECTION OF CODE WAS ADDED FOR APAR 44022 *****   38220021
DCBCLOSE CLOSE   (SYS1PARM),MF=L                                        38250021
DCBLEND  EQU   *                                                        38280021
*****             THIS ENDS THE SECTION OF CODE ADDED FOR APAR 44022 ** 38310021
         SPACE 3                                                        38340021
SYS1PARM DCB   EODAD=CLOSPARM,DEVD=DA,MACRF=R,DSORG=PO,BLKSIZE=80,     X38370021
               LRECL=80,RECFM=FB,DDNAME=SYSPARM,SYNAD=ERREXIT           38400021
DCBEND   EQU   *                                                        38430021
         EJECT                                                          38460021
WTO1     WTO   'IKJ004I  START REJECTED-OPEN FAILED FOR SYS1.PARMLIB',DX38490021
               ESC=5,MCSFLAG=(REG0),MF=L                                38520021
WTO1L    EQU   *-WTO1                                                   38550021
         SPACE 4                                                        38580021
WTO2     WTO   'IKJ005I  MEMBER OF SYS1.PARMLIB NOT FOUND',DESC=5,MCSFLX38610021
               AG=(REG0),MF=L                                           38640021
WTO2L    EQU   *-WTO2                                                   38670021
         SPACE 4                                                        38700021
WTO3     WTO   'IKJ007I START REJECTED - TIME SHARING IS IN PROGRESS',DX38730021
               ESC=5,MCSFLAG=(REG0),MF=L                                38760021
WTO3L    EQU   *-WTO3                                                   38790021
         EJECT                                                          38820021
WTO4     WTO   'IKJ006I  START REJECTED - IO ERROR READING SYS1.PARMLIBX38850021
               ',DESC=5,MCSFLAG=(REG0),MF=L                             38880021
WTO4L    EQU   *-WTO4                                                   38910021
         SPACE 4                                                        38940021
WTO5     WTO   'IKJ009I START REJECTED-BLDL FAILED FOR A TSO MODULE',DEX38970021
               SC=5,MCSFLAG=(REG0),MF=L                                 39000021
WTO5L    EQU   *-WTO5                                                   39030021
         SPACE 4                                                        39060021
WTO6     WTO   'IKJ011I START REJECTED - MODULE, CCCCCCCC, COULD NOT INX39090021
               ITIALIZE',DESC=5,MCSFLAG=(REG0),MF=L                     39120021
WTO6L    EQU   *-WTO6                                                   39150021
WTO6X    EQU   37                                                       39180021
         EJECT                                                          39210021
WTO7     WTO   'IKJ010I START REJECTED - BLDL FAILED FOR TSO DRIVER MODX39240021
               ULE,CCCCCCCC',DESC=5,MCSFLAG=(REG0),MF=L                 39270021
WTO7L    EQU   *-WTO7                                                   39300021
WTO7X    EQU   63                                                       39330021
         SPACE 4                                                        39360021
WTO8     WTO   '                                                       X39390021
                                        ',DESC=5,MCSFLAG=(REG0),MF=L    39420021
WTO8L    EQU   *-WTO8                                                   39450021
         SPACE 4                                                        39480021
WTO11    WTO   'IKJ014I START REJECTED-I/O ERROR SEARCHING SYS1.LINKLIBX39510021
               DIRECTORY',DESC=5,MCSFLAG=(REG0),MF=L                    39540021
WTO11L   EQU   *-WTO11             LENGTH OF WTO11                      39570021
         EJECT                                                          39600021
WTOR1    WTOR  'IKJ001D START ERROR - REPLY ''MEMBER NAME'', ''U'', OR X39630021
               ''CANCEL''',DESC=2,MCSFLAG=(REG0),MF=L                   39660021
WTOR1L   EQU   *-WTOR1             LENGTH OF WTOR1                      39690021
         SPACE 3                                                        39720021
WTOR2    WTOR  'IKJ002D START ERROR - REPLY ''LIST'', ''U'', OR ''CANCEX39750021
               L''',DESC=2,MCSFLAG=(REG0),MF=L                          39780021
WTOR2L   EQU   *-WTOR2             LENGTH OF WTOR2                      39810021
         SPACE 3                                                        39840021
WTOR3    WTOR  'IKJ003D START ERROR - REPLY ''FORM'',''FORM=ALL'', ''U'X39870021
               ', OR ''CANCEL''',DESC=2,MCSFLAG=(REG0),MF=L             39900021
WTOR3L   EQU   *-WTOR3             LENGTH OF WTOR3                      39930021
         EJECT                                                          39960021
*                                  R15-RETURN COMPUTATION               39990021
*****    THE FOLLOWING SECTION OF CODE WAS ADDED FOR APAR 44022 *****   40020021
         DS    0H                                                       40050021
BLDRTN   EQU   *                                                        40080021
         LR    R6,R14         SAVE RETURN REG.                          40110021
         LH    NBLDLREG,ZERO(R2) GET NO. OF ENTRIES IN LIST.            40140021
         LA    R5,FOUR(R2)   R5=1ST ENTRY ADDR.                         40170021
BLDLOOP  EQU   *                                                        40200021
         L     R2,TWTYFOUR(R5) R2=AMT.OF STORAGE NEEDED.                40230021
         SRL   R2,EIGHT       CLEAR LOW-ORDER BYTE.                     40260021
         BAL   R14,SREBUILD   ADD TO SRE CHAIN.                         40290021
         LA    R5,N56(R5)    UPDATE POINTER TO NEXT ENTRY.              40320021
         BCT   NBLDLREG,BLDLOOP IF THERE IS ANOTHER ENTRY,CONTINUE.     40350021
         LR    R14,R6         OTHERWISE,                                40380021
         BR    R14            RETURN TO CALLER.                         40410021
         SPACE 4                                                        40440021
FREERTN  LM    R0,R1,FOUR(PARMLST) GET LENGTH AND ADR PARM DATA IN SP=0 40470021
         FREEMAIN R,LV=(0),A=(1)   FREE PARM DATA                       40500021
         LH    R0,N32              GET LENGTH PARMLST                   40530021
         L     R4,TWTYEIGT(PARMLST) GET ADR TSC TABLE                   40560021
         A     R0,ZERO(R4)         ADD LENGTH TSC TABLE                 40590021
         LR    R1,PARMLST          GET ADR LIST AND TABLE IN SP0        40620021
         FREEMAIN R,LV=(0),A=(1)   FREE LIST AND TSC TABLE              40650021
         BR    R8                 RETURN                                40680021
         SPACE 2                                                        40710021
*********************************************************************** 40740021
*  THIS SECTION ACQUIRES STORAGE FOR AND BUILDS AN SRE FOR THE SRE    * 40770021
*  CHAIN. ON ENTRY REGISTER 2 CONTAINS THE SIZE TO BE REPRESENTED     * 40800021
*  BY THE NEW SRE AND REGISTER 5 POINTS TO TO THE BLDL ENTRY NAME     * 40830021
*  FIELD IF IT IS TO REPRESENT A MODULE, OR ZERO IF THE SRE IS TO     * 40860021
*  REPRESENT A BLOCK OF STORAGE.                                      * 40890021
*                                                                     * 40920021
         SPACE 3                                                        40950021
SREBUILD EQU   *                                                        40980021
         STM   R0,R15,SAVE1  SAVE CALLER'S REGS.                        41010021
         BALR  BASEREG,ZERO  ROUTINE ADDRESSABILITY.                    41040021
         USING *,BASEREG     *                                          41070021
         LA    R0,SRELNGTH   R0=LENGTH FOR GETMAIN.                     41100021
         O     R0,SP254B         OR IN SUBPOOL 254 INDICATOR            41130021
         GETMAIN R,LV=(0)        GET STORAGE FOR NEW SRE.               41160021
         USING SRE,R1            *                                      41190021
         XC    SRE(SRELNGTH),SRE ZERO THE SRE.                          41220021
         LA    R2,SEVEN(R2)  ROUND INPUT LENGTH UP TO DOUBLE WORD.      41250021
         N     R2,DBLMASK    *                                          41280021
         ST    R2,SRESIZE                                               41310021
         LTR   R5,R5             Q.IS THERE A NAME                      41340021
         BZ    NONAME         NO, SKIP THE NAME PROCESSING.             41370021
         BL    CBSWAP        R5 NEGATIVE,PLACE THIS SRE 1ST ON CHAIN.   41400021
         MVC   SRENAME,ZERO(R5) MOVE NAME INTO SRE NAME FIELD.          41430021
         LR    R3,R5          R3=TRUE NAME ADDR (UNLESS ALIAS).         41460021
         TM    N13(R5),ALIASBIT        Q.THIS AN ALIAS NAME ENTRY.      41490021
         BZ    TRUENAME      NO,LEAVE R3 ALONE.                         41520021
         TM    N22(R5),REENTBIT+REUSBIT Q.IS MODULE RENT OR REUS.       41550021
         BZ    NONAME         NEITHER, LEAVE SIZE FIELD ALONE.          41580021
         LA    R3,N38(R5)    R3=TRUE NAME ADDR (NO SCATTER).            41610021
         TM    N22(R5),SCATTBIT        Q.SCATTER ATTRIBUTE.             41640021
         BZ    TRUENAME       NO,DON'T ADJUST NAME POINTER.             41670021
         LA    R3,N46(R5)    R3=TRUE NAME ADDR (SCATTER).               41700021
TRUENAME EQU   *                                                        41730021
         L     R4,SRECHAIN   R4=HEAD OF SRE CHAIN.                      41760021
         MVC   SRETNAME,ZERO(R3) MOVE TRUE NAME INTO SRE.               41790021
COMPLOOP EQU   *                                                        41820021
         LTR   R4,R4         Q.ANY MORE SRE'S.                          41850021
         BZ    NONAME        NO,DON'T ZERO SIZE FIELD.                  41880021
         CLC   SRETNAME,SRETNAME-SRE(R4) Q.MODULE ALREADY ON CHAIN.     41910021
         BE    ADJUST        YES,ZERO SIZE FIELD IN NEW SRE.            41940021
         L     R4,SRELINK-SRE(R4) NO,CHECK NEXT SRE ON CHAIN.           41970021
         B     COMPLOOP       *                                         42000021
ADJUST   EQU   *                                                        42030021
         XC    SRESIZE,SRESIZE ZERO THE SIZE FIELD.                     42060021
NONAME   EQU   *                                                        42090021
         LA    R2,SRECHAIN       R2=HEAD OF SRE CHAIN.                  42120021
BLDLOOP1 NC    ZERO(FOUR,R2),ZERO(R2) Q.ANY MORE SRE'S.                 42150021
         BNZ   SHUFFLE           YES,LOCATE NEW SRE ON CHAIN.           42180021
         ST    R1,ZERO(R2)       ADD NEW SRE TO END OF CHAIN            42210021
         B     ENDSRE            AND RETURN.                            42240021
CBSWAP   EQU   *                                                        42270021
         L     R2,SRECHAIN   R2=1ST SRE ON CHAIN.                       42300021
         B     SWAPIT        PLACE CB SRE 1ST ON CHAIN.                 42330021
         SPACE                                                          42360021
SHUFFLE  EQU   *                                                        42390021
         L     R2,ZERO(R2)       R2=ADDR OF 'CURRENT' SRE.              42420021
         NC    SRENAME,SRENAME   Q.NEW ENTRY NAME FIELD ZERO.           42450021
         BNZ   NAMED         NO,LOOK FOR 1ST NAMED SRE.                 42480021
         NC    SRENAME-SRE(EIGHT,R2),SRENAME-SRE(R2) Q.CURRENT SRE      42510021
*                            NAME FIELD ZERO.                           42540021
         BNZ   SWAPIT        NO,CHAIN ZERO SRE BEFORE 1ST NAMED.        42570021
         B     BLDLOOP1      YES,DRIP THRU TIL A NAMED SRE OR END.      42600021
NAMED    EQU   *                                                        42630021
         NC    SRENAME-SRE(EIGHT,R2),SRENAME-SRE(R2) Q.CURRENT SRE      42660021
*                            NAME FIELD ZERO.                           42690021
         BZ    BLDLOOP1      YES,DRIP THRU TIL A NAMED SRE OR END.      42720021
         CLC   SRESIZE,PLUSOSB   Q.IS SIZE REPRESENTED BY NEW SRE 2K OR 42750021
*                                LARGER.                                42780021
         BL    NEWCUR            NEW SRE SMALLER THAN 2K.               42810021
         CLC   SRESIZE-SRE(FOUR,R2),PLUSOSB  Q.'CURRENT' SRE            42840021
*                                SIZE VS. 2K                            42870021
         BL    SWAPIT            CHAIN NEW BEFORE CURRENT               42900021
         L     R15,SRESIZE-SRE(R2) R15='CURRENT' SIZE                   42930021
         L     R0,SRESIZE        R0=NEW SIZE                            42960021
         A     R15,PLUS2KB       ROUND BOTH SIZES UP TO 2K MULTIPLE.    42990021
         A     R0,PLUS2KB        *                                      43020021
         N     R15,TWKMASKB      *                                      43050021
         N     R0,TWKMASKB       *                                      43080021
         S     R15,SRESIZE-SRE(R2) R15='CURRENT'  'HOLE'                43110021
         S     R0,SRESIZE        R0=NEW 'HOLE'.                         43140021
         CR    R0,R15            Q.NEW HOLE LTE 'CURRENT' HOLE.         43170021
         BH    BLDLOOP1          NEW HOLE LARGER,DRIP DOWN NEXT NOTCH.  43200021
         B     SWAPIT            LTE,CHAIN NEW BEFORE CURRENT           43230021
NEWCUR   EQU   *                                                        43260021
         CLC   SRESIZE,SRESIZE-SRE(R2) Q.NEW SIZE LT CURRENT.           43290021
         BL    BLDLOOP1          YES,DRIP DOWN ONE MORE.                43320021
SWAPIT   EQU   *                 NO,CHAIN NEW BEFORE CURRENT            43350021
         ST    R1,SRELINK        POINTER TO SPACE OCCUPIED BY NEW INTO  43380021
*                                NEW'S LINK FIELD.                      43410021
         XC    SRE(SRELNGTH),ZERO(R2) SWAP SPACES.                      43440021
         XC    ZERO(SRELNGTH,R2),SRE  *                                 43470021
         XC    SRE(SRELNGTH),ZERO(R2) *                                 43500021
ENDSRE   EQU   *                                                        43530021
         LM    R0,R15,SAVE1  RESTORE REGS.                              43560021
         BR    R14                                                      43590021
         DS    0F                                                       43620021
SP254B   DC    X'FE000000'                                              43650021
PLUSOSB  DC    F'2048'                                                  43680021
PLUS2KB  DC    F'2047'                                                  43710021
TWKMASKB DC    X'FFFFF800'                                              43740021
DBLMASK  DC    X'FFFFFFF8'   MASK FOR DOUBLE-WORD ROUND UP.             43770021
*****             THIS ENDS THE SECTION OF CODE ADDED FOR APAR 44022 ** 43800021
         EJECT                                                          43830021
*********************************************************************   43860021
*                                                                   *   43890021
* THIS SECTION SEACHES THE COMMAND INPUT BUFFER(CIB).IT SEARCHES    *   43920021
* FOR A MEMBER NAME,AND MOVES IT TO THE WORK AREA.IF NONE WAS       *   43950021
* SPECIFIED IT MOVES THE DEFAULT NAME TO THE WORK AREA.IT ALSO      *   43980021
* SEARCHES FOR LIST AND FORM OPTIONS AND SETS BITS DEPENDING ON WHAT*   44010021
* WAS SPECIFIED. IT ALSO SETS A BIT INDICATING MODIFYS OR NO MODIFYS*   44040021
* IN THE CIB. THEN IT RETURNS TO MAINLINE.                          *   44070021
*                                                                   *   44100021
*********************************************************************   44130021
         SPACE 3                                                        44160021
CIBRTN   STM   R14,R12,TWELVE(R13)  SAVE REGISTERS                      44190021
         BALR  BASEREG,ZERO        SET UP BASE REGISTER                 44220021
         USING *,BASEREG           SET UP ADDRESSABILITY FOR BASE       44250021
         USING CIBD,CIBREG         SET UP ADDRESSABILITY FOR CIB DSECT  44280021
         MVC   CONSLID(ONE),CIBCONID PUT CONSOLE ID INTO WK AREA        44310021
         LH    LCIBREG,CIBDATLN    GET LENGTH CIB DATA                  44340021
         LTR   LCIBREG,LCIBREG     IS THERE ANY CIB DATA                44370021
         BZ    DFLTALL             NO-BR AND USE DEFAULT VALUES         44400021
         LA    CIBREG,CIBDATA      YES-GET BEG ADDR CIB DATA            44430021
         AR    LCIBREG,CIBREG      ADD ADR TO LENGTH AND GET STOPER ADR 44460021
         ST    LCIBREG,CIBENDAD    SAVE END ADR OF CIB MODIFYS          44490021
         DROP  CIBREG              DROP CIB                             44520021
         SPACE                                                          44550021
         CLI   ZERO(CIBREG),COMMA  DOES PTR EQ COMMA                    44580021
         BE    CIBDFNAM            YES-BR AND TAKE DEFAULT NAME         44610021
         SPACE                                                          44640021
         LR    R9,CIBREG           SAVE ADR OF BEG OF NAME              44670021
CIBLOOP4 LA    CIBREG,ONE(CIBREG)  UPDATE CIB PTR BY ONE                44700021
         CR    CIBREG,LCIBREG      IS IT END OF CIB                     44730021
         BE    CIBNAME2            YES-MOVE NAME TO WK AREA             44760021
         CLI   ZERO(CIBREG),COMMA  DOES CIB PTR EQ COMMA                44790021
         BNE   CIBLOOP4            NO- CONTINUE SEARCH                  44820021
         SPACE                                                          44850021
CIBNAME2 MVC   PARMNAME(EIGHT),BLNKS BLNK OUT NAME IN WK AREA           44880021
         LR    R10,CIBREG          SAVE END ADR OF NAME                 44910021
         SR    R10,R9              GET LENGTH OF PARM NAME              44940021
         CH    R10,CIBN8           IS NAME GR TH EIGHT CHAR             44970021
         BH    CIBLIST             YES-BR AND EVENTUALLY ISSUE ERROR    45000021
*                                  MSG WHEN CIB IS ALL EDITED           45030021
         BCTR  R10,ZERO            DECREMENT LENGTH BY ONE              45060021
         EX    R10,CIBMVNME        MOVE NAME TO WORK AREA               45090021
         SPACE                                                          45120021
CIBLIST  CR    CIBREG,LCIBREG      DOES PTR EQ STOPPER ADDR             45150021
         BE    CIBDFLT3            YES BRANCH AND TAKE DEFAULT          45180021
         LA    CIBREG,ONE(CIBREG)  UPDATE CIB PTR BY ONE                45210021
         CLI   ZERO(CIBREG),COMMA  DOES PTR EQ COMMA                    45240021
         BE    CIBNOLST            YES BR AND TAKE DEFAULT              45270021
         CLC   ZERO(FOUR,CIBREG),CIBLIST1 DOES PTR POINT TO LIST OPTION 45300021
         BE    CIBLST              YES-BRANCH                           45330021
         MVI   LISTSW,LSTERBIT     SET LIST SW TO ERROR                 45360021
         B     CIBLTEND            BR TO SEARCH FOR FORM OPTION         45390021
         SPACE                                                          45420021
CIBDFNAM MVC   PARMNAME(EIGHT),CIBDFNME MVE DFLT NAME TO WK AREA        45450021
         B     CIBLIST             CONTINUE SEARCH OF CIB               45480021
         SPACE                                                          45510021
CIBNOLST MVI   LISTSW,NOLIST       SET SWITCH TO NO LIST OPTION         45540021
         B     CIBFORM             BR TO CHECK FORM OPTION              45570021
         SPACE                                                          45600021
CIBLST   MVI   LISTSW,LISTBIT      SET SWITCH TO LIST OPTION            45630021
         LA    CIBREG,FOUR(CIBREG) UPDATE CIB PTR BY FOUR               45660021
         SPACE                                                          45690021
CIBLOOP6 CLI   ZERO(CIBREG),COMMA  DOES PTR EQ COMMA                    45720021
         BE    CIBFORM             YES BRANCH                           45750021
CIBLTEND CR    CIBREG,LCIBREG      DOES PTR EQ STOPPER ADR              45780021
         BH    CIBDFLT2            YES-BRANCH                           45810021
         LA    CIBREG,ONE(CIBREG)  UPDATE CIB PTR BY ONE                45840021
         B     CIBLOOP6            CONT SEARCH FOR COMMA OR RT PAREN    45870021
         SPACE                                                          45900021
CIBFORM  CR    CIBREG,LCIBREG      DOES PTR EQ STOPPER ADR              45930021
         BE    CIBDFLT2            YES BRANCH                           45960021
         LA    CIBREG,ONE(CIBREG)  UPDATE CIB PTR BY ONE                45990021
         CLI   ZERO(CIBREG),COMMA  DOES PTR EQ COMMA                    46020021
         BE    CIBNOFRM            YES BRANCH                           46050021
         SPACE                                                          46080021
         CLC   ZERO(EIGHT,CIBREG),CIBFORMA DOES PTR POINT TO FORM=ALL   46110021
         BE    CIBFRMA             YES-BRANCH                           46140021
         CLC   ZERO(FOUR,CIBREG),CIBFORM1 DOES PTR POINT TO FORM OPTION 46170021
         BE    CIBFRM              YES-BRANCH                           46200021
CIBLOOP3 MVI   FORMSW,FRMERBIT     SET FRM SW TO ERROR                  46230021
CIBLOOP7 CR    CIBREG,LCIBREG      DOES PTR EQ STOPPER ADR              46260021
         BE    CIBDFLT1            YES BRANCH-NO MODIFYS FOLLOW         46290021
         LA    CIBREG,ONE(CIBREG)  UPDATE PTR BY ONE                    46320021
CIBLOOP8 CLI   ZERO(CIBREG),COMMA  DOES PTR EQ COMMA                    46350021
         BNE   CIBLOOP7            NO CONT SEARCH FOR COMMA             46380021
         SPACE                                                          46410021
CIBMOD   LA    CIBREG,ONE(CIBREG)  UPDATE PTR PASS COMMA                46440021
         CR    CIBREG,LCIBREG      IS IT THE END OF CIB                 46470021
         BNL   CIBEND              YES BR TO RETURN                     46500021
         MVI   MODIFYSW,MODIFY     NO SET SWITCH FOR MODIFYS            46530021
         ST    CIBREG,MODFYADR     SAVE ADR OF MODIFYS                  46560021
         B     CIBEND              RETURN                               46590021
         SPACE                                                          46620021
CIBNOFRM MVI   FORMSW,NOFORM       SET SW TO NO FORM OPTION             46650021
         B     CIBMOD              BR TO SET MODIFY SW                  46680021
         SPACE                                                          46710021
CIBFRMA  MVI   FORMSW,FORMABIT     SET FORM=ALL SWITCH                  46740021
         LA    CIBREG,EIGHT(CIBREG) UPDATE PTR BY EIGHT                 46770021
         B     CIBLOOP8            BR CONT SEARCH FOR COMMA OR END      46800021
         SPACE                                                          46830021
CIBFRM   LA    CIBREG,FOUR(CIBREG) UPDTE PTR PASS FORM                  46860021
         CLI   ZERO(CIBREG),COMMA  IS THERE A COMMA                     46890021
         BE    CIBFRM1             YES BR TO SET FORM BIT               46920021
         CR    CIBREG,LCIBREG      IS IT END OF CIB                     46950021
         BNE   CIBLOOP3            NO- BYPASS SETTING FORM BIT          46980021
         MVI   FORMSW,FORMBIT      SET FORM SWITCH                      47010021
         B     CIBDFLT1            BR - SET NO MODIFY BIT               47040021
CIBFRM1  MVI   FORMSW,FORMBIT      SET FORM SWITCH                      47070021
         B     CIBMOD              BR TO SET MODIFY SWITCH              47100021
         SPACE                                                          47130021
DFLTALL  MVC   PARMNAME(EIGHT),CIBDFNME  MVE DFLT NME TO WK AREA        47160021
CIBDFLT3 MVI   LISTSW,NOLIST       SET SW TO NO LIST OPTION             47190021
CIBDFLT2 MVI   FORMSW,NOFORM       SET SW TO NO FORM OPTION             47220021
CIBDFLT1 MVI   MODIFYSW,NOMODFY    SET SW TO NO MODIFYS IN CIB          47250021
CIBEND   LM    R14,R12,TWELVE(R13) RESTORE REGISTERS                    47280021
         BR    R14                 RETURN TO MAIN RTN                   47310021
         SPACE 5                                                        47340021
**********               CONSTANTS FOR CIB ROUTINE          **********  47370021
         SPACE                                                          47400021
         DS    0H                                                       47430021
CIBN8    DC    H'8'                MAX LENGTH OF PARMLIB MEMBER NAME    47460021
CIBLIST1 DC    C'LIST'             LIST PARAMETER OPTION                47490021
CIBFORM1 DC    C'FORM'             FORM PARAMETER OPTION                47520021
CIBFORMA DC    C'FORM=ALL'         FORM PARAMETER OPTION                47550021
CIBDFNME DC    C'IKJPRM00'         DEFAULT PARMLIB MEMBER               47580021
CIBMVNME MVC   PARMNAME(ZERO),ZERO(R9) MVE MEMBER NAME TO WK AREA       47610021
BLNKS    DC    CL8' '              BLANK OUT 8 BYTES                    47640021
         EJECT                                                          47670021
**********************************************************************  47700021
*                                                                    *  47730021
* THIS SECTION GETS A BUFFER AND READS THE PARM DATA INTO THE BUFFER.*  47760021
* AFTER READING IT CLOSES THE DATA SET. THEN IT MOVES THE MODIFYS    *  47790021
* INTO THE BUFFER AND IT ALSO MOVES SOME BLANK DRIVER CARDS INTO THE *  47820021
* BUFFER WHICH ARE NEEDED BY THE DRIVER. IT THEN RETURNS TO MAIN RTN *  47850021
*                                                                    *  47880021
**********************************************************************  47910021
PARMRTN  STM   R14,R12,TWELVE(R13)   SAVE REGISTERS                     47940021
         BALR  BASEREG,ZERO                                             47970021
         USING *,BASEREG                                                48000021
         LH    R0,PARMLENG         GET LENGTH OF BUFFER FOR PARM DATA   48030021
         LH    PARMSTOP,PARMLENG   SAVE LENGTH OF BUFFER                48060021
         SR    R5,R5                                                    48090021
         TM    MODIFYSW,MODIFY   IS MODIFY SWITCH SET                   48120021
         BZ    NOMODS              NO BRANCH                            48150021
         L     R5,CIBENDAD        GET END ADR CIB MODIFYS               48180021
         L     CIBREG,MODFYADR    GET BEG ADDR OF CIB MODIFYS           48210021
         SR    R5,CIBREG           GET LENGTH OF CIB MODIFYS            48240021
         AR    R0,R5               ADD TO L OF BUFFER,THE MS NEEDED FOR 48270021
*                                  CIB MODIFYS                          48300021
NOMODS   AH    R0,LDRVPARM        ADD LENGTH OF DRVR CARDS              48330021
         SPACE                                                          48360021
         GETMAIN R,LV=(0)          GET BUFFER                           48390021
         SPACE                                                          48420021
         LR    PARMAD,R1           SAVE ADDR OF PARM FIELD BUFFER       48450021
         LR    PARMBUF,R1                                               48480021
         AR    PARMSTOP,PARMAD     GET STOPPER ADDR FOR BUFFER          48510021
         LA    DCBREG,DCBPARM      GET ADDR OF DCB IN WK AREA           48540021
         LA    R3,LISTMAC                                               48570021
READLOOP MVC   LISTMAC(READEND-READ1),READ1 MVE READ LST INTO WK AREA   48600021
         MVI   IOERRSW,GOODREAD    SET IO ERROR SW TO 0                 48630021
         LR    R2,R13              SAVE ADR TSC SAVE AR                 48660021
         LA    R13,RDSAVE          GET ADR SAVE AR FOR RD               48690021
         SPACE                                                          48720021
         READ  (R3),SF,(DCBREG),(PARMAD),MF=E READ CARD INTO PARM BUFF  48750021
         SPACE                                                          48780021
         CHECK (R3)              CHECK FOR GOOD READ                    48810021
         LR    R13,R2              RESTORE ADR TSC SAV AR               48840021
         TM    IOERRSW,BADREAD     IS THERE AN IO ERROR ON READ         48870021
         BNZ   PRMRTEND            YES- RETURN TO REJECT START TS       48900021
         LA    PARMAD,EIGHTY(PARMAD) NO - UPDATE BUFFER PTR             48930021
         CR    PARMAD,PARMSTOP     IS PARM BUFFER FULL                  48960021
         BNE   READLOOP             NO-CONTINUE READ PROCESSING         48990021
         BAL   R7,MOREBUF           BR AND GET MORE BUFFER SPACE        49020021
         B     READLOOP            BR TO READ NEXT CARD                 49050021
         SPACE                                                          49080021
MOREBUF  SR    PARMSTOP,PARMBUF    GET LENGTH OF BUFFER                 49110021
         LR    R0,PARMSTOP                                              49140021
         SLL   R0,ONE              DOUBLE ORIGINAL LENGTH               49170021
         AR    R0,R5            ADD TO LENGTH OF PARM DATA              49200021
         AH    R0,LDRVPARM         ADD LENGTH OF DRVR CARDS             49230021
         SPACE                                                          49260021
         GETMAIN R,LV=(0)          GETMAIN AN AREA FOR 2X OLD BUFFER    49290021
         LR    PARMAD,R1           SAVE ADDR NEW BUFFER                 49320021
         LR    R11,PARMSTOP        GET LENGTH OF PARM TO MOVE           49350021
         LR    R2,PARMBUF         GET ADR OF BEG OF PARM DATA           49380021
EXLOOP1  CH    R11,PN256                                                49410021
         BH    MOVE1               YES BRANCH                           49440021
         BCTR  R11,ZERO           DECREMENT LENGTH BY ONE               49470021
         EX    R11,MOVEPARM                                             49500021
         LR    R1,PARMBUF          GET ADR OLD BUFFER                   49530021
         LR    R0,PARMSTOP         GET LENGTH OLD BUFFER                49560021
         FREEMAIN R,LV=(0),A=(1)   FREE OLD BUFFER                      49590021
         SPACE                                                          49620021
         LR    PARMBUF,PARMAD      SAVE ADDR NEW BUFFER                 49650021
         AR    PARMAD,PARMSTOP     UPDATE PTR FOR NEXT FREE SPACE       49680021
         SLL   PARMSTOP,ONE        GET LENGTH OF NEW BUFFER             49710021
         AR    PARMSTOP,PARMBUF    GET STOPPER ADDRESS OF NEW BUFFER    49740021
         BR    R7                  RETURN TO READ MORE PARM DATA        49770021
         SPACE                                                          49800021
MOVE1    LA    R15,TWFTYFIV                                             49830021
         EX    R15,MOVEPARM       MOVE 256 BYTES INTO NEW AREA          49860021
         SH    R11,PN256              DECREMENT LENGTH BY 256 BYTES     49890021
         LA    R1,TWFTYSIX(R1)     UPDTE PTR 256 BYTES                  49920021
         LA    R2,TWFTYSIX(R2)    UPDATE PTR TO PARM BY 256 BYTES       49950021
         B     EXLOOP1            BR AND MOVE REST OF PARM              49980021
         EJECT                                                          50010021
CLOSPARM LR    R13,R2              RESTORE REG 13                       50040021
         MVC   LISTMAC(CLOSEND-CLOSEDCB),CLOSEDCB  MOVE LIST FORM OF    50070021
         LA    R1,LISTMAC                          CLOSE MACRO TO WKAR  50100021
         SPACE                                                          50130021
         CLOSE ((DCBREG)),MF=(E,(1))    CLOSE PARMLIB                   50160021
         MVC   ZERO(EIGHTY,PARMAD),LPACARD MVE LPA MODULES INTO PARM    50190021
         MVC   EIGHTY(EIGHTY,PARMAD),LPACARD1 MVE LPA MODULES           50220021
         LA    PARMAD,ONESXTY(PARMAD) UPDATE PTR TO PARM                50250021
         ST    PARMAD,PARMEND      SAVE STOPPER OF PARM DATA            50280021
         ST    PARMAD,DRVCRDAD     SAVE ADR DRIVER CARDS                50310021
         LA    R2,SIX              GET COUNT =6                         50340021
DRCDLOOP MVC   ZERO(EIGHTY,PARMAD),DRVCARD MOVE A DRVR CARD INTO PARM   50370021
         LA    PARMAD,EIGHTY(PARMAD) UPDATE PTR TO PARM                 50400021
         BCT   R2,DRCDLOOP         DECREMENT CT BY ONE IF NOT=0 THEN LP 50430021
         TM    MODIFYSW,MODIFY     IS MODIFY SWITCH SET                 50460021
         BZ    NOMOVE              NO BRANCH                            50490021
         ST    PARMAD,DRVRCIB                                           50520021
         L     R1,MODFYADR        GET ADR OF BEG CIB MODIFYS            50550021
EXLOOP3  CH    R5,PN256             IS LENGTH GR TH 256 BYTES           50580021
         BH    MOVE3               YES BRANCH                           50610021
         BCTR  R5,ZERO             DECREMENT LENGTH BY ONE              50640021
         EX    R5,MOVECIB          MOVE CIB INTO PARM FIELD             50670021
         LA    R5,ONE(R5)         RESTORE LENGTH OF MODIFYS             50700021
         AR    PARMAD,R5           ADD LENGTH CIB AND GET ADR FREE SPCE 50730021
NOMOVE   LR    R1,PARMAD           GET ADR OF FREE SPACE IN PARM        50760021
         SR    PARMAD,PARMBUF      GET LENGTH PARM FIELD                50790021
         ST    PARMAD,PARMLEN      SAVE LENGTH PARM                     50820021
         ST    PARMBUF,PARMADR     SAVE ADR PARM                        50850021
         LA    R14,EIGHT           PUT ADDRESS OF FREE SPACE ON         50880021
         AR    R1,R14              A DOUBLE WORD BOUNDARY               50910021
         SRL   R1,THREE            SHIFT RIGHT THREE BITS               50940021
         SLL   R1,THREE            SHIFT LEFT                           50970021
         LR    R0,PARMSTOP         GET ADR STOPPER OF PARM DATA         51000021
         AR    R0,R5               ADD LENGTH OF MODIFYS                51030021
         AH    R0,LDRVPARM         ADD LENGH OF DRV CARDS               51060021
         SR    R0,R1               GET LENGTH FREE SPACE                51090021
         BNP   RESTREGS            BRANCH IF NONE TO FREE     CC A67733 51100021
         SPACE                                                          51120021
         FREEMAIN R,LV=(0),A=(1)   FREE REMAINING AREA OF PARM          51150021
RESTREGS LM    R14,R12,TWELVE(R13) RESTORE REGISTERS          CC A67733 51180021
         BR    R14                                                      51210021
         SPACE                                                          51240021
PRMRTEND LM    R14,R12,TWELVE(R13)  RESTORE REGISTERS                   51270021
         B     FOUR(R14)           RETURN                               51300021
         SPACE                                                          51330021
MOVE3    LA    R2,TWFTYFIV         GET NUM=255                          51360021
         EX    R2,MOVECIB          MOVE 256 BYTES FR CIB INTO PARM      51390021
         SH    R5,PN256             SUBTRACT 256 FR LENGTH              51420021
         LA    R1,TWFTYSIX(R1)     UPDTE PTR TO CIB BY 256 BYTES        51450021
         LA    PARMAD,TWFTYSIX(PARMAD) UPDTE PTR TO PARM BY 256 BYTES   51480021
         B     EXLOOP3             BRANCH                               51510021
         SPACE                                                          51540021
ERREXIT  LR    R7,R13              SAVE REG13 PASSED FROM READ          51570021
         LR    R13,R2              SET UP REG 13 WITH TOO WK AREA       51600021
         MVI   IOERRSW,BADREAD     SET READ SW TO BAD READ              51630021
         LR    R13,R7              RESTORE REG 13 FROM READ             51660021
         BR    R14                 RETURN                               51690021
         SPACE 3                                                        51720021
**********                 CONSTANTS FOR PARM ROUTINE       **********  51750021
         SPACE 2                                                        51780021
         DS    0H                                                       51810021
LDRVPARM DC    H'640'              6 DRIVER + 2 LPA CARDS     CC A70793 51840021
PN256    DC    H'256'                                                   51870021
PARMLENG DC    H'8000'                                                  51900021
DRVCARD  DC    CL80' DRIVER'                                            51930021
LPACARD  DC    CL80' TS LPA=(IKJEFLS,IKJEFLS1,IKJEFLS2,IKJEFLS3,IKJEAT0X51960021
               8,IKJEAT04)'                                             51990021
LPACARD1 DC    CL80' TS LPA=(IKJPTGT,IKJPUTL,IKJGETL,IKJSTCK)'          52020021
         SPACE                                                          52050021
MOVECIB  MVC   ZERO(ZERO,PARMAD),ZERO(R1)                               52080021
MOVEPARM MVC   ZERO(ZERO,R1),ZERO(R2)                                   52110021
         SPACE                                                          52140021
READ1    READ  DECBAD,SF,MF=L                                           52170021
READEND  EQU   *                                                        52200021
         SPACE                                                          52230021
CLOSEDCB CLOSE (SYS1PARM),MF=L                                          52260021
CLOSEND  EQU   *                                                        52290021
         EJECT                                                          52320021
*********************************************************************   52350021
*                                                                   *   52380021
* THIS SECTION COMPUTES THE MAIN STORAGE NEEDED FOR ALL THE TSO     *   52410021
* CONTROL BLOCKS.IT SAVES THE AMOUNT IN THE WORK AREA,AND THEN      *   52440021
* RETURNS TO THE MAIN ROUTINE.                                      *   52470021
*                                                                   *   52500021
*********************************************************************   52530021
         SPACE 3                                                        52560021
CNBLKRTN STM   R14,R12,TWELVE(R13)   SAVE REGISTERS                     52590021
         BALR  BASEREG,ZERO                                             52620021
         USING *,BASEREG                                                52650021
         LA    LDSCTREG,LTSCVT     GET LENGTH OF TSCVT                  52680021
         LR    MSTOREG,LDSCTREG    ADD TO AMT OF MS NEEDED              52710021
         LA    LDSCTREG,LTSDMP     GET LENGTH OF TSO DMP CNTLR BLK      52740021
         AR    MSTOREG,LDSCTREG    ADD TO AMT OF MAIN STOR NEEDED       52770021
         LA    LDSCTREG,LRCB       GET LENGTH OF RCB                    52800021
         MH    LDSCTREG,REGNUM MULT LENGTH BY NO.OF REGIONS             52830021
         AR    MSTOREG,LDSCTREG    ADD TO AMT OF MS NEEDED              52860021
         SR    R10,R10                                                  52890021
         LA    LDSCTREG,LTJB       GET LENGTH OF TJB                    52920021
         L     USEREG,MAXUSER      GET NO.USERS                         52950021
         LA    USEREG,ONE(USEREG)  UPDTE NO. USERS BY ONE               52980021
         MR    R10,USEREG          MULT LENG TJB BY USERS               53010021
         AR    MSTOREG,LDSCTREG    ADD TO AMT OF MS NEEDED              53040021
         LA    LDSCTREG,LTSSAVE    GET LENGTH SYSTEM SAVE AREA          53070021
         AR    MSTOREG,LDSCTREG    ADD TO AMT MS NEEDED                 53100021
         LA    LDSCTREG,LECBTAB    GET ADDR ECB TABLE                   53130021
         AR    MSTOREG,LDSCTREG    ADD TO AMT OF MS NEEDED              53160021
         LA    LDSCTREG,FOUR       GET SIZE MAP ENTRIES                 53190021
         MH    LDSCTREG,MAPENT                                          53220021
         LH    R1,REGNUM           GET NO.RCBS                          53250021
         A     R1,MAXUSER         ADD NO. TJB'S                         53280021
         LA    R1,ONE(R1)          ADD ONE TO NO.AND RESULT IS NO.MAPS  53310021
         SR    R10,R10             MULT NUM MAPS BY SIZE EACH MAP       53340021
         MR    R10,R1                                                   53370021
         AR    MSTOREG,LDSCTREG    ADD TO AMT MS NEEDED                 53400021
         LA    LDSCTREG,LDPA       GET LENGTH DPA                       53430021
         AR    MSTOREG,LDSCTREG    ADD TO AMT MS NEEDED                 53460021
         LA    LDSCTREG,LTSIA      GET LENGTH FIXED TSIA                53490021
         LA    R1,FOUR             MULT NUMBER REGIONS BY FOUR          53520021
         MH    R1,REGNUM                                                53550021
         AR    LDSCTREG,R1         ADD TO FIXED LENGTH TSIA             53580021
         AR    MSTOREG,LDSCTREG    ADD TO AMT MAIN STOR NEEDED          53610021
         LA    MSTOREG,SVNTYTW(MSTOREG) ADD SIZE SAVE AR TO AMT         53640021
         ST    MSTOREG,SZECNBLK    SAVE TOTAL AMT MS NEEDED FOR CNT BLK 53670021
         LM    R14,R12,TWELVE(R13) RESTORE REGISTERS                    53700021
         BR    R14                 RETURN                               53730021
         EJECT                                                          53760021
*********************************************************************   53790021
*                                                                   *   53820021
* THIS SECTION TEST WHETHER THE NECESSARY TS PARAMETERS WERE        *   53850021
* SPECIFIED IN THE PARM DATA OR IN THE CIB. THE NECESSARY TS PARAM  *   53880021
* ARE TERMAX=,REGNMAX=,AND MAPS=. IF THEY ARE MISSING WTORS ARE     *   53910021
* ISSUED. THERE ARE OTHER TS PARAMETERS IF THEY ARE MISSING THEN    *   53940021
* DEFAULT VALUES ARE USED. THESE ARE DRIVER=,USERS=,AND SUBMIT=.    *   53970021
* THERE ARE ALSO TESTS DONE ON CERTAIN VALUES THAT HAVE LIMITS.IF   *   54000021
* THEY EXCEED THEIR LIMIT A WTOR IS ISSUED OR DEFAULT VALUE IS USED *   54030021
*                                                                   *   54060021
*********************************************************************   54090021
         SPACE 3                                                        54120021
PARMTEST STM   R14,R12,TWELVE(R13) SAVE REGISTERS                       54150021
         BALR  BASEREG,ZERO        SET UP ADDRESSABILITY                54180021
         USING *,BASEREG                                                54210021
         SR    R2,R2                                                    54240021
         SPACE                                                          54270021
         C     R2,MAXUSER          IS TERMAX VALUE MISSING              54300021
         BE    PRMTEST1            YES-BRANCH                           54330021
         SPACE                                                          54360021
PRMLIMUS CH    R2,LIMUSER          IS USERS VALUE MISSING               54390021
         BNE   PRMTEST2            NO-BRANCH                            54420021
         TM    USERSW,ONBIT        DID WE STORE USERS=0 IN LIMUSER      54450021
         BO    PRMREGNM            YES-BR AND BYPASS DEFAULTING TO      54480021
*                                  TERMAX VALUE                         54510021
MAXDFLT1 MVC   LIMUSER(TWO),MAXNUSER NO-LET IT DFLT TO TERMAX VALUE     54540021
         SPACE                                                          54570021
PRMREGNM CH    R2,REGNUM           IS REGNMAX VALUE MISSING             54600021
         BE    PRMTEST3            YES BRANCH                           54630021
         SPACE                                                          54660021
PRMMAPEN CH    R2,MAPENT           IS NUMB MAPS VALUE MISSING           54690021
         BE    PRMTEST4            YES-BRANCH                           54720021
         SPACE                                                          54750021
PRMDSPCH C     R2,DRVR             IS DRIVER PARAMETER MISSING          54780021
         BE    PRMDFDRV            YES BRANCH                           54810021
         SPACE                                                          54840021
PRMSMF   TM    SMFSW,ONBIT         DID WE PROCESS SMF PARAMETER         54870021
         BO    PRMSUBMT            YES BR TO TEST NEXT PARAMETER        54900021
         L     R4,CVTPTR           GET ADDRESS OF CVT                   54930021
         USING CVTSECT,R4                                               54960021
         L     R3,CVTSMCA          GET ADDR OFSYS MNGMT CNTRL AREA      54990021
         LTR   R3,R3               DOES ADDRESS EXIST                   55020021
         BZ    PRMSMF1             NO BRANCH AND BYPASS SMF PROC        55050021
         DROP  R4                                                       55080021
         USING SMCABASE,R3                                              55110021
         MVC   SMFPARM1(ONE),SMCAOPT SET FOREGRND=BACKGRND              55140021
         DROP  R3                                                       55170021
         B     PRMSUBMT            CONTINUE WITH NEXT PARAMETER         55200021
PRMSMF1  MVC   LISTMAC(WTO10L),WTO10                                    55230021
         LA    R1,LISTMAC          GET ADR LIST FORM OF WTO             55260021
         SR    R0,R0               CLEAR REGISTER                       55290021
         IC    R0,CONSLID          PUT CONSOLE ID INTO REG 0            55320021
         WTO   MF=(E,(1))          ISSUE WTO                            55350021
PRMSUBMT L     R4,CVTPTR           GET ADR CVT                          55380021
         USING CVTSECT,R4          SET UP ADDRESSABILITY FOR CVT DSECT  55410021
         L     R4,CVTJOB           GET ADR QUEUE MANAGER RES CORE       55440021
         USING IEFQM,R4            SET UP ADDRESSABILITY FOR IEFQMRES   55470021
         LH    R4,QMFIBLIM         GET MAX LIM OF TRKS FOR SUBMIT       55500021
         CH    R2,SUBMTMAX         IS SUBMIT MAX VALUE = 0              55530021
         BE    PRMSUB1             YES BRANCH                           55560021
         CH    R4,SUBMTMAX         NO - IS LIMIT GR TH OR EQ TO MAX     55590021
         BNL   PRMDRVR             YES BRANCH AND RETURN                55620021
PRMSUB1  STH   R4,SUBMTMAX         LET MAX VALUE DEFLT TO LIM           55650021
         DROP  R4                                                       55680021
         SPACE 2                                                        55710021
PRMDRVR  TM    DRVSW,ONBIT         ARE THERE DRIVER OVERRIDES           55740021
         BO    PRMREGSZ            YES BRANCH                           55770021
         XC    DRVRCIB(FOUR),DRVRCIB NO ZERO ADR OF OVERRIDES           55800021
         SPACE 3                                                        55830021
**********  ISSUE WTO TELLING THE NUMBER OF REGIONS SPECIFIED  ******** 55860021
*           AND THE ACTUAL NUMBER OF REGIONS STARTED.                   55890021
         SPACE 2                                                        55920021
PRMREGSZ MVC   LISTMAC(WTO9L),WTO9                                      55950021
         LH    R4,REGNUM           GET NUMBER OF REGIONS                55980021
         CH    R4,N10              IS NUM REGIONS LESS TH 10            56010021
         BNL   PRMCVD1             NO BRANCH                            56040021
         STC   R4,KYWD3            YES PUT NUMBER IN MESSAGE            56070021
         MVZ   KYWD3(ONE),ZONES    MOVE IN ZONE TO MAKE CHAR PRINTABLE  56100021
PRMRGLP3 SR    R3,R3                                                    56130021
         SR    R7,R7               USE FOR COUNT OF REGIONS STARTED     56160021
         LA    R6,REGN1            GET ADDR OF TAB OF REGION SIZES      56190021
         LH    R4,REGNUM           GET NUMBER OF REGIONS REQUESTED      56220021
PRMRGLP1 EQU   *                                                        56250021
         NI    ZERO(R6),MASKF          TURN OFF HI ORDER BIT            56280021
         C     R3,ZERO(R6)             WAS IT GIVEN REG SIZE            56310021
         BE    PRMRGLP2            NO - BRANCH AND TEST NXT REGION      56340021
         LA    R7,ONE(R7)          YES UPDATE COUNT BY ONE              56370021
PRMRGLP2 LA    R6,FOUR(R6)         UPDATE PTR TO NEXT REG SIZE          56400021
         BCT   R4,PRMRGLP1         DECREMENT REG CT BY ONE AND BR       56430021
         CH    R7,N10              IS NUM REG STARTED LESS TH 10        56460021
         BNL   PRMCVD2             NO - BRANCH                          56490021
         STC   R7,KYWD2            YES- PUT NO. IN MESSAGE              56520021
         MVZ   KYWD2(ONE),ZONES    MVE IN ZONE TO MAKE CHAR PRINTABLE   56550021
         B     PRMMESG             BR TO WTO MESSAGE                    56580021
PRMCVD1  CVD   R4,CVBDWD           CONVERT NUM TO DECIMAL               56610021
         UNPK  CVBDWD(TWO),CVBDWD6(TWO)   UN PACK                       56640021
         MVZ   CVBDWD1(ONE),ZONES   MOVE IN ZONE                        56670021
         MVC   KYWD3(TWO),CVBDWD   PUT NUMBER IN MESSAGE                56700021
         XC    CVBDWD(EIGHT),CVBDWD                                     56730021
         B     PRMRGLP3            BR TO CONVERT NUM REG STARTED        56760021
PRMCVD2  CVD   R7,CVBDWD           CONVERT NUM TO DECIMAL               56790021
         UNPK  CVBDWD(TWO),CVBDWD6(TWO)  UNPACK TO 1ST 2 BYTES          56820021
         MVZ   CVBDWD1(ONE),ZONES  MOVE IN ZONE                         56850021
         MVC   KYWD2(TWO),CVBDWD   PUT NUM IN MESSAGE                   56880021
         XC    CVBDWD(EIGHT),CVBDWD  CLEAR DOUBLE WORD                  56910021
PRMMESG  LA    R1,LISTMAC          GET ADDR MESSAGE                     56940021
         SR    R0,R0               CLEAR REGISTER                       56970021
         IC    R0,CONSLID          PUT CONSOLE ID INTO REG 0            57000021
         WTO   MF=(E,(1))          ISSUE MESSAGE                        57030021
*****    THE FOLLOWING SECTION OF CODE WAS ADDED FOR APAR 44022 *****   57060021
         TM    REGWTOFL,REGWTOM        SPECIAL WTO?                     57090021
         BZ    PRMMESG0                IF NOT,START TESTING             57120021
         MVC   LISTMAC(WTO14XL),WTO14XX  PUT NEXT MSG IN                57150021
         LA    R2,LISTMAC              ADDRESS OF LIST                  57180021
         SR    R0,R0                   GET THE                          57210021
         IC    R0,CONSLID              CONSOLE ID FOR WTO               57240021
         WTO    MF=(E,(2))             ISSUE THE WTO                    57270021
         CH    R7,N14                  ARE ALL REGIONS TESTED?          57300021
         BL    PRMMESG2                IF NOT,KEEP GOING                57330021
         B     PRMMESG5                RETURN TO CALLER                 57360021
PRMMESG0 EQU   *                                                        57390021
         LH    R7,REGNUM               MAX NO. REGIONS FROM KEYWORD     57420021
         CH    R7,N14                  IS REGION NO. OVER 14            57450021
         BE    PRMMESG5                IF SO,DISREGARD TEST             57480021
         LR    R4,R7                   SAVE FOR LATER USE               57510021
         LA    R6,REGN1                                                 57540021
         SLL   R4,TWO                  MULTIPLY BY TO GET ADDRESS       57570021
         AR    R6,R4                   1ST REGION WORKAREA FOR REGION   57600021
*                                      HIGHER THAN NAX.NO.SPECIFIED.    57630021
PRMMESG1 LA    R7,ONE(R7)              NEXT HIGHER REGNO.               57660021
         TM    ZERO(R6),HIBIT          IF HIGH ORDER BIT IS ON THEN     57690021
*                                      REGSIZE KEYWORD WAS              57720021
*                                      SPECIFIED FOR THIS REGION        57750021
         BO    PRMMESG3                WILL INFORM OPERATOR OF ERROR    57780021
         CH    R7,N14                  WAS REGION 14 TESTED?            57810021
         BE    PRMMESG5                IF SO,VALIDATION IS COMPLETED.   57840021
PRMMESG2 LA    R6,FOUR(R6)             PREPARE FOR NEXT REGION          57870021
         B     PRMMESG1                                                 57900021
PRMMESG3 EQU   *                                                        57930021
         MVC   LISTMAC(WTO14L),WTO14   MOVE LIST WTO TO WORK AREA       57960021
         LA    R2,LISTMAC                                               57990021
         XC    THTYEIGT(TWTYSIX,R2),THTYEIGT(R2) CLEAR VARIABLE PART    58020021
         MVC   KYWD1(EIGHT),REGSZEDC   PUT KEYWORD IN                   58050021
         OI    REGWTOFL,REGWTOM        SET INTERNAL FLAG ON             58080021
         CH    R7,N10                  IS REGION NO. ABOVE 9            58110021
         BNL   PRMMESG4                IF SO,GO ELSEWHERE               58140021
         STC   R7,KYWD1+EIGHT          PUT REGNO IN                     58170021
         MVZ   KYWD1+EIGHT(ONE),ZONES  CONVERT TO EBCDIC                58200021
         MVI   KYWD1+NINE,RTPAREN      CLOSE WITH RIGHT PARENTH.        58230021
         B     PRMMESG                                                  58260021
PRMMESG4 EQU   *                                                        58290021
         CVD   R7,CVBDWD               CONVERT TO DECIMAL               58320021
         UNPK  CVBDWD(TWO),CVBDWD6(TWO)  UNPACK TO 1ST 2 BYTES          58350021
         MVZ   CVBDWD1(ONE),ZONES      PUT ZONE ON LOW ORDDR DIGIT      58380021
         MVC   KYWD1+EIGHT(TWO),CVBDWD MOVE EBCDIC NUMBERS IN           58410021
         XC    CVBDWD(EIGHT),CVBDWD    CLEAR WORK WORD                  58440021
         MVI   KYWD1+TEN,RTPAREN       CLOSE OFF WITH RIGHT PARENTH.    58470021
         B     PRMMESG                 AND ISSUE WTO                    58500021
PRMMESG5 EQU   *                                                        58530021
         SPACE                                                          58560021
         LM    R14,R12,TWELVE(R13) RESTORE REGISTERS                    58590021
         B     FOUR(R14)           RETURN AND CONTINUE                  58620021
         SPACE                                                          58650021
RETMAIN1 LM    R14,R12,TWELVE(R13) RESTORE REGISTERS                    58680021
         BR    R14                 RETURN AND REJECT START TS           58710021
         SPACE                                                          58740021
PRMDFDRV MVC   DRVR(SIX),DEFDRV    MOVE DEFAULT DRVER NAME TO WK AREA   58770021
         MVC   DRVR2(SIX),DEFDRV   MOVE DEF DRV NAME TO BLDL LIST       58800021
         MVC   DRVR3(SIX),DEFDRV                                        58830021
         B     PRMSMF            BR TO TEST SMF PARAMETERS              58860021
         SPACE                                                          58890021
PRMTEST2 CLC   LIMUSER(TWO),MAXNUSER IS USER VALUE GR TH TERMAX VALUE   58920021
         BH    MAXDFLT1            YES-BRANCH TO USE TERMAX FOR USER    58950021
         B     PRMREGNM            NO BR AND CONTINUE                   58980021
         SPACE                                                          59010021
PRMTEST1 LA    R4,TRMX             GET ADR TERMAX KEYWORD               59040021
         LA    R6,SIX              LENGTH OF KYWD LESS ONE              59070021
         BAL   R7,PRMTSTRT         BR TO GET VALUE AND TEST IT          59100021
         ST    R3,MAXUSER          STORE VALUE IN WK AREA               59130021
         B     PRMLIMUS            BR TO TEST IF USER VALUE IS MISSING  59160021
         SPACE                                                          59190021
PRMTEST3 LA    R4,REGN             GET ADR REGNMAX PARAMETER            59220021
         LA    R6,SEVEN            LENGTH OF KEYWORD LESS ONE           59250021
         BAL   R7,PRMTSTRT         BR TO GET VALUE AND TEST IT          59280021
PRMCONT2 CH    R3,N14              IS VALUE GR THAN 14                  59310021
         BH    PRMERR2             YES BRANCH                           59340021
         STH   R3,REGNUM           STORE NUM REGIONS IN WK AREA         59370021
         B     PRMMAPEN            BR TO TEST IF MAP VALUE IS MISSING   59400021
         SPACE                                                          59430021
PRMTEST4 LA    R4,MAPN             GET ADR OF MAP KEYWORD               59460021
         LA    R6,THREE            GET LENGTH KEYWORD LESS ONE          59490021
         BAL   R7,PRMTSTRT         BR TO GET VALUE AND TEST IT          59520021
         STH   R3,MAPENT           STORE NUM MAPS IN WK AREA            59550021
         B     PRMDSPCH            BR TO TEST IF DRVR PARAM IS MISSING  59580021
         SPACE                                                          59610021
PRMERR2  BAL   R7,PRMERR1          B TO ERR RTN                         59640021
         B     PRMCONT2            B TO TEST VALUE                      59670021
         SPACE                                                          59700021
PRMTSTRT MVC   LISTMAC(WTO12L),WTO12 MOVE WTOR LIST TO WK AREA          59730021
         MVC   KYWD1(EIGHT),ZERO(R4) MOVE KEYWORD IN ERROR INTO LIST    59760021
PRMTST2  LA    R1,LISTMAC          GET ADDRESS OF LIST OF WTO           59790021
         SR    R0,R0               CLEAR REGISTER                       59820021
         IC    R0,CONSLID          PUT CONSOLE ID INTO REG 0            59850021
         WTO   MF=(E,(1))          ISSUE WTO                            59880021
         MVC   LISTMAC(WTOR5L),WTOR5 MVE LIST INTO WK AREA              59910021
         LA    R3,TWTYSIX          GET LENGTH OF REPLY FIELD            59940021
         BAL   R9,WTORRTN1         BR TO WTOR RTN                       59970021
         SR    R3,R3               ZERO REGISTER FOR COUNT              60000021
         CLI   ZERO(R5),BLANK      IS IT A BLANK                        60030021
         BE    PRMTST1             YES BR AND REISSUE WTOR              60060021
         EX    R6,PRMCOMP          COMP REPLY TO KEYWORD IN QUESTION    60090021
         BNE   PRMTST1             NOT EQ-BR AND RE-ISSUE WTOR          60120021
         SPACE                                                          60150021
         AR    R5,R6               UPDATE REPLY PTR TO PT AT VALUE      60180021
         LA    R5,ONE(R5)                                               60210021
         LR    R1,R5               SAVE PTR TO VALUE                    60240021
         CLI   ZERO(R5),BLANK      IS IT A BLANK                        60270021
         BE    PRMTST1             YES-BR AND REISSUE WTOR              60300021
PRMLOOP1 CLI   ZERO(R5),CZERO      IS DIGIT LESS TH ZERO         A45370 60310021
         BL    PRMERR1             YES BR TO HANDLE ERROR        A45370 60320021
         CLI   ZERO(R5),CNINE      IS DIGIT GR TH NINE           A45370 60322021
         BH    PRMERR1             YES BR TO HANDLE ERROR        A45370 60324021
         LA    R3,ONE(R3)          NO-UPDATE CT BY ONE                  60330021
         LA    R5,ONE(R5)          UPDATE REPLY PTR BY ONE              60360021
         CLI   ZERO(R5),BLANK      IS IT A BLANK                        60390021
         BNE   PRMLOOP1            NO-BR AND CONTINUE SEARCH FOR END NO 60420021
         CH    R3,N5               IS LENGTH NUM GR TH 5                60450021
         BH    PRMERR1             YES-BR TO HANDLE ERROR               60480021
         BCTR  R3,ZERO             DECREMENT LENGTH BY ONE              60510021
         O     R3,PACK1            PUT IN NECESSARY DIGITS FOR PACK     60540021
         EX    R3,T00PACK          PACK THE NUMBER                      60570021
         CVB   R3,CVBDWD           CONVERT THE VALUE TO BINARY          60600021
         XC    CVBDWD(EIGHT),CVBDWD CLEAR DOUBLE WORD USED FOR CVB      60630021
         LTR   R3,R3               IS NUM 0 OR NEGATIVE                 60660021
         BC    12,PRMERR1          YES BR TO HANDLE ERROR               60690021
         BR    R7                  RETURN TO MAIN RTN (CALLER)          60720021
         SPACE                                                          60750021
PRMTST1  MVC   LISTMAC(WTO14L),WTO14 MVE LIST OF WTO TO WK AREA         60780021
         LA    R1,REPLYAD          GET ADRR OF REPLY                    60810021
         MVC   KYWD1(TWTYSIX),ZERO(R1) MVE KYWD IN ERROR INTO LIST      60840021
         B     PRMTST2             BR TO ISSUE MESSAGE                  60870021
PRMERR1  MVC   LISTMAC(WTO13L),WTO13 MOVE LIST WTO TO WK AREA           60900021
         LA    R1,REPLYAD          GET ADRR OF REPLY                    60930021
         MVC   KYWD4(TWTYSIX),ZERO(R1) MOVE KEYWORD IN ERROR INTO LIST  60960021
         B     PRMTST2             BR TO ISSUE MESSAGE                  60990021
         SPACE                                                          61020021
WTORRTN1 LA    R1,LISTMAC          GET ADDR LIST FORM WTOR              61050021
         LA    R5,REPLYAD          GET ADDR OF ANSWER FIELD             61080021
         XC    ZERO(N76,R5),ZERO(R5)  CLEAR ANS AND ECB FIELD    A45370 61110021
         SR    R0,R0               CLEAR REGISTER                       61170021
         IC    R0,CONSLID          PUT CONSOLE ID INTO REG 0            61200021
         WTOR  ,REPLYAD,(3),ECBAD,MF=(E,(1))                            61230021
         WAIT  1,ECB=ECBAD         WAIT FOR REPLY                       61260021
         OC    ZERO(TWTYSIX,R5),BLANKS  DO FOLDING ON REPLY             61290021
         CLC   ZERO(SIX,R5),CANCEL DOES REPLY EQ CANCEL                 61320021
         BNE   ZERO(R9)            NO - RETURN                          61350021
         B     RETMAIN1            YES - REJECT START TS                61380021
         EJECT                                                          61410021
         SPACE                                                          61440021
**********************************************************************  61470021
*                                                                    *  61500021
*                        CONSTANTS FOR PARM TEST ROUTINE             *  61530021
*                                                                    *  61560021
**********************************************************************  61590021
         SPACE 3                                                        61620021
CANCEL   DC    C'CANCEL'                                                61650021
BLANKS   DC    CL26' '                                                  61680021
N5       DC    H'5'                                                     61710021
N14      DC    H'14'                                                    61740021
N10      DC    H'10'                                                    61770021
ZONES    DC    X'FF'                                                    61800021
DEFDRV   DC    C'IKJEAD'                                                61830021
PACK1    DC    F'112'                                                   61860021
REGN     DC    C'REGNMAX='                                              61890021
MAPN     DC    C'MAP=    '                                              61920021
TRMX     DC    C'TERMAX= '                                              61950021
REGSZEDC DC    C'REGSIZE('                                              61980021
         SPACE                                                          62010021
T00PACK  PACK  CVBDWD(ZERO),ZERO(ZERO,R1)                               62040021
PRMCOMP  CLC   ZERO(ZERO,R5),ZERO(R4)                                   62070021
         SPACE 4                                                        62100021
WTO9     WTO   'IKJ016I REGNMAX=   - REGIONS STARTING=  ',DESC=5,MCSFLAX62130021
               G=(REG0),ROUTCDE=2,MF=L                                  62160021
WTO9L    EQU   *-WTO9                                                   62190021
         SPACE 3                                                        62220021
WTO10    WTO   'IKJ017I SMF NOT ACTIVE - SMF PARAMETER IGNORED',DESC=5,X62250021
               MCSFLAG=(REG0),MF=L                                      62280021
WTO10L   EQU   *-WTO10                                                  62310021
         SPACE 3                                                        62340021
WTO12    WTO   'IKJ063I THIS KEYWORD IS MISSING - CCCCCCCC',DESC=5,MCSFX62370021
               LAG=(REG0),MF=L                                          62400021
WTO12L   EQU   *-WTO12                                                  62430021
         SPACE 3                                                        62460021
WTO13    WTO   'IKJ064I THE VALUE OF THIS KEYWORD IS INVALID - CCCCCCCCX62490021
               CCCCCCCCCCCCCCCCCC',DESC=5,MCSFLAG=(REG0),MF=L           62520021
WTO13L   EQU   *-WTO13                                                  62550021
         EJECT                                                          62580021
WTO14    WTO   'IKJ061I THIS KEYWORD IS INVALID - CCCCCCCCCCCCCCCCCCCCCX62610021
               CCCCC',DESC=5,MCSFLAG=(REG0),MF=L                        62640021
WTO14L   EQU   *-WTO14                                                  62670021
WTO14XX  WTO   'IKJ067I THE ABOVE KEYWORD AND ITS VALUE WILL BE IGNOREDX62700021
               ',DESC=5,MCSFLAG=(REG0),MF=L                             62730021
WTO14XL  EQU   *-WTO14XX                                                62760021
         SPACE 4                                                        62790021
WTOR5    WTOR  'IKJ066D REPLY ''KEYWORD=VALUE'' OR ''CANCEL''',DESC=2,MX62820021
               CSFLAG=(REG0),MF=L                                       62850021
WTOR5L    EQU   *-WTOR5             LENGTH OF MESSAGE                   62880021
         EJECT                                                          62910021
**********************************************************************  62940021
*                                                                    *  62970021
* THIS SECTION EDITS THE PARM BUFFER AND THE CIB MODIFYS.IT LOOKS    *  63000021
* FOR TS PARAMETERS AND BRANCHES TO THE SUBROUTINE TO HANDLE THE     *  63030021
* KEYWORD. IF A KEYWORD IS MISPELLED OR INVALID THEN IT IS IGNORED.  *  63060021
* IF IT IS VALID THEN VALUE OF KEYWORD IS SAVED.                     *  63090021
*                                                                    *  63120021
**********************************************************************  63150021
         SPACE 4                                                        63180021
EDITRTN  STM   R14,R12,TWELVE(R13) SAVE REGISTERS                       63210021
         BALR  BASEREG,ZERO        SET UP ADDRESSABILITY                63240021
         USING *,BASEREG           ESTABLISH BASE                       63270021
         L     PARMBUF,PARMADR     GET ADR PARM DATA                    63300021
         L     CARDPTR,PARMADR     GET ADR PARM DATA                    63330021
         LA    KWDENREG,KYWDEND    GET ADR OF END OF TABLE OF KEY WORDS 63360021
         L     R3,PARMEND          GET STOPPER ADR PARM DATA            63390021
CRDLOOP2 LA    RTNREG,RTNADTAB     GET ADR OF TABLE OF RTN ADDRESSES    63420021
         LA    LKYWDREG,KYWDTAB    GET ADR OF LENGTH OF FIRST KEY WD    63450021
         LA    KYWDREG,KYWD        GET ADR OF FIRST KEY WORD            63480021
PARMLOOP LA    CARDSTOP,N79(CARDPTR) GET PTR TO END OF CARD       M1574 63490021
         CR    R3,CARDPTR          IS IT END OF PARM FIELD              63540021
         BE    CIBMODED      YES,BRANCH                                 63570021
IDLOOP   CLI   ZERO(PARMBUF),BLANK IS PARM PTR POINTING AT BLANK        63600021
         BNE   IDTSC               NO-BRANCH                            63630021
         LA    PARMBUF,ONE(PARMBUF) YES-UPDATE PTR BY ONE               63660021
         CR    PARMBUF,CARDSTOP    IS IT END OF CARD                    63690021
         BNE   IDLOOP              NO CONTINE SEARCH FOR ID             63720021
NXTCARD  LA    CARDPTR,EIGHTY(CARDPTR) UPDATE PTR TO NEXT CARD          63750021
         LR    PARMBUF,CARDPTR     SET PARM PTR TO BEG OF CARD          63780021
         B     PARMLOOP            BRANCH TO SEARCH NXT CARD            63810021
         SPACE                                                          63840021
IDTSC    CLC   ZERO(THREE,PARMBUF),TS  DOES ID=TS                       63870021
         BNE   NXTCARD             NO-BRANCH AND GET NEXT CARD          63900021
         LA    PARMBUF,THREE(PARMBUF) UPDATE PTR 2 CHAR                 63930021
KYWDLOOP CR    PARMBUF,CARDSTOP    IS IT END OF CARD                    63960021
         BE    NXTCARD             YES BRANCH AND GET NEXT CARD         63990021
         CLI   ZERO(PARMBUF),BLANK DOES PARM PTR POINT AT A BLANK       64020021
         BNE   KYWDTEST            NO BRANCH AND CHECK KEY WORD         64050021
         LA    PARMBUF,ONE(PARMBUF) UPDATE PTR BY ONE                   64080021
         B     KYWDLOOP            BR AND CONTINUE SEARCH FOR KEYWD     64110021
         EJECT                                                          64140021
KYWDTEST LH    R1,ZERO(LKYWDREG)   GET LENGTH OF KEY WORD IN TABLE      64170021
         EX    R1,COMPKYWD         COMPARE WITH KEYWORD IN PARM FIELD   64200021
         BE    PARMKYWD            IF EQUAL BRANCH                      64230021
         LA    RTNREG,FOUR(RTNREG) UPDATE ADR OF RTN TABLE              64260021
         LA    LKYWDREG,TEN(LKYWDREG) UPDATE PTR TO LENGTH NXT KYWD     64290021
         LA    KYWDREG,TEN(KYWDREG) UPDATE PTR TO NXT KYWD IN TABLE     64320021
         CR    RTNREG,KWDENREG     IS IT END OF KEYWORD TABLE           64350021
         BNE   KYWDTEST            NO BR AND CONTINUE                   64380021
         B     PARMINIT            YES -BRANCH                          64410021
         SPACE                                                          64440021
BLNKLOOP LA    PARMBUF,ONE(PARMBUF) UPDATE PTR-SEARCH FOR NXT KYWD      64470021
         CR    PARMBUF,CARDSTOP    IS IT END OF CARD                    64500021
         BE    NXTCARD             YES-BRANCH AND GET NXT CARD          64530021
         CLI   ZERO(PARMBUF),BLANK IS IT A BLANK                        64560021
         BE    NXTKYWD             YES BRANCH                           64590021
         B     BLNKLOOP            BR AND CONTINUE SEARCH FOR BLANK     64620021
NXTKYWD  LA    PARMBUF,ONE(PARMBUF) UPDATE PTR BY ONE                   64650021
         B     KYWDLOOP            BR TO SEARCH FOR NXT KYWD            64680021
PARMKYWD L     RTNREG,ZERO(RTNREG) GET ADR RTN TO PROC KYWD             64710021
         LA    R1,ONE(R1)          UPDATE LENGTH KEY WD BY ONE          64740021
         AR    R6,R1               UPDTE PTR TO BUF PASS KEY WD         64770021
         CR    R6,CARDSTOP         IS IT END CARD OR CIB BUF            64800021
         BH    CRDLOOP1            YES BRANCH                           64830021
         BALR  R14,R7              NO-BR TO PROCESS KEY WORD            64860021
         SPACE                                                          64890021
PARMINIT LA    RTNREG,RTNADTAB     GET ADR TABLE OF RTN ADDRESSES       64920021
         LA    LKYWDREG,KYWDTAB    GET ADR OF LENGTH OF FIRST KY WD     64950021
         LA    KYWDREG,KYWD        GET ADR FIRST KY WD                  64980021
         B     BLNKLOOP            BR TO GET NEXT KEYWORD               65010021
         SPACE                                                          65040021
CRDLOOP1 LA    CARDPTR,EIGHTY(CARDPTR) GET NEXT CARD                    65070021
         LR    PARMBUF,CARDPTR     SET BUF PTR TO BEG NXT CRD           65100021
         B     CRDLOOP2            B TO GET NEXT KEYWORD                65130021
         SPACE 4                                                        65160021
CIBMODED TM    MODIFYSW,MODIFY     IS SW SET TO INDICATE MODIFYS IN CIB 65190021
         BZ    EDITEND             NO RETURN                            65220021
         MVI   MODSW,ONBIT         SET SW INDICATING EDIT OF MODIFYS    65250021
         L     CIBBUF,MODFYADR     GET ADR MODIFYS IN CIB               65280021
         L     R4,CIBENDAD         GET ADR OF END OF CIB MODIFYS        65310021
         LA    KWDENREG,KYWDEND    GET ADR END OF TAB OF KYWDS          65340021
EDLOOP2  LA    RTNREG,RTNADTAB     GET ADR OF TABLE OF RTN ADDRESSES    65370021
         LA    LKYWDREG,KYWDTAB    GET ADR OF LENGTH OF FIRST KEY WD    65400021
         LA    KYWDREG,KYWD        GET ADR OF FIRST KEY WORD            65430021
         ST    R6,CIBPTR1          SAVE BEG ADDR OF KYWD                65460021
COMPAGN  LH    R1,ZERO(LKYWDREG)   GET LENGTH OF KEY WORD IN TABLE      65490021
         EX    R1,COMPKYWD         DOES CIB KYWD=KEY WORD IN TABLE      65520021
         BE    EDITKYWD            YES BRANCH TO PROCESS KYWD           65550021
         LA    RTNREG,FOUR(RTNREG) NO-UPDTE PTR TO RTNS                 65580021
         LA    LKYWDREG,TEN(LKYWDREG) UPDTE PTR TO LENGTH NXT KEY WD    65610021
         LA    KYWDREG,TEN(KYWDREG) UPDATE PTR TO NXT KEY WORD          65640021
         CR    RTNREG,KWDENREG     IS IT END OF KYWD TABLE              65670021
         BNE   COMPAGN             NO-DO NXT COMPARE                    65700021
CIBLOOP9 LA    CIBBUF,ONE(CIBBUF)  UPDATE CIB PTR BY ONE                65730021
         CR    CIBBUF,R4           IS IT END OF CIB                     65760021
         BNL   CIB2               YES, THEN RETURN                      65790021
         CLI   ZERO(CIBBUF),LFPAREN DOES IT POINT TO A LEFT PAREN       65820021
         BE    CIBLOOP5            YES BR TO SEARCH FOR RT PAREN        65850021
         CLI   ZERO(CIBBUF),COMMA  DOES PTR PT AT COMMA                 65880021
         BE    CIB2                YES BRANCH                           65910021
         B     CIBLOOP9            NO BR AND CONTINUE SEARCH            65940021
CIBLOOP5 LA    CIBBUF,ONE(CIBBUF)  YES UPDTE PTR PASS PAREN             65970021
         CR    CIBBUF,R4           IS IT END OF OVERRIDES               66000021
         BNL   CIB2               YES, THEN RETURN                      66030021
         CLI   ZERO(CIBBUF),RTPAREN IS IT A RIGHT PAREN                 66060021
         BNE   CIBLOOP5            NO BR AND CONTINUE SEARCH            66090021
         B     CIBLOOP9            YES BR AND SEARCH FOR COMMA          66120021
         SPACE                                                          66150021
CIB2     ST    R6,CIBPTR           SAVE PTR TO CIB OVERRIDES            66180021
         LR    R7,R6               GET END OF KYWD AND VALUE            66210021
         L     R10,CIBPTR1         GET END ADR OF KEYWORD               66240021
         SR    R7,R10              GET LENGTH OF KYWD AND VALUE         66270021
         MVC   LISTMAC(WTO17L),WTO17 MVE LIST OF WTO TO WK AREA         66300021
         LA    R1,LISTMAC          GET ADDR OF LIST OF WTO              66330021
         XC    THTYEIGT(TWTYSIX,R1),THTYEIGT(R1) BLANK OUT PART OF LIST 66360021
         BCTR  R7,ZERO             DECREMENT LENGTH BY ONE              66390021
         EX    R7,KYWDMVE          MVE KYWD IN ERROR INTO LIST          66420021
         SR    R0,R0               CLEAR REGISTER                       66450021
         IC    R0,CONSLID          PUT CONSOLE ID INTO REG 0            66480021
         WTO   MF=(E,(1))          ISSUE WTO                            66510021
         MVC   LISTMAC(WTOR6L),WTOR6 MVE LIST INTO WK AREA              66540021
         LA    R10,TWTYSIX         GET LENGTH OF REPLY FIELD            66570021
         B     WTORRTN2            BR TO WTOR RTN                       66600021
CIB1     L     R6,CIBPTR           RESTORE REG 6 WITH ADR OF CIB        66630021
*                                  OVERRIDES                            66660021
         CR    CIBBUF,R4           IS IT END OF CIB BUFFER              66690021
         BNL   EDITEND             YES,THEN RETURN                      66720021
         LA    CIBBUF,ONE(CIBBUF)  UPDATE PTR TO NEXT KEYWORD           66750021
         B     EDLOOP2                                                  66780021
         SPACE                                                          66810021
EDITEND  TM    SMF1SW,ONBIT        IS SW ON TO INDICATE SMF DSA BIT IS  66840021
*                                  SET AND OPT=2 MUST BE USED           66870021
         BZ    EDITEND2            NO BR TO RESTORE REGISTERS           66900021
         MVC   LISTMAC(WTO22L),WTO22 MVE WTO LIST TO WK AREA            66930021
         LA    R1,LISTMAC          GET ADR WTO LIST                     66960021
         SR    R0,R0               CLEAR REGISTER                       66990021
         IC    R0,CONSLID          PUT CONSOLE ID INTO REG 0            67020021
         WTO   MF=(E,(1))          ISSUE WTO TO OP OPT=2 TO BE USED     67050021
EDITEND2 LM    R14,R12,TWELVE(R13) YES-RESTORE REGISTERS                67080021
         B     FOUR(R14)           RETURN TO CONTINUE START TS          67110021
         SPACE                                                          67140021
EDITEND1 LM    R14,R12,TWELVE(R13) RESTORE REGISTERS                    67170021
         BR    R14                 RETURN TO REJECT START TS            67200021
         SPACE                                                          67230021
EDITKYWD L     RTNREG,ZERO(RTNREG) GET ADR OF RTN TO HANDLE KYWD        67260021
         LA    R1,ONE(R1)          UPDATE LENGTH KEY WD BY ONE          67290021
         AR    R6,R1               UPDATE PTR TO BUF PASS KEY WD        67320021
         CR    CIBBUF,R4           IS IT END OF CIB BUFFER              67350021
         BNL   CIB2               KEYWORD IN ERROR                      67380021
         BALR  R14,R7              NO BRANCH TO PROCESS KY WD           67410021
EDITKYW2 LA    CIBBUF,ONE(CIBBUF)  UPDATE PTR BY ONE                    67440021
         CR    CIBBUF,R4           IS IT END OF OVERRIDES               67470021
         BNL   EDITEND             YES,THEN RETURN                      67500021
         CLI   ZERO(CIBBUF),LFPAREN IS IT A LEFT PARENTHESIS            67530021
         BE    EDITKYW6            YES BR TO SEARCH FOR RT PAREN        67560021
         CLI   ZERO(CIBBUF),COMMA  IS IT A COMMA DELIMITER              67590021
         BNE   EDITKYW2            NO CONTINUE SEARCH                   67620021
         LA    CIBBUF,ONE(CIBBUF)  YES UPDTE PTR PASS COMMA             67650021
         B     EDLOOP2             BR TO PROCESS NEXT KEY WORD          67680021
EDITKYW6 LA    R6,ONE(R6)          UPDTE PTR PASS LEFT PAREN            67710021
         CR    R6,R4               IS IT END OF OVERRIDES               67740021
         BNL   EDITEND             YES,THEN RETURN                      67770021
         CLI   ZERO(R6),RTPAREN IS IT A RIGHT PAREN                     67800021
         BNE   EDITKYW6            NO BR AND CONTINUE SEARCH            67830021
         B     EDITKYW2            YES BR AND SEARCH FOR COMMA          67860021
         SPACE                                                          67890021
TERMXRTN BAL   R5,CVBRTN           BR TO CONVERT NUM TO BINARY          67920021
         BAL   R9,EDITERR          ERROR RTN                            67950021
         B     EDITERR5            B TO ISSUE WTOR                      67980021
         ST    R15,MAXUSER         STORE NUMBER MAX USERS IN WK AREA    68010021
         BR    R14                 RETURN                               68040021
         SPACE 2                                                        68070021
USERSRTN BAL   R5,CVBRTN           BR TO CONVERT NUMBER TO BINARY       68100021
         B     USER1               THIS INSTR NEEDED FOR BR TABLE       68130021
         B     USER2               IF ZERO IT IS NOT AN ERROR           68160021
USER00   EQU   *                                                        68190021
         C     R15,USERNUM         IS NUMBER GR TH MAX ALLOWED          68220021
         BH    USER2               YES BR TO HANDLE ERROR               68250021
         STH   R15,LIMUSER         NO SAVE NUMBER OF USERS              68280021
         MVI   USERSW,ONBIT        INDICATE THAT WE SAVED NO. OF USERS  68310021
         BR    R14                 RETURN                               68340021
USER1    LTR   R15,R15             IS NUMBER NEGATIVE                   68370021
         BZ    USER00             IF ZERO, IT IS VALID                  68400021
USER2    BAL   R9,EDITERR          BR TO HANDLE ERROR                   68430021
         B     EDITERR6            BR TO ISSUE WTOR                     68460021
         SPACE 2                                                        68490021
RGNMXRTN BAL   R5,CVBRTN           BR TO CONVERT NUM TO BINARY          68520021
RGMX2    BAL   R9,EDITERR          BR TO HANDLE ERROR                   68550021
         B     EDITERR5            BR TO ISSUE WTOR                     68580021
         CH    R15,RN14            IS NUMBER REGIONS GR TH 14           68610021
         BH    RGMX2               YES- RETURN                          68640021
         STH   R15,REGNUM          NO- STORE NUM REGIONS IN WK AREA     68670021
         BR    R14                 RETURN                               68700021
         SPACE 2                                                        68730021
SMFRTN   L     R5,CVTPTR           GET ADDR CVT                         68760021
         USING CVTSECT,R5          SET UP CVT DSECT                     68790021
         L     R5,CVTSMCA          GET ADR SYST MGMT CNTRL AREA         68820021
         LTR   R5,R5               IS ADR ZERO                          68850021
         BZ    ZERO(R14)           YES-RETURN- BYPASS SMF PROCESSING    68880021
         USING SMCABASE,R5         SET UP SMCABASE DSECT                68910021
         MVI   SMF1SW,OFFBIT       CLEAR SMF BIT BEFORE PROCESSING SMF  68940021
         TM    MODSW,ONBIT         ARE WE EDITTING MODIFYS              68970021
         BO    SMF1RTN             YES BR TO ANOTHER RTN                69000021
SMF12    MVI   SMFSW,ONBIT         SET BIT INDICATING PROC SMF PARAM    69030021
         MVC   SMFPARM1(ONE),SMCAOPT SET FOREFROUND TO BACKGROUND       69060021
         NI    SMFPARM1,SMFBIT     TURN OFF OPT1,OPT2,EXT,&FORGRND BITS 69090021
         CLI   ZERO(R6),COMMA      IS FIRST PARAMETER MISSING           69120021
         BE    SMF1                YES-BRANCH-PROCESS 2ND PARAMETER     69150021
         CLC   ZERO(THREE,R6),OFF  IS FIRST PARAM=OFF                   69180021
         BE    SMF2                YES-BRANCH                           69210021
         CLC   ZERO(FIVE,R6),OPT1  IS FIRST PARAM- OPT=1                69240021
         BE    SMF3                YES-BRANCH                           69270021
         CLC   ZERO(FIVE,R6),OPT2  IS FIRST PARAM- OPT=2                69300021
         BNE   SMF11               NO-ERROR-BYPASS THIS SMF PARAM-RETN  69330021
         TM    SMCAOPT,SMCAOPT2    YES-IS BACKGRND OPTION-OPT=2         69360021
         BZ    SMF11               NO-BR BYPASS SETTING FOREGRND        69390021
SMF6     OI    SMFPARM1,SMCAOPT2   SET FOREGRND BIT TO OPT=2            69420021
         OI    SMFPARM1,SMCAOPT1   SET FOREGROUND BIT TO OPT=1          69450021
         CLC   ZERO(THREE,R6),OFF  IS FIRST PARAM=OFF                   69480021
         BNE   SMF5                NO BRANCH                            69510021
         LA    R6,THREE(R6)        UPDATE PTR PASS 1ST PARAM            69540021
         B     SMF7                CONTINUE                             69570021
SMF5     LA    R6,FIVE(R6)         UPDTE PTR TO 2ND SMF PARAMETER       69600021
SMF7     CR    R6,R4               IS IT END OF CARD                    69630021
         BE    SMF11               YES BRANCH-ERROR                     69660021
         CLI   ZERO(R6),COMMA      IS THERE A 2ND SMF PARAMETER         69690021
         BE    SMF9                YES-BR AND PROCESS                   69720021
         CLI   ZERO(R6),RTPAREN    IS IT END OF SMF PARAMETER           69750021
         BNE   SMF11               YES BRANCH                           69780021
         TM    SMCAOPT,SMCAEXT     IS BACKGRND=YES                      69810021
         BZ    ZERO(R14)           NO-BYPASS SETTING FRGRND YES-RETURN  69840021
         OI    SMFPARM1,SMCAEXT    YES-SET FRGRND=YES                   69870021
         BR    R14                 RETURN                               69900021
SMF3     TM    SMCAOPT,SMCADSA     IS DATA ACCT BIT SET                 69930021
         BO    SMF4                YES BR OPT=2 IS TO BE USED           69960021
         TM    SMCAOPT,SMCAOPT1    IS BACKGROUND OPTION SET             69990021
         BZ    SMF11               NO-BR-BYPASS SETTING FRGRND TO 1     70020021
         OI    SMFPARM1,SMCAOPT1   NO-SET FRGRND TO ONE                 70050021
         LA    R6,FIVE(R6)         UPDATE PTR PASS 1ST PARAMETER        70080021
         B     SMF7                BR-TEST FOR 2ND PARAMETER            70110021
SMF2     TM    SMCAOPT,SMCADSA     IS DATA ACCT BIT SET                 70140021
         BO    SMF4                YES BR OPT=2 IS TO BE USED           70170021
         LA    R6,THREE(R6)        UPDATE PTR PASS 1ST PARAM            70200021
         B     SMF7                BR-TEST FOR 2ND PARAMETER            70230021
SMF1     MVC   SMFPARM1(ONE),SMCAOPT SET FOREGROUND TO BACKGROUND       70260021
         NI    SMFPARM1,ONBIT-SMCAEXT RESET EXT BIT TO 0                70290021
SMF9     LA    R6,ONE(R6)          UPDATE PTR PASS THE COMMA            70320021
         CR    R6,R4               IS IT END OF CARD                    70350021
         BE    SMF11               YES-BR TO RESET BYTE TO ZERO         70380021
         CLI   ZERO(R6),RTPAREN    IS IT A RT PAREN                     70410021
         BE    SMF11               YES ERROR RETURN                     70440021
         CLC   ZERO(EIGHT,R6),EXTYES IS 2ND PARAM-EXT=YES               70470021
         BE    SMF8                YES-BRANCH                           70500021
         CLC   ZERO(SEVEN,R6),EXTNO IS 2ND PARAM-EXT=NO                 70530021
         BE    ZERO(R14)           YES-BIT ALREADY SET- RETURN          70560021
         B     SMF11               BR-TO RESET BYTE TO ZERO-ERROR       70590021
SMF11    MVC   SMFPARM1(ONE),SMCAOPT SET FOREGROUND TO BACKGROUND       70620021
         BAL   R9,EDITERR3         BR TO HANDLE ERROR                   70650021
         B     EDITERR6            BR TO ISSUE WTOR                     70680021
SMF8     TM    SMCAOPT,SMCAEXT     IS BACKGROUND = YES                  70710021
         BZ    SMF11               NO BYPASS SETTING FRGRND             70740021
         OI    SMFPARM1,SMCAEXT    YES SET FRGRND = YES                 70770021
         BR    R14                 RETURN                               70800021
SMF4     MVI   SMF1SW,ONBIT        SET SW TO INDICATE DSA BIT IS SET    70830021
*                                  AND OPT=2 TO BE USED - MESSAGE WILL  70860021
*                                  BE SENT WHEN EDIT OF ALL PARAMETERS  70890021
*                                  IS FINISHED IN CASE THIS SMF         70920021
*                                  PARAMETER HAS BEEEN OVERRIDDEN       70950021
         B     SMF6                BR- TO USE OPT=2                     70980021
SMF1RTN  TM    SMCAMISC,SMCAOPI    IS OPERATION INTERVENTION BIT SET    71010021
         BZ    SMF12               NO BR TO PROCESS SMF OVERRIDE        71040021
         MVC   LISTMAC(WTO16L),WTO16 MVE LIST INTO WK AREA              71070021
         LA    R1,LISTMAC          GET ADR WTO LIST                     71100021
         SR    R0,R0               CLEAR REGISTER                       71130021
         IC    R0,CONSLID          PUT CONSOLE ID INTO REG 0            71160021
         WTO   MF=(E,(1))          ISSUE WTO SAYING NO SMF OVERRIDES    71190021
*                                  WHEN OPI BIT IS SET                  71220021
         B     EDITKYW6            RETURN                               71250021
DSPCHRTN CLI   SIX(R6),BLANK       IS DSPCH NAME 6 CHAR-IS DELIM BLANK  71280021
         BE    DSPCHGD             YES- PROCESS NAME                    71310021
         CLI   SIX(R6),COMMA       IS-DELIMITER COMMA                   71340021
         BE    DSPCHGD             YES -PROCESS NAME                    71370021
         BAL   R9,EDITERR          BR TO HANDLE ERROR                   71400021
         B     EDITERR6            BR TO ISSUE WTOR                     71430021
DSPCHGD  MVC   DRVR(SIX),ZERO(R6)  YES-MOVE DRIVER NAME INTO NEC FIELDS 71460021
         MVC   DRVR2(SIX),ZERO(R6) MVE ID INTO NAME                     71490021
         MVC   DRVR3(SIX),ZERO(R6) MVE ID INTO NAME                     71520021
         BR    R14                 RETURN                               71550021
         SPACE 2                                                        71580021
SUBMTRTN BAL   R5,CVBRTN           BR TO CONVERT TO BINARY              71610021
         BAL   R9,EDITERR          BR TO HANDLE ERROR                   71640021
         B     EDITERR6            B TO ISSUE WTOR                      71670021
         STH   R15,SUBMTMAX        SAVE SUBMIT MAX VALUE IN WK AREA     71700021
         BR    R14                 RETURN                               71730021
         SPACE 2                                                        71760021
REGSZRTN BAL   R5,CVBRTN           BR TO CONVERT VALUE TO BINARY        71790021
REGSZ2   BAL   R9,EDITERR          BR TO HANDLE WTOR                    71820021
         B     EDITERR6                GIVE OPERATOR CHANCE TO CANCEL,  71850021
*                                      RESPECIFY OR OVERRIDE.           71880021
         CH    R15,RN14            IS REG NUM LESS TH 14                71910021
         BH    REGSZ2              NO-RETURN                            71940021
         LR    R7,R15              YES-SAVE REG NUM                     71970021
         LR    R6,R1               RESTORE REG 6                        72000021
REGLP1   LA    R6,ONE(R6)          UPDATE BUF PTR                       72030021
         CR    R6,R4               IS IT END OF CARD OR BUF             72060021
         BE    REGLP2              YES RETURN                           72090021
         CLI   ZERO(R6),LFPAREN    IS IT LEFT PARENTHESIS               72120021
         BNE   REGLP1              NO-BR AND CONTINUE SEARCH            72150021
         LA    R6,ONE(R6)          YES-UPDATE BUF PTR TO REG.SIZE       72180021
         CR    R6,R4               IS IT END OF CARD OR BUF             72210021
         BE    REGLP2              YES BRANCH                           72240021
         BAL   R5,CVBRTN           BR TO CONVERT TO BINARY              72270021
REGSZ3   C     R15,RN0             IF ZERO REG SIZE IT IS A GOOD NO     72300021
         BL    REGSZ5              IF LESS TH ZERO ERROR                72330021
         LR    R9,R15              NO- SAVE REGION SIZE                 72360021
         LR    R6,R1               UPDATE BUF PTR TO LSQS SIZE          72390021
*****    THE FOLLOWING SECTION OF CODE WAS ADDED FOR APAR 44022 *****   72420021
         CLI   ZERO(R6),CONSTK         WAS IT IN K UNITS?               72450021
         BNE   REGSZ5                  IF NOT=ERROR                     72480021
         LA    R6,ONE(R6)                                               72510021
         CLI   ZERO(R6),COMMA      IS IT A COMMA DELIMITER              72540021
         BNE   REGLP3                  MAKE SURE IT'S REALLY INVALID    72570021
         LA    R6,ONE(R6)          UPDATE PTR BY ONE                    72600021
         CR    R6,R4               IS IT END OF CARD OR BUF             72630021
         BE    REGLP2              YES BRANCH                           72660021
         BAL   R5,CVBRTN           BR TO CONVERT TO BINARY              72690021
REGSZ4   C     R15,RN0             IF ZERO LSQS SIZE IT IS VALID        72720021
         BL    REGSZ5              IF LESS TH ZERO ERROR                72750021
         LR    R6,R1              PUT CURRENT DATA PTR FOR NEXT TEST    72780021
         CLI   ZERO(R6),CONSTK    WAS LSQS IN K UNITS?                  72810021
         BNE   REGSZ5             IF NOT=ERROR                          72840021
         CLI   ONE(R6),RTPAREN    ENCLOSED IN PARENTHESES?              72870021
         BNE   REGSZ55            IF NOT=ERROR                          72900021
         LTR   R9,R9                    REG SIZE=0?                     72930021
         BZ    REGSZ61                  IF SO,SEPARATE TEST NEEDED.     72960021
         LTR   R15,R15                  IS LSQS=0? AND REG SIZE ISN'T?  72990021
         BZ    REGSZ5                   THEN IT'S AN ERROR              73020021
         CR    R15,R9              IS LSQS SIZE GR TH OR EQ TO REG SIZE 73050021
         BNL   REGSZ5              YES-ERROR-RETURN                     73080021
         LA    R5,ONE                   TEST FOR EVEN NUMBER REGN SIZE  73110021
         NR    R5,R9                    IF SO, IGNORE                   73140021
         BZ    REGSZ41                  THE NEXT STEP                   73170021
         LA    R9,ONE(R9)               = INCREMENT BY ONE              73200021
REGSZ41  EQU   *                                                        73230021
         LA    R5,ONE                   TEST FOR EVEN  NUMBER LSQS SIZE 73260021
         NR    R5,R15                   IF SO,IGNORE                    73290021
         BZ    REGSZ42                  NEXT STEP                       73320021
         LA    R15,ONE(R15)             = INCREMENT BY ONE.             73350021
REGSZ42  EQU   *                                                        73380021
         LR    R0,R15                   ADD THE TWO                     73410021
         AR    R0,R9                    SIZES TOGETHER                  73440021
         CH    R0,RNSZE                 AND TEST FOR                    73470021
         BH    REGSZ5                   VALID REQUEST=16382 1K BYTES    73500021
         SRA   R9,ONE              NO-CONVERT REG SZE TO NO. 2K BYTES   73530021
         SRA   R15,ONE             CONVERT LSQS SZE TO NO. 2K BYTES     73560021
REGSZ6   EQU   *                                                        73590021
         SLL   R7,TWO                   MULTIPLY REG NO. BY 4           73620021
         LA    R10,REGDISP         GET ADDR IN WK AREA OF WRD BEF RG SZ 73650021
         AR    R7,R10              ADD REGNUMX4 TO GET ADR OF REG SIZE  73680021
*                                  AND LSQS SIZE FOR THAT REG NUM       73710021
         STH   R9,ZERO(R7)         PUT REG SIZE IN WK AREA AT THAT ADR  73740021
         STH   R15,TWO(R7)         PUT LSQS SIZE IN WK AREA             73770021
         OI    ZERO(R7),HIBIT          SET HI ORDER BIT ON              73800021
*                                      FOR LATER VALIDATION             73830021
         BR    R14                 RETURN                               73860021
REGSZ61  EQU   *                                                        73890021
         LTR   R15,R15                  LSQS=0 TOO?                     73920021
         BNZ   REGSZ5                   IF NOT=ERROR                    73950021
         B     REGSZ6                                                   73980021
         SPACE                                                          74010021
REGSZ5   BAL   R9,EDITERR                                               74040021
         B     EDITERR6                GIVE OPERATOR CHANCE TO CANCEL,  74070021
*                                      RESPECIFY OR OVERRIDE.           74100021
REGSZ55  BAL   R9,EDITERR                                               74130021
         B     EDITERR6                COMPLETE INFO. TO OPERATOR       74160021
*****             THIS ENDS THE SECTION OF CODE CHANGED FOR APAR44022*  74190021
REGLP2   TM    MODSW,ONBIT         ARE WE EDITTING MODIFYS              74220021
         BZ    ZERO(R14)           NO RETURN                            74250021
         B     CIB2                YES BRANCH                           74280021
REGLP3   EQU   *                                                        74310021
         C     R15,RN0                 REGION SIZE=0?                   74340021
*                                      THEN NO LSQS IS REQUIRED         74370021
         BE    REGSZ6             CAN NOW SET UP ENTRY FOR REGION       74400021
         CR    R6,R4                   END OF CARD OR BUFFER            74430021
         BE    REGLP2                  IF SO, PUT MSG OUT               74460021
         B     REGSZ5                  OTHERWISE OTHER MESSAGE ISSUED   74490021
         SPACE 2                                                        74520021
MAPRTN   BAL   R5,CVBRTN           BR TO CONVERT TO BINARY              74550021
         BAL   R9,EDITERR          BR TO HANDLE ERROR                   74580021
         B     EDITERR5            BR TO ISSUE WTOR                     74610021
         STH   R15,MAPENT          STORE NUMBER MAP ENTRIES             74640021
         BR    R14                 RETURN TO GET NXT KEY WORD           74670021
*****    THE FOLLOWING SECTION OF CODE WAS ADDED FOR APAR 44022 *****   74700021
TSCRGRTN EQU   *                                                     *  74730021
         BAL   R5,CVBRTN                BR TO CONVERT TO BINARY      *  74760021
         BAL   R9,EDITERR               IF ERROR RC -ISSUE WTO       *  74790021
         B     EDITERR6                 AND WTOR                     *  74820021
         CLI   ZERO(R1),CONSTK         WAS SPECIFIED IN K UNITS?        74850021
         BNE   TSCRG200                IF NOT,ERROR CONDITION           74880021
         LA    R9,ONE                   CHECK FOR ODD NUMBER         *  74910021
         NR    R9,R15                   TEST LOW ORDER BIT           *  74940021
         BZ    TSCRG100                 IF ALREADY EVEN LEAVE IT BE  *  74970021
         LA    R15,ONE(R15)             OTHERWISE INCREMENT BY ONE   *  75000021
*                                                                    *  75030021
TSCRG100 CH    R15,RNSZE                MAKE SURE IT'S VALID 3 BYTE  *  75060021
         BH    TSCRG200                 ADDRESS-MAX 16382               75090021
         SLA   R15,TEN                 CONVERT TO NUMBER OF BYTES       75120021
         ST    R15,TSCRGSZE             AND SAVE FOR LATER USE WHEN  *  75150021
*                                       TOTAL STORAGE REQUIREMENTS   *  75180021
*                                       ARE NEEDED.                  *  75210021
         BR    R14                      GO TO PROCESS NEXT KEYWORD   *  75240021
TSCRG200 EQU   *                                                     *  75270021
         BAL   R9,EDITERR               INVALID SIZE - GO INFORM     *  75300021
         B     EDITERR6                 USER OF ERROR IF EDITING     *  75330021
*                                       OVERRIDES                    *  75360021
*****             THIS ENDS THE SECTION OF CODE ADDED FOR APAR 44022 ** 75390021
         SPACE 2                                                        75420021
LPARTN   EQU   *                                                        75450021
         STM   R7,R5,SAVE2   SAVE MAINLINE REGS.                        75480021
         TM    MODSW,ONBIT         IS MODIFY BIT SET                    75510021
         BZ    LPA13         NO,PROCESS LPA PARAMETER.                  75540021
         MVC   LISTMAC(WTO18L),WTO18 MVE LIST INTO WK AREA              75570021
         MVC   KYWD5(EIGHT),KYWD7 MVE LPA KYWD INTO LIST                75600021
         LA    R1,LISTMAC          GET ADDR OF LIST                     75630021
         SR    R0,R0               CLEAR REGISTER                       75660021
         IC    R0,CONSLID          PUT CONSOLE ID INTO REG 0            75690021
         WTO   MF=(E,(1))          ISSUE WTO SAYING YOU CANNOT          75720021
*                                  OVERRIDE LPA PARAMETER               75750021
         MVC   LISTMAC(WTO15L),WTO15 MVE LIST WTO INTO WK AREA          75780021
         LA    R1,LISTMAC          GET ADDR OF LIST                     75810021
         SR    R0,R0               CLEAR REGISTER                       75840021
         IC    R0,CONSLID          PUT CONSOLE ID INTO REG 0            75870021
         WTO   MF=(E,(1))          ISSUE WTO                            75900021
         B     LPARETN       RETURN.                                    75930021
         SPACE                                                          75960021
LPA13    CLI   ZERO(R6),BLANK      IS THERE A BLANK                     75990021
         BNE   LPA2                NO BRANCH                            76020021
LPA1     LA    R6,ONE(R6)          UPDATE PTR BY ONE                    76050021
         CR    R6,R4               IS IT END OF BUFFER                  76080021
         BE    LPARETN       YES,RETURN.                                76110021
         B     LPA13               NO CONTINUE SEARCH FOR MOD NAME      76140021
LPA2     LR    R7,R6               SAVE PTR TO BEG OF NAME              76170021
LPALOOP2 LA    R6,ONE(R6)          UPDATE BUFFER BY ONE                 76200021
         CR    R6,R4               IS IT END OF BUFFER                  76230021
         BE    LPARETN       YES,RETURN.                                76260021
         CLI   ZERO(R6),COMMA      IS IT A COMMA DELIMITER              76290021
         BE    LPA3                YES-BRANCH TO DO BLDL ON MODULE      76320021
         CLI   ZERO(R6),RTPAREN    IS IT A RT PAREN DELIMITER           76350021
         BNE   LPALOOP2            NO CONT SEARCH FOR END OF NAME       76380021
         SPACE                                                          76410021
         BAL   R10,LPAMOD          BR AND DO BLDL ON MODULE             76440021
LPARETN  EQU   *                                                        76470021
         LM    R7,R5,SAVE2   RESTORE MAINLINE REGS.                     76500021
         BR    R14           RETURN.                                    76530021
         SPACE                                                          76560021
         SPACE                                                          76590021
LPA3     BAL   R10,LPAMOD          BR AND DO BLDL ON MODULE             76620021
         B     LPA1                BR AND GET NXT MODULE SPECIFIED      76650021
LPAMOD   LR    R9,R6               SAVE END ADR OF MOD NAME             76680021
         SR    R9,R7               GET LENGTH OF MODULE NAME            76710021
         CH    R9,LN8              IS LENGTH GR TH EIGHT                76740021
         BH    LPA5                YES-BRANCH-ERROR                     76770021
         BCTR  R9,ZERO             NO-DECREMENT LENGTH BY ONE           76800021
         L     R2,SRECHAIN   R2=1ST SRE ADDR.                           76830021
SRCLOOP1 EQU   *                                                        76860021
         LTR   R2,R2         Q.ANY MORE SRE'S.                          76890021
         BZ    OKBLDL        NO,DO BLDL AND SRE BUILD.                  76920021
         EX    R9,SRECOMPR   YES,COMPARE NAMES.                         76950021
         BCR   EIGHT,R10     EQUAL,DON'T BLDL OR BUILD SRE.             76980021
         L     R2,SRELINK-SRE(R2)      NOT EQUAL,CHECK NEXT SRE.        77010021
         B     SRCLOOP1      *                                          77040021
SRECOMPR CLC   SRENAME-SRE(ZERO,R2),ZERO(R7)  COMPARE NAMES.            77070021
OKBLDL   EQU   *                                                        77100021
         EX    R9,LPAMV1           MOVE NAME INTO WKAREA                77130021
         SR    R15,R15             ZERO RETURN CODE REG                 77160021
         SR    R1,R1               ZERO DCB REG                         77190021
         LA    R0,LPALIST          GET ADR OF LPA NAME IN WK AREA       77220021
         BLDL  (1),(0)             DO BLDL ON MODULE                    77250021
         LTR   R15,R15             WAS BLDL SUCCESSFUL                  77280021
         BNZ   LPA7                NO BR TO BLNK NME IN BUFFER          77310021
         LA    R5,LPANAME    R5=BLDL ENTRY ADDR.                        77340021
         L     R2,TWTYFOUR(R5)         R2=SIZE FROM BLDL ENTRY.         77370021
         SRL   R2,EIGHT      ADJUSTED IN R2.                            77400021
         L     R9,BLDCON     R9=SREBUILD ENTRY POINT.                   77430021
         BALR  R14,R9        BUILD SRE FOR THIS MODULE.                 77460021
         MVC   LPANAME(EIGHT),BLNKS1   BLANK BLDL ENTRY NAME FIELD.     77490021
         BR    R10           RETURN FOR NEXT NAME.                      77520021
BLDCON   DC    A(SREBUILD)   SRE BUILD ROUTINE ENTRY POINT.             77550021
*****             THIS ENDS THE SECTION OF CODE CHANGED FOR APAR44022*  77580021
LPA5     BCTR  R9,ZERO             DECREMENT LENGTH OF NAME BY ONE      77610021
LPA7     CLI   ZERO(R6),COMMA      IS DELIMITER = COMMA                 77640021
         BE    LPA8                YES- BRANCH                          77670021
         BCTR  R9,ZERO             NO DECREMENT LENGTH BY ONE MORE      77700021
LPA8     MVI   ZERO(R7),BLANK      BLNK NAME IN BUFFER DUE TO           77730021
         EX    R9,LPAMV2           ERROR-                               77760021
         MVC   LISTMAC(WTO21L),WTO21 MVE WTO LIST TO WK AREA            77790021
         MVC   KYWD6(EIGHT),LPANAME MVE NAME IN ERROR INTO LIST         77820021
         LA    R1,LISTMAC          GET ADDR IF LIST                     77850021
         SR    R0,R0               CLEAR REGISTER                       77880021
         IC    R0,CONSLID          PUT CONSOLE ID INTO REG 0            77910021
         WTO   MF=(E,(1))          ISSUE WTO                            77940021
LPA8B    MVC   LISTMAC(WTO15L),WTO15 MVE MESSAGE IGNORE MODULE          77970021
         LA    R1,LISTMAC          GET ADR WTO LIST                     78000021
         SR    R0,R0               CLEAR REGISTER                       78030021
         IC    R0,CONSLID          PUT CONSOLE ID IN REG 0              78060021
         WTO   MF=(E,(1))          ISSUE MESSAGE                        78090021
         MVI   LPANAME,BLANK       PUT BLANK INTO FIRST BYTE OF LIST    78120021
         MVC   LPANM(FIFTYFIV),LPANAME BLANK OUT REST OF LIST           78150021
         BR    R10                 RETURN                               78180021
         SPACE 2                                                        78210021
TSDMPRTN TM    MODSW,ONBIT         IS MODIFY BIT SET                    78240021
         BZ    TSDMP1              NO PROCESS DUMP PARAMETER            78270021
         MVC   LISTMAC(WTO18L),WTO18 MVE LIST INTO WK AREA              78300021
         MVC   KYWD5(EIGHT),KYWD8 MVE DUMP KYWD INTO LIST               78330021
         LA    R1,LISTMAC          GET ADDR OF LIST                     78360021
         SR    R0,R0               CLEAR REGISTER                       78390021
         IC    R0,CONSLID          PUT CONSOLE ID INTO REG 0            78420021
         WTO   MF=(E,(1))          ISSUE WTO SAYING YOU CANNOT          78450021
*                                  OVERRIDE DUMP PARAMETER              78480021
         MVC   LISTMAC(WTO15L),WTO15 MVE LIST WTO INTO WK AREA          78510021
         LA    R1,LISTMAC          GET ADDR OF LIST WTO                 78540021
         SR    R0,R0               CLEAR REGISTER                       78570021
         IC    R0,CONSLID          PUT CONSOLE ID INTO REG 0            78600021
         WTO   MF=(E,(1))          ISSUE WTO                            78630021
         BR    R14                 RETURN                               78660021
TSDMP1   CLC   ZERO(FOUR,R6),DMP   IS DUMP =DUMP                        78690021
         BNE   ZERO(R14)           NO- RETURN                           78720021
         MVI   DMPSW,DUMPYES       YES- SET DUMP SW TO DUMP=YES         78750021
         BR    R14                 RETURN                               78780021
DRVRTN   TM    MODSW,ONBIT         ARE WE EDITTING OVERRIDES            78810021
         BZ    ZERO(R14)           NO - RETURN                          78840021
DRVR6    CLI   ZERO(R6),LFPAREN    IS THERE A LEFT PARENTHESIS          78870021
         BE    DRVR5               YES BR TO FIND RT PAREN              78900021
         CLI   ZERO(R6),RTPAREN    IS IT END OF DRVR OVERRIDES          78930021
         BE    DRVR1               YES BRANCH AND SET SWITCH            78960021
         LA    R6,ONE(R6)          NO UPDATE PTR BY ONE                 78990021
         CR    R6,R4               IS IT END OF OVERRIDES               79020021
         BE    DRVR4               YES ERROR BRANCH TO ISSUE WTO        79050021
         CLI   ZERO(R6),BLANK      IS IT A BLANK DELIMITER              79080021
         BE    DRVR4               YES ERROR BRANCH TO ISSUE WTO        79110021
         B     DRVRTN              NO BR TO CONTINUE SERCH FOR RT PAREN 79140021
DRVR5    LA    R6,ONE(R6)          UPDATE PTR PASS LEFT PAREN           79170021
         CR    R6,R4               IS IT END OF OVERRIDES               79200021
         BE    DRVR4               YES ERROR BR TO ISSUE WTO            79230021
         CLI   ZERO(R6),RTPAREN    IS IT A RIGHT PAREN                  79260021
         BNE   DRVR5               NO KEEP SEARCHING                    79290021
         LA    R6,ONE(R6)          YES UPDATE PTR PASS RT PAREN         79320021
         B     DRVR6               CONTINUE                             79350021
DRVR1    MVI   DRVSW,ONBIT         SET DRVR OVERRIDE BIT ON             79380021
         BR    R14                 RETURN                               79410021
DRVR4    MVC   LISTMAC(WTO20L),WTO20 MVC LIST INTO WK AREA              79440021
         LA    R1,LISTMAC          GET ADDR OF LIST                     79470021
         SR    R0,R0               CLEAR REGISTER                       79500021
         IC    R0,CONSLID          PUT CONSOLE ID INTO REG 0            79530021
         WTO   MF=(E,(1))          ISSUE WTO                            79560021
         MVC   LISTMAC(WTO15L),WTO15 MVC LIST WTO INTO WK AREA          79590021
         LA    R1,LISTMAC          GET ADDR OF LIST                     79620021
         SR    R0,R0               CLEAR REGISTER                       79650021
         IC    R0,CONSLID          PUT CONSOLE ID INTO REG 0            79680021
         WTO   MF=(E,(1))          ISSUE WTO                            79710021
         B     EDITKYW2            RETURN                               79740021
         SPACE 2                                                        79770021
CVBRTN   LR    R1,R6               SAVE BEG ADR OF VALUE                79800021
         CLI   ZERO(R1),BLANK      IS VALUE EQ TO BLANK                 79830021
         BE    ZERO(R5)            YES- ERROR -RETURN                   79860021
         SR    R15,R15             ZERO FOR COUNT OF DIGITS             79890021
CVBLOOP  CLI   ZERO(R1),CZERO      IS DIGIT LESS THAN ZERO              79920021
         BL    ZERO(R5)            YES ERROR - RETURN                   79950021
         CLI   ZERO(R1),CNINE      IS DIGIT GR TH NINE                  79980021
         BH    ZERO(R5)            YES ERROR - RETURN                   80010021
         LA    R15,ONE(R15)        UPDATE DIGIT COUNT BY ONE            80040021
         LA    R1,ONE(R1)          UPDATE DIGIT PTR BY ONE              80070021
         CLI   ZERO(R1),BLANK      IS DELIMITER EQ BLANK                80100021
         BE    CVBNUM              YES-BRANCH TO CONVERT TO BINARY      80130021
         CLI   ZERO(R1),COMMA      IS DELIMITER EQ COMMA                80160021
         BE    CVBNUM              YES- BR TO CONVERT TO BINARY         80190021
         CLI   ZERO(R1),CONSTK     IS IT A K                            80220021
         BE    CVBNUM              YES BR TO CONVERT NUM TO BINARY      80250021
         CLI   ZERO(R1),RTPAREN    IS DELIMITER A RIGHT PAREN           80280021
         BE    CVBNUM              YES BR TO CONVERT NUM TO BINARY      80310021
         CR    R1,R4               IS IT END OF NUM IN CIB              80340021
         BNE   CVBLOOP             BR AND FIND DELIMITER                80370021
CVBNUM   CH    R15,CN5             YES-IS DIGIT COUNT GR TH FIVE        80400021
         BH    ZERO(R5)            YES- ERROR -RETURN                   80430021
         BCTR  R15,ZERO            DECREMENT DIGIT CT BY ONE            80460021
         O     R15,PACK2           OR IN FIELD FOR PACKING              80490021
         EX    R15,CVBPACK         PACK                                 80520021
         CVB   R15,CVBDWD          CONVERT VALUE TO BINARY              80550021
         XC    CVBDWD(EIGHT),CVBDWD ZERO DOUBLE WORD                    80580021
         LTR   R15,R15             IS VALUE ZERO OR NEGATIVE            80610021
         BNP   ZERO(R5)            YES- ERROR -RETURN                   80640021
         B     EIGHT(R5)           NO RETURN AND SAVE VALUE             80670021
         SPACE                                                          80700021
WTORRTN2 LA    R1,LISTMAC          GET ADDR LIST FORM WTOR              80730021
         LA    R6,REPLYAD          GET ADDR OF ANSWER FIELD             80760021
         XC    ZERO(N76,R6),ZERO(R6)  CLEAR ANS FIELD AND        A44413 80790021
*                                  ECB FIELD                            80820021
         SR    R0,R0               CLEAR REGISTER                       80850021
         IC    R0,CONSLID          PUT CONSOLE ID INTO REG 0            80880021
         WTOR  ,REPLYAD,(10),ECBAD,MF=(E,(1))                           80910021
         WAIT  1,ECB=ECBAD         WAIT FOR REPLY                       80940021
         OC    ZERO(SVNTYTW,R6),BLNKS1  DO FOLDING ON REPLY      A44413 80970021
         CLC   ZERO(SIX,R6),CANCL  DOES REPLY EQ CANCEL                 81000021
         BE    EDITEND1            YES BR TO REJECT START TS            81030021
         CLC   ZERO(TWO,R6),REPLU  IS REPLY U FOR DEFAULT               81060021
         BE    EDITKYW3            YES RETURN                           81090021
         CLC   ZERO(EIGHT,R6),DRVKYWD IS IT A DRIVER= PARAMETER         81120021
         BE    EDITDRV             YES BR TO EDIT                       81150021
         LA    RTNREG,RTNADTAB     GET ADR OF TABLE OF RTN ADDRESSES    81180021
         LA    LKYWDREG,KYWDTAB    GET ADR OF LENGTH OF FIRST KEY WD    81210021
         LA    KYWDREG,KYWD        GET ADR OF FIRST KEY WORD            81240021
COMPAGN1 LH    R1,ZERO(LKYWDREG)   GET LENGTH OF KEY WORD IN TABLE      81270021
         EX    R1,COMPKYWD         DOES CIB KYWD=KEY WORD IN TABLE      81300021
         BE    EDITKYW1            YES BRANCH TO PROCESS KYWD           81330021
         LA    RTNREG,FOUR(RTNREG) NO-UPDTE PTR TO RTNS                 81360021
         LA    LKYWDREG,TEN(LKYWDREG) UPDTE PTR TO LENGTH NXT KEY WD    81390021
         LA    KYWDREG,TEN(KYWDREG) UPDATE PTR TO NXT KEY WORD          81420021
         CR    RTNREG,KWDENREG     IS IT END OF KYWD TABLE              81450021
         BNE   COMPAGN1            NO-DO NXT COMPARE                    81480021
EDITERR7 MVC   LISTMAC(WTO17L),WTO17 MVE LIST INTO WK AREA              81510021
         LA    R1,LISTMAC          GET ADDR OF LIST OF WTO              81540021
         XC    THTYEIGT(TWTYSIX,R1),THTYEIGT(R1)                        81570021
         MVC   KYWD1(TWTYSIX),REPLYAD MVE KYWD IN ERROR INTO LST        81600021
         SR    R0,R0               CLEAR REGISTER                       81630021
         IC    R0,CONSLID          PUT CONSOLE ID INTO REG 0            81660021
         WTO   MF=(E,(1))          ISSUE WTO                            81690021
EDITKYW4 MVC   LISTMAC(WTOR6L),WTOR6 MVE LIST WTOR INTO WK AREA         81720021
         LA    R10,TWTYSIX         GET LENGTH OF REPLY FIELD            81750021
         B     WTORRTN2                                                 81780021
EDITKYW3 TM    EDITSW,ONBIT        IS EDIT SW ON-CAN DEFAULT            81810021
         BO    ZERO(R9)            YES - RETURN TO USE DEFAULT VALUE    81840021
         B     EDITKYW4            NO  REISSUE WTOR                     81870021
EDITKYW1 L     RTNREG,ZERO(RTNREG) GET ADR OF RTN TO HANDLE KYWD        81900021
         LA    R1,ONE(R1)          UPDATE LENGTH KEY WD BY ONE          81930021
         AR    R6,R1               UPDATE PTR TO BUF PASS KEY WD        81960021
         BALR  R14,R7              NO BRANCH TO PROCESS KY WD           81990021
         B     CIB1                RETURN                               82020021
EDITERR  TM    MODSW,ONBIT         ARE WE EDITING OVERRIDES             82050021
         BZ    ZERO(R14)                                                82080021
EDITERR1 LA    R6,ONE(R6)          UPDATE PTR BY ONE                    82110021
         CR    R6,R4               IS IT END OF BUFFER                  82140021
         BE    EDITERR2            YES- BRANCH                          82170021
         CLI   ZERO(R6),LFPAREN IS IT ALEFT PAREN                       82200021
         BE    EDITERR3            YES BR TO SEARCH F                   82230021
         CLI   ZERO(R6),COMMA      IS IT A COMMA DELIMITER              82260021
         BE    EDITERR2            NO CONTINUE SEARCH                   82290021
         CLI   ZERO(R6),BLANK      IS IT A BLANK                        82320021
         BNE   EDITERR1            NO-CONTINUE SEARCH FOR DELIMITER     82350021
         LR    R7,R6               GET END ADDR OF KYWD IN ERROR        82380021
         LA    R10,REPLYAD         GET BEG ADDR OF KYWD IN ERROR        82410021
         B     EDITERR4            BRANCH                               82440021
EDITERR3 TM    MODSW,ONBIT         ARE WE EDITTING OVERRIDES            82470021
         BZ    ZERO(R14)           NO RETURN                            82500021
         CR    R6,R4                                                    82530021
         BE    EDITERR2                                                 82560021
         CLI   ZERO(R6),RTPAREN                                         82590021
         BE    EDITERR1                                                 82620021
         LA    R6,ONE(R6)          YES-UPDATE PTR BY ONE                82650021
         B     EDITERR3                                                 82680021
EDITERR2 ST    R6,CIBPTR           SAVE OVERRIDE PTR                    82710021
         LR    R7,R6               GET END ADDR OF KYWD IN ERROR        82740021
         L     R10,CIBPTR1                                              82770021
EDITERR4 SR    R7,R10              GET  LENGTH OF KYWD                  82800021
         BCTR  R7,ZERO             DECREMENT LENGTH BY ONE              82830021
         MVC   LISTMAC(WTO19L),WTO19                                    82860021
         LA    R1,LISTMAC          GET ADDR OF LIST                     82890021
         XC    FIFTYONE(TWTYSIX,R1),FIFTYONE(R1)                        82920021
         EX    R7,KYWDMVE1         MVE KYWD INTO LIST                   82950021
         SR    R0,R0               CLEAR REGISTER                       82980021
         IC    R0,CONSLID          PUT CONSOLE ID INTO REG 0            83010021
         WTO   MF=(E,(1))          ISSUE WTO -INVALID VALUE OF KYWD     83040021
         BR    R9                  RETURN                               83070021
EDITERR5 MVC   LISTMAC(WTOR6L),WTOR6                                    83100021
         LA    R1,LISTMAC          GET ADDR OF LIST OF WTOR             83130021
         LA    R10,TWTYSIX         GET LENGTH OF REPLY                  83160021
         B     WTORRTN2            ISSUE WTOR                           83190021
EDITERR6 MVC   LISTMAC(WTOR4L),WTOR4                                    83220021
         LA    R1,LISTMAC          GET ADDR OF LIST OF WTOR             83250021
         LA    R10,TWTYSIX         GET LENGTH OF REPLY                  83280021
         MVI   EDITSW,ONBIT        SET SW ON FOR DEFAULTS ALLOWED       83310021
         BAL   R9,WTORRTN2                                              83340021
         MVI   EDITSW,OFFBIT       RESTORE EDIT BIT OFF                 83370021
         B     CIB1                RETURN                               83400021
         SPACE                                                          83430021
EDITDRV  LA    R15,SVNTYONE(R6)    END ADR OF ACCEPTED DRV DATA  A44413 83440021
         LR    R1,R6               GET PTR TO DRIVER DATA        A44413 83442021
         LA    R1,EIGHT(R1)        UPDATE PTR TO DRV DATA        A44413 83450021
EDITDRV1 CLI   ZERO(R1),RTPAREN    IS THERE A RT PAREN           A44413 83452021
         BE    EDITDRV2            YES MOVE DRVR DATA            A44413 83454021
         LA    R1,ONE(R1)          NO UPDATE PTR                 A44413 83456021
         CR    R1,R15              ARE WE PASS END ADR           A44413 83458021
         BH    EDITDRV3            YES ERROR BRANCH              A44413 83458121
         B     EDITDRV1            NO CONTINUE SEARCH            A44413 83458821
EDITDRV2 LA    R15,NINE(R6)        GET PTR BEG OF DRV DATA       A44413 83459221
         SR    R1,R15              LENGTH OF DATA                A44413 83459621
         L     R15,DRVCRDAD        GET ADR DRIVER CARDS          A44413 83850021
         EX    R1,DRVKYMVE         MOVE BACKGRND DATA TO DRVER CARD     83880021
         LA    R15,EIGHTY(R15)     UPDATE ADR DRVER CARD         A44413 83910021
         ST    R15,DRVCRDAD        SAVE NEW ADDRESS              A44413 83940021
         B     CIB1                BR TO CONTINUE                A44413 83970021
         SPACE                                                          83980021
EDITDRV3 MVC   LISTMAC(WTO20L),WTO20 MVC LIST INTO WK AREA       A44413 83990021
         LA    R1,LISTMAC          GET ADDR OF LIST              A44413 83992021
         SR    R0,R0               CLEAR REGISTER                A44413 83994021
         IC    R0,CONSLID          PUT CONSOLE ID INTO REG 0     A44413 83996021
         WTO   MF=(E,(1))          ISSUE WTO                     A44413 83998021
         MVC   LISTMAC(WTO15L),WTO15 MVC LIST WTO INTO WK AREA   A44413 83998421
         LA    R1,LISTMAC          GET ADDR OF LIST              A44413 83998821
         SR    R0,R0               CLEAR REGISTER                A44413 83999221
         IC    R0,CONSLID          PUT CONSOLE ID INTO REG 0     A44413 83999621
         WTO   MF=(E,(1))          ISSUE WTO                     A44413 83999721
         B     CIB1                CONTINUE EDIT                 A44413 83999821
         EJECT                                                          84000021
**********               CONSTANTS FOR EDIT ROUTINE          ********** 84030021
         SPACE 2                                                        84060021
BLNKS1   DC    CL26' '                                                  84090021
REPLU    DC    C'U '                                                    84120021
CANCL    DC    C'CANCEL'                                                84150021
DMP      DC    C'DUMP'                                                  84180021
OFF      DC    C'OFF'                                                   84210021
OPT1     DC    C'OPT=1'                                                 84240021
OPT2     DC    C'OPT=2'                                                 84270021
EXTNO    DC    C'EXT=NO)'                                               84300021
EXTYES   DC    C'EXT=YES)'                                              84330021
TS       DC    C'TS '                                                   84360021
RN0      DC    F'0'                                                     84480021
CN5      DC    H'5'                                                     84570021
LN8      DC    H'8'                                                     84600021
RN14     DC    H'14'                                                    84660021
RNSZE    DC    H'16382'                                                 84690021
PACK2    DC    F'112'                                                   84720021
USERNUM  DC    F'32767'            MAX NUMBER OF USERS ALLOWED          84750021
         SPACE 3                                                        84780021
KYWDTAB  DC    H'6'                                                     84810021
KYWD     DC    C'TERMAX= '                                              84840021
         DC    H'5'                                                     84870021
         DC    C'USERS=  '                                              84900021
         DC    H'7'                                                     84930021
         DC    C'REGNMAX='                                              84960021
         DC    H'4'                                                     84990021
         DC    C'SMF=(   '                                              85020021
         DC    H'5'                                                     85050021
         DC    C'DSPCH=  '                                              85080021
         DC    H'6'                                                     85110021
         DC    C'SUBMIT= '                                              85140021
         DC    H'7'                                                     85170021
         DC    C'REGSIZE('                                              85200021
         DC    H'3'                                                     85230021
         DC    C'MAP=    '                                              85260021
         DC    H'4'                                                     85290021
KYWD7    DC    C'LPA=(   '                                              85320021
         DC    H'4'                                                     85350021
KYWD8    DC    C'DUMP=   '                                              85380021
         DC    H'7'                                                     85410021
DRVKYWD  DC    C'DRIVER=('                                              85440021
         DC    H'8'                                                     85470021
         DC    C'TSCREGSZ='                                             85500021
*  NOTE: SINCE KEYWORD TSCREGSZ IS 8 BYTES IT MUST ALWAYS BE THE        85530021
*  LAST KEYWORD IN THIS LIST SINCE LOOP LOGIC INCREMENTS BY 10 BYTES    85560021
* BETWEEN EACH KEYWORD COMPARE. =LENGTH OF HALFWORD PLUS                85590021
*  9 BYTE CHAR STRING=11                                                85620021
         EJECT                                                          85650021
RTNADTAB DC    A(TERMXRTN)                                              85680021
         DC    A(USERSRTN)                                              85710021
         DC    A(RGNMXRTN)                                              85740021
         DC    A(SMFRTN)                                                85770021
         DC    A(DSPCHRTN)                                              85800021
         DC    A(SUBMTRTN)                                              85830021
         DC    A(REGSZRTN)                                              85860021
         DC    A(MAPRTN)                                                85890021
         DC    A(LPARTN)                                                85920021
         DC    A(TSDMPRTN)                                              85950021
         DC    A(DRVRTN)                                                85980021
         DC    A(TSCRGRTN)                                              86010021
KYWDEND  EQU   *                                                        86040021
         SPACE 4                                                        86070021
COMPKYWD CLC   ZERO(ZERO,PARMBUF),ZERO(KYWDREG)                         86100021
LPAMV1   MVC   LPANAME(ZERO),ZERO(R7)                                   86160021
LPAMV2   MVC   ONE(ZERO,R7),ZERO(R7)                                    86190021
CVBPACK  PACK  CVBDWD(ZERO),ZERO(ZERO,R6)                               86220021
KYWDMVE  MVC   KYWD1(ZERO),ZERO(R10)                                    86250021
KYWDMVE1 MVC   KYWD4(ZERO),ZERO(R10)                                    86280021
DRVKYMVE MVC   EIGHT(ZERO,R15),EIGHT(R6)                         A44413 86310021
         EJECT                                                          86340021
WTO15    WTO   'IKJ067I THE ABOVE KEYWORD AND ITS VALUE WILL BE IGNOREDX86370021
               ',DESC=5,MCSFLAG=(REG0),MF=L                             86400021
WTO15L   EQU   *-WTO15                                                  86430021
         SPACE 4                                                        86460021
WTO16    WTO   'IKJ018I SMF OPI BIT IS SET - SMF PARAMETER IGNORED',DESX86490021
               C=5,MCSFLAG=(REG0),MF=L                                  86520021
WTO16L   EQU   *-WTO16                                                  86550021
         SPACE 4                                                        86580021
WTO17    WTO   'IKJ061I THIS KEYWORD IS INVALID - CCCCCCCCCCCCCCCCCCCCCX86610021
               CCCCC',DESC=5,MCSFLAG=(REG0),MF=L                        86640021
WTO17L   EQU   *-WTO17                                                  86670021
         EJECT                                                          86700021
WTO18    WTO   'IKJ013I CCCCCCCC PARAMETER IS NOT ALLOWED ON THE START X86730021
               COMMAND',DESC=5,MCSFLAG=(REG0),MF=L                      86760021
WTO18L   EQU   *-WTO18                                                  86790021
         SPACE 4                                                        86820021
WTO19    WTO   'IKJ064I THE VALUE OF THIS KEYWORD IS INVALID - CCCCCCCCX86850021
               CCCCCCCCCCCCCCCCCC',DESC=5,MCSFLAG=(REG0),MF=L           86880021
WTO19L   EQU   *-WTO19                                                  86910021
         SPACE 4                                                        86940021
WTO20    WTO   'IKJ012I DRIVER=( PARAMETER DOES NOT HAVE A RIGHT PARENTX86970021
               HESIS',DESC=5,MCSFLAG=(REG0),MF=L                        87000021
WTO20L   EQU   *-WTO20                                                  87030021
         EJECT                                                          87060021
WTO21    WTO   'IKJ008I BLDL FAILED FOR MODULE, CCCCCCCC, FOR TSO LINK X87090021
               PACK AREA',DESC=5,MCSFLAG=(REG0),MF=L                    87120021
WTO21L   EQU   *-WTO21                                                  87150021
         SPACE 4                                                        87180021
WTO22    WTO   'IKJ068I SMF DSA BIT IS SET - OPT=2 MUST BE USED',DESC=5X87210021
               ,MCSFLAG=(REG0),MF=L                                     87240021
WTO22L   EQU   *-WTO22             LENGTH OF MESSAGE                    87270021
         SPACE 4                                                        87300021
         EJECT                                                          87420021
WTOR4    WTOR  'IKJ066D REPLY ''KEYWORD=VALUE'', ''U'',OR ''CANCEL''',DX87450021
               ESC=2,MCSFLAG=(REG0),MF=L                                87480021
WTOR4L   EQU   *-WTOR4             LENGTH OF MESSAGE                    87510021
         SPACE 4                                                        87540021
WTOR6    WTOR  'IKJ066D REPLY ''KEYWORD=VALUE'' OR ''CANCEL''',DESC=2,MX87570021
               CSFLAG=(REG0),MF=L                                       87600021
WTOR6L   EQU   *-WTOR6             LENGTH OF MESSAGE                    87630021
         SPACE                                                          87660021
         END                                                            87690021
