IKJEAT02 START                                                          00020020
**********************************************************************  00030020
*                                                                       00040020
* STATUS/CHANGE LEVEL=0                                           20021 00050020
*                                                                       00060020
*D091120,091130                                               CC A69893 00060821
*                                                                       00061621
*                                                                       00062421
*                                                                       00063221
*                                                                       00064021
*                                                              @SA69893 00064821
*                                                              @SA69893 00065621
*                                                              @SA69893 00066421
*********************************************************************** 00067221
*                                                              @SA69893 00068021
*                                                              @SA69893 00068821
* ROUTINE NAME - TSC'S INITIALIZATION ROUTINE                           00070020
*                                                                       00080020
* FUNCTION - IKJEAT02 PERFORMS MOST OF THE INITIALIZATION OF THE        00090020
*          SUBSYSTEM AS FOLLOWS:                                        00100020
*             A. OBTAINS MAIN STORAGE AND CREATES THE SUBSYSTEM         00110020
*                CONTROL BLOCKS                                         00120020
*             B. INVOKES ROUTINES FOR INITIALIZATION OF THE TS          00130020
*                DRIVER,SWAP DATA SETS,, TIOC AND TSO DUMP.             00140020
*             C. LOADS MODULES FOR SUBSYSTEM TASKS,NUCLEUS EXTENSION,   00150020
*                AND LINK PACK AREA EXTENSION                           00160020
*             D. ATTACHES REGION CONTROL TASKS (RCT'S)                  00170020
*                                                                       00180020
* ENTRY POINTS - IKJEAT02                                               00190020
*                                                                       00200020
* ATTRIBUTES - SERIALLY REUSEABLE, PROTECT KEY ZERO                     00210020
*                                                                       00230020
* APPLICABILITY - MVT SYSTEMS WITH TSO.                                 00240020
*                                                                       00250020
* EXTERNAL REFERENCES -                                                 00260020
*          A. PASSING CONTROL TO IKJEAS01                               00270020
*             1. REASON - INITIALIZE SWAP DATA SETS                     00280020
*             2. METHOD OF PASSING CONTROL - LINK                       00290020
*             3. INPUT TO CALLED ROUTINE                                00300020
*                REGISTER 1: ADDRESS OF PARAMETER LIST                  00310020
*                REGISTER 13: ADDRESS OF A SAVE AREA                    00320020
*                REGISTER 14: RETURN ADDRESS IN TSC                     00330020
*                REGISTER 15: ENTRY POINT ADDRESS                       00340020
*             4. RETURN INFORMATION -                                   00350020
*                RETURN CODE IN REGISTER 15:                            00360020
*                   0 - INITIALIZATION PERFORMED                        00370020
*                   4 - NOT DEFINED                                     00380020
*                   8 - CANNOT INITIALIZE                               00390020
*                                                                       00400020
*          B. PASSING CONTROL TO IKJEAD01                               00410020
*             1. REASON - INITIALIZE THE DRIVER                         00420020
*             2 2. METHOD OF PASSING CONTROL - LINK                     00430020
*             3. INPUT TO CALLED ROUTINE - (SAME AS IKJEAS01)           00440020
*                                                                       00450020
*               +20 IN PARM LIST WILL HAVE AN ADDRESS OF                00460020
*                   THE START COMMAND OVERRIDES IN THE PARM             00470020
*                   AREA. THE DRIVER WILL EDIT HIS OVERRIDES.           00480020
*                                                                       00490020
*                  THE HI ORDER BIT IN +20 IN PARM LIST WILL BE ON      00492020
*                  IF SMF IS ACTIVE IN THE SYSTEM                       00494020
*                                                                       00496020
*             4.RETURN INFORMATION - RETURN CODES SAME AS IKJEAS01      00500020
*               PARAMETER LIST -+16 ADDRESS OF DRIVER CONTROL           00510020
*               BLOCKS TO BE PLACED AT DPADCA IN DPA.                   00520020
*                                                                       00530020
*          C. PASSING CONTROL TO IKJGGE01                               00540020
*             1. REASON - INITIALIZE TIOC                               00550020
*             2. METHOD OF PASSING CONTROL - LINK                       00560020
*             3. INPUT TO CALLED ROUTINE - (SAME AS IKJEAS01)           00570020
*             4. RETURN INFORMATION - SAME AS IKJEAS01                  00580020
*                                                                       00590020
*                                                                       00591020
*          D. PASSING CONTROL TO IKJEAP00                               00600020
*             1. REASON - INITIALIZE TSO DUMP ROUTINE                   00610020
*             2. METHOD OF PASSING CONTROL - LINK                       00620020
*             3. INPUT TO CALLED ROUTINE - (SAME AS IKJEAS01)           00630020
*                                                                       00640020
*                +28 IN PARM LIST HAS A SWITCH FOR TSO DUMP             00650020
*                    DUMP=X'FF' , NO DUMP=X'00'                         00660020
*                                                                       00670020
*             4. RETURN INFORMATION - (SAME AS IKJEAS01)                00680020
*                                                                       00690020
*                                                                       00691020
*          D. PASSING CONTROL TO IKJEAR00                               00700020
*             1. REASON - CREATE REGION CONTROL TASK (RCT)              00710020
*             2. METHOD OF PASSING CONTROL - ATTACH                     00720020
*             3. INPUT TO CALLED ROUTINE                                00730020
*                 REGISTER 1: ADDRESS OF RCB                            00740020
*                 REGISTER 13:  ADDRESS OF A SAVE AREA                  00750020
*                 REGISTER 14: RETURN ADDRESS                           00760020
*                 REGISTER 15: ENTRY POINT ADDRESS                      00770020
*             4. RETURN INFORMATION - NONE                              00780020
*                                                                       00790020
* SVC'S - ATTACH              SMFWTM                                    00800020
*         FREEMAIN            STAE                                      00801020
*         GETMAIN             WAIT                                      00810020
*         LINK                WTO                                       00820020
*         LOAD                XCTL                                      00821020
*                                                                       00830020
* INPUT - REGISTER 1: TSC PARAMETER LIST ADDRESS                        00840020
*           REGISTER 13: ADDRESS OF A SAVE AREA                         00850020
*           REGISTER 14: RETURN ADDRESS                                 00860020
*           REGISTER 15: ENTRY POINT ADDRESS                            00870020
*                                                                       00880020
* OUTPUT - NONE                                                         00890020
*                                                                       00900020
* EXITS - NORMAL - XCTL TO IKJEAT03                                     00910020
*         ERROR - RETURN TO SYSTEM CONTROL TASK IF UNABLE TO            00920020
*                 INITIALIZE THE SYSTEM.                                00930020
*                                                                       00940020
* REGISTERS USED BY IKJEAT02:                                           00940420
*        REGISTER 4 - ADDRESS OF TSCVT                                  00940820
*              ONCE TSCVT IS OBTAINED ITS ADDRESS REMAINS               00940920
*              IN REG 4 THROUGHOUT IKJEAT02.                            00941020
*        REGISTER 2 - ADDRESS PARAMETER LIST                            00943020
*              ADDRESS OF PARAMETER LIST PASSED IN REG1 IS PUT          00945020
*              IN REG 2 AND REMAINS THERE UNTIL IT IS FREED.            00947020
*        REGISTER 13 - ADDRESS OF MY SAVE AREA AND WORK AREA            00949020
*                                                                       00949420
* TABLES/CONTROL BLOCKS/WORK AREAS -                                    00950020
*                                                                       00960020
*          A. TSC PARAMETER LIST                                        00970020
*              +0  MAXIMUM NUMBER OF USERS  (TERMAX= PARAMETER)         00980020
*              +4  LENGTH PARM DATA                                     00990020
*              +8  ADDRESS OF PARM DATA                                 01000020
*              +12 SWITCH FOR FORM OPTION                               01010020
*                  X'FF' FORMAT ALL SWAP DATA SETS                      01020020
*                  X'0F' FORMAT DATA SETS PER OP REQUIREMENTS           01030020
*                  X'00' DO NOT FORMAT SWAP DATA SETS                   01040020
*              +13 CONSOLE ID FOR START COMMAND                         01050020
*              +14 MAXIMUM NUMBER OF REGIONS (REGNMAX= PARAMETER)       01060020
*              +16 USED TO RETURN AMT MAIN STOR NEEDED BY               01070020
*                  SWAP,TIOC,AND DRIVER                                 01080020
*              +20 SIZE NEW REGION IF NEEDED                            01090020
*                -- ALSO THE ADR OF THE START COMMAND OVERRIDES IN      01100020
*                   THE PARM AREA OR ZERO.(PASSED TO THE DRIVER ONLY)   01110020
*                -- ALSO X'80' IN THE HI ORDER BYTE OF THE WORD         01118020
*                   INDICATES TO THE DRIVER THAT SMF IS ACTIVE          01118420
*              +24 ADDR COMMUNICATIONS PARAMETER LIST(CPL)              01120020
*              +28 SWITCH FOR TSO DUMP                                  01130020
*                  X'FF' DUMP=DUMP - SAVE SWAPPED USER                  01140020
*                  X'00' DUMP=NODUMP - DO NOT SAVE SWAPPED USER         01150020
*              +29 ADDRESS TSC TABLE                                    01160020
*                                                                       01170020
*          B. TSC TABLE                                                 01180020
*              +0  LENGTH OF TSC TABLE                                  01190020
*              +4  NUMBER OF MAPS (MAP= PARAMETER)                      01200020
*              +6  LIMIT NUMBER OF USERS  (USERS= PARAMETER)            01210020
*              +8  DRIVER NAME (DSPCH= PARAMETER)                       01220020
*              +16 SUBMIT PARAMETER                                     01230020
*              +18 SMF PARAMETER                                        01240020
*              +20 MEMBER NAME IN SYS1.PARMLIB                          01250020
*              +28 ADDRESS OF SRE CHAIN                                 01252021
*              +32 REGSIZE AND LSQS SIZE OF REGION 1                    01260021
*              +36 REGSIZE AND LSQS SIZE OF REGION 2                    01270021
*                 ETC.                                                  01280020
*                                                                       01281020
*          C. TSC PARM DATA                                             01290020
*                                                                       01291020
*          D. OS CONTROL BLOCKS                                         01300020
*             CVT                                                       01310020
*             SCVT                                                      01320020
*             IFASMFR                                                   01330020
*             IEFQMRES                                                  01340020
*             IEESMCA                                                   01350020
*             IEEBASEA                                                  01360020
*                                                                       01360420
*          E. TS CONTROL BLOCKS                                         01370020
*             IKJTSCVT                                                  01380020
*             IKJECBS                                                   01390020
*             IKJRCB                                                    01400020
*             IKJTJB                                                    01410020
*             IKJTSIA                                                   01420020
*             IKJSAVED                                                  01430020
*             IKJDPA                                                    01440020
*             IKJRXL                                                    01450020
*             IKJRXLQE                                                  01460020
*             IKJPQE                                                    01470020
*             IKJTCB                                                    01480020
*             IKJTSDMP                                                  01490020
*             TAVTD                                                     01500020
*             IFASMFR 30                                                01510020
*                                                                       01511020
*          F. SMF RECORD  TYPE 30                                       01520020
*              +0  RECORD LENGTH                                        01530020
*              +2  SEGMENT DESCRIPTOR                                   01540020
*              +4  RECORD TYPE                                          01550020
*              +6  TIME STAMP                                           01560020
*              +10 DATE                                                 01570020
*              +14 CPU IDENTIFICATION                                   01580020
*              +18 TS PROC NAME AND TASK IDENTIFIER                     01590020
*              +34 MEMBER NAME IN PARMLIB                               01600020
*              +42 FOREGRND OPTIONS - MAX NO. OF TS REGIONS             01610020
*              +44 TSC REGION SIZE                                      01620020
*              +46 TS DISPATCHING ROUTINE NAME                          01630020
*              +54 MAXIMUM NUMBER OF TERMINALS                          01640020
*              +56 RESERVED                                             01650020
*              +82 LENGTH OF REST OF RECORD                             01660020
*              +84 NUMBER OF ENTRIES (ONE ENTRY FOR EACH REGION)        01670020
*                                                                       01680020
*              EACH ENTRY                                               01690020
*              1 BYTE - REGION NUMBER                                   01700020
*              2 BYTES - LSQS SIZE IN 2K BLOCKS                         01710020
*              2 BYTES - REGION SIZE IN 2K BLOCKS                       01720020
*                                                                       01722020
* SMF RECORD 30 WILL BE WRITTEN IS TSO GETS INITIALIZED. IT WILL        01724020
* REFLECT THE ACTUAL NUMBER OF REGIONS THAT ARE ACTIVE AFTER            01726020
* INITIALIZATION IS COMPLETE. IF TCAM FAILS TO INILIALIZE NO SMF        01728020
* RECORDS WILL BE WRITTEN                                               01728820
*                                                                       01730020
* NOTES -                                                               01731020
*        GETMAIN SUBPOOL USAGE                                          01732020
*          0 - TEMORARY    REGION  SMF RECORD,ETC                       01733020
*        252 - PERMANENT   REGION  TSO CONTROL BLOCKS                   01734020
*        253 - PERMANENT   SQS     RMS CONTROL BLOCKS                   01735020
*        254 - TEMPORARY   SQS     SAVE AND WORK AREAS                  01736020
**********************************************************************  01740020
         EJECT                                                          01750020
*********************************************************************** 01760020
*                                                                     * 01770020
*                             DSECTS                                  * 01780020
*                                                                     * 01790020
*********************************************************************** 01800020
         SPACE                                                          01810020
         IKJTSCVT                                                       01820020
ENDTSCVT EQU   *                                                        01830020
LTSCVT   EQU   ENDTSCVT-TSCVT                                           01840020
         EJECT                                                          01850020
         IKJRCB                                                         01860020
ENDRCB   EQU   *                                                        01870020
LRCB     EQU   ENDRCB-RCB                                               01880020
         EJECT                                                          01890020
         IKJTJB                                                         01900020
ENDTJB   EQU   *                                                        01910020
LTJB     EQU   ENDTJB-TJB                                               01920020
         SPACE 3                                                        01930020
         SPACE 3                                                        01940020
WKAREA   DSECT                                                          01950020
SAVE     DS    18F                 SAVE AREA                            01960020
LISTMAC  DS    16F                 AREA FOR LIST FORM OF MACROS         01980020
SIZEMAPS DS    1F                  SIZE OF MAPS                         01990020
SIZETJB  DS    1F                  SIZE OF TJB'S                        02000020
TWKBLKAD DS    1F                  ADDR OF 2K BLOCK               M7635 02002021
LTSCBLKS DS    1F                  LENGTH OF TSO CNTRL BLKS             02010020
RCTRXLQ  DS    1F                  ADDR OF FIRST USER RXLQE             02020020
DRVNAME  DS    2F                  DRIVER NAME                          02030020
WKAREND  EQU   *                   END OF WK AREA                       02060020
LWKAREA  EQU   WKAREND-WKAREA      LENGTH OF WK AREA                    02070020
         SPACE 4                                                        02080020
         IKJSAVED                                                       02090020
ENDSAVE  EQU   *                                                        02100020
LTSSAVE  EQU   ENDSAVE-TSSAVE      LENGTH OF DSECT                      02110020
         EJECT                                                          02120020
         IKJECBS                                                        02130020
ENDECB   EQU   *                                                        02140020
LECBTAB  EQU   ENDECB-TSECB                                             02150020
         SPACE 4                                                        02160020
         IKJDPA                                                         02170020
ENDDPA   EQU   *                                                        02180020
LDPA     EQU   ENDDPA-DPA                                               02190020
         EJECT                                                          02200020
         IKJTSIA                                                        02210020
ENDTSIA  EQU   *                                                        02220020
LTSIA    EQU   TSIARST-TSIA                                             02230020
         EJECT                                                          02240020
         IKJRXL                                                         02250020
RXLEND   EQU   *                                                        02260020
LRXL     EQU   *-RXL                                                    02270020
         SPACE 5                                                        02280020
         IKJRXLQE                                                       02290020
RXLQEND  EQU   *                                                        02300020
LRXLQ    EQU   *-RXLQE                                                  02310020
         EJECT                                                          02320020
         IKJPQE                                                         02330020
         SPACE 6                                                        02340020
         TAVTD                                                          02350020
         EJECT                                                          02360020
         IKJTCB                                                         02370020
         EJECT                                                          02380020
CVTSECT  DSECT                                                          02390020
         CVT                                                            02400020
         SPACE 4                                                        02410020
SCVTSECT DSECT                                                          02420020
         SCVT                                                           02430020
         EJECT                                                          02440020
IEFQM    DSECT                                                          02450020
         IEFQMRES                                                       02460020
         EJECT                                                          02470020
         IEESMCA                                                        02480020
         EJECT                                                          02490020
         IEEBASEA                                                       02500020
         SPACE 4                                                        02510020
         IKJTSDMP                                                       02520020
ENDTSDMP EQU   *                                                        02530020
LTSDMP   EQU   ENDTSDMP-IKJTSDMP                                        02540020
         EJECT                                                          02540921
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    02541821
SRE      DSECT               STORAGE REQUEST ELEMENT.                   02542721
         SPACE                                                          02543621
SRELINK  DS    1F            CHAIN FIELD ('NEXT' POINTER).              02544521
SRESIZE  DS    1F            AMOUNT OF STORAGE REQUESTED.               02545421
SRENAME  DS    CL8           NAME FIELD (ZERO IF NOT A MODULE).         02546321
SRETNAME DS    CL8           TRUE NAME FIELD FOR LOAD MODULES.          02547221
SRELNGTH EQU   *-SRE         SRE LENGTH.                                02548121
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       02549021
         SPACE 5                                                        02550021
         IFASMFR 30                                                     02560020
LTSREC   EQU   TSTRGNF-TSTSMF                                           02570020
TSTREGNM EQU   TSTRGNF+1                                                02580020
TSTLSSIZ EQU   TSTRGNF+2                                                02590020
TSTRGSIZ EQU   TSTRGNF+4                                                02600020
         EJECT                                                          02610020
IKJEAT02 CSECT                                                          02620020
*********************************************************************** 02630020
*                                                                     * 02640020
*                                  EQUATES                            * 02650020
*                                                                     * 02660020
*********************************************************************** 02670020
         SPACE                                                          02680020
*                             REGISTER EQUATES                          02690020
         SPACE                                                          02700020
R0       EQU   0                   GENERAL REGISTER                     02710020
R1       EQU   1                   GENERAL REGISTER                     02720020
MODADR   EQU   1                   PTR TO BEG OF TSLPA MOD NAME         02730020
ADTSLPA  EQU   1                   PTR TO TSLPA                         02740020
T02SAVE  EQU   1                   PTR TO IKJEAT02 SAVE AREA            02750020
UMSMPTR  EQU   1                   PTR TO USER MAIN STOR MAPS           02760020
PARMLST  EQU   2                   PTR TO PARM LIST                     02780020
CVTREG   EQU   3                   PTR TO CVT                           02800020
R4       EQU   4                   GENERAL REGISTER                     02810020
TSCVTREG EQU   4                   TSCVT PTR                            02820020
R5       EQU   5                   GENERAL REGISTER                     02830020
RCBAD    EQU   5                   RCB PTR                              02840020
RCBNUM   EQU   5                   CONTAINS NUMBER OF RCB'S SPECIFIED   02860020
SIZECBLK EQU   5                   REG CONT SIZE OF TSO CONTROL BLKS    02880020
R6       EQU   6                   GENERAL REGISTER                     02890020
DPAREG   EQU   6                   PTR TO DPA                           02900020
R7       EQU   7                   GENERAL REGISTER                     02920020
TCBAD    EQU   7                   PTR TO TCB                           02930020
LDSECT   EQU   7                   CONTAINS LENGTH OF DSECTS            02940020
NMRCB    EQU   7                   CONTAINS NUMBER OF RCB'S             02950020
RCBREG   EQU   7                   RCB PTR                              02960020
R8       EQU   8                   GENERAL REGISTER                     02980020
LMAP     EQU   8                   CONTAINS LENGTH OF A MAP             02990020
NUMRCB   EQU   8                   CONTAINS NUMBER OF RCB'S             03000020
SIZERCB  EQU   8                   CONTAINS SIZE OF RCB                 03010020
NUMUSER  EQU   8                   CONTAINS NUMBER OF LIMIT USERS       03020020
R9       EQU   9                   GENERAL REGISTER                     03040020
RCBTAB   EQU   9                   PTR TO RCB                           03050020
TJBREG   EQU   9                   PTR TO TJB                           03060020
TSCECBAD EQU   10                  PTR TO TSC TABLE                     03090020
TJBSTOP  EQU   10                  PTR TO END OF TJB'S                  03100020
UMSMSTOP EQU   10                  ADR OF END OF UMSM'S                 03120020
R11      EQU   11                  GENERAL REGISTER                     03130020
TSCTABAD EQU   11                  PTR TO TSC TABLE                     03140020
ADEXITRT EQU   11                  ADDRESS OF EXIT RTN                  03150020
R12      EQU   12                  GENERAL REGISTER                     03160020
BASEREG  EQU   12                  BASE REGISTER                        03170020
R13      EQU   13                  GENERAL REGISTER                     03180020
SYSSAVE  EQU   13                  PTR TO SYSTEM SAVE AREA              03190020
R14      EQU   14                  GENERAL REGISTER                     03200020
RETREG   EQU   14                  ADDRESS OF RETURN                    03210020
R15      EQU   15                  GENERAL REGISTER                     03220020
CODEREG  EQU   15                  RETURN CODE REGISTER                 03230020
         SPACE                                                          03250020
*                             NUMBER EQUATES                            03260020
         SPACE                                                          03270020
ZERO     EQU   0                   NUMBER                               03280020
ONE      EQU   1                   NUMBER                               03290020
TWO      EQU   2                   NUMBER                               03300020
FOUR     EQU   4                   NUMBER                               03320020
FIVE     EQU   5                   NUMBER                               03330020
SIX      EQU   6                   NUMBER                               03340020
SEVEN    EQU   7                   NUMBER                               03342020
EIGHT    EQU   8                   NUMBER                               03350020
ELEVEN   EQU   11                  NUMBER                               03360020
TWELVE   EQU   12                  NUMBER                               03370020
THRTEEN  EQU   13                  NUMBER                               03380020
FRTEEN   EQU   14                  NUMBER                               03390020
FIFTN    EQU   15                  NUMBER                               03400020
SXTN     EQU   16                  NUMBER                               03410020
EIGTN    EQU   18                  NUMBER                               03420020
TWTY     EQU   20                  NUMBER                               03430020
TWTYFOUR EQU   24                  NUMBER                               03440020
TWTYEIGT EQU   28                  NUMBER                               03450020
SMFREC30 EQU   30                  SMF RCORD = RECORD 30                03460020
THRTYTW  EQU   32                  NUMBER                               03470020
SVNTYTW  EQU   72                  NUMBER                               03480020
TSIPSVC  EQU   95                  TSIP SVC = SVC 95                    03500020
QTIPSVC  EQU   101                 QTIP SVC= SVC 101                    03510020
DISPL    EQU   4*TSIPSVC           DISPLACEMENT OF TSIP IN SVC TABLE    03520020
DISPL1   EQU   4*QTIPSVC           DISPLACEMENT OF QTIP IN SVC TABLE    03530020
TWFTYFIV EQU   255                 NUMBER                               03540020
TWFTYSIX EQU   256                 NUMBER                               03550020
TWKCONST EQU   2048                                               M7635 03550421
FETCHAR1 EQU   1360                                               M7635 03550821
FETCHAR2 EQU   688                                                M7635 03551221
         SPACE                                                          03560020
*                             GENERAL EQUATES                           03570020
         SPACE                                                          03580020
ATTRBIT  EQU   X'B0'               BITS IN CDE FOR LOAD BY NIP,         03601020
*                                  REENTRANT,AND REUSEABLE              03602020
TSCACTV  EQU   X'C0'               BITS IN RXLQE FOR ACTIVE AND         03640020
*                                  INDICATING IT IS A TSC RXLQE         03641020
TCMACTV  EQU   X'A0'               BITS IN RXLQE FOR ACTIVE AND         03650020
*                                  INDICATING IT IS A TCAM RXLQE        03651020
SMFFLAG  EQU   X'80'               USED TO INDICATE TO DRIVER SMF       03653020
*                                  IS ACTIVE IN SYSTEM                  03655020
         EJECT                                                          03660020
         SPACE 3                                                        03670020
*********************************************************************** 03680020
*                                                                     * 03690020
* THIS SECTION ESTABLISHES ADDRESSIBILITY.  GETMAINS FOR AND ZEROS    * 03710020
* A WORK AREA IN SUBPOOL 254.                                         * 03730020
*                                                                     * 03760020
*********************************************************************** 03770020
         SPACE 2                                                        03780020
         STM   R14,R12,TWELVE(SYSSAVE) SAVE SYSTEM REGISTERS            03790020
         BALR  BASEREG,R0          SET UP ADDRESSABILITY                03800020
         USING *,BASEREG           ESTABLISH BASE REGISTER              03810020
         LR    PARMLST,R1          SAVE ADDR TSC PARM LIST              03820020
         SPACE                                                          03830020
         LA    R0,LWKAREA          GET LENGTH OF SAVE AND WK AREA       03840020
         O     R0,SP254            SUBPOOL 254 IN HI BYTE               03940020
         GETMAIN R,LV=(0)          GET SAVE AREA FOR T02                04040020
         ST    T02SAVE,EIGHT(SYSSAVE)    CHAIN                          04140020
         ST    SYSSAVE,FOUR(T02SAVE)            THE                     04240020
         LR    SYSSAVE,T02SAVE                     AREAS                04340020
         USING WKAREA,SYSSAVE      SET UP WK AREA DSECT                 04440020
         LA    R0,TWKCONST         GET LENGTH 2K                  M7635 04490021
         O     R0,SP252            INDICATE SUBPOOL 252           M7635 04500021
         GETMAIN R,LV=(0)          GET AREA                       M7635 04510021
         ST    R1,TWKBLKAD         SAVE ADDRESS                   M7635 04520021
         EJECT                                                          04540020
**********************************************************************  04650020
*                                                                    *  04660020
* THIS SECTION COMPUTES THE MAIN STORAGE NEEDED FOR THE TSO CONTROL  *  04670020
* BLOCKS.  GETMAINS AN AREA FROM SUBPOOL 252 AND CLEARS IT.          *  04680020
*                                                                    *  04690020
**********************************************************************  04700020
         SPACE 3                                                        04710020
T02TSCB  LA    SIZECBLK,LTSCVT     GET LENGTH TSCVT                     04720020
         LA    LDSECT,LTSDMP       GET LENGTH OF TSO DMP CNTRL BLOCK    04730020
         AR    SIZECBLK,LDSECT     ADD TO SIZE OF OTHER CNTRL BLOCKS    04740020
         LA    R6,SEVEN            SET DOUBLE WORD MASK                 04742020
         NR    R6,SIZECBLK         IS LENGTH A MULTIPLE OF EIGHT        04744020
         BZ    DBLNOW              YES IT IS ALREADY ALIGNED            04746020
         LA    SIZECBLK,FOUR(SIZECBLK) ROUND UP TO DOUBLE WORD MULTIPLE 04748020
*                                  THE REASON FOR THIS IS THAT THE      04748120
*                                  SAVE AREAS IN DSECT IKJSAVED MUST    04748220
*                                  BE ON A DOUBLE WORD BOUNDARY         04748320
DBLNOW   LA    LDSECT,LTSSAVE      GET LENGTH OF SYSTEM SAVE AREA       04748420
         AR    SIZECBLK,LDSECT     ADD TO SIZE OF OTHER CONTROL BLOCKS  04748820
         LA    LDSECT,LRCB         GET LENGTH RCB                       04750020
         MH    LDSECT,FRTEEN(PARMLST) MULT LRCB BY #REGIONS             04760020
         AR    SIZECBLK,LDSECT     ADD TO SIZE OF OTHER CNTRL BLOCKS    04770020
         SR    R6,R6               ZERO REGISTER                        04780020
         LA    LDSECT,LTJB         GET LENGTH OF TJB                    04790020
         L     NUMUSER,ZERO(PARMLST) GET NUMBER OF MAX USERS FR PARMLST 04800020
         LA    NUMUSER,ONE(NUMUSER) ADD ONE TO NO OF USERS              04810020
         MR    R6,NUMUSER          MULT SIZE TJB BY NO OF USERS         04820020
         ST    LDSECT,SIZETJB      SAVE SIZE OF TJB CORE                04830020
         AR    SIZECBLK,LDSECT     ADD RESULT TO REG CONTAINING SIZE    04840020
*                                  OF OTHER CONTROL BLOCKS              04850020
         LA    LDSECT,LECBTAB      GET LENGTH OF TSECB TABLE            04880020
         AR    SIZECBLK,LDSECT     ADD TO SIZE OF OTHER CONTROL BLOCKS  04890020
         LA    LDSECT,FOUR         LENGTH OF MAP = 4                    04910020
         L     TSCTABAD,TWTYEIGT(PARMLST) GET ADR TSC TABLE             04920020
         LA    TSCTABAD,ZERO(TSCTABAD) ZERO HI ORDER BYTE               04930020
         MH    LDSECT,FOUR(TSCTABAD) MULT #MAP ENTRIES BY FOUR          04940020
         LH    NUMRCB,FRTEEN(PARMLST) GET NUMBER RCB'S                  04950020
         A     NUMRCB,ZERO(PARMLST) ADD NUMBER OF TJB'S                 04960020
         LA    NUMRCB,ONE(NUMRCB)  ADD ONE AND RESULT NO MAPS           04970020
         SR    R6,R6               MULT NUM MAPS BY SIZE EACH MAP       04980020
         MR    R6,NUMRCB           RESULT IS SIZE OF MAPS               04990020
         ST    LDSECT,SIZEMAPS     SAVE SIZE OS USER MAIN ST MAP CORE   05000020
         AR    SIZECBLK,LDSECT     ADD TO SIZE OF OTHER CNTRL BLKS      05010020
         LA    LDSECT,LDPA         GET LENGTH OF DPA                    05020020
         AR    SIZECBLK,LDSECT     ADD TO SIZE OF OTHER CONTROL BLOCKS  05030020
         LA    LDSECT,LTSIA        GET LENGTH OF FIXED TSIA             05040020
         LA    NUMRCB,FOUR         MULT NO REGIONS BY FOUR              05050020
         MH    NUMRCB,FRTEEN(PARMLST)                                   05060020
         AR    LDSECT,NUMRCB       ADD TO LENGTH OF FIXED TSIA          05070020
         AR    SIZECBLK,LDSECT     ADD TO SIZE OF OTHER CONTROL BLOCKS  05080020
         LA    SIZECBLK,SVNTYTW(SIZECBLK) ADD A SAVE AREA TO SIZE OF    05090020
*                                  CONTROL BLOCKS                       05100020
         ST    SIZECBLK,LTSCBLKS   SAVE LENGTH OF CNTRL BLK AREA        05110020
         LR    R0,SIZECBLK         PUT SIZE IN REG0                     05120020
         O     R0,SP252            SUBPOOL 252 IN HI BYTE               05125020
         GETMAIN R,LV=(0)          GET AREA FOR TS CONTROL BLOCKS.      05130020
         LR    R7,R1               SAVE ADR PTR TO AREA                 05140020
         LA    R4,TWFTYFIV         GET LENGTH=255                       05150020
EXLOOP2  CH    SIZECBLK,N256       IS LENGTH GR THAN 256                05160020
         BH    MOVE2               YES BRANCH                           05170020
         BCTR  SIZECBLK,ZERO       NO- DECREMENT LENGTH BY ONE          05180020
         EX    SIZECBLK,CLEARAR    ZERO ENTIRE AREA                     05190020
         B     INITCBLK            BRANCH TO INITIALIZE CONTROL BLOCKS  05200020
         SPACE 2                                                        05210020
MOVE2    EX    R4,CLEARAR          CLEAR 256 BYTES                      05220020
         SH    SIZECBLK,N256       SUBSTRACT 256 BYTES FROM LENGTH      05230020
         LA    R7,TWFTYSIX(R7)     UPDATE PTR 256 BYTES                 05240020
         B     EXLOOP2             BR- CONTINUE CLEARING AREA           05250020
         EJECT                                                          05260020
**********************************************************************  05270020
*                                                                    *  05280020
* THIS SECTION INITIALIZES CERTAIN FIELDS IN THE TSO CONTROL BLOCKS, *  05290020
* AND OS CONTROL BLOCKS.                                             *  05300020
*                                                                    *  05310020
**********************************************************************  05320020
         SPACE 3                                                        05330020
**********                    INITIALIZE TSCVT               ********** 05340020
         SPACE 3                                                        05350020
INITCBLK LR    R6,R1               SAVE ADR TSO DUMP CBLK               05360020
         LA    LDSECT,LTSDMP       GET LENGTH TSO DMP CNTRL BLK         05370020
         AR    R1,LDSECT           ADD AND GET ADR NEXT CNTRL BLK       05380020
         LR    TSCVTREG,R1         SAVE ADR CNTRL BLK AREA              05390020
         USING TSCVT,TSCVTREG      FIRST BLOCK IS TSCVT                 05400020
         MVC   TSCVTLUS,SIX(TSCTABAD) PUT LIMIT NUM OF USERS IN TSCVT   05410020
         MVC   TSCVTMUS,TWO(PARMLST) PUT MAX NO. USERS IN TSCVT         05420020
         MVC   TSCVTSPL,TWTYFOUR(PARMLST)  PUT ADR CPL IN TSCVT         05430020
         ST    R6,TSCVTDMP         PUT ADR TSO DUMP CNTRL BLK IN TSCVT  05440020
         L     CVTREG,CVTPTR       GET ADR CVT                          05450020
         USING CVTSECT,CVTREG      SET UP CVT DSECT                     05460020
         L     R7,CVTTCBP          GET ADDR PTR TO CURRENT TCB          05470020
         L     TCBAD,FOUR(R7)      GET ADDR CURRENT TCB                 05480020
         ST    TCBAD,TSCVTTSC      PUT ADDR CURRENT TCB IN TSCVT        05490020
         L     R7,CVTMSER          GET ADR.MAST. SCA.RESID DATA AREA    05500020
         USING BASE,R7             SET UP IEEBASEA DSECT                05510020
         LH    R7,BAMINPAR         GET MIN INIT REGION SIZE             05520020
         SRL   R7,ONE              CHANGE SIZE TO 2K BLOCKS             05530020
         STH   R7,TSCVTRSZ         SAVE IN TSCVT                        05540020
         DROP  R7                  DROP USING IN IEEBASEA               05550020
         L     R6,CVTABEND         GET ADR SECONDARY CVT                05560020
         USING SCVTSECT,R6         SET UP SCVT DSECT                    05570020
         MVC   TSCVTTQE(FOUR),SCVTTQE PROPAG TQE PTR FR SCVT TO TSCVT   05580020
         L     R6,SCVTSVCT         GET ADR OF SVC TABLE                 05590020
         L     R7,DISPL(R6)        GET ENTRY ADR IN SVC TABLE           05600020
         ST    R7,TSCVTSVT         SAVE ADR IN TSCVT                    05610020
         L     R7,DISPL1(R6)       GET ENTRY ADR IN SVC TABLE           05620020
         ST    R7,TSCVTSVQ         STORE ADR IN TSCVT                   05630020
         DROP  R6                  DROP USING ON SCVT                   05640020
         LA    LDSECT,LTJB         GET SIZE TJB                         05650020
         STH   LDSECT,TSCVTSZU     PUT SIZE TJB IN TSCVT                05660020
         MVC   TSCVTCTR,FRTEEN(PARMLST) PUT NO.RCB'S ALLOCATED INIT     05670020
         MVC   TSCVTNTJ,TWO(PARMLST) PUT NO.TJB'S ALLOCATED INIT        05680020
         LA    LDSECT,LTSCVT       GET LENGTH TSCVT                     05690020
         AR    R1,LDSECT           ADD AND GET ADR NEXT CNTRL BLK       05700020
         LA    R6,SEVEN            SET DOUBLE WORD MASK                 05702020
         NR    R6,SIZECBLK         IS LENGTH A MULTIPLE OF EIGHT        05704020
         BZ    DBLNOW1             YES IT IS ALREADY ALIGNED            05706020
         LA    SIZECBLK,FOUR(SIZECBLK) ROUND UP TO DOUBLE WORD MULTIPLE 05708020
DBLNOW1  ST    R1,TSCVTSAV         PUT ADR SAVE AREAS IN TSCVT.         05708420
         LA    LDSECT,LTSSAVE      GET LENGTH OF SAVE AREAS             05708820
         AR    R1,LDSECT           ADD &GET ADDR OF NXT CNTRL BLK       05709220
         ST    R1,TSCVTECB         PUT ADR ECB TABLE IN TSCVT           05710020
         LA    LDSECT,LECBTAB      GET LENGTH ECB TABLE                 05720020
         AR    R1,LDSECT           ADD AND GET ADR NEXT CNTRL BLK       05730020
         ST    R1,TSCVTICB         PUT ADR TSICB IN TSCVT- TSICB INCLDS 05770020
*                                  DPA,SAVE AREA,AND TSIA               05780020
         SPACE                                                          05790020
         LR    DPAREG,R1           SAVE ADR DPA                         05800020
         LA    LDSECT,LDPA         GET LENGTH OF DPA                    05810020
         AR    R1,LDSECT           ADD AND GET ADR OF SAVE AREA         05820020
         LA    R1,SVNTYTW(R1)      UPDATE PTR 72 BYTES AND GET ADR TSIA 05830020
         ST    R1,TSCVTSIA         PUT ADR TSIA IN TSCVT                05840020
         USING DPA,DPAREG          SET UP DPA DSECT                     05850020
         ST    R1,DPATSIA          PUT ADR TSIA IN DPA                  05860020
         LA    LDSECT,LTSIA        GET LEN FIXED TSIA                   05870020
         LA    R8,FOUR             GET LENGTH OF VARIABLE TSIA DEPENDNT 05880020
         MH    R8,FRTEEN(PARMLST)  ON NUMBER REGIONS                    05890020
         AR    LDSECT,R8           ADD TO FIXED LENGTH                  05900020
         AR    R1,LDSECT           ADD AND GET ADR NEXT CONTROL BLOCK   05910020
         ST    R1,TSCVTTJB         PUT ADR TJB IN TSCVT                 05920020
         SPACE 4                                                        05930020
**********                    INITIALIZE TJB'S               ********** 05940020
         SPACE 3                                                        05950020
         SR    R14,R14             SET TJID CT TO ZERO                  05960020
         LR    TJBREG,R1           GET ADR TJB                          05970020
         USING TJB,TJBREG          SET UP TJB DSECT                     05980020
         A     R1,SIZETJB          ADD TO PTR OF CNTRL BLKS SIZE TJB'S  05990020
         LR    TJBSTOP,R1          SAVE STOPPER ADR OF TJB'S            06000020
         LA    LMAP,FOUR           LENGTH OF EACH MAP = 4               06010020
         MH    LMAP,FOUR(TSCTABAD) GET SIZE OF EACH MAP                 06020020
TJBLOOP  MVC   TJBUMSMN,FIVE(TSCTABAD) PUT NO.MAP ENTR IN TJB           06030020
         ST    R1,TJBUMSM          PUT ADR MAP IN TJB                   06040020
         AR    R1,LMAP             UPDTE PTR TO NEXT MAP                06050020
         STH   R14,TJBTJID         PUT TJID IN TJB                      06060020
         LA    R14,ONE(R14)        UPDATE TJID CT BY ONE                06070020
         OI    TJBSTAT,TJBNJB      TURN BIT ON TO MARK TJB UNUSED       06080020
         LA    TJBREG,TJBEND       UPDTE PTR TO NEXT TJB                06090020
         CR    TJBREG,TJBSTOP      IS THIS END OF TJB'S                 06100020
         BNE   TJBLOOP             NO-CONTINUE TJB PROCESSING           06110020
         DROP  TJBREG              YES-START PROCESSING RCB'S           06120020
         EJECT                                                          06130020
         SPACE 2                                                        06140020
**********                    INITIALIZE RCB'S               ********** 06150020
         SPACE 3                                                        06160020
         LA    RCBTAB,THRTYTW(TSCTABAD) GET ADR TABLE CONTAINING A44022 06170021
*                                  REGION AND LSQS SIZE OF RCB          06180020
         A     TJBSTOP,SIZEMAPS    GET STOPPER FOR MAPS                 06190020
         LR    RCBREG,TJBSTOP      GET BEG ADR OF RCB'S                 06200020
         USING RCB,RCBREG          SET UP RCB DSECT                     06210020
         ST    RCBREG,TSCVTRCB     PUT ADR RCB IN TSCVT                 06220020
         LA    RCBNUM,ONE          START A NUMBER COUNT FOR THE RCB'S   06230020
RCBLOOP  STC   RCBNUM,RCBNMBR      PUT NUMBER IN RCB                    06240020
         MVC   RCBUMSMN,FIVE(TSCTABAD) PUT NO.MAP ENTRIES IN RCB        06250020
         ST    UMSMPTR,RCBUMSM     PUT ADR MAP IN RCB                   06260020
         MVC   RCBRSIZE(FOUR),ZERO(RCBTAB)    PUT REGION SIZE AND       06270020
*                                  LSQS SIZE IN RCB                     06280020
         MVC   RCBCONID(ONE),THRTEEN(PARMLST) PUT CONSOLE ID            06282020
*                                  OF START COMMAND IN RCB              06284020
         LA    RCBNUM,ONE(RCBNUM)  UPDTE NUMBER CT BY ONE               06290020
         LA    RCBTAB,FOUR(RCBTAB) UPDTE PTR TO RCB TABLE               06300020
         AR    UMSMPTR,LMAP        UPDTE PTR TO NEXT MAP                06310020
         LA    RCBREG,RCBEND       UPDTE PTR TO NEXT RCB                06320020
         CR    UMSMPTR,UMSMSTOP    IS THAT END OF MAPS                  06330020
         BNE   RCBLOOP             NO-CONTINUE PROC RCB'S               06340020
         SPACE 4                                                        06350020
***** WE HAVE TO INITIALIZE OS CNTRL BLK IEFQMRES WITH SUBMIT VALUES ** 06360020
         SPACE 3                                                        06370020
         L     R5,CVTJOB           GET ADR QUEUE MANAGER RESIDENT CORE  06380020
         USING IEFQM,R5            SET UP ADDRESSABILITY                06390020
         MVC   QMFIBMAX(TWO),SXTN(TSCTABAD) PUT SUBMIT VALUE INTO BLK   06400020
         DROP  R5                                                       06402020
         SPACE                                                          06410020
         ST    R4,CVTTSCVT         PUT ADR TSCVT IN CVT                 06420020
         EJECT                                                          06430020
*********************************************************************   07320020
*                                                                   *   07330020
* THIS SECTION LINKS TO TIOC,SWAP,DRVR,&TSO DUMP TO SEE IF THEY CAN *   07340021
* INITIALIZE THEIR PART OF THE SYSTEM.IF THEY WILL BE ABLE TO       *   07350020
* INITIALIZE THEY RETURN A CODE OF 0 AND PROCESSING CONTINUES. IF   *   07360020
* THEY CAN'T INITIALIZE THEY RETURN A CODE OF 8 AND A WTO IS ISSUED *   07370020
* TELLING THE OPERATOR START TS IS REJECTED.AND WE RETURN.          *   07380020
*                                                                   *   07390020
*********************************************************************   07400020
         SPACE 1                                                        07410020
**********               LINK TO TIOC                        ********** 07420020
         SPACE 2                                                        07430020
T02LINKS SR    CODEREG,CODEREG     ZERO REG 15 FOR RETURN CODE USE      07440020
         MVC   TWTY(FOUR,PARMLST),SXTN(PARMLST) SVE PTR TO DRVR OVER-   07450020
*                                  RIDES IN PARM DATA                   07460020
         LR    R1,PARMLST          PUT PARAMETER LIST ADDR IN REG1      07470020
         MVC   LISTMAC(LLINK),LINKLIST MOVE LIST FORM OF                07480020
         LA    R5,LISTMAC          LINK MACRO TO WKAREA-GET ADDR        07490020
         LINK  EP=IKJGGE01,SF=(E,(R5))  LINK TO TIOC ROUTINE TO DO      07500020
         B     *+FOUR(CODEREG)     ITS INITIALIZATION                   07510020
         B     LINKGD1             IF RET CODE=0 THEN LINK GOOD         07520020
         B     LINKGD1             IF RET CODE=4 THEN LINK GOOD         07530020
         SPACE 2                                                        07540020
*****    WE CAN'T INITIALIZE THE SYSTEM SO WE RETURN TO CALLER.   ***** 07550020
         SPACE 2                                                        07560020
LINKBAD  MVC   LISTMAC(WTO1L),WTO1 RET CODE=8 -MEAN CANNOT              07570020
         SR    R0,R0               CLEAR REGISTER                       07580020
         IC    R0,THRTEEN(PARMLST) PUT CONSOLE ID INTO REG 0            07590020
         LA    R1,LISTMAC          INITIALIZE SYSTEM                    07600020
         WTO   MF=(E,(1))          TELL OPERATOR                        07610020
REJST1   SR    R0,R0               CLEAR REGISTER                       07620020
         ST    R0,CVTTSCVT         ZERO ADR TSCVT IN CVT                07630020
         L     R1,TSCVTDMP         GET ADR OF BEG TSO CNTRL BLKS        07644020
         L     R0,LTSCBLKS         GET LENGTH TS CNTRL BLKS             07650020
         O     R0,SP252            SUBPOOL 252 IN HI BYTE               07655020
         FREEMAIN R,LV=(0),A=(1)   FREE AREA TS CNTRL BLKS              07660020
         LA    R0,LWKAREA          GET LENGTH T02 SVE AND WORK AREA     07670020
         LR    T02SAVE,R13         SET UP REG 1 WITH ADR T02 SAVE AREA  07680020
         L     SYSSAVE,FOUR(R13)   SET UP 13 WITH SYSTEM SAVE AREA      07690020
         O     R0,SP254            SUBPOOL 254 IN HI BYTE               07695020
         FREEMAIN R,LV=(0),A=(1)   FREE T02 SAVE+WORK AREA              07700020
         LM    R14,R12,TWELVE(SYSSAVE) RESTORE SYSTEM REGISTERS         07710020
         BR    RETREG              RETURN TO CALLER                     07720020
         SPACE 2                                                        07730020
**********               LINK TO SWAP                        ********** 07740020
         SPACE 2                                                        07750020
LINKGD1  SR    CODEREG,CODEREG     ZERO REG15 FOR RETURN CODE USE       07760020
         LR    R1,PARMLST          PUT PARAMETER LIST ADDR IN REG1      07770020
         MVC   LISTMAC(LLINK),LINKLIST MVE LINK LIST TO WK AREA         07780020
         LA    R5,LISTMAC          GET ADR LIST                         07790020
         LINK  EP=IKJEAS01,SF=(E,(R5)) LINK TO SWAP TO DO ITS           07800020
         B     *+FOUR(CODEREG)     INITIALIZATION                       07810020
         B     LINKGD2             RET CODE=0 MEANS LINK GOOD           07820020
         B     LINKGD2             RET CODE=4 NOT DEFINED               07830020
         B     LINKBAD             RET CODE=8 MEANS TIOC COULD NOT INIT 07840020
         SPACE 4                                                        07850020
**********               LINK TO DRIVER                      ********** 07860020
         SPACE 2                                                        07870020
LINKGD2  SR    CODEREG,CODEREG     ZERO RETURN CODE REG                 07880020
         C     R15,CVTSMCA         IS SMF ACTIVE IN SYSTEM              07882020
         BE    NOSMF               NO BYPASS TURNING ON BIT             07884020
         OI    TWTY(PARMLST),SMFFLAG INDICATE SMF ACTIVE                07886020
NOSMF    LR    R1,PARMLST          PUT ADDR PARAMETER LIST IN REG1      07890020
         MVC   LISTMAC(LLINK),LINKLIST MVE LINK LIST TO WK AREA         07900020
         LA    R5,LISTMAC          GET ADDR OF LIST                     07910020
         MVC   FRTEEN(TWO,R11),DRVCD1 PUT DRVER ID IN DRVER NAME        07920020
         LA    R8,EIGHT(R11)       GET ADR DRIVER RTN                   07930020
         LINK  EPLOC=(R8),SF=(E,(R5)) LINK TO DRVER TO PERFORM HIS      07940020
         B     *+FOUR(CODEREG)     INITIALIZATION                       07950020
         B     LINKGD3             RET CODE=0 MEANS LINK GOOD           07960020
         B     LINKGD3             RET CODE=4 NOT DEFINED               07970020
         B     LINKBAD             RET CODE=8 BAD                       07980020
LINKGD3  MVC   DPADCA(FOUR),SXTN(PARMLST) PUT A RETURN ADDR FROM DRIVER 07990020
*                                  INTO DPA                             08000020
         SPACE 4                                                        08011020
**********           LINK TO TSO DUMP INITIALIZATION RTN     ********** 08020020
         SPACE 2                                                        08030020
         SR    CODEREG,CODEREG     ZERO RETURN CODE REGISTER            08040020
         LR    R1,PARMLST          PUT ADR PARM LIST IN REG 1           08050020
         MVC   LISTMAC(LLINK),LINKLIST MVE LINK LIST TO WK AREA         08060020
         LA    R5,LISTMAC          GET ADR LIST FORM OF LINK            08070020
         LINK  EP=IKJEAP00,SF=(E,(R5))   LINK TO TSO DUMP               08080020
         B     *+FOUR(CODEREG)     BRANCHING TABLE                      08090020
         B     T02TSLPA      RET. CODE 0 & 4 LINK GOOD.          A44022 08102021
         B     T02TSLPA      *                                   A44022 08108021
         B     LINKBAD             RETURN CODE=8 COULD NOT INITIALIZE   08120020
         EJECT                                                          08130020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    08140021
*********************************************************************** 08150021
*  THIS SECTION LOADS MODULES WHOSE NAMES OCCUR IN SRE'S ON THE       * 08160021
*  SRE CHAIN.AS EACH SRE IS INSPECTED/PROCESSED IT IS FREED.CDE'S FOR * 08170021
*  LOADED MODULES ARE SET TO SHOW 'NIP-LOADED', RENT AND REUS.        * 08180021
*********************************************************************** 08190021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       08200021
         SPACE 3                                                        08230020
T02TSLPA L     R1,CVTTCBP          GET PTR TO ADDR OF CURRENT TCB       08240020
         L     TCBAD,FOUR(R1)      GET ADDR CURRENT TCB                 08250020
         USING TCB,TCBAD           SET UP TCB DSECT                     08260020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    08265021
         L     R8,TWTYEIGT(PARMLST) R8=TSCTABLE ADDR.                   08270021
         MVC   DRVNAME(SIX),EIGHT(R8) MOVE DRIVER NAME TO WKAREA.       08275021
         L     R8,TWTYEIGT(R8) R8=HEAD OF SRE CHAIN.                    08280021
         LA    R0,FETCHAR1         GET LENGTH                     M7635 08282021
         L     R1,TWKBLKAD         GET ADDR OF 2K BLK             M7635 08284021
         LR    R9,R1               SAVE ADR                       M7635 08284421
         AR    R9,R0               UPDATE ADDR                    M7635 08284821
         ST    R9,TWKBLKAD         SAVE ADR REMAINING AREA        M7635 08284921
         O     R0,SP252            INDICATE SP 252                M7635 08289821
         FREEMAIN R,LV=(0),A=(1)   FREE PART OF AREA FOR FETCH    M7635 08299821
LOADLOOP EQU   *                                                        08301121
         LTR   R8,R8         Q.ANY MORE SRE'S.                          08306021
         BZ    PARMEND       NO,PROCESS CDE'S.                          08310921
         USING SRE,R8        SRE ADDRESSABILITY.                        08315821
         TM    SRENAME,ALLBITS Q.THIS SRE CONTAIN A NAME.               08320721
ALLBITS  EQU   X'FF'         BYTE MASK, ALL BITS ON.                    08325621
         BC    FIVE,BLDLMOD  YES,DO BLDL AND LOAD.                      08330521
NEXTSRE  EQU   *                                                        08335421
         L     R9,SRELINK    OTHERWISE,BUMP TO NEXT SRE AND             08340321
*                            FREE THE OLD ONE.                          08345221
         LR    R1,R8         R1=ADDR OF SRE BEING FREED.                08350121
         LA    R0,SRELNGTH   R0=LENGTH OF SRE.                          08355021
         O     R0,SP254      INDICATE SUBPOLL 254.                      08359921
         FREEMAIN R,LV=(0),A=(1) FREE SRE.                              08364821
         LR    R8,R9         NEXT SRE ADDRESS.                          08369721
         B     LOADLOOP      CHECK IT FOR A NAME.                       08374621
BLDLMOD  EQU   *                                                        08379521
         MVC   LPABNAME(EIGHT),SRENAME MOVE MODULE NAME INTO BLDL LIST. 08384421
         SR    R15,R15       ZERO RETURN CODE.                          08389321
         SR    R1,R1         INDICATE SYSTEM LIBRARY.                   08394221
         BLDL  (1),LPABLDL   ISSUE BLDL.                                08399121
         LTR   R15,R15       Q.BLDL SUCCESSFUL.                         08404021
         BNZ   NEXTSRE       NO,CHECK NEXT SRE.                         08408921
         OI    LPABATTR,LPABRENT+LPABREUS SET RENT +REUS.               08413821
         LOAD  DE=LPABNAME   LOAD THE MODULE.                           08418721
         CLC   T04,SRENAME   Q.IKJEAT04.                                08423621
         BNE   CHKT08        NO,CHECK IKJEAT08.                         08428521
         MVC   LISTMAC(LSTAE),STAELIST MOVE STAE LIST FORM TO WKAREA.   08433421
         LA    R1,LISTMAC    R1=STAE LIST POINTER.                      08438321
         LR    R5,R0         R5=EXIT ENTRY POINT.                       08443221
         STAE  (5),OV,XCTL=YES,MF=(E,(1)) ISSUE STAE.                   08448121
         LTR   R15,R15       CHECK RETURN CODE.                         08453021
         BZ    NEXTSRE       OK,GET ANOTHER SRE.                        08457921
         WTO   'IKJ060I START REJECTED - UNABLE TO ESTABLISH A STAE ENVX08462821
               IRONMENT',DESC=4,ROUTCDE=(2)                             08467721
         B     REJST1        RETURN.                                    08472621
CHKT08   EQU   *                                                        08477521
         CLC   T08,SRENAME   Q.IKJEAT08.                                08482421
         BNE   CHKL00        NO,CHECK IKJEAL00.                         08487321
         ST    R0,TSCVTT08   PUT IKJEAT08 EP IN TSCVT.                  08492221
         B     NEXTSRE       NEXT SRE.                                  08497121
CHKL00   EQU   *                                                        08502021
         CLC   L00,SRENAME   Q.IKJEAL00.                                08506921
         BNE   CHKI00        NO,CHECK IKJEAI00.                         08511821
         ST    R0,TSCVTSLF   YES,PUT IKJEAL00 EP IN TSCVT.              08516721
         B     NEXTSRE       NEXT SRE.                                  08521621
CHKI00   EQU   *                                                        08526521
         CLC   I00,SRENAME   Q.IKJEAI00.                                08531421
         BNE   CHKI01        NO,CHECK IKJEAI01.                         08536321
         L     R6,CVTABEND   YES,R6=2NDARY CVT ADDR.                    08541221
         USING SCVTSECT,R6   ADDRESSABILITY.                            08546121
         L     R5,SCVTSVCT   R5=SVC TABLE ADDR.                         08551021
         ST    R0,DISPL(R5)  INITIALIZE TSIP SVC TABLE ENTRY.           08555921
         B     NEXTSRE       NEXT SRE.                                  08560821
CHKI01   EQU   *                                                        08565721
         CLC   I01,SRENAME   Q.IKJEAI01.                                08570621
         BNE   CHKI02        NO,CHECK IKJEAI02.                         08575521
         ST    R0,TSCVTI01   YES,PUT IKJEAI01 EP IN TSCVT.              08580421
         B     NEXTSRE       NEXT SRE.                                  08585321
CHKI02   EQU   *                                                        08590221
         CLC   I02,SRENAME   Q.IKJEAI02.                                08595121
         BNE   CHKI03        NO,CHECK IKJEAI03.                         08600021
         ST    R0,TSCVTI02   YES,PUT IKJEAI02 EP IN TSCVT.              08604921
         B     NEXTSRE       NEXT SRE.                                  08609821
CHKI03   EQU   *                                                        08614721
         CLC   I03,SRENAME   Q.IKJEAI03.                                08619621
         BNE   CHKFLM        NO,CHECK IKJEFLM.                          08624521
         ST    R0,TSCVTI03   YES,PUT IKJEAI03 EP IN TSCVT.              08629421
         B     NEXTSRE       NEXT SRE.                                  08634321
CHKFLM   EQU   *                                                        08639221
         CLC   FLM,SRENAME   Q.IKJEFLM.                                 08644121
         BNE   CHKT07        NO,CHECK IKJEAT07.                         08649021
         ST    R0,TSCVTFLM   YES,PUT IKJEFLM EP IN TSCVT.               08653921
         B     NEXTSRE       NEXT SRE.                                  08658821
CHKT07   EQU   *                                                        08663721
         CLC   T07,SRENAME   Q.IKJEAT07.                                08668621
         BNE   CHKT05        NO,CHECK IKJEAT05.                         08673521
         ST    R0,TSCVTABN   YES,PUT IKJEAT07 EP IN TSCVT.              08678421
         B     NEXTSRE       NEXT SRE.                                  08683321
CHKT05   EQU   *                                                        08688221
         CLC   T05,SRENAME   Q.IKJEAT05.                                08693121
         BNE   CHKLS3        NO,CHECK IKJEFLS3.                         08698021
         LR    ADEXITRT,R0   YES,SAVE T05 EP ADDR FOR LATER ATTACH.     08702921
         B     NEXTSRE       NEXT SRE.                                  08707821
CHKLS3   EQU   *                                                        08712721
         CLC   LS3,SRENAME   Q.IKJEFLS3.                                08717621
         BNE   CHKQT0        NO,CHECK IKJGGQT0.                         08722521
         ST    R0,TSCVTLS3   YES,PUT IKJEFLS3 EP IN TSCVT.              08727421
         B     NEXTSRE       NEXT SRE.                                  08732321
CHKQT0   EQU   *                                                        08737221
         CLC   QT0,SRENAME   Q.IKJGGQT0.                                08742121
         BNE   CHKQT1        NO,CHECK IKJGGQT1.                         08747021
         L     R6,CVTABEND   R6=2NDARY CVT ADDR.                        08751921
         USING SCVTSECT,R6   ADDRESSABILITY.                            08756821
         L     R5,SCVTSVCT   R5=SVC TABLE ADDR.                         08761721
         ST    R0,DISPL1(R5) INITIALIZE QTIP SVC TABLE ENTRY.           08766621
         B     NEXTSRE       NEXT SRE.                                  08771521
CHKQT1   EQU   *                                                        08776421
         CLC   QT1,SRENAME   Q.IKJGGQT1.                                08781321
         BNE   CHKDRVR       NO,CHECK D02 & D03.                        08786221
         BNE   NEXTSRE       NO,END OF SPECIAL PROCESSING.              08791121
         ST    R0,TSCVTQTP   YES,PUT QTIP BRANCH ENTRY ADDR IN TSCVT.   08796021
         B     NEXTSRE       NEXT SRE.                                  08800921
CHKDRVR  EQU   *                                                        08805821
         CLC   DRVNAME(SIX),SRENAME Q.D02 OR D03.                       08810721
         BNE   NEXTSRE       CHECK NEXT SRE.                            08815621
         CLC   DRVCD2(TWO),SRENAME+SIX Q.D02.                           08820521
         BNE   CHKD03        NO,CHECK D03.                              08825421
         ST    R0,TSCVTD02   YES,PUT D02 ADDR IN TSCVT.                 08830321
         B     NEXTSRE       CHECK NEXT SRE.                            08835221
CHKD03   EQU   *                                                        08840121
         CLC   DRVCD3(TWO),SRENAME+SIX Q.D03.                           08845021
         BNE   NEXTSRE       CHECK NEXT SRE.                            08849921
         ST    R0,TSCVTD03   YES,PUT D03 ADDR IN TSCVT.                 08854821
         B     NEXTSRE       CHECK NEXT SRE.                            08859721
T04      DC    CL8'IKJEAT04'                                            08864621
T08      DC    CL8'IKJEAT08'                                            08869521
L00      DC    CL8'IKJEAL00'                                            08874421
I00      DC    CL8'IKJEAI00'                                            08879321
I01      DC    CL8'IKJEAI01'                                            08884221
I02      DC    CL8'IKJEAI02'                                            08889121
I03      DC    CL8'IKJEAI03'                                            08894021
FLM      DC    CL8'IKJEFLM'                                             08895021
T07      DC    CL8'IKJEAT07'                                            08900021
T05      DC    CL8'IKJEAT05'                                            08905021
LS3      DC    CL8'IKJEFLS3'                                            08910021
QT0      DC    CL8'IKJGGQT0'                                            08915021
QT1      DC    CL8'IKJGGQT1'                                            08920021
         SPACE 4                                                        08925021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       08930021
PARMEND  L     ADTSLPA,TCBJPQ      GET ADR OF JPQ OF TS MODULES         09030020
         ST    ADTSLPA,TSCVTLPA    PUT ADR IN TSCVT                     09040020
         LTR   R1,R1               ARE THERE ANY CDE'S                  09060020
         BZ    T02RMS              NO BR TO CONTINUE                    09070021
CDELOOP  OI    ZERO(R1),ATTRBIT    SET BITS INDICATING LOAD BY NIP      09080020
*                                  REENTRANT AND REUSEABLE              09081020
         L     R1,ZERO(R1)         GET PTR TO NEXT CDE                  09090020
         LA    R1,ZERO(R1)         CLEAR HI ORDER BYTE                  09100020
         LTR   R1,R1               ARE THERE ANY MORE CDE'S             09110020
         BNZ   CDELOOP             YES BRANCH                           09111020
         DROP  R7                  DROP USING ON TCB DSECT              09120020
         EJECT                                                          09920020
**********************************************************************  09930020
*                                                                    *  09940020
* THIS SECTION GETMAINS AN AREA IN SQS FOR RMS CONTROL BLOCKS.THERE  *  09950020
* IS A RECOVERY EXTENT LIST(RXL),AND RECOVERY EXTENT LIST QUEUE      *  09960020
* ELEMENTS,- ONE FOR TSC REGION,TCAM REGION AND EACH USER REGION-    *  09970020
* (RXLQ).EACH ELEMENT POINTS TO NEXT ELEMENT ON QUEUE.               *  09980020
*                                                                    *  09990020
**********************************************************************  10000020
         SPACE 3                                                        10010020
T02RMS   EQU   *                                                        10012020
         L     R1,TWKBLKAD         GET ADR REMAINING 2K BLK       M7635 10014021
         LA    R0,FETCHAR2         GET LENGTH                     M7635 10016021
         O     R0,SP252            INDICATE SP 252                M7635 10018021
         FREEMAIN R,LV=(0),A=(1)  FREE AREA                       M7635 10018421
         LA    R5,LRXLQ            GET LENGTH RXLQ                      10020020
         MH    R5,FRTEEN(PARMLST)  MULT BY NO. REGIONS FOR USER         10030020
         LA    R7,LRXL             GET LENGTH OF RXL                    10040020
         AR    R5,R7               ADD TO AMT NEEDED FOR RMS CNTRL BLKS 10050020
         LA    R7,LRXLQ            GET LENGTH OF RXLQEN                 10060020
         AR    R5,R7               ADD L OF RXLQE FOR TSC               10070020
         AR    R5,R7               ADD AMT FOR ELEM FOR TCAM REGION     10080020
         LR    R0,R5               INITIALIZE REG0 WITH LENGTH          10090020
         O     R0,SP253            INDICATE SQS -SP 253                 10100020
         SPACE                                                          10110020
         GETMAIN R,LV=(0)          GETMAIN AN AREA                      10120020
         LR    R7,R1               SAVE PTR TO AREA                     10130020
         SPACE                                                          10140020
EXLOOP3  CH    R5,N256             IS LENGTH GR TH 256 BYTES            10150020
         BH    MOVE3               YES-BRANCH AND CLEAR 256 BYTES       10160020
         BCTR  R5,ZERO             DECREMENT LENGTH BY ONE              10170020
         EX    R5,CLEARAR          CLEAR REMAINING AREA                 10180020
         SPACE                                                          10190020
         ST    R1,SCVTRXLQ         PUT ADR OF RXL IN SCVT               10200020
         USING RXL,R1              SET UP RXL DSECT                     10210020
         MVC   RXLTSLPA(FOUR),TSCVTLPA PUT ADR TS LINK PK AREA QUEUE    10220020
*                                  IN RXL                               10230020
         LR    R8,R1               SAVE PTR TO RXL                      10240020
         LA    R8,LRXL(R8)         GET ADR OF FIRST RXL QU ELEM         10250020
         ST    R8,RXLRXLQ          PUT ADR IN RXL                       10260020
         LA    R1,RXLEND           UPDATE PTR TO NXT CNTRL BLK          10270020
         DROP  R1                  DROP USING ON RXL                    10280020
         SPACE                                                          10290020
         USING RXLQE,R1            SET UP RXLQE DSECT                   10300020
         L     R5,TSCVTTSC         GET ADR TSC'S TCB                    10310020
         ST    R5,RXLQCBLK         PUT ADR TSC'S TCB IN ITS RXLQ        10320020
         MVI   RXLQFLG1,TSCACTV    SET BITS INDICATING THIS RXLQ HAS    10330020
*                                  INFO ABT TSC REGION AND IT IS ACTIVE 10340020
         USING TCB,R5              SET UP TCB DSECT                     10350020
         BAL   R7,RXLQINIT         BR TO INIT RXLQ                      10360020
         SPACE                                                          10370020
         L     R5,CVTAQAVT         GET  PTR TO ADR TCAM VECTOR TABLE    10380020
         L     R5,EIGHT(R5)        GET ADR TCAM'S TCB                   10382020
         LA    R5,ZERO(R5)         CLEAR HI ORDER BYTE                  10384020
         ST    R5,RXLQCBLK         PUT ADR TCAM'S TCB IN ITS RXLQ       10420020
         MVI   RXLQFLG1,TCMACTV    SET BITS INDICATING THIS RXLQ HAS    10430020
*                                  INFO ABT TCAM REGION AND IT IS ACTIV 10440020
         USING TCB,R5              SET UP TCB DSECT                     10460020
         BAL   R7,RXLQINIT         INITIALIZE TCAM'S RXLQ               10470020
         SPACE                                                          10480020
         ST    R8,RCTRXLQ          SAVE ADR OF FIRST USER REG RXLQ      10490020
         LH    R7,FRTEEN(PARMLST)  GET NUMBER REGIONS                   10500020
         BCTR  R7,ZERO             DECREMENT NUMBER OF REGIONS BY ONE   10510020
         LTR   R7,R7               IS THERE ONLY ONE REGION             10520020
         BZ    RXLQLAST            YES BRANCH AND SET USER REG BIT      10530020
RXLQNXT  MVI   RXLQFLG1,RXLQFRCT   SET BIT INDICATING THIS EQ ELEM HAS  10540020
*                                  INFO ABT USER REGION                 10550020
         LA    R8,LRXLQ(R8)        GET ADR NEXT USER QU ELEMENT         10560020
         ST    R8,RXLQRXLQ         PUT ADR IN PRES USER RXQL            10570020
         LA    R1,RXLQEND          UPDATE PTR TO NEXT RXQL              10580020
         BCT   R7,RXLQNXT          DECREMENT NUMBER REGIONS BY ONE-BR   10590020
RXLQLAST MVI   RXLQFLG1,RXLQFRCT   FOR LAST RXLQ ON CHAIN JUST SET      10600020
*                                  BIT INDICATING IT IS FOR USER REGION 10610020
         B     RCBPROC             BRANCH                               10620020
         SPACE                                                          10630020
MOVE3    LA    R8,TWFTYFIV         GET LENGTH=255                       10640020
         EX    R8,CLEARAR          CLEAR 256 BYTES                      10650020
         LA    R7,TWFTYSIX(R7)     UPDATE PTR TO AREA BY 256            10660020
         SH    R5,N256             SUBTRACT 256 BYTES FR LENGTH OF AR   10670020
         B     EXLOOP3             BRANCH                               10680020
         SPACE                                                          10690020
RXLQINIT L     R5,TCBPQE           GET ADR DUMMY PQE                    10700020
         DROP  R5                  DROP USING ON TCB                    10710020
         USING PQESECT,R5          SET UP PQE DSECT                     10720020
         L     R5,PQEFPQE          GET ADR PQE                          10730020
         L     R9,PQEREGN          GET BEG ADR OF TSC REGION            10740020
         ST    R9,RXLQRGLO         STORE ADR IN RXLQ                    10750020
         A     R9,PQESIZE          ADD TO BEG ADR THE SIZE TSC REGION   10760020
         ST    R9,RXLQRGHI         STORE END ADR IN RXLQ                10770020
         LA    R8,LRXLQ(R8)        GET ADR NEXT RXLQ                    10780020
         ST    R8,RXLQRXLQ         STORE ADR IN TSC RXLQ                10790020
         LA    R1,RXLQEND          UPDATE PTR TO NEXT RXLQ              10800020
         DROP  R5                  DROP USING ON PQE                    10810020
         BR    R7                  RETURN                               10820020
         EJECT                                                          10830020
**********************************************************************  10840020
*                                                                    *  10850020
* THIS SECTION SEARCHES THROUGH THE RCB'S FOR THE ACTIVE RCB'S.AN RCB   10860020
* IS DESIGNATED ACTIVE IF IT HAS A REGION SIZE AND AN LSQS SIZE      *  10870020
* ASSOCIATED WITH IT. IF THE RCB IS ACTIVE WE BRANCH TO ATTACH AN    *  10880020
* RCT.UPON RETURN FROM ATTACH WE PUT THE ADDRESS OF THE ATTACHED     *  10890020
* RCT IN THE RCB, AND SEARCH FOR THE NEXT RCB. IF THE RCB IS NOT     *  10900020
* ACTIVE WE JUST UPDATE THE POINTER TO THE NEXT RCB ON THE CHAIN,    *  10910020
* AND CONTINUE THE RCB PROCESSING.                                   *  10920021
*                                                                    *  10940020
**********************************************************************  10950020
         SPACE 3                                                        10960020
RCBPROC  EQU   *                                                        10970020
         DROP  R1                  DROP USING ON RXLQE                  10980020
         DROP  R6                  DROP USING ON SCVT                   10990020
         L     RCBAD,TSCVTRCB      GET ADDR RCB TABLE                   11000020
         LH    NMRCB,FRTEEN(PARMLST) GET NUMBER OF RCB'S                11010020
         L     R9,TWTYEIGT(PARMLST) GET ADDRESS TSC TABLE               11012020
         LA    R9,TWTYEIGT(R9)     ADR OF REG AND LSQS SZE FOR 1ST REG  11014020
         USING RCB,RCBAD           SET UP RCB DSECT                     11020020
NXTRCB   LH    SIZERCB,RCBRSIZE    IF AN RCB SIZE IS SPECIFIED IT IS AC 11030020
         LTR   SIZERCB,SIZERCB     IS RCB ACTIVE                        11040020
         BNZ   ATTRCB              YES-BRANCH TO ATTACH                 11050020
MORERCB  LA    RCBAD,RCBEND        GET NEXT RCB                         11060020
         LA    R9,FOUR(R9)         UPDTE TO NXT REG SZ ENTRY IN TSC TAB 11062020
         BCT   NMRCB,NXTRCB        DECREASE CT OF RCB'S BY ONE          11070020
         B     T02SMF              CONTINUE INITIALIZATION              11070820
RCBPROC1 LH    SIZERCB,RCBRSIZE    GET SIZE REGION JUST ATTACHED        11071220
         LTR   SIZERCB,SIZERCB     HAS IT BEEN ZEROED                   11071620
*                                  IF RCT INIT COULD NOT GETPART        11072120
*                                  THE REGION THE SIZE IS ZEROED FROM   11072220
*                                  THE RCB SO IT WILL NOT APPEAR IN     11072320
*                                  THE SMF RECORD AS AN ACTIVE REGION   11072720
         BNZ   MORERCB             NO GET NEXT RCB                      11072820
         XC    ZERO(FOUR,R9),ZERO(R9) CLEAR THE RCT SIZE IN THE TSC     11073220
*                                  TABLE- SO IT WILL NOT GO INTO THE    11074020
*                                  SMF RECORD                           11074420
         B     MORERCB             GET NEXT RCB                         11074820
         EJECT                                                          11077221
*****  FOR EACH ACTIVE RCB WE ATTACH AN RCT ASSOCIATED WITH IT    ****  11077621
         SPACE 3                                                        11078021
ATTRCB   MVC   LISTMAC(LATT),ATTLIST MVE LIST FORM OF ATTACH            11078421
         LA    R15,LISTMAC         GET ADR OF LIST                      11078521
         L     TSCECBAD,TSCVTECB   GET ADR ECB FOR TSC                  11078621
         MVI   ZERO(TSCECBAD),ZERO CLEAR HI ORDER BYTE OF ECB           11078721
         LR    R1,RCBAD            PASS ADR RCB IN REG1                 11079621
         ATTACH EP=IKJEAR00,ETXR=(ADEXITRT),LPMOD=2,                   X11080021
               ECB=RCBDIECB,DPMOD=-2,SM=SUPV,SF=(E,(15))                11080421
         ST    R1,RCBRCT           SVE ADR ATTACHED TCB IN RCB          11081221
         WAIT  ONE,ECB=(TSCECBAD)  WAIT UNTIL ECB IS POSTED             11081321
         B     RCBPROC1            GET MORE RCB'S IF THERE ARE ANY      11081421
         EJECT                                                          11081521
*********************************************************************   11081621
*  THIS SECTION GETMAINS AN AREA FOR THE SMF RECORD AND INITIALIZES *   11097321
*  IT. IT THEN ISSUES THE SMF WRITER MACRO FOR RECORD 30. IT        *   11097421
*  THEN FREES THE RECORD.                                           *   11097521
*                                                                   *   11097621
*********************************************************************   11097721
         SPACE 4                                                        11098021
T02SMF   EQU   *                                                        11098321
         L     R5,CVTSMCA          GET ADDR OF SYS MGMT CTRL AREA       11098621
         LTR   R5,R5               IS IT ZERO                           11098921
         BZ    FREEPARM            YES-BRANCH AROUND SMF PROCESSING     11099221
         SPACE                                                          11099521
         L     TSCTABAD,TWTYEIGT(PARMLST) GET ADR TSC TABLE             11099821
         USING SMCABASE,R5         SET UP IEESMCA DSECT                 11100121
         MVC   SMCAFOPT(ONE),EIGTN(TSCTABAD)   SET SMF OPTION           11100421
         OI    SMCAFOPT,SMCAFGND   SET FOREGROUND BIT ON                11100721
         LA    R8,LTSREC           GET LENGTH OF FIXED PRT OF REC 30    11101021
         LA    R1,FIVE             GET LEN OF EACH ENTRY FOR A REG      11101321
         MH    R1,FRTEEN(PARMLST)  MULT LEN OF ENTRY BY NUM OF REG      11101621
         AR    R8,R1               ADD TO FIXED LENGTH                  11101921
         LA    R8,ONE(R8)          INCREMENT BY ONE BYTE                11102221
         LR    R0,R8               PUT LEN IN REG0 FOR GETMAIN          11102521
         O     R0,SP251            INDICATE SP 251                M7635 11102821
         SPACE                                                          11103121
         GETMAIN R,LV=(0)          GETMAIN AREA FOR SMF REC30           11103421
         BCTR  R8,ZERO             DECREMENT LENGTH BY ONE              11103721
         EX    R8,CLEAR1           ZERO OUT THE AREA                    11104021
         LA    R8,ONE(R8)          RESTORE LENGTH OF RECORD             11104321
         SPACE                                                          11104621
         USING TSTSMF,R1           SET UP IFASMFR 30 DSECT              11104921
         STH   R8,TSTRLEN          SAVE RECORD LENGTH IN RECORD         11105221
         MVI   TSTRCDTY,SMFREC30   PUT RECORD TYPE=30 IN RECORD         11105521
         MVC   TSTMBR(EIGHT),TWTY(TSCTABAD) SVE MEMBER OF PARMLIB       11105821
         MVC   TSTSMFOP(ONE),SMCAFOPT SVE FOREGRND OPTION IN REC        11106121
         DROP  R5                  DROP USING ON IEESMCA                11106421
         L     R7,TSCVTTSC         GET ADR OF TSC'S TCB                 11106721
         USING TCB,R7              SET UP TCB DSECT                     11107021
         L     R5,TCBTIO           GET ADR TASK I/O TABLE               11107321
         MVC   TSTSPROC(SXTN),ZERO(R5) SVE TS PROC NAME AND TASK        11107621
*                                  ID IN RECORD                         11107921
         MVC   TSTNRGNF(ONE),FIFTN(PARMLST) SVE MAX NUM REGIONS         11108221
         MVC   FRTEEN(TWO,TSCTABAD),DRVCD0 PUT DRVR ID IN NAME          11108521
         MVC   TSTDSPCH(EIGHT),EIGHT(TSCTABAD) SVE TS DRIVER NAME       11108821
         MVC   TSTTRMS(TWO),TWO(PARMLST) SAVE MAX NUMB OF TERMINALS     11109121
         L     R5,TCBPQE           GET ADR TSC'S PQE                    11109421
         USING PQESECT,R5          SET UP PQE DSECT                     11109721
         DROP  R7                  DROP USING ON TCB                    11110021
         L     R5,PQEFPQE          GET NEXT PQE AFTER DUMMY PQE         11110321
         L     R5,PQESIZE          GET REG SIZE FOR TSC IN BYTES        11110621
         SRL   R5,ELEVEN           CHG SIZE TO 2K BLOCKS                11110921
         STH   R5,TSTTSC           PUT TSC REG SIZE IN RECORD           11111221
         DROP  R5                  DROP USING ON PQE                    11111521
         LR    R15,R8              GET LENGTH OF RECORD                 11111821
         LA    R7,LTSREC           GET LEN OF FIXED PRT OF RECORD       11112121
         SR    R15,R7              GET VARIABLE LENGTH OF RECORD        11112421
         LA    R15,TWO(R15)        ADD TWO BYTES TO VARIABLE LEN        11112821
         STH   R15,TSTVAR          SVE VARIABLE LEN IN RECORD           11113221
         MVC   TSTRGNF(ONE),FIFTN(PARMLST) PUT NUM ENTRIES IN REC       11113621
*                                  NUM ENTRIES=NUM MAX REGIONS          11114021
         LH    R5,FRTEEN(PARMLST)  GET MAX NUMB OF REGIONS              11114421
         LA    R7,ONE              INIT COUNT FOR EACH REG ENTRY        11114821
         LA    R15,THRTYTW(TSCTABAD) GET ADR OF REG AND LSQS SIZ A51700 11115221
*                                  FOR EACH REGION                      11115621
         LR    R9,R1               SAVE ADR OF SMF RECORD               11116021
SMFLOOP  MVC   TSTRGSIZ(TWO),ZERO(R15) PUT REGN SIZ IN REC ENTRY        11116421
         MVC   TSTLSSIZ(TWO),TWO(R15) PUT LSQS SIZE FOR THIS REG IN     11116821
*                                  RECORD ENTRY                         11117221
         STC   R7,TSTREGNM         PUT REG NUM IN REC ENTRY             11117621
         LA    R1,FIVE(R1)         UPDATE PTR TO NEXT ENTRY             11118021
         LA    R7,ONE(R7)          UPDATE CT FOR REGION NUMB            11118421
         LA    R15,FOUR(R15)       UPDTE PTR TO NEXT REG SIZE           11118821
         BCT   R5,SMFLOOP          DECREMENT REG NUMB COUNT- BRANCH     11119221
         LR    R1,R9               GET ADR SMF RECORD                   11119621
         SPACE                                                          11120021
         SMFWTM (1)                ISSUE SMF WRITER MACRO               11120421
         LR    R1,R9               RESTORE ADR SMF RECORD FOR FREEMAIN  11120821
         LR    R0,R8               GET LENGTH OF RECORD                 11121221
         O     R0,SP251            INDICATE SP 251                M7635 11121621
         SPACE                                                          11122021
         FREEMAIN R,LV=(0),A=(1)   FREE SMF RECORD                      11122421
         EJECT                                                          11122821
**********************************************************************  11123221
*                                                                    *  11123621
* THIS SECTION FREES THE PARM DATA,PARM LIST AND TSC TABLE.          *  11124021
*                                                                    *  11124421
**********************************************************************  11124821
         SPACE 2                                                        11125221
FREEPARM LR    R1,PARMLST          GET ADDR PARMLST                     11125621
         LH    R0,THRTYTWO         GET LENGTH PARMLST                   11126021
         A     R0,THRTYTW(PARMLST) ADD LENGTH OF TSC TABLE              11126421
         A     R0,FOUR(PARMLST)    ADD LENGTH OF PARM DATA              11126821
         O     R0,SP254            SUBPOOL 254 IN HI BYTE               11127221
         FREEMAIN R,LV=(0),A=(1)   FREE PARM LIST                       11127621
         SPACE 3                                                        11128021
****** THIS SECTION WE FREE UP OUR WORK AREA AND XCTL TO IKJEAT03. **** 11128421
         SPACE 2                                                        11128821
         LA    R0,LWKAREA          GET LENGTH OF WORK AREA              11129221
         LR    R1,R13              GET ADR OF WORK AREA                 11129621
         L     SYSSAVE,FOUR(R13)   RESTORE REG13 TO ADR SYST SAVE AREA  11130020
         O     R0,SP254            SUBPOOL 254 IN HI BYTE               11135020
         FREEMAIN R,LV=(0),A=(1)   FREE WORK AND SAVE AREA              11140020
         SPACE 2                                                        11142020
         XCTL  (2,12),EP=IKJEAT03  XCTL TO IKJEAT03                     11150020
         EJECT                                                          11320020
*********************************************************************** 11330020
*                                                                     * 11340020
*                                 CONSTANTS                           * 11350020
*                                                                     * 11360020
*********************************************************************** 11370020
         SPACE                                                          11380020
         DS    0F                  ALIGN ON FULL WORD BOUNDARY          11410020
SP251    DC    X'FB000000'         SUBPOOL 251 IN HI ORDER BYTE   M7635 11414421
SP252    DC    X'FC000000'         SUBPOOL 252 IN HI ORDER BYTE         11415020
SP253    DC    X'FD000000'         SUBPOOL 253 IN HI ORDER BYTE         11420020
SP254    DC    X'FE000000'         SUBPOOL 254 IN HI ORDER BYTE         11430020
         DS    0H                  ALIGN ON HALF WORD BOUNDARY          11450020
N256     DC    H'256'              LENGTH OF 256 FOR EX INSTRUCTION     11460020
THRTYTWO DC    H'32'               LENGTH OF PARM LIST                  11480020
DRVCD0   DC    X'F0F0'             DRIVER MODULE ID=00                  11490020
DRVCD1   DC    X'F0F1'             DRIVER MODULE ID=01                  11500020
DRVCD2   DC    X'F0F2'             DRIVER MODULE ID=02                  11510020
DRVCD3   DC    X'F0F3'             DRIVER MODULE ID=03                  11520020
TSOMODS  DS    0F                  ALIGN ON FULL WORD BOUNDARY          11530020
         DC    C'IKJEAR00'         RCT INITIALIZATION MODULE            11540020
         DC    C'IKJEAR01'         RCT MAINLINE MODULE                  11550020
         DC    C'IKJEAT06'         TSC MODIFY MODULE                    11560020
TSOEND   EQU   *                   END OF TSO MODULE TABLE              11570020
**********                    LPA BLDL AREA/FLAGS      **************   11571020
LPABLDL  DS    0D                  LPA BLDL                             11572020
         DC    H'1'                ONE BLDL                             11573020
         DC    H'58'               FOR 58 BYTES                         11574020
LPABNAME DS    8C                  MODULE NAME                          11575020
LPABDATA DS    50C                 MODULE DATA                          11576020
LPABATTR EQU   LPABNAME+22         ATTRIBUTES FIELD                     11577020
LPABRENT EQU   X'80'               'RENT' FLAG                          11578020
LPABREUS EQU   X'40'               'REUS' FLAG                          11579020
         EJECT                                                          11580020
**********                  LIST FORM OF MACROS              ********** 11590020
         SPACE 2                                                        11600020
LINKLIST LINK  SF=L                LIST FORM OF LINK                    11610020
LLINK    EQU   *-LINKLIST          LENGTH OF LIST FORM OF LINK          11620020
         SPACE 5                                                        11630021
WTO1     WTO   'IKJ015I THE TIME SHARING SYSTEM CANNOT BE INITIALIZED',C11640020
               DESC=5,MCSFLAG=(REG0),MF=L                               11650020
WTO1L    EQU   *-WTO1              LENGTH OF MESSAGE                    11660020
         EJECT                                                          11670020
ATTLIST  ATTACH ROLL=(NO,NO),SF=L  LIST FORM OF ATTACH                  11680020
LATT     EQU   *-ATTLIST           LENGTH OF LIST FORM OF ATTACH        11690020
         SPACE 3                                                        11700020
STAELIST STAE  MF=L                LIST FORM OF STAE                    11710020
LSTAE    EQU   *-STAELIST          LENGTH OF LIST FORM OF STAE          11720020
         SPACE 3                                                        11730020
**********                   CONSTANT INSTRUCTIONS           ********** 11740020
         SPACE 2                                                        11750020
CLEARAR  XC    ZERO(ZERO,R7),ZERO(R7)      CLEAR AREA                   11760020
CLEAR1   XC    ZERO(ZERO,R1),ZERO(R1)      CLEAR AREA                   11800020
         END                                                            11810020
