         TITLE 'IKJGG001 - TIOC INITIALIZATION'                         00100020
         COPY  LCGASMS2                                                 00130021
IKJGG001 CSECT                                                          00200020
         ENTRY IKJGGE00                                                 00300020
         ENTRY IKJGGE01                                                 00400020
         SPACE 3                                                        00500020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 00580020
*                                                                     * 00660020
*                                                                     * 00740020
*    NAME - IKJGG001, TIOC INITIALIZATION                             * 00820020
*                                                                     * 00900020
*    RELEASE 23 DELETIONS/CHANGES                                     * 00980020
*    RELEASE 22 DELETIONS/CHANGES                                     * 01060020
*    RELEASE 21 DELETIONS/CHANGES                                     * 01140020
*1342152600,507000,510000,729000                                 S22028 01160001
*1342066600,127000,152600,163000,267000,268000,326000,711000     A44022 01180021
*    RELEASE 20 DELETIONS/CHANGES                                     * 01220020
*                                                                TS1623 01300020
*                                                                 M0709 01380020
*                                                                TS1637 01460021
*                                                                 M3047 01620020
*                                                                 M5113 01700020
*                                                                 M6095 01740020
*                                                                     * 01780020
* STATUS -                                                            * 01860020
* STATUS CHANGE LEVEL 001                                               01940021
*                                                                     * 02020020
* FUNCTION -                                                          * 02100020
*    CALCULATE TIOC CORE REQUIREMENT (FOR TIOCRPT, TSB'S AND BUFFERS) * 02180020
*    CONSTRUCT AND INITIALIZE TIOCRPT, TSB CHAIN, AND BUFFER CHAIN    * 02260020
*                                                                     * 02340020
* ENTRY POINTS -                                                      * 02420020
*         IKJGG001/IKJGGE00, BEGINNING OF ROUTINE, FROM TSC TO CALCU- * 02500020
*         LATE TIOC CORE REQUIREMENT                                  * 02580020
*         IKJGGE01, BODY OF ROUTINE, FROM TSC TO CONSTRUCT AND INITI- * 02660020
*         ALIZE TIOC CONTROL BLOCKS                                   * 02740020
*                                                                     * 02820020
* INPUT -                                                             * 02900020
*    REGISTER  1 HAS TSC PARAMETER LIST ADDRESS                       * 02980020
*    REGISTER 13 HAS REGISTER SAVE AREA ADDRESS                       * 03060020
*    REGISTER 14 HAS RETURN ADDRESS                                   * 03140020
*    REGISTER 15 HAS ENTRY ADDRESS                                    * 03220020
*                                                                     * 03300020
* OUTPUT -                                                            * 03380020
*    WORD 5 OF TSC'S PARAMETER LIST IS FILLED WITH AMOUNT OF CORE RE- * 03460020
*    QUIRED BY TIOC IF FIRST ENTRY IS TAKEN                           * 03540020
*                                                                     * 03620020
* EXTERNAL REFERENCES -                                               * 03700020
*         GETMAIN, VIA SVC 10                                         * 03780020
*         FREEMAIN, VIA SVC 10                                        * 03860020
*         WTO, VIA SVC 35                                             * 03940020
*         SMFWTM, VIA SVC 83                                          * 04020020
         AIF   ('&LIB' NE 'LIB4').LIB4BAA                        Y01018 04030000
*         PAGE SERVICE, VIA SVC 113                                   * 04040000
*         WAIT, VIA SVC 1                                             * 04050000
.LIB4BAA ANOP                                                           04060000
*                                                                     * 04100020
* EXITS, NORMAL -                                                     * 04180020
*         BR 14, RETURN TO TSC FOR BOTH ENTRIES......REGISTER 15 CON- * 04260020
*         TAINS 0 (NO PARAMETERS DEFAULTED) OR 4 (ONE OR MORE PARAME- * 04340020
*         TERS DEFAULTED)                                             * 04420020
*                                                                     * 04500020
* EXITS, ERROR -                                                      * 04580020
*         BR 14, RETURN TO TSC FOR SECOND ENTRY......REGISTER 15 CON- * 04660020
*         TAINS 8 (TCAM NOT UP, OR TCAM DOESN'T  SUPPORT TSO, OR GET- * 04740020
*         MAIN FAILED)                                                * 04820020
*                                                                     * 04900020
* TABLES/WORK AREAS -                                                 * 04980020
*    CONTROL BLOCKS ARE DESCRIBED IN THE DSECTS AT END OF LISTING     * 05060020
*    REGISTERS ARE SAVED IN THE SAVE AREA SENT IN REGISTER 13         * 05140020
*    A MEMBER OF SYS1.PARMLIB, WHICH IS READ INTO CORE BY TSC, SPECI- * 05220021
*    FIES ALL THE TSO PARAMETERS, INCLUDING THOSE FOR TIOC            * 05300021
*    'WA', A WORK AREA FOR CONVERTING TO BINARY                       * 05380020
*    'GMLIST', A WORK AREA FOR GETMAIN                                * 05460020
*    'DTBL', A TABLE BUILT BY THIS ROUTINE OF VALID TIOC PARAMETERS   * 05540020
*    'KEYWDTBL', A TABLE OF SYS1.PARMLIB TIOC PARAMETER KEYWORDS, VA- * 05620020
*    LIDITY CHECK ROUTINE ADDRESSES, AND DEFAULT ROUTINE ADDRESSES    * 05700020
*    'TTISMF', SMF RECORD TYPE 31 BUILT BY THIS ROUTINE               * 05780020
*                                                                     * 05860020
* ATTRIBUTES -                                                        * 05940020
*    ENABLED, SUPERVISOR STATE                                        * 06020021
*                                                                     * 06100020
* CHARACTER CODE DEPENDENCY -                                         * 06180020
*    THE OPERATION OF THIS MODULE IS DEPENDENT UPON  CERTAIN INTERNAL * 06260020
*    REPRESENTATIONS OF ITS CHARACTER SET...IT IS ASSEMBLED IN EBCDIC * 06340020
*    BUT MUST BE SPECIALLY MODIFIED IF RE-ASSEMBLY IN ANOTHER CHARAC- * 06420020
*    TER SET IS DESIRED...THE FIELDS  REQUIRING THIS MODIFICATION ARE * 06500020
*    ALL UNDER THE 'MASKS AND CHARACTERS' HEADING, AND ARE 'WORDINT', * 06580020
*    AND 'MAKEWORD'                                                   * 06660021
*                                                                     * 06740020
* NOTES -                                                             * 06820020
*    REGISTER EQUATES START WITH 'R'                                  * 06900020
*    LENGTH AND DISPLACEMENT EQUATES START WITH 'E'                   * 06980020
*    CERTAIN CONSTANTS START WITH 'K'                                 * 07060020
*                                                                     * 07140020
*                                                                     * 07220020
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 07300020
         EJECT                                                          07900020
********                                                                08000020
******** REGISTER NAMES                                                 08100020
********                                                                08200020
R0       EQU   0                        SVC PARM REG             M1806  08300021
R1       EQU   1                        TSC PARM LIST PASSED ON BOTH    08400020
*                                       ENTRIES AND SVC PARM REG        08500021
RWORK    EQU   1                        WORK REG                 M1806  08550021
RSCAN    EQU   2                        PARAMETER SCANNER AND WORK REG  08600020
RWABASE  EQU   3                        BASE REG FOR WORK AREA   M1806  08700021
RGO      EQU   4                        HOLDS ADDR OF PARM CHK RTN      08800020
*                                       AND THEN PARM DEFAULT RTN       08900020
RRPT     EQU   4                        TIOCRPT ADDR                    09000020
RTBL     EQU   5                        ADDR OF ENTRY IN KEYWORD TBL    09100020
RTSB     EQU   5                        TSB ADDR                        09200020
REC      EQU   6                        HOLDS ENTRY CODE (0 FROM TSC    09300020
*                                       AND NON-0 FROM SECOND HALF)     09400020
RBFR     EQU   6                        BUFFER ADDR                     09500020
REND     EQU   7                        END OF PARAMETERS               09600020
RTSCVT   EQU   7                        TSCVT ADDR                      09700020
RCVT     EQU   8                        CVT ADDR                        09800020
RPLIST   EQU   9                        PARAMETER LIST ADDR             09900020
REVEN    EQU   10                       WORK REG                        10000020
RODD     EQU   11                       WORK REG                        10100020
RBASE    EQU   12                       BASE REG                        10200020
R13      EQU   13                       SAVE AREA ADDR                  10300020
R14      EQU   14                       RETURN ADDR                     10400020
RNEXTCD  EQU   14                       ADDR OF NEXT SYS1.PARMLIB CARD  10500020
R15      EQU   15                       ENTRY ADDR AND RETURN CODE      10600020
         SPACE 3                                                        10800020
********                                                                10900020
******** DISPLACEMENTS AND LENGTHS                                      11000020
********                                                                11100020
E1       EQU   1                        GIVES A VALUE OF 1              11200020
E3       EQU   3                        GIVES A VALUE OF 3              11300020
E4       EQU   4                        GIVES A VALUE OF 4              11400020
E5       EQU   5                        GIVES A VALUE OF 5              11500020
E6       EQU   6                        GIVES A VALUE OF 6              11600020
E8       EQU   8                        GIVES A VALUE OF 8              11700020
E12      EQU   12                       GIVES A VALUE OF 12             11800020
E14      EQU   14                       GIVES A VALUE OF 14             11900020
E80      EQU   80                       GIVES A VALUE OF 80             12000020
         SPACE 3                                                        12100020
********                                                                12200020
******** MASKS AND CHARACTERS                                           12300020
********                                                                12400020
ERRCODE  EQU   8                        ERROR RETURN CODE        TS1637 12450020
WORDINT  EQU   X'03'                    TESTS 'BUFSIZE' FOR WD INTEGRAL 12500020
MAKEWORD EQU   X'FC'                    MAKES 'BUFSIZE' A WD INTEGRAL   12600020
BLANK    EQU   C' '                     BLANK - DENOTES END OF VALUE    12800020
COMMA    EQU   C','                     COMMA - MAY DENOTE END OF VALUE 12850020
EQSIGN   EQU   C'='                     EQUAL SIGN FOR PARM SCAN        12900020
PLUS     EQU   C'+'                     PLUS - DENOTES POS VALUE M1806  12910021
ZERO     EQU   C'0'                     LOWER LIM OF VALID CHAR  M1806  12940021
NINE     EQU   C'9'                     UPPER LIM OF VALID CHAR  M1806  12970021
ENTSIZE  EQU   12                       SIZE OF ONE PARM'S ENTRY        13000020
*                                       IN KEYWORD TABLE                13100020
         AIF   ('&LIB' NE 'LIB4').LIB4BAB                        Y01018 13120000
FIXOPPUR EQU   X'48'                    SAYS FIX OP WAS PURGED   Y01018 13140000
PAGEMAKE EQU   12                       MAKES ADDR INTO PAGE NO. Y01018 13160000
.LIB4BAB ANOP                                                           13180000
TYPE31   EQU   31                       IDENTIFIES SMF RECORD           13200020
NOT      EQU   X'FF'                    TURNS OFF VARIOUS BITS          13300020
         SPACE 3                                                        13400020
* * * * * * * * * * * * * * * FIRST ENTRY * * * * * * * * * * * * * * * 13500020
         SPACE 3                                                        13600020
********                                                                13700020
******** SAVE REGISTERS AND ESTABLISH ADDRESSABILITY FOR FIRST ENTRY    13800020
********                                                                13900020
IKJGGE00 EQU   *                                                        14000020
         STM   R14,RBASE,E12(R13)       SAVE REGS                       14100020
         BALR  RBASE,0                  GET BASE ADDR                   14200020
         USING START,RBASE              ADDRESSABILITY FOR BASE         14300020
START    EQU   *                                                        14400020
         LR    RPLIST,R1                GET TSC PARM LIST ADDR          14500020
         USING PLIST,RPLIST                                             14600020
         L     RCVT,CVTPTR              GET CVT ADDR                    14700020
         USING CVT,RCVT                                                 14800020
         SR    REC,REC                  DENOTE ENTRY FROM TSC           15200020
         B     PASTID                   GET PAST MODULE ID              15220020
         DC    C'IKJGG001'              MODULE ID                       15240020
         DC    X'2038'                  DATE - 2/7/72            S22028 15260001
PASTID   DS    0H                                                       15280020
         SPACE 3                                                        15800020
********                                                                15900020
******** OBTAIN A WORK AREA FOR PARAMETER CHECKING                      16000020
********                                                                16100020
CHKPARMS EQU   *                                                        16200020
         L     R0,WORK                  GET SUBPOOL NO. & WORK   A44022 16260021
*                                       AREA SZ                  A44022 16320021
         GETMAIN    R,LV=(0)            GET CORE AMOUNT IN REG 0        16400020
         SPACE 3                                                        16500020
********                                                                16600020
******** INITIALIZE THE WORK AREA                                       16700020
********                                                                16800020
         LR    RWABASE,R1               CORE ADDR RETURNED IN R1 M1806  16900021
         USING WADSECT,RWABASE                                   M1806  16950021
         LH    REVEN,WORKSIZE           GET SIZE OF WORK AREA GIVEN     17000020
         BCTR  REVEN,0                  SUB 1 FOR EX INSTR              17100020
         EX    REVEN,ZEROCORE           ZERO ENTIRE WORK AREA           17200020
         MVC   CVBWA,CHARZERO           PREPARE CVBWA FOR PACK AND CVB  17300020
         SPACE 3                                                        17400020
********                                                                17500020
******** INITIALIZE FOR FINDING TIOC PARAMETER CARDS                    17600020
********                                                                17700020
         MVC   DNUMUSER,PARMNU2         PUT NO. USERS IN TBL            17800020
         LA    RTBL,KEYWDTBL-ENTSIZE    POINT AT KEYWD TBL - ENT SIZE   17900020
*                                       ADDR WILL BE ADJUSTED BELOW     18000020
         L     REND,PARMAD              GET PARM ADDR FROM TSC LIST     18100020
         A     REND,PARMLNG             ADD PARM LNG TO GET END ADDR    18200020
NEXTPARM EQU   *                                                        18300020
         LA    RTBL,ENTSIZE(0,RTBL)     POINT TO NEXT ENT IN KEYWD TBL  18400020
         L     RSCAN,PARMAD             GET PARM ADDR FROM TSC LIST     18500020
         LR    RNEXTCD,RSCAN            GET PARM ADDR                   18600020
         LA    RNEXTCD,E80(0,RNEXTCD)   ADD 80 TO POINT AT NEXT CARD    18700020
         SPACE 3                                                        18800020
********                                                                18900020
******** LOCATE TIOC PARAMETER CARDS WITHIN TSC PARAMETER AREA          19000020
********                                                                19100020
ISITTIOC EQU   *                                                        19200020
         CLI   0(RSCAN),BLANK           IS THIS A BLANK                 19300020
         BNE   CHKID                    NO - SEE IF ID IS 'TIOC'        19400020
         LA    RSCAN,E1(0,RSCAN)        YES - POINT AT NEXT CHAR        19500020
         CR    RSCAN,RNEXTCD            HAVE WE REACHED THE NEXT CARD   19600020
         BL    ISITTIOC                 NO - GO LOOK FOR 'TIOC'         19700020
         SPACE 3                                                        19800020
********                                                                19900020
******** CHECK FOR HAVING REACHED THE END OF THE PARAMETER LIST         20000020
********                                                                20100020
CHKEND   EQU   *                                                        20200020
         CR    RNEXTCD,REND             HAVE WE REACHED THE LAST CARD   20300020
         BNL   DEFAULT                  YES - GO GIVE A DEFAULT         20400020
         LR    RSCAN,RNEXTCD            NO - POINT AT NEXT CARD         20500020
         LA    RNEXTCD,E80(0,RNEXTCD)   POINT AT NEXT CARD              20600020
         B     ISITTIOC                 GO LOOK FOR 'TIOC'              20700020
         SPACE 3                                                        20800020
********                                                                20900020
******** SEE IF THIS REALLY IS TIOC'S ID, 'TIOC'                        21000020
********                                                                21100020
CHKID    EQU   *                                                        21200020
         CLC   TIOCID,0(RSCAN)          IS THIS TIOC'S ID               21300020
         BNE   CHKEND                   NO - TRY THE NEXT CARD, IF ANY  21400020
         SPACE 3                                                        21500020
********                                                                21600020
******** TIOC'S ID FOUND - PREPARE TO SCAN FORWARD FOR DESIRED KEYWORD  21700020
********                                                                21800020
         LA    RSCAN,E5(0,RSCAN)        POINT TO FIRST POSSIBLE KEYWORD 21900020
         SH    RNEXTCD,K9               POINT TO LAST POSSIBLE CHAR     22000020
         SPACE 3                                                        22100020
********                                                                22200020
******** LOOK FOR AN EQUAL SIGN AND DESIRED KEYWORD                     22300020
********                                                                22400020
ISITEQSN EQU   *                                                        22500020
         CLI   0(RSCAN),EQSIGN          IS THIS AN EQUAL SIGN           22600020
         BNE   CONTSCAN                 NO - BR TO CONT LOOKING         22700020
         SH    RSCAN,K4                 YES - POINT TO LAST 4 CHARS     22800020
*                                       OF KEYWORD                      22900020
         CLC   0(E4,RSCAN),0(RTBL)      IS THIS THE KEYWORD WE WANT     23000020
         BE    KWFOUND                  YES - GO CHK IT OUT             23100020
         LA    RSCAN,E6(0,RSCAN)        POINT PAST KEYWD JUST SCANNED   23200020
         B     ISITEQSN                 BR TO CHK NEXT CHAR             23300020
         SPACE 3                                                        23400020
********                                                                23500020
******** CHECK FOR HAVING REACHED THE END OF A CARD                     23600020
********                                                                23700020
CONTSCAN EQU   *                                                        23800020
         LA    RSCAN,E1(0,RSCAN)        POINT AT NEXT CHAR              23900020
         CR    RSCAN,RNEXTCD            ENTIRE CARD SCANNED             24000020
         BL    ISITEQSN                 NO - BR TO CHK NEXT CHAR        24100020
         AH    RNEXTCD,K9               YES - GET EXACT END OF CD AGAIN 24200020
         B     CHKEND                   TRY NEXT CARD, IF ANY           24300020
         SPACE 3                                                        24400020
********                                                                24500020
******** DESIRED KEYWORD FOUND - PICK UP ITS VALUE                      24600020
********                                                                24700020
KWFOUND  EQU   *                                                        24800020
         LA    RSCAN,E5(0,RSCAN)        POINT TO VALUE SPEC'ED          24900020
         LR    RODD,RSCAN               GET ADDR OF VALUE               25000020
         LA    REVEN,E1                 PREPARE REG FOR COUNTING        25100020
         CLI   0(RODD),PLUS             IS THIS A PLUS SIGN      A44022 25110021
         BNE   RELOOK                   NO - CHK FOR A NUMBER    A44022 25120021
         MVI   0(RODD),ZERO             OVERLAY AN INVALID NO.   M1806  25140021
         B     NEXTCHAR                 CHECK NEXT CHAR          A44022 25160021
RELOOK   EQU   *                                                        25200020
         CLI   0(RODD),ZERO             IS CHAR GT OR EQ ZERO    A44022 25210021
         BL    CONTSCAN                 NO - INVALID             A44022 25220021
*                                       VALUE...LOOK FOR         A44022 25230021
*                                       ANOTHER VALUE FOR THIS PARM     25240021
         CLI   0(RODD),NINE             IS CHAR LT OR EQ NINE    A44022 25250021
         BH    CONTSCAN                 NO - INVALID             A44022 25260021
*                                       VALUE...LOOK FOR         A44022 25270021
*                                       ANOTHER VALUE FOR THIS PARM     25280021
NEXTCHAR EQU   *                                                 A44022 25290021
         LA    RODD,E1(0,RODD)          POINT TO NEXT CHAR              25300020
         CLI   0(RODD),BLANK            IS THIS A BLANK (END OF VALUE)  25400020
         BE    LETSPACK                 YES - GO PACK VALUE             25500020
         CLI   0(RODD),COMMA            IS THIS A COMMA (END OF VALUE)  25530020
         BE    LETSPACK                 YES - GO PACK VALUE             25560020
         CR    RODD,RNEXTCD             HAVE WE REACHED END OF CARD     25600020
         BE    LETSPACK                 YES - GO PACK VALUE             25700020
         CH    REVEN,K8                 8 CHARS COUNTED YET             25800020
         BE    RELOOK                   YES - DON'T INCR COUNT ANYMORE  25900020
         LA    REVEN,E1(0,REVEN)        ADD 1 TO NO. CHARS IN VALUE     26000020
         B     RELOOK                   KEEP LOOKING FOR END OF VALUE   26100020
         SPACE 3                                                        26200020
********                                                                26300020
******** PREPARE VALUE FOR PACKING                                      26400020
********                                                                26500020
LETSPACK EQU   *                                                        26600020
         BCTR  RODD,0                   POINT AT CHAR BEFORE     A44022 26700021
*                                       DELIMITER                A44022 26800021
         LA    RWORK,CVBLAST            GET ADDR OF LAST BYTE IN CVBWA  26900020
MOVEM    EQU   *                                                        27000020
         MVC   0(E1,RWORK),0(RODD)      MOVE CHAR TO CVBWA              27100020
         BCTR  RWORK,0                  POINT AT NEXT POS IN CVBWA      27200020
         BCTR  RODD,0                   POINT AT NEXT CHAR IN VALUE     27300020
         BCT   REVEN,MOVEM              MOVE WHOLE VALUE                27400020
         SPACE 3                                                        27500020
********                                                                27600020
******** PACK VALUE AND SEE IF IT IS ACCEPTABLE FOR THIS KEYWORD        27700020
********                                                                27800020
         PACK  CVBWA(E8),CVBWA(E8)      PACK VALUE                      28000020
         CVB   RODD,CVBWA               CONVERT VALUE TO BINARY         28100020
         MVC   CVBWA,CHARZERO           PREPARE CVBWA FOR NEXT USE      28200020
         L     RGO,E4(0,RTBL)           GET PARM CHK RTN ADDR           28300020
         BR    RGO                      GO CHK THIS PARM'S VALIDITY     28400020
         SPACE 3                                                        28500020
********                                                                28600020
******** GIVE A DEFAULT VALUE SINCE KEYWORD NOT FOUND                   28700020
********                                                                28800020
DEFAULT  EQU   *                                                        28900020
         L     RGO,E8(0,RTBL)           YES - GET PARM DEFAULT RTN ADDR 29000020
         BR    RGO                      GO GIVE DEFAULT FOR THIS PARM   29100020
         SPACE 3                                                        29200020
********                                                                29300020
******** DETERMINE BUFFER AREA REQUIRED                                 29400020
********                                                                29500020
CNTCORE  EQU   *                                                        29600020
         LH    RODD,DBFRSIZE            GET BFR SIZE                    29700020
         MH    RODD,DNUMBFRS            MULT BY TOTAL NO. BFRS WANTED   29800020
         SPACE 3                                                        29900020
********                                                                30000020
******** DETERMINE TSB AREA REQUIRED                                    30100020
********                                                                30200020
         LH    REVEN,DNUMUSER           GET NO. USERS IN SYSTEM         30300020
         MH    REVEN,KTSBSIZE           MULT BY TSB SIZE                30400020
         AR    RODD,REVEN               ADD TO BFR AREA                 30500020
         SPACE 3                                                        30600020
********                                                                30700020
******** DETERMINE TOTAL AREA REQUIRED                                  30800020
********                                                                30900020
         AH    RODD,KRPTSIZE            ADD RPT SIZE                    31000020
         SPACE 3                                                        31100020
********                                                                31200020
******** CHECK FROM WHENCE ENTRY CAME                                   31300020
********                                                                31400020
         LTR   REC,REC                  IS ENTRY FROM TSC               31500020
         BNZ   GETCORE                  NO - GO BACK AND CONT INIT      31600020
         ST    RODD,PARMCORE            YES - PUT CORE REQ IN PLIST     31700020
         SPACE 3                                                        31800020
********                                                                31900020
******** RETURN TO TSC                                                  32000020
********                                                                32100020
GOBACK   EQU   *                                                        32200020
         LH    REVEN,RETCODE            SAVE RETURN CODE         M1806  32400021
         L     R0,WORK                  SUBPOOL & WORK AREA SZ   M1806  32500021
         LR    R1,RWABASE               STARTING ADDR TO FREE    M1806  32600021
         FREEMAIN   R,LV=(0),A=(1)      FREE THE WORK AREA              32700020
         LR    R15,REVEN                PUT RET CODE WHERE EXPECTED     32770020
PEACE    EQU   *                                                 TS1637 32850020
         RETURN     (14,12),RC=(15)     RESTORE ALL REGS 'CEPT REG 15   32900020
         SPACE 3                                                        33000020
* * * * * * * * * * * * * * * SECOND ENTRY  * * * * * * * * * * * * * * 33100020
         SPACE 3                                                        33200020
********                                                                33300020
******** ADJUST BASE REGISTER FOR SECOND ENTRY                          33400020
********                                                                33500020
IKJGGE01 EQU   *                                                        33600020
         B     E6(R15)                  BRANCH AROUND TO INIT BASE REG  33700020
         DC    AL2(IKJGGE01-START)      OFFSET FROM THE BASE            33800020
         STM   R14,RBASE,E12(R13)       SAVE REGS                       33900020
         LR    RBASE,R15                STORE ENTRY ADDRESS             34000020
         SH    RBASE,E4(0,R15)          SET RBASE TO BASE               34100020
         SPACE 3                                                        34200020
********                                                                34300020
******** SAVE REGISTERS AND ESTABLISH ADDRESSABILITY FOR SECOND ENTRY   34400020
********                                                                34500020
         LR    RPLIST,R1                GET PARAMETER LIST ADDR         34600020
         USING PLIST,RPLIST                                             34700020
         L     RCVT,CVTPTR              GET CVT ADDR                    34800020
         USING CVT,RCVT                                                 34900020
         LA    REC,*                    SET ENTRY CODE TO NON-0 NO.     35000020
         SPACE 3                                                        35100020
********                                                                35200020
******** SEE IF TCAM HAS BEEN STARTED                                   35300020
********                                                                35400020
         TM    CVTTCMFG,CVTTCRDY        IS TCAM UP                      35500020
         BO    CHKCOMBO                 YES - CHK FOR TCAM-TSO COMBO    35600020
         SPACE 3                                                        35700020
********                                                                35800020
******** TCAM NOT STARTED                                               35900020
********                                                                35920020
         SR    R0,R0                    CLEAR REG FOR IC INSTR          35950020
         IC    R0,PMCSFLAG              GET MASTER CONSOLE ID           36000020
         WTO   'IKJ401I START TCAM BEFORE TSO',                        C36060020
               DESC=5,MCSFLAG=(REG0)                                    36120020
         SPACE 3                                                        36200020
********                                                                36300020
******** ERROR RETURN                                                   36400020
********                                                                36500020
ERROR    EQU   *                                                        36600020
         LA    R15,ERRCODE              GET ERROR RETURN CODE    TS1637 36700020
         B     PEACE                    BR TO RETURN             TS1637 36800020
         SPACE 3                                                        36900020
********                                                                37000020
******** SEE IF THE VERSION OF TCAM THAT WAS STARTED INCLUDES TSO       37100020
********                                                                37200020
CHKCOMBO EQU   *                                                        37300020
         L     RWORK,CVTAQAVT           GET TCAM DISPATCHER ADDR M1806  37400021
         L     RWORK,0(0,RWORK)         GET AVT ADDR FROM DISPA  M1806  37500021
         USING IEDQAVTD,RWORK                                    M1806  37600021
         NI    AVTBIT3,NOT-AVTTSAB      ZERO ABEND INDICATOR     M1806  37650021
         NC    AVTTSOPT+1(E3),AVTTSOPT+1     DOES TCAM INCLUDE TSO      37700020
         BNZ   CHKPARMS                 YES - BR TO CALC CORE NEEDS     37800020
         DROP  RWORK                    NO LONGER AVT BASE       M1806  37850021
         SPACE 3                                                        37900020
********                                                                38000020
******** TCAM DOES NOT INCLUDE TSO                                      38100020
********                                                                38200020
         SR    R0,R0                    CLEAR REG FOR IC INSTR          38240020
         IC    R0,PMCSFLAG              GET MASTER CONSOLE ID           38280020
         WTO   'IKJ402I TCAM PROCEDURE DOES NOT SUPPORT TSO',          C38340020
               DESC=5,MCSFLAG=(REG0)                                    38400020
         B     ERROR                    GIVE ERROR RETURN        TS1637 38460020
         SPACE 3                                                        38700020
********                                                                38800020
******** GET CORE FOR TIOC CONTROL BLOCKS (TIOCRPT, TSB'S, BUFFERS)     38900020
********                                                                39000020
GETCORE  EQU   *                                                        39100020
         LA    RSCAN,COREADDR           GET PLACE TO PUT CORE ADDR      39300020
         LA    R1,GMLIST                GET ADDR OF GETMAIN PARM LIST   39400020
         GETMAIN    EC,LV=(11),A=(2),SP=252,MF=(E,(1))                  39460020
*                                       GET AMOUNT IN REG 11            39520020
         SPACE 3                                                 Y01018 39600000
********                                                                39604000
******** RETURN IF CORE NOT GIVEN - OTHERWISE, SET UP TO BUILD BLOCKS   39608000
********                                                                39612000
         CH    R15,K4                   WAS CORE ALLOCATED       Y01018 39616000
         BE    ERROR                    NO - GIVE ERROR RETURN   Y01018 39620000
         L     RRPT,COREADDR            GET ADDR OF CORE GOTTEN  Y01018 39624000
         LA    RRPT,0(0,RRPT)           ZERO HI-ORDER BYTE       Y01018 39628000
         AIF   ('&LIB' NE 'LIB4').LIB4BAC                        Y01018 39632000
         LR    RSCAN,RRPT               GET ADDR OF CORE GOTTEN  Y01018 39636000
         AR    RSCAN,RODD               GET END OF CORE GOTTEN   Y01018 39640000
         SPACE 3                                                 Y01018 39644000
********                                                                39648000
******** FIX TIOC PAGE(S) INTO CORE ONE BY ONE                          39652000
********                                                                39656000
FIXIT    EQU   *                                                 Y01018 39660000
         XC    FIXECB,FIXECB            CLEAR OUT ECB            Y01018 39664000
         LA    R0,FIXECB                PUT ECB ADDR WHERE NEC   Y01018 39668000
         L     R1,COREADDR              PUT START ADDR WHERE NEC Y01018 39672000
         PGFIX R,ECB=(0),A=(1),LONG=Y   FIX PAGE INTO CORE       Y01018 39676000
         SPACE 3                                                 Y01018 39680000
********                                                                39684000
******** MAKE SURE THAT PAGE GOT FIXED OK                               39688000
********                                                                39692000
         LTR   R15,R15                  FIX COMPLETED OK         Y01018 39696000
         BZ    FIXMORE                  YES - SEE IF MORE TO FIX Y01018 39700000
         CH    R15,K8                   NEC TO WAIT FOR RESULTS  Y01018 39704000
         BE    MUSTWAIT                 YES - FIX WILL POST ECB  Y01018 39708000
         SPACE 3                                                 Y01018 39712000
********                                                                39716000
******** FIX FAILED - GIVE ERROR RETURN TO TSC                          39720000
********                                                                39724000
FIXFAIL  EQU   *                                                 Y01018 39728000
         MVC   RETCODE,K8               TELL TSC WE HAD PROBS    Y01018 39732000
         B     GOBACK                   PREPARE TO RETURN TO TSC Y01018 39736000
         SPACE 3                                                 Y01018 39740000
********                                                                39744000
******** WAIT UNTIL FIX FINISHES AND TELLS US WHAT'S UP                 39748000
********                                                                39752000
MUSTWAIT EQU   *                                                 Y01018 39756000
         WAIT  ECB=FIXECB               WAIT AWHILE              Y01018 39760000
         CLI   FIXECBCC,AVTEZERO        FIX WENT OK              Y01018 39764000
         BE    FIXMORE                  YES - SEE IF MORE TO FIX Y01018 39768000
         CLI   FIXECBCC,FIXOPPUR        FIX OP PURGED            Y01018 39772000
         BNE   FIXFAIL                  NO - SERIOUS PROBS - RET Y01018 39776000
         B     FIXIT                    TRY AGAIN TO FIX         Y01018 39780000
         SPACE 3                                                 Y01018 39784000
********                                                                39788000
******** SEE IF MORE TIOC PAGES MUST BE FIXED                           39792000
********                                                                39796000
FIXMORE  EQU   *                                                 Y01018 39800000
         L     REVEN,COREADDR           GET ADDR FIXED LAST      Y01018 39804000
         SRL   REVEN,PAGEMAKE           GET ITS PAGE NUMBER      Y01018 39808000
         LA    REVEN,E1(0,REVEN)        GET NEXT PAGE NUMBER     Y01018 39812000
         SLL   REVEN,PAGEMAKE           MAKE ADDR OF IT          Y01018 39816000
         CR    REVEN,RSCAN              THIS PAGE IN TIOC AREA   Y01018 39820000
         BH    FIXOVER                  NO - FORMAT AREA FIXED   Y01018 39824000
         ST    REVEN,COREADDR           FIX THIS PAGE NEXT       Y01018 39828000
         B     FIXIT                    GO FIX ONE MORE PAGE     Y01018 39832000
FIXOVER  EQU   *                                                 Y01018 39836000
.LIB4BAC ANOP                                                           39840000
         SPACE 3                                                        39900020
********                                                                40000020
******** PUT TIOCRPT ADDRESS INTO TSCVT                                 40100020
********                                                                40200020
         L     RTSCVT,CVTTSCVT          GET TSCVT ADDR                  40300020
         USING TSCVT,RTSCVT                                             40400020
         ST    RRPT,TSCVTRPT            PUT TIOCRPT ADDR INTO TSCVT     40700020
         USING TIOCRPT,RRPT                                             40800020
         SPACE 3                                                        40900020
********                                                                41000020
******** INITIALIZE TIOCRPT                                             41100020
********                                                                41200020
         LH    RODD,KRPTSIZE            GET TIOCRPT SIZE                41300020
         BCTR  RODD,0                   SUB 1 FOR EX INSTR              41400020
         EX    RODD,ZERORPT             ZERO TIOCRPT CORE               41500020
         MVC   TIOCNBF,DNUMBFRS         NO. OF TS BFRS                  41600020
         MVC   TIOCNFBF(E4),DNUMBFRS    NO. FREE TS BFRS & SIZE  M1806  41700021
         MVC   TIOCOMAX(E8),DOBMAX      MAX OUTPUT BFRS THRU     M1806  41900021
*                                       RESTART THRESHOLD               42100021
         MVC   TIOCAOMX(E4),DOBMAX      MAX BFRS PER WR & READ   M1806  42300021
         MVC   TIOCUSLW(E4),DUSLW       PEAK LIMIT & SLACK LIMIT M1806  42500021
         MVC   TIOCUSCH,DUCHG           USER CHG NEC TO RECALC BFRS     42700020
         SPACE 3                                                        42800020
********                                                                42900020
******** PUT FIRST-TSB ADDRESS INTO TIOCRPT                             43000020
********                                                                43100020
         LR    RTSB,RRPT                GET TSB BASE REG                43200020
         AH    RTSB,KRPTSIZE            POINT PAST TIOCRPT TO FIRST TSB 43300020
         USING TSB,RTSB                                                 43400020
         ST    RTSB,TIOCTSB-1           PUT TSB TBL ADDR INTO TIOCRPT   43500020
         MVC   TIOCTSBS,KTSBSZ          TSB SIZE                        43600020
         SPACE 3                                                        43700020
********                                                                43800020
******** INITIALIZE TSB'S                                               43900020
********                                                                44000020
         LH    RODD,KTSBSIZE            GET TSB SIZE                    44100020
         BCTR  RODD,0                   SUB 1 FOR EX INSTR              44200020
         LH    REVEN,DNUMUSER           GET NO. OF TSBS NEEDED (IS CTR) 44300020
TSBINIT  EQU   *                                                        44400020
         EX    RODD,ZEROTSB             ZERO CORE FOR ONE TSB           44500020
         AH    RTSB,KTSBSIZE            POINT TO NEXT TSB               44600020
         BCT   REVEN,TSBINIT            BR TIL ALL TSBS ARE INITIALIZED 44700020
         SPACE 3                                                        44800020
         SPACE 3                                                 Y01018 44900000
********                                                                44980000
******** GET READY TO CHAIN BUFFERS                                     45060000
********                                                                45140000
         LR    RBFR,RTSB                GET ADDR OF FIRST BFR    Y01018 45220000
         LH    REVEN,TIOCBFSZ           GET SIZE OF ONE BFR      Y01018 45300000
         LNR   REVEN,REVEN              GET NEG SZ FOR INDEXING  Y01018 45380000
         LH    RODD,DNUMBFRS            GET NO. BFRS NEEDED      Y01018 45460000
         SPACE 3                                                 Y01018 45540000
********                                                                45620000
******** CHAIN BUFFERS                                                  45700000
********                                                                45780000
         ST    RBFR,TIOCFBFF            CHAIN FROM TIOCRPT       Y01018 45860000
BFRCHAIN EQU   *                                                 Y01018 45940000
         AH    RBFR,TIOCBFSZ            POINT TO NEXT BFR        Y01018 46020000
         ST    RBFR,BUFFTRLR-1-TIOCBUF(REVEN,RBFR)     CHAIN BFR Y01018 46100000
         BCT   RODD,BFRCHAIN            BR TIL ALL BFRS CHAINED  Y01018 46180000
         ST    RODD,BUFFTRLR-1-TIOCBUF(REVEN,RBFR)     END CHAIN Y01018 46260000
         SPACE 3                                                        46500020
********                                                                46600020
******** SEE IF SMF RECORD IS WANTED                                    46700020
********                                                                46800020
         NC    CVTSMCA,CVTSMCA          IS SMCA IN THE SYSTEM           46900020
         BZ    GOBACK                   NO - RETURN                     47000020
         SPACE 3                                                        47100020
********                                                                47200020
******** PREPARE AND WRITE A RECORD FOR SMF                             47300020
********                                                                47400020
         MVC   TTIRLEN,RCDSIZE          GET SIZE OF RCD TYPE 31         47500020
         MVC   TTIRSEG,K0               GET SEGMENT DESCRIPTOR          47600020
         MVI   TTIRCDTY,TYPE31          DENOTE RECORD TYPE 31           47700020
         MVC   TTINBF(E14),TIOCNFBF     GET TIOCNFBF THRU TIOCRSTH      47800020
         MVC   TTIUSLW(E5),TIOCUSLW     GET TIOCUSLW THRU TIOCTSBS      47900020
         MVC   TTIUSCH,TIOCUSCH         GET TIOCUSCH                    48000020
         LA    R1,TTISMF                PUT SMF RCD ADDR IN REG 1       48200020
*                                       FOR SMFWTM MACRO                48300020
         SMFWTM     (1)                 SEND THIS RCD TO SMF            48400020
         SPACE 3                                                        48600020
********                                                                48700020
******** RETURN TO TSC                                                  48800020
********                                                                48900020
         B     GOBACK                   BR TO RETURN                    49000020
         SPACE 3                                                        49100020
* * * * * * * * * * *  PARAMETER CHECK ROUTINES * * * * * * * * * * * * 49200020
         SPACE 3                                                        49300020
* NOTE - THESE ROUTINES ARE (& MUST BE) EXECUTED IN ORDER OF APPEARANCE 49400020
         SPACE 3                                                        49500020
********                                                                49600020
******** CHECK VALUE SPECIFIED FOR 'BUFFERS' - VALUE GTEQ 4             49700020
********                                                                49800020
NUMBFCHK EQU   *                                                        49900020
         CH    RODD,K4                  IS VALUE SPEC'ED GTEQ 4         50000020
         BL    CONTSCAN                 NO - LOOK FOR ANOTHER           50100020
*                                       VALUE FOR THIS PARM             50200020
         STH   RODD,DNUMBFRS            YES - PUT IN TBL                50300020
         B     NEXTPARM                 BR TO PROCESS NEXT PARM         50400020
         SPACE 3                                                        50500020
********                                                                50600020
******** CHECK VALUE SPECIFIED FOR 'BUFSIZE' - 20 LTEQ VALUE LTEQ 255   50700001
********                                                                50800020
BUFSZCHK EQU   *                                                        50900020
         CH    RODD,KBSLO               IS VALUE SPEC'ED LT 20   S22028 51000001
         BNH   CONTSCAN                 YES - LOOK FOR ANOTHER          51100020
*                                       VALUE FOR THIS PARM             51200020
         CH    RODD,KBSHI               IS VALUE SPEC'ED GT 255         51300020
         BNL   CONTSCAN                 YES - LOOK FOR ANOTHER          51400020
*                                       VALUE FOR THIS PARM             51500020
         STH   RODD,DBFRSIZE            NO - PUT IN TBL                 51600020
         TM    DBS2,WORDINT             IS VALUE A WD INTEGRAL          51700020
         BZ    NEXTPARM                 YES - BR TO PROCESS NEXT PARM   51800020
         NI    DBS2,MAKEWORD            NO - MAKE A WD INTEGRAL         51900020
         LH    RODD,DBFRSIZE            PREPARE TO ROUND UPWARDS        52000020
         LA    RODD,E4(0,RODD)          GET NEXT HIGHER MULT OF 4       52100020
         STH   RODD,DBFRSIZE            PUT ADJUSTED VALUE IN TBL       52200020
         B     NEXTPARM                 BR TO PROCESS NEXT PARM         52300020
         SPACE 3                                                        52400020
********                                                                52500020
******** CHECK VALUE SPECIFIED FOR 'OWAITHI' - 0 LT VALUE LT 'BUFFERS'  52600020
********                                                                52700020
OHICHK   EQU   *                                                        52800020
         CH    RODD,K0                  IS VALUE SPEC'ED GT 0           52900020
         BNH   CONTSCAN                 NO - LOOK FOR ANOTHER           53000020
*                                       VALUE FOR THIS PARM             53100020
         CH    RODD,DNUMBFRS            IS VALUE SPEC'ED LT NO. BFRS    53200020
         BNL   CONTSCAN                 NO - LOOK FOR ANOTHER           53300020
*                                       VALUE FOR THIS PARM             53400020
         STH   RODD,DOBMAX              YES - PUT IN TBL                53500020
         B     NEXTPARM                 BR TO PROCESS NEXT PARM         53600020
         SPACE 3                                                        53700020
********                                                                53800020
******** CHECK VALUE SPECIFIED FOR 'INLOCKHI' - 0 LT VALUE LT 'BUFFERS' 53900020
********                                                                54000020
IHICHK   EQU   *                                                        54100020
         CH    RODD,K0                  IS VALUE SPEC'ED GT 0           54200020
         BNH   CONTSCAN                 NO - LOOK FOR ANOTHER           54300020
*                                       VALUE FOR THIS PARM             54400020
         CH    RODD,DNUMBFRS            IS VALUE SPEC'ED LT NO. BFRS    54500020
         BNL   CONTSCAN                 NO - LOOK FOR ANOTHER           54600020
*                                       VALUE FOR THIS PARM             54700020
         STH   RODD,DIBMAX              YES - PUT IN TBL                54800020
         B     NEXTPARM                 BR TO PROCESS NEXT PARM         54900020
         SPACE 3                                                        55000020
********                                                                55100020
******** CHECK VALUE SPECIFIED FOR 'OWAITLO' - 0 LT VALUE LT 'BUFFERS'  55200020
********                                                                55300020
OLOCHK   EQU   *                                                        55400020
         CH    RODD,K0                  IS VALUE SPEC'ED GT 0           55500020
         BNH   CONTSCAN                 NO - LOOK FOR ANOTHER           55600020
*                                       VALUE FOR THIS PARM             55700020
         CH    RODD,DNUMBFRS            IS VALUE SPEC'ED LT NO. BFRS    55800020
         BNL   CONTSCAN                 NO - LOOK FOR ANOTHER           55900020
*                                       VALUE FOR THIS PARM             56000020
         STH   RODD,DOWTH               YES - PUT IN TBL                56100020
         B     NEXTPARM                 BR TO PROCESS NEXT PARM         56200020
         SPACE 3                                                        56300020
********                                                                56400020
******** CHECK VALUE SPECIFIED FOR 'INLOCKLO' - 0 LT VALUE LT 'BUFFERS' 56500020
********                                                                56600020
ILOCHK   EQU   *                                                        56700020
         CH    RODD,K0                  IS VALUE SPEC'ED GT 0           56800020
         BNH   CONTSCAN                 NO - LOOK FOR ANOTHER           56900020
*                                       VALUE FOR THIS PARM             57000020
         CH    RODD,DNUMBFRS            IS VALUE SPEC'ED LT NO. BFRS    57100020
         BNL   CONTSCAN                 NO - LOOK FOR ANOTHER           57200020
*                                       VALUE FOR THIS PARM             57300020
         STH   RODD,DRSTH               YES - PUT IN TBL                57400020
         B     NEXTPARM                 BR TO PROCESS NEXT PARM         57500020
         SPACE 3                                                        57600020
********                                                                57700020
******** CHK VALUE SPEC'ED FOR 'RESVBUF' - 0 LTEQ VALUE LTEQ 'BUFFERS'  57800020
********                                                                57900020
RESBFCHK EQU   *                                                        58000020
         CH    RODD,K0                  IS VALUE SPEC'ED LT 0           58100020
         BL    CONTSCAN                 YES - LOOK FOR ANOTHER          58200020
*                                       VALUE FOR THIS PARM             58300020
         CH    RODD,DNUMBFRS            IS VALUE SPEC'ED GT NO. BFRS    58400020
         BH    CONTSCAN                 YES - LOOK FOR ANOTHER          58500020
*                                       VALUE FOR THIS PARM             58600020
         STH   RODD,DUSLW               NO - PUT IN TBL                 58700020
         B     NEXTPARM                 BR TO PROCESS NEXT PARM         58800020
         SPACE 3                                                        58900020
********                                                                59000020
******** CHECK VALUE SPEC'ED FOR 'SLACK' - 0 LTEQ VALUE LTEQ NO. USERS  59100020
********                                                                59200020
SLACKCHK EQU   *                                                        59300020
         CH    RODD,K0                  IS VALUE SPEC'ED LT 0           59400020
         BL    CONTSCAN                 YES - LOOK FOR ANOTHER          59500020
*                                       VALUE FOR THIS PARM             59600020
         CH    RODD,DNUMUSER            IS VALUE SPEC'ED GT NO. USERS   59700020
         BH    CONTSCAN                 YES - LOOK FOR ANOTHER          59800020
*                                       VALUE FOR THIS PARM             59900020
         STH   RODD,DUSSL               NO - PUT IN TBL                 60000020
         B     NEXTPARM                 BR TO PROCESS NEXT PARM         60100020
         SPACE 3                                                        60200020
********                                                                60300020
******** ANY VALUE SPECIFIED FOR 'USERCHG' IS OKAY                      60400020
********                                                                60500020
UCHGCHK  EQU   *                                                        60600020
         STC   RODD,DUCHG               PUT VALUE IN TBL                60700020
         B     CNTCORE                  BR TO CALC CORE SIZE NEEDED     60800020
         SPACE 3                                                        60900020
* * * * * * * * * * * PARAMETER DEFAULT ROUTINES  * * * * * * * * * * * 61000020
         SPACE 3                                                        61100020
* NOTE - THESE ROUTINES ARE (& MUST BE) EXECUTED IN ORDER OF APPEARANCE 61200020
         SPACE 3                                                        61300020
********                                                                61400020
******** GIVE DEFAULT FOR 'BUFFERS' - (2)(NUMBER OF USERS)              61500020
********                                                                61600020
NUMBFDEF EQU   *                                                        61700020
         LH    REVEN,K2                 GET MULTIPLICAND                61800020
         MH    REVEN,DNUMUSER           MULT BY NO. USERS               61900020
         STH   REVEN,DNUMBFRS           PUT DEFAULT IN TBL              62000020
         MVC   RETCODE,K4               GIVE RETURN CODE OF 4           62100020
         B     NEXTPARM                 BR TO PROCESS NEXT PARM         62200020
         SPACE 3                                                        62300020
********                                                                62400020
******** GIVE DEFAULT FOR 'BUFSIZE' - 40                                62500020
********                                                                62600020
BUFSZDEF EQU   *                                                        62700020
         MVC   DBFRSIZE,KBSDEF          PUT DEFAULT IN TBL              62800020
         MVC   RETCODE,K4               GIVE RETURN CODE OF 4           62900020
         B     NEXTPARM                 BR TO PROCESS NEXT PARM         63000020
         SPACE 3                                                        63100020
********                                                                63200020
******** GIVE DEFAULT FOR 'OWAITHI' - 2                                 63300020
********                                                                63400020
OHIDEF   EQU   *                                                        63500020
         MVC   DOBMAX,K2                PUT DEFAULT IN TBL              63600020
         MVC   RETCODE,K4               GIVE RETURN CODE OF 4           63700020
         B     NEXTPARM                 BR TO PROCESS NEXT PARM         63800020
         SPACE 3                                                        63900020
********                                                                64000020
******** GIVE DEFAULT FOR 'INLOCKHI' - 2                                64100020
********                                                                64200020
IHIDEF   EQU   *                                                        64300020
         MVC   DIBMAX,K2                PUT DEFAULT IN TBL              64400020
         MVC   RETCODE,K4               GIVE RETURN CODE OF 4           64500020
         B     NEXTPARM                 BR TO PROCESS NEXT PARM         64600020
         SPACE 3                                                        64700020
********                                                                64800020
******** GIVE DEFAULT FOR 'OWAITLO' - 1                                 64900020
********                                                                65000020
OLODEF   EQU   *                                                        65100020
         MVC   DOWTH,KLODEF             PUT DEFAULT IN TBL              65200020
         MVC   RETCODE,K4               GIVE RETURN CODE OF 4           65300020
         B     NEXTPARM                 BR TO PROCESS NEXT PARM         65400020
         SPACE 3                                                        65500020
********                                                                65600020
******** GIVE DEFAULT FOR 'INLOCKLO' - 1                                65700020
********                                                                65800020
ILODEF   EQU   *                                                        65900020
         MVC   DRSTH,KLODEF             PUT DEFAULT IN TBL              66000020
         MVC   RETCODE,K4               GIVE RETURN CODE OF 4           66100020
         B     NEXTPARM                 BR TO PROCESS NEXT PARM         66200020
         SPACE 3                                                        66300020
********                                                                66400020
******** GIVE DEFAULT FOR 'RESVBUF' - (10/100)('BUFFERS')               66500020
********                                                                66600020
RESBFDEF EQU   *                                                        66700020
         LA    RODD,RBDEF               GET DEFAULT - 10                66800020
         MH    RODD,DNUMBFRS            MULT BY NO. OF BFRS             66900020
         SR    REVEN,REVEN              ZERO REG FOR DIVISION           67000020
         D     REVEN,K100               DIVIDE BY 100 FOR PERCENTAGE    67100020
         STH   RODD,DUSLW               PUT DEFAULT IN TBL              67200020
         MVC   RETCODE,K4               GIVE RETURN CODE OF 4           67300020
         B     NEXTPARM                 BR TO PROCESS NEXT PARM         67400020
         SPACE 3                                                        67500020
********                                                                67600020
******** GIVE DEFAULT FOR 'SLACK' - (25/100)(NO. OF USERS)              67700020
********                                                                67800020
SLACKDEF EQU   *                                                        67900020
         LA    RODD,SLDEF               GET DEFAULT - 25                68000020
         MH    RODD,DNUMUSER            MULT BY NO. OF USERS            68100020
         SR    REVEN,REVEN              ZERO REG FOR DIVISION           68200020
         D     REVEN,K100               DIVIDE BY 100 FOR PERCENTAGE    68300020
         STH   RODD,DUSSL               PUT DEFAULT IN TBL              68400020
         MVC   RETCODE,K4               GIVE RETURN CODE OF 4           68500020
         B     NEXTPARM                 BR TO PROCESS NEXT PARM         68600020
         SPACE 3                                                        68700020
********                                                                68800020
******** GIVE DEFAULT FOR 'USERCHG' - 10                                68900020
********                                                                69000020
UCHGDEF  EQU   *                                                        69100020
         LA    RODD,UCDEF               GET DEFAULT - 10                69200020
         STC   RODD,DUCHG               PUT DEFAULT IN TBL              69300020
         MVC   RETCODE,K4               GIVE RETURN CODE OF 4           69400020
         B     CNTCORE                  BR TO CALC CORE SIZE NEEDED     69500020
         SPACE 3                                                        69600020
* * * * * * * * *  CONSTANTS, VARIABLES, AND TABLES * * * * * * * * * * 69700020
         SPACE 3                                                        69800020
********                                                                69900020
******** CONSTANTS                                                      70000020
********                                                                70100020
TIOCID   DC    C'TIOC'                  CHKS FOR 'TIOC' ON PARMLIB CDS  70200020
K0       DC    H'0'                     CONSTANT OF 0 USED RANDOMLY     70300020
K2       DC    H'2'                     CONSTANT OF 2 USED RANDOMLY     70400020
K4       DC    H'4'                     CONSTANT OF 4 USED RANDOMLY     70500020
K8       DC    H'8'                     CONSTANT OF 8 USED RANDOMLY     70600020
K9       DC    H'9'                     CONSTANT OF 9 USED RANDOMLY     70700020
K100     DC    F'100'                   MAKES PERCENTAGE         M1806  70800021
WORK     DS    0F                                                A44022 70940021
         DC    AL1(251)                 WORK AREA SUBPOOL        M1806  70980021
WORKSIZE EQU   WORK+2                                            A44022 71060021
         DC    AL3(WADEND-WADSECT)      WORK AREA SZ TO GETMAIN  M1806  71100021
KTSBSIZE DC    AL2(TSBEND-TSB)          SIZE OF ONE TSB                 71200020
KRPTSIZE DC    AL2(TIOCEND-TIOCRPT)     SIZE OF TIOCRPT                 71300020
KTSBSZ   EQU   KTSBSIZE+1               SECOND BYTE OF KTSBSIZE         71400020
RCDSIZE  DC    AL2(TTIREND-TTISMF)      SIZE OF SMF RCD TYPE 31  M1806  71500021
CHARZERO DC    C'00000000'              ZEROS CVB WORK AREA             71600020
         SPACE 3                                                        71700020
********                                                                71800020
******** VARIABLES                                                      71900020
********                                                                72000020
ZEROCORE XC    0(0,RWABASE),0(RWABASE)  ZEROS GETMAINED WORKAREA M1806  72100021
ZERORPT  XC    0(0,RRPT),0(RRPT)        ZEROS TIOCRPT                   72200020
ZEROTSB  XC    0(0,RTSB),0(RTSB)        ZEROS ONE TSB                   72300020
GMLIST   GETMAIN    EC,LV=0,MF=L        BUILDS GETMAIN PARAMETER LIST   72400020
         SPACE 3                                                        72500020
********                                                                72600020
******** PARAMETER LIMITS AND DEFAULTS                                  72700020
********                                                                72800020
KBSLO    DC    H'19'                    'BUFSIZE' LOWER LIMIT    S22028 72900001
KBSHI    DC    H'256'                   'BUFSIZE' UPPER LIMIT           73000020
KBSDEF   DC    H'40'                    'BUFSIZE' DEFAULT               73100020
KLODEF   DC    H'1'                     'OWAITLO' & 'INLOCKLO' DEFAULT  73200020
RBDEF    EQU   10                       'RESVBUF' DEFAULT               73300020
SLDEF    EQU   25                       'SLACK' DEFAULT                 73400020
UCDEF    EQU   10                       'USERCHG' DEFAULT               73500020
         SPACE 3                                                        73600020
********                                                                73700020
******** SYS1.PARMLIB PARAMETER KEYWORD TABLE, VALIDITY CHECK ROUTINE   73800020
******** ADDRESSES, AND DEFAULT ROUTINE ADDRESSES                       73900020
********                                                                74000020
KEYWDTBL DS    0F                                                       74100020
BUFFERS  DC    C'FERS'                  NUMBER OF TS BUFFERS            74200020
         DC    A(NUMBFCHK)              'BUFFERS' CHECK RTN ADDR        74300020
         DC    A(NUMBFDEF)              'BUFFERS' DEFAULT RTN ADDR      74400020
BUFSIZE  DC    C'SIZE'                  SIZE OF TS BUFFERS              74500020
         DC    A(BUFSZCHK)              'BUFSIZE' CHECK RTN ADDR        74600020
         DC    A(BUFSZDEF)              'BUFSIZE' DEFAULT RTN ADDR      74700020
OWAITHI  DC    C'ITHI'                  MAX OUTPUT BFRS PER TERM        74800020
         DC    A(OHICHK)                'OWAITHI' CHECK RTN ADDR        74900020
         DC    A(OHIDEF)                'OWAITHI' DEFAULT RTN ADDR      75000020
INLOCKHI DC    C'CKHI'                  MAX INPUT BFRS PER TERM         75100020
         DC    A(IHICHK)                'INLOCKHI' CHECK RTN ADDR       75200020
         DC    A(IHIDEF)                'INLOCKHI' DEFAULT RTN ADDR     75300020
OWAITLO  DC    C'ITLO'                  OWAIT THRESHOLD                 75400020
         DC    A(OLOCHK)                'OWAITLO' CHECK RTN ADDR        75500020
         DC    A(OLODEF)                'OWAITLO' DEFAULT RTN ADDR      75600020
INLOCKLO DC    C'CKLO'                  RESTART THRESHOLD               75700020
         DC    A(ILOCHK)                'INLOCKLO' CHECK RTN ADDR       75800020
         DC    A(ILODEF)                'INLOCKLO' DEFAULT RTN ADDR     75900020
RESVBUF  DC    C'VBUF'                  NO. BFRS SAVED FOR PEAK TIME    76000020
         DC    A(RESBFCHK)              'RESVBUF' CHECK RTN ADDR        76100020
         DC    A(RESBFDEF)              'RESVBUF' DEFAULT RTN ADDR      76200020
SLACK    DC    C'LACK'                  NO. USERS THAT = SLACK TIME     76300020
         DC    A(SLACKCHK)              'SLACK' CHECK RTN ADDR          76400020
         DC    A(SLACKDEF)              'SLACK' DEFAULT RTN ADDR        76500020
USERCHG  DC    C'RCHG'                  CHG NEC TO RECALC BFR ALLOC     76600020
         DC    A(UCHGCHK)               'USERCHG' CHECK RTN ADDR        76700020
         DC    A(UCHGDEF)               'USERCHG' DEFAULT RTN ADDR      76750020
         SPACE 3                                                        77000020
* * * * * * * * * * * * * DSECT FOR WORK AREA * * * * * * * * * * * * * 77100020
         SPACE 3                                                        77200020
WADSECT  DSECT                                                          77300020
         SPACE 3                                                        77400020
********                                                                77500020
******** SMF RECORD                                                     77600020
********                                                                77700020
         IFASMFR (31)                                                   77800020
TTIREND  EQU   *                                                 M1806  77850021
         SPACE 3                                                        77900020
********                                                                78000020
******** VARIABLES                                                      78100020
********                                                                78200020
         DS    0D                                                       78300020
CVBWA    DC    C'00000000'              CONVERT TO BINARY WORK AREA     78400020
CVBLAST  EQU   CVBWA+7                  LAST BYTE OF CVBWA              78500020
COREADDR DC    F'0'                     ADDR OF GETMAIN CORE GOES HERE  78600020
         AIF   ('&LIB' NE 'LIB4').LIB4BAD                        Y01018 78610000
FIXECB   DC    F'0'                     WAIT HERE IF FIX NOT     Y01018 78620000
*                                       DONE                     Y01018 78630000
FIXECBCC EQU   FIXECB+3                 FIX PUTS COMPL CODE HERE Y01018 78640000
.LIB4BAD ANOP                                                           78650000
RETCODE  DC    H'0'                     HOLDS GOOD RET CODE, 4 OR 0     78700020
         SPACE 3                                                        78800020
********                                                                78900020
******** TABLE OF VALID PARAMETERS                                      79000020
********                                                                79100020
DTBL     DS    0F                                                       79200020
DFLAG    DC    X'0000'                  FILLER FOR NOW           M1806  79300021
DNUMBFRS DC    X'0000'                  TIOCNBF, TIOCNFBF        M1806  79400021
*                                                                       79500020
DBFRSIZE DC    X'0000'                  TIOCBFSZ                        79600020
DBS2     EQU   DBFRSIZE+1               BYTE OFFSET                     79700020
DNUMUSER DC    X'0000'                  NUMBER OF USERS IN SYSTEM       79800020
*                                                                       79900020
DOBMAX   DC    X'0000'                  TIOCOMAX, TIOCAOMX              80000020
DIBMAX   DC    X'0000'                  TIOCIMAX, TIOCAIMX              80100020
*                                                                       80200020
DOWTH    DC    X'0000'                  TIOCOWTH                        80300020
DRSTH    DC    X'0000'                  TIOCRSTH                        80400020
*                                                                       80500020
DUSLW    DC    X'0000'                  TIOCUSLW                        80600020
DUSSL    DC    X'0000'                  TIOCUSSL                        80700020
*                                                                       80800020
DUCHG    DC    X'00'                    TIOCUSCH                        80900020
*                                                                       81000020
WADEND   DS    0F                       END OF WADSECT           M1806  81050021
         SPACE 3                                                        81100020
* * * * * * * * * * * *  CONTROL BLOCK DSECTS * * * * * * * * * * * * * 81200020
         SPACE 3                                                        81300020
CVT      DSECT                                                          81400020
         CVT                                                            81500020
         SPACE 3                                                        81600020
         IKJTSCVT                                                       81700020
         SPACE 3                                                        81800020
         IKJTIOCP                                                       81900020
         SPACE 3                                                        82000020
         IKJTSB                                                         82100020
         SPACE 3                                                        82200020
         IKJTIOCB                                                       82300020
         SPACE 3                                                        82400020
PLIST    DSECT                          PARAMETER LIST PASSED BY TSC    82500020
         DS    0F                                                       82600020
PARMNU   DS    F                        NUMBER OF USERS IN THE SYSTEM   82700020
PARMNU2  EQU   PARMNU+2                 HALFWORD OFFSET                 82800020
*                                                                       82900020
PARMLNG  DS    F                        LENGTH OF PARAMETER AREA        83000020
*                                                                       83100020
PARMAD   DS    F                        ADDR OF PARAMETER AREA          83200020
*                                                                       83300020
PARMFLAG DS    XL1                      FLAG BYTE                       83350020
PMCSFLAG DS    XL1                      MASTER CONSOLE ID (FOR MCSFLAG) 83400020
PARMXRGN DS    XL2                      MAX NUMBER OF REGIONS           83600020
*                                                                       83700020
PARMCORE DS    F                        PUT CORE REQUIREMENTS HERE      83800020
         SPACE 3                                                        83900020
         TAVTD                                                          84000020
         END                                                            84100020
