*   IBM SYSTEM/360 OPERATING SYSTEM                                   * 00020000
*   COBOL(E) 360S-CO-503                                              * 00040000
*   MODULE IEPBLD00                                                   * 00060000
*(                                                                      00065019
*2494                                                             22075 00070019
*)                                                                      00075019
 TITLE 'IEPBLD00--CONSTRUCTS ATTRIB TABLE FROM INDIV. ENTRIES'          00080000
*STATUS:  CHANGE LEVEL 10                                             * 00100000
*FUNCTION/OPERATION:                                                  * 00120000
*   BUILDS A TABLE, CALLED THE ATTRIBUTE TABLE, IN CORE WHICH WILL BE * 00140000
*   USED BY THE NEXT PHASE, DMG, FOR SUBSTITUTING 8-BYTE ATTRIBUTES   * 00160000
*   FOR NAMES USED IN THE DATA DIVISION.  IF THE WHOLE ATTRIBUTE TABLE* 00180000
*   WILL NOT FIT IN CORE AT ONE TIME, THE TABLE IS WRITTEN OUT IN     * 00200000
*   SEGMENTS ON A WORKFILE AND A SMALL TABLE, CALLED A SEGMENT TABLE, * 00220000
*   IS BUILT IN CORE WHICH CONTAINS THE NOTEWORD OF THE SEGMENT       * 00240000
*   WRITTEN ON THE WORKFILE AND THE DISPLACEMENT FROM THE BEGINNING OF* 00260000
*   THE COMPLETE ATTRIBUTE TABLE OF THE FIRST RECORD IN THIS SEGMENT. * 00280000
*   THIS DISPLACEMENT MAY BE REFERRED TO IN OTHER DOCUMENTATION AS THE* 00300000
*   LOAD ADDRESS.                                                     * 00320000
*ENTRY POINTS:                                                        * 00340000
*        CETBLD    CALLING SEQUENCE FOR THIS PHASE:                   * 00360000
*                         LA  15,CPHSAD                               * 00380000
*                         SVC 7                                       * 00400000
*                  CPHSAD DC  A(CPHNM)                                * 00420000
*                                     DC    A(0)                      * 00440000
*                  CPHNM  DC  CL8'IEPBLD00'                           * 00460000
*INPUT:                                                               * 00480000
*   EACH BRANCH TO CGETC POINTS REGISTER 3 TO THE NEXT INPUT RECORD   * 00500000
*   WHICH MAY BE ONE OF THREE TYPES:                                  * 00520000
*   1. STANDARD TABLE LOADER ENTRY WHICH ADDS ON THE END OF THE       * 00540000
*      ATTRIBUTE TABLE AND INCREASES ITS LENGTH,                      * 00560000
*   2. MOVE FIXUP ENTRY WHICH MERELY CHANGES THE ADDRESS IN THE       * 00580000
*      ATTRIBUTE ENTRY ALREADY IN THE TABLE,                          * 00600000
*   3. OR FIXUP ENTRY WHICH MERELY CHANGES SOME INDICATOR BITS IN THE * 00620000
*      ATTRIBUTE OF AN ENTRY ALREADY IN THE TABLE.                    * 00640000
*   IF SEGMENTATION IS REQUIRED THE STANDARD TABLE LOADER ENTRY       * 00660000
*   RECORDS, VIA CGETC, ARE BUILT UNTIL CORE IS FILLED.  THEN AFTER   * 00680000
*   REWINDING FILEA, VIA CGETA, MOVE AND OR TYPE FIXUPS ARE APPLIED TO* 00700000
*   THIS SEGMENT OF THE ATTRIBUTE TABLE.  THIS FIXED-UP SEGMENT IS    * 00720000
*   THEN WRITTEN OUT VIA CPUTB AND THE PROCESS IS REPEATED FOR ANOTHER* 00740000
*   SEGMENT.                                                          * 00760000
*   IF NO SEGMENTATION IS REQUIRED THE ENTIRE TABLE IS BUILT AND FIXED* 00780000
*   UP VIA CGETC AND THE ENTIRE TABLE IS WRITTEN OUT VIA CPUTB.       * 00800000
*OUTPUT:                                                              * 00820000
*   ALL OUTPUT IS ON FILEB VIA CPUTB.                                 * 00840000
*   ONE 506 BYTE HASH TABLE WHICH WAS BUILT BY ALC PHASE.             * 00860000
*   N SEGMENTS OF THE ATTRIBUTE TABLE.  N WILL BE 1 IF THE ATTRIBUTE  * 00880000
*   TABLE ALL FITS IN CORE AT ONE TIME.  N WILL BE GREATER THAN 1 IF  * 00900000
*   THE ATTRIBUTE TABLE WILL NOT FIT IN CORE ALL AT ON  TIME AND IN   * 00920000
*   ADDITION THERE WILL FOLLOW A 150 BYTE SEGMENT TABLE AS DESCRIBED  * 00940000
*   IN FUNCTION/OPERATION.                                            * 00960000
*EXTERNAL ROUTINES: N/A                                               * 00980000
*EXITS NORMAL:                                                        * 01000000
*   CEXIT - AT BLD CONCLUSION A BRANCH TO THIS LABEL CAUSES THE NEXT  * 01020000
*   PHASE, DMG, TO BE FETCHED.                                        * 01040000
*EXITS ERROR: N/A                                                     * 01060000
*TABLE/WORK AREAS:                                                    * 01080000
*   HASH TABLE 506 BYTES BUILT IN CORE BY PREVIOUS PHASE, ALC.        * 01100000
*   ATTRIBUTE TABLE - VARIABLE LENGTH - BUILT BY THIS PHASE.          * 01120000
*   SEGMENT TABLE - 150 BYTES - BUILT BY THIS PHASE IF ATTRIBUTE      * 01140000
*   TABLE DOES NOT FIT IN CORE ALL AT ONE TIME.                       * 01160000
*ATTRIBUTES: N/A                                                      * 01180000
*                                                                       01200000
*                                                                       01220000
       CIOP  PHASE=BLD,ENTRY=BLDBEG,INREG=4,OUTREG=3,EOFWK=END          01240000
XSEG   EQU   X'40'           SEGMENTED TABLE SWITCH                     01260000
XPROT  EQU   X'01'                                                      01280000
BLDBEG L     C2,CCOMM        POINT TO COMM AREA                         01300000
       MVC   WORK+1(3),UHASH(C2)  MOVE HASH TABLE ADR TO F.W. BOUND     01320000
       L     P1,WORK         LOAD ADR OF HASH TABLE LEFT BY ALC         01340000
       SH    P1,FOR          POINT TO HASH TABLE PREFIX POSITION        01360000
       MVC   0(4,P1),HPREF   MOVE PREFIX IN FRONT OF HASH TABLE         01380000
       BAL   L1,CWRITE                                                  01400000
       L     P1,CCORAD       LOAD ADR OF TABLE CORE                     01420000
       MVC   TBSZ+2(2),UATBL(C2)  MOVE ATRIB TABLE SIZE TO F.W.         01440000
       L     C1,TBSZ         LOAD SIZE OF ATRIB TABLE                   01460000
         LA    C1,5(C1)            BUMP FOR PREFIX AND EXTRA BYTE       01480000
       ST    C1,TBSZ         STORE ACTUAL ATRIB TABLE SIZE              01500000
       L     W1,CCORSZ       LOAD SIZE OF TABLE CORE                    01520000
       CR    C1,W1           WILL TABLE FIT AS ONE SEGMENT              01540000
       BNH   BLD0            IF YES SKIP                                01560000
       S     W1,CCORDF       REDUCE SIZE TO THAT FOR SMG                01580000
       ST    W1,TBSZ         STORE ACTUAL SIZE OF SMG TABLE CORE        01600000
       LA    W2,USTSZ+4      LOAD SIZE OF SEGMENT TABLE WITH PREFIX     01620000
       STH   W2,0(P1)        STORE SIZE IN SEG TABLE PREFIX             01640000
       SR    W1,W2           DEDUCT SEG TABLE SIZE FROM SMG TABLE CORE  01660000
       SH    W1,FOR          DUNK BY FOUR TO GIVE ACTUAL SEGMENT SIZE   01680000
       LA    P1,4(P1)        POINT TO FIRST ENTRY IN SEGMENT TABLE      01700000
       ST    P1,SNXT         STORE ADR OF FIRST ENTRY                   01720000
       LA    P1,USTSZ(P1)    POINT TO START OF ATTRIB. TABLE            01740000
       OI    USWCH(C2),XSEG  INDICATE SEGMENTED TABLE IN COMM AREA      01760000
       OI    DSW,SSEG        SET SWITCH TO INDICATE SEG. TABLE          01780000
       MVI   BLD1A,X'10'     SET PARAMETER TO OPEN WKA FOR FIXUPS       01800000
BLD0   ST    P1,TABPRE       STORE ADR OF ATTRIBUTE TABLE PREFIX        01820000
       LA    S1,4(P1)        POINT TO START OF ATTRIBUTE TABLE          01840000
       ST    S1,TABAD                                                   01860000
       MVC   0(FIGEND-FIGS,S1),FIGS   PRIME TABLE WITH FIGCONS          01880000
       BAL   L1,COPEN                                                   01900000
BLD1A  DC    X'00001000'                                                01920000
       LA    P1,FIGEND-FIGS+4  LOAD INITIAL BYTE COUNT                  01940000
BLD2   BAL   L1,CGETC        GET RECORD FROM WKC                        01960000
       CLI   0(S2),X'CE'     IS THIS A PLAIN ENTRY                      01980000
       BE    BLD3            IF YES GO POINT W2 TO MOVE INSTR.          02000000
         TM    DSW,SSEG            IS TABLE SEGMENTED                   02020000
         BO    BLD2                IF SO-SKIP FIXUPS ON FILE C          02040000
       CLI   0(S2),X'D0'     IS THIS AN OR TYPE FIXUP                   02060000
       BE    BLD5            IF YES POINT W2 TO OC INSTR.               02080000
       CLI   0(S2),X'D2'     IS THIS A MOVE TYPE FIXUP                  02100000
       BNE   BLD2            IF NO WE AREN,T INTERESTED. GET NEXT REC.  02120000
BLD3   LA    W2,MVC          POINT W2 TO MOVE INSTR. FOR EXECUTION      02140000
BLD4   L     S1,TABAD        LOAD ADR OF ATTRIBUTE TABLE                02160000
       MVC   LO2+2(2),4(S2)  MOVE A TO WORK AREA FOR LOADING            02180000
       L     C1,LO2          LOAD A, THE REL. ADR. OF THIS ENTRY        02200000
       SR    C2,C2                                                      02220000
       IC    C2,3(S2)        C2 HAS N                                   02240000
       SH    C2,THRE         DEDUCT 2 FOR ADRES, AND 1 FOR EX. INSTR.   02260000
       TM    DSW,SSEG        IS TABLE SEGMENTED                         02280000
         BO    SEG2                IF YES-BRANCH                        02300000
       CLI   0(S2),X'CE'     IS THIS AN ORIGINAL ENTRY                  02320000
       BNE   BLD4A           IF NOT DONT ADD LENGTH TO TOTAL            02340000
       LA    P1,1(P1,C2)     ADD LENGTH OF ENTRY TO P1                  02360000
BLD4A  ALR   C1,S1           C1 HAS A + B                               02380000
       EX    C2,0(W2)        EXECUTE INSTR. POINTED TO BY W2            02400000
       B     BLD2            GO FOR NEXT ENTRY                          02420000
BLD5   LA    W2,OC           POINT TO OC INSTR FOR EXECUTION            02440000
       B     BLD4            GO HANDLE ENTRY                            02460000
SEG2   S     C1,LO1          C1 HAS A - LO(I)                           02480000
       LA    C3,1(C1,C2)     C3 HAS A - LO(I) + N + 1                   02500000
       CLR   C3,W1           COMPARE TO SEGEMNT SIZE                    02520000
       BNL   SEG3            HI OR EQ DO FIXUPS THEN PUT SEG. AND START 02540000
*                            NEW ONE.                                   02560000
       LA    P1,1(P1,C2)     ACCUMULATE LENGTH OF SEGMENT IN P1         02580000
       LA    C1,1(C1,S1)     C1 NOW HAS A - LO(I) + B + 1               02600000
       EX    C2,MVC          MOVE ENTRY TO TABLE                        02620000
       B     BLD2            GET NEXT RECORD                            02640000
SEG3   L     L1,TABPRE       LOAD ADR OF ATTRIBUTE TABLE PREFIX         02660000
       STH   P1,0(L1)             STORE SEGMENT LENGTH THERE            02680000
       ST    S2,S2SAV        STORE INPUT POINTER WHILE READING WKA      02700000
       L     C5,SNXT         POINT TO NEXT ENTRY IN SEGMENT TABLE       02720000
       MVC   4(2,C5),LO1+2   MOVE LO(I) TO SEGMENT TABLE ENTRY          02740000
SEG4   OI    DSW,SWKA        SET SWITCH FOR READIN WKA                  02760000
       BAL   L1,CGETA        GET RECORD FROM WKA                        02780000
       CLI   0(S2),X'D0'     IS IT AN OR TYPE FIXUP                     02800000
       BE    SEG4A           IF YES GO CHECK IT                         02820000
       CLI   0(S2),X'D2'     IS IT A MOVE TYPE FIXUP                    02840000
       BNE   SEG4            IF NO ITS NOT A FIXUP. GET NEXT RECORD     02860000
SEG4A  MVC   WORD+2(2),4(S2)  MOVE REL. ADR. OF FIXUP TO FW BOUND       02880000
       L     C1,WORD         LOAD A                                     02900000
       C     C1,LO2          COMPARE A TO LO(I+1)                       02920000
       BNL   SEG4            IF HI THIS FIXUP GOES ON HIGHER SEG        02940000
       S     C1,LO1          CALC A - LO(I)                             02960000
       BM    SEG4            IF MINUS THIS FIXUP WAS ON LOWER SEG       02980000
       LA    C1,1(C1,S1)     C1 HAS A - LO(I) + B + 1                   03000000
       CLI   0(S2),X'D0'     IS IT A OR TYPE FIXUP                      03020000
       BE    SEG5            IF YES BR                                  03040000
       CLI   0(S2),X'D2'     IS IT A MOVE TYPE FIXUP                    03060000
       BNE   SEG4            IF NO ITS NOT A FIXUP                      03080000
       MVC   0(3,C1),6(S2)   MOVE IN THE 3 BYTE FIXUP                   03100000
       B     SEG4            GO GET NEXT RECORK                         03120000
SEG5   OC    0(8,C1),6(S2)   OR IN THE 8 BYTE OR TYPE FISUP             03140000
       B     SEG4            GO GET NEXT ENTRY                          03160000
SEG6   NI    DSW,255-SWKA    TURN OFF WKA READ SWITCH                   03180000
       L     P1,TABPRE       LOAD ADR OF ATRIB. TABLE PREFIX            03200000
       BAL   L1,CWRITE       GO WRITE SEGMENT                           03220000
       ST    C1,WORK         STORE RETURNED NOTEWORD IN WORK AREA       03240000
       MVC   0(4,C5),WORK    MOVE RETURNED NOTEWORD TO SEGMENT TABLE    03260000
       TM    DSW,SEOFC            HAS END OF FILE BEEN REACHED ON C     03280000
       BO    SGEND           IF YES GO EXIT                             03300000
       BAL   L1,CCLOSE       CLOSE WK A                                 03320000
        DC   X'01000000'                                                03340000
       BAL   L1,COPEN        OPEN WK A FOR NEXT PASS ON FIXUPS          03360000
        DC   X'10000000'                                                03380000
       LH    C3,SCNT         LOAD SEGMENT COUNT                         03400000
       LA    C3,1(C3)        BUMP NO OF SEGMENTS                        03420000
       STH   C3,SCNT         STORE SEGMENT COUNT                        03440000
       LA    C5,6(C5)        BUMP TO ADR OF NEXT ENTRY                  03460000
       ST    C5,SNXT         STORE ADR OF NEXT ENTRY                    03480000
       LA    P1,5            RESET BYTE COUNT FOR SEGMENT               03500000
       L     S2,S2SAV        RESTORE INPUT POINTER                      03520000
       MVC   LO1+2(2),LO2+2  SET UP NEW LO(I)                           03540000
       B     BLD4            START NEW SEGMENT                          03560000
SGEND  MVC   10(2,C5),STOP    INSERT ENTRY IN TABLE TO FORCE LOW CPR    03580000
       L     P1,CCORAD       POINT TO PREFIX OF SEGMENT TABLE           03600000
       BAL   L1,CWRITE       WRITE SEGMENT TABLE                        03620000
       ST    C1,WORK         STORE RETURNED NOTEWORD IN WORK AREA       03640000
       L     L1,CCOMM        POINT TO COMM AREA                         03660000
       MVC   USGTB(4,L1),WORK  SAVE NOTEWORD OF SEGMENT TABLE           03680000
       MVC   UATSG(1,L1),SCNT+1  STORE NUMBER OF SEGMENTS               03700000
       ST    C5,WORK         STORE POINTER TO CURRENT SEG. TBL ENTRY    03720000
         MVC   0(4,P1),WORK                                             03740000
       BAL   L1,CCLOSE       CLOSE FILES                                03760000
       DC    X'01000100'                                                03780000
       B     CEXIT                                                      03800000
END    TM    DSW,SWKA        IS THIS EOF ON WORK A                      03820000
       BO    SEG6            IF YES BRANCH                              03840000
       OI    DSW,SEOFC       SET SWITCH FOR EOF ON WKC                  03860000
       TM    DSW,SSEG        IS TABLE SEGMENTED                         03880000
       BO    SEG3            IF YES DO FIXUPS ON LAST SEGMENT           03900000
       L     L1,TABPRE       POINT TO PREFIX OF ATTRIBUTE TABLE         03920000
       STH   P1,0(L1)        STORE LENGTH OF TABLE IN PREFIX            03940000
       LR    P1,L1           POINT TO PREFIX FOR CWRITE                 03960000
       BAL   L1,CWRITE       GO WRITE TABLE ON WKB                      03980000
       BAL   L1,CCLOSE       CLOSE FILES                                04000000
        DC   X'00040100'                                                04020000
       B     CEXIT           EXIT FROM PHASE                            04040000
DSW    DC    X'0'                    SWITCHES FOR DBLD                  04060000
SSEG   EQU   X'1'            INDICATES SEGMENTED TABLE                  04080000
SEOFC  EQU   X'2'            INDICATES END OF FILE REACHED ON WKC       04100000
SWKA   EQU   X'4'            ON WHEN READING FROM WKA                   04120000
CLR    MVC   1(0,C3),0(C3)                                              04140000
MVC    MVC   0(,C1),6(S2)                                               04160000
OC     OC    0(0,C1),6(S2)                                              04180000
ZERO   DC    H'0'                                                       04200000
THRE   DC    H'3'                                                       04220000
FOR    DC    H'4'                                                       04240000
HPREF  DC    H'506'          PREFIX FOR HASH TABLE                      04260000
       DC    H'0'            1ST REL. ADR                               04280000
STOP   DC    X'FFFF'         PUT AFTER SEG. TABLE-FORCES LOW COMPARE    04300000
WORD   DC    F'0'            USED TO LOAD THE TWO BYTE RELATIVE ADR IN  04320000
S2SAV  DC    F'0'            SAVE S2 WHILE READING FIXUPS FROM WKA      04340000
WORK   DC    F'0'            GENERAL WORK AREA                          04360000
LO1    DC    F'1'            CURRENT LO(I)                              04380000
LO2    DC    F'0'            WORK FILED. LO(I+1) WHEN SEG IS COMPLETE   04400000
TABPRE DC    F'0'            ADR OF ATTRIBUTE TABLE PREFIX STORED HERE  04420000
TABAD  DC    F'0'            ADR. OF ATTRIBUTE TABLE                    04440000
SNXT   DC    F'0'            ADR OF NEXT ENTRY IN SEGMENT TABLE         04460000
TBSZ   DC    F'0'            SIZE OF TABLE OR OF SEGMENT                04480000
SCNT   DC    H'1'            COUNT OF SEGMENTS IN SEGMENTED ATRIB TBL   04500000
FIGS   EQU   *                                                          04520000
       DC    X'0'                                                       04540000
       DC    X'4C000000000000F0000004'                                  04560000
       DC    C'ZERO'                                                    04580000
       DC    X'4C000000000000F0000005'                                  04600000
       DC    C'ZEROS'                                                   04620000
       DC    X'4C000000000000F0000006'                                  04640000
       DC    C'ZEROES'                                                  04660000
       DC    X'4C00000000000040000005'                                  04680000
       DC    C'SPACE'                                                   04700000
       DC    X'4C00000000000040000006'                                  04720000
       DC    C'SPACES'                                                  04740000
       DC    X'4C0000000000007D000005'                                  04760000
       DC    C'QUOTE'                                                   04780000
       DC    X'4C0000000000007D000006'                                  04800000
       DC    C'QUOTES'                                                  04820000
       DC    X'4C000000000000FF00000A'                                  04840000
       DC    C'HIGH-VALUE'                                              04860000
       DC    X'4C000000000000FF00000B'                                  04880000
       DC    C'HIGH-VALUES'                                             04900000
       DC    X'4C00000000000000000009'                                  04920000
       DC    C'LOW-VALUE'                                               04940000
       DC    X'4C0000008000000000000A'                                  04960000
       DC    C'LOW-VALUES'                                              04980000
       DC    X'0088'                                                    05000000
       DC    X'4200316400000005000005'                                  05020000
       DC    C'TALLY'                                                   05040000
FIGEND EQU   *                                                          05060000
         CIOPL BLD                                                      05080000
       END   CETBLD                                                     05100000
