*STATUS  CHANGE LEVEL 0       2/6/69                                    00100020
SAVE     TITLE 'SAVE SUBCOMMAND MODULE IKJEFF68 OUTPUT CP'              00200020
*STATUS - CHANGE LEVEL 0                                                00300020
*                                                                       00350021
*A192500-197500,198500                                           A49992 00360021
*C198000                                                         A49992 00370021
*D193000-197000,505000-514000                                    A49992 00380021
*                                                                       00390021
*FUNCTION-                                                              00400020
*        THE PURPOSE OF THIS ROUTINE IS TO ALLOW THE USER TO SAVE       00500020
*        ANY SYSOUT DATA SET PROCESSED BY THIS COMMAND.  IT DOES        00600020
*        THIS BY CHANGING THE NAME OF THE SYSOUT DATA SET TO THAT       00700020
*        SUPPLIED WITH THE SAVE SUBCOMMAND, THEN CATALOGING IT          00800020
*        UNDER THE NEW NAME.                                            00900020
*                                                                       01000020
*        THIS ROUTINE GETS CONTROL FROM IKJEFF63 WHEN IT HAS DE-        01100020
*        TERMINED THE USER ENTERED THE SAVE SUBCOMMAND IN RESPONSE      01200020
*        TO THE PAUSE MESSAGE (IKJEF114A).                              01300020
*                                                                       01400020
*        IKJEFF68 SENDS THE COMMAND BUFFER CONTAINING THE SAVE          01500020
*        SUBCOMMAND TO PARSE IN ORDER TO DETERMINE THE VALIDITY         01600020
*        OF THE DSNAME.  WHEN PARSE DETERMINES THE DSNAME IS SYN-       01700020
*        TACTICALLY CORRECT, IT GIVES CONTROL TO AN EXIT ROUTINE        01800020
*        (CHKDSNM) WHICH DETERMINES IF A MEMBERNAME AND/OR A PAS-       01900020
*        SWORD WAS INCLUDED.  IN THESE CASES, THE EXIT ROUTINE          02000020
*        ISSUES AN ERROR MESSAGE (IKJEF112I VIA IKJEFF67) AND RE-       02100020
*        TURNS TO PARSE TELLING IT TO PROMPT THE USER TO RE-ENTER       02200020
*        THE DSNAME.  AFTER THE USER SUBMITS ANOTHER SYNTACTICALY       02300020
*        CORRECT DSNAME, THE EXIT ROUTINE IS AGAIN ENTERED.  IF         02400020
*        THERE IS NO MEMBRNAME OR PASSWORD INCLUDED, THE USERID         02500020
*        AND DESCRIPTIVE QUALIFIER '.OUTLIST' ARE ADDED TO THE          02600020
*        DSNAME IF IT LACKS THESE AND IS NOT QUOTED.  IF ADDING         02700020
*        EITHER ATTACHMENT TO THE DSNAME WILL CAUSE IT TO EXCEED        02800020
*        44 CHARACTERS, AN ERROR MESSAGE IS ISSUED AND PARSE IS         02900020
*        RETURNED TO TO PROMPT THE USER.                                03000020
*                                                                       03100020
*        WHEN THE EXIT ROUTINE IS SATISFIED, PARSE RETURNS CONTR-       03200020
*        OL TO THE MAINLINE PROGRAM WHERE THE FIRST ACTION IS TO        03300020
*        CLOSE THE INPUT (SYSOUT) DATA SET.  THEN THE DATA SET IS       03400020
*        RENAMED TO THE DSNAME PROVIDED BY THE USER WITH THE POS-       03500020
*        SIBLE  ADDITIONS.  AFTER  IT IS RENAMED, THE DATA SET IS       03600020
*        UNALLOCATED (UNDER THE SYSOUT NAME).  THIS IS FOLLOWED         03700020
*        BY ALLOCATING AND UNALLOCATING IT UNDER ITS NEW NAME           03800020
*        WITH A DISPOSITION OF CATLG.  A SUCCESSFUL COMPLETION OF       03900020
*        THESE FUNCTIONS ENDS THE SAVE SUBCOMMAND WITH CONTROL          04000020
*        GIVEN BACK TO IKJEFF63.                                        04100020
*                                                                       04200020
*        EXCEPTIONAL CONDITIONS                                         04300020
*                                                                       04400020
*        IF A FAILURE OCCURS IN ALLOCATION OR UNALLOCATION, THE         04500020
*        DATA SET IS RENAMED TO ITS FORMER SYSOUT NAME AND AN ER-       04600020
*        ROR MESSAGE IS ISSUED BEFORE GOING BACK TO IKJEFF63.           04700020
*        BECAUSE OF THE RETURN CODE (04) IT RECEIVES IN THIS CASE,      04800020
*        IKJEFF63 WILL RE-ISSUE THE PAUSE MESSAGE (IKJEF114A) TO        04900020
*        GIVE THE USER ANOTHER OPPORTINITY AT SAVING THE DATA SET       05000020
*        IF CIRCUMSTANCES PERMIT.                                       05100020
*                                                                       05200020
*        AN ERROR OCCURRING DURING PARSE OR RENAME CAUSES IMMEDI-       05300020
*        ATE TERMINATION WITH AN ERROR MESSAGE AND AN 04 CODE RE-       05400020
*        TURNED TO IKJEFF63.                                            05500020
*                                                                       05600020
*        A CHECK FOR A POST'ED ECB IS MADE MADE BEFORE ANY PROC-        05700020
*        ESSING IS STARTED AND AGAIN UPON RETURN FROM PARSE.  IF        05800020
*        POSTING (ATTENTION KEY PRESSED) IS DETECTED AT EITHER          05900020
*        PLACE, AN IMMEDIATE RETURN IS MADE TO IKJEFF63 WITH A          06000020
*        ZERO RETURN CODE                                               06100020
*                                                                       06200020
*ENTRY POINTS - 1. IKJEFF68                                             06300020
*               2. CHKDSNM (PARSE EXIT ROUTINE)                         06400020
*                                                                       06500020
*INPUT - ADDRESS OF OUTCOMTB IN REGISTER 1                              06600020
*                                                                       06700020
*EXITS - 1. IKJPARSE                                                    06800020
*        2. RENAME SVC                                                  06900020
*        3. IKJDAIR                                                     07000020
*        4. IKJEFF67                                                    07100020
*        5. IKJEFF63                                                    07200020
*                                                                       07300020
*EXTERNAL REFERENCES- VPARSPCL (CONTAINS ADDR OF THE PCL (PARSE         07400020
*                     CONTROL LIST) CSECT CALLED PARSAVE                07500020
         EJECT                                                          07600020
IKJEFF68 CSECT                                                          07700020
*                             EQUATES                                   07800020
R0       EQU   0                                                        07900020
R1       EQU   1                                                        08000020
R2       EQU   2                                                        08100020
R3       EQU   3                                                        08200020
R4       EQU   4                                                        08300020
R5       EQU   5                                                        08400020
R6       EQU   6                                                        08500020
R7       EQU   7                                                        08600020
R8       EQU   8                                                        08700020
R9       EQU   9                                                        08800020
R10      EQU   10                                                       08900020
R11      EQU   11                                                       09000020
R12      EQU   12                                                       09100020
R13      EQU   13                                                       09200020
R14      EQU   14                                                       09300020
R15      EQU   15                                                       09400020
         SPACE                                                          09500020
BIT2OFF  EQU   X'DF'               TURN OFF USERID IN DAIR BLOCK        09600020
BLNK     EQU   X'40'                                                    09700020
CHAR9    EQU   X'09'                                                    09800020
CPPLADDR EQU   24                  OFFSET OF R1 INTO SAVE AREA          09850000
DAIRMSG  EQU   16                                                       09900020
DOT      EQU   C'.'                FOR USERID                           10000020
ECBPOST  EQU   X'40'                                                    10100020
FIB      EQU   100                 SVC 100                              10150000
FIRSTIME EQU   X'40'               DAIR18 ENTERED ONE TIME              10200020
FOUR     EQU   4                                                        10300020
L8       EQU   X'08'                                                    10400020
MAXNAME  EQU   44                                                       10500020
MSG111   EQU   111                 MESSAGE IKJ56311I                    10700020
MSG122   EQU   122                 MESSAGE IKJ56325I                    10800020
MSG124   EQU   124                 MESSAGE IKJ56327I                    10820000
MSG132   EQU   132                 MESSAGE IKJ56311I                    10840000
MSG133   EQU   133                 MESSAGE IKJ56326I                    10860000
MSG141   EQU   141                 MESSAGE IKJ56310I                    10880000
ONE      EQU   X'01'                                                    10900020
PARSMSG  EQU   32                                                       11000020
RC00     EQU   X'00'                                                    11100020
RC04     EQU   X'04'                                                    11200020
RC08     EQU   X'08'                                                    11300020
RC20     EQU   20                                                       11400020
RENAMSG  EQU   28                                                       11500020
TWO      EQU   2                                                        11600020
         EJECT                                                          11700020
*                             SAVE ROUTINE  GET CORE FOR COMB-          11800020
*                             INATION SAVE AND WORK AREA AND            11900020
*                             ESTABLIXH ADDRESSABILITY FOR IT AND       12000020
*                             OUTCOMTB                                  12100020
         SAVE  (14,12),,*                                               12200020
         BALR  R12,0               ESTABLISH ADDRESSABILITY             12300020
         USING *,R12               FOR IKJEFF68                         12400020
         LR    R10,R1              SAVE PARM REG                        12500020
         USING OUTCOMTB,R10        ADDRESSABILITY FOR OUTCOMTB          12600020
         GETMAIN R,LV=SAVLTH,SP=1  GET SAVE AREA                        12700020
         USING SAVEAREA,R1         ADDRESSABILITY FOR NEW AREA          12800020
         ST    R13,SAVEBACK        STORE BACK PTR IN NEW AREA           12900020
         USING SAVEAREA,R13        ADDRESSABILITY FOR OLD AREA          13000020
         ST    R1,SAVEFORW         STORE FORWARD PTR IN OLD AREA        13100020
         LR    R13,R1              ESTABLISH NEW SAVE AREA              13200020
         CLI   OUTATECB,ECBPOST    IS ECB POSTED                        13300020
         BE    RTN3             BRANCH IF IT IS                         13400020
         MVI   SWITCH,RC00      CLEAR SWITCH                            13500020
         MVI   CAMLIST,RC00        ZERO WORK AREA BEHIND                13600020
         MVC   CAMLIST+ONE(SAVLTH1),CAMLIST  THE SAVE AREA              13700020
         ST    R13,OUTSAV68        ADDR OF SAVE AREA IN OUTCOMTB        13800020
         XC    SAVDSN,SAVDSN       ZERO ADDR OF DSNAME                  13900020
         EJECT                                                          14000020
* ENTER PARSE ROUTINE                                                   14100020
*                             SET UP THE PARSE PARAMETER LIST. LOAD     14200020
*                             WITH PTRS TO PCL AND ANSPLACE. REST OF    14300020
*                             LIST IS VALID                             14400020
         USING PARSPARM,R1                                              14500020
         L     R1,OUTPARS          PTR TO PARSE PARAMETER LIST          14600020
         LA    R0,ANSPL            ADDR OF ANSWER PLACE (PTR TO PDE)    14700020
         ST    R0,PARSANSP         PUT PTR TO ANSPLACE IN PARM LIST     14800020
         L     R0,VPARSPCL         PUT PTR TO PCL IN PARM LIST          14900020
         ST    R0,PARSPCL                                               15000020
         ST    R13,PARSUWA         ADDR OF SAVE AREA FOR EXIT RTN       15100020
         SPACE                                                          15200020
         LINK  EP=IKJPARS     GO TO PARSE                               15300020
         SPACE                                                          15400020
*                             TEST RETURN CODE IN REGISTER 15           15500020
         LTR   R15,R15             IS RETURN CODE 0                     15600020
         BNZ   ERROR5              BRANCH IF NOT                        15700020
         EJECT                                                          15800020
*                             CLOSE INPUT (SYSOUT) DATA SET             15900020
*                                CHECK FOR COMPLETED I/O                16000020
CLOSE    EQU   *                                                        16100020
         USING IDS,R9              ADDRESSABILITY FOR INPUT             16200020
*                                  DATA SET (IDS) CONTROL BLOCKS        16300020
         L     R9,OUTIDSP          ADDR OF IDS                          16400020
         NI    IDSSW,X'FF'-OLDSW   TURN OFF OLDSW FOR IKJEFF62          16500020
         L     R1,BUFFAD           ADDR OF I/O WORK AREA                16600020
         USING GETAB,R1            ADDRESSABILITY                       16700020
         L     R1,DECBPTR          ADDR OF DECB                         16800020
         USING DECB,R1                                                  16900020
         TM    DECSDECB,WAITING    IS I/O COMPLETED                     17000020
         BE    CLSHERE             BRANCH IF IT IS                      17200020
         CHECK DECB                CHECK ALTERNATE DECB                 17300020
         DROP  R1                                                       17400020
         SPACE                                                          17500020
CLSHERE  EQU   *                   CLOSE INPUT DATA SET                 17600020
         CLOSE (IDSDCB),MF=(E,IDSCLOSE) CLOSE INPUT DATA SET            17700020
         SPACE 3                                                        17800020
*                             RENAME DATA SET                           17900020
*                                BUILD CAMLIST FOR RENAME MACRO         18000020
*                                INITIALIZE CAMLIST                     18100020
         MVC   CAMLIST(CAMLTH),CAMLST  MOVE LIST INTO OWN CORE          18200020
         MVC   VOLUME,H1           NO. OF VOLUME LISTS (1)              18300020
         MVC   DATASEQ,H0          DATA SET SEQUENCE (0)                18400020
         LA    R0,INFMJFCB         ADDR OF OLD (SYSOUT) NAME            18500020
         ST    R0,OLD              IN JFCB                              18600020
         LA    R0,NEWNAME          ADDR OF NEW (USER-ASSIGNED)          18700020
         ST    R0,NEW              NAME                                 18800020
         LA    R0,VOLUME           ADDR OF VOLUME DATA                  18900020
         ST    R0,VLIST                                                 19000020
         L     R5,IDSUCBP          UCB ADDRESSEABILITY                  19100020
         USING UCBOB,R5                                                 19200020
         CLI   UCBID,X'FF'         IS THIS A UCB FOR A DEVICE           19250021
*                                        OTHER THAN A 2321       A49992 19260021
         BE   NOT2321              YES-THIS UCB IS FOR A DEVICE         19300021
*                                        OTHER THAN A 2321       A49992 19310021
*   NO - IT IS A 2321 AND UCBID IS POINTING TO A SUBCELL ENTRY   A49992 19350021
         DROP  R5                                                A49992 19360021
         USING DATACELL,R5         ADDR UCB AT BEGINNING OF CELL        19370021
*                                        DESCRIPTION             A49992 19380021
         LH   R3,DCELBBNR          PICK UP THE BIN NUMBER        A49992 19400021
         SLL   R3,4                MULTIPLY BY 16 WHICH IS THE LENGTH   19450021
*                                         OF EACH ENTRY          A49992 19460021
         LA  R3,56(R3)    PICK UP THE LENGTH OF THE MAIN UCB SECTION    19500021
*                                     PLUS SUBCELL ENTRY LENGTHS A49992 19550021
         SR    R5,R3    SUBTRACT THIS LENGTH FROM THE CURRENT UCB PTR   19600021
*                                      TO GET THE UCB START ADDR A49992 19650021
         DROP R5                                                 A49992 19700021
         USING  UCBOB,R5                                         A49992 19750021
NOT2321  MVC   DEVICE,UCBTYP       PUT DEVCODE FROM UCB INTO CAMLIST    19800021
*                                                                A49992 19850021
         MVC   VOLSER,JFCBVOLS     MOVE VOL SERIAL INTO CAMLIST         19900020
         SR    R0,R0               INDICATE NO UCB ADDR                 20000020
         SPACE                                                          20100020
         RENAME CAMLIST                                                 20200020
         SPACE                                                          20300020
*                             CHECK RETURN CODES                        20400020
         LTR   R15,R15                                                  20500020
         BNZ   ERROR3              RETURN CODE IS NOT 0                 20600020
         EJECT                                                          20700020
*                             UNALLOCATE DATA SET USING DAIR18          20800020
*                                FILL IN DAIR 18 BLOCK                  20900020
         USING DAPB18,R7           DAIR18 CTL LIST                      21000020
         L     R7,IDSDAIRP         ADDR DAPB08                          21100020
         SPACE                                                          21200020
         XC    DA18FLG(DA18FRDL),DA18FLG ZERO FLAGS TO DDNAME           21300020
*                                  (DDNAME ALREADY FILLED IN)           21400020
         MVC   DA18MNM(L'BLANK),BLANK  FILL MEMBERNAME AND              21500020
*                                  SYSOUTCLASS WITH BLANKS              21600020
         XC    DA18DPS2(TWO),DA18DPS2 ZERO DIP2 AND CONTROL FLDS        21700020
         OI    DA18DPS2,DA18KEEP   DISP=KEEP                            21800020
         MVC   DA18CD,CODE18       FUNCTION CODE                        21900020
         LR    R1,R7               LOAD PARM LIST PTR                   22000020
         SPACE                                                          22100020
         LINK  EP=IKJDAIR                                               22200020
         SPACE                                                          22300020
         CLC   DA18DARC,BADCODE    AVOID 0038 CODE                      22400020
         BE    CATALOG             BRANCH IF IT IS                      22500000
         LTR   R15,R15             TEST ZERO RETURN CODE                22600020
         BNZ   ERROR4              BRANCH IF OTHER CODE                 22700020
         SPACE                                                          22800020
         EJECT                                                          24506000
*                             THIS ROUTINE CATALOGS THE NEWLY-          24512000
*                            NAMED DATA SET.                            24518000
         SPACE                                                          24524000
CATALOG  EQU   *                                                        24527000
*                                FILL IN CAMLIST FOR CATLG MACRO        24530000
         LA    R1,NEWNAME          ADDR OF NEW DSNAME                   24536000
         ST    R1,DSNADDR1         STORE IN CAMLIST                     24542000
         LA    R1,VOLUME           ADDR OF VOLUME PARAMETER LIST        24548000
         ST    R1,VOLLIST          STORE IN CAMLIST                     24554000
         SPACE                                                          24560000
         CATALOG CTLGCAM           ISSUE CATALOG MACRO                  24566000
         SPACE                                                          24572000
         LTR   R15,R15             TEST ZERO RETURN CODE                24578000
         BNZ   ERROR6              BRANCH IF NOT ZERO                   24584000
         MVI   OUTMSGID,MSG122     MSGID, 'DSNAME SAVED'                26584000
         LA    R0,NEWLNTH          ADDR OF DSNAME                       28600020
         ST    R0,SAVDSN           STORE FOR MESSAGE ROUTINE            28700020
         BAL   R5,SENDMSG          ISSUE MESSAGE                        28800020
         L     R2,OUTQMPAR         ADDR OF Q MANAGER PARMS              28810000
         USING IOPARAMS,R2         ADDRESSABILITY                       28820000
         LA    R1,DSBBUF           ADDR OF DSB                          28830000
         USING DSBMAP,R1           ADDRESSABILITY FOR DSB               28840000
         TM    DSBWSMNT,NOTMNTED   WAS VOL MOUNTED & UCB USER CT        28850000
*                                    INCREMENTED AT WARM START          28860000
         BO    RTN3                NO, SKIP INCREMENTING USER CT        28870000
         MVI   OQMFUNC,OQMUCB      INCICATE TO IKJEFF61 TO DECR UCB     28880000
         LA    R0,R3               INDICATE OUTPUT COMMAND              28882000
         LA    R0,R3               INDICATE OUTPUT COMMAND              28885000
         LA    R0,R3               INCICATE OUTPUT COMMAND              28890000
         LA    R1,OQMCPPL          PASS ADDR OF SVC 100 PARMS           28900000
         SVC   FIB                 GET TO IKJEFF61 VIA SVC 100          28910000
         SPACE                                                          28920000
         DROP  R1,R2                                                    28930000
         EJECT                                                          28940000
RTN3     SR    R5,R5               ZERO FOR RETURN CODE                 28950000
         SPACE                                                          29100020
FREEPDL  EQU   *                                                        29200020
         IKJRLSA ANSPL                                                  29300020
         LR    R1,R13              ADDR OF CURRENT SAVE AREA            29400020
         L     R13,SAVEBACK        ADDR OF OLD SAVE AREA                29500020
         SPACE                                                          29600020
         FREEMAIN R,LV=SAVLTH,A=(1),SP=1 FREE CURRENT SAVE AREA         29700020
         SPACE                                                          29800020
         XC    OUTSAV68,OUTSAV68   ZERO ADDR OF SAVE AREA               29900020
         LR    R15,R5              TRANSFER RETURN CODE                 30000020
         SPACE                                                          30100020
         RETURN (14,12),T,RC=(15)     RETURN TO CALLER IKJEFF63         30200020
         EJECT                                                          30300020
*                             PARSE EXIT ROUTINE - ADDS USER ID         30400020
*                             AND DESCRIPTIVE QUALIFIER TO DSNAME       30500020
*                             IF NECESSARY  - ALSO CHECKS FOR           30600020
*                             PRESENCE OF MEMBERNAME AND OVERSIZED      30700020
*                             DSNAME                                    30800020
CHKDSNM  EQU   *                 SET UP ADDRESSABILITY                  30900020
         STM   R14,R12,R12(R13)    SAVE PARSE'S REGISTERS               31000020
         LR    R2,R13              RETAIN ADDR OF PARSE SAVE AREA       31100020
         L     R13,FOUR(R1)        ADDR OF THIS CSECT SAVE AREA         31200020
         STM   R1,R2,SAVPAR1      SAVE PARSE'S SAVE & PARM ADDR         31300020
         LM    R14,R12,R12(R13)    RESTORE THIS CSECT REGSS             31400020
         L     R8,SAVPAR1          ADDR OF PARM LIST                    31500020
         L     R8,0(R8)            ADDR OF PDE                          31600020
         USING DSNMAD,R8           ADDRESSABILITY FOR PDE               31700020
*                                CHECK DSNAME PDE                       31800020
         CLI   DSNFLG2,DSNMEMB     DOES PDE CONTAIN MEMBERNAME          31900020
         BE    ERROR1              YES                                  32000020
*                             EXAMINE DSNAME AND ATTACH DESCRI-         32100020
*                             PTIVE QUALIFIER '.OUTLIST'AND USERID      32200020
*                             IF MISSING                                32300020
DSNCHK   EQU   *                                                        32400020
         MVC   DSNCNT,DSNMLTH      STORE DSNAME LENGTH                  32500020
         MVI   NEWNAME,BLNK        FILL FIELD IN CAMLIST WITH           32600020
FORTY3   EQU   43                                                       32660020
         MVC   NEWNAME+ONE(FORTY3),NEWNAME  BLANKS                      32720020
         SR    R4,R4               ZERO REGISTER                        32800020
         TM    DSNFLG1,DSNQUO      DSNAME IN QUOTES                     32900020
         BNO   NOQUOTES            BRANCH IF NOT                        33000020
         MVI   NEWQUO,DSNMQUO      INDICATE QUOTE FOR MSG ROUTINE       33100020
         B     MOVENAME            BRANCH                               33200020
NOQUOTES EQU   *                                                        33300020
         L     R2,DSNMAD           ADDR OF DSNAME FROM PDE              33400020
         USING DAPB08,R6           GET USERID FROM PSCB                 33500020
         L     R9,OUTIDSP           ADDR OF INPUT DAIR BLOCK            33600020
         L     R6,IDSDAIRP         ADDR OF DAIR BLOCK                   33700020
         L     R6,DA08PSCB         ADDR OF PSCB                         33800020
         USING PSCB,R6                                                  33900020
         SR    R3,R3               ZERO REG                             34000020
         IC    R3,PSCBIDL          USER ID LENGTH                       34100020
*                             MOVE USERID INTO DSNAME BUFFER            34200020
*                             IF TOGETHER THEY DO NOT EXCEED 44         34300020
*                             CHARACTERS                                34400020
MOVEID   LA    R3,ONE(R3)          ADD 1 FOR PERIOD                     34500020
         AH    R3,DSNCNT           ADD TO DSNAME LENGTH AND             34600020
         STH   R3,DSNCNT           CHECK IF IT EXCEEDS                  34700020
         CLI   DSNCNTB,MAXNAME     44 CHARACTERS (INCLUDE '.')          34800020
         BH    ERROR2              YES, BRANCH                          34900020
         IC    R3,PSCBIDL          USERID LENGTH                        35000020
         EX    R3,MVCUSRID         NEWNAME FIELD IN CAMLIST             35100020
         LA    R5,NEWNAME          MOVE '.' BEHIND USERID               35200020
         AR    R5,R3               ADD LENGTH OF USERID                 35300020
         MVI   0(R5),DOT                                                35400020
*                             CHECK FOR PRESENCE OF DESCRIPTIVE         35500020
*                             QUALIFIER '.OUTLIST'                      35600020
DSNLTH   EQU   *                                                        35700020
         LH    R3,DSNMLTH          DETERMINE OFFSET TO CHECK FOR        35800020
         SH    R3,H8               PRESENCE OF DESCRIPTIVE QUALI-       35900020
*                                  FIER '.OUTLIST'                      36000020
         AR    R2,R3               ADD OFFSET TO ADDR OF DSNAME         36100020
         CLC   0(L'OUTLIST,R2),OUTLIST                                  36200020
         BE    CHKID               TO CHECK FOR '.OUTLIST'              36300020
         SR    R2,R3               REINSTATE DSNAME PTR                 36400020
*                             MOVE '.OUTLIST' INTO DSNAME BUFFER        36500020
*                             IF TOTAL CHARACTERS DO NOT EXCEED         36600020
*                             44                                        36700020
MOVEDQ   LH    R3,DSNCNT           SIZE OF DSNAME.                      36800020
         AH    R3,H8               INCREMENT FOR '.OUTLIST'             36900020
         STH   R3,DSNCNT           COMPARE FOR GREATER                  37000020
         CLI   DSNCNTB,MAXNAME     THAN 44 CHARACTERS                   37100020
         BH    ERROR2              YES, BRANCH                          37200020
         LA    R4,NEWNAME          ADDR IN CAMLIST                      37300020
         SH    R3,H8               SUBTRACT LENGTH OF '.OUTLIST'        37400020
         AR    R4,R3               ADD OFFSET                           37500020
         MVC   0(L'OUTLIST,R4),OUTLIST MOVE '.OUTLIST'                  37600020
*                                                                       37700020
CHKID    EQU   *                  MOVE DSNAME INTO BUFFER               37800020
         SR    R4,R4               ZERO REGISTER                        37900020
         IC    R4,PSCBIDL          USERIDLENGTH                         38000020
         LA    R4,ONE(R4)          USERID LENGTH PLUS PERIOD            38100020
MOVENAME L     R2,DSNMAD           ADDR OF DSNAME FROM PDE              38200020
         LH    R3,DSNMLTH          LENGTH OF DSNAME FROM PDE            38300020
         BCTR  R3,0                REDUCE FOR USE IN MVC                38400020
         LA    R5,NEWNAME          ADDR IN CAMLIST                      38500020
         AR    R5,R4               ADD OFFSET                           38600020
         EX    R3,MVCDSN           MOVE DSNAME                          38700020
         MVC   NEWLNTH,DSNCNT      MOVE DSNAME LENGTH INTO CAMLIST      38800020
         SPACE                                                          38900020
         SR    R15,R15             SET RETURN CODE OF 0                 39000020
RTRNPARS EQU   *                                                        39100020
         MVC   CPPLADDR(L'OUTPARS,R13),OUTPARS  MOVE PARSE PARMS        39130000
*                                   INTO SAVE AREA                      39160000
         L     R13,SAVPAR13        ADDR OF PARSE SAVE AREA              39200020
         RETURN (14,12),T,RC=(15)  RETURN TO PARSE                      39300020
         EJECT                                                          39400020
ERROR1   EQU   *                 ISSUE MSG IKJ56311I AND LET            39500020
*                          PARSE PROMPT                                 39600020
         MVC   SAVMBR,DSNMBR       MOVE ADDR OF MEMBERNAME INTO         39700020
*                                  SAVE WORK AREA                       39800020
         MVC   OUTRTCD,DSNMBRLN    LENGTH OF MEMBERNAME                 39850000
         MVI   OUTMSGID,MSG132     MESSAGE ID                           39950000
         BAL   R5,SENDMSG          GO TO IKJEFF67                       40050020
         B     CHECK1              BRANCH                               40150020
ERROR2   EQU   *                 ISSUE MSG IKJ56310I AND LET            40300020
*                          PARSE PROMPT                                 40400020
         BAL   R5,MOVENM           BRANCH                               40500020
         MVI   OUTMSGID,MSG141     MESSAGE ID                           40600000
         L     R2,SAVPAR1          ADDR OF PARM LIST                    40700000
         LA    R1,MSG336           ADDR OF 2ND LEVEL MSG                40800020
         ST    R1,R8(R2)           STORE IN PARM LIST                   40900020
         BAL   R5,SENDMSG          GO TO IKJEFF67                       41000020
CHECK1   LA    R15,R8              PREPARE AN 08 RETURN CODE TO         41100020
*                                  CAUSE PARSE TO PROMPT AND            41200020
*                                  RE-ENTER EXIT ROUTINE                41300020
         CLI   OUTRESUM,QUIT       WAS MESSAGE ISSUED                   41400020
         BNE   RTRNPARS            BRANCH IF IT WAS                     41500020
         LA    R15,R12             RETURN CODE 12 TO CAUSE              41600020
*                                  PARSE TO RETURN CODE 20              41700020
         B     RTRNPARS            BRANCH                               41800020
         SPACE 2                                                        41900020
ERROR3   EQU   *                 RENAME FAILURE                         42000020
         MVC   OUTRTCD,DATASEQ     STORE RETURN CODE FOR MSG ROUTINE    42100020
         MVI   OUTMSGID,RENAMSG    INDICATE RENAME FAILURE              42200020
         LA    R2,NEWLNTH          ADDR OF NEW DSNAME                   42300020
         ST    R2,SAVDSN           STORE IN SAVE WORK AREA              42400020
         BAL   R5,SENDMSG          GO TO IKJEFF67                       42500020
         SPACE                                                          42600020
         LA    R5,R4               PREPARE 04 RETURN CODE (TO RE-       42700020
*                                  ISSUE PUTGET)                        42800020
         B     FREEPDL             RETURN TO CALLING ROUTINE            42900020
ERROR4   EQU   *                 DAIR ERROR                             43000020
         STH   R15,OUTRTCD         STORE RETURN CODE FOR MSG ROUTINE    43100020
         MVI   OUTMSGID,DAIRMSG    INDICATE DAIR FAILURE TO MSG ROUTINE 43200020
         BAL   R5,SENDMSG          BRANCH                               43300020
         SPACE                                                          43400020
*                                RENAME DATA SET BACK TO SYSOUT NAME    43500020
REVERT   XC    NEW,OLD             EXCHANGE NEW AND OLD DSNAME          43600000
         XC    OLD,NEW             ADDRESSES                            43700020
         XC    NEW,OLD                                                  43800020
         SR    R0,R0               INDICATE NO UCB ADDR                 43900020
         SPACE                                                          44000020
         RENAME CAMLIST                                                 44100020
         SPACE                                                          44200020
         SPACE                                                          44300020
         LA    R5,R4               PREPARE 04 RETURN CODE               44400020
         B     FREEPDL             BRANCH                               44500020
         EJECT                                                          44600020
ERROR5   EQU   *                 ERROR CODE FROM PARSE                  44700020
         STH   R15,OUTRTCD       STORE RC FOR MESSAGE ROUTINE           44800020
         CLI   OUTRTCD+ONE,RC08    RETURN CODE 08 (ECB POSTED)          45100020
         BE  RTN3                BRANCH IF IT IS                        45200020
         MVI   OUTRESUM,QUIT       STORE QUIT INDICATOR                 45205000
         CLI   OUTRTCD+ONE,RC04    NOPROMPT MODE                        45210000
         BNE   PRMSG               NO, BRANCH                           45220000
         B     RTN3                RETURN                               45240000
PRMSG    EQU   *                                                        45250000
         MVI   OUTMSGID,PARSMSG    ID FOR PARSE FAILURE                 45300020
         LA    R0,NEWLNTH        ADDR OF DSNAME                         45400020
         ST    R0,SAVDSN         STORE FOR MESSAGE ROUTINE              45500020
         BAL   R5,SENDMSG          GO TO IKJEFF67 (MESSAGE ROUTINE)     45600020
         SPACE                                                          45700020
         B     FREEPDL             BRANCH                               46000020
         SPACE 3                                                        46100020
ERROR6   EQU   *                 CATALOG FAILURE                        46107000
         STH   R15,OUTRTCD         SAVE RC FOR MESSAGE ROUTINE          46114000
         CLI   OUTRTCD+ONE,RC08    IS RETURN CODE 08                    46121000
         BNE   CATERR              BRANCH IF NOT                        46128000
         MVI   OUTMSGID,MSG124     MSGID, 'DSNAME ALREADY EXISTS'       46135000
         B     DSCAT               BRANCH                               46142020
CATERR   MVI   OUTMSGID,MSG133     MSG ID, 'CATALOG ERROR'              46149000
DSCAT    LA    R0,NEWLNTH          ADDR OF DSNAME                       46156000
         ST    R0,SAVDSN           STORE FOR MSG ROUTINE                46163000
         BAL   R5,SENDMSG          GO TO MSG ROUTINE                    46170000
         B     REVERT              GO RENAME DS TO SYSOUT NAME          46177000
         SPACE 2                                                        46184000
MOVENM   EQU   *                 MOVE DSNAME INTO BUFFER                46200020
         L     R2,DSNMAD           ADDR OF DSNAME                       46300020
         LH    R3,DSNMLTH          LENGTH OF DSNAME                     46400020
         STH   R3,NEWLNTH          STORE LENGTH                         46500020
         BCTR  R3,0                DECREMENT FOR MOVE                   46600020
MVCDSNM  MVC   NEWNAME(0),0(R2)    MOVE INSTRUCTION                     46700020
         EX    R3,MVCDSNM          EXECUTE MOVE INSTRUCTION             46800020
         LA    R0,NEWLNTH          ADDR OF BUFFER                       46900020
         ST    R0,SAVDSN           STORE FOR MESSAGE ROUTINE            47000020
         BR    R5                  BRANCH                               47100020
         EJECT                                                          47200020
SENDMSG  EQU   *                 LINK TO MESSAGE ROUTINE                47300020
         LR    R1,R10              ADDR OF OUTCOMTB                     47400020
         SPACE                                                          47500020
         LINK  EP=IKJEFF67         MESSAGE MODULE                       47600020
         SPACE                                                          47700020
         BR    R5                  BRANCH                               47800020
CMPUSER  CLC   PSCBUSER(R0),0(R2)  CHECK FOR USER ID IN PDE             47900020
MVCDSN   MVC   0(R0,R5),0(R2)      MOVE DSNAME FROM PDE TO CAMLST       48000020
MVCUSRID MVC   NEWNAME(R0),PSCBUSER MOVE USERID INTO CAMLIST            48100020
         EJECT                                                          48200020
BLANK    DC    CL10' '             FOR BLANKING FIELDS                  48300020
CODE08   DC    X'0008'             DAIR 08 CODE                         48400020
CODE18   DC    X'0018'             DAIR 18 CODE                         48500020
H0       DC    H'0'               DS SEQ NO. FOR CAMLIST                48600020
H1       DC    H'1'                NO. VOLUME LISTS FOR CAMLIST         48700020
H8       DC    H'8'                LENGTH OF '.OUTLIST'                 48800020
OUTLIST  DC    CL8'.OUTLIST'       DESCRIPTIVE QUALIFIER                48900020
RETURN3  DC    H'3'                TEST RETURN CODE                     49000020
RETURN4  DC    H'4'                TEST RETURN CODE                     49100020
SUB2     DC    H'2'                HALFWORD 2                           49200020
MSG336   DC    H'91',H'0',C'IKJ56336I NAME TOO LONG WHEN USERID'     C  49300000
         DC    C' AND/OR DESCRIPTIVE QUALIFIER ''.OUTLIST'' IS'      C  49400020
         DC    C' APPENDED'                                          C  49500000
IEFSQCBS DC    C'SYSIEFSD'         MAJOR NAME                           49600020
IEFQ5QCB DC    C'Q5'               MINOR NAME                           49700020
BADCODE  DC    XL2'0038'           DADSM RETURN CODE                    49800020
         SPACE                                                          49900020
VPARSPCL DC    V(PARSAVE)          ADDR OF PCL CSECT                    50000020
         SPACE                                                          50100020
CAMLST   CAMLST RENAME,0,0,0       PARM LIST FOR RENAME                 50200020
         CAMLST CATBX,0,,0         PARMLIST FOR CATALOG                 50250000
CAMLTH   EQU   *-CAMLST            LENGTH OF CAMLIST                    50300020
ENQDQLST ENQ   (IEFSQCBS,IEFQ5QCB,E,2,SYSTEM),MF=L ENQ/DQ PARMS         50400020
         EJECT                                                          51500020
PARSAVE IKJPARM DSECT=PARMSAVE                                          51600020
         SPACE 2                                                        51700020
DSNAME   IKJPOSIT DSNAME,PROMPT='DATA SET NAME',VALIDCK=CHKDSNM,       X51800020
               HELP=('NEW NAME FOR SYSOUT DATA SET')                    51900020
         SPACE 2                                                        52000020
         IKJENDP                                                        52100020
         EJECT                                                          52200020
SAVEAREA DSECT                                                          52300020
         DS    F                   REGISTER                             52400020
SAVEBACK DS    F                   BACK POINTER                         52500020
SAVEFORW DS    F                   FORWARD POINTER                      52600020
         DS    15F                 REGISTERS                            52700020
*                                  CAMLIST FOR RENAME MACRO             52800020
CAMLIST  CAMLST RENAME,0,0,0                                            52900020
OLD      EQU   CAMLIST+4                                                53000020
NEW      EQU   CAMLIST+8                                                53100020
VLIST    EQU   CAMLIST+12                                               53200020
CTLGCAM  CAMLST CATBX,0,,0         CAMLIST FOR CATALOG MACRO            53210000
         ORG   CTLGCAM             DEFINE PRECEDINGG WORDS              53220020
         DS    F                   FULLWORD                             53230020
DSNADDR1 DS    F                   ADDR OF DSNAME                       53240000
         DS    F                   FULLWORD                             53250020
VOLLIST  DS    F                   ADDR OF VOLUME PARMS                 53260000
         ORG                                                            53270000
NEWLNTH  DS    H                   LENGTH OF NEWNAME                    53300020
NEWNAME  DS    CL44                USER-SUPPLIED DSNAME                 53400020
NEWQUO   DS    XL1                 INDICATOR FOR QUOTED DSNAME          53500020
DSNMQUO  EQU   X'01'               DSNAME IS QUOTED (FOR IKJEFF67)      53600020
VOLUME   DS    H                   NO. OF VOLUME LISTS                  53700020
DEVICE   DS    XL4                 DEVICE CODE                          53800020
VOLSER   DS    CL6                 VOLUME SERIAL                        53900020
DATASEQ  DS    H                   DATA SET SEQUENCE NUMBER             54000020
         SPACE                                                          54100020
DSNCNT   DS    0H                  COUNT FIELD                          54200020
         DS    XL1                 BYTE                                 54300020
DSNCNTB  DS    XL1                 FOR NEW DSNAME                       54400020
ANSPL    DS    F                   ANSWER PLACE (ADDR OF PDL)           54500020
SAVPAR1   DS    F                  ADDR OF PARSE EXIT PARM (R1)         54600020
SAVPAR13 DS    F                   ADDR OF PARSE SAVE AREA              54700020
SAVMBR   DS    A                   ADDR OF MEMBERNAME                   54800020
SAVDSN   DS    A                   ADDR OF DSNAME                       54900020
SWITCH   DS    XL1                 GENERAL-PURPOSE SWITCH               55000020
RTCODE   DS    XL1                 DAIR RETURN CODE                     55100020
USRID    EQU   X'80'                                                    55200020
SAVLTH   EQU   *-SAVEAREA          LENGTH OF SAVEAREA                   55300020
SAVLTH1  EQU   *-CAMLIST           LENGTH FROM CAMLIST                  55400020
         EJECT                                                          55500020
         IKJOCMTB                                                       55600020
         EJECT                                                          55700020
PARSPARM DSECT                PARSE PARAMETER LIST                      55800020
PARSUPT  DS    A                   ADDR OF UPT                          55900020
PARSECT  DS    A                   ADDR OF ECT                          56000020
PARSECBA DS    A                   ADDR OF ATTENTION ECB                56100020
PARSPCL  DS    A                   ADDR OF PCL                          56200020
PARSANSP DS    A                   ADDR OF ADDR OF PDL (ANS PLACE)      56300020
PARSCBUF DS    A                   ADDR OF COMMAND BUFFER               56400020
PARSUWA  DS    A                   ADDR OF USER WORK AREA               56500020
PARSLNTH EQU   *-PARSPARM          LENGTH OF PARSE PARAMETER LIST       56600020
         SPACE 3                                                        56700020
DSNPDL   DSECT                PARAMETER DESCRIPTOR LIST (PDL)           56800020
         DS    2A                  STORAGE CHAINS                       56900020
*                                PARAMETE DESCRIPTOR ENTRY (PDE)        57000020
*                                FOR DSNAME                             57100020
DSNMAD   DS    A                   ADDR OF DSNAME                       57200020
DSNMLTH  DS    0H                                                       57300020
         DS    XL1                 BYTE                                 57400020
DSNMLTH1 DS    XL1                 LENGTH OF DSNAME                     57500020
DSNFLG1  DS    XL1                 DSNAME FLAGS                         57600020
DSN      EQU   X'80'               DSNAME SPECIFIED                     57700020
DSNQUO   EQU   X'40'               DSNAME QUOTED                        57800020
         DS    XL1                 RESERVED                             57900020
DSNMBR   DS    F                   ADDR OF MEMBERNAME                   58000020
DSNMBRLN DS    H                   LENGTH OF MEMBERNAME                 58100000
DSNFLG2  DS    XL1                 MEMBERNAME FLAGS                     58200020
DSNMEMB  EQU   X'80'               MEMBERNAME SPECIFIED                 58300020
         DS    XL1                 RESERVED                             58400020
         DS    F                   ADDR OF PASSWORD                     58500020
         DS    H                   LENGTH OF PASSWORD                   58600020
DSNFLG3  DS    XL1                 PASSWORD FLAGS                       58700020
DSNPASWD EQU   X'80'               PASSWORD SPECIFIED                   58800020
DSNLNTH  EQU   *-DSNPDL            LENGTH OF PDL                        58900020
         SPACE  3                                                       59000020
GETAB    DSECT                                                          59100020
         DS    2F                  SPACE                                59200020
DECBPTR  DS    A                   PTR TO DECB FOR NEXT READ            59300020
*                                  OR CHECK                             59400020
         DS    2A                  SPACE                                59500020
DECSDECB DS    F                   DECB                                 59600020
         DS    F                   SPACE                                59700020
DECB     EQU   DECSDECB                                                 59800020
WAITING  EQU   X'80'                                                    59900020
         EJECT                                                          60000020
IDS      DSECT                     INPUT DATA SET (IDS)                 60100020
IDSDCB   DCB   MACRF=RP,DSORG=PS   INPUT DCB MAP                        60200020
IDSOPEN  OPEN  (0,INPUT),MF=L      LIST PART OF OPEN                    60300020
IDSCLOSE CLOSE (0),MF=L            LIST PART OF CLOSE                   60400020
IDSJFCBP DS    XL1                 JFCB INDICATOR                       60500020
         DS    AL3                 ADDR OF JFCB                         60600020
         DS    XL1                 EOV INDICATOR                        60700020
         DS    AL3                 ADDR OF EOV ROUTINE                  60800020
IDSOPNEX DS    XL1                 LAST ENTRY & OPEN INDICATOR          60900020
         DS    AL3                 ADDR OF OPEN EXIT                    61000020
IDSUCBP  DS    A                   ADDR OF UCB                          61100020
IDSDAIRP DS    A                   ADDR OF DAIR BLOCK                   61200020
IDSSAVW  DS    XL1                 RETURN CODE SAVE AREA                61300020
IDSSW    DS    XL1                 SWITCH                               61400020
OLDSW    EQU   X'40'               INPUT DATA SET IS OPEN               61500020
IDSDSNLN DS    H                   LENGTH OF JFCB NAME                  61600020
         SPACE 2                                                        61700020
         IEFJFCBN                  JFCB                                 61800020
OPNEXSAV DS    18F                 OPEN EXIT SAVE AREA                  61900020
CORESIZE DS    F                   SIZE OF CORE                         62000020
BUFFAD   DS    F                   BUFFER ADDR                          62100020
         DS    H                   SPACE                                62200020
IDSLNTH  EQU   *-IDS               LENGTH OF IDS                        62300020
         EJECT                                                          62400020
PSCB     DSECT                                                          62500020
PSCBUSER DS    CL7                 USERID PADDER RIGHT WITH BLANKS      62600020
PSCBIDL  DS    CL1                 LENGTH OF USERID                     62700020
         SPACE 3                                                        62800020
DAPB08   DSECT                                                          62900020
DA08UPT  DS    A                   ADDR OF UPT                          63000020
DA08ECT  DS    A                   ADDR OF UCT                          63100020
DA08ECBA DS    A                   ADDR OF ATTENTION ECB                63200020
DA08PSCB DS    A                   ADDR OF PSCB                         63300020
DA08STLN EQU   *-DAPB08            LENGTH OF STANDARD PART OF           63400020
*                                  DAIR PARM BLOCK                      63500020
DA08DAPB DS    A                   ADDR OF DAIR PARM BLOCK              63600020
DA08STAR EQU   *                   START OF DAIR PARM BLOCK             63700020
         SPACE                                                          63800020
         IKJDAP08                                                       63900020
DAPB08   DSECT                                                          64000020
DA08FRLN EQU   DA08PDSN-DA08FLG                                         64100020
DA08LNTH EQU   *-DAPB08            LENGTH OF DAIR08                     64200020
         EJECT                                                          64300020
DAPB18   DSECT                                                          64400020
DA18UPT  DS    A                   ADDR OF UPT                          64500020
DA18ECT  DS    A                   ADDR OF ECT                          64600020
DA18ECBA DS    A                   ADDR OF ATTENTION ECB                64700020
DA18PSCB DS    A                   ADDR OF PSCB                         64800020
DA18DAPB DS    A                   ADDR OF UNALLOCATE PARM BLOCK        64900020
DA18STAR EQU   *                   START OF DAIR PARM BLOCK             65000020
         SPACE                                                          65100020
         IKJDAP18                                                       65200020
DA18FRDL EQU   DA18DDN-DA18FLG     LENGTH OF FLAG, RETURN CODE &        65300020
*                                  DSNAME PTR                           65400020
DAPB18   DSECT                                                          65500020
DA18LNTH EQU   *-DAPB18            LENGTH OF DAIR18                     65600020
         EJECT                                                          65700020
*******************************************************************     65700800
*                                                                       65701600
*                                                                       65702400
*                       DATA SET BLOCK (DSB)                            65703200
*                                                                       65704000
*                                                                       65704800
DSBMAP   DSECT                                                          65705600
         DS    0F                                                       65706400
DSBDSKAD DS    XL3                 TTR OF THIS DSB                      65707200
DSBTABID DS    XL1                 TABLE ID                             65708000
DSBNXT   DS    XL3                 TTR OF NEXT DSB                      65708800
         DS    XL2                 RESERVED                             65709600
DSBPCCPY DS    XL1                 NO.OF COPIES OF SYSOUT DATASET       65710400
DSBPCPTN DS    H                   LAST TWO CHARS OF TEST PTRN.MEM.NAME 65711200
DSBLGOUT DS    XL1                 LOG OUT BITS                         65712000
         DS    XL1                 RESERVED                             65712800
DSBFLAG  DC    X'FF'               STATUS BYTE TO DISINGUISH FROM SMB   65713600
DSBWSMNT DS    XL1                WARM START INDICATOR THAT             65714400
*                                 VOLUME NOT MOUNTED                    65715200
NOTMNTED EQU   X'80'               ON MEANS FIRST VOL. NOT MNTD         65716000
*                                  AT WARM START                        65716800
DSBTIOLN DS    XL1                 LENGTH OF TIOT PORTION OF DSB        65717600
DSBSTTA  DS    XL1                 STATUS -A-                           65718400
DSBRLOC  DS    H                   REL. LOC OF POOL                     65719200
DSBDDNAM DS    CL8                 DDNAME OF SPOOLED OUTPUT DATASET     65720000
DSBJFCB  DS    XL3                 JFCB DISK ADDRESS                    65720800
DSBSTTC  DS    XL1                 STATUS -C-                           65721600
DSBSTTB  DS    XL1                 STATUS -B-                           65722400
         DS    XL1                 RESERVED                             65723200
DSBFSRT  DS    XL2                 SRT ADDRESS                          65724000
*  DISPLACEMENTS FROM THIS POINT ON MAY BE INCORRECT FOR TIOT           65724800
*  ENTRIES LONGER THAN THE MINIMUM. DSBTIOLN SHOUL BE USED              65725600
*  IN ESTABLISHING ADDRESSABILITY FOR THE REMAINDER OF THE DSB          65726400
*        LA    R6,DSBBUF           GET ADDR OF DSB                      65727200
*        USING DSBDSKAD,R6         ESTABLISH DSB ADDRESSABILITY         65728000
*        SR    R7,R7               CLEAR FOR INSERT CHAR                65728800
*        IC    R7,DSBTIOLN         LENGTH OF TIOT ENTRY IN DSB          65729600
*        LA    R7,DSBBASE(R7,R6)   ADD LENGTH OF DSB TIOT ENTRY         65730400
*        USING DSBXXX,R7           GET ADDRESSABILITY FOR DSB           65731200
*                                    AFTER TIOT ENTRY                   65732000
DSBBASE  EQU   DSBTIOLN-DSBDSKAD  LENGTH OF DSB BASE                    65732800
DSBXXX   DS    XL1                RESERVED                              65733600
DSBCLA   DS    CL1                 OUTPUT CLASS                         65734400
         DS    XL2                                                      65735200
DSBFOR   DS    F                   FORM TYPE TO BE USED FROM SYSOUT DD  65736000
DSBPRG   DS    2F                  NAME OF USER WRITER FROM SYSOUT DD   65736800
DSBSMF   EQU   *                                                        65737600
DSBCPUID DS    F                   SID AND MDL FROM SMCA                65738400
DSBJOB   DS    2F                  JOB NAME                             65739200
DSBENTRY DS    F                   ENTRY TIME IN 1/100'S SEC            65740000
DSBDATE  DS    F                   ENTRY DATE 00YYDDDF                  65740800
DSBUSEID DS    2F                  USER ID - INIT BLANK BY R/I EACH JOB 65741600
DSBCLAS  DS    CL1                 OUTPUT CLASS                         65742400
         DS    0F                                                       65743200
DSBHOLD  DS    XL3       TTR IN INPUT DS AT POINT OF INTERRUPTION       65744000
DSBVOL   DS    XL1                VOL AT PT OF INTERRUPTION             65744800
DSBPOS     DS    XL2                POS IN BLOCK AT POINT OF INTERPT    65745600
         EJECT                                                          65746400
IOPARAMS DSECT                                                          65747200
OQMPARM  DS    0D                                                       65748000
OQMSIZE  DS    F                   SIZE OF GETMAIN                      65748800
OQMCPPL  DS    A                   ADDR OF CPPL                         65749600
OQMFUNC  DS    XL1                 FUNC INICATION FOR IKJEFF61          65750400
OQMLOCDQ EQU   X'80'               LOCDQ FUNCTION                       65751200
OQMREAD  EQU   X'40'               READ FUNCTION                        65752000
OQMDELE  EQU   X'20'               DELETE FUNCTION                      65752800
OQMENQ   EQU   X'10'               ENQUE FUNCTION                       65753600
OQMUCB   EQU   X'08'               UCB FUNCTION                         65754400
OQMUCBAD DS    A                   UCB ADDR                             65755200
OQM1STSM DS    XL3                 TTR OF FIRST SMB/DSB FOR JOB         65756000
         DS    0D                                                       65756800
         IEFQMNGR                                                       65757600
QMPCA    DS    F                   CORE ADDR OF DSB/SMB BUFFER          65758400
QMPEX    DS    XL3                 DISK ADDR OF DSB/SMB (TTR)           65759200
         DS    XL1                 Z OF TTRZ IN DSB/SMB ADDR            65760000
QMPALTH  EQU   *-QMNAM             LENGTH OF QMPA                       65760800
SMBBUF   DS    176XL1              SMB BUFFER                           65761600
DSBBUF   EQU   SMBBUF              DSB BUFFER                           65762400
         DS    F                   PLACE FOR PUTLINE TO PUT LL          65763200
SMBWORK  DS    CL1                 AREA TO DEBLOCK & DECOMPRESS-        65764000
SMBWORK1 DS    CL165               SYSTEM MESSAGES                      65764800
QMLNGTH  EQU   *-QMNAM             LENGTH OF CORE FOR Q-MANAGER         65765600
LDQJBPTR DS    A                   ADDR OF JOBNAME LIST                 65766400
LDQNPTR  DS    A                   ADDR OF NO. OF JOB NAMES             65767200
LDQNNPTR DS    A                   ADDR OF NN OF QCR                    65768000
LDQINFOP DS    A                   ADDR OF INFO AREA                    65768800
LDQNFNDP DS    A                   ADDR OF NO. OF JOBS FOUND            65769600
LDQQLSTP DS    A                   ADDR OF LIST OF Q ENTRIES            65770400
LDQEIPP  DS    A                   ADDR OF THE ECB/IOB PTR              65771200
LDQNN    DS    F                   NN OF Q TO BE SEARCHED               65772000
LDQNFND  DS    F                   NO. OF JOBS FOUND                    65772800
LDQEIP   DS    A                   ECB/IOB PTR                          65773600
LDQFIXLN EQU   *-OQMPARM           LENGTH OF FIXED PART OF LIST         65774400
LDQJB    DS    D                   JOB NAME LIST                        65775200
LDQINFO  EQU   *                   INFORMATION AREA                     65776000
LDQPOS   DS    F                   POSITION OF JOB IN Q                 65776800
*                                 *ZERO IF NOT FOUND                    65777600
LDQPRI   DS    F                   PRIORITY OF JOB                      65778400
LDQSTA   DS    F                   STATUS OF JOB                        65779200
LDQJBNN  DS    F                   NN OF JOB'S ENTRY IN Q               65780000
LDQINFOL EQU   *-LDQINFO           LENGTH OF LDQINFO ENTRY              65780800
LDQQLST  EQU   *                   LIST OF Q ENTRIES                    65781600
LDQQMNAM DS    D                   JOB NAME                             65782400
LDQQMPOP DS    XL1                 FUNCTION CODE PARAMETER              65783200
LDQQMFLT DS    XL2                 1ST LOG TRK ASGND TO JOB             65784000
LDQQMTST DS    XL1                 NO. RECS. USED IN LOG. TRK           65784800
LDQQMTLN DS    XL2                 REL. ADDR OF NEXT LOG. TRK           65785600
LDQQMNOT DS    XL1                 NO. LOGICAL TRK ASGND TO JOB         65786400
LDQQMTPY DS    XL1                 JOB TYPE                             65787200
LDQQMSTA DS    XL1                 JOB STATUS                           65788000
LDQQMPRI DS    XL1                 JOB PRIORITY                         65788800
LDQQMLNK DS    XL2                 REL. ADDR OF NEXT Q ENTRY            65789600
LDQQLSTL EQU   *-LDQQLST           LENGTH OF LTH (QMPA)                 65790400
LDQVARLN EQU   *-LDQJB             LENGTH OF VARIABLE PARMS             65791200
         IEFUCBOB                                                       65800020
         END                                                            65900020
