         TITLE '   STAX  SVC  SERVICE  ROUTINE'                         00200020
*********************************************************************** 00400020
*                                                                     * 00600020
*  NAME - STAX SVC SERVICE ROUTINE                                    * 00800020
*                                                                     * 01000020
*  STATUS - 0                                                         * 01200020
*A478500,479000,490500,491000                                 AJ A52533 01250021
*C920000                                                      AJ A52533 01300021
*A718500,718520,713056,713076                                 AJ  M5028 01350021
*C722500                                                      AJ  M5028 01360021
*                                                                     * 01400020
*  FUNCTION - STAX IS A TYPE 3 SVC.  THIS SERVICE ROUTINE CREATES,    * 01600020
*             MAINTAINS, AND RELEASES TERMINAL ATTENTION EXIT ELEMENTS* 01800020
*             (TAXES) WHICH CONTAIN INFORMATION FOR SCHEDULING        * 02000020
*             TERMINAL ATTENTION EXITS.  THESE TAXES ARE QUEUED FROM  * 02200020
*             THE TIME SHARING JOB BLOCK EXTENSION (TJBX) AS  THEY    * 02400020
*             ARE CREATED.  TAXES ARE REMOVED FROM THE QUEUE WHEN     * 02600020
*             REQUESTED BY A 'CANCEL'.                                * 02800020
*             THE STAX SERVICE ROUTINE VALIDITY CHECKS THE PARAMETERS * 03000020
*             ON THE STAX MACRO INSTRUCTION SINCE ONLY FOREGROUND     * 03200020
*             TSO TASKS CAN REQUEST AN ATTENTION EXIT.  IT ALSO       * 03400020
*             MAINTAINS A STAX COUNT IN THE TJB                       * 03600020
*                                                                     * 03800020
*  ENTRY POINTS -  IGC0009F                                           * 04000020
*                                                                     * 04200020
*  INPUT -  REGISTER 1 - ADDRESS STAX PARAMETER LIST                  * 04400020
*                        OR 0 FOR CANCEL REQUEST                      * 04600020
*           REGISTER 3 - ADDRESS OF CVT                               * 04800020
*           REGISTER 4 - ADDRESS OF TCB                               * 05000020
*           REGISTER 5 - SVRB ADDRESS                                 * 05200020
*           REGISTER 14 -RETURN ADDRESS                               * 05400020
*           REGISTER 15 -ENTRY POINT ADDRESS                          * 05600020
*                                                                     * 05800020
*           PARAMETER LIST FOR STAX                                   * 06000020
*           ********************************                          * 06200020
*           *       STXEXIT                *                          * 06400020
*           ********************************                          * 06600020
*           *  STXISIZ      *  STXOSIZ     *                          * 06800020
*           ********************************                          * 07000020
*           *       STXOBUF                *                          * 07200020
*           ********************************                          * 07400020
*           *       STXIBUF                *                          * 07600020
*           ********************************                          * 07800020
*           *STXOPTS*      STXUSER         *                          * 08000020
*           ********************************                          * 08200020
*                                                                     * 08400020
*         STXEXIT - ADDRESS OF USER PROGRAM TO GET CONTROL AT         * 08600020
*                   ATTENTION INTERRUPT                               * 08800020
*         STXISIZ - SIZE OF USER'S INPUT BUFFER (MAX 4095)            * 09000020
*         STXOSIZ - SIZE OF USER'S OUTPUT BUFFER (MAX 4095)           * 09200020
*         STXOBUF - ADDRESS OF OUTPUT BUFFER                          * 09400020
*         STXIBUF - ADDRESS OF INPUT BUFFER                           * 09600020
          EJECT                                                         09800020
*         STXOPTS - STAX OTPIONS FLAGS                                * 10000020
*                                                                     * 10200020
*         BIT       MEANING                                           * 10400020
*          0                  RESERVED                                * 10600020
*          1           0      REPLACE = YES SPECIFIED                 * 10800020
*                      1      REPLACE = NO SPECIFIED                  * 11000020
*       2-15                  RESERVED FOR FUTURE USE                 * 11200020
*                                                                     * 11400020
*         STXUSER - ADDRESS OF USER PARAMETERS FOR USER PROGRAM       * 11600020
*                                                                     * 11800020
*         NOTE - TO CANCEL A PREVIOUS STAX MACRO INSTRUCTION, THE     * 12000020
*         EXIT ADDRESS IS OMITTED ON THE STAX MACRO INSTRUCTION;      * 12200020
*         THEN NO PARAMETER LIST WILL BE CREATED.  FOR THIS CASE,     * 12400020
*         REGISTER 1 WILL CONTAIN ZERO.                               * 12600020
*                                                                     * 12800020
*  OUTPUT - REGISTER 1 - THE ADDRESS OF PARAMETER LIST USED TO        * 13000020
*                        SCHEDULE THE PREVIOUS EXIT.  THIS VALUE CAN  * 13200020
*                        BE USED IN THE E-FORM OF THE MACRO TO        * 13400020
*                        RE-ESTABLISH AN EXIT REQUEST.  FOR THE FIRST * 13600020
*                        STAX MACRO ISSUED BY A TASK OR THE FIRST     * 13800020
*                        ISSUED AFTER A 'CANCEL' OPTION, THE STAX     * 14000020
*                        ROUTINE WILL RETURN A ZERO IN REGISTER 1.    * 14200020
*           REGISTERS 2-14 - SAME AS WHEN ENTERED                       14400020
*           REGISTER 15 - RETURN CODES                                * 14600020
*                         0 - SUCCESSFUL EXECTUTION OF STAX ROUTINE   * 14800020
*                         8 - INVALID PARAMETER, STAX IGNORED         * 15000020
*                                                                     * 15200020
*  EXTERNAL REFERENCES - CIRB MACRO                                   * 15400020
*                      A.  TO CREATE TAXE WHICH IS AN IRB, WITH IQE,  * 15600020
*                          REGISTER SAVE AREA AND 12 BYTE WORK AREA.  * 15800020
*                      B.  OPTIONS ON MACRO INSTRUCTION - SUPERVISOR  * 16000020
*                          KEY AND MODE, REUSABLE, SAVE AREA, WORK    * 16200020
*                          AREA OF 12 BYTES.                          * 16400020
*                      C.  RETURN INFORMATION -                       * 16600020
*                                       REGISTER 1 - ADDRESS OF IRB   * 16800020
*                                                                     * 17000020
*  EXITS,NORMAL - RETURN TO CALLER VIA BRANCH ON REGISTER 14          * 17200020
*                                                                     * 17400020
*  EXITS,ERROR - RETURN TO CALLER VIA BRANCH ON REGISTER 14 WITH      * 17600020
*                CODE OF 8 IN REGISTER 15 INDICATING INVALID          * 17800020
*                PARAMETER AND THAT THE STAX MACRO WAS IGNORED        * 18000020
*                                                                     * 18200020
*  TABLES/WORK AREAS - NONE                                           * 18400020
*                                                                     * 18600020
*  ATTRIBUTES - REENTRANT, REFRESHABLE, SUPERVISOR STATE, DISABLED    * 18800021
*                                                                     * 19000020
*********************************************************************** 19200020
          EJECT                                                         19400020
IKJEAX00 START                                                          19600020
        SPACE 2                                                         19800020
*                                                                       20000020
*   STAX PARAMETER LIST                                                 20200020
*                                                                       20400020
STAXPARM DSECT                                                          20600020
STXEXIT  DS    F                  ADDR USER EXIT RTN                    20800020
STXISIZ  DS    H                  SIZE OF INPUT BUFFER                  21000020
STXOSIZ  DS    H                  SIZE OF OUTPUT BUFFER                 21200020
STXOBUF  DS    F                  ADDR OF OUTPUT  BUFFER                21400020
STXIBUF  DS    F                  ADDR OF INPUT BUFFER                  21600020
STXOPTS  DS    0X                 OPTIONS FLAGS                         21800020
STXRPLNO EQU   X'40'              INDICATES CREATE NEW TAXE FOR TCB     22000020
STXDFRYS EQU   X'20'                   INDICATES DEFER ATTENTION EXITS  22060020
STXDFRNO EQU   X'10'               INDICATES CANCEL OF DEFERRALS        22120020
STXUSER  DS    F                  ADDR USER PARAMETER FOR USER RTN      22200020
         EJECT                                                          22400020
*                                                                       26000020
*    REGISTER EQUATES                                                   26200020
*                                                                       26400020
X0       EQU   0                  REGISTER ZERO                         26450020
XSTXPARM EQU   1                  ADDRESS OF STAX PARAMETER LIST        26600020
X1       EQU   1                  REGISTER ONE                          26800020
XNSI     EQU   2                  ADDRESS OF NEXT INSTR. AFTER BAL      27000020
XSAVE    EQU   2                  SAVE REGISTER                         27200020
XSTAX    EQU   2                  STAX COUNT FOR TJB                    27400020
XWORK    EQU   2                  WORK REGISTER                         27600020
XNTAXE   EQU   2                  ADDRESS OF NEXT TAXE                  27800020
XCVT     EQU   3                  ADDRESS OF CVT                        28000020
XSAVTAXE EQU   3                  TAXE SAVE REGISTER          AI A45359 28200021
XTCB     EQU   4                  ADDRESS OF TCB                        28400020
XRB      EQU   5                  ADDRESS OF SVRB                       28600020
XBASE    EQU   6                  BASE REGISTER                         28800020
XBUF     EQU   7                  ADDRESS OF BUFFER                     29000020
XSTCB    EQU   7                  SELECT TCB                  AI A47499 29200021
XINPUT   EQU   7                  INPUT TO VALIDITY CHECK RTN.          29400020
XRETURN  EQU   8                  RETURN REG                            29600020
XVALID   EQU   8                  ADDRESS OF VALIDITY CHECK RTN         29800020
XTAXE    EQU   9                  ADDRESS OF TAXE                       30000020
XTCBV    EQU   9                  TCB ADDR PASSED VALIDITY CHECK RTN    30200020
XWTAXE   EQU   10                 ADDRESS OF TAXE IN WORK REG           30400020
XQTAXE   EQU   10                 ADDRESS OF TAXE USED IN QUEUEING TAXE 30600020
XRETADDR EQU   10                 RETURN REG FROM VALIDITY CHECK RTN    30800020
XJSCB    EQU   11                 ADDRESS OF JSCB                       31000020
XTJID    EQU   11                 TJID                                  31200020
XTJB     EQU   11                 ADDRESS OF TJB                        31400020
XTSCVT   EQU   12                 ADDRESS OF TSCVT                      31600020
XTJBX    EQU   12                 ADDRESS OF TJBX                       31800020
XSIZE    EQU   13                 SIZE OF BUFFERS                       32000020
XRET     EQU   14                 RETURN ADDRESS                        32400020
XWORK15  EQU   15                 WORK REG FOR TCB CHAIN CHK  AI A47499 32500021
XRTCODE  EQU   15                  RETURN CODE - 0 GOOD,                32600020
*                                  4 DEFERRALS HAVE ALREADY BEEN REQ.,  32800020
*                                  8 INVALID                            33000020
         EJECT                                                          33200020
*                                                                       33400020
*    MISCELLANEOUS EQUATES                                              33600020
*                                                                       33800020
ADRERROR EQU   7                  CONDITION CODE FOR ERROR FROM         34010020
*                                 VALIDITY CHECK RTN                    34020020
WORD     EQU   4                  DISPLACEMENT FOR 4 BYTES = 1 WORD     34030020
WORD11   EQU   44                 44 BYTES = 11 WORDS                   34040020
ONE      EQU   1                  MASK OF ONE                           34050020
THREE    EQU   3                  LENGTH OF 3 BYTES                     34060020
FOUR     EQU   4                  USED TO RESTORE CURRENT TCB           34062020
X16      EQU   16                 ADR OF CVT                            34064020
ZERO     EQU   0                  USED TO DECREMENT COUNT               34070020
ZEROKEY  EQU   X'F0'              CALLER KEY ZERO                       34080020
LINK     EQU   X'74'              DISPLACEMENT TAXELNK FIELD IN TAXE    34090020
PMODE    EQU   X'01'              CALLER IN PROBLEM PROGRAM MODE        34100020
RETCODE4 EQU   4                  RETURN CODE, INDICATES DEFER HAS      34600020
*                                 ALREADY BEEN REQUESTED                35100020
ERRORCD  EQU   8                  ERROR CODE - INVALID PARAM  AI  21A72 35300021
LNGESA   EQU   48                 LENGTH OF SVRB EXTENDED S/A AI A45359 35500021
         EJECT                                                          35800020
IGC0009F CSECT                                                          36000020
         BALR  XBASE,ZERO         INITIALIZE BASE REGISTER              36200020
         USING *,XBASE            ESTABLISH ADDRESSABILITY              36400020
         USING STAXPARM,XSTXPARM  ADDRESSABILITY OF STAX PARM LIST      36600020
         USING TCB,XTCB           ADDRESSABILITY OF TCB                 36800020
         USING CVT,XCVT           ADDRESSIBILITY OF CVT                 36850021
         USING RBSECT,XRB         ADDRESSIBILITY CURRENT SVRB AI  21A72 36900021
         XC    RBEXSAVE(LNGESA),RBEXSAVE ZERO OUT ESA AND     AI A45359 36950021
*                                  INITIALIZE PREVIOUS STAX   AI A45359 37000021
*                                  PARAMETER LIST POINTER TO  AI A45359 37050021
*                                  ZERO                       AI A45359 37100021
         TM    TCBTSFLG,TCBTSTSK  IS THIS TSO TASK                      37200020
         BZ    ERROR              NO, ERROR                             37400020
         L     XJSCB,TCBJSCB      ADDR JSCB                             37600020
*                                                             AI        37660021
*        XXXXXXXXXX                                           AI        37720021
         USING IEZJSCB,XJSCB      ADDRESSABILITY OF JSCB                37800020
*        XXXXXXXXXX                                           AI        37803021
*                                                             AI        37806021
         SPACE  5                                                       37810020
*                                                                       38000020
*  COMPUTE ADDR OF TJB FOR THIS TJID BY ADDING THE PRODUCT OF THE     * 38200020
*  TJID AND THE TJB SIZE TO ADDR OF TJB INDEX TABLE                   * 38400020
*                                                                       38600020
         LH    XTJID,JSCBTJID     TJID FROM JSCB                        38800020
         L     XTSCVT,CVTTSCVT    ADDR TSCVT                            39000020
*                                                             AI        39060021
*        XXXXXXXXXX                                           AI        39120021
         USING TSCVT,XTSCVT       ADDRESSABILITY OF TSCVT               39200020
*        XXXXXXXXXX                                           AI        39260021
*                                                             AI        39320021
         MH    XTJID,TSCVTSZU     DISPLACEMENT IN TJB TABLE EQUALS      39400020
*                                 PRODUCT OF TJID AND SIZE OF TJB       39410020
         A     XTJID,TSCVTTJB     ADDR CORRECT TJB FOR THIS TJB         39600020
*                                                             AI        39660021
*        XXXXXXXXXX                                           AI        39720021
         USING TJB,XTJB           ADDRESSABILITY OF TJB                 39800020
*        XXXXXXXXXX                                           AI        39860021
*                                                             AI        39920021
         L     XTJBX,TJBEXTNT     ADDR TJBX                             40000020
*                                                             AI        40060021
*        XXXXXXXXXX                                           AI        40120021
         USING TJBX,XTJBX         ADDRESSABILITY OF TJBX                40200020
*        XXXXXXXXXX                                           AI        40260021
*                                                             AI        40320021
         SPACE  2                                                       40400020
         SR    XSIZE,XSIZE        ZERO SWITCH FOR RETURN CODE           40500020
         LA    XSTXPARM,0(,XSTXPARM) CLEAR HI-BYTE FOR LATER  AI  21A72 40530021
*                                  STORE (SHOULD ALREADY BE 0)AI  21A72 40560021
         LTR   XSTXPARM,XSTXPARM  IS CANCEL INDICATED                   40600020
         BZ    CANCEL1            YES, CANCEL PREVIOUS STAX EXIT        40700020
         SPACE 5                                                        40810020
*                                                                       41000020
*   VALIDITY  CHECK ROUTINE                                             41200020
*                                                                       41400020
         LR    XWORK,XSTXPARM     STAX PARM ADDR INTO WORK REG          41600020
         N     XWORK,FULLWORD     FORCE PARM ADDRESS TO FULL WORD       41800020
         CR    XWORK,XSTXPARM     STAX PARM LST ADDR ON FULL WORD       42000020
         BNE   ERROR              NO, ERROR                             42200020
         TM    STXOPTS,STXDFRYS+STXDFRNO   ANY DEFERRAL BITS SET        42210020
         BZ    NODEFREQ           NO, FURTHER TESTS UNNECESSARY         42220020
         BO    ERROR              BOTH SET, INVALID PARAMETER LIST      42230020
         L     XRTCODE,RBLINK     GET CALLER'S RB                       42250020
*                                                             AI        42253021
*        XXXXXXXXXX                                           AI        42256021
         DROP  XRB                                                      42260020
         USING RBSECT,XRTCODE                                           42270020
*        XXXXXXXXXX                                           AI        42273021
*                                                             AI        42276021
         TM    RBSTAB1,RBFTIRB+RBFTSIRB  IS RB TYPE AN IRB OR SIRB      42280020
         BM    ERROR              YES, CANNOT ASK FOR DEFERRAL          42290020
NODEFREQ EQU   *                                                        42300020
         L     XINPUT,STXEXIT     ADDRESS EXIT RTN                      42400020
         LTR   XINPUT,XINPUT      USER EXIT RTN SPECIFIED               42600020
         BZ    CANCEL             NO,CANCEL REQUEST                     42800020
         EJECT                                                          43210020
*                                                                       43400020
*     VALIDITY CHECK BUFFERS                                            43600020
*                                                             AI        43620021
*                                                             AI        43640021
* THIS ROUTINE VALIDITY CHECKS THE ADDRESS AND LENGTH OF THE  AI        43660021
* INPUT BUFFER. IT ALSO CHECKS THE LENGTH OF THE OUTPUT       AI        43680021
*  BUFFER BUT NOT ITS ADDRESS SINCE THE MESSAGE SENT TO       AI        43700021
* THE USER AT THE BEGINNING OF THE ATTENTION EXIT'S           AI        43720021
* PROCESSING MAY BE INSIDE A REENTRANT PROGRAM.               AI        43740021
*                                                             AI        43760021
*                                                                       43800020
         LR    XTCBV,XTCB         ADDRESS OF TCB TO PASS VALIDITY CHECK 44000021
         L     XVALID,CVT0VL00    ADDRESS OF VALIDITY CHECK RTN         44200021
*                                                                       44400021
*        XXXXXXXXXX                                                     44600021
         DROP  XCVT               DROP ADDRESSIBILITY OF CVT  AI        44800021
*        XXXXXXXXXX                                                     45000021
*                                                                       45200021
         L     XBUF,STXIBUF       ADDRESS OF INPUT BUFFER               45400020
         LTR   XBUF,XBUF          INPUT BUFFER SPECIFIED                45600020
         BZ    BUFSIZE            NO,CHECK LENGTH OF OUTPUT BUFFER      45800020
         BAL   XNSI,VALIDCK       YES,VALIDITY CHECK INPUT BUF ADDR     46000020
         L     XBUF,STXIBUF       ADDRESS OF INPUT BUFFER               46050020
         AH    XINPUT,STXISIZ     ADDRESS OF END OF BUFFER              46200020
         BCTR  XINPUT,ZERO        DECREMENT ADDRESS ONE BYTE            46400020
         LA    XNSI,BUFSIZE       ADDRESS OF PLACE TO RETURN            46600020
VALIDCK  EQU   *                                                        46800020
         BALR  XRETADDR,XVALID    BRANCH TO SYSTEM VALIDITY CK RTN      47000020
         BC    ADRERROR,ERROR     INVALID ADDRESS - GO TO ERROR EXIT    47200020
         BR    XNSI               RETURN TO CALLER                      47400020
BUFSIZE  EQU   *                                                        47600020
         L     XBUF,STXOBUF       ADDR OF OUTPUT BUFFERS                47650020
         LTR   XBUF,XBUF          OUTPUT BUFFER SPECIFIED               47700020
         BZ    BUFSIZE1           NO CHECK INPUT BUFFER                 47750020
         LH    XSIZE,STXOSIZ      SIZE OUTPUT BUFFER                    47800020
         LTR   XSIZE,XSIZE         SEE IF HIGH ORDER BYTE ON  AJ A52533 47850021
         BM    ERROR              IF SO RETURN CODE-ERROR     AJ A52533 47900021
         CH    XSIZE,MAXSIZE      SIZE VALID                            48000020
         BH    ERROR              NO, SIZE TOO LARGE                    48200020
BUFSIZE1 L     XBUF,STXIBUF       ADDR INPUT BUFFER                     48400020
         LTR   XBUF,XBUF          INPUT BUFFER SPECIFIED                48600020
         BZ    NOBUFFER           NO, SKIP BUFFER VALIDITY CHECK        48800020
         LH    XSIZE,STXISIZ      SIZE INPUT BUFFER                     49000020
         LTR   XSIZE,XSIZE        SEE IF HIGH ORDER BIT IS ON AJ A52533 49050021
         BM    ERROR              IF SO RETURN ERROR CODE     AJ A52533 49100021
         CH    XSIZE,MAXSIZE      SIZE VALID                            49200020
         BH    ERROR              NO, EXCEEDS MAX ALLOWED               49400020
         B     TAXEQCK            BRANCH TO CHECK TAXE QUEUE            49600020
         EJECT                                                          49610020
*                                                                       49800020
*  CHECK FOR TAXES ON QUEUE AND A CANCEL REQUEST                        50000020
*                                                                       50200020
CANCEL   EQU   *                                                        50400020
NOBUFFER EQU   *                                                        50402020
TAXEQCK  EQU   *                                                        50404020
         SR    XSIZE,XSIZE        ZERO RETURN CODE 4 SWITCH             50410020
         TM    STXOPTS,STXDFRYS+STXDFRNO   ANY DEFERRAL BITS SET        50420020
         BZ    CANCEL2            NO, BYPASS ALL DEFERRAL ACTION        50430020
         TM    STXOPTS,STXDFRYS   IS DEFER = YES                        50440020
         BO    DFRTSTRB           YES, TEST IF BIT IS ALREADY ON        50450020
         NI    RBSTAB2,255-RBATTN TURN OFF DEFER BIT IN RB              50460020
         B     CANCELTS           CHECK PARAMETER LIST FOR EXIT ADDR    50470020
RTCOD4TS EQU   *                                                        50480020
         LA    XSIZE,RETCODE4     SET UP RETURN CODE OF 4 TO INDICATE   50490020
         B     CANCELTS           DEFER HAD ALREADY BEEN REQUESTED      50500020
DFRTSTRB EQU   *                                                        50510020
         TM    RBSTAB2,RBATTN     IS BIT ALREADY ON                     50520020
         BO    RTCOD4TS           YES, SET UP FOR RETURN CODE OF 4      50530020
         OI    RBSTAB2,RBATTN     SET DEFER BIT IN RB                   50540020
*                                                             AI        50543021
*        XXXXXXXXXX                                           AI        50546021
         DROP  XRTCODE                                                  50550020
*        XXXXXXXXXX                                           AI        50553021
*                                                             AI        50556021
CANCELTS EQU   *                                                        50560020
         NC    STXEXIT(4),STXEXIT IS AN EXIT ADDRESS SPECIFIED IN LIST  50570020
         BNZ   CANCEL1            YES, GO ACT ON LIST                   50580020
*                                                             AI        50583021
* AT THIS TIME NO PREVIOUS STAX PARAMETER LIST ADDRESS CAN BE AI A45359 50586021
* RETURNED BECAUSE NONE WAS AVAILABLE. 'PREVSTAX' IN THE ESA  AI A45359 50589021
* IS STILL ZERO FROM THE INITIAL CLEARING OF THE SVRB ESA.    AI A45359 50592021
*                                                             AI        50595021
         B     COMPLETE           WITHOUT AN ADDRESS IN REG 1           50600020
CANCEL2  EQU   *                                                        50610020
         NC    STXEXIT(4),STXEXIT IS AN EXIT ADDRESS SPECIFIED IN LIST  50620020
         BNZ   CANCEL1            YES, BYPASS INDICATION OF CANCEL      50630020
         SR    XSTXPARM,XSTXPARM  INDICATE CANCEL REQUEST               50640020
CANCEL1  EQU   *                                                        50650020
*                                                             AI A45359 51150021
         LA    XWTAXE,TJBXTAXE    ADDRESS OF LINK FIELD FOR CANCEL      51800020
         L     XTAXE,TJBXTAXE     ADDR FIRST TAXE ON QUEUE              52000020
         LTR   XTAXE,XTAXE        ANY EXISTING TAXES                    52200020
         BNZ   SRCHQ              YES,BRANCH TO SEARCH QUEUE FOR A      52400020
*                                 TAXE FOR THIS TASK                    52600020
         LTR   XSTXPARM,XSTXPARM  CANCEL REQUEST                        52800020
         BZ    COMPLETE           YES, BUT NO TAXES THEREFORE RETURN    53000020
*                                  NO PREV STAX PARM AVAIL    AI A45359 53100021
         BAL   XRETURN,GETTAXE    BRANCH TO OBTAIN TAXE AND INITIALIZE  53200020
         ST    XTAXE,TJBXTAXE     PLACE TAXE AT TOP OF QUEUE            53400020
         BAL   XRETURN,INCRSTAX   BUMP THE STAX COUNT         AI  2A472 53500021
         SPACE 5                                                        53600021
*                                                             AI        53700021
* BEFORE RETURNING CONTROL TO THE USER, REGISTER 1 MUST BE    AI        53800021
* LOADED WITH THE ADDRESS OF THE PREVIOUS STAX PARAMETER LIST AI        53900021
* OR ZERO. THE PROPER VALUE AT THIS TIME IS IN THE FIRST WORD AI A45359 54000021
* OF THE SVRB EXTENDED SAVE AREA.  THE PROPER RETURN CODE     AI A45359 54100021
* MUST BE PUT IN REGISTER 15. IT IS NOW IN REGISTER 13.       AI        54200021
*                                                             AI        54300021
COMPLETE EQU   *                                                        54400020
*                                                             AI        54480021
*        XXXXXXXXXX                                           AI        54560021
         USING RBSECT,XRB         ADDRESS OF CURRENT SVRB     AI A45359 54640021
*        XXXXXXXXXX                                           AI        54720021
*                                                             AI        54800021
         L     X1,PREVSTAX        ADDR OF PREV STAX PARM LIST AI A45359 54880021
         LR    XRTCODE,XSIZE      SUCCESSFUL RETURN CODE                55000020
         BR    XRET               RETURN TO CALLER                      55200020
         SPACE 5                                                        55300021
ERROR    EQU   *                                                        55400020
         LA    XRTCODE,ERRORCD    PASS BACK ERROR CODE        AI  21A72 55600021
         BR    XRET               RETURN TO CALLER                      55800020
         EJECT                                                          56000020
*                                                                       56200020
*   SEARCH TAXE QUEUE FOR EXISTING TAXES FOR THIS TASK                  56400020
*                                                                       56600020
*                                                             AI        56660021
*        XXXXXXXXXX                                           AI        56720021
         USING TAXE,XTAXE         ADDRESSABILITY OF TAXE                56800020
*        XXXXXXXXXX                                           AI        56860021
*                                                             AI        56920021
SRCHQ    EQU   *                                                        57000020
         C     XTCB,TAXETCB       TAXE FOR THIS TASK                    57200020
         BE    TAXEFND            YES, TAXE IS FOR THIS TASK            57400020
         LA    XWTAXE,TAXELNK     ADDRESS OF LINK FIELD FOR CANCEL      57600020
         L     XTAXE,TAXELNK      ADDR NEXT TAXE                        57800020
         LTR   XTAXE,XTAXE        ANY MORE TAXES ON QUEUE               58000020
         BNZ   SRCHQ              YES,CONTINUE TO SEARCH TAXE QUEUE     58200020
         LTR   XSTXPARM,XSTXPARM  IS CANCEL REQUEST SPECIFIED           58400020
         BZ    COMPLETE           NO CANCEL AND NO TAXE FOR THIS TASK   58600020
         B NOTAXE                 NO TAXE FOUND                         58800020
TAXEFND  EQU   *                                                        59000020
         LTR   XSTXPARM,XSTXPARM  IS CANCEL REQUESTED                   59200020
         BZ    CANCLRTN           YES, BRANCH TO CANCEL CURRENT TAXE    59400020
         MVC   PREVSTAX+ONE(THREE),TAXEPARM+ONE MUST PASS     AI A45359 59460021
*                                  USER THE PREVIOUS STAX     AI A45359 59520021
*                                  PARAMETER LIST ADDRESS     AI A45359 59580021
*                                                             AI        59640021
*        XXXXXXXXXX                                           AI        59700021
         DROP  XRB                END ADDR OF CURRENT SVRB    AI A45359 59760021
*        XXXXXXXXXX                                           AI        59820021
*                                                             AI        59880021
         TM    STXOPTS,STXRPLNO   IS REPLACE REQUESTED                  60000020
         BZ    REPLACE            YES, REPLACE CURRENT TAXE             60200020
NOTAXE   EQU   *                                                        60400020
         BAL   XRETURN,GETTAXE    GET AND INITIALIZE NEW TAXE           60600020
         BAL   XRETURN,QTAXE      BRANCH TO QUEUE NEW TAXE              60800020
         B     COMPLETE           PROCESSING COMPLETE                   61000020
         EJECT                                                          61200020
*                                                                       61400020
*  REPLACE PREVIOUS TAXE FOR THIS TASK WITH NEW TAXE                    61600020
*                                                                       61800020
*                                                             AI        61809021
* THIS ROUTINE IS ENTERED TO REPLACE A PREVIOUS ATTENTION     AI        61818021
* REQUEST. IF THE TAXE TO BE REPLACED IS NOT ACTIVE, THE      AI        61827021
* PERTINENT FIELDS IN THE EXISTING TAXE ARE OVERLAID WITH THE AI        61833021
* SAME AVAILABILITY STATUS AS THE ONE BEING REPLACED. IF THE  AI        61839021
* TAXE IS ACTIVE, THE ACTIVE TAXE IS MARKED TO BE FREED AT    AI        61845021
* EXIT. A NEW TAXE IS BUILT WITH THE APPROPRIATE INFORMATION  AI        61854021
* AND THE TAXE IS QUEUED IMMEDIATELY BEFORE THE THE TAXE JUST AI A47499 61863021
* MARKED TO BE FREED AT EXIT. THE NEW TAXE IS MARKED NOT      AI A47499 61872021
* AVAILABLE. IN NEITHER CASE IS THE STAX COUNT CHANGED        AI A47499 61881021
*                                                             AI A47499 61890021
* NOTE- PRIOR TO RELEASE 21, THE NEW TAXE WAS QUEUED AFTER    AI A47499 61899021
* THE ACTIVE TAXE, IT WAS MARKED AVAILABLE, AND THE STAX      AI A47499 61908021
* COUNT WAS INCREMENTED.                                      AI A47499 61917021
*                                                             AI        61926021
*    INPUT REGS -                                             AI        61935021
*                 1 XSTXPARM  STAX PARAMETER LIST ADDRESS     AI        61944021
*                 6 XBASE     BASE ADDRESS                    AI        61953021
*                 9 XTAXE     TAXE TO BE REPLACED             AI        61962021
*                 A XWTAXE    PREVIOUS TAXE QUEUE POINTER     AI        61971021
*                                                             AI        61980021
REPLACE  EQU   *                                                        62000020
*                                                             AI        62060021
*        XXXXXXXXXX                                           AI        62120021
         DROP  XTAXE              DROP ADDRESSABILITY OF TAXE           62200020
         USING RBSECT,XTAXE       ADDRESSABILITY OF TAXE(IRB)           62400020
*        XXXXXXXXXX                                           AI        62460021
*                                                             AI        62520021
         TM    RBSTAB2,RBFACTV    IS THIS TAXE ON TCB RB Q              62600020
         BO    DEACTVTX           YES, ALLOW TAXE BE FREED AT EXIT      62800020
*                                                             AI        62860021
*        XXXXXXXXXX                                           AI        62920021
         DROP  XTAXE              DROP ADDRESSABILITY OF TAXE(IRB)      63000020
         USING TAXE,XTAXE         ADDRESSABILITY OF TAXE                63200020
*        XXXXXXXXXX                                           AI        63260021
*                                                             AI        63320021
         MVC   TAXEIBUF,STXIBUF   UPDATE INPUT BUFFER ADDR IN TAXE      63400020
         MVC   TAXEUSER+ONE(THREE),STXUSER+ONE UPDATE USER PARM ADDR    63600020
         MVC   TAXEEXIT,STXEXIT   UPDATE USER RTN ADDR                  63800020
         TM    TAXESTAT,TAXEFREQ  Q. IS OLD TAXE UNAVAILABLE? AI A47499 63840021
         ST    XSTXPARM,TAXEPARM  UPDATE TAXE TO NEW STAX     AI        63880021
*                                  PARAMETER LIST ADDRESS     AI        63960021
         BZ    SKIPFREQ           NO. KEEP OLD STATUS ON NEW  AI A47499 63980021
         OI    TAXESTAT,TAXEFREQ  YES. MAKE NEW ONE UNAVAIL   AI A47499 64000021
SKIPFREQ EQU   *                                              AI A47499 64020021
*                                                             AI        64040021
*        XXXXXXXXXX                                           AI        64120021
         USING RBSECT,XRB          ADDRESS OF CURRENT RB      AI A51203 64400021
*        XXXXXXXXXX                                           AI        64460021
*                                                                       64510021
         L     XWORK,RBLINK        ADDR OF PREVIOUS RB        AI A51203 64560021
*                                                                       64570021
*        XXXXXXXXXX                                                     64580021
         DROP  XRB                 END OF CURRENT RB'S ADDR   AI A51203 64590021
         USING RBSECT,XWORK        ADDRESS OF CALLERS RB      AI A51203 64592021
*        XXXXXXXXXX                                           AI        64594021
*                                                                       64596021
         TM    RBOPSW+ONE,ZEROKEY CALLER PSW IN ZERO KEY                64600020
         BZ    SKIPK              SKIP SETTING KEY IN TAXE              64800020
         OI    TAXESTAT,TAXEFKEY  INDICATE KEY IN TAXE                  65400020
SKIPK    EQU   *                                                        66000020
         TM    RBOPSW+ONE,PMODE   CALLER IN PROBLEM STATE               66200020
         BZ    COMPLETE           SKIP SETTING MODE IN TAXE             66400020
*                                                             AI        66460021
*        XXXXXXXXXX                                           AI        66520021
         DROP  XWORK              DROP  ADDRESS CALLING RB    AI A51203 66600021
*        XXXXXXXXXX                                           AI        66860021
*                                                             AI        66920021
         OI    TAXESTAT,TAXEFMOD  INDICATE MODE IN TAXE                 67000020
         B     COMPLETE           PROCESSING COMPLETE                   67010020
*                                                             AI        67110021
*        XXXXXXXXXX                                           AI        67210021
         DROP  XTAXE              DROP ADDRESSABILITY OF TAXE           67400020
         USING RBSECT,XTAXE       ADDRESSABILITY OF TAXE(IRB)           67600020
*        XXXXXXXXXX                                           AI        67650021
*                                                             AI        67700021
         SPACE 3                                              AI        67750021
DEACTVTX EQU   *                                                        67800020
         OI    RBSTAB2,RBFDYN     SET DYN FLAG ,SO FREE RB AT EXIT      68000020
         BAL   XRETURN,GETTAXE    BRANCH GET ANOTHER TAXE FOR TASK      68400020
         MVC   LINK(WORD,XTAXE),ZERO(XWTAXE) SET UP LINK      AI A45359 68450021
*                                  FIELD OF NEW TAXE          AI A45359 68500021
         ST    XTAXE,ZERO(,XWTAXE) UPDATE PREVIOUS TAXE'S PTR AI A47499 68550021
*                                                             AI        68600021
*        XXXXXXXXXX                                           AI        68650021
         DROP  XTAXE              DROP ADDRESSIBILITY ON IRB  AI A47499 68700021
         USING TAXE,XTAXE          & PICK UP AS TAXE          AI A47499 68750021
*        XXXXXXXXXX                                           AI        68800021
*                                                             AI        68850021
         OI    TAXESTAT,TAXEFREQ  MAKE TAXE UNAVAILABLE       AI A47499 68900021
*                                                             AI        68950021
*        XXXXXXXXXX                                           AI        69000021
         DROP  XTAXE              DROP OLD ADDRESSIBILITY     AI        69050021
*        XXXXXXXXXX                                           AI        69100021
*                                                             AI        69150021
* DON'T UPDATE STAX COUNT SINCE TAXE IS UNAVILIBLE UNTIL THE  AI A47499 69200021
* REPLACED RB EXITS.                                          AI A47499 69250021
*                                                             AI        69300021
         B     COMPLETE           PROCESSING COMPLETE                   69460020
         EJECT                                                          69600020
*                                                                       69800020
*  CANCEL TAXE ROUTINE                                                  70000020
*                                                                       70200020
*                                                             AI        70210021
* THIS ROUTINE IS ENTERED TO CANCEL A TAXE WHICH IS KNOWN TO  AI        70220021
* BE ON THE TAXE QUEUE. IF THE TAXE IS CURRENTLY BEING USED,  AI        70230021
* IT IS MARKED TO BE FREED AT EXIT AND ITS PSW IS SET TO      AI        70240021
* FORCE IT THRU EXIT. IF THE TAXE IS NOT BEING USED, IT IS    AI        70250021
* MANUALLY DEQUEUED AND FREED.                                AI        70260021
*                                                             AI        70270021
*    INPUT REGS -                                             AI        70280021
*                 6 XBASE     BASE ADDRESS                    AI        70290021
*                 9 XTAXE     TAXE TO BE CANCELLED            AI        70300021
*                 A XWTAXE    ADDR OF POINTER TO SUBJECT TAXE AI        70310021
*                 B XTJB      TJB ADDR                        AI        70320021
*                 C XTJBX     TJBX ADDR                       AI        70330021
*                                                             AI        70340021
CANCLRTN EQU   *                                                        70400020
*                                                             AI        70460021
*        XXXXXXXXXX                                           AI        70520021
         USING RBSECT,XTAXE       ADDRESSABILITY OF TAXE(IRB)           70600020
*        XXXXXXXXXX                                           AI        70660021
*                                                             AI        70720021
         OI    RBSTAB2,RBFDYN     SET DYN FLAG SO FREE RB AT EXIT       70800020
*                                  IN CASE IQE IS BEING       AI        70860021
*                                  PROCESSED                  AI        70920021
         TM    RBSTAB2,RBFACTV    IS RB ON TCB Q                        71000020
         BO    COMPLETE           YES, PROCESSING COMPLETE              71200020
*                                                             AI        71202021
*        XXXXXXXXXX                                           AI        71204021
         DROP  XTAXE              DROP ADDRESSABILITY OF IRB            71206420
         USING TAXE,XTAXE         SET UP ADDRESSABILITY OF TAXE         71206820
*        XXXXXXXXXX                                           AI        71206921
*                                                             AI        71207021
         LA    X1,TIQELNK         GET ADDR NEXT IQE                     71207220
         C     X1,TJBXAIQE        IS IT IQE CURRENTLY BEING PROC        71207620
         BNE   CONTDQ             NO. CONTINUE DEQUEUEING     AI        71213621
*                                                             AI        71219621
*        XXXXXXXXXX                                           AI        71225621
         DROP  XTAXE              DROP ADDRESSIBILITY OF TAXE AI        71231621
         USING RBSECT,XTAXE       SET UP ADDR OF IRB          AI        71237621
*        XXXXXXXXXX                                           AI        71243621
*                                                             AI        71249621
         L     X1,CVTPTR          GET ADDR OF CVT             AI        71255621
*                                                             AI        71261621
*        XXXXXXXXXX                                           AI        71267621
         USING CVT,X1             SET UP ADDR OF CVT          AI        71273621
*        XXXXXXXXXX                                           AI        71279621
*                                                             AI        71285621
         LA    X1,CVTEXIT         GET ADDRESS OF SVC 3(EXIT)  AI        71291621
         ST    X1,RBOPSW+WORD      IN CVT & PLACE IN RESUME   AI        71297621
*                                  PSW OF RB TO CANCEL        AI        71303621
         ST    X1,RBEP             PLACE IN ENTRY PT FOR EXIT AJ  M5028 71305621
*                                    EFFECTOR WHEN SCHED IQE  AJ  M5028 71307621
*                                                             AI        71309621
*        XXXXXXXXXX                                           AI        71315621
         DROP  X1                                             AI        71321621
*        XXXXXXXXXX                                           AI        71327621
*                                                             AI        71333621
*                                                             AI 21A72  71339621
         B     COMPLETE           PROCESSING FINISHED         AI        71345621
*                                                             AI        71351621
*        XXXXXXXXXX                                           AI        71357621
         DROP  XTAXE              DROP ADDR OF TAXE(IRB)      AI        71363621
         USING TAXE,XTAXE         ADDRESSABILITY OF TAXE      AI        71369621
*        XXXXXXXXXX                                           AI        71375621
*                                                             AI        71381621
CONTDQ   EQU   *                                                        71400020
         L     X1,TAXEIRB         GET ADR SAVE AREA GETMAINED           71650020
*                                 BY CIRB MACRO                         71700020
         L     X0,SP250           GET LENGTH AND SP OF SVE AREA         71750020
         FREEMAIN R,LV=(0),A=(1)  FREE SAVE AREA                        71760020
         MVC   ZERO(WORD,XWTAXE),TAXELNK   DEQUEUE TAXE                 71800020
         TM    TAXESTAT,TAXEFREQ   IS TAXE AVAILABLE           AJ M5028 71850021
         BO    NODEC            NO,UNAVIL DON'T DECREMENT CNT  AJ M5028 71852021
         SR    XSTAX,XSTAX        ZERO REG FOR STAX  COUNT              71860021
         IC    XSTAX,TJBSTAX      CURRENT STAX COUNT                    71920021
         BCTR  XSTAX,ZERO         DECREMENT STAX COUNT                  72000020
         STC   XSTAX,TJBSTAX      STORE UPDATE STAX COUNT               72200020
NODEC    LA    X0,LTAXE           GET LENGTH OF TAXE           AJ M5028 72250021
         O     X0,SP253           INDICATE SUBPOOL 253                  72300020
         LR    X1,XTAXE           GET ADDR OF TAXE CANCELLING           72350020
         FREEMAIN R,LV=(0),A=(1)  FREE TAXE CANCELLING                  72360020
         B     COMPLETE           PROCESSING COMPLETE                   72400020
         EJECT                                                          72600020
*                                                                       72800020
*  OBTAIN AND INITIALIZE TAXE FROM SUBPOOL 253                          73000020
*                                                                       73200020
*                                                             AI        73208021
* THIS SUBROUTINE IS ENTERED TO CREATE AND INITIALIZE A TAXE  AI        73216021
* IF A NEW ATTENTION EXIT IS SPECIFIED OR IF THE STAX IS TO   AI        73224021
* REPLACE A TAXE WHOSE ATTENTION EXIT IS CURRENTLY ACTIVE.    AI        73232021
*                                                             AI        73240021
*    INPUT REGS -                                             AI        73248021
*                 1 XSTXPARM  STAX PARAMETER LIST ADDRESS     AI        73256021
*                 4 XTCB      CURRENT TCB                     AI        73264021
*                 5 XRB       CURRENT SVRB                    AI        73272021
*                 6 XBASE     BASE ADDRESS                    AI        73280021
*                 8 XRETURN   RETURN TO MAINLINE ADDRESS      AI        73288021
*                                                             AI        73296021
*   OUTPUT REGS -                                             AI        73304021
*                 ALL INPUT REGS                              AI        73312021
*                 9 XTAXE     ADDR OF CREATED TAXE            AI        73320021
*                                                             AI        73328021
* DESTROYS REGS -                                             AI        73336021
*                 0                                           AI        73344021
*                 2                                           AI        73352021
*                 F (POSSIBLE ACROSS CIRB)                    AI        73360021
*                                                             AI        73368021
*   UNUSED REGS - 3,7,A,B,C,D,E                               AI        73376021
*                                                             AI        73384021
GETTAXE  EQU   *                                                        73400020
*                                                             AI        73410021
*        XXXXXXXXXX                                           AI        73420021
         USING STAXPARM,XSTXPARM  SET UP ADDRESSABILITY FOR STAX LIST   73450020
*        XXXXXXXXXX                                           AI        73550021
*                                                             AI        73650021
         LR    XSAVE,XSTXPARM .   SAVE STAX PARM LST ADDR               73800020
         CIRB  EP=PROLOG,KEY=SUPR,MODE=SUPR,STAB=RE,SVAREA=YES,        *74000020
               WKAREA=6                                                 74200020
         LR    XTAXE,X1           ADDR OF NEW TAXE                      74600020
         LR    XSTXPARM,XSAVE     RESTORE STAX PARM LST ADDR            75000020
         XC    TIQELNK(WORD11),TIQELNK  CLEAR IQE AND WORK AREA         75200020
         ST    XTCB,TAXETCB       TCB ADDR                              75400020
         ST    XSTXPARM,TAXEPARM  ADDR STAX PARM LST                    75600020
         ST    XTAXE,TIQEPARM     ADDR OF TAXE PASSED TO ATTN PROLOGUE  75800020
         MVC   TAXEIBUF,STXIBUF   INPUT BUFFER ADDR INTO TAXE           76000020
         ST    XTAXE,TIQEIRB      ADDR IRB INTO IQE                     76200020
         MVC   TAXEUSER+ONE(THREE),STXUSER+ONE USER PARAMETER INTO TAXE 76400020
         MVC   TAXEEXIT,STXEXIT   ADDR EXIT RTN INTO TAXE               76600020
*                                                             AI        76660021
*        XXXXXXXXXX                                           AI        76720021
         DROP  XTAXE              DROP ADDRESSABILITY OF TAXE           76800020
         USING RBSECT,XTAXE       ADDRESSABILITY OF TAXE(IRB)           77000020
*        XXXXXXXXXX                                           AI        77060021
*                                                             AI        77120021
         OI    RBSTAB2,RBATTN     TURN ON ATTENTION FLAG                77200020
*                                                             AI        77260021
*        XXXXXXXXXX                                           AI        77320021
         DROP  XTAXE              DROP ADDRESSABILITY OF TAXE(IRB)      77400020
         USING RBSECT,XRB         ADDRESSABILITY OF RB                  77600020
*        XXXXXXXXXX                                           AI        77660021
*                                                             AI        77720021
         L     XWORK,RBLINK       ADDR PREVIOUS RB                      77800020
         LA    XWORK,ZERO(,XWORK) ZERO HIGH ORDER BYTE        AI  21A72 77900021
*                                                             AI        78000021
*        XXXXXXXXXX                                           AI        78100021
         DROP  XRB                DROP ADDRESSABILITY OF RB             78200020
         USING RBSECT,XWORK       ADDRESSABILITY OF RB                  78400020
*        XXXXXXXXXX                                           AI        78460021
*                                                             AI        78520021
         TM    RBOPSW+ONE,ZEROKEY CALLER PSW IN ZERO KEY                78600020
         BZ    KEYSKIP            YES,SKIP SETTING KEY IN TAXE          78800020
*                                                             AI        78860021
*        XXXXXXXXXX                                           AI        78920021
         USING TAXE,XTAXE         ADDRESSABILITY OF TAXE                79000020
*        XXXXXXXXXX                                           AI        79060021
*                                                             AI        79120021
         OI    TAXESTAT,TAXEFKEY  INDICATE KEY IN TAXE                  79200020
KEYSKIP  EQU   *                                                        79400020
         TM    RBOPSW+ONE,PMODE   CALLER IN PROBLEM STATE               79600020
         BZ    MODESKIP           NO,SKIP SETTING MODE                  79800020
         OI    TAXESTAT,TAXEFMOD  INDICATE PROBLEM MODE                 80000020
MODESKIP EQU   *                                                        80200020
         BR    XRETURN            RETURN TO CALLER                      80400020
         EJECT                                                          80600020
*                                                                       80800020
* PLACE NEW TAXE ON TAXE QUEUE                                          81000020
*                                                                       81200020
*                                                             AI        81250021
* THIS SUBROUTINE IS USED TO Q A NEWLY CREATED TAXE TO ITS    AI A47499 81300021
* PROPER PLACE ON THE TAXE QUEUE. IF THE NEW TAXE IS NOT TO   AI A47499 81350021
* REPLACE A CURRENTLY ACTIVE TAXE, I.E. ANOTHER ATTENTION     AI A47499 81400021
* LEVEL IS REQUESTED, THE TAXE SHOULD BE PLACED ON THE QUEUE  AI A47499 81450021
* AS INDICATED BY THE FOLLOWING TWO RULES.                    AI A47499 81500021
*  1. AN ATTENTION EXIT ROUTINE FOR A TASK WILL ALWAYS OCCUPY AI A47499 81550021
*     A HIGHER ATTENTION LEVEL THAN THE ATTENTION EXIT        AI A47499 81600021
*     ROUTINE OF ANY OF ITS SUBTASKS.                         AI A47499 81650021
*  2. THE ATTENTION EXIT ROUTINE IS PLACED AT THE LOWEST      AI A47499 81700021
*     POSSIBLE ATTENTION LEVEL, WITHOUT VIOLATING RULE 1.     AI A47499 81750021
* THESE TWO RULES ARE DESIGNED TO ELIMINATE INTERLOCKS WHEN A AI A47499 81800021
* SUBTASK IS SET NON-DISPATCHABLE ACROSS AN ATTENTION EXIT    AI A47499 81850021
* AND ANOTHER ATTENTION IF FIELDED.                           AI A47499 81900021
*                                                             AI A47499 81950021
* NOTE- THIS SUBROUTINE IS NOT USED FOR A STAX WITH           AI A47499 82000021
* REPLACE=YES                                                 AI A47499 82050021
*                                                             AI A47499 82100021
* THE GENERAL METHOD USED IN THE ALGORITHM IS TO ASSUME THAT  AI A47499 82150021
* THE TAXE GOES AT THE BEGINNING OF THE TAXE QUEUE UNLESS ONE AI A47499 82200021
* OF THE CURRENTLY QUEUED TAXES IS FOR A TASK WHICH IS A      AI A47499 82250021
* DESCENDANT OF THE CURRENT TASK (WHICH IS MAKING THE STAX    AI A47499 82300021
* REQUEST). THE TAXE IS ASUMED TO GO BEHIND THE DESCENDANT'S  AI A47499 82350021
* TAXE UNLESS ANOTHER DESCENDANT IS HIGHER ON THE QUEUE.      AI A47499 82400021
* THE SEARCH OF THE TAXE QUEUE IS TERMINATED BY ONE OF THREE  AI A47499 82450021
* CONDITIONS AND THE TAXE IS QUEUED AFTER THE ASSUMED PLACE   AI A47499 82500021
* ON THE QUEUE. THE THREE CONDITIONS ARE AS FOLLOWS.          AI A47499 82550021
*  1. ALL TAXES ON THE QUEUE CHECKED.                         AI A47499 82600021
*  2. A TAXE ON THE QUEUE IS FOUND WHICH IS FOR THE CURRENT   AI A47499 82650021
*     TCB.                                                    AI A47499 82700021
*  3. A TAXE ON THE QUEUE IS FOUND WHICH IS FOR THE MOTHER OF AI A47499 82750021
*     THE CURRENT TCB.                                        AI A47499 82800021
*                                                             AI A47499 82850021
* NOTE- CONDITION 1 IS SUFFICIENT IN ITSELF. CONDITIONS 2 & 3 AI A47499 82900021
* ARE MERELY USED TO ELIMINATE A TOTAL QUEUE SEARCH FOR THE   AI A47499 82950021
* MOST LIKLEY SITUATIONS IN WHICH THE TOTAL QUEUE NEED NOT BE AI A47499 83000021
* SEARCHED.                                                   AI A47499 83050021
*                                                             AI A47499 83100021
* THIS SUBROUTINE HAS AN INTERNAL SUBROUTINE 'INCRSTAX' WHICH AI A47499 83150021
* IS ENTERED FROM OTHER PLACES IN THE MODULE.                 AI A47499 83200021
*                                                             AI A47499 83250021
*    INPUT REGS -                                             AI A47499 83300021
*                 4 XTCB      CURRENT TCB                     AI A47499 83350021
*                 8 XRETURN   RETURN TO MAINLINE ADDR         AI A47499 83400021
*                 9 XTAXE     NEWLY CREATED TAXE              AI A47499 83450021
*                 B XTJB      TJB                             AI A47499 83500021
*                 C XTJBX     TJBX                            AI A47499 83550021
*                                                             AI A47499 83600021
*   OUTPUT REGS -                                             AI A47499 83650021
*                 ALL INPUT REGS                              AI A47499 83700021
*                                                             AI A47499 83750021
* DESTROYS REGS -                                             AI A47499 83800021
*                 2 XNTAXE    LINK ADDR FOR NEW TAXE          AI A47499 83850021
*                 7 XSTCB     TCB OF TAXE ON QUEUE & SUBTASKS AI A47499 83900021
*                 A XQTAXE    TAXE BEING CHECKED ON THE QUEUE AI A47499 83950021
*                 F XWORK15   USED TO SELECT DESCENDANT TASKS AI A47499 84000021
*                             ALSO TO CORRECT AVAILABILITY    AI A49291 84010021
*                                                             AI A47499 84050021
*   UNUSED REGS - 0,1,3,5,6,D,E                               AI A47499 84100021
*                                                             AI A47499 84150021
QTAXE    EQU   *                                              AI A47499 84200021
         LA    XNTAXE,TJBXTAXE    INITIALIZE TO QUEUE NEW     AI A47499 84250021
*                                  TAXE HERE                  AI A47499 84300021
         L     XQTAXE,TJBXTAXE    LOCATE FIRST TAXE ON QUEUE  AI A47499 84350021
QUECHECK EQU   *                                              AI A47499 84400021
         LTR   XQTAXE,XQTAXE      END OF TAXE QUEUE?          AI A47499 84450021
         BNZ   CHECKEND           NO. CHECK THIS TAXE'S TCB   AI A47499 84500021
QNEWTAXE EQU   *                                              AI A47499 84550021
         L     XWORK15,0(,XNTAXE) ADDR NEXT AFTER REQUE       AI A49291 84600021
         ST   XWORK15,TAXELNK     QUE NEWLY CREATED TAXE      AI A49291 84610021
         ST    XTAXE,ZERO(,XNTAXE) IN SPECIFIED LOCATION      AI A47499 84650021
         LTR  XWORK15,XWORK15     Q. HIGHER LEVEL TAXE ON Q?  AI A49291 84700021
         BZ    INCRSTAX            NO. BUMP STAX COUNT AND    AI A49291 84710021
*                                   RETURN SINCE NO HIGHER    AI A49291 84720021
*                                    LEVEL CAN BE ACTIVE      AI A49291 84730021
*                                                             AI A49291 84740021
*        XXXXXXXXXX                                           AI A49291 84742021
         DROP  XTAXE                DROP ADR ON NEW TAXE AND  AI A49291 84744021
         USING TAXE,XWORK15          PICK IT UP ON NEXT CHAINEDI A49291 84746021
*        XXXXXXXXXX                                           AI A49291 84748021
*                                                             AI A49291 84748421
         TM    TAXESTAT,TAXEFREQ  Q. IS THERE AN ACTIVE TAXE  AI A49291 84748821
*                                  AT SOME HIGHER LEVEL?      AI A49291 84749221
         BZ    INCRSTAX           NO. BUMP STAXCNT AND RTN    AI A49291 84749621
*                                                             AI A49291 84749721
*        XXXXXXXXXX                                           AI A49291 84749821
         DROP  XWORK15            DROP ADR ON NEXT CHAINED    AI A49291 84749921
         USING TAXE,XTAXE          AND PICK UP ON NEW         AI A49291 84766621
*        XXXXXXXXXX                                           AI A49291 84776621
*                                                             AI A49291 84778621
         OI    TAXESTAT,TAXEFREQ  MAKE THE NEW TAXE UNAVAIL   AI A49291 84780621
         BR    XRETURN            NO NEED TO INCREMENT STAX   AI A49291 84782621
*                                                             AI A47499 84783321
*        XXXXXXXXXX                                           AI A47499 84800021
         DROP  XTAXE              DROP ADDR ON NEW TAXE AND   AI A47499 84850021
         USING TAXE,XQTAXE         PICK IT UP ON QUEUED TAXE  AI A47499 84900021
*        XXXXXXXXX                                            AI A47499 84950021
*                                                             AI A47499 85000021
CHECKEND EQU   *                                              AI A47499 85050021
         C     XTCB,TAXETCB       QUEUED TAXE'S TCB CURRENT?  AI A47499 85100021
         BE    QNEWTAXE           YES. SEARCH IS OVER         AI A47499 85150021
         CLC   TCBOTC,TAXETCB     IS IT CURRENT'S MOTHER?     AI A47499 85200021
         BE    QNEWTAXE           YES. SEARCH IS OVER         AI A47499 85250021
         LR    XSTCB,XTCB         SET UP FOR TCB SEARCH       AI A47499 85300021
*                                                             AI A47499 85350021
*        XXXXXXXXXX                                           AI A47499 85400021
         DROP  XTCB               DROP ADDRESSIBILITY ON CUR  AI A47499 85450021
         USING TCB,XSTCB           TCB & SET UP ON SELECT TCB AI A47499 85500021
*        XXXXXXXXXX                                           AI A47499 85550021
*                                                             AI A47499 85600021
CHECKSUB EQU   *                                              AI A47499 85650021
         L     XWORK15,TCBLTC     LOCATE DAUGHTER OF SEL TASK AI A47499 85700021
QNOTASK  EQU   *                                              AI A47499 85750021
         LTR   XWORK15,XWORK15    IS THERE A DAUGHTER/SISTER? AI A47499 85800021
         BNZ   TCBCOMPR           YES. CHECK FOR A MATCH      AI A47499 85850021
         L     XWORK15,TCBNTC     LOCATE SISTER OF TASK THAT  AI A47499 85900021
*                                  HAS NO DAUGHTERS TO SELECT AI A47499 85950021
         CR    XSTCB,XTCB         WORKED BACK TO CURRENT TCB? AI A47499 86000021
         BE    NEXTTAXE           YES. THIS TAXE NOT FOR A    AI A47499 86050021
*                                  DESCENDANT. LOOK AT NEXT.  AI A47499 86100021
         L     XSTCB,TCBOTC       WORK UP ONE LEVEL IN CASE   AI A47499 86150021
*                                  ALL SISTERS CHECKED ON THISAI A47499 86200021
*                                  LEVEL ON RELATIONSHIP QUE  AI A47499 86250021
         B     QNOTASK            CHECK FOR OUT OF TASKS ON   AI A47499 86300021
*                                  THIS LEVEL                 AI A47499 86350021
TCBCOMPR EQU   *                                              AI A47499 86400021
         LR    XSTCB,XWORK15      USE SELECTED TASK TO START  AI A47499 86450021
*                                  NEXT TCB CHAIN SEARCH      AI A47499 86500021
         C     XSTCB,TAXETCB      IS TAXE FOR THIS DESCENDANT?AI A47499 86550021
         BNE   CHECKSUB           NO. CONTINUE THE SEARCH     AI A47499 86600021
         LA    XNTAXE,TAXELNK     YES. MUST QUEUE NEW TAXE AT AI A47499 86650021
*                                  LEAST BEHIND DESCENDANT    AI A47499 86700021
NEXTTAXE EQU   *                                              AI A47499 86750021
         L     XQTAXE,TAXELNK     LOOK AT NEXT TAXE ON QUEUE  AI A47499 86800021
         B     QUECHECK           CHECK FOR END OF QUEUE      AI A47499 86850021
*                                                             AI A47499 86900021
*        XXXXXXXXXX                                           AI A47499 86950021
         DROP  XQTAXE             END OF ADDRESS QUEUED TAXE  AI A47499 87000021
         USING TAXE,XTAXE         ADDRESSIBILITY NEW TAXE     AI A47499 87050021
         DROP  XSTCB              END OF ADDRESSIBILITY ON    AI A47499 87100021
         USING TCB,XTCB            SELECT TCB & SET UP CURRENTAI A47499 87150021
*        XXXXXXXXXX                                           AI A47499 87200021
*                                                             AI A47499 87250021
         SPACE 3                                                        87300021
INCRSTAX EQU   *                                                        88200020
         SR    XSTAX,XSTAX        CLEAR STAX COUNT REG                  88400020
         IC    XSTAX,TJBSTAX      STAX COUNT FROM TJB                   88600020
         LA    XSTAX,ONE(,XSTAX)  INCREMENT STAX COUNT        AI  21A72 88800021
         STC   XSTAX,TJBSTAX      STORE NEW STAX COUNT                  89000020
         BR    XRETURN            RETURN TO CALLER                      89200020
         EJECT                                                          89400020
*                                                                       89600020
*  CONSTANTS                                                            89800020
*                                                                       90000020
         SPACE 2                                                        90200020
*********************************************************************** 90210020
*   THE ADDRESS OF THE ATTENTION PROLOGUE(IKJEAR05) IS PLACED         * 90400020
*   IN THE IRB BEFORE THE ATTENTION HANDLER (IKJEAR04) SCHEDULES      * 90600020
*   THE IRB WHICH THE ATTENTION EXIT ROUTINE RUNS UNDER.              * 90800020
*********************************************************************** 90810020
         SPACE 1                                                        90820020
PROLOG   DC    F'0'           DUMMY ADDRESS OF IKJEAR05 WHICH IS USED   91000020
*                             AS EXIT ADDRESS IN IRB INITIALLY          91010020
         SPACE     1                                                    91200020
*                                                             AI  21A72 91400021
         DS    0F             ALIGN TO FULL WORD BOUNDARY               91600020
SP253    DC    X'FD000000'    SUBPOOL 253 FOR FREEING TAXE'S            91650020
SP250    DC    X'FA000048'    CIRB SAVE AREA IN SP 250                  91700020
FULLWORD DC    X'FFFFFFFC'    USED TO TEST FOR WORD BOUNDARY            91800020
MAXSIZE  DC    X'7FFF'        MAXIMUM SIZE OF BUFFERS         AJ A52533 92000021
         EJECT                                                          92002021
*                                                                       92004021
*        ZAP SPACE FOR MAINTENANCE USE                                  92006021
*                                                                       92008021
         DC    H'0'                                                     92010021
         DC    H'0'                                                     92012021
         DC    H'0'                                                     92014021
         DC    H'0'                                                     92016021
         DC    H'0'                                                     92018021
         DC    H'0'                                                     92020021
         DC    H'0'                                                     92022021
         DC    H'0'                                                     92024021
         DC    H'0'                                                     92026021
         DC    H'0'                                                     92028021
         DC    H'0'                                                     92030021
         DC    H'0'                                                     92032021
         DC    H'0'                                                     92034021
         DC    H'0'                                                     92036021
         DC    H'0'                                                     92038021
         DC    H'0'                                                     92040021
         DC    H'0'                                                     92042021
         DC    H'0'                                                     92044021
         DC    H'0'                                                     92046021
         DC    H'0'                                                     92048021
         DC    H'0'                                                     92050021
         DC    H'0'                                                     92052021
         DC    H'0'                                                     92054021
         DC    H'0'                                                     92056021
         DC    H'0'                                                     92058021
         DC    H'0'                                                     92060021
         DC    H'0'                                                     92062021
         DC    H'0'                                                     92064021
         DC    H'0'                                                     92066021
         DC    H'0'                                                     92068021
         DC    H'0'                                                     92070021
         DC    H'0'                                                     92072021
         DC    H'0'                                                     92074021
         EJECT                                                          92100021
         IEZJSCB                  JSCB                                  92500021
         EJECT                                                          92900021
         IKJRB                    RB                                    93300021
         EJECT                                                          93700021
CVT      DSECT                                                          94100021
         CVT                                                            94500021
         EJECT                                                          94900021
         IKJTCB                   TCB                                   95300021
         EJECT                                                          95700021
         IKJTJB                   TJB                                   96100021
         EJECT                                                          96500021
         IKJTJBX                  TJBX                                  96900021
         EJECT                                                          97300021
         IKJTAXE                  TAXE                                  97700021
LTAXE    EQU   *-TAXE             LENGTH OF TAXE                        98100021
         EJECT                                                          98500021
         IKJTSCVT                 TSCVT                                 98900021
         EJECT                                                          99300021
         EJECT                                                          99400021
PREVSTAX EQU   RBEXSAVE           SAVE AREA FOR PREV PARAM    AI A45359 99500021
         END                                                            99600021
