IKJEES75 CSECT                 MODULE FOR I/O FOR LISTBC                00050020
         TITLE    'IKJEES75 - LISTBC I/O MODULE'                        00060020
*/*IKJEES75:  CHART */                                                  00100020
*/*           E  IKJEES75 */                                            00150020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 00200020
*                                                                     * 00250020
* STATUS: CHANGE LEVEL 000                                            * 00300020
*   D  368500                                                  SA70717* 00320021
*                                                                M0843* 00350020
*                                                                     * 00400020
* TITLE:  IKJEES75                                                    * 00450020
*                                                                     * 00500020
* FUNCTION/OPERATION:  THIS MODULE PERFORMS ALL I/O OPERATIONS FOR    * 00550020
*         THE LISTBC COMMAND PROCESSOR. FUNCTIONS PROVIDED ARE:       * 00600020
*                                                                     * 00650020
*               OPEN              CLOSE           ENQUEUE(SHARE)      * 00700020
*               DEQUEUE           LOAD            ENQUEUE(EXCLUSIVE)  * 00750020
*               READ              WRITE           CHECK               * 00800020
*               INITIALIZE DCB    DELETE                              * 00850020
*               INTERFACE WITH PUTLINE                                * 00900020
*               BUILD CHAIN OF MESSAGE UNITS WHEN ENTERED FROM LOGON  * 00950020
*                                                                     * 01000020
*         OPERATIONS DESIRED AND INFORMATION TO DO THEM ARE INDICATED * 01050020
*         BY THE FOLLOWING PARAMETER LIST (POINTER IN REG 1);         * 01100020
*                                                                     * 01150020
*                          ------------------                         * 01200020
*                           4 FLAG BYTES                            * 01250020
*                          ----------------                         * 01300020
*                           PTR TO PUTLINE                          * 01350020
*                           PARM BLOCK                              * 01400020
*                          ----------------                         * 01450020
*                           PTR TO DCB                              * 01500020
*                          ----------------                         * 01550020
*                           RBA FOR WRITE                           * 01600020
*                          ----------------                         * 01650020
*                           RBA FOR ENQ                             * 01700020
*                          ----------------                         * 01750020
*                           RBA FOR READ                            * 01800020
*                          ----------------                         * 01850020
*                           PTR TO LWAPNOT                          * 01900020
*                          ----------------                         * 01950020
*                           INDEX   RETURN                         * 02000020
*                            CODE    CODE                          * 02050020
*                          ------------------                         * 02100020
*                                                                     * 02150020
*         INFORMATION IN THE FLAG BYTES INDICATES THE I/O OPERATION TO* 02200020
*         BE PERFORMED. OPERATIONS ARE PERFORMED ON THE BASIS OF WHICH* 02250020
*         BITS ARE SET TO 1.                                          * 02300020
*                                                                     * 02350020
*             BYTE 1:  BIT 0- OPEN                                    * 02400020
*                      BIT 1- ENQUEUE(SHARE)                          * 02450020
*                      BIT 2- READ BY RBA                             * 02500020
*                      BIT 3- READ FIRST RECORD                       * 02550020
*                      BIT 4- UNUSED                                  * 02600020
*                      BIT 5- DEQUEUE                                 * 02650020
*                      BIT 6- CLOSE                                   * 02700020
*                      BIT 7- PUTLINE                                 * 02750020
*                                                                     * 02800020
*             BYTE 2:  BIT 0- USE DIRECTORY BUFFER                    * 02850020
*                      BIT 1- ENQUEUE(EXCLUSIVE)                      * 02900020
*                      BIT 2- LOAD (PUTLINE MODULES)                  * 02950020
*                      BIT 3- DELETE (PUTLINE MODULES)                * 03000020
*                      BIT 4- WRITE (TO BROADCAST DATA SET)           * 03050020
*                      BIT 5- DEQ FROM EXCLUSIVE ENQ                  * 03100020
*                      BIT 6-7- RESERVED                              * 03150020
*                                                                     * 03200020
*                                                                     * 03250020
*         THE NEXT FLAG BYTE IS USED TO INDICATE WHICH MESSAGE TO BE  * 03300020
*         PRINTED BY PUTLINE.                                         * 03350020
*             BYTE 3:   BIT 0- INDICATE ERROR CONDITION OCCURRED      * 03400020
*                       BIT 1- INDICATE ONE-LEVEL MESSAGE             * 03450020
*                       BIT 2- INDICATE TEXT INSERTION REQUIRED       * 03500020
*                       BIT 3- INDICATE RETURN CODE MUST BE CONVERTED * 03550020
*                              TO PRINTABLE HEX                       * 03600020
*                       BIT 4- INDICATES THAT NOTICE MSG UNIT IS TO   * 03650020
*                              BE BUILT                               * 03700020
*                       BIT 5- INDICATES THAT MAIL MSG UNIT IS TO     * 03750020
*                              BE BUILT                               * 03800020
*                       BIT 6- RESERVED                               * 03850020
*                                                                     * 03900020
*         THE NEXT FLAG BYTE REMAINS SET PERMANENTLY.                 * 03950020
*                                                                     * 04000020
*             BYTE 4:  BIT 0- DCB IS ALREADY INITIALIZED              * 04050020
*                      BIT 1- FIRST BROADCAST MESSAGE FOUND           * 04100020
*                      BIT 2- USER MESSAGES ONLY (MAIL)               * 04150020
*                      BIT 3- BROADCAST MESSAGES ONLY (NOTICES)       * 04200020
*                      BIT 4- ENTRY IS FROM LOGON                     * 04250020
*                      BIT 5- AN I/O ERROR OCCURRED                   * 04300020
*                      BIT 6- INDICATES ONE ATTEMPT HAS BEEN MADE TO  * 04350020
*                             PUTLINE                                 * 04400020
*                      BIT 7- RESERVED                                * 04450020
*                                                                     * 04500020
*         EACH OPERATION BIT IS CHECKED SO THAT ANY NUMBER OF         * 04550020
*         OPERATIONS MAY BE PERFORMED IN ONE CALL. ALL OPERATIONS     * 04600020
*         ARE FOR A BDAM DATA SET.                                    * 04650020
*                                                                     * 04700020
*         CORE FOR THE DCB, PUTLINE PARAMETER LISTS, AND MACRO PARM   * 04750020
*         LISTS IS GOTTEN FROM SUBPOOL 1.                             * 04800020
*                                                                     * 04850020
*         IN ADDITION TO BDAM I/O OPERATIONS THIS MODULE CARRIES OUT  * 04900020
*         THE INTERFACE WITH THE PUTLINE SERVICE ROUTINE. THIS        * 04950020
*         REQUIRES 3 DIFFERENT TYPES OF INTERFACES. MESSAGES FROM THE * 05000020
*         SYS1.BRODCAST DATA SET ARE PRINTED AS 'DATA' ITEMS SINCE    * 05050020
*         THAT IS THE MOST DIRECT ROUTE TO THE TERMINAL.  ERROR       * 05100020
*         MESSAGES ARE PUT OUT AS SINGLE-LINE INFORMATIONAL MESSAGES  * 05150020
*         OF BOTH ONE AND TWO LEVELS.  BITS IN THE PARAMETER LIST FROM* 05200020
*         THE CALLER ALSO DIRECT THE PRINTING OF MESSAGES THROUGH     * 05250020
*         PUTLINE.                                                      05300020
*                                                                     * 05350020
*         THIS MODULE ALSO CONTAINS SYNAD CODE FOR I/O ERROR RECOVERY.* 05400020
*         NO ATTEMPT IS MADE TO CONTINUE PROCESSING.  WORK AREAS ARE  * 05450020
*         FREED, A MESSAGE DESCRIBING THE ERROR IS ISSUED AND CONTROL * 05500020
*         RETURNS TO THE CALLER WITH AN ERROR CODE (8).               * 05550020
*                                                                     * 05600020
* ENTRY POINTS:  IKJEES75 (SEE NOTES IF LISTBC IS ENTERED FROM LOGON) * 05650020
*                                                                     * 05700020
* INPUT: REGISTER 1 POINTS TO THE PARM BLOCK                          * 05750020
*        REGISTER 4 POINTS TO THE DIRECTORY BUFFER(130 BYTES)         * 05800020
*        REGISTER 5 POINTS TO THE MESSAGE BUFFER(130 BYTES)           * 05850020
*                                                                     * 05900020
* OUTPUT: 1. THIRD WORD IN PARAMETER LIST POINTS TO THE DCB.          * 05950020
*         2. SEVENTH WORD IN PARAMETER LIST POINTS TO A               * 06000020
*            FIELD IN THE LOGON WORK AREA (LWA) CALLED THE            * 06050020
*            LWAPNOT. THE LWAPNOT FIELD CONTAINS EITHER THE ADDRESS   * 06100020
*            OF THE FIRST NOTICE MSG UNIT ON THE CHAIN (IF            * 06150020
*            THERE IS A CHAIN BUILT FOR THAT TYPE) OR ZERO (IF        * 06200020
*            NO CHAIN FOR THAT TYPE MESSAGE IS BUILT).                * 06250020
*         3. LWAPMAL FIELD IN THE LWA CAN BE DETERMINED BY ADDING     * 06300020
*            4 TO THE ADDRESS OF LWAPNOT. THE LWAPMAL FIELD CONTAINS  * 06350020
*            EITHER THE ADDRESS OF THE FIRST MAIL MSG UNIT ON THE     * 06400020
*            CHAIN (IF THERE IS A CHAIN BUILT FOR THAT TYPE) OR       * 06450020
*            ZERO (IF NO CHAIN FOR THAT TYPE MESSAGE IS BUILT).       * 06500020
*         4. IF ANY ERROR OCCURS, A RETURN CODE OF 8 IS PUT IN REG15. * 06550020
*                                                                     * 06600020
* EXTERNAL ROUTINES: PUTLINE SERVICE ROUTINE.                         * 06650020
*                                                                     * 06700020
* EXITS: RETURN TO CALLER                                             * 06750020
*                                                                     * 06800020
* ERROR EXITS: NONE. ERROR RETURN CODE TO CALLER IN REG 15.           * 06850020
*                                                                     * 06900020
* TABLES/WORK AREAS: DCB(BDAM)                                        * 06950020
*                                                                     * 07000020
* ATTRIBUTES: REENTRANT,REFRESHABLE                                   * 07050020
*                                                                     * 07100020
* NOTES:                                                              * 07150020
*    1. TSO SCHEDULER SUPPORT CODE FOR THIS MODULE IS 20035           * 07200020
*                                                                     * 07250020
*    2. WHEN LISTBC IS ENTERED AT THE LOGON ENTRY POINT (IKJEES73),   * 07300020
*         THIS MODULE PRODUCES A CHAIN OF MAIL AND/OR NOTICES MESSAGE * 07350020
*         UNITS.  THE FORMAT OF EACH MESSAGE UNIT IS:                 * 07400020
*                                                                     * 07450020
*         --------------------------------------------------------    * 07500020
*          NEXT        LENGTH    RESERVED      T   E   X   T     * 07550020
*         --------------------------------------------------------    * 07600020
*                                                                     * 07650020
*         WHERE:                                                      * 07700020
*                                                                     * 07750020
*         NEXT        - A FOUR BYTE ADDRESS OF THE NEXT MESSAGE UNIT  * 07800020
*                       OR ZERO IF IT IS THE LAST ONE                 * 07850020
*         LENGTH      - A TWO BYTE LENGTH FIELD WHICH INDICATES THE   * 07900020
*                       LENGTH OF TEXT + 4 BYTES FOR HEADER           * 07950020
*         RESERVED    - A TWO BYTE FIELD (NOT CURRENTLY USED) OF ZEROS* 08000020
*         TEXT        - THE MESSAGE TEXT                              * 08050020
*                                                                     * 08100020
*         THE MESSAGE UNIT (MSGU) CHAINS ARE BUILT IN CORE (SP 1)     * 08150020
*         AND THEN ISSUED TO THE TERMINAL BY THE LOGON MODULE         * 08200020
*         IKJEFLH                                                     * 08250020
*                                                                     * 08300020
*    3. WHEN ENTRY IS FROM LOGON AND EITHER AN I/O ERROR OR AN        * 08310020
*       OPEN ERROR OCCURS, THIS MODULE SETS A RETURN CODE IN THE      * 08320020
*       THIRD WORD OF THE PARM LIST FROM LOGON INDICATING THE TYPE    * 08330020
*       OF ERROR THAT OCCURRED AND THEN RETURNS TO LOGON WHO WILL     * 08340020
*       ISSUE THE ERROR MESSAGE TO THE TERMINAL.                      * 08342020
*                                                                     * 08344020
*    4. THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL         * 08350020
*       REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS         * 08400020
*       EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME. THE CHARACTER    * 08450020
*       DEPENDENCY CODE IS C EXCEPT FOR THE TRANSLATE TABLE WHICH     * 08500020
*       HAS A DEPENDENCY CODE OF D.                                   * 08550020
*                                                                     * 08600020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 08650020
         EJECT                                                          08700020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 08750020
*                                                                     * 08800020
*        MAPPING DSECT FOR PARAMETERS TO COMMUNICATE FUNCTIONS TO BE  * 08850020
*        DONE- BETWEEN THE LISTBC MAIN MODULE AND THE I/O MODULE      * 08900020
*                                                                     * 08950020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 09000020
BCIOPARM DSECT                    DSECT FOR PARMS TO I/O MODULE         09050020
*                                                                     * 09100020
BCIOF1   DS    1C                 FLAGS FOR OPERATIONS                  09150020
BCOPEN   EQU   X'80'              PERFORM OPEN                          09200020
BCENQ    EQU   X'40'              PERFORM ENQUEUE                       09250020
BCRD     EQU   X'20'              READ SPECIFIED RECORD                 09300020
BCRD1    EQU   X'10'              READ FIRST RECORD                     09350020
BCUNUSED EQU   X'08'              ISSUE CHECK                           09400020
BCDEQ    EQU   X'04'              PERFORM DEQUEUE                       09450020
BCCLOSE  EQU   X'02'              INDICATES CLOSE                       09500020
BCPUTL   EQU   X'01'              PERFORM PUTLINE                       09550020
*                                                                     * 09600020
BCIOF2   DS    1C                 FLAGS FOR OPERATIONS                  09650020
BCDIR    EQU   X'80'              FLAG FOR DIRECTORY                    09700020
BCENQX   EQU   X'40'              ENQUEUE FOR EXCLUSIVE USE OF DS       09750020
BCLOAD   EQU   X'20'              LOAD PUTLINE MODULES                  09800020
BCDELETE EQU   X'10'              DELETE PUTLINE MODULES                09850020
BCWRITE  EQU   X'08'              WRITE RECORD                          09900020
BCDEQX   EQU   X'04'              DEQ FROM EXCLUSIVE ENQ                09950020
*                                                                     * 10000020
BCIOF3   DS    1C                 FLAGS FOR MESSAGE NUMBERS             10050020
BCERFLG  EQU   X'80'              INDICATES ERROR CONDITION             10100020
BC1LVL   EQU   X'40'              INDICATES ONE-LEVEL MESSAGE           10150020
BCTXTIN  EQU   X'20'              INDICATES TEXT INSERTION REQUIRED     10200020
BCHXCV   EQU   X'10'              INDICATES THAT RETURN CODE MUST BE    10250020
*                                 CONVERTED TO PRINTABLE HEX            10300020
BCMSUB   EQU   X'08'              NOTICE MSG UNIT TO BE BUILT           10350020
BCMSUU   EQU   X'04'              MAIL MSG UNIT TO BE BUILT             10400020
BCRSV2   EQU   X'02'              RESERVED                              10450020
*                                                                     * 10500020
BCPERMF  DS    1C                 FLAGS SET FOR LIFE OF LISTBC          10550020
BCDCB    EQU   X'80'              INDICATE DCB IS NOT SET UP            10600020
BCMSGSW  EQU   X'40'              MESSAGES FOUND                        10650020
BCMAIL   EQU   X'20'              MAIL KEYWORD ON COMMAND               10700020
BCNOTICE EQU   X'10'              NOTICE KEYWORD ON COMMAND             10750020
BCLOGON  EQU   X'08'              CONTROL COMES FROM LOGON ROUTINE      10800020
BCERROR  EQU   X'04'              FLAG FOR I/O ERROR                    10850020
BCPUTER  EQU   X'01'              FLAG TO INDICATE ONE ATTEMPT          10900020
*                                 HAS BEEN MADE TO PUTLINE A          * 10950020
*                                 MESSAGE TO A TERMINAL               * 11000020
*                                                                     * 11050020
BCPUTLP  DS    F                  PTR FOR PUTLINE                       11100020
*                                                                     * 11150020
BCDCBP   DS    F                  PTR TO DCB                            11200020
*                                                                     * 11250020
BCWRRBA  DS    F                  RBA FOR WRITE INSTRUCTION             11300020
*                                                                     * 11350020
BCEQXRBA DS    1F                 RBA FOR EXCLUSIVE ENQUEUE             11400020
*                                                                     * 11450020
BCIORBA  DS    2F                 RBA USED FOR READ AND FEEDBACK        11500020
*                                                                     * 11550020
BCLWAMSG DS    F                  PTR TO THE LWAPNOT FIELD IN THE       11600020
*                                 LOGON WORK AREA (LWA). THE LWAPNOT    11650020
*                                 WILL CONTAIN (ON RETURN TO CALLER)    11700020
*                                 EITHER THE ADDRESS OF THE FIRST       11750020
*                                 NOTICE MESSAGE UNIT ON THE CHAIN OR   11800020
*                                 ZERO IF NO MSGS EXIST                 11850020
BCERCDE  DS    H                  MESSAGE CODE TO BE USED FOR INDEX-    11900020
*                                 ING INTO THE MESSAGE MODULE           11950020
BCRTCDE  DS    H                  ERROR RETURN CODE FROM A SERVICE      12000020
*                                 ROUTINE WHICH WILL BE INSERTED INTO   12050020
*                                 AN APPROPRIATE ERROR MSG              12100020
         EJECT                                                          12150020
*********************************************************************** 12200020
*                                                                     * 12250020
*        MAPPING FOR PARM LISTS FOR MACROS- MOVED TO DYNAMIC CORE FOR * 12300020
*        RE-ENTRANT PURPOSES                                          * 12350020
*                                                                     * 12400020
*********************************************************************** 12450020
BCLISTS  DSECT                                                          12500020
*        OPEN                                                           12550020
BCOPL    OPEN  (,(OUTPUT)),MF=L   OPEN SYS1.BRODCAST                    12600020
         SPACE 3                                                        12650020
*        ENQUEUE SHARE                                                  12700020
BCNQL    ENQ   (BCQNM,BCDSN,S,,SYSTEM),MF=L  ENQUEUE SHARING            12750020
         SPACE 3                                                        12800020
*        DEQUEUE                                                        12850020
BCDQL    DEQ   (BCQNM,BCDSN,,SYSTEM),MF=L  DEQUEUE FROM DATA SET        12900020
         SPACE 3                                                        12950020
*        ENQUEUE EXCLUSIVE                                              13000020
BCNQLX   ENQ   (BCQNM,,E,3,SYSTEM),MF=L                                 13050020
         SPACE 3                                                        13100020
*        DEQUEUE FROM EXCLUSIVE ENQUEUE                                 13150020
BCDQLX   DEQ   (BCQNM,,3,SYSTEM),RET=HAVE,MF=L                          13200020
         SPACE 3                                                        13250020
*        READ                                                           13300020
         READ  BCDECB1,DIF,,,'S',0,,MF=L                                13350020
         SPACE 3                                                        13400020
*        READ SPECIAL FIRST RECORD                                      13450020
         READ  BCDECB2,DI,,,'S',0,BCFRREC,MF=L                          13500020
         SPACE 3                                                        13550020
*        WRITE                                                          13600020
         WRITE BCDECB3,DI,,,'S',0,,MF=L                                 13650020
         SPACE 3                                                        13700020
*        WRITE                                                          13750020
         WRITE BCDECB4,DI,,,'S',BCKEY,,MF=L                             13800020
         SPACE 3                                                        13850020
*        CLOSE                                                          13900020
BCCLL    CLOSE 0,MF=L             CLOSE SYS1.BRODCAST                   13950020
         SPACE 3                                                        14000020
*        PUTLINE- ONE LEVEL                                             14050020
BCPUTL1L PUTLINE ,MF=L                                                  14100020
         SPACE 3                                                        14150020
*        PUTLINE- TWO LEVELS                                            14200020
BCPUTL2L PUTLINE OUTPUT=(0,MULTLVL),MF=L                                14250020
         SPACE 3                                                        14300020
*        PUTLINE- DATA                                                * 14350020
BCPUTLDL PUTLINE ,MF=L                                                  14400020
*                                                                     * 14450020
*          GETMAIN CONDITIONAL                                        * 14500020
BCGETMNL GETMAIN   EC,MF=L       GETMAIN LIST FORM FOR MESSAGE UNITS    14550020
         SPACE 3                                                        14600020
*                                                                       14650020
BCDEC    DS    D                  CONTAINS PACK DECIMAL RESULT          14700020
*                                                                     * 14750020
UNPCK    DS    D                  CONTAINS ZONED DECIMAL RESULT         14800020
*                                                                       14850020
BCGETADR DS    1F                 ADDRESS OF ALLOCATED GETMAIN AREA     14900020
*                                                                     * 14950020
BCGETLN  DS    1F                 LENGTH OF ALLOCATED GETMAIN AREA      15000020
*                                                                     * 15050020
MSGOFF   DS    1F                 ADDRESS OF ERROR MESSAGE IN THE       15100020
*                                 LISTBC MESSAGE MODULE (IKJEES74)      15150020
*                                                                     * 15200020
BCNXTP   DS    1F                 PTR TO LAST MESSAGE UNIT BUILT        15250020
*                                                                     * 15300020
BCPUT    DS    1F                 PTR TO PUTLINE MODULES FROM LOAD      15350020
*                                                                     * 15400020
*********************************************************************** 15450020
*                                                                     * 15500020
*        PARM BLOCK USED BY PUTLINE FOR ONE LEVEL BROADCAST           * 15550020
*                        MESSAGES                                     * 15600020
*                                                                     * 15650020
*********************************************************************** 15700020
PUTPAR   DS    0H                 POINTERS FOR PUTLINE INTERFACE        15750020
*                                                                     * 15800020
PUTLEN   DS    F                  LENGTH OF MSG SEGMENT- ALWAYS 1       15850020
PUTADDR  DS    F                  ADDRESS OF OUTPUT LINE OR 1ST SEG     15900020
*********************************************************************** 15950020
*                                                                     * 16000020
*        PARM BLOCKS USED BY PUTLINE FOR TWO LEVEL MESSAGES           * 16050020
*                                                                     * 16100020
*********************************************************************** 16150020
MSG1B    DS    0H                 FIRST OF TWO LEVELS                   16200020
MSG2PTR  DS    F                  POINTER TO SECOND LEVEL MSG           16250020
*                                 OUTPUT LINE DESCRIPTOR BLOCK (OLD)    16300020
MSG1SEG  DS    F                  NUMBER OF SEGMENTS IN LEVEL ONE       16350020
SEG1A    DS    F                  POINTER TO FIRST SEGMENT              16400020
SEG1B    DS    F                  POINTER TO SECOND SEGMENT             16450020
*                                                                     * 16500020
MSG2B    DS    0H                 PARM FOR SECOND LEVEL MESSAGE         16550020
MSG3PTR  DS    F                  PTR TO THIRD LEVEL MSG (ZEROES)       16600020
MSG2SEG  DS    F                  NUMBER OF SEGMENTS IN SECOND LEVEL    16650020
SEG2A    DS    F                  POINTER TO FIRST SEGMENT              16700020
SEG2B    DS    F                  POINTER TO SECOND SEGMENT             16750020
SEG2C    DS    F                  POINTER TO THIRD SEGMENT              16800020
*                                                                     * 16850020
MSG3B    DS    0H                 STRUCTURE FOR MESSAGE SEGMENT         16900020
SEGLTH   DS    H                  LENGTH OF MESSAGE SEGMENT             16950020
SEGOFSET DS    H                  OFFSET TO MESSAGE SEGMENT             17000020
SEGSRT   DS    CL3                INSERTED TEXT                         17050020
         EJECT                                                          17100020
BCDCBD   DCBD  DSORG=DA,DEVD=DA                                         17150020
DCBEND   DS    0D                      END OF DCB DSECT                 17200020
BCMSGU   DSECT                    DSECT FOR MESSAGE UNIT                17250020
BCMNXT   DS    AL4                PTR TO NEXT MESSAGE UNIT ON CHAIN     17300020
BCMLTH   DS    CL2                LENGTH OF MSG TEXT + 4 BYTES FOR      17350020
*                                 HEADER                                17400020
BCMRSV   DS    CL2                TWO BYTES OF ZEROS (UNUSED)           17450020
BCMTXT   DS    CL129              ACTUAL MESSAGE TEXT                   17500020
         EJECT                                                          17550020
IKJEES75 CSECT                    MODULE TO DO I/O FOR LISTBC           17600020
*                                                                       17608021
*                                                                       17616021
* A 531800-531900                                              A56110   17624021
*                                                                       17632021
*                                                                       17640021
REG0     EQU   0                  REGISTER FOR LENGTH                   17650020
PARMREG  EQU   1                  REGISTER FOR PARAMETERS               17700020
REG2     EQU   2                  SAVE PTR FROM CALLER                  17750020
REG3     EQU   3                  REGISTER FOR I/O RBA                  17800020
REG4     EQU   4                  REG FOR BUFFER                        17850020
REG5     EQU   5                  REGISTER FOR DIRECTORY BASE           17900020
REG6     EQU   6                  REGISTER FROM LISTBC WITH DAIR LIST   17950020
REG7     EQU   7                                                        18000020
REG8     EQU   8                  REGISTER FOR TEMP SAVE                18050020
REG9     EQU   9                                                        18100020
REGA     EQU   10                 REGISTER FOR DCB POINTER              18150020
REG11    EQU   11                 BASE REGISTER FOR MESSAGE UNIT        18200020
SAVE     EQU   13                 REGISTER FOR SAVE AREAS               18250020
REG14    EQU   14                 BASE REGISTER FOR PREVIOUS MSG UNIT   18300020
REG15    EQU   15                 REG FOR RETURN CODES                  18350020
N0       EQU   0                                                        18400020
N3       EQU   3                  LENGTH OF RETURN CODE                 18450020
N4       EQU   4                                                        18500020
OPNERROR EQU   4                  INDICATES OPEN ERROR TO LOGON         18550020
N5       EQU   5                  LENGTH OF HEADER + ONE                18600020
N7       EQU   7                  LENGTH OF THE SEGMENT TO BE INSERTED  18650020
*                                 IN SECOND LEVEL ERROR MSG             18700020
N8       EQU   8                  LENGTH OF HEADER FOR MSG UNIT         18750020
IOERROR  EQU   8                  INDICATES I/O ERROR TO LOGON          18800020
N9       EQU   9                                                        18850020
BCIOERR  EQU   8                  I/O ERROR RETURN CODE                 18900020
N16      EQU   16                 LENGTH OF OUT PUT LINE DESCRIPTOR     18950020
*                                 FOR FIRST LEVEL ERROR MSG             19000020
N20      EQU   20                 LENGTH OF OUT PUT LINE DESCRIPTOR     19050020
*                                 FOR SECOND LEVEL ERROR MSG            19100020
SEGNUM   EQU   1                  MSGS ARE ALL ONE SEGMENT              19150020
PRFIX    EQU   1                  OFFSET OF LENGTH IN PARM BLOCK        19200020
LENLEN   EQU   1                  LENGTH OF THE LENGTH FIELD            19250020
BFOFFSET EQU   4                  OFFSET OF LENGTH IN BUFFER            19300020
BLANK    EQU   C' '               SYMBOLIC                              19350020
DCBERR   EQU   X'10'              ERROR IN OPEN                         19400020
DCBLENG  EQU   DCBEND-IHADCB           SYMBOLIC LENGTH OF DCB           19450020
*/*           P  SAVE REGISTER CONTENTS */                              19500020
         STM   14,12,12(13)       SAVE CALLERS REGISTERS                19550020
*/*           P  ESTABLISH ADDRESSIBILITY FOR CSECT */                  19600020
         BALR  12,0               ESTABLISH ADDRESSABILITY              19650020
         USING *,12                                                     19700020
         B     AROUND                                                   19750020
         DC    AL1(8)              LENGTH OF MOD NAME                   19800020
         DC    CL8'IKJEES75'       MODULE NAME                          19850020
         DC    CL7'3411970'        JULIAN DATE                          19900020
AROUND   DS    0H                                                       19950020
         USING IHADCB,REGA        BASE FOR DCB                          20000020
         USING BCIOPARM,REG2      BASE FOR PARAMETER LIST               20050020
         LR    REG2,PARMREG       SET UP BASE FOR PARM LIST             20100020
         SPACE 3                                                        20150020
*********************************************************************** 20200020
*        SET UP FOR REGISTER SAVE AREA                                * 20250020
*                                                                     * 20300020
*********************************************************************** 20350020
*/*           P  GETMAIN FOR REGISTER SAVE AREA */                      20400020
         GETMAIN R,LV=72,SP=1     GETMAIN FOR SAVE AREA FOR IKJEES75    20450020
         ST    SAVE,4(PARMREG)    SAVE PTR TO CALLERS SAVE AREA         20500020
         ST    PARMREG,8(SAVE)    CHAIN IKJEES75 SAVE AREA TO CALLERS   20550020
         LR    SAVE,PARMREG       SET UP PTR TO IKJEES75 SAVE AREA      20600020
         L     REGA,BCDCBP        ADDRESSING FOR DCB                    20650020
         LA    REG8,DCBLENG(REGA)      ADDRESSING FOR MACRO PARM LISTS  20700020
         SPACE 3                                                        20750020
*********************************************************************** 20800020
*                                                                     * 20850020
*        SET UP DCB IN DYNAMIC CORE IF THIS IS THE FIRST USE OF THE   * 20900020
*              I/O MODULE                                             * 20950020
*                                                                     * 21000020
*********************************************************************** 21050020
*/*           D  (YES,,NO,BCCLOAD) IS DCB SET UP REQUESTED */           21100020
         TM    BCPERMF,BCDCB      SET UP DCB REQUESTED                  21150020
         BO    BCCLOAD             NO, BRANCH TO CHECK FOR LOAD         21200020
*/*           P  GETMAIN FOR DCB */                                     21250020
         GETMAIN R,LV=WKARLEN,SP=1   GET CORE FOR DCB AND MACRO LISTS   21300020
*/*           P  MOVE DCB INTO GOTTEN CORE */                           21350020
         MVC   0(DCBLENG,PARMREG),BCCDCB  MOVE DCB TO GOTTEN CORE       21400020
         LR    REGA,PARMREG       SET BASE FOR DCB DSECT                21450020
         OI    BCPERMF,BCDCB      TURN ON FLAG TO INDICATE DCB HAS      21500020
*                                 BEEN SET UP                           21550020
*/*           P  SAVE DCB PTR */                                        21600020
         ST    REGA,BCDCBP        SAVE DCB PTR                          21650020
         SPACE 3                                                        21700020
*********************************************************************** 21750020
*                                                                     * 21800020
*        MOVE ALL MACRO PARM LISTS AND NON RE-ENTRANT MESSAGES TO     * 21850020
*        DYNAMIC CORE - FIRST PASS ONLY                               * 21900020
*                                                                     * 21950020
*********************************************************************** 22000020
*/*           P  MOVE MACRO LIST AND MSGS TO CORE */                    22050020
         MVC   DCBLENG(BCLENMV,PARMREG),BCBEGL  MACRO LISTS             22100020
         LA    REG8,DCBLENG(PARMREG)   BASE FOR PARM LISTS              22150020
         USING BCLISTS,REG8       BASE FOR LISTS IN GOTTEN CORE         22200020
*********************************************************************** 22250020
*                                                                     * 22300020
*        LOAD THE MODULES OF THE PUTLINE SERVICE ROUTINE              * 22350020
*                                                                     * 22400020
*********************************************************************** 22450020
BCCLOAD  DS    0H                 CODE TO LOAD PUTLINE MODULES          22500020
*/*BCCLOAD:   D  (NO,BCCONT,YES,) PUTLINE LOAD REQUESTED */             22550020
         TM    BCIOF2,BCLOAD      IS LOAD OF PUTLINE MODULES REQUESTED? 22600020
         BZ    BCCONT             NO, BRANCH TO CHECK FOR OPEN          22650020
*/*           P  LOAD THE PUTLINE MODULES */                            22700020
         LOAD  EP=IKJPUTL         YES, LOAD PUTLINE MODULES             22750020
         ST    REG0,BCPUT         SAVE PTR TO PUTLINE MODULES           22800020
         SPACE 3                                                        22850020
*/*BCCONT:    D  (YES,,NO,BCCENQ) IS OPEN REQUESTED */                  22900020
BCCONT   TM    BCIOF1,BCOPEN      IS OPEN REQUESTED?                    22950020
         BZ    BCCENQ             NO, BRANCH TO CHECK FOR ENQUE         23000020
*********************************************************************** 23050020
*                                                                     * 23100020
*        OPEN SYS1.BRODCAST                                           * 23150020
*                                                                     * 23200020
*********************************************************************** 23250020
BCCOPEN  DS    0H                 CODE TO OPEN DATA SET                 23300020
         LA    PARMREG,BCOPL      PTR TO GENERATED PARM LIST            23350020
*/*           I  OPEN BROADCAST DATA SET */                             23400020
         OPEN  ((REGA)),MF=(E,(1))     OPEN SYS1.BRODCAST               23450020
*/*           D  (YES,,NO,BCERR1) OPEN SUCCESSFUL */                    23500020
         TM    DCBOFLGS,DCBERR    WAS OPEN SUCCESSFUL?                  23550020
         BZ    BCERR1             NO, BRANCH TO PUT OUT ERROR MSG       23600020
         SPACE 3                                                        23650020
*********************************************************************** 23700020
*                                                                     * 23750020
*        ENQUEUE WITH SHARE FOR THE BROADCAST DATA SET                * 23800020
*                                                                     * 23850020
*********************************************************************** 23900020
BCCENQ   DS    0H                 CODE TO ENQUEUE ON DATA SET           23950020
*/*BCCENQ:    D  (YES,,NO,BCCDEQ) ENQUE REQUESTED */                    24000020
         TM    BCIOF1,BCENQ       IS ENQUEUE REQUESTED?                 24050020
         BZ    BCCDEQ             NO, BRANCH TO CHECK FOR DEQUE         24100020
         LA    PARMREG,BCNQL      PTR TO GENERATED PARM LIST            24150020
*/*           P  ENQUE ON BROADCAST DATA SET */                         24200020
         ENQ   ,MF=(E,(1))        ENQUEUE SHARING ON SYS1.BRODCAST      24250020
         SPACE 3                                                        24300020
*********************************************************************** 24350020
*                                                                     * 24400020
*        DEQUEUE FROM THE BROADCAST DATA SET                          * 24450020
*                                                                     * 24500020
*********************************************************************** 24550020
BCCDEQ   DS    0H                 CODE TO DEQUEUE FROM BROADCAST D S    24600020
*/*BCCDEQ:    D  (YES,,NO,BCCENQX) DEQUE REQUESTED */                   24650020
         TM    BCIOF1,BCDEQ       IS DEQUEUE REQUESTED?                 24700020
         BZ    BCCENQX            NO, BRANCH TO CHECK FOR EXCLUSIVE     24750020
*                                 ENQUE                                 24800020
         LA    PARMREG,BCDQL      PTR TO GENERATED PARM LIST            24850020
*/*           P  DEQUE ON BROADCAST DATA SET */                         24900020
         DEQ   ,MF=(E,(1))        DEQUEUE FROM SYS1.BRODCAST            24950020
         SPACE 3                                                        25000020
*********************************************************************** 25050020
*                                                                     * 25100020
*        ENQUEUE EXCLUSIVELY BY RBA TO WRITE BROADCAST RECORD         * 25150020
*                                                                     * 25200020
*********************************************************************** 25250020
BCCENQX  DS   0H                  CODE TO ENQUEUE EXCLUSIVELY           25300020
*/*BCCENQX:   D  (YES,,NO,BCCDEQX) ENQUE EXCLUSIVE REQUESTED */         25350020
         TM   BCIOF2,BCENQX       IS ENQUEUE EXCLUSIVE REQUESTED?       25400020
         BZ    BCCDEQX            NO, BRANCH TO CHECK FOR EXCLUSIVE     25450020
*                                 DEQUEUE                               25500020
         LA    REG3,BCEQXRBA      RBA FOR ENQUEUE                       25550020
         LA    PARMREG,BCNQLX     PTR TO ENQ PARM LIST                  25600020
*/*           P  ENQUE EXCLUSIVE ON BROADCAST DATA SET */               25650020
         ENQ   (,(REG3)),MF=(E,(1))  ENQUEUE EXCLUSIVE                  25700020
         SPACE 3                                                        25750020
*********************************************************************** 25800020
*        DEQUEUE FROM EXCLUSIVE ENQUEUE BY RELATIVE BLOCK ADDRESS     * 25850020
*********************************************************************** 25900020
BCCDEQX  DS    0H                                                       25950020
*/*BCCDEQX:   D  (YES,,NO,BCCREAD) DEQUE EXCLUSIVE REQUESTED */         26000020
         TM    BCIOF2,BCDEQX      EXCLUSIVE DEQUEUE REQUESTED?          26050020
         BZ    BCCREAD            NO, BRANCH TO CHECK FOR READ          26100020
         LA    REG3,BCEQXRBA      PTR TO RBA                            26150020
         LA    PARMREG,BCDQLX     PTR TO DEQ PARM LIST                  26200020
*/*           P  DEQUE EXCLUSIVE ON BROADCAST DATA SET */               26250020
         DEQ   (,(REG3)),MF=(E,(1))                                     26300020
         SPACE 3                                                        26350020
         SPACE 3                                                        26400020
*********************************************************************** 26450020
*                                                                     * 26500020
*        READ A MESSAGE OR DIRECTORY RECORD FROM BROADCAST DATA SET   * 26550020
*              REG5 POINTS TO THE INPUT BUFFER AND THE RELATIVE BLOCK * 26600020
*              ADDRESS IS IN LOCATION 'BCIORBA' OF THE PARAMETER LIST * 26650020
*              PASSED TO THIS ROUTINE BY THE CALLER. (SEE PROLOGUE)   * 26700020
*              REG3 POINTS TO THIS WORD IN ORDER TO AVOID RELOCATA-   * 26750020
*              BILITY PROBLEMS.                                       * 26800020
*********************************************************************** 26850020
BCCREAD  DS    0H                 CODE TO READ BY REL BLOCK ADDR        26900020
*/*BCCREAD:   D  (YES,,NO,BCREAD1) READ REQUESTED */                    26950020
         TM    BCIOF1,BCRD        IS READ REQUESTED                     27000020
         BZ    BCREAD1            BRANCH IF NOT                         27050020
*/*           D  (YES,,NO,BCREAD) READ DIRECTORY */                     27100020
         TM    BCIOF2,BCDIR       READ DIRECTORY RECORD                 27150020
         BZ    BCREAD             BRANCH IF NOT                         27200020
*/*           P  GET PTR TO DIRECTORY RECORD */                         27250020
         LR    REG5,REG4          PTR TO BUFFER IN R5 FOR READ          27300020
*/*BCREAD:    P  SET RBA FOR READ */                                    27350020
BCREAD   LA    REG3,BCIORBA       RBA FOR READ                          27400020
*/*           I  READ RECORD */                                         27450020
         READ  BCDECB1,DIF,(REGA),(REG5),,,(REG3),MF=(E,(1))            27500020
*********************************************************************** 27550020
*                                                                     * 27600020
*        CHECK TO BE SURE I/O HAS COMPLETED SATISFACTORILY            * 27650020
*                                                                     * 27700020
*********************************************************************** 27750020
BCCCHK1  DS    0H                 CODE TO ISSUE CHECK                   27800020
*/*BCCCHK1:   P  CHECK FOR SUCCESSFUL READ */                           27850020
         CHECK BCDECB1            CHECK FOR COMPLETE READ               27900020
*********************************************************************** 27950020
*        DETERMINE IF ENTRY IS FROM LOGON. IF IT IS , MESSAGE UNITS   * 28000020
*              WILL BE BUILT IN CORE GOTTEN FROM SP 1 BY THE FOLLOWING* 28050020
*              CODE; AND THEN ISSUED (PUTLINE) TO THE TERMINAL BY THE * 28100020
*              THE LOGON MODULE IKJEFLH .                             * 28150020
*********************************************************************** 28200020
*/*           D  (YES,,NO,BCCCLOSE) ENTRY FROM LOGON? */                28250020
         SPACE 3                                                        28300020
         TM    BCPERMF,BCLOGON         IS ENTRY FROM LOGON?             28350020
         BZ    BCCCLOSE                NO, CONTINUE PROCESSING          28400020
*/*           D  (YES,BCCCLOSE,NO,) DIRECTORY RECORD READ? */           28450020
         TM    BCIOF2,BCDIR            WAS A DIRECTORY RECORD READ?     28500020
         BO    BCCCLOSE                YES, DO NOT BUILD MSG UNITS      28550020
         SR    REG9,REG9               ZERO OUT REG9                    28600020
         IC    REG9,N0(N0,REG5)        GET LENGTH OF MSG TEXT FROM      28650020
*                                      MSG BUFFER POINTED TO BY REG5    28700020
         LA    REG9,N8(REG9)           LENGTH OF MSG TXT + HEADER       28750020
*/*           P  GET CORE TO BUILD THE MESSAGE UNIT (SP 1) */           28800020
         GETMAIN  ,LV=(REG9),A=BCGETADR,SP=1,MF=(E,BCGETMNL)            28850020
*                                      GET AREA FOR MESSAGE UNIT      * 28900020
*/*           D  (YES,,NO,NOCORE) GETMAIN SUCCESSFUL? */                28950020
         LTR   REG15,REG15             WAS GETMAIN SUCCESSFUL?          29000020
*                                                                       29050020
         BNZ   NOCORE                  IF NOT SUCCESSFUL REG 15 NOT 0   29100020
         L     REG11,BCGETADR          MOVE ADDRESS OF GOTTEN CORE      29150020
*                                      INTO REG 11.                     29200020
         L     REG9,BCLWAMSG           GET POINTER TO LWANOT FIELD IN   29250020
*                                      LOGON PARM LIST                  29300020
*********************************************************************** 29350020
*        DETERMINE IF 'NOTICES' WERE REQUESTED FROM LOGON. IF SO      * 29400020
*        DETERMINE IF THIS IS THE FIRST NOTICE MESSAGE UNIT TO BE     * 29450020
*        BUILT.  IF IT IS THE FIRST, STORE ITS ADDRESS IN THE LOGON   * 29500020
*        PARM LIST AND THEN BRANCH TO BUILD THE MESSAGE UNIT. IF      * 29550020
*        IT IS NOT THE FIRST NOTICE MESSAGE UNIT, CHAIN THIS ONE TO   * 29600020
*        THE PREVIOUS MESSAGE UNIT.                                   * 29650020
*********************************************************************** 29700020
TESTNOT  EQU   *                       TEST IF NOTICE MSG UNITS ARE     29750020
*                                      TO BE BUILT IN CORE GOTTEN       29800020
*/*TESTNOT:   D  (YES,,NO,TESTMAL) NOTICES REQUESTED? */                29850020
         TM    BCIOF3,BCMSUB           ARE NOTICE MSG UNITS TOBE BUILT? 29900020
         BZ    TESTMAL                 NO, BRANCH TO TEST FOR MAIL      29950020
         L     REG9,N0(REG9)           YES, GET CONTENTS OF LWAPNOT     30000020
*/*           D  (YES,,NO,NOTFIRST) FIRST NOTICES MSGU? */              30050020
         LTR   REG9,REG9               TEST IF LWAPNOT IS ZERO. IF YES  30100020
*                                      THIS IS THE FIRST MSG UNIT TO    30150020
*                                      BE BUILT                         30200020
         BNZ   NOTFIRST                NOT FIRST, BRANCH TO BUILD MSG   30250020
*                                      UNIT.                            30300020
*/*           P  (,SETMSGU) SAVE PTR TO FIRST NOTICE MSGU IN FIELD IN   30350020
*/*LWA */                                                               30400020
         L     REG9,BCLWAMSG                                            30450020
         ST    REG11,N0(N0,REG9)       STORE ADDRESS OF FIRST NOTICE    30500020
*                                      MSG UNIT IN LWAPNOT FIELD.       30550020
         ST    REG11,BCNXTP            SAVE PTR TO CURRENT MSG UNIT     30600020
         B   SETMSGU                   BRANCH TO SET UP NOTICE MSG UNIT 30650020
*********************************************************************** 30700020
*        DETERMINE IF 'MAIL' WAS REQUESTED FROM LOGON. IF SO          * 30750020
*        DETERMINE IF THIS IS THE FIRST MAIL MESSAGE UNIT TO BE       * 30800020
*        BUILT.  IF IT IS THE FIRST, STORE ITS ADDRESS IN THE LOGON   * 30850020
*        WORKAREA AND THEN BRANCH TO BUILD THE MESSAGE UNIT. IF       * 30900020
*        IT IS NOT THE FIRST MAIL MESSAGE UNIT, CHAIN THIS ONE TO     * 30950020
*        THE PREVIOUS MESSAGE UNIT.                                   * 31000020
*********************************************************************** 31050020
*/*TESTMAL:   D  (YES,,NO,BCEND) MAIL REQUESTED? */                     31100020
TESTMAL  EQU   *                       TEST IF MAIL MSG UNITS ARE TO    31150020
*                                      BE BUILT IN CORE GOTTEN          31200020
         TM    BCIOF3,BCMSUU           ARE MAIL MSG UNITS TO BE BUILT?  31250020
         BZ    BCEND                   NO, RETURN TO CALLER             31300020
         L     REG9,N4(REG9)           YES, GET CONTENTS OF LWAPMAL     31350020
*/*           D  (YES,,NO,NOTFIRST) FIRST MAIL MSGU? */                 31400020
         LTR   REG9,REG9               TEST IF LWAPMAL IS ZERO. IF YES  31450020
*                                      THIS IS THE FIRST MAIL MSG UNIT  31500020
*                                      TO BE BUILT IN CORE.             31550020
         BNZ   NOTFIRST                NOT FIRST, BRANCH TO BUILD MSG   31600020
*                                      UNIT.                            31650020
*/*           P  (,SETMSGU) SAVE PTR TO FIRST MAIL MSGU IN FIELD IN     31700020
*/*LWA */                                                               31750020
         L     REG9,BCLWAMSG           GET ADDRESS OF LWAPNOT           31800020
         ST    REG11,N4(N0,REG9)       STORE ADDRESS OF FIRST MAIL MSG  31850020
*                                      UNIT IN LWAPMAL.                 31900020
         ST    REG11,BCNXTP                                             31950020
         B     SETMSGU                 BRANCH TO SET UP MSG UNIT        32000020
*********************************************************************** 32050020
*        CHAIN THE MESSAGE UNIT TO THE PREVIOUS MESSAGE UNIT          * 32100020
*                                                                     * 32150020
*********************************************************************** 32200020
NOTFIRST EQU   *                       THIS IS NOT THE FIRST MSG UNIT   32250020
*/*NOTFIRST:  P  CHAIN CURRENT MSGU TO PREVIOUS MSGU */                 32300020
         L     REG14,BCNXTP            GET PREVIOUS MSG UNIT ADDRESS    32350020
         USING BCMSGU,REG14            SET ADDRESSIBILITY FOR PREV MSGU 32400020
         ST    REG11,BCMNXT            CHAIN  THIS MSG UNIT TO THE      32450020
*                                      PREVIOUS MSG UNIT                32500020
         ST    REG11,BCNXTP            UPDATE PTR TO NEXT MSGU          32550020
         DROP  REG14                                                    32600020
*********************************************************************** 32650020
*        BUILD THE MESSAGE UNIT IN CORE GOTTEN FROM SP 1              * 32700020
*********************************************************************** 32750020
SETMSGU  EQU   *                       SET UP MSG UNIT                  32800020
*/*SETMSGU:   P  (,BCEND) BUILD THE MESSAGE UNIT (MSGU) */              32850020
         USING BCMSGU,REG11            SET ADDRESSIBILITY FOR NEW MSGU  32900020
         SR    REG9,REG9               ZERO OUT REGISTER 9              32950020
         ST    REG9,BCMNXT             ZERO PTR TO NEXT MSG UNIT        33000020
         STH   REG9,BCMRSV             ZERO RESERVE FIELD               33050020
         IC    REG9,N0(N0,REG5)        GET MSG TXT LENGTH FROM MSG      33100020
*                                      BUFFER POINTED TO BY REG5.       33150020
         BCTR  REG9,REG0               DECREMENT LENGTH BY 1 FOR EX     33200020
*                                      INSTRUCTION                      33250020
         EX    REG9,MOVETXT            MOVE MSG TXT INTO MSG UNIT       33300020
         LA    REG9,N5(REG9)           GET LENGTH OF MSG TXT + 4  FOR   33350020
*                                      HEADER + 1 FOR EX INSTRUCTION    33400020
         STH   REG9,BCMLTH             SET LENGTH OF MSGU               33450020
         B     BCEND                   BRANCH FOR CLEAN UP.             33500020
*********************************************************************** 33550020
*                                                                     * 33600020
*        READ THE FIRST RECORD (RESERVED) OF THE BROADCAST DATA SET   * 33650020
*              BY KEY TO SEE IF IT HAS BEEN FORMATTED AND TO GET THE  * 33700020
*              RBA OF THE FIRST DIRECTORY RECORD                      * 33750020
*                                                                     * 33800020
*********************************************************************** 33850020
BCREAD1  DS    0H                 CODE FOR READING FIRST RECORD         33900020
*/*BCREAD1:   D  (NO,BCCWRITE,YES,) READ FIRST RECORD REQUESTED */      33950020
         TM    BCIOF1,BCRD1       IS READ OF FIRST RECORD REQUESTED     34000020
         BZ    BCCWRITE           BRANCH IF NOT                         34050020
*/*           I  READ RECORD ONE */                                     34100020
         READ  BCDECB2,DI,(REGA),(REG4),,,,MF=(E,(1)) READ FIRST REC    34150020
*********************************************************************** 34200020
*                                                                     * 34250020
*        CHECK TO BE SURE I/O HAS COMPLETED SATISFACTORILY            * 34300020
*                                                                     * 34350020
*********************************************************************** 34400020
BCCCHK2  DS    0H                 CODE TO ISSUE CHECK                   34450020
*/*BCCCHK2:   P  (,BCCCLOSE) CHECK FOR SUCCESSFUL READ OF RECORD 1 */   34500020
         CHECK BCDECB2            CHECK FOR COMPLETE READ               34550020
*                                                                     * 34600020
         B     BCCCLOSE           GO CHECK FOR CLOSE                    34650020
         SPACE 3                                                        34700020
*********************************************************************** 34750020
*                                                                     * 34800020
*        WRITE BY RBA UPDATED RECORDS TO SYS1.BRODCAST                * 34850020
*********************************************************************** 34900020
BCCWRITE DS    0H                 CODE TO DO WRITE                      34950020
*/*BCCWRITE:  D  (NO,BCCCLOSE,YES,) WRITE REQUESTED */                  35000020
         TM    BCIOF2,BCWRITE     IS WRITE REQUESTED                    35050020
         BZ    BCCCLOSE           BRANCH IF NOT                         35100020
*/*           D  (YES,,NO,BCWRIT) WRITE DIRECTORY RECORD */             35150020
         TM    BCIOF2,BCDIR       IS THIS FOR A DIRECTORY RECORD        35200020
         BZ    BCWRIT             BRANCH IF NOT                         35250020
         LR    REG5,REG4          TRANSFER BUFFER POINTER FOR READ      35300020
*/*           P  GET RBA FOR WRITE */                                   35350020
         LA    REG3,BCWRRBA       RBA FOR WRITE                         35400020
*/*           I  WRITE DIRECTORY RECORD */                              35450020
         WRITE BCDECB3,DI,(REGA),(REG5),,,(REG3),MF=(E,(1))             35500020
*********************************************************************** 35550020
*                                                                     * 35600020
*        CHECK TO BE SURE I/O HAS COMPLETED SATISFACTORILY            * 35650020
*                                                                     * 35700020
*********************************************************************** 35750020
BCCCHK   DS    0H                 CODE TO ISSUE CHECK                   35800020
*/*BCCCHK:    P  (,BCCCLOSE) CHECK FOR SUCCESSFUL WRITE OF DIRECTORY    35850020
*/*RECORD */                                                            35900020
         CHECK BCDECB3            CHECK FOR COMPLETE WRITE              35950020
         B     BCCCLOSE           GO CHECK FOR CLOSE                    36000020
         SPACE 3                                                        36050020
*********************************************************************** 36100020
*                                                                     * 36150020
*        WRITE MESSAGE RECORD TO DATA SET WITH KEY 'FF' TO ALLOW RE-USE 36200020
*                                                                     * 36250020
*********************************************************************** 36300020
*/*BCWRIT:    P  GET RBA FOR WRITE MSG */                               36350020
BCWRIT   LA    REG3,BCWRRBA       RBA FOR WRITE                         36400020
         MVC   0(1,REG5),BCIORBA+7     MOVE REL POSITION ON TRACK       36450020
*/*           I  WRITE MESSAGE RECORD */                                36500020
         WRITE BCDECB4,DI,(REGA),(REG5),,,(REG3),MF=(E,(1))             36550020
*********************************************************************** 36600020
*                                                                     * 36650020
*        CHECK TO BE SURE I/O HAS COMPLETED SATISFACTORILY            * 36700020
*                                                                     * 36750020
*********************************************************************** 36800020
BCCCHK3  DS    0H                 CODE TO ISSUE CHECK                   36900020
*/*BCCCHK3:   P  CHECK WRITE */                                         36950020
         CHECK BCDECB4            CHECK FOR COMPLETE WRITE              37000020
         SPACE 3                                                        37050020
*********************************************************************** 37100020
*                                                                     * 37150020
*        CLOSE SYS1.BRODCAST                                          * 37200020
*                                                                     * 37250020
*********************************************************************** 37300020
BCCCLOSE DS    0H                 CODE TO ISSUE CLOSE                   37350020
*/*BCCCLOSE:  D  (YES,,NO,BCPUTLN) CLOSE REQUESTED */                   37400020
         TM    BCIOF1,BCCLOSE     IS CLOSE REQUESTED                    37450020
         BZ    BCPUTLN            BRANCH IF NOT                         37500020
         LA    PARMREG,BCCLL      PTR TO GENERATED PARM LIST            37550020
*/*           I  CLOSE BROADCAST DATA SET */                            37600020
         CLOSE ((REGA)),MF=(E,(1))      CLOSE DATA SET                  37650020
         SPACE 3                                                        37700020
*********************************************************************** 37750020
*                                                                     * 37800020
*        THE DCB FOR SYS1.BRODCAST WILL BE RELEASED AUTOMATICALLY     * 37850020
*             AFTER THAT DATA SET IS CLOSED                           * 37900020
*                                                                     * 37950020
*********************************************************************** 38000020
         LR    PARMREG,REGA       PTR TO DCB AND WORK AREA              38050020
*/*           P  FREEMAIN DCB CORE */                                   38100020
         FREEMAIN R,LV=WKARLEN,A=(1),SP=1  FREE DCB AND MACRO LISTS     38150020
*/*           P  CLEAR PERMANENT FLAGS */                               38200020
         XC    BCPERMF,BCPERMF    CLEAR 'PERMANENT' FLAGS               38250020
         SPACE 3                                                        38300020
*********************************************************************** 38350020
*                                                                     * 38400020
*        ISSUE PUTLINE FOR ERROR MESSAGES OR FOR PRINTING BROADCAST   * 38450020
*              MESSAGES.                                              * 38500020
*                                                                     * 38550020
*********************************************************************** 38600020
BCPUTLN  DS    0H                 CODE TO DO PUTLINE                    38650020
*/*BCPUTL:    D  (YES,,NO,BCDELET) PUTLINE REQUESTED */                 38700020
         TM    BCIOF1,BCPUTL      IS PUTLINE REQUESTED                  38750020
         BZ    BCDELET            BRANCH IF NOT                         38800020
         L     PARMREG,BCPUTLP    PTR TO PARM LIST FOR PUTLINE          38850020
         SPACE 3                                                        38900020
*********************************************************************** 38950020
*                                                                     * 39000020
*        CHECK TO SEE IF THE PUTLINE IS FOR AN ERROR MESSAGE. IF NOT  * 39050020
*        IT IS FOR A BROADCAST MESSAGE- BRANCH TO PUTLINE FOR 1 LEVEL * 39100020
*                                                                     * 39150020
*********************************************************************** 39200020
*/*           D  (YES,,NO,BCPUTLM) FOR ERROR MSG? */                    39250020
         TM    BCIOF3,BCERFLG     IS PUTLINE FOR ERROR MESSAGE?         39300020
         BZ    BCPUTLM            NO, BRANCH TO PUTLINE BROADCAST MSG   39350020
         SPACE 3                                                        39400020
*/*FINDMSG:   P  LOCATE APPROPRIATE MESSAGE */                          39450020
**********************************************************************  39500020
*        THE FOLLWING CODE INDEXES INTO THE LISTBC MESSAGE MODULE    *  39550020
*        IKJEES74, AND RETRIEVES THE POINTER TO THE APPROPRIATE      *  39600020
*        ERROR MESSAGE OUT PUT LINE DESCRIPTOR BLOCK.                *  39650020
**********************************************************************  39700020
         SPACE 3                                                        39750020
**********************************************************************  39800020
*        CALCULATE THE OFFSET TO THE ADDRESS OF THE OUT PUT LINE     *  39850020
*        DESCRIPTOR FOR THE APPROPRIATE ERROR MESSAGE                *  39900020
**********************************************************************  39950020
FINDMSG  EQU   *                                                        40000020
         LA    REG15,2            LOAD MULTIPLICAN INTO REGISTER        40050020
         MH    REG15,BCERCDE      MULTIPLY ERROR MESSAGE INDEX BY       40100020
*                                 MULTIPLICAN                           40150020
         SH    REG15,TWO          SUBTRACT 2 FROM THE QUOTIENT          40200020
         L     REG7,VMSG          LOAD THE ADDRESS CONSTANT FOR THE     40250020
*                                 MESSAGE MODULE IKJEES74               40300020
         AR    REG15,REG7         ADD THE REMAINDER FROM THE SUBTRACT-  40350020
*                                 TION AND THE ADCON OF IKJEES74        40400020
         ST    REG15,MSGOFF       STORE ADDRESS OF THE OFFSET TO THE    40450020
*                                 ERROR MESSAGE                         40500020
*********************************************************************** 40550020
*        CALCULATE THE ADDRESS OF THE MESSAGE TEXT IN THE MESSAGE     * 40600020
*        CSECT                                                        * 40650020
*********************************************************************** 40700020
         LR    REG15,REG7         LOAD THE ADDRESS CONSTANT FOR THE     40750020
*                                 MESSAGE MODULE IKJEES74               40800020
         L     REG9,MSGOFF        LOAD THE PTR TO THE OFFSET            40850020
         AH    REG15,0(REG9)      ADD THE ACTUAL OFFSET TO THE ERROR    40900020
*                                 MESSAGE AND THE ADDRESS OF IKJEES74   40950020
         ST    REG15,MSGOFF       STORE THE POINTER TO THE OUT PUT LINE 41000020
*                                 DESCRIPTOR FOR THE ERROR MESSAGE      41050020
*/*           D  (YES,TXTSRT,NO,) TEXT INSERTION REQUIRED? */           41100020
*********************************************************************** 41150020
*        DETERMINE IF THE ERROR MESSAGE REQUIRES TEXT INSERTION.      * 41200020
*        IF TEXT INSERTION IS NOT REQUIRED, IT IS THEN DETERMINED     * 41250020
*        IF THE ERROR MESSAGE IS A ONE-LEVEL OR TWO-LEVEL MESSAGE     * 41300020
*        AND THE APPROPRIATE 'PUTLINE' IS USED TO ISSUE THE ERROR     * 41350020
*        MESSAGE TO THE TERMINAL. IF TEXT INSERTION IS REQUIRED,      * 41400020
*        THEN A BRANCH IS TAKEN TO DO THE INSERTION.                  * 41450020
*********************************************************************** 41500020
         TM    BCIOF3,BCTXTIN     IS TEXT INSERTION REQUIRED FOR THIS   41550020
*                                 ERROR MESSAGE?                        41600020
         BO    TXTSRT             YES, BRANCH TO DO INSERTION           41650020
         L     REG15,BCPUT        LOAD THE ENTRY POINT TO PUTLINE       41700020
         L     REG5,MSGOFF        LOAD PTR TO THE ERROR MESSAGE         41750020
*/*           D  (YES,BCPUTL1,NO,BCPUTL2) ONE LEVEL MESSAGE? */         41800020
         TM    BCIOF3,BC1LVL      IS THIS A ONE-LEVEL ERROR MESSAGE?    41850020
         BO    BCPUTL1E           BRANCH TO ISSUE ONE-LEVEL ERROR MSG   41900020
         B     BCPUTL2E           BRANCH TO ISSUE TWO-LEVEL ERROR MSG   41950020
*/*TXTSRT:    P  CONVERT COMPLETION CODE (IF ANY) TO DECIMAL */         42000020
*********************************************************************** 42050020
*        TEXT INSERTION IS REQUIRED FOR THE ERROR MESSAGE. THE        * 42100020
*        FOLLOWING CODE CONVERTS THE ERROR CODE, WHICH HAS BEEN       * 42150020
*        RETURNED BY THE EXTERNAL ROUTINE (I.E. PUTLINE, DAIR,        * 42200020
*        PARSE) IN ERROR FROM BINARY TO ZONED DECIMAL.                * 42250020
*********************************************************************** 42300020
TXTSRT   EQU   *                                                        42350020
         TM    BCIOF3,BCHXCV      IS ERROR CODE TO BE PUT OUT IN        42400020
*                                 PRINTABLE HEX?                        42450020
         BO    HEXCV              YES, BRANCH TO DO CONVERSION          42500020
         LH    REG7,BCRTCDE       LOAD ERROR RETURN CODE FROM I/O PARM  42550020
*                                 LIST                                  42600020
         CVD   REG7,BCDEC         CONVERT RETURN CODE TO DECIMAL        42650020
         UNPK  UNPCK(N8),BCDEC    UNPACK THE RETURN CODE                42700020
         OI    UNPCK+N7,X'F0'                                           42750020
*/*           P  SET UP TEXT INSERTION SEGMENTS */                      42800020
*********************************************************************** 42850020
*        THE FOLLOWING CODE MOVES THE OUTPUT LINE DESCRIPTOR FOR      * 42900020
*        THE FIRST-LEVEL MESSAGE, THE OUTPUT LINE DESCRIPTOR FOR      * 42950020
*        THE SECOND-LEVEL MESSAGE, AND THE SEGMENT INTO THE WHICH     * 43000020
*        THE ERROR CODE IS TO BE PLACED INTO DYNAMIC CORE. THIS IS    * 43050020
*        FOR THE PURPOSE OF STORING INTO THE APPROPRIATE ADDRESS      * 43100020
*        CONSTANT, IN THE SECOND-LEVEL OUTPUT LINE DESCRIPTOR, THE    * 43150020
*        POINTER TO THE SEGMENT INTO WHICH THE ERROR CODE HAS BEEN    * 43200020
*        INSERTED;AND CHAINING THE OUTPUT LINE DESCRIPTOR FOR THE     * 43250020
*        SECOND-LEVEL MESSAGE TO THE OUTPUT LINE DESCRIPTOR FOR THE   * 43300020
*        FIRST-LEVEL MESSAGE. REG5 WILL THEN BE LOADED WITH THE       * 43350020
*        ADDRESS OF THE OUTPUT LINE DESCRIPTOR FOR THE FIRST LEVEL    * 43400020
*        MESSAGE AND THEN PUTLINED TO THE TERMINAL.                   * 43450020
*********************************************************************** 43500020
INSERT   EQU   *                                                        43550020
         L     REG7,MSGOFF        LOAD OFFSET TO OUTPUT LINE DESCRIP-   43600020
*                                 TOR (OLD) FOR ERROR MESSAGE           43650020
         MVC   MSG1B(N16),N0(REG7)  MOVE OLD FOR FIRST-LEVEL MESSAGE    43700020
*                                 INTO DYNAMIC CORE                     43750020
         L     REG7,N0(REG7)      LOAD ADDRESS OF OLD FOR SECOND-LEVEL  43800020
*                                 ERROR MESSAGE                         43850020
         MVC   MSG2B(N20),N0(REG7)  MOVE OLD FOR SECOND-LEVEL MESSAGE   43900020
         LA    REG7,MSG2B         LOAD ADDRESS OF SECOND-LEVEL OLD      43950020
         ST    REG7,MSG2PTR       CHAIN OLD FOR SECOND-LEVEL TO OLD     44000020
*                                 FOR FIRST-LEVEL MESSAGE               44050020
         L     REG7,SEG2C         GET ADDRESS OF SEGMENT NEEDING TEXT   44100020
*                                 INSERTION                             44150020
         MVC   MSG3B(N8),N0(REG7) MOVE THE SEGMENT REQUIRING INSERTION  44200020
*                                 INTO THE DYNAMIC AREA                 44250020
         LA    REG7,MSG3B         LOAD THE ADDRESS OF THE MESSAGE       44300020
*                                 SEGMENT NEEDING INSERTION             44350020
         ST    REG7,SEG2C         STORE ADDRESS IN SECOND-LEVEL OLD     44400020
         MVC   SEGSRT(N4),UNPCK+N4  MOVE DECIMAL RETURN CODE INTO       44450020
*                                 SEGMENT                               44500020
         L     REG15,BCPUT        LOAD ADDRESS OF PUTLINE ENTRY         44550020
         LA    REG5,MSG1B         LOAD ADDRESS OF OLD FROM DYNAMIC AREA 44600020
         B     BCPUTL2E           BRANCH TO ISSUE ERROR MESSAGE TO      44650020
*                                 TERMINAL                              44700020
HEXCV    EQU   *                  CONVERT THE ERROR CODE TO PRINTABLE   44750020
*                                 HEX                                   44800020
         UNPK  UNPCK(N9),BCRTCDE(N3)  UNPACK THE ERROR CODE             44850020
         XC    UNPCK+N4(N4),ZERO                                        44900020
         TR    UNPCK+N4(N4),TRTABLE  CONVERT ERROR CODE TO PRINTABLE    44950020
*                                   HEX                                 45000020
         B     INSERT             BRANCH TO INSERT ERROR CODE INTO      45050020
*                                 ERROR MESSAGE                         45100020
*********************************************************************** 45150020
*        THIS IS THE ENTRY FOR PUTTING OUT BROADCAST MESSAGES.  REG5  * 45200020
*        POINTS TO THE BUFFER WHERE THE MESSAGE WAS JUST READ INTO- SO* 45250020
*        REG5 IS DECREMENTED BY FOUR TO POINT TO THE LENGTH AND OFFSET* 45300020
*        FIELDS (USED BY PUTLINE) WHICH IMMEDIATELY PRECEDE THE BUFFER* 45350020
*        ALSO THE LENGTH OF THE MESSAGE IS IN THE FIRST BYTE OF THE   * 45400020
*        BUFFER- SO THIS LENGTH IF TRANSFERRED TO THE 'PREFIX' PARM   * 45450020
*        WORD AND THEN THE BYTE IS BLANKED OUT.                       * 45500020
*        THE LENGTH IS INCREMENTED TO INCLUDE THE LENGTH OF THE PREFIX* 45550020
*        WORD AND THE LENGTH OF THE LENGTH FIELD ITSELF.              * 45600020
*                                                                     * 45650020
*********************************************************************** 45700020
BCPUTLM  DS    0H                                                       45750020
*/*BCPUTLM:   P  GET LENGTH OF MESSAGE */                               45800020
         S     REG5,PREFIX        SET BUFF PTR TO PREFIX PARM           45850020
         SR    REG6,REG6          CLEAR REG                             45900020
         IC    REG6,BFOFFSET(REG5)     LOAD LENGTH                      45950020
         LA    REG6,BFOFFSET+LENLEN(REG6)   INCREMENT LENGTH COUNT      46000020
         STC   REG6,PRFIX(REG5)   STORE IN PARM BLOCK                   46050020
         MVI   BFOFFSET(REG5),BLANK   BLANK OUT LENGTH BYTE             46100020
         LA    REG6,SEGNUM        ONE SEGMENT MSGS                      46150020
         ST    REG6,PUTLEN        STORE IN PARM LIST                    46200020
         L     REG15,BCPUT        PTR TO PUTLINE ENTRY POINT            46250020
         SPACE 3                                                        46300020
*/*BCPUTL1:   S  IKJPUTL: ISSUE MESSAGE TO TERMINAL */                  46350020
PUTLDATA PUTLINE PARM=BCPUTLDL,OUTPUT=((REG5),DATA),ENTRY=(15),        C46400020
               MF=(E,(1))                                               46450020
*/*           D  (YES,BCDELET,NO,) PUTLINE SUCCESSFUL? */               46500020
*/*           D  (YES,NOCORE,NO,) INSUFFIC- IENT CORE? */               46550020
*/*           P  (,TXTSRT) SET ERROR MESSAGE CODE: COMMAND SYSTEM ERROR 46600020
*/* */                                                                  46650020
         LTR   REG15,REG15             TEST RTN CODE FROM PUTLINE       46700020
         BNZ   NOCORE                  BAD RTN CODE BRANCH TO ERR TRN   46750020
         B     BCDELET            BRANCH TO NEXT OPERATION              46800020
         SPACE 3                                                        46850020
*********************************************************************** 46900020
*        REG5 POINTS TO THE OUTPUT LINE DESCRIPTOR IN MESSAGE MODULE  * 46950020
*        IKJEES74 FOR THE APPROPRIATE ONE-LEVEL ERROR MESSAGE THAT    * 47000020
*        IS TO BE ISSUED TO THE TERMINAL VIA 'PUTLINE'.               * 47050020
*********************************************************************** 47100020
BCPUTL1E PUTLINE PARM=BCPUTL1L,OUTPUT=((REG5)),ENTRY=(15),MF=(E,(1))    47150020
         LTR   REG15,REG15             CHECK RTN CODE FROM PUTLINE      47200020
         BNZ   NOCORE                  CHECK PUTINE RETURN CODE         47250020
         B     BCDELET            CONTINUE PROCESSING                   47300020
         SPACE 3                                                        47350020
*********************************************************************** 47400020
*       THE FOLLOWING IS THE PUTLINE FOR ALL TWO-LEVEL ERROR          * 47450020
*       MESSAGES.  REG5 POINTS TO THE OUTPUT LINE DESCRIPTOR          * 47500020
*       FOR THE ERROR MESSAGE THAT IS TO BE ISSUED TO THE TERMINAL    * 47550020
*       VIA 'PUTLINE'.                                                * 47600020
*********************************************************************** 47650020
*/*BCPUTLN:   P  PUTLINE FOR 2 LEVEL MSGS */                            47700020
*/*BCPUTL2:  S   IKJPUTL: ISSUE 2 LEVEL ERROR MESSAGE */                47750020
BCPUTL2E PUTLINE PARM=BCPUTL2L,OUTPUT=((REG5),MULTLVL),ENTRY=(15),     C47800020
               MF=(E,(1))                                               47850020
*/*           D  (YES,,NO,) PUTLINE SUCCESSFUL? */                      47900020
*/*           D  (YES,NOCORE,NO,) INSUFFIC- IENT CORE? */               47950020
*/*           P  (,TXTSRT) SET ERROR MESSAGE CODE: COMMAND SYSTEM ERROR 48000020
*/* */                                                                  48050020
         LTR   REG15,REG15             CHECK PUTLINE RETURN CODE        48100020
         BNZ   NOCORE                  BRANCH TO ERROR ROUTINE          48150020
         SPACE 3                                                        48200020
*********************************************************************** 48250020
*                                                                     * 48300020
*        DELETE THE MODULES OF THE PUTLINE SERVICE ROUTINE            * 48350020
*                                                                     * 48400020
*********************************************************************** 48450020
BCDELET  DS    0H                 CODE TO DELETE PUTLINE MODULES        48500020
*/*BCDELET:   D  (YES,,NO,BCEND) DELETE REQUESTED */                    48550020
         TM    BCIOF2,BCDELETE    IS DELETE REQUESTED                   48600020
         BZ    BCEND              BRANCH IF NOT                         48650020
*/*           P  DELETE PUTLINE MODULES */                              48700020
         DELETE EP=IKJPUTL        MACRO                                 48750020
         SPACE 3                                                        48800020
*********************************************************************** 48850020
*                                                                     * 48900020
*        CLEAN UP CODE EXECUTED BEFORE RETURNING TO LISTBC MODULE     * 48950020
*                                                                     * 49000020
*********************************************************************** 49050020
*/*BCEND:     P  CLEAR OPERATION FLAGS */                               49100020
BCEND    DS    0H                 CLEAN UP CODE                         49150020
         XC    BCIOF1(3),BCIOF1   CLEAR OPERATION FLAGS                 49200020
         LR    PARMREG,SAVE       PTR TO THIS MODULES SAVE AREA         49250020
         L     SAVE,4(SAVE)       LOAD PTR TO CALLERS SAVE AREA         49300020
*/*           P  FREEMAIN SAVE AREA CORE */                             49350020
         FREEMAIN R,LV=72,A=(1),SP=1  FREE SAVE AREA                    49400020
*/*           D  (YES,,NO,BCRTN) IS THERE AN ERROR */                   49450020
         LA    REG15,N0           LOAD ZERO RETURN CODE                 49470020
         TM    BCPERMF,BCERROR    WAS THERE AN ERROR CONDITION?         49500020
         BZ    BCRTN              NO, RETURN TO CALLER                  49550020
         LA    REG15,BCIOERR      YES SET RETURN CODE TO 8              49560020
*/*           P  SET RETURN CODE TO 8 */                                49570020
*/*BCRTN:     R  RETURN TO CALLER */                                    49580020
BCRTN    EQU   *                                                        49590020
         RETURN (14,12),RC=(15)   RETURN TO CALLER                      49650020
*/*BCEROUT:   P  RETURN CODE = 8 */                                     49700020
BCEROUT  EQU   *                                                        49750020
         OI    BCPERMF,BCERROR    INDICATE THAT AN ERROR CONDITION      49810020
*                                 OCCURRED                              49820020
         B     BCEND              BRANCH TO FREE SAVE AREA              49830020
*/*           P  (,BCEND) BRANCH TO FREE SAVE AREA */                   49840020
         SPACE 3                                                        49950020
*********************************************************************** 50000020
*        SYNAD ROUTINE TO HANDLE MESSAGES FOR I/O ERROR CASES. IF     * 50050020
*        ENTRY IS FROM LOGON, A RETURN CODE IS SET IN THE LOGON       * 50100020
*        WORKAREA INDICATING AN I/O ERROR OCCURRED AND THE LOGON      * 50150020
*        MODULE IKJEFLGM ISSUES THE ERROR MESSAGE TO THE TERMINAL.    * 50200020
*********************************************************************** 50250020
*/*BCSYNAD:   P  INDICATE ERROR OCCURRED */                             50300020
BCSYNAD  DS    0H                 ERROR ROUTINE FROM READ               50350020
*/*           D  (YES,SETRCDE,NO,) ENTRY FROM LOGON? */                 50360020
         TM    BCPERMF,BCLOGON    IS ENTRY FROM LOGON?            M0843 50400020
         BO    SETRCDE            YES,BRANCH TO SET RETURN CODE   M0843 50450020
         XC    BCIOF1(3),BCIOF1   CLEAR OPERATION FLAGS                 50500020
         OI    BCIOF1,BCPUTL      INDICATE PUTLINE                      50550020
         OI    BCIOF2,BCDEQX      INDICATE DEQUEUE                      50600020
*/*           P  SET ERROR MSG CODE: I/O SYNAD ERROR */                 50610020
         OI    BCIOF3,BCERFLG     INDICATE ERROR CONDITION OCCURRED     50650020
         OI    BCPERMF,BCERROR    INDICATE ERROR HAS OCCURRED           50700020
         LA    REG7,1             LOAD ERROR MSG INDEX INTO REGISTER    50750020
         STH   REG7,BCERCDE       SAVE ERROR MSG INDEX                  50800020
*/*           P  (,BCCDEQX) INDICATE DEQUE */                           50850020
         B     BCCDEQX            DO CLEANUP PROCESSING                 50900020
         SPACE 3                                                        50950020
*********************************************************************** 51000020
*                                                                     * 51050020
*        ROUTINE TO HANDLE MESSAGES FOR AN OPEN ERROR. IF ENTRY IS    * 51100020
*        FROM LOGON, A RETURN CODE IS SET IN THE LOGON PARM LIST      * 51150020
*        INDICATING AN OPEN ERROR OCCURRED AND THE LOGON MODULE       * 51200020
*        IKJEFLGM ISSUES THE ERROR MESSAGE TO THE TERMINAL.           * 51250020
*                                                                     * 51300020
*********************************************************************** 51350020
*/*BCERR1:    P  INDICATE ERROR OCCURRED */                             51400020
BCERR1   DS    0H                 ERROR CASE                            51500020
         OI    BCPERMF,BCERROR    INDICATE I/O ERROR HAS OCCURRED M0843 51550020
*/*           D  (YES,SETRCDE,NO,) ENTRY FROM LOGON? */                 51560020
         TM    BCPERMF,BCLOGON    IS ENTRY FROM LOGON?            M0843 51600020
         BO    SETRCDE            YES, BRANCH TO SET RETURN CODE  M0843 51650020
*/*           P  (,BCPUTLN) SET ERROR MSG CODE: CANNOT OPEN DATA SET */ 51660020
         XC    BCIOF1(3),BCIOF1   CLEAR OPERATION FLAGS                 51700020
         OI    BCIOF1,BCPUTL      INDICATE PUTLINE                      51750020
         OI    BCIOF3,BCERFLG     INDICATE ERROR CONDITION OCCURRED     51800020
         LA    REG7,2             LOAD ERROR MSG INDEX INTO REGISTER    51850020
         STH   REG7,BCERCDE       SAVE ERROR MSG INDEX                  51900020
         B     BCPUTLN            PUT OUT MESSAGES                      51950020
*/*NOCORE:    D  (YES,BCEROUT,NO,) 2ND ATTEMPT TO PUTLINE/ GETMAIN */   52000020
NOCORE   EQU   *                                                        52050020
         TM    BCPERMF,BCPUTER    IS THIS SECOND ATTEMPT TO PUTLN       52100020
         BNZ   BCEROUT            YES,BRANCH TO SET RTNCD=8             52150020
         XC    BCIOF1(3),BCIOF1   CLEAR OPERATION FLAGS                 52200020
*/*           P  SET FLAG TO INDICATE ONE ATTEMPT */                    52250020
*/*           P  (,FINDMSG) SET ERROR MESSAGE CODE: INSUFFICIENT CORE   52300020
*/*TO EXECUTE COMMAND */                                                52350020
         OI    BCIOF1,BCPUTL      INDICATE PUTLINE                      52400020
         OI    BCIOF3,BC1LVL      INDICATE ONE-LEVEL ERROR MSG          52450020
         OI    BCPERMF,BCPUTER    SET FLAG TO INDICATE ONE ATTEMT       52500020
*                                 HAS BEEN MADE TO PUTLINE A MSG        52550020
         LA    REG7,8             LOAD ERROR MSG INDEX INTO REGISTER    52600020
         STH   REG7,BCERCDE       SAVE ERROR MSG INDEX                  52650020
         B     FINDMSG            BRANCH TO PUTLINE ERROR MSG           52700020
*/*SETRCDE:   P  DETERMINE WHAT TYPE OF ERROR OCCURRED: OPEN OR I/O */  52710020
SETRCDE  EQU   *                                                  M0843 52750020
         L     REG9,BCLWAMSG      LOAD POINTER TO LWANOT FIELD IN M0843 52800020
*                                 LOGON PARM LIST                 M0843 52850020
*/*           D  (YES,OPENERR,NO,) IS THIS OPEN ERR? */                 52860020
         TM    BCPERMF,BCERROR    IS THIS AN OPEN ERROR?          M0843 52900020
         BO    OPENERR            BRANCH TO SET OPEN ERROR RETURN       52950020
*                                 CODE                            M0843 53000020
*/*           P  (,BCEROUT) SET RETURN CODE OF 8 */                     53010020
         LA    REG7,IOERROR       LOAD RETURN CODE 8              M0843 53050020
         ST    REG7,N8(N0,REG9)   SAVE RETURN CODE IN LOGON PARM LIST   53100020
*                                 LIST                            M0843 53150020
*                                                                       53156021
*        INSURE DEQ FROM RBA BEFORE RETURNING TO CALLER                 53162021
*                                                                       53168021
*/*           P  DEQ EXCLUSIVE ON BRODCAST DATASET            */        53174021
         LA    REG3,BCEQXRBA      PTR TO RBA                   A56110   53180021
         LA    PARMREG,BCDQLX     PTR TO DEQ PARM LIST         A56110   53186021
         DEQ   (,(REG3)),MF=(E,(1))                            A56110   53192021
         B     BCEROUT            BRANCH TO SET RETURN CODE FOR         53200020
*                                 CALLER                          M0843 53250020
*/*OPENERR:   P  (,BCEROUT) SET RETURN CODE OF 4 */                     53260020
OPENERR  EQU   *                                                  M0843 53300020
         LA    REG7,OPNERROR      LOAD RETURN CODE 4              M0843 53350020
         ST    REG7,N8(N0,REG9)   SAVE RETURN CODE IN LOGON PARM        53400020
*                                 LIST                            M0843 53450020
         B     BCEROUT            BRANCH TO SET RETURN CODE FOR         53500020
*                                 CALLER                          M0843 53550020
MOVETXT  MVC   BCMTXT(N0),LENLEN(REG5)                                  53600020
         EJECT                                                          53650020
*********************************************************************** 53700020
*                                                                     * 53750020
*        DCB FOR READING AND WRITING IN THE SYS1.BRODCAST DATA SET    * 53800020
*                                                                     * 53850020
*********************************************************************** 53900020
BCCDCB   DCB   BLKSIZE=129,                                            C53950020
               BUFL=129,                                               C54000020
               DDNAME=SYSLBC,                                          C54050020
               DSORG=DA,                                               C54100020
               KEYLEN=1,                                               C54150020
               MACRF=(RIC,WIC),                                        C54200020
               OPTCD=WR,                                               C54250020
               RECFM=F,                                                C54300020
               SYNAD=BCSYNAD                                            54350020
         EJECT                                                          54400020
*********************************************************************** 54450020
*                                                                     * 54500020
*        FOLLOWING ARE PARAMETER LISTS FORMED BY THE LIST FORM OF     * 54550020
*             MACROS.                                                 * 54600020
*                                                                     * 54650020
*********************************************************************** 54700020
BCBEGL   DS    0H                 BEGIN GENERATED LISTS                 54750020
         SPACE 3                                                        54800020
*                                                                     * 54850020
*        OPEN                                                           54900020
*                                                                     * 54950020
BCOPLST  OPEN  (,(OUTPUT)),MF=L   OPEN SYS1.BRODCAST                    55000020
         SPACE 3                                                        55050020
*                                                                     * 55100020
*        ENQUEUE SHARE                                                  55150020
*                                                                     * 55200020
BCEQLST  ENQ   (BCQNM,BCDSN,S,,SYSTEM),MF=L  ENQUEUE SHARING            55250020
         SPACE 3                                                        55300020
*                                                                     * 55350020
*        DEQUEUE                                                        55400020
*                                                                     * 55450020
BCDQLST  DEQ   (BCQNM,BCDSN,,SYSTEM),MF=L  DEQUEUE FROM DATA SET        55500020
         SPACE 3                                                        55550020
*                                                                     * 55600020
*        ENQUEUE EXCLUSIVE                                              55650020
*                                                                     * 55700020
BCEQLSTX ENQ   (BCQNM,,E,3,SYSTEM),MF=L                                 55750020
         SPACE 3                                                        55800020
*                                                                     * 55850020
*        DEQUEUE FROM EXCLUSIVE ENQUEUE                               * 55900020
*                                                                     * 55950020
BCDQLSTX DEQ   (BCQNM,,3,SYSTEM),RET=HAVE,MF=L                          56000020
         SPACE 3                                                        56050020
*                                                                     * 56100020
*        READ                                                           56150020
*                                                                     * 56200020
BCRDLST  READ  BCDECB,DIF,,,'S',0,,MF=L                                 56250020
         SPACE 3                                                        56300020
*                                                                     * 56350020
*        READ SPECIAL FIRST RECORD                                      56400020
*                                                                     * 56450020
BCRDLST1 READ  DECB1,DI,,,'S',0,BCFRREC,MF=L                            56500020
         SPACE 3                                                        56550020
*                                                                     * 56600020
*        WRITE                                                          56650020
*                                                                     * 56700020
BCWRLST  WRITE BCDEC1,DI,,,'S',0,,MF=L                                  56750020
         SPACE 3                                                        56800020
*                                                                     * 56850020
*        WRITE                                                          56900020
*                                                                     * 56950020
BCWRKLST WRITE BCDECBX,DI,,,'S',BCKEY,,MF=L                             57000020
         SPACE 3                                                        57050020
*                                                                     * 57100020
*        CLOSE                                                          57150020
*                                                                     * 57200020
BCCLLST  CLOSE 0,MF=L             CLOSE SYS1.BRODCAST                   57250020
         SPACE 3                                                        57300020
*                                                                     * 57350020
*        PUTLINE- ONE LEVEL                                             57400020
*                                                                     * 57450020
BCPUTL1  PUTLINE ,MF=L                                                  57500020
         SPACE 3                                                        57550020
*                                                                     * 57600020
*        PUTLINE- TWO LEVELS                                            57650020
*                                                                     * 57700020
BCPUTL2  PUTLINE OUTPUT=(0,MULTLVL),MF=L                                57750020
         SPACE 3                                                        57800020
*                                                                     * 57850020
*        PUTLINE- DATA                                                * 57900020
*                                                                     * 57950020
BCPUTLD  PUTLINE ,MF=L                                                  58000020
BCGETML1 GETMAIN   EC,MF=L                                              58050020
*                                                                     * 58100020
BCMOVEND DS    0H                 END OF LISTS TO MOVE                  58150020
*                                                                     * 58200020
BDEC     DS    D                  SPACE FOR PACKED DECIMAL RETURN CODE  58250020
*                                                                     * 58300020
BCUNPK   DS    D                  SPACE FOR ZONED DECIMAL RETURN CODE   58350020
*                                                                     * 58400020
BCADRLST DS    1F                 SPACE FOR THE ADDRESS OF ALLOCATED    58450020
*                                 AREA (GETMAIN)                        58500020
BCGETLST DS    1F                 SPACE FOR LENGTH OF AREA (GETMAIN)    58550020
MSGOFLST DS    1F                 SPACE FOR PTR TO ERROR MESSAGE        58600020
BCNXTLST DS    1F                 SPACE FOR PTR TO LAST MSG UNIT BUILT  58650020
BCPUTLST DS    1F                 SPACE FOR PTR TO PUTLINE              58700020
         DS    2F                 PUTLINE PARAMETERS                    58750020
         DS    11F                PARM BLOCKS FOR 2 LEVEL MESSAGES      58800020
BCENDL   DS    0H                 END OF GENERATED LISTS                58850020
BCLLEN   EQU   BCENDL-BCBEGL      LENGTH OF GENERATED AREA              58900020
BCLENMV  EQU   BCMOVEND-BCBEGL    LENGTH TO BE MOVED                    58950020
WKARLEN  EQU   DCBLENG+BCLLEN     LENGTH OF WORK AREA                   59000020
BCDSN    DC    C'SYSDSN'          DATA SET NAME FOR LIST FORM OF ENQ    59050020
*                                 AND DEQ WHICH IS OVERRIDDEN IN THE    59100020
*                                 EXECUTE FORM BY A 3 BYTE RBA          59150020
BCQNM    DC    C'SYSIKJBC'        ENQUEUE NAME                          59200020
BCFRREC  DC    X'000000'          RELATIVE BLOCK ADDRESS OF FIRST       59250020
*                                 RECORD IN DATA SET = ZERO             59300020
BCKEY   DC     X'FF'              KEY TO INDICATE RECORD IS AVAILABLE   59350020
TWO     DC     H'2'               ALGORITHM FOR INDEXING INTO MESSAGE   59400020
*                                 MODULE 'IKJEES74'                     59450020
PREFIX  DC     F'4'                                                     59500020
VMSG    DC     V(LSTBMSG)         VCON FOR MESSAGE MODULE 'IKJEES74'    59550020
TRTABLE DC     C'0123456789ABCDEF'  TRANSLATE TABLE FOR PRINTABLE HEX   59600020
*                                   CONVERSION                          59650020
ZERO    DC     X'F0F0F0F0'        ZERO OUT F IN HALF WORDS              59700020
*/*IKJEES75:  END END OF IKJEES75 */                                    59750020
         END                                                            59800020
