 TITLE ' JOB PROCESSOR  MODULE IKJEFF62  OUTPUT CP '                    00070020
*STATUS. CHANGE LEVEL 0            1/9/70                               00140000
*FUNCTION.                                                              00210000
*       1-READ DSB/SMB'S                                                00280000
*       2-ALLOCATE, OPEN, AND READ DATASET FOR EACH DSB                 00350000
*       3-DIRECT OUTPUT TO.                                             00420000
*                         -A TERMINAL                                   00490000
*                         -A DIRECT ACCESS DATASET                      00560000
*                         -ANOTHER CLASS                                00630000
*                         -OR ELIMINATE IT FROM THE SYSTEM              00700000
*       4-RESUME INTERRUPTED OUTPUT AS REQUESTED                        00770000
*       5-PASS CONTROL TO IKJEFF63 THE SUBCOMMAND HANDLER               00840000
*         AFTER PROCESSING EACH DSB IF PAUSE WAS SPECIFIED              00910000
*ENTRY POINT. IKJEFF62 -INITIAL ENTRY                                   00980000
*            OUTPROC1 -RESUME NORMAL DSB PROCESSING                     01050000
*            OUTPROC2 -TERMINATE NORMAL DSB PROCESSING                  01120000
*             OUTPROC3 -RESUME NORMAL SMB PROCESSING                    01190000
*             OUTPROC4 -TERMINATE NORMAL SMB PROCESSING                 01260000
*INPUT. ADDR OF OUTPUT COMMUNICATIONS TABLE IN REG.1                    01330000
*EXITS.                                                                 01400000
*       1-READ FUNCTION OF TRANSIENT Q-MANAGER VIA SVC 100              01470020
*       2-RE-ENQUEUE FUNCTION OF TRANSIENT Q-MANAGER VIA SVC 100        01540020
*       3-IEFQDELQ VIA SVC 100                                          01610020
*       4-IKJEFF63 THE SUBCOMMAND HANDLER                               01640000
*       6-IKJEFFGT, USES READ,NOTE & POINT (SIMULATES GET)              01670000
*       7-IKJEFF64 THE END PROCESSOR ON SERIOUS ERROR                   01700000
*       5-RETURN TO CALLER                                              01750020
*TABLES/WORK AREAS.                                                     01753000
*       1-OUTCOMTB  GENERAL COMMUNICATIONS AREA FOR ENTIRE CP.          01756000
*       2-PDL       PARAMETER DESCRIPTOR LIST.                          01759000
*       3-OQMPARM   OUTPUT Q/MNGR PARMS USED AS PARMS TO IKJEFF61.      01762000
*       4-IOPARAMS  QMPA (Q/MANAGER PARAMETER AREA).                    01765000
*       5-LOCDQ PARMS CONTAINS LTH (LOGICAL TRACK HEADER) FOR           01768000
*                   EACH JOB TO BE PROCESSED.                           01771000
*       6-SMB       SYSTEM MESSAGE BLOCK, IT IS A PRIMARY               01774000
*                   OBJECTIVE OF THIS CP TO OBTAIN THESE BLOCKS         01777000
*                   AND PRINT THE MESSAGES THEREIN.                     01780000
*       7-DSB       DATA SET BLOCK, ANOTHER PRIMARY OBJECTIVE           01783000
*                   IS TO OBTAIN THIS TYPE OF BLOCK AND PRINT           01786000
*                   THE DATA SET REFERED TO THERIN.                     01789000
*       8-IDSCORE   INPUT DATASET CORE CONTAINS DCB,JFCB AND            01792000
*                   OTHER INFORMATION RELATED TO THE SYSOUT D.S.        01795000
*       9-DAPB08    USED TO ALLOCATE SYSOUT DATASET.                    01798000
*      10-DAPB18    USED TO UNALLOCATE SYSOUT DATASET. OCCUPIES         01801000
*                   SAME CORE AS DAPB08.                                01804000
*      11-GETAB     USED BY IKJEFFGT TO READ SYSOUT DATASET.            01807000
*      12-TERMPARM  USED WITH PUTLINE.                                  01810000
IKJEFF62 CSECT                                                          01820020
R0       EQU   0                   REGISTER  0                          01890020
*                                  LENGTH OF COMPRESSED MSG             01960020
*                                     IN INTERRUPTED BLOCK              02030020
R1       EQU   1                   REGISTER  1                          02100020
*                                  CLASPDE, LENGTH OF EXPANDED M        02170020
R2       EQU   2                   REGISTER  2                          02240020
*                                  ADDR OF MSG PART OF SMB,             02310020
*                                  UCB ADDR                             02380020
R3       EQU   3                   REGISTER  3                          02450020
*                                  OUTCOMTB                             02520020
R4       EQU   4                   REGISTER  4                          02590020
R5       EQU   5                   REGISTER  5                          02660020
*                                  SMBWORK, JFCB                        02730020
R6       EQU   6                   REGISTER  6                          02800020
*                                  LDQINFO, SMBBUF, DSBBUF              02870020
R7       EQU   7                   REGISTER  7                          02940020
*                                  LDQQLST, ADDR OF INPUT DCB           03010020
R8       EQU   8                   REGISTER  8                          03080020
*                                  DAPB08, DAPB18,                      03150020
*                                  LENGTH OF SMB FIELD                  03220020
R9       EQU   9                   REGISTER  9                          03290020
*                                  PDL                                  03360020
R10      EQU   10                  REGISTER  10                         03430020
*                                  Q/M PARMS                            03500020
R11      EQU   11                  REGISTER  11                         03570020
*                                  INPUT DCB ADDR                       03640020
R12      EQU   12                  REGISTER  12                         03710020
*                                  BASE                                 03780020
R13      EQU   13                  REGISTER  13                         03850020
R14      EQU   14                  REGISTER  14                         03920020
R15      EQU   15                  REGISTER  15                         03990020
         SAVE  (14,12),,*          SAVE CALLERS REGISTERS               04060020
         BALR  R12,0               ESTABLISH ADDRESSABILITY             04130020
         USING *,R12               FOR IKJEFF62                         04200020
         LR    R3,R1               SAVE PARM REGISTER                   04270020
         USING OUTCOMTB,R3         ESTAB. OUTCOMTB ADDRESSABILITY       04340020
         GETMAIN R,LV=SAVLTH,SP=SP1       GET SAVE AREA                 04410020
         USING SAVEAREA,R1         ADDRESSABILITY FOR NEW AREA          04480020
         ST    R13,SAVBACK         STORE BACK PTR IN NEW AREA           04550020
         USING SAVEAREA,R13        ADDRESSABILITY FOR OLD AREA          04620020
         ST    R1,SAVFORW          STORE FORWARD PTR IN OLD AREA        04690020
         LR    R13,R1              ESTABLISH NEW SAVE AREA              04760020
*                                  ADDRESSABILITY                       04830020
         L     R9,OUTPDL           GET ADDR OF PDL                      04970020
         USING IKJPARMD,R9         ESTABLISH PDL ADDRESSABILITY         05040020
         EJECT                                                          05740020
* READ DSB/SMB                                                          05810020
READSMB  EQU   *                                                        05880020
         L     R10,OUTQMPAR        GET ADDR OF Q-MANAGER PARMS          05950020
         USING IOPARAMS,R10        ESTAB. Q-MNGR PARM ADDRABILIY        06020020
         XC    QMNAM(QMPALTH),QMNAM ZERO QMPA                           06090020
         LA    R1,QMPCA            GET ADDR OF EXTERNAL PARM LST        06160020
         ST    R1,QMPCL            STORE IN QMPA                        06230020
         LA    R1,SMBBUF           GET ADDR OF BUFFER                   06300020
         ST    R1,QMPCA            PUT IN EXTERNAL PARM. LIST           06370020
WASJBFND EQU   *                                                        06440020
         L     R6,LDQINFOP         GET ADDRESSABILITY FOR INFO          06510020
         USING LDQINFO,R6          AREA OF JOB BEING PROCESSED          06580020
         CLC   LDQPOS,ZERO         WAS JOB ASSOC. WITH THIS             06650020
*                                  ENTRY FOUND                          06720020
         BNE   MOVELTH             YES, SEE IF OUTPUT TO BE ELIMIN.     06790000
*        *   ISSUE MSG 103 JOB NOT FND                                  06860000
         MVI   OUTMSGID,M7         NO, ISSUE MSG IKJEF103               06930000
         BAL   R9,MSGOUT           GO LINK TO IKJEFF67                  07000000
         CLC   PRINT,TWO           WAS NOPRINT SPECIFIED                07010020
         BE    ALLDONE             YES, SEE IF ALL JOBS DONE            07020020
JBNFOUND EQU   X'F0'                                                    07030020
         MVI   OUTRESUM,JBNFOUND   NO, SET BIT TO RETURN CODE 12 TO TMP 07040020
         B     ALLDONE             ARE ALL JOBS DONE                    07070000
MOVELTH  EQU   *                                                        07140000
         L     R7,LDQQLSTP         GET ADDRESSABILITY FOR LTH           07210000
*                                  (LOGICAL TRACK HEADER)               07280000
         USING LDQQLST,R7          OF JOB BEING PROCESSED               07350000
         MVC   QMNAM(LDQQLSTL),LDQQLST MOVE LTH FOUND BY LOCDQ          07420020
*                                  INTO QMPA USED TO READ ETC.          07490020
*  WAS NOPRINT CLASSNAME SPECIFIED                                      07560020
         LA    R1,CLASNAME         GET ADDR OF NOPRINT CLASSNAME        07630020
         USING CLASPDE,R1          GET PDE ADDRESSABILITY               07700020
         TM    CLASFLGS,CLAS       WAS NOPRINT CLASNAME SPECIFIED       07770020
         BO    REENQ               YES, GO RE-ENQUE JOB                 07840020
         LA    R6,SMBBUF           GET ADDR OF SMB                      07910020
         USING SMBDSKAD,R6         ESTABLISH SMB ADDRESSABILITY         07980020
         XC    SMBNEXT,SMBNEXT     ZERO PTR TO NEXT SMB SO              08050020
*                                  QMPEX WILL BE ZERO FOR FIRST         08120020
*                                  CALL TO Q/MNGR                       08190020
READQ    EQU   *                                                        08260020
         MVC   QMPEX,SMBNEXT       PASS TTR OF NEXT DSB/SMB             08330020
*                                  ZERO IF FIRST READ                   08400020
         MVI   OQMFUNC,OQMREAD     INDICATE READ FUNCTION REQ.          08470020
         LA    R1,OQMCPPL          PASS ADDR OF SVC 100 PARMS           08540020
         LA    R0,THREE            PASS OUTPUT INDICATOR                08570020
         SVC   FIB                 ISSUE SVC 100 TO GET PROTECT         08610020
*                                  KEY OF ZERO FOR Q-MNGR READ          08680020
*                                  **********                           08750020
         LTR   R15,R15             WAS Q/MANAGER SUCCESSFUL             08820020
         BZ    WASDSB              YES, SKIP MSG                        08890020
         MVI   OUTMSGID,M5         NO, ISSUE MSG IKJEF106               08960020
         LA    R9,RESETJP          WHERE TO GO AFTER MSG                09030020
         B     MSGOUTER            GO LINK TO IKJEFF67                  09130020
WASDSB   EQU   *                                                        09240020
         CLI   SMBMSGLN,DSB        WAS BLOCK READ A DSB                 09310020
DSB      EQU   X'FF'               DSB INDICATOR                        09380020
         BE    DSBPROC             YES, GO TO DSB PROCESSING            09450000
         EJECT                                                          09520000
OUTPROC3 EQU   *                                                        09590000
         CLC   PRINT,TWO           IS OUTPUT TO BE ELIMINATED           09660000
         BE    CKLAST              YES, SEE IF MORE SMB'S               09730000
         LA    R6,SMBBUF           GET ADDR OF SMB                      09760000
         LA    R2,SMBMESAG         ESTABLISH ADDRESSABILITY FOR         09800020
         USING SMBMESAG,R2         PART OF SMB TO GET MSG FROM          09870020
         LA    R6,SMBMSGLN         SET UP BASE SAME AS                  09940020
         USING SMBMSGLN,R6         IN MSG PROCESSING LOOP               10010020
ISLTH0   EQU   *                   IS LENGTH ZERO                       10080020
         CLI   SMBMSGLN,EMPTY      WAS BLOCK READ EMPTY                 10150020
EMPTY    EQU   0                   ZERO LENGTH IN SMB/DSB               10220020
         BE    CKLAST              YES, SEE IF TERE IS ANOTHER          10290020
*                                  DSB/SMB                              10360020
         LA    R5,SMBWORK          ESTABLISH ADDRESSABILITY FOR         10430020
         USING SMBWORK,R5          PLACE TO BUILD LOGICAL MSG.          10500020
         MVI   SMBWORK,BLNK        BLANK SMB                            10570020
         MVC   SMBWORK1,SMBWORK    WORK AREA                            10640020
         CLI   SMBMSGLN,SMBDCOMP   SHOULD MESSAGE BE DECOMPRESSED       10710020
         BNE   DEBLKMES            NO, PROCESS NORMAL MESSAGE           10780020
* DECOMPRESS SMB                                                        10850020
         SR    R0,R0               ZERO LENGTH OF COMPRESSED MSG        10920020
         SR    R1,R1               ZERO LENGTH OF EXPANDED MESS         10990020
         IC    R0,SMBCMTLN         GET TOTAL LTH OF COMPRESSED M        11060020
         SH    R0,ONE              UPDATE TOTAL LENGTH LEFT             11130020
         SR    R8,R8               ZERO FIELD LENGTH                    11200020
MOVEFLD  EQU   *                                                        11270020
         IC    R8,SMBFLDLN         GET FIELD LENGTH                     11340020
         BCTR  R8,0                 DECREMENT LTH FOR MOVE              11410020
MVFIELD  MVC   SMBWORK,SMBFIELD    DUMMY                                11480020
         EX    R8,MVFIELD          MOVE FIELD                           11550020
         AH    R8,ONE               ADD ONE BACK                        11620020
         AR    R1,R8               ADJUST LENGTH OF EXPANDED            11690020
*                                  MESSAGE IN SMBWORK.                  11760020
         AR    R5,R8               ADJUST ADDR OF WHERE TO MOVE         11830020
*                                  NEXT FIELD IN SMBWORK.               11900020
         AH    R8,TWO              ADD LENGTH OF SMBNBLKS               11970020
*                                  (SMBCMTLN IF FIRST FIELD)            12040020
*                                  PLUS LENGTH OF SMBFLDLN TO           12110020
*                                  LENGTH OF FIELD.                     12180020
         AR    R2,R8               ADD THAT TO COMPRESSED               12250020
*                                  MSG BASE AND                         12320020
         SR    R0,R8               SUBTRACT IT FROM LENGTH OF           12390020
*                                  COMPRESSED MESSAGE LEFT.             12460020
         LR    R6,R2               SAVE ADDR OF BYTE AFTER              12530020
*                                  COMPRESSED MSG                       12600020
         BZ    GOPUT               IF LENGTH LEFT IS 0, BRANCH          12670020
         IC    R8,SMBNBLKS         GET NO. OF BLANKS                    12740020
         AR    R1,R8               ADD NO. OF BLANKS TO EXPANDED        12810020
*                                  LENGTH OF MESSAGE IN SMBWORK         12880020
         AR    R5,R8               ADD NO. OF BLANKS TO ADDR OF         12950020
*                                  WHERE TO MOVE NEXT FIELD IN          13020020
*                                  SMBWORK                              13090020
         B     MOVEFLD             GO MOVE NEXT FIELD                   13160020
DEBLKMES EQU   *                                                        13230020
         SR    R1,R1               CLEAR FOR INSERT CHAR                13300020
         IC    R1,SMBMSGLN         GET LOGICAL MESSAGE LENGTH           13370020
MVLOGMSG MVC   SMBWORK,SMBMESAG    DUMMY                                13440020
         EX    R1,MVLOGMSG         MOVE LOGICAL MSG (MOVES ONE          13510020
*                                  EXTRA BYTE)                          13580020
         LA    R6,SMBMESAG(R1)     GET ADDR OF NEXT LOGICAL MSG         13650020
*                                  LENGTH FIELD                         13720020
GOPUT    EQU   *                                                        13790020
         DROP  R2                                                       13860020
         ST    R1,OUTRECL          PASS LENGTH OF LOGICAL MSG           13930020
         DROP  R5                                                       14000020
         LA    R5,SMBWORK          GET ADDR OF LOGICAL MSG              14070020
         ST    R5,OUTRECA          PASS ADDR OF LOGICAL MSG             14140020
         MVI   OUTRECFM,FIXSW      INDICATE SMB TO PUTLINE              14210020
         BAL   R5,PUT              GO TO PUT MSG                        14280020
         LA    R2,SMBMESAG         GET ADDR OF NEXT LOGICAL MSG         14350020
         B     ISLTH0              SEE IF NEXT LOGICAL MESSAGE          14420020
*                                  LENGTH IS ZERO.                      14490020
         EJECT                                                          14560020
REENQ    EQU   *                                                        14630020
         XC    QMPCL,QMPCL         ZERO PTR TO EXTERNAL                 14700020
*                                  PARAMETER LIST SO ENQ WILL           14770020
*                                  BE DONE WITHOUT A WRITE.             14840020
* CONVERT CLASSNAME TO NN                                               14910020
*CLASSNAME A-I TO NN  3-11                                              14980020
*          J-R       12-20                                              15050020
*          S-Z       21-28                                              15120020
*          0-9       29-38                                              15190020
*                                                                       15260020
         LA    R1,CLASNAME         GET ADDR OF NOPRINT CLASS PDE        15330020
         USING CLASPDE,R1          ESTAB. CLASSNAME PDE ADDRABLT        15400020
         L     R1,CLASNMAD         GET CLASSNAME ADDR FROM PDE          15470020
         LA    R0,TWONINE          29 MUST BE ADDED TO BOTTOM           15540020
*                                  FOUR BITS IF CLASS 0-9               15610020
TWONINE  EQU   29                  TWENTY NINE                          15680020
         TM    0(R1),ZEROTO9       IS CLASS 0-9 OR A-I                  15750020
ZEROTO9  EQU   X'30'               THESE TWO BITS WILL BE ON FOR        15820020
*                                  0-9 AND OFF FOR A-I                  15890020
         BO    MAKENN              BRANCH IF 0-9                        15960020
         LH    R0,TWO              2 MUST BE ADDED TO BOTTOM            16030020
*                                  FOUR BITS IF CLASS A-I               16100020
         BZ    MAKENN              BRANCH IF A-I                        16170020
         LA    R0,ELEVEN           ELEVEN MUST BE ADDED TO              16240020
*                                  BOTTOM FOUR BITS IF CLASS J-R        16310020
ELEVEN   EQU   11                  ELEVEN                               16380020
         TM    0(R1),JTOR          IS CLASS J-R OR S-Z                  16450020
JTOR     EQU   X'10'               THIS BIT WILL BE ON FOR J-R          16520020
*                                  AND OFF FOR S-Z                      16590020
         BO    MAKENN              BRANCH IF J-R                        16660020
         LA    R0,NINETEEN         IF S-Z 19 MUST BE ADDED TO           16730020
*                                  BOTTOM FOUR BITS                     16800020
NINETEEN EQU   19                  NINETEEN                             16870020
MAKENN   EQU   *                                                        16940020
         SR    R15,R15             CLEAR FOR INSERT CHAR                17010020
         IC    R15,0(R1)           GET CLASSNAME                        17080020
         N     R15,SAVLOW4         TURN OFF ALL BUT LOW 4 BITS          17150020
         AR    R15,R0              ADD VALUE TO GET NN                  17220020
         STC   R15,LDQQMTPY        STORE NN IN LOCDQ PARM LIST          17290020
         MVI   OQMFUNC,OQMENQ      INDICATE ENQ TO IKJEFF61             17360020
         LA    R1,OQMCPPL          PASS ADDR OF FIB SVC PARMS           17430020
         LA    R0,THREE            PASS OUTPUT INDICATOR                17460020
         SVC   FIB                 ISSUE FIB SVC TO GET PROTECT         17500020
*                                  KEY OF ZERO FOR Q/MNGR ENQ.          17570020
         LTR   R15,R15             WAS ENQ SUCCESSFUL                   17640020
         BZ    ALLDONE             YES,SEE IF ALL JOBS ARE DONE         17710020
         MVI   OUTMSGID,M5         NO, ISSUE MSG IKJEF106               17780020
         LA    R9,LEAVE            WHERE TO GO AFTER MSG                17850020
         B     MSGOUTER            GO LINK TO IKJEFF67                  17950020
         EJECT                                                          18060020
DSBPROC  EQU   *                                                        18130020
         GETMAIN R,LV=IDSCOREL,SP=SP1     GET CORE FOR INPUT DATASET    18200020
         LR    R11,R1              SAVE ADDR OF GOTTEN CORE             18270020
         ST    R11,OUTIDSP         PASS TO OTHER MODULES                18340020
         USING IDSCORE,R11         GET DCB & JFCB ADDRESSABILITY        18410020
         XC    IDSDAIRP,IDSDAIRP   ZERO PTR TO DAIR PARMS               18440020
         MVI   IDSSW,EMPTY          INITIALIZE IDSSW                    18480020
         LA    R6,DSBBUF           GET ADDR OF DSB                      18550020
         USING DSBMAP,R6           ESTABLISH DSB ADDRESSABILITY         18620020
         SR    R7,R7               CLEAR FOR INSERT CHAR                18690020
         IC    R7,DSBTIOLN         LENGTH OF TIOT ENTRY IN DSB          18760020
         LA    R1,TIOTLNTH         GET LENGTH OF ONE VOL ENTRY          18768020
TIOTLNTH EQU   20                  LENGTH OF TIOT PART OF DSB           18776020
         CR    R7,R1               IS THIS A ONE VOL DATASET            18784020
         B     DSBADDR             YES, SKIP ERROR MSG                  18792000
         MVI   OUTMSGID,M15        MSG IKJEF118 ONLY ONE VOL.           18800020
         LA    R9,FREEDCB          WHERE TO GO AFTER MESSAGE            18805000
         B     MSGOUTER            PRINT MESSAGE AND QUIT               18810000
DSBADDR  EQU   *                   CONTINUE DSB ADDRESSABILITY          18816020
         LA    R7,DSBBASE(R7,R6)   ADD LENGTH OF DSB TIOT ENTRY         18830020
         USING DSBXXX,R7           GET ADDRESSABILITY FOR DSB           18900020
*                                  AFTER TIOT ENTRY.                    18970020
         L     R1,DSBHOLD           GET RESUME POINT (TTR)              19040020
         LTR   R1,R1                WAS THIS DATASET INTERRUPTED        19110020
         BNZ   RESMSG              YES, ISSUE MSG                       19120020
         MVC   DSBHOLD(FIRSTPGL),FIRSTPAG SET TTR TO FIRST LINE         19130020
         B     READJ               SKIP RESUME PROCESSING               19140020
*        *     IF DSB IS NOT FIRST BLOCK OF JOB, MSG 102 WAS            19150020
*              IN PREVIOUS SMB.                                         19160020
RESMSG   CLC   DSBDSKAD,OQM1STSM   WAS MSG ALREADY ISSUED BY SMB        19170020
         BNE   RESPR               YES, SKIP MSG                        19180020
*        *     ISSUE MESSAGE OUTPUT RESUMED                             19250020
         L     R1,OUTTERM          GET ADDR OF PUTLINE CORE             19257020
         LTR   R1,R1               IS OUTPUT GOING TO TERMINAL          19264020
         BZ    DSMSG               NO, DO NOT GO TO IKJEFF67            19271020
         MVI   OUTMSGID,M12        ISSUE MSG 102 OUTPUT RESUMED         19278020
         LA    R9,RESPR            WHERE TO GO AFTER MSG                19285000
         B     MSGOUT              GO LINK TO IKJEFF67                  19292020
FIXNEXT  EQU   *                                                        19293000
         OI    IDSSW,NEXT          SET SW TO AVOID OPENING DATA SET     19294000
         B     READJ               IF NOPRINT WAS SPECIFIED             19295000
DSMSG    EQU   *                                                        19299020
         OI    IDSSW,PUTDSMSG      INDICATE MSG SHOULD BE PUT           19306020
RESPR    EQU   *                                                        19313020
         CLC   HERE,TWO             WAS HERE,BEGIN OR NEXT REQ.         19320020
         BL    FIXNEXT             NEXT, BRANCH                         19390000
         BH    READJ                BEGIN, READ DATASET                 19460020
         OI    IDSSW,RESUME         INDICATE RESUME TTR BE USED         19530020
* READ INPUT JFCB VIA Q-MANAGER                                         19600020
READJ    EQU   *                                                        19670020
*                                  AFTER TIOT ENTRY                     19740020
         MVC   QMPEX,DSBJFCB       GET DISK ADDR OF JFCB                19810020
         LA    R5,IDSJFCB           GET ADDR OF JFCB                    19880020
         USING INFMJFCB,R5          GET JFCB ADDRESSABILITY             19950020
         ST    R5,QMPCA             PASS WHERE TO PUT JFCB              20020020
         LA    R0,THREE           PASS OUTPUT INDICATOR                 20090020
THREE    EQU   3                  3 INDICATES OUTPUT CALLED             20160020
         LA    R1,OQMCPPL          PASS ADDR OF SVC 100 PARMS           20230020
         SVC   FIB                 ISSUE SVC 100 TO GET PROTECT         20300020
*                                  KEY OF ZERO FOR Q-MNGR READ          20370020
*                                  *****************                    20440020
         ST R6,QMPCA              FIX WHERE TO READ SMB                 20510020
         LTR   R15,R15             IS RETURN CODE ZERO                  20580020
         BZ    ZEROBLK             YES, SKIP MSG                        20650020
         MVI   OUTMSGID,M5         NO, ISSUE MSG IKJEF106               20720020
         LA    R9,FREEDCB          WHERE TO GO AFTER MSG                20790020
         B     MSGOUTER            GO LINK TO IKJEFF67                  20890020
ZEROBLK  EQU   *                                                        21000020
         XC    JFCBLKSI,JFCBLKSI   ZERO SO THAT IF DCB IS FILLED        21070020
         XC    JFCBUFL,JFCBUFL     IN, WE KNOW IT CAME FROM DSCB        21140020
         GETMAIN R,LV=DA08LTH,SP=SP1      GET CORE FOR DAIR PARAMS      21210020
         LR    R8,R1               SAVE ADDR OF GOTTEN CORE             21280020
         ST    R8,IDSDAIRP         SAVE ADDR OF DAIR PARMS              21350000
         USING DAPL,R8             GET DAIR PARM ADDRESSABILITY         21420000
         XC    DAPL(DA08LTH),DAPL  ZERO GOTTEN CORE                     21490000
         L     R1,OUTPARS          GET ADDR OF INPUT PARSE PARMS        21560000
         MVC   DAPL(DAPLSTLN),0(R1) GET STANDARD PART OF PARMS          21630000
*                                  FROM PARSE PARAMETER LIST            21700020
         L     R1,OQMCPPL          GET ADDR OF CPPL                     21770020
         USING CPPL,R1             ESTABLISH CPPL ADDRESSABILITY        21840020
         MVC   DAPLPSCB,CPPLPSCB   MOVE ADDR OF PSCB FROM CPPL          21910000
         LA    R0,DA08STAR         GET ADDR OF DAIR PARM BLOCK          21980020
         ST    R0,DAPLDAPB         STORE IN DAIR PARM LIST              22020000
         USING DAPB08,R8                                                22060000
         MVC   DA08CD,DA08         MOVE FUNCTION CODE INTO PARMS        22120020
* DETERMINE LENGTH OF DSNAME                                            22190020
         LA    R1,JFCBELNM         GET ADDR OF BYTE AFTER DSNAME        22260020
FINDLGTH EQU   *                                                        22330020
         BCTR  R1,0                SUBTRACT FROM PTR TO END DSN         22400020
*                                  IN JFCB                              22470020
         CLI   0(R1),BLNK          IS THIS LAST CHAR OF DSNAME          22540020
BLNK     EQU   C' '                                                     22610020
         BE    FINDLGTH            NO,SEE IF CHAR TO LEFT IS LST        22680020
         LA    R0,IDSDSNLN         GET ADDR OF  DSNAME LENGTH           22750020
         ST    R0,DA08PDSN         PUT IN DAIR DSNAME PTR               22820020
         SR    R1,R5               SUBTRACT ADDR OF DSNAME FROM         22890020
*                                  ADDR OF LAST CHAR. IN DSNAME         22960020
         AH    R1,ONE              ADD ONE TO DIFFERENCE                23030020
         STH   R1,IDSDSNLN         STORE DSNAME LENGTH IN WORD          23100020
*                                  BEFORE DSNAME IN JFCB                23170020
         MVC   DA08DDN,BLANKS      BLANK DDNAME IN DAIR BLOCK           23240020
         SPACE 2                                                        23243000
*                                  IN THIS SECTION, A CHECK IS          23246000
*                                  MADE TO SEE IF THE SYSOUT            23249000
*                                  VOLUME IS MOUNTED.  IN CASE          23252000
*                                  THERE ARE MULTIPLE VOLUMES,          23255000
*                                  ONLY THE 1ST VOLUME WILL BE          23258000
*                                  PRINTED. THE 1ST VOLUME, TAKEN       23261000
*                                  FROM THE JFCB, IS COMPARED TO        23264000
*                                  THE VOLUME IN EACH UCB SPECIFIED     23267000
*                                  IN THE TIOT, BEGINNING WITH THE      23270000
*                                  LAST UCB.  THE ORDER OF UCB'S        23273000
*                                  AS LISTED IN THE TIOT IS UPRE-       23276000
*                                  DICTABLE FOR MULTIPLE VOLUMES        23279000
*                                  BECAUSE THE EOV ROUTINES PLACE       23282000
*                                  THE CURRENT VOLUME 1ST IN THE        23285000
*                                  LIST                                 23288000
         SPACE                                                          23291000
         SR    R1,R1               ZERO INDEX REGISTER                  23294000
         IC    R1,DSBTIOLN         LENGTH OF TIOT ENTRY IN DSB          23297000
         SH    R1,TWENTY           SUB 20 LEAVING INDEX TO LAST         23300000
*                                  UCB ENTRY IN TIOT                    23303000
GETUCB   LH    R2,DSBFSRT(R1)      GET UCB ADDR FOR INPUT DS            23333000
         SLL   R2,SIXTEEN          SHIFT OUT POSSIBLE                   23380020
         SRL   R2,SIXTEEN          HIGH ORDER BITS                      23450020
SIXTEEN  EQU   16                                                       23520020
         USING UCBOB,R2            ESTABLISH UCB ADDRESSABILITY         23590020
         ST    R2,IDSUCBP          SAVE ADDR OF UCB FOR SAVE            23660020
*                                  SUBCOMMAND                           23730020
         ST    R2,OQMUCBAD         STORE IN IOPARAMS FOR IKJEFF61       23760000
         CLC   SRTEVOLI,JFCBVOLS   IS SYSOUT D.S. VOL. MOUNTED          23800020
         BE    GOTODAIR                   YES, SKIP MSG                 23870020
         SH    R1,FOUR             SUB 4 FROM INDEX REGISTER            23890000
         BNM   GETUCB              BRANCH IF 0 OR GREATER               23910000
         MVI   OUTMSGID,M14        ALL UCB'S SEARCHED, ISSUE VOL-       23940000
*                                  UME-NOT-MOUNTED MESSAGE              23970000
         LA    R9,FREEDAIR                WHERE TO GO AFTER MSG         24010020
         B     MSGOUTER                   GO LINK TO IKJEFF67           24110020
         SPACE 2                                                        24160000
GOTODAIR EQU   *                                                        24220020
         MVC   DA08UNIT,BLANKS     BLANK UNIT NAME SO ITS PADDED        24290020
         MVC   DA08UNIT(L'UCBNAME),UCBNAME GET SHORT UCBNAME            24360020
         MVC   DA08SER,BLANKS      BLANK VOL. SET. SO ITS PADDED        24430020
         MVC   DA08SER(L'SRTEVOLI),JFCBVOLS GET SHORT SER. NO.          24500020
         DROP  R5                                                       24570020
         MVC   DA08MNM,BLANKS      BLANK MEMBER NAME IN DAIR BLK        24640020
         MVC   DA08PSWD,BLANKS     BLANK PASSWORD IN DAIR BLOCK         24710020
         CLI   DSBTIOLN,TIOTLNTH   IS TIOT LENGTH 20                    24720000
         BE    CNTALLOC            YES, CONTINUE ALLOCATION             24730000
         CLC   PRINT,TWO           WAS NOPRINT SPECIFIED                24733000
         BE    CNTALLOC            YES, CONTINUE ALLOCATION             24736000
         MVI   OUTMSGID,M15        NO, ISSUE MESSAGE & TERMINATE        24743000
         LA    R9,FREEDAIR         WHERE TO GO AFTER MESSAGE            24750000
         B     MSGOUTER            PRINT MSG AND QUIT                   24760000
CNTALLOC  EQU  *                                                        24770000
         LR    R1,R8               PASS ADDR OF DAIR PARM BLOCK         24780020
         LINK  EP=IKJDAIR          GO TO DAIR                           24850020
*                                  **********                           24920020
         LTR   R15,R15             WAS ALLOCATION SUCCESSFUL            24990020
         BZ    WASNOPRN                   YES, SKIP MSG                 25060020
         CLC   DA08DARC,RC6708     IS RC 6708 (DS NOT ON VOLUME)        25060600
         BNE   CHKRC16             NO, BRANCH                           25061200
         CLC   PRINT,TWO           WAS NOPRINT SPECIFIED                25061800
         BNE   PRMSG130            NO, BRANCH                           25062400
         B     FREEDAIR            CONTINUE PROCESSING                  25063000
PRMSG130 MVI   OUTMSGID,M130       MSG ID, 'DS NOT ON VOLUME'           25063600
         LA    R9,FREEDAIR         WHERE TO GO AFTER MESSAGE            25064200
         B     MSGOUT              GET TO MESSAGE ROUTINE               25064800
CHKRC16  EQU   *                                                        25065400
         CLC   PRINT,TWO           WAS NOPRINT SPECIFIED                25066000
         BNE   CKDAIRCD            NO, ISSUE MESSAGE                    25072000
         CH    R15,SIXTN           IS RETURN CODE 16 (TOO MANY          25078000
         BNE   FREEDAIR            DATA SETS)                           25084000
CKDAIRCD EQU   *                                                        25090000
         MVI   OUTMSGID,M4                NO, ISSUE MSG IKJEF110        25130020
         LA    R9,FREEDAIR                WHERE TO GO AFTER MSG         25200020
         B     MSGOUTER                   GO LINK TO IKJEFF67           25300020
WASNOPRN EQU   *                                                        25410020
         CLC   PRINT,TWO           WAS NOPRINT SPECIFIED                25480020
         BE    UNALLOC             YES, GO TO DELETE DATASET &          25550020
*                                  DECREMENT USER COUNT                 25620020
         TM    IDSSW,NEXT          WAS NEXT SPECIFIED                   25630000
         BO    UNALLOC             YES, GO TO DELETE DATA SET &         25640000
*                                  DECREMENT USER COUNT                 25650000
* OPEN INPUT                                                            25690020
         MVC   IDSDCB(IDSDCBLN),DCBIN INITIALIZE DCB,OPEN & CLOS        25760020
         O     R11,IDSOPEN         OR OPTION BYTE INTO DCB ADDR         25830020
         ST    R11,IDSOPEN         STORE DCB ADDR IN OPEN LIST          25900020
         LA    R11,0(R11)          ZERO HIGH ORDER BYTE OF DCBAD        25970020
         O     R11,IDSCLOSE        OR OPTION BYTE INTO DCB ADDR         26040020
         ST    R11,IDSCLOSE        STORE DCB ADDR IN CLOSE LIST         26110020
         LR    R7,R11              GET DCB ADDR                         26180020
         USING IHADCB,R7           GET DCB ADDRESSABILITY               26250020
         MVC   DCBDDNAM,DA08DDN    PUT DDNAME FROM DAIR IN DCB DCB      26320020
*                                                                       26390020
         LA    R1,IDSJFCBP         PUT ADDR OF FIRST ELEM IN            26460020
         ST    R1,DCBEXLST         EXIT LIST IN DCB                     26530020
         O     R5,IDSJFCBP         OR JFCB INDICATOR W/ JFCB PTR        26600020
         ST    R5,IDSJFCBP         STORE JFCB ADDR IN EXIT LIST         26670020
         LA    R1,OPENEXIT         GET ADDR OF INPUT OPEN EXIT          26740020
         O     R1,IDSOPNEX         OR LAST ENTRY & OPEN FLAG            26810020
         ST    R1,IDSOPNEX         STORE OPEN EXIT ADDR IN EXLST        26880020
         OPEN  (IDSDCB,INPUT),TYPE=J,MF=(E,IDSOPEN)                     26950020
         TM    IDSSW,UNOPENED      WAS SYSOUT DATASET UNOPENED          26970020
         BO    EODPROC             YES, SKIP EMPTY DATA SET             26990000
         TM    DCBOFLGS,OPNOK      WAS OPEN OK                          27020000
OPNOK    EQU   X'10'               DCBOFLGS OPEN OK                     27050000
         BO    CKRECFM            YES, SKIP MSG                         27100020
         MVI   OUTMSGID,M13        ISSUE MSG                            27160020
         LA    R9,FREEDAIR         WHERE TO GO AFTER MSG                27230020
         B     MSGOUTER            GO LINK TO IKJEFF67                  27240020
* ARE INPUT DATASET ATTRIBUTES SAME AS OUTPUT DATASET.                  27250020
CKRECFM  L     R4,OUTDCB           GET ADDR OF OUTPUT DCB               27260020
         LTR   R4,R4               IS OUTPUT ON TERMINAL                27270020
         BZ    OUTPROC1            YES, SKIP ERROR MSG                  27280020
         CLC   DCBRECFM,DCBRECFM-IHADCB(R4) IS RECFM THE SAME           27290020
         BNE   UNLIKE              NO, ISSUE MSG                        27300020
         CLC   DCBLRECL,DCBLRECL-IHADCB(R4) IS LRECL THE SAME           27310020
         BNE   UNLIKE              NO, ISSUE MSG                        27320020
         CLC   DCBBLKSI,DCBBLKSI-IHADCB(R4) IS BLKSIZE THE SAME         27330020
         BE    OUTPROC1            YES, SKIP ERROR MSG                  27340020
UNLIKE   EQU   *                                                        27350020
         MVI   OUTMSGID,M6         MSG 113 UNLIKE ATTRIBUTES            27360020
         BAL   R9,MSGOUT           GO LINK TO IKJEFF67                  27370020
         EJECT                                                          27440020
OUTPROC1 EQU   *                                                        27510020
         SR    R7,R7               CLEAR FOR INSERT CHAR                27517020
         IC    R7,DSBTIOLN         LENGTH OF TIOT ENTRY IN DSB          27524020
         LA    R7,DSBBASE(R7,R6)   ADD LENGTH OF DSB TIOT ENTRY         27531020
         USING DSBXXX,R7           GET ADDRESSABILITY FOR DSB           27538020
         TM    IDSSW,PUTDSMSG      SHOULD RESUME MSG BE PUT             27545020
         BZ    INITBK10            NO, SKIP MSG                         27552020
         LA    R1,MSG102LN         GET MSG LENGTH                       27559020
         ST    R1,OUTRECL          PASS TO PUT ROUTINE                  27566020
         LA    R1,MSG102           GET ADDR OF MSG                      27573020
         ST    R1,OUTRECA          PASS TO PUT ROUTINE                  27580020
         MVI   OUTRECFM,FIXSW      PASS RECFM OF MSG TO PUT             27587020
         BAL   R5,PUT              GO PUT                               27594020
         NI    IDSSW,X'FF'-PUTDSMSG TURN OFF RESUME MSG INDICATOR       27601000
INITBK10 EQU   *                                                        27608020
         XC    BAK10CNT,BAK10CNT   ZERO BACK SPACE COUNT                27615020
         MVC   BAK10NEW,DSBHOLD    INITIALIZE NEW ENTRY                 27622020
         MVC   BAK10APX,DSBHOLD    INITIALIZE APROXIMATION              27629020
         L     R1,BUFFAD           GET ADDR OF I/O WORKAREA             27650020
         USING GETAB,R1            GET ADDRESSABILITY FOR SAME          27720020
         XC    RECSTART,RECSTART   ZERO RECSTART & LTHLEFT              27760000
         XC    LTHLEFT,LTHLEFT     SO POINT WILL WORK.                  27800000
         LH    R5,DSBPOS             GET POSITION OF RECORD             27860020
*                                  IN BLOCK.                            27930020
GETLOGRC EQU   *                                                        28000020
         LR    R1,R3               PASS ADDR OF OUTCOMTB                28070020
         L     R15,GETLOG          GET ADDR OF GET RTN                  28140020
         BALR  R14,R15             GO TO GET RTN                        28210020
*                                  *******************                  28280020
         CH    R15,FOUR            LOOK AT RETURN CODE                  28350020
         BE    EODEXIT             BRANCH IF EOD REACHED                28420020
         BH    INERRTN             BRANCH IF SYNAD OCCURRED             28490020
*                                  FALL THRU NORMAL RETURN              28560020
         TM    IDSSW,RESUME        IS THIS AN INTERRUPTED DS            28630020
         BZ    GOTOPUT             NO, SKIP FINDING POSITION            28700020
*                                  IN BLOCK AT TIME OF INTERRUPT        28770020
         CH    R5,DSBPOS           ARE WE AT RESUME POINT               28840020
         BNE   GETLOGRC            NO, DONT PUT,GET NEXT REC            28910020
         NI    IDSSW,X'FF'-RESUME  TURN OFF RESUME SW                   28980000
GOTOPUT  EQU   *                                                        29050020
         LH    R5,BAK10CNT         GET COUNT                            29055020
         AH    R5,ONE              ADD ONE TO COUNT                     29060020
         STH   R5,BAK10CNT         SAVE COUNT                           29065020
         CH    R5,SIX              DOES COUNT EQUAL SIX                 29070020
         BNE   PASSLNG             NO, SKIP CHANGING APPROX             29075020
         XC    BAK10CNT,BAK10CNT   ZERO COUNT FOR NEXT APPROX.          29080020
         MVC   BAK10APX,BAK10NEW   SAVE NEW APPROX.                     29085020
         MVC   BAK10NEW,DSBHOLD    GET NEXT APPROXIMATION               29090020
PASSLNG  EQU   *                                                        29095020
         LR    R1,R11              GET ADDR OF INPUT DCB                29103000
         USING IHADCB,R1           GET INPUT DCB ADDRESSABILITY         29111000
         LH    R0,DCBLRECL         PASS LENGTH                          29120020
         ST    R0,OUTRECL          OF RECORD                            29190020
         MVC   OUTRECFM,DCBRECFM   PASS RECFM FROM DCB TO PUT           29260020
         BAL   R5,PUT              GO TO PUT ROUTINE                    29330020
         OI    IDSSW,OLDSW          INDICATE INPUT DATASET OPEN         29400020
         B     GETLOGRC            GO TO TOP OF GET/PUT LOOP            29470000
         DROP  R1                                                       29500000
         EJECT                                                          29540020
PUT      EQU   *                                                        29610020
CKATECB  EQU   *                                                        29617020
         CLI   OUTRESUM,QUIT       WAS THER A SERIOUS ERROR             29624020
         BE    CKWHERE             YES, GO SEE HOW TO QUIT              29631020
         TM    OUTATECB,POSTED     WAS ATTENTION PRESSED                29638020
         BZ    NOATTN              NO, GO GET NEXT INPUT LINE           29645020
         XC    OUTATECB,OUTATECB   CLEAR ATTENTION ECB                  29652020
         B     GOTO63              PROCESS NEW SUBCOMMAND               29659020
NOATTN   EQU   *                                                        29666020
         L     R1,DSNAME           GET ADDR OF DSNAME                   29680020
         CLI   0(R1),C'*'          IS OUTPUT ON TERMINAL                29750020
         BNE   QSAMPUT             NO, SKIP PUTLINE                     29820020
         L     R1,OUTTERM          GET ADDR OF PUTLINE WORK CORE        29890020
         USING TERMPARM,R1         GET ADDRESSABILITY FOR SAME          29960020
         XC    TERMPARM(TERMLNTH),TERMPARM ZERO PUTLINE PARMS           30030020
         LA    R0,TERMPUT          GET ADDR OF LIST PART OF             30100020
*                                  PUTLINE                              30170020
         ST    R0,TERMPUTA         STORE IN PARM LIST                   30240020
         L     R15,OUTPARS         GET ADDR OF PARSE PARMS              30310020
         MVC   TERMPARM(TERMSTAN),0(R15) GET ADDR OF UPT,ECT,ECB        30380020
         L     R2,OUTRECA          GET ADDR OF REC. TO PUT              30410020
         TM    OUTRECFM,FIXSW      IS INPUT FIXED OR UNDEFINED          30470000
         BZ    CKCTLCH             NO , SKIP CONVERT TO VARIABLE        30530000
         L     R0,OUTRECL          GET LENGTH OF REC. TO PUT            30590020
         AH    R0,FOUR             ADD LENGTH OF LL                     30660020
         L     R2,OUTRECA          GET ADDR OF REC. TO PUT              30730020
         SH    R2,FOUR             SUBTRACT LENGTH OF LL                30800020
         STH   R0,OUTRTCD         STORE LL IN HALFWORD BEFORE           30820000
         MVC   0(L'OUTRTCD,R2),OUTRTCD                                  30840000
CKCTLCH  EQU   *                                                        30880020
         TM    OUTRECFM,CONCHAR    DOES INPUT HAVE CONTROL CHARS        30890020
         BZ    DOPUTLN             NO, GO PUTLINE                       30900020
         MVI   DATA(R2),BLNK       YES, BLANK CONTROL CHARACTER         30910020
DOPUTLN  EQU   *                                                        30940020
         PUTLINE OUTPUT=((R2),DATA),MF=(E,(1))                          31010020
         CH    R15,FOUR            WAS RETURN CODE GREATER              31080020
*                                  THAN FOUR.                           31150020
         BNH   GOBACK              NO,PUT IS COMPLETE                   31220020
         MVI   OUTMSGID,M18        ISSUE MSG                            31290020
         LA    R9,CKWHERE          WHERE TO GO AFTER MSG                31360020
         B     MSGOUTER            GO LINK TO IKJEFF67                  31460020
QSAMPUT  EQU   *                                                        31570020
         DROP  R7                                                       31640020
         L     R1,OUTDAIR          ADDR OF OUTPUT DAIR BLOCK            31648000
         DROP  R8                                                       31652000
         USING DAPB08,R1           ADDRESSABILITY                       31656000
         CLI   DA08DPS2,DA08DEL    IS DS NEW (MARKED FOR DELETE)        31664000
         BNE   RECFM               NO, SKIP CHANGING DISPOSITION        31672000
         MVI   DA08DPS2,DA08KEEP   CHANGE DISPOSITION TO KEEP           31680000
         DROP  R1                                                       31688000
RECFM    EQU   *                                                        31696000
         L     R4,OUTDCB          GET ADDR OF OUTPUT DCB                31710020
         USING IHADCB,R4          GET OUTPUT DCB ADDRESSABILITY         31780020
         LA    R1,OUTERRTN        GET ADDR OF I/O ERR RTN               31850020
         ST    R1,DCBSYNAD        PUT IT IN DCB                         31920020
         TM    DCBRECFM,FIXSW     IS OUTPUT FIXED OR UNDEFINED          31990020
         BZ    VARPROC            NO, SKIP FIXED & UNDF PROCESS         32060020
         DROP  R4                                                       32130020
         TM    OUTRECFM,FIXSW     IS INPUT FIXED OR UNDEFINED           32200020
         BO    TSTUNDFO           YES, SKIP CONVERT TO FIXED            32270020
         L     R0,OUTRECL         GET LENGTH OF INPUT LINE              32340020
         SH    R0,FOUR            SUBTRACT LENGTH OF LL                 32410020
         ST    R0,OUTRECL         SAVE NEW LENGTH                       32480020
         L     R1,OUTRECA         GET ADDR OF VAR. INPUT LINE           32550020
         AH    R1,FOUR            ADD LENGTH OF LL                      32620020
         ST    R1,OUTRECA         SAVE ADDR OF FIXED RECORD             32690020
         USING IHADCB,R4          GET OUTPUT DCB ADDRESSABILITY         32760020
TSTUNDFO TM    DCBRECFM,VARSW     IS OUTPUT RECFM UNDEFINED             32830020
*                                 IF BOTH FIXED & VAR BITS ON           32900020
*                                 RECFM=UNDF.                           32970020
         BZ    DOPUT              NO, SKIP MOVE OF LRECL                33040020
         MVC   DCBLRECL,DCBBLKSI  FIX SO UNDF LOOKS LIKE FIXED          33110020
DOPUT    EQU   *                                                        33180020
         LR    R1,R4              PASS ADDR OF OUTPUT DCB               33250020
         PUT   (1)                PUT REC & GET ADDR OF NEXT            33320020
*                                 BUFFER                                33390020
         MVI   0(R1),BLNK         BLANK                                 33460020
BLANKOUT MVC   1(0,R1),0(R1)       OUTPUT BUFFER                        33530020
         LH    R15,DCBLRECL        GET LENGTH OF OUTPUT BUFFER          33600020
         BCTR  R15,0               ADJUST LENGTH FOR EXECUTE            33670020
         CH    R15,TWO55           IS LRECL MORE THAN 256               33680000
         BNH   DOBLANK             NO, USE LRECL FOR MOVE               33690000
         LH    R15,TWO55           USE 255 FOR MOVE                     33700000
DOBLANK  EQU   *                                                        33710000
         EX    R15,BLANKOUT        BLANK OUTPUT BUFFER                  33740020
         L     R2,OUTRECA          GET ADDR OF INPUT LINE               33810020
         L     R14,OUTRECL         GET LENGTH OF INPUT LINE             33830000
         BCTR  R14,0               DECREMENT LENGTH FOR EXECUTE         33850000
         CR    R15,R14             IS OUTPUT LRECL LOWER THAN           33870000
*                                  TOTAL RECORD LENGTH                  33890000
         BL    MOVEREC             YES, USE OUTPUT LRECL                33910000
         LR    R15,R14             NO, USE TOTAL RECORD LENGTH          33930000
MOVEREC  MVC   0(0,R1),0(R2)       DUMMY MOVE                           33950020
         CH    R15,TWO55           IS LRECL MORE THAN 256               33970000
         BNH   DOMOVEF             NO, USE LRECL FOR MOVE               33990000
         LH    R15,TWO55           USE 255 FOR MOVE                     34010000
DOMOVEF  EQU   *                                                        34030000
         EX    R15,MOVEREC         MOVE INPUTLINE TO OUTPUT BUF         34090020
         AH    R2,DCBLRECL         ADD LENGTH OF LINE PUT               34160020
*                                  TO ADDR OF INPUT LINE                34190020
         ST    R2,OUTRECA          SAVE ADDR OF REMAINDER OF            34230020
*                                  INPUT LINE                           34300020
         L     R1,OUTRECL          GET LENGTH OF INPUT LINE             34370020
         SH    R1,DCBLRECL         SUBTRACT LENGTH OF LINE PUT          34440020
         ST    R1,OUTRECL          SAVE LTH OF REMAINDER OF             34510020
*                                  INPUT LINE.                          34580020
         LTR   R1,R1               IS REMAINING LENGTH GREATER          34650020
*                                  THAN ZERO.                           34720020
         BP    DOPUT               YES, GO PUT REMAINDER OF REC         34790020
         B     GOBACK              NO, PUT IS COMPLETE                  34860020
VARPROC EQU   *                                                         34930020
        DROP  R4                                                        35000020
         L     R0,OUTRECL          GET LENGTH OF INPUT LINE             35030020
         TM    OUTRECFM,FIXSW     IS INPUT FIXED OR UNDEFINED           35070020
         BZ    ALREADYV            NO, SKIPCONVERT TO VARIABLE          35140020
         L     R0,OUTRECL          GET LENGTH OF INPUT LINE             35210020
         AH    R0,FOUR             ADD LENGTH OF LL                     35280020
         ST    R0,OUTRECL          SAVE NEW LENGTH                      35350020
         L     R1,OUTRECA          GET ADDR OF INPUT LINE               35420020
         SH    R1,FOUR             SUBTRACT LENGTH OF LL                35490020
         STH   R0,OUTRTCD          STORE LENGTH IN NEW LL               35530000
         MVC   0(L'OUTRTCD,R1),OUTRTCD                                  35570000
         ST    R1,OUTRECA          SAVE NEW ADDR OF CONVERTED RECORD    35630020
ALREADYV EQU   *                                                        35700020
         L     R2,OUTRECA          GET ADDR OF RECORD TO BE PUT         35770020
         USING IHADCB,R4           GET OUTPUT DCB ADDRESSABILITY        35840020
         LH    R1,DCBLRECL         GET SIZE OF OUTPUT LRECL             35910000
         CR    R0,R1               IS INPUT LL LESS THAN OR EQ          36050020
*                                  OUTPUT LRECL                         36120000
         BNH   DOPUTV              YES, SKIP CHANGE OF LL               36190020
         STH   R1,OUTRTCD          STORE LRECL IN LL                    36230000
         MVC   0(L'OUTRTCD,R2),OUTRTCD                                  36270000
DOPUTV   EQU   *                                                        36330020
         LR    R1,R4               GET ADDR OF OUTPUT DCB               36400020
         PUT   (1)                 GET ADDR OF NEXT BUFFER &            36470020
*                                  PUT LAST LINE                        36540020
         MVC   OUTRTCD,0(R2)       MOVE LL TO HALF WORD                 36580000
         LH    R15,OUTRTCD         GET INPUT LINE LL                    36620000
         BCTR  R15,0               ADJUST LENGTH FOR EXECUTE            36680020
         CH    R15,TWO55           IS LRECL MORE THAN 256               36690000
         BNH   DOMOVEV             USE LRECL FOR MOVE                   36700000
         LH    R15,TWO55           USE 255 FOR MOVE                     36710000
DOMOVEV  EQU   *                                                        36720000
         EX    R15,MOVEREC         MOVE INPUT LINE TO OUTPUT BUF        36750020
         L     R0,OUTRECL          GET LENGTH OF INPUT LINE             36820020
         SH    R0,OUTRTCD          SUBTRACT LENGTH OF LINE PUT          36890000
         AH    R0,FOUR             ADD LENGTH OF NEW LL                 36960000
         ST    R0,OUTRECL          SAVE LTH OF REMAINDER OF             37030000
*                                  INPUT LINE                           37100000
         AH    R2,OUTRTCD          ADD LL TO ADDR OF INPUT LINE         37170000
         SH    R2,FOUR             SUBTRACT LENGTH OF NEW LL            37240020
         ST    R2,OUTRECA          SAVE ADDR OF REMAINDER OF            37310020
*                                  INPUT LINE                           37380020
         CH    R0,FOUR             IS ALL OF LINE OUT                   37400000
         BNH   GOBACK              YES RETURN                           37420000
         STH   R0,OUTRTCD          PUT NEW LL IN REMAINDER OF           37450000
         MVC   0(L'OUTRTCD,R2),OUTRTCD                                  37480000
*                                  RECORD.                              37520020
         B     ALREADYV            GO PUT REMAINDER OF RECORD           37620020
GOBACK   EQU   *                                                        38080020
         BR    R5                  RETURN                               38150020
         EJECT                                                          38220020
         USING IHADCB,R7           ESTABLISH INPUT DCB                  38290020
*                                  ADDRESSABILITY                       38360020
* END OF DATA EXIT                                                      38430020
EODEXIT  EQU   *                                                        38500020
         L     R1,OUTTERM          GET ADDR OF PUTLINE CORE             38505000
         LTR   R1,R1               IS OUTPUT TO TERMINAL                38510000
         BZ    EODPROC             NO, SKIP SEPARATOR                   38515000
         LA    R2,SEPARATE         GET ADDR OF SEPARATOR LINE           38520000
         PUTLINE OUTPUT=((R2),DATA),TERMPUT=(HOLD),MF=(E,(1))           38525000
EODPROC  EQU   *                                                        38530000
         TM    OUTATECB,POSTED     WAS ATTENTION PRESSED                38535000
         BZ    NOATT               NO, AVOID ECB TEST                   38540000
         XC    OUTATECB,OUTATECB   YES, ZERO ECB                        38545000
         B     GOTO63              GO TO SUBCOMMAND HANDLER             38550000
NOATT    EQU   *                                                        38555000
         CLC   PAUSE,ONE           WAS PAUSE SPECIFIED                  38570020
         BNE   CLOSE               NO, DO NOT GO TO ATTN EXIT           38640020
*      ISSUE PAUSE MESSAGE                                              38710020
         MVI   OUTMSGID,M0         ISSUE PAUSE MSG                      38780020
         MVI   OUTRTCD+R1,R0       INDICATE PUTGET MODE MESSAGE         38810000
         BAL   R9,MSGOUT           GO LINK TO IKJEFF67                  38850020
         LTR   R15,R15             WAS PUTGET OK                        38920020
         BNZ   OUTPROC2            SKIP SUBCOMMAND HANDLER              38990020
         OI    IDSSW,EODSW         INDICATE SUBCOMMAND HANDLER          39090020
*                                  CALLED BY EOD                        39190020
GOTO63   EQU   *                                                        39290020
         L     R15,VJEFF63         GET ADDR OF SUBCOMMAND HANDLR        39390020
         LR    R1,R3               PASS ADDR OF OUTCOMTB                39490020
         BALR  R14,R15             GO TO SUBCOMMAND HANDLER             39590020
*                                  ********************                 39760020
         TM    OUTATECB,POSTED     WAS ATTENTION PRESSED                39770000
         BZ    CHNGPATH            NO, AVOID ZEROING ECB                39780000
         XC    OUTATECB,OUTATECB   ZERO ECB                             39790000
         B     GOTO63              GO TO SUBCOMMAND HANDLER             39800000
CHNGPATH EQU   *                                                        39830020
*                                  USE R15 RETURN CODE AS               39930020
*                                  DISPLACEMENT IN BRANCH TAB           40040020
         B     BRTAB(R15)          GO TO CORRECT BRANCH                 40110020
BRTAB    EQU   *                                                        40180020
         B     OUTPROC1            IF RESUME CODE 0                     40250020
         B     OUTPROC2            IF RESUME CODE 4                     40320020
         B     OUTPROC3            IF RESUME CODE 8                     40390020
         B     OUTPROC4            IF RESUME CODE 12                    40460020
         LA    R9,CKWHERE          IF RESUME CODE 16                    40480020
         B     CKQUIT              GO SEE IF SERIOUS ERROR              40500020
OUTPROC2 EQU   *                                                        40530020
CLOSE    EQU   *                                                        40600020
         NI    IDSSW,X'FF'-OLDSW   TURN OFF OLDSW                       40670000
         L     R1,BUFFAD           GET ADDR OF I/O WORKAREA             40740020
         USING GETAB,R1            GET ADDRESSABILITY FOR SAME          40810020
         L     R1,DECBPTR          GET ADDR OF DECB                     40880020
         USING DECB,R1             GET DECB ADDRESSABILITY              40950020
         TM    DECSDECB,WAITING      IS ALLL I/O COMPLETE               41020020
         BZ    CLSHERE             YES SKIP CHECK OF OUTSTANDING I/O    41090020
         CHECK DECB                CHECK ALTERNATE DECB                 41160020
         DROP  R1                                                       41230020
CLSHERE  EQU   *                                                        41300020
         CLOSE (IDSDCB),MF=(E,IDSCLOSE) CLOSE INPUT DATASET             41370020
         L     R1,CORESIZE         PASS LENGTH OF INPUT                 41420000
*                                  BUFFERS ETC.                         41470000
         LA    R1,0(R1)            CLEAR HIGH ORDER BYTE                41520000
         LR    R0,R1               SET UP FOR FREEMAIN                  41570000
         O     R0,SUBPOOL1         PASS SUBPOOL NUMBER                  41650020
         L     R1,BUFFAD           PASS ADDRESS OF CORE TO FREE         41720020
         FREEMAIN R,LV=(0),A=(1)   FREE INPUT BUFFERS ETC.              41790020
         CLI   OUTRESUM,QUITEND    END SUBCOMMAND                       41796000
         BE    FREEDAIR            YES, BRANCH                          41802000
         CLI   OUTRESUM,QUIT       WAS THERE A SERIOUS ERROR            41810020
         BE    FREEDAIR            YES, SKIP UNALLOCATION               41830020
UNALLOC  EQU   *                                                        41860020
         USING DAPB18,R8           GET UNALOC BLOCK ADDRESSABILITY      41930020
         XC    DA18FLG(DA18FRDL),DA18FLG ZERO FLAG , RETURN CODE        42000020
*                                  AND DSNAME                           42070020
         MVI   DA18DPS2,DA18DEL    DELETE INPUT ON UNALLOC              42140020
         MVI   DA18CTL,EMPTY       ZERO CONTROL BYTE                    42210020
         MVC   DA18MNM,BLANKS      BLANK MEMBER NAME                    42280020
         MVC   DA18CD,DA18         SET FUNCTION CODE TO UNALLOC         42350020
         MVC   DA18SCLS,BLANKS     BLANK SYSOUT CLASS REQUEST           42420020
         MVC   DA18JBNM,BLANKS     BLANK JOBNAME                        42450000
         LR    R1,R8               PASS ADDR OF DAIR PARM BLOCK         42490020
         LINK  EP=IKJDAIR          GO TO DAIR                           42560020
         LA    R0,IDSDSNLN         GET ADDR OF DSNAME                   42561000
         ST    R0,DA18PDSN         PASS TO MSG RTN                      42562000
         LTR   R15,R15             WAS DAIR RC 0                        42563000
         BZ    FREEDAIR            YES, GO FREE DAIR CORE               42564000
         B     CKDAIRCD            NO GO TO MSG RTN                     42565000
FREEDAIR EQU   *                                                        42570020
         LR    R1,R8               GET ADDR OF CORE TO FREE             42580020
         FREEMAIN R,LV=DA08LTH,A=(1),SP=SP1 FREE DAIR PARMS             42590020
FREEDCB  EQU   *                                                        42600020
         LR    R1,R11              GET ADDR OF CORE TO FREE             42630020
         FREEMAIN R,LV=IDSCOREL,A=(1),SP=SP1 FREE DCB ETC.              42700020
         XC    OUTIDSP,OUTIDSP     ZERO ADDR OF IDSCORE                 42730020
         CLI   OUTRESUM,QUITEND    END SUBCOMMAND                       42750000
         BE    LEAVE               YES, BRANCH                          42770000
         CLI   OUTRESUM,QUIT       WAS THERE A SERIOUS ERROR            42790020
         BE    LEAVE               YES, SKIP DECREMENTING USE CT        42850020
         TM    DSBWSMNT,NOTMNTED   WAS VOL. MOUNTED & UCB USER          42910020
*                                  COUNT INCREMENTED AT WARM ST.        42980020
         BO    CKLAST              NO, SKIP DECREMENTING USER CT        43080000
         MVI   OQMFUNC,OQMUCB      INCICATE DECREMENT UCB               43180000
         LA    R0,THREE            PASS OUTPUT INCICATOR                43280000
         LA    R1,OQMCPPL          PASS ADDR OF SVC100 PARMS            43380000
         SVC   FIB                 ISSUE SVC 100 TO GET TO IKJEFF61     43480000
OUTPROC4 EQU   *                                                        43820020
CKLAST   EQU   *                                                        43890020
         CLI   OUTRESUM,QUIT       WAS THERE A SERIOUS ERROR            43910000
         BNE   OK                  NO, KEEP GOING                       43914020
         LA    R9,CLOSE            WHERE TO RETURN                      43918020
         B     END                 GO ENQUE JOBS                        43922020
OK       EQU   *                                                        43926020
         LA    R6,SMBBUF           GET ADDR OF SMB                      43960020
         USING SMBDSKAD,R6                                              44030020
         CLC   SMBNEXT,ZERO        IS THIS THE LAST DSB/SMB             44100020
         BE    DELETEJB            YES, GO DELETE JOB FROM JOB-Q        44170020
         B     READQ               GO READ NEXT DSB/SMB                 44240020
DELETEJB EQU   *                                                        44310020
         MVI   OQMFUNC,OQMDELE     INDICATE DELETE FUNCTION REQ.        44520020
         LA    R1,OQMCPPL          PASS ADDR OF SVC 100 PARMS           44590020
         LA    R0,THREE            PASS OUTPUT INDICATOR                44620020
         SVC   FIB                 ISSUE SVC 100 TO GET PROJECT         44660020
*                                  KEY OF ZERO FOR Q/M DELETE           44730020
*                                  **********                           44800020
         LTR   R15,R15             WAS Q/MANAGER SUCCESSFUL             44870020
         BZ    ALLDONE             YES, SKIP MSG                        44940020
         MVI   OUTMSGID,M5         NO, ISSUE MSG IKJEF106               45010020
         LA    R9,LEAVE            WHERE TO GO AFTER MSG                45080020
         B     MSGOUTER            GO LINK TO IKJEFF67                  45180020
ALLDONE  EQU   *                                                        45290020
         CLC   OUTJBCNT,OUTJBPTR   ARE  ALL VALID JOBNAMES DONE         45360020
         BE    RESETJP             YES, GO RETURN                       45430020
         L     R1,OUTJBPTR         INCREMENT NO.                        45500020
         AH    R1,ONE              OF JOB BEING PROCESSED               45570020
         ST    R1,OUTJBPTR         BY ONE                               45640020
         L     R6,LDQINFOP         GET ADDRESSABILITY FOR INFO          45710020
         USING LDQINFO,R6          AREA OF JOB BEING PROCESSED          45780020
         LA    R1,LDQINFOL         GET LENGHT OF INFO AREA              45850020
         AR    R6,R1               ADD TO ADDR OF INFO AREA             45920020
*                                  OF JOB BEING PROCESSED               45990020
         ST    R6,LDQINFOP         SAVE IN INFO AREA PTR                46060020
         LA    R1,LDQQLSTL         GET LENGTH OF LTH (QMPA)             46130020
         L     R7,LDQQLSTP         GET ADDRESSABILITY FOR LTH           46200020
*                                  (LOGICAL TRACK HEADER)               46270020
         USING LDQQLST,R7          OF JOB BEING PROCESSED               46340020
         AR    R7,R1               ADD TO ADDR OF LTH (QMPA) OF         46410020
*                                  JOB BEING PROCESSED.                 46480020
         ST    R7,LDQQLSTP         SAVE IN LTH (QMPA) PTR               46550020
         XC    OQM1STSM,OQM1STSM   ZERO ADDR OF FIRST DSB/SMB           46580020
         B     READSMB             DO NEXT JOB                          46630020
RESETJP  EQU   *                                                        46690020
         LH    R1,ONE              RE-INITIALIZE NO. OF JOB             46760020
         ST    R1,OUTJBPTR         BEING PROCESSED                      46830020
         XC    OUTQMPAR,OUTQMPAR   NO JOBS DEQUEUED                     46860020
LEAVE    EQU   *                                                        46880000
         LR    R1,R13              SAVE ADDR OF CURRENT SAVEAREA        46900020
         L     R13,SAVBACK         GET ADDR OF PREVIOUS SAVEAREA        46970020
         FREEMAIN R,LV=SAVLTH,A=(1),SP=SP1 FREE CURRENT SAVEAREA        47040020
         RETURN (14,12),T,RC=0      RETURN                              47110020
         DROP  R13                                                      47180020
         EJECT                                                          47250020
*        *     *                                                        47310020
OPENEXIT EQU   *                                                        47370020
         USING IHADCB,R7             GET INPUT DCB ADDRESSABILITY       47430020
         L     R13,OPNEXSAV        ESTABLISH EXIT SAVE AREA             47490020
         CLC   DCBBLKSI,BBLK        TEST FOR LARGE BLOCK                47550000
         BNH   SDBLK               BRANCH IF NOT TOO LARGE              47610020
         MVI   DCBBUFNO,ONEBUF      USE ONE BUFFER                      47650000
ONEBUF   EQU   1                   INDICATES ONE BUFFER                 47690000
SDBLK    EQU   *                                                        47730020
*DOES DATASET HAVE FIELDS WHICH ARE NEEDED TO OPEN                      47790020
         CLC   DCBBLKSI,ZERO         TEST FOR ZERO IF NOT               47850000
         BNE     GETBUFFS          GETBUFFERS ETC &                     47910000
*                                  CONTINUE OPEN                        47970020
         CLC   DCBBUFL,ZERO          TEST FOR ZERO IF NOT       O       48030000
         BNE     GETBUFFS          GETBUFFERS ETC &                     48090000
*                                  CONTINUE OPEN                        48150020
* FIX SO DATASET CAN COMPLETE OPEN                                      48210020
         LA    R2,EIGHTEEN         GET MINUM SIZE BLOCK                 48270020
         STH   R2,DCBBLKSI         PUT IN DCB BLOCK SIZE                48330020
         STH   R2,DCBLRECL         PUT IN DCB LOGICAL RECORD SZ         48390020
EIGHTEEN EQU   18                  MINIMUM SIZE BLOCK                   48450020
         OI    IDSSW,UNOPENED      INDICATE SYSOUT DATASET EMPTY        48510020
* SET UNOPENED DATASET FLAG                                             48580020
* GET CORE FOR BUFFERS AND CONTROL INFORMATION USED BY BSAM &           48650020
* DEBLOCKING ROUTINE. TRY FOR TWO BUFFERS IF CORE NOT AVAILABLE         48720020
* TRY AGAIN FOR ONE.                                                    48790020
GETBUFFS EQU   *                                                        48860020
         LR    R10,R14             SAVE RETURN ADDRESS                  48930020
         LH    R3,DCBBLKSI         GET BLKSIZE FOR BUFF SIZE CAL        49000020
         AH    R3,FOUR             ADD FOUR IN FRONT OF BLKSIZE         49070000
*                                  SO THAT PUTLINE WILL HAVE A          49140020
*                                  PLACE TO PUT LL IF NEEDED            49210020
         LH    R5,SEVEN            ADD 7 TO BLKSIZE, SHIFT RIGHT        49280000
         AR    R3,R5               THREE AND SHIFT LEFT THREE           49350020
         SRL   R3,3                THIS ROUNDS BLKSIZE UP TO THE        49420020
         SLL   R3,3                NEXT HIGHER DOUBLE WORD              49490020
         LH    R5,TWO              MULTIPLY THE ROUNDED BLKSIZE         49560000
         MR    R4,R3               BY TWO                               49630020
         LA    R0,GETABLT2         ADD LENGTH OF TABLE TO BE USE        49700020
         AR    R5,R0               IN BSAM & DEBLOCKING ROUTINE         49770020
         LA    R1,GETLIST          GET ADDR OF LIST PART OF MAC         49840020
*                                    ISSUE CONDITIONAL GETMAIN F        49910020
*                                    TWO BUFFERS                        49980020
         XC    GETLIST(GL),GETLIST ZERO LIST PART OF GETMAIN            50050000
         CLI   DCBBUFNO,ONEBUF      IS BUFFNO ONE                       50120000
         BE    FORCEONE            YES, SKIP GETMAIN FOR 2 BUFFS        50190020
         GETMAIN EC,LV=(R5),A=BUFFAD,MF=(E,(R1)),SP=SP1                 50260020
         LTR   R15,R15             WAS GETMAIN SUCCESSFUL, CODE         50330020
         BZ    TWOBUFFS            ZERO INDICATES SUCCESS, BRANC        50400020
*                                  AROUND ATTEMPT FOR GETMAIN FO        50470020
*                                  SINGLE BUFFER                        50540020
FORCEONE EQU   *                                                        50610020
         LA    R5,GETABLT1         ADD LENGTH OF TABLE TO BE USE        50680020
         AR    R5,R3               IN BSAM & DEBLOCKING ROUTINE         50750020
*                                  TO ROUNDED BLKSIZE SAVED IN          50820020
*                                  PREVIOUS GETMAIN CALCULATION         50890020
         O     R5,SUBPOOL1         INDICATE SUBPOOL ONE                 50960020
         LR    R0,R5               PASS LENGTH OF CORE                  51030020
         GETMAIN R,LV=(0)          GET CORE FOR ONE BUFFER              51100020
         LR    R4,R1               ESTABLISH ADDRESSABILITY             51170020
*                                  FOR DECB, BUFFER & GETAB.            51240020
         ST    R4,BUFFAD           SAVE ADDRESS OF CORE                 51310020
         USING GETAB,R4            DECB,   BUFFER  & GETAB              51380020
         ST    R5,CORESIZE         SAVE LENGTH OF GOTTEN CORE           51450020
*   MASK IS A VALUE WHICH WHEN EXCLUSIVE ORED WITH DECBPTR IN           51520020
*   THE BSAM READ ROUTINE MUST ALWAYS YIELD THE ADDRESS OF THE          51590020
*   ALTERNATE DECB. IF THERE IS ONLY ONE DECB, THE MASK SHOULD          51660020
*   BE ZERO SO THAT THE EXCLUSIVE OR IN THE READ ROUTINE WILL           51730020
*   YIELD THE SAME DECB ADDRESS.                                        51800020
         XC    DECB1(DL),DECB1     ZERO DECB                            51870000
         LA    R0,DECB1            FOR ONE BUFFER THE ADDRESS OF        51940020
         ST    R0,MASK             THE FIRST DECB IS PLACED IN          52010020
*                                  BOTH DECBPTR & MASK, SO THAT         52080020
*                                  WHEN MASK IS EXCLUSIVE ORED          52150020
*                                  WITH DECBPTR DURING INITIAL-         52220020
*                                  IZATION, MASK BECOMES ZERO.          52290020
         ST    R7,DECDCBAD         STORE ADDRESS OF DCB IN DECB         52360020
         LA    R0,BUFFER           STORE THE ADDRESS OF THE             52430020
         ST    R0,DECAREA          BUFFER TO BE USED FOR SINGLE         52500020
*                                  BUFFERING IN DECB                    52570020
         B     SKIP2BUF            AVOID INITIALIZING MASK FOR          52640020
*                                  TWO BUFFERS                          52710020
TWOBUFFS L     R4,BUFFAD           ESTABLISH ADDRESSABILITY FOR         52780020
*                                  GETAB                                52850020
         ST    R5,CORESIZE         SAVE LENGTH OF GOTTEN CORE IN        52920020
*                                  FIRST WORD OF GOTTEN CORE.           52990020
         XC    DECB1(DL),DECB1     ZERO DECB1                           53060000
         XC    DECB2(DL),DECB2     ZERO DECB                            53130000
         LA    R0,DECB2            FOR TWO BUFFERS THE ADDRESS          53200020
         ST    R0,MASK             OF THE SECOND DECB SHOULD BE         53270020
*                                  IN MASK SO THAT WHEN MASK &          53340020
*                                  DECBPTR ARE EXCLUSIVE ORED           53410020
*                                  DURING INITIALIZATION, MASK          53480020
*                                  WILL YIELD A HASH VALUE WHICH        53550020
*                                  WHEN EXCLUSIVE ORED WITH             53620020
*                                  DECBPTR IN THE BSAM READ RTN.        53690020
*                                  WILL ALWAYS YIELD THE ADDRESS        53760020
*                                  OF THE ALTERNATE DECB.               53830020
         ST    R7,DECDCBAD         STORE ADDRESS OF DCB IN FIRST        53900020
*                                  DECB                                 53970020
         LA    R0,BUFFERS          STORE ADDRESS OF THE                 54040020
         ST    R0,DECAREA          FIRST BUFFER IN DECB                 54110020
         AR    R0,R3               ADD ROUNDED BLOCK SIZE TO            54180020
*                                  ADDRESS OF FIRST BUFFER              54250020
*                                  REG.0 NOW HAS ADDRESS OF             54320020
*                                  SECOND BUFFER                        54390020
         LA    R3,DECB2            ESTABLISH ADDRESSABILITY FOR         54460020
         USING DECB,R3             SECOND DECB                          54530020
         ST    R0,DECAREA          STORE ADDRESS OF SECOND BUFF         54600020
*                                  IN SECOND DECB                       54670020
         ST    R7,DECDCBAD         STORE ADD. OF DCB IN SECOND          54740020
*                                  DECB                                 54810020
         DROP  R3                                                       54880020
SKIP2BUF LA    R0,DECB1            INITIALIZE DECBPTR SO IT             54950020
         ST    R0,DECBPTR          POINTS TO FIRST DECB                 55020020
         XC    MASK,DECBPTR        MASK NOW IS ZERO IF ONE BUFF.        55090000
*                                  & A HASH VALUE IF TWO BUFFS.         55160020
         XC    RECSTART,RECSTART   ZERO RECSTART                        55250000
         XC    LTHLEFT,LTHLEFT     ZERO LTHLEFT                         55340000
COMPOPEN EQU   *                                                        55440020
         LR    R14,R10             GET ADDR TO RETURN TO                55510020
         USING OUTCOMTB,R3                                              55580020
         BR    R14                 COMPLETE OPEN                        55650020
         EJECT                                                          55720020
INERRTN  EQU   *                                                        55790020
         LM    R0,R1,SYN0AND1      GET SYNAD REGS 0 AND 1               55860020
         SYNADAF ACSMETH=BSAM      GET MSG BUILT                        55930020
         MVI   OUTMSGID,M          ISSUE MSG IKJEF106                   56000020
         ST    R1,OUTSYNMS         PASS MSG TO MSG RTN                  56070020
         BAL   R9,MSGOUTER         GOTO IKJEFF67                        56170020
         SYNADRLS                  FREE SYNAD CORE ETC.                 56280020
         B     CLOSE               RETURN TO IKJEFF60                   56350020
         EJECT                                                          56420020
OUTERRTN EQU   *                                                        56490020
         SYNADAF ACSMETH=QSAM      GET MSG BUILT                        56560020
         MVI   OUTMSGID,M8         ISSUE MSG IKJEF106                   56630020
         ST    R1,OUTSYNMS         PASS MSG TO MSG RTN                  56700020
         BAL   R9,MSGOUTER         GO LINK TO IKJEFF67                  56800020
         SYNADRLS                  FREE SYNAD CORE ETC.                 56910020
CKWHERE  EQU   *                                                        56920020
         CLC   OUTIDSP,ZERO        WAS DCB GOTTEN                       56930020
         BE    LEAVE               NO, RETURN TO IKJEFF60               56940020
         CLC   IDSDAIRP,ZERO       WAS DAIR CORE GOTTEN                 56950020
         BE    FREEDCB             NO, FREE DCB CORE                    56960020
         LR    R7,R11              GET INPUT DCB                        56970020
         USING IHADCB,R7           ADDRESSABILITY                       56980020
         TM    DCBOFLGS,OPEN       IS INPUT DCB OPEN                    56990020
         BO    CLOSE               YES, GO CLOSE                        57000020
         B     FREEDAIR            NO, GO FREE DAIR CORE                57010020
         EJECT                                                          57050020
MSGOUTER MVI   OUTRESUM,QUIT       SET SERIOUS ERROR                    57080020
MSGOUT   EQU   *                                                        57120020
         STH   R15,OUTRTCD         SAVE RETURN CODE                     57150000
         LR    R1,R3               PASS ADDR OF OUTCOMTB                57190020
         LINK  EP=IKJEFF67         GO TO MSG RTN                        57260020
CKQUIT   EQU   *                                                        57268020
         CLI   OUTRESUM,QUIT       ANY SERIOUS ERROR                    57276000
         BE    END                 YES, TO RE-ENQUE JOB                 57278000
QUITEND  EQU   X'0F'                                                    57280000
         CLI   OUTRESUM,QUITEND    QUIT BECAUSE OF END SUBCOMMAND       57282000
         BNE   BACK                NO, GO BACK                          57284000
END      EQU   *                                                        57288020
         L     R15,VJEFF64         GET ADDR OF END MODULE               57292000
         LR    R1,R3               PASS ADDR OF OUTCOMTB                57300000
         BALR  R14,R15             GO TO END PROCESSOR                  57305000
*                                  ****************                     57310000
BACK     EQU   *                                                        57316020
         LR    R14,R9              SAVE CONTINUE ADDR                   57330020
         L     R9,OUTPDL           RESTORE PDL ADDRESSABILITY           57400020
         BR    R14                 CONTINUE                             57470020
         EJECT                                                          57540020
SP1      EQU   1                   SUBPOOL NUMBER                       57610020
*CONSTANTS.                                                             57650000
CONCHAR  EQU   X'06'               CONTROL CHAR IN RECFM                57700020
DATA     EQU   4                   DATA PART OF OUTPUT LINE             57720020
WAITING  EQU   X'80'               WAIT BIT  IN ECB                     57750020
POSTED   EQU   X'40'               POSTED BIT IN ECB                    57820020
OPEN     EQU   X'10'               DCB OFLGS FOR OPEN DCB               57850020
VJEFF63  DC    V(IKJEFF63)         ADDR OF SUBCOMMAND HANDLER           57880020
VJEFF64  DC    V(IKJEFF64)         VCON FOR REENQ                       57910020
GETLOG   DC    V(IKJEFFGT)         ADDR OF GET ROUTINE                  57970000
BLANKS   DC    CL8' '              CONSTANT OF BLANKS                   58030000
ONE      DC    H'1'                CONSTANT OF ONE                      58100000
TWO      DC    H'2'                CONSTANT OF TWO                      58170000
DA08     DC    H'8'                DAIR FUNCTION CODE TO ALLOC          58240020
DA18     DC    H'24'               DAIR FUNCTION CODE TO UNALLOC        58310020
SEVEN   DC     H'7'                CONSTANT OF SEVEN                    58340000
TWENTY   DC    H'20'               CONSTANT OF TWENTY                   58350000
EIGHT    DC    H'8'                CONSTANT OF EIGHT                    58370000
SIX      DC    H'6'                CONSTANT OF SIX                      58400020
SIXTN    DC    H'16'               CONSTANT OF SIXTEEN                  58410000
FOUR     DC    H'4'                CONSTANT OF FOUR                     58420020
BBLK     DC    H'3000'             THIS SIZE INPUT BLOCK OR             58450020
*                                  GREATER CAUSES SINGLE                58590020
*                                  BUFFERING                            58660020
RC6708   DC    X'6708'             DYNAMIC ALLOC RETURN CODE            58665000
FIRSTPAG DC    XL3'000001'         TTR OF FIRST RECORD                  58670020
         DC    X'00'               EOV COUNT                            58680020
         DC    H'1'                POSITION OF FIRST REC IN BLK         58690020
FIRSTPGL EQU   *-FIRSTPAG          LENGTH OF TTR,EOV &COUNT             58700020
MSG102   DC    C'IKJ56319I INTERRUPTED OUTPUT RESUMED'                  58710000
MSG102LN EQU   *-MSG102                                                 58720020
SEPARATE DC    H'5'                LENGTH OF LINE                       58730000
         DC    H'0'                OFFSET                               58740000
         DC    CL1' '              TEXT IS BLANK                        58760000
TWO55    DC    H'255'              CONSTANT OF 255                      58770000
ZERO     DC    F'0'                CONSTANT OF ZERO                     58820000
SUBPOOL1 DC    X'01000000'         SUBPOOL NUMBER                       59010020
SAVLOW4  DC    X'0000000F'         MASK USED TO CNVRT CLASS             59080020
FIB      EQU   100                 NO. OF FIB SVC TO GET KEY 0          59150020
DCBIN    DCB   MACRF=RP,DSORG=PS,NCP=2,BUFNO=2 BSAM INPUT DCB           59430020
         OPEN  (0,INPUT),MF=L      LIST PART OF OPEN                    59500020
         CLOSE (0),MF=L            LIST PART OF CLOSE                   59570020
         DC    X'07'               JFCB INDICATOR                       59640020
         DC    AL3(0)              ADDR OF JFCB                         59710020
         DC    X'06'               EOV INDICATOR                        59730020
         DC    AL3(0)              GO TO EOD ON EOV                     59750000
         DC    X'85'               OPEN EXIT & LAST ELEMENT FLAG        59780020
         DC    AL3(0)              ADDR OF OPEN EXIT                    59850020
         EJECT                                                          59880000
IKJEFFPO IKJPARM                                                        59930000
JOBNAME  IKJIDENT 'JOBNAME',LIST,PROMPT='JOBNAME',OTHER=ALPHANUM,MAXLNTX59990020
               H=8,                                                    X60030000
               HELP=('NAME(S) OF PREVIOUSLY SUBMITTED JOB(S)')          60070000
CLASS    IKJKEYWD                                                       60130020
         IKJNAME 'CLASS',SUBFLD=CLASLIST                                60200020
PRINT    IKJKEYWD DEFAULT='PRINT'                                       60270020
         IKJNAME 'PRINT',SUBFLD=DSNAM                                   60340020
         IKJNAME 'NOPRINT',SUBFLD=CLASNAM                               60410020
HERE     IKJKEYWD DEFAULT='HERE'                                        60480020
         IKJNAME 'NEXT'                                                 60550020
         IKJNAME 'HERE'                                                 60620020
         IKJNAME 'BEGIN'                                                60690020
PAUSE    IKJKEYWD DEFAULT='NOPAUSE'                                     60760020
         IKJNAME  'PAUSE'                                               60830020
         IKJNAME  'NOPAUSE'                                             60900020
CLASLIST IKJSUBF                                                        60970020
CLASSLST IKJIDENT 'CLASSNAME',LIST,FIRST=ALPHANUM,MAXLNTH=1             61040020
DSNAM    IKJSUBF                                                        61110020
DSNAME   IKJPOSIT  DSTHING,PROMPT='DATA SET NAME'                       61180020
CLASNAM  IKJSUBF                                                        61250020
CLASNAME  IKJIDENT  'CLASSNAME',FIRST=ANY,MAXLNTH=1                     61320000
         IKJENDP                                                        61390020
         EJECT                                                          61420000
* THE FOLLOWING PDL DSECT IS GENERATED BY PARSE FOR OUTPUT              61460020
*IKJPARMD DSECT                                                         61530020
*         DS   A                   STORAGE                              61600020
*         DS   A                   CHAINS                               61670020
*JOBNAME  DS   A                   PTR TO FIRST JOBNAME                 61740020
*         DS   H                   LENGTH OF FIRST JOBNAME              61810020
*         DS   XL1                 FLAGS                                61880020
*         DS   XL1                 RESERVED                             61950020
*         DS   F                   CHAIN PTR FOR NXT JOBNAME PDE        62020020
*CLASS    DS   H                   ONE IF CLASS SPECIFIED               62090020
**                                *ZERO IF NOT SPECIFIED                62160020
*PRINT    DS   H                   ONE IF PRINT SPECIFIED               62230020
**                                *TWO IF NOPRINT SPECIFIED             62300020
*HERE     DS   H                   ONE IF NEXT SPECIFIED                62370020
**                                *TWO IF HERE SPECIFIED                62440020
**                                *THREE IF BEGIN SPECIFIED             62510020
*PAUSE    DS   H                   ONE IF PAUSE SPECIFIED               62580020
**                                *TWO IF NOPAUSE SPECIFIED             62650020
*CLASSLST DS   A                   PTR TO FIRST CLASSNAME               62720020
**                                *ZERO IF NOT SPECIFIED                62790020
*         DS   H                   LENGTH OF FIRST CLASSNAME            62860020
*         DS   XL1                 FLAGS,BIT 0,0 IF OMITTED             62930020
*         DS   XL1                 RESERVED                             63000020
*         DS   A                   CHAIN PTR TO NEXT CLASS PDE          63070020
*DSNAME   DS   A                   PTR TO DSNAME                        63140020
*         DS   H                   LENGTH OF DSNAME                     63210020
*         DS   XL1                 FLAGS,BIT 0,0 IF OMITTED             63280020
**                                *      BIT 1,1 IF QUOTED              63350020
*         DS   XL1                 RESERVED                             63420020
*         DS   A                   PTR TO MEMBER NAME                   63490020
*         DS   H                   LENGTH OF MEMBER NAME                63560020
*         DS   XL1                 FLAGS,BIT 0,0 IF OMITTED             63630020
*         DS   XL1                 RESERVED                             63700020
*         DS   A                   PTR TO PASSWORD                      63770020
*         DS   H                   LENGTH OF PASSWORD                   63840020
*         DS   XL1                 FLAGS, BIT 0, 0 IF OMITTED           63910020
*         DS   XL1                 RESERVED                             63980020
*CLASNAME DS   A                   PTR TO NOPRINT CLASSNAME             64050020
*         DS   H                   LENGTH OF NOPRINT CLASSNAME          64120020
*         DS   XL1                 FLAGS                                64190020
*         DS   XL1                 RESERVED                             64260020
PARSPARM DSECT                PARSE PARAMETER LIST                      64330020
JOBPDE   DSECT                                                          65030020
JBNAMEAD DS    A                   ADDR OF FIRST JOBNAME                65100020
JBNMLTH  DS    H                   LENGTH OF FIRST JOBNAME              65170020
JBNMFLGS DS    XL1                 FLAGS                                65240020
         DS    XL1                 RESERVED                             65310020
JBNMNEXT DS    A                   ADDR OF NEXT JOBNAME PDE             65380020
JBNM     EQU   X'80'               JOBNAME SPECIFIED                    65450020
CLASPDE  DSECT                                                          65520020
CLASNMAD DS    A                   ADDR OF THE CLASS NAME               65590020
CLASLTH  DS    H                   LENGTH OF THE CLASS NAME             65660020
CLASFLGS DS    XL1                 CLASS NAME FLAGS                     65730020
         DS    XL1                 RESERVED                             65800020
CLASNEXT DS    A                   ADDR OF NEXT CLASS NAME PDE          65870020
CLAS     EQU   X'80'               CLASS NAME SPECIFIED                 65940020
DSNPDE   DSECT                                                          66010020
DSNAMEAD DS    A                   ADDR OF DATA SET NAME                66080020
DSNLTH1  DS    H                   LENGTH OF DATA SET NAME              66150020
DSNFLG1  DS    XL1                 DATA SET NAME FLAGS                  66220020
         DS    XL1                 RESERVED                             66290020
DSNMEMAD DS    A                   ADDR OF DATA SET MEMBER NAME         66360020
DSNLTH2  DS    H                   LNGTH OF DATA SET MEMBER NAME        66430020
DSNFLG2  DS    XL1                 MEMBER NAME FLAGS                    66500020
         DS    XL1                 RESERVED                             66570020
DSNPASAD DS    A                   ADDR OF DATA SET PASSWORD NM         66640020
DSNLTH3  DS    H                   LENGTH OF PASSWORD                   66710020
DSNFLG3  DS    XL1                 PASSWORD FLAGS                       66780020
         DS    XL1                 RESERVED                             66850020
DSN      EQU   X'80'               DSNAME SPECIFIED                     66920020
DSNQUO   EQU   X'40'               DSNAME QUOTED                        66990020
DSM      EQU   X'80'               MEMBER SPECIFIED                     67060020
DSP      EQU   X'80'               PASSWORD SPECIFIED                   67130020
         IKJCPPL                                                        67200020
         EJECT                                                          67270020
IDSCORE  DSECT                     INPUT DATA SET CORE                  67340020
IDSDCB   DCB   MACRF=RP,DSORG=PS   INPUT DCB MAP                        67410020
IDSOPEN  OPEN  (0,INPUT),MF=L      LIST PART OF OPEN                    67480020
IDSCLOSE CLOSE (0),MF=L            LIST PART OF CLOSE                   67550020
IDSJFCBP DS    XL1                 JFCB INDICATOR                       67620020
         DS    AL3                 ADDR OF JFCB                         67690020
IDSEOV   DS    XL1                 EOV INDICATOR                        67710000
         DS    AL3                 ADDR OF EOV RTN                      67730020
IDSOPNEX DS    XL1                 LAST ENTRY & OPEN INDICATOR          67760020
         DS    AL3                 ADDR OF OPEN EXIT                    67830020
IDSDCBLN EQU   *-IDSDCB            LENGTH OF INPUT DCB OPN & CLS        67900020
IDSUCBP  DS    A                   ADDR OF INPUT UCB                    67970020
IDSDAIRP DS    A                   ADDR OF INPUT DAIR BLK               68000000
IDSSAVW  DS    XL1                 SAVE PARSE RETURN CODE               68030000
IDSSW    DS    XL1                 ATTENTION RTN SWITCHES               68060000
RESUME   EQU   X'80'                POINT WILL BE ISSUED IN             68080000
*                                   GET ROUTINE                         68100000
OLDSW    EQU   X'40'                INPUT DATASET IS OPEN               68120000
EODSW    EQU   X'20'                ATTN ENTERED FROM EOD               68140000
PUTDSMSG EQU   X'10'               PUT RESUM MSG                        68160000
UNOPENED EQU   X'08'               SYSOUT DATASET NEVER USED            68180000
NEXT     EQU   X'04'                                                    68200000
IDSDSNLN DS    H                   LENGTH OF JFCB  DSNAME               68250020
IDSJFCB  EQU   *                                                        68320020
         IEFJFCBN                  JFCB                                 68390020
OPNEXSAV DS    18F                 OPEN EXIT SAVE AREA                  68460020
SYN0AND1 EQU   OPNEXSAV            SAVE AREA FOR SYNAD REGS             68530020
         DS    0F                                                       68560020
GETLIST  EQU   *                   LIST PART OF GETMAIN                 68590000
CORESIZE DS    F                   SIZE OF THIS GETMAIN                 68620020
BUFFAD   DS    F                   ADDRESS OF BSAM INPUT BUFFERS        68650020
         DS    H                   GETMAIN FLAGS                        68670000
GL       EQU   *-GETLIST           LENGTH OF LIST PART OF GETMAIN       68690000
* THIS TABLE IS USED TO MAINTAIN AN APPROXIMATION OF TENTH LINE         68710020
* BACK.                                                                 68740020
BAK10CNT DS    H                   COUNT                                68770020
BAK10NEW DS    XL6                 NEW APPROXIMATION                    68800020
BAK10APX DS    XL6                 TTR OF APPOX. 10 LINES BACK          68830020
BAK10LNG EQU   *-BAK10CNT          LENGTH OF BACKSPACE TABLE            68860020
IDSCOREL EQU   *-IDSCORE           LENGTH OF INPUT DATASET CORE         68950020
         EJECT                                                          69020020
GETAB    DSECT                                                          69080000
RECSTART DS    F                   POINTS TO NEXT LOGICAL RECORD        69140000
LTHLEFT  DS    F                   NO. OF BYTES LEFT IN BLOCK           69200000
DECBPTR  DS    A                   POINT TO THE DECB FOR NEXT           69260000
*                                  READ OR CHECK                        69320000
MASK     DS    F                   VALUE WHICH WHEN EXCLUSIVE           69380000
*                                  ORED WITH DECBPTR YIELDS             69440000
*                                  ADDRESS OF ALTERNATE DECB            69740000
TEMP     DS    F                      PLACE TO SAVE TTR                 69920000
         DS    0F                                                       69980000
DECB1    EQU   *                   PRIMARY DECB                         70040000
DECB     EQU   DECB1                                                    70100000
DECSDECB DS    F                   ECB (EVENT CONTROL BLOCK)            70160000
DECTYPE  DS    H                   TYPE OF I/O MACRO OPTIONS            70220000
DECLNGTH DS    H                   LENGTH OF DATA OR KEY & DATA         70280000
DECDCBAD DS    A                   DCB ADDRESS                          70330000
DECAREA  DS    A                   BUFFER ADDRESS                       70380000
DECIOBPT DS    A                   IOB ADDRESS                          70430000
DL       EQU   *-DECB1             LENGTH OF DECB                       70480000
DECB2    DS    5F                  ALTERNATE DECB SAME FORMAT AS        70550000
*                                  PRIMARY DECB IF USED                 70620000
         DS    F                   PLACE FOR PUTLINE TO PUT LL          70690000
BUFFER   EQU   DECB2+4             ADDRESS OF BUFFER,SINGLE BUFF        70760000
*                                  ALLOW 4 FOR PUTLINE LL               70830000
BUFFERS  DS    0F                  BUFFERS START HERE                   70900000
DECBLTH  EQU   DECB2-DECB1         LENGTH OF DECB                       70970000
GETABLT2 EQU   BUFFERS-GETAB       LTH OF TABLE & DECB'S DOUBLE         71040000
*                                  BUFFERING                            71110000
GETABLT1 EQU   BUFFER-GETAB        LTH OF TABLE & DECB SINGLE           71180000
*                                  BUFFERING                            71250000
IOB      DS    9CL1                IOB FIELDS NOT USED BY OUTPUT        71350000
IOBCSW   DS    CL7                 CSW IN IOB                      O101 71470020
         DCBD  DSORG=PS                                                 71540020
         EJECT                                                          71610020
         IEFUCBOB                                                       71680020
SMBDSECT DSECT                                                          71750020
         IEFAJCTB                                                       71820020
SMBCMTLN EQU   SMBMESAG            COMPRESSED MESS TOTAL LENGTH         71890020
SMBNBLKS EQU    SMBMESAG           NO. OF BLANKS BETWEEN FIELDS         71960020
SMBFLDLN EQU   SMBMESAG+1          COMPRESSED MESS FIELD LENGTH         72030020
SMBFIELD EQU   SMBMESAG+2          COMPRESSED MESS FIELD                72100020
SMBDCOMP EQU   X'FE'               COMPRESSED MSG INDICATOR             72170020
         EJECT                                                          72240020
*******************************************************************     72310020
*                                                                       72380020
*                                                                       72450020
*                       DATA SET BLOCK (DSB)                            72520020
*                                                                       72590020
*                                                                       72660020
DSBMAP   DSECT                                                          72730020
         DS    0F                                                       72800020
DSBDSKAD DS    XL3                 TTR OF THIS DSB                      72870020
DSBTABID DS    XL1                 TABLE ID                             72940020
DSBNXT   DS    XL3                 TTR OF NEXT DSB                      73010020
         DS    XL2                 RESERVED                             73080020
DSBPCCPY DS    XL1                 NO.OF COPIES OF SYSOUT DATASET       73150020
DSBPCPTN DS    H                   LAST TWO CHARS OF TEST PTRN.MEM.NAME 73220020
DSBLGOUT DS    XL1                 LOG OUT BITS                         73290020
         DS    XL1                 RESERVED                             73360020
DSBFLAG  DC    X'FF'               STATUS BYTE TO DISINGUISH FROM SMB   73430020
DSBWSMNT DS    XL1                WARM START INDICATOR THAT             73500020
*                                 VOLUME NOT MOUNTED                    73570020
NOTMNTED EQU   X'80'               ON MEANS FIRST VOL. NOT MNTD         73640020
*                                  AT WARM START                        73710020
DSBTIOLN DS    XL1                 LENGTH OF TIOT PORTION OF DSB        73780020
DSBSTTA  DS    XL1                 STATUS -A-                           73850020
DSBRLOC  DS    H                   REL. LOC OF POOL                     73920020
DSBDDNAM DS    CL8                 DDNAME OF SPOOLED OUTPUT DATASET     73990020
DSBJFCB  DS    XL3                 JFCB DISK ADDRESS                    74060020
DSBSTTC  DS    XL1                 STATUS -C-                           74130020
DSBSTTB  DS    XL1                 STATUS -B-                           74200020
         DS    XL1                 RESERVED                             74270020
DSBFSRT  DS    XL2                 SRT ADDRESS                          74340020
*  DISPLACEMENTS FROM THIS POINT ON MAY BE INCORRECT FOR TIOT           74410020
*  ENTRIES LONGER THAN THE MINIMUM. DSBTIOLN SHOUL BE USED              74480020
*  IN ESTABLISHING ADDRESSABILITY FOR THE REMAINDER OF THE DSB          74550020
*        LA    R6,DSBBUF           GET ADDR OF DSB                      74620020
*        USING DSBDSKAD,R6         ESTABLISH DSB ADDRESSABILITY         74690020
*        SR    R7,R7               CLEAR FOR INSERT CHAR                74760020
*        IC    R7,DSBTIOLN         LENGTH OF TIOT ENTRY IN DSB          74830020
*        LA    R7,DSBBASE(R7,R6)   ADD LENGTH OF DSB TIOT ENTRY         74900020
*        USING DSBXXX,R7           GET ADDRESSABILITY FOR DSB           74970020
*                                    AFTER TIOT ENTRY                   75040020
DSBBASE  EQU   DSBTIOLN-DSBDSKAD  LENGTH OF DSB BASE                    75110020
DSBXXX   DS    XL1                RESERVED                              75180020
DSBCLA   DS    CL1                 OUTPUT CLASS                         75250020
         DS    XL2                                                      75320020
DSBFOR   DS    F                   FORM TYPE TO BE USED FROM SYSOUT DD  75390020
DSBPRG   DS    2F                  NAME OF USER WRITER FROM SYSOUT DD   75460020
DSBSMF   EQU   *                                                        75530020
DSBCPUID DS    F                   SID AND MDL FROM SMCA                75600020
DSBJOB   DS    2F                  JOB NAME                             75670020
DSBENTRY DS    F                   ENTRY TIME IN 1/100'S SEC            75740020
DSBDATE  DS    F                   ENTRY DATE 00YYDDDF                  75810020
DSBUSEID DS    2F                  USER ID - INIT BLANK BY R/I EACH JOB 75880020
DSBCLAS  DS    CL1                 OUTPUT CLASS                         75950020
         DS    0F                                                       76020020
DSBHOLD  DS    XL3       TTR IN INPUT DS AT POINT OF INTERRUPTION       76090020
DSBVOL   DS    XL1                VOL AT PT OF INTERRUPTION             76160020
DSBPOS     DS    XL2                POS IN BLOCK AT POINT OF INTERPT    76230020
         EJECT                                                          76300020
IOPARAMS DSECT                                                          76370020
OQMPARM  DS    0D                                                       76440020
OQMSIZE  DS    F                   SIZE OF GETMAIN                      76510020
OQMCPPL  DS    A                   ADDR OF CPPL                         76580020
OQMFUNC  DS    XL1                 FUNC INICATION FOR IKJEFF61          76650020
OQMLOCDQ EQU   X'80'               LOCDQ FUNCTION                       76720020
OQMREAD  EQU   X'40'               READ FUNCTION                        76790020
OQMDELE  EQU   X'20'               DELETE FUNCTION                      76860020
OQMENQ   EQU   X'10'               ENQUE FUNCTION                       76930020
OQMUCB   EQU   X'08'               UCB FUNCTION                         76950000
OQMUCBAD DS    A                   UCB ADDR                             76970000
OQM1STSM DS    XL3                 TTR OF FIRST SMB/DSB FOR JOB         77000020
         DS    0D                                                       77070020
         IEFQMNGR                                                       77140020
QMPCA    DS    F                   CORE ADDR OF DSB/SMB BUFFER          77210020
QMPEX    DS    XL3                 DISK ADDR OF DSB/SMB (TTR)           77280020
         DS    XL1                 Z OF TTRZ IN DSB/SMB ADDR            77350020
QMPALTH  EQU   *-QMNAM             LENGTH OF QMPA                       77420020
SMBBUF   DS    176XL1              SMB BUFFER                           77490020
DSBBUF   EQU   SMBBUF              DSB BUFFER                           77560020
         DS    F                   PLACE FOR PUTLINE TO PUT LL          77630020
SMBWORK  DS    CL1                 AREA TO DEBLOCK & DECOMPRESS-        77700020
SMBWORK1 DS    CL165               SYSTEM MESSAGES                      77770020
QMLNGTH  EQU   *-QMNAM             LENGTH OF CORE FOR Q-MANAGER         77840020
LDQJBPTR DS    A                   ADDR OF JOBNAME LIST                 77910020
LDQNPTR  DS    A                   ADDR OF NO. OF JOB NAMES             77980020
LDQNNPTR DS    A                   ADDR OF NN OF QCR                    78050020
LDQINFOP DS    A                   ADDR OF INFO AREA                    78120020
LDQNFNDP DS    A                   ADDR OF NO. OF JOBS FOUND            78190020
LDQQLSTP DS    A                   ADDR OF LIST OF Q ENTRIES            78260020
LDQEIPP  DS    A                   ADDR OF THE ECB/IOB PTR              78330020
LDQNN    DS    F                   NN OF Q TO BE SEARCHED               78400020
LDQNFND  DS    F                   NO. OF JOBS FOUND                    78470020
LDQEIP   DS    A                   ECB/IOB PTR                          78540020
LDQFIXLN EQU   *-OQMPARM           LENGTH OF FIXED PART OF LIST         78610020
LDQJB    DS    D                   JOB NAME LIST                        78680020
LDQINFO  EQU   *                   INFORMATION AREA                     78750020
LDQPOS   DS    F                   POSITION OF JOB IN Q                 78820020
*                                 *ZERO IF NOT FOUND                    78890020
LDQPRI   DS    F                   PRIORITY OF JOB                      78960020
LDQSTA   DS    F                   STATUS OF JOB                        79030020
LDQJBNN  DS    F                   NN OF JOB'S ENTRY IN Q               79100020
LDQINFOL EQU   *-LDQINFO           LENGTH OF LDQINFO ENTRY              79170020
LDQQLST  EQU   *                   LIST OF Q ENTRIES                    79240020
LDQQMNAM DS    D                   JOB NAME                             79310020
LDQQMPOP DS    XL1                 FUNCTION CODE PARAMETER              79380020
LDQQMFLT DS    XL2                 1ST LOG TRK ASGND TO JOB             79450020
LDQQMTST DS    XL1                 NO. RECS. USED IN LOG. TRK           79520020
LDQQMTLN DS    XL2                 REL. ADDR OF NEXT LOG. TRK           79590020
LDQQMNOT DS    XL1                 NO. LOGICAL TRK ASGND TO JOB         79660020
LDQQMTPY DS    XL1                 JOB TYPE                             79730020
LDQQMSTA DS    XL1                 JOB STATUS                           79800020
LDQQMPRI DS    XL1                 JOB PRIORITY                         79870020
LDQQMLNK DS    XL2                 REL. ADDR OF NEXT Q ENTRY            79940020
LDQQLSTL EQU   *-LDQQLST           LENGTH OF LTH (QMPA)                 80010020
LDQVARLN EQU   *-LDQJB             LENGTH OF VARIABLE PARMS             80080020
         EJECT                                                          80150020
SAVEAREA DSECT                                                          80220020
         DS    F                   RESERVED                             80290000
SAVBACK  DS    F                   ADDR OF CALLERS SAVE AREA            80360000
SAVFORW  DS    F                   ADDR OF CALLED SAVE AREA             80430000
         DS    15F                 REST OF SAVE AREA                    80500000
SAVEND   EQU   *                                                        80570020
SAVLTH   EQU   SAVEND-SAVEAREA                                          80640020
         IKJDAPL                                                        80740000
DAPLSTLN EQU   DAPLPSCB-DAPL       LENGTH OF STANDARD PART OF PARMS     80840000
DAPLLTH  EQU   *-DAPL              LENGTH OF DAPL                       80940000
DA08STAR EQU   *                   START OF DAIR PARM BLOCK             81270020
DAPB08   DSECT                     START DSECT EARLY SO WE CAN          81290000
         ORG   *+DAPLLTH           ORG TO BEGINNING OF GETMAIN          81310000
         IKJDAP08                                                       81340020
DAPB08   DSECT                                                          81410020
DA08END  EQU   *                   END OF ALLOCATE BLOCK                81480020
DA08LTH  EQU   DA08END-DAPB08      LENGTH OF ALLOCATE BLOCK             81550020
DAPB18   DSECT                                                          81620020
         ORG   *+DAPLLTH           ORG TO BEGINNING OF GETMAIN          81820000
         IKJDAP18                                                       82110020
DA18FRDL EQU   DA18DDN-DA18FLG     LENGTH OF FLAG, RETURN CODE &        82180020
*                                  DSNAME PTR                           82250020
DAPB18   DSECT                                                          82320020
DA18END  EQU   *                   END OF UNALLOCATE BLOCK              82390020
DA18LTH  EQU   DA18END-DAPB18      LENGTH OF UNALLOCATE BLOCK           82460020
         EJECT                                                          82530020
*THE FOLLOWING CODES ARE PASSED TO IKJEFF67 THE MESSAGE PROCESSOR.      82630000
M        EQU   107                 SYSOUT DATASET I/O ERROR             82730000
M0       EQU   0                   MODE MSG PUTGET                      82830000
M4       EQU   16                  DAIR ERROR                           82930000
M5       EQU   114                 Q/MANAGER ERROR                      83030000
M6       EQU   125                 UNLIKE ATTRIBUTES                    83130000
M7       EQU   118                 JOB NOT FOUND                        83230000
M8       EQU   129                 PRINT DATASET I/O ERROR              83330000
M12      EQU   117                 INTERRUPTED OUTPUT RESUMED           83430000
M13      EQU   108                 OPEN OUTPUT FAILED                   83530000
M14      EQU   102                 VOLUME NOT MOUNTED                   83630000
M15      EQU   121                 NO MULTI-VOL DATASETS                83730000
M18      EQU   40                  PUTLINE ERROR                        83830000
M130     EQU   130                 DS NOT ON VOLUME                     84230000
         IKJOCMTB                                                       84670000
TERMPARM DSECT                                                          85330020
TERMUPT  DS    A                   ADDR OF UPT                          85400020
TERMECT  DS    A                   ADDR OF ECT                          85470020
TERMECBA DS    A                   ADDR OF ATTENTION ECB                85540020
TERMSTAN EQU   *-TERMPARM          LENGTH OF STANDARD PART              85610020
*        OF PARM LIST                                                   85680020
*                                  OF PARM LIST                         85750020
TERMPUTA DS    A                   ADDR OF LIST PART OF PUTLINE         85820020
TERMPUT  PUTLINE MF=L              LIST PART OF PUTLINE                 85890020
TERMLNTH EQU   *-TERMPARM          LENGTH OF PUTLINE CORE               85960020
         EJECT                                                          86030020
*        *     *                                                        86100020
* THIS ROUTINE SIMULATES GET USING BSAM READ/CHECK. DOUBLE              86170020
* BUFFERING IS USED UNLESS CORE AVAILABLE IS SUFFICIENT ONLY FOR        86240020
* SINGLE BUFFERING. GET LOCATE IS NOT USED BECAUSE NOTE/POINT           86310020
* WOULD NOT BE AVAILABLE FOR USE IN BACKSPACE PAGE.                     86380020
IKJEFFGT CSECT                                                          86450000
         SAVE  (14,12),,*          SAVE CALLERS REGISTERS               86520020
         BALR  R12,0               ESTABLISH ADDRESSABILITY             86590020
         USING *,R12               FOR IKJEFF62                         86660020
         LR    R3,R1               SAVE PARM REGISTER                   86730020
         USING OUTCOMTB,R3         GET OUTCOMTB ADDRESSABILITY          86800020
         GETMAIN R,LV=SAVLTH       GET SAVEAREA                         86870020
         USING SAVEAREA,R1         ADDRESSABILITY FOR NEW AREA          86940020
         ST    R13,SAVBACK         STORE BACK PTR IN NEW AREA           87010020
         USING SAVEAREA,R13        ADDRESSABILITY FOR OLD AREA          87080020
         ST    R1,SAVFORW          STORE FORWARD PTR IN OLD AREA        87150020
         LR    R13,R1              ESTABLISH NEW SAVE AREA              87220020
*                                    ADDRESSABILITY                     87290020
          L     R11,OUTIDSP          GET ADDR OF DCB ETC.               87360020
          USING IDSCORE,R11          GET DCB ADDRESSABILITY             87430020
         LR    R8,R11              FIX SO DCBD                          87500020
         USING IHADCB,R8            LABELS CAN BE USED.                 87570020
          L     R6,OUTQMPAR          GET ADDR OF Q/M PARMS              87640020
          USING OQMPARM,R6          GET Q/M PARM ADDRESSABILITY         87710020
          LA    R6,DSBBUF            GET ADDR OF DSB                    87780020
          USING DSBMAP,R6            GET DSB ADDRESSABILITY             87850020
         SR    R7,R7                 CLEAR FOR INSERT CHAR              87920020
         IC    R7,DSBTIOLN           LENGTH OF TIOT ENTRY IN DSB        87990020
         LA    R7,DSBBASE(R7,R6)     ADD LENGTH OF DSB TIOT ENTRY       88060020
         USING DSBXXX,R7             GET ADDRESSABILITY FOR DSB         88130020
*                                    AFTER TIOT ENTRY                   88200020
         TM    IDSSW,OLDSW           IS THIS THE FIRST GET              88270020
         BO    CKLTHLFT              NO, SKIP DCBEODAD & SYNAD          88340020
*                                    INITIALIZATION                     88410020
         LA    R1,EOD                ADDR OF EOD RETURN CODE SETUP      88480020
         ST    R1,DCBEODAD           PUT IT IN DCB                      88550020
         O     R1,IDSEOV           GET EOV FLAG                         88570000
         ST    R1,IDSEOV           ENTER EOD ROUTINE ON EOV             88590000
         LA    R0,SYN                ADDR OF SYN RETURN CODE SETUP      88620020
         ST    R0,DCBSYNAD           PUT IT IN DCB                      88690020
CKLTHLFT EQU   *                                                        88760020
         L     R4,BUFFAD           ESTABLISH ADDRESSABILITY FOR         88830020
         USING GETAB,R4            GETAB,DECB'S,BUFFERS, ETC.           88900020
         L     R0,LTHLEFT          GET THE NO. OF BYTES LEFT IN         88970020
         LTR   R0,R0               BLOCK. IS IT ZERO                    89040020
         BP    DEBLOCK             NO, SKIP READING ANOTHER BLK         89110020
         L     R5,DECBPTR          ESTABLISH ADDRESSABILITY FOR         89180020
         USING DECB,R5             PRIME OR ALTENATE DECB               89250020
*                                  DEPENDING ON VALUE IN DECBPTR        89320020
         L     R0,RECSTART         GET THE ADDRESS OF THE NEXT          89390020
         LTR   R0,R0               LOGICAL RECORD. IS IT ZERO           89460020
         BP    TST1BUF             NO, SKIP PRIMING BUFFER AND          89530020
*                                  IF GET WAS ISSUED IN BACKSPCE        89600020
*                                  ROUTINE.SKIP CHECK ON                89670020
*                                  ALTERNATE DECB                       89740020
CKRESUM  EQU   *                                                        89810020
         TM    IDSSW,RESUME        WAS HERE SPECIFIED                   89880020
         BNO   READ                RTN, NO, SKIP POINT                  89950020
         L     R0,MASK             IS SINGLE BUFFERING BEING USE        90020020
         LTR   R0,R0               YES, SKIP CHECK OF ALTERNATE         90090020
         BZ    POINT               DECB                                 90160020
        TM    IDSSW,OLDSW          WAS INPUT JUST OPENED                90230020
         BNO   POINT               YES, SKIP CHECK OF ALT DECB          90300020
         CHECK DECB                CHECK ALTERNATE DECB                 90370020
POINT    EQU   *                                                        90440020
         LR    R1,R11              GET ADDR OF DCB                      90510020
         L     R0,DSBHOLD          GET TTR                              90580020
         IC    R0,ZIP              ZERO THE VOL NO. FOR Z OF TTR        90650020
         ST    R0,TEMP             SAVE TTRZ                            90720020
         LA    R0,TEMP             PASS ADDR OF TTR TO POINT            90790020
         POINT (R1),(R0)           ISSUE POINT                          90860020
         B     READ                ISSUE READ NORMALLY USED FOR         90930020
*                                  SINGLE BUFFERING TO PRIME            91000020
*                                  FIRST BUFFER FOR DOUBLE BUFF         91070020
TST1BUF  EQU   *                                                        91140020
         L     R0,MASK             IF SINGLE BUFFERING, SKIP            91210020
         LTR   R0,R0               READ USED TO PRIME FOR               91280020
         BNZ   CHECK               DOUBLE BUFFS AND READ NORMALLY       91350020
*                                  FOR SINGLE BUFFS                     91420020
READ     READ  DECB,SF,,,'S',MF=E  READ INTO ALTERNATE BUFFER           91490020
CHECK    EQU   *                                                        91560020
         CHECK DECB                CHECK ALTERNATE DECB                 91630020
         XC    DECBPTR,MASK        POINT TO ALTERNATE DECB              91700020
         L     R5,DECBPTR          FIX DECB ADDRESSABILITY              91770020
         NOTE  IHADCB              GET TTR OF CURREN BLOCK              91840020
         IC    R1,DSBVOL           SAVE EOV COUNT IN Z OF TTRZ          91910020
         ST    R1,DSBHOLD          PUT TTR & VOLCOUNT IN NEW            91980020
*                                  CURRENT ENTRY OF BACKSPACE           92050020
*                                  TABLE                                92120020
         L     R0,MASK             GET MASK. IF IT IS ZERO.             92190020
         LTR   R0,R0               SINGLE BUFFERING IS BEING            92260020
         BZ    STRECCT             USED. SKIP READ USED IN DOUBLE       92330020
         READ  DECB,SF,,,'S',MF=E  BUFFERING                            92400020
STRECCT  EQU   *                                                        92470020
         SR    R1,R1               ZERO RECCOUNT IN THE NEW             92540020
         STH   R1,DSBPOS           CURRENT ENTRY OF BACKSPACE           92610020
*                                  TABLE                                92680020
         XC    DECBPTR,MASK        POINT TO ALTERNATE DECB              92750020
         L     R5,DECBPTR          FIX DECB ADDRESSABILITY              92820020
         MVC   RECSTART,DECAREA    SAVE ADDR OF FIRST LOGICAL           92890000
         L     R1,DECIOBPT         ESTABLISH ADDRESSABILITY FOR         92960020
         USING IOB,R1              IOB. DECB POINT TO IOB               93030020
         XC    DECBPTR,MASK        POINT TO ALTENATE DECB               93100020
         L     R5,DECBPTR          FIX DECB ADDRESSABILITY              93170020
         LH    R0,DCBBLKSI         DETERMIN ACTUAL BLOCKSIZE BY         93240020
         SH    R0,IOBCSW+5         SUBTRACTING RESIDUAL COUNT IN        93310020
         DROP  R1                                                       93380020
         ST    R0,LTHLEFT          IOBCSW. STORE IN LTHLEFT             93450020
         TM    DCBRECFM,FIXSW      IS RECFM FIXED OR UNDEFINED          93520020
         BO    DEBLOCK             YES, SKIP ADJUSTMENT FOR LL          93590020
         L     R0,FOURY            SET   RECSTART PAST LL FOR           93660020
         A     R0,RECSTART         THE VARIABLE BLOCK                   93730020
         ST    R0,RECSTART         LL IS 4 BYTES                        93800020
         L     R0,LTHLEFT          SUBTRACT FOUR (LL FOR VARIABL        93870020
         S     R0,FOURY            BLOCK) FROM LTHLEFT (ACTUAL          93940020
         ST    R0,LTHLEFT          SIZE OF BLOCK READ)                  94010020
DEBLOCK  EQU   *                                                        94080020
         TM    DCBRECFM,FIXSW      IS RECFM FIXED OR UNDEFINED          94150020
         BO    TSTUNDF             YES, SKIP- STORE OF LRECL            94220020
         L     R1,RECSTART         GET THE ADDRESS OF LL                94290020
         MVC   DCBLRECL,0(R1)      MOVE LL INTO DCB LRECL               94360000
         B     SKIPUNDF            SKIP STORE OF LRECL FOR U-TYP        94430020
TSTUNDF  EQU   *                                                        94500020
         TM    DCBRECFM,VARSW      IF BOTH THE FIXED & VARIABLE         94570020
         BZ    SKIPUNDF            BITS ARE ON RECFM=U.IF NOT           94640020
*                                  SKIP STORE OF LRECL FOR U-TYP        94710020
         MVC   DCBLRECL,LTHLEFT+2  STORE ACTUAL SIZE OF BLOCK           94780000
*                                    READ IN LRECL                      94850020
SKIPUNDF EQU   *                                                        94920020
         L     R0,LTHLEFT          DECREMENT NO. OF BYTES LEFT          94990020
         SH    R0,DCBLRECL         IN BLOCK BY LOGICAL REC. SIZE        95060020
         ST    R0,LTHLEFT                                               95130020
         LH    R1,DSBPOS           ADD ONE TO RECCOUNT SO THAT          95200020
         AH    R1,ONEY             WHEN NEWCURNT IS MOVED TO            95270000
         STH   R1,DSBPOS           NEWZERO, RECCOUNT POINTS TO          95340020
*                                  RECORD IN BLOCK THAT WAS AT          95410020
         SR    R15,R15               SET UP NORMAL RETURN CODE          95480020
RETURN   EQU   *                                                        95550020
         L     R1,RECSTART         RETURN ADDRESS OF NEXT               95620020
         ST    R1,OUTRECA          LOGICAL RECORD                       95690020
         LR    R0,R1                                                    95760020
         AH    R0,DCBLRECL         ADD LOGICAL RECORD LENGTH TO         95830020
         ST    R0,RECSTART         THE LOGICAL RECORD POINTER SO        95900020
*                                  IT POINTS TO NEXT LOGICAL REC        95970020
         LR    R1,R13              SAVE ADDR OF CURRENT SAVEAREA        96040020
          L     R13,SAVBACK         GET ADDR OF PREVIOUS SAVEAREA       96110020
          FREEMAIN R,LV=SAVLTH,A=(1)  FREE CURRENT SAVEAREA             96180020
          RETURN (14,12),T,RC=(15)   RETURN                             96250020
EOD      EQU   *                                                        96320020
         L     R15,FOURY             INDICATE EOD ENTERED               96390020
         B     RETURN                RETURN                             96460020
SYN      EQU   *                                                        96530020
         STM   R0,R1,SYN0AND1      SAVE SYNAD REGS                      96600020
         L     R15,EIGHTY            INDICATE SYNAD DETECTED            96670020
         B     RETURN                RETURN                             96740020
EIGHTY   DC    F'8'                  CONSTANT OF EIGHT                  96810020
ONEY     DC    H'1'                CONSTANT OF ONE                      96840000
FOURY   DC    F'4'                   CONSTANT OF 4                      96880020
FIXSW   EQU   X'80'                  FIXED TYPE DCBRECFM                96950020
VARSW   EQU   X'40'                  VARIABLE TYPE DCBRECFM             97020020
ZIP       EQU   FOURY               3 BYTES OF ZERO                     97090020
         END                                                            97160020
OUTCPPL  DS    A                   ADDR OF CPPL                         97230020
