*   IBM SYSTEM/360 OPERATING SYSTEM                                   * 00020000
*   COBOL(E) 360S-CO-503                                              * 00040000
*   MODULE IEPDMG00                                                   * 00060000
 TITLE 'IEPDMG00--REPLACES DATA-NAMES WITH DESCRIP. ATTRIBUTE'          00080000
*STATUS:  CHANGE LEVEL 10                                             * 00100000
*FUNCTION/OPERATION:                                                  * 00120000
*   THE RECORDS ENTERING THIS PHASE STILL CONTAIN FILENAMES AND       * 00140000
*   DATANAMES IN THEIR SPELLED OUT FORM AS WRITTEN IN THE SOURCE      * 00160000
*   PROGRAM.  THE PREVIOUS PHASE HAS ASSEMBLED AN ATTRIBUTE TABLE     * 00180000
*   WHICH CONTAINS THESE NAMES AND FOR EACH NAME AN 8-BYTE ATTRIBUTE  * 00200000
*   WHICH CONTAINS THE CHARACTERISTICS OF THE FILE OR FIELD REFERRED  * 00220000
*   TO BY THE NAME.  FOR SOME OF THESE INPUT RECORDS THIS PHASE NOW   * 00240000
*   LOOKS UP THE NAME IN THE ATTRIBUTE TABLE AND EITHER REPLACES THE  * 00260000
*   NAME, OR ADDS TO THE RECORD THE ATTRIBUTE CORRESPONDING TO THE    * 00280000
*   NAME.  OTHER RECORDS ARE MERELY COPIED OUT WITHOUT CHANGE.  TO    * 00300000
*   INCREASE THE SPEED OF THE LOOK-UP, USE IS MADE OF THE HASH TABLE  * 00320000
*   BUILT BY THE ALC PHASE.  THE NAME IS MATHEMATICALLY MANIPULATED TO* 00340000
*   PRODUCE A POINTER TO A SPOT IN THE HASH TABLE WHERE CAN BE FOUND  * 00360000
*   A POINTER TO THE NAME IN THE ATTRIBUTE  TABLE.  IF THE ATTRIBUTE  * 00380000
*   TABLE IS SEGMENTED, USE IS ALSO MADE OF THE SEGMENT TABLE BUILT BY* 00400000
*   THE BLD PHASE IN ORDER TO GET THE PROPER SEGMENT OF THE ATTRIBUTE * 00420000
*   TABLE INTO CORE FASTER.                                           * 00440000
*   THE FOLLOWING CONDITIONS ARE DIAGNOSED IN THIS PHASE-             * 00460000
*   1. UNDEFINED DATANAME                                             * 00480000
*   2. A DATANAME THAT HAS SUBSCRIPTING THAT SHOULD NOT               * 00500000
*   3. A DATANAME THAT SHOULD BE SUBSCRIPTED AND IS NOT               * 00520000
*   4. A DATANAME THAT HAS INSUFFICIENT SUBSCRIPTING.                 * 00540000
*ENTRY POINTS:                                                        * 00560000
*        CETDMG    CALLING SEQUENCE FOR THIS PHASE:                   * 00580000
*                         LA  15,CPHSAD                               * 00600000
*                         SVC 7                                       * 00620000
*                  CPHSAD DC  A(CPHNM)                                * 00640000
*                                     DC    A(0)                      * 00660000
*                  CPHNM  DC  CL8'IEPDMG00'                           * 00680000
*INPUT;                                                               * 00700000
*   EACH BRANCH TO CGETA POINTS REGISTER 3 TO THE NEXT INPUT RECORD   * 00720000
*   FROM FILEA.  THE RECORDS FOR WHICH ATTRIBUTES WILL BE ADDED OR    * 00740000
*   MERGED ARE THE FOLLOWING:                                         * 00760000
*   FD BASE RECORD                                                    * 00780000
*   SYMBOLIC KEY RECORD                                               * 00800000
*   ACTUAL KEY RECORD                                                 * 00820000
*   RECORD KEY RECORD                                                 * 00840000
*   LABEL RECORD                                                      * 00860000
*   TRACK AREA RECORD                                                 * 00880000
*   OCCURS DEPENDING ON RECORD                                        * 00900000
*OUTPUT:                                                              * 00920000
*   THE RECORDS LISTED IN INPUT ABOVE EITHER HAVE AN ATTRIBUTE ADDED  * 00940000
*   TO THEM OR AN ATTRIBUTE SUBSTITUTED IN PLACE OF THE NAME.  ALL    * 00960000
*   OTHER RECORDS ARE WRITTEN ON FILEC WITHOUT CHANGE.  ALL RECORDS   * 00980000
*   ARE WRITTEN ON FILEC VIA CPUTC.                                   * 01000000
*EXTERNAL ROUTINES: N/A                                               * 01020000
*EXITS NORMAL:                                                        * 01040000
*   CEXIT - AT THE CONCLUSION OF DMG A BRANCH TO THIS LABEL CAUSES THE* 01060000
*   NEXT PHASE, LIT, TO BE FETCHED.                                   * 01080000
*EXITS ERROR: N/A                                                     * 01100000
*TABLE/WORK AREAS:                                                    * 01120000
*   HASH TABLE BUILT BY ALC PHASE - 506 BYTES.                        * 01140000
*   HASH TABLE BUILT BY ALC PHASE - 506 BYTES.                        * 01160000
*   ATTRIBUTE TABLE BUILT BY BLD PHASE - MAY BE SEGMENTED.            * 01180000
*   SEGMENT TABLE BUILT BY BLD IF ATTRIBUTE TABLE SEGMENTED-150 BYTES.* 01200000
*ATTRIBUTES: N/A                                                      * 01220000
         CIOP  PHASE=DMG,EOFWK=END,INREG=4,OUTREG=12,ENTRY=DMGBEG       01240000
XSEG   EQU   X'40'      SWITCH IN USWCH. INDICATES SEGMENTED TABLE.     01260000
DMGBEG BAL   L1,COPEN                                                   01280000
        DC   X'10002000'                                                01300000
       L     L1,CCOMM        POINT TO COMM AREA                         01320000
       MVC   HASH+1(3),UHASH(L1)   GET ADR OF HASH TABLE LEFT BY BLD    01340000
       L     P1,CCORAD       POINT TO TABLES LEFT IN CORE BY BLD        01360000
       TM    USWCH(L1),XSEG    IS ATTRIBUTE TABLE SEGMENTED             01380000
       BZ    MRGIN           IF NO SKIP                                 01400000
       MVC   INSEG(4),0(P1)    GET ADR OF CURRENTLY LOADED SEGMENT      01420000
       LA    P1,USTSZ+4(P1)   BUMP PAST SEGMENT TABLE TO ATTRIB TABLE   01440000
       ST    P1,TABAD        STORE TABLE ADR                            01460000
       OI    NSW,SSEG        SET SEGMENTED TABLE SWITCH                 01480000
MRGIN  LA    S1,4(P1)        POINT S1 PAST PREFIX TO ATRIB TABLE        01500000
       ST    S1,BSE          STORE ADR OF ATTRIBUTE TABLE               01520000
MRG    BAL   L1,CGETA        GET INPUT RECORD FROM WKA                  01540000
       SR    C0,C0           ZERO WORK REG FOR CODE BYTE FROM SRC       01560000
       IC    C0,0(S2)        LOAD CODE                                  01580000
       SRL   C0,1                                                       01600000
       STC   C0,CODE                                                    01620000
MRG2   TM    NSW,SEOFA       ARE WE FINISHED ON FILE A                  01640000
       BO    END1                                                       01660000
       MVC   OUT(3),0(S2)     LOAD PREFIX IN OUTPUT                     01680000
       CLI   CODE,X'2'       SYMBOLIC KEY                               01700000
       BE    MRG3                                                       01720000
       CLI   CODE,X'3'       ACTUAL KEY                                 01740000
       BE    MRG3                                                       01760000
       CLI   CODE,X'52'      LABEL RECORD DATA NAME                     01780000
       BE    MRG3                                                       01800000
         CLI   CODE,X'0D'               IS THIS RECORD KEY ITEM         01820000
         BE    MRG3                     IF SO-GO MERGE ATTRIBUTE        01840000
         CLI   CODE,X'0E'               IS THIS TRACK AREA ITEM         01860000
         BE    MRG3                     IF SO-GO MERGE ATTRIBUTE        01880000
       CLI   CODE,X'6F'      END FLAG                                   01900000
       BE    END1                                                       01920000
       CLI   CODE,X'51'      FD TABLE                                   01940000
       BE    FD                                                         01960000
       CLI   CODE,X'62'      OCC. DEP. ON                               01980000
       BNE   DIAG                                                       02000000
       MVC   OUT+12(1),4(S2)  MOVE CELL NUMBER TO OUTPUT AREA           02020000
       MVI   OUT+3,X'9'      MOVE IN LENGTH FOR OCC. DEP. OUTPUT        02040000
       SR    C5,C5           ZERO WORK REG FOR LENGTH                   02060000
       IC    C5,5(S2)        LOAD LENGTH OF NAME                        02080000
       EX    C5,MOV          MOVE NAME DOWN TO MAKE OC DEP LOOK NORMAL  02100000
       B     MRG4            GO CONTINUE AS FOR NORMAL RECORD           02120000
MRG3   MVI   OUT+3,X'8'      BYTE COUNT FOR RECORDS OTHER THAN FD AND   02140000
*                              OCC. DEP. ON                             02160000
       SR    C5,C5           ZERO WORK REG FOR BYTE COUNT               02180000
       IC    C5,3(S2)        BYTE COUNT IN C5                           02200000
MRG4   LA    W1,4(S2)        LOAD ADR OF NAME FOR HASH                  02220000
MRG5   BAL   L1,HASHR                                                   02240000
       MVC   HALF+2(2),0(W3)           LOAD HASH VALUE                  02260000
       L     W3,HALF                                                    02280000
       BAL   L1,CHAIN1       GO CHECK TABLE FOR NAME                    02300000
       C     W3,ZRO                                                     02320000
       BE    DEAD1                                                      02340000
       MVC   OUT+4(8),0(W3)  MOVE ATRIBUTE TO OUTPUT AREA               02360000
       LA    C1,3(C5)        TOTAL BYTE COUNT MINUS 1                   02380000
       EX    C1,MVC                                                     02400000
       OI    NSW,SGA1        SET 2ND READ SWITCH                        02420000
       BAL   L1,CGETA                                                   02440000
       NI    NSW,255-SGA1    TURN OFF 2ND READ SWITCH                   02460000
       SR    C0,C0           ZERO WORK REG FOR CODE BYTE FROM SRC       02480000
       IC    C0,0(S2)        LOAD CODE                                  02500000
       SRL   C0,1                                                       02520000
       STC   C0,CODE                                                    02540000
         TM    CODE,X'70'          IS IT A TRAILER                      02560000
         BO    QUAL                IF YES GO RESOLVE QUALIFICATION      02580000
       LR    C0,S2                     STORE INPUT POINTER              02600000
       LA    S2,QAREA                                                   02620000
       BAL   L1,CHAIN        ELSE GO CHAIN FOR SYNONYMS                 02640000
       LR    S2,C0                     RESTORE INPUT POINTER            02660000
       C     W3,ZRO          IF NO SYNONYM W3 WILL BE ZERO              02680000
       BE    MRG7            IF NO SYNONYM THEN ITS NOT AMBIGUOUS       02700000
       BAL   L1,CDIAGC       DIAGNOS AMBIGUOUS DATA NAME                02720000
        DC   X'1006'                                                    02740000
        LA   0,OUT                                                      02760000
        LA   0,QAREA+3                                                  02780000
       MVC   OUT+4(8),0(W3)                                             02800000
MRG7   LA    W3,OUT          POINT TO OUTPUT RECORD                     02820000
       BAL   L1,CPUTC                                                   02840000
       B     MRG2                                                       02860000
DIAG   CLI   CODE,X'41'      IS THIS A DIAGNOSTIC                       02880000
       BE    COPY            IF YES GO COPY ON WK C                     02900000
       CLI   CODE,X'74'                                                 02920000
       BE    COPY                                                       02940000
       TM    CODE,X'70'      I/O BASE OTHER THAN THOSE ABOVE            02960000
       BZ    COPY            IF YES PUT IT ON WORK C                    02980000
       CLI   CODE,X'42'                                                 03000000
       BE    COPY            IF YES GO COPY ON WK C                     03020000
       CLI   CODE,X'72'      IS IT A DIAGNOSTIC TRAILER                 03040000
         BE    COPY                     COPY IT OUT                     03060000
         CLI   CODE,X'77'               IS IT A RESTRICTED SEARCH TRL   03080000
       BNE   MRG                        IF NOT DIAG RETURN              03100000
COPY   LR    W3,S2           POINT OUTPUT REGISTER TO INPUT RECORD      03120000
       BAL   L1,CPUTC        WRITE DIAG ON WKC                          03140000
       B     MRG             RETURN                                     03160000
FD     MVC   OUT+12(5),4(S2)  MOVE FD  TABLE TO OUTPUT AREA             03180000
       LA    W1,10(S2)       ADR OF NAME FOR HASH                       03200000
       SR    C5,C5           ZERO WORK REG FOR BYTE COUNT               03220000
       IC    C5,9(S2)        BYTE COUNT FOR HASH                        03240000
       EX    C5,MVV          MOVE FILE NEME TO OUTPUT                   03260000
       LA    C3,14(C5)       CALC TOTAL LENGTH OF OUTPUT RECORD         03280000
       STC   C3,OUT+3        AND STORE IT IN SRC                        03300000
       LA    S2,6(S2)                                                   03320000
       B     MRG5                                                       03340000
DEAD1  BAL   L1,CDIAGC       DIAGNOS UNDEFINED NAME                     03360000
       DC    X'100B'         UNDEFINED NAME                             03380000
       LA    0,OUT                                                      03400000
       LA    0,3(S2)                                                    03420000
DEAD2  MVC   OUT+4(8),DUMY   MOVE IN ERROR ATRIBUTE                     03440000
       LA    W3,OUT                                                     03460000
       BAL   L1,CPUTC                                                   03480000
       B     MRG             GO GET NEXT RECORD                         03500000
*      W1 IS  ADR OF WORD                                               03520000
*      C5  IS BYTE COUNT                                                03540000
*      W3 IS  RESULT                                                    03560000
*      L1  IS LINK                                                      03580000
RWORD  EQU   10                                                         03600000
RNDX   EQU   11                                                         03620000
RQUT   EQU   12     EVEN/                                               03640000
RADD   EQU   13          ODD                                            03660000
RFOUR  EQU   14     EVEN/                                               03680000
RCNT   EQU   15          ODD                                            03700000
WORC   DS    9F                                                         03720000
LOAD   DC    F'0'                                                       03740000
       DC    F'0'                                                       03760000
       DC    F'0'                                                       03780000
       DC    F'4'                                                       03800000
PRIME  DC    F'251'                                                     03820000
INST   MVC   WORC(0),0(RWORD)                                           03840000
HASHR  EX    RCNT,INST                                                  03860000
       LA    RQUT,WORC(RCNT)                                            03880000
       MVC   0(4,RQUT),LOAD                                             03900000
       LM    RNDX,RFOUR,LOAD                                            03920000
LOOP   AL    RADD,WORC(RNDX)                                            03940000
       BXLE  RNDX,RFOUR,LOOP                                            03960000
       D     RQUT,PRIME                                                 03980000
       AR    RQUT,RQUT                                                  04000000
       AL    RQUT,HASH                                                  04020000
         ST    RQUT,LOAD-4             STORE RESULT FOR DEBUGING ONLY   04040000
       BR    L1                                                         04060000
MVV    MVC   OUT+17(0),9(S2)                                            04080000
MOV    MVC   3(0,S2),5(S2)                                              04100000
MVC    MVC   QAREA(0),0(S2)                                             04120000
MLC    MVC   0(,P1),0(S2)                                               04140000
CPR    CLC   3(,S2),10(W3)                                              04160000
CPR2   CLC   3(,P1),10(C2)                                              04180000
QUAL   LA    P1,QAREA                                                   04200000
       SR    W2,W2           ZERO WORK REG FOR QUALIFIER COUNT          04220000
QUAL1  LA    W2,1(W2)        BUMP QUALIFIER COUNT                       04240000
       BAL   L1,QL1                                                     04260000
       IC    C5,3(S2)        LOAD BYTE COUNT                            04280000
       LA    C5,3(C5)        ADJUST FOR PREFIX                          04300000
       EX    C5,MLC                     LOAD QUALIFIER IN QAREA         04320000
       OI    NSW,SGA2        SET 3RD READ SWITCH                        04340000
       BAL   L1,CGETA                                                   04360000
       NI    NSW,255-SGA2    TURN OFF 3RD READ SWITCH                   04380000
       SR    C0,C0           ZERO WORK REG FOR CODE BYTE FROM SRC       04400000
       IC    C0,0(S2)        LOAD CODE                                  04420000
       SRL   C0,1                                                       04440000
       STC   C0,CODE                                                    04460000
       CLI   CODE,X'70'      IS IT ANOTHER TRAILER                      04480000
       BE    QUAL1           IF YES GO STACK IT IN THE Q-AREA           04500000
*                            IF NO THEN THE WORD AND ALL QUALIFIERS     04520000
*                            ARE STACKED IN THE QAREA WITH THEIR SRC,S  04540000
QUAL2  NI    NSW,255-SFND    TURN OFF FOUND SWITCH                      04560000
       STH   W2,QCNT         STORE QUALIFIER COUNT                      04580000
       ST    S2,HOLD1        STORE S2 SO WE CAN USE COMMON CHAIN ROUTIN 04600000
       LA    P1,QAREA        SET P1 TO FIRST NAME IN WORK AREA          04620000
QUAL4  MVC   OUT+4(8),0(W3)  MOVE ATTRIBUTE TO OUTPUT AREA              04640000
QL2      LR    C2,W3         LOAD C2 FOR UP POINT ROUTINE             $ 04660000
       SR    C3,C3           SET COUNT TO ZERO                          04680000
QL10   BAL   L1,QL1                                                     04700000
QL7    BAL   L1,UPPT                                                    04720000
       C     C2,ZRO          IF C2 IS ZERO THERE IS NO UP POINTER       04740000
       BE    QL4                                                        04760000
       IC    C4,3(P1)        LOAD LENGTH FOR COMPARE                    04780000
       EX    C4,CPR2          COMPARE UPPOINT NAME TO QUALIFIER         04800000
       BNE   QL7              NO. GET NEXT UPPOINTER                    04820000
       LA    C3,1(C3)        BUMP COUNT                                 04840000
       CH    C3,QCNT         IS THAT ALL OF THE QUALIFIERS              04860000
       BNE   QL10                                                       04880000
       TM    NSW,SFND        IS FOUND SWITCH ON                         04900000
       BO    QL3                                                        04920000
       OI    NSW,SFND        SET FOUND SWITCH                           04940000
QL4    LA    P1,QAREA                                                   04960000
       LR    S2,P1           LOAD S2 FOR COMMON CHAIN ROUTINE           04980000
       IC    C5,3(P1)        LOAD BYTE COUNT FOR CHAIN                  05000000
       BAL   L1,CHAIN                                                   05020000
       C     W3,ZRO           W3 IS ZERO IF NAME NOT FOUND              05040000
         BE    QL5                      GO TEST FOUND SWITCH            05060000
       TM    NSW,SFND        TEST FOUND SWITCH                          05080000
         BO    QL2                      GO CHECK FOR DUPLICATES         05100000
         B     QUAL4                    GO CHECK NEXT LEVEL UP          05120000
QL5      TM    NSW,SFND                 TEST FOUND SWITCH               05140000
         BO    QL6                                                      05160000
       BAL   L1,CDIAGC       DIAGNOS UNDEFINED HIERARCHY                05180000
        DC   X'1007'                                                    05200000
        LA   0,QAREA                                                    05220000
        LA   0,QAREA+3                                                  05240000
QL6    L     S2,HOLD1        RESTORE S2                                 05260000
       B     MRG7            RETURN TO MAIN ROUTINE. QUALIFICATION DONE 05280000
QL1    SR    W1,W1           CLEAR WORK REGISTER FOR BYTE COUNT         05300000
       IC    W1,3(P1)        LOAD BYTE COUNT                            05320000
       LA    P1,4(P1,W1)     BUMP P1 TO NEXT QUALIFIER IN STACK         05340000
       BR    L1                                                         05360000
QL3    BAL   L1,CDIAGC       DIAGNOS AMBIGUOUS HIERARCHY                05380000
        DC   X'1008'                                                    05400000
        LA   0,QAREA                                                    05420000
        LA   0,QAREA+3                                                  05440000
       B     QL6                                                        05460000
UPPT   MVC   HLOAD+2(2),8(C2)  MOVE UP POINT TO FIELD FOR LOADING       05480000
       L     C2,HLOAD        LOAD UPPOINT.                              05500000
       C     C2,ZRO          IS THERE AN UP POINTER                     05520000
       BCR   8,L1            IF NO, EXIT                                05540000
       TM    NSW,SSEG        IS TABLE SEGMENTED                         05560000
       BZ    UPPT1           IF NO BR.                                  05580000
       ST    L1,SLINK2       STORE LINK                                 05600000
       BAL   L1,ITC          AND GO CHECK FOR ITERATION                 05620000
       L     L1,SLINK2                                                  05640000
UPPT1  ALR   C2,S1           ADD B TO REL. ADR.                         05660000
       BR    L1                                                         05680000
CHAIN  L     W3,CHLOAD       LOAD CHAIN POINTER                         05700000
CHAIN1 C     W3,ZRO          ANY UP POINTER                             05720000
       BCR   8,L1            IF NO, EXIT                                05740000
       TM    NSW,SSEG        IS TABLE SEGMENTED                         05760000
       BO    ITW             IF YES GO LOAD PROPER SEGMENT              05780000
CHAIN2 ALR   W3,S1           ADD TABLE BASE ADR TO RELATIVE ADR         05800000
       TM    4(W3),X'80'     IS THERE A CHAIN POINTER                   05820000
       BZ    DEAD            IF NO THEN BRANCH                          05840000
       SR    C1,C1           ZERO WORK REG FOR NAME LENGTH              05860000
       IC    C1,10(W3)       LOAD BYTE COUNT OF NAME                    05880000
       LA    W2,11(C1,W3)    POINT W2 PAST NAME TO THE CHAIN POINTER    05900000
       MVC   CHLOAD+2(2),0(W2)  STORE CHAIN POINTER                     05920000
CHAIN3 EX    C5,CPR          COMPARE TO DESIRED NAME                    05940000
       BCR   8,L1            IF EQUAL THEN EXIT                         05960000
       B     CHAIN           ELSE LOOP AND TRY NEXT ENTRY ON CHAIN      05980000
DEAD   MVC   CHLOAD+2(2),ZRO  ZERO HOLD AREA THAT IS FOR CHAIN POINTER  06000000
       B     CHAIN3          AND RETURN                                 06020000
ITC    STM   L1,W1,HOLD                                                 06040000
         L     W1,INSEG            W1 POINTS TO ENTRY FOR CURRENT SEG   06060000
         MVC   HALF+2(2),10(W1)    LO(I+1) TO FW FIELD                  06080000
         C     C2,HALF             COMPARE A TO LO(I+1)                 06100000
         BNL   IT3                 IF HI WANT HIGHER SEG THAN IS NOW    06120000
*                                  LOADED IN CORE.                      06140000
         MVC   HALF+2(2),4(W1)     LO(I) TO FW FIELD                    06160000
         S     C2,HALF             CALC  A - LO(I)                      06180000
         BM    IT5                 IF MINUS WANT LOWER SEG THAN IS NOW  06200000
*                                  LOADED IN CORE                       06220000
IT2      LA    C2,1(C2)            C2 IS A - LO(I) + 1                  06240000
         LM    L1,W1,HOLD                                               06260000
         BR    L1                                                       06280000
IT3      LA    W1,6(W1)            BUMP LO TABLE INDEX TO NEXT ENTRY    06300000
         MVC   HALF+2(2),10(W1)    LO(I+1) TO FW BOUND                  06320000
         C     C2,HALF             COMPARE A TO LO(I+1)                 06340000
         BNL   IT3                LOOP TILL HIGH, AT WHICH TIME W1 WILL 06360000
*                                  POINT TO ENTRY FOR CORRECT SEGMENT   06380000
IT4      MVC   HALF+2(2),4(W1)    LO(I) TO FW BOUND                     06400000
         S     C2,HALF             CALC  A - LO(I)                      06420000
         ST    W1,INSEG            STORE POINTER TO CURRENT SEG         06440000
         L     P1,TABAD           POINT TO TABLE AREA                   06460000
         BAL   L1,CREAD            GO READ CORRECT SEGMENT              06480000
         B     IT2                 EXIT                                 06500000
IT5      A     C2,HALF             RESTORE A                            06520000
IT6      SH    W1,SIX              REDUCE TABLE POINTER                 06540000
         MVC   HALF+2(2),4(W1)     LO(I) TO FW                          06560000
         C     C2,HALF             COMPARE A TO LO(I)                   06580000
         BL    IT6                 LOOP TILL HI OR EQ, AT WHICH TIME    06600000
*                                  W1 POINTS TO ENTRY FOR CORRECT SEG.  06620000
         B     IT4                                                      06640000
ITW    LR    C2,W3           SET UP REG FOR COMMON SEG SEARCH           06660000
       ST    L1,SLINK2       STORE LINK                                 06680000
       BAL   L1,ITC          GO CHECK FOR ITERATION                     06700000
       L     L1,SLINK2       RESTORE LINK                               06720000
       LR    W3,C2           SET RESULT IN W3 FOR CHAIN ROUTINE         06740000
       B     CHAIN2          RETURN                                     06760000
END    OI    NSW,SEOFA       INDICATE EOF ON WK A                       06780000
       TM    NSW,SGA1        IS THIS DURING 2ND READ                    06800000
       BO    MRG7            IF YES RETURN THERE                        06820000
       TM    NSW,SGA2        IS THIS DURING 3RD READ                    06840000
       BO    QUAL2           IF YES RETURN THERE                        06860000
END1   TM    NSW,SSEG        IS TABLE SEGMENTED                         06880000
       BZ    CEXIT           IF NOT EXIT                                06900000
       BAL   L1,CCLOSE       ELSE CLOSE WKB                             06920000
        DC   X'000400'                                                  06940000
       B     CEXIT           THEN EXIT                                  06960000
       DC    0F'0'                                                      06980000
QAREA  DC    300X'0'         WORK AREA FOR QUALIFICATION                07000000
CODE   DC    X'0'            HOLD AREA FOR SHIFTED SRC CODE             07020000
NSW    DC    X'0'                                                       07040000
SGA1   EQU   X'2'       INDICATES 2ND BRANCH TO CGETA IN PROG           07060000
SGA2   EQU   X'4'       3RD BRANCH TO CGETA IN PROG.  SGA1 AND          07080000
*                       SGA2 TELL WHERE WE WERE ON EOF ON WK A          07100000
SFND   EQU   X'8'       CORRECT HIERARCHY WAS FOUND IN QUAL.            07120000
*                       AND WE ARE CHECKING FOR A DUPLICATE             07140000
SSEG   EQU   X'10'      ATTRIBUTE TABLE IS SEGMENTED                    07160000
SEOFA  EQU   X'20'      EOF HAS BEEN REACHED ON WK A. THIS PREVENTS     07180000
*                       FURTHER GETS ON WK A WHEN WE FINISH CURRENT     07200000
*                       ROUTINE.                                        07220000
ZRO    DC    F'0'                                                       07240000
TWO    DC    H'2'                                                       07260000
FOR    DC    H'4'                                                       07280000
SIX    DC    H'6'                                                       07300000
TEN    DC    H'10'           CONSTANT TO CALC POS IN UODPA FOR OC DEP   07320000
HLOAD  DC    F'0'            USED TO LOAD TWO BYTE POSITIVE FIELDS. THE 07340000
CHLOAD DC    F'0'                                                       07360000
*                            FIRST TWO BYTES OF HLOAD MUST REMAIN ZERO. 07380000
HALF   DC    F'0'                                                       07400000
HOLD   DC    F'0'            WORK AREA                                  07420000
HOLD1  DC    F'0'            WORK AREA                                  07440000
HOLD2  DC    F'0'                                                       07460000
SLINK2 DC    F'0'                                                       07480000
TABAD  DC    F'0'            ADR OF TABLE INPUT AREA                    07500000
BSE    DC    F'0'            ADR OF ATTRIBUTE TABLE IS STORED HERE      07520000
HASH   DC    F'0'            ADR OF HASH TABLE IS STORED HERE           07540000
QCNT   DC    H'0'            COUNT OF NO. OF QUALIFIERS                 07560000
OUT    DC    11F'0'                                                     07580000
DUMY   DC    2F'0'           ERROR ATRIBUTE                             07600000
INSEG  DC    F'0'            ADR OF SEGMENT TABLE ENTRY FOR CURRENT SEG 07620000
         CIOPL DMG                                                      07640000
       END   CETDMG                                                     07660000
