         TITLE 'IKJEAT05  TSO/TSC ETXR ROUTINE FOR RCT'                 00020020
IKJEAT05 START                                                          00030020
*********************************************************************** 00040020
*D015160-018200                                        MP/TSO AJ A53356 00042021
*STATUS  =0                                                      20021* 00050020
*                                                                     * 00060020
*FUNCTION-TSC'S ETXR ROUTINE FOR AN RCT                               * 00070020
*        IKJEAT05 IS SPECIFIED AS THE EXTR ROUTINE FOR AN RCT WHEN AN * 00080020
*        RCT IS ATTACHED BY THE TSC.                                  * 00090020
*        RECEIVES CONTROL WHEN AN RCT TCB IS TERMINATING.             * 00100020
*                                                                     * 00130020
*        IKJEAT05:                                                    * 00140020
*                                                                     * 00141020
*        RETURNS THE PROTECTION KEY FOR THE REGION TO THE MASTER      * 00142020
*        SCHEDULER RESIDENT DATA AREA                                 * 00144020
*                                                                     * 00145020
*        REINITIALIZES RXLQE AND RCB                                  * 00181020
*                                                                     * 00182020
*        ISSUES MESSAGE THAT REGION HAS TERMINATED                    * 00183020
*                                                                     * 00184020
*        ISSUES DETACH FOR THE RCT TCB.                               * 00190020
*                                                                     * 00200020
*ENTRY POINTS- IKJEAT05                                               * 00210020
*                                                                     * 00220020
*INPUT-  REG   1    ADDR. OF TCB OF TERMINATING RCT                   * 00230020
*        REG   13   ADDR. OF SAVE AREA                                * 00240020
*        REG   14   RETURN ADDR.                                      * 00250020
*        REG   15   ADDR. OF EP - IKJEAT05                            * 00260020
*OUTPUT-NONE                                                          * 00270020
*                                                                     * 00280020
*EXTERNAL REFERENCES-                                                 * 00290020
*        FREEMAIN/DETACH                                              * 00300021
*                                                                     * 00310020
*EXIT-   RETURN TO CALLER                                             * 00320020
*                                                                     * 00330020
*EXIT ERROR-NONE                                                      * 00340020
*                                                                     * 00350020
*TABLES/CONTROL BLOCKS/WORK AREAS                                     * 00360020
*        CVT, TCB, PQE, FBQE, TSCVT, RCB                              * 00370020
*                                                                     * 00380020
*ATTRIBUTES-RESIDENT IN TSO CONTROL REGION. REFRESHABLE, RE-ENTERANT, * 00390020
*        SUPERVISOR STATE.                                            * 00400020
*                                                                     * 00410020
*CHARACTER CODE DEPENDENCY - THE OPERATION OF THIS MODULE DEPENDS     * 00411020
*        UPON AN INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER    * 00412020
*        SET WHICH IS EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME.    * 00413020
*        THE CODING HAS BEEN ARRANGED SO THAT REDEFINITION OF         * 00414020
*        'CHARACTER' CONSTANTS, BY REASSEMBLY, WILL RESULT IN A       * 00415020
*        CORRECT MODULE FOR THE NEW DEFINITIONS.                      * 00416020
*                                                                     * 00417020
*NOTES-  IKJEAT05 CAN NOT ISSUE PRIVILEGED INSTRUCTIONS.              * 00420020
*********************************************************************** 00430020
         EJECT                                                          00440020
CVTDSECT DSECT                                                          00450020
         CVT                                                            00460020
         SPACE                                                          00470020
         IKJTCB                                                         00480020
         SPACE                                                          00490020
         IKJPQE                                                         00500020
         SPACE                                                          00510020
         IKJTSCVT                                                       00520020
         SPACE                                                          00530020
         IKJRCB                                                         00540020
         SPACE 3                                                        00550020
         IEEBASEA                                                       00560020
         SPACE 3                                                        00570020
SCVTSECT DSECT                          DSECT LABEL FOR SCVT            00580020
         SCVT                                                           00590020
         SPACE 3                                                        00600020
         IKJRXL                                                         00610020
         EJECT                                                          00620020
         IKJRXLQE                                                       00630020
RXLQEND  EQU   *-RXLQE                 FIND LENGTH RXLQE                00640020
         SPACE 3                                                        00650020
         IKJECBS                                                        00651020
         SPACE 3                                                        00652020
WORKAREA DSECT                         LABEL FOR WORKAREA DSECT         00660020
RCTPACK  DS    2F                      AREA FOR CONVERTING REGION NO.   00670020
RCTWTO   DS    13F                     WORK AREA FOR WTO MANIPULATING   00680020
REGNO    EQU   RCTWTO+32               DISP TO REG NO. IN WORK AREA     00690020
RCTWKEND EQU   *-WORKAREA              FIND DSECT LENGTH                00700020
         EJECT                                                          00710020
****************REGISTER EQUATES                                        00720020
*                                      WORK REGISTERS                   00730020
WR0      EQU   0                       *                                00740020
WR1      EQU   1                       *                                00750020
WR2      EQU   2                       *                                00760020
WR3      EQU   3                       *                                00770020
WR4      EQU   4                       *                                00780020
WR5      EQU   5                       *                                00790020
*                                                                       00800020
PQER     EQU   6                       ADDR. OF PQE                     00810020
TSCTCBR  EQU   7                       ADDR. OF TSC TCB                 00820020
RCTTCBR  EQU   8                       ADDR. OF RCT TCB                 00830020
RCBR     EQU   9                       ADDR. OF RCB                     00840020
TSCVTR   EQU   10                      ADDR. OF TSCVT                   00850020
CVTR     EQU   11                      ADDR. OF CVT                     00860020
BASER    EQU   12                      ADDR. OF BASE                    00870020
****************NUMERIC EQUATES                                         00910020
E0       EQU   0                       *                                00920020
E1       EQU   1                       *                                00930020
E2       EQU   2                       *                                00940020
E4       EQU   4                       *                                00950020
E5       EQU   5                       *                                00960020
E7       EQU   7                       *                                00970020
E8       EQU   8                       *                                00980020
E19      EQU   19                      *                                00990020
****************GENERAL EQUATES                                         01000020
DECFLAG  EQU   X'0F'                   MASK INSURE REGION NO. DEC       01010020
ALLFLAG  EQU   X'FF'                   ALL BITS ARE SET                 01020020
         EJECT                                                          01030020
IKJEAT05 CSECT                                                          01040020
*********************************************************************** 01050020
*IKJEAT05 INIT. SAVE REGISTERS. GET ADDR. OF OS/CVT AND TS/CVT.       * 01060020
*********************************************************************** 01070020
         SAVE  (14,12)                 SAVE THE CALLER'S REGISTERS      01080020
         BALR  BASER,0                 EST. ADDRESSABILITY              01090020
         USING *,BASER                 *                                01100020
         LR    RCTTCBR,WR1             SAVE RCT TCB ADDR.               01110020
         USING CVTDSECT,CVTR           CVT                              01120020
         USING TSCVT,TSCVTR            TS CVT                           01130020
         L     CVTR,CVTPTR             ADDR. OF OS CVT                  01140020
         L     TSCVTR,CVTTSCVT         ADDR. OF TSCVT                   01150020
         L     TSCTCBR,TSCVTTSC        ADDR. OF TSC TCB                 01160020
*********************************************************************** 01170020
*FIND THE RCB FOR THIS RCT. SEARCH RCB'S BY RCT TCB ADDR.             * 01180020
*********************************************************************** 01190020
         USING RCB,RCBR                RCB                              01200020
         L     RCBR,TSCVTRCB           ADDR. OF FIRST RCB               01210020
T05SR00  C     RCTTCBR,RCBRCT          TCB ADDR. EQUAL?                 01220020
         BE    T05SR01                 YES, FOUND IT.                   01230020
         LA    RCBR,RCBEND             ADDR. OF NEXT RCB                01240020
         B     T05SR00                 TO TOP                           01250020
*********************************************************************** 01260020
*DETERMINE IF KEY OBTAINED                                            * 01270020
*********************************************************************** 01280020
T05SR01  SR    WR1,WR1                 INIT REG                         01290020
         IC    WR1,RCBPKEY             GET REGION PROTECT KEY           01300020
         LTR   WR1,WR1                 IS THERE A KEY?                  01310020
         BZ    T05SR01A                NO, CHECK IF REGION OBTAINED     01320020
         SRL   WR1,E4                  KEY TO RIGHT FOR PROCESSING      01330020
         LA    WR3,E1                  GET A ONE                        01340020
         SLL   WR3,E0(WR1)             SHIFT LEFT TO GET MASK           01350020
         L     WR2,CVTMSER             ADDR MS RESIDENT DATA AREA       01360020
         USING BASE,WR2                BASE FOR DSECT                   01370020
         EX    WR3,KEYOFF1             SWITCH OFF THIS HALF             01380020
         SRL   WR3,E8                  SHIFT MASK                       01390020
         EX    WR3,KEYOFF2             SWITCH OFF THIS HALF             01400020
         B     T05SR01A                CONTINUE PROCESSING              01410020
KEYOFF1  XI    BARSW+E5,E0             TURN OFF LEFT HALF KEY           01420020
KEYOFF2  XI    BARSW+E4,E0             TURN OFF RIGHT HALF KEY          01430020
         DROP  WR2                     DROP WORK REGISTER               01440020
*********************************************************************** 01450020
*GET ADDR. OF DUMMY PQE FROM RCB FOR THIS RCT.                        * 01460020
*********************************************************************** 01470020
T05SR01A L     PQER,RCBPQE             ADDR DUMMY PQE FOR USER REGION   01480020
         LTR   PQER,PQER               IS THERE A PQE IN THE RCB        01490020
         BZ    T05SR03A                NO, DETACH ONLY                  01500020
         SPACE 3                                                        01500421
**********************************************************************  01502021
         EJECT                                                          01502421
         SPACE 3                                                        01502521
*********         ***********          ********       *******           01502821
*****                                                      ******       01503221
*****    THIS IS THE BEGINNING OF THE SECTION OF CODE      ******       01503621
*****         MOVED TO R01 FOR MP/TSO CHANGES              ******       01503721
*****                APAR 53356                            ******       01503821
*************          *********          ******      *******           01503921
         SPACE 3                                                        01507921
*********************************************************************** 01516021
*BUILD AN FBQE FOR ENTIRE REGION FOR THIS PQE AT START OF REGION      * 01520020
*********************************************************************** 01530020
*        USING PQESECT,PQER            PQE                              01540021
*T05SR02  L     PQER,PQEFPQE            ADDR. OF PQE                    01550021
*        L     WR1,PQEREGN             ADDR. OF START OF REGION         01560021
*        ST    PQER,E0(WR1)            ADDR. OF PQE IN FBQE             01570021
*        ST    PQER,E4(WR1)            ADDR. OF PQE IN FBQE             01580021
*        MVC   E8(E4,WR1),PQESIZE      SIZE OF REGION IN FBQE           01590021
*        ST    WR1,PQEFFBQE            ADDR. OF FBQE IN PQE             01600021
*        ST    WR1,PQEBFBQE            ADDR. OF FBQE IN PQE             01610021
*        ST    TSCTCBR,PQETCB          ADDR. OF TSC TCB TO PQE          01620021
*        L     PQER,PQEFPQE            ADDR. OF NEXT PQE                01630021
*        LTR   PQER,PQER               ANOTHER PQE?                     01640021
*        BNZ   T05SR02                 YES, TO TOP                      01650021
*                                      NO                               01660020
*        EJECT                                                          01670021
*********************************************************************** 01680020
*ISSUE FREEPART FOR THIS PART USING TSC TCB.                          * 01690020
*********************************************************************** 01700020
*        USING TCB,TSCTCBR             TCB                              01710021
*        L     WR5,TCBPQE              PQE ADDR FOR TSC CONTROL REGION  01720021
*        L     WR4,TCBMSS              ADDR TSC'S SPQE CHAIN            01730021
*        NI    TCBJPQ,ALLFLAG-TCBJPQF  CLEAR JPQ PURGE FLAG             01740021
*        L     PQER,RCBPQE             ADDR PQE FOR USER REGION         01750021
*        ST    PQER,TCBPQE             TO TSC'S TCB                     01760021
*        XC    TCBMSSB,TCBMSSB         ZERO PTR TO TSC'S SPQE CHAIN     01770021
*        GETMAIN R,LV=8,SP=252         SUBPOOL 252 FOR FREEPART         01782021
*        FREEMAIN  R,SP=247            FREEPART                         01790021
*        L     WR1,TCBMSS              GET SPQE PTR FROM TCB      M1412 01792021
*        FREEMAIN R,LV=8,SP=255,A=(1)  FREE SPQE                  M1412 01794021
*        ST    WR5,TCBPQE              RESTORE TSC PQE IN TSC TCB       01800021
*        ST    WR4,TCBMSS              RESTORE SPQE PTR                 01810021
*        DROP  TSCTCBR                 TO TSC TCB                       01820021
**********************************************************************  01820421
         SPACE 3                                                        01822021
**********        **********         ********     *******               01824021
****                                                    ******          01826021
****        THIS ENDS THE SECTION OF CODE MOVED TO R01  ******          01828021
****                FOR MP/TSO CHANGES                  ******          01828421
****                     APAR 53356                     ******          01828821
***********        *************          **************                01829221
         EJECT                                                          01829621
*********************************************************************** 01830020
*DETERMINE RXLQE ADDR AND REINITIALIZE BLOCK                          * 01840020
*********************************************************************** 01850020
T05SR03  L     WR2,CVTABEND            ADDR SCVT                        01860020
         USING SCVTSECT,WR2            BASE FOR SCVT                    01870020
         L     WR4,SCVTRXLQ            ADDR CHAIN RECOVERY BLOCKS       01880020
         USING RXL,WR4                 *                                01890020
         L     WR4,RXLRXLQ             ADDR RXLQE                       01900020
         USING RXLQE,WR4               *                                01910020
         LA    WR3,E1                  WILL SET UP TO SKIP 1ST 2 BLOCKS 01920020
         SR    WR5,WR5                 INIT REG                         01930020
         IC    WR5,RCBNMBR             REGION NUMBER                    01940020
         AR    WR5,WR3                 SET UP DISP IN CHAIN             01950020
         LA    WR3,RXLQEND             SIZE RXLQE                       01960020
         SR    WR2,WR2                 INIT LEFT HALF REGISTER PAIR     01961020
         MR    WR2,WR5                 DISP RXLQE CHAIN                 01970020
         AR    WR4,WR3                 DISP PLUS START CHAIN = ADDR     01980020
         USING RXLQE,WR4               BASE FOR RXLQE                   01990020
         XC    RXLQCBLK(E19),RXLQCBLK  CLEAR OUT BLOCK EXCEPT FOR FLAG  02000020
         NI    RXLQFLG1,ALLFLAG-RXLQFACV INDICATE RXLQE NOT ACTIVE      02002020
*********************************************************************** 02010020
*WRITE MESSAGE INDICATING REGION TERMINATED                           * 02020020
*********************************************************************** 02030020
         LA    WR0,RCTWKEND            LENGTH WORK AREA                 02040020
         GETMAIN R,LV=(0)              GET WORK AREA                    02050020
         LR    WR3,WR1                 SET UP REG                       02060020
         USING WORKAREA,WR3            BASE FOR WORKAREA DSECT          02070020
         XC    E0(RCTWKEND,WR1),E0(WR1) CLEAR AREA                      02080020
         MVC   RCTWTO(MSG1LNTH),MSG1   MOVE MSG TO WORK AREA            02090020
         SR    WR2,WR2                 INIT REG                         02100020
         IC    WR2,RCBNMBR             GET REGION NO                    02110020
         LA    WR1,RCTPACK             AREA TO UNPACK REGION NUMBER     02120020
*                                      CONVERT REGION NO TO DECIMAL     02130020
         CVD   WR2,E0(WR1)             FOR EVENTUAL INSERTION IN MSG    02140020
         OI    E7(WR1),DECFLAG         INSURE NUMBER READABLE           02150020
         UNPK  REGNO(E2),RCTPACK+E4    PLACE NO. IN MSG                 02160020
         SR    WR0,WR0                 INIT REG                         02161020
         IC    WR0,RCBCONID            GET CONSOLE ID FOR MESSAGE       02162020
         LA    WR1,RCTWTO              ADDR OF MESSAGE                  02170020
         WTO   MF=(E,(1))              WRITE MSG REGION TERMINATED      02180020
         LR    WR1,WR3                 SET UP TO FREE WORK AREA         02190020
         LA    WR0,RCTWKEND            LENGTH WORK AREA                 02200020
         FREEMAIN  R,LV=(0),A=(1)      FREE UP WORK AREA                02210020
         NI    RCBFLG2,ALLFLAG-RCBACTV INDICATE REGION NOT ACTIVE       02220020
*********************************************************************** 02230020
*DETACH THE RCT TCB.                                                  * 02240020
*********************************************************************** 02250020
T05SR03A LA    WR1,RCBRCT          GET ADR RCT TCB               A42839 02257021
         DETACH (1)                DETACH RCT                    A42839 02264021
         XC    RCBRCT,RCBRCT       CLEAR ADR RCT TCB             A42839 02271021
         XC    RCBEXTNT,RCBEXTNT   ADR TJBX                      A42839 02278021
         XC    RCBPQE,RCBPQE       ADR PQE FOR REGION                   02285021
         XC    RCBTJID,RCBTJID     CLEAR TJID                    A42839 02292021
         MVI   RCBPKEY,E0          CLEAR PROTECT KEY             A42839 02299021
         NI    RCBFLG,ALLFLAG-RCBFND RESET RCT END FLG           A42839 02306021
         L     WR2,TSCVTECB        ADR ECB TABLE                 A42839 02313021
         USING TSECB,WR2           SET UP ADDRESSABILITY         A42839 02320021
         TM    RCBFLG2,RCBSTR1+RCBSTR2 ARE STOP/START ON         A42839 02327021
         BO    START               YES BRANCH                    A42839 02334021
         TM    RCBFLG2,RCBMODFY    IS MODIFY IN PROGREESS FOR    A42839 02341021
*                                  REGION TO STOP                A42839 02348021
         BNO   EXIT                NO RETURN                     A42839 02355021
         POST  TSCECB4             YES TELL T06 MODIFY COMPLETE  A42839 02362021
         B     EXIT                RETURN                        A42839 02369021
START    POST  TSCECB              POST T03 OUT OF WAIT          A42839 02376021
EXIT     RETURN (14,12),RC=0                                            02383021
*********************************************************************** 02390020
         EJECT                                                          02400020
****************CONSTANTS                                               02410020
MSG1     WTO   'IKJ051I TIME SHARING REGION    HAS TERMINATED',MF=L,   X02420020
               MCSFLAG=REG0                                             02421020
MSG1LNTH EQU   *-MSG1                  LENGTH OF MESSAGE                02430020
         END                                                            02440020
