 TITLE 'CONVERT  MODULE IKJEFF66  OUTPUT CP'                            00400020
IKJEFF66 CSECT                                                          00600020
*********************************************************************** 00800020
*                                                                       01200020
*   TITLE - IEFCNVRT  CONVERT ROUTINE                                   01600020
*                                                                       02000020
*   STATUS - CHANGE LEVEL 0                                             02400020
*                                                                       02800020
*   FUNCTION - TO CONVERT AN NN FOR A QCR OR A QUEUE ENTRY TO  AN       03200020
*              TTR                                                      03600020
*                                                                       04000020
*   ENTRY POINT - IKJEFF66                                              04400020
*                                                                       04800020
*   INPUT - REGISTER 1 POINTS TO THE FOLLOWING PARAMETER LIST           05200020
*      +0*************************                                      05600020
*        * PTR TO A 4 BYTE MASK  *                                      06000020
*      +4*************************                                      06400020
*        * PTR TO NN               *                                    06800020
*      +8*************************                                      07200020
*        * PTR TO   QMPEX                                               07600020
*     +12*************************                                      08000020
*                                                                       08400020
*WHERE                                                                  08800020
*      1)THE MASK SHOULD BE X'80000000' IF THE NN IS FOR A QUEUE        09200020
*        CONTROL RECORD AND X'40000000' IF THE NN IS FOR A QUEU& ENTRY  09600020
*                                                                       10000020
*      2)PTR TO NN POINTS TO A FULL WORD CONTAINING THE NN OF EITHER    10400020
*        A QUEUE CONTROL RECORD OR A QUEUE ENTRY                        10800020
*                                                                       11200020
*      3)PTR TO ADDR OF ECB/IOB POINTS TO A FULL WORD CONTAINING A      11600020
*        PTR TO             WHERE THE TTR      IS TO BE PLACED          12000020
*                                                                       12400020
*   OUTPUT - TTR      IS RETURNED IN THE CORRECT LOCATION (QMPEX)       12800020
*                                                                       13200020
*                                                                       13600020
*   EXIT - BR 14 BACK TO CALLING ROUTINE                                14000020
*                                                                       14400020
*   TABLES/WORK AREAS -                                                 14800020
*              CVT DSECT                                                15200020
*              QUEUE MANAGER RESIDENT AREA DSECT                        15600020
*                                                                       16000020
*   ATTRIBUTES - THIS ROUTINE IS RE-ENTRANT                             16400020
*                                                                       16800020
R0       EQU    0                                                       17200020
R1       EQU   1                                                        17600020
R2       EQU   2                                                        18000020
R3       EQU   3                                                        18400020
R4       EQU   4                                                        18800020
R5       EQU   5                                                        19200020
R6       EQU   6                                                        19600020
R7       EQU   7                                                        20000020
R8       EQU   8                                                        20400020
R9       EQU   9                                                        20800020
R10      EQU   10                                                       21200020
R11      EQU   11                                                       21600020
R12      EQU   12                                                       22000020
R13      EQU   13                                                       22400020
R14      EQU   14                                                       22800020
R15      EQU   15                                                       23200020
*                                                                       23600020
*                                                                       24000020
         SAVE  (14,12),,*          SAVE CALLERS REGS                    24400000
         LR    R4,R13                                                   24800020
         BALR  R11,0                    SET UP                          25200020
         USING *,R11                           ADDRESSABILITY           25600020
         L     R10,FOUR(R1)             GET PTR TO NN                   26000000
         L     R10,0(R10)               GET NN                          26400020
         L     R2,0(R1)                 GET PTR TO MASK                 26800020
         O     R10,0(R2)                OR R10 WITH MASK TO SET INDI-   27200020
*                                       CATOR BIT WHICH TELLS WHETHER   27600020
*                                       THE NN IS FOR A QCR OR QUEUE    28000020
*                                       ENTRY                           28400020
         L     R12,EIGHT(R1)            GET   ADDR OF QMPEX             28800000
         L     R3,CVTPTR                GET QUEUE                       29200020
         USING COMMVECT,R3                        MGR DCB ADDR          29600020
         L     R3,CVTJOB                                       IN R3    30000020
QMCNVA   LTR   R10,R10                  DETERMINE IF THE NN PERTAINS    30400020
*                                       TO A HANDLE OR TO A RECORD      30800020
*                                       WITHIN THE LOGICAL TRACK AREA   31200020
         USING QMRESAR,R3               DESIGNATE GENERAL REGISTER      31600020
*                                       THREE AS THE BASE FOR THE QMGR  32000020
*                                       RESIDENT AREA                   32400020
         BC    4,QMCNVA10               BRANCH IF THE HIGH ORDER BIT IS 32800020
*                                       A ONE TO INITIALIZE ROUTINE TO  33200020
*                                       PROCESS A HANDLE NN             33600020
         LH    R14,QMKTT                LOAD THE TT OF THE FIRST TRACK  34000020
*                                       IN THE QMGRS DISK AREA THAT     34400020
*                                       CONTAINS ONLY RECORDS WITHIN    34800020
*                                       OR CONTROLLING LOGICAL TRACKS   35200020
         LA    R10,0(R10)               CLEAR THE HIGH ORDER BYTE OF    35600020
*                                       THE INPUT REGISTER              36000020
         CH    R10,QMFQR                IS THIS RECORD CONTAINED IN THE 36400020
*                                       TRANSITION TRACK (THIS IS THE   36800020
*                                       TRACK WHICH CONTAINS THE LAST   37200020
*                                       OF THE CONTROL HANDLES AND THE  37600020
*                                       BEGINNING OF THE LOGICAL TRACK  38000020
*                                       RECORDS                         38400020
         BNL   QMCNVA20                 BRANCH IF THIS RECORD IS ON A   38800020
*                                       TRACK WHICH CONTAINS ONLY       39200020
*                                       LOGICAL TRACKS                  39600020
         BCTR  R14,R0                   DECREMENT THE TT FOR THE FIRST  40000020
*                                       TRACK CONTAINING ONLY LOGICAL   40400020
*                                       TRACK ENTRIES THE RESULT IS     40800020
*                                       THE TT OF THE TRANSITION TRACK  41200020
         AH    R10,QMNHM                ADD THE NUMBER OF CONTROL       41600020
*                                       HANDLES WHICH ARE CONTAINED ON  42000020
*                                       THE TRANSITION TRACK TO THE NN. 42400020
*                                       THE RESULT IS THE RECORD NUMBER 42800020
*                                       PORTION OF THE TTR FOR THIS NN  43200020
         BCTR  R10,R0                   REDUCE THE RECORD NUMBER        43600020
*                                       INORDER TO BE COMPATABLE WITH   44000020
*                                       THE ROUTINE THAT COMBINES THE   44400020
*                                       RECORD AND TRACK TO FORM A TTR  44800020
         BC    15,QMCNVA40              BRANCH TO THE EXIT OF THIS      45200020
*                                       ROUTINE WHICH IS ALSO THE       45600020
*                                       BEGINNING OF THE TTR CONVERSION 46000020
*                                       ROUTINE                         46400020
QMCNVA10 LA    R10,0(R10)               ZERO THE HIGH ORDER BYTE OF     46800020
*                                       REGISTER TEN (CLEARS THE BIT    47200020
*                                       WHICH WAS USED TO INDICATE A    47600020
*                                       HANDLE NN)                      48000020
         LA    R0,ONE                   SET A SWITCH TO INDICATE A      48400000
*                                       MBBCCHHR SHOULD BE RETURNED TO  48800020
*                                       USER                            49200020
         SR    R14,R14                  ZERO REGISTER 14 (SINCE THE     49600020
*                                       HANDLES START ON THE FIRST      50000020
*                                       LOGICAL TRACK IN THE QMGRS      50400020
*                                       EXTENT NO DISPLACEMENT MUST BE  50800020
*                                       APPLIED TO THE CALCULATED TTR)  51200020
         LH    R1,QMHPT                 LOAD THE NUMBER OF HANDLES PER  51600020
*                                       PHYSICAL TRACK, THIS VALUE WILL 52000020
*                                       BE USED AS THE DIVISOR WHEN     52400020
*                                       CALCULATING THE TTR             52800020
         BC    15,QMCNVA30              THE INITIALIZATION NEEDED FOR   53200020
*                                       HANDLE NNS IS NOW COMPLETE AND  53600020
*                                       THE REMAINING PROCESSING CAN    54000020
*                                       BE PERFORMED BY A SECTION OF    54400020
*                                       CODE COMMON TO BOTH HANDLES AND 54800020
*                                       LOGICAL TRACK RECORDS           55200020
QMCNVA20 LH    R1,QMRPT                 LOAD THE NUMBER OF LOGICAL      55600020
*                                       RECORDS PER PHYSICAL TRACK      56000020
*                                       THIS VALUE WILL BE USED AS THE  56400020
*                                       DIVISOR WHEN CALCULATING THE    56800020
*                                       TTR                             57200020
         SH    R10,QMFQR                SUBTRACT THE NN OF THE FIRST    57600020
*                                       RECORD ON THE TRACK CONTAINING  58000020
*                                       ONLY JOB QUEUE ENTRIES          58400020
*                                       FROM THE NN TO BE CONVERTED     58800020
*********************************************************************** 59200020
**               THIS SECTION OF CODING IS USED TO CONVERT THE NNS   ** 59600020
**             OF ALL THE HANDLES AND ALL THE LOGICAL TRACK RECORDS  ** 60000020
**             EXCEPT THOSE RESIDING ON THE TRANSITION TRACK         ** 60400020
*********************************************************************** 60800020
QMCNVA30 SRDL  R10,32                   SHIFT THE NN (PASSED TO THIS    61200020
*                                       ROUTINE IN REGISTER TEN) TO     61600020
*                                       REGISTER ELEVEN AND AT THE SAME 62000020
*                                       TIME ZERO REGISTER TEN. NOW THE 62400020
*                                       NN IS RIGHT JUSTIFIED IN AN     62800020
*                                       EVEN ODD PAIR OF REGISTERS AND  63200020
*                                       CAN BE USED AS THE DIVIDEND IN  63600020
*                                       THE CALCULATION OF A TTR        64000020
         DR    R10,R1                   DIVIDE THE LOGICAL RECORD       64400020
*                                       NUMBER (NN) BY THE NUMBER OF    64800020
*                                       RECORDS PER PHYSICAL TRACK      65200020
*********************************************************************** 65600020
**               THE SIGNIFICANCE OF THE TWO VALUES DEVELOPED DURING ** 66000020
**             THE DIVISION IS AS FOLLOWS-                           ** 66400020
**                  A. THE QUOTIENT IS THE LOGICAL TRACK (TT) FOR    ** 66800020
**             THE NN (RELATIVE TO THE BEGINNING OF THE QMGRS        ** 67200020
**             EXTENT)  (REG 10)                                     ** 67600020
**                  B. THE REMAINDER IS THE RECORD NUMBER MINUS ONE. ** 68000020
**             A RECORD NUMBER DENOTES THE POSITION OF THE RECORD    ** 68400020
**             RELITIVE TO THE BEGINNING OF A TRACK.     (REG 10)    ** 68800020
*********************************************************************** 69200020
         AR    R14,R11                  ADD THE NUMBER OF LOGICAL TRKS, 69600020
*                                       FROM THE BEGINNING OF THE QMGR  70000020
*                                       EXTENT TO THE BEGINNING OF THE  70400020
*                                       AREA CONTAINING THE NN, TO THE  70800020
*                                       TT JUST DEVELOPED.              71200020
QMCNVA40 SLL   R14,8                    SHIFT THE TT LEFT ONE BYTE TO   71600020
*                                       ALLOW ROOM TO INCORPORATE THE   72000020
*                                       RECORD NIMBER                   72400020
         LA    R10,ONE(R10,R14)         THE LOGICAL TRACK (TT) AND THE  72800000
*                                       RECORD NUMBER (R) ARE COMBINED  73200020
*                                       TO FORM A LOGICAL DISK ADDRESS  73600020
*                                       (TTR). TTR = 1+(R-1)+(TTO)      74000020
         SLL   R10,8                    THE TTR IN REGISTER TEN IS LEFT 74400020
*                                       JUSTIFIED BY SHIFTING THE TTR   74800020
*                                       LEFT ONE BYTE. THE TTR IS NOW   75200020
*                                       IN THE CORRECT LOCATION FOR THE 75600020
*                                       TTR CONVERSION ROUTINE OR TO BE 76000020
*                                       RETURNED TO THE USER            76400020
*********************************************************************** 76800020
**               THIS ROUTINE CONVERTS A LOGICAL DISK ADDRESS (TTR)  ** 77200020
**             TO A DISK ADDRESS WHICH CAN BE USED BY THE I/O ROUTINE** 77600020
*********************************************************************** 78000020
QMCNVB   ST    R10,0(R12)          STORE TTR IN QMPEX                   78400020
         LR    R13,R4                                                   78800020
         RETURN (14,12)            RETURN TO CALLER                     79400000
*                                                                       80000020
ONE      EQU   1                   CONSTANT OF ONE                      80100000
FOUR     EQU   4                   CONSTANT OF FOUR                     80200000
EIGHT    EQU   8                   CONSTANT OF EIGHT                    80300000
QMCONVAD EQU   36                       DISPLACEMENT IN ECB/IOB OF      80400020
*                                       FIELD WHERE MBBCCHHR IS TO BE   80800020
*                                       PLACED                          81200020
*                                                                       81600020
QMRESAR DSECT                                                           82000020
         IEFQMRES                                                       82400020
*                                                                       82800020
COMMVECT DSECT                                                          83200020
         CVT                                                            83600020
*                                                                       84000020
         END                                                            84400020
*        * PTR TO '                                                     84800020
