          TITLE 'ENQUE REMQINING JOBS IKJEFF64 OUTPUT CP'               00200020
*STATUS - CHANGE LEVEL 0                                                00400020
*                                                                       00450021
* A454500                                                        SM4187 00500021
* C 090000-094000,310000,352000,354000                           A56936 00510021
* A 310800 ,311600,312400,313200,353000,355000,508900            A56936 00520021
*                                                                       00550021
*FUNCTION                                                               00600020
*        THIS IS A CLEANUP MODULE, ENTERED ON THREE OCCASIONS,          00800020
*        EACH OF WHICH CAUSES EARLY TERMINATION OF THE OUTPUT CP-       01000020
*        1) WHEN THE OUTPUT CP DETECTS A SERIOUS ERROR, 2) WHEN         01200020
*        THE END SUBCOMMAND IS ENTERED, 3) WHEN ATTENTION TAKES         01400020
*        CONTROL AWAY, AND 4) WHEN AN ABEND OCCURS.  IN 1) CONT-        01600020
*        ROL IS RECEIVED FROM IKJEFF62, IN 2) CONTROL IS RECEIVED       01800020
*        FROM IKJEFF63, AND IN 3) AND 4) CONTROL IS RECEIVED FROM       02000020
*        THE STAE EXIT IN IKJEFF60.                                     02200020
*                                                                       02400020
*        IN EACH OF THESE CASES THE OUTPUT CP MAY LEAVE A JOB           02600020
*        ONLY PARTIALLY PROCESSED WITH POSSIBLY ADDITIONAL JOBS         02800020
*        DEQUED FROM THE SAME OUTPUT CLASS.  THIS ROUTINE WILL          03000020
*                                                                       03200020
*        ENQUE THESE JOBS.  OUTPUT QUEUE RECORDS (DSB'S AND SMB'S)      03400020
*        THAT HAVE ALREADY BEEN PROCESSED IN THE CURRENT JOB ARE        03600020
*        ELIMINATED.                                                    03800020
*                                                                       04000020
*        THE FIRST CHECK MADE BY THIS MODULE IS FOR ANY JOBS HAV-       04200020
*        ING BEEN DEQUED OFF THE OUTPUT QUEUE.  IF NONE HAVE, THE       04400020
*        ROUTINE RETURNS IMMEDIATELY TO THE CALLER.  IF ONE OR          04600020
*        MORE JOBS HAVE BEEN DEQUED AND A DSB OR SMB IS BEING           04800020
*        PROCESSED THAT IS NOT THE FIRST OF THE JOB'S OUTPUT            05000020
*        QUEUE RECORDS, A NEW SMB IS CREATED WITH THE MESSAGE IK-       05200020
*        JEF102I (INTERRUPTED OUTPUT RESUMED).  THIS SMB IS WRIT-       05400020
*        TEN AS THE FIRST OF THE JOB'S OUTPUT QUEUE RECORDS AND         05600020
*        IS CHAINED TO THE CURRENT DSB/SMB (THEREBY CUTTING OUT         05800020
*        THE RECORDS IN BETWEEN THAT HAVE BEEN PROCESSED).              06000020
*                                                                       06200020
*        IF A DSB WAS BEING PROCESSED, IT IS WRITTEN BACK ONTO          06400020
*        THE QUEUE IN PLACE- ITS RECORD POINTER (TTR) POINTING TO       06600020
*        THE LAST RECORD WRITTEN (IF OUTPUT WAS TO ANOTHER DATA         06800020
*        SET) OR TO APPROXIMATELY TEN RECORDS EARLIER (IF OUTPUT        07000020
*        WAS TO THE TERMINAL).  THE CURRENT JOB IS ENQUED SIMUL-        07200020
*        TANEOUSLY WITH THE LAST-WRITTEN CONTROL BLOCK.  ADDITI-        07400020
*        ONAL DEQUED JOBS ARE PUT BACK ON THE OUTPUT QUEUE WITH-        07600020
*        OUT ANY PROCESSING.                                            07800020
*                                                                       08000020
*ENTRY POINT - IKJEFF64                                                 08200020
*                                                                       08400020
*INPUT - ADDRESS OF OUTCOMTB IN REGISTER 1                              08600020
*                                                                       08800020
*EXITS - 1. SVC 100 TO GET TO IKJEFF61 TO:                       A56936 09000021
*            A.  ENQUEUE ANY REMAINING JOBS                      A56936 09100021
*            B.  WRITE OUTPUT Q RCDS W/O ENQUEING JOBS           A56936 09200021
*            C.  WRITE OUTPUT Q RCDS WITH ENQUEING JOBS          A56936 09300021
*            D.  DELETING BLOCKS ALREADY PROCESSED               A56936 09400021
*                                                                       09600020
*EXTERNAL REFERENCES - NONE                                             09800020
         EJECT                                                          10000020
IKJEFF64 CSECT                                                          10200020
** HEAD1       /*TSO OUTPUT COMMAND PROCESSOR*/;                        10400020
** HEAD2       /*END SUBCOMMAND*/;                                      10600020
** HEAD3       /*IKJEFF67*/;                                            10800020
** IKJEFF64: T ENTER;                                                   11000020
DSBBLK   EQU   X'FF'               DSB INDICATOR                        11200020
FIB      EQU   100                 SVC 100                              11300020
L164     EQU   164                                                      11400020
MSG114   EQU   114                 ID FOR MSG IKJ56313I                 11600020
MSGLNTH  EQU   35                  LENGTH OF MESSAGE IKJEF102I          11800020
ONE      EQU   1                                                        12000020
QMGR     EQU   90                  Q MANAGER SVC                        12100020
R0       EQU   0                   REGISTER 0                           12200020
R1       EQU   1                   REGISTER 1                           12400020
R2       EQU   2                   REGISTER 2                           12600020
R3       EQU   3                   REGISTER 3                           12800020
R4       EQU   4                   REGISTER 4                           13000020
R5       EQU   5                   REGISTER 5                           13200020
R6       EQU   6                   REGISTER 6                           13400020
R7       EQU   7                   REGISTER 7   BASE FOR DSB            13600020
R8       EQU   8                   REGISTER 8   BASE FOR DSB            13800020
R9       EQU   9                   REGISTER 9   BASE FOR IOPARAMS       14000020
R10      EQU   10                  REGISTER 10  BASE FOR OUTCOMTB       14200020
R11      EQU   11                  REGISTER 11  BASE FOR IDSCORE        14400020
R12      EQU   12                  REGISTER 12  BASE FOR IKJEFF64       14600020
R13      EQU   13                  REGISTER 13                          14800020
R14      EQU   14                  REGISTER 14                          15000020
R15      EQU   15                  REGISTER 15                          15200020
S213     EQU   X'80'               S213 ABEND                           15300000
THREE    EQU   3                                                        15400020
ZERO     EQU   X'00'                                                    15600020
         EJECT                                                          15800020
         SAVE  (14,12),,*                                               16000020
         BALR  R12,0               ESTABLISH ADDRESSABILITY             16200020
         USING *,R12               FOR IKJEFF68                         16400020
         LR    R10,R1              SAVE PARM REG                        16600020
         USING OUTCOMTB,R10        ADDRESSABILITY FOR OUTCOMTB          16800020
         LA    R1,OUTSAV64         ADDRESSABILITY FOR SAVE AREA         17000020
         USING OUTSAV64,R1                                              17200020
         ST    R13,OUTSVBK          STORE BACK PTR IN NEW AREA          17400020
         USING OUTSAV64,R13        ADDRESSABILITY FOR OLD AREA          17600020
         ST    R1,OUTSVFWD         STORE FWD PTR IN OLD AREA            17800020
         LR    R13,R1              ESTABLISH NEW SAVE AREA              18000020
         EJECT                                                          18200020
*                             DETERMINE IF CORE FOR Q-MGR PARMS         18400020
*                             HAVE BEEN OBTAINED AND IF SO WHETHER      18600020
*                             A JOB IS BEING PROCESSED                  18800020
         L     R9,OUTQMPAR         ADDR OF Q-MGR PARAMETERS             19000020
         LTR   R9,R9               CHECK FOR THEIR EXISTENCE            19200020
**           D ANY JOBS DEQUEUED;                                       19400020
         BZ    RETURN              BRANCH IF THEY DO NOT                19600020
**           IF NO  GO TO RETURN; ELSE YES;                             19800020
         USING IOPARAMS,R9         ADDRESSABILITY FOR PARMS             20000020
         CLC   OQM1STSM,ZEROS      IF NOT ZERO,CONTAINS TTR OF          20200020
*                                  1ST SMB/DSB                          20400020
         BNE   CHKRCD              NO,CHECK IF DSB OR SMB               20460000
         XC    QMNAM(QMPALTH),QMNAM     ZERO QMPA                       20520000
**           D JOB IN PROCESS;                                          20600020
         B     ENQNXTJB            GO ENQ POSSIBLE OTHER JOBS           20800000
*                                  PROCESSED                            21000020
**           IF NO GO TO CHKJOBS; ELSE YES;                             21200020
         SPACE                                                          21400020
*                             ESTABLISH ADDRESSABILITY FOR DSB          21600020
*                             WHICH CAN VARY IN SIZE -SEE MAP           21800020
CHKRCD   EQU   *                                                        21900000
         LA    R8,DSBBUF           ADDR OF DSB/SMB                      22000020
         USING DSBDSKAD,R8         NOW HAVE ADDR. FOR MIN. DSB          22200020
         SR    R7,R7               CLEAR FOR INSERT CHAR                22400020
         IC    R7,DSBTIOLN         LENGTH OF TIOT ENTRY IN DSB          22600020
         LA    R7,DSBBASE(R7,R8)   ADD LENGTH OF TIOT ENTRY             22800020
         USING DSBXXX,R7           ADDRESSABILITY FOR DSB BEYOND        23000020
*                                  TIOT ENTRY                           23200020
         SPACE                                                          23400020
*                             IF THE RECORD (DSB/SMB) IS A DSB          23600020
*                             AND THE OUTPUT WAS TO THE TERMINAL,       23800020
*                             PUT A NEW TTR IN THE DSB WHICH            24000020
*                             POINTS TO APPROXIMATELY 10 LINES          24200020
*                             EARLIER IN THE DATA SET                   24400020
         CLI   DSBFLAG,DSBBLK      IS BLOCK A DSB                       24600020
**           D  DSB OR SMB;                                             24800020
         BNE   CHK1STJB            BRANCH IF NOT (BLOCK IS SMB)         25000020
**           IF SMB GO TO CHIKSTJB; ELSE DSB;                           25200020
         L     R11,OUTIDSP         ADDR OF INPUT DS PARAMETERS          25206000
         LTR   R11,R11             HAS OPERATION COMPLETED              25212000
**           D  HAS OPERATION COMPLETED;                                25218000
         BNZ   CHKTERM             NO, BRANCH                           25224000
**           IF NO GO TO CHKTERM; ELSE YES;                             25230000
         CLC   DSBNXT,ZEROS        IS FORWARD POINTER ZERO              25242000
         BE    DELJOB              YES, DELETE JOB                      25254000
**           IF YES GOTO DELJOB; ELSE NO;                               25260000
**           P  MOVE PTR IN DSB TO NEXT Q RECORD INTO SELF PTR FIELD;   25266000
         MVC   DSBDSKAD,DSBNXT     NEXT PTR FIELD TO SELF PTR FLD       25272000
**           GOTO WRITESMB;                                             25278000
         B     WRITESMB            BRANCH                               25284020
DELJOB   EQU   *                 RETURN Q RECORDS TO FREE TRACK Q       25290000
**DELJOB:    P  DELETE JOB BY RETURNING Q RECORDS TO FREE TRACK Q;      25296000
         MVI   OQMFUNC,OQMDELE     SET DELETE CODE FOR IKJEFF61         25302000
**           GO TO GOTO61;                                              25308000
         B     GOTO61              BRANCH                               25314020
**           IF NO GO TO CHKTERM; ELSE YES;                             25320000
CHKTERM  EQU   *                                                        25330000
         L     R1,OUTTERM          ADDR OF PUTLINE CORE                 25356000
         LTR   R1,R1               WAS OUTPUT TO TERMINAL               25362000
**           D  WAS OUTPUT TO TERMINAL;                                 25368000
         BZ    CHK1STJB            YES, BRANCH -CURRENT TTR IS OK       25374000
**           IF NO  GO TO CHKISTJB; ELSE YES;                           25380000
**           P  SET RECORD PTR IN DSB BACK 10 LINES (APPROX);           27400020
         USING IDS,R11             ADDRESSABILITY FOR INPUT DS PARMS    27600020
         MVC   DSBHOLD(L'BAK10APX),BAK10APX CHG TTR BACK 10 LINES       27800020
         EJECT                                                          28000020
*                             WRITE BLOCK BACK ON THE Q IF IT IS        28200020
*                             A DSB AND NOT THE 1ST BLOCK OF JOB        28400020
CHK1STJB CLC   OQM1STSM,DSBDSKAD    IS DSB/SMB 1ST BLOCK OF JOB         28600020
** CHK1STJB: D  DSB/SMB 1ST CTRL BLOCK;                                 28800020
         BE    WRITE               YES, BRANCH                          29000020
**           IF YES GO TO WRITE; ELSE NO;                               29200020
         CLI   DSBFLAG,DSBBLK      IS BLOCK A DSB                       29400020
**           D  DSB OR SMB;                                             29600020
         BNE   WRITESMB            BRANCH IF NOT (BLOCK IS SMB)         29800020
**           IF SMB GO TO WRITESMB; ELSE DSB; SKIP 2C+1;                30000020
**           L (Q-MANAGER) WRITE DSB;                                   30200020
         MVC   QMPEX(L'DSBDSKAD),DSBDSKAD TTR OF THIS DSB               30400020
*                                  INTO PARM FIELD FOR QMPA             30600020
         MVI   QMPOP,QMWRTE        PUT FUNCTION BYTE IN QMPA            30800020
         MVI   OQMFUNC,OQMSVC       SET SVC 90 CODE FOR IKJEFF61 A56936 31000021
         LA    R1,OQMCPPL           PTR TO CPPL ADDR             A56936 31080021
         LA    R0,THREE             OUTPUT CP INDICATOR          A56936 31160021
         SVC   FIB                  WRITE ALTERED DSB ONTO Q     A56936 31240021
*                                      VIA IKJEFF61              A56936 31320021
         LTR   R15,R15             TEST FOR ZERO RETURN CODE            31400020
         BNE   SENDMSG             BRANCH IF NOT ZERO                   31600020
         SPACE                                                          31800020
*                             CREATE AND WRITE W/ENQ AN SMB WITH        32000020
*                             A MESSAGE INDICATING AN INTERRUPTION      32200020
*                             SMB WILL BE 1ST OF JOB'S BLOCKS           32400020
         USING SMBDSKAD,R8         DSB ADDRESSABILITY                   32600020
WRITESMB MVI   SMBMESAG,ZERO       ZERO MESSAGE FIELD                   32800020
** WRITESMB: P CREATE SMB CONTAINING MESSAGE IKJ56319J;                 33000020
         MVC   SMBMESAG+ONE(L164),SMBMESAG                              33200020
         MVC   SMBIDENT(IRPTMSGL),IRPTMSG  FILL IN REST OF SMB          33400020
*                                  FIELDS EXCEPT TTR'S                  33600020
         MVC   SMBNEXT(L'SMBDSKAD),SMBDSKAD   PUT SELF-PTR FROM         33800020
*                                  PREVIOUS BLOCK INTO NEXT PTR         34000020
*                                  IN THIS BLOCK                        34200020
         MVC   SMBDSKAD,OQM1STSM   MAKE 1ST BLOCK ADDR SELF-PTR         34400020
WRITE    MVC   QMPEX(L'OQM1STSM),OQM1STSM SAME TTR INTO PARM LIST       34600020
         MVI   QMPOP,QMWREN        PUT FUNCTION BYTE IN QMPA            34800020
** WRITE:    L (Q-MANAGER) WRITE WITH ENQUE;                            35000020
         MVI   OQMFUNC,OQMSVC       SET SVC 90 CODE FOR IKJEFF61 A56936 35200021
         LA    R1,OQMCPPL           PTR TO CPPL                  A56936 35300021
         LA    R0,THREE             OUTPUT CP INDICATOR          A56936 35400021
         SVC   FIB                  WRITE W/ENQ SMB VIA IKJEFF61 A56936 35500021
         LTR   R15,R15             TEST FOR ZERO RETURN CODE            35600020
         BNE   SENDMSG             BRANCH IF NOT ZERO                   35800020
         SPACE                                                          36000020
*                             ENQUE ANY REMAINING DEQUED JOBS           36200020
*                                ANY JOBS REMAINING? JOB POINTER        36400020
*                                & JOB COUNTER EQUAL IF THERE           36600020
*                                ARE NONE                               36800020
CHKJOBS  CLC   OUTJBPTR,OUTJBCNT   COMPARE JOB PTR & COUNTER            37000020
** CHKJOBS:  D OTHER JOBS POSSIBLY DEQUEUED # JOB POINTER AND           37200020
**             JOB COUNTER ARE NOT EQUAL;                               37400020
         BE    RETURN              BRANCH IF EQUAL                      37600020
**           IF NO GO TO RETURN; ELSE YES;                              37800020
**           L INCREMENT JOB POINTER # POINTS TO NEXT VALID             38000020
**             JOB SUBMITTED;                                           38200020
         L     R1,OUTJBPTR         INCREMENT JOB BEING                  38400020
         LA    R1,ONE(R1)          PROCESSED POINTER                    38600020
         ST    R1,OUTJBPTR                                              38800020
*                                INCREMENT LDQ PTRS TO FIND REM-        39000020
*                                AINING JOBS' LTH'S                     39200020
         L     R2,LDQINFOP         ADDR OF CURRENT INFO  AREA           39400020
         LA    R2,LDQINFOL(R2)     ADD LENGTH FOR NEXT INFO AREA        39600020
         ST    R2,LDQINFOP         STORE NEW ADDRESS                    39800020
         L     R3,LDQQLSTP         ADDR OF CURRENT Q LIST (LTH)         40000020
         LA    R3,LDQQLSTL(R3)     ADD LENGTH FOR NEXT Q LIST           40200020
         ST    R3,LDQQLSTP         STORE NEW ADDRESS                    40400020
**ENQNXTJB:  P  LOCATE JOB PARAMETERS;                                  40420000
ENQNXTJB L     R2,LDQINFOP         LOAD THESE ADDR AGAIN IN CASE        40440000
         L     R3,LDQQLSTP         ABOVE  LOADING WAS BYPASSED          40460000
*                                  (ADDR CORRECT FROM IKJEFF62 WHEN     40480000
*                                  JOB JUST COMPLETED, OR FROM          40500000
*                                  IKJEFF60, WHEN JOB NOT YET STARTED)  40520000
         USING LDQINFO,R2          ADDRESS. FOR NEW INFO AREA           40600020
         USING LDQQLST,R3          ADDRESS. FOR NEW Q LIST              40800020
         CLI   LDQPOS+THREE,ZERO   CHK ZERO IND. (JOB NOT FOUND)        41000020
**           D JOB FOUND (DEQUEUED);                                    41200020
         BE    CHKJOBS             BRANCH IF ZERO                       41400020
**           IF NO GO TO CHKJOBS; ELSE YES;                             41600020
**           P ENQUEUE JOB'S ONTO SAME OUTPUT CLASS AS BEFORE;          41800000
         SPACE                                                          42000020
*                             ENQUE JOB ONTO SAME OUTPUT Q              42200020
         MVC   QMNAM(LDQQLSTL),LDQQLST  MOVE LTH INTO QMPA              42400020
         MVI   OQMFUNC,OQMENQ      INDICATE ENQUE FUNCTION              42600020
         MVC   QMPCL,ZEROS         INDICATE ENQUE WITHOUT WRITE         42800020
         LA    R1,OQMCPPL          PTR TO CPPL ADDR                     43000020
**           P (SVC100) GO TO Q MGR VIA SVC100 & IKJEFF61;              43060000
GOTO61   LA    R1,OQMCPPL          PTR TO CPPL ADDR                     43120000
         LA    R0,R3               OUTPUT CP INDICATOR                  43200020
         SPACE                                                          43400020
         SVC   FIB                 EQUE JOB VIA IKJEFF61                43600020
         LTR   R15,R15             TEST FOR ZERO RETURN CODE            43800020
         BNE   SENDMSG             BRANCH IF NOT ZERO                   44000020
         SPACE                                                          44200020
**           GO TO CHKJOBS; SKIP;                                       44400020
         B     CHKJOBS             BRANCH                               44600020
         SPACE                                                          44800020
SENDMSG  EQU   *                   ISSUE MESSAGE IKJ56313I              45000020
         STH   R15,OUTRTCD         STORE RETURN CODE FOR MSG ROUTINE    45200020
         MVI   OUTMSGID,MSG114     STORE MESSAGE ID                     45400020
         LR    R1,R10              ADDR OF OUTCOMTB              SM4187 45450021
      SPACE                                                             45600021
         LINK  EP=IKJEFF67         MESSAGE MODULE                       45800020
         SPACE                                                          45850020
ANY      EQU   X'F0'                                                    45900020
         MVI   OUTRESUM,ANY        INDICATE ERROR TO FORCE RC12 TO TMP  45950020
         EJECT                                                          46000020
RETURN   EQU   *                                                        46200020
** RETURN:   T RETURN;                                                  46400020
         L     R13,OUTSVBK         GET ADDR OF PREVIOUS SAVE AREA       46600020
         RETURN (14,12),T,RC=0     RETURN                               46800020
ZEROS    DC    XL4'00'                                                  47000020
*                             CREATED SMB                               47200020
IRPTMSG  DC    X'05'               SMBIDENT                             47400020
         DC    8X'00'              SMBNEXT & SMBDUMMY                   47600020
         DC    X'0027'             SMBNABPT                             47800020
         DC    X'24'               SMBMSGLN                             48000020
         DC    C'IKJ56319I INTERRUPTED OUTPUT RESUMED'                  48200020
IRPTMSGL EQU   *-IRPTMSG           LENGTH                               48400020
         EJECT                                                          48600020
         IKJOCMTB                                                       48800020
         EJECT                                                          49000020
IOPARAMS DSECT                                                          49200020
OQMPARM  DS    0D                                                       49400020
OQMSIZE  DS    F                   SIZE OF GETMAIN                      49600020
OQMCPPL  DS    A                   ADDR OF CPPL                         49800020
OQMFUNC  DS    XL1                 FUNC INICATION FOR IKJEFF61          50000020
OQMLOCDQ EQU   X'80'               LOCDQ FUNCTION                       50200020
OQMREAD  EQU   X'40'               READ FUNCTION                        50400020
OQMDELE  EQU   X'20'               DELETE FUNCTION                      50600020
OQMENQ   EQU   X'10'               ENQUE FUNCTION                       50800020
OQMUCB   EQU   X'08'               UCB FUNCTION                         50860000
OQMSVC   EQU   X'04'                SVC 90 FUNCTION              A56936 50890021
OQMUCBAD DS    A                   UCB ADDR                             50920000
OQM1STSM DS    XL3                 TTR OF FIRST SMB IN JOB              51000020
         DS    0D                                                       51200020
         IEFQMNGR                                                       51400020
QMPCA    DS    F                   CORE ADDR OF DSB/SMB BUFFER          51600020
QMPEX    DS    F                   DISK ADDR OF DSB/SMB                 51800020
QMPALTH  EQU   *-QMNAM             LENGTH OF QMPA                       52000020
SMBBUF   DS    176XL1              SMB BUFFER                           52200020
DSBBUF   EQU   SMBBUF              DSB BUFFER                           52400020
         DS    F                   PLACE FOR PUTLINE TO PUT LL          52600020
SMBWORK  DS    CL1                 AREA TO DEBLOCK & DECOMPRESS         52800020
SMBWORK1 DS    CL165               SYSTEM MESSAGES                      53000020
QMLNGTH  EQU   *-QMNAM             LENGTH OF CORE FOR Q-MANAGER         53200020
LDQJBPTR DS    A                   ADDR OF JOBNAME LIST                 53400020
LDQNPTR  DS    A                   ADDR OF NO. OF JOB NAMES             53600020
LDQNNPTR DS    A                   ADDR OF NN OF QCR                    53800020
LDQINFOP DS    A                   ADDR OF INFO AREA                    54000020
*                                  ADDR OF INFO AREA OF JOB             54200020
*                                  BEING PROCESSED                      54400020
LDQNFNDP DS    A                   ADDR OF NO. OF JOBS FOUND            54600020
LDQQLSTP DS    A                   ADDR OF LIST OF QMPA'S (LTH'S)       54800020
*                                  ADDR OF QMPA (LTH) OF JOB            55000020
*                                  BEING PROCESSED                      55200020
LDQEIPP  DS    A                   ADDR OF THE ECB/IOB PTR              55400020
LDQNN    DS    F                   NN OF Q TO BE SEARCHED               55600020
LDQNFND  DS    F                   NO. OF JOBS FOUND                    55800020
LDQEIP   DS    A                   ECB/IOB PTR                          56000020
LDQFIXLN EQU   *-OQMPARM           LENGTH OF FIXED PART OF LIST         56200020
LDQJB    DS    D                   JOB NAME LIST                        56400020
LDQINFO  EQU   *                   INFORMATION AREA                     56600020
LDQPOS   DS    F                   POSITION OF JOB IN Q                 56800020
*                                 *ZERO IF NOT FOUND                    57000020
LDQPRI   DS    F                   PRIORITY OF JOB                      57200020
LDQSTA   DS    F                   STATUS OF JOB                        57400020
LDQJBNN  DS    F                   NN OF JOB'S ENTRY IN Q               57600020
LDQINFOL EQU   *-LDQINFO           LENGTH OF LDQINFO ENTRY              57800020
LDQQLST  EQU   *                   LIST OF QMPA'S (LTH'S)               58000020
LDQQMNAM DS    D                   JOB NAME                             58200020
LDQQMPOP DS    XL1                 FUNCTION CODE PARAMETER              58400020
LDQQMFLT DS    XL2                 1ST LOG TRK ASGND TO JOB             58600020
LDQQMTST DS    XL1                 NO. RECS. USED IN LOG. TRK           58800020
LDQQMTLN DS    XL2                 REL. ADDR OF NEXT LOG. TRK           59000020
LDQQMNOT DS    XL1                 NO. LOGICAL TRK ASGND TO JOB         59200020
LDQQMTPY DS    XL1                 JOB TYPE                             59400020
LDQQMSTA DS    XL1                 JOB STATUS                           59600020
LDQQMPRI DS    XL1                 JOB PRIORITY                         59800020
LDQQMLNK DS    XL2                 REL. ADDR OF NEXT Q ENTRY            60000020
LDQQLSTL EQU   *-LDQQLST           LENGTH OF LTH (QMPA)                 60200020
LDQVARLN EQU   *-LDQJB             LENGTH OF VARIABLE PARMS             60400020
         EJECT                                                          60600020
SMBDSECT DSECT                                                          60800020
         IEFAJCTB                                                       61000020
SMBCMTLN EQU   SMBMESAG            COMPRESSED MESS TOTAL LENGTH         61200020
SMBNBLKS EQU    SMBMESAG           NO. OF BLANKS BETWEEN FIELDS         61400020
SMBFLDLN EQU   SMBMESAG+1          COMPRESSED MESS FIELD LENGTH         61600020
SMBFIELD EQU   SMBMESAG+2          COMPRESSED MESS FIELD                61800020
SMBDCOMP EQU   X'FE'               COMPRESSED MSG INDICATOR             62000020
         EJECT                                                          62200020
*                                                                       62400020
*                                                                       62600020
*                       DATA SET BLOCK (DSB)                            62800020
*                                                                       63000020
*                                                                       63200020
DSBMAP   DSECT                                                          63400020
         DS    0F                                                       63600020
DSBDSKAD DS    XL3                 TTR OF THIS DSB                      63800020
DSBTABID DS    XL1                 TABLE ID                             64000020
DSBNXT   DS    XL3                 TTR OF NEXT DSB                      64200020
         DS    XL2                 RESERVED                             64400020
DSBPCCPY DS    XL1                 NO.OF COPIES OF SYSOUT DATASET       64600020
DSBPCPTN DS    H                   LAST TWO CHARS OF TEST PTRN.MEM.NAME 64800020
DSBLGOUT DS    XL1                 LOG OUT BITS                         65000020
         DS    XL1                 RESERVED                             65200020
DSBFLAG  DC    X'FF'               STATUS BYTE TO DISINGUISH FROM SMB   65400020
DSBWSMNT DS    XL1                WARM START INDICATOR THAT             65600020
*                                 VOLUME NOT MOUNTED                    65800020
NOTMNTED EQU   X'80'               ON MEANS FIRST VOL. NOT MNTD         66000020
*                                  AT WARM START                        66200020
DSBTIOLN DS    XL1                 LENGTH OF TIOT PORTION OF DSB        66400020
DSBSTTA  DS    XL1                 STATUS -A-                           66600020
DSBRLOC  DS    H                   REL. LOC OF POOL                     66800020
DSBDDNAM DS    CL8                 DDNAME OF SPOOLED OUTPUT DATASET     67000020
DSBJFCB  DS    XL3                 JFCB DISK ADDRESS                    67200020
DSBSTTC  DS    XL1                 STATUS -C-                           67400020
DSBSTTB  DS    XL1                 STATUS -B-                           67600020
         DS    XL1                 RESERVED                             67800020
DSBFSRT  DS    XL2                 SRT ADDRESS                          68000020
*  DISPLACEMENTS FROM THIS POINT ON MAY BE INCORRECT FOR TIOT           68200020
*  ENTRIES LONGER THAN THE MINIMUM. DSBTIOLN SHOUL BE USED              68400020
*  IN ESTABLISHING ADDRESSABILITY FOR THE REMAINDER OF THE DSB          68600020
*        LA    R6,DSBBUF           GET ADDR OF DSB                      68800020
*        USING DSBDSKAD,R6         ESTABLISH DSB ADDRESSABILITY         69000020
*        SR    R7,R7               CLEAR FOR INSERT CHAR                69200020
*        IC    R7,DSBTIOLN         LENGTH OF TIOT ENTRY IN DSB          69400020
*        LA    R7,DSBBASE(R7,R6)   ADD LENGTH OF DSB TIOT ENTRY         69600020
*        USING DSBXXX,R7           GET ADDRESSABILITY FOR DSB           69800020
DSBBASE  EQU   DSBTIOLN-DSBDSKAD  LENGTH OF DSB BASE                    70000020
DSBXXX   DS    XL1                RESERVED                              70200020
DSBCLA   DS    CL1                 OUTPUT CLASS                         70400020
         DS    XL2                 SPACE                                70600020
DSBFOR   DS    F                   FORM TYPE TO BE USED FROM SYSOUT DD  70800020
DSBPRG   DS    2F                  NAME OF USER WRITER FROM SYSOUT DD   71000020
DSBSMF   EQU   *                                                        71200020
DSBCPUID DS    F                   SID AND MDL FROM SMCA                71400020
DSBJOB   DS    2F                  JOB NAME                             71600020
DSBENTRY DS    F                   ENTRY TIME IN 1/100'S SEC            71800020
DSBDATE  DS    F                   ENTRY DATE 00YYDDDF                  72000020
DSBUSEID DS    2F                  USER ID - INIT BLANK BY R/I EACH JOB 72200020
DSBCLAS  DS    CL1                 OUTPUT CLASS                         72400020
         DS    0F                                                       72600020
DSBHOLD  DS    XL3                 TTR AT INTERRUPTION OF INPUT DS      72800020
DSBVOL   DS    XL1                VOL AT PT OF INTERRUPTION             73000020
DSBPAGE  DS    XL2                PAGE IN BLOCK AT PT OF INTERPT        73200020
IDS      DSECT                     INPUT DATA SET                       73400020
IDSDCB   DCB   MACRF=RP,DSORG=PS   INPUT DCB MAP                        73600020
IDSOPEN  OPEN  (0,INPUT),MF=L      LIST PART OF OPEN                    73800020
IDSCLOSE CLOSE (0),MF=L            LIST PART OF CLOSE                   74000020
IDSJFCBP DS    XL1                 JFCB INDICATOR                       74200020
         DS    AL3                 ADDR OF JFCB                         74400020
         DS    XL1                 EOV INDICATOR                        74600020
         DS    AL3                 ADDR OF EOV ROUTINE                  74800020
IDSOPNEX DS    AL1                 LAST ENTRY & OPEN INDICATOR          75000020
         DS    AL3                 ADDR OF OPEN EXIT                    75200020
IDSUCBP  DS    A                   ADDR OF UCB                          75400020
IDSDAIRP DS    A                   ADDR OF DAIR BLOCK                   75600020
IDSSAVW  DS    XL1                 RETURN CODE SAVE AREA                75800020
IDSSW    DS    XL1                 SWITCH                               76000020
OLDSW    EQU   X'40'               INPUT DATA SET IS OPEN               76200020
IDSDSNLN DS    H                   LENGTH OF JFCB NAME                  76400020
         IEFJFCBN                  JFCB                                 76600020
OPNEXSAV DS    18F                 OPEN EXIT SAVE AREA                  76800020
CORESIZE DS    F                   SIZE OF CORE                         77000020
BUFFAD   DS    F                   BUFFER ADDR                          77200020
         DS    H                   SPACE                                77400020
* THIS TABLE IS USED TO MAINTAIN AN APPROXIMATION OF TENTH LINE         77600020
* BACK                                                                  77800020
BAK10CNT DS    H                   COUNT                                78000020
BAK10NEW DS    XL6                 NEW APPROXIMATION                    78200020
BAK10APX DS    XL6                 TTR OF APPROX. 10 LINES BACK         78400020
BAK10LNG EQU   *-BAK10CNT          LENGTH OF BACKSPACE TABLE            78600020
IDSLNTH  EQU   *-IDS               LENGTH OF IDS                        78800020
**       END;                                                           79000020
         END                                                            79200020
