         TITLE 'IKJEAT01 -FREEPART/GETPART'                             00900020
**********************************************************************  01800020
* STATUS/CHANGE - LEVEL=0     NEW MODULE FOR TSO (R20)                  02700020
*                                                                       03600020
* ROUTINE NAME - TSC'S FREEPART/GETPART ROUTINE                         04500020
*                                                                       05400020
* FUNCTION - IKJEAT01 OBTAINS A TS REGION OF THE SIZE COMPUTED BY       06300020
*            IKJEAT00. IT ISSUES A FREEPART FOR THE PRESENT REGION      07200020
*            IT ISSUES A GETPART FOR A NEW REGION OF PROPER SIZE        08100020
*            FOR THE TS CONTROL REGION. IF THE SIZE REQUESTED IS AN     09000020
*            INVALID SIZE THEN GETPART RETURNS A NON ZERO CODE IN       09050020
*            REG15. IN THIS CASE T01 MUST DO A GETPART FOR MINPART      09100020
*            AND RETURN TO THE SYSTEM. THE PURPOSE OF MINPART IS TO     09150020
*            ALLOW THE INITIATOR TO TERMINATE. T01 ALSO ISSUES A MSG    09200020
*            WHICH SAYS START TS IS REJECTED DUE TO AN INVALID          09250020
*            REQUEST. THE VALUE FOR MINPART IS FOUND IN THE DATA        09300020
*            RESIDENT AREA OF MASTER SCHEDULER(IEEBASEA).               09350020
*                                                                       09360020
*            IF THE SIZE REQUESTED IS VALID BUT NOT AVAILABLE           09400020
*            GETMAIN WILL PUT TSC INTO A WAIT STATE.                    09450020
*            LOAD'S TSC MAINLINE - IKJEAT03                             09900020
*            XCTL'S TO TSC INITIALIZATION - IKJEAT02                    10800020
*                                                                       11700020
* ENTRY POINT - IKJEAT01                                                12600020
*               IKJEAT09 (TSC STAE EXIT RTN FOR PRE INIT)               12650020
*                                                                       13500020
* ATTRIBUTES - REENTRANT,REFRESHABLE,READ ONLY                          14400020
*           IKJEAT01 IS RESIDENT IN OS LINK PACK AREA.                  15300020
*                                                                       16200020
* APPLICABILITY - MVT SYSTEMS WITH TSO                                  17100020
*                                                                       18000020
* EXTERNAL REFERENCES - NONE                                            18900020
*                                                                       19800020
* SVC'S - FREEMAIN - SUBPOOL 0, SP247(FREEPART)                         20700020
*         GETMAIN  - SUBPOOL 247  GETPART                               21600020
*         LOAD/XCTL                                                     22500020
*                                                                       23400020
* INPUT - REGISTER 1: TSC PARAMETER LIST                                24300020
*          (PARAMETER LIST +20 CONTAINS SIZE IN BYTES OF NEW TS REGION) 25200020
*         REGISTER 13: ADDRESS OF A SAVE AREA                           26100020
*         REGISTER 14: RETURN ADDRESS                                   27000020
*         REGISTER 15: ENTRY POINT ADDRESS                              27900020
*                                                                       28800020
* OUTPUT - NONE                                                         29700020
*                                                                       30600020
* EXIT - NORMAL - XCTL TO IKJEAT02                                      31500020
*        ERROR - NONE                                                   32400020
*                                                                       33300020
* CONTROL BLOCKS -                                                      33350020
*        CVT                                                            33400020
*        IEEBASEA                                                       33450020
*                                                                       33500020
* TABLES/WORK AREAS -                                                   34200020
*         TSC PARAMETER LIST                                            35100020
*              +0 NUMBER MAX USERS (TERMAX PARAMETER)                   36000020
*              +4 LENGTH PARM DATA                                      36900020
*              +8 ADDRESS PARM DATA                                     37800020
*              +12 SWITCH FOR FORM OPTION                               38700020
*              +14 MAXIMUM NUMBER OF REGIONS (REGNMAX PARAMETER)        39600020
*              +16 USED TO RETURN AMOUNT OF MAIN STORAGE                40500020
*                  NEEDED BY SWAP,TIOC,AND DRIVER.                      41400020
*              +20 SIZE OF NEW REGION IF NEEDED                         42300020
*              +24 ADDRESS OF COMMUNICATIONS PARAMETER LIST (CPL)       43200020
*              +28 ADDRESS OF TSC TABLE                                 44100020
*                                                                       45000020
**********************************************************************  45900020
          EJECT                                                         46800020
CVTSECT  DSECT                                                          46850020
         CVT                                                            46900020
         EJECT                                                          46910020
         IEEBASEA                                                       46920020
         EJECT                                                          46950020
IKJEAT01 CSECT                                                          47700020
**********************************************************************  48600020
*                                                                     * 49500020
*                                  EQUATES                            * 50400020
*                                                                     * 51300020
*********************************************************************** 52200020
         SPACE 4                                                        53100020
R0       EQU   0                   REGISTER EQUATE                      54000020
R1       EQU   1                   REGISTER EQUATE                      54900020
R2       EQU   2                   REGISTER EQUATE                      54910020
R3       EQU   3                   REGISTER EQUATE                      54950020
R12      EQU   12                  REGISTER EQUATE                      55800020
R13      EQU   13                  REGISTER EQUATE                      56700020
R14      EQU   14                  REGISTER EQUATE                      57600020
R15      EQU   15                  REGISTER EQUATE                      57650020
FOUR     EQU   4                   DISPLACEMENT EQUATE                  57700020
PARMLST  EQU   4                   REGISTER EQUATE FOR PARM LIST ADDR   58500020
BASEREG  EQU   12                  BASE REGISTER EQUATE                 59400020
TWELVE   EQU   12                  DISPLACEMENT EQUATE                  60300020
THIRTEEN EQU   13                  DISPLACEMENT EQUATE                  60350020
TWTY     EQU   20                  DISPLACEMENT EQUATE                  61200020
         EJECT                                                          62100020
         STM   R14,R12,TWELVE(R13) SAVE SYSTEM REGISTERS                63000020
         BALR  BASEREG,R0          SET UP ADDRESSABILITY                63900020
         USING *,BASEREG           SET UP BASE REGISTER                 64800020
         LR    PARMLST,R1          SAVE ADDR PARMLIST                   65700020
         SPACE 3                                                        66600020
**********                  FREE SUBPOOL 0                   *********  67500020
         SPACE 3                                                        68400020
         FREEMAIN R,SP=0           FREE SUBPOOL 0                       69300020
         SPACE 3                                                        70200020
**********      FREE OLD REGION - GET NEW REGION             *********  71100020
         SPACE 3                                                        71110020
T01GETPT EQU   *                                                        71150020
         SR    R1,R1               ZERO REG1 FOR FREEPART               72050020
         SR    R0,R0               INDICATE ZERO LENGTH FOR FREEPART    72100020
*                                  OF A REGION                          72200020
         O     R0,SP247            SP247 MEANS FREEPART REGION          72250020
         FREEMAIN R,LV=(0),A=(1)   FREE REGION                          72300020
         SPACE 3                                                        72350020
         L     R0,TWTY(PARMLST)    GET LENGTH OF NEW REGION             72400020
         O     R0,SP247            INDICATE GETPART OF A REGION         72450020
         GETMAIN R,LV=(0)          GET NEW REGION                       72500020
         SPACE                                                          72510020
         LTR   R15,R15             IF IT IS AN INVALID REQUEST THEN     72550020
*                                  GETPART RETURNS A NON ZERO RETURN    72600020
*                                  CODE IN REGISTER 15                  72650020
         BZ    T01END                   RC=0=SUCCESSFUL GETPART  A44022 72680021
         SPACE                                                          72710020
         SR    R0,R0               CLEAR REGISTER                       72750020
         IC    R0,THIRTEEN(PARMLST) PUT CONSOLE ID INTO REGISTER        72800020
         WTO   'IKJ021I START REJECTED - INVALID CORE REQUEST FOR TSC RX72850020
               EGION',DESC=5,MCSFLAG=(REG0)                             72900020
         SPACE 3                                                        72902020
         L     R3,CVTPTR           GET ADDRESS CVT                      72910020
         USING CVTSECT,R3          ADDRESSABILITY FOR CVT               72920020
         XC    CVTTSCVT(FOUR),CVTTSCVT CLEAR TSCVT PTR IN CVT           72930020
*                                  TO ALLOW FOR SUBSEQUENT START TS     72940020
         L     R2,CVTMSER          GET ADR MAST SCH DATA RESID AREA     72940420
         USING BASE,R2             SET UP ADDRESSABILITY                72940820
         LH    R0,BAMINPAR         GET MINPART REGION SIZE - IF WE ARE  72941220
*                                  UNABLE TO GETPART A TSC REGION       72941720
*                                  BECAUSE OF AN INVALID REQUEST WE     72941820
*                                  MUST ISSUE A GETPART FOR MINPART TO  72941920
*                                  ALLOW THE INITIATOR TO TERMINATE     72956420
         SLL   R0,10              CONVERT FROM 1K UNITS TO BYTES A44022 72961421
         DROP  R2                  DROP BASE                            72966420
         O     R0,SP247            INDICATE SP247 TO GETPART            72968420
         GETMAIN R,LV=(0)          ISSUE GETPART                        72970420
         DROP  R3                  DROP CVT                             72971020
         LM    R14,R12,TWELVE(R13) RESTORE REGISTERS                    72985520
         BR    R14                 RETURN                               73000020
         EJECT                                                          76500020
         SPACE 3                                                        80100020
**********                 XCTL TO LOAD THREE - IKJEAT02     *********  81000020
         SPACE 3                                                        81900020
T01END   EQU   *                                                        81950020
         LR    R1,PARMLST          PUT ADR PARM LIST IN REG1            82800020
         XCTL  (2,12),EP=IKJEAT02  GIVE CONTROL TO TSC LOAD THREE       83700020
         EJECT                                                          83750020
**********************************************************************  83760020
*                                                                       83770020
*  IKJEAT09 IS THE STAE EXIT ROUTINE FOR TSC PRE INITIALIZATION         83780020
*  IT WILL GET CONTROL  WHENEVER TSC ABENDS BEFORE THE STAE             83790020
*  IS ISSUED FOR TSC IN IKJEAT02. IT'S SOLE FUNCTION IS TO ZERO         83792020
*  THE TSCVT ADDRESS IN THE CVT TO ALLOW FOR ANOTHER START TS.          83794020
*  IKJEAT09 IS LOADED BY IKJEAT00.                                      83796020
*                                                                       83798020
**********************************************************************  83798420
         ENTRY IKJEAT09                                                 83800020
IKJEAT09 SR    R15,R15             ZERO REG15 TO INDICATE TO            83810020
*                                  ABEND NO RETRY                       83820020
         L     R3,CVTPTR           GET ADDRESS CVT                      83850020
         USING CVTSECT,R3          ADDRESSABILITY ON CVT                83900020
         ST    R15,CVTTSCVT        ZERO ADR TSCVT IN CVT TO             83950020
*                                  ALLOW FOR ANOTHER START TS           84000020
         DROP  R3                  DROP CVT                             84050020
         BR    R14                 RETURN                               84100020
         SPACE 2                                                        84600020
*                                                                     * 85500020
*                                  CONSTANT                           * 86400020
*                                                                     * 87300020
         SPACE 1                                                        88200020
         DS    0F                  ALIGN ON A FULL WORD BOUNDARY        89100020
SP247    DC    X'F7000000'         SP 247 IN HI ORDER BYTE              90000020
         END                                                            90900020
