P20      TITLE 'IKJEFP20   COMMON MODULE FOR PARSE AND COMMAND SCAN    *00020120
               VERSION TWO DATE 8/7/70'                                 00020220
**********************************************************************  00022320
*                                                                       00022720
* TITLE -- IKJEFP20-  COMMON MODULE FOR PARSE AND COMMAND SCAN          00024320
*                                                                       00024420
* STATUS -- VERSION THREE                                               00040400
*                                                                       00042020
* FUNCTION/OPERATION -- GENERALIZED SCAN SYNTAX CHECKS PARAMETERS FOR   00043620
*     PARSE AND COMMAND SCAN ACCORDING TO CONTROL INFORMATION           00045220
*     SET UP BY THE CALLER FOR THE SCAN. THIS ROUTINE ALSO TRANSLATES   00046820
*     A PARAMETER TO UPPER CASE.                                        00048420
*                                                                       00050020
* ENTRY POINTS -- GENSCAN -- ENTRY POINT AT WHICH SYNTAX CHECKING OF  A 00051620
*     PARAMETER IS DONE ACCORDING TO CONTROL INFORMATION PASSED.        00053220
*    TRANSQ -- ENTRY POINT AT WHICH A PARAMETER IS TRANSLATED TO UPPER- 00054820
*     CASE.                                                             00056420
*    TRANSX -- ENTRY POINT TO TRANSLATE TO UPPERCASE IF PARAMETER       00058020
*     IS KNOWN NOT TO BE DEFAULTED.                                     00059620
*    TRTAB -- ENTRY POINT TO ACCESS TABLE ASSIGNING A CHARACTER CLASS   00061220
*     TO AN EBCIDIC CHARACTER.                                          00062820
*    UPPERTAB -- ENTRY POINT TO ACCESS TRANSLATE TABLE ONLY.            00064420
*                                                                       00066020
* INPUT -- PDWORD CONTAINS A POINTER TO A WORD CONTAINING               00067620
*     CONTROL INFORMATION                                               00069220
*      **********************************************************       00070820
*      / SCAN OPTIONS / FIRST CHARACTER /OTHER CHARACTER/MAXIMUM/       00072420
*      /              /    TYPE         /    TYPE       /LENGTH /       00074020
*      **********************************************************       00075620
*      0              1                 2               3               00077220
*     REGISTER FOUR CONTAINS POINTER TO PARAMETER TO BE SCANNED.        00078820
*     --TRANSLATION FUNCTION - PPOINTER CONTAINS ADDRESS                00080420
*     OF PARAMETER TO BE TRANSLATED                                     00082020
*     PLENGTH CONTAINS LENGTH OF PARAMETER.                             00083620
*                                                                       00085220
* OUTPUT -- THE TRANSLATED PARAMETER IN ITS ORIGINAL BUFFER.            00086820
*                                                                       00088420
* EXTERNAL REFERENCES -- NONE                                           00090020
*                                                                       00091620
* EXITS- NORMAL-- FROM SCAN ROUTINE EXITS TO THE LINK REGISTER          00093220
*     ADDRESS                                                           00094820
*      +0 - IF PARAMETER IS MISSING                                     00096420
*      +4 - IF PARAMETER IS INVALID                                     00098020
*      +8 - IF END OF BUFFER IS ALSO PARAMETER END                      00099620
*      +12- IF PARAMETER NOT AT END OF BUFFER                           00101220
*                                                                       00102820
*      --FROM TRANSLATION ROUTINE EXITS TO LINK REGISTER ADDRESS        00104420
*                                                                       00106020
* EXITS- ERROR-- NONE                                                   00107620
*                                                                       00109220
* TABLES/WORKAREAS -- TRTAB-TABLE WHICH ASSIGNS CHARACTER CLASS TO      00110820
*    EACH EBCIDIC CONFIGURATION                                         00112420
*    CHARTYPE-TABLE WHICH SELECTS MASK FOR TYPE OF CHARACTER REQUIRED   00114020
*    BY ROUTINE WHICH TEST CHARACTER TYPE.                              00115620
*    IKJEFPWA-MACRO MAPPING WORK AREA.                                  00117220
* ATTRIBUTES -- REENTRANT                                               00118820
*                                                                       00120420
* CHARACTER CODE DEPENDENCY -- CLASS C. THE OPERATION OF THIS MODULE    00122020
*     IS DEPENDENT UPON AN INTERNAL REPRESENTATION OF THE EXTERNAL CHAR 00123620
*     ACTER SET WHICH IS EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME.   00125220
*     THE CODING HAS BEEN ARRANGED SO THAT REDEFINITION OF 'CHARACTER'  00126820
*     CONSTANTS,BY REASSEMBLY, WILL RESULT IN A CORRECT MODULE FOR THE  00128420
*     NEW DEFINITION.                                                   00130020
*                                                                       00131620
* RELEASE 20 SUPPORT CODE -- 20035                                      00133220
*                                                                       00134820
**********************************************************************  00136420
         EJECT                                                          00138020
IKJEFP20 CSECT                                                          00139620
*  F41448 - COBOL SYMBOLIC DEBUG SUPPORT                                00140000
         ENTRY GENSCAN,TRANSQ,TRANSX,TRTAB,UPPERTAB                     00141220
         SPACE                                                          00142820
*                                                                       00144420
* REGISTER EQUATES.                                                     00146020
*                                                                       00147620
R0       EQU   0                       SCRATCH/PARAMETER REGISTER --    00149220
*                                         MUST BE 0                     00150820
R1       EQU   1                       SCRATCH/PARAMETER REGISTER --    00152420
*                                         MUST BE 1                     00154020
R2       EQU   2                       GENERAL SCRATCH REGISTER         00155620
R3       EQU   3                       GENERAL SCRATCH REGISTER         00157220
XINPUT   EQU   4                       NEXT CHARACTER TO SCAN           00158820
XINPUTB  EQU   5                       LAST CHARACTER SCANNED USED TO   00160420
*                                         COMPUTE LENGTH OF SCANNED     00162020
*                                         DATA                          00163620
XPCE     EQU   6                       IF CALLED BY PARSE, POINTS TO    00165220
*                                         THE CURRENT PCE. IF CALLED    00166820
*                                         BY COMMAND SCAN, NOT USED.    00168420
R7       EQU   7                       NOT USED                         00170020
LINK2    EQU   8                       SECOND LEVEL RETURN REGISTER     00171620
LINK1    EQU   9                       FIRST LEVEL RETURN REGISTER      00173220
R10      EQU   10                      NOT USED                         00174820
R11      EQU   11                      NOT USED                         00176420
R12      EQU   12                      NOT USED                         00178020
WORKBASE EQU   13                      BASE REGISTER FOR COMMON         00179620
*                                         WORKSPACE -- MUST BE 13       00181220
R14      EQU   14                      SCRATCH REGISTER                 00182820
BASE     EQU   15                      LINKAGE REGISTER USED AS         00184420
*                                         BASE REGISTER                 00186020
*                                                                       00187620
* BIT SETTINGS FOR CHARACTER TYPES USED BY TYPETEST                     00189220
*                                                                       00190820
HEX      EQU   X'80'                   HEX CHARACTER                    00192420
OLETTER  EQU   X'40'                   LETTER NOT A HEX CHARACTER       00194020
NATL     EQU   X'20'                   NATIONAL CHARACTER               00195620
NUMBER   EQU   X'10'                   NUMBER                           00197220
SEPAR    EQU   X'08'                   SEPARATOR                        00198820
NSEPDLIM EQU   X'04'                   DELIMITER THAT IS NOT A          00200420
*                                         A SEPARATOR                   00202020
NDLIMSPC EQU   X'02'                   SPECIAL CHARACTER THAT IS NOT    00203620
*                                         ALSO A DELIMITER OR A         00205220
*                                         SEPARATOR                     00206820
CMDDLIM  EQU   X'01'                   COMMAND NAME DELIMITER           00208420
INVALID  EQU   X'00'                   INVALID CHARACTER                00210020
         SPACE                                                          00211620
*                                                                       00213220
* BIT PATTERNS USED TO TEST THE OPTIONS SELECTED BY THE PARSE USER AND  00214820
* REFLECTED IN VARIOUS BYTES IN THE PCE.                                00216420
*                                                                       00218020
PCEFPRPT EQU   B'00010000'             BIT 3  - PROMPT IS SPECIFIED     00219620
PCEFDFLT EQU   B'00001000'             BIT 4  - DEFAULT IS SPECIFIED    00221220
PCEFSUBF EQU   B'00000100'             BIT 5  - SUBFIELD IS SPECIFIED   00222820
PCEFHELP EQU   B'00000010'             BIT 6  - HELP IS SPECIFIED       00224420
PCEFVCHK EQU   B'00000001'             BIT 7  - VALIDITY CHECK EXIT IS  00226020
*                                         SPECIFIED                     00227620
PCEFLIST EQU   B'10000000'             BIT 8  - LIST IS SPECIFIED       00229220
PCEFASIS EQU   B'01000000'             BIT 9  - NO TRANSLATION REQUIRED 00230820
PCEFRNGE EQU   B'00100000'             BIT 10 - RANGE IS SPECIFIED      00232420
PCEFINST EQU   B'00010000'             BIT 11 - INSERT IS SPECIFIED     00234020
PCEFASTK EQU   B'10000000'             BIT 0 - ASTERISK IS ALLOWED      00235620
PCEFMAXL EQU   B'01000000'             BIT 1  - MAXLNTH IS SPECIFIED    00237220
         SPACE                                                          00238820
*                                                                       00240420
* OFFSETS FOR REQUIRED FIELDS IN PARSE PCE'S.                           00242020
*                                                                       00243620
PCEPCLLN EQU   0                       PCL LENGTH FIELD IN IKJPARM      00245220
PCEPDLLN EQU   2                       PDL LENGTH FIELD IN IKJPARM      00246820
PCEKYEND EQU   4                       IKJKEYWD OR END-OF-FIELD OFFSET  00248420
*                                         IN IKJPARM                    00250020
PCEFLGB1 EQU   0                       FLAG BYTE 1                      00251620
PCEFLGB2 EQU   1                       FLAG BYTE 2                      00253220
PCELEN   EQU   2 - 3                   PCE LENGTH                       00254820
PCEPDEO  EQU   4 - 5                   PDE OFFSET INTO PDL              00256420
PCEPOST  EQU   6                       TYPE OF POSITIONAL PARAMETER     00258020
PCENAML  EQU   4                       LENGTH OF NAME FOR IKJNAME       00259620
PCENAMN  EQU   5 - N                   NAME SPECIFIED                   00261220
PCEOPT   EQU   6                       IKJIDENT OPTION BYTE             00262820
PCEFIRST EQU   7                       IKJIDENT FIRST CHARACTER FLAGS   00264420
PCEOTHER EQU   8                       IKJIDENT OTHER CHARACTER FLAGS   00266020
PCEPARMT EQU   9                       IKJIDENT PARAMETER TYPE SEGMENT  00267620
         EJECT                                                          00269220
*                                                                       00270820
* MISCELLANEOUS EQUATES                                                 00272420
*                                                                       00274020
ZERO     EQU   0                       USED AS A 0                      00275620
ONE      EQU   1                       USED AS A 1                      00277220
TWO      EQU   2                       USED AS A 2                      00278820
FOUR     EQU   4                       USED AS A 4                      00280420
EIGHT    EQU   8                       USED AS A 8                      00282020
TWELVE   EQU   12                      USED AS A 12                     00283620
CC1      EQU   1                       CONDITION CODE 1                 00285220
CC5      EQU   5                       CONDITION CODE 5                 00286820
CC8      EQU   8                       CONDITION CODE 8                 00288420
CC13     EQU   13                      CONDITION CODE 13                00290020
IPDLMAXE EQU   10                      MAXIMUM INPUT STACKING DEPTH FOR 00291620
*                                         A INPUT PUSHDOWN STACK        00293220
ASTERISK EQU   C'*'                    ASTERISK                         00294820
LEFTPRN  EQU   C'('                    LEFT PARENTHESIS                 00296420
RIGHTPRN EQU   C')'                    RIGHT PARENTHESIS                00298020
HE0      EQU   X'E0'                   USED TO OBTAIN TYPE INDICATOR    00299620
*                                         FROM PCE FLAG BYTE            00301220
         SPACE                                                          00302820
*                                                                       00304420
* PCE TYPE USED TO DETERMINE THE TYPE OF PCE BEING PROCESSED            00306020
*                                                                       00307620
KEYWDPCE EQU   X'40'                   KEYWORD PCE                      00309220
RSVDPCE  EQU   X'A0'                   RESERVED WORD PCE FOR     F41448 00309600
*                                      COBOL                     F41448 00310000
     EJECT                                                              00310800
GENSCAN  DS    0H                      GENERALIZED SCAN ROUTINE         00312420
         SPACE                                                          00314020
*                                                                       00315620
* ESTABLISH ADDRESSABILITY USING THE CALL REGISTER (R15) AS A           00317220
* BASE REGISTER.                                                        00318820
*                                                                       00320420
         USING *,BASE                  ESTABLISH ADDRESSABILITY         00322020
*                                         FOR GENSCAN                   00323620
         USING PWORK,WORKBASE          ESTABLISH ADDRESSABILITY TO      00325220
*                                         COMMON WORKAREA               00326820
         L     R3,PDWORD               GET PTR TO GENSCAN CONTROL INFO  00328420
         USING GCONTROL,R3             ESTABLISH ADDRESSABILITY TO      00330020
*                                         GENSCAN CONTROL INFORMATION   00331620
         LA    XINPUT,ONE(XINPUT)      GET NEXT CHARACTER               00333220
         CLC   GFIRST(L'GFIRST+L'GOTHER),H0 IS THIS AN ANY/ANY          00334820
*                                         COMBINATION                   00336420
         BZ    GS02                    IF YES BRANCH --- IF ASTERISK    00338020
*                                         WAS SUPPLIED IT IS REDUNDANT  00339620
*                                         WITH ANY/ANY OPTIONS          00341220
         SPACE                                                          00342820
         TM    GOPTIONS,ASTKALWD       IS AN ASTERISK ALLOWED           00344420
         BZ    GS02                    NO, CONTINUE                     00346020
         SPACE                                                          00347620
         CLI   ZERO(XINPUT),ASTERISK   IS THERE AN ASTERISK IN THE      00349220
*                                         BUFFER                        00350820
         BNE   GS02                    NO, CONTINUE                     00352420
         SPACE                                                          00354020
GS015    DS    0H                      ONE CHARACTER RETURN             00355620
         LA    XINPUT,ONE(XINPUT)      GET NEXT CHARACTER               00357220
         LR    XINPUTB,XINPUT          SET LAST CHAR SCANNED            00358820
         C     XINPUTB,ENDINPUT        IS SCAN AT END OF CURRENT INPUT  00360420
         BNL   EIGHT(LINK2)            YES, RETURN +8 INDICATING THE    00362020
*                                         PARAMETER IS GOOD AND ENDED   00363620
*                                         AT THE END OF THE BUFFER      00365220
         SPACE                                                          00366820
         B     TWELVE(LINK2)           NO, RETURN +12 INDICATING THE    00368420
*                                         PARAMETER IS GOOD BUT THE     00370020
*                                         DELIMITER MUST BE CHECKED     00371620
         SPACE                                                          00373220
GS02     DS    0H                      CHECK FIRST CHARACTER            00374820
         XR    R2,R2                   CLEAR DEPTH METER                00376420
         XR    R1,R1                   CLEAR WORK REG                   00378020
         IC    R1,GFIRST               GET FIRST CHARACTER TYPE         00379620
*                                         INDICATOR AND USE AS INDEX    00381220
*                                         INTO TYPE DESIRED TABLE       00382820
         IC    R1,CHARTYPE(R1)         SET TYPE DESIRED FOR TYPETEST    00384420
         BAL   LINK1,TYPETEST          TEST FIRST CHARACTER SYNTAX      00386020
         SPACE                                                          00387620
         B     ZERO(LINK2)             +0 RETURN - THE FIRST CHARACTER  00389220
*                                         IS INVALID.  RETURN IS TO     00390820
*                                         LINK2+0 INDICATING THE        00392420
*                                         PARAMETER IS MISSING          00394020
*                                                                       00395620
*                                      +4 RETURN - THE FIRST CHARACTER  00397220
*                                         IS VALID, CONTINUE            00398820
         SPACE                                                          00400420
         CLI   ZERO(XINPUT),LEFTPRN    IS THE CHARACTER A LEFT PAREN    00402020
         BNE   GS03                    IF NO SKIP SETTING OF DEPTH      00403620
*                                         METER                         00405220
         SPACE                                                          00406820
         LA    R2,ONE                  SET DEPTH METER TO ONE           00408420
         SPACE                                                          00410020
GS03     DS    0H                      * * * *                          00411620
         ST    XINPUT,PPOINTR          SAVE PTR TO PARM                 00413220
         TM    GOPTIONS,MAXLSPEC       IS A MAX LENGTH SPECIFIED        00414820
         BZ    GS04                    NO, CONTINUE                     00416420
         SPACE                                                          00418020
         CLI   GMAXLNTH,ONE            IS THE MAX LENGTH 1              00419620
         BE    GS015                   YES, RETURN AS WITH ASTERISK     00421220
         SPACE                                                          00422820
         XR    R0,R0                   ZERO LOOP CONTROL REG            00424420
         IC    R0,GMAXLNTH             USE MAXLENGTH FOR CONTROL OF     00426020
*                                         SCAN LOOP                     00427620
         SPACE                                                          00429220
GS04     DS    0H                      * * * *                          00430820
         XR    R1,R1                   CLEAR WORK REG                   00432420
         IC    R1,GOTHER               GET OTHER CHARACTER TYPE         00434020
*                                         INDICATOR AND USE AS INDEX    00435620
*                                         INTO TYPE DESIRED TABLE       00437220
         IC    R1,CHARTYPE(R1)         SET TYPE DESIRED FOR TYPETEST    00438820
         SPACE                                                          00440420
GSLOOP   DS    0H                      OTHER LOOP                       00442020
         LA    XINPUT,ONE(XINPUT)      GET NEXT CHARACTER               00443620
         LR    XINPUTB,XINPUT          SET LAST CHARACTER SCANNED       00445220
         C     XINPUT,ENDINPUT         IS SCAN AT END OF CURRENT INPUT  00446820
         BNL   EIGHT(LINK2)            YES, RETURN +8 INDICATING THE    00448420
*                                         PARAMETER IS GOOD AND ENDED   00450020
*                                         AT THE END OF THE BUFFER      00451620
         SPACE                                                          00453220
         BAL   LINK1,TYPETEST          TEST CHARACTER SYNTAX            00454820
         SPACE                                                          00456420
         B     GS06                   +0 RETURN - THE CHARACTER IS      00458020
*                                         AN INVALID OTHER CHARACTER.   00459620
*                                         SEE IF THE DEPTH METER        00461220
*                                         SHOULD BE CHECKED             00462820
         SPACE                                                          00464420
*                                      +4 RETURN - THE CHARACTER IS     00466020
*                                         A VALID OTHER CHARACTER,      00467620
*                                         CONTINUE                      00469220
         SPACE                                                          00470820
         CLI   GOTHER,ZERO             IS THE OTHER CHARACTER AN ANY    00472420
         BNE   GS05                    IF NO SKIP OVER FURTHER CHECKS   00474020
         SPACE                                                          00475620
         CLI   ZERO(XINPUT),LEFTPRN    IS THE NEXT CHARACTER A LEFT     00477220
*                                         PARENTHESIS                   00478820
         BNE   GS05                    IF NO SKIP SETTING DEPTH METER   00480420
         SPACE                                                          00482020
         LA    R2,ONE(R2)              INCREMENT DEPTH METER BY ONE     00483620
         SPACE                                                          00485220
GS05     DS    0H                      * * * *                          00486820
         TM    GOPTIONS,MAXLSPEC       IS A MAX LENGTH SPECIFIED        00488420
         BZ    GSLOOP                  NO, SCAN NEXT CHAR               00490020
         SPACE                                                          00491020
         BCT   R0,GSLOOP               YES, DECREMENT LENGTH AND TEST   00500020
*                                         FOR 0, IF GREATER THAN 0 SCAN 00510020
*                                         NEXT CHARACTER                00520020
         SPACE                                                          00530020
         B     FOUR(LINK2)             IF R0 REACHES 0, THE             00540020
*                                      MAXIMUM LENGTH HAS BEEN          00541020
*                                      EXCEEDED.  RETURN IS TO LINK2+4  00542020
*                                      INDICATING THE PARAMETER IS      00543020
*                                      INVALID                          00544020
         SPACE                                                          00544120
GS06     DS    0H                      * * * *                          00544420
         CLI   GOTHER,ZERO             IS THE OTHER CHARACTER AN ANY    00544520
         BNE   TWELVE(LINK2)           RETURN TO LINK2+12 INDICATING    00544620
*                                         THE PARAMETER IS GOOD BUT THE 00544820
*                                         DELIMITER MUST BE CHECKED     00544920
         SPACE                                                          00545020
         CLI   ZERO(XINPUT),RIGHTPRN   IS CHARACTER A RIGHT PAREN       00545120
         BNE   TWELVE(LINK2)           IF NO EXIT                       00545220
         SPACE                                                          00545320
         BCTR  R2,ZERO                 DECREMENT DEPTH METER            00545420
         LTR   R2,R2                   IS THIS THE END OF THE PARAMETER 00545520
         BM    TWELVE(LINK2)           IF YES EXIT                      00545620
         SPACE                                                          00545720
         B     GS05                    NOT PARAMETER END CONTINUE SCAN  00545820
         EJECT                                                          00545920
*********************************************************************** 00546020
*                                                                     * 00547020
*                 CHARACTER TYPE TEST ROUTINE                         * 00548020
*                                                                     * 00549020
* THIS IS AN INTERNAL SUBROUTINE WHICH CHECKS THE CURRENT CHARACTER   * 00549120
* FOR BELONGING TO A SPECIFIED CHARACTER CLASS.                       * 00549520
*                                                                     * 00549620
* INPUT - R1=MASK OF DESIRED CHARACTER CLASS.                         * 00549720
*         XINPUT=POINTER TO CHARACTER TO BE CHECKED.                  * 00549820
*                                                                     * 00549920
* OUTPUT - THE RESULT OF THE TEST IS INDICATED BY THE                 * 00550020
*          LOCATION TO WHICH CONTROL IS RETURNED.                     * 00550120
*                                                                     * 00550220
* EXISTS - LINK1+0=THE CHARACTER DOES NOT BELONG TO THE SPECIFIED     * 00550320
*                  CHARACTER CLASS.                                   * 00550420
*                                                                     * 00550520
*        - LINK1+4=THE CHARACTER BELONGS TO THE CHARACTER CLASS       * 00550620
*                  SPECIFIED.                                         * 00550720
*                                                                     * 00550820
*********************************************************************** 00550920
         SPACE                                                          00551020
TYPETEST DS    0H                      * * * *                          00551120
         XR    R14,R14                 CLEAR WORK REG                   00551220
         IC    R14,ZERO(XINPUT)        USE CURRENT CHARACTER AS         00551320
*                                         OFFSET INTO TESTING TABLE     00551420
         LA    R14,TRTAB(R14)          GET ADDRESS IN TABLE             00551520
*                                         CORRESPONDING TO CHARACTER IN 00551620
*                                         QUESTION                      00551720
         EX    R1,TYPETM               EXECUTE TEST UNDER MASK OF       00551820
*                                         TYPEBYTE FOR CHARACTER        00551920
*                                         SPECIFICATION GIVEN IN R1     00552020
*                                                                       00552120
         BC    CC5,FOUR(LINK1)         TYPE MATCHES, RETURN +4          00552320
*                                                                       00552420
         BR    LINK1                   TYPE DOESN'T MATCH, RETURN +0    00552520
         EJECT                                                          00552720
*********************************************************************** 00560020
*                                                                     * 00570020
*                       TRANSLATE INPUT DATA SUBROUTINE               * 00580020
*                                                                     * 00590020
*   THIS ROUTINE TRANSLATES THE INPUT DATA TO UPPERCASE UNLESS THE    * 00600020
* ASIS OPTION WAS SELECTED BY THE USER. THE INPUT DATA ADDRESS IS     * 00610020
* TAKEN FROM PPOINTR AND THE LENGTH FROM PLENGTH. IF THE DATA LIES    * 00620020
* WITHIN THE PCE (DEFAULTED) NO TRANSLATION TAKES PLACE.              * 00630020
*                                                                     * 00640020
*********************************************************************** 00650020
         SPACE                                                          00660020
TRANSQ   DS    0H                      TRANSLATION SUBROUTINE           00670020
         USING *,BASE                  ESTABLISH ADDRESSABILITY         00671020
*                                         FOR TRANSLATE ROUTINE         00672020
         SPACE                                                          00675020
         MVC   PDWORD(ONE),PCEFLGB1(XPCE) MOVE PCE FLAG                 00676020
*                                         BYTE TO WORKAREA              00677020
         NI    PDWORD,HE0              ISOLATE PCE TYPE INDICATORS      00678020
         CLI   PDWORD,KEYWDPCE         IS IT A KEYWORD PCE              00679020
         BE    TRANS                   YES, TRANSLATE                   00679120
         SPACE                                                          00679220
         CLI   PDWORD,RSVDPCE          IS IT A RESERVED WORD     F41448 00679600
*                                      PCE?                      F41448 00679700
         BO    TRANS                   IF YES, TRANSLATE         F41448 00679800
*                                      REGARDLESS                F41448 00679900
         SPACE                                                          00683200
         TM    PCEFLGB2(XPCE),PCEFASIS SHOULD THE DATA BE TRANSLATED TO 00686700
*                                         UPPERCASE                     00690020
         BCR   CC1,LINK1               NO RETURN TO CALLER              00700020
         SPACE                                                          00710020
TRANS    DS    0H                      BRANCHED TO FOR TRANSLATION OF A 00720020
*                                         KEYWORD PARAMETER             00730020
         NC    PPOINTR+ONE(L'PPOINTR-ONE),PPOINTR+ONE IS THERE ANY DATA 00740020
*                                         TO CONVERT                    00750020
         BCR   CC8,LINK1               IF NO RETURN TO CALLER           00760020
         SPACE                                                          00770020
         CLC   PPOINTR+ONE(L'PPOINTR-ONE),PTABLEAD+ONE DOES THE DATA    00780020
*                                         LIE WITHIN THE PCL            00790020
         BL    TRANS1                  NO BRANCH - CANNOT BE DEFAULT    00800020
         SPACE                                                          00810020
         CLC   PPOINTR+ONE(L'PPOINTR-ONE),PTABLEND+ONE DOES THE DATA    00820020
*                                         LIE WITHIN THE PCL            00830020
         BCR   CC13,LINK1              YES WITHIN PCL MUST BE DEFAULT   00840020
         B     TRANS1                  BRANCH AROUND TRANSX CODE        00841020
         SPACE                                                          00850020
*********************************************************************** 00881020
*                                                                     * 00882020
* IF TRANSLATE ROUTINE IS ENTERED AT ENTRY POINT TRANSX, ADJUST       * 00883020
* THE VALUE OF THE BASE REGISTER (WHICH IS ALSO THE CALL REGISTER)    * 00884020
* SO THAT LOCATIONS ABOVE THIS ENTRY POINT WILL BE ADDRESSABLE        * 00885020
* BY INSTRUCTIONS BELOW THIS ENTRY POINT.                             * 00886020
*********************************************************************** 00887020
         SPACE                                                          00888020
TRANSX   DS    0H                      * * * *                          00890020
         LA    R14,TRANSX-TRANSQ       LOAD SCRATCH REG WITH            00891020
*                                         DIFFERENCE IN ENTRY POINTS    00892020
         SR    BASE,R14                ADJUST VALUE OF BASE REGISTER    00893020
*                                         TO THAT AT ENTRY POINT TRANSQ 00894020
         SPACE                                                          00896020
*                                                                       00896220
* PROCEED TO TRANSLATE DATA TO UPPERCASE.                               00896320
*                                                                       00896420
TRANS1   DS    0H                      * * * *                          00897020
         LH    R14,PLENGTH             LOAD LENGTH OF DATA              00900020
         LTR   R14,R14                 ANY DATA TO TRANSLATE            00910020
         BCR   CC8,LINK1               NO ZERO RETURN TO CALLER         00920020
         SPACE                                                          00930020
         BCTR  R14,ZERO                REDUCE FOR 'EX' INSTRUCTION      00940020
         L     R1,PPOINTR              LOAD ADDRESS OF DATA             00950020
         EX    R14,TRANSTR             TRANSLATE TO UPPERCASE           00960020
         BR    LINK1                   RETURN TO CALLER                 00970020
         SPACE                                                          00980020
H0       DC    H'0'                    HALFWORD OF ZEROES FOR CLC       00981020
         SPACE                                                          00982020
DATE     DC    C'IKJEFP20-8/7/70'      MODULE LEVEL IDENTITY CONSTANT   00983020
         SPACE                                                          00990020
*                                                                       01000020
* TRANSLATION TABLE USED BY TRANSLATE TO UPPERCASE ROUTINE.             01010020
*                                                                       01020020
UPPERTAB DC    256AL1(*-UPPERTAB)      GENERATE BASIC TABLE             01030020
         ORG   UPPERTAB+C'A'-X'40'     POSITION INST. CTR. TO SMALL A-Z 01040020
         DC    (C'Z'-C'A'+1)AL1(*-UPPERTAB+X'40') RAISE LOWER TO UPPER  01050020
         ORG   UPPERTAB+256            RESET INSTRUCTION COUNTER        01060020
         EJECT                                                          01070020
*                                                                       01080020
* THIS 256 BYTE TABLE IS USED TO TEST IF A GIVEN INPUT CHARACTER        01090020
* BELONGS TO A CHARACTER CLASS. EACH EBCIDIC CONFIGURATION IS           01100020
* ASSIGNED A CHARACTER CLASS                                            01110020
*                                                                       01120020
TRTAB    DC    256AL1(INVALID)         INITIALIZE TYPETEST TABLE        01130020
         ORG   TRTAB+X'05'                                              01140020
         DC    AL1(SEPAR+CMDDLIM)      HORIZONTAL TAB = SEPARATOR AND   01150020
*                                         COMMAND DELIMITER             01160020
         ORG   TRTAB+C' '                                               01170020
         DC    AL1(NSEPDLIM+CMDDLIM)   NEW LINE CHAR = DELIMITER AND    01180020
*                                         COMMAND DELIMITER             01190020
         ORG   TRTAB+C' '                                               01200020
         DC    AL1(SEPAR+CMDDLIM)      BLANK = SEPARATOR AND COMMAND    01210020
*                                         DELIMITER                     01220020
         ORG   TRTAB+C''                                               01230020
         DC    AL1(NDLIMSPC)           CENT SIGN = SPECIAL              01240020
         ORG   TRTAB+C'.'                                               01250020
         DC    AL1(NDLIMSPC+CMDDLIM)   PERIOD = SPECIAL                 01260020
*                                         AND COMMAND DELIMITER         01270020
         ORG   TRTAB+C'<'                                               01280020
         DC    AL1(NDLIMSPC)           LESS THAN = SPECIAL              01290020
         ORG   TRTAB+C'('                                               01300020
         DC    AL1(NDLIMSPC+CMDDLIM)   LEFT PAREN = SPECIAL             01310020
*                                         AND COMMAND DELIMITER         01320020
         ORG   TRTAB+C'+'                                               01330020
         DC    AL1(NDLIMSPC)           PLUS = SPECIAL                   01340020
         ORG   TRTAB+C''                                               01350020
         DC    AL1(NDLIMSPC)           OR = SPECIAL                     01360020
         ORG   TRTAB+C'&&'                                              01370020
         DC    AL1(NDLIMSPC+CMDDLIM)   AMPERSAND = SPECIAL              01380020
*                                         AND COMMAND DELIMITER         01390020
         ORG   TRTAB+C'!'                                               01400020
         DC    AL1(NDLIMSPC)           EXCLAMATION = SPECIAL            01410020
         ORG   TRTAB+C'$'                                               01420020
         DC    AL1(NATL)               DOLLAR SIGN = NATIONAL           01430020
         ORG   TRTAB+C'*'                                               01440020
         DC    AL1(NDLIMSPC)           ASTERISK= SPECIAL                01450020
*                                         AND COMMAND DELIMITER         01460020
         ORG   TRTAB+C')'                                               01470020
         DC    AL1(NSEPDLIM+CMDDLIM)   RIGHT PAREN = SPECIAL            01480020
*                                         AND COMMAND DELIMITER         01490020
         ORG   TRTAB+C';'                                               01500020
         DC    AL1(NSEPDLIM+CMDDLIM)   SEMICOLON = DELIMITER            01510020
*                                         AND COMMAND DELIMITER         01520020
         ORG   TRTAB+C''                                               01530020
         DC    AL1(NDLIMSPC)           NOT SIGN = SPECIAL               01540020
         ORG   TRTAB+C'-'                                               01550020
         DC    AL1(NDLIMSPC+CMDDLIM)   MINUS = SPECIAL                  01560020
*                                         AND COMMAND DELIMITER         01570020
         ORG   TRTAB+C'/'                                               01580020
         DC    AL1(NDLIMSPC+CMDDLIM)   SLASH = DELIMITER                01590020
*                                         AND COMMAND DELIMITER         01600020
         ORG   TRTAB+C','                                               01610020
         DC    AL1(SEPAR+CMDDLIM)      COMMA = SEPARATOR                01620020
*                                         AND COMMAND DELIMITER         01630020
         ORG   TRTAB+C'%'                                               01640020
         DC    AL1(NDLIMSPC)           PERCENT = SPECIAL                01650020
         ORG   TRTAB+C'_'                                               01660020
         DC    AL1(NDLIMSPC)           DASH = SPECIAL                   01670020
         ORG   TRTAB+C'>'                                               01680020
         DC    AL1(NDLIMSPC)           GREATER-THAN = SPECIAL           01690020
         ORG   TRTAB+C'?'                                               01700020
         DC    AL1(NDLIMSPC)           QUESTION MARK = SPECIAL          01710020
         ORG   TRTAB+C':'                                               01720020
         DC    AL1(NDLIMSPC)           COLON = SPECIAL                  01730020
         ORG   TRTAB+C'#'                                               01740020
         DC    AL1(NATL)               POUND SIGN = NATIONAL            01750020
         ORG   TRTAB+C'@'                                               01760020
         DC    AL1(NATL)               AT SIGN = NATIONAL               01770020
         ORG   TRTAB+C''''             QUOTE                            01780020
         DC    AL1(NDLIMSPC+CMDDLIM)   QUOTE = SPECIAL                  01790020
*                                         AND COMMAND DELIMITER         01800020
         ORG   TRTAB+C'='                                               01810020
         DC    AL1(NDLIMSPC+CMDDLIM)   EQUAL = SPECIAL                  01820020
*                                         AND COMMAND DELIMITER         01830020
         ORG   TRTAB+C'"'                                               01840020
         DC    AL1(NDLIMSPC)           DOUBLE QUOTE = SPECIAL           01850020
         ORG   TRTAB+X'81'                                              01860020
         DC    (C'F'-C'A'+1)AL1(HEX)   SMALL A THRU F = HEX             01870020
         DC    (C'I'-C'G'+1)AL1(OLETTER) SMALL G THRU I = OTHER LETTER  01880020
         ORG   TRTAB+C'J'                                               01890020
         ORG   TRTAB+X'91'                                              01900020
         DC    (C'R'-C'J'+1)AL1(OLETTER) SMALL J THRU R = OTHER LETTER  01910020
         ORG   TRTAB+C'S'                                               01920020
         ORG   TRTAB+X'A2'                                              01930020
         DC    (C'Z'-C'S'+1)AL1(OLETTER) SMALL S THRU Z = OTHER LETTER  01940020
         ORG   TRTAB+C'A'                                               01950020
         DC    (C'F'-C'A'+1)AL1(HEX)   A THRU F = HEX                   01960020
         DC    (C'I'-C'G'+1)AL1(OLETTER) G THRU I = OTHER LETTER        01970020
         ORG   TRTAB+C'J'                                               01980020
         DC    (C'R'-C'J'+1)AL1(OLETTER) J THRU R = OTHER LETTER        01990020
         ORG   TRTAB+C'S'                                               02000020
         DC    (C'Z'-C'S'+1)AL1(OLETTER) S THRU Z = OTHER LETTER        02010020
         ORG   TRTAB+C'0'                                               02020020
         DC    (C'9'-C'0'+1)AL1(NUMBER) 0 THRU 9 = NUMBER               02030020
         ORG   TRTAB+256                                                02030120
         SPACE                                                          02031020
TRANSTR  TR    ZERO(*-*,R1),UPPERTAB   TO CONVERT TO UPPERCASE          02032020
         SPACE                                                          02033020
TYPETM   TM    ZERO(R14),*-*           USED BY TYPETEST TO TEST         02033120
*                                         FOR A CHARACTER TYPE          02033220
         SPACE                                                          02033420
*                                                                       02033520
* TABLE USED BY GENSCAN TO SELECT THE CORRECT MASK TO BE PASSED         02033620
* TO TYPETEST GIVEN THE TYPE OF CHARACTER REQUIRED IN THE FORM          02033720
* OF A HEX NUMBER.                                                      02033820
*                                                                       02033920
CHARTYPE DC    0H'0'                   * * * *                          02034020
ANY      DC    AL1(HEX+OLETTER+NATL+NUMBER+NDLIMSPC) ALL ALPHABETIC     02034120
*                                         NUMERIC,NATIONAL AND          02034220
*                                         ENTERABLE SPECIAL CHARACTERS  02034320
*                                         THAT ARE NOT DELIMITERS       02034420
ALPHA    DC    AL1(HEX+OLETTER+NATL)   ALL ALPHABETIC CHARACTERS        02034520
NUMERIC  DC    AL1(NUMBER)             ALL NUMERIC CHARACTERS           02034620
ALPHANUM DC    AL1(HEX+OLETTER+NATL+NUMBER) ALL ALPHABETIC AND          02034720
*                                         NUMERIC CHARACTERS            02034820
         SPACE                                                          02034920
*                                                                       02035220
* MAPPING OF THE CONTROL INFORMATION PASSED TO GENSCAN BY THE CALLER    02035320
* THE ADDRESS OF THE CONTROL INFORMATION IS CONTAINED IN PDWORD         02036020
* IN THE COMMON WORKAREA.                                               02037020
*                                                                       02038020
GCONTROL DSECT                                                          02039020
GOPTIONS DS    X                       FLAG BYTE WHICH INDICATES THE    02039120
*                                         SCAN OPTIONS                  02039220
GFIRST   DS    X                       FIRST CHARACTER TYPE - A HEX     02039320
*                                         NUMBER                        02039420
GOTHER   DS    X                       OTHER CHARACTERS TYPE - A HEX    02039520
*                                         NUMBER                        02039620
GMAXLNTH DS    X                       MAXIMUM LENGTH (OPTIONAL)        02039720
         SPACE                                                          02039820
*                                                                       02039920
* GENSCAN OPTIONS FLAGS.                                                02040020
*                                                                       02040120
ASTKALWD EQU   X'80'                   AN ASTERISK MAY BE SUBSTITUTED   02040220
*                                         FOR THE PARM                  02040320
MAXLSPEC EQU   X'40'                   MAXIMUM LENGTH IS SPECIFIED      02040420
         EJECT                                                          02040620
PWORK    IKJEFPWA                                                       02050020
         END                                                            02060020
