P30      TITLE 'IKJEFP30   TSO COMMAND SCAN PROGRAM   VERSION 2 DATE 7/*00021020
               10/70'                                                   00022020
*********************************************************************** 00023020
*                                                                     * 00030020
* TITLE -- 'IKJEFP30 - COMMAND SCAN FOR TSO COMMANDS'                 * 00040020
*                                                                     * 00041020
* STATUS -- VERSION 2                                                 * 00042020
*                                                                     * 00043020
* FUNCTION/OPERATION -- COMMAND SCAN SCANS THE TSO COMMAND BUFFER FOR * 00044020
*    THE COMMAND NAME, OPTIONALLY SYNTAX CHECKS IT, INDICATES         * 00045020
*    IF THERE ARE PARAMTERS ON THE COMMAND, AND TRANSLATES THE        * 00046020
*    COMMAND NAME TO UPPER CASE.  SYNTAX CHECKING IS DONE BY USING    * 00047020
*    GENSCAN ROUTINE AND CHARACTER TYPE TABLE OF MODULE IKJEFP20.     * 00048020
*    TRANSLATION TO UPPERCASE IS DONE USING THE TRANSX ROUTINE OF     * 00049020
*    MODULE IKJEFP20.                                                 * 00049120
*                                                                     * 00049220
* ENTRY POINTS --                                                     * 00049320
*                                                                     * 00049420
*         IKJSCAN - PURPOSE:  TO OBTAIN ALL OF THE ABOVE FUNCTION     * 00049520
*                 - CALLING SEQUENCE:  LA    R1,CSPL                  * 00049720
*                                      LINK  EP=IKJSCAN               * 00049820
*                                                                     * 00049920
* INPUT -- REGSITER 1 POINTS TO THE COMMAND SCAN PARAMETER LIST       * 00050020
*    (CSPL).  THE CSPL CONTAINS THE FOLLOWING:                        * 00050120
*                                                                     * 00050220
*         /-----------------------------------------------/           * 00050320
*         / A POINTER TO THE UPT                          /           * 00050420
*         /-----------------------------------------------/           * 00050520
*         / A POINTER TO THE ECT                          /           * 00050620
*         /-----------------------------------------------/           * 00050720
*         / A POINTER TO THE CP'S ECB                     /           * 00050820
*         /-----------------------------------------------/           * 00050920
*         / A POINTER TO A FLAG WORD                      /           * 00051020
*         /-----------------------------------------------/           * 00051120
*         / A POINTER TO THE OUTPUT AREA                  /           * 00051220
*         /-----------------------------------------------/           * 00051420
*         / A POINTER TO THE COMMAND BUFFER               /           * 00051720
*         /-----------------------------------------------/           * 00051820
*         0                                               4           * 00051920
*                                                                     * 00052020
*    THE UPT, ECT, AND CP'S ECB ARE NOT USED BY COMMAND SCAN.         * 00052120
*    THE FLAG WORD IS OBTAINED AND FREED BY THE CALLER. BIT 0 SET TO  * 00052220
*    0 = SYNTAX CHECKING.  BIT 0 SET TO 1 = NO SYNTAX CHECKING.       * 00052320
*    THE OUTPUT AREA IS TWO WORDS IN LENGTH AND IS OBTAINED AND       * 00052420
*    FREED BY THE INVOKER.  IT IS USED FOR THE RESULTS OF THE SCAN.   * 00052520
*    THE COMMAND BUFFER CONTAINS THE COMMAND TO BE SCANNED.           * 00052720
*    IT HAS THE FOLLOWING FORMAT:                                     * 00052820
*                                                                     * 00052920
*         /-----------------------------------------------/           * 00053020
*         / LENGTH / OFFSET / TEXT                        /           * 00053120
*         /-----------------------------------------------/           * 00053220
*         0        2        4                                         * 00053320
*                                                                     * 00053420
*    THE FIRST 2 BYTES CONTAIN THE TOTAL LENGTH OF THE COMMAND        * 00053520
*    AND HEADER. THE SECOND 2 BYTES CONTAIN THE OFFSET INTO THE       * 00053620
*    TEXT AT WHICH THE SCAN SHOULD BEGIN.                             * 00053720
*                                                                     * 00053820
* OUTPUT -- THE RESULTS OF THE SCAN ARE PLACED IN THE OUTPUT AREA.    * 00053920
*    A POINTER TO THE OUTPUT AREA IS IN THE CSPL. IT HAS THE          * 00054020
*    FOLLOWING FORMAT:                                                * 00054120
*                                                                     * 00054220
*         /-----------------------------------------------/           * 00054320
*         / A POINTER TO THE COMMAND NAME                 /           * 00054420
*         /-----------------------------------------------/           * 00054520
*         / LENGTH OF CMD. NAME  / FLAGS     / RESERVED   /           * 00054620
*         /-----------------------------------------------/           * 00054720
*         0                      2           3            4           * 00054820
*                                                                     * 00055020
*    THE POINTER AND LENGTH ARE ZERO IF THE BUFFER IS EMPTY OR        * 00055120
*    THE COMMAND NAME IS INVALID.  THE FLAGS ARE SET AS FOLLOWS:      * 00055220
*                                                                     * 00055320
*         X'80'  VALID COMMAND WITH PARAMETERS                        * 00055420
*         X'40'  VALID COMMAND WITH NO PARAMETERS                     * 00055520
*         X'20'  QUESTION MARK                                        * 00055620
*         X'10'  BUFFER IS EMPTY                                      * 00055720
*         X'08'  INVALID COMMAND NAME                                 * 00055820
*                                                                     * 00055920
*    THE OFFSET IN THE COMMAND BUFFER HEADER IS ALSO UPDATED.         * 00056020
*    IT IS SET TO THE FIRST PARAMETER FOLLOWING THE COMMAND           * 00056120
*    OR THE END OF THE BUFFER IF THERE ARE NO PARAMETERS              * 00056220
*    OR THE BUFFER WAS EMPTY.  IF THE COMMAND IS INVALID THE          * 00056320
*    OFFSET IS UNCHANGED.                                             * 00056420
*                                                                     * 00056520
* EXTERNAL REFERENCHES --                                               00056620
*         GENSCAN:  A SUBROUTINE OF MODULE IKJEFP20 USED TO SYNTAX    * 00056720
*                   CHECK THE COMMAND NAME.                           * 00056820
*         TRANSX:  A SUBROUTINE OF MODULE IKJEFP20 USED TO TRANSLATE  * 00056920
*                  THE COMMAND NAME TO UPPER CASE.                    * 00057020
*         TRTAB:  A 256 BYTE TABEL IN MODULE IKJEFP20 USED TO CHECK A * 00057120
*                 CHARACTER FOR A SPECIFIED CHARACTER TYPE.           * 00057220
*                                                                     * 00057320
* EXISTS,NORMAL -- THE FOLLOWING RETURN CODES ARE SET IN REGISTER 15. * 00057420
*    0  SUCCESSFUL COMPLETION                                         * 00057520
*    4  THE CSPL CONTAINS INVALID PARAMETERS                          * 00057620
*                                                                     * 00057720
*    FOR A NON-ZERO RETURN CODE, THE OUTPUT AREA AND COMMAND BUFFER   * 00057820
*    OFFSET ARE UNCHANGED.                                            * 00058020
*                                                                     * 00058120
* EXISTS,ERROR -- N/A                                                 * 00058220
*                                                                     * 00058320
* TABLES/WORK AREAS --                                                * 00058420
*    IKJCSPL:  MAPPING OF COMMAND SCAN PARAMETER LIST                 * 00058520
*    IKJCSOA:  MAPPING OF COMMAND SCAN OUTPUT AREA                    * 00058620
*    IKJEFPWA:  MAPPING OF WORKAREA USED BY COMMAND SCAN AND          * 00058720
*               UTILITY MODULE IKJEFP20.                              * 00058820
*                                                                     * 00058920
* ATTRIBUTES -- REENTRANT                                             * 00059020
*                                                                     * 00059120
* CHARACTER CODE DEPENDENCY -- CLASS C.  THE OPERATION OF THIS MODULE * 00059220
*    DEPENDS UPON AN INTERNAL REPRESENTATION OF THE EXTERNAL          * 00059420
*    CHARACTER SET WHICH IS EQUIVALENT TO THE ONE USED AT             * 00059520
*    ASSEMBLY TIME.  THE CODING HAS BEEN ARRANGED SO THAT             * 00059620
*    REDEFINITION OF 'CHARACTER' CONSTANTS, BY REASSEMBLY,            * 00059720
*    WILL RESULT IN A CORRECT MODULE FOR THE NEW DEFINITION.          * 00059820
*                                                                     * 00059920
* RELEASE 20 SUPPORT CODE -- 20035                                    * 00060020
*                                                                     * 00060220
*********************************************************************** 00060320
         SPACE                                                          00070020
IKJEFP30 CSECT                                                          00080020
         ENTRY IKJSCAN                 ESTABLISH ENTRY POINT FOR        00090020
*                                         COMMAND SCAN                  00090120
         EXTRN TRTAB                   EXTERNAL TABLE USED BY TYPETEST  00091020
IKJSCAN  DS    0H                      * * * *                          00100020
         SPACE                                                          00111020
*                                                                       00112020
* REGISTER EQUATES.                                                     00113020
*                                                                       00114020
R0       EQU   0                       SCRATCH/PARAMETER REGISTER --    00115020
*                                         MUST BE 0                     00116020
R1       EQU   1                       SCRATCH/PARAMETER REGISTER --    00117020
*                                         MUST BE 1                     00118020
R2       EQU   2                       GENERAL SCRATCH REGISTER         00119020
R3       EQU   3                       GENERAL SCRATCH REGISTER         00119120
XINPUT   EQU   4                       NEXT CHARACTER TO SCAN           00119220
XINPUTB  EQU   5                       LAST CHARACTER SCANNED USED TO   00119320
*                                         COMPUTE LENGTH OF SCANNED     00119420
*                                         DATA                          00119520
XFLAGS   EQU   6                       PTR TO INPUT FLAG WORD           00119620
CSOAPTR  EQU   7                       ADDRESS OF OUTPUT AREA           00119720
LINK2    EQU   8                       SECOND LEVEL LINKAGE REGISTER    00120220
*                                         FOR LINKAGE BETWEEN           00120320
*                                         SUBROUTINES                   00120420
LINK1    EQU   9                       FIRST LEVEL LINKAGE REGISTER FOR 00120520
*                                         LINKAGE BETWEEN MAINLINE AND  00120620
*                                         SUBROUTINES                   00120720
CSPLPTR  EQU   10                      ADDRESS OF COMMAND SCAN          00120820
*                                         PARAMETER LIST                00120920
CBUFPTR  EQU   11                      ADDRESS OF COMMAND BUFFER        00121020
BASE     EQU   12                      BASE REGISTER FOR COMMAND SCAN   00121120
*                                         CSECT                         00121220
WORKBASE EQU   13                      BASE REGISTER FOR COMMAND SCAN   00121520
*                                         WORKSPACE -- MUST BE 13       00121920
R14      EQU   14                      SCRATCH/CALL REGISTER -- MUST BE 00122020
*                                         14                            00122120
R15      EQU   15                      SCRATCH/CALL REGISTER -- MUST BE 00122220
*                                         15                            00122320
         SPACE                                                          00122420
*                                                                       00122520
* BIT SETTINGS FOR CHARACTER TYPES USED BY TYPETEST                     00122620
*                                                                       00122720
HEX      EQU   X'80'                   HEX CHARACTER                    00122820
OLETTER  EQU   X'40'                   LETTER NOT A HEX CHARACTER       00122920
NATL     EQU   X'20'                   NATIONAL CHARACTER               00123020
NUMBER   EQU   X'10'                   NUMBER                           00123120
SEPAR    EQU   X'08'                   SEPARATOR                        00123220
NSEPDLIM EQU   X'04'                   DELIMITER THAT IS NOT A          00123320
*                                         A SEPARATOR                   00123420
NDLIMSPC EQU   X'02'                   SPECIAL CHARACTER THAT IS NOT    00123520
*                                         ALSO A DELIMITER OR A         00123620
*                                         SEPARATOR                     00123720
CMDDLIM  EQU   X'01'                   COMMAND NAME DELIMITER           00123820
INVALID  EQU   X'00'                   INVALID CHARACTER                00123920
         SPACE                                                          00124020
*                                                                       00124120
* MSICELLANEOUS EQUATES                                                 00124220
*                                                                       00124320
ZERO     EQU   0                       USED AS A ZERO                   00124420
ONE      EQU   1                       USED AS A ONE                    00124520
TWO      EQU   2                       USED AS A TWO                    00124620
THREE    EQU   3                       USED AS A THREE                  00124720
FOUR     EQU   4                       USED AS A FOUR                   00124820
EIGHT    EQU   8                       USED AS AN EIGHT                 00125020
QUESTMRK EQU   C'?'                    QUESTION MARK                    00125120
CC5      EQU   5                       CONDITION CODE 5                 00125220
         SPACE                                                          00125520
*                                                                       00125620
* COMMAND SCAN INPUT FLAGS                                              00125720
*                                                                       00125820
NOSYNCHK EQU   X'80'                   INDICATES NOT TO SYNTAX CHECK    00125920
*                                         THE COMMAND NAME              00126020
         SPACE                                                          00126120
*                                                                       00126220
* RETURN CODES                                                          00126320
*                                                                       00126420
RCGOOD   EQU   0                       SUCESSFUL COMPLETION             00126520
RCINVP   EQU   4                       INVALID PARAMETERS - THE OFFSET  00126620
*                                         IN THE COMMAND BUFFER IS      00127020
*                                         GREATER THAN THE LENGTH-4     00127120
         EJECT                                                          00127320
*                                                                       00127420
* ENTRY CODE:  SAVE REGISTERS AND ESTABLISH ADDRESSABILITY TO COMMAND   00127520
*              SCAN CSECT AND COMMAND SCAN PARAMETER LIST.              00127620
*                                                                       00127920
         SAVE  (14,12),,IKJSCAN-7/10/70 SAVE CALLERS REGISTERS          00128120
         SPACE                                                          00130020
         BALR  BASE,ZERO               ESTABLISH ADDRESSABILITY TO      00140020
         USING *,BASE                     COMMAND SCAN CSECT            00150020
         SPACE                                                          00190020
         LR    CSPLPTR,R1              SAVE INPUT PARAMETER LIST ADDR   00200020
         USING CSPL,CSPLPTR            ESTABLISH ADDRESSABILITY TO      00201020
*                                         COMMAND SCAN PARMATER LIST    00202020
         SPACE                                                          00210020
*                                                                       00220020
* DO UNCONDITIONAL GETMAIN FOR SAVEAREA AND FOR WORKSPACE               00230020
* NECESSARY FOR COMMAND SCAN PROCESSING.                                00231020
*                                                                       00240020
         GETMAIN R,LV=CSWORKSZ         UNCONDITIONAL REQUEST FOR        00250020
*                                         COMMAND SCAN WORKAREA         00260020
         SPACE                                                          00261020
*                                                                       00262020
* STANDARD LINKAGE CONVENTIONS.                                         00263020
*                                                                       00264020
         LR    R2,WORKBASE             SAVE ADDRESS OF CALLER'S SAVE    00270020
*                                         AREA                          00280020
         LR    WORKBASE,R1             ESTABLISH COMMAND SCAN SAVEAREA  00290020
*                                         ADDRESS AND INITIALIZE        00300020
*                                         WORKSPACE BASE REGISTER       00310020
         USING CSWORK,WORKBASE         ESTABLISH ADDRESSABILITY TO      00311020
*                                         COMMAND SCAN WORKSPACE        00312020
         ST    R2,FOUR(WORKBASE)       BACK CHAIN TO CALLER'S SAVEAREA  00320020
         ST    WORKBASE,EIGHT(R2)      FORWARD CHAIN TO COMMAND SCAN'S  00330020
*                                         SAVEAREA                      00340020
         SPACE                                                          00370020
*                                                                       00380020
* ESTABLISH ADDRESSABILITY TO COMMAND SCAN OUTPUT AREA                  00390020
* OBTAINED BY THE INVOKER.                                              00391020
*                                                                       00400020
         NI    RETCODE,RCGOOD          SET RETURN CODE TO 0             00401020
         L     XFLAGS,CSPLFLG          GET ADDRESS OF FLAG WORD         00410020
         L     CSOAPTR,CSPLOA          GET ADDRESS OF OUTPUT AREA       00430020
         USING CSOA,CSOAPTR            ESTABLISH ADDRESSABILITY TO      00440020
*                                         OUTPUT AREA PROVIDED BY USER  00441020
         SPACE                                                          00442020
*                                                                       00442120
* ESTABLISH ADDRESSABILITY TO COMMAND BUFFER PASSED IN PARM LIST        00443020
* AND CHECK THAT THE OFFSET IS NOT GREATER THAN THE LENGTH-4.           00444020
*                                                                       00445020
         L     CBUFPTR,CSPLCBUF        GET ADDRESS OF COMMAND BUFFER    00450020
         USING CBUF,CBUFPTR            ESTABLISH ADDRESSABILITY TO      00460020
*                                         COMMAND BUFFER                00461020
         XC    CSOA(EIGHT),CSOA        CLEAR OUTPUT AREA                00461120
         MVC   PDWORD(FOUR),CBUFLEN    ALIGN BUFFER LENGTH ON FULL      00462020
*                                         WORD BOUNDARY AND OFFSET ON   00463020
*                                         HALF WORD BOUNDARY            00464020
         LH    R2,PDWORD               LOAD LENGTH                      00465020
         LA    R3,FOUR                 LOAD A FOUR FOR SUBTRACT         00466020
         SR    R2,R3                   SUBTRACT FOUR FROM LENGTH        00467020
         STH   R2,PDWORD+FOUR          PUT ADJUSTED LENGTH IN           00468020
*                                         PDWORD+4                      00469020
         CLC   PDWORD+FOUR(TWO),PDWORD+TWO IS THE LENGTH-4 GREATER      00469120
*                                         OR EQUAL TO THE OFFSET        00469220
         BNL   CS01                    YES,CONTINUE                     00469420
         SPACE                                                          00469520
         OI    RETCODE,RCINVP          NO, SET THE RETURN CODE TO       00469620
*                                         INVALID PARAMETERS            00469720
         B     CSEXIT                  EXIT                             00469820
         SPACE                                                          00469920
*                                                                       00470020
* START SCAN AT OFFSET INDICATED IN COMMAND BUFFER HEADER.              00470120
*                                                                       00470220
CS01     DS    0H                      * * * *                          00470320
         LR    R2,CBUFPTR              COPY COMMAND BUFFER ADDRESS      00470620
         AH    R2,PDWORD               COMPUTE ADDRESS OF END OF BUFFER 00490020
         ST    R2,ENDINPUT             SAVE FOR FUTURE COMPARES         00500020
         LH    R2,PDWORD+TWO           LOAD CURRENT BUFFER OFFSET       00530020
         LA    XINPUT,THREE(R2,CBUFPTR) SET STARTING ADDRESS OF SCAN AT 00540020
*                                         ONE BEFORE THE LOCATION       00550020
*                                         INDICATED BY THE CURRENT      00560020
*                                         BUFFER OFFSET                 00570020
         SPACE                                                          00570220
*                                                                       00570420
* CHECK ALL COMMANDS FOR A POSSIBLE QUESTION MARK IN PLACE OF THE       00571020
* COMMAND NAME.                                                         00572020
*                                                                       00573020
         LA    XINPUT,ONE(XINPUT)      GET FIRST CHARACTER              00574020
         LR    XINPUTB,XINPUT          SET LAST CHARACTER SCANNED       00575020
         CLI   ZERO(XINPUT),QUESTMRK   IS FIRST CHAR A QUESTION MARK    00580020
         BE    CSEXIT20                YES,SET FLAG TO INDICATE         00590020
*                                         QUESTION MARK IS PRESENT      00590120
         BCTR  XINPUT,ZERO             NO CHECK FOR VALID COMMAND       00591020
         SPACE                                                          00600020
*                                                                       00651020
* SKIP SEPARATORS TO BEGINNING OF COMMAND NAME.                         00652020
* A +4 RETURN FROM SKIPB INDICATES THE COMMAND BUFFER IS EMPTY.         00653020
*                                                                       00654020
         BAL   LINK2,SKIPB             SKIP BLANKS TO BEGINNING OF      00660020
*                                         COMMAND NAME                  00670020
         B     CSEXIT10                RETURN +0, END OF BUFFER REACHED 00680020
*                                         TAKE NULL EXIT                00690020
*                                      RETURN +4, START OF COMMAND NAME 00700020
*                                         HAS BEEN ESTABLISHED          00710020
         LA    XINPUT,ONE(XINPUT)      GET FIRST CHARACTER              00720020
         LR    XINPUTB,XINPUT          SET LAST CHARACTER SCANNED       00730020
         SPACE                                                          00730120
*                                                                       00751120
* ONCE IT IS ESTABLISHED THAT THERE IS A COMMAND NAME AND IT IS NOT     00752020
* A QUESTION MARK, CHECK THE FLAG WORD SET BY THE INVOKER TO            00753020
* DETERMINE IF THE COMMAND NAME SHOULD BE SYNTAX CHECKED.               00754020
*                                                                       00755020
         TM    ZERO(XFLAGS),NOSYNCHK   TEST INPUT FLAG BYTE TO          00760020
*                                         DETERMINE IF SYNTAX CHECKING  00770020
*                                         IS REQUESTED                  00780020
         BO    CSNOSYN                 NO, GO SCAN FOR END ONLY         00790020
         BCTR  XINPUT,ZERO             BACK UP INPUT PTR FOR GENSCAN    00800020
         SPACE                                                          00801020
*                                                                       00802020
* THE GENERAL SCAN ROUTINE OF MODULE IKJEFP20 IS USED TO SYNTAX         00803020
* CHECK THE COMMAND. PDWORD IN THE COMMON WORK AREA MUST CONTAIN THE    00804020
* ADDRESS OF THE CONTROL BITS FOR SYNTAX CHECKING. THE FIRST CHARACTER  00805020
* OF A COMMAND NAME MUST BE ALPHABETIC. THE OTHER CHARACTERS MUST       00806020
* BE ALPHAMERIC. THE MAXIMUM LENGTH IS 8.                               00807020
*                                                                       00808020
         LA    R3,CMDSYNTX             GET ADDR OF CMND SYNTAX REQD     00810020
         ST    R3,PDWORD               SAVE FOR GENSCAN                 00820020
         L     R15,AGSCAN              GET ADDRESS OF GENSCAN ROUTINE   00821020
         BALR  LINK2,R15               LINK TO GENSCAN TO               00830020
*                                         SYNTAX CHECK COMMAND NAME     00831020
*                                                                       00832020
         B     CSEXIT08                RETURN +0, FIRST CHAR IS INVALID 00840020
*                                         TAKE ERROR EXIT               00850020
*                                                                       00851020
         B     CSEXIT08                RETURN +4, TOO LONG, TAKE ERROR  00860020
*                                         EXIT                          00870020
*                                                                       00871020
         B     CS03                    RETURN +8, OK, REACHED END, GO   00880020
*                                         SET PTR AND LENGTH            00890020
*                                                                       00891020
*                                      RETURN +12, OK, CHECK DELIMITER  00900020
*                                                                       00901020
         SPACE                                                          00902020
*                                                                       00903020
* GENSCAN RETURNS CONTROL WITH XINPUT POINTING TO THE DELIMITER         00904020
* CHARACTER OF THE COMMAND NAME. THE DELIMITER MUST BE A SEPARATOR OR   00905020
* THE END OF THE BUFFER.  IF THE END OF THE BUFFER WAS NOT REACHED      00906020
* DURING GENSCAN, THE DELIMITER MUST BE CHECKED.  TYPETEST IS           00907020
* USED TO PERFORM THIS TEST.                                            00908020
*                                                                       00909020
         LA    R1,SEPAR                SET UP TEST FOR VALID COMMAND    00910020
*                                         NAME SEPARATOR                00910120
         BAL   LINK1,TYPETEST          LINK TO TYPETEST TO              00920020
*                                         PERFORM TEST                  00921020
*                                                                       00922020
         B     CSEXIT08                RETURN  +0, INVALID, TAKE ERROR  00930020
*                                         EXIT                          00940020
*                                                                       00940120
*                                      RETURN  +4, VALID, CONTINUE      00941020
         SPACE                                                          00941120
*                                                                       00941220
* IF THE COMMAND NAME IS VALID, IT IS TRANSLATED TO UPPERCASE           00941320
* USING THE TRANSX ROUTINE OF MODULE IKJEFP20.  PPOINTR AND PLENGTH     00941420
* IN THE COMMON WORKAREA MUST CONTAIN A POINTER TO THE COMMAND          00941520
* NAME AND THE LENGTH.                                                  00941620
*                                                                       00942020
CS03     DS    0H                      * * * *                          00950020
         MVC   CSOACNM,PPOINTR         PUT PTR TO COMMAND NAME IN       00960020
*                                         OUTPUT AREA                   00970020
         S     XINPUTB,PPOINTR         COMPUTE LENGTH OF COMMAND NAME   00980020
         STH   XINPUTB,CSOALNM         PUT LENGTH IN OUTPUT AREA        00990020
         STH   XINPUTB,PLENGTH         STORE LENGTH FOR TRANSLATE       01000020
         L     R15,ATRANSX             GET ADDRESS OF TRANSLATE ROUTINE 01001020
         BALR  LINK1,R15               LINK TO TRANSX TO TRANSLATE      01010020
*                                         THE COMMAND TO UPPER CASE     01011020
         SPACE                                                          01011120
*                                                                       01012020
* SKIP SEPARATORS TO THE FIRST PARAMETER OF THE COMMAND OF THE END      01013020
* OF THE BUFFER.  THE OUTPUT FLAGS ARE SET ACCORDING TO THE RESULTS.    01014020
*                                                                       01015020
         BCTR  XINPUT,ZERO             BACK UP FOR SKIPB                01020020
         BAL   LINK2,SKIPB             SKIP BLANKS TO FIRST PARAMETER   01030020
         B     CSEXIT40                RETURN +0, REACHED END OF BUFFER 01040020
*                                         TAKE VALID EXIT 2             01050020
         B     CSEXIT80                RETURN +4, REACHED FIRST         01060020
*                                         PARAM,TAKE VALID EXIT 1       01070020
         SPACE                                                          01071020
*                                                                       01311020
* IF THE COMMAND NAME IS NOT SYNTAX CHECKED IT IS SCANNED AS FOLLOWS    01312020
* USING THE TYPETEST ROUTINE:                                           01313020
*        1. THE FIRST CHARACTER MUST BE AN ENTERABLE CHARACTER          01314020
*     THAT IS NOT A COMMAND DELIMITER.                                  01315020
*        2. THE OTHER CHARACTERS MUST BE ENTERABLE CHARACTERS.          01316020
*        3. THE SCAN STOPS WHEN A COMMAND DELIMITER IS FOUND.           01317020
*                                                                       01317120
* NOTE:  THE FOLLOWING ARE COMMAND DELIMITERS -- BLANK, TAB, COMMA,     01317220
*        EQUAL SIGN, MINUS SIGN, SLASH, PERIOD, SEMI-COLON, QUOTE,      01317320
*        AMPERSAND, LEFT PAREN, RIGHT PAREN.                            01317420
*                                                                       01318020
CSNOSYN  DS    0H                      NO SYNTAX CHECKING REQUESTED     01320020
         LA    R1,CMDDLIM              SET UP TO TEST FOR VALID         01330020
*                                         COMMAND DELIMITER             01340020
         BAL   LINK1,TYPETEST          LINK TO TYPETEST TO              01342020
*                                         PERFORM TEST                  01343020
*                                                                       01344020
         B     CS11                    +0 RETURN - NOT A COMMAND        01370020
*                                         DELIMITER, CHECK IF GOOD      01380020
*                                         CHARACTER                     01390020
*                                                                       01400020
         B     CSEXIT08                +4 RETURN - A COMMAND DELIMITER, 01410020
*                                         THEN COMMAND NAME IS INVALID  01420020
         SPACE                                                          01430020
CS11     DS    0H                      * * * *                          01440020
***                                                                     01450020
*                                                                       01460020
* DEPENDS UPON CONTENTS OF R15 FROM TYPETEST                            01470020
*                                                                       01480020
***                                                                     01490020
         CLI   ZERO(R15),INVALID       IS CURRENT CHARACTER AN          01500020
*                                         INVALID CHARACTER             01510020
         BE    CSEXIT08                YES, TAKE ERROR EXIT             01520020
         SPACE                                                          01530020
         LA    XINPUT,ONE(XINPUT)      NO, GET NEXT CHARACTER           01540020
         LR    XINPUTB,XINPUT          SET LAST CHARACTER SCANNED       01550020
         C     XINPUT,ENDINPUT         IS SCAN AT END OF BUFFER         01560020
         BNL   CS03                    YES, EXIT NORMALLY               01570020
         SPACE                                                          01580020
         LA    R1,CMDDLIM              SET UP TO TEST FOR VALID         01581020
*                                         COMMAND DELIMITER             01582020
         BAL   LINK1,TYPETEST           LINK TO TYPETEST TO             01584020
*                                         PERFORM TEST                  01585020
*                                                                       01586020
         B     CS11                    +0 RETURN - NOT A COMMAND        01612720
*                                         DELIMITER, CHECK IF GOOD      01620020
*                                         CHARACTER                     01630020
*                                                                       01640020
         B     CS03                    +4 RETURN - A COMMAND DELIMITER, 01650020
*                                         EXIT NORMALLY                 01660020
         SPACE                                                          01670020
CSEXIT80 DS    0H                      * * * *                          01680020
         OI    CSOAFLG,CSOAVWP         SET FLAG IN OUTPUT AREA TO       01690020
*                                         INDICATE COMMAND NAME IS      01700020
*                                         VALID AND THERE ARE NON-      01710020
*                                         SEPARATORS REMAINING          01720020
         B     SETOFF                  GO SET OFFSET                    01730020
         SPACE                                                          01740020
CSEXIT40 DS    0H                      * * * *                          01750020
         OI    CSOAFLG,CSOAVNP         SET FLAG IN OUTPUT AREA TO       01760020
*                                         INDICATE COMMAND NAME IS      01770020
*                                         VALID AND THERE ARE NO NON-   01780020
*                                         SEPARATORS REMAINING          01790020
         B     SETOFF                  GO SET OFFSET                    01800020
         SPACE                                                          01810020
CSEXIT20 DS    0H                      * * * *                          01820020
         OI    CSOAFLG,CSOAQM          SET FLAG IN OUTPUT AREA TO       01830020
*                                         INDICATE COMMAND NAME IS A    01840020
*                                         QUESTION MARK                 01850020
         B     CSEXIT                  EXIT                             01860020
         SPACE                                                          01870020
CSEXIT10 DS    0H                      * * * *                          01880020
         OI    CSOAFLG,CSOANOC         SET FLAG IN OUTPUT AREA TO       01890020
*                                         INDICATE BUFFER IS EMPTY      01900020
         B     SETOFF                  GO SET OFFSET                    01910020
         SPACE                                                          01920020
CSEXIT08 DS    0H                      * * * *                          01930020
         OI    CSOAFLG,CSOABAD         SET FLAG IN OUTPUT AREA TO       01940020
*                                         INDICATE COMMAND NAME IS      01950020
*                                         INVALID                       01960020
         B     CSEXIT                  EXIT                             01970020
         SPACE                                                          01980020
SETOFF   DS    0H                      RESET OFFSET WITHIN COMMAND      01990020
*                                         BUFFER                        02000020
         LA    R2,CBUFTEXT             GET ADDR OF COMMAND BUFFER TEXT  02060020
         SR    XINPUTB,R2              COMPUTE CURRENT OFFSET           02070020
         STH   XINPUTB,PDWORD          STORE CURRENT OFFSET IN          02080020
         MVC   CBUFOFST,PDWORD            COMMAND BUFFER HEADER         02090020
         SPACE                                                          02100020
CSEXIT   DS    0H                      SUCCESSFUL COMPLETION EXIT       02110020
         XR    R3,R3                   CLEAR WORK REG                   02111020
         IC    R3,RETCODE              SAVE RETURN CODE                 02112020
         LR    R1,WORKBASE             LOAD CORE ADDRESS FOR FREEMAIN   02120020
         L     WORKBASE,FOUR(WORKBASE) RESTORE CALLERS SAVE AREA ADDR   02130020
         FREEMAIN R,LV=CSWORKSZ,A=(1)  RELEASE WORKAREA                 02140020
         LR    R15,R3                  LOAD RETURN CODE REGISTER        02150020
         RETURN (14,12),RC=(15)        EXIT FROM COMMAND SCAN           02160020
         EJECT                                                          02170020
*********************************************************************** 02171020
*                                                                     * 02172020
*                       SKIP BLANKS SUBROUTINE                        * 02173020
*                                                                     * 02174020
*   THE FUNCTION OF THIS ROUTINE IS TO SKIP BLANKS, COMMAS AND TABS IN* 02175020
* THE COMMAND BUFFER.                                                   02176020
*                                                                       02176120
*                                                                       02177020
* INPUT - XINPUT=POINTER TO THE LAST CHARACTER SCANNED.                 02178020
*                (THE SCAN FOR SEPARATORS BEGINS AT THE NEXT            02179020
*                CHARACTER.)                                            02179120
*                                                                       02179220
* OUTPUT - IF A NON-SEPARATOR WAS FOUND:                                02179320
*               XINPUT=POINTER TO THE LAST SEPARATOR SCANNED.           02179420
*               PPOINTR=POINTER TO THE FIRST NON-SEPARATOR.             02179520
*                                                                       02179620
*        - IF THE END OF THE BUFFER WAS REACHED BEFORE A                02179720
*          NON-SEPARATOR WAS FOUND:                                     02179820
*               XINPUT=POINTER TO THE LAST CHARACTER IN THE BUFFER.     02179920
*               PPOINTR=POINTER TO THE END OF THE BUFFER.               02180020
*                                                                       02180120
* EXITS - LINK2+0=THE END OF THE BUFFER WAS REACHED BEFORE A            02180220
*                 NON-SEPARATOR WAS FOUND.                              02180320
*                                                                       02180420
*       - LINK2+4=A NON-SEPARATOR CHARACTER WAS FOUND.                  02180520
*                                                                     * 02180720
*********************************************************************** 02180820
         SPACE                                                          02180920
SKIPB    DS    0H                      SKIP SEPARATORS SUBROUTINE       02181020
         LA    XINPUT,ONE(XINPUT)      BUMP INPUT PTR BY ONE            02181120
         LR    XINPUTB,XINPUT          SET BACKUP REGISTER              02181220
         C     XINPUT,ENDINPUT         END OF INPUT                     02181320
*                                                                       02181420
         BNL   SKIPBX                  YES - EXIT                       02181720
*                                                                       02181820
*                                      NO - TEST FOR A SEPARATOR        02181920
         LA    R1,SEPAR                SET UP TEST FOR VALID SEPARATOR  02182020
         BAL   LINK1,TYPETEST          LINK TO TYPETEST TO              02182320
*                                         PERFORM TEST                  02182420
*                                                                       02182520
         B     SKIPB2                  +0 RETURN - NON-SEPARATOR, GO    02182620
*                                         SET PPOINTR AND EXIT          02182720
*                                                                       02182820
         B     SKIPB                   +4 RETURN - SEPARATOR, CONTINUE  02182920
*                                         LOOP                          02183020
         SPACE                                                          02183220
SKIPB2   DS    0H                      * * * *                          02183320
         ST    XINPUT,PPOINTR          STORE ADDRESS OF NON-SEPARATOR   02183620
         BCT   XINPUT,FOUR(LINK2)      BACK UP INPUT PTR BY ONE AND     02183720
*                                         RETURN TO NSI +4              02183820
         SPACE                                                          02183920
SKIPBX   DS    0H                      * * * *                          02184020
         ST    XINPUT,PPOINTR          STORE ADDRESS                    02184120
         BCTR  XINPUT,LINK2            BACK UP INPUT PTR BY ONE AND     02184220
*                                         RETURN TO NSI +0              02184320
         EJECT                                                          02184420
*********************************************************************** 02184520
*                                                                     * 02184620
*                 CHARACTER TYPE TEST ROUTINE                         * 02184820
*                                                                     * 02184920
*   THIS SUBROUTINE CHECKS THE CURRENT INPUT CHARACTER FOR              02185020
* BELONGING TO A SPECIFIED CHARACTER CLASS.                           * 02185120
*                                                                     * 02185220
* INPUT - R1=MASK OF DESIRED CHARACTER CLASS.                         * 02185320
*         XINPUT=POINTER TO CHARACTER TO BE CHECKED.                  * 02185420
*                                                                     * 02185520
* OUTPUT - THE RESULT OF THE TEST IS INDICATED BY THE                 * 02185620
*          LOCATION TO WHICH CONTROL IS RETURNED.                     * 02185720
*                                                                     * 02185820
* EXISTS - LINK1+0=THE CHARACTER DOES NOT BELONG TO THE SPECIFIED     * 02185920
*                  CHARACTER CLASS.                                   * 02186020
*                                                                     * 02186120
*        - LINK1+4=THE CHARACTER BELONGS TO THE CHARACTER CLASS       * 02186220
*                  SPECIFIED.                                         * 02186320
*                                                                     * 02186420
*********************************************************************** 02186520
         SPACE                                                          02186720
TYPETEST DS    0H                      * * * *                          02186820
         XR    R15,R15                 CLEAR WORK REG                   02186920
         IC    R15,ZERO(XINPUT)        USE CURRENT CHARACTER AS         02187020
*                                         OFFSET INTO TESTING TABLE     02187120
         A     R15,ATRTAB              GET ADDRESS IN TABLE             02187220
*                                         CORRESPONDING TO CHARACTER IN 02187320
*                                         QUESTION                      02187420
         EX    R1,TYPETM               EXECUTE TEST UNDER MASK OF       02187620
*                                         TYPEBYTE FOR CHARACTER        02187720
*                                         SPECIFICATION GIVEN IN R1     02187820
*                                                                       02187920
         BC    CC5,FOUR(LINK1)         TYPE MATCHES, RETURN +4          02188220
*                                                                       02188320
         BR    LINK1                   TYPE DOESN'T MATCH, RETURN +0    02188420
         EJECT                                                          02188620
*********************************************************************** 02188720
*                                                                     * 02190020
*                          CONSTANT AREA                              * 02200020
*                                                                     * 02210020
*********************************************************************** 02220020
         SPACE                                                          02221020
*                                                                       02222020
* CONTROL INFORMATION FOR GENSCAN WHEN SCANNING FOR A COMMAND NAME      02223020
*                                                                       02224020
CMDSYNTX EQU   *                       * * * *                          02225020
         DC    X'40'                   ASTERISK NOT ALLOWED, MAXIMUM    02226020
*                                         LENGTH SPECIFIED              02227020
         DC    X'01'                   FIRST CHARACTER MUST BE          02228020
*                                         ALPHABETIC                    02229020
         DC    X'03'                   OTHER CHARACTERS MUST BE         02229120
*                                         ALPHAMERIC                    02229220
         DC    X'08'                   MAXIMUM LENGTH = 8               02229320
*                                                                       02229420
* VCON'S FOR EXTERNAL UTILITY ROUTINES                                  02229520
*                                                                       02229620
AGSCAN   DC    V(GENSCAN)              ADDRESS OF GENERALIZED SCAN      02230420
*                                         UTILITY ROUTINE USED TO       02230520
*                                         SYNTAX CHECK THE COMMAND NAME 02230620
         SPACE                                                          02230720
ATRANSX  DC    V(TRANSX)               ADDRESS OF TRANSLATE UTILITY     02230920
*                                         ROUTINE USED TO TRANSLATE THE 02231220
*                                         COMMAND NAME TO UPPER CASE    02231320
         SPACE                                                          02231420
*                                                                       02231520
* ADCON FOR EXTERNAL TABLE USED BY TYPETEST TO TEST FOR A               02231620
* GIVEN CHARACTER CLASS                                                 02231720
*                                                                       02231820
ATRTAB   DC    A(TRTAB)                ADDRESS OF EXTERNAL TABLE USED   02231920
*                                         BY TYPETEST                   02232020
         SPACE                                                          02232120
TYPETM   TM    ZERO(R15),*-*           USED BY TYPETEST TO TEST         02232220
*                                         FOR A CHARACTER TYPE          02232320
         EJECT                                                          02232420
CSWORK   IKJEFPWA                                                       02232520
         SPACE                                                          02233920
         IKJCSPL                                                        02234220
         SPACE                                                          02234320
         IKJCSOA                                                        02234620
         SPACE                                                          02234720
*********************************************************************** 02235020
*                                                                     * 02235120
*        THE COMMAND BUFFER IS A BUFFER POINTED TO BY THE CSPL.       * 02235320
*        IT CONTAINS THE COMMAND TO BE SCANNED.                       * 02235420
*                                                                     * 02235520
*********************************************************************** 02235620
         SPACE                                                          02235720
CBUF     DSECT                         * * * *                          02235920
CBUFLEN  DS    CL2                     LENGTH OF COMMAND BUFFER         02236020
CBUFOFST DS    CL2                     OFFSET INTO BUFFER TEXT          02236120
CBUFTEXT EQU   *                       TEXT                             02236220
         END                                                            02236320
