*(                                                                      00003017
*    143300                                                        7679 00006020
*2923144250-144350,144700-144900,145400,146200                     2789 00009020
*)                                                                      00015017
*   IBM SYSTEM/360 OPERATING SYSTEM                                   * 00020000
*   COBOL(E) 360S-CO-503                                              * 00040000
*   MODULE IEPIOT00                                                   * 00060000
*STATUS0  CHANGE LEVEL 21                                          9112 00080000
*7050,3566                                                         9112 00100000
 TITLE 'IEPIOT00--BUILDS I/O TABLES,DCB S AND COMPILE-TIME-FILES'       00120000
*FUNCTION/OPERATION:                                                  * 00140000
*   BUILDS AN IO TABLE FROM INFORMATION RECEIVED FROM THE ENVIRONMENT * 00160000
*   DIVISION AND DATA DIVISION SYNTAX PHASES.  CHECKS ALL ENTRIES FOR * 00180000
*   EACH FILE IN THE IO TABLE FOR CONTEXTUAL ERRORS (CONFLICTS IN THE * 00200000
*   USE OF THE DEFINING CLAUSES WITHIN THE FILE DESCRIPTION).  BUILDS * 00220000
*   A SAME AREA TABLE FOR FILES THAT WILL USE SAME IO AREAS AT OBJECT * 00240000
*   TIME.  ALLOCATES STORAGE FOR DCB TABLES AND ASSIGNS ADDRESSES FOR * 00260000
*   THEM IN BASE LOCATOR AND DISPLACEMENT FORM.  CALCULATES LENGTH OF * 00280000
*   THE IO AREAS.  BUILDS DCB ACCORDING TO THE FILE DESCRIPTION OF    * 00300000
*   EACH ENTRY IN IO TABLE. BUILDS COMPILE-TIME-FILE RECORDS          * 00320000
*   FOR THE GENERATOR PHASES.                                         * 00340000
*ENTRY POINTS:                                                        * 00360000
*        CETIOT    CALLING SEQUENCE FOR THIS PHASE:                   * 00380000
*                         LA  15,CPHSAD                               * 00400000
*                         SVC 7                                       * 00420000
*                  CPHSAD DC  A(CPHNM)                                * 00440000
*                         DC    A(0)                                  * 00460000
*                  CPHNM  DC  CL8'IEPIOT00'                           * 00480000
*INPUT:                                                               * 00500000
*   EACH BRANCH TO CGETC BUMPS THE INPUT POINTER (REGISTER 3) TO THE  * 00520000
*   NEXT INPUT ITEM WHOSE FORMAT VARIES DEPENDING ON IT'S TYPE (I.E.  * 00540000
*   IO BASE, FD BASE, SAME AREA, USER LABELS, ETC.).  RECORD FORMATS  * 00560000
*   ARE DESCRIBED IN THE COBOL PLM APPENDIX.  ALL RECORDS ARE READ    * 00580000
*   FROM FILE C.                                                      * 00600000
*OUTPUT:                                                              * 00620000
*   OUTPUT RECORDS ARE WRITTEN THROUGH CPUT.  THE DIAGNOSTIC RECORD   * 00640000
*   FORMAT IS DESCRIBED IN THE PLM APPENDIX.  THE DCB'S ARE OUTPUT IN * 00660000
*   LOADER TEXT CARD FORMAT PRECEEDED BY A 4-BYTE STANDARD-RECORD-    * 00680000
*   CONTROL-FIELD (SRC). THE FORMAT FOR THE COMPILE-TIME-FILE         * 00700000
*   RECORD CONSISTS OF A 4-BYTE STANDARD-RECORD-CONTROL-FIELD (SRC),  * 00720000
*   2-BYTE LOAD ADDRESS, 4-BYTE TYPE FILE BYTES, 3-BYTE DCB ADDRESS,  * 00740000
*   3-BYTE SYMBOLIC KEY ADDRESS,3-BYTE ACTUAL KEY ADDRESS, AND 3-BYTE * 00760000
*   TRACK-AREA ADDRESS IN BASE LOCATOR AND DISPLACEMENT FORM. THE     * 00780000
*   FORMAT FOR THE SAME AREA RECORD IS A 4-BYTE STANDARD-RECORD-      * 00800000
*   CONTROL-FIELD (SRC), 2-BYTE EQUATE BASE LOCATOR AND 2-BYTE DCB    * 00820000
*   BASE LOCATOR.  THE FORMAT FOR THE LABEL EQUATE RECORD IS A 4-BYTE * 00840000
*   STANDARD-RECORD-CONTROL-FIELD (SRC), 2-BYTE BASE LOCATOR          * 00860000
*   ASSIGNMENT FROM THE ATTRIBUTE OF THE DATA ITEM, AND 3-BYTE BASE   * 00880000
*   LOCATOR AND DISPLACEMENT ASSIGNED TO THE DCB FOR A FILE.          * 00900000
*EXTERNAL ROUTINES: N/A                                               * 00920000
*EXITS NORMAL:                                                        * 00940000
*   CEXIT - WHEN COMPLETION OF PROCESSING ALL ENTRIES IN THE IO TABLE * 00960000
*           A BRANCH TO CEXIT OCCURS WHICH WILL IN TURN FETCH THE NEXT* 00980000
*           PHASE.                                                    * 01000000
*EXITS ERROR: N/A                                                     * 01020000
*TABLE/WORK AREAS:                                                    * 01040000
*   IOTAB  - IO TABLE USED FOR CREATING DCB'S.                        * 01060000
*   SAMTAB - SAME AREA TABLE TO IDENTIFY FILES USING THE SAME IO AREAS* 01080000
*            AT OBJECT TIME.                                          * 01100000
*   QSAM   - BUILD AREA FOR STANDARD SEQUENTIAL DCB.                  * 01120000
*   BSAMD  - BUILD AREA FOR DIRECT ORGANIZATION,SEQUENTIAL ACCESS DCB * 01140000
*   BSAMR  - BUILD AREA FOR REL. ORGANIZATION,SEQUENTIAL ACCESS DCB   * 01160000
*   BDAMD  - BUILD AREA FOR DIRECT ORGANIZATION,RANDOM ACCESS DCB     * 01180000
*   BDAMR  - BUILD AREA FOR REL. ORGANIZATION,RANDOM ACCESS DCB       * 01200000
*   QISAM  - BUILD AREA FOR INDEXED ORGAN.,SEQUENTIAL ACCESS DCB      * 01220000
*   BISAM  - BUILD AREA FOR INDEXED ORGAN.,RANDOM ACCESS DCB          * 01240000
*   CMPBLD - BUILD AREA FOR COMPILE-TIME-FILE RECORD                  * 01260000
*   SAMRCD - BUILD AREA FOR SAME EQUATE RECORD                        * 01280000
*   SAMLAB - BUILD AREA FOR LABEL EQUATE RECORD                       * 01300000
*   RUNSRC - BUILD AREA FOR RERUN RECORD                              * 01320000
*   OUTSRC - OUTPUT AREA FOR TEXT CARDS                               * 01340000
*   FILNWK - WORKAREA FOR FILE-NAME                                   * 01360000
*   IHADCB - DCB SYMBOLIC DEFINITION(DCBD)                            * 01380000
*ATTRIBUTES: N/A                                                      * 01400000
*                                                                       01420000
*                                                                       01440000
         EJECT                                                          01460000
       CIOP  PHASE=IOT,ENTRY=BDIOT1,EOFWK=ENDIN                         01480000
*                                                                       01500000
*    *****************************************************************  01520000
*                  *****  START  IOT  PHASE  *****                      01540000
*    *****************************************************************  01560000
*                                                                       01580000
*            IOT BUILDS AN I/O TABLE, CHECKS IT FOR VALIDITY AND        01600000
*            OUTPUTS THE DCB TEXT WHICH AT OBJECT TIME WILL COMMUNICATE 01620000
*            WITH IOCS.                                                 01640000
*    *****************************************************************  01660000
*                                                                       01680000
BDIOT1 DS    0H                                                         01700000
       BAL   L1,COPEN                                                   01720000
       DC    X'20'                      FILE A, OPEN FOR OUTPUT  S2 REG 01740000
       DC    X'00'                      FILE B, NOT USED                01760000
       DC    X'10'                      FILE C, OPEN FOR INPUT   S1 REG 01780000
       DC    X'00'                     EXPLICIT SLACK BYTE FOR IMA      01800000
       EJECT                                                            01820000
*                                                                       01840000
*   *****************************************************************   01860000
*      SET  START OF BUILDING I/O TABLE IN CORE                         01880000
*      REG  C5 WILL CONTAIN ADDRESS OF TABLE ENTRY BEING BUILT, OR      01900000
*            THE ADDRESS FOR THE NEXT ONE.                              01920000
*      REG  C4 WILL BE USED FOR FINDING TABLE ENTRY TO WHICH ASSOC      01940000
*            RECORD APPLIES. (I.E. SYMBOLIC KEY, OVERFLOW,FD BASE ETC.) 01960000
*            IT WILL ALSO BE USED FOR MAKING ADDITIONS TO THE TABLE     01980000
*            ENTRY AFTER IT IS INITIALLY SET UP.                        02000000
*   *****************************************************************   02020000
*                                                                       02040000
         L     W1,CCOMM                GET ADDR OF COMMON AREA          02060000
         MVC   FRCDBL(4),UBUCK(W1)     01 AND 77 COUNT IN LINK SECTION  02080000
         L     C5,FRCDBL               INIT. ACCUMULATOR WITH COUNT     02100000
         AH    C5,REGCT                ADD REGISTER COUNT CONSTANT      02120000
         STH   C5,REGCT                RESTORE NEW REG COUNT            02140000
       LA    C5,IOTAB                  LOAD IOTAB ADDRESS               02160000
GETREC BAL   L1,CGETC                   GET RECORD FROM INPUT FILE      02180000
       LR    S2,S1                      MOVE ADDR OF IN TO OUT          02200000
GETR1  TM    0(S1),SRCIO                TEST SRC MAJOR CODE             02220000
       BZ    GIOENT                     BRANCH IF I/O ENTRY FROM DSYN1  02240000
       MVC   SRCTST,0(S1)                                               02260000
       NI    SRCTST,SRCIO               MASK OUT MINOR CODE             02280000
       CLI   SRCTST,SRCFD               TEST FOR FD MAJOR CODE          02300000
       BE    GFDENT                     BRANCH IF FD ENTRY FROM DSYN2   02320000
       BAL   L1,CPUTA                   PUT RECORD NOT INTERESTED IN    02340000
*      ALL RECORDS SUCH AS DIAGNOSTICS, DATA ATTRIBUTES, TABLES, AND    02360000
*          LOADER TEXT FOR DLIT LITERALS ARE PASSED FROM FILE C TO      02380000
*          FILE A DURING DIOT                                           02400000
       B     GETREC                     GO BACK TO GET AND CHECK NEXT   02420000
*                                       INPUT RECORD.                   02440000
*                                                                       02460000
         EJECT                                                          02480000
*                                                                       02500000
*    *****************************************************************  02520000
*              DETERMINE RECORD TYPE FROM DS1.                          02540000
*    *****************************************************************  02560000
*                                                                       02580000
GIOENT MVC   SRCTST,0(S1)              SAVE CURRENT RECORD SRC          02600000
       NI    SRCTST,SRCMIN              MASK OUT BITS SO MINOR CODE     02620000
*                                        REMAINS                        02640000
       MVI   FDSWIT,X'00'              CLEAR FD ERROR SWITCH            02660000
       CLC   FILECT(2),NUM25+2         IO TABLE  OVERFLOW               02680000
       BE    IOFULL                                                     02700000
       CLI   SRCTST,SRCEXT                                              02720000
       BE    EXTNAM                    BRANCH IS EXTERNAL-NAME          02740000
       CLI   SRCTST,SRCSYM                                              02760000
       BE    SYMK                       BRANCH IF SYMBOLIC KEY          02780000
       CLI   SRCTST,SRCACT                                              02800000
       BE    ACTK                       BRANCH IF ACTUAL KEY            02820000
         CLI   SRCTST,SRCRKP                                            02840000
         BE    RECK                    BRANCH IF RECORD KEY             02860000
         CLI   SRCTST,SRCMSW                                            02880000
         BE    TRKARE                  BRANCH IF TRACK AREA             02900000
         CLI   SRCTST,SRCFLM                                            02920000
         BE    FILIM                   BRANCH IF FILE LIMIT             02940000
       CLI   SRCTST,SRCIOB                                              02960000
       BE    IOBAS                      BRANCH IF I/O BASE FROM DS1     02980000
       CLI   SRCTST,SRCRI                                               03000000
       BE    REINTG                     BRANCH IF RERUN INTEGER         03020000
       BAL   L1,FILFND                  FIND CORRECT TABLE ENTRY        03040000
       CLI   SRCTST,SRCSA                                               03100000
       BE    SAMAR                      BRANCH IF SAME AREA             03120000
       CLI   SRCTST,SRCRS                                               03140000
       BE    RESTRC                     BRANCH ON RESTRICTED SEARCH     03160000
       CLI   SRCTST,SRCOF                                               03180000
       BE    OVFLO                      BRANCH ON FORMS OVERFLOW        03200000
         CLI   SRCTST,SRCWRT                                            03220000
         BE    APWRIT                  BRANCH IF APPLY WRITE ONLY       03240000
*      SYSTEM FAILURE IF WE FALL THROUGH THIS BRANCH                    03260000
         B     GETREC                                                   03280000
       EJECT                                                            03300000
*                       ****MASKS****                                   03320000
SRCIO  EQU   X'E0'                      MASK TO TEST MAJOR SRC CODE     03340000
SRCFD  EQU   X'A0'                      MASK FOR SRC FD MAJOR CODE      03360000
SRCMIN EQU   X'1E'                      MASK TO GET ONLY MINOR CODE     03380000
SRCSYM EQU   X'04'                      SYMBOLIC KEY MASK               03400000
SRCACT EQU   X'06'                      ACTUAL KEY MASK                 03420000
SRCIOB EQU   X'02'                      I/O BASE MASK                   03440000
SRCRI  EQU   X'0C'                      RERUN INTEGER SRC MASK          03460000
SRCROV EQU   X'0A'                      RERUN END OF VOLUME MASK        03480000
SRCSA  EQU   X'08'                      SAME AREA MASK                  03500000
SRCRS  EQU   X'0E'                      RESTRICTED SEARCH MASK          03520000
SRCOF  EQU   X'1E'                      FORMS OVERFLOW MASK             03540000
SRCRST EQU   X'EE'                      RESTRICTED SEARCH TRAILER MASK  03560000
SRCSAT EQU   X'E8'                      SAME AREA TRAILER MASK          03580000
SRCLAB EQU   X'A4'                      FD LABEL RECORD                 03600000
SRCFDB EQU   X'A2'                      FD BASE ENTRY                   03620000
SRCEXT EQU   X'16'                     MASK FOR SRC EXTERNAL-NAME       03640000
SRCRKP   EQU   X'1A'                   RECORD KEY                       03660000
SRCMSW   EQU   X'1C'                   TRACK AREA                       03680000
SRCWRT   EQU   X'10'                   APPLY WRITE ONLY                 03700000
SRCFLM   EQU   X'18'                   FILE LIMIT                       03720000
MON0   EQU   X'80'                      MASK FOR BIT 0                  03740000
MON1   EQU   X'40'                                   1                  03760000
MON2   EQU   X'20'                                   2                  03780000
MON3   EQU   X'10'                                   3                  03800000
MON4   EQU   X'08'                                   4                  03820000
MON5   EQU   X'04'                                   5                  03840000
MON6   EQU   X'02'                                   6                  03860000
MON7   EQU   X'01'                                   7                  03880000
MON8   EQU   X'30'                     MASK FOR FIXED OR UNDEFINED      03900000
       EJECT                                                            03920000
*                                                                       03940000
*   *****************************************************************   03960000
*      THE FOLLOWING ROUTINES PROCESS EACH OF THE VARIOUS RECORDS WHICH 03980000
*            CONTRIBUTE TO THE ENTRIES IN THE I/O TABLE                 04000000
*                                                                       04020000
*      I/O BASE ENTRY FROM DSYN1                                        04040000
*      THE FOLLOWING DISPLACEMENTS APPLY TO THE PARTS OF I/O RECORD     04060000
*   *****************************************************************   04080000
*                                                                       04100000
FILET  EQU   4                          TYPE BYTE                       04120000
MODEL  EQU   5                          MODEL NUMBER                    04140000
ALTAR  EQU   7                          ALTERNATE AREA                  04160000
EXTNM  EQU   8                          EXTERNAL NAME                   04180000
FNLGTI EQU   16                         LENGTH OF FILE NAME             04200000
FILNMI EQU   17                         FILE NAME                       04220000
*                                                                       04240000
IOBAS  SR    C1,C1                                                      04260000
       CLI   FNLGTI(S1),X'00'          LENGTH OF FILE-NAME ZERO         04280000
         BE    GETREC                  YES                              04300000
       LH    C1,FILECT                 GET CURRENT FILE COUNT           04320000
       LA    C1,1(C1)                                                   04340000
       CL    C1,NUM25                  MORE THAN 25 FILES               04360000
       BH    IOFULL                    YES-ERROR                        04380000
       STH   C1,FILECT                                                  04400000
       MVC   TFIL1(1,C5),FILET(S1)     MOVE TYPE BYTE                   04420000
*                                                                       04440000
*    *****************************************************************  04460000
*        THIS RTNE ASSUMES SEQUENTIAL ACESS METHOD IF NONE SPECIFIED.   04480000
*    *****************************************************************  04500000
*                                                                       04520000
         TM    TFIL1(C5),MSKRAN        WAS RANDOM ACCESS SPECIFIED      04540000
         BO    TSTORGS                 YES                              04560000
         OI    TFIL1(C5),MSKSEQ        SET SEQ. ACCESS BIT ON           04580000
*                                                                       04600000
*    *****************************************************************  04620000
*        THIS RTNE SETS SEQ. ORG. BIT ON IF NO OTHER ORG. SPECIFIED.    04640000
*    *****************************************************************  04660000
TSTORGS  TM    TFIL1(C5),MSKORG        CHK FOR DIR.,INDEXED, & REL. ORG 04680000
         BM    SWRELBIT                YES-ONE OF ABOVE                 04700000
         OI    TFIL4(C5),MSKSEQOR      SET SEQ. ORGANIZATION BIT ON     04720000
         B     IOBAS2                                                   04740000
*                                                                       04760000
*    *****************************************************************  04780000
*        THIS RTNE SWITCHES REL.ORG. BIT FROM TFIL1 TO TFIL4 IF         04800000
*        RELATIVE ORGANIZATION IS SPECIFIED.                            04820000
*    *****************************************************************  04840000
*                                                                       04860000
SWRELBIT TM    TFIL1(C5),MON7          WAS RELATIVE ORG. SPEC.          04880000
         BZ    IOBAS2                  NO                               04900000
         OI    TFIL4(C5),MSKREL        SET REL. BIT ON IN TFIL4         04920000
         NI    TFIL1(C5),X'FE'         TURN REL. ORG. BIT OFF IN TFIL1  04940000
*                                                                       04960000
IOBAS2   MVC   TMODNO(2,C5),MODEL(S1)  MOVE MODEL NUMBER                04980000
         TM    TFIL1(C5),MSKUTIL       IS THIS FILE A UTILITY DEVICE    05000000
         BZ    IOBAS5                  NO                               05020000
         CLC   TMODNO(2,C5),H2400      YES-IS IT A TAPE UTILITY DEVICE  05040000
         BE    IOBAS5                  YES                              05060000
         OI    TFIL4(C5),MSKDRACC NO-DIR.ACC.DEV.SPECIFIED AS UTILITY   05080000
IOBAS5   MVC   TSEQ(2,C5),1(S1)        SAVE SEQUENCE FROM SRC           05100000
       NI    TSEQ(C5),X'0F'            CLEAR POS BITS                   05120000
       MVC   TEXTNM(8,C5),EXTNM(S1)     MOVE IN EXTERNAL NAME           05140000
       SR    C1,C1                                                      05160000
       IC    C1,ALTAR(S1)            PUT NO. OF BUFFERS IN REGISTER     05180000
*    *****************************************************************  05200000
*    *   IF RESERVE CLAUSE NOT SPECIFIED, ALTAR WILL CONTAIN HEX 'FF'*  05220000
*    *****************************************************************  05240000
       AH    C1,ONEH                    ADD 1                           05260000
IOBAS1 STC   C1,TNOBUF(C5)             STORE NUMBER OF BUFFERS          05280000
         CLI   TNOBUF(C5),0            WAS RESERVE CLAUSE SPECIFIED     05300000
         BNE   IOBAS4                  YES                              05320000
IOBAS3   SR    C1,C1                   CLEAR REGISTER                   05340000
       IC    C1,FNLGTI(S1)             PUT FILE NAME LGTH IN REG.       05360000
       EX    C1,FNMMOV                  MOVE IN FILE NAME               05380000
*            END OF INITIAL BUILD                                       05400000
*            NOW PREPARE REG FOR NEXT ENTRY                             05420000
       A     C1,FTBLEN                 ADD FIXED LENGTH OF AREA         05440000
         AR    C5,C1  ADD LGTH OF AREA TO LGTH OF FILE NAME             05460000
       ST    C5,TEMBUK                 SAVE LGTH OF LAST IOTAB ENTRY    05480000
       B     GETREC                                                     05500000
IOBAS4   TM    TFIL1(C5),MSKDASD       DIRECT ACCESS DEVICE?            05520000
         BZ    IOBAS3                  NO                               05540000
         CLI   TNOBUF(C5),2            WAS MORE THAN 1 BUFFER SPEC      05560000
         BL    IOBAS3                  NO (ALREADY CHECKED FOR ZERO)    05580000
         TM    TFIL1(C5),MSKDIR        IS ORG DIRECT                    05600000
         BO    BUFERR                  YES                              05620000
         TM    TFIL4(C5),MSKREL        IS ORG RELATIVE                  05640000
         BO    BUFERR                  YES                              05660000
         TM    TFIL1(C5),MSKSEQ  SEQ ACC FOR IND OR SEQ ORG             05680000
         BO    IOBAS3                  YES-OK                           05700000
BUFERR   MVC   POSSEQ+1(2),TSEQ(C5)    NO-ERROR                         05720000
         IC    C1,FNLGTI(S1)           GET FILE NAME LGTH               05740000
         EX    C1,FILMVE               MOVE FILE-NAME TO WORK AREA      05760000
*                                                                       05780000
*    *****************************************************************  05800000
         BAL   L1,CDIAGA               GO PRINT MESSAGE                 05820000
         DC    H'119'                  ERROR-119                        05840000
         LA    0,POSSEQ                POS-SEQ                          05860000
*    *****************************************************************  05880000
*                                                                       05900000
         MVI   TNOBUF(C5),1            ASSUME 1 BUFFER                  05920000
         B     IOBAS3                                                   05940000
*                                                                       05960000
         EJECT                                                          05980000
*                                                                       06000000
*   *****************************************************************   06020000
*              THE FOLLOWING ROUTINES PROCESS THE FIRST ENTRIES FOR     06040000
*              A FILE. REGISTER C5 POINTS TO I/O TABLE ENTRY.           06060000
*   *****************************************************************   06080000
*                                                                       06100000
SYMK     OI    TFIL2(C5),MSKSYMK       TURN ON SYMBOLIC KEY BIT         06120000
         BAL   L1,DREC                                                  06140000
         STH   C1,HWORD                SYMBOLIC KEY LENGTH              06160000
         CLC   HWORD(2),C255            IS SYMB KEY LGTH GRTR THAN 255  06180000
         BH    SYMREC                  YES                              06200000
         MVC   TKEYL(1,C5),HWORD+1     MOVE LENGTH TO IOTABLE           06220000
         MVC   TSYMKY(3,C5),5(S1)  MOVE SYMKEY ADDR FROM ATTRIBUTE      06240000
         B     GETREC                                                   06260000
*                                                                       06280000
ACTK     OI    TFIL3(C5),MSKACTK       TURN ON ACTUAL KEY BIT           06300000
         NI    4(S1),X'0F'             CLEAR MAJOR CODE FM ATTRIB       06320000
         CLI   4(S1),X'02'             IS USAGE COMPUTATIONAL(BINARY)   06340000
         BNE   DREC4                   NO-GIVE ERROR 110                06360000
         CLC   10(2,S1),C005  LGTH ALLOC FM ATTRIB MUST BE 5--(S9(5))   06380000
         BNE   ACTERR                  NOT 5 ERROR 115                  06400000
         MVC   TACTKY(3,C5),5(S1)  MOVE ACTKEY ADDR FROM ATTRIBUTE      06420000
         B     GETREC                                                   06440000
*                                                                       06460000
RECK     OI    TFIL3(C5),MSKRECK       TURN ON RECORD KEY BIT           06480000
         BAL   L1,DREC                                                  06500000
         STH   C1,HWORD                RECORD KEY LENGTH                06520000
         CLC   HWORD(2),C255            IS REC KEY LGTH GRTR THAN 255   06540000
         BH    SYMREC                  YES                              06560000
         MVC   TKEYR(1,C5),HWORD+1     MOVE RECORD KEY LGTH TO IOTAB    06580000
         NC    6(2,S1),MSKAND          CLEAR BASE LOCATOR TO GET        06600000
         MVC   TRECKY(2,C5),6(S1)  MOVE RECKEY ADDR FROM ATTRIBUTE      06620000
         B     GETREC                                                   06640000
*                                                                       06660000
TRKARE   OI    TFIL4(C5),MSKTRKAR      BIT ON IN IOTAB FOR TRACK AREA   06680000
         MVC   TTKAR(3,C5),5(S1)       ADDR OF TRACK AREA TO IOTAB      06700000
         MVC   TTALN(2,C5),10(S1)      TRACK AREA LGTH OF PICTURE       06720000
         B     GETREC                  GET NEXT RECORD                  06740000
*                                                                       06760000
FILIM    OI    TFIL4(C5),MSKFILIM      BIT ON IN IOTAB FOR FILE LIMIT   06780000
         MVC   TFLIM+1(2,C5),4(S1)   NO. TRKS IN FILE LIM TO IOTAB      06800000
         CLC   TFLIM(3,C5),ZEROF       WERE ANY GIVEN                   06820000
         BNE   GETREC                  YES                              06840000
         MVI   TFLIM+2(C5),X'01'       DEFAULT OF 1 TRACK               06860000
         B     GETREC                  GET NEXT RECORD                  06880000
*                                                                       06900000
         EJECT                                                          06920000
*                                                                       06940000
*                                                                       06960000
*                                                                       06980000
*   *****************************************************************   07000000
*            THIS ROUTINE CALCULATES THE ACTUAL LENGTH OF THE ACTUAL    07020000
*            KEY, RECORD KEY, OR SYMBOLIC KEY ACCORDING TO DATA TYPE.   07040000
*   *****************************************************************   07060000
*                                                                       07080000
DREC     SR    C1,C1                                                    07100000
         NI    4(S1),X'0F'             CLEAR MAJOR CODE FM ATTRIBUTE    07120000
         IC    C1,4(S1)                GET MINOR CODE FROM ATTRIBUTE    07140000
         IC    C1,DRECCD(C1)           USE AS INDEX POINTER             07160000
         B     DREC(C1)                SELECT PROPER ROUTINE            07180000
DREC1    IC    C1,11(S1)               ONE CHARACTER ACTUAL LENGTH      07200000
         BR    L1                                                       07220000
DREC2    IC    C1,11(S1)               ONE CHARACTER PACKED             07240000
         SRL   C1,1                    HALVE                            07260000
         LA    C1,1(C1)                ADD ONE FOR ACTUAL LENGTH        07280000
         BR    L1                                                       07300000
DREC3    LA    C1,2                    BINARY                           07320000
         CLI   11(S1),X'5'             HALF WORD                        07340000
         BCR   4,L1                    YES - EXIT                       07360000
         LA    C1,4                                                     07380000
         CLI   11(S1),X'A'             FULL WORD                        07400000
         BCR   4,L1                    YES - EXIT                       07420000
         LA    C1,8                    DOUBLE WORD                      07440000
         BR    L1                                                       07460000
*            ********************************************************** 07480000
DREC4    BAL   L1,CDIAGA               INCORRECT DATA TYPE FOR KEY      07500000
         DC    X'006E'                 ERROR 110                        07520000
         LA    0,0(S2)                 POS-SEQ                          07540000
         B     GETREC                                                   07560000
*            ********************************************************** 07580000
DREC5    MVC   HWORD(2),10(S1)         TWO BYTE LENGTH                  07600000
         LH    C1,HWORD                                                 07620000
         BR    L1                                                       07640000
DRECCD   DC    AL1(DREC1-DREC)         EXTERNAL DECIMAL                 07660000
         DC    AL1(DREC2-DREC)         INTERNAL DECIMAL                 07680000
         DC    AL1(DREC3-DREC)         BINARY                           07700000
         DC    AL1(DREC4-DREC)         INVALID DATA ITEM                07720000
         DC    AL1(DREC4-DREC)         INVALID DATA ITEM                07740000
         DC    AL1(DREC4-DREC)         INVALID DATA ITEM                07760000
         DC    AL1(DREC4-DREC)         INVALID DATA ITEM                07780000
         DC    AL1(DREC4-DREC)         INVALID DATA ITEM                07800000
         DC    AL1(DREC5-DREC)         ALPHABETIC                       07820000
         DC    AL1(DREC5-DREC)         ALPHANUMERIC                     07840000
         DC    AL1(DREC5-DREC)         FIXED GROUP LENGTH               07860000
         DC    AL1(DREC4-DREC)         INVALID DATA TYPE                07880000
         DC    AL1(DREC4-DREC)         INVALID DATA TYPE                07900000
         DC    AL1(DREC4-DREC)         INVALID DATA TYPE                07920000
         DC    AL1(DREC4-DREC)         INVALID DATA TYPE                07940000
         DC    AL1(DREC4-DREC)         INVALID DATA TYPE                07960000
*                                                                       07980000
       EJECT                                                            08000000
*                                                                       08020000
*    *****************************************************************  08040000
*                        EXTERNAL  NAME  ROUTINE                        08060000
*    *****************************************************************  08080000
*                                                                       08100000
EXTNAM   DS    0H                                                  000C 08200017
ENTNAM OI    NAMESW,X'01'              SET SW FOR FIRST EXTERNAL-NAME   08380000
       SR    C1,C1                                                      08400000
       IC    C1,3(S1)                                                   08420000
         MVI   XTNAME,C' '                                         000C 08426017
         MVC   XTNAME+1(8),XTNAME  CLEAR XTNAME TO SPACES          000C 08432017
       EX    C1,EXTMOV                 MOVE EXTERNAL-NAME TO SAVE AREA  08440000
       B     GETREC                                                     08460000
       EJECT                                                            08480000
*                                                                       08500000
*   *****************************************************************   08520000
*      THE FOLLOWING ROUTINES ADD INFORMATION TO THE PREVIOUSLY         08540000
*            BUILT  TABLE ENTRIES. BEFORE EACH ROUTINE THE CORRECT      08560000
*            ENTRY WOULD BE FOUND BY MATCHING FILE NAMES.               08580000
*   *****************************************************************   08600000
*                                                                       08620000
REINTG   DS    0H                  RERUN EVERY INT RECORDS OF F-N  000C 08630017
*        INPUT RECORD (S1)   0-3   X'0CXXXXLL'    SRC FIELD        000C 08640017
*                           4-6    X'KKKKKK'      INTEGER (BIN)    000C 08650017
*                           7      X'NN'          F-N LENGTH       000C 08660017
*                           8      X'FILE-NAME..' FILE-NAME(MAX 30)000C 08670017
*        EXTERNAL NAME HAS ALREADY BEEN RECEIVED                   000C 08680017
*                                                                  000C 08690017
         BAL   L1,FILFND           TO FIND THE FILE WE WANT        000C 08700017
         TM    TFIL3(C4),MSKRERUN  IS THERE ALREADY RERUN THIS FILE000C 08710017
         BZ    REINTG1             NO, CONTINUE                    000C 08720017
         BAL   L1,CDIAGA           YES, PUT OUT                    000C 08730017
         DC    X'0060'             ERROR 96                        000C 08740017
         LA    0,0(S1)             POS-SEQ                         000C 08750017
         B     GETREC              IGNORE CLAUSE                   000C 08760017
REINTG1  EQU   *                                                   000C 08770017
         MVC   RRNLIT1(8),XTNAME+1 MOVE EXTERNAL-NAME TO LIT       000C 08780017
         MVC   RRNLIT2(3),4(S1)    MOVE RECORD COUNT TO LIT        000C 08790017
         L     L1,CCOMM            GET LATEST LITERAL NUMBER       000C 08800017
         LH    W2,UNLIT(L1)                                        000C 08810017
         LA    W2,1(W2)            STEP IT                         000C 08820017
         STH   W2,UNLIT(L1)        PUT IT BACK                     000C 08830017
         MVC   RRNLIT+5(2),UNLIT(L1) USE IT                        000C 08840017
         MVC   RRNLIT(3),0(S1)     MOVE IN POS-SEQ                 000C 08850017
         NI    RRNLIT,X'01'                                        000C 08860017
         OI    RRNLIT,X'CA'        MOVE IN SRC-ID                  000C 08870017
         LA    S2,RRNLIT           POINT TO RERUN LITERAL          000C 08880017
         BAL   L1,CPUTA              AND PUT IT OUT                000C 08890017
         MVC   TRRNLIT(2,C4),RRNLIT+5  SAVE LIT NO IN IOTAB        000C 08900017
         OI    TFIL3(C4),MSKRERUN  INDICATE RERUN FOR THIS FILE    000C 08910017
         B     GETREC                                              000C 08920017
*                                                                  000C 08930017
*                                                                       09040000
RESTRC MVC   TNORS(2,C4),4(S1)          MOVE NO TRACKS RESTRICTED SRCH  09060000
       OI    TFIL3(C4),MSKRSTCH         TURN ON BIT FOR RESTRICTED SCH  09080000
         CLC   TNORS(2,C4),ZEROF       WERE ANY TRKS SPECIFIED          09100000
         BNE   REST2                   YES                              09120000
         MVC   TNORS(2,C4),C215TH DEFAULT TO 2 TO 15TH - 1(32767)       09140000
         B     REST1                                                    09160000
*                                                                       09180000
REST2  CLC   TNORS(2,C4),C215TH         CHECK TRACKS RESTRICTED SEARCH  09200000
       BH    RESBIG                      LESS 2-15TH ,BRANCH IF NOT     09220000
REST1  BAL   L1,CGETC                  GET RECORD                       09240000
       MVC   SRCTST,0(S1)                                               09260000
       NI    SRCTST,X'FE'               MASK OUT BIT 7                  09280000
       CLI   SRCTST,SRCRST   WAS REST. SEARCH TRAILER FOUND             09300000
       BNE   GETR1                      GO BACK TO CHECK OTHERS         09320000
         OI    RESTCK,X'01'        SET RESTRCT SRCH TRLR ERR SW         09340000
REST3  BAL   L1,FILFND                  FIND FILENAME ENTRY             09360000
         MVI   RESTCK,X'00'        CLEAR TRLR ERR SW                    09380000
       B     RESTRC                                                     09400000
*                                                                       09420000
OVFLO  CLI   OVFCT+1,X'09'              CHECK TOO MANY OVFL REC         09440000
       BE    OVTOO                                                      09460000
       OI    TFIL2(C4),MSKFMOVR         TURN ON OVERFLOW BIT IN TABLE   09480000
       MVC   TDCB(2,C4),OVFCT                                           09500000
       LH    C1,OVFCT                                                   09520000
       AH    C1,THREEH                  SET FOR NEXT RECORD             09540000
       STH   C1,OVFCT                                                   09560000
       B     GETREC                                                     09580000
*                                                                       09600000
SAMAR  TM    TFIL3(C4),MSKSAME          CHECK IF SAME FILE USED IN      09620000
       BO    SAMER                       PREVIOUS SAME CLAUSE           09640000
       L     C3,STBADR                  GET ADDRESS FOR NEXT ENTRY      09660000
SAMTR2 CL    C3,SAMEND                 HAS SAME TABLE AREA BEEN EXCEEDD 09680000
       BE    SAMTO2                    YES-ERROR                        09700000
       OI    TFIL3(C4),MSKSAME         SET SAME AREA SWITCH             09720000
       LA    C2,TREG(C4)                GET ADDRS OF                    09740000
       ST    C2,0(C3)                   STORE TABLE ADDR IN SAMTAB      09760000
       A     C3,FOUR                    INCREMENT STADR FOR NEXT ENTRY  09780000
       ST    C3,STBADR                                                  09800000
SAMGET BAL   L1,CGETC                   GET NEXT RECORD                 09820000
       LR    S2,S1                                                      09840000
       MVC   SRCTST,0(S1)                                               09860000
       NI    SRCTST,X'FF'               CLEAR POS BIT                   09880000
       CLI   SRCTST,SRCSAT              CHECK SAME AREA TRAILER         09900000
       BE    SAMTR                                                      09920000
*      NO MORE TRAILERS STORE NECESSARY POINTERS                        09940000
         L     C3,STBADR           GET ADDRESS OF SAME AREA TABLE       09960000
       LA    C2,0                                                       09980000
       ST    C2,0(C3)                   STORE END OF STRING BUCKET      10000000
       A     C3,FOUR                                                    10020000
       ST    C3,STBADR                  SAVE NEXT TABLE ADDRESS         10040000
       B     GETR1                      GO BACK TO TEST OTHER RECORDS   10060000
*                                                                       10080000
SAMTR    OI    TRLCHK,X'01'        SET SAME AREA TRLR ERR SW            10100000
       BAL   L1,FILFND                  FIND RIGHT FILE ENTRY           10120000
         MVI   TRLCHK,X'00'        CLEAR TRLR ERR SW                    10140000
       B     SAMAR                                                      10160000
*                                                                       10180000
APWRIT   OI    TFIL3(C4),MSKWTONY      BIT ON IN IOTAB FOR WRITE ONLY   10200000
         B     GETREC                  GET NEXT RECORD                  10220000
*                                                                       10240000
*                                                                       10260000
       EJECT                                                            10280000
*                                                                       10300000
*   *****************************************************************   10320000
*      FOLLOWING IS SUBROUTINE LOOKS FOR A MATCHING FILENAME IN A       10340000
*            RECORD AND IOTAB ENTRY ALREADY IN CORE                     10360000
*            REG C5 CONTAINS ADDRESS OF POS AFTER LAST TABLE ENTRY.     10380000
*              IF MORE TO BUILD WOULD BE ADDRESS OF NEXT ENTRY.         10400000
*            REG C4 CONTAINS ADDRESS OF ENTRY WE ARE LOOKING AT.        10420000
*              IF CORRECT MATCH IS FOUND THIS REGISTER RETURNED         10440000
*              TO MAIN LINE FOR UPDATING ENTRY.                         10460000
*            REG C3 CONTAINS LENGTH  OF FILENAME FROM RECORD FOR        10480000
*              EXECUTED MOVES AND COMPARES.                             10500000
*   *****************************************************************   10520000
*                                                                       10540000
FILFND DS    0H                                                    000C 10544017
       CLI   0(S1),SRCRI                IS THIS A RERUN RECORD?    000C 10548017
       BNE   FILFN2                     NO, BRANCH                 000C 10552017
       IC    C3,7(S1)                   GET LENGTH OF FILE NAME    000C 10556017
       EX    C3,FILMOV1                 MOVE FILE NAME TO WORK     000C 10560017
       B     FILFN1                                                000C 10564017
FILFN2 EQU   *                                                     000C 10568017
       IC    C3,6(S1)                   GET LENGTH OF FILE NAME    000C 10572017
       EX    C3,FILMOV                  MOVE FILE NAME TO WORK          10580000
FILFN1 LA    C4,IOTAB                   GET START ADDRESS OF TABLE      10600000
       SR    C2,C2                                                      10620000
FILOOP CLR   C4,C5                      CHECK END OF TABLE              10640000
       BE    NOTFND                     BRANCH IF NOT FOUND.            10660000
       EX    C3,FILCMP                  COMPARE THE FILENAMES           10680000
       BE    FOUND                      BRANCH IF MATCH FOUND           10700000
       IC    C2,TLENFN(C4)              GET LENGTH OF FILE NAME         10720000
       A     C4,FTBLEN                  ADD FIXED LENGTH                10740000
       AR    C4,C2                      ADD LENGTH OF FILE NAME         10760000
       B     FILOOP                     GO CHECK NEXT FILE NAME         10780000
FOUND  MVI   FDSWIT,X'00'                                               10800000
       BR    L1                                                         10820000
       EJECT                                                            10840000
*                                                                       10860000
*   *****************************************************************   10880000
*      THIS PORTION PROCESSES THE ENTRIES PUT OUT BY THE                10900000
*           FILE DESCRIPTION OF DS2.                                    10920000
*   *****************************************************************   10940000
*                                                                       10960000
GFDENT NI    0(S1),X'FE'                CLEAR POS BIT                   10980000
       CLI   0(S1),SRCFDB               CHECK FOR FD BASE RECORD        11000000
       BE    FDBASE                                                     11020000
       CLI   0(S1),SRCLAB               CHECK FOR LABEL RECORD          11040000
       BE    LABREC                                                     11060000
*      SYSTEM FAILURE IF WE FALL THROUGH THIS BRANCH                    11080000
         B     GETREC                                                   11100000
LABREC MVC   MMCODE,4(S1)              GET MAJOR-MINOR CODE             11120000
       NI    MMCODE,MMMASK             MASK OUT MINOR CODE              11140000
       CLI   MMCODE,LKCHCK             IS IT LINKAGE SECTION            11160000
       BNE   LABERR                                                     11180000
*                                                                       11200000
LABOUT   OI    TFIL2(C4),MSKUSLAB      SET USER LABEL SWITCH ON         11220000
*            ********************************************************** 11240000
       BAL   L1,CDIAGA                 USER LABELS NOT PERMITTED        11260000
       DC    X'004D'                   ERROR 77                         11280000
       LA    0,0(S2)                   POS-SEQ                          11300000
*            ********************************************************** 11320000
       B     GETREC                    TEMPORARY UNTIL USER LABELS      11340000
*                                        ARE SUPPORTED                  11360000
*            ********************************************************** 11380000
       MVC   BASESV,5(S1)                                               11400000
       L     C3,BASESV                                                  11420000
       SRL   C3,20                       ATTRIBUTE                      11440000
       STH   C3,BASLOC                 STORE BASE LOCATOR               11460000
       LA    S2,SAMLAB                                                  11480000
       MVC   SAMLAB+4(2),BASLOC         MOVE BASE LOCATOR TO OUTPUT     11500000
LABTAP MVC   SAMLAB+6(3),SVBSDS         MOVE BASE/DIS TO OUTPUT         11520000
       BAL   L1,CPUTA                                                   11540000
       B     GETREC                                                     11560000
*                                                                       11580000
         EJECT                                                          11600000
*                                                                       11620000
*    *****************************************************************  11640000
*      FOLLOWING ARE EQUATES FOR FD RECORD PARTS                        11660000
*    *****************************************************************  11680000
*                                                                       11700000
FDDCB  EQU   5                          DCB ADDRESS FROM MERGED ATTR.   11720000
FDLDR  EQU   6                         LOAD ADDRESS                     11740000
FDLEN  EQU   10                         LENGTH OF RECORD                11760000
FDSW   EQU   12                         SWITCH BYTE                     11780000
FDREC  EQU   13                         RECORD COUNT                    11800000
FDBLK  EQU   15                         BLOCK CONTAINS                  11820000
FDFNML EQU   17                         LENGTH BYTE OF FILE NAME        11840000
FDFNM  EQU   18                         FILE NAME IN FD ENTRY           11860000
*                                                                       11880000
FDBASE IC    C3,FDFNML(S1)              GET LENGTH OF NAME FROM RECORD  11900000
       EX    C3,FDNMOV                  MOVE FILE NAME TO WORK BUCKET   11920000
       OI    FDSWIT,X'01'                                               11940000
       BAL   L1,FILFN1                  GET CORRECT IOTAB ENTRY         11960000
*                                       NOTE, THIS IS SECOND ENTRY PT   11980000
       MVC   TLDADR(2,C4),FDLDR(S1)    MOVE LOAD ADDRESSS TO I/O TABLE  12000000
       L     W1,CCOMM                                                   12020000
       MVC   DCBSAV+1(3),UNEXT(W1)     GET BASE/DISP FROM COMMON AREA   12040000
       L     W2,DCBSAV                                                  12060000
       LA    W2,7(W2)                  INCREMENT BASE/DISPLACEMENT      12080000
       SRL   W2,3                        AND SHIFT TO ALIGN ON          12100000
       SLL   W2,3                        DOUBLE WORD BOUNDRY            12120000
       ST    W2,DCBSAV                                                  12140000
         TM    TFIL4(C4),MSKREL        RELATIVE ORGANIZATION            12160000
         BO    FDREL                   YES                              12180000
       TM    TFIL1(C4),MSKIND          INDEXED ORGANIZATION             12200000
       BO    FDIND                     YES                              12220000
       TM    TFIL1(C4),MSKDIR          DIRECT ORGANIZATION              12240000
       BO    FDDIR                     YES                              12260000
         A     W2,QSAMLEN              NO-ADD SEQ ORG & SEQ ACCESS      12280000
FDGO   ST    W2,DCBUP                  SAVE UPDATED DCB ADDRESS         12300000
       MVC   UNEXT(3,W1),DCBUP+1       MOVE NEW BASE/DISPLACEMENT TO    12320000
*                                        COMMON AREA                    12340000
         TM    FDSW(S1),X'04'      BLOCK CONTAINS CHARACTERS      32789 12343020
         BZ    FDLBL               NO                             32789 12346020
         OI    TFIL4(C4),X'04'     SET BLK = CHAR IND ON          32789 12349020
         NI    FDSW(S1),X'FB'      TURN OF BLK = CHAR SW          32789 12352020
FDLBL    EQU   *                                                  32789 12355020
       TM    FDSW(S1),X'08'            LABEL RECORDS OMITTED            12360000
       BO    FDLABL                    YES                              12380000
         OI    TFIL3(C4),MSKSTLAB      SET STD LAB SWITCH ON            12400000
FDCHK  OC    TFIL2(1,C4),FDSW(S1)      SET SWITCHES FROM FD TO TABLE    12420000
         TM    TFIL2(C4),X'10'     TEST FOR UNDEFINED REC.         3070 12428015
         BZ    TSTVAR              NO - TEST FOR VAR. LENGTH       3070 12436015
         NI    TFIL3(C4),X'FE'     RESET APPLY WRITE ONLY BIT      3070 12444015
TSTVAR   TM    TFIL2(C4),MON8      IS THIS REC VAR LENGTH          3070 12452015
         BC    7,FDCHK1                YES                              12460000
         OI    TFIL2(C4),MSKVARBL       NO - SET VARIABLE LENGTH SWITCH 12480000
         B     FDRCHK                                                   12500000
FDCHK1   TM    9(S1),MON4              TEST ATTRIBUTE FOR VARYING       12520000
       BZ    FDRCHK                                                     12540000
       OI    TFIL2(C4),MON4             TURN ON VARYING BIT IN IOTABB   12560000
FDRCHK MVC   TRECL(4,C4),FDREC(S1)      MOVE RECORD LEN + BLOCK COUNT   12580000
*                                       TO TABLE ENTRY                  12600000
       CLC   TRECL(2,C4),FDLEN(S1)      CHECK RECORD LENGTH FROM FD VS. 12620000
       BE    FDBCHK                     LENGTH FROM RECORD DESCRIPTIONS 12640000
*                                       FOLLOWING FD                    12660000
       CLC   TRECL(2,C4),ZEROH         IS RECORD LENGTH ZERO            12680000
       BNE   RECERR                    NO-ERROR REC. LGTHS DISAGREE     12700000
FDLCHK MVC   TRECL(2,C4),FDLEN(S1)     MOVE CALCULATED RECORD LENGTH    12720000
*                                        TO I/O TABLE                   12740000
FDBCHK TM    TFIL2(C4),MSKBLKCT         CHECK BLOCK CHAR  OR RECORD     12760000
       BZ    FDBLCK                    BLK LENGTH NOT BLKING FACTOR     12780000
       CLC   TRBLCK(2,C4),ONEH          CHECK BLOCK COUNT 1             12800000
       BE    FDRCCK                    YES-GO SEE IF VARIABLE RECORDS   12820000
       OI    TFIL2(C4),MSKBLKA          TURN ON BLOCKED BIT             12840000
FDBKCP   EQU   *                                                        12850020
       MVC   WKPT,TRBLCK(C4)            MOVE BLOCK COUNT TO WORK        12860000
       LH    C2,WKPT                   INIT. TO COMPUTE BLOCK LENGTH    12880000
       MVC   WKPT,TRECL(C4)             MOVE RECORD LENGTH TO WORK      12900000
       TM    TFIL2(C4),MON8            IS RECORD LENGTH VARIABLE LENGTH 12920000
       BC    7,FDVARY                  NO                               12940000
       SR    W1,W1                     INCREMENT RECORD LENGTH          12960000
       LH    W1,WKPT                     BY FOUR                        12980000
       LA    W1,4(W1)                                                   13000000
       STH   W1,WKPT                                                    13020000
       MVC   TRECL(2,C4),WKPT                                           13040000
FDVARY MH    C2,WKPT                   MULTIPLY BLOCK BY RECORD LENGTH  13060000
       TM    TFIL2(C4),MON8            IS BLOCK RECORD VARIABLE         13080000
       BC    7,FDVALU                  NO                               13100000
         CLC   TRBLCK(2,C4),ZEROH      IS BLOCK SIZE ZERO               13106020
         BE    FDVALU                  YES,DONT ADD 4 TO BLKSIZE        13112020
FDVAL  LA    C2,4(C2)                  INCREMENT LENGTH BY FOUR         13120000
FDVALU CH    C2,C215TH                 CHECK VALUE LESS 2-15TH          13140000
       BH    BLKBIG                     BRANCH IF TO BIG                13160000
FDBCK1 STH   C2,WKPT                                                    13180000
       MVC   TRBLCK(2,C4),WKPT         BLOCK LENGTH TO IOTAB            13200000
*                                                                       13220000
*      NOW CHECK TO SEE IF OVERFLOW SWITCH NEEDS SET                    13240000
*                                                                       13260000
OVFCHK TM    TFIL2(C4),MSKFMOVR        OVERFLOW                         13280000
       BZ    FDCBST                    NO                               13300000
       MVC   WKPT(2),TDCB(C4)           GET NUMBER                      13320000
       LH    C1,WKPT                                                    13340000
       L     C2,CCOMM                                                   13360000
       AR    C2,C1                      GET ADDRESS TO MOVE INTO        13380000
       MVC   UDCBF(3,C2),DCBSAV+1      MOVE DCB ADDR TO OVFLO COMMON    13400000
FDCBST MVC   TDCB(3,C4),DCBSAV+1       MOVE DCB TO TABLE ENTRY          13420000
       MVC   SVBSDS(3),DCBSAV+1         SAVE BASE AND DISPLACEMENT      13440000
FDREG  MVC   TREG(2,C4),REGCT           STORE REGISTER IN TABLE ENTRY   13460000
       LH    C1,REGCT                                                   13480000
       AH    C1,ONEH                                                    13500000
       STH   C1,REGCT                   STORE NEXT REG.                 13520000
       B     GETREC                                                     13540000
FDIND    TM    TFIL1(C4),MSKRAN        RANDOM ACCESS                    13560000
         BO    FDINDR                  YES                              13580000
         A     W2,QISAMLEN             NO-SEQUENTIAL ADD DCB LENGTH     13600000
         B     FDGO                                                     13620000
FDINDR   A     W2,BISAMLEN             ADD RANDOM DCB LENGTH            13640000
       B     FDGO                                                       13660000
FDDIR TM    TFIL1(C4),MSKRAN           RANDOM ACCESS                    13680000
       BO    FDDIR1                    YES                              13700000
         A     W2,BSAMDLEN             ADD DCB LENGTH                   13720000
       B     FDGO                                                       13740000
FDDIR1   A     W2,BDAMDLEN             ADD DCB LENGTH                   13760000
       B     FDGO                                                       13780000
*                                                                       13800000
FDREL    TM    TFIL1(C4),MSKRAN        RANDOM ACCESS                    13820000
         BO    FDREL1                  YES                              13840000
         A     W2,BSAMRLEN             NO-SEQUENTIAL ADD DCB LGTH       13860000
         B     FDGO                                                     13880000
FDREL1   A     W2,BDAMRLEN             ADD RANDOM DCB LGTH              13900000
         B     FDGO                                                     13920000
*                                                                       13940000
FDBLCK CLC   TRBLCK(2,C4),ZEROH        IS BLOCK LENGTH ZERO             13960000
       BE    FDRCCK                    YES                              13980000
         TM    TFIL4(C4),X'04'     IS BLOCK CONTAINS CLAUSE PRES  32789 13982020
         BZ    FDRCCK              NO                             32789 13984020
         CLC   TRECL(2,C4),TRBLCK(C4)     REC/BLK SIZE DISAGFEE    0439 13986014
         BH    ERREC                                               0439 13992014
         CLC   TRECL(2,C4),ZEROH       IS RECORD LENGTH ZERO       9412 13992317
         BE    ERREC                                               9412 13992617
         TM    TFIL2(C4),MON8          VARIABLE                    4478 13992915
         BC    8,FDBLCK1               YES                         4478 13993815
         CLC   TRECL(2,C4),ZEROH       IS RECORD LENGTH ZERO       0417 13994117
         BE    FDBLC                   YES                         0417 13994417
         MVC   BLKFACT+2(2),TRBLCK(C4)  GET BLOCK SIZE             4478 13994715
         MVC   RECSIZ+2(2),TRECL(C4)   GET RECORD SIZE             4478 13995615
         SR    W1,W1                                               4478 13996515
         L     W2,BLKFACT                                          4478 13997415
         L     W3,RECSIZ                                           4478 13998315
         DR    W1,W3                                               4478 13999215
         LTR   W1,W1                                               4478 14000115
         BC    7,ERREC                                             4478 14001015
FDBLCK1  OI    TFIL2(C4),MON6     TURN ON BLOCK BIT                0439 14002014
         TM    TFIL1(C4),MSKDASD       IS THIS DIR ACCESS               14020000
         BZ    FDBLC                   NO                               14040000
         CLC   TRECL(2,C4),ZEROH       IS RECORD LENGTH ZERO       9412 14046017
         BE    FDBLCX                                              9412 14052017
         MVC   BLKFACT+2(2),TRBLCK(C4)     GET BLOCKSIZE           4478 14060015
         MVC   RECSIZ+2(2),TRECL(C4)       GET RECORD SIZE         4478 14080015
         SR    W1,W1                   CLEAR REMAINDER REGISTER         14100000
         L     W2,BLKFACT              GET BLOCK SIZE                   14120000
         L     W3,RECSIZ               GET RECORD LENGTH                14140000
         DR    W1,W3                   COMPUTE BLKING FACTOR  BLK/REC   14160000
         STH   W2,BLKFACT+2            SAVE BLK FACTOR                  14180000
FDBLCX   EQU   *                                                   9412 14190017
*        MVC   TBLOCK(2,C4)BLKFACT+4   BLKFACT TO IOTAB IF REQ LATER    14200000
FDBLC  TM    TFIL2(C4),MON8            IS RECORD VARIABLE               14220000
       BC    7,FDBLC1                  NO                               14240000
       MVC   WKPT,TRECL(C4)            GET RECORD LENGTH                14260000
       LH    C2,WKPT                   INCREMENT BY 4 TO INCLUDE        14280000
       LA    C2,4(C2)                    RECORD CONTROL FIELD           14300000
       STH   C2,WKPT                                                    14320000
         CLC   TRBLCK(2,C4),WKPT       BLOCK SIZE AT LEAST = TO    7679 14330020
         BL    VBLKERR            INCREMENTED RECORD SIZE, NO     25231 14340000
FDBLC0   MVC   TRECL(2,C4),WKPT                                   25231 14350000
FDBLC1 MVC   WKPT,TRBLCK(C4)           MOVE BLOCK LENGTH TO WORK        14360000
       LH    C2,WKPT                                                    14380000
       TM    TFIL2(C4),MON8            IS  RECORD VARIABLE              14400000
         BNE   FDVALU                                                   14410020
       B     FDVAL                                                      14440000
FDRCCK MVC   WKPT,TRECL(C4)            MOVE RECORD LENGTH TO WORK       14460000
FDBLRC LH    C2,WKPT                   INSERT IN REGISTER               14500000
         TM    TFIL4(C4),X'04'                                    32789 14503020
         BZ    FDBCCH                                             32789 14506020
         CLC   TRBLCK(2,C4),ZEROH                                 32789 14509020
         BE    FDBKCP                                             32789 14512020
FDBCCH   EQU   *                                                  32789 14515020
       TM    TFIL2(C4),MON8            IS RECORD LENGTH VARIABLE LENGTH 14520000
         BNE   FDVALU                                                   14540020
       LA    C2,4(C2)                  YES - ADD 4 TO BLOCK SIZE        14560000
       STH   C2,WKPT                                                    14580000
       MVC   TRECL(2,C4),WKPT                                           14600000
         B     FDVAL                                                    14620020
FDLABL NI    FDSW(S1),X'F0'            CLEAR LABELS OMITTED INDICATOR   14640000
       OI    TFIL3(C4),MSKLABOM        SET LABEL RECORDS OMITTED SWITCH 14660000
       B     FDCHK                                                      14680000
*      FINISH  OF FD BASE ENTRY                                         14700000
*                                                                       14720000
       EJECT                                                            14740000
ENDIN  L     C5,TEMBUK                                                  14760000
       ST    C5,IOEND                   STORE END ADDR OF I/O TABLE     14780000
*                                                                       14800000
*      AT THIS POINT THE CHECKPOINT DCB WILL BE BUILT WHEN ALL          14820000
*      NECESSARY INFORMATION IS AVAILABLE.                              14840000
*                                                                       14860000
*      MVC   MAXLEN(4),CPTCON          GET CHECKPOINT LENGTH            14880000
*      MVC   SDCB(4),DCBCPT            GET ADDRESS FOR CHECKPOINT DCB   14900000
*                                                                       14920000
*      ALL OTHER NECESSARY INSTRUCTIONS.                                14940000
*                                                                       14960000
*      B     ITEXT1                                                     14980000
*                                                                       15000000
       EJECT                                                            15040000
*                                                                       15060000
*   *****************************************************************   15080000
*      THE   FOLLOWING PICKS UP WITH THE DIAGNOSTIC FUNCTION OF IOT     15100000
*            AN ERROR MATRIX WILL BE USED TO CATCH CONFLICTING TYPES    15120000
*            IN-LINE TESTING WILL BE USED TO FIND THE ABSENCE OF        15140000
*            REQUIRED CLAUSES ON PARTICULAR FILES                       15160000
*   *****************************************************************   15180000
*                                                                       15200000
IDIAG  SR    C4,C4                      CLEAR  REGISTERS                15220000
       SR    C5,C5                                                      15240000
       LA    C4,IOTAB                                                   15260000
IDNEXT C     C4,IOEND                   CHECK END OF I/O TABLE          15280000
       BE    IDEND                                                      15300000
       CLC   TREG(2,C4),ZEROH          IS THERE FD BASE ENTRY           15320000
       BE    NOFDBS                    NO                               15340000
IDGA   TM    TFIL1(C4),MSKDASD          CHECK FOR DIRECT ACCESS         15360000
       BZ    IDGA1                                                      15380000
       BAL   L1,IERCHK                  CHECK ERROR MATRIX              15400000
       DC    S(IERDAC)                                                  15420000
       DC    X'80000000'                                                15440000
       B     IDGB                                                       15460000
IDGA1  TM    TFIL1(C4),MSKUTIL          CHECK FOR UTILITY               15480000
       BZ    IDGA2                                                      15500000
       BAL   L1,IERCHK                  CHECK ERROR MATRIX              15520000
       DC    S(IERUTL)                                                  15540000
       DC    X'40000000'                                                15560000
       B     IDGB                                                       15580000
IDGA2  TM    TFIL1(C4),MSKUNIT          CHECK FOR UNIT RECORD           15600000
       BZ    IDGB                                                       15620000
       BAL   L1,IERCHK                  CHECK ERROR MATRIX              15640000
       DC    S(IERURC)                                                  15660000
       DC    X'20000000'                                                15680000
IDGB   TM    TFIL1(C4),MSKRAN           CHECK RANDOM ACCESS             15700000
       BZ    IDGB1                                                      15720000
       BAL   L1,IERCHK                  CHECK ERROR MATRIX              15740000
       DC    S(IERRAD)                                                  15760000
       DC    X'08000000'                                                15780000
       B     IDGC                                                       15800000
IDGB1  BAL   L1,IERCHK                  SEQUENTIAL ASSUMED              15820000
       DC    S(IERSEQ)                  CHECK ERROR MATRIX              15840000
       DC    X'10000000'                                                15860000
IDGC   TM    TFIL1(C4),MSKDIR           CHECK DIRECT ORGANIZATION       15880000
       BZ    IDGC1                                                      15900000
       BAL   L1,IERCHK                  CHECK ERROR MATRIX              15920000
       DC    S(IERDIR)                                                  15940000
       DC    X'04000000'                                                15960000
       B     IDGD                                                       15980000
IDGC1  TM    TFIL1(C4),MSKIND           CHECK INDEXED ORGANIZATION      16000000
       BZ    IDGD                                                       16020000
       BAL   L1,IERCHK                  CHECK ERROR MATRIX              16040000
       DC    S(IERIND)                                                  16060000
       DC    X'02000000'                                                16080000
IDGD   TM    TFIL3(C4),MSKACTK          CHECK ACTUAL KEY                16100000
       BZ    IDGE                                                       16120000
       BAL   L1,IERCHK                  CHECK ERROR MATRIX              16140000
       DC    S(IERACT)                                                  16160000
       DC    X'00001000'                                                16180000
IDGE   TM    TFIL2(C4),MSKSYMK          CHECK FOR SYMBOLIC KEY          16200000
       BZ    IDGF                                                       16220000
       BAL   L1,IERCHK                  CHECK ERROR MATRIX              16240000
       DC    S(IERSYM)                                                  16260000
       DC    X'00010000'                                                16280000
IDGF   TM    TFIL2(C4),MSKBLKA          CHECK FOR BLOCKED RECORDS       16300000
       BZ    IDGG                                                       16320000
       BAL   L1,IERCHK                  CHECK ERROR MATRIX              16340000
       DC    S(IERBLK)                                                  16360000
       DC    X'00020000'                                                16380000
IDGG   TM    TFIL3(C4),MSKRSTCH         CHECK FOR RESTRICTED SEARCH     16400000
       BZ    IDGH                                                       16420000
       BAL   L1,IERCHK                  CHECK ERROR MATRIX              16440000
       DC    S(IERRST)                                                  16460000
       DC    X'00002000'                                                16480000
IDGH   TM    TFIL2(C4),MSKVARBL         CHECK VARIABLE FORMAT           16500000
       BZ    IDGI                                                       16520000
       BAL   L1,IERCHK                  CHECK ERROR MATRIX              16540000
       DC    S(IERVAR)                                                  16560000
       DC    X'00080000'                                                16580000
IDGI   TM    TFIL2(C4),MSKFMOVR         CHECK FORMS OVERFLOW            16600000
         BZ    IDGJ                                                     16620000
       BAL   L1,IERCHK                  CHECK ERROR MATRIX              16640000
       DC    S(IERFOR)                                                  16660000
       DC    X'00040000'                                                16680000
IDGJ     TM    TFIL4(C4),MSKREL        CHECK RELATIVE ORG.              16700000
         BZ    IDGK                    NO                               16720000
         BAL   L1,IERCHK               CHECK ERROR MATRIX               16740000
         DC    S(IERREL)               ADDR IN ERROR MATRIX             16760000
         DC    X'00000080'             POSITION IN TYPE BYTE BITS       16780000
IDGK     TM    TFIL3(C4),MSKWTONY      CHECK APPLY WRITE-ONLY           16800000
         BZ    IDGL                    NO                               16820000
         BAL   L1,IERCHK               CHECK ERROR MATRIX               16840000
         DC    S(IERWRT)               ADDR IN ERROR MATRIX             16860000
         DC    X'00000100'             POSITION IN ERROR MATRIX         16880000
IDGL     TM    TFIL4(C4),MSKSEQOR      CHECK IF SEQUENTIAL ORGANIZATION 16900000
         BZ    IDGREQ                  NO                               16920000
         BAL   L1,IERCHK               CHECK ERROR MATRIX               16940000
         DC    S(IERSEQOR)             ADDRESS OF THIS MATRIX           16960000
         DC    X'00000010'             POSITION IN MATRIX               16980000
*      THIS  IS THE END OF MATRIX CHECKING FOR CONFLICTING CLAUSES      17000000
*                                                                       17020000
         EJECT                                                          17040000
*                                                                       17060000
*   *****************************************************************   17080000
*      THE FOLLOWING ARE DIAGNOSING MISSING REQUIRED CLAUSES            17100000
*   *****************************************************************   17120000
*                                                                       17140000
IDGREQ   TM    TFIL4(C4),MSKFILIM      WAS FILE-LIMIT SPECIFIED         17160000
         BO    IDRFILM                 YES-GO DIAGNOSE IT               17180000
IDGREQ1  TM    TFIL1(C4),X'8A'   CHK DIR DEV,W/INDX ORG,W/RAND ACC.     17200000
         BO    IDRSYM                  CHK SYM KEY AND REC KEY          17220000
         TM    TFIL1(C4),X'92'   CHK DIR DEV,W/INDX ORG,W/SEQ ACC       17240000
         BO    IDRREC                  CHK REC KEY                      17260000
         TM    TFIL1(C4),X'8C'   CHK DIR DEV, W/DIRCT ORG, W/RAND ACC   17280000
       BO    IDBOTH                    CHECK SYM & ACT KEY              17300000
         TM    TFIL1(C4),X'94'   CHK DIR DEV,W/DIRCT ORG,W/SEQ ACC      17320000
         BO    IDBOTH                  BR YES TO CHK SYMK & ACTK        17340000
         TM    TFIL1(C4),MSKDASD       IS DEVICE TYPE DIRECT ACCESS     17360000
         BZ    IDGEND                  NO                               17380000
*                                                                       17400000
*   **  DEVICE TYPE IS DIRECT ACCESS                                    17420000
*                                                                       17440000
         TM    TFIL4(C4),MSKREL        IS ORG RELATIVE                  17460000
         BZ    IDGEND                  NO                               17480000
*                                                                       17500000
*   **  ORGANIZATION IS RELATIVE AND DEVICE TYPE IS DIRECT ACCESS  **   17520000
*                                                                       17540000
         TM    TFIL1(C4),MSKRAN        IS ACCESS METHOD RANDOM          17560000
         BO    IDRSYMR       YES-(RELATIVE-RANDOM) GO CHK SYM KEY       17580000
         TM    TFIL2(C4),MSKSYMK       CHK IF SYM KEY GIVEN IN ERROR    17600000
         BZ    IDGEND                  NO ERROR                         17620000
         B     SYMKERR                 ERROR-GO PUT DIAG NUMBER 59      17640000
*                                                                       17660000
*                                                                       17680000
*    *****************************************************************  17700000
*    *   ENTER HERE WHEN SYM KEY AND REC KEY ARE REQ. FOR I/O FILES  *  17720000
*    *****************************************************************  17740000
*                                                                       17760000
IDRSYM   OI    INDISW,X'01'            TURN RECKEY CHK SW ON            17780000
         TM    TFIL2(C4),MSKSYMK       CHK FOR SYM KEY                  17800000
         BZ    NOSKEY                  ERROR-117                        17820000
*                                                                       17840000
*                                                                       17860000
*    *****************************************************************  17880000
*    *   ENTER HERE WHEN REC KEY REQUIRED FOR I/O FILES              *  17900000
*    *****************************************************************  17920000
*                                                                       17940000
IDRREC   TM    TFIL3(C4),MSKRECK       CHK REQUIRED RECORD KEY          17960000
         BZ    NORKEY                  ERROR-107                        17980000
*                                                                       18000000
IDRREC1  CLI   INDISW,X'01'  IF REC KEY SW ON THEN SYM KEY WAS GIVEN    18020000
         BNE   IDGEND                  NO SYM KEY GIVEN.BYP LGTH CHECK  18040000
*                                                                       18060000
         MVI   INDISW,X'00'            RESET REC KEY SW TO ZERO         18080000
         CLC   TKEYL(1,C4),TKEYR(C4)   ARE SYM KEY AND REC KEY EQUAL    18100000
         BNE   KEYLGTER                GO PUT ERROR 112                 18120000
         B     IDGEND                  GO BUILD DCB                     18140000
*                                                                       18160000
*                                                                       18180000
*    *****************************************************************  18200000
*    *   ENTER HERE FOR SYM KEY ONLY REQUIRED FOR I/O FILES          *  18220000
*    *****************************************************************  18240000
*                                                                       18260000
IDRSYMR  TM    TFIL2(C4),MSKSYMK       CHK FOR SYM KEY ONLY(NO RETURN)  18280000
         BZ    NOSKEY                  ERROR-117                        18300000
         B     IDGEND                  GO BUILD DCB                     18320000
*                                                                       18340000
*                                                                       18360000
*    *****************************************************************  18380000
*    *   ENTER HERE WHEN SYM KEY AND ACT KEY REQ. FOR I/O FILES      *  18400000
*    *****************************************************************  18420000
*                                                                       18440000
IDBOTH   OI    INDISW,X'02'            TURN ACT KEY CHK SW ON           18460000
         TM    TFIL2(C4),MSKSYMK       CHK FOR SYM KEY                  18480000
         BZ    NOSKEY                  ERROR-117                        18500000
*                                                                       18520000
*                                                                       18540000
*    *****************************************************************  18560000
*    *   ENTER HERE FOR DIR ORG FILES & ISSUE A W DIAG IF NO ACT KEY *  18580000
*    *****************************************************************  18600000
*                                                                       18620000
IDRACT   MVI   INDISW,X'00'            TURN ACT KEY CHK SW OFF          18640000
         TM    TFIL3(C4),MSKACTK       CHK FOR ACT KEY                  18660000
         BZ    NOAKEY                  ERROR-118                        18680000
         B     IDGEND                  GO BUILD DCB                     18700000
*                                                                       18720000
*                  THIS RTNE DIAGNOSES FILE-LIMIT CLAUSE.               18740000
*                  VALID ONLY FOR DIR ORG, SEQ METH. (MATRIX CHK        18760000
*                  WILL CHECK ACCESS METHOD).                           18780000
*                                                                       18800000
IDRFILM  TM    TFIL1(C4),MSKDIR        IS ORG DIRECT                    18820000
         BZ    FILIMER                 NO-ERROR 116                     18840000
         B     IDGREQ1                 YES-CHK FOR OUT/FIL IN PG PHASE  18860000
*                                                                       18880000
*                                                                       18900000
*      THIS SHOULD BE THE END OF NECESSARY DIAGNOSTICS FOR A SINGLE     18920000
*            ENTRY IN I/O TABLE                                         18940000
*                                                                       18960000
       EJECT                                                            18980000
*                                                                       19000000
*   *****************************************************************   19020000
*      THE FOLLOWING SUBROUTINE CHECKS THE ERROR MATRIX                 19040000
*   *****************************************************************   19060000
*                                                                       19080000
IERCHK MVC   IERC+4(2),0(L1)            MOVE IN ADDRESS OF MATRIX ENTRY 19100000
       MVC   IERWK(4),TFIL1(C4)        MOVE ALL TYPE BYTES TO WORKAREA  19120000
       EX    0,IERC                    BLAST THEM WITH AN AND INSTR     19140000
       BZ    6(0,L1)                   BRANCH ZERO, VALID RETURN        19160000
       ST    L1,SAVL1                   SAVE LINK REGISTER              19180000
       OC    IERWK(4),2(L1)            OR CONFLICTING CLAUSE            19200000
       MVC   POSSEQ+1(2),TSEQ(C4)       MOVE IN SAVED SEQUENCE NUMBER   19220000
*            ********************************************************** 19240000
       BAL   L1,CDIAGA                 MATRIX ERROR                     19260000
       DC    X'205A'                   ERRROR 90                        19280000
       LA    0,POSSEQ                                                   19300000
       LA    0,TLENFN(C4)              FILE-NAME                        19320000
       LA    0,IERWKL                   TRAILER ERROR VECTOR            19340000
*            ********************************************************** 19360000
       L     L1,SAVL1                   RESTORE LINK                    19380000
       B     6(0,L1)                   GO CHECK NEXT ERROR              19400000
*                                                                       19420000
IERC   NC    IERWK(4),0                 CHECK CONFLICTS IN CLAUSES      19440000
*                                                                       19460000
*   *****************************************************************   19480000
*      THE FOLLOWING IS THE ERROR MATRIX FOR CONFLICTING CLAUSES        19500000
*            ON FILE DESCRIPTIONS                                       19520000
*   *****************************************************************   19540000
*                                                                       19560000
IERDAC   DC    X'60040800'             DIRECT ACCESS  DEVICE            19580000
IERUTL   DC    X'AE0534E0'             UTILITY        DEVICE            19600000
IERURC   DC    X'CE4137E0'             UNIT RECORD    DEVICE       000C 19620017
IERSEQ   DC    X'08002040'             SEQUENTIAL     ACCESS METHOD     19640000
IERRAD   DC    X'70040930'             RANDOM         ACCESS METHOD000C 19660017
IERDIR   DC    X'63860DD0'             DIRECT         ORGANIZATION      19680000
IERIND   DC    X'641C39B0'             INDEXED        ORGANIZATION 000C 19700017
IERACT   DC    X'63860DD0'              ACTUAL KEY                      19720000
IERSYM   DC    X'60040910'              SYMBOLIC KEY                    19740000
IERBLK   DC    X'041430A0'             BLOCKED RECORDS            25224 19760018
IERVAR   DC    X'022004C0'             VARIABLE RECORDS                 19780000
IERFOR   DC    X'CFC337E0'             FORMS OVERFLOW (APPLY OPT 2)000C 19800017
IERRST   DC    X'73860DF0'             RESTRICTED SEARCH (APPLY OPT 1)  19820000
IERWRT   DC    X'2E3534E0'             WRITE-ONLY        (APPLY OPT 5)  19840000
IERREL   DC    X'679E3D70'             RELATIVE       ORGANIZATION      19860000
IERSEQOR DC    X'0E0134E0'             SEQUENTIAL     ORGANIZATION      19880000
*                           **END MATRIX**                              19900000
         CIOPC IOT,A                                               4478 19910015
       EJECT                                                            19920000
*                                                                       19940000
*   *****************************************************************   19960000
*            DIAGNOSTIC ROUTINES                                        19980000
*   *****************************************************************   20000000
*                                                                       20020000
*                                                                       20040000
*    *****************************************************************  20060000
*        NOTE...  DIAGNOSTIC ROUTINE NOT FOUND HERE ARE AS FOLLOWS..    20080000
*    *****************************************************************  20100000
*                                                                       20120000
*        LABOUT    CONTAINS ERROR NUMBER 77.                            20140000
*  M77   USER LABELS NOT SUPPORTED IN THIS VERSION.                     20160000
*        IERCHK    CONTAINS ERROR NUMBER 90 (ERROR MATRIX).             20180000
*  M90   THE DESCRIPT. OF XXX FILE CONFLICTS ON FOLLOWING POINTS--XXX.  20200000
*        EXTNAM    CONTAINS ERROR NUMBER 96.                            20220000
*  M96   ONLY ONE CHECKPOINT FILE MAY BE SPECIFIED.                     20240000
*        DREC4     IS ERROR NUMBER 110.                                 20260000
* M110   INCORRECT DATA ITEM TYPE SPEC. FOR KEY.                        20280000
*        BUFERR    IS ERROR NUMBER 119.                                 20300000
* M119   ONLY 1 AREA SUPPRTD FOR STD SEQ & INDXD SEQ ACC. FILES.        20320000
*                                                                       20340000
*                                                                       20360000
*    *****************************************************************  20380000
*        NOTE..  DIAGNOSTIC ROUTINES FOUND HERE INCLUDE...              20400000
*    *****************************************************************  20420000
*                                                                       20440000
*  M59   SYM KEY NOT ALLOWED WITH SEQ ACCESS METH ON FILE XXX.          20460000
*  M76   INTEGER OPTION IS NOT PERMITTED.                               20480000
*  M78   INT FILE-NAME AND DESCR TBLE OVFLWED.XXX NOT PROCESSED.        20500000
*  M79   RESTRICTED SEARCH INTEGER TO LARGE ON XXX.CLAUSE DROPPED.      20520000
*  M80   MORE THAN 3 FORMS OVFLW CLAUSES.OVFLW-NAME XXX IS DROPPED.     20540000
*  M81   XXX APPEARED PREV. IN SAME CLAUSE.REMAINDER OF SAME CL DROPPED 20560000
*  M82   INTERNAL SAME TBLE OVERFLOW. ENTRIES AFTER XXX DROPPED.        20580000
*  M83   REC LGTH SPEC DISAGREES WITH CALC. MAX. ETC ETC                20600000
*  M84   BLOCK SIZE FOR XXX TOO BIG.  32K ASSUMED.                      20620000
*  M87   THE XXX FILE MUST BE DESCRIBED IN A SELECT CL. ETC..           20640000
*  M88   LABEL RECORD DATA-NAME MUST BE DEFINED IN LINK SECTION.        20660000
*  M94   XXX FILE WAS NOT DEFINED BY AB FD ENTRY.                       20680000
* M107   RECORD KEY REQ. FOR INDEX ORG. FILE XXX.                       20700000
* M108   LGTH OF SYM/REC KEY GREATER THAN 255.                          20720000
* M112   SYM AND REC KEY LGTH FOR XXX DISAGREE.                         20740000
* M115   LGTH OF ACTUAL KEY IS GREATER/LESS THAN 5.                     20760000
* M116   FILE LIMIT VALID FOR DIR ORG-SEQ  ACC OUTPUT FILES ONLY.       20780000
* M117   SYM KEY MUST BE SPECIFIED FOR XXX.                             20800000
* M118   ACTUAL KEY MUST BE SPECIFIED FOR OUTPUT FILES.                 20820000
*                                                                       20840000
* M120   RECORD/BLOCK SIZE DISAGREE                                0439 20846014
*                                                                  0439 20852014
*    *****************************************************************  20860000
*                                                                       20880000
SYMKERR  MVC   POSSEQ+1(2),TSEQ(C4)    SYM KEY GIVEN FOR REL-SEQUENTIAL 20900000
         BAL   L1,CDIAGA               PUT ERROR                        20920000
         DC    X'103B'                 ERROR 59                         20940000
         LA    0,POSSEQ                POSITION-SEQUENCE                20960000
         LA    0,TLENFN(C4)            FILE NAME                        20980000
         B     IDGEND                                                   21000000
*                                                                       21020000
*                                                                       21120000
IOFULL CLI   SRCTST,SRCIOB             IO BASE RECORD                   21140000
       BNE   GETREC                                                     21160000
       ST    C3,MULSAV                                                  21180000
       IC    C3,FNLGTI(S1)             GET LENGTH OF FILE-NAME          21200000
       EX    C3,FILMVE                 MOVE FILE-NAME TO WORK           21220000
       L     C3,MULSAV                                                  21240000
       BAL   L1,CDIAGA                 TOO MANY FILES                   21260000
       DC    X'104E'                   ERROR 78                         21280000
       LA    0,0(S2)                   POS-SEQ                          21300000
       LA    0,FILNWK                  FILE-NAME                        21320000
       B     GETREC                                                     21340000
*                                                                       21360000
RESBIG MVC   POSSEQ+1(2),TSEQ(C4)                                       21380000
       BAL   L1,CDIAGA                 RESTRICTED SEARCH GREATER/215TH  21400000
       DC    X'104F'                   ERROR 79                         21420000
       LA    0,POSSEQ                  POS-SEQ                          21440000
       LA    0,TLENFN(C4)              FILE-NAME                        21460000
         B     REST1  ALLOW DEFAULT ALREADY IN DCB AND GET NEXT CLAUSE  21480000
*                                                                       21500000
OVTOO  MVC   POSSEQ+1(2),TSEQ(C4)                                       21520000
       BAL   L1,CDIAGA                 MORE THAN 3 FORMS OVERFLOW       21540000
       DC    X'1050'                   ERROR 80                         21560000
       LA    0,POSSEQ                  POS-SEQ                          21580000
       LA    0,TLENFN(C4)              FILE-NAME                        21600000
       B     GETREC                                                     21620000
*                                                                       21640000
SAMER  IC    C3,6(S1)                  GET LENGTH OF FILE-NAME          21660000
       EX    C3,FILMOV                 MOVE FILE-NAME TO WORK           21680000
       BAL   L1,CDIAGA                 SAME RECORD                      21700000
       DC    X'1051'                   ERROR 81                         21720000
       LA    0,0(S2)                   POS-SEQ                          21740000
       LA    0,FILNWK                  FILE-NAME                        21760000
       L     C3,STBADR                                                  21780000
       B     SAMGET                                                     21800000
*                                                                       21820000
SAMTO2 ST    C3,MULSAV                                                  21840000
       IC    C3,6(S1)                  GET LENGTH OF FILE-NAME          21860000
       EX    C3,FILMOV                 MOVE FILE-NAME TO WORK           21880000
       BAL   L1,CDIAGA                 INTERNAL SAME TABLE OVERFLOW     21900000
       DC    X'1052'                   ERROR 82                         21920000
       LA    0,0(S2)                   POS-SEQ                          21940000
       LA    0,FILNWK                  FILE-NAME                        21960000
       L     C3,MULSAV                                                  21980000
       B     GETREC                                                     22000000
*                                                                       22020000
RECERR MVC   POSSEQ+1(2),TSEQ(C4)                                       22040000
       MVC   LENREC(2),FDLEN(S1)       GET RECORD LENGTH                22060000
       SR    W1,W1                                                      22080000
       LH    W1,LENREC                                                  22100000
       CVD   W1,FRCDBL                                                  22120000
       UNPK  PRTFLD(10),FRCDBL+4(5)    CONVERT LENGTH TO                22140000
       MVC   RECLEN+1(4),PRTFLD+4        PRINTABLE CHARACTERS           22160000
       BAL   L1,CDIAGA                 RECORD LENGTHS DISAGREE          22180000
       DC    X'2053'                   ERROR 83                         22200000
       LA    0,POSSEQ                  POS-SEQ                          22220000
       LA    0,RECLEN                                                   22240000
       LA    0,TLENFN(C4)              FILE-NAME                        22260000
       B     FDLCHK                                                     22280000
*                                                                       22300000
BLKBIG MVC   POSSEQ+1(2),TSEQ(C4)                                       22320000
       LH    C2,C215TH                 INSERT MAXIMUM LENGTH (32767)    22340000
       BAL   L1,CDIAGA                 BLOCK SIZE TOO BIG               22360000
       DC    X'1054'                   ERROR 84                         22380000
       LA    0,POSSEQ                  POS-SEQ                          22400000
       LA    0,TLENFN(C4)              FILE-NAME                        22420000
       B     FDBCK1                                                     22440000
*                                                                       22460000
NOTFND BAL   L1,CDIAGA                 UNDEFINED FILE-NAME              22480000
       DC    X'1057'                   ERROR 87                         22500000
       LA    0,0(S2)                   POS-SEQ                          22520000
       LA    0,FILNWK                  FILE-NAME                        22540000
         TM    TRLCHK,X'01'        SAME AREA TRAILER ERROR?             22560000
         BO    NOTFN2              YES                                  22580000
         TM    RESTCK,X'01'        RSTRCT SRCH TRAILER ERROR?           22600000
         BO    NOTFN3              YES                                  22620000
       TM    FDSWIT,X'01'              IS THIS AN FD BASE ENTRY         22640000
       BZ    GETREC                    NO                               22660000
NOTFN1 LA    S2,CMPSRC                 OUTPUT ERROR ATTRIBUTE           22680000
         XC    CMPSW(16),CMPSW         CLEAR LAST 16 BYTES OF C-T-F REC 22700000
         MVC   CMPLD(2),FDLDR(S1) MVE FD LOAD ADDR(ACTUAL CTR) TO C-T-F 22720000
       MVI   CMPDCB,X'FF'              NULIFY C-T-F RECORD              22740000
       BAL   L1,CPUTA                                                   22760000
       B     GETREC                                                     22780000
*                                                                       22800000
NOTFN2   MVI   TRLCHK,X'00'        CLEAR SAME AREA TRLR ERR SW          22820000
         B     SAMGET              GO GET NEXT                          22840000
NOTFN3   MVI   RESTCK,X'00'        CLEAR RSTRCT SRCH TRLR ERR SW        22860000
         B     REST1                                                    22880000
*                                                                       22900000
LABERR BAL   L1,CDIAGA                 LABEL RECORD ERROR IN LINK/SECT  22920000
       DC    X'0058'                   ERROR 88                         22940000
       LA    0,0(S2)                   POS-SEQ                          22960000
       B     GETREC                                                     22980000
*                                                                       23000000
NOFDBS MVC   POSSEQ+1(2),TSEQ(C4)                                       23020000
       BAL   L1,CDIAGA                 NO  FD BASE RECORD               23040000
       DC    X'105E'                   ERROR 94                         23060000
       LA    0,POSSEQ                  POS-SEQ                          23080000
       LA    0,TLENFN(C4)              FILE-NAME                        23100000
       B     ITEXT3                                                     23120000
*                                                                       23140000
NORKEY   MVC   POSSEQ+1(2),TSEQ(C4)    RECKEY REQ. FOR INDXD FILES      23160000
         BAL   L1,CDIAGA                                                23180000
         DC    X'106B'                 ERROR 107                        23200000
         LA    0,POSSEQ                POS-SEQ                          23220000
         LA    0,TLENFN(C4)                                             23240000
         B     IDRREC1   GO CHK SYM & REC KEY LGTH IF BOTH GIVEN.       23260000
*                                                                       23280000
SYMREC   BAL   L1,CDIAGA                SYM/REC KEY GRTR THAN 255       23300000
         DC    H'108'                  ERROR 108                        23320000
         LA    0,0(S2)                 POS-SEQ                          23340000
         B     GETREC                                                   23360000
*                                                                       23380000
KEYLGTER MVC   POSSEQ+1(2),TSEQ(C4)                                     23400000
         BAL   L1,CDIAGA               SYM & REC KEY NOT EQUAL          23420000
         DC    X'1070'                 ERROR 112                        23440000
         LA    0,POSSEQ                POS-SEQ                          23460000
         LA    0,TLENFN(C4)            FILE-NAME                        23480000
         B     IDGEND                                                   23500000
*                                                                       23520000
ACTERR   BAL   L1,CDIAGA               ACTUAL KEY MUST BE 5 BYTES LONG  23540000
         DC    H'115'                  ERROR 115                        23560000
         LA    0,0(S2)                 POS-SEQ                          23580000
         B     GETREC                                                   23600000
*                                                                       23620000
FILIMER  MVC   POSSEQ+1(2),TSEQ(C4)    DIRECT ORG & SEQ ACC METH REQ    23640000
         BAL   L1,CDIAGA               FOR FILE-LIMIT CLAUSE            23660000
         DC    H'116'                  ERROR-116                        23680000
         LA    0,POSSEQ                POS-SEQ                          23700000
         B     IDGREQ1                                                  23720000
*                                                                       23740000
NOSKEY MVC   POSSEQ+1(2),TSEQ(C4)                                       23760000
       BAL   L1,CDIAGA                 NO SYMBOLIC KEY SPECIFIED        23780000
         DC    X'1075'                 ERROR-117                        23800000
       LA    0,POSSEQ                  POS-SEQ                          23820000
       LA    0,TLENFN(C4)              FILE-NAME                        23840000
         TM    INDISW,X'01'            IS REC KEY CHK SW ON             23860000
         BO    IDRREC                  YES-GO CHK FOR REC KEY           23880000
         TM    INDISW,X'02'            IS ACT KEY CHK SW ON             23900000
         BO    IDRACT                  YES-GO CK FOR ACT KEY            23920000
         B     IDGEND                  GO BUILD DCB (NO RETURN)         23940000
*                                                                       23960000
NOAKEY MVC   POSSEQ+1(2),TSEQ(C4)                                       23980000
       BAL   L1,CDIAGA                 NO ACTUAL KEY SPECIFIED          24000000
         DC    H'118'                  ERROR-118                        24020000
       LA    0,POSSEQ                  POS-SEQ                          24040000
         B     IDGEND                  GO BUILD DCB                     24060000
ERREC    MVC   POSSEQ+1(2),TSEQ(C4)       RCD/BLK SIZE DIAGREE     0439 24063014
         BAL   L1,CDIAGA                                           0439 24066014
         DC    X'0078'            ERROR-120                        0439 24069014
         LA    0,POSSEQ           POS-SEQ                          0439 24072014
         B     FDBLCK1                                             0439 24075014
*                                                                       24080000
VBLKERR  MVC   POSSEQ+1(2),TSEQ(C4)                               25231 24082000
         BAL   L1,CDIAGA                                          25231 24084000
         DC    X'0079'                                            25231 24086000
         LA    0,POSSEQ                                           25231 24088000
         B     FDBLC0                                             25231 24090000
*                                                                 25231 24092000
       EJECT                                                            24100000
*                                                                       24140000
*    *****************************************************************  24160000
*                            I / O  TABLE                               24180000
*    *****************************************************************  24200000
*                                                                       24220000
IOTAB    DC    405X'0000000000'         I/O TABLE (2025 BYTES)     000C 24240017
*                                                                       24260000
*      THE FOLLOWING DISPLACEMENTS APPLY TO THE TABLE ENTRIES           24280000
*                                                                       24300000
TFIL1    EQU   0                        TYPE BYTE 1                     24320000
TFIL2    EQU   1                        TYPE BYTE 2                     24340000
TFIL3    EQU   2                        TYPE BYTE 3                     24360000
TFIL4    EQU   3                        TYPE BYTE 4                     24380000
TKEYL    EQU   4                        KEY LENGTH FROM SYMBOLIC KEY    24400000
TMODNO   EQU   5                        MODEL NUMBER                    24420000
TNOBUF   EQU   7                        NUMBER OF BUFFERS               24440000
TNORS    EQU   8                        NUMBER OF TRACKS RESTRICTED SCH 24460000
TRECL    EQU   10                       RECORD LENGTH                   24480000
TRBLCK   EQU   12                       RECORDS/BLOCK                   24500000
TDCB     EQU   14                       DCB DISPLACEMENT                24520000
TREG     EQU   17                       REGISTER ASSIGNMENT             24540000
TSEQ     EQU   19                       SEQUENCE NO FROM SRC            24560000
TLDADR   EQU   21                       LOAD ADDRESS                    24580000
TSYMKY   EQU   23                       SYMBOLIC KEY                    24600000
TACTKY   EQU   26                       ACTUAL KEY                      24620000
TTKAR    EQU   29                       TRACK AREA ADDRESS              24640000
TFLIM    EQU   32                       FILE-LIMIT TRACKS               24660000
TTALN    EQU   35                       LENGTH OF TRACK-AREA            24680000
TRECKY   EQU   37                       OFFSET OF RECORD KEY            24700000
TEXTNM   EQU   39                       EXTERNAL NAME                   24720000
TKEYR    EQU   47                       KEY LENGTH FOR RECORD KEY       24740000
TRRNLIT  EQU   48                       LITERAL NUMBER FOR RERUN   000C 24750017
TLENFN   EQU   50                       LENGTH OF FILE-NAME        000C 24760017
TFILNM   EQU   51                       FILE-NAME(MAX. 30 BYTES)   000C 24770017
*    *****************************************************************  24800000
*        TOTAL LENGTH OF EACH IOTAB ENTRY IS 81 BYTES MAXIMUM.     000C 24820017
*        25 IOTABS ALLOWED - THUS 2025 BYTES                       000C 24840017
*    *****************************************************************  24860000
*                                                                       24880000
*              END OF IOTAB ENTRIES                                     24900000
*                                                                       24920000
       EJECT                                                            24940000
*                                                                       24960000
*    *****************************************************************  24980000
*                            SAME  AREA  TABLE                          25000000
*    *****************************************************************  25020000
*                                                                       25040000
       DS    0D                                                         25060000
SAMTAB DC    38F'0'                    SAME AREA TABLE                  25080000
*                                                                       25100000
       EJECT                                                            25120000
*                                                                       25140000
*   *****************************************************************   25160000
*            INSTRUCTIONS TO BE EXECUTED                                25180000
*   *****************************************************************   25200000
*                                                                       25220000
FNMMOV  MVC  TLENFN(1,C5),FNLGTI(S1)         MOVE FILE NAME             25240000
*                                                                       25260000
FDNMOV MVC   FILNWK(1),FDFNML(S1)       MOVE FD FILE NAME               25280000
*                                                                       25300000
FILMOV MVC   FILNWK(1),6(S1)            MOVE FILE NAME FROM ASSOC REC   25320000
*                                                                       25340000
FILMOV1 MVC  FILNWK(1),7(S1)       MOVE FILE NAME FROM RERUN RECORD000C 25346017
*                                                                  000C 25352017
FILCMP CLC   FILNWK(1),TLENFN(C4)       COMPARE TWO FILE NAMES          25360000
*                                                                       25380000
EXTMOV MVC   XTNAME(0),3(S1)           MOVE EXTERNAL-NAME TO SAVE AREA  25400000
*                                                                       25420000
CPNAME CLC   XTNAME(0),3(S1)           COMPARE EXTERNAL-NAMES           25440000
*                                                                       25460000
FILMVE MVC   FILNWK(1),FNLGTI(S1)      MOVE FILE-NAME                   25480000
       EJECT                                                            25500000
IDGEND EQU   *                                                          25520000
*                                                                       25540000
*   *****************************************************************   25560000
*            THE FOLLOWING ROUTINE BUILDS THE DATA-CONTROL-BLOCK (DCB)  25580000
*            ACCORDING TO FILE ORGANIZATION.                            25600000
*                                                                       25620000
*            REG C4 - POINTS TO THE I/O TABLE ENTRIES.                  25640000
*                                                                       25660000
*            REG W1 - POINTS TO THE DCB TABLE.                          25680000
*   *****************************************************************   25700000
*                                                                       25720000
IBLD   LA    C1,VRINFO                 ADDRESS OF VAR FIELD IN LDR TEXT 25740000
       LA    S2,OUTSRC                 ADDRESS OF OUTPUT ARE A          25760000
       USING IHADCB,W1    ADVISE ASSEMBLER OF BASE OF DCBD              25780000
       TM    TFIL1(C4),MSKIND           INDEXED ADDRESSING              25800000
       BO    INDEX                      YES                             25820000
       TM    TFIL1(C4),MSKDIR           DIRECT ADDRESSING               25840000
       BO    DIRCT                                                      25860000
         TM    TFIL4(C4),MSKREL        IS ORGANIZATION RELATIVE         25880000
         BO    RLTVE                   BRANCH IF RELATIVE ORGANIZATION  25900000
       MVC   MAXLEN(4),QSAMLEN                                          25920000
       LA    W1,QSAM                    GET ADDRESS OF QSAM DCB         25940000
       TM    TFIL2(C4),MSKOVR           FORMS OVERFLOW                  25960000
       BO    IBLD2                      YES                             25980000
       MVC   DCBMACR(2),FNOVER          NO-NO FORMS OVFLW TO DCB        26000000
       B     IBLD3                                                      26020000
IBLD2  MVC   DCBMACR(2),FOVER                                           26040000
IBLD3  MVC   DCBBUFNO(1),TNOBUF(C4)     MOVE NUMBER OF BUFFERS TO DCB   26060000
IBLD6    MVC   DCBLRECL(2),TRECL(C4)   MOVE REC LENGTH TO DCB           26080000
IBLD4  MVC   DCBBLKSI(2),TRBLCK(C4)     MOVE BLOCK LENGTH TO DCB        26100000
       MVC   DCBDDNAM(8),TEXTNM(C4)     MOVE EXTERNAL ID TO DCB         26120000
       BAL   L1,IBLK     GO INIT. BLOCK & RECORD CODE TO DCB            26140000
         CLI   TKEYL(C4),0             WAS SYM KEY LENGTH GIVEN         26160000
         BNE   IBLD5                   YES-GO INIT BIT AT RECFM IN DCB  26180000
         CLI   TKEYR(C4),0             WAS REC KEY LENGTH GIVEN         26200000
         BE    ITEXT                   NO                               26220000
IBLD5    OI    DCBRECFM,1  INIT DCB WITH KELEN SPECIFIED BIT.           26240000
       B     ITEXT                                                      26260000
       EJECT                                                            26280000
*                                                                       26300000
*    *****************************************************************  26320000
*            THE FOLLOWING ROUTINE CHECKS FOR CORRECT RECORD LENGTH     26340000
*            TYPE (F,V OR U) AND BLOCKING FACTOR (BLOCKED OR UNBLOCKED) 26360000
*                                                                       26380000
*            REG C4 - POINTS TO THE I/O TABLE ENTRIES.                  26400000
*    *****************************************************************  26420000
*                                                                       26440000
IBLK   TM    TFIL2(C4),MSKFUN          FIXED LENGTH RECORDS             26460000
       BO    IBLK1                     YES                              26480000
       TM    TFIL2(C4),MSKU            UNDEFINED RECORDS                26500000
       BZ    IBLK3                     NO                               26520000
       MVI   DCBRECFM,UBLK              MOVE UNDEFINED CODE TO DCB      26540000
       BR    L1                                                         26560000
IBLK1  TM    TFIL2(C4),MSKFBL          FIXED BLOCK RECORDS              26580000
       BO    IBLK2                     YES                              26600000
       MVI   DCBRECFM,FUNBLK            NO - UNBLOCKED RECORDS          26620000
       BR    L1                                                         26640000
IBLK2  MVI   DCBRECFM,FBLK              MOVE FIXED BLOCK CODE TO DCB    26660000
       BR    L1                                                         26680000
IBLK3  TM    TFIL2(C4),MSKVBL          VARIABLE BLOCKED RECORDS         26700000
       BC    14,IBLK4                  NO                               26720000
       MVI   DCBRECFM,VBLK              MOVE VAR BLOCKED CODE TO DCB    26740000
       BR    L1                                                         26760000
IBLK4  MVI   DCBRECFM,VUNBLK            MOVE VAR UNBLOCKED CODE TO DCB  26780000
       BR    L1                                                         26800000
       EJECT                                                            26820000
*                                                                       26840000
*    *****************************************************************  26860000
*            THE FOLLOWING EQUATES ARE USED AS MASKS TO CHECK FOR       26880000
*            RECORD LENGTH TYPE (F,V OR U) AND BLOCKING FACTOR          26900000
*            (BLOCKED OR UNBLOCKED).                                    26920000
*    *****************************************************************  26940000
*                                                                       26960000
*            IF ALL TEST-UNDER-MASKS ARE ZERO - VARIABLE UNBLOCKED      26980000
*            RECORDS ARE ASSUMED.                                       27000000
*                                                                       27020000
MSKFUN EQU   X'20'                     FIXED UNBLOCKED RECORDS          27040000
MSKFBL EQU   X'22'                     FIXED BLOCKED RECORDS            27060000
MSKVBL EQU   X'0A'                     VARIABLE BLOCKED RECORDS         27080000
MSKU   EQU   X'10'                     UNDEFINED RECORDS                27100000
*                                                                       27120000
*            THE FOLLOWING EQUATES ARE MOVED INTO THE DCB DEPENDING     27140000
*            ON TM OF THE ABOVE.                                        27160000
*                                                                       27180000
FUNBLK EQU   X'80'                     FIXED UNBLOCKED RECORDS          27200000
FBLK   EQU   X'90'                     FIXED BLOCKED RECORDS            27220000
VUNBLK EQU   X'40'                     VARIABLE UNBLOCKED RECORDS       27240000
VBLK   EQU   X'50'                     VARIABLE BLOCKED RECORDS         27260000
UBLK   EQU   X'C0'                     UNDEFINED RECORDS                27280000
       EJECT                                                            27300000
*                                                                       27320000
*    *****************************************************************  27340000
*            THE FOLLOWING EQUATES ARE USED TO TEST FOR FILE            27360000
*            TYPE BITS IN IOTAB.                                        27380000
*    *****************************************************************  27400000
*                                                                       27420000
*                                                                       27440000
*    *****************************************************************  27460000
*                       *****  TFIL1 - TFIL4  MASKS  *****              27480000
*    *****************************************************************  27500000
*                                                                       27520000
MSKDASD  EQU   X'80'                   DIRECT ACCESS DEVICE             27540000
MSKUTIL  EQU   X'40'                   UTILITY DEVICE                   27560000
MSKUNIT  EQU   X'20'                   UNIT RECORD DEVICE               27580000
MSKSEQ   EQU   X'10'                   SEQUENTIAL ACCESS METHOD         27600000
MSKRAN   EQU   X'08'                   RANDOM ACCESS METHOD             27620000
MSKDIR   EQU   X'04'                   DIRECT ORGANIZATION              27640000
MSKIND   EQU   X'02'                   INDEXED ORGANIZATION             27660000
MSKBLK   EQU   X'01'                   BLKD RECS(REL ORG AT IOBAS TIME) 27680000
MSKBLKCT EQU   X'80'                   BLOCK CONTAINS NUMBER OF RECORDS 27700000
MSKUSLAB EQU   X'40'                   USER LABELS                      27720000
MSKFIXED EQU   X'20'                   FIXED LENGTH RECORDS             27740000
MSKUNDEF EQU   X'10'                   UNDEFINED LENGTH RECORDS         27760000
MSKVARBL EQU   X'08'                   VARIABLE LENGTH RECORDS          27780000
MSKFMOVR EQU   X'04'                   APPLY FORMS OVERFLOW             27800000
MSKBLKA  EQU   X'02'                   BLOCKED RECORDS                  27820000
MSKSYMK  EQU   X'01'                   SYMBOLIC KEY                     27840000
MSKRERUN EQU   X'80'                   RERUN ON EOV                     27860000
MSKSAME  EQU   X'40'                   SAME AREA                        27880000
MSKRSTCH EQU   X'20'                   APPLY RESTRICTED SEARCH          27900000
MSKACTK  EQU   X'10'                   ACTUAL KEY                       27920000
MSKLABOM EQU   X'08'                   LABELS OMITTED                   27940000
MSKRECK  EQU   X'04'                   RECORD KEY                       27960000
MSKSTLAB EQU   X'02'                   STANDARD LABELS                  27980000
MSKWTONY EQU   X'01'                   APPLY WRITE ONLY                 28000000
MSKREL   EQU   X'80'                   RELATIVE ORGANIZATION(AFTIOBAS)  28020000
MSKTRKAR EQU   X'40'                   TRACK-AREA                       28040000
MSKFILIM EQU   X'20'                   FILE-LIMIT                       28060000
MSKSEQOR EQU   X'10'                   STANDARD SEQUENTIAL ORGANIZATION 28080000
MSKDRACC EQU   X'08'                   DIR.ACC.DEV. SPEC AS UTILITY     28100000
*                                                                       28120000
*                              MISCELLANEOUS MASKS                      28140000
*                                                                       28160000
MSKORG   EQU   X'07'   DIRECT,INDEXED,RELATIVE ORGS BEFORE IOBAS RTNE   28180000
*                                                                       28200000
       EJECT                                                            28220000
*                                                                       28240000
*    *****************************************************************  28260000
*            THE FOLLOWING EQUATE IS USED TO TEST FOR FORMS OVERFLOW.   28280000
*    *****************************************************************  28300000
*                                                                       28320000
MSKOVR EQU   X'04'                     FORMS OVERFLOW                   28340000
*                                                                       28360000
*            THE FOLLOWING CONSTANTS ARE MOVED INTO THE DCB DEPENDING   28380000
*            ON TM OF THE ABOVE.                                        28400000
*                                                                       28420000
FNOVER DC    X'4848'                   NO FORMS OVERFLOW                28440000
FOVER  DC    X'484A'                   FORMS OVERFLOW                   28460000
       EJECT                                                            28480000
*                                                                       28500000
*    *****************************************************************  28520000
*            THE FOLLOWING BUILDS THE VARIABLE PORTION OF THE DCB FOR   28540000
*            INDEXED ADDRESSING.                                        28560000
*                                                                       28580000
*            REG C4 - POINTS TO THE I/O TABLE ENTRIES.                  28600000
*                                                                       28620000
*            REG W1 - POINTS TO THE DCB TABLE.                          28640000
*    *****************************************************************  28660000
*                                                                       28680000
*                                                                       28700000
INDEX    MVC   POSSEQ+1(2),TSEQ(C4)     SAVE POSITION & SEQUENCE NO.    28720000
         TM    TFIL1(C4),MSKRAN         IS ACCESS RANDOM                28740000
         BO    INDEX3                   YES                             28760000
         MVC   MAXLEN(4),QISAMLEN       NO-GET SEQUENTIAL DCB LENGTH    28780000
         LA    W1,QISAM                 GET ADDRESS OF DCB              28800000
INDEX2   MVC   DCBRKP(2),TRECKY(C4)    REC KEY DISP TO DCB              28820000
         MVC   DCBKEYLE(1),TKEYR(C4)    RECORD KEY LGTH TO DCB          28840000
         B     IBLD3     GET DDNAME,BLKSI,LRECL & RECFM & BUFNO         28860000
*                                                                       28880000
INDEX3   LA    W1,BISAM                 GET DCB ADDRESS                 28900000
         MVC   MAXLEN(4),BISAMLEN       GET DCB LENGTH                  28920000
         MVC   DCBMSWA+1(3),TTKAR(C4)   TRACK AREA ADDRESS TO DCB       28940000
         MVC   DCBSMSW(2),TTALN(C4)     TRACK AREA LGTH TO DCB          28960000
         MVI   SAVL1,X'00'              CLEAR WORK AREA                 28980000
         MVI   SAVL1+1,X'00'                                            29000000
         MVC   SAVL1+2(2),TRBLCK(C4)    COMPUTE                         29020000
         L     W2,SAVL1                  BLKSIZE PLUS                   29040000
         LA    W2,16(W2)                   16                           29060000
         ST    W2,SAVL1                      AND                        29080000
         MVC   DCBBUFL(2),SAVL1+2       PLACE IN DCB                    29100000
         B     INDEX2                   GET RKP,KELEN ETC...            29120000
*                                                                       29140000
       EJECT                                                            29160000
*                                                                       29180000
*    *****************************************************************  29200000
*            THE FOLLOWING BUILDS THE VARIABLE PORTION OF THE DCB FOR   29220000
*            DIRECT/RELATIVE ADDRESSING.                                29240000
*                                                                       29260000
*            REG C4 - POINTS TO THE I/O TABLE ENTRIES.                  29280000
*                                                                       29300000
*            REG W1 - POINTS TO THE DCB TABLE.                          29320000
*    *****************************************************************  29340000
*                                                                       29360000
DIRCT    MVC   POSSEQ+1(2),TSEQ(C4)     SAVE POSITION & SEQUENCE        29380000
         TM    TFIL1(C4),MSKRAN         IS ACCESS RANDOM                29400000
         BO    BDAMD1                   YES                             29420000
BSAMD1   LA    W1,BSAMD                 NO-ACCESS IS SEQUENTIAL         29440000
         MVC   MAXLEN(4),BSAMDLEN       INIT. DCB LENGTH                29460000
         MVC   DCBLRECL(2),TRECL(C4)    REC. LGTH TO DCB                29480000
         MVC   DFILIMT+1(3),TFLIM(C4)     MOVE FILE LIM TO CURRENT DCB  29500000
         SR    L1,L1                    CLEAR WORK                      29520000
         SR    W2,W2                      REGISTERS                     29540000
         IC    W2,TKEYL(C4)             GET KEYLEN                      29560000
         LA    W2,7(W2)                 ADD 7 FOR LATER ALLIGNMENT      29580000
         MVI   SAVL1,X'00'              CLEAR UPPER                     29600000
         MVI   SAVL1+1,X'00'              HALF OF SAVE AREA             29620000
         MVC   SAVL1+2(2),TRBLCK(C4)    ALLIGN BLOCK LENGTH ON FULL WD  29640000
         L     L1,SAVL1                 LOAD BLOCK LENGTH               29660000
         AR    W2,L1                    ADD-BLOCKLENGTH + KELEN + 7     29680000
         ST    W2,SAVL1                 STORE RESULT                    29700000
         MVC   DCBBUFL(2),SAVL1+2       PLACE RESULT BUFF LGTH IN DCB   29720000
         OI    DIRCT2+1,X'F0'           INIT. TO BYPASS OTHER BUFL MOVE 29740000
DIRCT1   MVC   DCBKEYLE(1),TKEYL(C4)    KEYLEN TO DCB                   29760000
DIRCT2   BC    0,*+10                   ON FOR BSAM DIRECT ONLY         29780000
         MVC   DCBBUFL(2),TRBLCK(C4)    BUFFER LENGTH TO DCB            29800000
         NI    DIRCT2+1,X'0F'           TURN SWITCH OFF                 29820000
         B     IBLD4                    GET DDNAME,BLKSIZE, & RECFM     29840000
*                                                                       29860000
BDAMD1   LA    W1,BDAMD                 GET DCB ADDRESS                 29880000
         MVC   MAXLEN(4),BDAMDLEN       INIT. DCB LENGTH                29900000
         CLC   TNORS(2,C4),ZEROH   WAS RESTR. SEARCH CLAUSE GIVEN       29920000
         BE    DIRCT1  NO-DEFAULT IN DCB WILL BE USED                   29940000
         MVC   DCBLIMCT+1(2),TNORS(C4)  NO. RESTR SEARCH TRKS TO DCB    29960000
         B     DIRCT1                                                   29980000
*                                                                       30000000
*                                                                       30020000
RLTVE    LA    W1,BDAMR                 GET ADDRESS OF DCB              30040000
         MVC   POSSEQ+1(2),TSEQ(C4)     GET POSITION & SEQUENCE NO.     30060000
         MVC   MAXLEN(4),BDAMRLEN       GET LGTH OF DCB                 30080000
         TM    TFIL1(C4),MSKRAN         IS ACCESS RANDOM                30100000
         BO    DIRCT2                   YES                             30120000
         MVC   MAXLEN(4),BSAMRLEN       GET SEQUENTIAL DCB LENGTH       30140000
         LA    W1,BSAMR                 GET ADD OF SEQ DCB              30160000
         MVC   DCBLRECL(2),TRECL(C4)    REC. LENGTH TO DCB              30180000
         B     DIRCT2                   GO FINISH BUILD                 30200000
       EJECT                                                            30220000
*                                                                       30240000
*    *****************************************************************  30260000
*            THIS ROUTINE BUILDS LOADER TEXT CARDS AND PUTS IT ON FILEA 30280000
*                                                                       30300000
*            REG C1 - POINTS TO VARIABLE FIELD IN LOADER TEXT CARD      30320000
*                                                                       30340000
*            REG W1 - POINTS TO DCB TABLE ENTRIES                       30360000
*                                                                       30380000
*            REG C4 - POINTS TO I/O TABLE ENTRIES                       30400000
*    *****************************************************************  30420000
*                                                                       30440000
ITEXT MVC    OUTSEQ(2),TSEQ(C4)        MOVE SEQUENCE NUMBER TO SRC      30460000
         S     W1,FULL20 REDUCE DCB PTR TO ACTUAL START DCB O/P AREA    30480000
*                                                                       30500000
*            THE FOLLOWING ROUTINE CALCULATES THE LOAD ADDRESS FOR THE  30520000
*            DCB AND INSERTS IT IN THE FIRST LOADER TEXT CARD.          30540000
*                                                                       30560000
       MVC   SDCB+1(3),TDCB(C4)        STORE LOAD ADDR FROM I/O TABLE   30580000
ITEXT1 ST    C4,MULSAV                 SAVE POINTER REGISTER            30600000
       L     C5,SDCB                   GET B. LOCATOR AND DISPLACEMENT  30620000
       SRL   C5,12                     SHIFT TO GET BASE LOCATOR        30640000
       L     C3,CCOMM                                                   30660000
       SR    C2,C2                                                      30680000
       IC    C2,UWSRG(C3)              START REGISTER OF W/S SECTION    30700000
       SR    C5,C2                     GET NUMBER OF REGISTERS FOR W/S  30720000
       M     C4,HEXCON                 MULTIPLY = OF REGS BY 4096       30740000
       L     C4,MULSAV                  RESTORE POINTER REGISTER        30760000
       MVC   LDADR(4),SDCB             SET TO GET RELATIVE ADDRESS      30780000
       NI    LDADR+2,X'0F'             ONLY DISPLACEMENT NEEDED         30800000
       LH    C2,LDADR+2                                                 30820000
       AR    C5,C2                     GET THE RELATIVE ADDRESS         30840000
       ST    C5,LDADR                  MOVE ADDRESS TO SAVE AREA        30860000
       MVC   ADDR(3),LDADR+1             AND TO LOADER TEXT             30880000
ITEXT2 MVC   BYTES(2),NUM56            MOVE MAX BYTES (56) TO LDR TEXT  30900000
       MVC   0(56,C1),0(W1)            MOVE 56 CHARS INTO LDR TEXT      30920000
       BAL   L1,CPUTA                  GO PUT LOADER TEXT               30940000
       L     C5,LDADR                  INCREMENT LOAD ADDRESS           30960000
       AH    C5,NUM56                    BY 56                          30980000
       ST    C5,LDADR                  SAVE NEW LOAD ADDRESS            31000000
       MVC   ADDR(3),LDADR+1           MOVE ADDRESS TO LDR TEXT         31020000
       AH    W1,NUM56                  INCREMENT TO NEXT FIELD IN DCB   31040000
       L     W3,MAXLEN                 GET MAX LENGTH FOR DCB           31060000
       SH    W3,NUM56                  SUBTRACT 56 FROM MAXIMUM LENGTH  31080000
       ST    W3,MAXLEN                 SAVE BYTES LEFT IN THIS DCB      31100000
       C     W3,MAXINF                 MORE THAN 56 CHARS LEFT          31120000
       BH    ITEXT2                    YES                              31140000
*                                                                       31160000
*            THE FOLLOWING ROUTINE BLANKS OUT THE VARIABLE FIELD BEFORE 31180000
*            MOVING THE LAST CHARACTERS TO LOADER TEXT AREA FOR OUTPUT. 31200000
*                                                                       31220000
       MVI   VRINFO,X'40'              MOVE IN BLANK                    31240000
       MVC   VRINFO+1(55),VRINFO       BLANK OUT VARIABLE FIELD         31260000
       BCTR  W3,0                        LOAD REMAINING CHARS           31280000
       EX    W3,REMAIN                                                  31300000
*                                                                       31320000
*            AT THIS POINT THE REMAINING 56 OR LESS CHARS ARE IN LOADER 31340000
*            TEXT AREA FOR OUTPUT.                                      31360000
*                                                                       31380000
       LA    W3,1(W3)                                                   31400000
       STC   W3,BYTES+1                MOVE NUMBER OF BYTES TO LDR TEXT 31420000
       L     W1,LDADR                  GET CURRENT LOAD ADDRESS         31440000
       AR    W3,W1                     INCREMENT TO GET NEXT ADDRESS    31460000
       ST    W3,LDADR                  SAVE NEXT AVAIL. LOAD ADDRESS    31480000
       BAL   L1,CPUTA                                                   31500000
         BAL   L1,CMPBLD               GO BUILD COMP-TIME-FILE RECORD   31560000
ITEXT5   TM    TFIL2(C4),MSKBLKA       BLOCKED RECORDS??                31580000
       BZ    ITEXT4                    NO                               31600000
       OI    CMPSW,MSKBLK              SET BLOCKED RECORDS SWITCH       31620000
ITEXT4 BAL   L1,CPUTA                                                   31640000
       B     ITEXT3                    TEMPORARY UNTIL RERUN SUPPORTED  31720000
ITEXT3   L     W1,FTBLEN               GET FIXED LENGTH OF I/O TABLE    31840000
       MVC   FILLEN+1(1),TLENFN(C4)    GET LENGTH OF FILENAME           31860000
       AH    W1,FILLEN                   AND ADD IT TO FIXED LENGTH     31880000
       AR    C4,W1                     INCREMENT TO GET NEXT I/O ENTRY  31900000
       B     IDNEXT                                                     31920000
*                                                                       31940000
REMAIN MVC   0(0,C1),0(W1)             INSTRUCTION TO MOVE LAST REMAIN- 31960000
*                                        ING CHARS TO LDR TEXT AREA     31980000
         B     IDEND                                                    32000000
*                                                                       32020000
         EJECT                                                          32040000
*                                                                       32060000
*    *****************************************************************  32080000
*            THE FOLLOWING IS OUTPUT AREA FOR TEXT CARDS                32100000
*    *****************************************************************  32120000
*                                                                       32140000
OUTSRC DC    X'D4'                     SRC CODE 1101010                 32160000
OUTSEQ DC    X'0000'                   POS-SEQ                          32180000
       DC    X'50'                     LENGTH                           32200000
LOADID DC    X'02'                     LOADER IDENTIFIER - COLUMN 1     32220000
TEXT   DC    CL3'TXT'                  TEXT CARD CODE    - COLUMN 2-4   32240000
       DC    X'40'                     BLANK             - COLUMN 5     32260000
ADDR   DS    CL3                       ADDR OF 1ST BYTE  - COLUMN 6-8   32280000
       DC    X'4040'                   BLANK             - COLUMN 9-10  32300000
BYTES  DC    X'0000'                   NUMBER OF BYTES   - COLUMN 11-12 32320000
       DC    X'4040'                   BLANK             - COLUMN 13-14 32340000
ESDID  DC    X'0001'                   ESD IDENTIFIER    - COLUMN 15-16 32360000
VRINFO DC    CL56' '                   VARIABLE FIELD    - COLUMN 17-72 32380000
       DC    CL8' '                    NOT USED          - COLUMN 73-80 32400000
       EJECT                                                            32420000
*                                                                       32440000
*    *****************************************************************  32460000
*              BUILD COMPILE TIME FILE RECORDS                          32480000
*    *****************************************************************  32500000
*                                                                       32520000
*                                                                       32540000
CMPBLD   L     S2,SDCB                 GET DCB ADDRESS & BASE LOCATOR   32560000
         A     S2,FULL20     INCR. TO POINT PAST EXPANSION BYTES        32580000
         ST    S2,REGMOVE              RESULT TO CORE FOR MV TO CTF     32600000
         LA    S2,CMPSRC               GET ADDR OF COMP-TIME-FILE ENTRY 32620000
         MVC   CMPDCB(3),REGMOVE+1     MOVE DCB ADDR TO C-T-F           32640000
         MVC   CMPLD(2),TLDADR(C4)     MOVE LOAD ADDRESS TO O/P AREA    32660000
         MVC   CMPSW(4),TFIL1(C4)      MOVE TYPE BYTES TO C-T-F         32680000
         MVC   CMPSYM(3),TSYMKY(C4)    MOVE ADR OF SYMK TO O/P AREA     32700000
         MVC   CMPACT(3),TACTKY(C4)    MOVE ADR OF ACTK TO O/P AREA     32720000
         MVC   CMPTRK(3),TTKAR(C4)     MOVE TRACK AREA ADDR TO CTF      32740000
         MVC   CMPRRLIT(2),TRRNLIT(C4) MOVE RERUN LIT-NO TO CTFT   000C 32750017
         BR    L1                                                       32760000
       EJECT                                                            32780000
*                                                                       32800000
*              COMPUTE IOAREAS RTNE HERE IF APPLICABLE                  32820000
*                                                                       32840000
         EJECT                                                          32860000
*                                                                       32880000
*    *****************************************************************  32900000
*            THE FOLLOWING ROUTINE OUTPUTS EQUATE RECORDS               32920000
*    *****************************************************************  32940000
*                                                                       32960000
IDEND  L     C3,CCOMM                                                   32980000
       SR    C5,C5                                                      33000000
       MVC   SDCB+1(3),UNEXT(C3)       GET LAST BASE/DISPLACEMENT OT    33020000
       L         C5,SDCB                 WORKING STORAGE SECTION        33040000
       SRL   C5,12                     SHIFT TO GET BASE ONLY           33060000
       STH   C5,FRCDBL                 MOVE LAST BASE LOCATOR USED      33080000
       MVC   UBLOC(2,C3),FRCDBL          IN W/S SECTION TO COMM AREA    33100000
       SR    C2,C2                                                      33120000
       IC    C2,UWSRG(C3)              GET FIRST REGISTER OF WORK/STORE 33140000
       SR    C5,C2                     GET NUMBER OF REGISTERS          33160000
       M     C4,HEXCON                 MULTIPLY # OF REGS BY 4096       33180000
       MVC   LDADR(4),SDCB                                              33200000
       NI    LDADR+2,X'0F'             GET DISPLC OF LAST REG           33220000
       LH    C2,LDADR+2                                                 33240000
       AR    C5,C2                     ADD TO GET SIZE OF WORK/STORE    33260000
       ST    C5,UWSIZ(C3)                AND MOVE TO COMMON AREA        33280000
       LA    S2,SAMRCD                  ADDRESS OF OUTPUT AREA          33300000
SAMEQU LA    W1,SAMTAB                 GET ADDRESS OF SAME TABLE        33320000
SAME1  CL    W1,STBADR                 HAVE WE REACHED END OF ENTRIES   33340000
       BE    IDOUT                                                      33360000
       CLC   0(4,W1),ZEROF                                              33380000
       BE    SAME3                                                      33400000
       L     W2,0(W1)                  GET ADDRESS OF REGISTER          33420000
       MVC   SAMRCD+6(2),0(W2)          MOVE REGISTER TO OUTPUT         33440000
SAME2  LA    W1,4(W1)                  INCREMENT TO GET NEXT ENTRY      33460000
       CLC   0(4,W1),ZEROF             IS IT ZERO                       33480000
       BE    SAME3                                                      33500000
       L     W2,0(W1)                  GET ADDRESS OF REGISTER          33520000
       MVC   SAMRCD+4(2),0(W2)          MOVE REGISTER TO OUTPUT         33540000
       BAL   L1,CPUTA                  PUT RECORD                       33560000
       B     SAME2                                                      33580000
SAME3  LA    W1,4(W1)                  INCREMENT TO GET NEXT ENTRY      33600000
       B     SAME1                                                      33620000
       EJECT                                                            33640000
*                                                                       33660000
*    *****************************************************************  33680000
*            CALL NEXT PHASE                                            33700000
*    *****************************************************************  33720000
*                                                                       33740000
IDOUT  BAL   L1,CCLOSE                 CLOSE WORKFILES                  33760000
       DC    X'00'                     FILE A OPEN                      33780000
       DC    X'00'                     FILE B CLOSE                     33800000
       DC    X'01'                     FILE C CLOSE                     33820000
       DC    X'00'                     EXPLICIT SLACK BYTE FOR IMA      33840000
*                                                                       33860000
       B     CEXIT                                                      33880000
       EJECT                                                            33900000
         CIOPC IOT,B                                                    33920000
*                                                                       33940000
*    *****************************************************************  33960000
*                            COMPILE - TIME - FILE RECORD               33980000
*    *****************************************************************  34000000
*                                                                       34020000
CMPSRC   DC    X'AA0000'                                           000C 34030017
         DC    AL1(CMPEND-CMPLD)                                   000C 34040017
CMPLD    DS    CL2                     LOAD ADDRESS                     34060000
CMPSW    DS    CL4       (TFIL1)   TYPE BYTE 1                          34080000
*                                      BIT 0 - DIRECT ACCESS DEVICE     34100000
*                                          1 - UTILITY DEVICE           34120000
*                                          2 - UNIT RECORD DEVICE       34140000
*                                          3 - SEQUENTIAL ACCESS METH.  34160000
*                                          4 - RANDOM ACCESS METHOD     34180000
*                                          5 - DIRECT ORGANIZATION      34200000
*                                          6 - INDEXED ORGANIZATION     34220000
*                                          7 - BLOCKED RECORDS          34240000
CMPSW1   EQU   CMPSW+1   (TFIL2)   TYPE BYTE 2                          34260000
*                                      BIT 0 - IF TRBLCK IS BLK FACTOR  34280000
*                                          1 - USER LABELS              34300000
*                                                      USE OPTION 1 & 2 34320000
*                                          2 - FIXED LENGTH RECORDS     34340000
*                                          3 - UNDEFINED RECORDS        34360000
*                                          4 - VARIABLE LENGTH RECORDS  34380000
*                                          5 - APPLY FORMS OVERFLOW     34400000
*                                                      APPLY OPTION 2   34420000
*                                          6 - BLOCKED RECORDS          34440000
*                                          7 - SYMBOLIC KEY             34460000
CMPSW2   EQU   CMPSW+2   (TFIL3)   TYPE BYTE 3                          34480000
*                                      BIT 0 - RERUN ON EOV             34500000
*                                          1 - SAME CLAUSE USED         34520000
*                                          2 - APPLY RESTRICTED SEARCH  34540000
*                                                      APPLY OPTION 1   34560000
*                                          3 - ACTUAL KEY               34580000
*                                          4 - LABEL RECORDS OMITTED    34600000
*                                          5 - RECORD KEY               34620000
*                                          6 - LABEL RECORDS STANDARD   34640000
*                                          7 - APPLY WRITE-ONLY(OPT 5)  34660000
CMPSW3   EQU   CMPSW+3   (TFIL4)   TYPE BYTE 4                          34680000
*                                      BIT 0 - RELATIVE ORGANIZATION    34700000
*                                          1 - TRACK-AREA               34720000
*                                          2 - FILE-LIMIT               34740000
*                                          3 - SEQUENTIAL ORGANIZATION  34760000
*                                          4 - DIR. ACC. AS UTILITY     34780000
*                                          5 -                          34800000
*                                          6 -                          34820000
*                                          7 -                          34840000
*                                                                       34860000
CMPDCB DS    CL3                       DCB ADDRESS                      34880000
CMPSYM DS    CL3                       SYMBOLIC KEY                     34900000
CMPACT DS    CL3                       ACTUAL KEY                       34920000
CMPTRK   DS    CL3                     TRACK AREA ADDRESS               34940000
CMPRRLIT DS    2C                                                  000C 34946017
CMPEND   EQU   *                                                   000C 34952017
*    *****************************************************************  34960000
*    *               END OF COMPILE - TIME - FILE                    *  34980000
*    *****************************************************************  35000000
*                                                                       35020000
       EJECT                                                            35040000
*                                                                       35060000
*    *****************************************************************  35080000
*            DATA-CONTROL-BLOCK (DCB) BUILD AREA                        35100000
*    *****************************************************************  35120000
*                                                                       35140000
*                                                                       35160000
STQSAM   DC    4F'0'                   STANDARD BYTE                    35180000
         DC    F'1'                      AHEAD OF DCB                   35200000
*                                                                       35220000
QSAM   DCB     DSORG=PS,               PHYSICAL SEQUEN ORGANIZATION    C35240000
               MACRF=(GL,PL),          GET-LOCATE-MODE PUT-LOCATE-MODE C35260000
               BFTEK=S,                SIMPLE BUFFERING                C35280000
               BFALN=D                 DOUBLE WORD BOUNDRY FOR BUFFER   35300000
*                                                                       35320000
ENDQSAM  EQU   *       REQUIRED AFTER  QSAM  DCB FOR LENGTH CALC.       35340000
         EJECT                                                          35360000
*                                                                       35380000
STBSAMD  DC    4F'0'                   STANDARD BYTE                    35400000
         DC    F'1'                      AHEAD OF DCB                   35420000
*                                                                       35440000
*                                                                       35460000
BSAMD    DCB   DSORG=PS,               PHYSICAL SEQ. ORGANIZATION      C35480000
               MACRF=(R),              READ MACRO INSTRUCTION          C35500000
               DEVD=DA,KEYLEN=1,       DIRECT ACCESS,KEY LENGTH        C35520000
               OPTCD=W                 WRITE VALIDITY CHK OPTION        35540000
*                                                                       35560000
*                                                                       35580000
         DC    4X'00'        REQUIRED  AT END OF BSAMD DCB     1 OF 6   35600000
         DC    X'80'                                           2 OF 6   35620000
         DC    19X'00'                                         3 OF 6   35640000
DFILIMT  DC    F'0'                    FILE LIMIT              4 OF 6   35660000
         DC    2F'0'                                           5 OF 6   35680000
         DC    F'0'                                        6 OF 6  9112 35700000
*                                                                       35720000
ENDBSAMD EQU   *       REQUIRED AFTER  BSAMD DCB FOR LENGTH CALC.       35740000
         EJECT                                                          35760000
*                                                                       35780000
STBSAMR  DC    4F'0'                   STANDARD BYTE                    35800000
         DC    F'1'                      AHEAD OF DCB                   35820000
*                                                                       35840000
BSAMR    DCB   DSORG=PS,               PHYSICAL SEQ. ORG.              C35860000
               MACRF=(R),              READ MACRO INSTR.               C35880000
               RECFM=F,                FIXED LENGTH RECORDS            C35900000
               DEVD=DA,KEYLEN=0,       DIRECT ACCESS,KEYLEN OF ZERO    C35920000
               OPTCD=W                 WRITE VALIDITY CHECK OPTION      35940000
*                                                                       35960000
         DC    4X'00'        REQUIRED AFTER BSAMR DCB          1 OF 3   35980000
         DC    X'80'                                           2 OF 3   36000000
         DC    15X'00'                                         3 OF 3   36020000
*                                                                       36040000
ENDBSAMR EQU   *       REQUIRED AFTER  BSAMR DCB FOR LENGTH CALC.       36060000
         EJECT                                                          36080000
*                                                                       36100000
STBDAMD  DC    4F'0'                   STANDARD BYTE                    36120000
         DC    F'1'                      AHEAD OF DCB                   36140000
         DC    4F'0'                   PLUG UNUSED BYTES                36160000
*                                                                       36180000
*                                                                       36200000
BDAMD    DCB   DSORG=DA,               DIRECT ORGANIZATION             C36220000
               MACRF=(RKC),            READ MACRO,SEARCH ARG IS KEY    C36240000
               OPTCD=WE,   WRITE VAL CHK,EXTENDED SEARCH               C36260000
               LIMCT=X'007FFF'         MAX # OF BLKS OR TRKS TO SEARCH  36280000
*                                                                       36300000
*                                                                       36320000
*                                                                       36340000
*                                                                       36360000
*                                                                       36380000
*                                                                       36400000
         DC    32X'00'       REQUIRED AFTER BDAMD DCB          1 OF 2   36420000
         DC    F'0'                                            2 OF 2   36440000
*                                                                       36460000
ENDBDAMD EQU   *       REQUIRED AFTER  BDAMD DCB FOR LENGTH CALC.       36480000
         EJECT                                                          36500000
*                                                                       36520000
STBDAMR  DC    4F'0'                   STANDARD BYTE                    36540000
         DC    F'1'                      AHEAD OF DCB                   36560000
         DC    4F'0'                   PLUG UNUSED BYTES                36580000
*                                                                       36600000
*                                                                       36620000
BDAMR    DCB   DSORG=DA,               DIRECT ORGANIZATION             C36640000
               MACRF=(RIC),            READ MACRO,SEARCH ARG. IS BLK IDC36660000
               OPTCD=WR,   WRITE VAL CHK,REL BLK ADDRESS               C36680000
               RECFM=F                 FIXED LENGTH RECORDS             36700000
*                                                                       36720000
*                                                                       36740000
*                                                                       36760000
*                                                                       36780000
*                                                                       36800000
*                                                                       36820000
         DC    4X'00'        REQUIRED AFTER BDAMR DCB          1 OF 4   36840000
         DC    X'01'                                           2 OF 4   36860000
         DC    27X'00'                                         3 OF 4   36880000
         DC    F'0'                                            4 OF 4   36900000
*                                                                       36920000
ENDBDAMR EQU   *       REQUIRED AFTER  BDAMR DCB FOR LENGTH CALC.       36940000
         EJECT                                                          36960000
*                                                                       36980000
STQISAM  DC    4F'0'                   STANDARD BYTE                    37000000
         DC    F'1'                      AHEAD OF DCB                   37020000
         DC    4F'0'                   PLUG UNUSED BYTES                37040000
*                                                                       37060000
*                                                                       37080000
QISAM    DCB   DSORG=IS,               INDEXED SEQUENTIAL ORG.         C37100000
               MACRF=(PL),             LOCATE MODE,PUT MACRO INSTR     C37120000
               OPTCD=WLI,  WRT.VAL.CHK.,DELETE OPTN,OVFLOW AREA        C37140000
               BFALN=D                 DOUBLE WD BOUNDARY BUFFERS       37160000
*                                                                       37180000
*                                                                       37200000
         DC    F'0'          REQUIRED AFTER QISAM DCB          1 OF 1   37220000
*                                                                       37240000
ENDQISAM EQU   *       REQUIRED AFTER  QISAM DCB FOR LENGTH CALC.       37260000
         EJECT                                                          37280000
*                                                                       37300000
STBISAM  DC    4F'0'                   STANDARD BYTE                    37320000
         DC    F'1'                      AHEAD OF DCB                   37340000
         DC    4F'0'                   PLUG UNUSED BYTES                37360000
*                                                                       37380000
*                                                                       37400000
BISAM    DCB   DSORG=IS,               INDEXED SEQUENTIAL ORG.         C37420000
               MACRF=(R)               READ MACRO INSTR.                37440000
*                                                                       37460000
*                                                                       37480000
         DC    4X'00'        REQUIRED AFTER BISAM DCB          1 OF 3   37500000
         DC    X'02'                                           2 OF 3   37520000
         DC    31X'00'                                         3 OF 3   37540000
*                                                                       37560000
ENDBISAM EQU   *       REQUIRED AFTER  BISAM DCB FOR LENGTH CALC.       37580000
*                                                                       37600000
       EJECT                                                            37620000
*                                                                       37860000
*    *****************************************************************  37880000
*                            SAME  EQUATE  RECORD                       37900000
*    *****************************************************************  37920000
*                                                                       37940000
SAMRCD DC    X'22000004'                SRC FOR SAME EQUATES            37960000
       DS    CL2                       EQUATE BASE LOCATOR              37980000
       DS    CL2                       BASE LOCATOR OR CONSTANT REG     38000000
       EJECT                                                            38020000
*                                                                       38040000
*    *****************************************************************  38060000
*                            LABEL  EQUATE  RECORD                      38080000
*    *****************************************************************  38100000
*                                                                       38120000
SAMLAB DC    X'24000005'               SRC FOR LABEL EQUATES            38140000
       DS    CL2                        BASE LOCATOR                    38160000
       DS    CL3                        BASE AND DISPLACEMENT           38180000
*                                                                       38200000
LKCHCK EQU   X'50'                     LINKAGE SECTION MAJOR CODE MASK  38220000
MMMASK EQU   X'F0'                     MAJOR-MINOR MASK                 38240000
       EJECT                                                            38260000
*                                                                  000C 38261017
*    **************************************************************000C 38262017
*                RERUN   LITERAL   RECORD                          000C 38263017
*    **************************************************************000C 38264017
*                                                                  000C 38265017
RRNLIT   DC    X'CA00001949FFFF001200001010'                       000C 38266017
RRNLIT1  DC    XL16'1'             FOR 8-BYTE EXT-NAME, THEN       000C 38267017
RRNLIT2  EQU   RRNLIT1+9           FOR RERUN INTEGER CONSTANT      000C 38268017
RRNLIT3  EQU   RRNLIT1+13          FOR RERUN RECORDS COUNTER       000C 38269017
*  COUNT OF ONE WILL FORCE CHECKPOINT BEFORE FIRST I/O OPERATION   000C 38270017
         EJECT                                                     000C 38271017
*                                                                       38280000
*    *****************************************************************  38300000
*            CONSTANTS AND STORAGE AREAS                                38320000
*    *****************************************************************  38340000
*                                                                       38360000
FRCDBL DS    D                         DOUBLE WORD CONVERSION AREA      38380000
HEXCON DC    F'4096'                   USED TO DETERMINE RELATIVE       38400000
*                                        ADDRESS FOR DCB                38420000
MULSAV DS    F                          STORAGE ARE A FOR POINT REG     38440000
MAXINF DC    F'56'                     MAX. BYTES TEXT CARD WILL HOLD   38460000
LDADR  DC    F'0'                      RELATIVE LOAD ADDRESS FOR DCB    38480000
MAXLEN DC    F'0'                      LENGTH OF DCB AREA               38500000
QSAMLEN  DC    A(ENDQSAM-STQSAM)       SEQ. ORG., SEQ. ACCESS           38520000
BSAMDLEN DC    A(ENDBSAMD-STBSAMD)     DIRECT ORG.,SEQ. ACCESS          38540000
BSAMRLEN DC    A(ENDBSAMR-STBSAMR)     RELATIVE ORG., SEQ. ACCESS       38560000
BDAMDLEN DC    A(ENDBDAMD-STBDAMD)     DIRECT ORG., RANDOM ACCESS       38580000
BDAMRLEN DC    A(ENDBDAMR-STBDAMR)     RELATIVE ORG., RANDOM ACCESS     38600000
QISAMLEN DC    A(ENDQISAM-STQISAM)     INDEXED ORG., SEQ. ACCESS        38620000
BISAMLEN DC    A(ENDBISAM-STBISAM)     INDEXED ORG., RANDOM ACCESS      38640000
NUM25  DC    F'25'                     MAXIMUN NUMBER OF FILES          38660000
REGMOVE  DC    F'0'                    WORK AREA FOR REGISTER MOVES     38680000
SDCB   DC    F'0'                      STORE AREA FOR LOAD ADDR         38700000
DCBCPT DC    F'0'                      DCB OF CHECKPOINT                38720000
DCBUP  DC    F'0'                      UPDATED DCB ADDRESS              38760000
DCBSAV DC    F'0'                      STORAGE AREA FOR DCB ADDRESS     38780000
ZEROF  DC    F'0'                      FULL WORD OF ZEROS               38800000
BASESV DC    F'0'                      STORE AREA FOR BASE LOCATOR      38820000
TEMBUK DC    A(IOTAB)                            TEMPORARY BUCKET       38840000
CBLSAV DS    F                          SAVE BUCKET FOR LINK            38860000
STBADR DC    A(SAMTAB)                 ADDR OF SAME AREA TABLE          38880000
IOEND  DC    A(IOTAB)                  ADDR OF START OF IOTAB           38900000
TEND     DC    A(IOTAB+1975)            END OF IO TABLE                 38920000
SAMEND DC    A(SAMTAB+152)             END OF SAME AREA TABLE           38940000
FOUR   DC    F'4'                                                       38960000
FTBLEN   DC    A(TFILNM-TFIL1)         FIXED LGTH OF IOTAB ENTRY   000C 38980017
SAVL1  DS    F                          LINK SAVE                       39000000
POSSEQ DC    F'0'                      POSITION AND SEQUENCE BUCKET     39020000
FULL20   DC    F'20'  STD 5 WORDS BEFORE EACH DCB (CONSTANT)            39040000
BLKFACT  DC    F'0'      BLKSIZE TO BLOCKING FACTOR WORK AREA           39060000
RECSIZ   DC    F'0'      RECORD SIZE WORKAREA                           39080000
NUM56  DC    H'56'                     MAX VAR FIELD IN LDR TEXT CARD   39100000
FILECT DC    H'0'                      FILE COUNT                       39120000
FILLEN DC    H'0'                      LENGTH OF FILE NAME              39140000
LENREC DC    H'0'                      RECORD LENGTH SAVE AREA          39160000
ZEROH  DC    H'0'                      HALF WORD OF ZEROS               39180000
BASLOC DC    H'0'                      BASE LOCATOR STORAGE AREA        39200000
REGCT  DC    H'16'                     BUCKET FOR REGISTER              39220000
SAMPT  DC    H'0'                       POINTER TO SAME TABLE           39240000
OVFCT  DC    H'0'                       OVERFLOW RECORD COUNTER         39260000
WKPT   DS    H                         WORK AREA                        39280000
HWORD    DC    H'0'                    SAVE AREA FOR KEY LENGTH         39300000
C255     DC    H'255'                   MAX. LGTH OF SYM/REC KEY        39320000
C005     DC    H'5'  REQ NO. BYTES ALLOCATED IN PICT. FOR ACT KEY       39340000
ONEH   DC    H'1'                      HALF WORD OF 1                   39360000
C24    DC    H'24'                                                      39380000
THREEH DC    H'3'                                                       39400000
H2400    DC    H'2400'                 TAPE DEVICE NUMB. IN BINARY      39420000
C215TH DC    H'32767'                  2 TO THE 15TH POWER              39440000
MSKAND   DC    X'0FFF'                 MASK TO CLEAR BASE LOCATOR       39460000
IERWKL DC    X'0502'                   LENGTH AND TABLE INDEX           39480000
IERWK  DC    X'00000000'               ERROR VECTOR                     39500000
RLCODE DC    X'303000'                 DIRECT/RELATIVE CODE             39520000
DNORS  DC    X'000000'                 NO. TRACKS FOR RESTRICTED SEARCH 39540000
MMCODE DC    X'00'                     STORAGE AREA MAJOR-MINOR CODE    39560000
XTNAME DC    CL9' '                    EXTERNAL-NAME AND LENGTH         39580000
NAMESW DC    X'00'                     FIRST EXTERNAL-NAME SWITCH       39600000
PRTFLD DS    CL10                      CONVERSION AREA                  39620000
SVBSDS DS    CL3                        SAVE AREA FOR BASE/DIS          39640000
SRCTST DS    C                          TEST AREA FOR SRC               39660000
NUM255 DC    X'FF'                     MAXIMUM NUMBER OF BASES (255)    39680000
TRLCHK   DC    X'00'               SAME AREA TRLR ERROR SW              39720000
RESTCK   DC    X'00'               RESTR SEARCH TRLR ERR SWITCH         39740000
FDSWIT DC    X'00'                     FD ERROR SWITCH                  39920000
INDISW   DC    X'00'   CHK SW WILL BE 01 FOR RECKEY,02 FOR ACTKEY,00    39940000
*                      FOR SYM KEY ONLY                                 39960000
RECLEN DC    X'04'                     AREA RESERVED FOR RECORD         39980000
       DS    CL4                         LENGTH TRAILER                 40000000
FILNWK DS    CL256                     WORK AREA FOR FILE-NAME          40020000
         CIOPL IOT                                                      40040000
       EJECT                                                            40060000
       DCBD    DSORG=(PS,IS,DA)        PHYSICAL,INDEXED AND DIRECT      40080000
       END   CETIOT                                                     40100000
