*   IBM SYSTEM/360 OPERATING SYSTEM                                   * 00020000
*   COBOL(E) 360S-CO-503                                              * 00040000
*   MODULE IEPPD100                                                   * 00060000
 TITLE 'IJSPD100 - DIAGNOSTIC PHASE 1 OF 2'                             00080000
*STATUS:  CHANGE LEVEL 10                                             * 00100000
 TITLE 'IEPPD100 - DIAGNOSTIC PHASE 1 OF 2'                             00120000
*STATUS: CHANGE LEVEL 0                                               * 00140000
*FUNCTION/OPERATION:                                                  * 00160000
*   ONE OR MORE SORT TABLE/SAVE TABLE PAIRS ARE BUILT FROM INFORMATION* 00180000
*   IN THE DIAGNOSTIC RECORDS AND THE MESSAGE TABLES.                 * 00200000
*ENTRY POINTS:                                                        * 00220000
*        CETPD1    CONTROL IS TRANSFERRED TO THIS ENTRY POINT WHEN THE* 00240000
*                  PHASE IS CALLED.                                   * 00260000
*                  CALLING SEQUENCE:                                  * 00280000
*                            LA  CR15,CPHSAD                          * 00300000
*                            SVC 7                                    * 00320000
*                    CPHSAD  DC  A(CPHNM)                             * 00340000
*                            DC  A(0)                                 * 00360000
*                    CPHNM   DC  CL8'IEPPD100'                        * 00380000
*        OTABLE    LOAD POINT FOR MESSAGE TABLE SET PHASES PT1/7.     * 00400000
*INPUT:                                                               * 00420000
*   INPUT IS FROM FILEA.                                              * 00440000
*   BAL L1,CGETA  CAUSES S1(REGISTER 3) TO POINT TO NEXT INPUT RECORD.* 00460000
*   THE FOLLOWING TYPES OF RECORDS ARE HANDLED:                       * 00480000
*        1.DIAGNOSTIC RECORD:                                         * 00500000
*            4-BYTE SRC                                               * 00520000
*            2-BYTE MESSAGE NO.(BINARY)                               * 00540000
*        2.DIAGNOSTIC TRAILER RECORD(WORD):                           * 00560000
*            4-BYTE SRC                                               * 00580000
*            VARIABLE-LENGTH WORD                                     * 00600000
*        3.DIAGNOSTIC TRAILER RECORD(ERROR VECTOR):                   * 00620000
*            4-BYTE SRC                                               * 00640000
*            1-BYTE TYPE CODE                                         * 00660000
*            4-BYTE ERROR VECTOR                                      * 00680000
*OUTPUT:                                                              * 00700000
*   OUTPUT IS ON FILEB.                                               * 00720000
*   EACH OUTPUT RECORD IS A SORT TABLE OR A SAVE TABLE.               * 00740000
*   BAL L1,CWRITE  , WITH P1(REGISTER 9) POINTING TO THE FIRST BYTE OF* 00760000
*   THE PREFIX, CAUSES A RECORD TO BE WRITTEN.                        * 00780000
*   THE FORMAT OF AN OUTPUT RECORD IS:                                * 00800000
*            4-BYTE PREFIX:                                           * 00820000
*                2-BYTE LENGTH OF TABLE                               * 00840000
*                2-BYTE NOT USED                                      * 00860000
*            VARIABLE-LENGTH TABLE                                    * 00880000
*EXTERNAL ROUTINES: N/A                                               * 00900000
*EXITS-NORMAL:                                                        * 00920000
*   CEXIT     WHEN END-OF-FILE IS REACHED ON FILEA THE LAST SORT TABLE* 00940000
*             /SAVE TABLE PAIR IS WRITTEN AND THE PHASE BRANCHES TO   * 00960000
*             CEXIT, WHICH CALLS THE NEXT PHASE.                      * 00980000
*EXITS-ERROR: N/A                                                     * 01000000
*TABLE/WORK AREAS:                                                    * 01020000
*   BSRTTB    WORK AREA TO BUILD SORT TABLE.                          * 01040000
*             UP TO 40 8-BYTE ENTRIES CAN BE WRITTEN ON A SORT TABLE. * 01060000
*             THE FORMAT OF A SORT TABLE ENTRY IS:                    * 01080000
*                  2-BYTE SEQUENCE NO.(BINARY)                        * 01100000
*                  1-BYTE POSITION(BINARY)                            * 01120000
*                  2-BYTE POINTER TO ENTRY IN SAVE TABLE              * 01140000
*                  3-BYTE MESSAGE NO.(EDITED)                         * 01160000
*             X'FF' IN THE FIRST BYTE OF AN ENTRY INDICATES END-OF-   * 01180000
*             TABLE.                                                  * 01200000
*   BSAVTB    WORK AREA TO BUILD SAVE TABLE.                          * 01220000
*             VARIABLE-LENGTH ENTRIES UP TO A TOTAL OF 2500 BYTES.    * 01240000
*             THE FORMAT OF A SAVE TABLE ENTRY IS:                    * 01260000
*                  VARIABLE-LENGTH MESSAGE(FROM MESSAGE TABLE),       * 01280000
*                         CONTAINING LENGTH, SEVERITY LEVEL CODE, TEXT* 01300000
*                         AND CONTROL CHARACTERS,ENDING IN AN EOM C.C.* 01320000
*                  VARIABLE-LENGTH ONE OR MORE TRAILERS(OPTIONAL)     * 01340000
*                  1-BYTE END-OF-TRAILERS INDICATION X'FF'            * 01360000
*   BREFTB    REFERENCE TABLE.                                        * 01380000
*             THIS TABLE IS USED TO DETERMINE THE MESSAGE TABLE SET   * 01400000
*             PHASE(PT1/7) WHERE A GIVEN MESSAGE NO. IS CONTAINED.    * 01420000
*             THE REFERENCE TABLE IS FULL-WORD ALIGNED AND ITS LENGTH * 01440000
*             IS 28 BYTES, DIVIDED INTO 7 4-BYTE ENTRIES.             * 01460000
*             THE FORMAT OF A REFERENCE TABLE ENTRY IS:               * 01480000
*                  2-BYTE MAXIMUM MESSAGE NO. IN THE MESSAGE TABLE SET* 01500000
*                         PHASE PTN                                   * 01520000
*                  1-BYTE N                                           * 01540000
*                  1-BYTE NOT USED                                    * 01560000
*ATTRIBUTES: N/A                                                      * 01580000
*NOTES:                                                               * 01600000
*   FOR EACH DIAGNOSTIC RECORD A SORT TABLE ENTRY AND A SAVE TABLE    * 01620000
*   ENTRY ARE BUILT.                                                  * 01640000
*   THE FOLLOWING PROCEDURE IS PERFORMED TO OBTAIN A MESSAGE(FOR A    * 01660000
*   SAVE TABLE ENTRY):                                                * 01680000
*        1.FROM THE MESSAGE NO.(DIAGNOSTIC RECORD) AND THE REFERENCE  * 01700000
*          TABLE DETERMINE THE MESSAGE TABLE SET PHASE(PTN) WHERE THE * 01720000
*          MESSAGE IS CONTAINED.                                      * 01740000
*          A MESSAGE TABLE SET CONSISTS OF ONE OR MORE MESSAGE TABLES.* 01760000
*        2.IF PTN IS NOT IN CORE, LOAD PTN AT THE LOCATION OTABLE BY  * 01780000
*          MEANS OF BAL L1,CLOAD  FOLLOWED BY  DC C'PTN'  .           * 01800000
*          ONLY ONE MESSAGE TABLE SET PHASE CAN BE IN CORE AT A TIME  * 01820000
*        3.ADDRESS PTN BY MEANS OF BASE REGISTER S2(REGISTER 4).      * 01840000
*   IF THERE ARE NO DIAGNOSTIC RECORDS ON FILEA, NO SORT TABLE/SAVE   * 01860000
*   TABLE PAIRS ARE WRITTEN ON FILEB.                                 * 01880000
*   IF AN OVERFLOW OCCURS IN EITHER THE SORT TABLE OR THE SAVE TABLE, * 01900000
*   BOTH TABLES ARE WRITTEN ON FILEB AND A NEW PAIR IS STARTED.       * 01920000
*   THE NUMBER OF PAIRS IS PASSED TO PD2 AS A HALF-WORD IN THE FIRST  * 01940000
*   2 BYTES OF THE COMPILER COMMON AREA.                              * 01960000
*                                                                       01980000
*                                                                       02000000
         CIOP  PHASE=PD1,ENTRY=MAIN1,EOFWK=ADDRA                        02020000
         USING OTABLE,S2                                                02040000
*            PDIAG MAIN ROUTINE                                         02060000
*                                                                       02080000
MAIN1    B     BUILD1              GO TO BUILD ROUTINE                  02100000
MAIN2    CLI   BSRTTB,X'FF'                                             02120000
         BE    MAIN5                                                    02140000
         LA    P1,BSORT                                                 02160000
         BAL   L1,CWRITE                                                02180000
         LA    P1,BSAVE                                                 02200000
         BAL   L1,CWRITE                                                02220000
         LH    W1,MCOUNT                                                02240000
         LA    W1,1(W1)                                                 02260000
         STH   W1,MCOUNT                                                02280000
MAIN4    TM    MSWTCH,X'80'                                             02300000
         BC    1,MAIN5             IF EOD SWITCH IS ON, GO TO MAIN5     02320000
         TM    MSWTCH,X'40'                                             02340000
         BC    1,M03               IF IM SWITCH IS ON, GO TO M03        02360000
         SR    W1,W1               INITIALIZE SORT TABLE POINTER        02380000
         SR    W2,W2               INITIALIZE SAVE TABLE POINTER        02400000
         B     BUILD2              GO TO BUILD ROUTINE                  02420000
M03      NI    MSWTCH,X'BF'        SET IM SWITCH OFF                    02440000
         MVC   BSRTTB(8),BSAVST    INCOMPLETE MESS RECORD TO SORT TABLE 02460000
         LA    W1,8                INITIALIZE SORT TABLE POINTER        02480000
         LA    C5,BSAVTB           ADDR OF SAVE TABLE TO C5             02500000
         LR    W3,C5               ADDR OF SAVE TABLE TO W3             02520000
         AH    W3,BSAVMA           ADDR OF INCOMPL. MESS TO W3          02540000
         LH    W2,BSAVML           LENGTH OF INCOMPL. MESS TO W2        02560000
         BCTR  W2,0                SUBTRACT ONE FROM W2                 02580000
         EX    W2,B10              EX MOVE INCOMPL. MESS TO SAVE TABLE  02600000
         LA    W2,1(W2)            INITIALIZE SAVE TABLE POINTER        02620000
         B     BUILD3              GO TO BUILD3                         02640000
MAIN5    L     W1,CCOMM                                                 02660000
         MVC   0(2,W1),MCOUNT                                           02680000
         BAL   L1,CCLOSE                                                02700000
         DC    X'010400'                                                02720000
         B     CEXIT                                                    02740000
*WORK FIELDS                                                            02760000
MSWTCH   DC    X'00'               'LOGICAL SWITCHES BYTE               02780000
*                                     BIT 0 - EOD SWITCH - END OF DATA  02800000
*                                     BIT 1 - IM  SWITCH - INCOMPL MESS 02820000
*                                     BITS 2/7 - NOT USED               02840000
MCOUNT   DC    H'0'                                                     02860000
       EJECT                                                            02880000
*                                                                       02900000
*            BUILD SORT AND SAVE TABLES ROUTINE                         02920000
*                                                                       02940000
*THIS ROUTINE READS FILEA,SELECTS THE DIAGNOSTIC RECORDS AND THEIR      02960000
*ASSOCIATE TRAILER RECORDS,FINDS FOR EACH DIAGNOSTIC RECORD ITS CO-     02980000
*RRESPONDENT MESSAGE IN THE MESSAGE TABLE,BUILDS THE SAVE TABLE WI-     03000000
*TH THE MESSAGES AND TRAILERS,AND THE SORT TABLE WITH THE RELATIVE      03020000
*ADDRESSES OF MESSAGES IN SAVE TABLE,UNTIL THE FILEA ENDS OR THE        03040000
*SORT TABLE IS FULL OR THE SAVE TABLE IS FULL.                          03060000
*                                                                       03080000
*MAIN ROUTINE                                                           03100000
BUILD1   BAL   L1,COPEN                                                 03120000
         DC    X'100000'                                                03140000
         L     S2,=A(OTABLE)                                            03160000
         SR    W1,W1               INITIALIZE SORT TABLE POINTER        03180000
         SR    W2,W2               INITIALIZE SAVE TABLE POINTER        03200000
B01      BAL   L1,CGETA            GET REC FROM FILEA                   03220000
BUILD2   MVC   BWRKF1,0(S1)        ENTRY 2 - SRC TO BWRKF1              03240000
         L     W3,BWRKF1                                                03260000
         SRL   W3,29                                                    03280000
B02      CH    W3,BK1                                                   03300000
         BNE   B01                 IF REC IS NOT DIAG GO TO B01         03320000
         L     W3,BWRKF1           SRC TO W3                            03340000
         SRL   W3,8                                                     03360000
         STH   W3,BWRKF1           LINE NO. TO BWRKF1                   03380000
         NI    BWRKF1,X'0F'                                             03400000
         SRL   W3,12                                                    03420000
         STC   W3,BWRKF1+2         ELEMENT NO. TO BWRKF1                03440000
         NI    BWRKF1+2,X'1F'                                           03460000
         LA    C5,BSRTTB(W1)                                            03480000
         MVC   0(3,C5),BWRKF1      LINE NO./ELEMENT NO. TO SORT TABLE   03500000
         MVC   BSAVST(3),BWRKF1    SAVE LINE NO./ELEMENT NO.            03520000
         STH   W2,BWRKF1                                                03540000
         LA    C5,BSRTTB+3(W1)                                          03560000
         MVC   0(2,C5),BWRKF1      SAVE TABLE ADDR TO SORT TABLE        03580000
         CLI   3(S1),X'02'         IF DIAG REC LENGTH IS 2,             03600000
         BE    B02A                GO TO B02A                           03620000
         MVC   BWRKF1(2),BSAVST+3  ZERO TO BWRKF1                       03640000
         B     B02B                GO TO B02B                           03660000
B02A     MVC   BWRKF1(2),4(S1)     ABS MESG NO. TO BWRKF1               03680000
B02B     LH    C4,BWRKF1           ABS MESG NO. TO C4                   03700000
         CVD   C4,BWRKF3           CONVERT ABS MESG NO. TO DECIMAL      03720000
         MVC   BWRKF4,BPAT         PATTERN TO BWRKF4                    03740000
         ED    BWRKF4,BWRKF3+6     EDIT ABS MESG NO.                    03760000
         MVC   BMXFLD,BWRKF4+1     ABS MESG NO. (EDITED) TO BMXFLD      03780000
         LA    C5,BSRTTB+5(W1)                                          03800000
         MVC   0(3,C5),BMXFLD      ABS MESG NO.(EDITED) TO SORT TABLE   03820000
         MVC   BSAVST+5(3),BMXFLD  SAVE ABS MESG NO.(EDITED)            03840000
         LA    W1,8(W1)            UPDATE SORT TABLE POINTER            03860000
         CLI   3(S1),X'02'         IF DIAG REC LENGTH IS NOT 2,         03880000
         BNE   B04F                GO TO B04F                           03900000
         CH    C4,BK5              IF ABS MESG NO. LOWER THAN MINIMUN,  03920000
         BL    B04E                GO TO B04E                           03940000
         CH    C4,BK6              IF ABS MESG NO. HIGHER THAN MAXIMUM, 03960000
         BH    B04E                GO TO B04E                           03980000
         LA    W3,BREFTB           INITIALIZE REF TABLE POINTER         04000000
B03      CH    C4,0(W3)            COMP ABS MESG NO. TO TABLE SET LIMIT 04020000
         BNH   B03A                IF EQUAL OR LOWER, GO TO B03A        04040000
         LA    W3,4(W3)            INCREMENT REF TABLE POINTER          04060000
         B     B03                 GO TO B03                            04080000
B03A     CLC   BSET,0(W3)          COMP PRESENT TABLE SET INDICATOR TO  04100000
         BE    B04                 REQUIRED TABLE SET.IF EQUAL, GO TO   04120000
         MVC   BSET,0(W3)          B04.IF NOT EQUAL, MOVE RTS TO PTSI   04140000
         MVC   B03B+2(1),2(W3)                                          04160000
         BAL   L1,CLOAD                                                 04180000
B03B     DC    C'PT0'                                                   04200000
B04      LA    W3,6                INITIALIZE TABLE SET INDEX POINTER   04220000
B04A     CH    C4,BTABLE(W3)       COMP ABS MESG NO. TO RANGE LIMIT     04240000
         BNH   B04B                IF EQUAL OR LOWER, GO TO B04B        04260000
         LA    W3,6(W3)            INCREMENT TABLE SET INDEX POINTER    04280000
         B     B04A                GO TO B04A                           04300000
B04B     CH    C4,BTABLE-4(W3)     COMP ABS MES NO. TO MAX IN MESG TAB. 04320000
         BH    B04E                IF HIGHER, GO TO B04E                04340000
         SH    C4,BTABLE-6(W3)     SUBTRACT RANGE CONSTANT FROM C4      04360000
         BCTR  C4,0                SUBTRACT ONE FROM REL MESG NO. IN C4 04380000
         AR    C4,C4               MULTIPLY BY TWO                      04400000
         AH    C4,BTABLE-2(W3)     ADD MESG ADDR TABLE DISPLCMENT TO C4 04420000
         LH    W3,BTABLE(C4)       REL ADDR OF MESG IN MESG TABLE TO W3 04440000
         LA    W3,BTABLE(W3)       ADDR OF MESG IN MESG TABLE TO W3     04460000
         CLI   0(W3),X'FF'         IF MESG HAS BEEN DELETED FROM MESG   04480000
         BE    B04E                TABLE, GO TO B04E                    04500000
B04C     STH   W2,BSAVMA           SAVE ADDR OF MESG IN SAVE TABLE      04520000
         SR    C5,C5               INITIALIZE B11 TO NO OPER            04540000
         STH   C5,BSAVML           INITIALIZE SAVE MESG LENGTH          04560000
         B     B05                 GO TO B05                            04580000
B04E     LA    W3,BMX              ADDR OF MESG BMX TO W3               04600000
         B     B04C                GO TO B04C                           04620000
B04F     LA    W3,BMY              ADDR OF MESG BMY TO W3               04640000
         B     B04C                GO TO B04C                           04660000
B05      LA    C4,BK2              SAVE TABLE CAPACITY -3 TO C4         04680000
         SR    C4,W2               SUBTRACT SAVE TABLE POINTER FROM C4  04700000
         MVC   BWRKF2+1(1),0(W3)                                        04720000
         SH    C4,BWRKF2           SUBTRACT MESS OR TRLR LENGTH FROM C4 04740000
         BC    4,B09               IF MESS OR TRLR DOES NOT FIT IN SAVE 04760000
*                                    TABLE, GO TO B09                   04780000
         LH    C4,BWRKF2           MESS OR TRLR LENGTH TO C4            04800000
         LA    C5,BSAVTB(W2)       CURRENT ADDR IN SAVE TABLE TO C5     04820000
         EX    C4,B10              EX MOVE MESS OR TRLR TO SAVE TABLE   04840000
         LA    C4,1(C4)                                                 04860000
         AR    W2,C4               UPDATE SAVE TABLE POINTER            04880000
         AH    C4,BSAVML           UPDATE SAVE MESS LENGTH              04900000
         STH   C4,BSAVML                                                04920000
         BAL   L1,CGETA            GET REC FROM FILEA                   04940000
         MVC   BWRKF1,0(S1)        SRC TO BWRKF1                        04960000
         L     W3,BWRKF1                                                04980000
         SRL   W3,29                                                    05000000
         CH    W3,BK3                                                   05020000
         BNE   B06                 IF REC IS NOT TRLR GO TO B06         05040000
BUILD3   LA    C5,64               ENTRY 3 - INITIALIZE B11 TO SET IM   05060000
*                                    SWITCH ON                          05080000
         LA    W3,3(S1)            ADDRESS OF TRLR TO W3                05100000
         B     B05                 GO TO B05                            05120000
B06      LA    C5,BSAVTB(W2)                                            05140000
         MVI   0(C5),X'FF'         END OF TRLRS SIGN TO SAVE TABLE      05160000
         LA    W2,1(W2)            UPDATE SAVE TABLE POINTER            05180000
         CH    W1,BK4                                                   05200000
         BNE   B02                 IF SORT TABLE IS NOT FULL, GO TO B02 05220000
B07      LA    C5,BSRTTB(W1)       ADDR OF NEXT REC IN SORT TABLE TO C5 05240000
B08      MVI   0(C5),X'FF'         EOF SIGN TO SORT TABLE               05260000
         B     MAIN2               EXIT1                                05280000
B09      EX    C5,B11              EX NO OPER OR SET IM SWITCH ON       05300000
         LA    C5,BSRTTB-8(W1)     ADDR OF LAST REC IN SORT TABLE TO C5 05320000
         B     B08                 GO TO B08                            05340000
*END OF FILEA ROUTINE                                                   05360000
ADDRA    LA    C5,BSAVTB(W2)                                            05380000
         MVI   0(C5),X'FF'         END OF TRLRS SIGN TO SAVE TABLE      05400000
         OI    MSWTCH,X'80'        SET EOD SWITCH ON                    05420000
         B     B07                 GO TO B07                            05440000
*EXECUTED INSTRUCTIONS                                                  05460000
B10      MVC   0(1,C5),0(W3)       MOVE MESS OR TRLR TO SAVE TABLE      05480000
B11      OI    MSWTCH,X'00'        NO OPER OR SET IM SWITCH ON          05500000
*CONSTANTS                                                              05520000
         DS    0H                                                       05540000
BK1      DC    X'0004'             DIAG REC CODE                        05560000
BK2      EQU   2497                ABS SYM FOR SAVE TABLE CAPACITY - 3  05580000
BK3      DC    X'0007'             TRLR REC CODE                        05600000
BK4      DC    X'0140'             SORT TABLE CAPACITY - 8              05620000
BK5      DC    X'0001'             MINIMUM ABS MESG NO. (001)           05640000
BK6      DC    X'0320'             MAXIMUM ABS MESG NO. (800)           05660000
BPAT     DC    C'0'                PATTERN FOR EDITING ABS MESG NO.     05680000
         DC    X'202120'           *IN BMXFLD OF MESG BMX               05700000
*WORK FIELDS                                                            05720000
BWRKF1   DS    F                                                        05740000
BWRKF2   DC    X'0000'                                                  05760000
BWRKF3   DS    D                                                        05780000
BWRKF4   DS    CL4                                                      05800000
BSAVMA   DS    H                   SAVE MESS ADDR                       05820000
BSAVML   DS    H                   SAVE MESS LENGTH                     05840000
BSAVST   DS    CL3                 'SAVE LINE NO./ELEMENT NO.           05860000
         DC    X'0000'             '                                    05880000
         DS    CL3                                                      05900000
BSET     DC    H'0'                                                     05920000
BMX      DC    X'2709'             ERROR MESG BMX, TO BE PRINTED IN ANY 05940000
         DC    C'MESSAGE NO. '     *OF THE FOLLOWING CASES              05960000
BMXFLD   DS    CL3                 * ABS MESG NO. LOWER THAN MINIMUN    05980000
         DC    C' IS NOT IN THE T' * ABS MESG NO. HIGHER THAN MAXIMUM   06000000
         DC    C'ABLE.'            * ABS MESG NO. BEYOND MESG TABLE     06020000
         DC    X'0D0C'             * ABS MESG NO. HAS BEEN DELETED      06040000
BMY      DC    X'2609'             ERROR MESSAGE                        06060000
         DC    C'DIAGNOSTIC RECORD HAS WRONG LENGTH.' *BMY              06080000
         DC    X'0D0C'             *                                    06100000
         CIOPC PD1,A                                                    06120000
         DS    D                                                        06140000
*SORT TABLE                                                             06160000
BSORT    DC    X'014C0000'                                              06180000
BSRTTB   DS    2CL164                                                   06200000
*SAVE TABLE                                                             06220000
BSAVE    DC    X'09C80000'                                              06240000
BSAVTB   DS    10CL250                                                  06260000
*REFERENCE TABLE                                                        06280000
         DS    0F                                                       06300000
BREFTB   DC    H'75'                                                    06320000
         DC    C'1'                                                     06340000
         DC    H'175'                                                   06360000
         DC    C'2'                                                     06380000
         DC    H'300'                                                   06400000
         DC    C'3'                                                     06420000
         DC    H'400'                                                   06440000
         DC    C'4'                                                     06460000
         DC    H'499'                                                   06480000
         DC    C'5'                                                     06500000
         DC    H'548'                                                   06520000
         DC    C'6'                                                     06540000
         DC    H'800'                                                   06560000
         DC    C'7'                                                     06580000
         CIOPL PD1                                                      06600000
         EJECT                                                          06620000
         ENTRY OTABLE                                                   06640000
OTABLE   DS    D                                                        06660000
BTABLE   EQU   *                                                        06680000
         END   CETPD1                                                   06700000
