 TITLE ' INITIALIZATION MODULE IKJEFF60 OUTPUT CP '                     00080020
*STATUS. CHANGE LEVEL 0       12/15/69                                  00160020
*FUNCTION.                                                              00240020
*       1-VERIFY THAT USER HAS SUBMIT PRIVILEGE                         00320020
*       2-INVOKE IKJPARSE TO CHECK COMMAND SYNTAX & BUILD PARMS         00400020
*       3-INVOKE SECURITY EXIT (IKJEFF53) TO VERIFY JOBNAMES            00480020
*       4-ALLOCATE & OPEN PRINT DATASET OR SETUP FOR PUTLINE            00560020
*       5-LOAD SYSGENED DEFAULT CLASSES (IKJEFF65) IF NECESSARY         00640020
*       6-INVOKE IEFLOCDQ THRU SVC 100 TO FIND AND DEQ JOBS             00720020
*       7-INVOKE OUTPUT PROCESSOR (IKJEFF62) TO PROCESS JOBS            00800020
*ENTRY POINT. IKJEFF60                                                  00880020
*INPUT. ADDR OF CPPL IN REG.1                                           00960020
*EXITS.                                                                 01040020
*       1-IKJPARSE                                                      01120020
*       2-IKJEFF53                                                      01200020
*       3-IEFLOCDQ VIA SVC 100 & IKJEFF61                               01280020
*       4-IKJEFF62                                                      01360020
*       5-RETURN TO TMP                                                 01440020
*EXTERNAL REFERENCES. IKJEFF65                                          01520020
*TABLES/WORK AREAS.                                                     01600020
*       1-OUTCOMTB  GENERAL COMMUNICATIONS TABLE FOR ENTIRE CP          01680020
*                   GOTTEN & PARTIALLY INITIALIZED                      01760020
*       2-PPL       PARSE PARAMETER LIST USED TO CALL PARSE             01840020
*       3-PDL       PARAMETER DESCRIPTOR LIST                           01920020
*       4-SECEXPAR  SECURITY EXIT PARMS USED TO CALL SECURITY EX        02000020
*       5-OUTPUT DCB GOTTEN & INITIALIZED IF PRINT TO DATASET           02080020
*       6-TERMPARM  GOTTEN IF OUTPUT ON TERMINAL                        02160020
*       7-DAPB04    USED TO ENTER DAIR TO SEE PRINT DATASET IS OLD      02240020
*       8-DAPB08    USED TO ALLOCATE PRINT DATASET OCCUPIES SAME        02320020
*                   CORE AS DAPB04                                      02400020
*       9-DFPL/DFPB DEFAULT ROUTINE PARAMETERS                          02480020
*      10-OQMPARM   OUTPUT Q/MNGR PARMS USED AS PARMS TO IKJEFF61       02560020
*      11-IOPARAMS  QMPA GOTTEN NOT USED IN THIS MODULE                 02640020
*      12-LOCDQ PARMS USED AS PARMS TO IEFLOCDQ TO DEQ JOBS             02720020
IKJEFF60 CSECT                                                          02800020
*D409600                                                         A42944 02820021
*A409300-409800                                                  A42944 02840021
*C688800                                                        SA60977 02860021
R0       EQU   0                   REGISTER  0                          02880020
R1       EQU   1                   REGISTER  1                          02960020
*                                  DAPB04,CLASPDE,DAPB1C,DAPB18         03040020
R2       EQU   2                   REGISTER  2                          03120020
R3       EQU   3                   REGISTER  3                          03200020
*                                  OUTCOMTB                             03280020
R4       EQU   4                   REGISTER  4                          03360020
*                                  DCBOUT                               03440020
R5       EQU   5                   REGISTER  5                          03520020
R6       EQU   6                   REGISTER  6                          03600020
*                                  LDQJB,LDQINFO                        03680020
R7       EQU   7                   REGISTER  7                          03760020
*                                  SEC. EXIT PARMS,DSNPDE,              03840020
*                                  CLASPDE,OQMPARM                      03920020
R8       EQU   8                   REGISTER  8                          04000020
*                                  JOBPDE,DAPB1C,DAPB04,DAPB08,         04080020
*                                  JOBPDE,DAPB18                        04160020
R9       EQU   9                   REGISTER  9                          04240020
*                                  PDL                                  04320020
R10      EQU   10                  REGISTER  10                         04400020
*                                  PARSPARM-(PCL)                       04480020
R11      EQU   11                  REGISTER  11                         04560020
*                                  CPPL                                 04640020
R12      EQU   12                  REGISTER  12                         04720020
*                                  BASE                                 04800020
R13      EQU   13                  REGISTER  13                         04880020
R14      EQU   14                  REGISTER  14                         04960020
R15      EQU   15                  REGISTER  15                         05040020
         SAVE  (14,12),,*          SAVE TMP'S REGISTERS                 05120020
         LR    R12,R15             ESTABLISH ADDRESSABILITY             05200020
         USING IKJEFF60,R12        FOR IKJEFF60                         05280020
         LR    R11,R1              SAVE PARM REGISTER                   05360020
         USING CPPL,R11            ESTABLISH CPPL ADDRESSABILITY        05440020
         GETMAIN R,LV=SAVLTH,SP=SP1       GET SAVE AREA                 05520020
         USING SAVEAREA,R1         ADDRESSABILITY FOR NEW AREA          05600020
         ST    R13,SAVBACK         STORE BACK PTR IN NEW AREA           05680020
         USING SAVEAREA,R13        ADDRESSABILITY FOR OLD AREA          05760020
         ST    R1,SAVFORW          STORE FORWARD PTR IN OLD AREA        05840020
         LR    R13,R1              ESTABLISH NEW SAVE AREA              05920020
* IS USER AUTHORIZED TO USE OUTPUT                                      06000020
         L     R5,CPPLPSCB         GET ADDR OF PSCB                     06080020
         USING PSCB,R5             ESTABLISH PSCB ADDRESSABILITY        06160020
         GETMAIN R,LV=OUTCOMLN,SP=SP1     GET CORE FOR COMMUNCATIONS    06240020
*                                  TABLE                                06320020
         LR    R3,R1               ESTABLISH COMMUNICATIONS             06400020
         USING OUTCOMTB,R3         TABLE ADDRESSABILITY                 06480020
         XC    OUTCOMTB(OUTCOML),OUTCOMTB ZERO COMTAB                   06560020
         ST    R11,OUTCPPL          SAVE ADDR OF CPPL                   06640020
         TM    PSCBATR1,PSCBJCL    DOES USER HAVE SUBMIT                06720020
*                                  PRIVILEGE.                           06800020
         BNZ   STAE                YES, CONTINUE PROCESSING             06880020
         MVI   OUTMSGID,M1         NO, ISSUE MSG IKJEF109               06960020
         LA    R2,RETURN           WHERE TO GO AFTER MSG                07040020
         B     MSGOUTER            GO LINK TO IKJEFF67                  07120020
         EJECT                                                          07200020
* ISSUE STAE MACRO                                                      07280020
STAELIST STAE  MF=L                LIST                                 07360020
STAESIZE EQU   *-STAELIST          LENGTH                               07440020
         SPACE 2                                                        07520020
STAE     LA    R7,STAEEXIT         ADDR OF STAE EXIT ROUTINE            07600020
         MVC   OUTINBUF(STAESIZE),STAELIST MOVE LIST IN OUTCOMTB        07680020
         MVC   OUTSAV13,SAVBACK    SAVE ADDR OF TMP SAVE AREA           07700020
*                                  FOR RETRY ROUTINE                    07720020
         SPACE                                                          07760020
         STAE  (R7),PARAM=(R3),MF=(E,OUTINBUF)                          07840020
         SPACE                                                          07920020
         LTR   R15,R15             TEST FOR ZERO RETURN CODE            08000020
         BZ    SKIPIT              BRANCH IF ZERO                       08080020
*                                  ISSUE ERROR MESSAGE & QUIT           08160020
         STH   R15,OUTRTCD         STORE RETURN CODE FOR MESSAGE        08240020
MSG104   EQU   44                  ID OF MESSAGE IKJEF104I              08320020
         MVI   OUTMSGID,MSG104     MOVE ID INTO PARAMETER FIELD         08400020
         LA    R2,RETURN           WHERE TO GO AFTER MSG                08480020
         B     MSGOUTER            GO LINK TO IKJEFF67                  08560020
SKIPIT   EQU   *                                                        08640020
         EJECT                                                          08720020
* PARSE OUTPUT COMMAND BUFFER                                           08800020
POUTPUT  EQU   *                                                        08880020
         GETMAIN R,LV=PARSPARL,SP=SP1     GET CORE FOR PARSE PARAM      08960020
         LR    R10,R1              ESTABLISH ADDRESSABILITY FOR         09040020
         ST    R10,OUTPARS         SAVE ADDR OF GOTTEN CORE             09120020
         USING PPL,R10             PARSE PARAMETER LIST                 09200020
         MVC   PPLUPT,CPPLUPT      PASS ADDR OF UPT TO PARSE            09280020
         MVC   PPLECT,CPPLECT      PASS ADDR OF ECT TO PARSE            09360020
         LA    R0,OUTATECB         GET ADDR OF ATTENTION ECB            09440020
         ST    R0,PPLECB           PASS ECB ADDR TO PARSE               09520020
         MVC   PPLPCL,VPARSOUT     PASS ADDR OF PCL TO PARSE            09600020
         LA    R9,OUTPDL           GET ADDR OF PDL PTR                  09680020
         ST    R9,PPLANS           PASS ADDR OF ANSWER PLACE            09760020
         MVC   PPLCBUF,CPPLCBUF    PASS ADDR OF COMMAND BUFFER          09840020
         LINK  EP=IKJPARS          GO TO PARSE                          09920020
*                                  ***********                          10000020
         L     R9,OUTPDL           GET ADDR OF PDL                      10080020
         USING IKJPARMD,R9         ESTABLISH PDL ADDRESSABILITY         10160020
         LTR   R15,R15             WAS PARSE SUCCESSFUL                 10240020
         BZ    SECEXIT             YES, GO TO SECURITY EXIT             10320020
         MVI   OUTRESUM,ANY        CAUSE STACK & INPUT Q TO RESET       10330020
         CH    R15,FOUR            IN NOPROMPT MODE                     10340020
         BE    FREEPDL             BRANCH IF SO                         10360020
         MVI   OUTMSGID,M2         NO, ISSUE MSG IKJEF104               10400020
         LA    R2,FREEPDL          WHERE TO GO AFTER MSG                10480020
         STH   R15,OUTRTCD         PASS RETURN CODE TO MSG RTN          10560020
         B     MSGOUTER            GO LINK TO IKJEFF67                  10640020
* VALIDITY CHECK EXIT FOR CLASS-LIST AND NOPRINT-CLASS                  10641020
* ENTERED BY PARSE FOR EACH CLASSNAME                                   10642020
CKCLASS  EQU   *                                                        10644020
         SAVE  (14,12)             SAVE PARSE REGS.                     10648020
         USING CKCLASS,R15         ESTABLISH BASE                       10652020
         USING CLASPDE,R1          GET PDE ADDRESSABILITY               10656020
         L     R1,0(R1)            GET ADDR OF CLASS PDE                10660020
         L     R1,CLASNMAD         GET ADDR OF CLASS TO CHECK           10664020
         DROP  R1                                                       10668020
         CLI   0(R1),C'A'          IS CLASS OTHER THAN A-Z, 0-9         10670020
         BL    BADCLASS            YES, PROMPT FOR CLASSNAME            10672020
         RETURN (14,12),,RC=0      INDICATE VALID CLASSNAME             10696020
BADCLASS EQU   *                                                        10700020
         RETURN (14,12),,RC=4      INDICATE INVALID CLASSNAME           10704020
         DROP  R15                                                      10708020
         EJECT                                                          10720020
* CALL SECURITY EXIT                                                    10800020
*       THIS ROUTINE REMOVES THE PDE OF EACH JOBNAME                    10880020
*       REJECTED BY THE SECURITY EXIT FROM THE PDE                      10960020
*       CHAIN. IT ALSO COUNTS THE NUMBER OF VALID                       11040020
*       JOBNAMES AT OUTJBCNT.                                           11120020
SECEXIT  EQU   *                                                        11200020
         GETMAIN R,LV=SECEXLTH,SP=SP1     GET CORE FOR SECURITY EXIT    11280020
*                                  PARM LIST                            11360020
         LA    R8,JOBNAME          GET ADDR OF FIRST JOBNAME PDE        11440020
         USING JOBPDE,R8           ESTABLISH PDE ADDRESSABILITY         11520020
         ST    R1,OUTSECMS         MAKE AVAILABLE TO IKJEFF67           11600020
         LR    R7,R1               ESTABLISH ADDRESSABILITY FOR         11680020
         USING SECEXPAR,R7         SECURITY EXIT PARMS                  11760020
         XC    SECEXPAR(SECEXLTH),SECEXPAR ZERO GOTTEN CORE             11840020
         LA    R0,PSCBUSER         GET ADDR OF USER ID                  11920020
         ST    R0,SECUSID          PUT IN PARM LIST                     12000020
         LA    R0,PSCBUSRL         GET ADDR OF USER ID LENGTH           12080020
         ST    R0,SECUSIDL         PUT IN PARM LIST                     12160020
         MVI   SECCODE,SECEXOUT   INDICATE OUTPUT COMMAND               12240020
         LA    R0,SECCODE           GET ADDR OF OUTPUT CODE             12320020
         ST    R0,SECCOMCD          PUT IN PARM LIST                    12400020
         L     R1,CVTPTR(0,0)      ADDR OF CVT                          12410020
         USING CVTBLK,R1           ADDRESSABILITY FOR CVT               12420020
         L     R1,CVTLINK          ADDR OF SYS1.LINKLIB                 12430020
         DROP  R1                                                       12440020
         SPACE                                                          12450020
         LOAD  EP=IKJEFF53,DCB=(1)    LOAD SECURITY EXIT FROM           12460020
*                                     SYS1.LINKLIB                      12470020
         SPACE                                                          12480020
         LR    R6,R0               SAVE ADDR OF SECURITY EXIT           12560020
MOVJBNAM MVC   SECJBNAM,JBNAMEAD   MOVE JOBNAME POINTER TO              12640020
*                                   SECURITY EXIT PARM LIST             12720020
         LA    R0,JBNMLTH          GET ADDR OF JOBNAME LENGTH           12800020
         ST    R0,SECJBLTH         PUT IN PARM LIST                     12880020
CALLEXIT LR    R15,R6              GET ADDR OF EXIT                     12960020
         LR    R1,R7               PASS SECURITY EXIT PARMS             13040020
         BALR  R14,R15             GO TO SECURITY EXIT                  13120020
*                                  ****************                     13200020
         LTR   R15,R15             IS RETURN CODE ZERO                  13280020
         BZ    UPJBPTR             YES, UPDATE JOB POINTER              13360020
         CH    R15,EIGHT           WAS RETURN CODE 4, 8 OR 12           13440020
         BH    BADENTRY            RETURN CODE WAS 12, BRANCH           13520020
         STC   R15,OUTMSGID        PASS RETURN CODE                     13600020
         BAL   R2,MSGOUT           GO LINK TO MSG RTN                   13680020
         LTR   R15,R15             WAS PUTGET SUCCESSFUL                13760020
         BZ    CALLEXIT            YES, GO TO EXIT AGAIN                13840020
         L     R8,JOBNAME          FIX SO FIRST JOB PDE IS              13920020
*                                  ZEROED.                              14000020
         B     ZEROPDE             GO ZERO FIRST PDE                    14080020
BADENTRY EQU   *                                                        14160020
         CH    R15,SIXTN           IS SECUTITY CODE 16                  14166020
         BL    RCEQ12              NO, BRANCH (RC12)                    14172020
         BNH   QUITCMD             YES, BRANCH                          14178020
         MVI   OUTMSGID,M142       RC GTR THAN 16 - ISSUE MSG           14184020
         LA    R2,FREEPDL          WHERE TO GO AFTER MSG                14190020
         B     MSGOUTER            GO LINK TO IKJEFF67                  14196020
QUITCMD  MVI   OUTRESUM,QUIT       INDICATE SERIOUS ERROR               14202020
         B     FREEPDL             FREE CORE AND RETURN TO TMP          14208020
RCEQ12   EQU   *                                                        14214020
JBREJECT EQU   X'F0'                                                    14220020
         MVI   OUTRESUM,JBREJECT   INDICATE AT LEAST ONE JOB REJECTED   14226020
         L     R5,JBNMNEXT         GET ADDR OF NEXT JOBNAME PDE         14240020
         C     R5,LAST             IS FORWARD PTR ZERO                  14320020
         BE    ZEROPDE             YES, SKIP SAVE OF NEXT PDE           14400020
         MVC   JOBPDE(JOBPDELN),0(R5) OVERLAY BAD JOBNAME PDE           14480020
         XC    SECMESS,SECMESS     ZERO ADDR OF MESSAGE                 14560020
         B     MOVJBNAM            GO TO SECURITY EXIT                  14640020
ZEROPDE  EQU   *                   LAST WORD (END OF CHAIN FLAG)        14720020
         XC    JOBPDE(JOBBEGLN),JOBPDE IF BAD PDE IS LAST PDE           14800020
*                                  ZERO ALL OF LAST PDE EXCEPT          14880020
*                                  FORWARD POINTER                      14960020
         B     ANYJBS              SEE IF ALL JOBNAMES PURGED           15040020
UPJBPTR  EQU   *                                                        15120020
         L     R1,OUTJBCNT         GET NO. OF VALID JOBNAMES            15200020
         AH    R1,ONE              ADD ONE TO NO. OF JOBNAMES           15280020
         ST    R1,OUTJBCNT         SAVE NO. OF VALID JOBNAMES           15360020
         L     R8,JBNMNEXT         GET ADDR OF NEXT JOBNAME PDE         15440020
         C     R8,LAST             IS FORWARD PTR ZERO                  15520020
         BNE   MOVJBNAM            NO, GO TO UPDATE EXIT PARMS          15600020
ANYJBS   EQU   *                                                        15680020
*       AT THIS POINT ONLY THE PDE OF EACH VALID                        15760020
*       JOBNAME REMAINS ON THE PDE CHAIN.                               15840020
         DELETE EP=IKJEFF53                                             15920020
         LR    R1,R7               GET ADDR OF CORE TO FREE             16000020
         FREEMAIN R,LV=SECEXLTH,A=(1),SP=SP1 FREE SECURITY  PARMS       16080020
         LA    R8,JOBNAME          GET ADDR OF FIRST JOBNAME PDE        16160020
         TM    JBNMFLGS,JBNM       IS FIRST ELEMENT EMPTY               16240020
         BNO   FREEPDL              YES, NO WORK TO DO, RETURN          16320020
* IS PRINT SW ON                                                        16400020
         CLC   PRINT,ONE           WAS PRINT SPECIFIED                  16480020
         BNE   CKCLSLST            NO, SKIP ALLOCATE OF OUTPUT          16560020
         LA    R7,DSNAME           GET ADDR OF DSNAME PDE               16640020
         USING DSNPDE,R7           DSNAMEPDE ADDRESSABILITY             16720020
         L     R6,DSNAMEAD         GET ADDR OF DATA SET NAME            16800020
         CLI   0(R6),C'*'          IS OUTPUT TO GO TO TERMINAL          16880020
         BNE   DSALLOC             NO,GO TO DATA SET ALLOC              16960020
         GETMAIN R,LV=TERMLNTH,SP=SP1                                   17040020
         ST    R1,OUTTERM          SAVE ADDR OF GOTTEN CORE             17120020
         B     CKCLSLST            SKIP DS ALLOCATION                   17200020
DSALLOC  GETMAIN  R,LV=DCBLTH,SP=SP1      GET CORE FOR DCB & LIST PART  17280020
*                                  OF OPEN                              17360020
         LR    R4,R1               ESTABLISH ADDRESSABILITY             17440020
         USING IHADCB,R4           FOR DCB                              17520020
         ST    R4,OUTDCB           SAVE ADDR OF OUTPUT DCB              17600020
         MVC   IHADCB(DCBLTH),DCBOUT INITIALIZE DCB & OPEN LIST         17680020
         EJECT                                                          17760020
* ALLOCATE OUTPUT                                                       17840020
         GETMAIN R,LV=DA08LTH,SP=SP1 GET CORE FOR DAIR PARM LIST        17920020
*        THE CORE OBTAINED BY THIS GETMAIN IS USED FOR TWO              18000020
*        ENTRIES TO DAIR. DAIR CODE X'04' TO SEE IF DATASET IS          18080020
*        OLD OR NEW. DAIR CODE X'08' TO ALLOCATE DATASET.               18160020
         LR    R8,R1               SAVE ADDR OF PARM LIST               18240020
         USING DAPL,R8             ESTABLISH PARM ADDRESSABILITY        18320020
         ST    R8,OUTDAIR          SAVE ADDR OF DAIR PARMS              18400020
         XC    DAPL(DA08LTH),DAPL  ZERO DAIR CORE                       18480020
         MVC   DAPL(DAPLBGLN),PPL  GET STANDARD PART OF                 18560020
*                                  SERVICE ROUTINE PARAMETR LIST        18640020
         MVC   DAPLPSCB,CPPLPSCB   GET PSCB ADDR FOR STANDARD           18720020
*                                  PART OF DAIR PARM LIST               18800020
         LA    R0,DA04STAR         GET ADDR OF DAIR PARM BLOCK          18880020
         ST    R0,DAPLDAPB         STORE IN DAIR PARM LIST              18960020
         USING DAPB04,R8           GET  DAIR 04 ADDRESSABILITY          19040020
         MVC   DA04CD,DA04         MOVE FUNCTION CODE INTO PARMS        19120020
         USING DAPB08,R1           GET DAPB08 ADDRESSABILITY            19200020
         MVC   DA08DSNM,0(R6)      MOVE DSNAME FROM COMMAND             19280020
*                                  INPUT BUFFER                         19360020
         MVC   DA08DSNL,DSNLTH1    GET LENGTH OF DSNAME                 19440020
         MVI   DA08QUO,QUO         INDICATE DSNAME QUOTED               19480020
         LA    R0,DA08DSNL         GET ADDR OF DSNAME & LENGTH          19520020
         ST    R0,DA04PDSN         PASS IT TO DAIR                      19600020
         TM    DSNFLG1,DSNQUO      IS DSNAME IN QUOTES                  19680020
         BO    LINKDAIR            YES, SKIP GOING TO DEFAULT           19760020
         DROP  R1                                                       19780020
* EXPAND SIMPLE NAME TO FULLY QUALIFIED DSNAME FOR PRINT DATASET        19800020
         GETMAIN R,LV=DFPBLTH,SP=SP1 GET CORE FOR DEFAULT PARMS         19860020
         LR    R10,R1              SAVE ADDR OF CORE                    19920020
         USING DAPB08,R8                                                19960020
         MVI   DA08QUO,NOTQUO      INDICATE DSNAME NOT QUOTED           20020020
         USING DFPL,R10            PARAMETER LIST ADDRESSABILITY        20080020
         MVC   DFPL(DAPLBGLN),DAPB08 GET STANDARD PART OF               20160020
*                                  SERVICE ROUTINE PARAMETER            20240020
         LA    R0,DFPB1            GET ADDR OF PARAMETER BLOCK          20320020
         ST    R0,DFPLDFPB         PASS TO CEFAULT ROUTINE              20400020
         USING DFPB,R10            PARAMETER BLOCK ADDRESSABILITY       20480020
         MVI   DFPBCODE,DFPB00     NO PROMT CODE                        20560020
         LA    R0,DA08DSNL         GET ADDR OF DSNAME & LENGTH          20640020
         ST    R0,DFPBDSN          PASS TO DEFAULT                      20720020
         MVC   DFPBPSCB,CPPLPSCB   PASS ADDR OF PSCB                    20800020
         MVI   DFPBCNTL,DFPBUID    PREFIX USERID REQUEST                20880020
         LA    R0,CLIST            GET ADDR OF QUALIFIER                20960020
         ST    R0,DFPBQUAL         PASS TO DEFAULT                      21040020
         LINK  EP=IKJEHDEF         GO TO DEFAULT                        21120020
*                                  *************                        21200020
         LR    R1,R10              GET ADDR OF CORE TO FREE             21280020
         LR    R10,R15             SAVE RETURN CODE                     21360020
         FREEMAIN R,LV=DFPBLTH,A=(1),SP=SP1 FREE DEFAULT CORE           21440020
         CH    R10,EIGHT           WAS DSNAME MORE THAN 44 CHARS        21520020
         BNE   LINKDAIR            NO, GO LINK TO DAIR                  21600020
         MVI   OUTMSGID,M19        ISSUE MSG DSNAME TOO LONG            21680020
         LA    R2,FREEDCB          WHERE TO GO AFTER MSG                21760020
         B     MSGOUTER                                                 21840020
LINKDAIR EQU   *                                                        21920020
         LR    R1,R8               PASS ADDR OF DAPB04 TO DAIR          22000020
         LINK  EP=IKJDAIR          GO TO DAIR                           22080020
*                                  **********                           22160020
         LTR   R15,R15             DOES DATA SET EXIST                  22240020
*       IF DAIR 8 AND LOCATE 8 DO NOT ISSUE MSG IKJEF110                22320020
         BZ    SETOLD              YES, SET STATUS TO OLD               22400020
         CH    R15,EIGHT           WAS PARAMETER ERROR                  22480020
         BNE   DAIR04ER            YES, GO ISSUE ERROR MSG              22560020
         USING DAPB04,R8                                                22600020
         CLC   NOTINCAT,DA04CTRC   ANY OTHER ERRORS                     22640020
         BE    SETNEW              NO, DATASET NOT IN CATALOG           22720020
DAIR04ER EQU   *                                                        22800020
         MVI   OUTMSGID,M4         ISSUE MSG IKJEF110 DAIR ERROR        22880020
         LA    R2,FREEDCB          WHERE TO GO AFTER ERROR MSG          22960020
         B     MSGOUTER            GO LINK TO IKJEFF67                  23040020
SETNEW   EQU   *                                                        23120020
         USING DAPB08,R8                                                23200020
         MVI   DA08DSP1,DA08NEW    SET STATUS TO NEW                    23280020
         OI    DA08CTL,DA08ABKL+DA08RLSE REQUEST SPACE IN BLOCKS        23360020
*                                  AND RELEASE ANY NOT USED             23440020
         MVC   DA08PQTY,PRIMSPCE   PRIMARY SPACE REQUEST                23520020
         MVC   DA08SQTY,SECSPCE    SECONDARY SPACE REQUEST              23600020
         MVC   DA08BLK,BLOCKSZ     SET BLKSIZE FOR SPACE REQ.           23680020
         MVI   DA08DPS2,DA08CAT    SET DISP TO CATALOG                  23760020
         B     BLDDA08             SKIP SETTING STATUS TO OLD           23840020
SETOLD   EQU   *                                                        23920020
         MVI   DA08DSP1,DA08OLD    SET STATUS TO OLD                    24000020
BLDDA08  EQU   *                                                        24080020
         MVC   DA08CD,DA08         SET FUNCTION CODE TO ALLOCATE        24160020
         XC    DA08FLG(DA08FRLN),DA08FLG ZERO FLAG & RETURN CODE        24240020
         LR    R1,R8                 GET ADDR OF DAIR PARMS             24320020
         MVC   DA08DDN,BLANKS      BLANK DDNAME                         24400020
         MVC   DA08UNIT,BLANKS     BLANK UNIT NAME                      24480020
         MVC   DA08SER,BLANKS      BLANK SERIAL NO.                     24560020
         MVC   DA08MNM,BLANKS      BLANK MEMBER NAME                    24640020
         TM    DSNFLG2,DSM         DID USER SPECIFY MEMBER NAME         24720020
         BZ    PASSWD              NO, SKIP PASSING MEMBER NAME         24800020
         LH    R6,DSNLTH2          GET LTH OF MEMBER NAME FR PDE        24880020
         BCTR  R6,0                DECREMENT FOR EXECUTE OF MOVE        24960020
         L     R5,DSNMEMAD         GET ADDR OF MEMBER NAME              25040020
MOVEMEM  MVC   DA08MNM(0),0(R5)    MOVE MEMBER NAME UNDER EXECUT        25120020
         EX    R6,MOVEMEM          EXECUTE MOVE OF MEMBER NAME          25200020
         CLI   DA08DSP1,DA08NEW    IS DATASET NEW                       25220020
         BNE   PASSWD              NO, SKIP DIRECTORY ALLOCATION        25240020
         MVC   DA08DQTY,DIRSPCE    ALLOCATE ONE DIRECTORY BLOCK         25260020
PASSWD   EQU   *                                                        25280020
         MVC   DA08PSWD,BLANKS     BLANK PASSWORD                       25360020
         TM    DSNFLG3,DSP         DID USER SPECIFY PASSWORD            25440020
         BZ    GOTODAIR            NO, SKIP PASSING PASSWORD            25520020
         LH    R6,DSNLTH3          GET LENGTH OF PASSWORD               25600020
         BCTR  R6,0                DECREMENT FOR EXECUTE OF MOVE        25680020
         L     R5,DSNPASAD         GET ADDR OF PASSWORD                 25760020
MOVEPAS  MVC   DA08PSWD(0),0(R5)   MOVE PASSWORD INTO PARM LIST         25840020
         EX    R6,MOVEPAS          EXECUTE MOVE OF PASSWORD             25920020
GOTODAIR EQU   *                                                        26000020
         LINK  EP=IKJDAIR          GO TO DAIR                           26080020
*                                  **********                           26160020
         LTR   R15,R15             HAS DATA SET BEEN ALLOCATED          26240020
         BZ    CHKNEW              YES, SKIP ERROR MSG                  26320020
         MVI   OUTMSGID,M4         ISSUE MSG IKJEF110 DAIR ERROR        26400020
         LA    R2,FREEDCB          WHERE TO GO AFTER MSG                26480020
         B     MSGOUTER            GO LINK TO IKJEFF67                  26560020
CHKNEW   EQU   *                                                        26570020
         CLI   DA08DSP1,DA08NEW    IS DATA SET NEW                      26580020
         BNE   CKDSORG             NO, CHECK DSORG                      26590020
         MVI   DA08DPS2,DA08DEL    SET DELETE BIT IN CASE DATA          26600020
*                                  SET IS NOT USED                      26610020
CKDSORG  EQU   *                                                        26640020
         TM    DSNFLG2,DSM         WAS MEMBER NAME SPECIFIED            26720020
         BZ    CKPS                NO, MAKE SURE DSORG IS PS            26800020
         TM    DA08DSO,PO          IS DSORG PO                          26880020
         BO    SAVDDNAM            YES, OK SINCE MEMBER GIVEN           26960020
         CLI   DA08DSO,ZIP         IS DSORG UNSPECIFIED                 26980020
         BE    SAVDDNAM            YES, MAKE IT PO                      27000020
         MVI   OUTMSGID,M16        NO, ISSUE MSG NOT PARTITIONED        27040020
         LA    R2,FREEDCB          WHERE TO GO AFTER MSG                27120020
         B     MSGOUTER            GO LINK TO IKJEFF67                  27200020
CKPS     EQU   *                                                        27280020
         TM    DA08DSO,PS          IS DSORG PS                          27360020
         BO    SAVDDNAM            YES, OK SINCE NO MEMBER NAME         27440020
         CLI   DA08DSO,ZIP         IS DSORG UNSPECIFIED                 27460020
         BE    SAVDDNAM            YES, MAKE IT PS                      27480020
         TM    DA08DSO,PO          IS DSORG PARTITIONED                 27520020
         BO    ALOCTEMP            YES, REALLOCATE W/ TEMPNAME          27600020
         MVI   OUTMSGID,M17        INDICATE ISAM DSORG MSG              27680020
         TM    DA08DSO,IS          IS DSORG ISAM                        27760020
         BO    DSORGMSG            GO ISSUE DSORG MESSAGE               27840020
         MVI   OUTMSGID,M20        INDICATE DA DSORG MSG                27920020
DSORGMSG EQU   *                                                        28000020
         LA    R2,FREEDCB          WHERE TO GO AFTER MSG                28080020
         B     MSGOUTER            GO TO LINK TO IKJEFF67               28160020
PS       EQU   X'40'               DSORG PS                             28240020
PO       EQU   X'02'               DSORG PO                             28320020
IS       EQU   X'80'               DSORG IS                             28400020
ZIP      EQU   0                   DSORG OF ZERO                        28440020
ALOCTEMP EQU   *                                                        28480020
         USING DAPB18,R8           GET DAPB18 ADDRESSABILITY            28560020
         MVI   DA18DPS2,DA18KEEP   TELL UNALLOCATE TO KEEP              28640020
         MVC   DA18CD,DA18         INDICATE UNALLOCATE ENTRY CODE       28720020
         LR    R1,R8               PASS ADDR OF DAIR BLOCK              28800020
         LINK  EP=IKJDAIR          GO TO DAIR                           28880020
         LTR   R15,R15             NORMAL RETURN                        28960020
         BZ    FIXTEMP             YES, GO DUMMY UP MEMBER NAME         29040020
         B     DAIR04ER            NO, ISSUE ERROR MESSAGE              29120020
FIXTEMP  EQU   *                                                        29200020
         MVC   DSNMEMAD(MEMPDELN),MEMPDE PUT DEFAULT MEMBER NAME        29280020
*                                  ENTRY IN DSNAME PDE                  29360020
         B     SETOLD              GO ALLOCATE AGAIN W/ MEMBER          29440020
SAVDDNAM EQU   *                                                        29520020
         USING DAPB08,R8                                                29560020
         MVC   DCBDDNAM,DA08DDN    PUT DDNAME IN OUTPUT DCB             29600020
* OPEN OUTPUT                                                           29680020
OPENOUT  EQU   *                                                        29760020
         MVC   DCBEXLST,OPENEXAD   PUT ADDR OF OPEN EXIT IN DCB         29840020
*                                                                       29920020
         OPEN  (IHADCB,OUTPUT),MF=(E,OPENLIST)                          30000020
         EJECT                                                          30080020
* IS CLASSNAME LIST PTR ZERO                                            30160020
* SUPPLY DEFAULT CLASS-LIST                                             30200020
CKCLSLST LA    R7,CLASSLST         GET ADDR OF CLASS LIST PDE           30240020
         USING CLASPDE,R7          ESTABLISH PDE ADDRESSABILITY         30320020
         TM    CLASFLGS,CLAS       WAS CLASS NAME SPECIFIED             30400020
         BO    SETJBPTR            YES, SKIP LOAD OF DEFAULT CLA        30480020
         LOAD  EP=IKJEFF65         LOAD SYSGENED DEFAULT CLASSES        30560020
         LR    R1,R0               SAVE LOCATION OF IKJEFF65            30640020
         USING IKJEFF65,R1                                              30720020
         MVC   CLASSLST(CLASPDEL),CLASSPDL MOVE FIRST ELEMENT OF        30800020
*                                  SYSGENED PDL TO NORMAL PDL           30880020
SETJBPTR EQU   *                                                        30960020
         LH    R1,ONE              INITIALIZE JOB BEING                 31040020
         ST    R1,OUTJBPTR         PROCESSED POINTER                    31120020
         LA    R1,CLASSLST         GET ADDR OF FIRST PDE IN             31200020
         ST    R1,OUTCLPTR         CLASSNAME LIST                       31280020
* ESTABLISH ATTENTION ENVIORNMENT                                       31320020
*                             GET ADDR OF ECT TO OBTAIN NAME OF COMMAND 31326020
         L     R7,OUTPARS          ADDR OF PARSE PARAMETERS             31332020
         USING PPL,R7              ADDRESSABILITY                       31338020
         L     R7,PPLECT           ADDR OF ECT                          31344020
         USING ECT,R7               ADDRESSABILITY                      31350020
         LA    R2,ATTNEXIT         GET ADDR OF ATTENTION EXIT           31360020
         LA    R1,STAXLIST         GET ADDR OF LIST PART OF STAX        31440020
         STAX  (R2),OBUF=(ECTPCMD,PAUSEMSL),                           X31520020
               IBUF=(OUTINBUF,MAXIBLTH),                               X31600020
               USADDR=OUTCOMTB,MF=(E,(1))                               31680020
         EJECT                                                          31760020
*BUILD IEFLOCDQ PARAMETER LIST                                          31840020
         L     R6,OUTJBCNT         GET NO. OF VALID JOBNAMES            31920020
         LA    R7,LDQVARLN         GET LENGTH OF VARIABLE               32000020
*                                  PART OF LOCDQ PARAMETERS             32080020
         MR    R6,R6               GET LENGTH OF VARIABLE               32160020
*                                  PART OF PARMS FOR THE                32240020
*                                  CURRENT NO. OF VALID                 32320020
*                                  JOBNAMES.                            32400020
         LA    R0,LDQFIXLN         GET LENGTH OF FIXED PART OF          32480020
*                                  LOCDQ PARAMETERS.                    32560020
         AR    R0,R7               ADD LENGTHS OF FIXED &               32640020
*                                  VARIABLE PARTS OF PARMS              32720020
         O     R0,SUBPOOL1         GET SUPOOL NO. IN BYTE 0             32800020
         LR    R6,R0               SAVE LENGTH OF LOCDQ PARMS           32880020
         GETMAIN R,LV=(0)          GET CORE FOR LOCDQ PARMS             32960020
         LR    R7,R1               SAVE ADDR OF LOCDQ PARMS             33040020
         USING OQMPARM,R7          ESTABLISH PARM ADDRESSABILITY        33120020
         ST    R6,OQMSIZE          SAVE LENGTH IN GOTTEN CORE           33200020
         LA    R6,LDQJB            GET ADDR OF JOBNAME LIST             33280020
         XC    OQM1STSM,OQM1STSM   ZERO PTR TO FIRST SMB OF JOB         33360020
         USING LDQJB,R6            BASE FOR JOBNAME IN PARM LIST        33440020
         ST    R6,LDQJBPTR         PUT IN LOCDQ PARM LIST               33520020
         LA    R8,JOBNAME          GET ADDR OF FIRST JOBNAME PDE        33600020
         USING JOBPDE,R8           ESTABLISH PDE ADDRESSABILITY         33680020
BLDJBLST EQU   *                                                        33760020
         L     R5,JBNAMEAD         GET ADDR OF JOB NAME                 33840020
         LH    R1,JBNMLTH          GET LENGTH OF JOBNAME                33920020
         BCTR  R1,0                DECREMENT FOR EXECUTE OF MOVE        34000020
         MVC   LDQJB,BLANKS        BLANK JOB NAME IN PARM LIST          34080020
MOVEJOB  MVC   LDQJB(0),0(R5)      MOVE VARIABLE SZ JOBNAME FROM        34160020
         EX    R1,MOVEJOB          PDE TO FIXED SZ LOCDQ PARM.          34240020
         L     R8,JBNMNEXT         GET ADDR OF NEXT JOBNAME PDE         34320020
         AH    R6,EIGHT            ADD EIGHT TO BASE FOR JOBNAME        34400020
*                                  IN LOCDQ PARM LIST                   34480020
         C     R8,LAST             IS FORWARD PTR ZERO                  34560020
         BE    LASTJOB             YES, BRANCH NO MORE JOB PDE'S        34580020
         TM    JBNMFLGS,JBNM       DOES NEW PDE HAVE A JOBNAME          34600020
         BO    BLDJBLST            YES, ADD NEXT JOBNAME TO LIST        34620020
*                                  NO, LAST PDE IS EMPTY-ZEROPDE        34640020
LASTJOB  EQU   *                                                        34660020
         USING LDQINFO,R6          BASE FOR LOCDQ INFO AREA             34720020
         LA    R1,OUTJBCNT         GET ADDR OF NO. OF JOBNAMES          34800020
         ST    R1,LDQNPTR          STORE IN LOCDQ PARM LIST             34880020
         LA    R1,LDQNN            GET ADDR OF NN FOR Q                 34960020
         ST    R1,LDQNNPTR         STORE IN LOCDQ PARM LIST             35040020
         ST    R6,LDQINFOP         STORE PTR TO INFO AREA               35120020
         LA    R1,LDQNFND          GET ADDR OF NO. JOBS FOUND           35200020
         ST    R1,LDQNFNDP         STORE IN LOCDQ PARM LIST             35280020
         EJECT                                                          35360020
GOLOCDQ  EQU   *                                                        35440020
* CONVERT CLASSNAME TO NN                                               35520020
*CLASSNAME A-I TO NN  3-11                                              35600020
*          J-R       12-20                                              35680020
*          S-Z       21-28                                              35760020
*          0-9       29-38                                              35840020
*                                                                       35920020
         L     R1,OUTCLPTR         GET ADDR OF CURRENT CLASS PDE        36000020
         USING CLASPDE,R1          ESTAB. CLASSNAME PDE ADDRABLT        36080020
         L     R1,CLASNMAD         GET CLASSNAME ADDR FROM PDE          36160020
         LA    R0,TWONINE          29 MUST BE ADDED TO BOTTOM           36240020
*                                  FOUR BITS IF CLASS 0-9               36320020
TWONINE  EQU   29                  TWENTY NINE                          36400020
         TM    0(R1),ZEROTO9       IS CLASS 0-9 OR A-I                  36480020
ZEROTO9  EQU   X'30'               THESE TWO BITS WILL BE ON FOR        36560020
*                                  0-9 AND OFF FOR A-I                  36640020
         BO    MAKENN              BRANCH IF 0-9                        36720020
         LA    R0,TWO              2 MUST BE ADDED TO BOTTOM            36800020
*                                  FOUR BITS IF CLASS A-I               36880020
TWO      EQU   2                   TWO                                  36960020
         BZ    MAKENN              BRANCH IF A-I                        37040020
         LA    R0,ELEVEN           ELEVEN MUST BE ADDED TO              37120020
*                                  BOTTOM FOUR BITS IF CLASS J-R        37200020
ELEVEN   EQU   11                  ELEVEN                               37280020
         TM    0(R1),JTOR          IS CLASS J-R OR S-Z                  37360020
JTOR     EQU   X'10'               THIS BIT WILL BE ON FOR J-R          37440020
*                                  AND OFF FOR S-Z                      37520020
         BO    MAKENN              BRANCH IF J-R                        37600020
         LA    R0,NINETEEN         IF S-Z 19 MUST BE ADDED TO           37680020
*                                  BOTTOM FOUR BITS                     37760020
NINETEEN EQU   19                  NINETEEN                             37840020
MAKENN   EQU   *                                                        37920020
         SR    R15,R15             CLEAR FOR INSERT CHAR                38000020
         IC    R15,0(R1)           GET CLASSNAME                        38080020
         N     R15,SAVLOW4         TURN OFF ALL BUT LOW 4 BITS          38160020
         AR    R15,R0              ADD VALUE TO GET NN                  38240020
         ST    R15,LDQNN           STORE NN IN LOCDQ PARM LIST          38320020
         LA    R1,LDQINFOL         GET LENGTH OF LDQINFO ENTRY          38400020
         L     R0,OUTJBCNT         GET NO. OF VALID JOBS                38480020
CLEARPOS EQU   *                                                        38560020
         XC    LDQPOS,LDQPOS       ZERO POSITION OF JOB IN Q            38640020
         AR    R6,R1               ADD LTH OF INFO AREA TO ADDR         38720020
         BCT   R0,CLEARPOS         ZERO POSITION OF NEXT JOB            38800020
         ST    R6,LDQQLSTP         STORE ADDR OF ENTRY FOLLOWING        38880020
*                                  INFO AREAS (LIST OF LTH'S)           38960020
         L     R6,LDQINFOP          GET ADDR OF FIRST LDQINFO ENTRY     39040020
         LA    R1,LDQEIP           GET ADDR OF ECB/IOB PTR              39120020
         ST    R1,LDQEIPP          STORE ADDR OF ECB/IOB PTR            39200020
         ST    R11,OQMCPPL         PASS ADDR OF CPPL TO SVC 100         39280020
         MVI   OQMFUNC,OQMLOCDQ    INDICATE LOCDQ FUNCTION REQ          39360020
         LA    R0,THREE             PASS OUTPUT INDICATOR               39440020
THREE    EQU   3                    3 INDICATES OUTPUT                  39520020
         LA    R1,OQMCPPL          PASS ADDR OF SVC 100 PARMS           39600020
         SVC   FIB                 ISSUE SVC 100 TO GET PROTECT         39680020
*                                  KEY OF ZERO FOR LOCDQ                39760020
*                                  **************                       39840020
         LTR   R15,R15             WAS LOCDQ SUCCESSFUL                 39920020
         BZ    GOTOOUTP            YES, GO TO OUTPUT PROC               40000020
         MVI   OUTMSGID,M5         NO, ISSUE MSG IKJEF104               40080020
         LA    R2,FREE65           WHERE TO GO AFTER MSG                40160020
         B     MSGOUTER            GO LINK TO IKJEFF67                  40240020
GOTOOUTP EQU   *                                                        40320020
         ST    R7,OUTQMPAR         SAVE ADDR OF Q-MANAGER PARMS         40400020
         ST    R9,OUTPDL           SAVE ADDR OF PDL                     40480020
         LA    R1,OUTCOMTB         PASS ADDR OF COMMUNICATIONS          40560020
*                                  TABLE                                40640020
         L     R15,VJEFF62         GET VCON FOR IKJEFF62                40720020
         BALR  R14,R15             GO TO IKJEFF62                       40800020
*                                  ***************                      40880020
QUITEND  EQU   X'0F'               QUIT CODE                     A42944 40930021
         TM    OUTRESUM,QUITEND    SHOULD WE QUIT                A42944 40980021
         BO    FREE65              YES, DO NOT PROCESS REMAINING        41040020
*                                  CLASSES.                             41120020
         ST    R6,LDQINFOP          RESET PTR TO INFO AREA              41200020
*                                   OF FIRST JOB.                       41280020
         L     R1,OUTCLPTR         GET ADDR OF CLASSNAME PDE            41360020
         USING CLASPDE,R1          & ESTABLISH ADDRESSABILITY           41440020
         L     R1,CLASNEXT         GET ADDR OF NEXT CLASSNAME           41520020
         ST    R1,OUTCLPTR         SAVE IN CLASS BEING PROCESSED        41600020
         C     R1,LAST             IS FORWARD PTR ZERO                  41680020
         BNE   GOLOCDQ             NO, DEQUE JOBS IN NEXT CLASS         41760020
         EJECT                                                          41840020
FREE65   EQU   *                                                        41920020
         CLC   CLASS,ONE           WAS CLASSNAME SPECIFIED              42000020
         BE    FREELDQ             YES, SKIP DELETE                     42080020
         DELETE EP=IKJEFF65        FREE SYSGENED DEFAULT CLASSES        42160020
FREELDQ  EQU   *                                                        42240020
         LA    R1,OQMPARM          GET ADDR OF CORE                     42320020
         USING IOPARAMS,R1         GET PARM ADDRESSABILITY              42400020
         L     R0,OQMSIZE          GET SIZE OF CORE                     42480020
         FREEMAIN R,LV=(0),A=(1)   FREE LOCDQ PARMS                     42560020
*                                                                       42640020
         STAX                                                           42720020
         CLC   PRINT,ONE           WAS PRINT SPECIFIED                  42800020
         BNE   FREEPDL              NO, SKIP CLOSE & UNALLOCATE         42880020
         L     R1,DSNAME           GET ADDR OF DSNAME                   42960020
         CLI   0(R1),C'*'          WAS OUTPUT DATASET A TERMINAL        43040020
         BNE   CLOSEDS             NO, GO TO CLOSE & UNALLOC            43120020
         L     R1,OUTTERM          GET ADDR OF CORE TO FREE             43200020
         FREEMAIN R,LV=TERMLNTH,A=(1),SP=SP1 FREE TERMINAL WORK CORE    43280020
         B     FREEPDL             SKIP CLOSE & UNALLOC                 43360020
* CLOSE OUTPUT                                                          43440020
CLOSEDS  EQU   *                                                        43520020
         CLOSE (IHADCB),MF=(E,CLOSLIST) CLOSE OUTPUT                    43600020
        FREEPOOL IHADCB             FREE OUTPUT BUFFERS                 43760020
FREEDCB  EQU   *                                                        43800020
         L     R8,OUTDAIR          ADDR OF DAIR BLOCK                   43802020
         USING DAPB08,R8           ADDRESSABILITY                       43804020
         CLI   DA08DPS2,DA08DELE   WAS PRINT DS MARKED FOR DELETE       43806020
*                                  (NEW DS & NOTHING PUT INTO IT)       43808020
         BNE   KEEPDS              NO,BRANCH                            43810020
         USING DAPB18,R8           ADDRESSIBILITY                       43812020
         XC    DA18FLG(R6),DA18FLG ZERO FLAG,RETURN CODE FLDS           43814020
*                                  & DSNAME                             43816020
         MVI   DA18DPS2,DA18DEL    DELETE ON UNALLOCATE                 43818020
         MVC   DA18CD,DA18         FUNCTION CODE TO UNALLOCATE          43820020
         MVI   DA18CTL,R0          ZERO CONTROL FIELD                   43820520
         LR    R1,R8               PASS DAIR PARMS                      43821020
         SPACE                                                          43822020
         LINK  EP=IKJDAIR          GO TO DAIR                           43824020
KEEPDS   EQU   *                                                        43826020
         L     R1,OUTDAIR          GET ADDR OF CORE TO FREE             43840020
         FREEMAIN R,LV=DA08LTH,A=(1),SP=SP1   FREE DAIR PARMS           43920020
         LR    R1,R4               GET ADDR OF CORE TO FREE             44000020
         FREEMAIN R,LV=DCBLTH,A=(1),SP=SP1 FREE OUTPUT DCB CORE         44080020
FREEPDL  EQU   *                                                        44160020
         IKJRLSA OUTPDL            FREE PDL                             44240020
         L     R1,OUTPARS          GET ADDR OF CORE TO FREE             44320020
         FREEMAIN R,LV=PARSPARL,A=(1),SP=SP1 FREE PARSE PARM CORE       44400020
RETURN   EQU   *                                                        44480020
         SR    R2,R2               ZERO RETURN CODE                     44560020
ANY      EQU   X'F0'                                                    44568020
         TM    OUTRESUM,ANY        WAS THERE ANY ERROR                  44576020
         BNO   SETDONE             NO, PASS ZERO RETURN CODE            44584020
*                              RESET STACK, INPUT Q                     44592020
*                                SET UP PARMS FOR STACK MACRO           44600020
         L     R11,OUTCPPL         ADDR OF CPPL                         44608020
         USING CPPL,R11            ADDRESSABILITY                       44616020
         MVC   OUTPDL,CPPLUPT      ADDR OF UPT IN PARM LIST             44624020
         MVC   OUTQMPAR,CPPLECT    ADDR  OF ECT IN PARM LIST            44632020
         LA    R1,OUTATECB     ADDR OF CP'S ECB                         44640020
         ST    R1,OUTDAIR          STORE IN PARM LIST                   44648020
         LA    R1,OUTSTACK         ADDR LIST PART OF STACK MACRO        44656020
         ST    R1,OUTCPPL          STORE IN PARM LIST                   44664020
         MVC   OUTSTACK(STACKLN),STACKLST FILL IN LIST PART OF STACK    44672020
         SPACE                                                          44680020
         LA    R1,OUTPDL           ADDR OF STACK PARM LIST              44688020
         STACK  MF=(E,(1))         STACK EXECUTE                        44696020
         SPACE                                                          44704020
         TCLEARQ  INPUT            FLUSH INPUT Q                        44712020
         LA    R2,CPERROR          YES, PASS ERROR RETURN CODE          44800020
SETDONE  EQU   *                                                        44880020
         LR    R1,R3               GET ADDR OF CORE TO FREE             44960020
         FREEMAIN R,LV=OUTCOMLN,A=(1),SP=SP1 FREE OUTCOMTB CORE         45040020
         LR    R1,R13              SAVE ADDR OF CURRENT SAVEAREA        45120020
         L     R13,SAVBACK         GET ADDR OF PREVIOUS SAVEAREA        45200020
         FREEMAIN R,LV=SAVLTH,A=(1),SP=SP1 FREE CURRENT SAVE AREA       45280020
         LR    R15,R2              PASS BACK RETURN CODE                45360020
         RETURN (14,12),T,RC=(15)  RETURN                               45440020
         DROP  R13                                                      45520020
         EJECT                                                          45600020
* DCB OPEN EXIT                                                         45680020
OPENEXIT EQU   *                                                        45760020
         CLC   DCBRECFM,ZERO       IS RECFM SUPPLIED BY USER            45840020
         BNE   RTNTOOPN            YES, SKIP SUPPLYING DEFAULTS         45920020
         MVC   DCBLRECL,LOGRECSZ   SET DEFAULT LRECL                    46080020
         MVI   DCBRECFM,RECFMFBS    SET DEFAULT RECFM                   46160020
         MVC   DCBBLKSI,BLOCKSZH   SET DEFAULT BLOCKSIZE                46200020
RTNTOOPN EQU   *                                                        46240020
         BR    R14                  RETURN TO OPEN                      46320020
         EJECT                                                          46400020
MSGOUTER EQU   *                                                        46480020
         MVI   OUTRESUM,QUIT       INDICATE SERIOUS ERROR               46560020
MSGOUT   EQU   *                                                        46640020
         STH    R15,OUTRTCD        SAVE RETURN CODE                     46680020
         LR    R1,R3               PASS ADDR OF OUTCOMTB                46720020
         LINK  EP=IKJEFF67         GO TO MSG MODULE                     46800020
         BR    R2                  CONTINUE                             46880020
         EJECT                                                          46960020
* ATTENTION EXIT                                                        47040020
ATTNEXIT EQU   *                                                        47120020
         SAVE  (14,12),,ATTENTION-EXIT                                  47200020
         USING ATTNEXIT,R15                                             47280020
         L     R12,CSECTAD         ESTABLISH ADDRESSABILITY             47360020
         DROP  R15                                                      47440020
         USING IKJEFF60,R12        FOR ENTIRE CSECT                     47520020
         LR    R11,R1              SAVE PARM REG.                       47600020
         USING ATTNLIST,R11        GET PARM LIST ADDRESSABILITY         47680020
         GETMAIN R,LV=SAVLTH,SP=1  GET SAVE AREA                        47760020
         USING SAVEAREA,R1         ADDRESSABILITY FOR NEW AREA          47840020
         ST    R13,SAVBACK         STORE BACK PTR IN NEW AREA           47920020
         USING SAVEAREA,R13        ADDRESSABILITY FOR OLD AREA          48000020
         ST    R1,SAVFORW          STORE FOWARD PTR IN OLD AREA         48080020
         LR    R13,R1              GET NEW AREA ADDRESSABILITY          48160020
         L     R3,ATTOUTP          GET ADDRESS OF OUTCOMTB              48240020
         USING OUTCOMTB,R3         GET ADDRESSABILITY FOR SAME          48320020
         L     R10,ATTTAIEP        GET ADDR OF TAIE                     48400020
         USING TAIE,R10            GET TAIE ADDRESSABILITY              48480020
         LH    R15,TAIEMSGL        GET LENGTH OF SUBCOMMAND             48720020
         LTR   R15,R15             WAS NULL LINE ENTERED                48740020
         BZ    LEAVE               YES, RESUME                          48760020
         AH    R15,FOUR            ADD LENGTH OF LL & OFFSET            48800020
         STH   R15,OUTIBLTH        STORE TOTAL LENGTH IN LL             48880020
         GETMAIN R,LV=TERMLNTH,SP=SP1                                   48960020
         LR    R8,R1               SAVE ADDR OF GOTTEN CORE             49040020
         USING TERMPARM,R8         GET ADDRESSABILITY FOR SAME          49120020
         XC    TERMPARM(TERMLNTH),TERMPARM ZERO PUTLINE PARMS           49280020
         LA    R0,TERMPUT          GET ADDR OF LIST PART OF             49360020
*                                  PUTLINE                              49440020
         ST    R0,TERMPUTA         STORE IN PARM LIST                   49520020
         L     R15,OUTPARS         GET ADDR OF PARSE PARMS              49600020
         MVC   TERMPARM(TERMSTAN),0(R15) GET ADDR OF UPT,ECT,ECB        49680020
         LA    R5,OUTIBLTH         GET ADDR OF TOTAL BUFFER             49690020
         AH    R5,OUTIBLTH         ADD LENGTH OF BUFFER                 49700020
         BCTR  R5,0                GET ADDR OF LAST CHARACTER           49710020
         CLI   0(R5),C'-'          IS IT MINUS (CONTINUATION)           49720020
         BNE   SCAN                NO, GOTOSCAN                         49730020
         BAL   R4,GETLINE          GET CONTINUATION LINE IN R1          49737020
         LH    R0,0(R1)            GET LENGTH OF CONTINUATION           49744020
         LR    R10,R1              SAVE ADDR OF CONTINUATION BUF        49751020
         LR    R9,R0               SAVE LENGTH OF CONTINUATION          49758020
         AH    R10,FOUR            GET ADDR OF CONTINUATION TEXT        49765020
         SH    R9,FOUR             GET LENGTH OF CONTINUATION           49772020
*                                  TEXT.                                49779020
         LA    R6,MAXIBLTH         GET MAXIMUM LENGTH OF                49786020
*                                  SUBCOMMAND BUFFER.                   49793020
         SH    R6,OUTIBLTH         SUBTRACT LENGTH OF FIRST PART        49800020
*                                  OF CONTINUED LINE.                   49807020
         CR    R9,R6               IS LENGTH OF SECOND LINE             49814020
*                                  CONTINUATION TEXT LESS THAN          49821020
*                                  OR EQUAL TO NO. OF BYTES LEFT        49828020
*                                  IN MAXIMUM SIZE SUBCOMMAND           49835020
*                                  BUFFER.                              49842020
         BNH   COMBINE             YES, USE LENGTH OF SECOND LINE       49849020
         LR    R9,R6               NO, USE LENGTH OF REMAINDER OF       49856020
*                                  SUBCOMMAND BUFFER.                   49863020
COMBINE  EQU   *                   LOGICAL LINE TRUNCATED AT 255        49870020
         BCTR  R9,0                DECREMENT LENGTH FOR EXECUTE         49877020
MOVECONT MVC   0(0,R5),0(R10)      DUMMY MOVE                           49884020
         EX    R9,MOVECONT         MOVE CONTINUATION LINE IN TO         49891020
*                                  REMAINDER OF SUBCOMMAND              49898020
*                                  BUFFER.                              49905020
         AH    R9,OUTIBLTH         GET LENGTH OF COMBINED BUFFER        49912020
         STH   R9,OUTIBLTH         PUT IN SUBCOMMAND LENGTH             49919020
         O     R0,SUBPOOL1         GET SUBPOOL NO. IN BYTE 0            49926020
         FREEMAIN R,LV=(0),A=(1)   FREE CONTINUATION BUFFER             49933020
SCAN     EQU   *                                                        49940020
         XC    OUTIBOFF,OUTIBOFF   ZERO OFFSET                          49947020
         L     R9,OUTPARS          GET ADDR OF PARSE PARM LIST          49954020
         USING PPL,R9              ADDRESSABILITY FOR PARSE/SCAN PARMS  49964020
         MVC   CMDUPT(R12),PPLUPT  MOVE INTO SCAN PARMS UPT, ECT, ECB   49974020
         LA    R1,OUTIBLTH         GET ADDR OF TOTAL SUBCOMMAND         50000020
         ST    R1,CMDCBUF          PASS TO COMMAND SCAN                 50080020
         LA    R0,OUTCSNAM         GET ADDR OF PDE LIKE AREA            50160020
         ST    R0,CMDNAMP          PASS TO COMMAND SCAN                 50240020
         XC    OUTCSREQ,OUTCSREQ   INDICATE SYNTAX CHECK REQUEST        50320020
         LA    R1,OUTCSREQ         PASS ADDR OF REQ FLAG                50400020
         ST    R1,CMDFLGP          TO COMMAND SCAN.                     50480020
         LA    R1,CMDUPT           PASS ADDR OF PARMS                   50560020
         LINK  EP=IKJSCAN          GO TO COMMAND SCAN                   50640020
*                                  ******************                   50720020
         LTR   R15,R15             IS SCAN SUCCESSFUL                   50800020
         BZ    QMARK               YES, CHECK QUESTION MARK             50880020
         MVI   OUTMSGID,M3         ISSUE MSG IKJEF104                   50960020
         LA    R2,RETURNAT         WHERE TO GO AFTER MSG                51040020
         B     MSGOUTER            GO LINK TO IKJEFF67                  51120020
QMARK    EQU   *                                                        51200020
         TM    OUTCSFLG,CMDQUEST   WAS QUESTION MARK ENTERED            51280020
         BZ    SUBCMD              NO, GO PROCESS SUBCOMMAND            51360020
* QUESTION MARK PROCESSING                                              51440020
         XC    TERMPUT(TERMPUTL),TERMPUT ZERO LIST PART OF MACRO        51520020
         LR    R1,R8               PASS ADDR OF PARMS                   51600020
         PUTLINE OUTPUT=(0),MF=(E,(1)) PRINT SECOND LEVEL MSGES         51680020
         XC    TERMPUT(TERMPUTL),TERMPUT ZERO LIST PART OF MACRO        51760020
*                                SET UP OUTPUT LINE                     51768020
         MVC   TERMMSG(TERMMSGL),PAUSEMSG  MOVE MSG CONSTANTS           51776020
         LA    R2,TERMMSGS         ADDR OF MSG SEGMENT                  51784020
         ST    R2,TERMMSGA         STORE IN OUTPUT LINE                 51792020
         L     R2,TERMECT          ADDR OF ECT                          51800020
         USING ECT,R2              ADDRESSABILITY                       51808020
         MVC   TERMMSGT,ECTPCMD    MOVE NAME OF COMMAND                 51816020
         DROP  R2                                                       51824020
         LR    R1,R8               PASS ADDR OF PARMS                   51840020
         PUTLINE  OUTPUT=(TERMMSG),MF=(E,(1))  PRINT PAUSE MESSAGE      51940020
         BAL   R4,GETLINE          GET LINE FROM TERMINAL IN R1         52120020
         MVC   OUTIBLTH(L'OUTINBUF),0(R1) SAVE IN ATTENTION BUFFER      52320020
         LH    R0,0(R1)            GET LENGTH OF CORE TO FREE           52560020
         O     R0,SUBPOOL1         INDICATE SUBPOOL                     52640020
         FREEMAIN R,LV=(0),A=(1)   FREE SUBCOMMAND BUFFER               52720020
         CLC   OUTIBLTH,FOUR       WAS NULL LINE ENTERED                52740020
         BE    RETURNAT            YES, RESUME                          52760020
         B     SCAN                SCAN NEW LINE                        52800020
SUBCMD   EQU   *                                                        52880020
         L     R1,OUTCPPL          GET ADDR OF CPPL                     55760020
         USING CPPL,R1             GET CPPL ADDRESSABILITY              55840020
         L     R6,CPPLECT          GET ADDR OF ECT                      55920020
         USING ECT,R6              GET ECT ADDRESSABILITY               56000020
         OI    ECTMSGF,DEL         DELETE SECOND LEVEL MESSAGES         56080020
DEL      EQU   X'80'                                                    56160020
         TCLEARQ INPUT             DELETE ANY INPUT LINES               56240020
         XC    TERMPUT(TERMPUTL),TERMPUT ZERO LIST PART OF STACK        56320020
         LR    R1,R8               PASS ADDR OF PARMS                   56400020
         STACK DELETE=ALL,MF=(E,(1)) RESET STACK TO TERM ELEMENT        56480020
         L     R5,OUTTCBH          GET ADDR OF HELP TCB                 56560020
         LTR   R5,R5               WAS HELP RUNNING                     56640020
         BZ    POSTECB             NO, GO POST ATTENTION ECB            56720020
         STATUS STOP,TCB=(R5)      YES, STOP HELP SUBTASK               56800020
POSTECB  EQU   *                                                        56880020
         POST  OUTATECB            POST ATTENTIONECB                    56960020
RETURNAT EQU   *                                                        57040020
         LR    R1,R8               PASS ADDR OF PARMS                   57120020
         FREEMAIN R,LV=TERMLNTH,A=(1),SP=SP1                            57200020
LEAVE    EQU   *                                                        57280020
         LR    R1,R13              SAVE ADDR OF CURRENT SAVEAREA        57360020
         L     R13,SAVBACK         GET ADDR OF PREVIOUS SAVEAREA        57440020
         FREEMAIN R,LV=SAVLTH,A=(1),SP=1 FREE CURRENT SAVEAREA          57520020
         RETURN (14,12),T,RC=0                                          57600020
GETLINE  EQU   *                                                        57608020
         LA    R7,TERMPUT          GET ADDR OF PUTLINE PARMS            57616020
         USING GTPB,R7             USE FOR GETLINE                      57624020
         LR    R1,R8               PASS ADDR OF PARMS                   57632020
         XC    GTPB(TERMPUTL),GTPB ZERO LIST PART OF GETLINE            57640020
         GETLINE INPUT=(TERM,LOGICAL),TERMGET=(EDIT),MF=(E,(1))         57648020
         L     R1,GTPBIBUF         PASS BACK ADDR OF INPUT LINE         57656020
         BR    R4                  GO BACK                              57664020
         EJECT                                                          57680020
*  STAE EXIT                                                            57760020
         USING *,R12                                                    57840020
STAEEXIT EQU   *                                                        57920020
         LR    R12,R15             SET UP BASE REGISTER                 58000020
         LR    R7,R1               SAVE ADDR OF WORK AREA               58040020
         CH    R0,RC12             CHECK FOR RETURN CODE 12             58080020
         BE    NOWKAREA            BRANCH IF IT IS (NO WORK AREA)       58160020
         L     R2,0(R1)            ADDR OF PARM LIST(1ST WORK IN        58240020
*                                  WORK AREA)                           58320020
         L     R1,4(R1)            ABEND COMPLETION CODE (2ND           58400020
*                                  WORD IN WORK AREA)                   58480020
NOWKAREA EQU   *                                                        58560020
         LR    R10,R2              ADDR OF OUTCOMTB                     58640020
         USING OUTCOMTB,R10                                             58720020
         L     R4,OUTDCB           ADDR OF OUTPUT DCB                   58760020
         STM   R13,R14,OUTSTAE     SAVE REGISTERS 13 & 14               58800020
         SPACE                                                          58880020
*                                FIND OUT IF THIS ROUTINE WAS EN-       58960020
*                                TERED BECAUSE OF ABEND OR DETACH       59040020
*                                W/STAE (ATTENTION INTERRUPT)           59120020
         L     R11,OUTCPPL         ADDR OF CPPL                         59200020
         USING CPPL,R11            ADDRESSABILITY FOR CPPL              59280020
         L     R11,CPPLECT         ADDR OF ECT                          59360020
         USING ECT,R11             ADDRESSABILITY FOR ECT               59440020
         CLI   ECTSWS,ECTATRM      DETACH W/STAE TERMINATION            59520020
         BE    ENQJOBS             YES, GO ENQ JOBS                     59600020
         ST    R1,ECTRCDF          STORE ABEND RETURN CODE IN ECT       59680020
ABEND    EQU   X'80'               INDICATE ABEND IN ECT                59760020
         MVI   ECTRCDF,ABEND       SET HI-ORDER BIT TO 1                59840020
*                                CHECK ABEND CODES                      59920020
         SLL   R1,EIGHT8           MANEUVER ABEND CODE INTO             59940020
         SRL   R1,TWENTY           LOW-ORDER TWO BYTES                  59960020
         STH   R1,OUTRTCD          STORE IN OUTCOMTB                    59980020
CHKGETMN CLI   OUTRTCD+ONE1,GETMERR IS IT A GETMAIN FAILURE             60440020
         BNE   CHKB37                BRANCH IF NOT                      60560020
         MVI   OUTMSGID,MSG112     MESSAGE ID                           60640020
         BAL   R5,SENDMSG          ISSUE MESSAGE IKJ56312I              60680020
         MVI   OUTTCBH,RTRY        SET SW TO ENTER DUMMY RETRY          60720020
RTRY     EQU   X'40'               AFTER IKJEFF64                       60760020
         B     ENQJOBS                                                  60800020
         SPACE                                                          60880020
CHKB37   EQU   *                                                        60960020
         CLC   B37,OUTRTCD         OUT OF DA SPACE (B37)                61040020
         BE    DASPACE             BRANCH IF YES                        61120020
         CLC   D37,OUTRTCD         OUT OF DA SPACE (D37)                61200020
         BE    DASPACE             BRANCH IF YES                        61280020
         CLC   E37,OUTRTCD         OUT OF DA SPACE (E37)                61360020
         BE    DASPACE             BRANCH IF YES                        61380020
         CLC   PASSWORD,OUTRTCD    INCORRECT PASSWORD GIVEN             61400020
         BNE   ENQJOBS             BRANCH IF NO                         61440020
         MVI   OUTTCBH,RTRY                                             61460020
         B     RSTSTACK            BRANCH                               61480020
DASPACE  EQU   *                                                        61520020
         MVI   OUTMSGID,MSG131     MESSAGE ID                           61570020
         BAL   R5,SENDMSG          ISSUE MESSAGE IKJ56331J              61620020
         MVI   OUTTCBH,RTRY        SET SW TO ENTER DUMMY RETRY          61680020
*                                  AFTER IKJEFF64                       61720020
         B     ENQJOBS                                                  61770020
         SPACE                                                          61840020
SENDMSG  EQU   *                 GO TO IKJEFF67 TO PRINT MESSAGE        61920020
         LR    R1,R10              PASS ADDR OF OUTCOMTB                62000020
         LA    R13,OUTSAVE         PROVIDE SAVE AREA                    62040020
         SPACE                                                          62080020
         LINK  EP=IKJEFF67                                              62160020
         MVC   ECTRTCD,ZERO        ZERO RETURN CODE SO TMP WON'T        62170020
*                                  ISSUE MESSAGE                        62180020
         BR    R5                  RETURN                               62200020
         SPACE                                                          62240020
         SPACE                                                          62400020
ENQJOBS  EQU   *                   GO TO IKJEFF64 TO ENQUE REMAINING    62480020
*                                  JOBS                                 62560020
         LR    R1,R10              ADDR OF OUTCOMTB                     62640020
         LA    R13,OUTSAVE         PROVIDE SAVE AREA                    62680020
         SPACE                                                          62720020
         L     R15,VJEFF64         GET ADDR OF IKJEFF64                 62800020
         BALR  R14,R15             GO RE-ENQ UNDONE JOBS                62880020
         SPACE                                                          62960020
*                                  RESET THE STACK AND INPUT QUEUE      63040020
RSTSTACK EQU   *               RESET STACK, CLEAR INPUT QUEUE           63080020
         L     R9,OUTPARS          ADDR OF PARSE PARMS (CONTAINING      63120020
*                                  ADDR OF UPT, ECT, & ECB)             63200020
         MVC   OUTSTACK(STACKLN),STACKLST  MOVE STACK LIST IN OUTCOMTB  63280020
         USING PARSPARM,R9         ADDRESSABILITY                       63360020
         LA    R2,OUTSTACK         ADDR OF STACK LIST                   63440020
         ST    R2,PARSTACK         STORE INTO PARSE PARMS               63520020
         LA    R1,PARSPARM         ADDR OF PARM LIST CONTAINING         63600020
*                                  PTRS TO UPT, ECT, ECB, & STACK       63680020
*                                  LIST                                 63760020
         SPACE                                                          63840020
         STACK MF=(E,(1))        STACK EXECUTE                          63920020
         SPACE                                                          64000020
         TCLEARQ INPUT             FLUSH THE TERMINAL INPUT             64080020
         SPACE                                                          64160020
         LM    R13,R14,OUTSTAE     RESTOR REGISTERS                     64240020
         TM    OUTTCBH,RTRY        ENTER DUMMY RETRY ROUTINE            64260020
         BO    RETURN04            YES, BRANCH                          64280020
         SR    R15,R15             PREPARE ZERO RETURN CODE             64320020
         BR    14                  RETURN                               64400020
         SPACE                                                          64405020
         SPACE 3                                                        64480020
RETURN04 EQU   *                SCHEDULE A DUMMY RETRY ROUTINE TO       64482020
*                                AVOID GOING THROUGH WITH THE ABEND     64484020
         LA    R0,RETRY            ADDR OF RETRY ROUTINE                64486020
         LR    R1,R7               ADDR OF WORK AREA                    64488020
         LA    R15,RC04            RC 04 INCICATES RETRY ROUTINE        64490020
         LM    R13,R14,OUTSTAE     RESTORE SAVE & RETURN REGISTERS      64492020
         BR    R14                 RETURN                               64494020
         SPACE 3                                                        64496020
RETRY    EQU   *                 DUMMY RETRY ROUTINE TO AVOID ABEND     64498020
         L     R10,0(R1)           ADDR OF OUTCOMTB                     64500020
         L     R13,OUTSAV13        ADDR OF TMP SAVE AREA                64502020
         SPACE                                                          64504020
         RETURN (14,12),T,RC=12    PASS ERROR RETURN CODE               64509020
         SPACE 3                                                        64514020
EIGHT8   EQU   8                   REGISTER MOVE                        64520020
GETMERR  EQU   X'0A'               GETMAIN/FREEMAIN ERROR               64560020
MSG101   EQU   101                 MESSAGE IKJ56302I                    64600020
MSG130   EQU   130                 MESSAGE IKJ56302I                    64640020
MSG131   EQU   131                 MESSAGE IKJ56331I                    64680020
MSG109   EQU   109                 MESSAGE IKJ56309I                    64720020
MSG112   EQU   112                 MESSAGE IKJ56312I                    64800020
ONE1     EQU   1                                                        64880020
RC04     EQU   4                   RETURN CODE 4                        64980020
TWENTY   EQU   20                  SIZE OF REGISTER MOVE                65000020
TWO2     EQU   2                                                        65040020
B37      DC    XL2'0B37'           END-OF-VOLUME RETURN CODE            65120020
D37      DC    XL2'0D37'           END-OF-VOLUME RETURN CODE            65200020
E37      DC    XL2'0E37'           END-OF-VOLUME RETURN CODE            65280020
PASSWORD DC    XL2'0913'           INCORRECT PASSWORD ABEND CODE        65320020
RC12     DC    H'12'               RETURN CODE 12                       65360020
STACKLST STACK DELETE=ALL,MF=L     LIST FORM OF STACK                   65440020
STACKLN  EQU   *-STACKLST          LENGTH OF LIST                       65520020
         EJECT                                                          65600020
*CONSTANTS.                                                             65680020
ABCD     EQU   4                   OFFSET OF ABEND CODE                 65760020
CPERROR  EQU   12                  OUTPUT CP ERROR                      65840020
PRIMSPCE DC    F'10'               10 -3600 BYTE BLOCKS PRIMARY         65920020
SECSPCE  DC    F'1'                1 -3600 BYTE BLOCK SECONDARY         66000020
DIRSPCE  EQU   SECSPCE             NO, OF DIRECTORY BLOCKS              66040020
BLOCKSZ  DC    F'3564'             BLOCK SIZE USED FOR ALLOCATE         66080020
BLOCKSZH EQU   BLOCKSZ+2            OUTPUT BLKSIZE HALFWORD             66160020
LOGRECSZ DC    H'132'               OUTPUT LRECL                        66240020
RECFMFBS EQU   X'98'                OUTPUT RECFM -FBS                   66320020
BLANKS   DC    CL8' '              CONSTANT OF BLANKS                   66400020
SP1      EQU   1                    SUBPOOL NUMBER                      66480020
         DS    0F                                                       66560020
SUBPOOL1 DC    X'01000000'          SUBPOOL NUMBER                      66640020
CSECTAD  DC    A(IKJEFF60)         ADDR OF CSECT                        66720020
ZERO     DC    F'0'                CONSTANT OF ZERO                     66800020
SAVLOW4  DC    X'0000000F'         MASK USED TO CNVRT CLASS             66880020
ONE      DC    H'1'                CONSTANT OF ONE                      66960020
DA04     DC    H'4'                DAIR FUNCTION CODE TO FIND DS        67040020
FOUR     EQU   DA04                CONSTANT OF FOUR                     67120020
DA08     DC    H'8'                DAIR FUNCTION CODE TO ALLOC          67200020
DA18     DC    H'24'               DAIR FUNCTION CODE TO UNALLOC        67280020
DA1C     DC    H'28'               DAIR FUNCTION CODE TO ALLOC          67360020
*                                  A TERMINAL                           67440020
EIGHT    DC    H'8'                CONSTANT OF EIGHT                    67520020
NOTINCAT DC    X'0008'             DATASET NOT FOUND IN CATALOG         67600020
SIXTN    DC    H'16'               CONSTANT OF 16                       67640020
LAST     DS    0F                                                       67680020
         DC    X'FF000000'         END OF PDE CHAIN                     67760020
VPARSOUT DC    V(IKJEFFPO)         ADDR OF CSECT GENED BY PARSE         67840020
VJEFF62  DC    V(IKJEFF62)         ADDR OF OUTPUT PROCESSOR             67920020
VJEFF64  DC    V(IKJEFF64)         ADDR OF END PROCESSOR                68000020
FIB      EQU   100                 NO. OF SVC TO GET KEY 0              68080020
PAUSEMSL EQU   8                   LENGTH OF MESSAGE TEXT               68160020
         DC    H'0'                                                     68240020
*                                CONSTANTS FOR PAUSE MSG                68250020
PAUSEMSG DC    F'1'                NO. OF SEGMENTS                      68260020
         DS    A                   ADDR OF MSG SEGMENT                  68270020
         DC    H'13'               SEGMENT LENGTH                       68280020
         DC    H'0'                SEGMENT OFFSET                       68290020
         DC    C' '                BLANK BEFORE  COMMAND NAME           68300020
MAXIBLTH EQU   255                 MAX LENGTH OF ATTENTION BUFFER       68500020
CLIST    DC    CL8'OUTLIST'        CONSTANT FOR DS NAMEING      SA60977 68880021
MEMPDE   DC    A(TEMPNAME)         ADDRESS OF MEMBER NAME               68960020
         DC    Y(L'TEMPNAME)       LENGTH OF MEMBER NAME                69040020
         DC    X'80'               INDICATE MEMBER NAME PRESENT         69120020
         DC    X'00'               RESERVED                             69200020
MEMPDELN EQU   *-MEMPDE            LENGTH OF MEMBER NAME ENTRY          69280020
TEMPNAME DC    CL8'TEMPNAME'       DEFAULT MEMBER NAME                  69360020
DCBOUT   DCB   DSORG=PS,MACRF=PL,BFTEK=S                                69440020
         OPEN  (0,OUTPUT),MF=L                                          69520020
         CLOSE (0),MF=L            LIST PART OF CLOSE                   69600020
OPENEXAD DC    A(OPNEXLST)         ADDR OF DCB EXIT LIST                69680020
OPNEXLST DC    X'85'               LAST ENTRY IN LIST                   69760020
         DC    AL3(OPENEXIT)       ADDR OF OPEN EXIT                    69840020
         EJECT                                                          69920020
IKJEFFPO IKJPARM                                                        70000020
JOBNAME  IKJIDENT 'JOBNAME',LIST,PROMPT='JOBNAME',OTHER=ALPHANUM,MAXLNTX70080020
               H=8,                                                    X70160020
               HELP=('NAME(S) OF PREVIOUSLY SUBMITTED JOB(S)')          70240020
CLASS    IKJKEYWD                                                       70320020
         IKJNAME 'CLASS',SUBFLD=CLASLIST                                70400020
PRINT    IKJKEYWD DEFAULT='PRINT'                                       70480020
         IKJNAME 'PRINT',SUBFLD=DSNAM                                   70560020
         IKJNAME 'NOPRINT',SUBFLD=CLASNAM                               70640020
HERE     IKJKEYWD DEFAULT='HERE'                                        70720020
         IKJNAME 'NEXT'                                                 70800020
         IKJNAME 'HERE'                                                 70880020
         IKJNAME 'BEGIN'                                                70960020
PAUSE    IKJKEYWD DEFAULT='NOPAUSE'                                     71040020
         IKJNAME  'PAUSE'                                               71120020
         IKJNAME  'NOPAUSE'                                             71200020
CLASLIST IKJSUBF                                                        71280020
CLASSLST IKJIDENT 'CLASSNAME',LIST,FIRST=ALPHANUM,MAXLNTH=1,           X71330020
               VALIDCK=CKCLASS                                          71380020
DSNAM    IKJSUBF                                                        71440020
DSNAME   IKJPOSIT  DSTHING,DEFAULT='*'                                  71520020
CLASNAM  IKJSUBF                                                        71600020
CLASNAME  IKJIDENT  'CLASSNAME',FIRST=ANY,MAXLNTH=1,                   X71650020
               VALIDCK=CKCLASS                                          71700020
         IKJENDP                                                        71760020
         EJECT                                                          71840020
* THE FOLLOWING PDL DSECT IS GENERATED BY PARSE FOR OUTPUT              71920020
*IKJPARMD DSECT                                                         72000020
*         DS   A                   STORAGE                              72080020
*         DS   A                   CHAINS                               72160020
*JOBNAME  DS   A                   PTR TO FIRST JOBNAME                 72240020
*         DS   H                   LENGTH OF FIRST JOBNAME              72320020
*         DS   XL1                 FLAGS                                72400020
*         DS   XL1                 RESERVED                             72480020
*         DS   F                   CHAIN PTR FOR NXT JOBNAME PDE        72560020
*CLASS    DS   H                   ONE IF CLASS SPECIFIED               72640020
**                                *ZERO IF NOT SPECIFIED                72720020
*PRINT    DS   H                   ONE IF PRINT SPECIFIED               72800020
**                                *TWO IF NOPRINT SPECIFIED             72880020
*HERE     DS   H                   ONE IF NEXT SPECIFIED                72960020
**                                *TWO IF HERE SPECIFIED                73040020
**                                *THREE IF BEGIN SPECIFIED             73120020
*PAUSE    DS   H                   ONE IF PAUSE SPECIFIED               73200020
**                                *TWO IF NOPAUSE SPECIFIED             73280020
*CLASSLST DS   A                   PTR TO FIRST CLASSNAME               73360020
**                                *ZERO IF NOT SPECIFIED                73440020
*         DS   H                   LENGTH OF FIRST CLASSNAME            73520020
*         DS   XL1                 FLAGS,BIT 0,0 IF OMITTED             73600020
*         DS   XL1                 RESERVED                             73680020
*         DS   A                   CHAIN PTR TO NEXT CLASS PDE          73760020
*DSNAME   DS   A                   PTR TO DSNAME                        73840020
*         DS   H                   LENGTH OF DSNAME                     73920020
*         DS   XL1                 FLAGS,BIT 0,0 IF OMITTED             74000020
**                                *      BIT 1,1 IF QUOTED              74080020
*         DS   XL1                 RESERVED                             74160020
*         DS   A                   PTR TO MEMBER NAME                   74240020
*         DS   H                   LENGTH OF MEMBER NAME                74320020
*         DS   XL1                 FLAGS,BIT 0,0 IF OMITTED             74400020
*         DS   XL1                 RESERVED                             74480020
*         DS   A                   PTR TO PASSWORD                      74560020
*         DS   H                   LENGTH OF PASSWORD                   74640020
*         DS   XL1                 FLAGS, BIT 0, 0 IF OMITTED           74720020
*         DS   XL1                 RESERVED                             74800020
*CLASNAME DS   A                   PTR TO NOPRINT CLASSNAME             74880020
*         DS   H                   LENGTH OF NOPRINT CLASSNAME          74960020
*         DS   XL1                 FLAGS                                75040020
*         DS   XL1                 RESERVED                             75120020
         IKJPPL                                                         75200020
PARSTACK EQU   PPLPCL              ADDR OF STACK LIST                   75280020
PARSPARM EQU   PPL                 ALTERNATE NAME FOR PPL               75360020
CMDUPT   DS    A                   ADDR OF UPT                          75368020
CMDECT   DS    A                   ADDR OF ECT                          75376020
CMDECBA  DS    A                   ADDR OF ATTENTION ECB                75384020
CMDFLGP  DS    A                   ADDR OF COMMAND SCAN FLAGS           75392020
CMDNAMP  DS    A                   ADDR OF PDE LIKE OUTPUT AREA         75400020
CMDCBUF  DS    A                   ADDR OF COMMAND BUFFER               75408020
CMDVALID EQU   X'C0'               COMMAND NAME VALID                   75416020
CMDQUEST EQU   X'20'               COMMAND IS A QUESTION MARK           75424020
CMDMTY   EQU   X'10'               BUFFER IS EMPTY                      75432020
PARSPARL EQU   *-PPL               LENGTH OF PARSE PARAMETER LIST       75440020
JOBPDE   DSECT                                                          75520020
JBNAMEAD DS    A                   ADDR OF FIRST JOBNAME                75600020
JBNMLTH  DS    H                   LENGTH OF FIRST JOBNAME              75680020
JBNMFLGS DS    XL1                 FLAGS                                75760020
         DS    XL1                 RESERVED                             75840020
JOBBEGLN EQU   *-JOBPDE            LENGTH OF BEGINING OF JOBPDE         75920020
JBNMNEXT DS    A                   ADDR OF NEXT JOBNAME PDE             76000020
JOBPDELN EQU   *-JOBPDE            LENGTH OF JOBPDE                     76080020
JBNM     EQU   X'80'               JOBNAME SPECIFIED                    76160020
CLASPDE  DSECT                                                          76240020
CLASNMAD DS    A                   ADDR OF THE CLASS NAME               76320020
CLASLTH  DS    H                   LENGTH OF THE CLASS NAME             76400020
CLASFLGS DS    XL1                 CLASS NAME FLAGS                     76480020
         DS    XL1                 RESERVED                             76560020
CLASNEXT DS    A                   ADDR OF NEXT CLASS NAME PDE          76640020
CLASPDEL EQU   *-CLASPDE           LENGTH OF CLASS PDE                  76720020
CLAS     EQU   X'80'               CLASS NAME SPECIFIED                 76800020
DSNPDE   DSECT                                                          76880020
DSNAMEAD DS    A                   ADDR OF DATA SET NAME                76960020
DSNLTH1  DS    H                   LENGTH OF DATA SET NAME              77040020
DSNFLG1  DS    XL1                 DATA SET NAME FLAGS                  77120020
         DS    XL1                 RESERVED                             77200020
DSNMEMAD DS    A                   ADDR OF DATA SET MEMBER NAME         77280020
DSNLTH2  DS    H                   LNGTH OF DATA SET MEMBER NAME        77360020
DSNFLG2  DS    XL1                 MEMBER NAME FLAGS                    77440020
         DS    XL1                 RESERVED                             77520020
DSNPASAD DS    A                   ADDR OF DATA SET PASSWORD NM         77600020
DSNLTH3  DS    H                   LENGTH OF PASSWORD                   77680020
DSNFLG3  DS    XL1                 PASSWORD FLAGS                       77760020
         DS    XL1                 RESERVED                             77840020
DSN      EQU   X'80'               DSNAME SPECIFIED                     77920020
DSNQUO   EQU   X'40'               DSNAME QUOTED                        78000020
DSM      EQU   X'80'               MEMBER SPECIFIED                     78080020
DSP      EQU   X'80'               PASSWORD SPECIFIED                   78160020
         EJECT                                                          79040020
         IKJCPPL                                                        79120020
         IKJPSCB                                                        79200020
         IKJECT                                                         79280020
         IKJTAIE                                                        79360020
SAVEAREA DSECT                                                          79440020
         DS    F                                                        79520020
SAVBACK  DS    F                                                        79600020
SAVFORW  DS    F                                                        79680020
         DS    15F                                                      79760020
SAVEND   EQU   *                                                        79840020
SAVLTH   EQU   SAVEND-SAVEAREA                                          79920020
         EJECT                                                          80000020
*        MAP OF MODULE CONTAINING DEFAULT CLASS PDE'S                   80080020
IKJEFF65 DSECT                                                          80160020
SMBCLASS DS    CL1                 DEFAULT MESSAGE CLASS                80240020
DSBCLASS DS    CL1                 DEFAULT SYSOUT CLASS                 80320020
         DS    0D                                                       80400020
CLASSPDL DC    A(SMBCLASS)         ADDR OF DEFAULT SMB CLASS            80480020
         DC    H'1'                LENGTH OF SMB CLASS NAME             80560020
         DC    X'80'               FLAGS BIT 0, 0 IF OMITTED            80640020
         DC    X'00'               RESERVED                             80720020
         DC    A(DSBPDE)           ADDR OF NEXT PDE                     80800020
DSBPDE   DC    A(DSBCLASS)         ADDR OF DEFAULT DSB CLASS            80880020
         DC    H'1'                LENGTH OF DSB CLASS NAME             80960020
         DC    X'80'               FLAGS BIT 0, 0 IF OMITTED            81040020
         DC    X'00'               RESERVED                             81120020
         DC    X'FF000000'         INDICATE LAST PDE                    81200020
         EJECT                                                          81280020
         IKJDAPL                                                        81360020
DAPLBGLN EQU   DAPLPSCB-DAPL       LENGTH OF BEGINING OF PARMS          81440020
DAPLLTH  EQU   *-DAPL              LENGTH OF DAPL                       81520020
DA04STAR EQU   *                   START OF DAIR PARM BLOCK             81600020
DAPB04   DSECT                     START DSECT EARLY SO WE CAN          81680020
         ORG   *+DAPLLTH           ORG TO BEGINING OF GETMAIN           81760020
         IKJDAP04                                                       81840020
DAPB04   DSECT                                                          81920020
DA04END  EQU   *                   END OF FIND DS BLOCK                 82000020
DA04LTH  EQU   DA04END-DAPB04      LENGTH OF FIND DS BLOCK              82080020
DAPB08   DSECT                                                          82160020
         ORG   *+DAPLLTH           ORG TO BEGINING OF GETMAIN           82240020
         IKJDAP08                                                       82320020
DAPB08   DSECT                                                          82400020
DA08DSNL DS    H                   OUTPUT DSNAME LENGTH                 82480020
DA08DSNM DS    CL44                OUTPUT DSNAME                        82560020
DA08QUO  DS    CL1                 INDICATE IF DSNAME QUOTED            82640020
NOTQUO   EQU   0                   DSNAME NOT QUOTED                    82690020
QUO      EQU   1                   DSNAME QUOTED                        82740020
DA08FRLN EQU   DA08PDSN-DA08FLG    LENGTH OF FLAG & RETURN CODES        82800020
DA08END  EQU   *                   END OF ALLOCATE BLOCK                82880020
DA08LTH  EQU   DA08END-DAPB08      LENGTH OF ALLOCATE BLOCK             82960020
DAPB18   DSECT                     START DSECT EARLY SO WE CAN          83040020
         ORG   *+DAPLLTH           ORG TO BEGINING OF GETMAIN           83120020
         IKJDAP18                                                       83200020
DA18FRDL EQU   DA18DDN-DA18FLG                                          83240020
         IKJDFPL                                                        83280020
DFPB1    EQU   *                                                        83360020
DFPLLTH  EQU   *-DFPL              LENGTH OF DFPL                       83440020
DFPB     DSECT                                                          83520020
         ORG   *+DFPLLTH           MAKE DFPB CONTIGUOUS TO DFPL         83600020
         IKJDFPB                                                        83680020
DFPBLTH  EQU   *-DFPB              LENGTH OF DFPL PLUS DFPB             83760020
         EJECT                                                          83840020
* PARAMETER LIST PASSED TO SECURITY EXIT                                83920020
SECEXPAR DSECT                                                          84000020
SECJBNAM DS    A                   ADDR OF JOBNAME                      84080020
SECJBLTH DS    A                   ADDR OF JOBNAME LENGTH               84160020
SECUSID  DS    A                   ADDR OF USER ID                      84240020
SECUSIDL DS    A                   ADDR OF USER ID LENGTH               84320020
SECMESS  DS    A                   ADDR OF MESSAGE FROM EXIT            84400020
SECREPLY DS    A                   ADDR OF REPLY FOR EXIT               84480020
SECCOMCD DS    A                   ADDR OR SECURITY EXIT CODE           84560020
SECCODE  DS    XL1                 SECURITY EXIT CODE                   84640020
SECEXOUT EQU   8                   OUTPUT SECURITY EXIT CODE            84720020
SECEXLTH EQU   *-SECEXPAR          LENGTH OF SEC EXIT PARM LIST         84800020
         EJECT                                                          84880020
         DCBD  DSORG=PS                                                 84960020
OPENLIST OPEN  (0,OUTPUT),MF=L     LIST PART OF OPEN                    85040020
CLOSLIST CLOSE (0),MF=L            LIST PART OF CLOSE                   85120020
DCBEND   EQU   *                   END OF DCB & OPEN LIST               85200020
DCBLTH   EQU   DCBEND-IHADCB       LENGTH OF DCB & OPEN LIST            85280020
         EJECT                                                          85300020
CVTBLK   DSECT                                                          85320020
         CVT                                                            85340020
         EJECT                                                          85360020
*THE FOLLOWING CODES ARE PASSED TO IKJEFF67 THE MESSAGE PROCESSOR.      85420020
M1       EQU   119                 COMMAND NOT AUTHORIZED               85480020
M2       EQU   12                  PARSE ERROR                          85540020
M3       EQU   20                  COMMAND SCAN ERROR                   85600020
M4       EQU   16                  DAIR ERROR                           85660020
M5       EQU   114                 Q/MANAGER ERROR                      85720020
M16      EQU   111                 MEMBER GIVEN BUT NOT PO              85780020
M17      EQU   126                 ISAM ORGINAZITION NO GOOD            85840020
M19      EQU   110                 DSNAME EXCEEDS 44 CHARACTERS         85900020
M20      EQU   127                 DA ORGINIZATION NO GOOD              85960020
M21      EQU   48                  GETLINE ERROR                        86020020
M142     EQU   142                 BAD RETURN CODE FROM SEC EXIT        86060020
         EJECT                                                          86100020
         IKJOCMTB                                                       86160020
TERMPARM DSECT                                                          86240020
TERMUPT  DS    A                   ADDR OF UPT                          86320020
TERMECT  DS    A                   ADDR OF ECT                          86400020
TERMECBA DS    A                   ADDR OF ATTENTION ECB                86480020
TERMSTAN EQU   *-TERMPARM          LENGTH OF STANDARD PART              86560020
TERMPUTA DS    A                   ADDR OF LIST PART OF                 86640020
*                                  PUTLINE                              86720020
TERMPUT  PUTLINE MF=L            LIST PART OF PUTLINE                   86800020
TERMPUTL EQU   *-TERMPUT           LENGTH OF LIST PART OF MACRO         86880020
*                                OUTPUT LINE CONTAINING MODE MSG        86890020
TERMMSG  DS    A                   NO. OF SEGMENTS                      86900020
TERMMSGA DS    A                   ADDR OF SEGMENT                      86910020
TERMMSGS DS    F                   SEGMENT LENGTH & OFFSET              86920020
         DS    C                   BLANK BEFORE COMMAND NAME            86930020
TERMMSGL EQU   *-TERMMSG           LENGTH OF CONSTANTS IN OUTPUT LINE   86940020
TERMMSGT DS    CL8                 TEXT (NAME OF COMMAND)               86950020
TERMLNTH EQU   *-TERMPARM          LENGTH OF PUTLINE CORE               86960020
         IKJGTPB                                                        87040020
ATTNLIST DS    0F                                                       87120020
ATTTAIEP DS    A                   ADDR OF TAIE                         87200020
ATTIBUFP DS    A                   ADDR OF INPUT BUFFER                 87280020
ATTOUTP  DS    A                   ADDR OF OUTCOMTB                     87360020
         EJECT                                                          87440020
IOPARAMS DSECT                                                          87520020
OQMPARM  DS    0D                                                       87600020
OQMSIZE  DS    F                   SIZE OF GETMAIN                      87680020
OQMCPPL  DS    A                   ADDR OF CPPL                         87760020
OQMFUNC  DS    XL1                 FUNC INICATION FOR IKJEFF61          87840020
OQMLOCDQ EQU   X'80'               LOCDQ FUNCTION                       87920020
OQMREAD  EQU   X'40'               READ FUNCTION                        88000020
OQMDELE  EQU   X'20'               DELETE FUNCTION                      88080020
OQMENQ   EQU   X'10'               ENQUE FUNCTION                       88160020
OQMUCB   EQU   X'08'               UCB FUNCTION                         88180020
OQMUCBAD DS    A                   UCB ADDR                             88200020
OQM1STSM DS    XL3                 TTR OF FIRST SMB/DSB                 88240020
*                                  FOR JOB                              88320020
         DS    0D                                                       88400020
         IEFQMNGR                                                       88480020
QMPCA    DS    F                   CORE ADDR OF DSB/SMB BUFFER          88560020
QMPEX    DS    F                   DISK ADDR OF DSB/SMB                 88640020
QMPALTH  EQU   *-QMNAM             LENGTH OF QMPA                       88720020
SMBBUF   DS    176XL1              SMB BUFFER                           88800020
DSBBUF   EQU   SMBBUF              DSB BUFFER                           88880020
         DS    F                   PLACE FOR PUTLINE TO                 88960020
*                                  PUT LL                               89040020
SMBWORK  DS    CL1                 AREA TO DEBLOCK & DECOMPRESS         89120020
SMBWORK1 DS    CL165               SYSTEM MESSAGES                      89200020
QMLNGTH  EQU   *-QMNAM             LENGTH OF CORE FOR Q-MANAGER         89280020
LDQJBPTR DS    A                   ADDR OF JOBNAME LIST                 89360020
LDQNPTR  DS    A                   ADDR OF NO. OF JOB NAMES             89440020
LDQNNPTR DS    A                   ADDR OF NN OF QCR                    89520020
LDQINFOP DS    A                   ADDR OF INFO AREA                    89600020
*                                  ADDR OF INFO AREA OF JOB             89680020
*                                  BEING PROCESSED                      89760020
LDQNFNDP DS    A                   ADDR OF NO. OF JOBS FOUND            89840020
LDQQLSTP DS    A                   ADDR OF LIST OF QMPA'S (LTH'S)       89920020
*                                  ADDR OF QMPA (LTH) OF JOB            90000020
*                                  BEING PROCESSED                      90080020
LDQEIPP  DS    A                   ADDR OF THE ECB/IOB PTR              90160020
LDQNN    DS    F                   NN OF Q TO BE SEARCHED               90240020
LDQNFND  DS    F                   NO. OF JOBS FOUND                    90320020
LDQEIP   DS    A                   ECB/IOB PTR                          90400020
LDQFIXLN EQU   *-OQMPARM           LENGTH OF FIXED PART OF LIST         90480020
LDQJB    DS    D                   JOB NAME LIST                        90560020
LDQINFO  EQU   *                   INFORMATION AREA                     90640020
LDQPOS   DS    F                   POSITION OF JOB IN Q                 90720020
*                                 *ZERO IF NOT FOUND                    90800020
LDQPRI   DS    F                   PRIORITY OF JOB                      90880020
LDQSTA   DS    F                   STATUS OF JOB                        90960020
LDQJBNN  DS    F                   NN OF JOB'S ENTRY IN Q               91040020
LDQINFOL EQU   *-LDQINFO           LENGTH OF LDQINFO ENTRY              91120020
LDQQLST  EQU   *                   LIST OF QMPA'S (LTH'S)               91200020
LDQQMNAM DS    D                   JOB NAME                             91280020
LDQQMPOP DS    XL1                 FUNCTION CODE PARAMETER              91360020
LDQQMFLT DS    XL2                 1ST LOG TRK ASGND TO JOB             91440020
LDQQMTST DS    XL1                 NO. RECS. USED IN LOG. TRK           91520020
LDQQMTLN DS    XL2                 REL. ADDR OF NEXT LOG. TRK           91600020
LDQQMNOT DS    XL1                 NO. LOGICAL TRK ASGND TO JOB         91680020
LDQQMTPY DS    XL1                 JOB TYPE                             91760020
LDQQMSTA DS    XL1                 JOB STATUS                           91840020
LDQQMPRI DS    XL1                 JOB PRIORITY                         91920020
LDQQMLNK DS    XL2                 REL. ADDR OF NEXT Q ENTRY            92000020
LDQQLSTL EQU   *-LDQQLST           LENGTH OF LTH (QMPA)                 92080020
LDQVARLN EQU   *-LDQJB             LENGTH OF VARIABLE PARMS             92160020
  END                                                                   92240020
