         TITLE 'IKJEAT04  TSO/TSC STAE EXIT ROUTINE'                    00030020
IKJEAT04 START                                                          00040020
*********************************************************************** 00050020
*STATUS  =0                                                      20021* 00060020
*FUNCTION-STAE EXITS AND RETRY ROUTINES FOR THE TIME SHARING          * 00063020
*        CONTROL TASK.                                                * 00066020
*                                                                     * 00069020
*   THIS MODULE CONTAINS THE THREE STAE EXITS AND THE TWO STAE        * 00072020
*   RETRY ROUTINES THAT ARE ENTERED WHEN THE TSO/TSC ABENDS.          * 00075020
*   A TSC ABEND IS CONSIDERED FATAL AND NO ATTEMPT IS MADE TO         * 00078020
*   RECOVER FROM IT.  ABEND PROCESSING CANNOT BE ALLOWED TO TRY       * 00081020
*   TO TERMINATE THE TSC.  TO PROVIDE THIS PROTECTION THE STAE        * 00084020
*   EXIT ROUTINES (LEVELS 1 AND 2) DO NOTHING MORE THAN SCHEDULE      * 00087020
*   RETRY ROUTINES WHICH AND PROTECTED FROM CONTINUED ABEND           * 00090020
*   PROCESSING BY THEIR OWN STAE EXITS.  THE THIRD LEVEL STAE         * 00093020
*   EXIT IS ENTERED WHEN AN ERROR OCCURS IN TRYING TO TERMINATE       * 00096020
*   THE TIME SHARING CONTROL TASK.  THIS FAILURE IS CONSIDERED        * 00099020
*   CATASTROPHIC AND TSO IS SET NON-DISPATCHABLE.                     * 00102020
*                                                                     * 00105020
*                                                                     * 00108020
*** TSC STAE EXIT ROUTINE LEVEL 1                                     * 00111020
*                                                                     * 00114020
*   ENTRY POINT- IKJEAT04                                             * 00117020
*   FUNCTION-                                                         * 00120020
*      1. TEST THE TIME SHARING CVT ADDRESS IN THE CVT FOR ZERO.      * 00123020
*      2. IF ZERO, THE TSC CAN SUCCESSFULLY BE ABENDED SO NO          * 00126020
*         RETRY IS SPECIFIED.  RETURN CODE=0.                         * 00129020
*      3. IF NOT ZERO, THE TSC CANNOT BE ALLOWED TO CONTINUE          * 00132020
*         ABENDING.  RETURN CODE=4.  RETRY ADDRESS=TSCRTRY1.          * 00135020
*      4. TO PREVENT THE TSC FROM ATTEMPTING ANY FURTHER TSC          * 00138020
*         PROCESSING THE TSCVTFL1 FUNCTION FLAGS AND RESETTING        * 00141020
*         THE TSO READY FLAG IN THE CVT.                              * 00144020
*                                                                     * 00147020
*   EXIT- RETURN TO ABEND STAE INTERFACE ROUTINE.  BR 14              * 00150020
*                                                                     * 00153020
*                                                                     * 00156020
*** TSC STAE EXIT ROUTINE LEVEL 2                                     * 00159020
*                                                                     * 00162020
*   ENTRY POINT- TSCEXIT2                                             * 00165020
*   FUNCTION-                                                         * 00168020
*      1. SPECIFY RETRY.                                              * 00171020
*         RETURN CODE=4.  RETRY ADDRESS=TSCRTRY2.                     * 00174020
*                                                                     * 00177020
*   EXIT- RETURN TO ABEND STAE INTERFACE ROUTINE.  BR 14              * 00180020
*                                                                     * 00183020
*                                                                     * 00186020
         EJECT                                                          00189020
*** TSC STAE EXIT ROUTINE LEVEL 3                                     * 00192020
*                                                                     * 00195020
*   ENTRY POINT- TSCEXIT3                                             * 00198020
*   FUNCTION-                                                         * 00201020
*      1. TSO CANNOT BE TERMINATED BECAUSE AN ERROR OCCURED IN        * 00204020
*         TRYING TO TERMINATE TSO IN THE SECOND LEVEL RETRY           * 00207020
*         ROUTINE.  TSO IS SET PERMANENTLY NON-DISPATCHABLE.          * 00210020
*      2. WAIT TO CAUSE A TASK SWITCH.                                * 00213020
*                                                                     * 00216020
*   EXIT- NONE                                                        * 00219020
*                                                                     * 00222020
*                                                                     * 00225020
*   ALL THREE TSC STAE EXIT ROUTINES ARE ENTERED FROM ABEND STAE      * 00228020
*   INTERFACE ROUTINES                                                * 00231020
*                                                                     * 00234020
*   INPUT-    FOR ALL THREE TSC STAE EXIT ROUTINES                    * 00237020
*        WHEN ABEND STAE INTERFACE ROUTINES OBTAINED A WORKAREA       * 00240020
*                                                                     * 00243020
*      REGISTER   0 - CODE TO INDICATE I/O STATUS                     * 00246020
*                     CODE         MEANING                            * 00249020
*                       0          ACTIVE I/O QUIESCED                  00252020
*                       4          ACTIVE I/O HALTED                  * 00255020
*                       8          NO ACTIVE I/O                      * 00258020
*      REGISTER   1 - ADDRESS OF STAE WORKAREA                        * 00261020
*      REGISTER  13 - ADDRESS OF REGISTER SAVE AREA                   * 00264020
*      REGISTER  14 - RETURN ADDRESS                                  * 00267020
*      REGISTER  15 - STAE EXIT ROUTINE ENTRY POINT ADDRESS           * 00270020
*                                                                     * 00273020
*        WHEN ABEND STAE INTERFACE ROUTINES DID NOT OBTAIN A WORKAREA * 00276020
*                                                                     * 00279020
*      REGISTER   0 - 12  INDICATING THAT THERE IS NO WORKAREA        * 00282020
*      REGISTER   1 - ABEND COMPLETION CODE FROM TCBCMP FIELD         * 00285020
*      REGISTER   2 - ADDRESS OF STAE EXIT PARAMETER LIST             * 00288020
*      REGISTER  13 - ADDRESS OF REGISTER SAVE AREA                   * 00291020
*      REGISTER  14 - RETURN ADDRESS                                  * 00294020
*      REGISTER  15 - STAE EXIT ROUTINE ENTRY POINT ADDRESS           * 00297020
*                                                                     * 00300020
*                                                                     * 00303020
         EJECT                                                          00306020
*** TSC STAE RETRY ROUTINE LEVEL 1                                      00309020
*                                                                     * 00312020
*   ENTRY POINT- TSCRTRY1                                             * 00315020
*   FUNCTION:                                                         * 00318020
*          1. GETMAIN A 21 WORD AREA CONSISTING OF:                   * 00321020
*                  16 WORD REGISTER SAVE                              * 00324020
*                  2 WORD INTERFACE SAVE                              * 00327020
*                  3 WORD STAE WORKAREA                               * 00330020
*          2. ISSUE STAE WITH TSCEXIT2 AS THE EXIT.                   * 00333020
*          3. BRANCH AND LINK TO TSO DUMP - IKJEAT08                  * 00336020
*          4. CANCEL PREVIOUS STAE FOR TSCEXIT2                       * 00339020
*                                                                     * 00342020
*                                                                     * 00345020
*** TSC STAE RETRY ROUTINE LEVEL 2                                    * 00348020
*                                                                     * 00351020
*   ENTRY POINT- TSCRTRY2                                             * 00354020
*  THIS IS THE SECOND LEVEL TSC STAE RETRY ROUTINE.  IT RECEIVES      * 00357020
*  CONTROL IN ONE OF TWO WAYS:                                        * 00360020
*                                                                     * 00363020
*      1. FROM THE FIRST LEVEL TSC STAE RETRY ROUTINE IF TSO DUMP     * 00366020
*         PROCESSING COMPLETED.                                       * 00369020
*      2. FROM ABEND STAE INTERFACE ROUTINE                           * 00372020
*         IF A FAILURE OCCURS DURING PROCESSING IN THE FIRST LEVEL    * 00375020
*         TSC STAE RETRY OR DURING TSO DUMP PROCESSING (IKJEAT08).    * 00378020
*                                                                     * 00381020
*  FUNCTION:                                                          * 00384020
*      1. RE-ESTABLISH A STAE ENVIRONMENT TO COVER PROCESSING         * 00387020
*         DONE BY THIS ROUTINE.                                       * 00390020
*      2. POST TERMINAL I/O COORDINATOR TO NOTIFY USERS THAT TSO      * 00393020
*         HAS FAILED.                                                 * 00396020
*      3. POST EACH ACTIVE REGION THAT HAS NOT PREVIOUS3Y DETECTED    * 00399020
*         AN UNRECOVERABLE ERROR INDICATING THE REGION SHOULD         * 00402020
*         TERMINATE.                                                  * 00405020
*      4. WAIT FOR ALL OF THE REGIONS TO STOP. THIS CONDITION WILL    * 00408020
*         BE SATISFIED ONLY IF ALL REGIONS TERMINATE.                 * 00411020
*      5. ZERO THE POINTER TO THE TSCVT IN THE CVT  (CVTTSCVT).       * 00414020
*      6. DETACH THE TSO MODIFY/STOP PROCESSING SUBTASK IF IT         * 00417020
*         EXISTS.                                                     * 00420020
*      7. RESTORE THE TSIP (SVC 95) AND QTIP (SVC 101) ENTRIES        * 00423020
*         IN THE SVC TABLE.                                           * 00426020
*      8. CHAIN THE TSO LPA TO THE TSC JOB PACK QUEUE.                * 00429020
*                                                                     * 00432020
         EJECT                                                          00435020
*  INPUT:     TO TSC STAE RETRY ROUTINES WHEN ENTERED BECAUSE         * 00438020
*             A TSC STAE EXIT ROUTINE SPECIFIED THEM AS RETRY         * 00441020
*             ROUTINES WHEN RETURNING TO ABEND STAE INTERFACE         * 00444020
*             ROUTINES                                                * 00447020
*                                                                     * 00450020
*        WHEN ABEND STAE INTERFACE ROUTINES OBTAINED A WORKAREA       * 00453020
*                                                                     * 00456020
*                                                                     * 00459020
*      REGISTER   0 - ZERO                                            * 00462020
*      REGISTER   1 - ADDRESS OF WORKAREA                             * 00465020
*      REGISTER  14 - RETURN ADDRESS                                  * 00468020
*      REGISTER  15 - STAE RETRY ROUTINE ENTRY POINT ADDRESS          * 00471020
*                                                                     * 00474020
*        WHEN ABEND STAE INTERFACE ROUTINES DID NOT OBTAIN A WORKAREA * 00477020
*                                                                     * 00480020
*      REGISTER   0 - TWELVE DECIMAL                                  * 00483020
*      REGISTER   1 - ABEND COMPLETION CODE                           * 00486020
*      REGISTER   2 - ADDRESS OF FIRST IOB OR ZERO                    * 00489020
*      REGISTER  14 - RETURN ADDRESS                                  * 00492020
*      REGISTER  15 - STAE RETRY ROUTINE ENTRY POINT ADDRESS          * 00495020
*                                                                     * 00498020
**********************************************************************  00501020
         EJECT                                                          00510020
*                                                                     * 00860020
*TABLES/CONTROL BLOCKS/WORK AREAS-                                    * 00870020
*                                                                     * 00880020
*        CVT, SCVT, SVCTABLE, TCB, CDE                                * 00890020
*                                                                     * 00900020
*        TSCVT, RCB, TSECBTAB, TAVTD, TTSID                           * 00910020
*                                                                     * 00920020
*ATTRIBUTES-REENTERANT, READ-ONLY, REFRESHABLE, SUPERVISOR STATE      * 00930020
*                                                                     * 00931020
*CHARACTER CODE DEPENDENCY - THE OPERATION OF THIS MODULE DEPENDS     * 00932020
*        UPON AN INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER    * 00933020
*        SET WHICH IS EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME.    * 00934020
*        THE CODING HAS BEEN ARRANGED SO THAT REDEFINITION OF         * 00935020
*        'CHARACTER' CONSTANTS, BY REASSEMBLY, WILL RESULT IN A       * 00936020
*        CORRECT MODULE FOR THE NEW DEFINITIONS.                      * 00937020
*                                                                     * 00940020
*NOTES-  IKJEAT04 CAN NOT ISSUE PRIVILEGED INSTRUCTIONS.              * 00950020
*********************************************************************** 00960020
         EJECT                                                          00970020
CVTDSECT DSECT                                                          00980020
         CVT                                                            00990020
         SPACE                                                          01000020
SCVTD    DSECT                                                          01010020
         SCVT                                                           01020020
         SPACE                                                          01030020
         IKJTCB                                                         01040020
         SPACE                                                          01050020
         IKJTSCVT                                                       01060020
         SPACE                                                          01070020
         IKJRCB                                                         01080020
         SPACE                                                          01081020
         TAVTD                                                          01082020
         SPACE                                                          01083020
         TTSID                                                          01084020
         EJECT                                                          01090020
***************REGISTER EQUATES                                         01100020
*                                  WORK REGISTERS                       01110020
WR0      EQU   0                   *                                    01120020
WR1      EQU   1                   *                                    01130020
WR2      EQU   2                   *                                    01140020
WR3      EQU   3                   *                                    01150020
WR4      EQU   4                   *                                    01160020
WR5      EQU   5                   *                                    01170020
WR8      EQU   8                   WORK REGISTER                        01173020
WR11     EQU   11                  WORK REGISTER                        01176020
R0       EQU   0                                                        01179020
R1       EQU   1                                                        01182020
R2       EQU   2                                                        01185020
R3       EQU   3                                                        01188020
R4       EQU   4                                                        01191020
R5       EQU   5                                                        01194020
R6       EQU   6                                                        01197020
R7       EQU   7                                                        01200020
R8       EQU   8                                                        01203020
R9       EQU   9                                                        01206020
R10      EQU   10                                                       01209020
R11      EQU   11                                                       01212020
R12      EQU   12                                                       01215020
R13      EQU   13                                                       01218020
R14      EQU   14                                                       01221020
R15      EQU   15                                                       01224020
CVTR     EQU   3                   CVT ADDRESS REGISTER                 01227020
TSCVTR   EQU   7                   TSCVT ADDRESS REGISTER               01230020
RCBR     EQU   9                   RCB ADDRESS REGISTER                 01233020
DIECBR   EQU   10                  RCBDIECB ADDRESS REGISTER            01236020
BASE     EQU   12                  RETRY ROUTINE BASE REGISTER          01239020
         EJECT                                                          01242020
***************NUMERIC EQUATES                                          01260020
E0       EQU   0                   *                                    01270020
E4       EQU   4                   *                                    01280020
E8       EQU   8                   *                                    01290020
ZERO     EQU   0                   CONSTANT                             01291020
ONE      EQU   1                   CONSTA5T                             01292020
FOUR     EQU   4                   CONSTANT                             01293020
Q4       EQU   4                                                        01294020
Q12      EQU   12                                                       01295020
Q72      EQU   72                                                       01296020
****************GENERAL EQUATES                                         01300020
*                                  BYTE MASKS                           01310020
ALLFLAG  EQU   X'FF'               ALL BITS ARE SET                     01320020
NOFLAG   EQU   X'00'               NO BITS ARE SET                      01330020
*                                  ECB CODES                            01340020
*                                  SVC NUMBERS/DISP IN SVC TABLE        01350020
WAITBIT  EQU   X'80'               ECB WAIT BIT                         01360020
TSIPSVC  EQU   95                  TSIP SVC 95                          01370020
TSIPDISP EQU   TSIPSVC*4           DISP IN SVC TABLE TO TSIP            01380020
QTIPSVC  EQU   101                 QTIP SVC 101                         01390020
QTIPDISP EQU   QTIPSVC*4           DISP IN SVC TABLE TO QTIP            01400020
EXITSVC  EQU   3                   EXIT SVC 3                           01402020
X10      EQU   X'10'                                                    01404020
CVTTSREC EQU   X'40'                                                    01406020
AQPARMS  EQU   X'40'         OFFSET TO TCAM AQCTL PARAMETER LIST A44022 01407021
AQCTLSVC EQU   102           AQCTL SVC NUMBER                    A44022 01408021
         EJECT                                                          01410020
DIECBS   DSECT                                                          01426020
ECBLIST  DS    0F                                                       01430020
         EJECT                                                          01434020
IKJEAT04 CSECT                                                          01438020
****************************************************************        01442020
*     THIS IS THE FIRST LEVEL OF THE TS EXIT ROUTINE.                   01446020
*     FUNCTION:                                                *        01450020
*          1.TEST THE TS CVT ADDR FOR ZERO.                    *        01454020
*          2. IF ZERO, SPECIFY NO RETRY BY ZEROING REG 15      *        01458020
*             AND RETURN BY BRANCH REG 14                      *        01462020
*           3. SET TSO READY BIT TO ZERO                         A44022 01468021
*          4. SPECIFY RETRY WITH RB PURGE BY LOADING REG 15=4  *        01474020
****************************************************************        01478020
         USING *,R15                                                    01482020
         USING CVTDSECT,R3                                              01486020
         L     R3,CVTPTR     GET ADRS OF CVT                     A44022 01490021
         L     R4,CVTTSCVT         GET ADDR OF TS CVT                   01494020
         USING TSCVT,R4                                                 01498020
         LTR   R4,R4               IS ADDR ZERO                         01502020
         BZ    NORETRY       YES - DO NOT RETRY                  A44022 01506021
         NI    CVTTSFLG,255-CVTTSRDY RESET TSO READY BIT                01514020
         LA    R0,TSCRTRY1         GET ADDR OF RETRY 1                  01518020
         LA    R15,Q4              SPECIFY RETRY WITH RB PURGE          01522020
         BR    R14                 RETURN                               01526020
NORETRY  SR    R15,R15             SPECIFY NO RETRY                     01530020
EXIT     BR    R14                                                      01534020
         DROP  R15,R4,R3                                         A44022 01536021
         EJECT                                                          01538020
****************************************************************        01542020
*     THIS IS THE FIRST LEVEL OF THE TSC STAE RETRY ROUTINE.   *        01546020
*   IT IS ENTERED FROM ABEND.                                  *        01550020
*     FUNCTION:                                                *        01554020
*          1.  GETMAIN FOR A 18 WORD SAVE AREA CONSISTING OF     A44022 01560021
*                  18 WORD REGISTER SAVE AREA                    A44022 01566021
*          2. ISSUE STAE WITH TSCEXIT2 AS THE EXIT.            *        01574020
*          3. BRANCH AND LINK TO TSO DUMP - IKJEAT0,           *        01578020
****************************************************************        01586020
TSCRTRY1 EQU   *                                                        01590020
         BALR  R12,0                                                    01594020
         USING *,R12                                                    01598020
*              GET 18 WORD SAVE AREA IN SP 253                   A44022 01602021
         GETMAIN R,LV=72,SP=253                                  A44022 01606021
         LR    R13,R1        SET UP REG 13 WITH SAVE AREA        A44022 01610021
         STAE  TSCEXIT2,CT                                       A44022 01620021
         USING CVTDSECT,R3                                              01634020
         L     R3,CVTPTR     GET ADRS OF CVT                     A44022 01638021
         USING TSCVT,R7                                                 01642020
         L     R7,CVTTSCVT         GET ADDR OF TS CVT                   01646020
         L     R15,TSCVTT08        GET ADDR OF TSO DUMP                 01654020
         SR    R1,R1               INDICATE TO DUMP ALL                 01658020
         BALR  R14,R15             GO TO TSO DUMP                       01666020
         STAE  TSCEXIT3,OV   ESTABLISH STAE EXIT THREE           A44022 01667021
         LA    BASE,TSCRTRY2 SET UP BASE REG FOR RETRY TWO       A44022 01668021
         DROP  R12           DROP RETRY ONE'S BASE REG           A44022 01669021
         USING TSCRTRY2,BASE                                     A44022 01670021
         B     RTRY2A        ENTER RETRY TWO                     A44022 01671021
         DROP  BASE,R3,R7    DROP RETRY ONE'S REGISTERS          A44022 01672021
         EJECT                                                   A44022 01673021
****************************************************************        01673321
*     THIS IS THE SECOND LEVEL OF THE TS EXIT ROUTINE.         *        01673621
*     FUNCTION:                                                *        01673921
*          1. GET THE ADDR OF THE SECOND LEVEL OF THE TSC STAE *        01674221
*             RETRY ROUTINE.                                   *        01674521
*          2. SPECIFY RETRY WITH RB PURGE BY LOADING REG15=4   *        01674821
****************************************************************        01675121
TSCEXIT2 EQU   *                                                        01675421
         USING *,R15                                                    01675721
         LA    R0,TSCRTRY2   GET ADDRESS OF RETRY TWO            A44022 01676021
         LA    R15,Q4        INDICATE RETRY WITH RB CHAIN PURGE  A44022 01676321
         BR    R14           RETURN TO ABEND PROCESSING          A44022 01676621
         DROP  R15           DROP EXIT ROUTINE'S BASE REG        A44022 01676921
         EJECT                                                   A44022 01677221
****************************************************************        01677521
*     THIS IS THE THIRD  LEVEL OF THE TS EXIT ROUTINE.         *        01677821
*     FUNCTION:                                                *        01678121
*          1. GET THE ADDR OF THE THIRD LEVEL OF THE TSC STAE  *        01678421
*             RETRY ROUTINE.                                   *        01678721
*          2. SPECIFY RETRY WITH RB PURGE BY LOADING REG15=4   *        01679021
****************************************************************        01679321
TSCEXIT3 EQU   *                                                        01679621
         USING *,R15                                                    01679921
         LA    R0,TSCRTRY3   GET ADDRESS OF RETRY THREE          A44022 01680221
         LA    R15,Q4        INDICATE RETRY WITH RB CHAIN PURGE  A44022 01680521
         BR    R14           RETURN TO ABEND PROCESSING          A44022 01680821
         DROP  R15           DROP EXIT THREE'S BASE REG          A44022 01681121
         EJECT                                                          01682020
*********************************************************************** 01686020
*                                                                     * 01690020
*  THIS IS THE SECOND LEVEL TSC STAE RETRY ROUTINE.  IT RECEIVES      * 01694020
*  CONTROL IN ONE OF TWO WAYS:                                        * 01698020
*                                                                     * 01702020
*      1. FROM THE FIRST LEVEL TSC STAE RETRY ROUTINE IF TSO DUMP     * 01706020
*         PROCESSING COMPLETED.                                       * 01710020
*                                                                     * 01714020
*      2. FROM ABEND STAE INTERFACE ROUTINE                           * 01718020
*         IF A FAILURE OCCURS DURING PROCESSING IN THE FIRST LEVEL    * 01722020
*         TSC STAE RETRY OR DURING TSO DUMP PROCESSING (IKJEAT08).    * 01726020
*                                                                     * 01730020
*                                                                     * 01734020
*  FUNCTION:                                                          * 01738020
*      1. RE-ESTABLISH A STAE ENVIRONMENT TO COVER PROCESSING         * 01742020
*         DONE BY THIS ROUTINE.                                       * 01746020
*                                                                     * 01750020
*      2. POST TERMINAL I/O COORDINATOR TO NOTIFY USERS THAT TSO      * 01754020
*         HAS FAILED.                                                 * 01758020
*                                                                     * 01762020
*      3. POST EACH ACTIVE REGION THAT HAS NOT PREVIOUSLY DETECTED    * 01766020
*         AN UNRECOVERABLE ERROR INDICATING THE REGION SHOULD         * 01770020
*         TERMINATE.                                                  * 01774020
*                                                                     * 01778020
*      4. WAIT FOR ALL OF THE REGIONS TO STOP. THIS CONDITION WILL    * 01782020
*         BE SATISFIED ONLY IF ALL REGIONS TERMINATE.                 * 01786020
*                                                                     * 01790020
*      5. ZERO THE POINTER TO THE TSCVT IN THE CVT  (CVTTSCVT).       * 01794020
*                                                                     * 01798020
*      6. DETACH THE TSO MODIFY/STOP PROCESSING SUBTASK IF IT         * 01802020
*         EXISTS.                                                     * 01806020
*      7. RESTORE THE TSIP (SVC 95) AND QTIP (SVC 101) ENTRIES        * 01810020
*         IN THE SVC TABLE.                                           * 01814020
*                                                                     * 01818020
*      8. CHAIN THE TSO LPA TO THE TSC JOB PACK QUEUE.                * 01822020
*********************************************************************** 01826020
TSCRTRY2 EQU   *                   TSC SECOND LEVEL RETRY               01830020
         LR    BASE,R15            SET UP BASE REGISTER                 01834020
         USING TSCRTRY2,BASE       ESTABLISH ADDRESSABILITY             01838020
         STAE  TSCEXIT3,CT                                       A44022 01844021
RTRY2A   L     CVTR,CVTPTR   GET THE ADDRESS OF THE CVT          A44022 01849021
         USING CVTDSECT,CVTR                                            01854020
         L     WR8,CVTAQAVT        GET PTR TO TCAM CONTROL BLOCK        01858020
         LTR   WR8,WR8             Q IS THERE A TCAM CONTROL BLOCK?     01866020
         BNM   NOTCAM        NO - BYPASS POSTING TIOC            A44022 01870021
         L     WR8,ZERO(WR8)       GET ADDRESS OF TCAM AVT              01874020
         USING IEDQAVTD,WR8        ADDRESSABILITY FOR TCAM AVT          01878020
         L     WR8,AVTTSOPT        GET ADDR. OF TCAM ECB BLOCK          01882020
         DROP  WR8                                                      01886020
*****************************************************************A44022 01888021
*        TELL TIOC THAT TSO HAS FAILED AND IS GOING AWAY -- NOTE A44022 01890021
*        TSC ASSUMES THAT UPON RETURN FROM THIS SVC THAT TCAM HASA44022 01892021
*        FURTHER DEPENDANCIES UPON THE TSC REGION!!!!!!!!??????!!A44022 01894021
*****************************************************************A44022 01896021
         LA    WR1,AQPARMS(WR8)        GET ADDRESS OF AQCTL PARAMA44022 01898021
*                                      LIST                      A44022 01900021
         SVC   AQCTLSVC      ISSUE AQCTL SVC                     A44022 01902021
*********************************************************************** 01910020
*FORCE ALL RCT'S THAT ARE ACTIVE AND THAT HAVE NOT PREVIOUSLY         * 01914020
*ENCOUNTERED AN UNRECOVERABLE ERROR (RCBDEAD FLAG SET) TO             * 01918020
*TERMINATE BY POSTING RCBECB AFTER RCBFND FLAG IS SET.                * 01922020
*********************************************************************** 01926020
NOTCAM   L     TSCVTR,CVTTSCVT     GET ADDR. OF TSCVT                   01930020
         USING TSCVT,TSCVTR        ADDRESSABILITY FOR TSCVT             01934020
         LA    TSCVTR,ZERO(TSCVTR) ZERO HI ORDER BYTE                   01938020
         L     RCBR,TSCVTRCB       GET ADDRESS OF FIRST RCB             01942020
         LH    WR8,TSCVTCTR        GET NUMBER OF RCBHS                  01946020
         LR    WR11,WR8                                                 01950020
         SLL   WR11,2              GET LENGTH FOR ECB LIST              01954020
         GETMAIN  R,LV=(WR11),SP=253 GET SPACE FOR ECB LIST             01958020
         LR    WR2,R1                                                   01962020
         USING DIECBS,WR2                                               01966020
         LA    WR11,ECBLIST        GET ADDR. OF RCBDIECB LIST           01970020
         LA    WR5,ZERO            SET NUMBER OF ECBS TO ZERO           01974020
         USING RCB,RCBR            ADDRESSABILITY FOR RCB               01982020
DEADCK   TM    RCBFLG2,RCBACTV+RCBDEAD+RCBSTR2   IS THERE AN RCT A44022 01986021
         BZ    NEXTRCB       BRANCH IF NO RCT OR RCT TO BE       A44022 01990021
         TM    RCBFLG2,RCBDEAD         IS THE RCT DEAD ?         A44022 01994021
         BO    BUILDLST      BRANCH IF DEAD TO SKIP THE POST     A44022 01998021
         OI    RCBFLG,RCBFND       INDICATE TERMINATE RCT               02002020
         POST  RCBECB              POST RCT TO TERMINATE                02006020
BUILDLST LA    DIECBR,RCBDIECB     GET ADDR. OF EOT ECB                 02010020
         ST    DIECBR,ZERO(WR11)   PUT RCT EOT ECB IN WAIT LIST         02014020
         LA    WR11,FOUR(WR11)     STEP TO NEXT ECB SLOT                02018020
         LA    WR5,ONE(WR5)        INCREMENT COUNT OF ECBS TO WAIT ON   02022020
NEXTRCB  LA    RCBR,RCBEND         GET ADDRESS OF NEXT RCB              02026020
         BCT   WR8,DEADCK          ANOTHER RCB? YES-BRANCH              02030020
*                                               NO -FALL THROUGH        02034020
         DROP  RCBR                                              A44022 02034821
         LTR   WR5,WR5       ANY RCT'S DEAD OR ACTIVE            A43049 02035621
         BZ    NORCT         NO, BYPASS WAIT FOR RCT'S TO        A43049 02036421
*                            TERMINATE                           A43049 02037221
         S     WR11,WORD           BACK UP TO LAST ECB                  02038020
         OI    ZERO(WR11),X'80'    FLAG END OF LIST                     02042020
*********************************************************************** 02046020
*WAIT FOR ALL ACTIVE RCT'S TO TERMINATE.  IF ANY RCT'S HAVE           * 02050020
*ENCOUNTERED UNRECOVERABLE ERRORS THIS WAIT WILL NOT BE SATISFIED.    * 02054020
*********************************************************************** 02058020
         WAIT  (WR5),ECBLIST=ECBLIST                                    02062020
         LA    WR11,ECBLIST  GET THE ADDRESS OF THE ECB LIST     A44022 02062421
DIECHK   L     WR8,ZERO(WR11)          GET ECB ADDRESS FROM LIST A44022 02062821
         L     WR8,ZERO(WR8) GET POST CODE FROM THE ECB          A44022 02063221
         LA    WR8,ZERO(WR8) CLEAR OUT THE POST BIT              A44022 02063621
         C     WR8,WORD      IS POST CODE FROM THE RCT DIE ROUTINA44022 02064021
         BE    LOCKUP        BRANCH IF ANY RCTS HAVE DIED        A44022 02064421
         LA    WR11,FOUR(WR11)         BUMP DOWN THE ECB LIST    A44022 02064821
         BCT   WR5,DIECHK    HAVE WE FINISHED THE LIST YET       A44022 02065221
         DROP  WR2                                               A44022 02105221
         EJECT                                                          02150020
*********************************************************************** 02160020
*RESTORE SVC TABLE FOR TSIP(SVC 95) AND QTIP(SVC 101)                 * 02170020
*TSCVTSVT AND TSCVTSVQ ARE SVC TABLE ENTRIES PRIOR TO START TSO       * 02180020
*********************************************************************** 02190020
         USING SCVTD,WR2           SECONDARY CVT                        02200020
NORCT    EQU   *                                                 A44022 02206021
         L     WR2,CVTABEND  GET ADDRESS OF SECONDARY CVT        A44022 02212021
         L     WR5,SCVTSVCT  ADRS OF SVC TABLE                   A44022 02222021
         LA    WR4,TSIPDISP(WR5)       ADRS TSIP ENTRY           A44022 02232021
         MVC   E0(E4,WR4),TSCVTSVT RESTORE TSIP FROM TSCVT              02250020
         LA    WR4,QTIPDISP(WR5)       ADDRESS OF QTIP ENTRY     A44022 02260021
         MVC   E0(E4,WR4),TSCVTSVQ RESTORE QTIP FROM TSCVT              02270020
*********************************************************************** 02271021
*DETACH THE TSO MODIFY/STOP SUBTASK (IKJEAT06) IF IT EXISTS.          * 02272021
*********************************************************************** 02273021
         L     WR5,TSCVTT06        GET ADDR. OF T06 TCB                 02274021
         LTR   WR5,WR5             Q ANY MODIFY/STOP SUBTASK?           02275021
         BZ    T04END        IF NO SUBTASK WE ARE DONE           A44022 02276021
         LA    R1,TSCVTT06         ADDRESS FOR DETACH                   02336021
         DETACH (1)                DETACH  IKJEAT06                     02396021
T04END   XC    CVTTSCVT,CVTTSCVT       MAKE TSO STARTABLE AGAIN  A44022 02456021
         EJECT                                                          02550020
         SVC   EXITSVC       RETURN TO STC                       A44022 02552021
         EJECT                                                          02554020
LOCKUP   L     WR2,CVTABEND  GET ADDRESS OF SECONDARY CVT        A44022 02556021
         L     WR5,SCVTSVCT  GET THE ADDRESS OF THE SVC TABLE    A44022 02558021
         MVC   TSIPDISP(E4,WR5),TSCVTSVT         RESET TSIP ENTRYA44022 02560021
         MVC   QTIPDISP(E4,WR5),TSCVTSVQ         RESET QTIP ENTRYA44022 02562021
         XC    CVTTSCVT,CVTTSCVT       MAKE TSO STARTABLE AGAIN  A44022 02564021
         LA    R12,RTRY3A    SET UP BASE REG FOR RETRY THREE     A44022 02566021
         DROP  BASE                                              A44022 02568021
         USING RTRY3A,R12                                        A44022 02570021
         B     TSOND         ENTER RETRY THREE                   A44022 02572021
         DROP  WR2,R12,CVTR,TSCVTR                               A44022 02574021
         EJECT                                                          02580020
****************************************************************        02582020
*     THIS IS THE THIRD LEVEL OF THE TS RETRY ROUTINE                 * 02584020
*     FUNCTION:                                                *        02586020
*        1. INFORM THE OPERATOR THAT TSC HAS FAILED AND TSO IS        * 02588020
*           NON-DISPATCHABLE.                                         * 02590020
*        2. SET TSO NON-DISPATCHABLE.                                 * 02592020
*        3. ISSUE WAIT.                                               * 02594020
****************************************************************        02596020
TSCRTRY3 EQU   *                                                        02598020
         BALR  R12,0                                                    02600020
         USING *,R12                                                    02602020
         USING CVTDSECT,R3                                              02604020
RTRY3A   L     R3,CVTPTR     GET ADDRESS OF THE CVT              A44022 02606021
         TM    CVTTSFLG,CVTTSREC   IS THIS FIRST ENTRY                  02608020
         BO    TSOND               NO - DO NOT TRY WTO                  02610020
         OI    CVTTSFLG,CVTTSREC   INDICATE WTO HAS BEEN TRIED          02612020
         STAE  TSCEXIT3,CT   REESTABLISH STAE EXIT THREE         A44022 02615021
         WTO   'IKJ023I - TSC RECOVERY FAILED - TSO NON-DISPATCHABLE', *02618020
               ROUTCDE=(2),DESC=4                                       02620020
TSOND    EQU   *                                                        02622020
         L     R7,ZERO(R3)         GET ADDR. OF NEW OLD                 02624020
         USING TCB,R4                                                   02626020
         L     R4,FOUR(R7)         GET TSC TCB ADDR                     02628020
         OI    TCBNDSP1,TCBDARPN   SET TSO NON-DISPATCHABLE             02630020
         OI    TCBFLGS5,TCBPNDSP   SET PRIMARY NON-DISPATCHABILITY BIT  02632020
         LA    R2,HOLDECB          GET ADDR OF ECB                      02634020
         WAIT  ECB=(2)                                                  02636020
         EJECT                                                          02670020
WORD     DC    F'4'                                              A44022 02700021
HOLDECB  EQU   WORD          ECB FOR MAKING TSC NONDISPATCHABLE  A44022 02730021
         END                                                            02770020
