 TITLE ' Q-CONTROL  MODULE IKJEFF61  OUTPUT CP '                        00300020
*STATUS. CHANGE LEVEL 0       1/20/70                                   00600000
*FUNCTION.                                                              00900000
* A 480300,480460,480520 ,504100-504500,598500                   A56936 01000021
*       THIS MODULE RECEIVES CONTROL FROM SVC 100 VIA A LINK.           01200000
*       SVC 100 PROVIDES THIS MODULE WITH PROTECT KEY OF ZERO.          01500000
*       AFTER DETERMINING WHICH Q-MANAGER FUNCTION IS REQUESTED,        01800000
*       THE QMPA IS COMPLETED IF NECESSARY AND CONTROL PASSED           02100000
*       TO THE APPROPRIATE Q-MANAGER FUNCTION.                          02400000
*ENTRY POINT. IKJEFF61 -INITIAL ENTRY                                   02700000
*INPUT. ADDR OF CPPL POINTER IN OUTPUT Q/M PARMS (OQMPARM)              03000000
*EXITS. 1-IEFLOCDQ VIA A CALL                                           03300000
*       2-IEFQDELQ VIA A CALL                                           03600020
*       3-TRANSIENT Q-MANAGER SVC                                       03900020
*       4-RETURN TO SVC 100                                             04200020
IKJEFF61 CSECT                                                          04500020
R0       EQU   0                   REGISTER 0                           04800020
R1       EQU   1                   REGISTER 1                           05100020
R2       EQU   2                   REGISTER 2                           05400020
R3       EQU   3                   REGISTER 3                           05700020
R4       EQU   4                   REGISTER 4                           06000020
R5       EQU   5                   REGISTER 5                           06300020
R6       EQU   6                   REGISTER 6                           06600020
R7       EQU   7                   REGISTER 7                           06900020
R8       EQU   8                   REGISTER 8                           07200020
R9       EQU   9                   REGISTER 9                           07500020
R10      EQU   10                  REGISTER 10                          07800020
R11      EQU   11                  REGISTER 11                          08100020
R12      EQU   12                  REGISTER 12                          08400020
R13      EQU   13                  REGISTER 13                          08700020
R14      EQU   14                  REGISTER 14                          09000020
R15      EQU   15                  REGISTER 15                          09300020
         SAVE  (14,12),,*          SAVE CALLERS REGISTERS               09600020
         BALR  R12,0                ESTABLISH ADDRESSABILITY            09900020
         USING *,R12               FOR IKJEFF61                         10200020
         LR    R10,R1              SAVE PARM REGISTER                   10500020
         USING OQMCPPL,R10         ESTAB. Q-MNGR PARMS ADDRESSAB        10800020
         GETMAIN R,LV=SAVLTH       GET SAVE AREA                        11100020
         USING SAVEAREA,R1         ADDRESSABILITY FOR NEW AREA          11400020
         ST    R13,SAVBACK         STORE BACK PTR IN NEW AREA           11700020
         USING SAVEAREA,R13        ADDRESSABILITY FOR OLD AREA          12000020
         ST    R1,SAVFORW          STORE FORWARD PTR IN OLD AREA        12300020
         LR    R13,R1              ESTABLISH NEW SAVE AREA              12600020
*                                  ADDRESSABILITY                       12900020
         EJECT                                                          13200020
*  PROCESS LOCDQ REQUEST                                                13500020
         CLI   OQMFUNC,OQMLOCDQ    WAS LOCDQ FUNCTION REQUESTED         13800020
         BNE   CKDELETE            NO, SEE IF DELETE REQUESTED          14100020
         ENQ   MF=(E,IEFALTRA)                                          14400020
         L     R15,VLOCDQ          GET ADDR WHERE TO GO                 14700020
         LA    R1,LDQJBPTR         PASS ADDR OF LOCDQ PARMS             15000020
         BALR  R14,R15             GO TO LOCDQ                          15300020
*                                  **********                           15600020
         DEQ   MF=(E,IEFALTRA)                                          15900020
         CLC LDQNFND,ZERO          WERE ANY JOBS FOUND                  16200020
         BE    RETURN              NO, SKIP FREE OF ECB/IOB             16500020
         L     R1,LDQEIP           GET ADDR OF ECB/IOB                  16800020
         SH    R1,FOUR             GET ADDR OF ECB/IOB SIZE             17100020
         L     R0,0(R1)            GET ECB/IOB SIZE                     17400020
         FREEMAIN R,LV=(0),A=(1)   FREE ECB/IOB GOTTEN BY LOCDQ         17700020
         B     RETURN              GO BACK TO SVC 100                   18000020
         EJECT                                                          18300020
*  PROCESS DELETE REQUEST                                               18600020
CKDELETE EQU   *                                                        18900020
         CLI   OQMFUNC,OQMDELE     WAS DELETE FUNCTION REQUESTED        19200020
         BNE   CKREAD              NO, SEE IF READ REQUESTED            19500020
         MVI   QMPOP,QMDELE        SET FUNC CODE IN QMPA                19800020
         LA    R14,RETURN          GET ADDR TO RETURN TO                20100020
         L     R15,VDELETE         GET ADDR WHERE TO GO                 20400020
         LA    R1,QMNAM            PASS ADDR OF QMPA                    20700020
         BR    R15                 GO TO Q/M DELETE                     21000020
         EJECT                                                          21300020
* PROCESS READ REQUEST                                                  21600020
CKREAD   CLI   OQMFUNC,OQMREAD     WAS READ FUNCTION REQUESTED          21900020
         BNE   CKENQ               NO, SEE IF ENQ REQUESTED             22200020
         L     R1,QMPEX            IS THIS THE FIRST READ OF JOB        22500020
         LTR   R1,R1               IF QMPEX IS NOT ZERO, THIS IS        22800020
         BNZ   FIXQMPOP            NOT FIRST READ. SKIP SET UP          23100020
         GETMAIN R,LV=QCTLPARL     GET CORE FOR TTR CONVERSION          23400020
         LR    R11,R1              SAVE ADDR OF GOTTEN CORE             23700020
         USING QCTLPARM,R11        GET PARMLIST ADDRESSABILITY          24000020
         MVC   QCTLMASK,MASK       INDICATE NN IS FOR A QUEUE           24300020
*                                  ENTRY                                24600020
         LA    R1,QCTLMASK         GET ADDR OF MASK                     24900020
         ST    R1,QCTLMSKP         STORE IN TTRCNVRT PARM LIST          25200020
         L     R1,LDQINFOP         GET ADDR OF LOCDQ INFO AREA          25500020
         USING LDQINFO,R1          FOR JOB-BEING-PROCESSE               25800020
         LA    R0,QCTLNN           GET ADDR OF NN FOR CURRENT JB        26100000
         ST    R0,QCTLNNPT          STORE IN TTRCNVRT PARMLIST          26400020
         MVC   QCTLNN+2(L'QMFLT),QMFLT  GET NN OF FIRST LTH             26700000
         XC    QCTLNN(R2),QCTLNN   ZERO THE FIRST TWO BYTES             26800020
         L     R0,QCTLNN           GET NN OF CURRENT JOB                27000000
         AH    R0,ONE              GET NN OF FIRST SMB                  27300020
         ST    R0,QCTLNN           PASS TO CNVRT                        27600000
         L     R6,QMPCA            GET ADDR OF SMB                      27900020
         USING SMBDSKAD,R6         ESTABLISH SMB ADDRESSABILITY         28200020
         LA    R0,QMPEX            GET ADDR WHERE TO PUT TTR            28500000
         ST    R0,QCTLTTRP           STORE IN TTRCNVRT PARM LIST        28800000
         LR    R1,R11                PASS ADDR OF PARM LIST             29100000
         L     R15,VTTRCNVR          GET ADDR WHERE TO GO               29400000
         BALR  R14,R15               GO TO TTRCNVRT                     29700000
*                                    *************                      30000000
         MVC   OQM1STSM,QMPEX      SAVE TTR OF FIRST SMB/DSB IN         30300000
*                                  JOB IN CASE RE-ENQ IS NECESS.        30600020
         MVI   QMPOP,QMASGS        SET Q/M FUNC TO ASSIGN/START         30900020
         L     R15,VAGST           GET ADDR WHERE TO GO                 31200020
         LA    R1,QMNAM            PASS ADDR OF QMPA                    31500020
         BALR  R14,R15             GO TO ASSIGN/START TO GET            31800020
*                                  *******************                  32100020
*                                                                       32400020
*                                  ECB/IOB NEEDED TO READ,              32700020
*                                  ENQ OR DELETE                        33000020
         L     R1,LDQQLSTP         GET ADDR OF LTH FOR JOB              33300020
*                                  BEING PROCESSED.                     33600020
         USING LDQQLST,R1          GET LTH ADDRESSABILITY               33900020
         MVC   QMNAM(LDQQLSTL),LDQQLST REPLACE PART OF                  34200020
*                                  QMPA (OVERLAYED BY                   34500020
*                                  ASSIGN/START) WITH SAVED             34800020
*                                  LTH                                  35100020
         L     R1,LDQINFOP         GET ADDR OF LOCDQ INFO AREA          35160000
         USING LDQINFO,R1          FOR JOB-BEING-PROCESSE               35220000
         MVC   QMTID,LDQJBNN+2     INITIALIZE SELF ID FIELD             35300000
*                                  TO NN OF LAST LTH FOR JOB            35500000
FIXQMPOP EQU   *                                                        35700020
         MVI   QMPOP,QMREAD        SET Q/M FUNC TO READ                 36000020
         MVI   QMPNC,ONEREC        SET NO. OF RECS. TO ONE              36300020
ONEREC   EQU   1                                                        36600020
         LA    R1,QMNAM            PASS ADDR OF QMPA TO Q/M             36900020
         SVC   QMNGR               ISSUE TRANSIENT Q/M SVC              37200020
*                                  ****************                     37500020
         CLC   QMPEX,OQM1STSM     IS THIS THE FIRST READ                37800020
         BNE   RETURN             NO, SKIP FREE OF CNVRT PARMS          38100020
         LR    R2,R15              SAVE Q/MNGR RETURN CODE              38400020
         LR    R1,R11              GET ADDR OF CORE TO FREE             38700020
         FREEMAIN R,LV=QCTLPARL,A=(1) FREE TTRCNVRT PARMS               39000020
         LR    R15,R2              RESTORE Q/MNGR RETURN CODE           39300020
         B     RETURN              GO BACK TO SVC 100                   39600020
         EJECT                                                          39900020
* PROCESS ENQ REQUEST                                                   40200020
CKENQ    EQU   *                                                        40500020
         CLI   OQMFUNC,OQMENQ      WAS ENQUEUE FUNCTION REQUESTED       40600000
         BNE   CKUCB               NO, SEE IF UCB  FUNCTION REQUESTED   40700000
         L     R1,QMPCL            GET PTR TO EXTERNAL PARMS            40800020
         LTR   R1,R1               IS IT ZERO                           41100020
         BNZ   GOENQ               NO, SKIP GETTING ECB/IOB             41400020
         MVI   QMPOP,QMASGS        SET Q/M FUNC TO ASSIGN/START         41700020
         L     R15,VAGST           GET ADDR WHERE TO GO                 42000020
         LA    R1,QMNAM            PASS ADDR OF QMPA                    42300020
         BALR  R14,R15             GO TO ASSIGN/START TO GET            42600020
*                                  *******************                  42900020
*                                                                       43200020
*                                  ECB/IOB NEEDED TO READ,              43500020
*                                  ENQ OR DELETE                        43800020
         L     R1,LDQQLSTP         GET ADDR OF LTH FOR JOB              44100020
*                                  BEING PROCESSED.                     44400020
         USING LDQQLST,R1          GET LTH ADDRESSABILITY               44700020
         MVC   QMNAM(LDQQLSTL),LDQQLST REPLACE PART OF                  45000020
*                                  QMPA (OVERLAYED BY                   45300020
*                                  ASSIGN/START) WITH SAVED             45600020
*                                  LTH                                  45900020
         L     R1,LDQINFOP         GET ADDR OF LOCDQ INFO AREA          45960000
         USING LDQINFO,R1          FOR JOB-BEING-PROCESSE               46020000
         MVC   QMTID,LDQJBNN+2     INITIALIZE SELF ID FIELD             46100000
*                                  TO NN OF LAST LTH FOR JOB            46300000
GOENQ    EQU   *                                                        46500020
         MVI   QMPOP,QMWREN        INDICATE ENQ TO Q/MANAGER SVC        46800020
         LA    R1,QMNAM            PASS ADDR OF QMPA                    47100020
         SVC   QMNGR               ISSUE TRANSIENT Q/MANAGER SVC        47400020
         B     RETURN              GO BACK TO SVC 100                   47700020
         EJECT                                                          48000020
* PROCESS UCB REQUEST - INCREMENT USER COUNT                            48020000
* CHECK FOR SVC 90 REQUEST                                       A56936 48030021
CKUCB    EQU   *                                                        48040000
         CLI   OQMFUNC,OQMSVC       WAS SVC 90 REQUESTED         A56936 48046021
         BE    ISSUESVC             YES, GO ISSUE SVC 90         A56936 48052021
         L     R2,OQMUCBAD         ADDR OF UCB                          48060000
         USING UCBOB,R2            ADDRESSABILITY                       48080000
         ENQ   MF=(E,ENQDQLST)     ENQ ON UCB RESOURCE                  48100000
         IC    R0,SRTEUSER         GET USER COUNT                       48120000
         BCT   R0,STORECNT         DECREMENT USER COUNT                 48140000
         NI    SRTESTAT,X'FF'-SRTEALOC SET UNALLOCATED IF CNT ZERO      48160000
         MVI   SRTEDMCT,R0         ZERO DATA MANAGEMENT COUNT           48180000
STORECNT EQU   *                                                        48200000
         STC   R0,SRTEUSER         STORE DECREMENTED USER COUNT         48220000
         DEQ   MF=(E,ENQDQLST)     DEQ FROM UCB RESOURCE                48240000
         EJECT                                                          48260000
*  RETURN WITH Q/MANAGER RETURN CODE                                    48300020
RETURN   EQU   *                                                        48600020
         LR    R2,R15              SAVE Q/MANAGER RETURN CODE           48900020
         LR    R1,R13              SAVE ADDR OF CURRENT SAVEAREA        49200020
         L     R13,SAVBACK         GET ADDR OF PREVIOUS SAVEAREA        49500020
         FREEMAIN R,LV=SAVLTH,A=(1) FREE CURRENT SAVEAREA               49800020
         LR    R15,R2              PASS BACK Q/MANAGER RETURN CODE      50100020
         RETURN (14,12),T,RC=(15)     RETURN                            50400020
* ISSUE SVC 90 FOR PROCESSING WHICH WAS SET UP IN IKJEFF64       A56936 50410021
ISSUESVC EQU   *                                                 A56936 50420021
         LA    R1,QMNAM             ADDR OF QMPA FOR SVC 90      A56936 50430021
         SVC   QMNGR                ISSUE SVC 90                 A56936 50440021
         B     RETURN                                            A56936 50450021
         EJECT                                                          50500000
IEFALTRA ENQ   (IEFQCBS,IEFQ1QCB,E,2,SYSTEM),MF=L                       50700020
IEFQCBS DC    C'SYSIEFSD'          MAJOR NAME                           51000020
IEFQ1QCB DC    C'Q1'               MINOR NAME                           51300020
VLOCDQ   DC    V(LOCDQ)           VCON FOR LOCDQ                        51600000
VDELETE  DC    V(IEFQDELE)         VCON FOR QDELQ (DELETE)              51900020
VTTRCNVR DC    V(IKJEFF66)         VCON FOR CONVRT                      52200020
VAGST    DC    V(IEFQAGST)         VCON FOR AGST (ASSIGN/START)         52500020
MASK     DC    X'40000000'         REQUEST FOR NN OF QUEUE              52800020
*                                  ENTRY BE CONVERTED TO A TTR          53100020
ONE      DC    H'1'                CONSTANT OF ONE                      53400020
ZERO     DC    F'0'                 CONSTANT OF ZERO                    53700020
FOUR     DC    H'4'                CONSTANT OF FOUR                     54000020
QMNGR    EQU   90                  Q/MANAGER SVC NO.                    54300020
ENQDQLST ENQ   (IEFSQCBS,IEFQ5QCB,E,2,SYSTEM),MF=L ENQ/DQ PARMS         54370000
IEFSQCBS DC    C'SYSIEFSD'         MAJOR NAME                           54440000
IEFQ5QCB DC    C'Q5'               MINOR NAME                           54510000
QCTLPARM DSECT                                                          54600020
QCTLMSKP DS    A                   ADDR OF MASK                         54900020
QCTLNNPT DS    A                   ADDR OF NN TO BE CONVERTED           55200020
QCTLTTRP DS    A                   ADDR OF WHERT TO PUT TTR             55500020
QCTLMASK DS    F                   '80000000' FOR AN NN OF A Q          55800020
*                                  '40000000' FOR AN NN OF A            56100020
*                                  Q-ENTRY                              56400020
QCTLNN   DS    F                   NN TO BE CONVERTED                   56500000
QCTLPARL EQU   *-QCTLPARM          LENGTH OF TTRCNVRT PARMS             56700020
         SPACE                                                          56760000
         EJECT                                                          57000020
IOPARAMS DSECT                                                          57300020
OQMPARM  DS    0D                                                       57600020
OQMSIZE  DS    F                   SIZE OF GETMAIN                      57900020
OQMCPPL  DS    A                   ADDR OF CPPL                         58200020
OQMFUNC  DS    XL1                 FUNC INICATION FOR IKJEFF61          58500020
OQMLOCDQ EQU   X'80'               LOCDQ FUNCTION                       58800020
OQMREAD  EQU   X'40'               READ FUNCTION                        59100020
OQMDELE  EQU   X'20'               DELETE FUNCTION                      59400020
OQMENQ   EQU   X'10'               ENQUE FUNCTION                       59700020
OQMUCB   EQU   X'08'               UCB FUNCTION                         59800000
OQMSVC   EQU   X'04'               SVC 90 FUNCTION               A56936 59850021
OQMUCBAD DS    A                   UCB ADDR                             59900000
OQM1STSM DS    XL3                 TTR OF FIRST SMB IN JOB              60000020
         DS    0D                                                       60300020
         IEFQMNGR                                                       60600020
QMPCA    DS    F                   CORE ADDR OF DSB/SMB BUFFER          60900020
QMPEX    DS    XL3                   DISK ADDR OF DSB/SMB (TTR)         61200020
         DS    XL1                   Z OF TTRZ                          61500020
QMPALTH  EQU   *-QMNAM             LENGTH OF QMPA                       61800020
SMBBUF   DS    176XL1              SMB BUFFER                           62100020
DSBBUF   EQU   SMBBUF              DSB BUFFER                           62400020
         DS    F                    PLACE FOR PUTLINE TO PUT LL         62700020
SMBWORK  DS    CL1                  AREA TO DEBLOCK & DECOMPRESS        63000020
SMBWORK1 DS    CL165                SYSTEM MESSAGES                     63300020
QMLNGTH  EQU   *-QMNAM             LENGTH OF CORE FOR Q-MANAGER         63600020
LDQJBPTR DS    A                   ADDR OF JOBNAME LIST                 63900020
LDQNPTR  DS    A                   ADDR OF NO. OF JOB NAMES             64200020
LDQNNPTR DS    A                   ADDR OF NN OF QCR                    64500020
LDQINFOP DS    A                   ADDR OF INFO AREA                    64800020
*                                  ADDR OF INFO AREA OF JOB             65100020
*                                  BEING PROCESSED                      65400020
LDQNFNDP DS    A                   ADDR OF NO. OF JOBS FOUND            65700020
LDQQLSTP DS    A                   ADDR OF LIST OF QMPA'S (LTH'S)       66000020
*                                  ADDR OF QMPA (LTH) OF JOB            66300020
*                                  BEING PROCESSED                      66600020
LDQEIPP  DS    A                   ADDR OF THE ECB/IOB PTR              66900020
LDQNN    DS    F                   NN OF Q TO BE SEARCHED               67200020
LDQNFND  DS    F                   NO. OF JOBS FOUND                    67500020
LDQEIP   DS    A                   ECB/IOB PTR                          67800020
LDQFIXLN EQU   *-OQMPARM           LENGTH OF FIXED PART OF LIST         68100020
LDQJB    DS    D                   JOB NAME LIST                        68400020
LDQINFO  EQU   *                   INFORMATION AREA                     68700020
LDQPOS   DS    F                   POSITION OF JOB IN Q                 69000020
*                                 *ZERO IF NOT FOUND                    69300020
LDQPRI   DS    F                   PRIORITY OF JOB                      69600020
LDQSTA   DS    F                   STATUS OF JOB                        69900020
LDQJBNN  DS    F                   NN OF JOB'S ENTRY IN Q               70200020
LDQINFOL EQU   *-LDQINFO           LENGTH OF LDQINFO ENTRY              70500020
LDQQLST  EQU   *                   LIST OF QMPA'S (LTH'S)               70800020
LDQQMNAM DS    D                   JOB NAME                             71100020
LDQQMPOP DS    XL1                 FUNCTION CODE PARAMETER              71400020
LDQQMFLT DS    XL2                 1ST LOG TRK ASGND TO JOB             71700020
LDQQMTST DS    XL1                 NO. RECS. USED IN LOG. TRK           72000020
LDQQMTLN DS    XL2                 REL. ADDR OF NEXT LOG. TRK           72300020
LDQQMNOT DS    XL1                 NO. LOGICAL TRK ASGND TO JOB         72600020
LDQQMTPY DS    XL1                 JOB TYPE                             72900020
LDQQMSTA DS    XL1                 JOB STATUS                           73200020
LDQQMPRI DS    XL1                 JOB PRIORITY                         73500020
LDQQMLNK DS    XL2                 REL. ADDR OF NEXT Q ENTRY            73800020
LDQQLSTL EQU   *-LDQQLST           LENGTH OF LTH (QMPA)                 74100020
LDQVARLN EQU   *-LDQJB             LENGTH OF VARIABLE PARMS             74400020
         EJECT                                                          74700020
SMBDSECT DSECT                                                          75000020
         IEFAJCTB                                                       75300020
SMBCMTLN EQU   SMBMESAG            COMPRESSED MESS TOTAL LENGTH         75600020
SMBNBLKS EQU    SMBMESAG           NO. OF BLANKS BETWEEN FIELDS         75900020
SMBFLDLN EQU   SMBMESAG+1          COMPRESSED MESS FIELD LENGTH         76200020
SMBFIELD EQU   SMBMESAG+2          COMPRESSED MESS FIELD                76500020
SMBDCOMP EQU   X'FE'               COMPRESSED MSG INDICATOR             76800020
         EJECT                                                          77100020
*******************************************************************     77400020
*                                                                       77700020
*                                                                       78000020
*                       DATA SET BLOCK (DSB)                            78300020
*                                                                       78600020
*                                                                       78900020
DSBMAP   DSECT                                                          79200020
         DS    0F                                                       79500020
DSBDSKAD DS    XL3                 TTR OF THIS DSB                      79800020
DSBTABID DS    XL1                 TABLE ID                             80100020
DSBNXT   DS    XL3                 TTR OF NEXT DSB                      80400020
         DS    XL2                 RESERVED                             80700020
DSBPCCPY DS    XL1                 NO.OF COPIES OF SYSOUT DATASET       81000020
DSBPCPTN DS    H                   LAST TWO CHARS OF TEST PTRN.MEM.NAME 81300020
DSBLGOUT DS    XL1                 LOG OUT BITS                         81600020
         DS    XL1                 RESERVED                             81900020
DSBFLAG  DC    X'FF'               STATUS BYTE TO DISINGUISH FROM SMB   82200020
DSBWSMNT DS    XL1                WARM START INDICATOR THAT             82500020
*                                 VOLUME NOT MOUNTED                    82800020
NOTMNTED EQU   X'80'               ON MEANS FIRST VOL. NOT MNTD         83100020
*                                  AT WARM START                        83400020
DSBTIOLN DS    XL1                 LENGTH OF TIOT PORTION OF DSB        83700020
DSBSTTA  DS    XL1                 STATUS -A-                           84000020
DSBRLOC  DS    H                   REL. LOC OF POOL                     84300020
DSBDDNAM DS    CL8                 DDNAME OF SPOOLED OUTPUT DATASET     84600020
DSBJFCB  DS    XL3                 JFCB DISK ADDRESS                    84900020
DSBSTTC  DS    XL1                 STATUS -C-                           85200020
DSBSTTB  DS    XL1                 STATUS -B-                           85500020
         DS    XL1                 RESERVED                             85800020
DSBFSRT  DS    XL2                 SRT ADDRESS                          86100020
*  DISPLACEMENTS FROM THIS POINT ON MAY BE INCORRECT FOR TIOT           86400020
*  ENTRIES LONGER THAN THE MINIMUM. DSBTIOLN SHOUL BE USED              86700020
*  IN ESTABLISHING ADDRESSABILITY FOR THE REMAINDER OF THE DSB          87000020
*        LA    R6,DSBBUF           GET ADDR OF DSB                      87300020
*        USING DSBDSKAD,R6         ESTABLISH DSB ADDRESSABILITY         87600020
*        SR    R7,R7               CLEAR FOR INSERT CHAR                87900020
*        IC    R7,DSBTIOLN         LENGTH OF TIOT ENTRY IN DSB          88200020
*        LA    R7,DSBBASE(R7,R6)   ADD LENGTH OF DSB TIOT ENTRY         88500020
*        USING DSBXXX,R7           GET ADDRESSABILITY FOR DSB           88800020
*                                  AFTER TIOT ENTRY                     89100020
DSBBASE  EQU   DSBTIOLN-DSBDSKAD  LENGTH OF DSB BASE                    89400020
DSBXXX   DS    XL1                RESERVED                              89700020
DSBCLA   DS    CL1                 OUTPUT CLASS                         90000020
         DS    XL2                 RESERVED                             90300000
DSBFOR   DS    F                   FORM TYPE TO BE USED FROM SYSOUT DD  90600020
DSBPRG   DS    2F                  NAME OF USER WRITER FROM SYSOUT DD   90900020
DSBSMF   EQU   *                                                        91200020
DSBCPUID DS    F                   SID AND MDL FROM SMCA                91500020
DSBJOB   DS    2F                  JOB NAME                             91800020
DSBENTRY DS    F                   ENTRY TIME IN 1/100'S SEC            92100020
DSBDATE  DS    F                   ENTRY DATE 00YYDDDF                  92400020
DSBUSEID DS    2F                  USER ID - INIT BLANK BY R/I EACH JOB 92700020
DSBCLAS  DS    CL1                 OUTPUT CLASS                         93000020
         DS    0F                                                       93300020
DSBHOLD  DS    XL3       TTR IN INPUT DS AT POINT OF INTERRUPTION       93600020
DSBVOL   DS    XL1                VOL AT PT OF INTERRUPTION             93900020
DSBPOS   DS    XL2                POS  IN BLOCK AT PT OF INTERPT        94200020
SAVEAREA DSECT                                                          94500020
         DS    F                   RESERVED                             94800000
SAVBACK  DS    F                   ADDR OF CALLERS SAVE AREA            95100000
SAVFORW  DS    F                   ADDR OF CALLED SAVE AREA             95400000
         DS    15F                 REST OF SAVE AREA                    95700000
SAVEND   EQU   *                                                        96000020
SAVLTH   EQU   SAVEND-SAVEAREA                                          96300020
         EJECT                                                          96400000
         IEFUCBOB                                                       96500000
         END                                                            96600020
VREAD   DC    V(IEFQMRAW)         VCON FOR READ/WRITE RTN               96900020
