         TITLE 'IKJEAT03  TSO/TSC MAIN LINE'                            00020020
IKJEAT03 START                                                          00030020
         EXTRN IKJEASSS,IKJEASSE   SWAP START/END                       00040020
         EXTRN IKJGG008            TIOC DISCONNECT                      00050020
*********************************************************************** 00060020
*STATUS- =0                                                      20025* 00070020
*A040220-040240,070270-070290                                   A44363* 00072021
*A018110-018150,024900,025340-025360,025400,025440-025880,      A44022* 00074021
*027804,032340-032830,033820,038920-039030,047440-047820,       A44022* 00076021
*A048400-049000,051610-051675,057340,057640-057660,058800,      A44022* 00078021
*A059560-059720,060500,060640,062760,063010,063620,063670-063690,     * 00078421
*A066110-066205,066300,066320-066340,066804,066814-066816,      A44022* 00078821
*A067140-067160,                                                A44022* 00079221
*A025920-025980,033860,054797,063710-063720,066808-066810       A42839* 00079621
*A041520                                                         M2572* 00082221
*                                                                     * 00084821
*FUNCTION-TSO/TSC MAIN CONTROL MODULE.  CONTAINS THESE ROUTINES:      * 00087421
*        IKJEAT03       FINAL INITIALIZATION                          * 00090020
*        IKJEATML       TSC MAINLINE CONTROL                          * 00100020
*        IKJEATLG       TSC LOGON                                     * 00110020
*        IKJEATDC       TSC DISCONNECT PREAMBLE                       * 00120020
*        IKJEATST       TSO/TSC TERMINATION                           * 00130020
*        IKJEATUR       USER REGION STOP, START, AND STOP/START       * 00140020
*     IKJEAT0A        MODIFY/STOP SUBTASK ETXR                          00145020
*                                                                     * 00150020
*        FINAL INITIALIZATION OF TSO.                                 * 00160020
*        ATTACHES TSC SUBTASK(IKJEAT06) TO HANDLE STOP/MODIFY TSO     * 00170020
*        LOADS QTIP(IKJGGQT0 AND IKJGGQT1).                           * 00175020
*        CREATE LOGON IMAGE FOR EACH REGION ACTIVE AT START TSO BY    * 00180020
*        CAUSING RCT QUIESCE AND SWAP OUT.  SET TSO READY FLAG IN CVT.* 00190020
*        ISSUE TSEVENT(SPRGNSZ) FOR EACH ACTIVE REGION.               * 00200020
*                                                                     * 00210020
*        TSC MAINLINE CONTROL.                                        * 00220020
*        WAITS ON TSCECB.  WHEN POSTED DETERMINES THE                 * 00230020
*        REQUIRED FUNCTION BY TESTING BITS IN TSCVTFLG:               * 00240020
*             TSCSWPND  -  INVOKE SWAP END(IKJEASSE/IKJEAS02)         * 00250020
*             TSCSWPBG  -  INVOKE SWAP START(IKJEASSS/IKJEAS02)       * 00260020
*             TSCLOGON  -  INVOKE TSC LOGON(IKJEATLG/IKJEAT03)        * 00270020
*             TSCDISC   -  INVOKE TSC DISCONNECT PREAMBLE             * 00280020
*                                             (IKJEATDC/IKJEAT03)     * 00290020
*                          INVOKE TIOC DISCONNECT(IKJGG008/IKJGG008)  * 00300020
*                                                                     * 00310020
*        REQUIRED FUNCTION BY TESTING BITS IN TSCVTFL1:               * 00320020
*             TSCSSTOP  -  INVOKE TSO STOP(IKJEATST/IKJEAT03)         * 00330020
*             TSCRSTOP  -  INVOKE REGION START/STOP(IKJEATUR/IKJEAT03)* 00340020
*             TSCASTOP  -  TERMINAL ACCESS HAS FAILED, POST TSCECB1   * 00350020
*                          TO INITIATE STOP TSO SEQUENCE.             * 00360020
*                                                                     * 00370020
*        TSC LOGON ROUTINE.                                           * 00380020
*        SCAN TJB'S FOR TJBLOGON BIT SET. DETERMINES:                 * 00390020
*        LOGON - ISSUES TSEVENT(REQRGNID AND LOGON) TO HAVE THE DRIVER* 00400020
*        SELECT AND CONNECT A USER TO A REGION.                       * 00410020
*        RE LOGON - ISSUES TSEVENT(REQGNID AND LOGON) TO HAVE DRIVER  * 00420020
*        CONNECT A USER TO A SPECIFIC REGION.                         * 00430020
*        FOR LOGON RETRY, ISSUE TSEVENT CYCLE 10 TIMES. FOR RETRY     * 00440020
*        FAIL, FORCE DISCONNECT OF USER.                              * 00450020
*        SUCCESSFUL LOGON. CONNECT LOGON IMAGE TO TJB AND ISSUE       * 00460020
*        TSEVENT(USERRDY)                                             * 00470020
         EJECT                                                          00480020
*        TSC DISCONNECT PREAMBLE                                      * 00490020
*        SCAN TJB'S FOR TJB DISCONNECT FLAG(TJBDISC) AND DECREMENT    * 00500020
*        THE CORRESPONDING RCB CURRENT USERS COUNT(RCBCUSE).          * 00510020
*                                                                     * 00520020
*        TSO STOP.                                                    * 00530020
*        FOR STOP TSO OPERATOR COMMAND, THE TSC SUB TASK(IKJEAT06)    * 00540020
*        HAS RECEIVED THE COMMAND, INITIATED THE STOP TSO SEQUENCE AND* 00550020
*        TERMINATED ITSELF.  THE TSC MAIN TASK WILL COMPLETE THE      * 00560020
*        STOP SEQUENCE.  WHEN ALL THE USERS ARE LOGGED OFF(TSCVTCUS   * 00570020
*        GOES TO ZERO), POST THE RCTECB TO CAUSE THE RCT'S TO         * 00580020
*        TERMINATE THEMSELVES.                                        * 00590020
*        RESET CVTTSRDY AND CVTTSCVT.                                 * 00600020
*        RESTORE THE SVC TABLE FOR TSIP AND QTIP.                     * 00610020
*        CHAIN TS0 LPA TO TSC JPQ. TERMINATE TSC.                     * 00620020
*                                                                     * 00630020
*        USER REGION STOP/START.                                      * 00640020
*        FOR MODIFY TSO OPERATOR COMMAND, THE TSC SUB TASK(IKJEAT06)  * 00650020
*        HAS RECEIVED THE COMMAND AND REQUIRES THAT THE MAIN TSC TASK * 00660020
*             STOP A REGION                                           * 00670020
*             START A REGION                                          * 00680020
*             STOP/START A REGION                                     * 00690020
*        TO STOP, FORCE TERMINATION OF THE RCT.                       * 00700020
*        TO START A REGION, ATTACH THE RCT AND CREATE A LOGON IMAGE   * 00710020
*                                                                     * 00720020
*ENTRY POINTS-IKJEAT03                                                * 00730020
*                                                                     * 00740020
*INPUT-  REG   13   ADDR. OF SAVE AREA                                * 00750020
*        REG   14   RETURN ADDR.                                      * 00760020
*        REG   15   ENTRY POINT ADDR.  IKJEAT03                       * 00770020
*                                                                     * 00780020
* ENTRY POINT - IKJEAT0A                                                00781020
* INPUT - REG 1    ADDR OF IKJEAT06                                     00782020
*         REG 13   ADDR OF SAVE AREA                                    00783020
*         REG 14   RETURN ADDR                                          00784020
*         REG 15   ADDR OF EP - IKJEAT0A                                00785020
*                                                                       00786020
*OUTPUT- NONE                                                         * 00790020
         EJECT                                                          00800020
*EXTERNAL REFERENCES-                                                 * 00810020
*        IKJEASSS                  SWAP START                         * 00820020
*        REG   13   ADDR. OF SAVE AREA                                * 00830020
*        REG   14   RETURN ADDR.                                      * 00840020
*        REG   15   ENTRY POINT ADDR.  IKJEASSS                       * 00850020
*                                                                     * 00860020
*        IKJEASSE                  SWAP END                           * 00870020
*        REG   13   ADDR. OF SAVE AREA                                * 00880020
*        REG   14   RETURN ADDR.                                      * 00890020
*        REG   15   ENTRY POINT ADDR.  IKJEASSE                       * 00900020
*                                                                     * 00910020
*        IKJGG008                  TIOC DISCONNECT                    * 00920020
*        REG   13   ADDR. OF SAVE AREA                                * 00930020
*        REG   14   RETURN ADDR.                                      * 00940020
*        REG   15   ENTRY POINT ADDR.  IKJGG008                       * 00950020
*                                                                     * 00960020
*        IKJEAT06                  TSC SUB TASK                       * 00970020
*         ATTACH SF=(E,(15)),EPLOC=T06NAME,LPMOD=1,ECB=TSCECB2,       * 00976020
*                ETXR=IKJEAT0A,SM=SUPV                                * 00982020
*                                                                     * 00990020
*        IKJEAR00                  RCT                                * 01000020
*        ATTACH EP=IKJEAR00,SM=SUPV,ETXR=IKJEAT05,ECB=RCBDIECB        * 01010020
*        REG   1    ADDR. OF RCB.                                     * 01020020
*                                                                     * 01030020
*        GETMAIN/FREEMAIN/LOAD/DELETE/ATTACH                          * 01040020
*                                                                     * 01050020
*        TSEVENT                                                      * 01060020
*                                                                     * 01070020
*EXIT-   RETURN TO CALLER(SYSTEM CONTROL TASK) AT TERMINATION OF TSO  * 01080020
*                                                                     * 01090020
*EXIT,ERROR-IKJEAT04(STAE EXIT ROUTINE) IF TSC TASK ABENDS.           * 01100020
*                                                                     * 01110020
*TABLES/CONTROL BLOCKS/WORK AREAS-                                    * 01120020
*                                                                     * 01130020
*        CVT, SCVT, TCB,                                              * 01140020
*                                                                     * 01150020
*        TSCVT, RCB, TJB, TSB, TSECBTAB, TSSAVE,                      * 01160020
*                                                                     * 01170020
*ATTRIBUTES-RESIDENT IN TSO CONTROL REGION. REFRESHABLE, RE-ENTERANT  * 01180020
*        SUPERVISOR STATE(KEY 0)                                      * 01190020
*                                                                     * 01200020
*CHARACTER CODE DEPENDENCY - THE OPERATION OF THIS MODULE DEPENDS     * 01201020
*        UPON AN INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER    * 01202020
*        SET WHICH IS EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME.    * 01203020
*        THE CODING HAS BEEN ARRANGED SO THAT REDEFINITION OF         * 01204020
*        'CHARACTER' CONSTANTS, BY REASSEMBLY, WILL RESULT IN A       * 01205020
*        CORRECT MODULE FOR THE NEW DEFINTIONS.                       * 01206020
         EJECT                                                          01208020
*NOTES-  FINDS ALL CONTROL BLOCK FROM OS CVT AND TS CVT               * 01210020
*                                                                     * 01220020
*        LINK EDIT WITH IKJEAS02(SWAP) AND IKJGG008(TIOC DISCONNECT)  * 01230020
*                                                                     * 01240020
*        IKJEAT03 CAN NOT ISSUE PRIVILEDGED INSTRUCTIONS(SSM, LPSW)   * 01250020
*                                                                     * 01260020
*        ATTACH'ES IKJEAT06(TSC SUB TASK) AND IKJEAR00(RCT) WITH      * 01270020
*        SM=SUPV TO ALLOW THEM TO ISSUE PRIVILEGED INSTRUCTIONS.      * 01280020
*                                                                     * 01283020
*        USE SUBPOOL 252 FOR ALL GETMAINS.                            * 01286020
*********************************************************************** 01290020
         EJECT                                                          01300020
CVTDSECT DSECT                                                          01310020
         CVT                                                            01320020
         SPACE                                                          01330020
SCVTD    DSECT                                                          01340020
         SCVT                                                           01350020
         SPACE                                                          01360020
         IKJTCB                                                         01370020
         SPACE                                                          01380020
         IKJTSCVT                                                       01390020
         SPACE                                                          01400020
         IKJRCB                                                         01410020
         SPACE                                                          01420020
         IKJTJB                                                         01430020
         SPACE                                                          01440020
         IKJSAVED                                                       01460020
         SPACE                                                          01470020
         IKJECBS                                                        01480020
         EJECT                                                          01490020
***************REGISTER EQUATES                                         01500020
*                                  WORK REGISTERS                       01510020
WR0      EQU   0                   *                                    01520020
WR1      EQU   1                   *                                    01530020
WR2      EQU   2                   *                                    01540020
WR3      EQU   3                   *                                    01550020
WR4      EQU   4                   *                                    01560020
WR5      EQU   5                   *                                    01570020
WR6      EQU   6                   *                                    01580020
WR15     EQU   15                                                       01585020
*                                                                       01590020
TECBR    EQU   7                   TSC ECB ADDR. REGISTER               01600020
TJBR     EQU   8                   TJB ADDR. REGISTER                   01610020
RCBR     EQU   9                   RCB ADDR. REGISTER                   01620020
TSCVTR   EQU   10                  TSCVT ADDR. REGISTER                 01630020
CVTR     EQU   11                  CVT ADDR. REGISTER                   01640020
BASER    EQU   12                  BASE ADDR. REGISTER                  01650020
SAVER    EQU   13                  SAVE AREA ADDR. REGISTER             01660020
RTNR     EQU   14                  RETURN ADDR. REGISTER                01670020
EPR      EQU   15                  ENTRY POINT ADDR. REGISTER           01680020
***************NUMERIC EQUATES                                          01690020
E0       EQU   0                   *                                    01700020
E1       EQU   1                   *                                    01710020
E2       EQU   2                   *                                    01720020
E4       EQU   4                   *                                    01740020
E8       EQU   8                   *                                    01780020
E16      EQU   16                  *                                    01800020
****************GENERAL EQUATES                                         01810020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    01811021
E72      EQU   72                                                       01812021
POSTED   EQU   X'40'                                                    01813021
HIBIT    EQU   X'80'                                                    01814021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       01815021
*                                  BIT SETTINGS                         01820020
ALLFLG   EQU   X'FF'               ALL BITS SET                         01830020
ALLFLAG  EQU   X'FF'               ALL BITS SET                         01840020
*                                  ECB FLAGS                            01860020
ECB7F    EQU   X'7F'               ECB COMPLETION CODE OF 7F            01870020
*                                  SVC NUMBERS/SVC TABLE DISP           01880020
TSIPSVC  EQU   95                  TSIP IS SVC 95                       01890020
TSIPDISP EQU   TSIPSVC*4           DISP IN SVC TABLE TO TSIP            01900020
QTIPSVC  EQU   101                 QTIP IS SVC 101                      01910020
QTIPDISP EQU   QTIPSVC*4           DISP IN SVC TABLE TO QTIP            01920020
*                                                                       01930020
LOGRTCT  EQU   10                  NUMBER OF LOGON RETRIES              01940020
TIOTJOB  EQU   0                                                        01943020
TIOTSTEP EQU   8                                                        01946020
         TITLE 'TSO/TSC FINAL INITIALIZATION'                           01950020
IKJEAT03 CSECT                                                          01960020
*********************************************************************** 01970020
*IKJEAT03 INITIALIZATION:  SAVE THE CALLER'S REGISTERS. ESTABLISH     * 01980020
*ADDRESSABILITY FOR THE ENTIRE MODULE.  GET THE ADDR. OF THE OS CVT   * 01990020
*AND TS CVT.  THESE REGISTERS WILL BE LOADED FOR THE ENTIRE MODULE.   * 02000020
*GET THE ADDRESS OF THE TSC SAVE AREA AND THE TSC ECB.                * 02010020
*********************************************************************** 02020020
         SAVE  (14,12)             SAVE THE CALLER'S REGISTERS          02030020
         BALR  BASER,0             EST. ADDRESSABILITY                  02040020
         USING *,BASER             *                                    02050020
         USING CVTDSECT,CVTR       0S COMMUNICATIONS VECTOR TABLE       02060020
         USING TSCVT,TSCVTR        TS COMMUNICATIONS VECTOR TABLE       02070020
         USING RCB,RCBR            REGION CONTROL BLOCK                 02080020
         USING TJB,TJBR            TERMINAL JOB BLOCK                   02090020
         L     CVTR,CVTPTR         ADDR. OS/CVT                         02100020
         L     TSCVTR,CVTTSCVT     ADDR. TS/CVT                         02110020
         USING TSSAVE,WR1          TSO SAVE AREAS                       02120020
         L     WR1,TSCVTSAV        ADDR. OF TSO SAVE AREAS              02130020
         LA    WR1,TSCSAVE         ADDR. OF TSC SAVE AREA               02140020
         DROP  WR1                 TSO SAVE AREAS                       02150020
         ST    SAVER,E4(WR1)       CHAIN                                02160020
         ST    WR1,E8(SAVER)       SAVE                                 02170020
         LR    SAVER,WR1           AREAS                                02180020
         USING TSECB,TECBR         TSO ECB'S                            02190020
         L     TECBR,TSCVTECB      ADDR. OF TSO ECB'S                   02200020
         MVI   TSCECB1,E0          CLEAR WAIT/POST BITS                 02210020
         LA    TECBR,TSCECB        ADDR. OF TSC ECB                     02220020
         DROP  TECBR               TSO ECB'S                            02230020
TST0     MVI   TSCVTFL1,E0         CLEAR TSC FLAGS(SECONDARY)           02272020
         EJECT                                                          02350020
*********************************************************************** 02360020
*'TIM' ROUTINE  CREATES THE LOGON IMAGES.  WILL SEARCH  RCB'S FOR     * 02370020
*ACTIVE TSO USER REGIONS                                              * 02380020
*********************************************************************** 02390020
TIM0     L     RCBR,TSCVTRCB       ADDR. OF FIRST RCB                   02400020
         LH    WR5,TSCVTCTR        CT. OF RCB'S                         02410020
TIM1     TM    RCBFLG2,RCBACTV     RCB ACTIVE?                          02420020
         BO    TIM3                YES, REGION IS ACTIVE                02430020
*                                  NO, FOR INACTIVE REGION              02440020
         XC    RCBRSIZE(E2),RCBRSIZE ZERO REGION SIZE                   02450020
         XC    RCBLSQSZ(E2),RCBLSQSZ ZERO REGION LSQS SIZE              02460020
TIM2     LA    RCBR,RCBEND         ADDR. OF NEXT RCB                    02470020
         BCT   WR5,TIM1            ANOTHER RCB, YES TO TOP              02480020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    02485021
         B     TRG03         CONTINUE INITIALIZATION                    02490021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       02495021
*********************************************************************** 02500020
*FOR ACTIVE REGION INVOKE CREATE LOGON IMAGE(RCBR-ADDR. OF RCB)       * 02510020
*********************************************************************** 02520020
TIM3     BAL   RTNR,T03LIM         TO CREATE LOGON IMAGE                02530020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    02532021
         TM    TSCVTFL1,TSCLOGPR       IS LOGON PROC TO STOP            02534021
         BO    INITEND       YES, STOP TSO                              02536021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       02538021
         B     TIM2                RESUME RCB SEARCH                    02540020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    02542021
*********************************************************************** 02544021
*SET UP FOR STOP TSO PROCESSING                                         02546021
*********************************************************************** 02548021
INITEND  MVI   E0(TECBR),E0  ZERO TSCECB                                02550021
         MVI   TSCVTFLG,E0   RESET PRINARY FLAGS                        02552021
         OI    TSCVTFL1,TSCSSTOP   SET STOP TSO FLAG                    02554021
         SR     WR5,WR5             *                                   02556021
         STH   WR5,TSCVTCUS         ZERO CURRENT USE COUNT              02558021
         STH   WR5,TSCVTLUS         ZERO USER LIMIT                     02560021
         L     RCBR,TSCVTRCB       GET FIRST RCB ADRS                   02562021
         LH    WR5,TSCVTCTR        GET NUMBER OF RCBS                   02564021
TRG01    TM    RCBFLG2,RCBACTV     IS THIS RCB ACTIVE                   02566021
         BZ    TRG02               NO, GET NEXT RCB                     02568021
         OI    RCBFLG2,RCBSTOP     YES,SET STOP FLAG IN RCB             02570021
TRG02    LA    RCBR,RCBEND         ADRS NEXT POTENTIAL RCB              02572021
         BCT   WR5,TRG01           IF NOT LAST-NOTDONE-BRANCH           02574021
         L     EPR,ATSCRSS         GET ADRS OF STOP TSO RTN             02576021
         LA    RTNR,T03MLEND       SET RETURN TO MAIN WIAT              02578021
*                                  (WHICH SHOULD NOT BE ENTERED)        02580021
         BR     EPR                 GO TO STOP PROCESSONG               02582021
TRG03    EQU   *                   CONTINUE NORMAL PROCESSING           02584021
         MVI   E0(TECBR),E0  CLEAR TSCECB                               02586021
         MVI   TSCVTFLG,E0   CLEAR PRINARY FLAGS                        02588021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       02590021
         L     WR2,TSCVTECB        GET ADR ECB TABLE             A42839 02592021
         USING TSECB,WR2           SET UP ADDRESSABILITY         A42839 02594021
         LA    WR2,TSCECB2         GET ADR ECB FOR MODIFY TASK   A42839 02596021
         DROP  WR2                 DROP ECB TABLE                A42839 02598021
*********************************************************************** 02602021
*'TST' ROUTINE ATTACH'S THE TSC SUBTASK.  SUBTASK WAITS FOR THE SYSTEM* 02606021
*OPERATORS MODIFY/STOP TS COMMANDS.                                   * 02610021
*********************************************************************** 02614021
         LA    WR0,T03ATTL         LEN  ATTACH PARM LIST                02615021
         O     WR0,SP252           SET SUBPOOL TO 252                   02616021
         GETMAIN  R,LV=(0)         DYNAMIC ATTACH LIST                  02617021
         LR    WR4,WR1             ADDR. TO ATTACH LIST REG.            02618021
         MVC   E0(T03ATTL,WR4),T03ATT  MOVE ATTACH PARM LIST            02619021
         ATTACH SF=(E,(WR4)),EPLOC=T06NAME,LPMOD=1,ECB=(WR2),          *02620021
               ETXR=IKJEAT0A                                            02621021
         EJECT                                                          02622021
         ST    WR1,TSCVTT06        SAVE IKJEAT06 TCB ADDRESS            02623021
         LA    WR0,T03ATTL         LEN ATTACH PARM LIST                 02624021
         O     WR0,SP252           SET SUBPOOL TO 252                   02625021
         FREEMAIN R,LV=(0),A=(WR4) FREE DYNAMIC AREA                    02626021
         OI    CVTTSFLG,CVTTSRDY   SET TSO READY FOR USERS              02629021
         L     RCBR,TSCVTRCB       GET ADR FIRST RCB                    02632021
         LH    WR5,TSCVTCTR        COUNT OF RCBS                        02635021
TRG1     TM    RCBFLG2,RCBACTV     RCB ACTIVE?                          02640020
         BZ    TRG2                NO                                   02650020
*                                  SET UP TSEVENT, REGION STARTED       02660020
*                                  REG 1 LH:REG. NUMBER, RH:REG. SIZE   02670020
         SR    WR1,WR1             ZERO PARM REG TO TSEVENT             02680020
         IC    WR1,RCBNMBR         REGION NUMBER                        02690020
         SLL   WR1,E16             SHIFT TO LEFT HALF                   02700020
         LH    WR2,RCBRSIZE        SIZE OF REGION FROM RCB              02710020
         OR    WR1,WR2             REGION NUMBER PLUS REGION SIZE       02720020
         TSEVENT   SPRGNSZ         REGION IS STARTED                    02730020
TRG2     LA    RCBR,RCBEND         ADDR. OF NEXT RCB                    02740020
         BCT   WR5,TRG1            ANOTHER RCB                          02750020
*********************************************************************** 02760020
*TSO IS UP AND READY FOR BUSINESS.                                    * 02770020
*********************************************************************** 02780020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    02780221
         L     RCBR,TSCVTRCB       ADRS FIRST RCB                       02780421
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       02780621
         SR    WR0,WR0             INIT REG                             02781020
         IC    WR0,RCBCONID        GET CONSOLE ID FOR MESSAGE           02782020
         LA    WR1,INITMSG         ADDR MESSAGE TSO READY               02783020
         WTO   MF=(E,(1))          TELL USER TSO READY                  02784020
         TITLE 'IKJEATML  TSO/TSC MAIN WAIT'                            02790020
*********************************************************************** 02800020
*********************************************************************** 02810020
*TSO/TSC MAIN WAIT ROUTINE.                                           * 02820020
*WAITS ON TSCECB FOR TSCVTFLG(SWAP START/END, LOGON, AND DISCONNECT)  * 02830020
*AND ON TSCVTFL1(FOR STOP OR MODIFY TS).                              * 02840020
*********************************************************************** 02850020
*********************************************************************** 02860020
IKJEATML WAIT  1,ECB=(TECBR)       THE TSC IS WAITING FOR ACTION!!!     02870020
         MVI   E0(TECBR),E0        ZERO TSCECB                          02880020
*                                  ANY TSC FLAGS SET?                   02890020
TSCM1    TM    TSCVTFLG,TSCSWPND+TSCSWPBG+TSCLOGON+TSCDISC              02900020
         BZ    T03ML09             NO TSCCVTFLG'S SET                   02910020
T03MLSTR LA    RTNR,T03MLSTR       SET RETURN TO TOP OF SEARCH          02920020
         TM    TSCVTFLG,TSCSWPND   SWAP END?                            02930020
         BZ    T03ML1              NO                                   02940020
         NI    TSCVTFLG,ALLFLG-TSCSWPND RESET SWAP END                  02950020
         L     EPR,ATSCSE          ADDR. SWAP END                       02960020
         BR    EPR                 GO TO SWAP END                       02970020
T03ML1   TM    TSCVTFLG,TSCSWPBG   SWAP START                           02980020
         BZ    T03ML2              NO                                   02990020
         NI    TSCVTFLG,ALLFLG-TSCSWPBG       SWAP START                03000020
         L     EPR,ATSCSS          ADDR. SWAP.START                     03010020
         BR    EPR                 GO TO SWAP START                     03020020
T03ML2   TM    TSCVTFLG,TSCLOGON   LOGON A USER                         03030020
         BZ    T03ML3              NO                                   03040020
         NI    TSCVTFLG,ALLFLG-TSCLOGON       LOGON                     03050020
         L     EPR,ATSCLG          ADDR. OF LOGON                       03060020
         BR    EPR                 GO TO LOGON                          03070020
T03ML3   TM    TSCVTFLG,TSCDISC    DISCONNECT A USER                    03080020
         BZ    T03ML09             NO                                   03090020
         NI    TSCVTFLG,ALLFLG-TSCDISC        DISCONNECT                03100020
         BAL   WR3,IKJEATDC        DISCONNECT PREAMBLE                  03110020
         L     EPR,ATSCDC          ADDR. OF DISC                        03120020
         BR    EPR                 GO TO DISCONNECT                     03130020
         SPACE 3                                                        03140020
T03MLEND TM    TSCVTFLG,TSCSWPND+TSCSWPBG+TSCLOGON+TSCDISC              03150020
         BZ    IKJEATML            NO, NONE SET                         03160020
         B     T03MLSTR            YES, AT LEAST ONE SET                03170020
         EJECT                                                          03180020
*********************************************************************** 03190020
*TEST SECONDARY TSC FLAGS 1)TCAM FAILURE, 2) START/STOP REGION          03200021
*********************************************************************** 03210020
T03ML09  LA    RTNR,T03MLEND       SET RETURN TO MAINLINE END           03220020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    03227021
         TM    TSCVTFL1,TSCASTOP   TCAM FAILURE                         03234021
         BZ    T03ML091            N/, MAKE NEXT TEST                   03241021
         L     EPR,ATSCTF          GET ADRS OF TCAM FAILURE RTN         03248021
         BR    EPR                 GO TO TCAM FAILURE RTN               03255021
T03ML091 TM    TSCVTFL1,TSCRSTOP   START/STOP REGION                    03262021
         BCR   E8,RTNR             NO, RECHECK PRIMARY FLAGS            03269021
         L     EPR,ATSCRSS         GET ADRS OF START/STOP RTN           03276021
         BR    EPR                 GO TO START/STOP REGION RTN          03283021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       03290021
*********************************************************************** 03335020
*TO STOP TSO, POST TSCECB1. TSC SUBTASK(IKJEAT06) WILL INITIATE THE   * 03350020
*STOP SEQUENCE, SET TSCSSTOP, AND TERMINATE.                          * 03360020
*********************************************************************** 03370020
         USING TSECB,TECBR         TSO ECB'S                            03380020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    03381021
T03ML093 EQU   *                                                        03382021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       03383021
         NI    TSCVTFL1,ALLFLAG-TSCASTOP YES RESET ASTOP BIT     A42839 03386021
         L     WR1,TSCVTECB        ADDR. OF TSO ECB'S                   03390020
         LA    WR1,TSCECB1         ADDR. OF SUB TASK COMMUNICATION ECB  03400020
         DROP  TECBR               TSO ECB'S                            03410020
         LA    WR0,ECB7F           COMP. CODE                           03420020
         POST  (1),(0)             POST SPLECB TO STOP TSO              03430020
         BR    RTNR                RETURN TO SEARCH                     03440020
*********************************************************************** 03450020
*TSC DISCONNECT PREAMBLE.  SCANS THE TJB'S FOR TJBDISC.  DECREMENTS   * 03460020
*COUNT OF CURRENT USERS IN A REGION(RCBCUSE) FOR THE CORRESPONDING RCB* 03470020
*********************************************************************** 03480020
IKJEATDC L     TJBR,TSCVTTJB       ADDR. OF FIRST TJB                   03490020
         LH    WR5,TSCVTSZU        SIZE OF TJB                          03500020
         AR    TJBR,WR5                BUMP TO FIRST USER TJB           03510020
         LH    WR6,TSCVTNTJ        NUMBER OF TJBS                       03520020
         LA    WR0,E1              ONE FOR DECREMENTING                 03530020
T03DIS01 TM    TJBSTAT,TJBDISC     TJBDISC SET                          03540020
         BO    T03DIS03            YES                                  03550020
T03DIS02 LA    TJBR,E0(WR5,TJBR)   ADDR. OF NEXT TJB                    03560020
         BCT   WR6,T03DIS01        ANOTHER TJB, TO TOP                  03570020
         BR    WR3                 RETURN                               03580020
T03DIS03 TM    TJBSTAT2,TJBRNAV    REGION NOT AVAIL. SET                03590020
         BO    T03DIS02            NEVER CONNECTED TO REGION            03600020
         TM    TJBSTAT2,TJBDEAD    Q:THIS USER FAIL IN T07?             03600720
         BZ    T03DIS05            NO, TREAT NORMAL                     03601420
         CLC   TSCVTLUS,TSCVTMUS   Q:LIMIT = MAX?                       03602120
         BNE   T03DIS04            NO, DECR ONLY MAX                    03602820
         LH    WR0,TSCVTLUS        GET LIMIT                            03603520
         BCTR  WR0,E0              DECR BY ONE                          03604220
         STH   WR0,TSCVTLUS        RESTORE                              03604920
T03DIS04 EQU   *                                                        03605620
         LH    WR0,TSCVTMUS        GET MAX                              03606320
         BCTR  WR0,E0              DECR BY ONE                          03607020
         STH   WR0,TSCVTMUS        RESTORE                              03607720
         LA    WR0,E1              RESTORE WR0                          03608420
T03DIS05 EQU   *                                                        03609120
         TM    TJBSTAT3,TJBDISC2   HAS THIS TJB BEEN TO DISCONNECT      03609520
         BO    T03DIS02            YES GO GET NEXT TJB                  03609920
         OI    TJBSTAT3,TJBDISC2   NO SET BIT INDICATING DISCONNECT     03613220
         L     RCBR,TJBRCB         ADDR. OF RCB                         03616720
         LH    WR1,RCBCUSE         CURRENT COUNT                        03620020
         SR    WR1,WR0             MINUS ONE                            03630020
         STH   WR1,RCBCUSE         TO RCB                               03640020
         B     T03DIS02            BACK TO TJB SEARCH                   03650020
         TITLE 'IKJEATLG   TSO/TSC LOGON ROUTINE'                       03660020
*********************************************************************** 03670020
*TSC LOGON SUBROUTINE: SCANS TJB'S FOR TJBLOGON SET.                  * 03680020
*FOR TJBLOGON, DO EITHER LOGON OR  RE/LOGON PROCESSING. FOR LOGON     * 03690020
*ISSUE TSEVENT(REQRGNID/LOGON) TO OBTAIN REGION ID AND CONNECT TJB TO * 03700020
*RCB. IF RE-LOGON, ISSUE TSEVENT(LOGON) TO CONNECT TJB TO RCB. FOR    * 03710020
*LOGON/RE-LOGON, SET TJB FOR SWAP IN LOGON IMAGE AND TSEVENT(USERRDY) * 03720020
*********************************************************************** 03730020
IKJEATLG SAVE  (14,12)             SAVE REGISTERS                       03740020
*********************************************************************** 03750020
*TSC LOGON SCAN SUBROUTINE                                            * 03760020
*********************************************************************** 03770020
T03LGSCN L     TJBR,TSCVTTJB       ADDR. OF FIRST TJB                   03780020
         LH    WR5,TSCVTSZU        SIZE OF TJB                          03790020
         AR    TJBR,WR5                BUMP TO FIRST USER TJB           03800020
         LH    WR6,TSCVTNTJ        NUMBER OF TJB'S                      03810020
T03LGS01 TM    TJBSTAT,TJBLOGON    LOGON FOR THIS TJB?                  03820020
         BO    T03LGLGN            YES, TO LOGON ROUTINE                03830020
         LA    TJBR,E0(WR5,TJBR)   ADDR. OF NEXT TJB                    03840020
         BCT   WR6,T03LGS01        ANOTHER TJB, YES TO TOP              03850020
*                                  NO, SCAN COMPLETE                    03860020
         RETURN (14,12)            DONE, RETURN TO CALLER               03870020
*                                                                       03880020
T03LGLGN NI    TJBSTAT,ALLFLG-TJBLOGON       RESET TJB LOGON            03890020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    03891021
         TM    TJBRSTOR,TJBLOGP        DID THE USER FAIL DURING         03892021
*                                      SWAP IN OF THE LOGON IMAGE ?     03893021
         BZ    NOLISIF                 BRANCH IF FIRST REQUEST          03894021
         NI    TJBRSTOR,ALLFLG-TJBLOGP TURN OFF BIT TO PREVENT RECURSE  03895021
         L     RCBR,TJBRCB             GET ADDRESS OF PREVIOUS RCB      03896021
         LH    WR1,RCBCUSE             GET REGION USER COUNT            03897021
         BCTR  WR1,0                   DECREMENT BY ONE                 03898021
         STH   WR1,RCBCUSE             SAVE NEW USE COUNT IN RCB        03899021
         XC    TJBEXTNT,TJBEXTNT       CLEAN UP THE TJB FROM BEFORE     03900021
         XC    TJBRCB,TJBRCB           CLEAN UP THE TJB FROM BEFORE     03901021
         XC    TJBSDCB,TJBSDCB         CLEAN UP THE TJB FROM BEFORE     03902021
NOLISIF  CLI   TJBNEWID,E0             RELOGON REQUESTED ?              03903021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       03904021
         BNE    T03LGL04    NO, IT IS RELOGON                           03910020
*********************************************************************** 03920020
*TSC LOGON SUBROUTINE                                                 * 03930020
*********************************************************************** 03940020
T03LGL01 LA    WR4,LOGRTCT         LOGON RETRY COUNT                    03950020
*                                  TSEVENT TO GET REGION ID             03960020
T03LGL02 LH    WR0,TJBTJID         GET TJID FROM TJB                    03970020
         SR    WR1,WR1             INDICATE ANY REGIO SIZE IS OKAY      03982020
         TSEVENT REQRGNID,TJID=(0) GET REGION ID FROM TSIP/DRIVER       03990020
         LTR   WR1,WR1             REGION  ID RETURN'ED                 04000020
         BM    T03LGL03            NO, GO TO RETRY                      04010020
*                                  TSEVENT TO LOGON USER                04020020
         C     WR1,NOREGMSK        REGION ID RETURNED            A44363 04022021
         BE    T03LGL03            NO-GO TO RETRY                A44363 04024021
         LH    WR0,TJBTJID         GET TJID FROM TJB                    04030020
         TSEVENT LOGON,TJID=(0)    CONNECT TO REGION                    04040020
         LTR   WR1,WR1             LOGON SUCCESSFUL                     04050020
         BM    T03LGL03            NO, GO TO RETRY                      04060020
         B     T03LGL05            YES, TO LOGON/RELOGON COMMON         04070020
T03LGL03 BCT   WR4,T03LGL02        RETRY COUNT ZERO, NO RETRY           04080020
*                                  YES, DISCONNECT                      04090020
*********************************************************************** 04100020
*TSC LOGON RETRY FAILED. FORCE USER DISCONNECT                          04110020
*********************************************************************** 04120020
         OI    TJBSTAT2,TJBRNAV    SET TJB NO LOGON MSG. FLAG           04130020
         OI    TSCVTFLG,TSCDISC    SET TSC DISCONNECT                   04140020
         OI    TJBSTAT,TJBDISC     SET TJB DISCONNECT                   04150020
         OI    TJBSTAT3,TJBDISC2   SET BIT FOR DISCONNECT         M2572 04152021
         B     T03LGSCN            TO TOP OF TJB SCAN                   04160020
*********************************************************************** 04170020
*TSC RE-LOGON SUBROUTINE                                              * 04180020
*********************************************************************** 04190020
T03LGL04 LA    WR0,E1              ONE FOR DECREMENTING                 04200020
         L     RCBR,TJBRCB         ADDR. OF RCB OLD REGION              04210020
         LH    WR1,RCBCUSE         CURRENT USERS COUNT                  04220020
         SR    WR1,WR0             MINUS ONE                            04230020
         STH   WR1,RCBCUSE         TO RCB                               04240020
         SR    WR1,WR1             ZERO REG.                            04250020
         IC    WR1,TJBNEWID        REGION IDENTIFICATION                04260020
         LH    WR0,TJBTJID         GET TJID FROM TJB                    04270020
         TSEVENT LOGON,TJID=(0)    CONNECT TO REGION                    04280020
         MVI   TJBNEWID,E0         ZERO REGION ID                       04290020
         LTR   WR1,WR1             RE LOGON SUCCESSFUL                  04300020
         BM    T03LGL01            NO, TO LOGON PROCESSING              04310020
         EJECT                                                          04320020
*********************************************************************** 04330020
*TSC LOGON/RE-LOGON COMMON SUBROUTINE                                 * 04340020
*********************************************************************** 04350020
T03LGL05 OI    TJBRSTOR,TJBLOGP    SET LOGON IN PROGRESS FOR SWAP IN    04360020
*                                  AND RCT QUIESCE                      04370020
*                                  WR1 CONTAINS REGION NUMBER           04380020
*                                  FIND RCB FOR REGION NUMBER           04390020
         L     RCBR,TSCVTRCB       ADDR. OF FIRST RCB                   04400020
         B     T03LGL07            TO FIND RCB LOOP                     04410020
T03LGL06 LA    RCBR,RCBEND         ADDR. OF NEXT RCB                    04420020
T03LGL07 BCT   WR1,T03LGL06        DEC. REGION NUMBER                   04430020
         ST    RCBR,TJBRCB         RCB ADDR. TO TJB                     04440020
*                                  HOOK RCB AND LOGON IMAGE TO TJB      04450020
         MVC   TJBSDCB(E4),RCBSDCB     ADDR. SWAP CB TO TJB             04460020
         MVC   TJBUTTMQ(E2),RCBUTTMQ  SWAP SPACE Q ANCHOR               04470020
*                                  MOVE SWAP IMAGE PTRS FROM RCB TO TJB 04480020
         L     WR2,RCBUMSM         ADDR. OF RCB UMSM                    04490020
         L     WR3,TJBUMSM         ADDR. OF TJB UMSM                    04500020
         IC    WR1,RCBUMSMN        NUM OF UMSM ENTRIES                  04510020
         SLL   WR1,E2              TIMES 4, SIZE OF UMSM ENTRY          04520020
         BCTR  WR1,0               MINUS ONE                            04530020
         EX    WR1,T03LGMVC        MOVE UMSM FROM RCB MAP TO TJB MAP    04540020
         MVC   TJBEXTNT(E4),RCBEXTNT MOVE ADDR. TJBX FOR REGION TO TJB  04550020
*                                  INCREMENT COUNT OF USER IN REGION    04560020
         LA    WR2,E1              ONE                                  04570020
         AH    WR2,RCBCUSE         PLUS CURRENT COUNT                   04580020
         STH   WR2,RCBCUSE         STORE IN THE RCB                     04590020
         LH    WR0,TJBTJID         GET TJID FROM TJB                    04600020
         TSEVENT USERRDY,TJID=(0)  USER MAY RUN, LOGON COMPLETE         04610020
         B     T03LGSCN            TO TOP OF TJB SCAN                   04620020
*                                                                       04630020
T03LGMVC MVC   E0(E0,WR3),E0(WR2)  MOVE RCB UMSM TO TJB UMSM            04640020
         TITLE 'IKJEATST TSO/TSC STOP TS ROUTINE'                       04650020
*********************************************************************** 04660020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    04670021
*STOP TSO PROCESSING HAS BEEN REQUESTED                                 04680021
*IF TSCVTCUS IS NOT ZERO - RETURN TO MAIN WAIT                          04690021
*IF ANY RCTS ARE DEAD- ISSUE MSG,RESET SVCS,RESETCVTTSRDY               04700021
*IF ENTERED FROM INITILIZATION FAILURE - ISSUE TSO IS STOPPING MSG      04710021
*IF ENTERED FOR ANY OTHER REASON- POST T06 AND WAIT FOR IT TO END       04720021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       04730021
*********************************************************************** 04740020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    04742021
IKJEATST OC    TSCVTCUS(E2),TSCVTCUS IS USER COUNT ZERO                 04744021
         BNZ   T03UR011            NO, RESTORE REGS AND WAIT            04746021
         LH    WR5,TSCVTCTR        GET NUMBER OF RCBS                   04748021
         L     RCBR,TSCVTRCB       ADRS FIRST RCB                       04750021
TST01    TM    RCBFLG2,RCBDEAD     IS THIS REGION HUNG                  04752021
         BZ    NOTDEAD             NO,CONTINUE SEARCH                   04754021
         SR    RCBR,RCBR           YES, SET SWITCH                      04756021
         B     TST03                                                    04758021
NOTDEAD  EQU   *                                                        04760021
         LA    RCBR,RCBEND         GET NEXT POTENTIAL RCB               04762021
         BCT   WR5,TST01           NOT ZERO, PROCESS THIS RCB           04764021
         TM    TSCVTFL1,TSCLOGPR   IS ENTRY FROM INITLZTION             04766021
         BO    TST02               YES, ISSUE STOP MSG                  04768021
         L     WR3,TSCVTECB  ADRSBLTY TO ECBS                           04770021
         USING TSECB,WR3                                                04772021
         POST  TSCECB5             TELL T06 TO END                      04774021
         WAIT  1,ECB=TSCECB2       WAIT FOR T06 TO END                  04776021
         DROP  WR3                                                      04778021
         B     TST03               CLOSE DOWN TSO                       04780021
TST02    EQU   *                                                        04782021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       04784021
         LA    WR0,M078IWL                                        M0049 04785021
         O     WR0,SP252            SET SP252                     M0049 04786021
         GETMAIN R,LV=(0)                                         M0049 04787021
         L     WR15,TSCVTTSC           ADDR OF TSC TCB                  04788021
         USING TCB,WR15            ADDRESSABILITY FOR TCB               04789021
         L     WR15,TCBTIO         ADDR OF TSO'S TIOT                   04790021
         DROP  WR15                DROP TCB                             04791021
         MVC   E0(M078IWL,WR1),M078IW  MOVE MSG                         04792021
         MVC   M078IWJ(E8,WR1),TIOTJOB(WR15)  JOBNAME TO MSG            04793021
         MVC   M078IWS(E8,WR1),TIOTSTEP(WR15)  STEP NAME TO MSG         04794021
         LR    WR3,WR1                 SAVE AREA PTR ACROSS WTO         04795021
         XR    WR0,WR0                 SET OPERATOR CONSOLE             04796021
         WTO   MF=(E,(1))              TELL OPERATOR WE QUIT            04797021
         LA    WR0,M078IWL                                        M0049 04798021
         O     WR0,SP252                                          M0049 04799021
         FREEMAIN R,LV=(0),A=(WR3)  FREE WTO BUFFER               M0049 04800021
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    04820021
*********************************************************************** 04840021
*RESET CVTTSRDY FLAG IN THE CVT                                         04860021
*********************************************************************** 04880021
TST03    NI    CVTTSFLG,ALLFLAG-CVTTSRDY  RESERT TSO READY FLAG         04900021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       04920021
         EJECT                                                          05000020
*********************************************************************** 05050020
*RESTORE SVCTABLE  FOR TSIP(SVC 95) AND QTIP(SVC 101)                 * 05060020
*SVC TABLE ENTRIES PRIOR TO START TSO IN TSCVTSVT AND TSCVTSVQ        * 05070020
*********************************************************************** 05080020
         USING SCVTD,WR2           SECONDARY CVT                        05090020
         L     WR2,CVTABEND        ADDR. OF SECONDARY CVT               05100020
         L     WR3,SCVTSVCT        ADDR. OF SVC TABLE                   05110020
         DROP  WR2                 SECONDARY CVT                        05120020
         LA    WR4,TSIPDISP(WR3)   ADDR. OF TSIP ENTRY IN SVC TABLE     05130020
         MVC   E0(E4,WR4),TSCVTSVT RESTORE TSIP FROM TSCVT              05140020
         LA    WR4,QTIPDISP(WR3)   ADDR. OF QTIP ENTRY IN SVC TABLE     05150020
         MVC   E0(E4,WR4),TSCVTSVQ RESTORE QTIP FROM TSCVT              05160020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    05160521
         LTR   RCBR,RCBR           WAS A DEAD REGION FOUND              05161021
         BNZ   TST04         NO, RETURN TO SYSTEM                       05161521
         WTO   'IKJ025I  TSO UNABLE TO TERMINATE DUE TO REGION FAILURE'X05162021
               ,ROUTCDE=2,DESC=4                                        05162521
*********************************************************************** 05163021
* GO TO NEVER ENDING WAIT -- TSO CAN NOT STOP WITH DEAD RCTS            05163521
         USING TSECB,TECBR                                              05164021
         XC    CVTTSCVT,CVTTSCVT       ZERO CVT POINTER TO TSOCVT       05164521
         L     TECBR,TSCVTECB          WAIT ON                          05165021
         MVI   TSCECB7,E0    NEVER POSTED                               05165521
         WAIT  1,ECB=TSCECB7      ECB                                   05166021
         DROP  TECBR                                                    05166521
*********************************************************************** 05167021
TST04    EQU   *                                                        05167521
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       05168021
         EJECT                                                          05170020
*********************************************************************** 05450020
*TSO IS DONE. RETURN TO IKJEAT03'S CALLER. SYSTEM CONTROL TASK        * 05460020
*********************************************************************** 05470020
TSODONE  EQU   *                    PREPARE FOR RETURN                  05475020
*********************************************************************** 05477020
*ZERO ADDRESS OF TSCVT IN CVT - CVTTSCVT                              * 05479020
*********************************************************************** 05479420
T03ST05  XC    CVTTSCVT,CVTTSCVT   ZERO TSCVT ADR IN CVT         A42839 05479721
         L     SAVER,E4(SAVER)     ADDR. OF SYS. CONTROL SAVE AREA      05480020
*                                  FROM 'T03' SAVE AREA                 05490020
         RETURN  (14,12)           RETURN TO SYSTEM CONTROL TASK        05500020
         TITLE 'IKJEATUR TSO/TSC STOP/START USER REGION ROUTINE'        05510020
*********************************************************************** 05520020
*IKJEATUR:TSO/TSC  USER REGION  1)STOP, 2)START, 3)STOP/START ROUTINE.* 05530020
*         FOR REGION STOP, RCBSTOP IS SET, USERS ARE LOGGING OFF.     * 05540020
*WHEN ARE ALL USER'S OFF, TERMINATE RCT.                              * 05550020
*FOR REGION START RCBSTR1 AND RCBSTR2 ARE SET. FOR RCBSTR1, ATTACH    * 05560020
*RCT. FOR RCBSTR2 CREATE(RCT Q/SWAP OUT)  LOGON IMAGE.  FOR STOP/START* 05570020
*RCBSTOP, RCBSTR1, AND RCBSTR2 ARE SET. STOP THEN START A REGION.     * 05580020
*SWITCH REG SET TO ZERO. IF SET(ZERO) AT END OF RCB SEARCH, RESET     * 05590020
*TSCRSTOP.  IF RE-SET(NON-ZERO), DO NOT  RE-SET TSCRSTOP. IKJEATUR    * 05600020
*WANTS CONTROL AGAIN.                                                 * 05610020
*********************************************************************** 05620020
IKJEATUR SAVE  (14,12)             SAVE REGISTERS                       05630020
         LH    WR5,TSCVTCTR        NUMBER OF RCB'S                      05640020
         L     RCBR,TSCVTRCB       ADDR. OF FIRST RCB                   05650020
T03UR01  TM    RCBFLG2,RCBSTOP     RCB STOP SET?                        05670020
         BO    T03UR02             YES                                  05680020
         TM    RCBFLG2,RCBSTR1     RCB START 1 SET?                     05690020
         BO    T03UR03             YES                                  05700020
         TM    RCBFLG2,RCBSTR2     RCB START 2 SET?                     05710020
         BO    T03UR04             YES                                  05720020
*                                  NOT THIS RCB                         05730020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    05732021
T03UR010 EQU   *                                                        05734021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       05736021
         LA    RCBR,RCBEND         ADR NEXT RCB                  A42839 05743021
         BCT   WR5,T03UR01         ANOTHER RCB, YES                     05750020
*                                  NO                                   05760020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    05762021
         TM    TSCVTFL1,TSCSSTOP   IS TSO TO STOP                       05764021
         BO    IKJEATST            YES, START THE STOP PROCESS          05766021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       05768021
T03UR011 RETURN (14,12)            RETURN TO TSC MAINLINE        A42839 05788021
*********************************************************************** 05810020
*REGION STOP PROCESSING                                               * 05820020
*********************************************************************** 05830020
*                                  REGION STOP PROCESSING               05840020
T03UR02  LH    WR1,RCBCUSE         COUNT OF USERS IN REGION             05850020
         LTR   WR1,WR1             COUNT OF ZERO?                       05860020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    05870021
         BNZ   T03UR010      CONTINUE LOOP                              05880021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       05890021
T03UR021 NI    RCBFLG2,ALLFLAG-RCBSTOP RESET RCB STOP FLAG              05900020
         OI    RCBFLG,RCBFND       SET RCB TERM FLAG                    05910020
         LA    WR0,ECB7F           COMP. CODE                           05920020
         LA    WR1,RCBECB          ADDR.  OF RCT ECB                    05930020
         POST  (1),(0)             POST RCBECB                          05940020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    05948021
         LA    WR1,RCBDIECB        ADR EOT ECB FOR RCB                  05956021
         WAIT  1,ECB=(1)           WAIT FOR RCT TO END                  05964021
         B     T03UR010            CONTINUE SEARCH                      05972021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       05980021
*********************************************************************** 05990020
*REGION START 1 PROCESSING                                              06000020
*********************************************************************** 06010020
T03UR03  L     WR1,RCBRCT          GET ADR RCT TCB               A42839 06015021
         LTR   WR1,WR1             IS THERE AN ADR               A42839 06020021
         BNZ   T03UR011            NO RETURN                     A42839 06025021
         NI    RCBFLG2,ALLFLAG-RCBSTR1  RESET START 1                   06030020
         MVI   RCBECB,E0           RESET WAIT/POST BITS ALL ECB'S       06040020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    06045021
         XC    RCBDIECB(E4),RCBDIECB *                                  06050021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       06055021
         MVI   RCBSTECB,E0         *                                    06060020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    06062021
         L     WR3,VT05            ADDRS OF ETXR                        06064021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       06066021
         LA    WR0,T03ATTL         LEN  ATTACH PARM LIST                06070020
         O     WR0,SP252           SET SUBPOOL TO 252                   06075020
         GETMAIN R,LV=(0)          DYNAMIC ATTACH LIST                  06080020
         LR    WR4,WR1             ADDR. TO ATTACH LIST REG.            06090020
         MVC   E0(T03ATTL,WR4),T03ATT MOVE ATTACH PARM LIST             06100020
         LA    WR2,RCBDIECB        ADDR. OF TERM. ECB IN RCB            06130020
         LR    WR1,RCBR            ADDR. OF RCB TO RCT                  06140020
         ATTACH SF=(E,(WR4)),EPLOC=R00NAME,ETXR=(WR3),ECB=(WR2),LPMOD=2X06150020
               ,DPMOD=-2                                                06152020
         ST    WR1,RCBRCT          RCT TCB ADDR. TO RCB                 06160020
         LA    WR0,T03ATTL         LEN. ATTACH DYNAMIC LIST             06170020
         O     WR0,SP252           SET SUBPOOL TO 252                   06175020
         FREEMAIN R,LV=(0),A=(WR4)  RELEASE DYNAMIC AREA                06180020
         B     T03UR011            NEXT RCB                             06190020
         EJECT                                                          06200020
*********************************************************************** 06210020
*REGION START 2 PROCESSING                                            * 06220020
*********************************************************************** 06230020
T03UR04  TM    RCBFLG2,RCBACTV     RCT INITIALIZED                      06240020
         BNO   T03UR011            NO RETURN                     A42839 06249021
         NI    RCBFLG2,ALLFLAG-RCBSTR2 RESET START 2             A42839 06258021
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    06267021
         LA    WR0,E72             LENGTH                               06276021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       06285021
         O     WR0,SP252           SET SUBPOOL TO 252                   06295020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    06298021
         GETMAIN  R,LV=(0)                                              06301021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       06304021
         ST    SAVER,E4(WR1)       CHAIN                                06310020
         ST    WR1,E8(SAVER)       SAVE                                 06320020
         LR    SAVER,WR1           AREAS                                06330020
         BAL   RTNR,T03LIM         TO CREATE LOGON IMAGE                06340020
         LR    WR1,SAVER           UNCHAIN SAVE                         06350020
         L     SAVER,E4(WR1)       AREAS                                06360020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    06361021
         LA    WR0,E72             LENGTH                               06362021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       06363021
         O     WR0,SP252           SET SUBPOOL TO 252                   06365020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    06366021
         FREEMAIN  R,A=(1),LV=(0)                                       06367021
         LTR   WR3,WR3             DID RCT DIE DURING QUIESCE           06368021
         BZ    T03UR011            YES, GO BACK TO MAIN WAIT            06369021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       06370021
         TM    RCBFLG2,RCBSTOP     IS STOP REGION FLAG SET       A42839 06371021
         BO    T03UR021            YES BRANCH                    A42839 06372021
         SR    WR1,WR1             ZERO PARM REG TO TSEVENT             06380020
         IC    WR1,RCBNMBR         REGION NUMBER                        06390020
         SLL   WR1,E16             SHIFT TO LEFT HALF                   06400020
         LH    WR2,RCBRSIZE        SIZE OF REGION FROM RCB              06420020
         OR    WR1,WR2             REGION NUMBER AND REGION SIZE        06421020
         TSEVENT  SPRGNSZ          REGION IS STARTED                    06430020
         L     WR2,TSCVTECB        GET ADR ECB TABLE                    06432020
         USING TSECB,WR2           SET UP ADDRESSABILITY                06434020
         POST  TSCECB4             TELL T06 REGION INITIALIZED          06436020
*                                  AND ANOTHER MODIFY WILL NOW BE       06438020
*                                  ACCEPTED                             06438420
         DROP  WR2                 DROP TSECB                           06438820
         B     T03UR011            NEXT RCB                             06440020
         TITLE 'IKJEAT03 TSO/TSC SUBROUTINES/CONSTANTS'                 06450020
*********************************************************************** 06460020
*CREATE LOGON IMAGE.  FOR ONE REGION(RCBR-ADDR. OF RCB), SET UP AND   * 06470020
*INVOKE RCT QUIESCE.  SET UP AND INVOKE SWAP START/END.  SAVE SWAP    * 06480020
*SPACE QUEUE ANCHOR AND UMSM IN RCB.                                  * 06490020
*USES  WR0, WR1, WR2, WR3, TJBR, RTNR, EPR.                           * 06500020
*********************************************************************** 06510020
T03LIM   SR    WR0,WR0             ZERO REGISTER, TJID=ZERO             06520020
         STH   WR0,RCBTJID         SET TJID IN RCB=ZERO                 06530020
         L     TJBR,TSCVTTJB       ADDR. OF TJB, TJID 0F ZERO           06540020
         ST    RCBR,TJBRCB         TJB CONTAINS ADDR. OF RCB            06550020
         MVC   TJBEXTNT(E4),RCBEXTNT MVE TJBX ADR TO TJB                06560020
         OI    RCBFLG,RCBFQU       SET QUIESCE FLAG FOR RCT             06570020
         L     WR2,TSCVTECB        GET ADR ECB TABLE                    06572020
         USING TSECB,WR2           ADDRESSABILITY FOR ECB TABLE         06574020
         LA    WR2,TSCECB3         GET ADR ECB FOR LOGON IMAGE PROC     06576020
         DROP  WR2                 DROP ECB TABLE                       06578020
         MVI   E0(WR2),E0          CLEAR TSCECB3                        06580020
         LA    WR1,RCBECB          ADDR. OF RCB ECB                     06590020
         LA    WR0,ECB7F           COMP. CODE                           06600020
         OI    RCBFLG2,RCBLOGPR    SET BIT INDICATING TO R02 THIS IS    06602020
*                                  LOGON IMAGE PROCESSING AND TSCECB3   06604020
*                                  IS TO BE POSTED                      06606020
         POST  (1),(0)             POST RCBECB TO START RCT             06610020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    06610521
         LA    WR0,E8              NEED 8 BYTES FOR LIST                06611021
         O     WR0,SP252           FROM SUBPOOL 252                     06611521
         GETMAIN R,LV=(0)                                               06612021
         LA    WR3,RCBDIECB        WAIT ON RCBDIECB                     06612521
         STM   WR2,WR3,E0(WR1) AND TSCECB3                              06613021
         OI    E4(WR1),HIBIT       SET END OF LIST INDICATOR            06613521
         LR    WR3,WR1             SAVE ADRS OF LIST AREA               06614021
         WAIT  1,ECBLIST=(1)       WAIT FOR EITHER POST                 06614521
         LR    WR1,WR3             RESTORE LIST ADRS                    06615021
         LA    WR0,E8              SET TO FREE THE 8 BYTE LIST          06615521
         O     WR0,SP252           FROM SUBPOOL 252                     06616021
         FREEMAIN R,LV=(0),A=(1)                                        06616521
         LA    WR3,RCBDIECB            GET RCBDIECB ADRS                06617021
         TM    E0(WR3),POSTED          WAS RCBDIECB POSTED              06617521
         BZ    T03LIM1             TSCECB3 WAS POSTED-CONTINUE          06618021
         SR    WR3,WR3             SET REG SWITCH TO GO TO              06618521
*                                  MAIN WAIT - RCT DIED DURING          06619021
*                                  QUIESCE                              06619521
         BR    RTNR                RETURN                               06620021
T03LIM1  EQU   *                                                        06620521
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       06621021
         LR    WR3,RTNR            SAVE RTNR ACROSS SWAP                06630020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    06631021
SWAP     NI    TSCVTFLG,ALLFLAG-TSCSWPBG  RESET SWAP BEGIIN FLAG        06632021
         OI    RCBFLG2,RCBLOGPR        RESET L.I. PROC IF ERROR WAS     06633021
*                            ENCOUNTERED ON FIRST TRY                   06634021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       06635021
         OI    RCBFLG,RCBFSO       SET SWAP OUT FLAG                    06640020
         MVI   E0(WR2),E0          CLEAR TSCECB3                        06650020
         L     EPR,ATSCSS          ADDR. SWAP START                     06660020
*                                  LOGON IMAGE PROCESSING AND TSCECB3   06664020
*                                  IS TO BE POSTED                      06666020
         BALR  RTNR,EPR            TO SWAP START                        06670020
         WAIT  1,ECB=(WR2)         WAIT ON SWAP START                   06680020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    06680221
         LR    RTNR,WR3      RESET RETURN REG                           06680421
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       06680621
         TM    RCBFLG2,RCBSTOP     IS STOP REGION FLG SET        A42839 06680821
         BCR   1,RTNR              YES BRANCH                    A42839 06681021
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    06681221
         TM    TSCVTFL1,TSCLOGPR       DID WE RUN OUT OF SWAP SPACE     06681421
         BCR   1,RTNR        YES,  STOP                                 06681621
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       06681821
         NI    RCBFLG2,ALLFLAG-RCBLOGPR RESET LOGON IMAGE PROC BIT      06682020
         OI    RCBFLG2,RCBFSE      SET SWAP END FLAG                    06690020
         L     EPR,ATSCSE          SET SWAP END FLAG                    06700020
         BALR  RTNR,EPR            TO SWAP END                          06710020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    06712021
         TM    TSCVTFLG,TSCSWPBG       START SWAP OVER                  06714021
         BO    SWAP          YES, SWAP IT                               06716021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       06718021
         LR    RTNR,WR3            UN SAVE RTNR                         06720020
         MVC   RCBSDCB(E4),TJBSDCB     ADDR. SWAP CB TO RCB             06730020
         MVC   RCBUTTMQ(E2),TJBUTTMQ SAVE SWAP SPACE Q. ANCHOR          06740020
         L     WR2,RCBUMSM         ADDR. OF RCB UMSM                    06750020
         L     WR3,TJBUMSM         ADDR. OF TJB UMSM                    06760020
         IC    WR1,TJBUMSMN        NUM. OF UMSM ENTRIES                 06770020
         SLL   WR1,E2              TIMES 4, SIZE IF UMSM ENTRY          06780020
         BCTR  WR1,0               MINUS 1 FOR EX                       06790020
         EX    WR1,T03LIMMV        MOVE UMSM FROM TJB MAP TO RCB MAP    06800020
         BR    RTNR                                                     06810020
*                                                                       06820020
T03LIMMV MVC   E0(E0,WR2),E0(WR3)  MOVE RCB UMSM TO TJB UMSM            06830020
          EJECT                                                         06830420
*********************************************************************** 06830820
* THIS IS THE TSO MODIFY/STOP SUBTASK ETXR RTN (IKJEAT0A).            * 06831220
* IT RECEIVES CONTROL WHEN THE IKJEAT06 SUBTASK TERMINATES.  ITS      * 06831620
* FUNCTION IS TO NOTIFY THE OPERATOR THAT TSO CANNOT BE MODIFIED      * 06832020
* OR STOPPED AND TO ZERO THE IKJEAT06 ADDRESS IN THE TSCVT.           * 06832420
*********************************************************************** 06832820
*                                                                       06833220
*                                                                       06833620
IKJEAT0A EQU   *                                                        06834020
         SAVE  (14,12)             SAVE INPUT REGS                      06834420
         BALR  BASER,0             BASE FOR THIS RTN                    06834820
         USING *,BASER             *                                    06835220
         WTO   'IKJ085I  TSO MODIFY/STOP SUBTASK TERMINATED',ROUTCDE=2,X06836020
               DESC=4                                                   06836420
         L     CVTR,CVTPTR         GET ADR CVT                          06836820
         L     TSCVTR,CVTTSCVT     GET ADDRESS TSCVT                    06837220
         LA    WR6,TSCVTT06        GET PTR TO T06'S TCB FOR DETACH      06837620
         DETACH  (WR6)             DETACH MODIFY/STOP SUBTASK           06838020
         XC    TSCVTT06,TSCVTT06   ZERO T06 TCB ADDR IN TSCVT           06838420
         RETURN (14,12)            RESTORE REGS & RETURN                06838820
*                                  TO CALLER                            06839220
         EJECT                                                          06840020
         DS    0D                                                       06850020
**********************************************************************  06860020
ATSCSS   DC    A(IKJEASSS)         SWAP START                           06870020
ATSCSE   DC    A(IKJEASSE)         SWAP END                             06880020
ATSCLG   DC    A(IKJEATLG)         TSC LOGON                            06890020
ATSCDC   DC    A(IKJGG008)         DISCONNECT                           06900020
ATSCST   DC    A(IKJEATST)         TSC/TSO STOP                         06910020
ATSCRSS  DC    A(IKJEATUR)         TSC/REGION START/STOP                06920020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    06922021
ATSCTF   DC    A(T03ML093)         TCAM FAILURE                         06924021
VT05     DC    V(IKJEAT05)         T05 ENTRY POINT                      06926021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       06928021
**********************************************************************  06930020
T03ATT   ATTACH  SF=L,SM=SUPV,ROLL=(NO,NO)                  1/2         06940020
T03ATTL  EQU   *-T03ATT            L' OF  ATTACH PARM LIST  2/2         06950020
         DS    0D                  EXTERNAL ROUTINES                    06960020
T06NAME  DC    C'IKJEAT06'         TSO/TSC SUBTASK                      06970020
T05NAME  DC    C'IKJEAT05'         ETXR FOR RCT                         06980020
R00NAME  DC    C'IKJEAR00'         RCT INIT                             06990020
QT0NAME  DC    C'IKJGGQT0'         QTIP SVC ENTRY POINT                 06990320
QT1NAME  DC    C'IKJGGQT1'         QTIP SVC BRANCH ENTRY POINT          06990620
INITMSG  WTO   'IKJ019I TSO HAS BEEN INITIALIZED',                     X06991020
               MF=L,MCSFLAG=REG0,ROUTCDE=2,DESC=5                       06992020
M078IW   WTO   'IKJ078I                    TSO IS STOPPING',           *06993020
               ROUTCDE=2,MCSFLAG=REG0,MF=L,DESC=5                 M0049 06994020
M078IWL  EQU   *-M078IW             LENGTH OF MESSAGE             M0049 06995020
M078IWJ  EQU   12                   DISP TO JOBNAME               M0049 06996020
M078IWS  EQU   21                   DISP TO STEPNAME              M0049 06997020
         DS    0F                  MASKS TO CLEAR BYTES, ADDR.          07000020
BYT0MASK DC    X'00FFFFFF'         MASK TO ZERO BYTE 0 IN FULL WORD     07020020
BIT0MASK DC    X'80000000'             MASK FOR BIT 0 OF FULLWD   M0049 07022020
SP252    DC    X'FC000000'         MASK FOR SUBPOOL 252                 07025020
NOREGMSK DC    X'7FFFFFFF'         MASK IF NO REGION ID RET      A44363 07027021
*                                  FROM DRIVER                   A44363 07029021
         END                                                            07030020
