IKJEAT07 START                                                          00020020
*********************************************************************** 00030020
*                                                                     * 00040020
*STATUS -- 0                                                          * 00050020
*C115804                                                       AJ M4911 00052021
*A139904                                                       AJ M4911 00054021
*C113020                                                      AJ  M4248 00054421
*A077720,077800                                 MP/TSO M3009  AJ A52740 00056021
*A043220-043900,067884-067975                                 AC A47178 00058121
*A013220-013364,015780,015784,043602-043670                   AJ A49808 00058521
*C039234                                                      AJ A49808 00058921
*C061200,061400,062200                                        AJ A58556 00059321
*A079840,079844                                               AJ A58556 00059721
*                                                                     * 00060020
*FUNCTION -- CONTROL SECTION NAME - IKJEAT07                          * 00070020
*     THIS ROUTINE IS INVOKED TO REMOVE A USER FROM THE SYSTEM WHEN   * 00080020
*     THE USER CANNOT BE SWAPPED IN AND TERMINATED OR TO PURGE A      * 00090020
*     USER WHO IS EITHER PARTIALLY QUIESCED OR RESTORED.  THE ROUTINE * 00100020
*     LOCATES AND RELEASES A USER'S 'IN CORE' SYSTEM CONTROL BLOCKS,  * 00110020
*     CAUSES A MESSAGE TO BE SENT TO THE TERMINAL AND CAUSES THE      * 00120020
*     USER TO BE DISCONNECTED FROM THE SYSTEM.  THE SYSTEM CONTROL    * 00130020
*     BLOCKS WHICH MUST BE PURGED ARE THE ENQ ELEMENTS (QEL'S AND     * 00140020
*     QCB'S), THE TIMER QUEUE ELEMENTS (TQE'S), WTOR CONTROL BLOCKS   * 00150020
*     (RQE'S AND WQE'S), THE INTERPARTITION POST BLOCKS (IPPB'S) AND  * 00160020
*     THE IOS REQUEST QUEUE ELEMENTS (RQE'S).                         * 00170020
*                                                                     * 00180020
*     THIS ROUTINE WILL PERFORM ANY PROCESSING NECESSARY TO MAKE THE  * 00190020
*     THE NEXT QEL ON THE QUEUE READY IF THE ONE REMOVED OWNED THE RE-* 00200020
*     SOURCE.                                                         * 00210020
*                                                                     * 00220020
*     REPLY ID'S ARE RETURNED TO THE UCM DURING THE WTOR PURGE.       * 00230020
*                                                                     * 00240020
*ENTRY POINTS -- IKJEAT07                                             * 00250020
*                                                                     * 00260020
*INPUT -- REG 1 - RCB ADDRESS OR TJID                                 * 00270020
*         REG13 - SAVE AREA ADDRESS                                   * 00280020
*         REG14 - RETURN ADDRESS                                      * 00290020
*         REG15 - ENTRY POINT                                         * 00300020
*                                                                     * 00310020
*OUTPUT -- NONE                                                       * 00320020
*                                                                     * 00330020
*EXTERNAL REFERENCES -- TIMER SECOND LEVEL INTERRUPT HANDLER FOR TQE  * 00340020
*     PURGE PROCESSING                                                * 00342020
*                                                                     * 00350020
*EXITS,NORMAL -- RETURN TO CALLER                                     * 00360020
*EXITS,ERROR -- NONE                                                  * 00361020
*                                                                     * 00362020
*TABLES/WORK AREAS -- A 36 WORD WORK AREA IS OBTAINED FOR USE DURING  * 00363020
*     THE QEL PURGE AND WTOR PURGE ROUTINES.                          * 00364020
*                                                                     * 00370020
*ATTRIBUTES -- DISABLED, REENTRANT, REFRESHABLE, SUPERVISOR STATE     * 00370120
*                                                                     * 00370220
*NOTES -- THIS ROUTINE MUST RUN UNDER A PRIVILEGED TASK               * 00380020
*                                                                     * 00390020
*    TASK REMOVE ROUTINE IN A MULTIPROCESSING SYSTEM WHEN A      21008* 00392021
*    TASK IS SET NON DISPATCHABLE                                21008* 00394021
*********************************************************************** 00400020
         EJECT                                                          00410020
         IEAQFX 65,MCH,M65MP                                      21008 00414021
         EJECT                                                    21008 00416021
CVT      DSECT                                                          00420020
         CVT                                                            00430020
         EJECT                                                          00440020
SCVTSECT DSECT                                                          00450020
         SCVT                                                           00460020
         SPACE 4                                                        00470020
         IKJQEL                                                         00480020
         SPACE 4                                                        00490020
         IEZJSCB                                                        00500020
         EJECT                                                          00510020
         IKJTCB                                                         00520020
         EJECT                                                          00530020
         IKJTJB                                                         00540020
         EJECT                                                          00550020
         IKJRCB                                                         00560020
         SPACE 2                                                        00570020
         IKJTJBX                                                        00580020
         EJECT                                                          00590020
         IKJTSCVT                                                       00600020
         SPACE 3                                                        00602020
         IKJTIOCP                                                       00604020
         EJECT                                                          00610020
         SPACE 4                                                        00612020
QPLSECT  DSECT                          QUIESCE I/O PARAMETER LIST      00620020
         DS    0F                                                       00630020
QPLCNT   DS    0C                       TOTAL COUNT FIELD               00640020
QPLNUM   DS    4C                       # OF EXTENTS                    00650020
QPLIOB   DS    1F                       ADDRESS OF IOB CHAIN            00660020
QPLFLG   DS    0C                       FLAGS FIELD                     00670020
QPLTCB   DS    1F                       ADDRESS OF TCB                  00680020
OPTIONS  EQU   X'0E'                    PURGE I/O OPTIONS               00690020
LSTEXT   EQU   X'80'                    LAST GPL EXTENT FLAG            00700020
OPTHALT    EQU  X'2E'                    PURGE I/O W/HALT OPTION        00705020
         SPACE 6                                                        00710020
         IKJECBS                                                        00720020
         EJECT                                                          00730020
         IKJRB                                                          00740020
         EJECT                                                          00750020
         IKJRQE                                                         00760020
           SPACE  4                                                     00770020
         IKJTQE                                                         00780020
         SPACE 3                                                        00790020
         IKJIPPB                                                        00800020
         EJECT                                                          00810020
UCM      DSECT                                                          00820020
         IEECUCM                                                        00830020
         EJECT                                                          00840020
         IKJWQE                                                         00850020
         SPACE 5                                                        00860020
         IKJRPQE                                                        00870020
         SPACE 5                                                        00880020
T07SAVE  DSECT                                                          00890020
REGSAVE  DS    18F                 T07'S REGISTER SAVE AREA             00900020
QELPRGSA DS    18F                 AUXILLIARY SAVE AREA                 00904020
WORKAREA EQU   QELPRGSA                                                 00908020
*                                  AND ALSO AS AREA PASSED TO SVC 102   00912020
WORKAR2  EQU   WORKAREA+2                                               00914020
QELRELS  DS    28F                 RELEASE DCB                          00922020
WORKAR3  EQU   QELRELS                                        AC A47178 00924021
T07WKLN  EQU   *-T07SAVE           LENGTH OF WORK AREA                  00930020
     EJECT                                                              00932020
           IKJUMSM                                                      00934020
           EJECT                                                        00936020
           IKJSWAPD                                                     00938020
         EJECT                                                          00940020
RLDCB    DSECT                     DCB,ECB,IOB AND DEB USED FOR RLSE    00950020
RLECB    DS    F                   ECB TO WAIT ON                       00960020
RLIOB    DS    0F                  START OF IOB                         00970020
IOBFL1   DS    X                   IOB FLAGS                            00980020
IOBFL2   DS    X                   IOB FLAGS                            00990020
         DS    H                   FILLER                               01000020
IOBECBAD DS    F                   ADDR OF ECB TO BE POSTED             01010020
         DS    2F                  FILLER                               01020020
IOBSTART DS    F                   ADDR OF CHANNEL PROGRAM              01030020
IOBDCBAD DS    F                   ADDR OF ASSOCIATED DCB               01040020
         DS    2F                  FILLER                               01050020
IOBMOD   DS    X                   MODIFIER - DEB EXTENT NUMBER         01060020
IOBSK    DS    CL4                 BBCC TO SEEK TO                      01070020
         DS    CL3                 FILLER                               01080020
DCBDEBAD DS    F                   FLAGS AND SDR OF ASSOC DEB           01090020
RLCCW    DS    X                   CCW OP CODE                          01100020
         DS    CL3                 FILLER                               01110020
         DS    X                   CCW FLAGS                            01120020
         DS    CL2                 FILLER                               01130020
         DS    X                   BYTE COUNT - END OF IOB INDICATOR    01140020
DEAPGV   DS    4F                  APPENDAGE VECTOR TABLE               01150020
DENEXT   DS    X                   NUMBER OF EXTENTS                    01160020
         DS    CL3                 REMAINDER OF APG VECTOR TABLE        01170020
DEPRIOR  DS    X                   DEB PRIORITY                         01180020
         DS    X                   FILLER BYTE                          01190020
DEVRET   DS    H                   APG VECTOR TABLE RETURN              01200020
DEPKID   DS    0X                  USERS PROTECTION KEY AND DEB ID      01210020
DEDCBAD  DS    F                   ADDR OF ASSOCIATED DCB               01220020
DEEXTSCL DS    0X                  SIZE OF EXTENTS                      01230020
DEAPPAD  DS    F                   ADDR OF APG VECTOR TABLE             01240020
DEFM     DS    X                   FILE MASK                            01250020
         DS    X                   FILLER BYTE                          01260020
DEUCBAD  DS    H                   ADDR OF UCB                          01270020
DEBB     DS    H                   BIN OF DEVICE                        01280020
DESTART  DS    2H                  START CCHH OF EXTENT                 01290020
DEEND    DS    2H                  END CCHH OF EXTENT                   01300020
DETRKS   DS    H                   NO OF TRACKS ALLOCATED               01310020
RLDCBLN  EQU   *-RLDCB             LENGTH OF DSECT                      01320020
       EJECT                                                            01322021
         SPACE 3                                                        01322421
**                                                            AJ A49808 01324021
*   IEAQMESSAGES DSECT  RELEASE 21.0 AND ON                   AJ A49808 01326021
**                                                            AJ A49808 01328021
         SPACE 3                                                        01328421
MSGENTRY DSECT                                                AJ A49808 01328821
INFENTRY DS    H                   RESERVED                   AJ A49808 01329221
INFTJID  DS    H                   TJID IF TSO USER           AJ A49808 01329621
INFTCB   DS    F                   TCB ADDRESS                AJ A49808 01329721
INFBADDR DS    F                                              AJ A49808 01329821
INFRCL   DS    X                   REASON CODE AND MSGLEN     AJ A49808 01329921
INFFLG   DS    X                   TYPE OF ENTRY FLAG         AJ A49808 01333221
INFCC    DS    H                   COMP CODE                  AJ A49808 01335221
INFVAR   DS    4F                  VARIABLE MSG INFO          AJ A49808 01335621
INFEND   EQU   *                                              AJ A49808 01336021
INFLEN   EQU   (INFEND-INFENTRY)   LENGTH OF ENTRY            AJ A49808 01336421
         EJECT                                                          01336721
*        REGISTER EQUATES FOR MAINLINE IKJEAT07                         01340020
         SPACE 2                                                        01350020
ZEROREG  EQU   0                   EQUATE FOR REG 0                     01360020
PARMREG  EQU   1                   PARAMETER REGISTER                   01370020
TJBXREG  EQU   2                   TJBX BASE REGISTER                   01380020
HOLDREG  EQU   2                   WORK REGISTER-SAVE PARM REG CONTENTS 01390020
R3       EQU   3                                                        01392020
CVTREG   EQU   3                   CVT BASE REGISTER                    01400020
SCVTREG  EQU   3                   SCVT BASE REGISTER                   01410020
TSCVTREG EQU   3                   TSCVT BASE REGISTER                  01420020
TJIDREG  EQU   5                   TJID OF USER BEING PROCESSED         01430020
R6       EQU   6                   WORK REGISTER                        01432020
TCBREG   EQU   6                   TCB BASE REGISTER                    01440020
IPPBREG  EQU   6                   IPPB BASE REGISTER                   01450020
WORKREG7 EQU   7                   WORK REGISTER                        01460020
FRSTREG  EQU   7                   TCB AND WORK REG                     01470020
COUNTREG EQU   8                   INDEX TO KEEP TRACK TJB'S TESTED     01480020
LASTREG  EQU   8                   ADDR USER'S LAST TCB                 01490020
TJBFSTRG EQU   9                   ADDR USER'S FIRST TCB                01500020
LINKREG  EQU   9                   BRANCH REG USED TO BAL TO SUBRTNS    01510020
BASEREG  EQU   10                  PROGRAM ADDRESSABILITY BASE REG      01520020
RCBREG   EQU   11                  RCB BASE REGISTER                    01530020
TJBREG   EQU   12                  TJB BASE REGISTER                    01540020
SAVREG   EQU   13                  ADDR SAVE AREA                       01550020
RTNREG   EQU   14                  RETURN REGISTER                      01560020
BNCHREG  EQU   15                  BRANCH REGISTER                      01570020
R15      EQU   15                  WORK REGISTER                        01572020
SAVELEN  EQU   72                  SAVE AREA LENGTH                     01576020
MESGREG  EQU   5                   QMESSAGES ENTRY PTR        AJ A49808 01578021
ENDREG   EQU   6                   LAST QMESSAGES ENTRY PTR   AJ A49808 01578421
         SPACE 4                                                        01580020
*   MISCELLANEOUS EQUATES FOR OUT OF CORE ABEND                         01590020
         SPACE 3                                                        01600020
BYTE     EQU   1                   LENGTH EQUATE                        01610020
CVTTKRM  EQU   12                  TASK REMOVE DISP IN MPCVT      21008 01612021
TCBNXT   EQU   116                 DISP IN TCB FOR ADDR NEXT TCB        01620020
SWTCHOFF EQU   X'00'               PURGE QUEUES BY TJID                 01630020
SWITCHON EQU   X'80'               PURGE QUEUES BY TCB ADDR             01640020
SWTCBOTH EQU   X'C0'               PURGE QUEUES BY TJID AND TCB         01650020
ALLFLAG  EQU   X'FF'               USED FOR TURNING OFF A BIT           01650420
FLGTJB1  EQU   X'5E'                                                    01650820
FLGTJB2  EQU   X'25'                                                    01651220
         EJECT                                                          01652020
         SPACE 1                                                        01660020
*          NUMERIC EQUATES                                              01670020
         SPACE 2                                                        01680020
FOUR     EQU   4                   *                                    01690020
EIGHT    EQU   8                   *                                    01700020
NINE     EQU   9                   *                                    01710020
ELEVEN   EQU   11                  *                                    01720020
TWELVE   EQU   12                  *                                    01730020
D25      EQU   25                  *                                    01750020
ONE28    EQU   128                 *                                    01770020
N100     EQU   100                 *                                    01772020
         SPACE 4                                                        01780020
*     REGISTERS AND EQUATES USED DURING TRANSIENT AREA AND I/0 PURGE    01790020
         SPACE 2                                                        01800020
SVRBREG  EQU   4                   SVRB BASE REGISTER                   01810020
RBREG    EQU   5                   RB BASE REGISTER                     01820020
WORK5    EQU   5                   WORK REG                             01830020
ENTRYREG EQU   7                   INIT ADDR FIRST SVRB ON USER QUEUE   01850020
TACTSREG EQU   8                   TACT BASE REGISTER                   01860020
TARFREG  EQU   12                  ADDR TA REFRESH RTN                  01870020
WORK14   EQU   14                  WORK REG                             01880020
CODEREG  EQU   15                  RETURN CODE REG                      01890020
NOTINUSE EQU   X'20'               FLG INDICATE TA NOT IN USE           01900020
PRGFENT  EQU   X'80'               INDICATE SVC 16 REENTRY NECESSARY    01910020
         EJECT                                                          01920020
         SPACE 4                                                        01922020
* REGISTER EQUATES FOR QEL PURGE                                        01930020
         SPACE 3                                                        01940020
WORKREG  EQU   2                   WORK REGISTER                        01950020
UCBREG   EQU   2                   ADDR UCB                             01960020
WORK2    EQU   2                   *                                    01970020
WORK3    EQU   3                   WORK REGISTER                        01980020
QELREG   EQU   3                   ADDR CURRENT QEL                     01990020
KEEPREG  EQU   4                   TEMP PARM REG SAVE                   02000020
WORK4    EQU   4                   WORK REG                             02010020
WORK6    EQU   6                   *                                    02020020
RLSEREG  EQU   7                   BASE FOR DSECT USED FOR RELEASE EXCP 02030020
MIQCBREG EQU   7                   ADDR CURRENT MINOR QCB               02040020
MJQCBREG EQU   8                   ADDR CURRENT MAJOR QCB               02050020
SIZEREG  EQU   5                   SIZE MINOR QCB                       02060020
R14      EQU   14                 SWITCH REGISTER                       02065020
         SPACE 5                                                        02070020
* MISCELLANEOUS EQUATES FOR QEL PURGE                                   02080020
FLAG00   EQU   X'00'               IOB FLAG                             02090020
FLAG01   EQU   X'01'               IOB FLAG                             02100020
EXTNMBR  EQU   X'02'               INDICATE EXTENTS FOR RLSE CODE       02110020
NOPCC    EQU   X'03'               NOP COMMAND CODE                     02120020
DESIZE   EQU   X'04'               EXTENT SIZE                          02130020
DEBKEY   EQU   X'0F'                                                    02140020
FILEMASK EQU   X'18'               FILE MASK FOR SET UP IN RELEASE EXCP 02150020
QELRBWT  EQU   X'20'               FLAG FOR SVRB PROCESSING NEEDED      02160020
LNTH     EQU   X'20'                                                    02170020
QELMCM   EQU   X'30'               MUST COMPLETE TEST MASK    AC A47178 02172021
RESERVED EQU   X'40'               MASK TO TEST FOR RESERVED DASD       02180020
SHARED   EQU   X'80'               FLAG INDICATING QEL A SHARED REQUEST 02190020
RSVDOFF  EQU   X'BF'               MASK TO TURN OFF RESERVED BIT IN QEL 02200020
IDENT    EQU   X'EE'               MASK FOR CHANNEL PROGRAM             02210020
         EJECT                                                          02220020
*       NUMERIC EQUATES USED IN QEL PURGE                               02230020
         SPACE 2                                                        02240020
ZERO     EQU   0                   *                                    02250020
ONE      EQU   1                   *                                    02260020
TWO      EQU   2                   *                                    02270020
THREE    EQU   3                   *                                    02280020
FSTQEL   EQU   0                   DISP IN MINOR QCB FOR ADDR FIRST QEL 02290020
LMINOR   EQU   1                   DISP IN MIN QCB FOR LENGTH MIN NAME  02300020
WORD     EQU   4                   LENGTH EQUATE                        02310020
PREVMIN  EQU   4                   DISP IN MINOR QCB FOR ADDR PREV MIN  02320020
PREVIOUS EQU   5                   DISP IN MINOR QCB FOR ADDR PREV MIN  02330020
SEVEN    EQU   7                   *                                    02340020
NXMIN    EQU   8                   DISP IN MIN QCB FOR ADDR NEXT MINOR  02350020
MINQCB   EQU   8                   DISP IN MAJ QCB FOR ADDR FIRST MINOR 02360020
QCBPKF   EQU   13                  DISP IN QCB FOR KNOWN TO   AC A47178 02362021
*                                   SYSTEM FLAG               AC A47178 02364021
QELSIZE  EQU   16                  SIZE QEL                             02370020
MAJSIZE  EQU   20                  SIZE MAJOR QCB                       02380020
FULLSIZE EQU   21                  EQUATE TO ROUND LENGTH TO FULL WORD  02390020
UCBRSCT  EQU   40                  DISP IN UCB TO RESERVE COUNT         02400020
RESINDIC EQU   41                  DEVICE RESERVATION INDICATOR IN UCB  02410020
UCBSKA   EQU   48                  DISP IN UCB TO BIN NUMBER OF DEVICE  02420020
CURPRG   EQU   80                  DISP TO PARM PTR SET BY ENQ          02430020
         SPACE 2                                                        02440020
*     REGISTER EQUATES FOR IQE PURGE                                    02450020
         SPACE  2                                                       02460020
IQEREG   EQU   4                   ADDR CURRENT IQE                     02470020
TAEQJREG EQU   5                   ADDR AEQ                             02480020
PREVREG  EQU   14                  WORK REG SAVE ADDR PREV IQE          02490020
TCBIQERG EQU   15                  ADDR TCB IN IQE PROCESSING           02500020
         SPACE  2                                                       02510020
*     MISCELLANEOUS EQUATES FOR IQE PURGE                               02520020
         SPACE 2                                                        02530020
IQELNK   EQU   0                   DISP IN IQE TO ADDR NEXT IQE         02540020
SIX      EQU   6                   DISP TO IQE QUEUE OFF AEQ            02550020
IQETCB   EQU   12                  DISP IN IQE FOR ADDR TCB             02560020
SIXTEEN  EQU   16                  LENGTH IQE                           02570020
TAEQMT   EQU   X'FF'               INDICATES IQE QUEUE EMPTY            02580020
         EJECT                                                          02590020
*     REGISTER EQUATES FOR TQE PURGE                                    02600020
         SPACE 3                                                        02610020
TQEBREG  EQU   4                   USED FOR BAL'S IN TQE PURGE          02630020
TIMEREG  EQU   5                   ADDR CURRENT TQE                     02640020
TQESAVRG EQU   6                   TEMP SAVE REG FOR ADDR TQE           02650020
TQETJDRG EQU   7                   WORK REG IN TQE PURGE                02660020
TQELNKRG EQU   8                   USED FOR BALS IN TQE RTN             02680020
CHKREG   EQU   8                   WORK REG                             02690020
         SPACE 5                                                        02700020
*     MISCELLANEOUS EQUATES FOR TQE PURGE                               02710020
         SPACE 4                                                        02720020
REALELM  EQU   X'01'               FLAG INDICATES REAL REQUEST          02722020
*                                  REAL REQUEST IS X'01' AND X'02'      02724020
SUPVELM  EQU   X'02'               FLAG INDICATING SUPV ELEMENT         02730020
TW4HRDEF EQU   X'46'               FLAG TO INDICATE 24 HR ELEMENT       02740020
TQENTONQ EQU   X'80'               FLAG FOR TQE NOT ON TIMER Q          02750020
TQESIZE  EQU   120                 SIZE TQE AND AQE OF 8 BYTES          02760020
         EJECT                                                          02770020
*    REGISTER EQUATES FOR RQE PURGE                                     02780020
         SPACE 4                                                        02790020
RQETCBRG EQU   0                   ADDR TCB FOR CURRENT RQE             02800020
PRVRQERG EQU   3                   ADDR PREVIOUS RQE                    02810020
RQEREG   EQU   4                   ADDR CURRENT RQE                     02820020
ERRQREG  EQU   5                   PTR TO AEQ                           02830020
TABENDRG EQU   6                   ADDR LAST RQE IN RQE TABLE           02840020
FREEREG  EQU   8                   ADDR NEXT AVAILABLE RQE              02850020
RQELNKRG EQU   15                  REG USED FOR BAL'S IN RQE PURGE      02860020
         SPACE 5                                                        02870020
*    MISCELLANEOUS EQUATES FOR RQE PURGE                                02880020
         SPACE 4                                                        02881020
FOURTEEN EQU   14                  *                                    02882020
SET      EQU   X'FF'               FLAG INDICATE RQE FREE               02883020
RQEFLG  EQU   X'04'               INDICATES RB HAS 1 OR MORE RQE'S      02883220
*                                 ASSIGNED                              02883420
IRBIQE  EQU   X'08'               INDICATES IRB HAS IQE'S NOT RQE'S     02883620
*                                 ASSIGNED                              02883820
RQESIZE  EQU   16                  SIZE RQE                             02884020
         EJECT                                                          02890020
*     REGISTER EQUATES FOR REPLY QUEUE ELEMENT AND WQE PURGES           02900020
         SPACE 3                                                        02910020
UCMREG   EQU   3                   UCM BASE REG                         02920020
RQESAVRG EQU   8                   TEMP SAVE FOR ADDR CURRENT RQE       02930020
WQESAVRG EQU   8                   TEMP SAVE FOR ADDR CURRENT WQE       02940020
WQEREG   EQU   4                   ADDR CURRENT WQE                     02950020
WTORREG  EQU   5                   REG USED FOR BRANCHING               02960020
TJID1REG EQU   6                   TJID REG IN WTOR PURGING             02970020
WTOLNKRG EQU   7                   REG USED FOR BALS IN WTOR PURGE RTN  02980020
RQEIDRG  EQU   11                  REG USED IN RESETTING REPLY ID       02990020
WORK14RG EQU   14                  WORK REG IN RTN RETURNING REPLY ID   02991020
MASKREG  EQU   15                  REG WITH MASK TO RETURN REPLY ID     02992020
RQEBUFRG EQU   15                  ADDR REPLY BUFFER                    02993020
         SPACE 5                                                        02994020
*     MISCELLANEOUS EQUATES FOR RPQE AND WQE PURGES                     02995020
         SPACE 3                                                        02996020
MCSINSYS EQU   X'02'               FLAG INDICATE MCS IN SYSTEM          03000020
RPQESIZE EQU   24                  SIZE REPLY QUEUE ELEMENT             03010020
MCSDISP  EQU   140                 DISP IN RQE FOR BUFF WHEN MCS IN SYS 03020020
BUFSIZE  EQU   144                 SIZE REPLY BUFFER                    03030020
WQESIZE  EQU   144                 SIZE WQE                             03040020
WQEMCSIZ EQU   168                 SIZE WQE WHEN MCS IN SYSTEM          03050020
          EJECT                                                         03050420
*    REGISTER EQUATES FOR SWAP UNIT RECOVERY                            03050820
           SPACE  3                                                     03051220
WR1        EQU  5                        *                              03051620
WR2        EQU  6                         *                             03052020
WR3        EQU  7                          * WORK REGS FOR SWAP UNIT    03052420
WR4        EQU  8                         *   CALCULATION               03052820
WR5        EQU  15                       *                              03053220
SWAPCBR    EQU  2                        ADDR SWAP CONTROL BLOCK        03053620
COUNT      EQU  14                       GROSS COUNT WORK REG           03054020
SUATR      EQU  5                        ADDR SWAP UNIT ALLC TABLE      03054420
FSTOFSET   EQU  6                        OFFSET TO CURRENT SWAP UNIT    03054820
NEXTUNIT   EQU  8                        OFFSET TO NEXT SWAP UNIT       03055220
           SPACE  5                                                     03055620
*    MISC EQUATES FOR SWAP UNIT RECOVERY                                03056020
           SPACE 3                                                      03056420
E0         EQU  0                                                       03056820
E1         EQU  1                                                       03057220
E4         EQU  4                                                       03057620
E8         EQU  8                                                       03058020
E7         EQU  7                                                       03058420
E12        EQU  12                                                      03058820
ALL        EQU  X'FF'                                                   03059220
NOFLG      EQU  X'00'                                                   03059620
         SPACE 5                                                        03060020
         EJECT                                                          03070020
IKJEAT07 CSECT                                                          03080020
         SPACE 2                                                        03090020
*********************************************************************** 03100020
*    THE FOLLOWING SECTION DETERMINES WHETHER THE PARAMETER PASSED IN * 03110020
* REGISTER 1 IS AN RCB ADDRESS OR A TJID.  IF THE HIGH ORDER BIT OF   * 03120020
* THE REGISTER IS ON, THE PARAMETER IS AN RCB ADDRESS.  PASSING OF AN * 03130020
* RCB ADDRESS INDICATES THAT ALL USERS OF THE REGION ARE TO BE PURGED * 03140020
* WHILE THE PASSING OF A TJID MEANS ONLY THIS USER IS TO BE REMOVED.  * 03150020
*********************************************************************** 03180020
         SPACE 2                                                        03190020
         STM   RTNREG,TJBREG,TWELVE(SAVREG)  SAVE CALLER'S REGS         03200020
         BALR  BASEREG,ZEROREG     ESTABLISH ADDRESSABILITY             03210020
         USING *,BASEREG           BASE FOR MODULE                      03220020
         LR    HOLDREG,PARMREG     SAVE REG OVER GETMAIN                03230020
         LA    WORK6,SAVELEN(SAVREG) R6=OOCA WORK AREA ADDR             03240020
         ST    SAVREG,FOUR(WORK6)  STORE BACK PTR                       03250020
         ST    WORK6,EIGHT(SAVREG) STORE FWD PTR                        03260020
         LR    SAVREG,WORK6        PT TO NEW SAVE AREA                  03270020
         USING T07SAVE,SAVREG      BASE FOR SAVE/WORK AREA              03280020
         L     CVTREG,CVTPTR       GET TO CVT                           03310020
         USING CVT,CVTREG          BASE FOR CVT                         03320020
         L     TSCVTREG,CVTTSCVT   GET PTR TO TSCVT                     03330020
         USING TSCVT,TSCVTREG      BASE FOR TSCVT                       03340020
         LTR   PARMREG,PARMREG     DETERMINE IF TJID OR RCB ADDR        03342020
         BM    CHCKMRE             RCB ADDRESS - CHECK FURTHER          03350020
         BZ    T07END1       RETURN TO CALLER                           03355021
         SPACE 5                                                        03360020
*********************************************************************** 03370020
* TJID PURGE. SET UP TJB AND RCB REGISTERS.  SET MESSAGE FLAG FOR TIOC* 03380020
*********************************************************************** 03390020
         SPACE 2                                                        03400020
         MH    HOLDREG,TSCVTSZU    DISP FOR THIS USER'S TJB             03410020
         A     HOLDREG,TSCVTTJB    ADDR THIS USER'S TJB                 03420020
         LR    TJBREG,HOLDREG      SET UP TJB REGISTER                  03430020
         USING TJB,TJBREG          BASE FOR TJB                         03440020
         TM    TJBSTAT2,TJBDEAD    HAS T07 FAILED ALREADY ON THIS TJB?  03442020
         BZ    TJIDPRGE            NO CONTINUE TJID PURGE               03444020
         TM    TJBSTAT,TJBDISC     HAS DISCONNECT BEEN REQUESTED?       03446020
         BO    T07END1       RETURN TO CALLER                           03447021
         OI    TJBSTAT,TJBDISC     NO REQUEST DISCONNECT                03448420
         BAL   LINKREG,TJIDEND     ISSUE LOGOFF TSEVENT                 03448820
         B     T07END1       RETURN TO CLLER                            03449221
TJIDPRGE OI    TJBSTAT2,TJBDEAD    INDICATE THIS TJB IS FAILING         03449620
         OI    TJBSTAT2,TJBOCAB    SET MESSAGE FLAGS FOR TIOC           03450020
         L     RCBREG,TJBRCB       GET ADDR RCB FOR REGION              03460020
         USING RCB,RCBREG          BASE FOR RCB                         03470020
         BAL   LINKREG,STSTOP          STATUS STOP THIS REGION          03475021
         BAL   LINKREG,CHKSTAT     RTN TO DETERMINE USER'S STATUS       03480020
         NI    TJBSTAT,SET-TJBINCOR TURN OFF USER IN CORE FLAG          03480521
         LH    HOLDREG,TJBTJID         GET TJID                         03481021
         LR    PARMREG,HOLDREG         RESTORE TJID                     03481521
         LH    HOLDREG,TJBTJID     GET USER TJID FOR LS3         A42840 03482021
         BALR  RTNREG,BNCHREG      GO TO RTN INDICATED IN BNCHREG       03490020
        LR    PARMREG,HOLDREG     SET UP TJID AS PARM TO                03492020
        L     BNCHREG,TSCVTLS3    LOGON ABEND RTN                       03494020
        BALR  RTNREG,BNCHREG      GO TO LOGON ABEND RTN                 03496020
         B     T07END              RETURN TO CALLER                     03500020
         SPACE 2                                                        03510020
*********************************************************************** 03520020
* DETERMINE IF ALL USERS IN REGION TO BE PURGED                       * 03530020
*********************************************************************** 03540020
         SPACE 2                                                        03541020
CHCKMRE  BAL   LINKREG,STSTOP          STATUS STOP THIS REGION          03550021
         LR    PARMREG,HOLDREG         RESTORE REG 1                    03559021
         LA    PARMREG,ZERO(PARMREG)   CLEAR RCB FLAG                   03568021
*                                  INIT SWITCH REG TO ZERO INDICATE     03580020
         LR    RCBREG,PARMREG      SET UP RCB ADDR IN RCBREG            03600020
         SR    COUNTREG,COUNTREG   CLEAR COUNT REG                      03610020
         USING RCB,RCBREG          BASE FOR RCB                         03620020
         LH    COUNTREG,TSCVTNTJ   NO. TJBS IN THE SYSTEM               03630020
         L     TJBREG,TSCVTTJB     ADDR TJB TABLE                       03640020
         USING TJB,TJBREG          BASE FOR TJB                         03660020
         LA    TJBREG,TJBEND SKIP TJB FOR TJID=0                        03670021
TJBTEST  C     RCBREG,TJBRCB       THIS TJB POINT TO RCB                03692020
         BNE   TRYNEXT             NO, TEST NEXT                        03700020
         TM    TJBSTAT,TJBNJB      IS THIS TJB UNUSED             M5609 03700420
         BO    TRYNEXT             YES TEST NEXT TJB              M5609 03700820
         TM    TJBSTAT2,TJBDEAD    HAS T07 FAILED ALREADY ON THIS TJB   03702020
         BZ    RCBPURGE            NO CONTINUE REGION PURGE             03704020
         TM    TJBSTAT,TJBDISC     HAS DISCONNECT BEEN REQUESTED?       03706020
         BO    TRYNEXT             YES SKIP AND TRY NEEXT TJB           03708020
         OI    TJBSTAT,TJBDISC     NO REQUEST DISCONNECT                03708420
          LH    PARMREG,TJBTJID      INITIALIZE REG 1                   03708620
         BAL   LINKREG,TJIDEND     ISSUE LOGOFF TSEVENT                 03708820
         B     TRYNEXT             TRY NEXT TJB                         03709220
RCBPURGE OI    TJBSTAT2,TJBDEAD    SET BIT INDICATING PURGING THIS TJB  03709620
         OI    TJBSTAT2,TJBOCAB    SET MESSAGE FLAGS FOR TIOC           03710020
         BAL   LINKREG,CHKSTAT     WAS USER PARTIALLY IN CORE?          03720020
          NI    TJBSTAT,SET-TJBINCOR TURN OFF USER IN CORE FLAG         03721021
         LH    HOLDREG,TJBTJID     GET TJID FROM TJB                    03722020
         LR    PARMREG,HOLDREG     PARAM FOR ROUTINE GOING TO           03760020
         BALR  RTNREG,BNCHREG      GO TO RTN IN BNCHREG                 03770020
        L     BNCHREG,TSCVTLS3    GET ADDR OF LOGON ABEND RTN AND       03774020
        BALR  RTNREG,BNCHREG        GO TO IT                            03778020
TRYNEXT  LA    TJBREG,TJBEND       ADRR NEXT TJB                        03782020
         BCT   COUNTREG,TJBTEST    IF COUNT NOT ZERO TEST NEXT TJB      03790020
         SPACE                                                          03800020
*********************************************************************** 03810020
* FREE UP SAVE/WORK AREA, RELOAD REGISTERS AND RETURN TO CALLER       * 03820020
*********************************************************************** 03830020
         SPACE                                                          03840020
T07END     EQU  *                                                       03850020
         NI    RCBSWTCH,ALLFLAG-RCBSTSP   RESET STATUS STOP SWITCH      03856021
T07END1  EQU   *             BIT NEVER SET BYPASS                       03862021
         SPACE 3                                                        03922721
OOCADONE L     SAVREG,FOUR(SAVREG) PTR TO CALLER'S SAVE AREA            03923421
         LM    RTNREG,TJBREG,TWELVE(SAVREG)  RESTORE CALLER'S REGS      03936721
         BR    RTNREG              RETURN                               03950020
         SPACE 3                                                        03959021
*                                                                       03968021
*        STATUS STOP THIS REGION IF NOT ALREADY STOPPED                 03977021
*                                                                       03986021
STSTOP   EQU   *                                                        03995021
         TM    RCBSWTCH,RCBSTSP        IS STATUS STOP BIT SET           04004021
         BO    AROUND        YES, DON'T RE-ISSUE STATUS STOP            04013021
         OI    RCBSWTCH,RCBSTSP        SET STATUS STOP SWITCH           04022021
         STATUS  STOP   ISSUE STATUS STOP FOR THIS REGION               04031021
AROUND   BR    LINKREG       RETURN TO CALLER                           04040021
         SPACE 3                                                        04049021
         SPACE 5                                                        04060020
*********************************************************************** 04070020
* DETERMINE WHETHER QUIESCE OR RESTORE OF THE USER WAS IN PROCESS     * 04080020
*********************************************************************** 04090020
         SPACE                                                          04100020
CHKSTAT  TM    RCBSWTCH,RCBZQRF    IF SET, THIS USER MUST BE     A44022 04100821
*                                  OUT OF CORE                   A44022 04101621
         BO    T07OUT2             PURGE BY TJID                 A44022 04102421
         CLC   TJBTJID,RCBTJID     ARE TJIDS EQUAL               A44022 04103221
         BNE   T07OUT2             YES PURGE BY TJID ONLY               04104020
         OI    RCBSWTCH,RCBZQRF    SET BIT FOR FUTURE USE AS     A44022 04106021
*                                  OUT OF CORE INDICATOR         A44022 04108021
         TM    RCBRSFLG,SET        WAS RESTORE IN PROCESS?              04110020
         BNZ   T07OUT              YES, GO TO PROCESS USER              04120020
         TM    RCBQUFLG,SET  ARE WE QUIESCING THIS USER                 04122021
         BNZ   T07OUT1       BRANCH IF IN QUIESCE PROCESSING            04124021
         TM    TJBSTAT,TJBINCOR        IS THE USER IN CORE              04126021
         BO    T07OUT1       YES SO PURGE AS IF JUST ENTERING QUIESCE   04128021
         SPACE 2                                                        04130021
*                            IF THE TJIDS COMPARE, ALL QUIESCE AND      04132021
*                            RESTORE FLAGS ARE ZERO, AND THE USER IS    04134021
*                            NOT IN CORE THEN OOCA HAS BEEN ENTERED     04136021
*                            EITHER JUST BEFORE RESTORE OR JUST AFTER   04138021
*                            QUIESCE AND THE USER IS EFFECTIVELY OUT    04140021
*                            OF CORE. THIS SHOULD RESULT NORMALLY       04142021
*                            FROM EITHER A SWAP IN OR SWAP OUT ERROR.   04144021
         SPACE 2                                                        04146021
T07OUT2  LA    BNCHREG,T07TJID     SET UP TO PURGE BY TJID              04150020
         BR    LINKREG             RETURN TO CALLER                     04160020
T07OUT   LA    BNCHREG,T07TJRST    ADDR RTN PROCESS PART RESTORED       04170020
         BR    LINKREG             GO TO RTN                            04180020
T07OUT1  LA    BNCHREG,T07TJQSE    ADDR RTN PROCESS PART QUIESCED       04190020
         BR    LINKREG             RETURN TO CALLER                     04200020
         EJECT                                                          04210020
*********************************************************************** 04220020
* CONTROL SECTION FOR PURGE BY TJID                                   * 04230020
*********************************************************************** 04240020
         SPACE                                                          04250020
T07TJID  STM   RTNREG,TJBREG,TWELVE(SAVREG)  SAVE MAINLINE'S REGS       04260020
*                                                                       04260620
* THIS SECTION OF CODE TESTS TO DETERMINE IF SWAP UNIT RECOVERY NEED BE 04261220
* ATTEMPTED                                                             04261820
*                                                                       04262420
           L    CVTREG,CVTPTR            GET TO CVT                     04263020
           USING CVT,CVTREG              BASE FOR CVT                   04263620
           TM   CVTTSFLG,CVTTSRDY        Q: TSO READY?                  04264220
           BZ   T07BNIN                  NO, SKIP SWAP UNIT RECOVERY    04264820
           L    TSCVTREG,CVTTSCVT        GET TO TSCVT                   04265420
           USING TSCVT,TSCVTREG           BASE FOR TSCVT                04266020
           TM   TJBSTAT2,TJBSURSV         Q: SWAP SPACE FREEABLE?       04266620
           BO   T07BNIN                  NO, SKIP SWAP UNIT RECOVERY    04267220
           CLC  TJBTJID,RCBTJID          Q: THIS USER IN CORE?          04267820
           BE   T07BNIN                  YES, NO SWAP UNITS TO RECOVR   04268420
           BAL  LINKREG,T07SUR           RECOVER SWAP UNITS             04269020
T07BNIN  MVI   RCBSWTCH,SWTCHOFF   SW OFF INDICATES SEARCH BY TJID      04270020
QELBNIN  BAL   LINKREG,T07QELP     PURGE QELS                           04280020
TQEBNIN  BAL   LINKREG,T07TQEP     PURGE TQES                           04290020
RQEBNIN  BAL   LINKREG,T07RQEP     PURGE RQES                           04300020
WTORBNIN BAL   LINKREG,T07WTORP    PURGE WTORS                          04310020
IPPBBNIN BAL   LINKREG,T07IPPB     PURGE IPPBS                          04320020
         SPACE 2                                                        04320421
*  ROUTINE TO CHECK IF USERS DEQUEUED QEL IS A SYSTEM KNOWN   AC A47178 04322021
*  MUST COMPLETE RESOURCE.  IF THE RESOURCE IS KNOWN TO THE   AC A47178 04324021
*  SYSTEM AND THE TASK IS SET MUST COMPLETE, THE OPERATOR IS  AC A47178 04326021
*  NOTIFIED.                                                  AC A47178 04328021
         SPACE 2                                                        04328421
         LA    HOLDREG,EIGHT            CRITICAL RES INDICATR AC A47178 04328821
         L     CVTREG,CVTPTR            GET CVT ADDR          AC A47178 04329221
         USING CVT,CVTREG               BASE FOR CVT          AC A47178 04329621
         L     SCVTREG,CVTABEND         GET SCVT ADDR         AC A47178 04329721
         USING SCVTSECT,SCVTREG         BASE FOR SCVT         AC A47178 04329821
         LR    KEEPREG,PARMREG          SAVE CONTENTS REG 1   AC A47178 04329921
         L     MJQCBREG,SCVTQCBO        ADDR DUMMY QCB        AC A47178 04333221
GNXTMAJ  L     MJQCBREG,ZERO(MJQCBREG)  ADDR OF MAJ QCB       AC A47178 04335221
         LA    MJQCBREG,ZERO(MJQCBREG)  CLEAR HI BYTE         AJ A47178 04335321
         LTR   MJQCBREG,MJQCBREG        Q, ANY QCBS           AC A47178 04335621
         BZ    TESTCRIT                 NO, CONT TO PROC      AC A47178 04336021
GNEXTMIN L     MIQCBREG,MINQCB(MJQCBREG) ADDR OF MINOR QCB    AC A47178 04336421
CHKEND   LA    MIQCBREG,ZERO(MIQCBREG)  CLEAR HI BYTE         AJ A47178 04337121
         LTR   MIQCBREG,MIQCBREG        Q, ANY MINOR QCBS     AC A47178 04338621
         BZ    GNXTMAJ                  NO, GET NEXT MAJOR    AC A47178 04339321
         L     QELREG,ZERO(MIQCBREG)    GET TOP QEL           AC A47178 04340021
         USING QELSECT,QELREG           BASE FOR QEL          AC A47178 04341921
CHKQEL   LH    TJIDREG,QELTJID1         GET FIRST HALF TJID   AC A47178 04342321
         IC    TJIDREG,QELTJID2         LAST HALF TJID        AC A47178 04342721
         N     TJIDREG,HIBITOFF         TURN OFF HI BIT TJID  AC A47178 04343121
         CR    TJIDREG,KEEPREG          Q, IS THIS USERS QEL  AC A47178 04343221
         BNE   GNXTQEL                  NO,GET NEXT QEL       AC A47178 04343321
         TM    QELSMC,QELMCM            Q, TASK MUST COMPLETE AC A47178 04346621
         BZ    GNXTMIN                  NO, BR TO CONT PROC   AC A47178 04348621
         CLI   QCBPKF(MIQCBREG),ALL     Q, SYS KNOWN RESOURCE AC A47178 04349021
         BE    CHECKEND                 YES, PREPARE MESSAGE  AC A47178 04349421
GNXTMIN  L    MIQCBREG,NXMIN(MIQCBREG)  GET NEXT MINOR PTR    AJ A47178 04349821
         B    CHKEND                    GO SEE IF ANY MORE    AJ A47178 04351221
         SPACE 2                                                        04354421
GNXTQEL  L     QELREG,ZERO(QELREG)       GET NEXT QEL         AJ A47178 04354821
         LA    QELREG,ZERO(QELREG)      CLEAR HI BYTE         AJ A47178 04355221
         LTR   QELREG,QELREG            IS THERE ONE          AJ A47178 04355621
         BZ    GNXTMIN                  NO-GO GET NEXT MINOR  AJ A47178 04355721
         B     CHKQEL                  YES-SEE IF OUR QEL     AJ A47178 04356121
         SPACE 2                                                        04356721
TESTCRIT LTR   HOLDREG,HOLDREG          Q, ANY RES CRITICAL   AC A47178 04359021
         BZ    QMSGPROC                 YES, DO NOT RESET FLG AC A47178 04360021
         XI    TJBSTAT2,TJBDEAD          TURNOFF NORM DISCONN AC A47178 04360121
         SPACE 3                                              AJ A49808 04360221
**                                                            AJ A49808 04360321
*  PURGE ANY IEAQMESSAGES FOR THIS TJID-REL 21.0 AND ON       AJ A49808 04360421
**                                                            AJ A49808 04360521
         SPACE 3                                                        04360921
QMSGPROC L     MESGREG,CVTPTR      GET CVT ADR                AJ A49808 04361621
         USING CVT,MESGREG                                    AJ A49808 04363621
         L     MESGREG,CVTQMSG     IEAQMESSAGE BUFFERS        AJ A49808 04363721
         DROP  MESGREG                                        AJ A49808 04363821
         L     ENDREG,ZERO(MESGREG) END OF BUFFERS            AJ A49808 04363921
         LA    MESGREG,FOUR(MESGREG)  POINT AT FIRST ENTRY    AJ A49808 04364121
         USING MSGENTRY,MESGREG                               AJ A49808 04364521
MESGPROC CR    ENDREG,MESGREG      ARE WE AT END              AJ A49808 04364621
         BE    QMSGDONE            YES-DONE GET OUT           AJ A49808 04364721
         NC    INFTJID,INFTJID     IS IT A TSO ENTRY          AJ A49808 04364921
         BNZ   TSOENTRY            YES-CHECK TJID MATCH       AJ A49808 04365321
NEXTMESG LA    MESGREG,INFLEN(MESGREG)  NO-GET NEXT ENTRY     AJ A49808 04365721
         B     MESGPROC            GO PROCESS IT              AJ A49808 04365821
TSOENTRY CH    PARMREG,INFTJID     THIS TJID OURS             AJ A49808 04366221
         BNE   NEXTMESG            NO-GO GET NEXT             AJ A49808 04366321
         XC    INFENTRY(INFLEN),INFENTRY  YES-CLEAR ENTRY     AJ A49808 04366421
         B     NEXTMESG            GO GET NEXT                AJ A49808 04366521
         DROP MESGREG                                         AJ A49808 04366621
         SPACE 3                                                        04367021
QMSGDONE BAL   LINKREG,TJIDENDA         FINISH PROC THIS TJID AC A47178 04367621
         LM    RTNREG,TJBREG,TWELVE(SAVREG)   RESTORE REGS              04367721
         BR    RTNREG              RETURN TO CALLER                     04367821
         SPACE 2                                                        04367921
CHECKEND EQU   *                                              AC A47178 04368021
         MVI   QELTJID1,ZERO       ZERO TJID SO FAIL FUTURE TEST A47178 04368121
         MVI   QELTJID2,ZERO       ZERO TJID                  AJ A47178 04368821
         MVC   WORKAR3(MSGLNTH),T07MSG  MOVE MSG EXEC STATMNT AC A47178 04369521
         MVC   WORKAR3+MSGUSRID(EIGHT),TJBUSER MOVE USER ID   AC A47178 04370221
*                                               INTO MESSAGE  AC A47178 04370921
         MVC   WORKAR3+MSGMAJ(EIGHT),TWELVE(MJQCBREG) MAJOR   AC A47178 04371621
*                                               INTO MESSAGE  AC A47178 04372321
         SR    WORK5,WORK5              ZERO REG FOR MIN LNG  AC A47178 04373021
         IC    WORK5,TWELVE(MIQCBREG)   LENGTH OF MINOR NAME  AC A47178 04373721
         C     WORK5,MINAMLNG           Q. AT LEAST 8 CHAR    AC A47178 04374421
         BNH   EXMOVE                   NO, BYPASS LENGTH ADJ AC A47178 04375121
         L     WORK5,MINAMLNG           SET MAX NAME LNG TO 8 AC A47178 04375821
EXMOVE   EX    WORK5,MOVEMIN            MOVE MIN NAME TO MSG  AC A47178 04376621
         SR    ZEROREG,ZEROREG          ZERO                  AC A47178 04378621
         IC    ZEROREG,RCBCONID         CONSOLE ID FOR MSG    AC A47178 04379021
         WTO   MF=(E,WORKAR3)           WRITE CRTICAL RES MSG AC A47178 04379421
         SR    HOLDREG,HOLDREG          IND CRITICAL RES FND  AC A47178 04379821
         B     GNXTMIN                  GET NEXT MINOR        AC A47178 04380021
         SPACE 2                                                        04382121
MOVEMIN  MVC   WORKAR3+MSGMIN(ZERO),FOURTEEN(MIQCBREG)  MOVE  AC A47178 04382521
*                                       MINOR NAME TO MSG     AC A47178 04382921
         SPACE 4                                                        04383321
T07MSG   WTO   'IKJ056I USER ID=         ENQUEUED RESOURCES          , C04388621
                      ',MF=L,MCSFLAG=REG0,ROUTCDE=2,DESC=4              04389021
MSGLNTH  EQU   *-T07MSG                 LENGTH OF MESSAGE     AC A47178 04389421
MSGUSRID EQU   21                       DISP USER ID (TJB)    AC A47178 04389821
MSGMAJ   EQU   49                       DISP MAJOR NAME       AC A47178 04389921
MSGMIN   EQU   59                       DISP MINOR NAME       AC A47178 04390021
         EJECT                                                          04393321
*********************************************************************** 04396821
*    THIS SECTION DETERMINES WHETHER THE USER TO BE PURGED WAS IN THE * 04400121
* MIDDLE OF BEING RESTORED BY THE REGION CONTROL TASK (IKJEAR03).  HOW* 04403421
* MUCH RESTORING R03 HAS COMPLETED CAN BE DETERMINED BY TESTING A BYTE* 04406721
* IN THE REGION CONTROL BLOCK (RCBRSFLG).                             * 04410020
*********************************************************************** 04420020
         SPACE 2                                                        04430020
T07TJRST STM   RTNREG,TJBREG,TWELVE(SAVREG)  SAVE MAINLINE'S REGS       04440020
         USING RCB,RCBREG          BASE FOR RCB                         04450020
         TM    RCBRSFLG,RCBTCBDN   TCB'S BEEN REQUEUED?                 04460020
         BZ    T07BNIN             NO, GO TO OUT OF CORE PROCESSING     04470020
         USING TJB,TJBREG          BASE FOR TJB                         04480020
         L     TJBXREG,TJBEXTNT    GET TJBX ADDR                        04490020
         USING TJBX,TJBXREG        BASE FOR TJBX                        04500020
         L     TJBFSTRG,TJBXFST    ADDR USER'S FIRST TCB                04510020
         LTR   TJBFSTRG,TJBFSTRG   IS THERE A FIRST                     04512020
         BZ    T07BNIN             NO BR TO PURGE BY TJID ONLY          04514020
         L     LASTREG,TJBXLAST    ADDR USER'S LAST TCB                 04520020
         L     FRSTREG,RCBRCT      RCT'S TCB ADDR                       04530020
         USING TCB,FRSTREG         TEMPORARY TCB BASE                   04540020
         XC    TCBLTC(WORD),TCBLTC CLEAR RCT'S DAUGHTER POINTER         04542020
SRCHAGIN L     TCBREG,TCBTCB       ADDR NEXT TCB                        04550020
         CR    TCBREG,TJBFSTRG     THIS TCB BELONG TO USER?             04560020
         BE    FOUND               YES, PROCESS IT                      04570020
         CR    TCBREG,LASTREG      IS THIS LAST TCB                     04572020
         BE    T07BNIN             YES PURGE BY TJID ONLY               04574020
         LR    FRSTREG,TCBREG      SAVE PREVIOUS TCB ADDR               04580020
         B     SRCHAGIN            CONTINUE SEARCH                      04590020
FOUND    MVC   TCBTCB(WORD),TCBNXT(LASTREG)  DEQUEUE TCBS               04600020
         NI    RCBRSFLG,ALLFLAG-RCBTCBDN TURN OFF BIT INDICATING TCB'S  04602020
*                                  ARE ON THE READY QUEUE               04604020
         DROP  FRSTREG             DROP TEMPORARY TCB BASE              04610020
         TM    RCBRSFLG,RCBQELCM   QEL'S BEEN RESTORED?                 04620020
         BO    QELDONE             YES, SET UP FOR QEL RTN              04630020
         MVI   RCBSWTCH,SWTCBOTH   SEARCH BOTH BY TCB AND TJID          04640020
         B     QELBNIN             GO TO QEL CLEAN UP                   04650020
QELDONE  MVI   RCBSWTCH,SWITCHON   INDICATE SEARCH BY TCB               04660020
         BAL   LINKREG,T07QELP     GO CLEAN UP QELS                     04670020
         TM    RCBRSFLG,RCBTQECM   TQE'S BEEN RESTORED?                 04680020
         BO    TQEDONE             YES, SET UP FOR TQE RTN              04690020
         MVI   RCBSWTCH,SWTCBOTH   SEARCH BOTH BY TCB AND TJID          04700020
         B     TQEBNIN             GO CLEAN UP TQES                     04710020
TQEDONE  BAL   LINKREG,T07TQEP     GO TO TQE PROCESSING                 04720020
         TM    RCBRSFLG,RCBRQIQC   RQE'S AND IQE'S BEEN RESTORED?       04730020
         BO    RQIQDONE            YES, SET UP FOR RQE & IQE RTNS       04740020
         MVI   RCBSWTCH,SWTCBOTH   SEARCH BOTH BY TCB AND TJID          04750020
         BAL   LINKREG,T07RQEP     GO CLEAN UP RQE'S                    04760020
         BAL   LINKREG,T07IQEP     CLEAN UP IQE'S                       04770020
         B     WTORBNIN            CONTINUE PROCESSING                  04780020
RQIQDONE BAL   LINKREG,T07RQEP     GO TO PURGE RQES                     04790020
         BAL   LINKREG,T07IQEP     PURGE USER'S IQES                    04800020
         TM    RCBRSFLG,RCBIORSC   I/O RESTORED?                        04810020
         BZ    WTORBNIN            NO, GO TO REMOVE WTOR CB'S           04820020
         BAL   LINKREG,T07IOPRG    YES, MUST QUIESCE IT                 04830020
         TM    RCBRSFLG,RCBWTORC   WTOR BLOCKS RESTORED?                04840020
         BO    WTORDONE            YES, PURGE THEM                      04850020
         MVI   RCBSWTCH,SWTCBOTH   SEARCH BY BOTH TCB PD AND TJID       04860020
         B     WTORBNIN            GO TO T07TJID ROUTINE                04870020
WTORDONE BAL   LINKREG,T07WTORP    GO PURGE WTOR BLOCKS                 04880020
         TM    RCBRSFLG,RCBTACMP   TA RESTORED?                         04890020
         BZ    IPPBBNIN            FINISH UP PURGE                      04900020
         BAL   LINKREG,T07TAP      GO PURGE TRANS AREAS                 04910020
         B     IPPBBNIN            FINISH PURGING USER                  04920020
         EJECT                                                          04930020
*********************************************************************** 04940020
*    THIS SECTION DETERMINES WHETHER THE USER TO BE PURGED WAS IN THE * 04950020
* MIDDLE OF BEING QUIESCED BY THE REGION CONTROL TASK (IKJEAR02).  HOW* 04960020
* MUCH QUIESCING R02 HAS COMPLETED CAN BE DETERMINED BY TESTING A BYTE* 04970020
* IN THE REGION CONTROL BLOCK (RCBQUFLG).                             * 04980020
*********************************************************************** 04990020
         SPACE 2                                                        05000020
T07TJQSE STM   RTNREG,TJBREG,TWELVE(SAVREG)  SAVE CALLER'S REGS         05010020
         USING RCB,RCBREG          BASE FOR RCB                         05020020
         TM    RCBQUFLG,RCBIOSTR   I/O PURGE STARTED?                   05030020
         BO    CHECKTA             YES, CHECK TA PURGE                  05040020
MARKNOND L     TJBXREG,TJBEXTNT    NO, MARK USER TASKS NON-DISP         05040620
         USING TJBX,TJBXREG        BASE FOR TJBX                        05041220
         L     TCBREG,TJBXFST      GET USERS TOP TCB                    05041820
         L     WORK4,TJBXLAST      GET USERS LAST TCB                   05042420
         USING TCB,TCBREG          BASE FOR TCB                         05043020
SETFLAG  OI    TCBFLGS5,TCBPNDSP   SET PRIMARY NON-DISP BIT             05043620
         OI    TCBNDSP1,PNONDISP   SET SECONDARY PERM NON-DISP BIT      05044220
*                                  TO ENSURE TASK NEVER DISPATCHED      05044820
         L     CVTREG,CVTPTR       ADDRESS OF CVT                 21008 05045221
         USING CVT,CVTREG          SET UP ADDRESSABILITY          21008 05045321
         TM    CVTDCB,CVT4MS1+CVT4MPS IS THIS AN MP SYSTEM        21008 05046721
         BNO   NOTMP               NO TAKE BRANCH                 21008 05048521
         STM   RTNREG,BNCHREG,WORKAREA SAVE REGS TEMPORARILY      21008 05048621
         L     R15,MPCVTPTR        POINTER TO MPCVT               21008 05048721
         L     R15,CVTTKRM(R15)    ADR OF TASK REMOVE RTN         21008 05048821
         BALR  RTNREG,BNCHREG      GO TO TASK REMOVE              21008 05048921
         LM    RTNREG,BNCHREG,WORKAREA RESTORE REGISTERS          21008 05049221
NOTMP    EQU   *                                                  21008 05049721
         CR    TCBREG,WORK4        Q: LAST USER TCB PROCESSED?          05050021
         BE    ENDNOND             YES, EXIT FROM LOOP                  05050221
         L     TCBREG,TCBTCB       GET NEXT USER TCB                    05051621
         B     SETFLAG             CONTINUE NON-DISP PROCESSING         05053021
         DROP  TCBREG                                                   05054421
         DROP  TJBXREG                                                  05055821
ENDNOND  EQU   *                                                        05057221
         BAL   LINKREG,T07IOPRG    GO TO START I/O QUIESCE              05058621
CHECKTA  TM    RCBQUFLG,RCBTADON   TA BEEN PURGED FOR USER?             05060020
         BO    TESTWTOR            YES, CHECK WTOR PURGE                05070020
         BAL   LINKREG,T07TAP      GO PURGE TRANSIENT AREAS             05080020
TESTWTOR TM    RCBQUFLG,RCBWTORD   WTOR BLOCKS PURGED?                  05090020
         BZ    PRGWTOR             NO, GO SET SWITCH                    05100020
         MVI   RCBSWTCH,SWTCHOFF   SET SWITCH TO PURGE BY TJID          05110020
         BAL   LINKREG,T07WTORP    GO TO PURGE WTOR BLOCKS              05120020
           B    TESTQEL                  GO CHECK QEL PURGE             05130020
PRGWTOR  MVI   RCBSWTCH,SWTCBOTH   PURGE BY TCB AND TJID                05140020
         B     WTORIN              GO TO PURGE REST OF CB'S             05150020
TESTQEL  TM    RCBQUFLG,RCBQELDN   QEL'S PURGED?                        05242020
         BZ    PRGQEL              NO, GO SET SWITCH                    05244020
         BAL   LINKREG,T07QELP     GO TO PURGE QELS                     05246020
         B     TESTQE              CHECK IO PURGE                       05248020
PRGQEL   MVI   RCBSWTCH,SWTCBOTH   PURGE BY TCB AND TJID                05248420
         B     QELIN               GO TO PURGE REST OF CB'S             05248820
TESTQE   TM    RCBQUFLG,RCBTQEDN   TQE'S PURGED?                        05250020
         BZ    PRGTQE              NO, GO SET SWITCH                    05260020
         BAL   LINKREG,T07TQEP     PURGE TQES                           05270020
         B     TESTRQE             CHECK RQE'S                          05280020
PRGTQE   MVI   RCBSWTCH,SWTCBOTH   SEARCH BY TJID AND TCB ADDR          05290020
         B     TQEIN               GO TO PURGE REST OF CB'S             05300020
TESTRQE  TM    RCBQUFLG,RCBRQIQD   RQES AND IQES QUIESCED?              05310020
         BZ    PRGRQIQE            NO, GO SET SWITCH                    05320020
         BAL   LINKREG,T07RQEP     PURGE RQES BY TJID                   05330020
         B     IPPBBNIN            GO FINISH PROCESSING                 05340020
PRGRQIQE MVI   RCBSWTCH,SWTCBOTH   SEARCH BY TCB AND TJID               05350020
         B     RQEIQEIN            GO PURGE RQE'S AND IQE'S             05360020
FREETCBS L     TJBXREG,TJBEXTNT    ADDR TJBX                            05370020
         USING TJBX,TJBXREG        BASE FOR TJBX                        05380020
         L     TJBFSTRG,TJBXFST    ADDR USER'S TOP TCB                  05390020
         L     WORK4,TJBXLAST      ADDR USER'S LAST TCB                 05400020
         L     TCBREG,RCBRCT       ADDR RCT'S TCB                       05410020
         USING TCB,TCBREG          TEMPORARY BASE FOR TCB               05420020
         XC    TCBLTC(WORD),TCBLTC CLEAR DAUGHTER PTR                   05430020
TCBNEXT  LR    R15,TCBREG          SAVE TCB ADR                         05432020
         L     TCBREG,TCBTCB       ADDR NEXT TCB                        05440020
         LTR   TCBREG,TCBREG       TCB'S DEQUEUED ALREADY?              05450020
         BZ    NOTCBS              YES, CONTINUE OTHER PROCESSING       05460020
         CR    TJBFSTRG,TCBREG     THIS USER'S TCB?                     05470020
         BNE   TCBNEXT             NO, CHECK NEXT TCB                   05480020
         MVC   TCBNXT(WORD,R15),TCBNXT(WORK4) DEQUEUE TCB'S             05490020
NOTCBS   B     IPPBBNIN            GO COMPLETE PURGE PROCESSING         05510020
             SPACE  4                                                   05520020
*********************************************************************** 05530020
* CONTROL SECTION USED AFTER DETERMINED MUST PURGE REST BY TCB ADDR   * 05540020
*********************************************************************** 05550020
         SPACE                                                          05560020
WTORIN   BAL   LINKREG,T07WTORP    GO PURGE WTOR CB'S                   05570020
         MVI   RCBSWTCH,SWITCHON   PURGE REST BY TCB ADDR               05620020
QELIN    BAL   LINKREG,T07QELP     PURGE QELS                           05622020
         MVI   RCBSWTCH,SWITCHON   PURGE REST BY TCB ADDR               05624020
TQEIN    BAL   LINKREG,T07TQEP     PURGE TQES                           05630020
         MVI   RCBSWTCH,SWITCHON   PURGE REST BY TCB ADDR               05640020
RQEIQEIN BAL   LINKREG,T07RQEP     PURGE RQES                           05650020
         BAL   LINKREG,T07IQEP     PURGE IQES                           05660020
         B     FREETCBS            GO REMOVE TCBS                       05670020
         EJECT                                                          05680020
*********************************************************************** 05690020
* THIS ROUTINE PURGES QELS, MAJOR AND MINOR QCB'S ASSOCIATED WITH THE * 05700020
* USER                                                                * 05710020
*     LINKREG (REG 9) CONTAINS THE RETURN ADDR                        * 05720020
*     PARMREG (REG 1) CONTAINS THE TJID OF THE USER TO BE PURGED      * 05730020
*********************************************************************** 05740020
         SPACE 4                                                        05750020
T07QELP  L     CVTREG,CVTPTR       GET CVT ADDR                         05760020
         USING CVT,CVTREG          BASE FOR CVT                         05770020
         L     SCVTREG,CVTABEND    GET SCVT ADDR                        05780020
         USING SCVTSECT,SCVTREG    BASE FOR SCVT                        05790020
         LR    KEEPREG,PARMREG     SAVE CONTENTS REG1                   05810020
         L     MJQCBREG,SCVTQCBO   ADDR DUMMY QCB                       05820020
GETMAJ   L     MJQCBREG,ZERO(MJQCBREG)  ADDR FIRST MAJOR QCB            05830020
NEXTMAJ  LTR   MJQCBREG,MJQCBREG   ARE THERE ANY QCB'S?                 05840020
         BZ    QELPEND             NO, RETURN TO CALLER                 05850020
         L     MIQCBREG,MINQCB(MJQCBREG) GET ADDR MINOR QCB             05860020
         LTR   MIQCBREG,MIQCBREG   IS THERE A MINOR QCB?                05870020
         BZ    FREEMAJR            NO, DEQUEUE AND FREE MAJOR QCB       05880020
GETQEL   L     QELREG,ZERO(MIQCBREG)    GET QEL                         05890020
         SR    WORK5,WORK5         INIT SWITCH REG                      05892020
         LR    R14,BASEREG        INITIALIZE SWITCH REG   - POS         05896020
         USING QELSECT,QELREG      BASE FOR QEL                         05900020
CHCKSRCH TM    RCBSWTCH,SWTCBOTH   CHECK QEL BY TCB ADDR AND TJID       05910020
         BM    TCBSRCH             GO FIND QELS BY TCB ADDR             05940020
         SPACE 4                                                        05960020
TJIDSRCH LH    TJIDREG,QELTJID1    GET FIRST HALF TJID FOR COMPARE      05970020
         IC    TJIDREG,QELTJID2    LAST HALF TJID                       05980020
         N     TJIDREG,HIBITOFF    TURN OFF HI BIT TJID                 05990020
         CR    TJIDREG,KEEPREG     THIS QEL BELONG TO USER?             06000020
         BE    CHKFRST             YES, REMOVE QEL AND FREE             06010020
         TM    RCBSWTCH,SWTCBOTH   Q: TJID AND TCB SEARCH               06020020
         BO    TCBSRCH             YES-BOTH - CHECK TCB'S               06022020
FINTEST  EQU   *                                                        06022320
         TM    QELCODE,SHARED     THIS QEL SHARED?                      06022620
         BO    TOPNOT             YES, CONTINUE                         06022920
         O     R14,MASKFULL       NO, EXCLUSIVE, SET SW REG NEG         06023220
TOPNOT   EQU   *                                                        06023520
         L     WORK5,HIBITOFF      INDICATE TOP QEL NOT PURGED          06024020
         SPACE 4                                                        06030020
ANOTRQEL L     QELREG,QELNQEL      GET ADDR NEXT QEL                    06050020
         LA    QELREG,ZERO(QELREG) ZERO HI ORDER BYTE                   06060020
NEXTQEL  LTR   QELREG,QELREG       IS THERE A NEXT QEL?                 06070020
         BZ    TESTMINR            NO, SEE IF MINOR CAN BE FREED        06080020
         TM    QELTJID1,SET        ANY BITS ON                          06090020
         BZ    NOTTSQEL            NO, QEL DOES NOT BELONG TO TS USER   06100020
         C     WORK5,HIBITOFF     THIS QEL OWN RESOURCE?      AJ A58556 06120021
         BE    CHCKSRCH            NO,RESOURCE NOT AVIALABLE  AJ A58556 06140021
         LH    ZEROREG,QELTJID1   PICK UP USER                          06160020
         IC    ZEROREG,QELTJID2       TJID FROM QEL                     06180020
         N     ZEROREG,HIBITOFF   CLEAR TSO INDICATOR                   06200020
         CR    KEEPREG,ZEROREG    TJID MATCH?                 AJ A58556 06220021
         BE    CHCKSRCH            YES, DETERMINE HOW SEARCH            06240020
*                                  FLAG QEL FOR SVRB PROCESSING         06270020
TSROLLIN OI    QELCODE,QELRBWT     AFTER SWAP IN                        06280020
         TSEVENT USERRDY,TJID=(0)  TELL TS DRIVER USER READY TO RUN     06340020
         B     ANOTRQEL            LOOK AT NEXT QEL                     06350020
         SPACE 3                                                        06360020
NOTTSQEL TM    RCBSWTCH,SWTCBOTH   Q: TCB AND TJID CHECK                06362020
         BZ    NOTCB               TJID ONLY SEARCH DONE                06364020
         LA    BNCHREG,NOTCB1     SET RET PT                            06366020
         B     TCBSRCH1           DO TCB SEARCH                         06368020
NOTCB    C     WORK5,HIBITOFF      PARM SET - THIS NOT TOP QEL          06370020
         BNE   CONTA              TOP, CONTINUE                         06371020
NOTCB1   EQU   *                                                        06372020
         TM    QELCODE,SHARED     THIS QEL SHARED?                      06373020
         BO    DECTEST            YES, TEST SWITCH REG                  06374020
         LTR   R14,R14            TEST FOR EXCLUSIVE TRAP               06375020
         BM   ANOTRQEL            YES, EXCLUSIVE(S) ABOVE, GET NEXT     06376020
         SR    R14,R14            INDICATE EXCLUSIVE DEQUED             06377020
         B     DECRSVRB           ALLOW WAITING USER ACCESS TO          06378020
*                                    RESOURCE                           06379020
DECTEST  EQU   *                                                        06380020
         LTR   R14,R14            CAN SHARE COME OUT OF WAIT?           06381020
         BNZ   ANOTRQEL           NO, GET NEXT                          06382020
         B     DECRSVRB           YES, ALLOW USE OF RESOURCE            06383020
CONTA    EQU   *                                                        06384020
         LTR   WORK5,WORK5         REMOVED QEL SHARED                   06390020
         BNL   TESTCODE            NO, EXCLUSIVE                        06400020
         TM    QELCODE,SHARED      THIS QEL SHARED                      06410020
         BO    DECTEST            SEE IF USER CAN COME OUT OF WAIT      06420020
         L     WORK6,ZERO(MIQCBREG) GETMINOR QCB PTR                    06432020
         LA    WORK6,ZERO(WORK6)   CLEAR HI ORDER BYTE TJID             06434020
         CR    QELREG,WORK6        THIS TOP QEL NOW                     06436020
         BNE   NOTTOP              NO, GET NEXT QEL                     06440020
         B     SETBIT              YES, SET BIT AND PROCESS QEL         06442020
         SPACE 4                                                        06470020
TESTCODE TM    QELCODE,SHARED      THIS QEL SHARED                      06480020
         BO    DECRSVRB            YES, DECREMENT SVRB                  06490020
         L     WORK6,ZERO(MIQCBREG) GETMINOR QCB PTR                    06502020
         LA    WORK6,ZERO(WORK6)   CLEAR HI ORDER BYTE TJID             06504020
         CR    QELREG,WORK6        THIS TOP QEL NOW                     06506020
         BNE   NOTTOP              NO, SET BIT AND CHECK NEXT QEL       06510020
SETBIT   L     WORK5,HIBITOFF      INDICATE NEW TOP PROCESSED           06520020
         O     R14,MASKFULL       MAKE R14 NEG, EXCLUSIVE FOUND,        06523020
*                                    REMAINING MUST WAIT                06526020
         SPACE 4                                                        06530020
*********************************************************************** 06540020
* A WAIT COUNT OF ZERO INDICATES THE TASK REPRESENTED BY THIS SVRB IS * 06550020
* BEING ABENDED.  IN THIS CASE DO NOT DECREMENT THE WAIT COUNT        * 06560020
*********************************************************************** 06570020
         SPACE 2                                                        06580020
DECRSVRB L     PARMREG,QELSVRB     GET SVRB FOR QEL                     06590020
         USING RBSECT,PARMREG      BASE FOR RB                          06600020
         CLI   RBWCF,ZERO          IS WAIT COUNT ZERO                   06610020
         BE    ANOTRQEL            YES, DO NOT DECREMENT                06620020
         IC    WORK6,RBWCF         GET WAIT COUNT                       06630020
         BCTR  WORK6,ZEROREG       DECREMENT COUNT                      06640020
         STC   WORK6,RBWCF         RESTORE NEW COUNT                    06650020
         TM    QELCODE,RESERVED    IS IT A RESERVE REQUEST              06660020
         BZ    ANOTRQEL            NO                                   06670020
         L     TCBREG,QELTCB       GET TCB PTR FROM QEL                 06680020
         L     TCBREG,CURPRG(TCBREG) GET PARM PTR IN TCB                06690020
         ST    TCBREG,QELSVRB      SET UCB PTR IN QEL                   06700020
         ST    R14,WORKAREA       SAVE SW REG                           06705020
      IC    COUNT,UCBRSCT(WORK6)          GET CURRENT UCB RESERVE CT    06710020
      LA    COUNT,ONE(COUNT)              INCREMENT RESERVE CT          06720020
      STC   COUNT,UCBRSCT(WORK6)          SAVE NEW COUNT                06730020
         L     R14,WORKAREA       RESTORE SW REG                        06740020
         B     ANOTRQEL            PICK UP NEXT TO CHECK                06750020
NOTTOP  EQU   *                                                         06752020
         O     R14,MASKFULL       SET R 14 NEG - EX QEL ENCOUNTERED     06754020
         L     WORK5,HIBITOFF     INDICATE TOP NOT PROCESSED            06756020
         B     ANOTRQEL           GET NEXT QEL                          06758020
         SPACE 3                                                        06760020
CHKFRST  L     WORK6,ZERO(MIQCBREG) GET TOP QEL PTR FROM MINOR QCB      06782020
         LA    WORK6,ZERO(WORK6)   CLEAR HI ORDER TJID BYTE             06784020
         CR    WORK6,QELREG        IS IT TOP QEL WE ARE DEQUEUING       06786020
         BNE   SETPARM             NO,JUST DEQUEUE,AND FREE IT          06788020
         TM    QELSMC,QELMCM       Q. TASK SET MUST COMP      AC A47178 06788421
         BZ    RESQEL              NO, CHECK IF RESERVED      AC A47178 06788821
         CLI   QCBPKF(MIQCBREG),ALL Q. SYSTEM KNOWN RESOURCE  AC A47178 06789221
         BNE   RESQEL              NO, CHECK IF RESERVED      AC A47178 06789621
         XC    QELTCB+1(3),QELTCB+1     ZERO QEL TCB FIELD    AC A47178 06789721
         XC    QELSVRB+1(3),QELSVRB+1   ZERO QEL SVRB FIELD   AC A47178 06789821
         STC   KEEPREG,QELTJID2   SAVE TJID MAY BE IN CORE    AJ A47178 06791821
         B     ANOTRQEL            GET NEXT QCB,  DONT DEQUE  AC A47178 06792321
RESQEL   EQU   *                                              AC A47178 06795021
         TM    QELCODE,RESERVED    Q. THIS QEL RESERVE QEL    AC A47178 06797521
         BZ    TESTTYPE            NOT RESERVED, GO DEQUEUE AND FREE    06800020
         L     WORKREG,QELSVRB     GET ADDR UCB FOR DEVICE RESERVED     06820020
         SR    PARMREG,PARMREG     INIT REG                             06830020
         IC    PARMREG,UCBRSCT(WORKREG) GET CURRENT UCB RESERVE COUNT   06840020
         LTR   PARMREG,PARMREG     IS COUNT ZERO                        06842020
         BZ    ZEROCT              YES SKIP DECREMENT                   06844020
         BCTR  PARMREG,ZEROREG     DECREMENT AND                        06850020
         STC   PARMREG,UCBRSCT(WORKREG) SAVE NEW COUNT                  06860020
         LTR   PARMREG,PARMREG     IF ZERO MUST RELEASE DEVICE          06870020
         BNZ   TESTTYPE            NOT ZERO, CONTINUE PROCESSING        06880020
ZEROCT   CLI   RESINDIC(WORKREG),ZERO        DEVICE RESERVED            06890020
         BZ    TESTTYPE            NOT RESERVED                         06900020
         EJECT                                                          06910020
*********************************************************************** 06920020
*  THE FOLLOWING CODE MUST BE MAINTAINED AND UPDATED ANY TIME THE     * 06930020
*  RELEASE EXCP ROUTINE IN ENQ/DEQ (IEAENQ) IS ALTERED                * 06940020
* FUNCTION                                                            * 06950020
*         1. GET LENGTH OF DCB BYTES FROM SUBPOOL 0                   * 06960020
*                                                                     * 06970020
*         2. INITIALIZE A DEB, DCB, IOB, ECB AND CHANNEL PROGRAM IN   * 06980020
*            SUBPOOL 0                                                * 06990020
*                                                                     * 07000020
*         3. ISSUE AN SVC 0 TO CAUSE A DEVICE RELEASE                 * 07010020
*                                                                     * 07020020
*         4. WAIT FOR RELEASE TO COMPLETE                             * 07030020
*                                                                     * 07040020
*         5. FREE CORE FROM SUBPOOL 0                                 * 07050020
*                                                                     * 07060020
* INPUT                                                               * 07070020
*                                                                     * 07080020
*         PTR TO UCB OF DEVICE REQUIRING A RELEASE IN REG 2           * 07090020
*                                                                     * 07100020
*********************************************************************** 07110020
         SPACE 4                                                        07120020
         STM   RTNREG,RCBREG,QELPRGSA   SAVE REGS FOR THIS RTN          07130020
         NI    QELCODE,RSVDOFF     TURN OFF RESERVED BIT                07184020
         LA    RLSEREG,QELRELS     SET DCB ADDR FOR RELEASE             07194020
         USING RLDCB,RLSEREG       BASE FOR DSECT                       07210020
         XC    ZERO(RLDCBLN,RLSEREG),ZERO(RLSEREG) LENGTH TO FREE       07220020
         MVI   DENEXT,EXTNMBR      SET NUMBER OF EXTENTS                07230020
         ST    RLSEREG,DEDCBAD     POINT DEB TO DCB                     07240020
         MVI   DEPKID,DEBKEY       SET DEB ID                           07250020
         MVZ   DEPKID,RCBPKEY      SET DEB PROTECT KEY                  07260020
         L     CVTREG,CVTPTR       GET CVT ADDRESS                      07270020
         USING CVT,CVTREG          CVT BASE                             07280020
         L     CVTREG,CVTXAPG      ADDR IOS APPENDAGE TABLE             07290020
         ST    CVTREG,DEAPPAD      SAVE IN TABLE PTR SLOT               07300020
         MVI   DEEXTSCL,DESIZE     SET SIZE OF EXTENTS                  07310020
         ST    UCBREG,DEUCBAD-TWO  SET PTR TO UCB                       07320020
         MVI   DEFM,FILEMASK       SET FILE MASK                        07330020
         MVC   DEBB(TWO),UCBSKA+ONE(UCBREG)                             07340020
         XC    DESTART(FOUR),DESTART INIT START CCHH TO ZEROS           07350020
         MVI   DEEND,SET           INIT END C TO 'FF'                   07360020
         MVC   DEEND+ONE(THREE),DEEND PROPAGATE 'FF' TO REMAINING CHH   07370020
         LA    WORK3,ONE           SET NO. ALLOCATED TRACKS TO 1        07380020
         STH   WORK3,DETRKS        STORE IN DEB                         07390020
* INITIALIZE IOB                                                        07400020
         MVI   IOBFL1,FLAG01       SET IOB                              07410020
         MVI   IOBFL2,FLAG00       FLAGS                                07420020
         ST    RLSEREG,IOBECBAD    SET ADDRESS OF ECB                   07430020
         LA    WORK3,RLCCW         GET ADDR OF CHANNEL PROGRAM          07440020
         ST    WORK3,IOBSTART      POINT IOB TO CHANNEL PROGRAM         07450020
         ST    RLSEREG,IOBDCBAD    POINT IOB TO DCB                     07460020
         XC    IOBMOD(EIGHT),IOBMOD  CLEAR FIELDS                       07461020
         MVC   IOBSK(FOUR),UCBSKA+ONE(UCBREG) MOVE IN SEEK AD FROM UCB  07462020
* INITIALIZE DCB                                                        07463020
         LA    WORK3,DEAPGV        GET ADDR OF DEB                      07464020
         ST    WORK3,DCBDEBAD      POINT DCB TO DEB                     07465020
* INITIALIZE CHANNEL PROGRAM                                            07470020
         MVI   RLCCW,NOPCC         NOP COMMAND CODE                     07480020
         MVI   RLCCW+FOUR,LNTH     SUPPRESS INCORRECT LENGTH INDICATOR  07490020
         MVI   RLCCW+SEVEN,IDENT   IDENTIFICATION  NORMALLY COUNT       07500020
         LA    PARMREG,RLIOB       SET UP FOR EXCP                      07510020
         SVC   0                   ISSUE EXCP SVC                       07524020
         LA    PARMREG,RLECB       PUT ADR ECB IN REG 1                 07530020
         WAIT  ONE,ECB=(1)         ISSUE WAIT                           07550420
         SSM   DISABLE                                                  07552020
         LM    RTNREG,RCBREG,QELPRGSA  RESTORE REGS                     07590020
         USING QELSECT,QELREG      BASE FOR QEL                         07600020
         SPACE 2                                                        07610020
*********************************************************************** 07620020
* SET UP REG 5 AS INDICATOR QEL SHARED OR EXCLUSIVE                   * 07630020
*********************************************************************** 07640020
         SPACE                                                          07650020
TESTTYPE LR    WORK5,QELREG        SET UP FOR TEST                      07660020
         TM    QELCODE,SHARED      QEL SHARED                           07670020
         BZ    SETR14             NO, EXCLUSIVE, SET SW AND REMOVE      07676020
*                                 QEL                                   07682020
         LCR   WORK5,QELREG        INDICATE QEL SHARED                  07690020
         B     REMFRQEL            GO TAKE OFF QUEUE AND FREE           07700020
SETR14   EQU   *                                                        07702020
         SR    R14,R14            SET TO ZERO - IND EX QEL DEQUEUED     07704020
         B     REMFRQEL           GO DEQ QEL                            07706020
SETPARM  EQU   *                                                        07707020
         TM    QELCODE,SHARED     THIS QEL SHARED?                      07708020
         BO    SETR5              YES, CONTINUE                         07709020
         LTR   R14,R14            TEST SW REG                           07710020
         BNH   SETR5              0 OR NEG BRANCH - MEANS EXCLUSIVE     07711020
*                                 ENCOUNTERED                           07712020
         SR    R14,R14            SET TO ZERO - INDICATE EXCLUSIVE      07713020
*                                 DEQUEUED                              07714020
SETR5    EQU   *                                                        07715020
         L     WORK5,HIBITOFF     THIS QEL NOT TOP                      07716020
         SPACE 4                                                        07720020
REMFRQEL LR    PARMREG,QELREG      SET UP REG FOR DEQ RTN               07730020
         L     QELREG,QELNQEL      GET ADDRESS NEXT QEL                 07740020
         LA    QELREG,ZERO(QELREG) ZERO HI ORDER BYTE                   07750020
         ST    R14,WORKAREA       SAVE SW REG                           07755020
         BAL   RTNREG,DQELEMNT     GO TO DEQUEUE QEL                    07760020
         LA    ZEROREG,QELSIZE     SIZE OF QEL FOR FREEMAIN             07770020
         L     R14,WORKAREA        RELOAD SWITCH REG    MP/TSO AJ M3009 07772021
         BAL   R6,FREELMNT         GO FREE ELEMENT      MP/TSO AJ M3009 07780021
         B     NEXTQEL             GO PICK UP NEXT QEL                  07790020
         SPACE 4                                                        07800020
FREEMAJR LR    PARMREG,MJQCBREG    ADDR MAJOR QCB                       07810020
         BAL   RTNREG,DQELEMNT     LINK TO DEQUEING RTN                 07820020
         LA    ZEROREG,MAJSIZE     GET SIZE OF QCB FOR FREEMAIN         07830020
         L     MJQCBREG,ZERO(MJQCBREG)  GET ADDR NEXT QCB               07840020
         LA    R6,NEXTMAJ          RETURN POINT                         07850020
         B     FREELMNT            GO TO FREE ELEMENT                   07860020
         SPACE 5                                                        07870020
TCBSRCH  LA    BNCHREG,ANOTRQEL    SET UP TO CONTINUE SEARCH            07872020
TCBSRCH1 L     TJBXREG,TJBEXTNT    GET ADDR TJBX                        07880020
         USING TJBX,TJBXREG        BASE FOR TJBX                        07890020
         L     TCBREG,TJBXFST      ADDR USER'S FIRST TCB                07900020
         USING TCB,TCBREG          BASE FOR TCB                         07910020
CMPRADDR C     TCBREG,QELTJID1     DOES THIS QEL BELONG THIS USER?      07920020
         BE    CHKFRST             YES, REMOVE QEL AND FREE             07930020
         C     TCBREG,TJBXLAST     USER'S LAST TCB?                     07940020
         BE    TCBSDONE            YES                                  07950020
         L     TCBREG,TCBTCB       ADDR NEXT TCB                        07960020
         B     CMPRADDR            CHECK NEXT TCB                       07970020
TCBSDONE EQU   *                                                        07974020
         TM    QELCODE,SHARED     THIS QEL SHARED?                      07978020
         BO    TCBSDON2           YES, CONTINUE                         07982020
         C      WORK5,HIBITOFF     IS THIS TOP QEL            AJ A58556 07984021
         BNE    TCBSDON2           YES,DO NOT SET INDICATOR   AJ A58556 07984421
         O     R14,MASKFULL       SET R14 NEG - EX QEL ENCOUNTERED      07986020
TCBSDON2 EQU   *                                                        07990020
         LTR   WORK5,WORK5        REMOVED QEL SHARED?                   07994020
         BCR   4,BNCHREG          YES, RETURN, DO NOT RESET R5          07998020
         L     WORK5,HIBITOFF     INDICATE TOP NOT PURGED               08002020
         BR    BNCHREG            RETURN                                08006020
         SPACE 4                                                        08010020
TESTMINR SR    ZEROREG,ZEROREG     CLEAR FOR TEST                       08020020
         LR    PARMREG,MIQCBREG    SET UP FOR POSSIBLE FREEMAIN         08030020
         L     WORK6,ZERO(MIQCBREG) GETMINOR QCB PTR                    08042020
         LA    WORK6,ZERO(WORK6)   CLEAR HI ORDER BYTE TJID             08044020
         CR    ZEROREG,WORK6       IS THERE A QEL                       08046020
         L     MIQCBREG,NXMIN(MIQCBREG)  ADDR NEXT MINOR QCB            08050020
         BNE   NEXTMINR            YES, CAN'T FREE MINOR                08060020
         BAL   RTNREG,DEQMINOR     DEQUEUE MINOR                        08070020
         LA    WORKREG,ELEVEN(PARMREG)   MINOR ADDR PLUS 11             08080020
         BAL   RTNREG,MINORSZE     DETERMINE MINOR SIZE                 08090020
         LR    ZEROREG,SIZEREG     SIZE FOR FREEMAIN                    08100020
         BAL   R6,FREELMNT         FREE MINOR                           08110020
NEXTMINR EQU   *                                                   4640 08115020
        LA    MIQCBREG,ZERO(MIQCBREG) CLEAR HI BYTE                4640 08120020
        LTR   MIQCBREG,MIQCBREG   IS THERE A MINOR?                4640 08125020
         BNZ   GETQEL              YES, GET NEXT QEL                    08130020
         SR    ZEROREG,ZEROREG     CLEAR REG FOR COMPARE                08132020
         CL    ZEROREG,NXMIN(MJQCBREG) DOES MAJOR POINT TO A MINOR      08134020
         BNE   GETMAJ              YES, GET NEXT MAJOR                  08150020
         B     FREEMAJR            NO, FREE MAJOR                       08160020
         EJECT                                                          08170020
*********************************************************************** 08180020
* ROUTINE FOR DEQUEUEING QELS AND MAJOR QCBS                          * 08190020
*   REGISTERS USED - WORKREG (REG 2) WORK REGISTER                    * 08200020
*                    PARMREG (REG 1) ADDR ELEMENT TO BE DEQUEUED      * 08210020
*                    RTNREG (REG 14) RETURN ADDRESS                  *  08220020
*********************************************************************** 08230020
         SPACE 4                                                        08240020
DQELEMNT L     WORKREG,ZERO(PARMREG)    GET ADDR NEXT ELEMENT           08250020
         LA    WORKREG,ZERO(WORKREG)    CLEAR HI ORDER BYTE             08260020
         LTR   WORKREG,WORKREG     IS THERE A NEXT ELEMENT?             08270020
         BZ    NOMORE              NO, BRANCH AROUND NEXT INSTR         08280020
         MVC   PREVIOUS(THREE,WORKREG),PREVIOUS(PARMREG)  DEQ ELEMENT   08290020
NOMORE   L     WORKREG,WORD(PARMREG)    GET PREVIOUS FIELD              08300020
         MVC   ONE(THREE,WORKREG),ONE(PARMREG) MOVE IN NEXT FIELD       08310020
         BR    RTNREG              RETURN TO CALLER                     08320020
         SPACE 5                                                        08330020
*********************************************************************** 08340020
* ROUTINE FOR DEQUEUEING MINOR QCBS                                   * 08350020
*   REGISTERS USED - WORKREG (REG 2) WORK REGISTER                    * 08360020
*                    PARMREG  (REG1)  ADDR MINOR QCB TO BE DEQUEUED   * 08370020
*                    RTNREG (REG 14) RETURN ADDRESS                  *  08380020
*********************************************************************** 08390020
         SPACE 4                                                        08400020
DEQMINOR L     WORKREG,NXMIN(PARMREG)   ADDR NEXT MINOR QCB             08410020
         LTR   WORKREG,WORKREG     IS THERE ONE?                        08411020
         BZ    LASTMIN             NO, TAKE BRANCH                      08412020
         MVC   PREVIOUS(THREE,WORKREG),PREVIOUS(PARMREG)  DEQ ELEMENT   08413420
LASTMIN  L     WORKREG,PREVMIN(PARMREG)  ADDR PREVIOUS MINOR            08414020
         MVC   NXMIN(WORD,WORKREG),NXMIN(PARMREG)  UPDATE NEXT FIELD    08415020
         BR    RTNREG              RETURN TO CALLER                     08416020
         SPACE 5                                                        08420020
*********************************************************************** 08430020
* ROUTINE FOR DETERMINING MINOR QCB SIZE                              * 08440020
*   REGISTERS USED - SIZEREG (REG 5) SIZE OF MINOR QCB               *  08450020
*                    WORKREG (REG 2) ADDR NAME LENGTH IN QCB MINUS 1  * 08460020
*                    BNCHREG (REG 15) RETURN ADDRESS                  * 08470020
*********************************************************************** 08480020
         SPACE 3                                                        08490020
MINORSZE SR    SIZEREG,SIZEREG     CLEAR ACCUMULATOR                    08500020
         IC    SIZEREG,LMINOR(WORKREG)   GET LENGTH OF MINOR NAME       08510020
         LA    SIZEREG,FULLSIZE(SIZEREG) ROUND LENGTH UP                08520020
         N     SIZEREG,MASKFULL    TO DOUBLE WORD                       08530020
         BR    RTNREG              RETURN TO CALLER                     08540020
         SPACE 3                                                        08550020
QELPEND  TM    RCBSWTCH,SWTCBOTH   SWITCH SET FOR BOTH?                 08560020
         BO    QELOUT              GO TO RETURN TO CALLER               08570020
QELDON     EQU  *                                                       08571020
           TM   RCBQUFLG,RCBQUSTR        Q: QUIESCE IN PROCESS?         08572020
           BZ   QELDON1                  NO, CONTINUE                   08573020
           TM   RCBQUFLG,RCBIOSTR        Q: I/O PURGE COMPLETE?         08574020
           BO   QELDON1                  YES, CONTINUE                  08575020
           LA   PARMREG,DQTBL            SET UP FOR DEQ                 08576020
           SVC  DEQ                      ISSUE DEQ, RET=HAVE            08577020
DEQ        EQU  48                                                      08578020
QELDON1    EQU  *                                                       08579020
           LR   PARMREG,KEEPREG          RESTORE TJID                   08580020
         BR    LINKREG             RETURN TO CALLER                     08590020
QELOUT   MVI   RCBSWTCH,SWTCHOFF   SET TO SEARCH BY TJID                08600020
         B     QELDON              GO RETURN TO CALLER                  08610020
         SPACE 5                                                        08620020
*********************************************************************** 08630020
* ROUTINE FOR FREEING ELEMENT                                         * 08640020
*    REG'S 0,1,15 DESTROTED OVER FREEMAIN INTERFACE                   * 08645020
*   REGISTERS USED - ZEROREG (REG 0) LENGTH OF ELEMENT                * 08650020
*                    PARMREG (REG 1) ADDR ELEMENT TO BE FREED         * 08660020
*                    WORK2 (REG 2) USED TO SAVE REG4                  * 08662020
*                    WORK4 (REG 4) A VALID TCB ADDR (ADDR RCT)        * 08664020
*                    BNCHREG (REG 15) BRANCH EP OF FREEMAIN           * 08666020
*                    RTNREG (REG 14) RETURN ADDRESS                   * 08670020
*********************************************************************** 08680020
         SPACE 3                                                        08690020
FREELMNT EQU   *                                                        08695020
         STM   R14,R15,WORKAREA   SAVE REGS                             08700020
         O     ZEROREG,SP245      INDICATE SUBPOOL FOR FREEMAIN         08705020
         LR    WORK2,WORK4         SAVE CONTENTS OF REG 4 OVER FREEMAIN 08713020
         L     WORK4,RCBRCT        INIT REG 4 W/ VALID TCB ADDR         08716020
         L     BNCHREG,CVTPTR      GET ADDRESS CVT                      08720020
         USING CVT,BNCHREG         SET UP ADDRESSABILITY ON CVT         08730020
         L     BNCHREG,CVTABEND    GET ADDRESS SECONDARY CVT            08740020
         DROP  BNCHREG             DROP CVT                             08742020
         USING SCVTSECT,BNCHREG    SET UP ADDRESSABILITY FOR SCVT       08744020
         L     BNCHREG,SCVTRMBR    GET ADDRESS REGMAIN BR ENTRY         08746020
         DROP  BNCHREG             DROP SCVT                            08748020
         BALR  RTNREG,BNCHREG      DO BR ENTRY TO FREEMAIN              08748420
         LR    WORK4,WORK2         RESTORE REG 4                        08748620
         LM    R14,R15,WORKAREA   RESTORE REGS                          08748720
         BR    R6                  RETURN TO CALLER                     08748820
         EJECT                                                          08750020
*********************************************************************** 08760020
*    ANY REPLY QUEUE ELEMENTS AND WRITER QUEUE ELEMENTS BUILT FOR THE * 08770020
* USER MUST BE DEQUEUED AND FREED.  IF A REPLY BUFFER WAS OBTAINED IT * 08780020
* MUST ALSO BE FREED.                                                 * 08790020
*********************************************************************** 08800020
T07WTORP EQU   *                                                        08820020
         TM    RCBSWTCH,SWTCBOTH   Q: PURGE BY TJID ONLY?               08840020
         BZ    TJIDONLY            YES, SKIP TCB SEARCH                 08860020
         L     TJBXREG,TJBEXTNT    GET TJBX                             08880020
         L     TCBREG,TJBXFST      GET USERS TOP TCB                    08900020
TCBLOOP  EQU   *                                                        08920020
         BAL   RTNREG,T07WRPRG     GO TO PURGE LINKAGE SUBRTN           08940020
         C     TCBREG,TJBXLAST     Q: LAST USER TCB PROCESSED?          08960020
         BE    WTORPDON            YES, EXIT FROM WTOR PROCESSING       08980020
         L     TCBREG,TCBTCB       GET USERS NEXT TCB                   09000020
         B     TCBLOOP             CONTINUE WTOR PURGE BY TCB           09020020
         SPACE 3                                                        09040020
TJIDONLY EQU   *                                                        09060020
         SR    TCBREG,TCBREG       ZERO TCB ADDR REG                    09080020
         BAL   RTNREG,T07WRPRG     GO TO PURGE LINKAGE SUBRTN           09100020
         SPACE 3                                                        09120020
WTORPDON EQU   *                                                        09140020
         TM    RCBSWTCH,SWTCBOTH   Q: PURGE BOTH WAYS?                  09160020
         BO    OFF                 YES, TURN SW OFF                     09180020
         BR    LINKREG             NO, RETURN TO CALLER                 09200020
OFF      EQU   *                                                        09220020
         MVI   RCBSWTCH,SWTCHOFF   TURN OFF SW                          09240020
         BR    LINKREG             RETURN TO CALLER                     09260020
         EJECT                                                          09280020
*********************************************************************** 09300020
*    THE FOLLOWING ROUTINE SAVES REGS AND BRANCHES TO THE COMM TASK   * 09320020
* WTO PURGE RTN TO PURGE WQE'S AND RPQE'S AND BUFFERS WHICH MAY HAVE  * 09340020
* BEEN ASSIGNED TO THE TERMINAL JOB BEING PURGED. REGS USED IN LINKAGE* 09360020
* TO IEECVPRG ARE AS FOLLOWS:                                         * 09380020
*     R1 - TCB ADDR IF PURGE BY TCB OR BOTH; ZERO IF TJID PURGE       * 09400020
*     R2 - TJID                                                       * 09420020
*     R3 - CVT ADDR                                                   * 09440020
*     R4 - ZERO                                                       * 09460020
*     R5 - ZERO                                                       * 09480020
*     R6 - EP TO PURGE RTN (IEECVPRG)                                 * 09500020
*     R14 - RETURN ADDR                                               * 09520020
*********************************************************************** 09540020
      SPACE 3                                                           09560020
T07WRPRG EQU   *                                                        09580020
         STM   ZEROREG,R15,QELPRGSA SAVE CALLERS REGS                   09600020
         LR    LINKREG,SAVREG      SAVE REGSAVE ADDR ACROSS IEECVPRG    09620020
         LR    HOLDREG,PARMREG     R2=TJID                              09640020
         LR    PARMREG,TCBREG      R1=TCB ADDR                          09660020
         L     CVTREG,CVTPTR       R3=CVT ADDR                          09680020
         USING CVT,CVTREG         BASE TO CVT                           09700020
         SR    KEEPREG,KEEPREG     R4=0                                 09720020
         L     WORK6,CVTABEND      GET ADDR OF SCVT                     09740020
         USING SCVTSECT,WORK6      BASE TO SCVT                         09760020
         L     WORK6,SCVTPGWR      R6=EP OF IEECVPRG                    09780020
         DROP  WORK6                                                    09800020
         DROP  CVTREG                                                   09820020
         SR    WORK5,WORK5         R5=0                                 09840020
         BALR  RTNREG,WORK6        GO TO WQE/RPQE PURGE RTN             09860020
         LR    SAVREG,LINKREG      RESTORE SAVE AREA ADDR               09880020
         LM    ZEROREG,R15,QELPRGSA RESTORE CALLERS REGS                09900020
         BR    RTNREG              RETURN TO CALLER                     09920020
         EJECT                                                          10360020
*********************************************************************** 10370020
*    TO PURGE TQE'S WHEN THE USER IS OUT OF CORE, A SEARCH OF THE     * 10380020
* TIMER QUEUE IS MADE.  THE ADDRESS OF THE USER'S TQE IS PASSED IN    * 10390020
* REGISTER 1 TO THE TIMER SLIH DEQ ROUTINE WHOSE ADDRESS IS FOUND IN  * 10392020
* THE CVTQTD00 FIELD IN THE CVT.  THIS ROUTINE WILL REMOVE THE TQE    * 10394020
* FROM THE TIMER QUEUE AND IF IT WAS THE TOP ONE, PROCESS THE NEXT.   * 10396020
* IF THE USER WAS IN THE MIDDLE OF A QUIESCE OR RESTORE, HIS TQE'S    * 10400020
* MAY BE FOUND BY FOLLOWING THE TCBTME POINTER.                       * 10410020
*********************************************************************** 10420020
         SPACE 2                                                        10430020
T07TQEP  L     CVTREG,CVTPTR       ADDR CVT                             10440020
         USING CVT,CVTREG          BASE FOR CVT                         10450020
         TM    RCBSWTCH,SWTCBOTH   CHECK TQE BY TCB AND TJID            10460020
         BO    TQESET              YES, FIND TQES BY TCB AND TJID       10470020
         BZ    TQELOAD             NO, FIND TQES BY TJID                10480020
         B     TQETCBP             SEARCH BY TCB ADDRESS ONLY           10490020
TQESET   LA    TQEBREG,TQETCBP     FIND BY EITHER                       10500020
         B     TQETJID             GO PURGE BY TJID                     10510020
TQELOAD  LA    TQEBREG,TQEPRGDN    SET UP RETURN ADDRESS                10520020
TQETJID  L     TIMEREG,CVTTPC      ADDR TIMER Q                         10530020
         USING TQE,TIMEREG         BASE FOR TQE                         10540020
         SR    CODEREG,CODEREG     INITIALIZE REG                       10550020
         L     TIMEREG,TWELVE(TIMEREG)  ADDR FIRST ELEMENT ON Q         10560020
SUPVCK   TM    TQEFLGS,SUPVELM     IS IT SUPERVISOR ELEMENT             10610020
         BNO   TESTENDQ            NO CHECK FOR LAST ELEMENT            10620020
         TM    TQEFLGS,REALELM     IF X'02' IS ON WE MUST CHECK X'01'   10622020
*                                  ALSO - IF THAT IS ON THEN IT IS      10624020
*                                  A REAL REQUEST - NOT A SUPERV ELEM   10626020
         BO    TESTENDQ            REAL REQUEST - GO CHECK LAST ELEM    10628020
         L     TIMEREG,TQEFLNK     GET ADDR NEXT ELEMENT ON QUEUE       10630020
         B     SUPVCK              GO CHECK IF SUPERVISOR ELEMENT       10660020
TESTENDQ LR    CHKREG,TIMEREG      SET UP CHKREG FOR TEST               10670020
         L     CHKREG,TWELVE(CHKREG) IF END ELEMENT HAVE ALL F'S        10680020
         C     CHKREG,ENDELMFF     IS IT DUMMY ELEMENT?                 10690020
         BE    TQEIDONE            YES, FINISHED TJID PURGE             10700020
         L     TQESAVRG,TQEFLNK    ADDR NEXT TQE                        10710020
         LH    TQETJDRG,TQETJID1   1ST HALF USER'S TJID                 10720020
         IC    TQETJDRG,TQETJID2   2ND HALF USER'S TJID                 10730020
         CR    TQETJDRG,PARMREG    USER'S TQE?                          10740020
         BE    GODEQFRE            YES, GO DEQ AND FREE                 10750020
NEXTTQE  LR    TIMEREG,TQESAVRG    ADDR NEXT TQE                        10760020
         B     SUPVCK              GO CHECK IF SUPERVISOR ELEMENT       10790020
GODEQFRE LA    TQELNKRG,NEXTTQE    SET UP FOR RETURN                    10800020
         B     TQEDEQFR            GO DEQ AND FREE TQE                  10810020
         SPACE 2                                                        10820020
TQEIDONE BR    TQEBREG             GO TO RTN IN REGISTER                10830020
         SPACE 4                                                        10840020
TQETCBP  L     TJBXREG,TJBEXTNT    ADDR TJBX                            10850020
         L     TCBREG,TJBXFST      ADDR USER'S TOP TCB                  10860020
         USING TCB,TCBREG          BASE FOR TCB                         10870020
CHKANOTR L     TIMEREG,TCBTME      ADDR TQE FOR TCB                     10880020
         LTR   TIMEREG,TIMEREG     ANY FOR THIS TCB?                    10890020
         BZ    LASTTCB             NO, TEST NEXT                        10900020
         TM    TQEFLGS,TQENTONQ    IS TQE ON QUEUE?                     10910020
         BO    FREETQE             NO, JUST FREE IT                     10920020
         BAL   TQELNKRG,TQEDEQFR   YES, DEQ AND FREE IT                 10930020
LASTTCB  C     TCBREG,TJBXLAST     USER'S LAST TCB?                     10940020
         BE    TQEPRGDN            YES, TQE PURGE DONE                  10950020
         L     TCBREG,TCBTCB       PTR TO NEXT TCB                      10960020
         B     CHKANOTR            GO CHECK ANOTHER TCB                 10961020
FREETQE  LA    TQELNKRG,LASTTCB    RETURN ADDR                          10962020
         LR    TQETJDRG,PARMREG   SAVE TJID OVER DEQUING                10962520
         B     TQEFREE             GO FREE TQE                          10963020
TQEDEQFR LR    TQETJDRG,PARMREG    SAVE TJID ACROSS DEQUEUING           10964020
         LR    PARMREG,TIMEREG     SET UP ADDR TQE TO BE DEQUEUED       10970020
         LR    RTNREG,BASEREG      SAVE BASE ACROSS DEQUEUING           10980020
         L     CVTREG,CVTPTR       CVT ADDRESS                          10990020
         L     BNCHREG,CVTQTD00    ADDR TIMER DEQ ROUTINE               10992020
         L     BASEREG,CVTTPC      SET UP BASE FOR CLOCKS               10994020
         LR    ZEROREG,WORK2      SAVE REG 2 OVER DEQ                   10995020
         BALR  WORK2,BNCHREG       BRANCH TO IT ON 2                    10996020
         LR    WORK2,ZEROREG      RESTORE REG 2                         10997020
         LR    BASEREG,RTNREG      RESTORE BASE                         10998020
TQEFREE  LA    ZEROREG,EIGHT       GET NUMBER 8                         10998420
         LR    PARMREG,TIMEREG     SET UP ADR TQE IN REG 1              10998820
         SR    PARMREG,ZEROREG     BACK UP ADR BY EIGHT TO INCLUDE AQE  10999220
         LA    ZEROREG,TQESIZE     GET SIZE TQE PLUS 8 BYTE AQE         10999620
         O     ZEROREG,SP245       INDICATE SP 245                      11009620
         L     BNCHREG,CVTPTR      GET ADDRESS CVT                      11019620
         USING CVT,BNCHREG         SET UP ADDRESSABILITY ON CVT         11029620
         L     BNCHREG,CVTABEND    GET ADDRESS SECONDARY CVT            11039620
         DROP  BNCHREG             DROP CVT                             11039720
         USING SCVTSECT,BNCHREG    SET UP ADDRESSABILITY FOR SCVT       11039820
         L     BNCHREG,SCVTRMBR    GET ADDRESS REGMAIN BR ENTRY         11039920
         DROP  BNCHREG             DROP SCVT                            11043220
         BALR  RTNREG,BNCHREG      DO BR ENTRY TO FREEMAIN TO FREE TQE  11045220
         LR    PARMREG,TQETJDRG    RESTORE PARM REG                     11050020
         BR    TQELNKRG            RETURN TO CALLER                     11060020
TQEPRGDN TM    RCBSWTCH,SWTCBOTH   CHECK BOTH WAYS?                     11070020
         BO    TQEOUT              NO, RETURN TO CALLER                 11080020
         BR    LINKREG             RETURN TO CALLER                     11090020
TQEOUT   MVI   RCBSWTCH,SWTCHOFF   YES, RESET SWITCH                    11100020
         BR    LINKREG             RETURN TO CALLER                     11110020
         EJECT                                                          11120020
*********************************************************************** 11130020
*    THE RQE'S ASSIGNED TO A USER WHO IS OUT OF CORE ARE FOUND BY     * 11140020
* SEARCHING THE RQE TABLE.  ANY RQE WITH THE USER'S TJID IS MARKED    * 11150020
* AVAILABLE AND PLACED ON THE FREE QUEUE.  THE RQE'S FOR A USER       * 11160020
* PARTIALLY QUIESCED OR RESTORED ARE FOUND BY SEARCHING THE ASYN-     * 11170020
* CHRONOUS EXIT QUEUES BY TCB ADDRESS.                                * 11180020
*********************************************************************** 11190020
         SPACE 2                                                        11200020
T07RQEP  L     CVTREG,CVTPTR       ADDR CVT                             11210020
         USING CVT,CVTREG          BASE FOR CVT                         11220020
         L     FREEREG,CVTIXAVL    PTR TO ADDR NEXT AVAILABLE RQE       11230020
         LH    FREEREG,ZERO(FREEREG) ADDR NEXT AVAILABLE RQE            11240020
         USING RQESECT,RQEREG      BASE FOR REQUEST QUEUE ELEMENT       11250020
         TM    RCBSWTCH,SWTCBOTH   CHECK RQE BY BOTH TJID AND TCB?      11260020
         BO    RQEBOTH             YES, FIND BY TCB ADDR AND TJID       11270020
         BZ    RQELOAD             NO, FIND RQES BY TJID                11280020
         B     RQEPTCB             PURGE BY TCB ADDRESS ONLY            11290020
RQEBOTH  LA    RTNREG,RQEPTCB      SET UP RETURN ADDR                   11300020
         B     RQETJID             PURGE FIRST BY TJID                  11301020
RQELOAD  LA    RTNREG,RQEPRGCP     PURGE BY TJID ONLY          AJ M4248 11302021
         SPACE 5                                                        11303020
RQETJID  L     RQEREG,CVTIOQET     ADDR RQE TABLE                       11304020
         L     CVTREG,CVTABEND     PTR TO SECONDARY CVT                 11310020
         USING SCVTSECT,CVTREG     BASE FOR SCVT                        11320020
         L     TABENDRG,SCVTRQND   ADDR END RQE TABLE                   11330020
CHCKRQE  LH    TJIDREG,RQETJID1    1ST HALF USER'S TJID                 11340020
         IC    TJIDREG,RQETJID2    2ND HALF USER'S TJID                 11350020
         CR    PARMREG,TJIDREG     USER'S RQE?                          11360020
         BNE   RQENEXT             NO,CHECK NEXT                        11370020
         BAL   RQELNKRG,RQEFRDEQ   YES, GO CLEAR AND PUT ON AVAIL       11380020
RQENEXT  LA    RQEREG,RQESIZE(RQEREG)   INCREMENT TO NEXT RQE           11390020
         CR    RQEREG,TABENDRG     BEYOND TABLE?                        11400020
         BNE   CHCKRQE             NO, GO CHECK RQE                     11420020
         BR    RTNREG              RETURN TO CALLER                     11430020
         SPACE 5                                                        11440020
RQEPTCB  L     TJBXREG,TJBEXTNT    ADDR TJBX                            11450020
         USING TJBX,TJBXREG        BASE FOR TJBX                        11460020
         L     FRSTREG,TJBXFST     ADDR USER'S TOP TCB                  11470020
         USING TCB,TCBREG          BASE FOR TCB                         11480020
         L     CVTREG,CVTPTR       CVT ADDR                             11490020
         USING CVT,CVTREG          BASE FOR CVT                         11500020
         L     ERRQREG,CVTIERLC    ADDR ERROR LOGICAL CHANNEL Q         11510020
         CLC   ZERO(TWO,ERRQREG),WORD(ERRQREG)  IS QUEUE EMPTY?         11520020
         BE    RQEPRGDN            YES, NO RQES FOR USER                11530020
         LR    RQEREG,ERRQREG      SAVE PTR TO AEQ                      11540020
NEXTRQE  LR    PRVRQERG,RQEREG     SAVE PTR TO RQE                      11560020
         LH    RQEREG,RQELNK       ADDR NEXT RQE                        11570020
NEXTRQE1 CH    RQEREG,FOUR(ERRQREG) HAS LAST RQE BEEN PROCESSED         11572020
         BE    RQEPRGDN            YES BRANCH                           11574020
         L     RQETCBRG,RQETCB     ADDR THIS RQE'S TCB                  11580020
         N     RQETCBRG,HIBYTOFF   CLEAR HI ORDER BYTE           A43809 11580421
         LR    TCBREG,FRSTREG      SAVE PTR                             11582020
COMRQE   CR    TCBREG,RQETCBRG     THIS RQE BELONG TO USER?             11590020
         BNE   NEXTCB              NO, GET NEXT TCB                     11600020
         MVC   ZERO(TWO,PRVRQERG),RQELNK   REMOVE FROM AEQ              11610020
         CH    RQEREG,TWO(ERRQREG) LAST RQE DEQUEUED?                   11620020
         BNE   CLEANUP             NO, GO PLACE ON FREELIST             11630020
         STH   PRVRQERG,TWO(ERRQREG) YES, SET PTR TO LAST RQE           11640020
CLEANUP  LH    R6,RQELNK           GET NEXT RQE AND SAVE                11642020
         BAL   RQELNKRG,RQEFRDEQ   CLEAN UP RQE AND MAKE AVAILABLE      11650020
         LR    RQEREG,R6           SET UP REG 4 WITH NEXT RQE ADR       11650420
         B     NEXTRQE1            BR TO PROCESS NEXT RQE               11652020
NEXTCB   C     TCBREG,TJBXLAST     USER'S LAST TCB?                     11660020
         BE    NEXTRQE             YES, SEE IF LAST RQE                 11670020
         L     TCBREG,TCBTCB       ADDR USER'S NEXT TCB                 11680020
         B     COMRQE              TEST NEXT TCB                        11690020
RQEPRGDN EQU   *                                                        11691020
        L     TJBXREG,TJBEXTNT    ADDR TJBX                             11692020
        L     TCBREG,TJBXFST      ADDR USERS TOP TCB                    11693020
TESTRB  EQU   *                                                         11694020
        NC    TCBRBP,TCBRBP       ANY RB'S?                             11695020
        BZ    MORETCBS            NO, CHECK FOR MORE TCB'S              11696020
        L     RBREG,TCBRBP        GET TOP RB ADDR                       11697020
        USING RBSECT,RBREG        BASE FOR RB                           11698020
TESTYPE EQU   *                                                         11699020
        TM    RBSTAB1,RBFTIRB     IS RB AN IRB?                         11700020
        BZ    NOTIRB              NO, CHECK FOR MORE RB'S               11701020
        TM    RBSTAB2,IRBIQE      ARE IQE'S ASSIGNED TO IRB?            11702020
        BO    NOTIRB              YES, CHECK FOR MORE RB'S              11703020
        TM    RBSTAB2,RQEFLG      ARE RQE'S ASSIGNED TO IRB?            11704020
        BZ    NOTIRB              NO, CHECK FOR MORE RB'S               11705020
        LH    RQEREG,RBIQE+2      GET FIRST RQE ADDR                    11706020
TSTIFREE EQU *                                                          11707020
        LH    WORKREG7,RQELNK     SAVE ADDR OF NEXT RQE                 11708020
        TM    RQEIDT,SET          CURRENT RQE ALREADY FREE?             11709020
        BO    GTMRRQES            YES, CHECK FOR MORE RQE'S             11710020
        BAL   RQELNKRG,RQEFRDEQ   MAKE RQE AVAILABLE                    11711020
GTMRRQES EQU   *                                                        11712020
        LR    RQEREG,WORKREG7     RECALL ADDR NEXT RQE                  11713020
        LTR   RQEREG,RQEREG       TEST FOR LAST RQE (0 OR FFFF)         11714020
        BP    TSTIFREE            VALID RQE ADDR, PROCESS IT            11715020
NOTIRB  EQU   *                                                         11716020
        TM    RBSTAB2,RBTCBNXT    LAST RB ON Q?                         11717020
        BO    MORETCBS            YES, CHECK FOR MORE TCB'S             11718020
        L     RBREG,RBLINK        GET ADDR OF NEXT RB AND               11719020
        B     TESTYPE             PROCESS IT                            11720020
MORETCBS EQU   *                                                        11721020
        C     TCBREG,TJBXLAST     CURRENT TCB LAST ON USER Q?           11722020
        BE    RQEPRGCP            YES, EXIT FROM IRB/RQE PROCESSING     11723020
        L     TCBREG,TCBTCB       ADDR USER'S NEXT TCB                  11724020
        B     TESTRB              CONTINUE PROCESSING                   11725020
        DROP  RBREG                                                     11726020
RQEPRGCP EQU   *                                                        11727020
        TM    RCBSWTCH,SWTCBOTH   CHECK BY TJID AND TCB?                11728020
         BO    RQEOUT              NO, RETURN TO CALLER                 11730020
         BR    LINKREG             RETURN TO CALLER                     11740020
RQEOUT   MVI   RCBSWTCH,SWTCHOFF   YES, RESET TO SEARCH BY TJID         11750020
         BR    LINKREG             RETURN TO CALLER                     11760020
         SPACE 4                                                        11770020
RQEFRDEQ MVC   RQELNK(TWO),ZERO(FREEREG)  CHAIN RQE TO FREELIST         11780020
         STH   RQEREG,ZERO(FREEREG) ADDR NEXT AVAILABLE                 11790020
         XC    RQEUCB(FOURTEEN),RQEUCB  CLEAR RQE.                      11800020
         OI    RQEIDT,SET          INDICATE RQE AVAILABLE               11810020
         BR    RQELNKRG            RETURN TO CALLER                     11820020
           DROP CVTREG                                                  11825020
         EJECT                                                          11830020
*********************************************************************** 11840020
*    INTERPARTITION POSTS FOR A USER ARE PROCESSED BY DEQUEUING AND   * 11850020
* FREEING THE IPPB'S BUILT TO HANDLE ANY INTERPARTITION POSTS.        * 11860020
*********************************************************************** 11870020
         SPACE 2                                                        11880020
T07IPPB  EQU   *                   START OF IPPB PURGE                  11890020
         USING TJB,TJBREG          BASE FOR TJB                         11900020
         L     IPPBREG,TJBIPPB     ADDR IPPB                            11910020
         LTR   IPPBREG,IPPBREG     ANY IPPB'S?                          11920020
         BZ    IPPBOUT             NO, CONTINUE PROCESSING              11930020
         LR    HOLDREG,PARMREG     SAVE PARM REG                        11940020
         XC    TJBIPPB,TJBIPPB     CLEAR IPPB PTR IN TJB                11942020
MOREIPPB LR    PARMREG,IPPBREG     SET UP FOR FREEING BLOCK             11950020
         USING IPPB,IPPBREG        BASE FOR IPPB                        11960020
         L     IPPBREG,IPPBTJQ     PTR TO NEXT IPPB                     11970020
         LA    ZEROREG,SIXTEEN     LENGTH OF IPPB                       11980020
         O     ZEROREG,SP245       INDICATE SP 245                      11982020
         L     BNCHREG,CVTPTR      GET ADDRESS CVT                      11984020
         USING CVT,BNCHREG         SET UP ADDRESSABILITY ON CVT         11986020
         L     BNCHREG,CVTABEND    GET ADDRESS SECONDARY CVT            11988020
         DROP  BNCHREG             DROP CVT                             11988420
         USING SCVTSECT,BNCHREG    SET UP ADDRESSABILITY FOR SCVT       11988820
         L     BNCHREG,SCVTRMBR    GET ADDRESS REGMAIN BR ENTRY         11989220
         DROP  BNCHREG             DROP SCVT                            11989620
         BALR  RTNREG,BNCHREG      DO BR ENTRY TO FREEMAIN TO FREE IPPB 11989720
         LTR   IPPBREG,IPPBREG     MORE TO FREE?                        12000020
         BNZ   MOREIPPB            YES, GO ON                           12020020
         LR    PARMREG,HOLDREG     RESTORE PARM REG                     12030020
IPPBOUT  BR    LINKREG             RETURN TO CALLER                     12040020
         EJECT                                                          12042020
*********************************************************************** 12044020
*              CANCEL PENDING INTERPARTITION POSTS FOR TSO              12046020
*                                                                       12048020
*     INPUT TO QTIP                                                     12048420
*        REG1 - ADDRESS OF PRE SUPPLIED REGISTER SAVE AREA              12048820
*        REG2 - TJID IN LO ORDER TWO BYTES,ZERO IN HI ORDER TWO BYTES   12049220
*        REG3 - ADDRESS OF TCB FOR WHOM REQUEST IS BEING MADE OR ZERO   12049620
*                                                                       12049720
*     MACRO CALL IS                                                     12049820
*        QTIP 29,(1)                                                    12049920
*********************************************************************** 12053220
         SPACE 3                                                        12055220
TJIDENDA LR    HOLDREG,PARMREG     SAVE TJID                            12055620
         L     PARMREG,CVTPTR      GET ADDRESS CVT                      12056020
         USING CVT,PARMREG         ADDRESSABILITY FOR CVT               12056420
         L     PARMREG,CVTTSCVT    GET ADDRESS OF TSCVT                 12056520
         DROP  PARMREG             DROP CVT                             12056620
         USING TSCVT,PARMREG       ADDRESSABILITY FOR TSCVT             12059920
         L     PARMREG,TSCVTRPT    GET ADDRESS TIOC TABLE               12060020
         DROP  PARMREG             DROP TSCVT                           12062020
         USING TIOCRPT,PARMREG     ADDRESSABILITY FOR RPT               12062420
           LA   PARMREG,TIOCSAVE      ADDR OF SAVE AREA TO PASS TO QTIP 12062820
         DROP  PARMREG             DROP RPT                             12063220
         SR    R3,R3               ZERO REG FOR TCB ADDRESS             12063320
         QTIP 29,(1)               ISSUE QTIP                           12066620
         EJECT                                                          12066720
*********************************************************************** 12068720
*              CANCEL PENDING INTERPARTITION POSTS FOR TCAM             12073320
*                                                                       12073420
* IN TCAM ENVIRONMENT THERE MAY BE A PENDING REQUEST TO POST A TASK     12075420
* BY ANOTHER TASK. SVC 102 WILL EFFECTIVELY CANCEL SUCH PENDING         12075820
* REQUESTS. IF THOSE REQUESTS WERE NOT CANCELLED THIS TASK COULD        12076220
* TERMINATE AND ANOTHER TASK POSSIBLY HAVING THE SAME TJID,TCB ADDRESS  12076620
* AND RB ADDRESS AS THIS TASK COULD BE POSTED BY MISTAKE.               12076720
*                                                                       12077820
*     INPUT TO SVC 102                                                  12079820
*        REG1 - ADDRESS OF TWO WORD SAVE AREA                           12079920
*             +0 X'FF' - TJID                                           12082720
*             +4 X'00' - TCB ADR(ZERO IF TSO)                           12083120
*                                                                       12084920
*     SVC CALL IS                                                       12085520
*        SVC 102                                                        12086120
*********************************************************************** 12086520
         SPACE 3                                                        12086620
         L     CVTREG,CVTPTR       GET ADDRESS CVT                      12087420
           USING CVT,CVTREG              BASE TO CVT                    12087820
         TM    CVTTCMFG,CVTTCRDY   IS TCAM RUNNING WELL                 12088220
         BZ    TJIDENDB            NO AVOID ISSUING SVC 102             12088620
         XC    WORKAREA(EIGHT),WORKAREA CLEAR 2 WORD WK AREA            12088720
         OI    WORKAREA,ALLFLAG    PUT X'FF' IN HI ORDER BYTE           12088820
         STH   HOLDREG,WORKAR2     PUT TJID IN LO ORDER 2 BYTES         12089020
         LA    PARMREG,WORKAREA    PUT ADR OF AREA IN REG1              12089120
         SVC   102                 ISSUE SVC                            12089820
         EJECT                                                          12090520
TJIDENDB LR    PARMREG,HOLDREG     RESTORE REG1 WITH TJID               12091220
TJIDEND    EQU  *                                                       12091920
           L    CVTREG,CVTPTR            RESTORE CVT ADDR               12092620
           TM   CVTTSFLG,CVTTSRDY        Q: TSO STILL UP?               12093320
          BCR   EIGHT,LINKREG      NO, RETURN TO CALLER                 12094020
           L    TSCVTREG,CVTTSCVT   GET TSCVT                           12094720
           USING TSCVT,TSCVTREG          BASE TSCVT                     12095420
         NI    RCBFLG,ALLFLAG-RCBFSO RESET SWAP OUT FLAG         A46544 12097121
         TM    RCBSWTCH,RCBZQRF    IS FLAG SET TO ZERO QU RESTOREA44022 12100521
         BZ    LEAVON              NO, LEAVE QUIESCE RESORE ALONEA44022 12102221
         MVI   RCBRSFLG,FLAG00     ZERO RESTORE FLAGS            A44022 12103921
         MVI   RCBQUFLG,FLAG00     ZERO QUIESCE FLAGS            A44022 12105621
         NI    RCBSWTCH,ALLFLAG-RCBZQRF RESET INDICATOR          A44022 12107321
LEAVON   EQU   *                                                 A44022 12109021
           XC   TJBEXTNT(E4),TJBEXTNT  CLEAN UP                         12110721
           XC   TJBSDCB(E7),TJBSDCB    TJB FOR                          12112421
           XC   TJBUSER(E12),TJBUSER   NEXT LOGON                       12114121
           XC   TJBMONI(E4),TJBMONI    *                                12115821
           NI   TJBSTAT2,ALLFLAG-FLGTJB1 (SEE EOT FOR SIMILIAR CODE)    12117521
         NI    TJBSTAT,ALLFLAG-FLGTJB2 *                                12119221
         MVI   TJBRSTOR,FLAG00     *                                    12120921
         MVI   TJBNEWID,FLAG00     *                                    12122621
         MVI   TJBATTN,FLAG00      *                                    12124321
         MVI   TJBSTAX,FLAG00          ZERO STAX COUNT                  12126021
LOGOFF  TSEVENT  LOGOFF,TJID=(PARMREG) TELL DRIVER THROUGH WITH TJID    12127721
         OI    TSCVTFLG,TSCDISC    SET DISCONNECT FLAG FOR TSC          12129421
         OI    TJBSTAT,TJBDISC     SET DISC BIT IN TJB FOR MSGS         12131121
         OI    TJBSTAT,TJBNJB      MARK TJB NOT IN USE                  12132821
TSCPOST  L     WORK4,TSCVTECB        GET TSC ECB ADDR                   12134521
         USING TSECB,WORK4                                              12136221
         STM   BASEREG,TJBREG,QELPRGSA SAVE PARM REGS FOR POST          12137921
         LA    RCBREG,TSCECB     SET PARM REG TO ECB                    12139621
         DROP  WORK4                                                    12141321
         L     TJBREG,TSCVTTSC    PASS ADDR TSC TCB                     12143021
         LA    BASEREG,COMP7F     PASS COM CODE FOR POST                12144721
COMP7F   EQU   X'7F'              POST CODE                             12146421
         SLL   BASEREG,24         SET POST CODE IN HI BYTE              12148121
         L     CVTREG,CVTPTR      GET CVT ADDR                          12149821
         USING CVT,CVTREG         BASE TO CVT                           12151521
         L     BNCHREG,CVT0PT01   PICK UP BR ENTRY TO POST              12153221
         BALR  RTNREG,BNCHREG     GO TO POST, POST TSC                  12154921
         L     TSCVTREG,CVTTSCVT  RESTORE TSCVT ADR               M1286 12155321
         USING TSCVT,TSCVTREG     ESTABLISH ADDRESSABILITY        M1286 12155721
         LM    BASEREG,TJBREG,QELPRGSA RESTORE REGS                     12156621
         BR    LINKREG             RETURN TO CALLER                     12158321
         EJECT                                                          12160020
*********************************************************************** 12170020
*    THE FOLLOWING SECTIONS ARE INVOKED ONLY WHEN THE USER TO BE      * 12180020
* PURGED HAS BEEN PARTIALLY QUIESCED OR RESTORED.  THEY INCLUDE A     * 12190020
* PURGE OF THE TRANSIENT AREA, I/O AND IQE'S.                         * 12200020
*********************************************************************** 12210020
         SPACE 2                                                        12220020
T07TAP   L     CVTREG,CVTPTR       ADDR CVT                             12230020
         USING CVT,CVTREG          BASE FOR CVT                         12240020
         L     SCVTREG,CVTABEND    ADDR SECONDARY CVT                   12250020
         USING SCVTSECT,SCVTREG    BASE FOR SCVT                        12260020
         L     TACTSREG,SCVTTACT   ADDR OF TACT                         12270020
         L     TJBXREG,TJBEXTNT    ADDR TJBX                            12280020
         USING TJBX,TJBXREG        BASE FOR TJBX                        12290020
         L     TCBREG,TJBXFST      FIRST TCB ON QUEUE FOR USER          12300020
         USING TCB,TCBREG          BASE FOR TCB                         12310020
         SR    ZEROREG,ZEROREG     INITIALIZE REG                       12312020
GETRB    L     SVRBREG,TCBRBP      GET FIRST RB                         12320020
         LTR   SVRBREG,SVRBREG     IS ADR ZERO                          12320420
         BZ    TCBMORE             YES BRANCH AND GET NEXT TCB          12320820
         USING RBSECT,SVRBREG      BASE FOR RB                          12330020
TESTNRES TM    RBSTAB,RBFNSVRB     IS IT NON RESIDENT SVRB?             12340020
         BO    RESVRB              YES, CHECK IF IN A USER Q            12350020
RBMORE   TM    RBSTAB+BYTE,RBTCBNXT MORE RB'S ON THIS Q?                12360020
         BO    TCBMORE             NO, SEE IF MORE TCBS                 12370020
         L     SVRBREG,RBLINK      YES, GET NEXT RB                     12380020
         LA    SVRBREG,ZERO(SVRBREG)   CLEAR HI ORDER BYTE              12390020
         B     TESTNRES            GO CHECK THIS RB                     12400020
TCBMORE  C     TCBREG,TJBXLAST     WAS LAST TCB FOR USER PROCESSED      12410020
         BE    REQPURGE            YES, PROCESS REQUEST QUEUE           12420020
         L     TCBREG,TCBTCB       NO, GET ADDR NEXT TCB                12430020
         B     GETRB               FIND RB AND TEST IT                  12440020
RESVRB   LH    ENTRYREG,RBTABNO    LOAD TAB NO                          12450020
         LTR   ENTRYREG,ENTRYREG   SVRB ON USER Q?                      12460020
         BE    RBMORE              NO, GET NEXT RB                      12470020
         AR    ENTRYREG,TACTSREG   YES, GET THIS TACT ENTRY             12480020
         L     WORK5,WORD(ENTRYREG) START OF USER Q                     12490020
         LTR   WORK5,WORK5         IS QUEUE PTR ZERO                    12492020
         BZ    RBMORE              YES BRANCH GET NEXT RB               12494020
         CR    WORK5,SVRBREG       IS THIS THE SVRB TO BE PURGED?       12500020
         BNE   NOTPURGE            NO, GET NEXT RB                      12510020
         MVC   WORD(WORD,ENTRYREG),RBSVTQN   TAKE THIS SVRB OFF Q       12520020
KEEPCONT LA    ZEROREG,ONE(ZEROREG) SET UP INDICATOR THAT SVRB OFF      12540020
         L     WORK14,SCVTAUCT     PTR TO NO TRANS AREA USERS           12550020
         L     CODEREG,ZERO(WORK14) GET NO USERS                        12560020
         BCTR  CODEREG,ZEROREG     DECREMENT COUNT                      12570020
         ST    CODEREG,ZERO(WORK14) SAVE NEW COUNT                      12580020
         B     TABUSE              CHECK IF TAB IN USE                  12590020
NOTPURGE LR    CODEREG,WORK5       SAVE ADDR PRIOR SVRB ON Q            12600020
         L     WORK5,TWELVE(WORK5) ADDR NEXT SVRB ON TA QUEUE           12610020
         LA    WORK5,ZERO(WORK5)   CLEAR HI ORDER BYTE                  12612020
         LTR   WORK5,WORK5         IS THERE AN SVRB                     12614020
         BZ    RBMORE              NO GO CHECK FOR MORE RB'S            12616020
         CR    WORK5,SVRBREG       HIT                                  12620020
         BNE   NOTPURGE            NO, UPDATE TO NEXT                   12630020
         MVC   TWELVE(WORD,CODEREG),RBSVTQN  YES DEQUEUE FROM USER Q    12640020
         B     KEEPCONT            BRANCH TO INDICATE SVRB PURGED       12650020
TABUSE   CLI   ZERO(ENTRYREG),ZERO IS TAB IN USE?                       12660020
         BNE   RBMORE              NO, CHECK FOR MORE RBS               12670020
         L     CODEREG,WORD(ENTRYREG)   TEST USER Q FOR MORE SVRBS      12680020
LASTSVRB LTR   CODEREG,CODEREG     USING TAB?                           12690020
         BE    SETFREE             NO, SET TAB FLAGS                    12700020
         CLC   NINE(THREE,ENTRYREG),D25(CODEREG)  THIS SVRB USING TAB?  12710020
         BE    RBMORE              YES, PROCESS NEXT RB                 12720020
         L     CODEREG,TWELVE(CODEREG)  GET NEXT USER ON USER Q         12730020
         B     LASTSVRB            GO SEE IF MORE SVRBS                 12740020
SETFREE  MVI   ZERO(ENTRYREG),NOTINUSE  SET TAB NOT IN USE              12750020
         B     RBMORE              GET NEXT RB ON TCB RB Q              12760020
REQPURGE L     SVRBREG,ZERO(TACTSREG)   REQUEST Q PTR                   12770020
         LTR   SVRBREG,SVRBREG     ANY QUEUE?                           12780020
         BE    CHECKPUR            NO                                   12790020
         SR    WORK5,WORK5         ZERO REG                             12800020
         ST    WORK5,ZERO(TACTSREG) ZERO TACT REQ Q PTR                 12810020
PURGEIT  MVI   RBWCF,ZERO          ZERO WAIT COUNT                      12820020
         L     WORK14,RBSVTQN      GET NEXT POINTER                     12830020
         ST    WORK5,RBSVTQN       ZERO POINTER                         12840020
         LTR   SVRBREG,WORK14      MORE ON QUEUE                        12850020
         BNE   PURGEIT             YES, REMOVE                          12860020
CHECKPUR LTR   ZEROREG,ZEROREG     ANY SVRB PURGED                      12870020
         BE    T07DONE             NO, GO ON                            12880020
         L     CVTREG,CVTPTR       GET TO CVT                           12890020
         USING CVT,CVTREG          BASE FOR CVT                         12900020
         L     TCBREG,CVTTCBP      PTR TO NEW/OLD                       12910020
         L     TCBREG,FOUR(TCBREG) ADDR THIS TCB                        12920020
         L     RBREG,TCBRBP        ADDR RB                              12930020
         USING RBSECT,RBREG        BASE FOR RB                          12940020
         MVC   RBOPSW(EIGHT),RETPSW SET OLD PSW TO RETURN POINT         12950020
         STM   ZEROREG,CODEREG,TCBGRS   SAVE REGISTERS                  12960020
         L     CVTREG,CVTABEND     PT TO XCVT                           12970020
         USING SCVTSECT,CVTREG     BASE FOR SCVT                        12980020
         L     TARFREG,SCVTTAR     ADDR TA REFRESH RTN                  12990020
         BR    TARFREG             GO TO ROUTINE                        13000020
RETPOINT L     CVTREG,CVTPTR       PT TO CVT                            13010020
         USING CVT,CVTREG          BASE FOR CVT                         13020020
         L     TCBREG,CVTTCBP      PT TO NEW/OLD                        13030020
         L     TCBREG,FOUR(TCBREG) ADDR OUR TCB                         13040020
         USING TCB,TCBREG          BASE FOR TCB                         13050020
         LM    ZEROREG,CODEREG,TCBGRS   RESTORE REGS                    13060020
T07DONE  BR    LINKREG             RETURN TO CALLER                     13070020
         EJECT                                                          13080020
*********************************************************************** 13090020
* PURGE ANY SCHEDULED USER I/O.  TWO ENTRIES TO PURGE MAY BE NECESSARY* 13100020
* TO HANDLE ALL OF THE PURGED USER I/O                                * 13110020
*********************************************************************** 13120020
         SPACE                                                          13130020
T07IOPRG EQU   *                   PURGE ANY USER I/O                   13140020
         LR    TJIDREG,PARMREG     SAVE PARM REG                        13150020
         USING TJB,TJBREG          BASE FOR TJB                         13160020
         L     TJBXREG,TJBEXTNT    ADDR TJBX                            13170020
         USING TJBX,TJBXREG        BASE FOR TJBX                        13180020
         L     CODEREG,TJBXQPL     ADDR QPL                             13190020
         ST    CODEREG,RCBQPL      ST ADDR QPL IN RCB                   13192020
         L     TCBREG,TJBXFST      TOP USER TCB                         13200020
         L     WORK4,TJBXLAST      LAST USER TCB                        13210020
         USING QPLSECT,CODEREG     BASE FOR QPL                         13220020
         SR    ZEROREG,ZEROREG     INITIALIZE REG                       13230020
GETTCB   ST    TCBREG,QPLTCB       STORE ADDR FOR PURGE                 13240020
         ST    ZEROREG,QPLIOB      INITIALIZE QPL                       13250020
         CR    TCBREG,WORK4        LAST USER TCB?                       13260020
         BE    SETFLG              YES, SET LAST ENTRY FLAG             13270020
         L     TCBREG,TCBTCB       NO, STORE NEXT ADDR                  13280020
         LA    CODEREG,EIGHT(CODEREG)      GET NEXT ENTRY               13290020
         B     GETTCB              CONTINUE BUILDING QPL                13300020
SETFLG   OI    QPLFLG,LSTEXT       SET LAST ENTRY FLAG IN QPL           13310020
         MVI   RCBPRG,ZERO         ZERO 1ST BYTE PARAM LIST             13320020
         MVC   RCBPRG+ONE(ELEVEN),RCBPRG  ZERO REST OF LIST EXCLUDING   13330020
*                                  ADDRESS OF QPL                       13332020
           MVI  RCBPRG,OPTHALT           SET FOR HALT I/O               13342020
         LA    PARMREG,RCBPRG      SET UP FOR SVC TO PURGE              13360020
         SVC   16                  GO TO SVC PURGE                      13370020
         LR    PARMREG,TJIDREG     RESTORE PARM REG                     13380020
         BR    LINKREG             RETURN TO CALLER                     13390020
         SPACE 5                                                        13400020
         EJECT                                                          13500020
*********************************************************************** 13510020
* PURGE ANY IQE'S ASSOCIATED WITH USER BEING PURGED                   * 13520020
*********************************************************************** 13530020
         SPACE                                                          13540020
T07IQEP  L     CVTREG,CVTPTR       GET CVT ADDR                         13550020
         USING CVT,CVTREG          BASE FOR CVT                         13560020
         L     TJBXREG,TJBEXTNT    ADDR TJBX                            13570020
         USING TJBX,TJBXREG        BASE FOR TJBX                        13580020
         L     FRSTREG,TJBXFST     ADDR USER'S TOP TCB                  13590020
         L     TAEQJREG,CVTIERLC   PTR TO ASYNCHRONOUS EXIT QUEUES      13600020
         LA    TAEQJREG,SIX(TAEQJREG) ADDR QUEUE OF IQE'S               13610020
         TM    ZERO(TAEQJREG),TAEQMT IS IQE QUEUE EMPTY                 13620020
         BO    IQEPROUT            NO,IQE'S, RETURN TO CALLER           13630020
         LR    CHKREG,PARMREG      SAVE PARM REG                        13640020
         LR    IQEREG,TAEQJREG     SAVE ADDRESS                         13650020
NEXTIQE  LR    PREVREG,IQEREG      SAVE ADDRESS                         13660020
TESTON   L     IQEREG,IQELNK(PREVREG)   ADDR NEXT IQE                   13670020
         LTR   IQEREG,IQEREG       LAST IQE ON QUEUE?                   13672020
         BM    IQEPRGDN            YES RETURN                           13674020
         L     TCBIQERG,IQETCB(IQEREG)  ADDR TCB FOR THIS IQE           13680020
         LR    TCBREG,FRSTREG      USER'S FIRST TCB                     13690020
COMIQE   CR    TCBIQERG,TCBREG     THIS IQE BELONG TO USER?             13700020
         BE    SAVEQ               YES  REMOVE FROM Q                   13710020
         C     TCBREG,TJBXLAST     USER'S LAST TCB?                     13720020
         BE    NEXTIQE             GET NEXT IQE                         13760020
         L     TCBREG,TCBTCB       ADDR USER'S NEXT TCB                 13770020
         B     COMIQE              PROCESS NEXT TCB                     13780020
SAVEQ    C     IQEREG,WORD(TAEQJREG) IS THIS LAST IQE BEING DEQUEUED    13792020
         BNE   QEMPTY              NO BRANCH                            13794020
         CLC   ZERO(WORD,TAEQJREG),WORD(TAEQJREG) IS FIRST = LAST       13794420
         BNE   T07IQE1             NO BRANCH                            13794820
         MVC   WORD(WORD,TAEQJREG),IQELNK(IQEREG) UPDATE LAST PTR WITH  13796020
*                                  LINK FIELD IQE BEING DEQUEUED        13798020
QEMPTY   MVC   IQELNK(WORD,PREVREG),IQELNK(IQEREG) REMOVE IQE FROM AEQJ 13798420
         CLI   ZERO(TAEQJREG),TAEQMT    QUEUE EMPTY NOW?                13800020
         BNE   TESTON              CONTINUE PROC IQE QUEUE              13802020
IQEPRGDN LR    PARMREG,CHKREG      RESTORE PARM REG                     13802820
IQEPROUT BR    LINKREG             RETURN TO CALLER                     13803620
T07IQE1  ST    PREVREG,WORD(TAEQJREG) UPDTE LAST PTR WITH PREVIOUS IQE  13804420
         B     QEMPTY              CONTINUE DEQUEUING                   13805220
          EJECT                                                         13806020
*                                                                       13806820
* SWAP UNIT RECOVERY ROUTINE                                            13807620
*                                                                       13808420
T07SUR     EQU  *                                                       13809220
* SUM MAIN STORAGE ALLOCATED TO USER                                    13810020
           SR   WR5,WR5                  SUM TO ZERO                    13810820
           SR   WR1,WR1                  CT OF UMSM ENTRIES TO ZERO     13811620
           IC   WR1,TJBUMSMN             CT OF UMSM ENTRIES             13812420
           L    WR2,TJBUMSM              ADDR FIRST ENTRY IN UMSM       13813220
           USING UMSM,WR2                BASE FOR UMSM                  13814020
SUM01      EQU  *                                                       13814820
           LH   WR3,UMSMLN               LEN FROM UMSM ENTRY            13815620
           LTR  WR3,WR3                  Q: LEN = 0?                    13816420
           BZ   CALCSU                   YES, SUMMING COMPLETE          13817220
           SLL  WR3,E8                   CONVERT TO S/360 ADDR          13818020
           AR   WR5,WR3                  ADD THIS LEN TO SUM            13818820
           LA   WR2,E4(WR2)              ADDR NEXT UMSM ENTRY           13819620
           BCT  WR1,SUM01                IF MORE ENTRIES, GO TO TOP     13820420
           DROP WR2                      NO MORE ENTRIES, CONTINUE      13821220
* CALCULATE NUMBER OF SWAP UNITS ALLOCATED THIS USER                    13822020
CALCSU     EQU  *                                                       13822820
           L    SWAPCBR,TJBSDCB          ADDR SWAP CB (DS #1)           13823620
           USING SWAPCBD,SWAPCBR         BASE FOR SWAP CB               13824420
           SR   WR2,WR2                  ZERO EVEN IN EVEN/ODD PAIR FOR 13825220
*                                  DIVIDE                               13826020
           LR   WR3,WR5                  INSERT SUM - ODD IN EVEN/ODD   13826820
*                                  PAIR                                 13827620
           D    WR2,SB3CAPB              DIV SUM BY UNIT CAPACITY IN    13828420
*                                  BYTES                                13829220
           LTR  WR2,WR2                  REMAINDER?                     13830020
           BZ   CALC1                    NO, USE AS IS                  13830820
           LA   WR3,E1(WR3)              ROUND QUOTIENT UP, ='S # SWAP  13831620
*                                  UNITS                                13832420
CALC1     EQU   *                                                       13833220
           L    SUATR,SB3UTSTR           ADDR SWAP UNIT ALLOC TABLE     13834020
           TM   TJBUTTMQ,TJBUTTMP        PARALLEL SWAP?                 13834820
           BO   PARSWAP                   YES                           13835620
           LH   FSTOFSET,TJBUTTMQ        OFFSET TO FIRST ALLOC UNIT     13836420
FREEUNIT EQU    *                                                       13837220
           LH   NEXTUNIT,E0(FSTOFSET,SUATR) GET OFFSET TO NEXT UNIT     13838020
           LR    WORK4,FSTOFSET          OBTAIN INDEX                   13838820
           AR    WORK4,SUATR              INTO SWAP UNIT ALLOC TAB      13839620
           BAL  WR5,FLAGUNIT             FREE UNIT & UP GROSS CT        13840420
           BCT  WR3,GETUNIT              DECREMENT LOOP CT              13841220
           BR   LINKREG                  IF CT = 0, RETURN              13842020
GETUNIT EQU     *                                                       13842820
           LR   FSTOFSET,NEXTUNIT        RECALL NEXT UNIT OFFSET        13843620
           B    FREEUNIT                 CONTINUE FREEING UNITS         13844420
* PROCESS HERE FOR PARALLEL SWAP DATA SETS                              13845220
PARSWAP    EQU  *                                                       13846020
           NI   TJBUTTMQ,ALL-TJBUTTMP CLEAR PARALLEL BIT                13846820
           LH   FSTOFSET,TJBUTTMQ        OFFSET TO FIRST ALLOC UNIT     13847620
PAR1       EQU  *                                                       13848420
           LH   NEXTUNIT,E0(FSTOFSET,SUATR) GET OFFSET TO NEXT UNIT     13849220
           LR    WORK4,FSTOFSET      OBTAIN INDEX INTO                  13850020
           AR    WORK4,SUATR            SWAP UNIT ALLOC TABLE           13850820
           BCTR  WR3,E0              REDUCE LOOP CT BY 1                13851620
           TM   E0(WORK4),SB3UTPDS Q:THIS UNIT ON 2ED DATA SET          13852420
           BO   SWITCHDS                 YES                            13853220
           BAL  WR5,FLAGUNIT             FREE UNIT & UP GROSS CT        13854020
           LR   FSTOFSET,NEXTUNIT        RECALL NEXT UNIT OFFSET        13854820
           B    PAR1                     CONTINUE SEARCH                13855620
SWITCHDS   EQU  *                                                       13856420
           BAL  WR5,FLAGUNIT             FREE UNIT AND UP GROSS CT      13857220
           N     NEXTUNIT,UNITMASK       CLEAR SWITCH SAYING THISA46441 13857621
*                                        UNIT ON 2ED DATA SET    A46441 13857721
           LA   WR5,E4                   SET SUBTRACT CONSTANT          13858020
           SR   SWAPCBR,WR5              PT TO SWAPCB MINUS 4           13858820
           L    SWAPCBR,E0(SWAPCBR)     GET ADDR SWAP CB #2             13859620
           L    SUATR,SB3UTSTR          GET ADDR SWAP UNIT ALLOC TAB #2 13860420
           LR   FSTOFSET,NEXTUNIT  GET OFFSET TO 1ST UNIT IN 2ED DS     13861220
           B    FREEUNIT                 CONTINUE AS IF SERIAL SWAP     13862020
* SUBROUTINE TO FLAG SWAP UNITS AS FREE AND INCREMENT GROSS CT          13862820
FLAGUNIT EQU    *                                                       13863620
           MVI  E0(WORK4),SB3UTAV FLAG UNIT FREE                        13864420
           MVI  E1(WORK4),NOFLG   ZERO REMAINING BYTE                   13865220
           L    COUNT,SB3GRCT            GET GROSS                      13866020
           LA   COUNT,E1(COUNT)          COUNT AND                      13866820
           ST   COUNT,SB3GRCT            ADD ONE                        13867620
           BR   WR5                      RETURN                         13868420
         EJECT                                                          13870020
*     CONSTANTS FOR OUT OF CORE ABEND                                   13880020
         SPACE 4                                                        13890020
         DS    0D                                                       13900020
RETPSW   DC    X'00040000'         MASK FOR PSW                         13910020
         DC    A(RETPOINT)         RETURN POINT FROM TA REFRESH         13920020
SP245    DC    X'F5000000'         MASK FOR SUBPOOL 245                 13930020
SP253    DC    X'FD000000'         SP FOR WORK AND SAVE AREAS           13940020
HIBITOFF DC    X'00007FFF'         MASK TO TURN OFF HI BIT QELTJID1     13960020
MASKFULL DC    X'FFFFFFF8'         MASK TO ROUND UP TO DOUBLE WORD      13970020
UNITMASK DC    X'0000BFFF'         CLEAR SWAP UNIT BIT           A46441 13972021
CLEARHO  DC    X'00000007'         MASK FOR 'AND' INSTR IN WTOR PRGE    13980020
MINAMLNG DC    X'00000007'         MINOR NAME LENGTH MASK     AC A47178 13982021
ENDELMFF DC    F'-1'               CONSTANT TO CHECK FOR DUMMY ELE      13990020
HIBYTOFF DC    X'00FFFFFF'         USED TO TURN OFF HI BYTE    AJ M4911 13990421
DQTBL      DC   X'FF014100'            DEQ PARMS FOR SVC PURGE RESOURCE 13991020
           DC   A(QNAME)                 RET=HAVE                       13992020
           DC   A(RNAME)                 *                              13993020
QNAME      DC   C'SYSIEC16'              *                              13994020
RNAME      DC   X'F0'                    *                              13995020
DISABLE  DC    X'00'               MASK OUT EXTERNAL INTERRUPTS         14000020
ENABLE   DC    X'FF'               ALLOW INTERRUPTS                     14010020
         END                                                            14020020
