         TITLE 'IKJEAT06 TSO/TSC SUB-TASK FOR OPERATOR COMMANDS'        00040020
IKJEAT06 START                                                          00080020
*********************************************************************** 00120020
*STATUS  =0                                                      20021* 00160020
*                                                                       00170021
*A200500,204700-204900,205700,207200,231254-231272,231281,       A42839 00180021
*A231299-231326,234400,287900-298400,299900,300500,303200-308000,A42839 00190021
*A372800,377600,530000,536500-536600,573400,587800-588000,       A42839 00192021
*A591000,620548,620667,620724,                                   A42839 00194021
*A787090,789400,794000,799600,806400,812000,816400,824100,        M1593 00196021
*828400,832800,839300,847040,847193,895197,                       M1593 00198021
*A412900,413000,413100                                        CC A67860 00198121
*C413200                                                      CC A67860 00198221
*A138300,160100,160200,751694-751718,781800                   CC A69344 00198421
*                                                                     * 00198621
*                                                                     * 00198821
*                                                                     * 00199021
*                                                                     * 00199221
*                                                                     * 00199421
*FUNCTION-TSC SUBTASK FOR OPERATOR STOP/MODIFY TSO COMMANDS.          * 00200020
*        SUBTASK WAITS ON ECB'S FOR WORK.  IF THE CPL ECB IS POSTED,  * 00240020
*        THE OPERATOR HAS ISSUED EITHER STOP TSO OR MODIFY TSO AND    * 00280020
*        A CIB FOR STOP OR MODIFY EXISTS.                             * 00320020
*        IF TSCECB1 IS POSTED, TSC MAIN TASK HAS DETERMINED THAT THE  * 00360020
*        THE TERMINAL ACCESS HAS FAILED, AND WANTS THE STOP TSO       * 00400020
*        SEQUENCE TO BE INITIATED.                                    * 00440020
*                                                                     * 00480020
*        STOP TSO  1) CIB VERB CODE IS STOP  OR  2) TSCECB1 IS POSTED * 00520020
*                                                                     * 00560020
*        THE TSC SUB TASK INITIATES THE STOP TSO SEQUENCE.            * 00600020
*        1)  SET THE CURRENT LIMIT OF USERS ON TSO(TSCVTLUS) TO ZERO. * 00640020
*        2)  FOR EACH ACTIVE RCT, INVOKE FORCE LOGOFF(IKJEAL00) TO    * 00680020
*            FORCE THE LOG OFF OF ALL USERS CURRENTLY ON TSO.         * 00720020
*        3) ISSUE SMF RECORD 42 IF SMF IS ACTIVE.                     * 00760020
*        4)  TELL THE OPERATOR THAT TSO IS STOPPING.                  * 00800020
*        5)  PSOT TSCECB TO TELL TSC MAIN TASK THAT TSO IS STOPPING.  * 00840020
*        6)  SUB TASK TERMINATES ITSELF BY RETURNING TO CALLER.       * 00880020
*                                                                     * 00920020
*        MODIFY   1) CIB VERB CODE IS MODIFY                          * 00960020
*                                                                     * 01000020
*        THE MODIFY TSO COMMAND MAY BE ISSUED BY EITHER               * 01040020
*        1) OS/360 CONSULE OPERATOR.  THE SUB TASK WILL USE WTO/WTOR  * 01080020
*        TO COMMUNICATE.  COMMUNICATION WILL BE USED TO RESOLVE       * 01120020
*        ANY ERRORS THAT MAY EXIST IN THE MODIFY DATA IN THE CIB.     * 01160020
*        2)  TSO TERMINAL IN THE OPERATOR MODE.  ONLY TPUT MAY BE     * 01200020
*        MAY BE USED TO COMMUNICATE WITH THE TSO TERMINAL.  ANY ERROR * 01240020
*        IN THE MODIFY DATA MUST BE CONSIDERED FATAL AND NO ATTEMPT   * 01280020
*        IS MADE TO CONTINUE THE MODIFY OF TSO.                       * 01320020
*                                                                     * 01360020
*        A MODIFY WORK AREA(LOCAL WORK AREA) IS OBTAINED AND THE CIB  * 01400020
*        IS SCANED FOR VALID KEYWORDS.  KEYWORD HANDLING ROUTINES     * 01440020
*        ARE INVOKED TO EXAMINE THE DATA WITH THE KEYWORD.  IF THE    * 01480020
*        DATA IS VALID AND TSO MAY BE MODIFIED, THE CHANGES TO TSO    * 01520020
*        ARE STORED IN THE MODIFY WORK AREA.  WHEN THE SCAN OF THE    * 01560020
*        CIB IS COMPLETE AND THE MODIFY OF TSO IS VALID, THE MODIFY   * 01600020
*        WORK AREA IS CHECKED AND THE ACTUAL CHANGES ARE MADE.        * 01640020
*        AFTER TSO IS MODIFIED, THE WORK AREA IS RELEASED.            * 01680020
*                                                                     * 01720020
*        IF KEYWORDS AND/OR DATA ARE INVALID,  COMMUNICATION WITH THE * 01760020
*        OPERATOR IS USED TO CORRECT THE ERRORS.  THE OPERATOR HAS    * 01800020
*        THREE OPTIONS  1) 'KEYWORD=VALUE'  2) 'U' TO IGNORE          * 01840020
*        THIS KEYWORD AND DATA, 3) 'CANCEL' TO CANCEL THE MODIFY      * 01880020
*        IF THE OPERATOR IS AT A TSO TERMINAL, ONLY TPUT IS USED      * 01920020
*        AND THE MODIFY IS REJECTED AT THE FIRST ERROR.               * 01960020
         EJECT                                                          02000020
*        VALID MODIFY KEYWORDS ARE:                                   * 02040020
*        USERS   SUBMIT   REGSIZE   SMF   DRIVER   HOLD               * 02080020
*                                                                     * 02120020
*                                                                     * 02160020
*                                                                     * 02200020
*        USERS=NNNNN   TO CHANGE THE CURRENT LIMIT OF USERS ALLOWED   * 02240020
*        ON TSO(TSCVTLUS) AND MAY NOT EXCEED THE MAXIMUM LIMIT OF     * 02280020
*        USERS ON TSO(TSCVTMUS)                                       * 02320020
*        IF CURRENT NUMBER OF USERS ON TSO(TSCVTCUS) EXCEEDS NEW      * 02360020
*        LIMIT OF USERS ON TSO, NO ATTEMPT IS MADE TO FORCE USERS     * 02400020
*        TO LOGOFF SO THAT TSCVTCUS IS LESS THAN OR EQUAL TO TSCVTLUS * 02440020
*        TSCVTLUS AND TSCVTMUS ARE IN THE TSO CVT                     * 02480020
*                                                                     * 02520020
*                                                                     * 02560020
*                                                                     * 02600020
*        SUBMIT=NNNNN  TO CHANGE THE MAXIMUM NUMBER OF LOGICAL TRACKS * 02640020
*        RESERVED IN JOB QUEUE FOR FOREGROUND INITIATED BACKGROUND    * 02680020
*        JOBS.  NNNNN IS THE MAXIMUM NUMBER OF RESERVED TRACKS        * 02720020
*        (QMFIBMAX) AND MAY NOT EXCEED A SYSGEN/IPL LIMIT(QMFIBLIM).  * 02760020
*        QMFIBMAX AND QMFIBLIM IN QUEUE MANAGER RESIDENT DATA AREA.   * 02800020
*                                                                     * 02840020
*                                                                     * 02880020
*                                                                     * 02920020
*        REGSIZE(RN)=(XXXXXK,YYYYYK) MODIFY TSO USER REGIONS.         * 02960020
*        RN IS THE REGION NUMBER.  XXXXXK IS THE SIZE OF THE REGION   * 03000020
*        AND YYYYYK IS LOCAL SQS SIZE IN 1024 BYTE BLOCKS.            * 03040020
*        YYYYY MAY NOT EXCEED XXXXX AND XXXXX MAY NOT EXCEED 16384    * 03080020
*        IF XXXXXK AND YYYYYK ARE ZERO AND THE REGION IS ACTIVE, THE  * 03120020
*        REGION IS STOPPED.                                           * 03160020
*        IF XXXXXK AND YYYYYK ARE NOT ZERO AND THE REGION IS INACTIVE,* 03200020
*        THE REGION IS STARTED.                                       * 03240020
*        IF XXXXXK AND YYYYYK ARE NOT ZERO AND THE REGION IS ACTIVE,  * 03280020
*        THE REGION IS STOPPED AND STARTED.                           * 03320020
*        TO STOP A REGION,  SET TSCRSTOP,RCBSTOP, INVOKE FORCE LOGOFF * 03360020
*        (IKJEAL00), ISSUE TSEVENT(RGNFAIL) AND POST TSCECB.          * 03400020
*        TO START A REGION, SET TSCRSTOP. RCBSTR1, RCBSTR2, SETS      * 03440020
*        RCBRSIZE AND RCBLSQSZ, AND POST TSCECB                       * 03480020
*                                                                     * 03520020
*                                                                     * 03530020
*        SMF=(PARM1,PARM2)  TO MODIFY FOREGROUND OPTIONS AND USE OF   * 03560020
*        EXITS TO INSTALLATION ROUTINES WHERE                         * 03600020
*        PARM1 MAY BE  OFF,  OPT=1,  OPT=2, OR DEFAULT TO CURRENT     * 03640020
*        BACKGROUND OPTIONS.  SMCAOPT1 AND SMCAOPT2 IN SMCAOPT.       * 03680020
*        PARM2 MAY BE   EXT=YES,  EXT=NO, OR DEFAULT TO CURRENT       * 03720020
*        BACKGROUND OPTIONS.  SMCAEXT IN SMCAOPT.                     * 03760020
*        PARM1 AND PARM2 MAY NOT EXCEED THE CURRENT SMF OPTIONS FOR   * 03800020
*        FOR BACKGROUND.                                              * 03840020
*        FOREGROUND OPTIONS ARE SET IN SMCAFOPT.                      * 03880020
*        SMCAOPT AND SMCAFOPT IN THE SYSTEM MANAGEMENT CONTROL AREA   * 03920020
*                                                                     * 03960020
*                                                                     * 04000020
*                                                                     * 04040020
*        DRIVER=(PARAMETER)  TO MODIFY THE TSO DRIVER                 * 04080020
*        INVOKE IKJEAD03 OR ITS EQUIVIALENT(ADDR. OF ROUTINE AT       * 04120020
*        TSCVTD03). PASS A PARMATER LIST DESCRIBING THE INPUT.        * 04160020
*        NO ATTEMPT TO VERIFY THE DATA OR COMMUNICATE WTIH THE        * 04200020
*        OPERATOR IS MADE FOR THIS KEYWORD.                           * 04240020
*                                                                     * 04280020
*                                                                     * 04320020
*                                                                     * 04360020
*        HOLD=RN TO PREVENT LOGONS IN REGION RN.  WHERE RN IS THE     * 04400020
*        REGION NUMBER.  ISSUES TSEVENT(RGNFAIL) WITH REGISTER 1      * 04440020
*        CONTAINING NO MORE LOGON PARAMETERS.                         * 04480020
*                                                                     * 04520020
*                                                                     * 04560020
*ENTRY POINTS-IKJEAT06                                                * 04600020
*                                                                     * 04640020
*INPUT-  REG   13   SAVE AREA ADDR.                                   * 04680020
*        REG   14   RETURN ADDR.                                      * 04720020
*        REG   15   ENTRY POINT ADDR.                                 * 04760020
*                                                                     * 04800020
*OUTPUT-NONE                                                          * 04840020
*                                                                     * 04880020
*EXTERNAL REFERENCES-                                                 * 04920020
*        IKJEAD03 OR EQUIVALENT    DRIVER MODIFICATION RTN            * 04960020
*        REG   1   ADDR. OF PARM LIST                                 * 05000020
*        REG   13  ADDR. OF SAVE AREA                                 * 05040020
*        REG   14  RETURN ADDRESS                                     * 05080020
*        REG   15  ENTRY POINT ADDRESS - FROM TSCVTD03                * 05120020
*                                                                     * 05160020
*        PARM LIST USE D03DSECT(LOCAL DSECT)                          * 05200020
*        +  0  SWITCHES                                               * 05240020
*              X'80' SMF IS ACTIVE AND SMFWTR SHOULD BE ISSUED        * 05280020
*              X'40' MODIFY FROM TSO TERMINAL IN OPERATOR MODE, USE   * 05320020
*                    TPUT ONLY TO COMMUNICATE WTIH THE OPERATOR.      * 05360020
*        +  1  OPERATOR CONSOLE ID(VALID FOR X'40' NOT SET)           * 05400020
*        +  2  TJID OF TSO TERMINAL(VALID FOR X'40' SWITCH ONLY)      * 05440020
*        +  4  ADDR. OF DCA                                           * 05480020
*        +  8  LENGTH OF DATA FOR MODIFY                              * 05520020
*        + 12  ADDR. OF DATA FOR MODIFY                               * 05560020
*                                                                     * 05600020
*        RETURN CODES                                                 * 05640020
*        0     MODIFY IS DONE                                         * 05680020
*        4     MODIFY IS NOT DONE                                     * 05720020
*                                                                     * 05760020
*                                                                     * 05800020
*        GETMAIN  FREEMAIN  WTO  WTOR  WAIT  TPUT  SMFWTM  QEDIT      * 05840020
*        LOAD  DELETE  POST  TSEVENT                                  * 05880020
         EJECT                                                          05920020
*EXIT-   RETURN TO CALLER AT COMPLETION OF STOP TS PROCESSING         * 05960020
*                                                                     * 06000020
*EXIT ERROR-NONE                                                      * 06040020
*                                                                     * 06080020
*TABLES/CONTROL BLOCKS/WORKAREAS                                      * 06120020
*                                                                     * 06160020
*        CVT   IKJTSCVT   IKJRCB   IKJECBS   IKJTSICB   IKJDPA        * 06200020
*                                                                     * 06240020
*        COMMUNICATIONS PARAMATER LIST(CPL) - R 19                    * 06280020
*        +  0  ADDR. OF ECB POSTED FOR STOP/MODIFY                    * 06320020
*        +  4  ADDR. OF FIRST COMMUNICATIONS INPUT BUFFER(CIB)        * 06360020
*                                                                     * 06400020
*        COMMUNICATION INPUT BUFFER(CIB) -  USE IEZCIB MACRO          * 06440020
*                                                                     * 06480020
*        QUEUE MANAGER RESIDENT DATA AREA(IEFJOB) USE IEFQMRES MACRO  * 06520020
*                                                                     * 06560020
*        SYSTEM MANAGMENT CONTROL AREA(SMCA) USE IEESMCA MACRO        * 06600020
*                                                                     * 06640020
*        SYSYEM MANAGEMENT FACILITIES RECORDS TYPE 41 AND 42          * 06680020
*        USE SMFRD AND SMF41ED(LOCAL DSECTS)                          * 06720020
*                                                                     * 06760020
*        LOCAL(TO MAKE THIS PROGRAM RE-ENTERANT AND RE-FRESHABILE)    * 06800020
*        1) SAVE AND WORK AREA(T06WORKD DSECT) CONTAINS SAVE AREA AND * 06840020
*        MESSAGE BUFFERS FOR MESSAGES WITH VARIABLES.                 * 06880020
*        2) MODIFY WORK AREA(FIXED PART - T6MEDIT DSECT, VARIABLE     * 06920020
*        PART - T6MEDITR DSECT) CONTAINS MODIFY TSO DATA DERIVED FROM * 06960020
*        THE CIB.                                                     * 07000020
*                                                                     * 07040020
*ATTRIBUTES-                                                          * 07080020
*        RESIDENT IN TSO CONTROL REGION. REFRESHABLE, RE-ENTERANT,    * 07120020
*        SUPERVISOR STATE, AND DISABLES.                              * 07160020
*                                                                     * 07200020
*NOTES-  USES CVT TO FIND TSO CVT AND ALL REQUIRED OS CONTROL BLOCKS  * 07240020
*                                                                     * 07280020
*        IKJEAT06 MUST BE ATTACH'ED WITH SM=SUPV TO ALLOW PRIVILEGED  * 07320020
*        INSTRUCTIONS TO BE ISSUED.                                   * 07360020
*                                                                     * 07400020
*        CHARACTER CODE DEPENDENT - EBCDIC.                           * 07440020
*********************************************************************** 07480020
         EJECT                                                          07520020
CVTDSECT DSECT                                                          07560020
         CVT                                                            07600020
         SPACE                                                          07640020
         IEESMCA                                                        07680020
         SPACE                                                          07720020
IEZCIBD  DSECT                                                          07760020
         IEZCIB                                                         07800020
         SPACE                                                          07840020
IEFQMD   DSECT                                                          07880020
         IEFQMRES                                                       07920020
*********************************************************************** 07960020
         EJECT                                                          08000020
         IKJTSCVT                                                       08040020
         SPACE                                                          08080020
         IKJRCB                                                         08120020
         SPACE                                                          08160020
         IKJECBS                                                        08200020
         SPACE                                                          08240020
         IKJDPA                                                         08280020
         SPACE                                                          08320020
         IKJTSICB                                                       08360020
         EJECT                                                          08400020
*WORK AREA USED BY THE TSC SUB TAKS.  CONTAINS SAVE AREA, MESSAGE     * 08440020
*AND REPLY BUFFERS.  OBTAINED WHEN THE SUB TASK IS ATTACHED AND NOT   * 08480020
*RELEASED UNTIL THE SUBTASK TERMINATES AT STOP TSO.                   * 08520020
*********************************************************************** 08560020
T06WORKD DSECT                                                          08600020
T06WSAVE DS    18F                 SAVE AREA                            08640020
         ORG   T06WSAVE+12         USE SAVE AREA FOR MESSAGES (15 F)    08680020
T06WWTOR DS    F                   WTOR REPLY LENGTH AND ADDR           08720020
         DS    F                   WTOR ADDR ECB                        08760020
T06WWTRL DS    H                   WTOR MESSAGE LENGTH                  08800020
T06WWTRF DS    H                   WTOR MCS FLAGS                       08840020
T06WWTRT DS    20F                 WTOR MESSAGE TEXT                    08880020
         SPACE                                                          08920020
T06WRBUF DS    9F                  REPLY BUFFER(WTOR ONLY)              08960020
T06WRBFL EQU   *-T06WRBUF          LENGTH OF REPLY BUFFER               09000020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    09020021
T06WWECB DS     F            SMF RECORD ADDRESS                         09040021
         SPACE                                                          09080020
T06WWTO  DS    0F                  WTO PARM LIST                        09120020
T06WWTOL DS    H                   WTO MESSAGE LENGTH                   09160020
T06WTOF  DS    H                   WTO MCS FLAGS                        09200020
STPRPLBF DS    CL5           REPLY BUFFER FOR STOP WTOR                 09208021
STPRPLEN EQU   5                                                        09216021
         ORG   STPRPLBF      PUT REPLY BUFFER ON TOP OF WTO MESSAGE     09224021
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    09232021
T06WWTOT DS    20F                 WTO MESSAGE TEXT                     09240020
         SPACE                                                          09280020
T06WPACK DS    D                   PACK/UN PACK BUFFER                  09320020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    09325021
T06ECBL1 DS     0F           MAIN WAIT LIST OF ECB ADDRESSES            09330021
L1ECB1AD DS    F             ADDRESS OF TSCECB1                         09335021
L1CECBAD DS    F             ADDRESS OF COMMAND INPUT ECB               09340021
L1ENDFLG EQU   L1CECBAD      BYTE USED TO FLAG END OF LIST FOR WAIT     09345021
         SPACE 1                                                        09350021
T06ECBL2 DS    0F            WAIT FOR MODIFY REGION TO COMPLETE         09355021
*                            LIST OF ADDRESSES                          09360021
L2ECB1AD DS    F             ADDRESS OF TSCECB1                         09365021
L2CECBAD DS    F             ADDRESS OF COMMAND INPUT ECB               09370021
L2ECB4AD DS    F             ADDRESS OF MODIFY REGION ECB               09375021
L2ENDFLG EQU   L2ECB4AD      BYTE USED TO FLAG END OF LIST FOR WAIT     09380021
         SPACE 1                                                        09385021
T06ECBL3 DS    0F            WAIT FOR PROMPTING OF THE OPERATOR         09390021
*                            TO COMPLETE LIST OF ECB ADDRESSES          09395021
L3ECB1AD DS    F             ADDRESS OF TSCECB1                         09400021
L3CECBAD DS    F             ADDRESS OF COMMAND INPUT ECB               09405021
L3ECB6AD DS    F             ADDRESS OF PROMPT OPERATOR WTOR ECB        09410021
L3ENDFLG EQU   L3ECB6AD      BYTE USED TO FLAG END OF LIST FOR WAIT     09415021
         SPACE 1                                                        09420021
T06ECBL4 DS    0F            WAIT FOR STOP TO COMPLETE LIST OF          09425021
*                            ECB ADDRESSES                              09430021
L4ECB5AD DS    F             ADDRESS OF ECB USED TO REQUEST T06 TO      09435021
*                            TERMINATE                                  09440021
L4ECB8AD DS    F             ADDRESS OF ECB FOR SPECIAL STOP WTOR OR    09445021
*                            FOR TIME INTERVAL TO EXPIRE                09450021
L4ENDFLG EQU   L4ECB8AD      BYTE USER TO FLAG END OF LIST FOR WAIT     09455021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       09460021
         SPACE 1                                                        09465021
T06WEDIT DS    F                   SAVE AREA FOR EDIT                   09480020
T06WL    EQU   *-T06WORKD          LENGTH OF T06 SAVE/WORK AREA         09520020
*********************************************************************** 09560020
*PARAMATER LIST FOR IKJEAD03(OR IT EQUIVALENT).  THE REPLY BUFFER IN  * 09600020
*WORK/SAVE AREA IS USED FOR MAIN STORAGE.                             * 09640020
*********************************************************************** 09680020
D03DSECT DSECT                                                          09720020
D03SW0   DS    X                   SWITCHES                             09760020
D03SMF   EQU   X'80'               SMF IS ACTIVE                        09800020
D03TPUT  EQU   X'40'               DO3 MUST USE TPUT                    09840020
D03CONID DS    X                   CONSOLE ID IF NOT TPUT               09880020
D03TJID  DS    H                   TJID IF TPUT                         09920020
D03DCA   DS    F                   ADDR. OF DCA                         09960020
D03LDATA DS    F                   LENGTH OF DATA DRIVER='IT=NNNN'      10000020
D03ADATA DS    F                   ADDR. OF DATA                        10040020
D03PL    EQU   *-D03DSECT          LENGTH OF D03 PARM LIST              10080020
         EJECT                                                          10120020
*********************************************************************** 10160020
*MODIFY TSO WORK AREA.  OBTAINED AND RELEASED WHEN MODIFY TSO COMMAND * 10200020
*IS PROCESSED.  CONTAINS A FIXED PART AND A VARIABLE PART.            * 10240020
*FIXED PART(T6MEDIT) CONTAINS SWITCHES AND DATA EXTRACTED FROM CIB.   * 10280020
*********************************************************************** 10320020
T6MEDIT  DSECT                                                          10360020
T6MSW0   DS    0X                  SWITCH ZERO                          10400020
T6MS0USE EQU   X'80'               USERS=                               10440020
T6MS0SMF EQU   X'40'               SMF=                                 10480020
T6MS0DRV EQU   X'20'               DRIVER=                              10520020
T6MS0RGN EQU   X'10'               REGSIZE=                             10560020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    10580021
T6MS0HLD EQU   X'04'                                                    10600021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       10620021
T6MS0SUB EQU   X'08'               SUBMIT=                              10640020
T06S0MSG EQU   X'01'               OPER NOT CANCEL MODIFY               10680020
T6MS0LP  EQU   X'02'               LEFT PAREN SWITCH                    10700021
T6MLEN   DS    F                   LENGTH OF WORK AREA                  10720020
T6MKEYA  DS    F                   ADDR. OF NEXT KEYWORD IN CIB         10760020
T6MCIBER DS    F                   ADDR. OF END OF CIB                  10800020
T6MREGS  DS    H                   COUNT OF REGIONS TO MODIFY           10840020
T6MUSER  DS    H                   NEW LIMIT OF USERS ON TSO            10880020
T6MSUB   DS    H                   NEW MAX NUMBER TRACKS FOR SUBMIT     10920020
T6MSMF   DS    X                   NEW SETTINGS IN SMCAFOPT             10960020
T6MDRVL  DS    H                   LENGTH OF DRIVER='DATA'              11000020
T6MDRVA  DS    F                   ADDR. OF DRIVER='DATA'               11040020
T6MEND   DS    0F                  END OF FIXED PART OF WORK AREA       11080020
T6MWAL   EQU   *-T6MEDIT           LENGTH OF FIXED PART OF WORK AREA    11120020
         SPACE                                                          11160020
*********************************************************************** 11200020
*VARIABLE PART OF MODIFY WORK AREA.  USED FOR REGSIZE(RN)=(NNNK,YYYK).* 11240020
*ONE FOR EACH POSSIBLE REGION SPECIFIED AT START TSO.                 * 11280020
*********************************************************************** 11320020
T6MEDITR DSECT                                                          11360020
T6MRSW0  DS    0X                  REGSIZE SWITCHES                     11400020
T6MRSTP  EQU   X'80'               STOP THIS REGION                     11440020
T6MRSTR  EQU   X'40'               START THIS REGION                    11480020
T6MRHLD  EQU   X'20'               HOLD THIS REGION                     11520020
T6MRCBA  DS    F                   ADDR. OF RCB FOR THIS REGION         11560020
T6MRSIZ  DS    H                   REGION SIZE IF START                 11600020
T6MRSQS  DS    H                   LOCAL SQS SIZE IF START              11640020
T6MREND  DS    0F                  END OF WORK AREA FOR ONE REGION      11680020
T6MRL    EQU   *-T6MEDITR          LENGTH OF REGION PART                11720020
         EJECT                                                          11760020
*********************************************************************** 11800020
*DSECT FOR SMF RECORD TYPES 41(MODIFY TSO) AND 42(STOP TSO).          * 11840020
*********************************************************************** 11880020
SMFRD    DSECT                     DSECT SMF RECORD 41 AND 42           11920020
SMFRL    DS    H                   RECORD LENGTH                        11960020
         DS    H                   RESERVED                             12000020
         DS    XL1                 RESERVED                             12040020
SMFRT    DS    XL1                 RECORD TYPE                          12080020
SMFRT41  EQU   41                  RECORD TYPE 41 MODIFY TSO            12120020
SMFRT42  EQU   42                  RECORD TYPE 42 STOP TSO              12160020
SMFTOD   DS    XL8                 TIME OF DAY AND DATE                 12200020
SMFCPU   DS    XL4                 CPU IDENTIFICATION                   12240020
SMFPROC  DS    XL8                 TSO PROC NAME                        12280020
SMFID    DS    XL8                 TSO IDENTIFIER NAME                  12320020
SMFDATA  EQU   *                   START OF DATA 41 AND 42              12360020
         SPACE                                                          12400020
         ORG   SMFDATA             41 START OF DATA                     12440020
         DS    XL8                 41 RESERVED                          12480020
SMF41SMF DS    XL1                 41 SMF SWITCH SETTINGS  SMACFOPT     12520020
         DS    XL1                 41 RESERVED                          12560020
         DS    XL2                 41 RESERVED                          12600020
         DS    XL8                 41 RESERVED                          12640020
SMF41TRM DS    XL2                 41 NUMBER OF TERMS  TSCVTLUS         12680020
         DS    XL2                 41 RESERVED                          12720020
         DS    XL2                 41 RESERVED                          12760020
         DS    XL2                 41 RESERVED                          12800020
         DS    XL20                41 RESERVED                          12840020
SMF41LV  DS    H                   41 LENGTH OF VARIABLE SECTION        12880020
SMF41NV  DS    XL1                 41 NUMBER OF REGION ENTRIES          12920020
SMF41END DS    0X                  41 ADDR. OF FIRST REGION ENTRY       12960020
SMF41L   EQU   *-SMFRD             41 LENGTH OF FIXED PART RECORD       13000020
         SPACE                                                          13040020
         ORG   SMFDATA             42 START OF DATA                     13080020
         DS    XL20                42 RESERVED                          13120020
SMF42L   EQU   *-SMFRD             42 LENGTH OF RECORD                  13160020
         SPACE                                                          13200020
SMF41ED  DSECT                     41 DSECT FOR REGION ENTRY RECORD     13240020
SMF41ERN DS    XL1                 41 ENTRY REGION NUMBER               13280020
SMF41ERL DS    XL2                 41 ENTRY LOCAL SQS SIZE              13320020
SMF41ERS DS    XL2                 41 ENTRY REGION SIZE                 13360020
SMF41EAN DS    0X                  41 ENTRY ADDR. NEXT ENTRY            13400020
SMF41EL  EQU   *-SMF41ED           41 ENTRY LENGTH OF ENTRY             13440020
         EJECT                                                          13480020
****************REGISTER EQUATES                                        13520020
*                                  WORK REGISTERS                       13560020
WR0      EQU   0                   *                                    13600020
WR1      EQU   1                   *                                    13640020
WR2      EQU   2                   *                                    13680020
WR3      EQU   3                   *                                    13720020
WR4      EQU   4                   *                                    13760020
WR5      EQU   5                   *                                    13800020
WR6      EQU   6                                                        13820021
WR8      EQU   8                   *                                    13830021
WR15     EQU   15                  *                                    13840020
*                                                                       13880020
KEYWR    EQU   6                   ADDR. OF KEYWORD TO HANDLE           13920020
KEYLR    EQU   7                   LENGTH OF KEYWORD TO HANDLE          13960020
TSOECBS  EQU   7                                                        13980021
CIBR     EQU   8                   ADDR. OF CURRENT CIB                 14000020
MODWAR   EQU   9                   ADDR. OF MODIFY WORK AREA            14040020
TSCVTR   EQU   10                  ADDR. OF TSCVT                       14080020
BASER1   EQU   11                  BASE ADDR. 1                         14120020
BASER2   EQU   12                  BASE ADDR. 2                         14160020
SAVER    EQU   13                  SAVE AREA ADDR.                      14200020
RTNR     EQU   14                  RETURN ADDR.                         14240020
TRANR    EQU   14                  INTERNAL RETURN REGISTER             14280020
EPR      EQU   15                  ENTRY POINT ADDR.                    14320020
****************NUMERIC EQUATES                                         14360020
E0       EQU   0                   *                                    14400020
E1       EQU   1                   *                                    14440020
E2       EQU   2                   *                                    14480020
E3       EQU   3                   *                                    14520020
E4       EQU   4                   *                                    14560020
E5       EQU   5                   *                                    14600020
E6       EQU   6                   *                                    14610020
E7       EQU   7                   *                                    14640020
E8       EQU   8                   *                                    14680020
E12      EQU   12                  *                                    14720020
E13      EQU   13                  *                                    14760020
E16      EQU   16                  *                                    14800020
E20      EQU   20                  *                                    14840020
E28      EQU   28                  *                                    14880020
***************CHARACTER EQUATES(EBCDIC)                                14920020
CBLANK   EQU   C' '                BLANK                                14960020
CEQ      EQU   C'='                EQUAL                                15000020
CLP      EQU   C'('                LEFT  PARENTHESIS                    15040020
CRP      EQU   C')'                RIGHT PARENTHESIS                    15080020
CCOMA    EQU   C','                COMMA                                15120020
CU       EQU   C'U'                U AS IN UNIFORM                      15160020
CK       EQU   C'K'                K AS IN KILO                         15200020
         EJECT                                                          15240020
****************GENERAL EQUATES                                         15280020
*                                  BYTE MASKS                           15320020
ALLFLAG  EQU   X'FF'               ALL BITS SET                         15360020
NOFLAG   EQU   X'00'               NO BITS SET                          15400020
SIGNMASK EQU   X'0F'               MASK TO CONVERT PACKED SIGN TO 'F'   15440020
NUMASK   EQU   X'F0'               MASK TO CHECK FOR NUMERICS           15480020
ENDLIST  EQU   X'80'               END OF LIST INDICATOR                15520020
*                                  ECB CODES                            15560020
WAITBIT  EQU   X'80'               WAIT BIT                             15600020
POSTBIT  EQU   X'40'               POST BIT                             15640020
SMFBIT1  EQU   X'DE'               SMF BITS FOR FOREGROUND OPTIONS      15650020
SMFBIT2  EQU   X'1E'               SMF BITS FOR FOREGROUND OPTIONS      15660020
***************DISPLACEMENT EQUATES                                     15680020
*                                  TCB                                  15720020
TCBTIOT  EQU   12                  DISP TO ADDR. OF TIOT                15760020
*                                  TIOT                                 15800020
TIOTJJJJ EQU   0                   DISP TO JJJJJJJJ                     15840020
TIOTSSSS EQU   8                   DISP TO SSSSSSSS                     15880020
*                                  DISP COMMUNICATIONS PARM LIST        15920020
DCPLECB  EQU   0                   ECB                                  15960020
DCPLCIB  EQU   4                   COMMAND INPUT BUFFER                 16000020
TIOCLECB EQU   84                  DISP OF TIOCLECB IN RPT    CC A69344 16010021
TSCFSTOP EQU   X'08'               FSTOP REPLY FLAG           CC A69344 16020021
         EJECT                                                          16040020
IKJEAT06 CSECT                                                          16080020
*********************************************************************** 16120020
*IKJEAT06 INIT SAVE THE REGISTERS, GETMAIN FOR SAVE/WORK AREA         * 16160020
*********************************************************************** 16200020
         SAVE  (14,12)             SAVE THE CALLER'S REGISTERS          16240020
         BALR  BASER1,0            EST. FIRST BASE ADDR.                16280020
         USING *,BASER1            *                                    16320020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    16340021
TSOT06   LA    BASER2,TSOT06+4095      SET SECOND BASE                  16360021
         USING TSOT06+4095,BASER2                                       16380021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       16400021
         LA    WR0,T06WL           LENGTH OF SAVE/WORK AREA             16440020
         GETMAIN R,LV=(0)          GET SAVE/WORK AREA                   16480020
         ST    WR1,E8(SAVER)       CHAIN                                16520020
         ST    SAVER,E4(WR1)       SAVE                                 16560020
         LR    SAVER,WR1           AREAS                                16600020
         USING T06WORKD,SAVER      T06 SAVE/WORK AREA                   16640020
         USING CVTDSECT,WR15       OS CVT                               16680020
         L     WR15,CVTPTR         ADDR. OF CVT                         16720020
         USING TSCVT,TSCVTR        TS CVT                               16760020
         L     TSCVTR,CVTTSCVT     TSCVT                                16800020
         DROP  WR15                OS CVT                               16840020
*********************************************************************** 16880020
*ESTABLISH LIST OF ECB ADDR. IN T06 WORK AREA FOR TSECB1 ECB AND THE  * 16920020
*CPL ECB.  IKJEAT06 WAITS ON THESE ECB'S FOR WORK.                    * 16960020
*********************************************************************** 17000020
         USING TSECB,WR15          TSO ECBS                             17040020
         L     WR15,TSCVTECB       ADDR. OF TSO ECB'S                   17080020
         SPACE 1                                                        17088021
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    17096021
*                            SET UP TSCECB1'S ADDRESS IN ECB LISTS      17104021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       17112021
         LA    WR1,TSCECB1         ADDR. OF TS ECB 1                    17120020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    17124021
         ST    WR1,L1ECB1AD  SAVE ECB1 ADDRESS IN LIST ONE              17128021
         ST    WR1,L2ECB1AD  SAVE ECB1 ADDRESS IN LIST TWO              17132021
         ST    WR1,L3ECB1AD  SAVE ECB1 ADDRESS IN LIST THREE            17136021
         SPACE 1                                                        17140021
*                            SET UP TSCECB4'S ADDRESS IN ECB LISTS      17144021
         LA    WR1,TSCECB4   GET THE ADDRESS OF ECB4                    17148021
         ST    WR1,L2ECB4AD  SAVE ADDRESS OF ECB4 IN LIST TWO           17152021
         SPACE 1                                                        17156021
*                            SET UP TSCECB5'S ADDRESS IN ECB LISTS      17160021
         LA    WR1,TSCECB5   GET ADDRESS OF ECB5                        17164021
         ST    WR1,L4ECB5AD  SAVE ECB5 ADDRESS IN LIST FOUR             17168021
         SPACE 1                                                        17172021
*                            SET UP TSCECB6'S ADDRESS IN ECB LISTS      17176021
         LA    WR1,TSCECB6   GET THE ADDRESS OF ECB6                    17180021
         ST    WR1,L3ECB6AD  SAVE ECB6 ADDRESS IN LIST THREE            17184021
         SPACE 1                                                        17188021
*                            SET UP TSCECB8'S ADDRESS IN ECB LISTS      17192021
         LA    WR1,TSCECB8   GET THE ADDRESS OF ECB8                    17196021
         ST    WR1,L4ECB8AD  SAVE ECB8 ADDRESS IN LIST FOUR             17200021
         DROP WR15                                                      17204021
         SPACE 1                                                        17208021
*                            SET UP COMMAND INPUT ECB ADDRESS IN        17212021
*                            THE ECB LISTS                              17216021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       17220021
         L     WR2,TSCVTSPL        ADDR. OF CPL                         17240020
         L     WR1,DCPLECB(WR2)    ADDR. OF CPL ECB                     17280020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    17289021
         ST    WR1,L1CECBAD  SAVE CECB ADDRESS IN LIST ONE              17298021
         ST    WR1,L2CECBAD  SAVE CECB ADDRESS IN LIST TWO              17307021
         ST    WR1,L3CECBAD  SAVE CECB ADDRESS IN LIST THREE            17316021
         SPACE 1                                                        17325021
*                            INITIALIZE THE END OF LIST INDICATORS      17334021
*                            FOR WAIT                                   17343021
         MVI   L1ENDFLG,ENDLIST        SET END OF LIST IN LIST ONE      17352021
         MVI   L2ENDFLG,ENDLIST        SET END OF LIST IN LIST TWO      17361021
         MVI   L3ENDFLG,ENDLIST        SET END OF LIST IN LIST THREE    17370021
         MVI   L4ENDFLG,ENDLIST        SET END OF LIST IN LIST FOUR     17379021
         SPACE 1                                                        17388021
*********************************************************************** 17400020
*ISSUE QEDIT TO ONLY ALLOW ONE CIB AT A TIME.  NOTE  'STOP'   CIB     * 17440020
*MUST BE ACCEPTED AT ANY TIME.                                        * 17480020
*********************************************************************** 17520020
         LA    WR0,DCPLCIB(WR2)    ORIGIN OF CIB CHAIN                  17560020
         QEDIT ORIGIN=(0),CIBCTR=1 ONE CIB AT A TIME                    17600020
*********************************************************************** 17640020
*INITIALIZATION DONE.  CHECK TSECB1 FOR POST AND CPL FOR CIB'S.       * 17680020
*********************************************************************** 17720020
         EJECT                                                          17760020
*********************************************************************** 17800020
*TEST TSECB1 FOR POST.  IF POSTED, TSC MAIN TASK(IKJEAT03) WANTS TO   * 17840020
*INITIATE THE STOP TSO SEQUENCE.                                      * 17880020
*********************************************************************** 17920020
T600     SR    CIBR,CIBR           NO CIB, SET ADDR. TO ZERO            17960020
         L     WR2,L1ECB1AD  GET ADDRESS OF TSCECB1                     17980021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       18000021
         TM    E0(WR2),POSTBIT     POSTED?                              18040020
         BO    T06STOP             YES, STOP TSO                        18080020
*********************************************************************** 18120020
*CPLECB HAS BEEN POSTED.  CHECK CPL FOR CIB'S.  CHECK CIB'S FOR       * 18160020
*CIB VERB CODE FOR STOP AND MODIFY TSO.  IF VERB CODE IS NOT STOP OR  * 18200020
*MODIFY, T06 WILL IGNORE THE CIB.                                     * 18240020
*********************************************************************** 18280020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    18288021
         L     WR2,L1CECBAD  GET ADDRESS OF COMMAND INPUT ECB           18296021
         MVI   E0(WR2),NOFLAG          CLEAR WAIT/POST FLAGS            18304021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       18312021
T601     L     CIBR,TSCVTSPL       ADDR. OF CPL                         18320020
         L     CIBR,DCPLCIB(CIBR)  ADDR. OF CIB                         18360020
         LTR   CIBR,CIBR           IS THERE A CIB                       18400020
         BZ    T603                NO, GO  TO WAIT                      18440020
         USING IEZCIBD,CIBR        CIB                                  18480020
         CLI   CIBVERB,CIBSTOP     STOP TSO                             18520020
         BE    T06STOP             YES                                  18560020
         CLI   CIBVERB,CIBMODFY    MODIFY TSO                           18600020
         BE    T06MODTS            YES                                  18640020
*********************************************************************** 18680020
*CIB QEDIT TO RELEASE THE CIB.  EITHER NOT STOP OR MODIFY OR THE CIB  * 18720020
*IS MODIFY AND MODIFY PROCESSING IS COMPLETE.                         * 18760020
*********************************************************************** 18800020
T602     L     WR2,TSCVTSPL        ADDR. OF CPL                         18840020
         LA    WR0,DCPLCIB(WR2)    ADDR. OF ADDR. OF CIB                18880020
         LR    WR1,CIBR            ADDR. OF CIB                         18920020
         QEDIT ORIGIN=(0),BLOCK=(1) FLUSH CIB                           18960020
         SR    CIBR,CIBR           NO CIB, SET ADDR. TO ZERO            19000020
         B     T601                CHECK FOR ANOTHER CIB                19040020
*********************************************************************** 19080020
*STOP OR MODIFY IS NOT OUTSTANDING.  WAIT ON ECBLIST FOR WORK.        * 19120020
*********************************************************************** 19160020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    19210021
T603     LA    WR1,T06ECBL1  GET ADDRESS OF MAIN WAIT ECB LIST          19260021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       19310021
         WAIT  1,ECBLIST=(1)       WAIT FOR SOME ACTION                 19360020
         B     T600                TO ECB AND CIB CHECKING              19400020
         EJECT                                                          19440020
*********************************************************************** 19480020
*********************************************************************** 19520020
*TO6STOP INITIATES THE STOP TSO SEQUENCE.                             * 19560020
*SETS CURRENT LIMIT OF USERS ON TSO(TSCVTLUS) TO ZERO.                * 19600020
*FOR EACH ACTIVE RCB, INVOKES FORCE LOGOFF(IKJEAL00) TO FORCE ALL     * 19640020
*THE USERS ON TSO TO LOGOFF.                                          * 19680020
*BUILDS AND ISSUES SMF RECORD 42 IF NECESSARY.                        * 19720020
*POSTS TSCECB TO WAKE UP THE TSC MAINLINE.                            * 19760020
*TERMINATES THE TSC SUB TASK.                                         * 19800020
*********************************************************************** 19840020
*********************************************************************** 19880020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    19900021
T06STOP  SSM   DISABLE             NO INTERRUPTS                        19920021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       19940021
         SR    WR1,WR1             ZERO                                 19960020
         STH   WR1,TSCVTLUS        SET CURRENT LIMIT TSO TO ZERO        20000020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    20010021
         OI    TSCVTFL1,TSCSSTOP+TSCRSTOP        SET BOTH STOP TSO      20020021
*                                                AND STOP REGION        20030021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       20040021
         L     WR4,TSCVTRCB        ADR FIRST RCB                 A42839 20050021
         USING RCB,WR4             RCB'S                                20240020
         LH    WR5,TSCVTCTR        COUNT OF RCB'S                       20320020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    20330021
T06ST01  TM    RCBFLG2,RCBACTV+RCBSTR2 TEST FOR RCT ACTIVE OR STARTING  20340021
         BZ    T06ST02       BRANCH IF THE RCT IS DEAD OR INACTIVE      20350021
         OI    RCBFLG2,RCBSTOP         SET THE STOP REGION FLAG FOR     20360021
*                            T03 STOP REGION PROCESSOR                  20370021
         NI    RCBFLG2,ALLFLAG-RCBSTR1-RCBSTR2   STOP ANY START         20380021
*                                                PROCESSING COLD - I.E. 20390021
*                                                STOP BEFORE START1 IS  20400021
*                                                STARTED, BEFORE        20410021
*                                                START2 IS STARTED, OR  20420021
*                                                WHILE IN A NORMAL      20430021
*                                                ACTIVE STATUS          20440021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       20450021
         BAL   WR2,T06TSIP                                       A42839 20470021
         BAL   WR2,T06SILF                                       A42839 20490021
         LTR   CIBR,CIBR     WAS THERE A CIB ?                          20510021
         BZ    T06ST02       BRANCH IF NO CIB - TERMINATION MESSAGES    20530021
*                            GO TO THE CONSOLE THAT STARTED THIS RCT    20550021
         MVC   RCBCONID,CIBCONID   PUT CONSOLE ID IN RCB         A42839 20570021
T06ST02  LA    WR4,RCBEND          ADDR. OF NEXT RCB                    20640020
         BCT   WR5,T06ST01         ANOTHER RCB. YES                     20680020
         SSM   ENABLE              ALLOW INTERRUPTS              A42839 20720021
         DROP  WR4                 RCB'S                                20760020
         EJECT                                                          20800020
         L     WR3,TSCVTTSC        ADDR. OF TSC TCB                     20840020
         L     WR3,TCBTIOT(WR3)    ADDR. OF THE TIOT                    20880020
*********************************************************************** 20920020
*IF SMF IS ACTIVE, BUILD AND ISSUE SMF RECORD 42(TSO IS STOPPING).    * 20960020
*********************************************************************** 21000020
         L     WR15,CVTPTR         ADDR. OF OS CVT                      21040020
         USING CVTDSECT,WR15       CVT                                  21080020
         L     WR15,CVTSMCA        ADDR. OF SMF CONTROL AREA            21120020
         DROP  WR15                CVT                                  21160020
         LA    WR15,E0(WR15)       CLEAR THE HIGH BYTE                  21200020
         LTR   WR15,WR15           ADDR. OF SMCA IS ZERO                21240020
         BZ    T06ST03             NO SMF ACTIVE                        21280020
         LA    WR1,T06WWTOR        USE MESSAGE BUFFER FOR SMF RECORD    21320020
         XC    E0(SMF42L,WR1),E0(WR1) CLEAR THE SMF RECORD              21360020
         USING SMFRD,WR1           SMF RECORD                           21400020
         LA    WR2,SMF42L          RECORD LENGTH                        21440020
         STH   WR2,SMFRL           TO THE RECORD                        21480020
         MVI   SMFRT,SMFRT42       RECORD TYPE                          21520020
         MVC   SMFPROC(E16),E0(WR3) PROC AND ID TIOT TO RECORD          21560020
         SMFWTM  (1)               ISSUE SMF WRITER(IGNORE RC'S)        21600020
         DROP  WR1                 SMF RECORD                           21640020
*********************************************************************** 21680020
*TELL THE OPERATOR THAT TSO IS STOPPING.  WR3-ADDR. JJJJJJJJ SSSSSSSS * 21720020
*IKJ078I JJJJJJJJ SSSSSSSS TSO IS STOPPING                            * 21760020
*********************************************************************** 21800020
T06ST03  LA    WR1,T06WWTO         ADDR. OF WTO BUFFER                  21840020
         LTR   CIBR,CIBR           IS THERE A CIB ADR                   21850020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    21857021
         BZ    T06ST05       IF NO CIB SKIP FIRST WTO                   21864021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       21871021
         CLC   CIBTJID(E2),TJID0   IF TJID NOT ZERO, TSO TERMINAL       21880020
         BE    T06ST04             OPERATOR CONSOLE                     21920020
         MVC   E0(M078ITL,WR1),M078IT MOVE THE MESSAGE                  21960020
         MVC   M078ITJ(E8,WR1),TIOTJJJJ(WR3) JOB NAME TO MSG            22000020
         MVC   M078ITS(E8,WR1),TIOTSSSS(WR3) STEP NAME TO MSG           22040020
         LA    WR0,M078ITL         LENGTH OF MESSAGE                    22080020
         BAL   TRANR,T06TPUT       TO TPUT ROUTINE                      22120020
         B     T06ST05             POST TSC ECB                         22160020
T06ST04  MVC   E0(M078IWL,WR1),M078IW MOVE THE MESSAGE                  22200020
         MVC   M078IWJ(E8,WR1),TIOTJJJJ(WR3) JOB NAME TO MSG            22240020
         MVC   M078IWS(E8,WR1),TIOTSSSS(WR3) STEP NAME TO MSG           22280020
         SR    WR0,WR0             ZERO                                 22320020
         IC    WR0,CIBCONID        CONSOLE ID                           22360020
         WTO   MF=(E,(1))          ISSUE THE WTO                        22400020
         EJECT                                                          22440020
*********************************************************************** 22480020
*POST THE TSC MAIN TASK IN CASE NO USERS ARE LOGGED ON TSO.           * 22520020
*********************************************************************** 22560020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    22570021
T06ST05  L     TSOECBS,TSCVTECB        GET THE ADDRESS OF THE TSO ECBS  22580021
         USING TSECB,TSOECBS                                            22590021
         L     WR6,CVTPTR    GET THE ADDRESS OF THE CVT                 22600021
         POST  TSCECB        POST THE TSC MAIN LINE INTO ACTION         22610021
STOPIT   MVI   TSCECB8,NOFLAG          CLEAR WAIT/POST BITS IN ECB8     22620021
         MVC   T06WWTOR(STPWLEN),STPWTOR         MOVE IN SPECIAL STOP   22630021
*                                                WTOR LIST              22640021
         LA    WR2,STPRPLBF  GET THE ADDRESS OF THE REPLY BUFFER        22650021
         LA    WR3,STPRPLEN  GET THE LENGTH OF THE REPLY BUFFER         22660021
         MVC   STPRPLBF,NBLANKS        BLANK THE REPLY AREA             22670021
         LA    WR4,TSCECB8   GET THE ADDRESS OF THE REPLY ECB           22680021
*                            TELL THE OPERATOR 'U' OR 'FSTOP'           22690021
         WTOR  ,(WR2),(WR3),(WR4),MF=(E,T06WWTOR)                       22700021
         LA    WR1,T06ECBL4  GET THE ADDRESS OF THE ECB LIST            22710021
         WAIT  ECBLIST=(WR1) WAIT FOR REPLY OR SUCCESSFUL TSO           22720021
*                                      TERMINATION                      22730021
         TM    TSCECB5,POSTBIT         TSO TERMINATING?                 22740021
         BZ    EXTRASTP      BRANCH IF OPERATOR HAS REPLIED             22750021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       22760021
*********************************************************************** 22840020
*TERMINATE THE TSC SUB TASK. STOP TS HAS BEEN INITIATED.              * 22880020
*********************************************************************** 22920020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    22940021
T06ST06  LR    WR1,SAVER     GET WORK AREA ADDRESS FOR FREEMAIN         22960021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       22980021
         L     SAVER,E4(WR1)       ADDR. OF CALLER SAVE AREA            23000020
         LA    WR0,T06WL           LENGTH OF SAVE/WORK AREA             23040020
         FREEMAIN  R,LV=(0),A=(1)  FREE SAVE/WORK AREA                  23080020
         RETURN  (14,12),RC=0      RETURN TO CALLER                     23120020
         SPACE 2                                                        23120921
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    23121821
         USING RCB,WR4                                                  23122721
T06TSIP  SR    WR1,WR1             CLEAR REGISTER                       23123621
         IC    WR1,RCBNMBR         GET REGION NUMBER                    23124521
         O     WR1,BIT0MASK                                      A42839 23125421
         L     EPR,TSCVTI01        ADR TSIP                      A42839 23126321
         TSEVENT RGNFAIL,ENTRY=BRANCH ISSUE TSEVENT              A42839 23127221
         BR    WR2                 RETURN                        A42839 23128121
         DROP  WR4                                                      23129021
T06SILF  L     EPR,TSCVTSLF        GET ENTRY TO LOGON            A42839 23129921
         LCR   WR1,WR4             COMPLIMENT OF RCB ADR         A42839 23130821
         BALR  RTNR,EPR            BRANCH TO LOGON               A42839 23131721
         BR    WR2                 RETURN                        A42839 23132621
         SPACE 5                                                        23133521
*********************************************************************** 23134421
*        THIS IS THE TIMER EXIT ROUTINE FOR THE 'FSTOP' FUNCTION      * 23135321
*********************************************************************** 23136221
         SPACE 2                                                        23137121
T06STIMX SAVE  (14,12)       SAVE THE REGISTERS ON ENTRY                23138021
         L     WR6,CVTPTR    GET THE CVT ADDRESS                        23138921
         USING CVTDSECT,WR6                                             23139821
         L     TSCVTR,CVTTSCVT         GET TSCVT ADDRESS                23140721
         LTR   TSCVTR,TSCVTR           IS THE TSCVT POINTER ZERO        23141621
         BZ    KEEPWAIT      YES,  T03 IN NEVER ENDING WAIT DUE         23142521
*                            FINDING A DEAD REGION DURING STOP TSO - -  23143421
*                            THE TSCVT POINTER IN THE CVT WAS ZEROED    23144321
*                            SKIP THE POST OF T06 AND CAUSE IT TO GO IN 23145221
*                            TO A NEVER ENDING WAIT ALSO                23146121
         L     TSOECBS,TSCVTECB        GET ADDRESS OF TSO ECBS          23147021
         POST  TSCECB8       LET T06 KNOW THAT TIME INTERVAL HAS        23147921
*                            EXPIRED                                    23148821
KEEPWAIT EQU   *                                                        23149721
         RETURN (14,12),RC=0                                            23150621
         DROP  WR6                                                      23151521
         SPACE 5                                                        23152421
ABORTMOD L     WR2,TSCVTSPL            GET ADDRESS OF SPL               23153321
         LA    WR0,DCPLCIB(WR2)        GET ADDRESS OF CIBPTR IN CSCB    23154221
*SET THE CIBCTR TO ZERO TO PREVENT ANY FUTURE MODIFIES                  23155121
         QEDIT ORIGIN=(0),CIBCTR=0                                      23156021
         B     MODABHLP      GO PURGE THE CURRENT MODIFY                23156921
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       23157821
         EJECT                                                          23160020
*********************************************************************** 23200020
*********************************************************************** 23240020
*T06MODTS IS THE MODIFY TSO ROUTINE.  COMPUTE THE SIZE OF MODIFY      * 23280020
*WORK AREA AND OBTAIN MAIN STORAGE FOR IT.                            * 23320020
*********************************************************************** 23360020
*********************************************************************** 23400020
T06MODTS LA    WR2,T6MWAL          LENGTH FIXED PART WK AREA     A42839 23440021
         LA    WR3,T6MRL           LENGTH OF WORK AREA PER REGION       23480020
         MH    WR3,TSCVTCTR        TIME NUMBER OF REGIONS               23520020
         AR    WR2,WR3             TOTAL MAIN STORAGE NEEDED            23560020
         GETMAIN R,LV=(WR2)        GETMAIN FOR MODIFY WORK AREA         23600020
         LR    MODWAR,WR1          LOAD WORK AREA BASE REGISTER         23640020
         USING T6MEDIT,MODWAR      MODIFY WORK AREA DSECT               23680020
         LR    WR3,WR2             SAVE THE LENGTH                      23720020
         BCTR  WR2,0               LENGTH MINUS ONE                     23760020
         EX    WR2,T06EDXC1        CLEAR THE WORK AREA                  23800020
         ST    WR3,T6MLEN          LENGTH OF WORK AREA                  23840020
*********************************************************************** 23880020
*T6MCIBER - ADDR. OF END OF CIB DATA, SCAN STOPPER.                   * 23920020
*T6MKEYA - ADDR. OF FIRST DATA TO EDIT IN CIB.                        * 23960020
*********************************************************************** 24000020
         LA    KEYWR,CIBDATA       FIRST KEYWORD AT START OF DATA       24040020
         ST    KEYWR,T6MKEYA       ADDR. OF FIRST DATA TO EDIT          24080020
         LR    WR1,KEYWR           END OF CIB DATA IS START PLUS        24120020
         AH    WR1,CIBDATLN        LENGTH OF DATA.                      24160020
         LR    WR2,KEYWR           GET BEG OF DATA IN CIB               24170020
T06MOD3  CR    WR2,WR1             IS CIB EXHAUSTED                     24180020
         BE    T06MOD1             YES SAVE END ADDRESS OF CIB          24190020
         CLI   E0(WR2),CBLANK      IS THERE A BLANK DELIMITER           24192420
         BE    T06MOD2             YES SAVE END ADDRESS OF CIB          24194020
*                                  A BLANK IS END OF CIB DATA           24196020
         LA    WR2,E1(WR2)         NO UPDATE PTR TO DATA                24198020
         B     T06MOD3             CONTINUE SEARCH FOR END OF DATA      24198420
T06MOD2  ST    WR2,T6MCIBER        SAVE END ADDRESS OF CIB              24198820
         B     T06ED00             CONTINUE EDIT                        24199220
T06MOD1  ST    WR1,T6MCIBER        MODIFY WORK AREA                     24200020
         EJECT                                                          24240020
*********************************************************************** 24280020
*EDIT OF KEYWORD'S IN THE CIB. T6MKEYA - ADDR. OF NEXT KEYWORD TO EDIT* 24320020
*DETERMINE THE VALIDITY OF THE KEYWORD AND THE LENGTH OF THE KEYWORD  * 24360020
*PLUS THE DATA ASSOCIATED WITH THE KEYWORD.  INVOKE THE KEYWORD       * 24400020
*HANDLING ROUTINE. FLUSH ANY LEADING COMMA'S.                         * 24440020
*********************************************************************** 24480020
T06ED00  L     KEYWR,T6MKEYA       LOAD THE ADDR. OF THE KEYWORD        24520020
         C     KEYWR,T6MCIBER      ADDR. KEYWORD TO END OF CIB          24560020
         BNL   T06ED10             CIB IS EXHAUSTED                     24600020
T06ED01  CLI   E0(KEYWR),CCOMA     LEADING COMMA                        24640020
         BNE   T06ED02             NO                                   24680020
         LA    KEYWR,E1(KEYWR)     BUMP TO NEXT CHARACTER               24720020
         C     KEYWR,T6MCIBER      ADDR. KEYWORD TO END OF CIB          24760020
         BNL   T06ED10             CIB IS EXHAUSTED                     24800020
         B     T06ED01             TO SCAN LEADING COMMA                24840020
T06ED02  BAL   TRANR,T06EDR00      KEYWORD EDIT ROUTINE                 24880020
         B     T06ED04             KEYWORD INVALID                      24920020
*        NOP   T06ED03             KEYWORD VALID                        24960020
*********************************************************************** 25000020
*KEYWORD IS VALID.   KEYWR - ADDR. OF THE KEYWORD.                    * 25040020
*********************************************************************** 25080020
T06ED03  LA    WR2,E1(WR2)         ACTUAL LENGTH OF KEYWORD             25120020
         LA    WR1,E0(WR2,KEYWR)   ADDR. OF DATA WITH KEYWORD           25160020
         C     WR1,T6MCIBER        ADDR. OF DATA TO END CIB DATA        25200020
         BNL   T06ED04             ERROR, NO DATA WITH THIS KEYWORD     25240020
*********************************************************************** 25280020
*DETERMINE ADDR. OF NEXT KEYWORD IN CIB.  KEYWR-ADDR. OF THIS KEYWORD * 25320020
*WR1-ADDR. OF DATA THIS KEYWORD. ON RTN, WR2-ADDR. OF NEXT KEYWORD.   * 25360020
*TO KEYWORD HANDLER, KEYWR-ADDR. OF KEYWORD KEYLR-LEN. KW AND DATA    * 25400020
*********************************************************************** 25440020
         BAL   TRANR,T06EDR20      TO FIND END OF DATA WITH KEYWORD     25480020
         ST    WR2,T6MKEYA         ADDR. OF NEXT KEYWORD TO EDIT        25520020
         LR    KEYLR,WR2           ADDR. OF NEXT KEYWORD                25560020
         SR    KEYLR,KEYWR         END MINUS START EQ LEN. KW PLUS DATA 25600020
*********************************************************************** 25640020
*WR4 - ADDR. OF KEYWORD HANDLING ROUTINE.                             * 25680020
*TO KEYWORD HANDLER, KEYWR-ADDR. OF KEYWORD KEYLR-LEN. KW AND DATA    * 25720020
*KEYWORD HANDLER'S BRANCH TO NORMAL OR ERROR ROUTINES.                * 25760020
*********************************************************************** 25800020
         BR    WR4                 TO KEYWORD HANDLER                   25840020
         EJECT                                                          25880020
*********************************************************************** 25920020
*KEYWORD IN CIB IS NOT VALID. DETERMINE THE ADDR. OF THE NEXT KEYWORD * 25960020
*IN THE CIB. KEYWR - ADDR. OF KEYWORD THAT IS INVALID.                * 26000020
*ATTEMPT TO OBTAIN A VALID KEYWORD FROM THE OPERATOR.  IF MODIFY IS   * 26040020
*FROM TSO TERMINAL IN THE OPERATOR MODE, CAN ONLY ISSUE TPUT. WE MUST * 26080020
*IGNORE THIS MODIFY.                                                  * 26120020
*ATTEMPT TO FIND ADDR. OF NEXT KEYWORD. HAVE EITHER JUNK=XX,GOOD OR   * 26160020
*JUNK=(XX),GOOD.  SCAN FOR COMMA, BUT IGNORE COMMA WITHIN THE LEFT TO * 26200020
*RIGHT PARENTHESIS.                                                   * 26240020
*********************************************************************** 26280020
T06ED04  LR    WR1,KEYWR           START OF THE SCAN                    26320020
T06ED05  CLI   E0(WR1),CCOMA       COMMA                                26360020
         BE    T06ED07             YES                                  26400020
         CLI   E0(WR1),CLP         LEFT PARENTHESIS                     26440020
         BE    T06ED06             YES                                  26480020
         LA    WR1,E1(WR1)         BUMP TO NEXT CHARACTER               26520020
         C     WR1,T6MCIBER        END CIB                              26560020
         BNL   T06ED07             YES                                  26600020
         B     T06ED05             NO, CONTINUE SCAN                    26640020
*********************************************************************** 26680020
*FOUND LEFT PARENTHESIS, LOOK FOR RIGHT PARENTHESIS                   * 26720020
*********************************************************************** 26760020
T06ED06  LA    WR1,E1(WR1)         BUMP TO NEXT CHARACTER               26800020
         C     WR1,T6MCIBER        END CIB                              26840020
         BNL   T06ED07             YES                                  26880020
         CLI   E0(WR1),CRP         RIGHT PARENTHESIS                    26920020
         BNE   T06ED06             CONTINUE SCAN                        26960020
         B     T06ED05             TO COMMA SCAN                        27000020
*********************************************************************** 27040020
*WR1 - EITHER 1) ADDR. OF NEXT KEYWORD(JUNK=XXX,GOOD) OR 2) ADDR. OF  * 27080020
*THE END OF THE CIB(JUNK=XXX).   DERIVE THE LENGTH OF THE INVALID     * 27120020
*KEYWORD AND DATA.  UPDATE T6MKEYA TO ADDR. OF NEXT KEYWORD.          * 27160020
*********************************************************************** 27200020
T06ED07  ST    WR1,T6MKEYA         SAVE FOR NEXT KEYWORD EDIT           27240020
         LR    KEYLR,WR1           ADDR. OF NEXT                        27280020
         SR    KEYLR,KEYWR         MINUS START IS LENGTH                27320020
         SR    WR15,WR15           ANY KEYWORD IS VALID                 27360020
         B     T06EDR40            INVALID KEYWORD ROUTINE              27400020
         EJECT                                                          27440020
*********************************************************************** 27480020
*THE EDIT OF THE CIB IS COMPLETE.  TSO MAY NOW BE MODIFIED.  ALL THE  * 27520020
*DATA IS IN THE MODIFY WORK AREA.  SCAN THE SWITCHES AND PERFORM THE  * 27560020
*MODIFICATIONS AS REQURIED.                                           * 27600020
*********************************************************************** 27640020
T06ED10  L     KEYLR,CVTPTR        ADDR. OF CVT                         27680020
         USING CVTDSECT,KEYLR      CVT                                  27720020
         CLI   T6MSW0,E0           ANY MODIFY SWITCHES SET              27760020
         BE    T06ED32             NO                                   27800020
*                                                                       27800721
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    27801421
*CHECK FOR REGSIZE/HOLD CONFLICTS                                       27802121
*                                                                       27802821
         TM    T6MSW0,T6MS0HLD+T6MS0RGN POSSIBLE CONFLICT               27803521
         BNO   T06EDXX       NO - SKIP CONFLICT CODE                    27804221
         USING T6MEDITR,WR3                                             27804921
         LA    WR3,T6MEND    FIRST REG WORK AREA                        27805621
         LH    WR5,TSCVTCTR  COUNT OF R W A                             27806321
MORE     TM    T6MRSW0,T6MRHLD         IS HOLD SPECIFIED                27807021
         BZ    NOCON         NO, NO CONFLICT                            27807721
         TM    T6MRSW0,T6MRSTR+T6MRSTP REGSIZE SPECIFIED                27808421
         BZ    NOCON         NO, NO CONFLICT                            27809121
         LA    WR1,T06WWTO   GET WTO BUFFER ADRS                        27809821
         MVC   E0(M026DL,WR1),M026D    MOVE MSG TEXT                    27810521
         LA    WR15,E1       *                                          27811221
         AH    WR15,TSCVTCTR * PUT                                      27811921
         SR    WR15,WR5      *  RN                                      27812621
         CVD   WR15,T06WPACK *    IN                                    27813321
         OI    T06WPACK+E7,SIGNMASK    *     WTO                        27814021
         UNPK  M026DRN(E2,WR1),T06WPACK+E6(E2) *  BUFFER                27814721
         CLC   CIBTJID(E2),TJID0       IS IT OP CONSL                   27815421
         BE    OPCONSL       YES                                        27816121
         LA    WR0,M026TL    SET LENGTH FOR TPUT                        27816821
         LA    WR1,E4(WR1)   POINT TO TEXT FOR TPUT                     27817521
         BAL   TRANR,T06TPUT TPUT THE MSG                               27818221
         B     T06ED34       TSO MODIFY REJECTEC                        27818921
OPCONSL  SR    WR0,WR0       CONSL ID FROM CIB                          27819621
         IC    WR0,CIBCONID  *                                          27820321
         WTO   MF=(E,T06WWTO)          ISSUE MSG                        27821021
*                                                                       27821721
         LA    WR1,T06WWTOR  ADDRS OF WTOR BUFFER                       27822421
         MVC   E0(M027DL,WR1),M027D    MOVE MSG                         27823121
ERROR    LR    KEYWR,WR3     SAVE REG WORK AREA ADRS                    27823821
         BAL   TRANR,T06WTOR TO WTOR AND WAIT                           27824521
         LR    WR3,KEYWR     RESTORE WORK AREA ADRS                     27825221
         CLC   E0(L'NCANCEL,WR2),NCANCEL REPLY CANCEL                   27825921
         BE    T06ED32       YES - MODIFY CNACELLED                     27826621
         CLI   E0(WR2),CU    REPLY 'U'                                  27827321
         BNE   NOTU          NO, CHECK FURTHER                          27828021
         XC    E0(E8,WR3),E0(WR3)      ZERO REG W A                     27828721
         B     NOCON         CONTINUE                                   27829421
NOTU     CLC   E0(L'REGSIZE,WR2),REGSIZE   REPLY REGSIZE                27830121
         BNE   NOTREG        NO- CHECK HOLD                             27830821
         NI    T6MRSW0,ALLFLAG-T6MRHLD YES, RESET HOLD                  27831521
         B     NOCON         CONTINUE                                   27832221
NOTREG   CLC   E0(L'HOLD,WR2),HOLD  REPLY HOLD                          27832921
         BNE   ERROR         NO - REPLY IS IN ERROR                     27833621
         XC    E4(E4,WR3),E4(WR3)      ZERO REG AND LSQS SZ             27834321
         NI    T6MRSW0,ALLFLAG-(T6MRSTR+T6MRSTP) CLEAR START STOP       27835021
NOCON    LA    WR3,T6MREND   NEXT W A                                   27835721
         BCT   WR5,MORE      DO MORE IF THERE IS ANY                    27836421
         DROP  WR3                                                      27837121
T06EDXX  EQU   *                                                        27837821
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       27838521
*********************************************************************** 27840020
*USERS= TO BE MODIFIED.  TSCVTLUS WILL BE CHANGED.                    * 27880020
*********************************************************************** 27920020
         TM    T6MSW0,T6MS0USE     USER= TO BE MODIFIED                 27960020
         BZ    T06ED11             NO                                   28000020
         SSM   DISABLE             NO INTERRPUTS                        28040020
         LH    WR1,T6MUSER         NEW LIMIT OF USERS ON TSO            28080020
         STH   WR1,TSCVTLUS        SET NEW LIMIT                        28120020
         SSM   ENABLE              ALLOW INTERRPUTS                     28160020
*********************************************************************** 28200020
*SMF= TO BE MODIFIED.  SMCAFOPT WILL BE CHANGED.                      * 28240020
*********************************************************************** 28280020
T06ED11  TM    T6MSW0,T6MS0SMF     SMF= TO BE MODIFIED                  28320020
         BZ    T06ED12             NO                                   28360020
         SSM   DISABLE             NO INTERRPUTS                        28400020
         L     WR2,CVTSMCA         ADDR. OF SMF CONTROL AREA            28440020
         USING SMCABASE,WR2        SMF CONTROL AREA                     28480020
         MVC   SMCAFOPT(E1),T6MSMF SET NEW OPTIONS FOR SMF              28520020
         SSM   ENABLE              ALLOW INTERRPUTS                     28560020
         DROP  WR2                 SMCA                                 28600020
*********************************************************************** 28640020
*REGSIZE TO BE MODIFIED.  SCAN MODIFY WORK AREA FOR EACH REGION.      * 28680020
*IF ANY REGSIZE AT ALL, SCAN MODIFY WORK AREA AND PERFORM MODIFY.     * 28720020
*********************************************************************** 28760020
         USING RCB,WR4             SET UP ADDRESSABILITY FOR RCB A42839 28790021
         USING T6MEDITR,WR3        ADDRESSABILITY                A42839 28820021
T06ED12  TM    T6MSW0,T6MS0RGN+T6MS0HLD IS MODIFY FOR REG OR HOLDA42839 28850021
         BZ    T06ED18             NO BRANCH                     A42839 28880021
         L     WR4,TSCVTRCB        GET ADR FIRST RCB                    28910021
         LA    WR3,T6MEND          YES GET REG ENTRY IN WK AR    A42839 28940021
         LH    WR5,TSCVTCTR        GET NUMBER OF REGIONS         A42839 28970021
         L     TSOECBS,TSCVTECB    GET ADR ECB TABLE             A42839 29000021
         USING TSECB,TSOECBS       SET UP ADDRESSABILITY                29030021
T06ED13  CLI   T6MRSW0,E0          IS SWITCH ZERO                A42839 29060021
         BE    T06ED14             YES BRANCH                    A42839 29090021
         LA    WR1,E1              GET NUMBER ONE                A42839 29120021
         AH    WR1,TSCVTCTR        ADD NUMBER OF REGIONS         A42839 29150021
         SR    WR1,WR5             GET REGION NUMBER             A42839 29180021
         CVD   WR1,T06WPACK        CONVERT TO BINARY             A42839 29210021
         OI    T06WPACK+E7,SIGNMASK                                     29240021
         UNPK  T06WEDIT(E2),T06WPACK+E6(E2)                             29270021
         SSM   DISABLE             NO INTERRUPTS                 A42839 29300021
         TM    RCBFLG2,RCBACTV     REGION ACTIVE                 A42839 29330021
         BZ    NOTACTV             BR IF NOT                     A42839 29360021
         TM    T6MRSW0,T6MRHLD     IS MODIFY FOR HOLD            A42839 29390021
         BO    HOLDRGN             BR IF ONLY HOLD               A42839 29420021
         OI    RCBFLG2,RCBSTOP     STOP REGION                   A42839 29450021
HOLDRGN  BAL   WR2,T06TSIP         STOP LOGONS                   A42839 29480021
         TM    T6MRSW0,T6MRHLD     HOLD?                         A42839 29510021
         BO    RHDONE              BR IF ONLY HOLD               A42839 29540021
         BAL   WR2,T06SILF         SILF USERS                    A42839 29570021
         TM    T6MRSW0,T6MRSTR     START?                        A42839 29600021
         BZ    MRDONE              BR IF ONLY STOP               A42839 29630021
MRSTART  OI    RCBFLG2,RCBSTR1+RCBSTR2 START REGION              A42839 29660021
MRDONE   OI    RCBFLG2,RCBMODFY    T06WAIT FLAG                  A42839 29690021
         OI    TSCVTFL1,TSCRSTOP   T03 RGN STOP START FLG        A42839 29720021
         MVC   RCBCONID(E1),CIBCONID PUT CONSOLE ID IN RCB       A42839 29750021
         MVC   RCBRSIZE(E2),T6MRSIZ PUT REG SIZE IN RCB          A42839 29780021
         MVC   RCBLSQSZ(E2),T6MRSQS PUT LSQS SIZ IN RCB          A42839 29810021
         SSM   ENABLE              ALLOW INTERRUPTS              A42839 29840021
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    29870021
         LA    WR1,TSCECB4   GET ADDRESS OF MODIFY REGION ECB           29900021
         MVI   E0(WR1),NOFLAG          CLEAR WAIT/POST BITS IN ECB      29930021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       29960021
         LA    WR1,TSCECB          GET ADR ECB                   A42839 29990021
         L     WR0,ECB7F                                                30020021
         POST  (1),(0)             POST TSC                      A42839 30050021
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    30080021
         LA    WR1,T06ECBL2  GET ADDRESS OF THE ECB LIST                30110021
         WAIT  ECBLIST=(WR1) WAIT FOR STOP OR REGION MODIFY TO          30140021
*                            COMPLETE                                   30170021
         L     WR1,L2ECB4AD  GET ADDRESS OF ECB4                        30200021
         TM    E0(WR1),POSTBIT         WAS IT REGION MODIFY COMPLETING  30230021
         BZ    ABORTMOD      BRANCH IF IT WAS A STOP DURING MODIFY      30260021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       30290021
         LH    WR1,T6MREGS         NUMBER OF REGIONS             A42839 30320021
         LA    WR1,E1(WR1)         ADD ONE                       A42839 30350021
         STH   WR1,T6MREGS         SVE NO REGIONS MODIFIED       A42839 30380021
         SSM   DISABLE             NO INTERRUPTS                 A42839 30410021
         NI    RCBFLG2,ALLFLAG-RCBMODFY RESET MODIFY FLAG        A42839 30440021
         NI    TSCVTFL1,ALLFLAG-TSCRSTOP RESET REG STOP FLAG     A42839 30470021
RHDONE   SSM   ENABLE              ALLOW INTERRUPTS              A42839 30500021
T06ED14  LA    WR3,T6MREND                                       A42839 30530021
         LA    WR4,RCBEND          UPDATE TO NEXT RCB                   30560021
         BCT   WR5,T06ED13         DECREMENT NUMBER OF REGIONS   A42839 30590021
         B     T06ED18                                                  30620021
NOTACTV  TM    RCBFLG2,RCBDEAD     DEAD FLAG SET                 A42839 30650021
         BO    T06RDMSG            ISSUE DEAD MESSAGE                   30680021
*   NOT ACTIVE, NOT DEAD, WAS IT START                                  30710021
         TM    T6MRSW0,T6MRSTR     START?                        A42839 30740021
         BO    MRSTART             BR IF START                   A42839 30770021
         B     T06RIMSG            INACTIVE MESSAGE              A42839 30800021
         EJECT                                                          30930020
         DROP  TSOECBS,WR3,WR4     ECBS,RCB,REG WK AREA                 30980021
*********************************************************************** 31040020
*SUBMIT= TO BE MODIFIED.  QMFIBMAX WILL BE CHANGED.                   * 31080020
*********************************************************************** 31120020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    31130021
T06ED18  L     KEYLR,CVTPTR        ADR CVT                              31140021
         USING CVTDSECT,KEYLR                                           31150021
         TM    T6MSW0,T6MS0SUB                                          31160021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       31170021
         BZ    T06ED19             NO                                   31200020
         SSM   DISABLE             NO INTERRUPTS                        31240020
         L     WR2,CVTJOB          ADDR. OF QUEUE MANAGER RESIDENT DATA 31280020
         USING IEFQMD,WR2          QUEUE MANAGER DATA                   31320020
         MVC   QMFIBMAX(E2),T6MSUB NEW SUBMIT MAXIMUM                   31360020
         SSM   ENABLE              ALLOW INTERRUPTS                     31400020
         DROP  WR2                 QUEUE MANAGER DATA                   31440020
*********************************************************************** 31480020
*DRIVER= TO BE MODIFIED. BUILD PARM LIST AND    BALR RTNR,EPR   TO    * 31520020
*IKJEAD03 OR ITS EQUIVLENT.  ENTRY POINT ADDR. AT TSCVTD03.           * 31560020
*********************************************************************** 31600020
T06ED19  TM    T6MSW0,T6MS0DRV     DRIVER=                              31640020
         BZ    T06ED25             MODIFY IS COMPLETE                   31680020
         NI    T6MSW0,ALLFLAG-T6MS0DRV RESET DRIVER= FLAG               31720020
         LA    WR1,T06WRBUF        USE REPLY BUFFER FOR PARM LIST       31760020
         USING D03DSECT,WR1        DO3 PARM LIST                        31800020
         XC    E0(D03PL,WR1),E0(WR1)   ZERO D03 PARM LIST               31840020
         L     WR2,CVTSMCA         ADDR. OF SMCA                        31880020
         LA    WR2,E0(WR2)         CLEAR HIGH BYTE                      31920020
         LTR   WR2,WR2             ZERO                                 31960020
         BZ    T06ED20             YES, SMF NOT ACTIVE                  32000020
         OI    D03SW0,D03SMF       SET SMF ACTIVE                       32040020
T06ED20  LH    WR0,CIBTJID         TJID FROM THE CIB                    32080020
         LTR   WR0,WR0             TJID IS NOT ZERO, TPUT ONLY          32120020
         BE    T06ED21             OPERATOR CONSOLE                     32160020
         OI    D03SW0,D03TPUT      SET TPUT ONLY                        32200020
         STH   WR0,D03TJID         TJID TO PARM LIST                    32240020
         B     T06ED22             CONTINUE                             32280020
T06ED21  MVC   D03CONID(E1),CIBCONID MOVE CONSOLE ID TO LIST            32320020
T06ED22  L     WR2,TSCVTICB        ADDR. OF INTERFACE CONTROL BLOCKS    32360020
         USING TSICB,WR2           INTERFACE CONTROL BLOCKS             32400020
         LA    WR2,TSICBDPA        ADDR. OF DPA                         32440020
         USING DPA,WR2             DPA                                  32480020
         MVC   D03DCA(E4),DPADCA   ADDR. OF DCA TO PARM LIST            32520020
         DROP  WR2                 DPA                                  32560020
         LH    WR2,T6MDRVL         LENGTH OF DATA                       32600020
         ST    WR2,D03LDATA        TO PARM LIST                         32640020
         MVC   D03ADATA(E4),T6MDRVA  ADDR. OF DATA                      32680020
         L     EPR,TSCVTD03        ENTRY POINT ADDR.                    32720020
         BALR  RTNR,EPR            GO                                   32760020
         EJECT                                                          32800020
         LR    WR5,WR15            SAVE RETURN CODE                     32840020
         LH    WR0,T6MDRVL         LENGTH OF AREA                       32880020
         L     WR1,T6MDRVA         ADDR. OF AREA                        32920020
         O     WR0,SP253MSK        SUBPOOL 253 MASK                     32960020
         FREEMAIN R,LV=(0),A=(1)   GIVE BACK SQS                        33000020
         LTR   WR5,WR5             TEST THE RETURN CODE                 33040020
         BZ    T06ED25             RC = 0                               33080020
         CLI   T6MSW0,E0           DRIVER= ONLY MODIFY TSO              33120020
         BNE   T06ED25             TSO MODIFY DONE                      33160020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    33170021
MODABHLP CLC   CIBTJID,TJID0 IF TJID=0 THEN THE COMMAND DID NOT         33180021
*                            ORIGINATE AT A TSO TERMINAL                33190021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       33200021
         BE    T06ED32             OPERATOR CONSOLE                     33240020
         B     T06ED34             TSO TERMINAL                         33280020
         DROP  KEYLR               CVT                                  33320020
*********************************************************************** 33360020
*MODIFY TSO IS DONE. TELL THE OPERATOR. IF SMF IS ACTIVE, BUILD AND   * 33400020
*ISSUE SMFWTR FOR SMF RECORD 41.                                      * 33440020
*IKJ079I JJJJJJJJ SSSSSSSS TSO HAS BEEN MODIFIED                      * 33480020
*********************************************************************** 33520020
T06ED25  CLI   T6MSW0,T06S0MSG     WAS THE ONLY MODIFY AN INVALID       33530020
*                                  SMF PARAMETER                        33532020
         BE    T06ED35             YES BYPASS SMF RECORD 41             33540020
         L     WR3,TSCVTTSC        ADDR. OF TSC TCB                     33560020
         L     WR3,TCBTIOT(WR3)    ADDR. OF TIOT                        33600020
         LA    WR1,T06WWTO         ADDR. OF WTO BUFFER                  33640020
         CLC   CIBTJID(E2),TJID0   IF TJID NOT ZERO, TSO TERMINAL       33680020
         BE    T06ED26             OPERATOR CONSOLE                     33720020
         MVC   E0(M079ITL,WR1),M079IT MOVE THE MESSAGE                  33760020
         MVC   M079ITJ(E8,WR1),TIOTJJJJ(WR3) JOB NAME TO MSG            33800020
         MVC   M079ITS(E8,WR1),TIOTSSSS(WR3) STEP NAME TO MSG           33840020
         LA    WR0,M079ITL         MESSAGE LENGTH                       33880020
         BAL   TRANR,T06TPUT       TO TPUT ROUTINE                      33920020
         B     T06ED27             B PAST WTO THIS MESSAGE              33960020
T06ED26  MVC   E0(M079IWL,WR1),M079IW MOVE THE MESSAGE                  34000020
         MVC   M079IWJ(E8,WR1),TIOTJJJJ(WR3) JOB NAME TO MSG            34040020
         MVC   M079IWS(E8,WR1),TIOTSSSS(WR3) STEP NAME TO MSG           34080020
         SR    WR0,WR0             ZERO                                 34120020
         IC    WR0,CIBCONID        CONSOLE ID                           34160020
         WTO   MF=(E,(1))          ISSUE THE WTO                        34200020
T06ED27  L     WR15,CVTPTR         ADDR. OF CVT                         34240020
         USING CVTDSECT,WR15       CVT                                  34280020
         L     WR15,CVTSMCA        ADDR, OF SMF CONTROL AREA            34320020
         DROP  WR15                CVT                                  34360020
         LA    WR15,E0(WR15)       CLEAR THE HIGH BYTE                  34400020
         LTR   WR15,WR15           IS SMF ACTIVE?                       34440020
         BZ    T06ED35             NO, IT IS NOT                        34480020
         USING SMCABASE,WR15       SMF CONTROL AREA                     34520020
         IC    KEYLR,SMCAFOPT      SMF FORE GROUND OPTIONS              34560020
         DROP  WR15                SMF CONTROL AREA                     34600020
         SPACE 3                                                        34640020
*********************************************************************** 34680020
*COMPUTE RECORD LENGTH AND GETMAIN FOR IT. BUILD FIXED PART.          * 34720020
*********************************************************************** 34760020
         USING T6MEDIT,MODWAR      MODIFY WORK AREA                     34800020
         LA    WR5,SMF41L          LENGTH FIXED PART RECORD 41          34840020
         LA    WR4,SMF41EL         LENGTH REGION ENTRY                  34880020
         MH    WR4,T6MREGS         TIMES NUMBER REGIONS MODIFIED        34920020
         AR    WR5,WR4             FIXED PLUS VARIABLE                  34960020
*                                  GETMAIN FOR SMF RECORD TYPE 41       35000020
         GETMAIN EC,LV=(WR5),A=T06WWECB,SP=0,MF=(E,T06WRBUF) SMF 41     35040020
         LTR   WR15,WR15           GETMAIN O.K.                         35080020
         BP    T06ED35             NO, FORGET ABOUT SMF RECORD 41       35120020
         L     WR1,T06WWECB        ADDR. OF SMF RECORD 41               35160020
         USING SMFRD,WR1           SMF RECORD                           35200020
         XC    E0(SMF41L,WR1),E0(WR1) CLEAR FIXED PART RECORD           35240020
         STH   WR5,SMFRL           RECORD LENGTH                        35280020
         MVI   SMFRT,SMFRT41       RECORD TYPE                          35320020
         MVC   SMFPROC(E16),E0(WR3) PROC AND ID FROM TIOT               35360020
         MVC   SMF41TRM(E2),TSCVTLUS  CURRENT LIMIT USER                35400020
         STC   KEYLR,SMF41SMF      SMF FORE GROUND OPTIONS              35440020
         AR    WR5,WR1             ADDR. END OF RECORD                  35480020
         LA    WR3,SMF41LV         ADDR. OF VARIABLE LENGTH FIELD       35520020
         SR    WR5,WR3             LENGTH OF VARIABLE PART OF RECORD    35560020
         STH   WR5,SMF41LV         TO LENGTH FIELD                      35600020
         EJECT                                                          35640020
         LH    WR15,T6MREGS        NUMBER OF REGIONS MODIFIED           35680020
         STC   WR15,SMF41NV        IS NUMBER OF REGION ENTRIES          35720020
         TM    T6MSW0,T6MS0RGN     ANY REGION MODIFIED                  35760020
         BZ    T06ED31             NO                                   35800020
*********************************************************************** 35840020
*BUILD A REGION ENTRY FOR EACH USER REGION MODIFICATION.              * 35880020
*********************************************************************** 35920020
         USING SMF41ED,WR2         SMF REGION ENTRY                     35960020
         LA    WR2,SMF41END        ADDR. FIRST REGION ENTRY             36000020
         USING T6MEDITR,WR5        REGION MODIFY WORK AREA              36040020
         LA    WR5,T6MEND          ADDR. OF REGION MODIFY WORK AREA     36080020
         LH    WR4,TSCVTCTR        NUMBER OF REGIONS                    36120020
T06ED28  TM    T6MRSW0,T6MRSTP+T6MRSTR REGION STOP OR START             36160020
         BNZ   T06ED30              YES                                 36200020
T06ED29  LA    WR5,T6MREND         NEXT REGION MODIFY AREA              36240020
         BCT   WR4,T06ED28         ANOTHER REGION MODIFY AREA           36280020
         B     T06ED31             NO, DONE BUILDING THE RECORD         36320020
T06ED30  XC    E0(SMF41EL,WR2),E0(WR2) ZERO SMF REGION ENTRY            36360020
         USING RCB,WR15            RCB                                  36400020
         L     WR15,T6MRCBA        ADDR. OF THE RCB                     36440020
         MVC   SMF41ERN(E1),RCBNMBR  REGION NUMBER TO SMF ENTRY         36480020
         MVC   SMF41ERL(E2),T6MRSQS  LOCAL SQS SIZE TO SMF ENTRY        36520020
         MVC   SMF41ERS(E2),T6MRSIZ REGION SIZE SMF ENTRY               36560020
         LA    WR2,SMF41EAN        ADDR. NEXT SMF REGION ENTRY          36600020
         B     T06ED29             NEXT MODIFY REGION ENTRY             36640020
T06ED31  SMFWTM  (1)               SMF WRITER(IGNORE RC'S)              36680020
         L     WR1,T06WWECB        ADDR. OF SMF RECORD                  36720020
         LH    WR0,SMFRL           RECORD LENGTH                        36760020
         FREEMAIN R,LV=(0),A=(1)   RELEASE MAIN STORAGE                 36800020
         B     T06ED35             MODIFY COMPLETE                      36840020
         DROP  WR1,WR2,WR5,WR15    SMF, SMF, REGION MODIFY, RCB         36880020
         EJECT                                                          36920020
*********************************************************************** 36960020
*OPERATOR HAS CANCELLED MODIFY TSO. ACKNOWLEDGE THE FACT.             * 37000020
*IKJ080I TSO MODIFY CANCELLED BY OPERATOR                             * 37040020
*********************************************************************** 37080020
T06ED32  LA    WR1,M080IW          ADDR. WTO LIST                       37120020
         SR    WR0,WR0             ZERO                                 37160020
         IC    WR0,CIBCONID        CONSOLE ID                           37200020
         WTO   MF=(E,(1))          ISSUE WTO                            37240020
         B     T06ED35             RELE MODFY WK AREA            A42839 37280021
*********************************************************************** 37320020
*MODIFY OF TSO FROM TSO TERMINAL HAS FAILED. TELL OPERATOR.           * 37360020
*IKJ081I TSO MODIFY REJECTED                                          * 37400020
*********************************************************************** 37440020
T06ED34  LA    WR0,M081ITL         LEN. MESSAGE                         37480020
         LA    WR1,M081IT          ADDR. MESSAGE                        37520020
         BAL   TRANR,T06TPUT       TPUT ROUTINE                         37560020
*********************************************************************** 37600020
*RELEASE THE MODIFY WORK AREA. GO BACK TO CIB SEARCH.                 * 37640020
*********************************************************************** 37680020
         USING T6MEDIT,MODWAR      MODIFY WORK AREA                     37720020
T06ED35  MVI   T6MLEN,E0           CLEAR HI BYTE OF LENGTH       A42839 37760021
         L     WR0,T6MLEN          LENGTH OF MODIFY WORK AREA           37800020
         FREEMAIN R,LV=(0),A=(MODWAR) RELEASE THE WORK AREA             37840020
         B     T602                RELEASE THE CIB                      37880020
         EJECT                                                          37920020
*********************************************************************** 37960020
*TABLE DRIVER KEYWORD EDIT. DETERMINES VALIDITY AND LENGTH OF KEYWORD * 38000020
*IN CIB.   KEYWR CONTAINS ADDR. OF KEYWORD.                           * 38040020
*WR1-ADDR. OF NEXT ENTRY IN EDIT TABLE  WR2-LEN. MODEL KEYWORD MINUS 1* 38080020
*WR2-LENGTH KEYWORD  WR4-ADDR. OF KEYWORD HANDLING ROUTINE            * 38120020
*WR3-ADDR. OF MODEL KEYWORD   WR4-ADDR. OF KEYWORD HANDLING ROUTINE   * 38160020
*TRANR-RETURN ADDR.  INVALID 0(TRANR)    VALID 4(TRANR)               * 38200020
*********************************************************************** 38240020
T06EDR00 LA    WR1,T06ETAB         ADDR. OF EDIT TABLE                  38280020
T06EDR01 LM    WR1,WR4,E0(WR1)     LOAD  EDIT TABLE ENTRY               38320020
         EX    WR2,T06EDRC1        KEYWORD TO MODEL KEYWORD             38360020
         BE    E4(TRANR)           GOOD(BE)                             38400020
         LTR   WR1,WR1             ANOTHER ENTRY IN TABLE               38440020
         BNZ   T06EDR01            YES                                  38480020
         BR    TRANR               DID NOT FIND KEY WORD                38520020
         SPACE                                                          38560020
*********************************************************************** 38600020
*DETERMINE ADDR. TO START NEXT KEYOWRD EDIT IN THE CIB.               * 38640020
*TYPES OF KEYWORDS AND DATA ARE                                       * 38680020
*1) KEYWORD=DATA,X    2) KEYWORD=(DATA),X                             * 38720020
*3) KEYWORD(DATA)=(DATA,DATA),X                                       * 38760020
*WR1 - ADDR. OF D OF DATA WITH THE KEYWORD.  ON RETURN, WR2 - ADDR.   * 38800020
*TO START EDIT FOR NEXT KEYWORD.                                      * 38840020
*********************************************************************** 38880020
T06EDR20 LR    WR2,WR1             START OF DATA                        38920020
         CLI   E0(WR2),CLP         KEYWORD=(DATA)                       38960020
         BE    T06EDR25            YES                                  39000020
*********************************************************************** 39040020
*FORM IS KEYWORD=DATA,KEYWORD    FIND THE ADDR. OF THE COMMA.         * 39080020
*********************************************************************** 39120020
T06EDR21 CLI   E0(WR2),CCOMA       COMMA                                39160020
         BCR   8,TRANR             YES(BE)                              39200020
         LA    WR2,E1(WR2)         BUMP ADDR.                           39240020
         C     WR2,T6MCIBER        END OF CIB                           39280020
         BCR   8,TRANR             YES(BE)                              39320020
         B     T06EDR21            TO TOP                               39360020
*********************************************************************** 39400020
*KEYWORD=(DATA) OR REGSIZE(DATA)=(DATA,DATA).                         * 39440020
*********************************************************************** 39480020
T06EDR25 CLC   E0(L'T06EREG,KEYWR),T06EREG  REGSIZE(DATA)=(DATA,DATA)   39520020
         BE    T06EDR28            TO FIND SECOND LEFT PAREN            39560020
         EJECT                                                          39600020
*********************************************************************** 39640020
*FORM IS KEYWORD=(DATA),KEYWORD   FIND ADDR. OF RIGHT PAREN PLUS ONE  * 39680020
*********************************************************************** 39720020
T06EDR26 CLI   E0(WR2),CRP         RIGHT PAREN.                         39760020
         BE    T06EDR27            YES                                  39800020
         LA    WR2,E1(WR2)         BUMP ADDR.                           39840020
         C     WR2,T6MCIBER        END OF CIB                           39880020
         BCR   8,TRANR             YES(BE)                              39920020
         B     T06EDR26            TO TOP                               39960020
T06EDR27 LA    WR2,E1(WR2)         ADDR. OF RIGHT PAREN PLUS ONE        40000020
         BR    TRANR               RETURN                               40040020
*********************************************************************** 40080020
*FORM IS KEYWORD(DATA)=(DATA,DATA)    FIND SECOND LEFT PAREN          * 40120020
*********************************************************************** 40160020
T06EDR28 LA    WR2,E1(WR2)         BUMP PAST FIRST LEFT PAREN           40200020
         C     WR2,T6MCIBER        END OF CIB                           40240020
         BCR   8,TRANR             YES(BE)                              40280020
T06EDR29 CLI   E0(WR2),CLP         LEFT PAREN                           40320020
         BE    T06EDR26            YES, TO SCAN FOR NEXT RIGHT PAREN    40360020
         LA    WR2,E1(WR2)         BUMP ADDR.                           40400020
         C     WR2,T6MCIBER        END OF CIB                           40440020
         BCR   8,TRANR             YES(BE)                              40480020
         B     T06EDR29            TO TOP                               40520020
         EJECT                                                          40560020
*********************************************************************** 40600020
*T06EDR40  INVALID KEYWORD OPERATOR COMMUNICATIONS ROUTINE.           * 40640020
*IKJ070I CCCCCCCCCCCCCCCCCCCCCCCCCCCCCC KEYWORD INVALID               * 40680020
*T06EDR50  VALID KEYWORD AND INVALID DATA COMMUNICATIONS ROUTINE.     * 40720020
*IKJ071I CCCCCCCCCCCCCCCCCCCCCCCCCCCCCC DATA INVALID                  * 40760020
*                                                                     * 40800020
*KEYLR CONTAIN THE ADDR. AND LENGTH OF THE INVALID KEYWORD AND DATA.  * 40840020
*IF MODIFY IS FROM TSO TERMINAL IN THE OPERATOR MODE, WE CAN NOT      * 40880020
*COMMUNICTE WITH THE TERMINAL(ONLY TPUT IS VALID). SET UP MESSAGE AND * 40920020
*ISSUE THE TPUT WITHOUT ANY OTHER PROCESSING.                         * 40960020
*                                                                     * 41000020
*IN  T06EDR40, WR5 AND WR15 ARE LOADED.                               * 41040020
*FOR T06EDR50, WR5 AND WR15 MUST BE TRANSPARENT.                      * 41080020
*********************************************************************** 41120020
T06EDR40 LA    WR1,T06WWTO         ADDR. OF WTO BUFFER                  41160020
         LA    WR2,M070IXL         MAX LEN. VARIABLE IN MESSAGE         41200020
         CR    WR2,KEYLR           VARIABLE TO INVALID KEYWORD AND DATA 41240020
         BL    T06EDR41            INVALID DATA LONGER THAN VARIABLE    41280020
         LTR   KEYLR,KEYLR         IS KEY LENGTH ZERO         CC A67860 41290021
         BP    T06EDR43            BRANCH IF NOT ZERO         CC A67860 41300021
         LA    KEYLR,E1            SET LENGTH TO ONE          CC A67860 41310021
T06EDR43 LR    WR2,KEYLR           LENGTH OF VARIABLE         CC A67860 41320021
T06EDR41 BCTR  WR2,0               MINUS ONE FOR EXECUTE                41360020
         CLC   CIBTJID(E2),TJID0   TJID NOT EQUAL ZERO, TSO TERMINAL    41400020
         BE    T06EDR42            OPERATOR CONSOLE                     41440020
         MVC   E0(M070ITL,WR1),M070IT MOVE THE TPUT MESSAGE             41480020
         EX    WR2,T6EM70TX        MOVE THE VARIABLE                    41520020
         LA    WR0,M070ITL         LENGTH TPUT MESSAGE                  41560020
         BAL   TRANR,T06TPUT       TO TPUT ROUTINE                      41600020
         B     T06ED34             TSO MODIFY REJECTED                  41640020
T06EDR42 MVC   E0(M070IWL,WR1),M070IW  MOVE THE WTO MESSAGE             41680020
         EX    WR2,T6EM70WX        MOVE THE VARIABLE                    41720020
         LA    WR5,NKEY            ADDR. OF 'KEYWORD=VALUE'             41760020
         SR    WR15,WR15           SET ANY KEYWORD IN REPLY             41800020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    41820021
         B     T06EDR60      TALK TO OPERATOR                           41840021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       41860021
         SPACE                                                          41880020
T06EDR50 LA    WR1,T06WWTO         ADDR. OF WTO BUFFER                  41920020
         LA    WR2,M071IXL         MAX. LENGTH VARIABLE IN MESSAGE      41960020
         CR    WR2,KEYLR           VARIABLE TO INVALID KEYWORD AND DATA 42000020
         BL    T06EDR51            INVALID DATA LONGER THAN VARIABLE    42040020
         LR    WR2,KEYLR           LENGTH OF VARIABLE                   42080020
T06EDR51 BCTR  WR2,0               MINUS ONE FOR EXECUTE                42120020
         CLC   CIBTJID(E2),TJID0   TJID NOT EQUAL ZERO, TSO TERMINAL    42160020
         BE    T06EDR52            OPERATOR CONSOLE                     42200020
         MVC   E0(M071ITL,WR1),M071IT MOVE THE TPUT MESSAGE             42240020
         EX    WR2,T6EM71TX        MOVE THE VARIABLE                    42280020
         LA    WR0,M071ITL         LENGTH TPUT MESSAGE                  42320020
         BAL   TRANR,T06TPUT       TO TPUT ROUTINE                      42360020
         B     T06ED34             TSO MODIFY REJECTED                  42400020
T06EDR52 MVC   E0(M071IWL,WR1),M071IW  MOVE THE WTO MESSAGE             42440020
         EX    WR2,T6EM71WX        MOVE THE VARIABLE                    42480020
         B     T06EDR60            TO COMMON                            42520020
         EJECT                                                          42560020
*********************************************************************** 42600020
*T06EDR60 ISSUES THE FOLLOWING MESSAGE SEQUENCE:                      * 42640020
*IKJNNNI SOMETHING IS NOT QUITE RIGHT                                 * 42680020
*IKJ066D REPLY 'A PARAMETER', 'U' OR 'CANCEL' OR IKJ066D REPLY        * 42720020
*'A PARAMETER', OR 'CANCEL'(WHEN A  'U' IS NOT VALID)                 * 42730020
*                                                                     * 42760020
*T06WWTO(THE WTO BUFFER IN THE WORK AREA) CONTAINS THE IKJNNNI MSG.   * 42800020
*WR5 - ADDRESS OF 'A SOMETHING' FOR IKJ076D MESSAGE.                  * 42840020
*WR15 - EITHER 1) EQ 0 FOR ANY KEYWORD ON THE REPLY IS VALID, OR      * 42880020
*2) ADDR. OF EDIT TABLE FOR A SPECIFIC KEYWORD                        * 42920020
*                                                                     * 42960020
*REPLY XX,'KEYWORD=VALUE'                                             * 43000020
*1) WR15 EQ 0 AND THE KEYWORD IS VALID, TO KEYWORD HANDLING ROUTINE   * 43040020
*2) WR15 EQ 0 AND THE KEYWORD IS INVALID, TO INVALID KEYWORD(T06EDR40)* 43080020
*3) WR15 NE 0 AND THE KEWORD IS SAME AS WR15 SPECIFICES, TO KEYWORD   * 43120020
*   HANDLING ROUTINE.                                                 * 43160020
*4) WR15 NE 0 AND THE KEYWORD IS INVALID, REISSUE IKJ076D(T06EDR61)   * 43200020
*********************************************************************** 43240020
T06EDR60 LA    WR1,T06WWTOR        ADDR. OF WTOR BUFFER                 43280020
         MVC   E0(M076DL,WR1),M076D MOVE THE WTOR MESSAGE               43320020
         MVC   M076DX(NKEYL,WR1),E0(WR5) MOVE VARIABLE TO WTOR          43360020
T06EDR64 ST    WR15,T06WEDIT       SAVE WR15 ACROSS WTO/WTOR            43400020
         SR    WR0,WR0             ZERO                                 43440020
         IC    WR0,CIBCONID        CONSOLE ID FROM CIB                  43480020
         WTO   MF=(E,T06WWTO)      ISSUE THE WTO                        43520020
T06EDR61 BAL   TRANR,T06WTOR       TO WTOR AND WAIT ROUTINE             43560020
*                                  WR2-ADDR. OF REPLY                   43600020
*                                  WR3-LENGTH REPLY BUFFER              43640020
         BAL   TRANR,T06EDR70      CHECK FOR 'U' OR 'CANCEL'            43680020
         BAL   TRANR,T06EDR80      FIND FIRST BLANK                     43720020
         L     WR15,T06WEDIT       RELOAD WR15                          43760020
         LR    KEYWR,WR2           ADDR. OF NEW KEYWORD                 43800020
         SR    WR1,WR2             START FROM ADDR. BLANK IS LENGTH     43840020
         LR    KEYLR,WR1           LENGTH OF KEYWORD=VALUE              43880020
         LTR   WR15,WR15           WR15 IS ZERO, ANY KEYWORD IS VALID   43920020
         BZ    T06EDR62            ANY KEYWORD                          43960020
         LM    WR1,WR4,E0(WR15)    LOAD EDIT TABLE FOR THIS KEYWORD     44000020
         EX    WR2,T06EDRC1        TEST FOR CORRECT KEYWORD             44040020
         BNE   T06EDR61            WRONG ONE, WRITE THE OPER. AGAIN     44080020
         BR    WR4                 TO KEYWORD HANDLING ROUTINE          44120020
T06EDR62 BAL   TRANR,T06EDR00      TO KEYWORD EDIT                      44160020
         B     T06EDR40            KEYWORD IS NOT SUPPORTED             44200020
         BR    WR4                 TO KEYWORD HANDLER                   44240020
         EJECT                                                          44280020
*********************************************************************** 44320020
*T06EDR70 EDITS A BUFFER FOR OPERATOR REPLIES.  WR2 - ADDR. OF BUFFER * 44360020
*1) REPLY XX,'U' - IGNORE THIS KEYWORD, RESUME CIB EDIT(T06ED00)      * 44400020
*2) REPLY XX,'CANCEL' - CANCEL MODIFY OF TSO(T06ED32)                 * 44440020
*CHECK FOR 'USERS=NNNNN' FIRST(LOOKS JUST LIKE 'U')                   * 44480020
*********************************************************************** 44520020
T06EDR70 CLC   E0(L'T06EUSE,WR2),T06EUSE REPLY XX,'USERS=NNNNN'         44560020
         BCR   8,TRANR             YES                                  44600020
         CLI   E0(WR2),CU          REPLY XX,'U'                         44640020
         BE    T06ED00             RESUME THE EDIT                      44680020
         CLC   E0(L'NCANCEL,WR2),NCANCEL  REPLY XX,'CANCEL'             44720020
         BE    T06ED32             CANCEL THIS MODFIY                   44760020
         BR    TRANR               RETURN                               44800020
         SPACE                                                          44840020
*********************************************************************** 44880020
*T06EDR80 FINDS THE ADDR. OF THE FIRST BLANK IN A BUFFER.             * 44920020
*WR2 - ADDR. OF BUFFER.  WR3 - LENGTH OF BUFFER.  RETURN   WR1 - ADDR.* 44960020
*FIRST BLANK OR END OF BUFFER.                                        * 45000020
*********************************************************************** 45040020
T06EDR80 LR    WR1,WR2             ADDR. OF BUFFER                      45080020
         LR    WR0,WR2             ADDR. OF BUFFER PLUS LENGTH OF BUF   45120020
         AR    WR0,WR3             IS ADDR. OF END OF BUFFER            45160020
T06EDR81 CLI   E0(WR1),CBLANK      BLANK                                45200020
         BCR   8,TRANR             BE, BLANK RETURN                     45240020
         LA    WR1,E1(WR1)         BUMP SEARCH ADDR.                    45280020
         CR    WR1,WR0             END OF BUFFER                        45320020
         BCR   8,TRANR             BE - YES                             45360020
         B     T06EDR81            TO TOP                               45400020
         SPACE                                                          45440020
*********************************************************************** 45480020
*T06EDR90 CHECK DATA FOR NUMERICS.  WR5 - ADDR. OF DATA. WR4 - LENGTH * 45520020
*RETURNS    0(TRANR)  DATA IS INVALID AND 4(TRANR) IS VALID.          * 45560020
*********************************************************************** 45600020
T06EDR90 LR    WR1,WR5             ADDR. OF DATA                        45640020
         LR    WR0,WR5             ADDR. OF DATA PLUS LENGTH IS         45680020
         AR    WR0,WR4             ADDR. OF END OF DATA                 45720020
T06EDR91 CR    WR1,WR0             END OF DATA                          45760020
         BE    E4(TRANR)           DONE, DATA IS VALID                  45800020
         TM    E0(WR1),NUMASK      DATA IS NUMERIC                      45840020
         BM    E0(TRANR)           NO, IT IS NOT                        45880020
         LA    WR1,E1(WR1)         BUMP CHECK ADDR.                     45920020
         B     T06EDR91            TO TOP OF CHECKER LOOP               45960020
         EJECT                                                          46000020
*********************************************************************** 46040020
*********************************************************************** 46080020
*T06USE IS THE KEYWORD HANDLING ROUTINE FOR                           * 46120020
*        USERS=NNNNN                                                  * 46160020
*WHERE NNNNN IS THE NEW LIMIT OF USERS ON TSO(TSCVTLUS) AND MAY       * 46200020
*NOT EXCEED THE MAXIMUM NUMBER OF USERS ON TSO(TSCVTMUS)              * 46240020
*IF TSO TERMINAL IN OPERATOR MODE, ANY ERROR IS FATAL.                * 46280020
*KEYWR-ADDR. OF KEYWORD  KEYLR-LENGTH OF KEYWORD                      * 46320020
*AT COMPLETION, BRANCHES TO T06ED00                                   * 46360020
*********************************************************************** 46400020
*********************************************************************** 46440020
T06USE   LH    WR2,TSCVTMUS        MAXIMUM NUMBER OF USERS ON TSO       46480020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    46488021
         NI    T6MSW0,ALLFLAG-T6MS0USE ZERO USER FLAG                   46496021
         XC    T6MUSER,T6MUSER         ZERO LIMIT                       46504021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       46512021
         LA    WR5,L'T06EUSE(KEYWR) ADDR. OF THE DATA NNNNN             46520020
         LA    WR3,L'T06EUSE       LENGTH USERS=                        46560020
         LR    WR4,KEYLR           LENGTH USERS=NNNNN                   46600020
         SR    WR4,WR3             MINUS LENGTH USERS= IS LENGTH NNNNN  46640020
         C     WR4,NF5             LENGTH NNNNN TO 5                    46680020
         BH    T06US05             DATA IS INVALID                      46720020
T06US01  BAL   TRANR,T06EDR90      DATA IS NUMERIC                      46760020
         B     T06US05             NO, DATA IS INVALID                  46800020
         BCTR  WR4,0               MINUS ONE FROM LENGTH                46840020
         EX    WR4,T06NNPK         PACK NNNNN                           46880020
         CVB   WR1,T06WPACK        TO BINARY                            46920020
         CR    WR1,WR2             NEW LIMIT TO MAXIMUM                 46960020
         BH    T06US02             ERROR, NEW LIMIT GT MAX              47000020
*********************************************************************** 47040020
*NEW LIMIT OF USERS ON TSO IS VALID. SAVE THE VALUE IN THE MODIFY WORK* 47080020
*AREA AND SET USER= SUCESSFUL SWITCH.                                 * 47120020
*********************************************************************** 47160020
         STH   WR1,T6MUSER         NEW LIMIT OF USERS                   47200020
         OI    T6MSW0,T6MS0USE     SET USERS= SWITCH                    47240020
         B     T06ED00             RETURN TO EDIT CIB ROUTINE           47280020
         EJECT                                                          47320020
*********************************************************************** 47360020
*ERROR NEW CURRENT LIMIT EXCEEDS MAXIMUM LIMIT. INFORM OPERATOR.      * 47400020
*IKJ072I USERS=99999         EXCEEDS MAXIMUM OF 00000                   47440020
*********************************************************************** 47480020
T06US02  LA    WR1,T06WWTO         ADDR. OF MESSAGE BUFFER              47520020
         CVD   WR2,T06WPACK        MAX TO BINARY                        47560020
         OI    T06WPACK+E7,SIGNMASK CHANGE SIGN FROM C TO F FOR PRINT   47600020
         LA    WR4,M072IXL         LENGTH VARIABLE IN MESSAGE           47640020
         CR    WR4,KEYLR           VARIABLE TO KEYWORD=VALUE            47680020
         BL    T06US03             KEYWORD TOO LONG                     47720020
         LR    WR4,KEYLR           USE KEYWORD LENGTH                   47760020
T06US03  BCTR  WR4,0               MINUS ONE FOR EXECUTE                47800020
         CLC   CIBTJID(E2),TJID0   TJID NOT EQUAL ZERO, TSO TERMINAL    47840020
         BE    T06US04             OPERATOR CONSOLE                     47880020
         MVC   E0(M072ITL,WR1),M072IT MOVE THE TPUT MESSAGE             47920020
         UNPK  M072ITY(M072IYL,WR1),T06WPACK UN PACK MAX INTO MESSAGE   47960020
         EX    WR4,T6EM72TX        MOVE VARIABLE TO MESSAGE             48000020
         LA    WR0,M072ITL         LENGTH TPUT MESSAGE                  48040020
         BAL   TRANR,T06TPUT       TO TPUT ROUTINE                      48080020
         B     T06ED34             MODIFY REJECTED                      48120020
T06US04  MVC   E0(M072IWL,WR1),M072IW MOVE THE WTO MESSAGE              48160020
         UNPK  M072IWY(M072IYL,WR1),T06WPACK UN PACK MAX INTO MESSAGE   48200020
         EX    WR4,T6EM72WX        MOVE VARIABLE TO MESSAGE             48240020
         LA    WR5,NUSE            ADDR. OF 'USERS=NNNNN'               48280020
         LA    WR15,T06ETUSE       ADDR. EDIT TABLE 'USERS=NNNNN'       48320020
         B     T06EDR60            TO TALK TO OPERATOR                  48360020
*********************************************************************** 48400020
*DATA IS INVALID.  NOT NUMERIC OR NNNNN GREATER THAN 5 CHARS.         * 48440020
*********************************************************************** 48480020
T06US05  LA    WR15,T06ETUSE       ADDR. EDIT TABLE USERS=              48520020
         LA    WR5,NUSE            ADDR. MODEL 'USERS=NNNNN'            48560020
         B     T06EDR50            INVALID DATA ROUTINE                 48600020
         EJECT                                                          48640020
*********************************************************************** 48680020
*********************************************************************** 48720020
*T06DRV IS THE KEYWORD HANDLING ROUTINE FOR                           * 48760020
*        DRIVER=(SOME PARAMETERS)                                     * 48800020
*AND DRIVER MODIFICATION ROUTINE(IKJEAD03 OR ITS EQUIVALENT IS        * 48840020
*INVOKED. ADDR. OF DRIVER MODIFY ROUTINE AT TSCVTD03.                 * 48880020
*NO EDIT OF DATA WITH DRIVER= IS DONE BY THIS MODULE.                 * 48920020
*KEYWR-ADDR. OF KEYWORD  KEYLR-LENGTH OF KEYWORD                      * 48960020
*AT COMPLETION, BRANCHES TO T06ED00                                   * 49000020
*********************************************************************** 49040020
*********************************************************************** 49080020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    49088021
T06DRV   TM    T6MSW0,T6MS0DRV         WAS DRIVER EDITED ONCE           49096021
         BZ    T06DRV2       NI, GET STORAGE                            49104021
         L     WR1,T6MDRVA   YES, MUST FREE LAST SPACE                  49112021
         LH    WR0,T6MDRVL   *                                          49120021
         O     WR0,SP253MSK  *                                          49128021
         FREEMAIN  R,LV=(0),A=(1)      *                                49136021
T06DRV2  GETMAIN R,LV=(KEYLR),SP=253 GET STORAGE FOR DRIVER=DATA        49144021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       49152021
         ST    WR1,T6MDRVA         ADDR. OF DATA TO WORK AREA           49160020
         STH   KEYLR,T6MDRVL       LENGTH OF DATA TO WORK AREA          49200020
         BCTR  KEYLR,0             MINUS ONE FOR EXECUTE                49240020
         EX    KEYLR,T06DRV01      MOVE THE DATA TO GETMAIN AREA        49280020
         OI    T6MSW0,T6MS0DRV     SET DRIVER= IN MOD WORK AREA         49320020
         B     T06ED00             RESUME EDIT                          49360020
         SPACE                                                          49400020
T06DRV01 MVC   E0(E0,WR1),E0(KEYWR) MOVE THE DATA                       49440020
         EJECT                                                          49480020
*********************************************************************** 49520020
*********************************************************************** 49560020
*T06SUB IS THE KEYWORD HANDLING ROUTINE FOR                           * 49600020
*        SUBMIT=NNNN                                                  * 49640020
*WHERE NNNNN IS THE MAXIMUM NUMBER OF LOGICAL JOB QUEUE TRACKS TO  BE * 49680020
*RESERVED(QMFIBMAX) AND MAY NOT EXCEED A DEFINED LIMIT(QMFIBLIM).     * 49720020
*QMFIBMAX AND QMFIBMIN ARE DEFINED IN THE QUEUE MANAGER RESIDENT DATA * 49760020
*AREA.  ADDR. OF AREA AT CVTJOB.                                      * 49800020
*IF TSO TERMINAL IN OPERATOR MODE, ANY ERROR IS FATAL.                * 49840020
*KEYWR-ADDR. OF KEYWORD  KEYLR-LENGTH OF KEYWORD                      * 49880020
*AT COMPLETION, BRANCHES TO T06ED00                                   * 49920020
*********************************************************************** 49960020
*********************************************************************** 50000020
T06SUB   L     WR15,CVTPTR         ADDR. OF CVT                         50040020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    50048021
         NI    T6MSW0,ALLFLAG-T6MS0SUB RESET SUBMIT FLAG                50056021
         XC    T6MSUB,T6MSUB ZERO      ZERO LIMIT                       50064021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       50072021
         USING CVTDSECT,WR15       CVT                                  50080020
         L     WR15,CVTJOB         ADDR. QUEUE MANG. RESIDENT DATA      50120020
         USING IEFQMD,WR15         QUEUE MANAGER RESIDENT DATA          50160020
         LH    WR2,QMFIBLIM        LOGICAL TRACK LIMIT FOR SUBMIT       50200020
         DROP  WR15                QUEUE MANAGER RESIDENT DATA          50240020
         LA    WR5,L'T06ESUB(KEYWR) ADDR. OF THE DATA NNNNN             50280020
         LA    WR3,L'T06ESUB       LENGTH SUBMIT=                       50320020
         LR    WR4,KEYLR           LENGTH SUBMIT=NNNNN                  50360020
         SR    WR4,WR3             MINUS LENGTH SUBMIT= IS LENGTH NNNNN 50400020
         C     WR4,NF5             LENGTH NNNNN TO 5                    50440020
         BH    T06SB05             DATA IS INVALID                      50480020
T06SB01  BAL   TRANR,T06EDR90      DATA IS NUMERIC                      50520020
         B     T06SB05             NO, DATA IS INVALID                  50560020
         BCTR  WR4,0               MINUS ONE FROM LENGTH                50600020
         EX    WR4,T06NNPK         PACK NNNNN                           50640020
         CVB   WR1,T06WPACK        TO BINARY                            50680020
         CR    WR1,WR2             NEW LIMIT TO MAXIMUM                 50720020
         BH    T06SB02             ERROR, NEW LIMIT GT MAX              50760020
*********************************************************************** 50800020
*NEW MAXIMUM OF LOGICAL JOB QUEUE TRACKS IS VALID.  SAVE VALUE IN THE * 50840020
*MODIFY WORK AREA AND SET SUBMIT= SWITCH.                             * 50880020
*********************************************************************** 50920020
         STH   WR1,T6MSUB          NEW SUBMIT MAXIMUM                   50960020
         OI    T6MSW0,T6MS0SUB     SET SUBMIT= SWITCH                   51000020
         B     T06ED00             RETURN TO EDIT CIB ROUTINE           51040020
         EJECT                                                          51080020
*********************************************************************** 51120020
*ERROR NEW CURRENT LIMIT EXCEEDS MAXIMUM LIMIT. INFORM OPERATOR.      * 51160020
*IKJ072I SUBMIT=99999         EXCEEDS MAXIMUM OF 00000                * 51200020
*********************************************************************** 51240020
T06SB02  LA    WR1,T06WWTO         ADDR. OF MESSAGE BUFFER              51280020
         CVD   WR2,T06WPACK        MAX TO BINARY                        51320020
         OI    T06WPACK+E7,SIGNMASK CHANGE SIGN FROM C TO F FOR PRINT   51360020
         LA    WR4,M072IXL         LENGTH VARIABLE IN MESSAGE           51400020
         CR    WR4,KEYLR           VARIABLE TO KEYWORD=VALUE            51440020
         BL    T06SB03             KEYWORD TOO LONG                     51480020
         LR    WR4,KEYLR           USE KEYWORD LENGTH                   51520020
T06SB03  BCTR  WR4,0               MINUS ONE FOR EXECUTE                51560020
         CLC   CIBTJID(E2),TJID0   TJID NOT EQUAL ZERO, TSO TERMINAL    51600020
         BE    T06SB04             OPERATOR CONSOLE                     51640020
         MVC   E0(M072ITL,WR1),M072IT MOVE THE TPUT MESSAGE             51680020
         UNPK  M072ITY(M072IYL,WR1),T06WPACK UN PACK MAX INTO MESSAGE   51720020
         EX    WR4,T6EM72TX        MOVE VARIABLE TO MESSAGE             51760020
         LA    WR0,M072ITL         LENGTH TPUT MESSAGE                  51800020
         BAL   TRANR,T06TPUT       TO TPUT ROUTINE                      51840020
         B     T06ED34             MODIFY REJECTED                      51880020
T06SB04  MVC   E0(M072IWL,WR1),M072IW MOVE THE WTO MESSAGE              51920020
         UNPK  M072IWY(M072IYL,WR1),T06WPACK UN PACK MAX INTO MESSAGE   51960020
         EX    WR4,T6EM72WX        MOVE VARIABLE TO MESSAGE             52000020
         LA    WR5,NSUB            ADDR. OF 'SUBMIT=NNNNN'              52040020
         LA    WR15,T06ETSUB       ADDR. EDIT TABLE 'SUBMIT=NNNNN'      52080020
         B     T06EDR60            TO TALK TO OPERATOR                  52120020
*********************************************************************** 52160020
*DATA IS INVALID.  NOT NUMERIC OR NNNNN GREATER THAN 5 CHARS.         * 52200020
*********************************************************************** 52240020
T06SB05  LA    WR15,T06ETSUB       ADDR. EDIT TABLE SUBMIT=             52280020
         LA    WR5,NSUB            ADDR. MODEL 'SUBMIT=NNNNN'           52320020
         B     T06EDR50            INVALID DATA ROUTINE                 52360020
         EJECT                                                          52400020
*********************************************************************** 52440020
*********************************************************************** 52480020
*T06REG IS THE KEYWORD HANDLING ROUTINE FOR                           * 52520020
*REGSIZE(RN)=(XXXXXK,YYYYYK)  WHERE RN IS THE REGION NUMBER,          * 52560020
*XXXXXK IS THE REGION SIZE, AND YYYYYK IS LSQS SIZE.                  * 52600020
*XXXXXK AND YYYYYK ARE NUMBER OF 1024 BYTE BLOCKS.                    * 52640020
*IF TSO TERMINAL IN OPERATOR MODE, ANY ERROR IS FATAL.                * 52680020
*KEYWR-ADDR. OF KEYWORD  KEYLR-LENGTH OF KEYWORD                      * 52720020
*AT COMPLETION, BRANCHES TO T06ED00                                   * 52760020
*WR3 - ADDR. OF REGION WORK AREA.  WR15 - ADDR. OF RCB.               * 52800020
*********************************************************************** 52840020
*********************************************************************** 52880020
         USING RCB,WR15            RCB                                  52920020
         USING T6MEDITR,WR3        REGION MODIFY WORK AREA              52960020
T06REG   AR    KEYLR,KEYWR         EST STOPPER FOR SCANS         A42839 53000021
         LA    WR5,L'T06EREG(KEYWR)  ADDR. OF ( OF (RN)                 53040020
         CR    WR5,KEYLR           END OF DATA                          53080020
         BNL   T06REG20            YES, DATA IS INVALID                 53120020
         CLI   E0(WR5),CLP         LEFT PAREN                           53160020
         BNE   T06REG20            NO, DATA IS INVALID                  53200020
         LA    WR5,E1(WR5)         ADDR. OF R OF (RN)                   53240020
         CR    WR5,KEYLR           END OF DATA                          53280020
         BNL   T06REG20            YES, DATA IS INVALID                 53320020
         LR    WR4,WR5             START SCAN FOR ) OR (RN)             53360020
T06REG0A CLI   E0(WR4),CRP         RIGHT PAREN                          53400020
         BE    T06REG00            YES                                  53440020
         LA    WR4,E1(WR4)         BUMP SCAN ADDR                       53480020
         CR    WR4,KEYLR           END OF DATA                          53520020
         BNL   T06REG20            YES, DATA IS INVALID                 53560020
         B     T06REG0A            TO TOP                               53600020
T06REG00 SR    WR4,WR5             LENGTH OF RN                         53640020
         LTR   WR4,WR4             IS LENGTH EQ 0                A42839 53650021
         BZ    T06REG20            YES-DATA INVALID              A42839 53660021
         BAL   TRANR,T06EDR90      DATA IS NUMERIC                      53680020
         B     T06REG20            NO, IT IS NOT                        53720020
         BCTR  WR4,0               MINUS ONE                            53760020
         EX    WR4,T06NNPK         PACK RN                              53800020
         CVB   WR1,T06WPACK        AND CONVERT TO BINARY                53840020
         C     WR1,NF14            RN EXCEED 14                         53880020
         BH    T06REG35            YES, DATA EXCEEDS MAXIMUM            53920020
         MVC   T06WEDIT(E4),NBLANKS BLANK TEMPORARY STORAGE             53960020
         EX    WR4,T06REGM1        MOVE RN TO WORK AREA(TEMP. STORAGE)  54000020
         LTR   WR1,WR1             ZERO IS NOT VALID RN                 54010020
         BZ    T06REG25            RN DOES NOT EXIST                    54020020
         CH    WR1,TSCVTCTR        RN TO MAXIMUM NUMBER OF REGIONS      54040020
         BH    T06REG25            REGION NUMBER EXCEEDS START TS       54080020
         LR    WR2,WR1             REGION NUMBER                        54120020
         L     WR15,TSCVTRCB       ADDR. OF FIRST RCB                   54160020
         LA    WR15,E0(WR15)       CLEAR HIGH BYTE                      54200020
         B     T06REG02            TO FIND RCB LOOP                     54240020
T06REG01 LA    WR15,RCBEND         ADDR. OF NEXT RCB                    54280020
T06REG02 BCT   WR2,T06REG01        DECREMENT REGION NUMBER              54320020
         LR    WR2,WR1             REGION NUMBER                        54360020
         LA    WR3,T6MEND          FIRST REGION MODIFY WORK AREA        54400020
         B     T06REG04            TO FIND REGION WORK AREA             54440020
T06REG03 LA    WR3,T6MREND         ADDR. NEXT REGION WORK AREA          54480020
T06REG04 BCT   WR2,T06REG03        DECREMENT REGION NUMBER              54520020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    54526021
         XC    E1(E7,WR3),E1(WR3)      ZZERO EXTRANEOUS STUFF           54532021
         NI    T6MRSW0,ALLFLAG-(T6MRSTP+T6MRSTR) RESET STOP START FLGS  54538021
         IC    WR2,T6MRSW0   SAVE FLAG BYTE                             54544021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       54550021
         ST    WR15,T6MRCBA        RCB ADDR. TO WORK AREA               54560020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    54565021
         STC   WR2,T6MRSW0   RESTORE FLAG BYTE                          54570021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       54575021
*********************************************************************** 54640020
*EXTRACT XXXXX FROM REGSIZE(RN)=(XXXXK,YYYYYK).                       * 54680020
*********************************************************************** 54720020
         LA    WR5,E2(WR5,WR4)     ADDR. OF =( OF (RN)=(XXX             54760020
         CR    WR5,KEYLR           END OF REGSIZE IN CIB                54800020
         BNL   T06REG20            DATA IS INVALID                      54840020
         CLC   E0(E2,WR5),NEQLP    =(                                   54880020
         BNE   T06REG20            NO, DATA IS INVALID                  54920020
         LA    WR5,E2(WR5)         ADDR. OF XXXXX                       54960020
         CR    WR5,KEYLR           END OF REGSIZE IN CIB                55000020
         BNL   T06REG20            DATA IS INVALID                      55040020
         LR    WR4,WR5             START OF SCAN FOR K OF XXXXXK        55080020
T06REG05 CLI   E0(WR4),CK          K OF XXXXXK                          55120020
         BE    T06REG11            FOUND IT                             55160020
         LA    WR4,E1(WR4)         BUMP SCAN ADDR.                      55200020
         CR    WR4,KEYLR           END OF REGSIZE IN CIB                55240020
         BNL   T06REG20            DATA IS INVALID                      55280020
         B     T06REG05            TRY AGAIN                            55320020
T06REG11 EQU   *                                                        55340021
T06REG06 SR    WR4,WR5             LENGTH OF XXXXX OF XXXXXK            55360020
         BAL   TRANR,T06EDR90      DATA IS NUMERIC                      55400020
         B     T06REG20            NO, DATA IS INVALID                  55440020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    55445021
         LTR   WR4,WR4       IS LENGTH ZERO                             55450021
         BZ    T06REG20      YES, ERROR                                 55455021
         CH    WR4,HW5       IS LENGTH GT 5                             55460021
         BH    T06REG20      YES, ERROR                                 55465021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       55470021
         BCTR  WR4,0               MINUS ONE                            55480020
         EX    WR4,T06NNPK         PACK XXXXX                           55520020
         CVB   WR2,T06WPACK        AND CONVERT TO BINARY                55560020
         C     WR2,NF16382         XXXXX TO BIG                         55840020
         BH    T06REG40            YES, EXCEEDS MAXIMUM                 55880020
         A     WR2,NF1             1024 BLOCKS PLUS ONE                 55920020
         SRL   WR2,E1              TO 2048 BLOCKS                       55960020
         STH   WR2,T6MRSIZ         TO MODIFY WORK AREA                  56000020
         EJECT                                                          56040020
*********************************************************************** 56080020
*EXTRACT YYYYYK OF  (XXXXXK,YYYYYK).                                  * 56120020
*********************************************************************** 56160020
         LA    WR5,E2(WR5,WR4)     ADDR. COMMA OF XXXXXK,YYYYYK         56200020
         CR    WR5,KEYLR           END OF REGSIZE IN CIB                56240020
         BNL   T06REG20            DATA IS INVALID                      56280020
         CLI   E0(WR5),CCOMA       COMMA                                56320020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    56328021
         BE    T06REGA0      YES, FIND THE K                            56336021
         CLI   E0(WR5),CRP   IS IT A RIGHT PAREN                        56344021
         BNE   T06REG20      NO, ERROR                                  56352021
         LA    WR2,E0        ZERO THE LSQS  SIZE                        56360021
         B     T06REGA1      CHECK THE VALIDITY                         56368021
T06REGA0 EQU   *                                                        56376021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       56384021
         LA    WR5,E1(WR5)         ADDR. OF YYYYYK                      56400020
         CR    WR5,KEYLR           END OF REGSIZE IN CIB                56440020
         BNL   T06REG20            DATA IS INVALID                      56480020
         LR    WR4,WR5             START OF SCAN FOR K OR YYYYYK        56520020
T06REG08 CLI   E0(WR4),CK          K OF YYYYYK                          56560020
         BE    T06REG09            FOUND IT                             56600020
         LA    WR4,E1(WR4)         BUMP SCAN ADDR.                      56640020
         CR    WR4,KEYLR           END OF  REGSIZE IN CIB               56680020
         BNL   T06REG20            DATA IS INVALID                      56720020
         B     T06REG08            TO TOP                               56760020
T06REG09 SR    WR4,WR5             LENGTH OF YYYYY OF YYYYYK            56800020
         BAL   TRANR,T06EDR90      DATA IS NUMERIC                      56840020
         B     T06REG20            NO, DATA IS INVALID                  56880020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    56885021
         LTR   WR4,WR4       IS LENGTH ZERO                             56890021
         BZ    T06REG20      YES, ERROR                                 56895021
         CH    WR4,HW5       IS LENGTH GT 5                             56900021
         BH    T06REG20      YES, ERROR                                 56905021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       56910021
         BCTR  WR4,0               MINUS ONE                            56920020
         EX    WR4,T06NNPK         PACK YYYYY                           56960020
         CVB   WR2,T06WPACK        AND CONVERT TO BINARY                57000020
         A     WR2,NF1             1024 BLOCKS PLUS ONE                 57040020
         SRL   WR2,E1              TO 2048 BYTE BLOCKS                  57080020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    57086021
T06REGA1 LTR   WR2,WR2       IS LSQS=0                                  57092021
         BNZ   T06REGA2      NO, ENSURE LSQS LT REGSIZE                 57098021
         OC    T6MRSIZ,T6MRSIZ         IS REGSZ=0                       57104021
         BNZ   T06REG20      NO, ERROR                                  57110021
         OI    T6MRSW0,T6MRSTP         SET STOP IN REG W A              57116021
         B     T06REG10      THIS IS A STOP                             57122021
T06REGA2 CH    WR2,T6MRSIZ   IS LSQS LT REGSIZE                         57128021
         BNL   T06REG45      NO, EROR                                   57134021
         OC    T6MRSIZ,T6MRSIZ         IS REGSIZE GT 0                  57140021
         BZ    T06REG20      NO, ERROR                                  57146021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       57152021
         LR    WR1,WR2             SAVE LSQS SIZE                       57170020
         AH    WR1,T6MRSIZ         ADD REGION SIZE                      57180020
         C     WR1,NF8191          IS TOTAL GR TH 16382                 57190020
         BH    T06REG40            YES ERROR BRANCH                     57192020
         STH   WR2,T6MRSQS         TO MODIFY WORK AREA                  57200020
         OI    T6MRSW0,T6MRSTR     SET REGION START                     57240020
T06REG10 OI    T6MSW0,T6MS0RGN     SET REGSIZE IN MOD WK AREA    A42839 57340021
         B     T06ED00             RESUME THE EDIT                      57560020
         DROP  WR15                RCB                                  57600020
         EJECT                                                          57640020
*********************************************************************** 57680020
*DATA WITH REGSIZE IS INVALID.                                        * 57720020
*********************************************************************** 57760020
T06REG20 SR    KEYLR,KEYWR         RESTORE LENGTH OF DATA               57800020
         LA    WR5,NREG            ADDR. 'REGSIZE ETC.  ' MODEL         57840020
         LA    WR15,T06ETREG       ADDR. OF REGSIZE EDIT TABLE          57880020
         B     T06EDR50            INVALID DATA ROUTINE                 57920020
*********************************************************************** 57960020
*RN OF REGSIZE(RN) EXCEEDS NUMBER OF REGIONS SPECIFIED AT START TSO.  * 58000020
*IKJ074I NN DOES NOT EXIST, REGSIZE INVALID                           * 58040020
*********************************************************************** 58080020
T06REG25 LA    WR1,T06WWTO         ADDR. OF MESSAGE BUFFER              58120020
         CLC   CIBTJID(E2),TJID0   TJID NOT EQUAL ZERO, TSO TERMINAL    58160020
         BE    T06REG26            OPERATOR CONSOLE                     58200020
         MVC   E0(M074ITL,WR1),M074IT MOVE THE TPUT MESSAGE             58240020
         MVC   M074ITX(E2,WR1),T06WEDIT MOVE RN TO MESSAGE              58280020
         LA    WR0,M074ITL         LENGTH TPUT MESSAGE                  58320020
         BAL   TRANR,T06TPUT       TO TPUT ROUTINE                      58360020
         B     T06ED34             MODIFY REJECTED                      58400020
T06REG26 MVC   E0(M074IWL,WR1),M074IW MOVE THE WTO MESSAGE              58440020
         MVC   M074IWX(E2,WR1),T06WEDIT MOVE RN TO MESSAGE              58480020
         LA    WR5,NREG            ADDR. 'REGSIZE ETC.  ' MODEL         58520020
         LA    WR15,T06ETREG       ADDR. OF REGSIZE EDIT TABLE          58560020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    58580021
         B     T06EDR60      TALK TO OPERATOR                           58600021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       58620021
*********************************************************************** 58640020
*REGSIZE(RN)=(0K) IS STOPPING AN IN ACTIVE REGION.                    * 58680020
*IKJ073I RN NOT ACTIVE REGION, REGSIZE INVALID                        * 58720020
*********************************************************************** 58760020
T06RIMSG SSM   ENABLE                                            A42839 58780021
         LA    WR1,T06WWTO         ADR OF MSG BUFFER             A42839 58800021
         CLC   CIBTJID(E2),TJID0   TJID NOT EQUAL ZERO, TSO TERMINAL    58840020
         BE    T06REG31            OPERATOR CONSOLE                     58880020
         MVC   E0(M073ITL,WR1),M073IT MOVE THE TPUT MESSAGE             58920020
         MVC   M073ITX(E2,WR1),T06WEDIT MOVE RN TO MESSAGE              58960020
         LA    WR0,M073ITL         LENGTH TPUT MESSAGE                  59000020
         BAL   TRANR,T06TPUT       TO TPUT ROUTINE                      59040020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    59050021
         USING T6MEDITR,WR3                                             59060021
         NI    T6MRSW0,ALLFLAG-(T6MRSTR+T6MRSTP) RESET FLAGS            59070021
         DROP  WR3                                                      59080021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       59090021
         B     T06ED14             MODIFY REJECTED               A42839 59100021
T06REG31 MVC   E0(M073IWL,WR1),M073IW MOVE THE WTO MESSAGE              59120020
         MVC   M073IWX(E2,WR1),T06WEDIT MOVE RN TO MESSAGE              59160020
RIRFWTO  SR    WR0,WR0                                                  59170021
         IC    WR0,CIBCONID                                             59180021
         WTO   MF=(E,T06WWTO)                                           59190021
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    59200021
         USING T6MEDITR,WR3                                             59210021
         NI    T6MRSW0,ALLFLAG-(T6MRSTR+T6MRSTP) RESET FLAGS            59220021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       59230021
         B     T06ED14                                                  59240021
         EJECT                                                          59320020
*********************************************************************** 59360020
*RN OF REGSIZE(RN)=(XXXXXK,YYYYYK) EXCEEDS 14                         * 59400020
*IKJ072I REGSIZE RN            EXCEEDS MAXIMUM OF 00014               * 59440020
*********************************************************************** 59480020
T06REG35 LA    WR15,T06WRBUF        ADDR. OF REPLY BUFFER               59520020
         MVC   E0(T06WRBFL,WR15),NBLANKS  BLANK THE BUFFER              59560020
         MVC   M072ID1(L'T06EREG,WR15),T06EREG MOVE REGSIZE TO REPLY    59600020
         LA    WR2,M072ID2L-1      LENGTH VARIABLE AREA                 59640020
         CR    WR2,WR4             VARIABLE TO LENGTH OF BAD DATA       59680020
         BH    T06REG36            LENGTH BAD DATA O.K.                 59720020
         LR    WR4,WR2             USE VARIABLE AREA LENGTH             59760020
T06REG36 EX    WR4,T6E72MD2        MOVE XXXXX TO MESSAGE                59800020
         LA    WR2,NC14            ADDR. MAXIMUM VALUE                  59840020
         B     T06REG50            COMMON FOR MESSAGE IKJ072I           59880020
*********************************************************************** 59920020
*XXXXX OF REGSIZE(RN)=(XXXXXK,YYYYYK) EXCEEDS 16382.                  * 59960020
*IKJ072I REGSIZE RN XXXXX   EXCEEDS MAXIMUM OF 16382                  * 60000020
*********************************************************************** 60040020
T06REG40 LA    WR1,T06WWTO         ADDR WTO BUFFER                      60042020
         CLC   CIBTJID(E2),TJID0   TJID NOT EQUAL ZERO, TSO TERMINAL    60050020
         BE    T06REG41            OPERATOR CONSOLE                     60060020
         MVC   E0(M085ITL,WR1),M085IT MOVE TPUT TO BUFFER               60070020
         LA    WR0,M085ITL         GET LENGTH OF MESSAGE                60090020
         BAL   TRANR,T06TPUT       ISSUE TPUT                           60100020
         B     T06ED34             MODIFY REJECTED                      60110020
T06REG41 MVC   E0(M085IWL,WR1),M085IW MVE WTO TO BUFFER                 60112020
         LA    WR5,NREG            ADDRESS OF REGSIZE ETC.              60114020
         LA    WR15,T06ETREG       ADDR OF REGSIZE EDIT TABLE           60116020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    60216021
         B     T06EDR60      TALK TO OPERATOR                           60316021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       60416021
*********************************************************************** 60520020
*YYYYY OF REGSIZE(RN)=(XXXXXK,YYYYYK) EXCEEDS XXXXX.                  * 60560020
*IKJ072I REGSIZE RN YYYYY   EXCEEDS MAXIMUM OF XXXXX                  * 60600020
*********************************************************************** 60640020
T06REG45 LA    WR15,T06WRBUF        ADDR. OF REPLY BUFFER               60680020
         MVC   E0(T06WRBFL,WR15),NBLANKS  BLANK THE BUFFER              60720020
         MVC   M072ID1(L'T06EREG,WR15),T06EREG MOVE REGSIZE TO REPLY    60760020
         MVC   M072ID2(E2,WR15),T06WEDIT MOVE RN TO REPLY BUFFER        60800020
         LA    WR2,M072ID3L-1      LENGTH VARIABLE AREA                 60840020
         CR    WR2,WR4             VARIABLE TO LENGTH OF BAD DATA       60880020
         BH    T06REG46            LENGTH BAD DATA O.K.                 60920020
         LR    WR4,WR2             USE VARIABLE AREA LENGTH             60960020
T06REG46 EX    WR4,T6E72MD3        MOVE XXXXX TO MESSAGE                61000020
         LH    WR2,T6MRSIZ         NNNNN IN BINARY (2K)                 61040020
         SLL   WR2,E1              CHANGE NUMBER TO 1K                  61050020
         CVD   WR2,T06WPACK        CONVERT TO DECIMAL                   61080020
         OI    T06WPACK+E7,SIGNMASK CHANGE SIGN FROM C TO F FOR PRINT   61120020
         LA    WR2,T06WWTOR        USE WTOR BUFFER TEMP STORAGE         61160020
         UNPK  E0(E5,WR2),T06WPACK(E8) UN PACK NNNNN                    61200020
*        B     T06REG50            TO COMMON IKJ072I                    61240020
         EJECT                                                          61280020
*********************************************************************** 61320020
*IKJ072I (ADDR. IN WR15)         EXCEEDS MAXIMUM VALUE OF (WR2)       * 61360020
*********************************************************************** 61400020
T06REG50 LA    WR1,T06WWTO         ADDR. OF WTO BUFFER                  61440020
         CLC   CIBTJID(E2),TJID0   TJID NOT EQUAL ZERO, TSO TERMINAL    61480020
         BE    T06REG51            OPERATOR CONSOLE                     61520020
         MVC   E0(M072ITL,WR1),M072IT MOVE TPUT TO BUFFER               61560020
         MVC   M072ITX(M072IXL,WR1),E0(WR15) MOVE VARIABLE TO MESSAGE   61600020
         MVC   M072ITY(M072IYL,WR1),E0(WR2)  MOVE VARIABLE TO MESSAGE   61640020
         LA    WR0,M072ITL         LENGTH TPUT MESSAGE                  61680020
         BAL   TRANR,T06TPUT       TO TPUT ROUTINE                      61720020
         B     T06ED34             MODIFY REJECTED                      61760020
T06REG51 MVC   E0(M072IWL,WR1),M072IW MOVE WTO TO BUFFER                61800020
         MVC   M072IWX(M072IXL,WR1),E0(WR15) MOVE VARIABLE TO MESSAGE   61840020
         MVC   M072IWY(M072IYL,WR1),E0(WR2)  MOVE VARIABLE TO MESSAGE   61880020
         LA    WR5,NREG            ADDR. 'REGSIZE ETC. ETC '            61920020
         LA    WR15,T06ETREG       ADDR. OF REGSIZE EDIT TABLE          61960020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    61980021
         B     T06EDR60      TALK TO OPERATOR                           62000021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       62020021
         DROP  WR3                 REGION MODIFY WORK AREA              62040020
*********************************************************************** 62040420
*     RN OF REGSIZE IS A REGION WHICH HAS FAILED.                     * 62049020
*     IKJ086I   RN HAS FAILED, REGSIZE INVALID                        * 62050720
*********************************************************************** 62052420
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    62053021
T06RDMSG SSM   ENABLE                                                   62053621
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       62054221
         LA    WR1,T06WWTO         ADR MSG BUFFER                A42839 62054821
         CLC   CIBTJID(E2),TJID0   TJID NOT EQUAL ZERO, TSO TERMINAL    62055820
         BE    T06REG61            OPERATOR CONSOLE                     62057520
         MVC   E0(M086ITL,WR1),M086IT MOVE THE TPUT MESSAGE             62059220
         MVC   M086ITX(E2,WR1),T06WEDIT MOVE RN TO MESSAGE              62060920
         LA    WR0,M086ITL         LENGTH TPUT MESSAGE                  62062620
         BAL   TRANR,T06TPUT       TO TPUT ROUTINE                      62064320
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    62064721
         USING T6MEDITR,WR3                                             62065121
         NI    T6MRSW0,ALLFLAG-(T6MRSTR+T6MRSTP) RESET FLAGS            62065521
         DROP  WR3                                                      62065921
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       62066321
         B     T06ED14             MODIFY REJECTED               A42839 62066721
T06REG61 MVC   E0(M086IWL,WR1),M086IW MOVE THE WTO MESSAGE              62067720
         MVC   M086IWX(E2,WR1),T06WEDIT MOVE RN TO MESSAGE              62069420
         B     RIRFWTO             BR TO ISSUE WTO               A42839 62072421
         SPACE                                                          62076220
         EJECT                                                          62106720
*********************************************************************** 62120020
*********************************************************************** 62160020
*T06SMF IS THE KEYWORD HANDLING ROUTINE FOR                           * 62200020
*        SMF=(PARM1,PARM2)                                            * 62240020
*WHERE PARM1 IS FOR FOREGROUND OPTIONS AND MAY BE OFF, OPT=1, OPT=2,  * 62280020
*OR DEFAULT TO CURRENT FOREGROUND(SMCAOPT1 AND SMCAOPT2 IN SMCAFOPT)  * 62320020
*AND PARM2 IS FOR USE OF INSTALLATION EXITS AND MAY BE   EXT=YES,     * 62360020
*EXT=NO, OR DEFAULT TO CURRENT FOREGROUND(SMCAEXT IN SMCAFOPT)        * 62400020
*EITHER PARM1 OR PARM2 MAY DEFAULT.  WHEN THEY DO NOT DEFAULT, THE    * 62440020
*NEW FOREGROUND OPTIONS MAY NOT EXCEED CURRENT BACKGROUND OPTIONS     * 62480020
*        FG MAY BE      OFF     IF BG  IS    OFF                      * 62520020
*                       OPT=1                OPT=1 OR OPT=2           * 62560020
*                       OPT=2                OPT=2                    * 62600020
*                       EXT=NO               EXT=NO OR EXT=YES        * 62640020
*                       EXT=YES              EXT=YES                  * 62680020
* DSA,VOL,ESV,TDS BITS IN SMCAFOPT (FOREGROUND) MUST DEFAULT          * 62690020
* TO SAME BITS IN SMCAOPT (BACKGROUND)                                  62700020
*IF TSO TERMINAL IN OPERATOR MODE, ANY ERROR IS FATAL.                * 62720020
*KEYWR-ADDR. OF KEYWORD  KEYLR-LENGTH OF KEYWORD                      * 62760020
*AT COMPLETION, BRANCHES TO T06ED00                                   * 62800020
*********************************************************************** 62840020
*********************************************************************** 62880020
T06SMF   L     WR15,CVTPTR         ADDR. OF CVT                         62920020
         USING CVTDSECT,WR15       CVT                                  62960020
         L     WR5,CVTSMCA         ADDR. OF SMF CONTROL AREA            63000020
         DROP  WR15                CVT                                  63040020
         USING SMCABASE,WR5        SMF CONTROL AREA                     63080020
         LA    WR5,E0(WR5)         CLEAR HIGH BYTE                      63120020
         LTR   WR5,WR5             ADDR. SMCA EQU ZERO                  63160020
         BZ    T06SMF19            YES, SMF NOT ACTIVE, TELL OPERATOR   63200020
         TM    SMCAMISC,SMCAOPI    OPI=NO                               63240020
         BO    T06SMF21            OPI=NO                               63280020
*********************************************************************** 63320020
*SMF IS ACTIVE.  PARM 1 DEFAULT TO CURRENT FOREGROUND OPTIONS.        * 63360020
*********************************************************************** 63400020
T06SMF00 MVI   T6MSMF,E0           RESET NEW OPTIONS IN MODIFY WA       63440020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    63450021
         NI    T6MSW0,ALLFLAG-T6MS0SMF RESET SMF FLAG                   63460021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       63470021
         AR    KEYLR,KEYWR         EST. STOPPER FOR SCAN                63480020
         LA    WR4,L'T06ESMF(KEYWR) ADDR. OF LEFT PAREN OF SMF=(P1,P2)  63520020
         CR    WR4,KEYLR           END OF DATA                          63560020
         BNL   T06SMF11            YES, DATA IS NOT VALID               63600020
         CLI   E0(WR4),CLP         IS IT THERE?                         63640020
         BNE   T06SMF11            NO, SORRY ABOUT THAT                 63680020
         LA    WR4,E1(WR4)         ADDR. OF PARM 1                      63720020
         CR    WR4,KEYLR           END OF DATA                          63760020
         BNL   T06SMF11            YES, DATA IS NOT VALID               63800020
         CLI   E0(WR4),CCOMA       DEFAULT PARM 1  SMF=(,PARM2)         63840020
         BNE   T06SMF02            NO                                   63920020
T06SMF01 MVC   T6MSMF(E1),SMCAFOPT CURRENT FOREGROUND TO NEW OPTIONS    63960020
         NI    T6MSMF,SMFBIT1      AND RESET OTHER FLAGS                63970020
         B     T06SMF07            PARM 2 EDIT                          64040020
         EJECT                                                          64050020
*********************************************************************** 64080020
*IF PARM 1 IS OFF, OPT=1, OR OPT=2, IT MUST NOT EXCEED BACKGROUND.    * 64120020
*********************************************************************** 64160020
T06SMF02 MVC   T6MSMF(E1),SMCAFOPT CURRENT FOREGROUND TO NEW OPTIONS    64170020
         NI    T6MSMF,SMFBIT2      AND RESET OTHER FLAGS                64180020
         CLC   E0(L'NOFF,WR4),NOFF  PARM 1 IS OFF                       64200020
         BNE   T06SMF04            NO                                   64280020
*********************************************************************** 64360020
*PARM 1 IS OFF AND DOES NOT EXCEED CURRENT BACKGROUND.  SMCAOPT1 AND  * 64400020
*SMCAOPT2 ARE RESET IN MODIFY WORK AREA.                              * 64440020
*********************************************************************** 64480020
T06SMF03 TM    SMCAOPT,SMCADSA     IS DATA SET ACCT BIT SET             64490020
         BO    T06SMF23            YES BR TO SET OPT=2                  64500020
T06SMF0B LA    WR4,L'NOFF(WR4)     ADDR. OF PARM 2                      64520020
         B     T06SMF07            PARM 2 EDIT                          64560020
T06SMF04 CLC   E0(L'NOPT1,WR4),NOPT1   OPT=1                            64600020
         BE    T06SMF05            YES                                  64640020
         CLC   E0(L'NOPT2,WR4),NOPT2   OPT=2                            64680020
         BE    T06SMF06            YES                                  64720020
         B     T06SMF11            DATA IS INVALID                      64760020
*********************************************************************** 64800020
*PARM 1 IS OPT=1 AND MAY NOT EXCEED OFF IN THE BACKGROUND.            * 64840020
*********************************************************************** 64880020
T06SMF05 TM    SMCAOPT,SMCADSA     IS DATA SET ACCT BIT SET             64890020
         BO    T06SMF23            YES BR TO SET OPT=2                  64900020
         TM    SMCAOPT,SMCAOPT1+SMCAOPT2 BACKGROUND IS OPT=1 OR OPT=2   64920020
         BZ    T06SMF12            OFF, ERROR                           64960020
         OI    T6MSMF,SMCAOPT1     SET OPT=1 IN NEW OPTIONS             65000020
         LA    WR4,L'NOPT1(WR4)    ADDR. OF PARM 2                      65040020
         B     T06SMF07            TO PARM 2                            65080020
*********************************************************************** 65120020
*PARM 1 IS OPT=2 AND BACKGROUND MUST BE OPT=2.                        * 65160020
*********************************************************************** 65200020
T06SMF06 TM    SMCAOPT,SMCAOPT2    BACKGROUND IS OPT 2                  65240020
         BZ    T06SMF12            OFF OR OPT=1, ERROR                  65280020
T06SMF0A OI    T6MSMF,SMCAOPT2+SMCAOPT1  SET OPT=2 IN NEW OPTIONS       65320020
         CLC   E0(L'NOFF,WR4),NOFF  PARM 1 IS OFF                       65330020
         BE    T06SMF0B            YES BRANCH TO UPDATE PTR             65350020
         LA    WR4,L'NOPT2(WR4)    ADDR. OF PARM 2                      65360020
*********************************************************************** 65400020
*PARM 2 DEFAULT TO CURENT FOREGROUND OPTIONS.                         * 65440020
*********************************************************************** 65480020
T06SMF07 CR    WR4,KEYLR           END OF DATA                          65520020
         BNL   T06SMF11            YES, DATA IS NOT VALID               65560020
         CLI   E0(WR4),CRP         EXT IS DEFAULT  SMF=(PARM1)          65600020
         BNE   T06SMF08            NO                                   65640020
         TM    SMCAFOPT,SMCAEXT    CURRENT OPTION IS EXT=YES            65680020
         BZ    T06SMF10            EXT=NO, DONE WITH SMF=               65720020
         OI    T6MSMF,SMCAEXT      SET EXT=YES IN NEW OPTIONS           65760020
         B     T06SMF10            DONE WITH SMF=                       65800020
T06SMF08 CLI   E0(WR4),CCOMA       COMA IN  SMF=(PARM1,PARM2)           65840020
         BNE   T06SMF11            NO, DATA IS INVALID                  65880020
         LA    WR4,L'CCOMA(WR4)    BUMP PAST COMMA                      65920020
         CR    WR4,KEYLR           END OF DATA                          65960020
         BNL   T06SMF11            YES, DATA IS NOT VALID               66000020
         SPACE 3                                                        66010020
*********************************************************************** 66040020
*PARM 2 IS EXT=NO OR EXT=YES AND MAY NOT EXCEED CURRENT BACKGROUND.   * 66080020
*EXT=NO DOES NOT EXCEED CURRENT BACLGROUND.                           * 66120020
*********************************************************************** 66160020
         CLC   E0(L'NEXTNO,WR4),NEXTNO  EXT=NO                          66200020
         BE    T06SMF10            YES, EXT=NO IS SET NEW OPTIONS       66240020
         CLC   E0(L'NEXTYES,WR4),NEXTYES  EXT=YES                       66280020
         BNE   T06SMF11            DATA IS NOT VALID                    66360020
*********************************************************************** 66440020
*PARM 2 IS EXT=YES AND MAY NOT EXCEED EXT=NO IN BACKGROUND.           * 66480020
*********************************************************************** 66520020
T06SMF09 TM    SMCAOPT,SMCAEXT     BACKGROUND EXT=YES                   66560020
         BZ    T06SMF12            EXT=NO, ERROR                        66600020
         OI    T6MSMF,SMCAEXT      SET EXT=YES                          66640020
*********************************************************************** 66680020
*SMF IS DONE, SET SMF= IN MODIFY WA AND FOREGROUND IN SMF OPTIONS.    * 66720020
*********************************************************************** 66760020
T06SMF10 OI    T6MSW0,T6MS0SMF     SMF= IN MODIFY WORK AREA             66800020
         OI    T6MSMF,SMCAFGND     SET FOREGROUND IN NEW OPTIONS        66840020
         B     T06ED00             RESUME THE EDIT                      66880020
*********************************************************************** 66920020
*THE DATA FOR PARM 1 OR PARM 2 IS NOT VALID. INVALID DATA ROUTINE.    * 66960020
*********************************************************************** 67000020
T06SMF11 SR    KEYLR,KEYWR         LENGTH OF KEYWORD AND DATA           67040020
         LA    WR5,NSMF            ADDR. MODEL 'SMF=(PARM1,PARM2)'      67080020
         LA    WR15,T06ETSMF       ADDR. EDIT TABLE SMF=                67120020
         B     T06EDR50            INVALID DATA ROUTINE                 67160020
         EJECT                                                          67200020
*********************************************************************** 67240020
*MODIFY SMF FOREGROUND EXCEEDS SMF BACKGROUND. TELL THE OPERATOR.     * 67280020
*IKJ075I TSO/SMF OPTIONS CANNOT EXCEED DATA1 DATA2                    * 67320020
*********************************************************************** 67360020
T06SMF12 LA    WR15,T06WRBUF       ADDR. OF REPLY BUFFER                67400020
         MVC   E0(T06WRBFL,WR15),NBLANKS  MOVE BLANKS TO THE BUFFER     67440020
         TM    SMCAOPT,SMCAOPT2    BACK GROUND IS OPT=2                 67480020
         BO    T06SMF13            YES                                  67520020
         TM    SMCAOPT,SMCAOPT1    BACK GROUND IS OPT=1                 67560020
         BO    T06SMF14            YES                                  67600020
         MVC   M075ID1(L'NOFF,WR15),NOFF  MOVE OFF TO BUFFER            67640020
         B     T06SMF15            NEXT VARIABLE                        67680020
T06SMF13 MVC   M075ID1(L'NOPT2,WR15),NOPT2  MOVE OPT=2 TO BUFFER        67720020
         B     T06SMF15            NEXT VARIABLE                        67760020
T06SMF14 MVC   M075ID1(L'NOPT1,WR15),NOPT1  MOVE OPT=1 TO BUFFER        67800020
T06SMF15 TM    SMCAOPT,SMCAEXT     BACKGROUND EXT=YES                   67840020
         BO    T06SMF16            NO                                   67880020
         MVC   M075ID2(E6,WR15),NEXTNO  MOVE EXT=NO TO BUFFER           67920020
         B     T06SMF17            TO OUTPUT MESSAGE                    67960020
T06SMF16 MVC   M075ID2(E7,WR15),NEXTYES  MOVE EXT=YES TO BUFFER         68000020
T06SMF17 LA    WR1,T06WWTO         ADDR. OF WTO BUFFER                  68040020
         CLC   CIBTJID(E2),TJID0   TJID NOT EQUAL ZERO, TSO TERMINAL    68080020
         BE    T06SMF18            OPERATOR CONSOLE                     68120020
         MVC   E0(M075ITL,WR1),M075IT MOVE THE MESSAGE                  68160020
         MVC   M075ITX(M075IXL,WR1),E0(WR15) MOVE THE VARIABLE          68200020
         LA    WR0,M075ITL         LENGTH TPUT MESSAGE                  68240020
         BAL   TRANR,T06TPUT       TO TPUT ROUTINE                      68280020
         B     T06ED34             MODIFY REJECTED                      68320020
T06SMF18 MVC   E0(M075IWL,WR1),M075IW  MOVE THE MESSAGE                 68360020
         MVC   M075IWX(M075IXL,WR1),E0(WR15) MOVE THE VARIABLE          68400020
         LA    WR5,NSMF            ADDR. MODEL 'SMF=(PARM1,PARM2)'      68440020
         LA    WR15,T06ETSMF       ADDR. EDIT TABLE SMF=                68480020
         B     T06EDR60            TALK TO THE OPERATOR                 68520020
*********************************************************************** 68560020
*SMF IS NOT ACTIVE, TELL THE OPERATOR AND RESUME THE EDIT.            * 68600020
*IKJ077I SMF IS NOT ACTIVE, TSO CANNOT MODIFY                         * 68640020
*********************************************************************** 68680020
T06SMF19 OI    T6MSW0,T06S0MSG     SET NO OPER CANCEL MSG               68720020
         CLC   CIBTJID(E2),TJID0   TJID NOT EQUAL ZERO, TSO TERMINAL    68760020
         BE    T06SMF20            OPERATOR CONSOLE                     68800020
         LA    WR1,M077IT          ADDR. IKJ077I MESSAGE                68840020
         LA    WR0,M077ITL         LENGTH TPUT MESSAGE                  68880020
         BAL   TRANR,T06TPUT       TO TPUT ROUTINE                      68920020
         B     T06ED00             RESUME THE EDIT                      68960020
T06SMF20 SR    WR0,WR0             ZERO                                 69000020
         IC    WR0,CIBCONID        CONSOLE ID                           69040020
         WTO   MF=(E,M077IW)       ISSUE THE WTO                        69080020
         B     T06ED00             RESUME THE EDIT                      69120020
         EJECT                                                          69130020
*********************************************************************** 69160020
*SMF IS OPI=NO TELL THE OPERATOR AND RESUME THE EDIT.                 * 69200020
*IKJ082I SMF IS OPI=NO, TSO CANNOT MODIFY                             * 69240020
*********************************************************************** 69280020
T06SMF21 OI    T6MSW0,T06S0MSG     SET NO OPER CANCEL MSG               69320020
         CLC   CIBTJID(E2),TJID0   TJID NOT EQUAL ZERO, TSO TERMINAL    69360020
         BE    T06SMF22            OPERATOR CONSOLE                     69400020
         LA    WR1,M082IT          ADDR. IKJ082I MESSAGE                69440020
         LA    WR0,M082ITL         LENGTH TPUT MESSAGE                  69480020
         BAL   TRANR,T06TPUT       TO TPUT ROUTINE                      69520020
         B     T06ED00             RESUME THE EDIT                      69560020
T06SMF22 SR    WR0,WR0             ZERO                                 69600020
         IC    WR0,CIBCONID        CONSOLE ID                           69640020
         WTO   MF=(E,M082IW)       ISSUE THE WTO                        69680020
         B     T06ED00             RESUME THE EDIT                      69720020
         SPACE 2                                                        69730020
*********************************************************************** 69740020
* SMCA DATA SET ACCOUNTING BIT IS SET. TELL THE OPERATOR                69750020
* IKJ068I SMFDSA BIT IS SET - OPT=2 MUST BE USED.                       69752020
*********************************************************************** 69754020
         SPACE                                                          69756020
T06SMF23 OI    T6MSW0,T06S0MSG     SET NO OPER CANCEL MESSAGE           69758020
         CLC   CIBTJID(E2),TJID0   TJID NOT EQ ZERO,TSO TERMINAL        69758420
         BE    T06SMF24            OPERATOR CONSOLE                     69758820
         LA    WR1,M068IT          ADDR IKJ068I MESSAGE                 69759220
         LA    WR0,M068ITL         LENGTH TPUT MESSAGE                  69759620
         BAL   TRANR,T06TPUT       TO TPUT ROUTINE                      69759720
         B     T06SMF0A            RESUME THE EDIT                      69759820
T06SMF24 SR    WR0,WR0             ZERO                                 69759920
         IC    WR0,CIBCONID        CONSOLE ID                           69773220
         WTO   MF=(E,M068IW)       ISSUE WTO                            69783220
         B     T06SMF0A            RESUME THE EDIT                      69785220
         SPACE 5                                                        69786720
         EJECT                                                          69960020
*********************************************************************** 70000020
*T06HLD IS THE KEYWORD HANDLING ROUTINE FOR                           * 70040020
*        HOLD=RN  WHERE RN IS THE REGION NUMBER.                      * 70080020
*REGION RN WILL NO LONGER BE USED FOR FUTURE LOGONS.                  * 70120020
*IF TSO TERMINAL IN OPERATOR MODE, ANY ERROR IS FATAL.                * 70160020
*KEYWR-ADDR. OF KEYWORD  KEYLR-LENGTH OF KEYWORD                      * 70200020
*AT COMPLETION, BRANCHES TO T06ED00                                   * 70240020
*********************************************************************** 70280020
         USING RCB,WR15            RCB                                  70320020
         USING T6MEDITR,WR3        REGION MODIFY WORK AREA              70360020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    70363021
T06HLD   EQU   *             HOLD KEY WORD PROCESSING                   70366021
         BAL   TRANR,T06HLD82      CLEAR HOLD,FLAGS                     70369021
         LA    WR5,L'T06EHLD(KEYWR) ADDRS OF DATA                       70372021
         AR    KEYLR,KEYWR         ESTABLISH STOP ADRS                  70375021
         CR    WR5,KEYLR           IS THERE ANY DATA                    70378021
         BE    T06HLD04            NO, ERROR                            70381021
*                                                                       70384021
         CLI   E0(WR5),CLP         IS IT  A LIST FORM                   70387021
         BNE   T06HLD10            NO,PROCESS IT                        70390021
*                                                                       70393021
*A LIST FORM MUST HAVE A CLOSING RIGHT PAREN                            70396021
*                                                                       70399021
         OI    T6MSW0,T6MS0LP      SET LEFT PAREN SW                    70402021
         LA    WR5,E1(WR5)         BUMP TO RN                           70405021
*                                                                       70408021
T06HLD10 BAL   TRANR,T06HLD11      PROCESS                              70411021
*                                                                       70414021
         CR    WR5,KEYLR           END OF DATA YET                      70417021
         BE    T06HLD12            YES, CHECK IF VALID                  70420021
         CLI   E0(WR5),CRP         IS THIS RIGHT PAREN                  70423021
         BE    T06HLD13            YES, CHECK IF VALID                  70426021
         CLI   E0(WR5),CCOMA       IS THOIS A COMMA                     70429021
         BNE   T06HLD04            NO, ERROR                            70432021
         LA    WR5,E1(WR5)         YES, BUMP TO RN                      70435021
         B     T06HLD10            GO PROCESS                           70438021
*                                                                       70441021
*IF END OF DATA FOUND AND LEADING LEFT PAREN SW IS SET - ERROR          70444021
*                                                                       70447021
T06HLD12 TM    T6MSW0,T6MS0LP      WAS LEFT PAREN FOUND                 70450021
         BO    T06HLD04            YES, ERROR                           70453021
         B     T06HLD14            NO, ALL DATA VALID                   70456021
*                                                                       70459021
*IF RIGHT PAREN FOUND W/OUT LEADING LEFT PAREN - ERROR                  70462021
*                                                                       70465021
T06HLD13 TM    T6MSW0,T6MS0LP      WAS LEFT PAREN FOUND                 70468021
         BZ    T06HLD04            NO, ERROR                            70471021
         B     T06HLD14            YES, ALL DATA IS VALID               70474021
*GET COUNT OF RN FIELD - SHOULD BE 1 OR 2                               70477021
*WR5 POINTS TO POTENTIAL BEGINNING OF RN                                70480021
*COUNT UNTIL END OF DATA, COMMA, OR RIGHT PAREN                         70483021
T06HLD11 LA    WR4,E0              ZERO LENGTH                          70486021
T06HLD15 CR    WR5,KEYLR           END OF DATA                          70489021
         BE    PROC                YES, PROCESS                         70492021
         CLI   E0(WR5),CCOMA       COMMA                                70495021
         BE    PROC                YES, PROCESS                         70498021
         CLI   E0(WR5),CRP         RIGHT PAREN                          70501021
         BE    PROC                YES, PROCESS                         70504021
         LA    WR5,E1(WR5)         BUMP DATA POINTER                    70507021
         LA    WR4,E1(WR4)         INCR RN LENGTH                       70510021
         B     T06HLD15            CONTINUE SEARCH                      70513021
PROC     LTR   WR4,WR4             IS RN LENGTH ZERO                    70516021
         BZ    T06HLD04            YES, ERROR                           70519021
         SR    WR5,WR4             POINT WR5 TO DATA                    70522021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       70525021
         C     WR4,NF2             LENGTH RN EXCEEDS TWO                70530020
         BH    T06HLD04            DATA IS INVALID                      70540020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    70545021
         LR    WR3,TRANR           SAVE REG                             70550021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       70555021
         BAL   TRANR,T06EDR90      DATA IS NUMERIC                      70560020
         B     T06HLD04            DATA IS INVALID                      70600020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    70610021
         LR    TRANR,WR3           RESTORE REG                          70620021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       70630021
         BCTR  WR4,0               MINUS ONE FROM LENGTH                70640020
         EX    WR4,T06NNPK         PACK RN                              70680020
         CVB   WR1,T06WPACK        TO BINARY                            70720020
         C     WR1,NF14            RN EXCEED 14                         70760020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    70780021
         BH    T06HLD04      YES, DATA EXCEEDS MAX                      70800021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       70820021
         MVC   T06WEDIT(E4),NBLANKS BLANK TEMPORARY STORAGE             70840020
         EX    WR4,T06REGM1        MOVE RN TO WORK AREA(TEMP. STORAGE)  70880020
         LTR   WR1,WR1             ZERO IS NOT VALID RN                 70890020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    70897021
         BZ    T06HLD04      RN DOES NOT EXIST                          70904021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       70911021
         CH    WR1,TSCVTCTR        RN TO MAXIMUM NUMBER OF REGIONS      70920020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    70940021
         BH    T06HLD04      RN EXCEEDS START TS REGS                   70960021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       70980021
         LR    WR2,WR1             REGION NUMBER                        71000020
         L     WR15,TSCVTRCB       ADDR. OF FIRST RCB                   71040020
         LA    WR15,E0(WR15)       CLEAR HIGH BYTE                      71080020
         B     T06HLD01            TO FIND RCB LOOP                     71120020
T06HLD00 LA    WR15,RCBEND         ADDR. OF NEXT RCB                    71160020
T06HLD01 BCT   WR2,T06HLD00        DECREMENT REGION NUMBER              71200020
         LR    WR2,WR1             REGION NUMBER                        71240020
         LA    WR3,T6MEND          FIRST REGION MODIFY WORK AREA        71280020
         B     T06HLD03            TO FIND REGION WORK AREA             71320020
T06HLD02 LA    WR3,T6MREND         ADDR. NEXT REGION WORK AREA          71360020
T06HLD03 BCT   WR2,T06HLD02        DECREMENT REGION NUMBER              71400020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    71410021
         IC    WR2,T6MRSW0   SAVE FLAG BYTE                             71420021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       71430021
         ST    WR15,T6MRCBA        RCB ADDR. TO WORK AREA               71520020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    71530021
         STC   WR2,T6MRSW0   RESTORE FLAG BYTE                          71540021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       71550021
*********************************************************************** 71560020
*RN IS VALID, SET HOLD= IN REGION AND TSO MODIFY WORK AREAS.          * 71600020
*********************************************************************** 71640020
         OI    T6MRSW0,T6MRHLD     SET HOLD= REGION WORK AREA           71680020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    71690021
         LA    WR5,E1(WR4,WR5)     POINT TO CHAR AFTER RN               71700021
         BR    TRANR               CONTINUE                             71710021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       71720021
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    71724021
T06HLD14 OI    T6MSW0,T6MS0HLD     SET HOLD PRCESSED FLAG               71728021
         NI    T6MSW0,ALLFLAG-T6MS0LP RESET LEFT PAREN SW               71732021
         B     T06ED00             CONTINUE WITH EDIT                   71736021
*                                                                       71740021
*THIS ROUTINE TURNS  OFF LEFT PAREN FLAG  -  HOLD AND TEMP FLAGS        71744021
*AND HOLD PROCESSED FLAG                                                71748021
*                                                                       71752021
T06HLD82 LA    WR3,T6MEND          FIRST MOD REG W A                    71756021
         NI    T6MSW0,ALLFLAG-(T6MS0LP+T6MS0HLD) RESET LEFT             71760021
*                                  PAREN AND HOLD                       71764021
         LH    WR15,TSCVTCTR       NUMBER OF MOD REG WA                 71768021
         B     T06HLD81            PROCESS FIRST WA                     71772021
T06HLD80 LA    WR3,T6MREND         PROCESS NEXT                         71776021
T06HLD81 NI    T6MRSW0,ALLFLAG-T6MRHLD RESET HOLD FLAG                  71780021
         BCT   WR15,T06HLD80       CONTINUE IF MORE WORK AREAS          71784021
         BR    TRANR               RETURN TO CALLER                     71788021
         DROP  WR3,WR15                                                 71792021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       71796021
         EJECT                                                          71800020
*********************************************************************** 71840020
*DATA IS INVALID. NOT NUMERIC OR EXCEEDS TWO CHARACTERS.              * 71880020
*********************************************************************** 71920020
T06HLD04 LA    WR5,NHLD            ADDR. MODEL 'HOLD=RN'                71960020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    71968021
         SR    KEYLR,KEYWR         RESET LENGTH                         71976021
         BAL   TRANR,T06HLD82      RESET FLAGS                          71984021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       71992021
         LA    WR15,T06ETHLD       ADDR. EDIT TABLE HOLD=               72000020
         B     T06EDR50            INVALID DATA ROUTINE                 72040020
         EJECT                                                          74560020
*********************************************************************** 74600020
*T06WTOR IS THE WRITE TO OPERATOR WITH REPLY AND WAIT ROUTINE.        * 74640020
*ON RETURN: WR2-ADDR. REPLY BUFFER  WR3-LENGTH REPLY BUFFER.          * 74680020
*********************************************************************** 74720020
T06WTOR  LA    WR2,T06WRBUF        ADDR. OF REPLY BUFFER                74760020
         LA    WR3,T06WRBFL        LENGTH OF REPLY BUFFER               74800020
         MVC   E0(T06WRBFL,WR2),NBLANKS BLANK THE BUFFER                74840020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    74850021
         L     WR4,TSCVTECB  GET TO ECBS                                74860021
         USING TSECB,WR4                                                74870021
         LA    WR4,TSCECB6   GET ECB6 - WTOR ECB                        74880021
         DROP  WR4                                                      74890021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       74900021
         MVI   E0(WR4),E0          CLEAR WAIT POST BITS                 74920020
         SR    WR0,WR0             ZERO                                 74960020
         IC    WR0,CIBCONID        CONSOLE ID                           75000020
         WTOR  ,(WR2),(WR3),(WR4),MF=(E,T06WWTOR) ISSUE THE WTOR        75040020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    75050021
         LA    WR4,T06ECBL3  GET ADRS OF LIST 3                         75060021
         WAIT  1,ECBLIST=(WR4)                                          75070021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       75080021
         OC    E0(T06WRBFL,WR2),NBLANKS  UPPER CASE THE REPLY           75120020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    75125021
         L     WR4,L3ECB6AD  GET ADRS OF ECB6 - WTOR ECB                75130021
         TM    E0(WR4),POSTBIT         WAS ECB6 POSTED                  75135021
         BZ    ABORTMOD      NO - ABORT THE MODIFY                      75140021
         MVI   E0(WR4),E0    YES - CLEAR THE ECB FLAGS                  75145021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       75150021
         BR    TRANR               RETURN TO CALLER                     75160020
         SPACE 5                                                        75160721
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    75161421
         USING TSECB,TSOECBS                                            75162121
         USING CVTDSECT,WR6                                             75162821
EXTRASTP OC    STPRPLBF,NBLANKS        FOLD THE REPLY                   75163521
         CLC   STPRPLBF,URPLY          TEST FOR A 'U'                   75164221
         BE    TIMEIT        BRANCH IF IT IS A 'U' TO TIMER             75164921
         CLC   STPRPLBF,FSTOPRPL       IS THE REPLY 'FSTOP'             75165621
         BNE   STOPIT        BRANCH TO REISSUE THE MESSAGE IF NEITHER   75166321
         SPACE 5                                                        75167021
*********************************************************************** 75167721
*        'FSTOP' HAS BEEN ENTERED BY THE OPERATOR -- BECAUSE OF THIS  * 75168421
*        OVERT ACTION BY THE OPERATOR, WE WILL O.O.C.A. ALL USERS     * 75169121
*        STILL ON THE SYSTEM BY ABTERMING ALL THE RCTS                * 75169221
*********************************************************************** 75169321
         SPACE 2                                                        75169421
         LR    WR4,BASER1          SAVE REGISTER ACROSS POST  CC A69344 75169521
         LR    WR5,BASER2          SAVE REGISTER ACROSS POST  CC A69344 75169621
         LR    WR8,TSCVTR          SAVE REGISTER ACROSS POST  CC A69344 75169721
         L     EPR,CVT0PT01        ADR OF POST BRANCH ENTRY   CC A69344 75169821
         DROP  BASER1                                         CC A69344 75169921
         USING TSOT06,WR4                                     CC A69344 75170021
         L     BASER1,TSCVTRPT     ADR OF TIOCRPT             CC A69344 75170121
         LA    BASER1,TIOCLECB(,BASER1)   ADR OF TIOCLECB     CC A69344 75170221
         L     BASER2,TSCVTTSC     ADR OF TSC TCB             CC A69344 75170321
         DROP  BASER2                                         CC A69344 75170421
         USING TSOT06+4095,WR5                                CC A69344 75170521
         L     TSCVTR,ECB4F        FSTOP POST CODE            CC A69344 75170621
         SSM   DISABLE             DISABLE FOR BR ENTRY TO POST  A69344 75170721
         BALR  RTNR,EPR            BR TO POST TIOC FOR FSTOP  CC A69344 75170821
         SSM   ENABLE              ENABLE FOR INTERRUPTS      CC A69344 75170921
         LR    BASER1,WR4          RESTORE REGISTERS AFTER POST  A69344 75171021
         LR    BASER2,WR5          RESTORE REGISTERS AFTER POST  A69344 75171121
         LR    TSCVTR,WR8          RESTORE REGISTERS AFTER POST  A69344 75171221
         DROP  WR4                                            CC A69344 75171321
         DROP  WR5                                            CC A69344 75171421
         USING TSOT06,BASER1                                  CC A69344 75171521
         USING TSOT06+4095,BASER2                             CC A69344 75171621
         OI    TSCVTFL1,TSCFSTOP   INDICATE FSTOP REPLY       CC A69344 75171721
*                                                                       75171821
         L     WR4,TSCVTRCB  GET THE ADDRESS OF THE FIRST RCB           75171921
         USING RCB,WR4                                                  75172621
         LH    WR5,TSCVTCTR  GET NUMBER OF RCTS                         75173321
ET06ST01 SSM   DISABLE       DISABLE FOR ABTERM                         75174021
         TM    RCBFLG2,RCBACTV         IS THIS RCT ACTIVE               75174721
         BZ    ET06ST02      BRANCH IF NO RCT                           75175421
         OI    RCBFLG,RCBFND SET END FUNCTION FLAG                      75176121
         L     WR0,RCBRCT    GET THE TCB ADDRESS FOR ABTERM             75176821
         L     WR1,ABENDCOD  GET THE ABEND CODE FOR ABTERM              75177521
         L     EPR,CVTBTERM  GET THE ENTRY POINT OF ABTERM              75178221
         BALR  RTNR,EPR      BRANCH TO ABTERM                           75178921
ET06ST02 LA    WR4,RCBEND    BUMP RCB ADDRESS TO NEXT RCB               75179621
         SSM   ENABLE        ENABLE FOR INTERRUPTS BETWEEN RCTS         75180321
         BCT   WR5,ET06ST01  BRANCH IF MORE RCBS TO LOOK AT             75181021
         DROP  WR4                                                      75181721
         SPACE 5                                                        75182421
         LA    WR1,TSCECB5   GET ADDRESS OF REQUEST TO TERMINATE ECB    75183121
         WAIT  ECB=(WR1)     WAIT FOR T03                               75183821
         B     T06ST06       BRANCH TO CLEAN UP ROUTINE                 75184521
         SPACE 5                                                        75185221
TIMEIT   LH    WR4,TSCVTCUS  FIND OUT HOW MANY USERS ARE STILL ON TSO   75185921
         LA    WR4,E1(WR4)   ENSURE NON ZERO NUMBER                     75186621
         SLL   WR4,9         GIVE A TIME INTERVAL OF 512 SECONDS        75187321
*                            PER USER ON THE SYSTEM                     75188021
         ST    WR4,T06WWECB  SAVE THE TIME INTERVAL FOR STIMER          75188721
         MVI   TSCECB8,NOFLAG          CLEAR WAIT/POST BITS IN ECB8     75189421
         STIMER REAL,T06STIMX,BINTVL=T06WWECB    SET TIMER FOR THE      75190121
*                                                OPERATOR REMINDER AT   75190821
*                                                  512 SECONDS FOR EACH 75191521
*                                                USER ON TSO            75192221
         LA    WR1,T06ECBL4  GET THE ADDRESS OF THE ECB LIST            75192921
         WAIT  ECBLIST=(WR1) WAIT FOR TSO TO STOP OR THE TIMER TO       75193621
*                            EXPIRE                                     75194321
         TM    TSCECB5,POSTBIT         DID TSO COMPLETE SUCCESSFULLY?   75195021
         BZ    STOPIT        BRANCH IF IT WAS THE TIMER EXPIRING        75195721
         TTIMER CANCEL       TSO COMPLETED SUCCESSFULLY SO CANCEL THE   75196421
*                            REMAINDER OF THE TIMER INTERVAL            75197121
         B     T06ST06       GO CLEAN UP AND TERMINATE                  75197821
         DROP  TSOECBS,WR6                                              75198521
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       75199221
         EJECT                                                          75200020
*********************************************************************** 75240020
*T06TPUT IS THE TPUT ROUTINE.                                         * 75280020
*WR0-LENGTH OF MESSAGE.  WR1-ADDR. OF MESSAGE.                        * 75320020
*********************************************************************** 75360020
T06TPUT  LH    WR2,CIBTJID         TJID OF TSO TERMINAL                 75400020
         TPUT  (1),(0),TJID=(WR2)  ISSUE THE TPUT                       75440020
         BR    TRANR               RETURN                               75480020
         EJECT                                                          75520020
*********************************************************************** 75560020
*THESE INSTRUCTIONS ARE 'EXECUTED'                                    * 75600020
*********************************************************************** 75640020
T06EDXC1 XC    E0(E0,MODWAR),E0(MODWAR)    ZERO MODIFY WORK AREA        75680020
T06EDRC1 CLC   E0(E0,WR3),E0(KEYWR)        MODEL TO KEYWORD IN CIB      75720020
T06NNPK  PACK  T06WPACK(E8),E0(E0,WR5)     PACK NNNNN(L2 VARIES)        75760020
T06REGM1 MVC   T06WEDIT(E0),E0(WR5)        RN FROM CIB TO WORK AREA     75800020
T6E72MD2 MVC   M072ID2(E0,WR15),E0(WR5)    DATA TO REPLY BUFFER         75840020
T6E72MD3 MVC   M072ID3(E0,WR15),E0(WR5)    DATA TO REPLY BUFFER         75880020
         SPACE                                                          75920020
T6EM70WX MVC   M070IWX(E0,WR1),E0(KEYWR)   VARIABLE TO IKJ070I WTO      75960020
T6EM70TX MVC   M070ITX(E0,WR1),E0(KEYWR)   VARIABLE TO IKJ070I TPUT     76000020
T6EM71WX MVC   M071IWX(E0,WR1),E0(KEYWR)   VARIABLE TO IKJ071I WTO      76040020
T6EM71TX MVC   M071ITX(E0,WR1),E0(KEYWR)   VARIABLE TO IKJ071I TPUT     76080020
T6EM72WX MVC   M072IWX(E0,WR1),E0(KEYWR)   VARIABLE TO IKJ072I WTO      76120020
T6EM72TX MVC   M072ITX(E0,WR1),E0(KEYWR)   VARIABLE TO IKJ072I TPUT     76160020
T6EM72WZ MVC   M072IWX(E0,WR1),E0(WR15)    VARIABLE TO IKJ072I WTO      76200020
T6EM72TZ MVC   M072ITX(E0,WR1),E0(WR15)    VARIABLE TO IKJ072I TPUT     76240020
T6EM75WX MVC   M075IWX(E0,WR1),E0(WR15)    VARIABLE TO IKJ075I WTO      76280020
T6EM75TX MVC   M075ITX(E0,WR1),E0(WR15)    VARIABLE TO IKJ075I TPUT     76320020
*********************************************************************** 76360020
*TABLE USED TO DRIVE EDIT OF COMMAND INPUT BUFFER FOR VALID KEYWORDS  * 76400020
*EACH TABLE ENTRY IS FOUR WORDS                                       * 76440020
*1) ADDR. OF NEXT ENTRY. 2) LENGTH OF KEYWORD. 3) ADDR. OF KEYWORD.   * 76480020
*4) ADDR. OF KEYWORD HANDLING ROUTINE.                                * 76520020
*********************************************************************** 76560020
T06ETAB  DS    0F                                               1/7   * 76600020
T06ETUSE DC    A(T06ETREG),A(L'T06EUSE-1),A(T06EUSE),A(T06USE)  2/7   * 76640020
T06ETREG DC    A(T06ETDRV),A(L'T06EREG-1),A(T06EREG),A(T06REG)  3/7   * 76680020
T06ETDRV DC    A(T06ETSMF),A(L'T06EDRV-1),A(T06EDRV),A(T06DRV)  4/7   * 76720020
T06ETSMF DC    A(T06ETSUB),A(L'T06ESMF-1),A(T06ESMF),A(T06SMF)  5/7   * 76760020
T06ETSUB DC    A(T06ETHLD),A(L'T06ESUB-1),A(T06ESUB),A(T06SUB)  6/7   * 76800020
T06ETHLD DC    A(0),A(L'T06EHLD-1),A(T06EHLD),A(T06HLD)         7/7   * 76840020
*                                                                     * 76880020
T06EUSE  DC    C'USERS='           USERS=NNNNN                        * 76920020
T06EREG  DC    C'REGSIZE'          RGSIZE(NN)=(NNNNK,NNNNK)           * 76960020
T06EDRV  DC    C'DRIVER='          DRIVER='ANYTHING=NNNN'             * 77000020
T06ESMF  DC    C'SMF='             SMF=(PARM1,PARM2)                  * 77040020
T06ESUB  DC    C'SUBMIT='          SUBMIT=NNNNN                       * 77080020
T06EHLD  DC    C'HOLD='            HOLD=RN                            * 77120020
*********************************************************************** 77130020
         EJECT                                                          77160020
*********************************************************************** 77170020
*                                  MODEL FOR MESSAGE IKJ076D            77200020
NUSE     DC    C'''USERS=NNNNN'',                '   *                  77240020
NREG     DC    C'''REGSIZE(RN)=(XXXXXK,YYYYYK)'','   *                  77280020
NDRV     DC    C'''DRIVER=''PARAMETER'''',       '   *                  77320020
NSMF     DC    C'''SMF=(PARM1,PARM2)'',          '   *                  77360020
NSUB     DC    C'''SUBMIT=NNNNN'',               '   *                  77400020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    77420021
NHLD     DC    C'''HOLD=VALUE'',                 '   *                  77440021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       77460021
NKEY     DC    C'''KEYWORD=VALUE'',              '   *                  77480020
NKEYL    EQU   *-NKEY              LENGTH OF MODELS FOR PRINT           77520020
*********************************************************************** 77560020
NCANCEL  DC    C'CANCEL'           FOR REPLY OF CANCEL                  77600020
NOFF     DC    C'OFF'              SMF PARM 1 OFF                       77640020
NOPT1    DC    C'OPT=1'            SMF PARM 1 OPT=1                     77680020
NOPT2    DC    C'OPT=2'            SMF PARM 2 OPT=2                     77720020
NEXTNO   DC    C'EXT=NO)'          SMF PARM 2 EXT=NO                    77760020
NEXTYES  DC    C'EXT=YES)'         SMF PARM 2 EXT=YES                   77800020
NC14     DC    C'00014'            FOR REGSIZE MESSAGES                 77840020
NC16382  DC    C'16382'            FOR REGSIZE MESSAGES                 77880020
NEQLP    DC    C'=('               FOR EDIT REGSIZE                     77920020
NC0      DC    C'0'                FOR REGSIZE PARAMETERS               77930020
NCK      DC    C',0K'              FOR REGSIZE PARAMETERS               77940020
NBLANKS  DC    36C' '              36 BLANKS                            77960020
         DS    0F                  WORD MASKS                           78080020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    78090021
ABENDCOD DC    X'00000999'                                              78100021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       78110021
BIT0MASK DC    X'80000000'         MASK FOR BIT 0 OF FULL WORD          78120020
ECB7F    DC    X'7F000000'         NORMAL POST CODE                     78160020
ECB4F    DC    X'4F000000'         TIOC POST CODE FOR FSTOP   CC A69344 78180021
SP253MSK DC    X'FD000000'         MASK FOR SUBPOOL 253                 78200020
NF1      DC    F'1'                ONE                                  78240020
NF2      DC    F'2'                TWO                                  78280020
NF4      DC    F'4'                FOUR                                 78320020
NF5      DC    F'5'                FIVE                                 78360020
NF14     DC    F'14'               FOURTEEN                             78400020
NF16382  DC    F'16382'            16382                                78440020
NF8191   DC    F'8191'             16382 IN 2K BLOCKS                   78450020
TJID0    DC    H'0'                TJID OF ZERO                         78480020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    78490021
HW5      DC    H'5'          COMPARE FOR XXXXXK AND YYYYYK              78500021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       78510021
ENABLE   DC    X'FF'               ALLOW INTERRUPTS                     78520020
DISABLE  DC    X'00'               NO INTERRUPTS                        78560020
*********************************************************************** 78600020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    78606021
REGSIZE  DC    CL36'REGSIZE'                                            78612021
HOLD     DC    CL36'HOLD'                                               78618021
CANCEL   DC    CL36'CANCEL'                                             78624021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       78630021
         EJECT                                                          78640020
*********************************************************************** 78680020
M068IW   WTO   'IKJ068I SMF DSA BIT IS SET - OPT=2 MUST BE USED',MCSFLAX78690020
               G=(REG0),MF=L,DESC=5                                     78700020
M068IWL  EQU   *-M068IW                                                 78703021
M068IT   EQU   M068IW+4                                                 78706021
M068ITL  EQU   M068IWL-8                                                78709021
*********************************************************************** 78714020
M070IW   WTO   'IKJ061I THIS KEYWORD IS INVALID -                      X78730020
                          ',MCSFLAG=(REG0),DESC=5,MF=L                  78740020
M070IWL  EQU   *-M070IW            LENGTH MESSAGE                       78800020
M070IWX  EQU   38                  DISP TO VARIABLE FIELD               78840020
         SPACE                                                          78880020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    78900021
M070IT   EQU   M070IW+4                                                 78920021
M070ITL  EQU   M070IWL-8                                                78940021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       78960021
M070ITX  EQU   34                  DISP TO VARIABLE FIELD               79000020
         SPACE                                                          79040020
M070IXL  EQU   32                  LENGTH OF VARIABLE FIELD             79080020
*********************************************************************** 79120020
M071IW   WTO   'IKJ064I THE VALUE OF THIS KEYWORD IS INVALID -         X79160020
                                       ',DESC=5,MCSFLAG=(REG0),MF=L     79200020
M071IWL  EQU   *-M071IW            LEN MESSAGE                          79240020
M071IWX  EQU   51                  DISP TO VARIABLE FIELD               79280020
         SPACE                                                          79320020
M071IT   EQU   M071IW+4                                                 79360021
M071ITL  EQU   M071IWL-8                                                79400021
M071ITX  EQU   47                  DISP TO VARIABLE FIELD               79440020
         SPACE                                                          79480020
M071IXL  EQU   32                  LENGTH OF VARIABLE FIELD             79520020
*********************************************************************** 79560020
         SPACE                                                          79600020
*********************************************************************** 79640020
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    79670021
M072IW   WTO   'IKJ072I                      EXCEEDS OR EQ TO MAXIMUM VX79700021
               ALUE OF          ',MCSFLAG=REG0,MF=L,DESC=5       A      79730021
M072IWL  EQU   *-M072IW            LENGTH MESSAGE                       79760020
M072IWX  EQU   12                  DISP TO VARIABLE FIELD ONE           79800020
M072IWY  EQU   68                   DISP YO VAR FLD 2                   79820021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       79840021
         SPACE                                                          79880020
M072IT   EQU   M072IW+4                                                 79920021
M072ITL  EQU   M072IWL-8                                                79960021
M072ITX  EQU   8                   DISP TO VARIABLE FIELD ONE           80000020
M072ITY  EQU   54                  DISP TO VARIABLE FIELD TWO           80040020
         SPACE                                                          80080020
M072IXL  EQU   20                  LENGTH OF VARIABLE FIELD ONE         80120020
M072ID1  EQU   0                   DISP TO DATA ONE IN VARIABLE ONE     80160020
M072ID2  EQU   8                   DISP TO DATA TWO IN VARIABLE ONE     80200020
M072ID2L EQU   11                  MAX. LENGTH DATA TWO                 80240020
M072ID3  EQU   11                  DISP TO DATA THREE IN VARIABLE ONE   80280020
M072ID3L EQU   9                   MAX LENGTH DATA THREE                80320020
M072IYL  EQU   5                   LENGTH OF VARIABLE FIELD TWO         80360020
*********************************************************************** 80400020
M073IW   WTO   'IKJ073I REGION    NOT ACTIVE - REGSIZE/HOLD IGNORED',MCX80440021
               SFLAG=REG0,MF=L,DESC=5                                   80480021
M073IWL  EQU   *-M073IW            LENGTH OF MESSAGE                    80520020
M073IWX  EQU   19                  DISP TO VARIABLE FIELD               80560021
M073IT   EQU   M073IW+4                                                 80600021
M073ITL  EQU   M073IWL-8                                                80640021
M073ITX  EQU   15                                                       80680021
         SPACE                                                          80760020
M073IXL  EQU   2                   LENGTH OF VARIABLE FIELD             80800020
*********************************************************************** 80840020
         EJECT                                                          80880020
*********************************************************************** 80920020
M074IW   WTO   'IKJ074I    DOES NOT EXIST, REGSIZE INVALID',           C80960020
               MCSFLAG=REG0,MF=L,DESC=5                                 81000020
M074IWL  EQU   *-M074IW            LENGTH MESSAGE                       81040020
M074IWX  EQU   12                  DISP TO VARIABLE FIELD               81080020
         SPACE                                                          81120020
M074IT   EQU   M074IW+4                                                 81160021
M074ITL  EQU   M074IWL-8                                                81200021
M074ITX  EQU   8                   DISP TO VARIABLE FIELD               81240020
         SPACE                                                          81280020
M074IXL  EQU   2                   LENGTH OF VARIABLE FILED             81320020
*********************************************************************** 81360020
M075IW   WTO   'IKJ075I TSO/SMF OPTIONS CANNOT EXCEED              ',  C81400020
               MCSFLAG=REG0,MF=L,DESC=5                                 81440020
M075IWL  EQU   *-M075IW            LENGTH OF MESSAGE                    81480020
M075IWX  EQU   42                  DISP TO VARIABLE FIELD               81520020
         SPACE                                                          81560020
M075IT   EQU   M075IW+4                                                 81600021
M075ITL  EQU   M075IWL-8                                                81640021
M075ITX  EQU   38                  DISP TO VARIABLE FIELD               81680020
         SPACE                                                          81720020
M075IXL  EQU   14                  LENGTH VARIABLE FIELD                81760020
M075ID1  EQU   0                   DISP TO DATA ONE IN VARIABLE         81800020
M075ID2  EQU   6                   DISP TO DATA TWO IN VARIABLE         81840020
*********************************************************************** 81880020
         EJECT                                                          81920020
*********************************************************************** 81960020
M076D    WTOR  'IKJ066D REPLY                                 ''U'', ORC82000020
               , ''CANCEL''',DESC=2,MCSFLAG=REG0,MF=L                   82040020
M076DL   EQU   *-M076D             LENGTH MESSAGE                       82080020
M076DX   EQU   26                  DISP TO VARIABLE FIELD               82120020
M076DXL  EQU   30                  LENGTH OF VARIABLE FIELD             82160020
*********************************************************************** 82170020
M066D    WTOR  'IKJ066D REPLY                                 OR, ''CANX82180020
               CEL''',DESC=2,MCSFLAG=REG0,MF=L                          82190020
M066DL   EQU   *-M066D             LENGTH MESSAGE                       82192020
M066DX   EQU   26                  DISP TO VARIABLE FIELD               82194020
*********************************************************************** 82200020
M077IW   WTO   'IKJ017I SMF NOT ACTIVE, SMF PARAMETER IGNORED',        X82240020
               MCSFLAG=REG0,MF=L,DESC=5                                 82280020
         SPACE                                                          82320020
M077IWL  EQU   *-M077IW                                                 82350021
M077IT   EQU   M077IW+4                                                 82380021
M077ITL  EQU   M077IWL-8                                                82410021
*********************************************************************** 82440020
         EJECT                                                          82480020
*********************************************************************** 82520020
M078IW   WTO   'IKJ078I                   TSO IS STOPPING',            C82560020
               ROUTCDE=2,MCSFLAG=REG0,MF=L,DESC=5                       82600020
M078IWL  EQU   *-M078IW            LEN MESSAGE                          82640020
M078IWJ  EQU   12                  DISP TO VARIABLE FIELD ONE           82680020
M078IWS  EQU   21                  DISP TO VARIABLE FIELD TWO           82720020
         SPACE                                                          82760020
M078IT   EQU   M078IW+4                                                 82800021
M078ITL  EQU   M078IWL-8                                                82840021
M078ITJ  EQU   8                   DISP TO VARIABLE FIELD ONE           82880020
M078ITS  EQU   17                  DISP TO VARIABLE FIELD TWO           82920020
*********************************************************************** 82960020
M079IW   WTO   'IKJ079I                   TSO HAS BEEN MODIFIED',      C83000020
               DESC=5,MCSFLAG=REG0,MF=L                                 83040020
M079IWL  EQU   *-M079IW           LEN MESSAGE                           83080020
M079IWJ  EQU   12                  DISP TO VARIABLE FIELD ONE           83120020
M079IWS  EQU   21                  DISP TO VARIABLE FIELD TWO           83160020
         SPACE                                                          83200020
M079IT   EQU   M079IW+4                                                 83240021
M079ITL  EQU   M079IWL-8                                                83280021
M079ITJ  EQU   8                   DISP TO VARIABLE FIELD ONE           83320020
M079ITS  EQU   17                  DISP TO VARIABLE FIELD TWO           83360020
*********************************************************************** 83400020
M080IW   WTO   'IKJ080I TSO MODIFY CANCELLED BY OPERATOR',             C83440020
               MCSFLAG=REG0,MF=L,DESC=5                                 83480020
*********************************************************************** 83520020
M081IT   DC   C'IKJ081I TSO MODIFY REJECTED'                            83560020
M081ITL  EQU   *-M081IT            LENGTH MESSAGE                       83600020
*********************************************************************** 83640020
         SPACE                                                          83680020
*********************************************************************** 83720020
M082IW   WTO   'IKJ018I SMF OPI BIT IS SET - SMF PARAMETER IGNORED',   X83760020
               MCSFLAG=REG0,MF=L,DESC=5                                 83800020
         SPACE                                                          83840020
M082IWL  EQU   *-M082IW                                                 83870021
M082IT   EQU   M082IW+4                                                 83900021
M082ITL  EQU   M082IWL-8                                                83930021
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    84030021
M086IW   WTO   'IKJ086I REGION    HAS FAILED - REGSIZE/HOLD IGNORED',MCX84130021
               SFLAG=REG0,DESC=5,MF=L                                   84230021
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       84330021
M086IWL  EQU   *-M086IW            LENGTH OF MESSAGE                    84692020
M086IWX  EQU   19                                                       84696021
M086IT   EQU   M086IW+4            MSG TEXT                             84700021
M086ITL  EQU   M086IWL-8           LENGTH OF MSG                        84704021
M086ITX  EQU   15                  DISP TO VAR FIELD                    84708021
M086IXL  EQU   2                   LENGTH OF VARIABLE FIELD             84712020
*********************************************************************** 84716020
M085IW   WTO   'IKJ076I SUM OF REGSIZE AND LSQA EXCEEDS MAX - 16382',  X84717021
               MCSFLAG=REG0,DESC=5,MF=L                                 84718820
M085IWL  EQU   *-M085IW                                                 84718920
M085IT   EQU   M085IW+4                                                 84719121
M085ITL  EQU   M085IWL-8                                                84719321
*********************************************************************** 84719720
***** THE FOLLOWING SECTION OF CODE WAS CHANGED FOR APAR 44022 *****    85519721
M026D    WTO   'IKJ026I HOLD AND REGSIZE SPECIFIED FOR SAME REGION=NN',X86319721
               MCSFLAG=REG0,MF=L,DESC=5                                 87119721
M026DL   EQU   *-M026D       SIZE OF WTO                                87919721
M026DRN  EQU   55            DISP TO RN FIELD OF MSG                    88719721
M026TL   EQU   M026DL-8      TPUT LENGTH                                89519721
*********************************************************************** 90319721
M027D    WTOR  'IKJ027D REPLY ''HOLD'', ''REGSIZE'', ''U'', OR ''CANCELX91119721
               ''',DESC=2,MCSFLAG=REG0,MF=L                             91919721
M027DL   EQU   *-M027D       SIZE OF WTOR LIST                          92719721
STPWTOR  WTOR  'IKJ024D TSO STOP IN PROGRESS, REPLY ''U'' OR ''FSTOP'''*93519721
               ,DESC=3,ROUTCDE=(2),MF=L                                 94319721
STPWLEN  EQU   *-STPWTOR                                                95119721
URPLY    DC    CL5'U'                                                   95919721
FSTOPRPL DC    CL5'FSTOP'                                               96719721
***** THIS ENDS THE SECTION OF CODE CHANGED FOR APAR 44022  *****       97519721
         END                                                            98319721
