*(                                                                      00005017
*2802                                                              8101 00010020
*)                                                                      00015017
*   IBM SYSTEM/360 OPERATING SYSTEM                                   * 00020000
*   COBOL(E) 360S-CO-503                                              * 00040000
*   MODULE IEPPMG00                                                   * 00060000
 TITLE 'IEPPMG00--REPLACES DATA-NAMES WITH DESCRIPT. ATTRIBUTE'         00080000
*STATUS:  CHANGE LEVEL 10                                             * 00100000
*FUNCTION/OPERATION-                                                  * 00120000
*   READS PROCEDURE DIVISION SOURCE CARDS, LISTS THEM, CHECKS SEQUENCE* 00140000
*   AND COMPRESSES THEM INTO A UNIFORM INTERNAL FORMAT. DATA DIVISION * 00160000
*   GENERATED ATTRIBUTES ARE SUBSTITUTED FOR DATA-NAMES, QUALIFICATION* 00180000
*   IS RESOLVED AND ALL INFORMATION NEEDED TO HANDLE FILE-NAMES, 88S, * 00200000
*   AND SUBSCRIPTING IS INCLUDED SO THAT NO SUBSEQUENT PHASE NEED     * 00220000
*   REFER TO ANY DATA DIVISION GENERATED INFORMATION OTHER THAN THAT  * 00240000
*   INCLUDED IN THE OUTPUT OF THIS MERGE PHASE.                       * 00260000
*ENTRY POINTS-                                                        * 00280000
*        CETPMG      CALLING SEQUENCE-          LA    CR15,CPHADR     * 00300000
*                                               SVC   6               * 00320000
*                                       CPHLN   DC    CL8'IEPPMG00'   * 00340000
*                                       CPHADR  DC    A(CPHLN)        * 00360000
*INPUT-                                                               * 00380000
*   INPUT IS FROM THE IPT DEVICE ASSIGNED. THE CARD IMAGE IS READ INTO* 00400000
*   THE INPUT AREA WITH REGISTER 1 POINTING TO IT. THIS REGISTER SCANS* 00420000
*   THE AREA ONE WORD AT A TIME NORMALLY BEING STOPPED BY A BLANK.    * 00440000
*   REGISTER 13 HOLDS THE BEGINNING ADDRESS OF THE CURRENT WORD FOR   * 00460000
*   CALCULATIONS THAT WILL BE DONE ON THE WORD, BASICLY GETTING ITS   * 00480000
*   LENGTH.                                                           * 00500000
*OUTPUT-                                                              * 00520000
*   EACH BRANCH TO CPUTA PUTS OUT A RECORD IN THE FOLLOWING FORMAT ON * 00540000
*   FILEA.                                                            * 00560000
*        4 BYTE SRC PLUS WORD OR ATTRIBUTE OF DATA-NAME               * 00580000
*        IF QUALIFIED, SUCH A RECORD GOES OUT FOR EACH QUALIFIED NAME.* 00600000
*        IF A DIAGNOSTIC CONDITION OCCURS, THE RECORD IS PREPARED WITH* 00620000
*        A DUMMY SRC WITH CODE '8D' AND PUTOUT ON FILEC FOR OUTPUTTING* 00640000
*        BY PSYN1.                                                    * 00660000
*EXTERNAL ROUTINES:                                                   * 00680000
*        IJJCPD1   CP LOGIC MODULE.                                   * 00700000
*        IJFWZNZZ  MAGNETIC TAPE LOGIC MODULE.                        * 00720000
*        IJGWZNZZ  SEQUENTIAL DISK LOGIC MODULE.                      * 00740000
*EXITS NORMAL-                                                        * 00760000
*   CEXIT- AT CONCLUSION OF THIS PHASE A BRANCH TO THIS LABEL CAUSES  * 00780000
*          THE NEXT PHASE TO BE FETCHED.                              * 00800000
*EXITS ERROR- N/A                                                     * 00820000
*TABLE/WORK AREAS-                                                    * 00840000
*   HSHTBL- HASH TABLE FOR FINDING DATA-NAME ATTRIBUTES IN ATTRIBUTE  * 00860000
*           TABLE. 506 BYTES LONG                                     * 00880000
*   ATTRIBUTE TABLE- CORE REMAINING BETWEEN A CALCULATED END OF PHASE * 00900000
*           ADDRESS (CCORAD) AND THE BEGINNING ADDRESS OF THE I/O     * 00920000
*           BUFFERS.                                                  * 00940000
*ATTRIBUTES- N/A                                                      * 00960000
*NOTES-                                                               * 00980000
*   1-   BECAUSE THIS PHASE DOES NOT HAVE THE CAPABILITY TO KNOW ABOUT* 01000000
*        A NOTE PARAGRAPH/STATEMENT, IT WILL DIAGNOSE CONDITIONS OR   * 01020000
*        WORDS THAT WOULD BE INVALID IN A PROCEDURE DIVISION STATEMENT* 01040000
*        FOR THIS REASON, ALL DIAGNOSTICS GENERATED BY THE MERGE PHASE* 01060000
*        ARE SENT TO PSYN1 WHERE THEY CAN BE SCREENED.                * 01080000
*   2-   THE ABILITY TO READ INPUT FROM A SOURCE STATEMENT LIBRARY IN * 01100000
*        CONJUNCTION WITH AN INCLUDE VERB IS IMPLIMENTED IN THIS PHASE* 01120000
*   3-   IF PMG HAS BEEN FETCHED, IT MEANS THAT ENOUGH CORE WAS AVAIL-* 01140000
*        ABLE TO HOLD THE HASH TABLE AND THE COMPLETE ATTRIBUTE TABLE * 01160000
*        AT ONE TIME.                                                 * 01180000
*   4-   IMPORTANT! IF PMG IS INCREASED, BE SURE THE NUMBER OF     7719 01186017
*        BYTES IN PMG PLUS THE NUMBER OF BYTES IN SIS IS LESS      7719 01192017
*        THAN THE TOTAL NUMBER OF BYTES IN BLD. BLD PADS ITSELF    7719 01198017
*        WITH A CONSTANT TO BE GREATER THAN PMG+SIS. IT MAY BE     7719 01204017
*        NECESSARY TO ADD TO THAT CONSTANT.                        7719 01210017
*                                                                       01220000
         CIOP  PHASE=PMG,ENTRY=PMGBEG,OUTREG=9,EOFIPT=ENDCD,           C01240000
               NFLIB=NCBAD,EOFLIB=NCEND                                 01260000
PMGBEG   L     W2,CCOMM                                                 01280000
XTRC     EQU   X'80'               POSITION IN USWCH FOR TRACE SWITCH   01300000
         BAL   L1,COPEN                                                 01320000
         DC    X'0'                LEAVE FILE A POSITIONED              01340000
         DC    X'0'                                                     01360000
         DC    X'20'                                                    01380000
         DC    X'0'                EXPLICIT SLACK BYTE FOR IMA          01400000
         LA    P1,HSH                                                   01420000
         BAL   L1,CREAD            READ IN HASH TABLE                   01440000
         L     P1,CCORAD                                                01460000
         BAL   L1,CREAD            READ IN ATTR. TABLE                  01480000
         LA    P1,4(P1)                                                 01500000
         ST    P1,BSE                                                   01520000
*            ****************************                               01540000
*            ****************************                               01560000
*            *******               ******                               01580000
*            *******     MERGE     ******                               01600000
*            *******               ******                               01620000
*            ****************************                               01640000
*            ****************************                               01660000
*                    GETWORD                                            01680000
*          THE PMRG GETWORD IS A ROUTINE WHICH HANDLES THE READING,     01700000
*    LISTING, AND SCAN FUNCTIONS FOR THE PMRG PHASE.  A DESCRIPTION     01720000
*    OF ITS OPERATION FOLLOWS.                                          01740000
*          A BAL TO GETWORD WILL CAUSE THE NEXT SOURCE WORD TO BE       01760000
*    PLACED IN A WORK AREA, AND THE POSITION AND LENGTH OF THE          01780000
*    FOLLOWING WORD TO BE PLACED IN REGISTERS.  PMRG CAN THEN ALWAYS    01800000
*    EXAMINE TWO WORDS OF SOURCE.                                       01820000
*          THERE ARE CERTAIN WORDS IT IS CONVENIENT FOR GETWORD TO      01840000
*    RECOGNIZE AND OUTPUT WITHOUT RETURNING TO PMRG.  THESE ARE ALPHA   01860000
*    OR NUMERIC WITH DECIMAL LITERALS, AND THE OPERATOR ** . THE WORDS  01880000
*    ,OF, AND ,IN, ALSO ARE OF INTEREST  TO PMRG ONLY AS NEXT WORDS,    01900000
*    AND SO ARE SKIPPED BY GETWORD.                                     01920000
*          TO FIND THE BEGINNING OF A WORD, POSITIONS ARE EXAMINED      01940000
*    UNTIL A NON-BLANK IS FOUND. THIS POSITION IS EXAMINED FOR ,(,  ,   01960000
*    WHICH IS TREATED AS A SEPARATE WORD, OR ,', , WHICH INDICATES A    01980000
*    LITERAL, AND IS NOT TREATED UNTIL THE NEXT TIME.                   02000000
*          OTHERWISE A TRT IS DONE, STARTING AT THIS POSITION, WHICH IS 02020000
*    STOPPED BY . , ) OR BLANK. IF IT IS A . WE THEN CHECK IF THE NEXT  02040000
*    POSITION IS NON-BLANK, IN WHICH CASE IT IS A NUMERIC WITH DECIMAL  02060000
*    LITERAL.  OTHERWISE  WE GO AND CALCULATE ITS LENGTH, LOAD ITS      02080000
*    ADDRESS IN A REGISTER FOR PMRG, AND EXIT, UNLESS TWO WORDS WERE    02100000
*    CALLED FOR BY THE TWO SWITCH. QV.                                  02120000
*          ON THE NEXT ENTRY WE EXAMINE THE WORD WE JUST CALLED THE     02140000
*    NEXT WORD. IF IT WAS A NUMERIC W/DECIMAL LITERAL OR THE OPERATOR   02160000
*    ** WE OUTPUT DIRECTLY AND SET THE ,TWO SWITCH, WHICH TELLS US TO   02180000
*    GET TWO WORDS BEFORE RETURNING.  IF IT WAS ,OF, OR ,IN, WE         02200000
*    SIMPLY SET THE TWO SWITCH, EFFECTIVELY SKIPPING THE WORD. IF IT    02220000
*    WAS THE START OF AN ALPHA LITERAL, WE SET THE TWO SWITCH, AND      02240000
*    HANDLE IT COMPLETELY, INCLUDING POSSIBLE CONTINUATIONS, AND OUTPUT 02260000
*    IT.                                                                02280000
*          IF IT WAS NONE OF THESE, WE MOVE THE WORD TO A WORK AREA AND 02300000
*    GET THE NEXT WORD.                                                 02320000
*      **********************                                           02340000
*      ***  CENTRAL PATH  ***                                           02360000
*      **********************                                           02380000
MERGE    LA    P1,WERD             RESTORE P1                           02400000
         BAL   L1,GETWRD           GO GET ANOTHER WORD                  02420000
MRGIN    CLI   3(P1),X'7'          IS LENGTH LESS THAN SEVEN            02440000
         BNH   MG                  IF NOT HI GO CHECK FOR SPECIAL NAMES 02460000
MRG1     LA    W1,4(0,P1)          SET UP FOR HASH, WORD ADR IN W1      02480000
         SR    C5,C5                                                    02500000
         IC    C5,3(P1)            C5 GETS BYTE COUNT FOR HASH          02520000
         STM   C3,C4,HOLD                                               02540000
         BAL   L1,HASH                                                  02560000
         LM    C3,C4,HOLD                                               02580000
         CLC   0(2,W3),ZERO        ANY ENTRY ON HASH TABLE              02600000
         BE    MG5                 NO. GO OUTPUT                        02620000
         MVC   HALF+2(2),0(W3)     MOVE TO WORD BOUND FOR LOADING       02640000
         L     C1,HALF             LOAD FROM FULL WORD SINCE HASH TABLE 02660000
*                                 ENTRIES USE 16 BITS.                  02680000
         BAL   L1,CHAIN3           SEE IF NAME ON TABLE                 02700000
         C     C1,ZERO             WAS NAME FOUND +                     02720000
         BE    MG5                 C1 EQUAL ZERO MEANS NAME WASNT FOUND 02740000
         TM    MSW,X'10'           TEST X SW.                           02760000
         BZ    MRG3                IF NO BR.                            02780000
         BAL   L1,CPUTC            ELSE CPUT WORD FOR EXHIBIT           02800000
MRG3     CH    C4,TWO              IS NEXT WORD LENGTH TWO              02820000
         BE    QUAL                YES. GO SEE IF QUALIFIED             02840000
AMB      TM    4(C1),X'80'         IS THERE A CHAIN POINTER             02860000
         BO    AMB1                IF HAS ONE SEE IF NAME AMBIGUOUS     02880000
FLNM     TM    0(C1),X'F0'         TEST MAJ CODE                        02900000
         BZ    FLNM1               ALL ZEROS  MEANS FILE OR REC NAME    02920000
T88      IC    W1,4(C1)            LOAD LEVEL AND MBS                   02940000
         LA    W3,3                PUT MASK IN REG                      02960000
         NR    W3,W1               GET MBS IN W3                        02980000
         TM    4(C1),X'40'         TEST 88 SWITCH                       03000000
         BO    T881                BRANCH IF ON                         03020000
         BAL   L1,PAT              GO OUTPUT ATTRIBUTE POINTED TO BY C1 03040000
         C     W3,ZERO             SUBSCRIPTED {                        03060000
         BE    MERGE               NO. RETURN                           03080000
*      ************************                                         03100000
*      ***  SUBSCRIPTING   ****                                         03120000
*      ************************                                         03140000
SUB1     TM    5(C1),X'20'         TEST O BIT                           03160000
         BZ    SUB2                NOT ONE GO CHECK UP POINT            03180000
         BAL   L1,PAT              GO OUTPUT ATTRIBUTE POINTED TO BY C1 03200000
         IC    W1,4(C1)            GET LEVEL AND MBS                    03220000
         LA    W3,3                PUT MASK IN REG                      03240000
         NR    W3,W1               GET MBS ONLY IN REG                  03260000
         BCT   W3,SUB2             W3, HAS MBS                          03280000
         B     MERGE                                                    03300000
SUB2     BAL   L1,UPPT             LOAD UP POINTER FROM C1              03320000
         LR    C1,C2                                                    03340000
         C     C2,BSE                                                   03360000
         BH    SUB1                                                     03380000
         BAL   L1,PDIAGC           DIAGNOSE SUBSCRIPTED NAME WITH       03400000
         DC    X'100C'             INSUFFICIENT UP POINTERS.            03420000
         LA    0,WERD                                                   03440000
         LA    0,WERD+3                                                 03460000
         B     MERGE                                                    03480000
*      ************************                                         03500000
*      ***  QUALIFICATION   ***                                         03520000
*      ************************                                         03540000
QUAL     CLC   0(2,C3),OF          N.W. OF                              03560000
         BE    QUAL1               YES THEN ITS QUALIFIED               03580000
         CLC   0(2,C3),IN          N.W. IN                              03600000
         BNE   AMB                 NO. NOT QUALIFIED SO RETURN          03620000
QUAL1    NI    MSW,X'FE'           TURN OFF FOUND SWITCH                03640000
         SR    S1,S1               CLEAR REG FOR QUALIFIER COUNT        03660000
         ST    C1,HOLD                                                  03680000
QUAL2    BAL   L1,QL1              BUMP POINTER TO NXT WORD IN WORK ARE 03700000
         OI    SWITCH,X'01'        SET TWO SWITCH TO BYPASS THE OF OR I 03720000
         BAL   L1,GETWRD           GETWRD                               03740000
         LA    S1,1(S1)            BUMP QUALIFIER COUNT                 03760000
         TM    MSW,X'10'           TEST X SW.                           03780000
         BZ    QUAL2A              IF OFF SKIP                          03800000
         BAL   L1,CPUTC            ELSE CPUTC WORD FOR EXHIBIT VERB     03820000
QUAL2A   CH    C4,TWO              IS NEXT WORD LENGTH TWO              03840000
         BE    QL2                 YES.GO SEE IF MORE QUALIFIERS        03860000
*                                  WHEN QUAL3 IS REACHED ALL QUALIFIERS 03880000
QUAL3    L     C1,HOLD                                                  03900000
         LA    P1,WERD             POINT P1 TO QUALIFIED NAME           03920000
QUAL4    LR    C2,C1                                                    03940000
         LA    S2,0                SET COUNT TO ZERO                    03960000
QL10     BAL   L1,QL1              BUMP POINTER TO NXT WORD IN WORK ARE 03980000
QL7      BAL   L1,UPPT2            LOAD UP POINTER FROM C2              04000000
         C     C2,BSE                                                   04020000
         BE    QL4                                                      04040000
         IC    W1,3(P1)            LOAD LENGTH FOR COMPARE              04060000
         EX    W1,CPR2             COMPARE LENGTH AND NAME              04080000
         BNE   QL7                 UNEQUAL. GET NEXT UPPOINTER          04100000
         LA    S2,1(S2)            BUMP COUNT                           04120000
         CLR   S1,S2               WAS THAT LAST QUALIFIER              04140000
         BNE   QL10                                                     04160000
         TM    MSW,X'01'           TEST FOUND SWITCH                    04180000
         BO    QL3                                                      04200000
         OI    MSW,X'01'           SET  FOUND SWITCH                    04220000
         ST    C1,HOLD                                                  04240000
QL4      LA    P1,WERD             RESET P1 TO POINT TO QUALIFIED NAME  04260000
         BAL   L1,CHAIN            LOAD CHAIN POINTER                   04280000
         C     C1,ZERO             C1 EQUAL ZERO IF NAME NOT FOUND      04300000
         BNE   QUAL4               BR. IF NAME FOUND                    04320000
         TM    MSW,X'01'           TEST FOUND SWITCH                    04340000
         BO    QL6                 BR. IF ON                            04360000
         MVI   D1,X'7'             UNDEFINED HIERARCHY DIAGNOSTIC       04380000
         B     DIAG                GO TO COMMON DIAGNOSTIC ROUTINE      04400000
QL6      L     C1,HOLD             GET OLD ATTRIBUTE                    04420000
         B     FLNM                GO TO FILE NAME ROUTINE              04440000
QL1      LA    W1,0                CLEAR WORK REG.                      04460000
         IC    W1,3(P1)            LOAD BYTE COUNT                      04480000
         LA    P1,4(P1,W1)         BUMP P1 TO NEXT QUALIFIER POSITION   04500000
         BR    L1                  RETURN                               04520000
QL2      CLC   0(2,C3),OF                                               04540000
         BE    QUAL2                                                    04560000
         CLC   0(2,C3),IN                                               04580000
         BE    QUAL2                                                    04600000
         B     QUAL3                                                    04620000
QL3      MVI   D1,X'8'             AMBIGUOUS HIERARCHY DIAGNOSTIC       04640000
         B     DIAG                GO TO COMMON DIAGNOSTIC ROUTINE      04660000
*                                  END UP HERE IF  NO UP POINTER        04680000
*      ********************                                             04700000
*      ***  AMBIGUITY   ***                                             04720000
*      ********************                                             04740000
AMB1     ST    C1,HOLD             STORE ADR OF ORIGINAL ATTRIBUTE      04760000
         BAL   L1,CHAIN2           LOAD CHAIN POINTER                   04780000
         C     C1,ZERO             C1 IS ZERO IF NAME NOT FOUND         04800000
         L     C1,HOLD             RESTORE ORIG. ATRIB. POINTER         04820000
         BE    FLNM                IF EQ. THERES NO AMBIGUITY           04840000
         MVI   D1,X'6'             AMBIGUOUS NAME DIAGNOSTIC            04860000
         B     DIAG                GO TO COMMON DIAGNOSTIC ROUTINE      04880000
*      ********************                                             04900000
*      ***  FILE NAME   ***                                             04920000
*      ********************                                             04940000
FLNM1    CLI   0(C1),X'0D'         MIN CODE FD                          04960000
         BNE   RCNM                NO. CHECK FOR REC NAME               04980000
       TM    MSW,X'8'             WRITE FILE-NAME...               7637 04982013
       BZ    FLNM4                NO                               7637 04984013
       BAL   L1,PDIAGC            YES, ISSUE MESSAGE               7637 04986013
       DC    X'21BC'              NUMBER 444, EXPECT 2 TRAILERS    7637 04988013
       LA    0,WERD               POS/SEQ                          7637 04990013
       LA    0,WRITE              CLAUSE    (TRAILER 1)            7637 04992013
       LA    0,WERD+3             FILE-NAME    (TRAILER 2)         7637 04994013
FLNM4  EQU   *                    ACCEPT AS IS                     7637 04996013
         BAL   L1,PAT              GO OUTPUT ATTRIBUTE POINTED TO BY C1 05000000
         SR    W2,W2                                                    05020000
         IC    W2,10(C1)           LOAD BYTE COUNT FOR NEXT INSTR.      05040000
         TM    4(C1),X'80'         TEST FOR PRESENCE OF CHAIN POINTER   05060000
         BZ    FLNM3               IF NONE SKIP                         05080000
         LA    C1,2(C1)            ADJUST FOR CHAIN POINTERS TWO BYTES  05100000
FLNM3    LA    C1,11(W2,C1)        LOAD ADR NEXT ATRIBUTE               05120000
         BAL   L1,PAT              GO OUTPUT ATTRIBUTE POINTED TO BY C1 05140000
         B     MERGE                                                    05160000
*      **********************                                           05180000
*      ***  RECORD NAME   ***                                           05200000
*      **********************                                           05220000
RCNM     TM    4(C1),X'4'          TEST LEVEL 1 SWITCH                  05240000
         BZ    T88                 IF OFF NOT RECORD, SO RETURN         05260000
         TM    MSW,X'8'            TEST WRITE SWITCH                    05280000
         BZ    RCNM1               IF OFF ITS NOT FOR A WRITE VERB      05300000
         BAL   L1,UPPT             LOAD UP POINTER                      05320000
         ST    C1,HOLD                                                  05340000
         C     C2,BSE              UP POINT ZERO +                      05360000
         BE    RCNM4               YES. GO FLAG ERROR                   05380000
         LR    C1,C2               POINT TO UP POINT IN C1              05400000
         BAL   L1,PAT              GO OUTPUT ATTRIBUTE POINTED TO BY C1 05420000
         L     C1,HOLD             RESTORE ORIG. ATRIB. POINTER         05440000
RCNM1    BAL   L1,PAT              GO OUTPUT ATRIB POINTED TO BY C1     05460000
         B     MERGE                                                    05480000
RCNM4    MVI   D1,X'0D'            RECORD NAME W/O UP POINTER DIAGNOSTI 05500000
         B     DIAG                GO TO COMMON DIAGNOSTIC ROUTINE      05520000
*      ******************                                               05540000
*      ***     88 S   ***                                               05560000
*      ******************                                               05580000
T881     BAL   L1,UPPT             LOAD UP POINTER                      05600000
         C     C2,BSE              UP POINT ZERO +                      05620000
         BE    T884                YES. GO FLAG ERROR                   05640000
         MVC   G88(3),WERD         MOVE IN ORIGINAL PREFIX              05660000
         MVC   G88+4(8),0(C1)      MOVE IN CONDITION NAME ATTRIBUTE     05680000
         MVC   B88(3),G88          PUT PREFIX ON OPERATOR               05700000
         NI    G88,X'01'           CLEAR FLAGS                          05720000
         LR    C1,C2               POINT TO UP POINT ATTRIBUTE          05740000
         BAL   L1,PAT              GO OUTPUT ATTRIBUTE POINTED TO BY C1 05760000
         TM    4(C1),X'03'         IS CONDITION POINTING TO SUBSCRIPTED 05780000
*                                   NAME                                05800000
         BC    5,T885              IF YES GO SET SWITCH AND HANDLE THE  05820000
*                                 SUBSCRIPTING BEFORE OUTPUTTING REST   05840000
*                                   OF 88 INFORMATION                   05860000
T883     LA    P1,B88              POINT TO OPERATOR                    05880000
         BAL   L1,CPUTC                                                 05900000
         LA    P1,G88                                                   05920000
         BAL   L1,CPUTC            OUTPUT CONDITION ATTRIBUTE           05940000
         B     MERGE                                                    05960000
T884     MVI   D1,X'10'            88 W/O UP POINTER DIAGNOSTIC         05980000
         ST    C1,HOLD                                                  06000000
         B     DIAG                GO TO COMMON DIAGNOSTIC ROUTINE      06020000
T885     OI    MSW,X'02'           SET  88 SWITCH                       06040000
         B     SUB1                GO DO SUBSCRIPTING ROUTINE BEFORE 88 06060000
*        *****************************                                  06080000
*        *********  CHAIN ROUTINE  ***                                  06100000
*        *****************************                                  06120000
*        W3 IS  LINK REG                                                06140000
*        P1  I S NAME AND PREFIX ADR                                    06160000
*        C1 IS  ADR OF OLD ATTRIBUTE                                    06180000
*        AND W ILL EITHOR HAVE ADR OF NEW ATTRIBUTE                     06200000
*        IF ON E IS FOUND OR WILL BE SET TO ZERO                        06220000
CHAIN    TM    4(C1),X'80'         TEST CHAIN SWITCH                    06240000
         BZ    DEAD                                                     06260000
CHAIN2   LA    W2,0                                                     06280000
         IC    W2,10(C1)           LOAD BYTE COUNT                      06300000
         LA    C1,11(W2,C1)        ADD TO C1 GIVING ADR OF CHAIN POINT  06320000
         MVC   HALF+2(2),0(C1)     MOVE CHAIN POINT TO POS. FOR LOADING 06340000
         L     C1,HALF             LOAD CHAIN POINT                     06360000
CHAIN3   A     C1,BSE                                                   06380000
         IC    C5,3(P1)            ELSE LOAD BYTE COUNT FOR COMPARE     06400000
         EX    C5,CPR              COMPARE NAMES                        06420000
         BNE   CHAIN               UNEQUAL GO CHECK FOR MORE CHAINS     06440000
         BR    L1                  EQUAL. RETURN WITH ADR IN C1         06460000
DEAD     LA    C1,0                NO SUCCESSFUL CHAINS. RETURN WITH    06480000
         BR    L1                  C1 SET TO ZERO                       06500000
*      ************************                                         06520000
*      ***  MISCELLANEOUS   ***                                         06540000
*      ************************                                         06560000
UPPT2    MVC   HALF+2(2),8(C2)     MOVE C2 UP POINT FOR LOADING         06580000
         B     UPX                 AND GO TO NORMAL UP POINT            06600000
UPPT     MVC   HALF+2(2),8(C1)     MOVE C1 UP POINT FOR LOADING         06620000
UPX      L     C2,HALF             LOAD UP POINT                        06640000
         A     C2,BSE              ADD TABLE BASE ADR TO RELATIVE ADR   06660000
         BR    L1                  RETURN                               06680000
PAT      MVC   WERD+4(8),0(C1)     MOVE ATTRIBUTE POINTED TO BY C1 IN   06700000
*                                   FRONT OF PREFIX IN WORK AREA.       06720000
         MVI   WERD+3,X'8'         MOVE IN BYTE COUNT                   06740000
         NI    WERD,X'1'           CLEAR FLAGS                          06760000
         NI    MSW,X'F7'           CLEAR WRITE SWITCH                   06780000
         ST    L1,LINK             STORE RETURN ADR                     06800000
         BAL   L1,CPUTC            GO OUTPUT ATTRIBUTE                  06820000
         L     L1,LINK             OAD RETURN ADR                       06840000
         BR    L1                  AND RETURN                           06860000
MG       CLI   3(P1),X'1'          LENGTH OF ONE                        06880000
         BE    MG1                                                      06900000
         CLI   3(P1),X'00'                                              06920000
         BE    MERGE                                                    06940000
         CLC   3(5,P1),THEN        IS THIS THE WORD THEN                06960000
         BE    MERGE               IF YES SKIP IT                       06980000
         CLC   3(6,P1),WRITE       IS THIS A WRITE VERB                 07000000
         BE    WRT                 IF YES GO SET SWITCH                 07020000
         CLC   3(8,P1),REWRIT      IS THIS A REWRITE VERB               07040000
         BE    WRT                 IF YES, GO SET SWT                   07060000
         CLC   3(8,P1),NCLUDE      IS THIS AN INCLUDE VERB              07080000
         BE    NCLD     IF YES, GO SET UP FOR A LIBRARY CALL       4632 07100017
         CLC   3(8,P1),XIBIT       IS THIS AN EXHIBIT VERB              07120000
         BE    XBT                 IF YES GO SET SWITCH FOR EXTRA OUTPU 07140000
         CLC   3(6,P1),TRACE       IS THIS A TRACE VERB                 07160000
         BNE   MRG1                IF NONE OF THESE RETURN              07180000
TRC      L     W1,CCOMM            LOAD ADR. OF COMM AREA               07200000
         OI    USWCH(W1),XTRC      SET TRACE SWITCH IN COMM REGION      07220000
         B     MG5                 AND GO OUTPUT                        07240000
WRT      OI    MSW,X'8'            SET WRITE SWITCH SO THAT WE OUTPUT   07260000
         B     MG5A                                                     07280000
NCLD     TM    MSW,X'4'            ARE WE ALREADY IN LIBRARY MODE.      07300000
         BZ    NC3                 NO--                                 07320000
         BAL   L1,PDIAGC           YES--DIAGNOSE INCLUDE W/IN LIBRARY   07340000
         DC    X'0017'                                                  07360000
         LA    0,WERD                                                   07380000
         B     MERGE                                                    07400000
NC3      OI    MSW,X'4'                 SET LIBRARY NAME SWITCH         07420000
         BAL   L1,GETWRD           GET LIBRARY NAME                     07440000
         NI    MSW,X'FB'           TURN OFF LIBRARY NAME SWITCH         07460000
         CLI   0(C3),C'.'          IS NEXT WORD PERIOD                  07480000
         BE    NC1                 IF YES OK                            07500000
         BAL   L1,PDIAGC           ELSE DIAGNOSE                        07520000
         DC    X'1018'             NO PERIOD AFTER MEMBER NAME          07540000
         LA    0,WERD                                                   07560000
         LA    0,WERD+3                                                 07580000
NC1      CLI   WERD+3,X'08'        IS LIBRARY NAME TOO LONG--OVER  8 CH 07600000
         BH    NCBAD               YES--DIAGNOSE AND GET NEXT CARD      07620000
         BAL   L1,CFIND            LOCATE ENTRY                         07640000
         L     C5,STOR+12          LOAD SEQ NO (ASSIGNED)               07660000
         OI    SWITCH,X'21'        SET TWO SWITCH AND LIB SWITCH        07680000
         MVC   NCSEQ(12),SEQ       STORE AND RESET SOURCE SEQ NO        07700000
NC2      LA    L1,MRGIN            LOAD RETURN ADR                      07720000
         ST    L1,LINK                                                  07740000
         B     READ                GO GETWORD                           07760000
BADNAM   NI    SWITCH,X'E1'                                             07780000
         MVI   TABLE+C' ',X'1'                                          07800000
         MVI   TABLE+C'.',X'2'                                          07820000
         MVI   TABLE+C',',X'4'                                          07840000
         MVI   TABLE+C';',X'3'                                          07860000
         MVI   TABLE+C')',X'3'                                          07880000
         MVI   TABLE+C'''',X'0'                                         07900000
NCBAD    BAL   L1,PDIAGC           DIAGNOSE UNFOUND MEMBER NAME         07920000
         DC    X'0020'                                                  07940000
         LA    0,WERD                                                   07960000
         OI    SWITCH,X'01'                                             07980000
NCEND    NI    SWITCH,X'DF'        TURN OFF LIB SWITCH                  08000000
         MVC   SEQ(4),NCSEQ        RESTORE SEQ FIELD FROM SOURCE        08020000
         NI    MSW,X'FB'           TURN OFF LIBRARY NAME SWITCH         08040000
         B     NC2                 READ NEXT CARD                       08060000
XBT      OI    MSW,X'10'           SET EXHIBIT SWITCH                   08080000
         NI   MSW,X'DF'           TURN OFF LEFT PARAN SW FOR EXHIBIT    08100000
         B     MG5                 AND GO OUTPUT                        08120000
MG1      CLI   4(P1),X'7F'         OPERATOR OR PUNCTUATION {            08140000
         BH    MRG1                NO. THEN RETURN                      08160000
         BAL   L1,CPUTC            OUTPUT OPERATOR                      08180000
         CLI   4(P1),C'('          LEFT PARAM                           08200000
         BE    HART1               YES                                  08220000
         CLI   4(P1),C')'          RIGHT PARAM                          08240000
         BE    HART2               YES                                  08260000
         CLI   4(P1),C'.'          IS IT A PERIOD                       08280000
         BNE   MG2                 IF NO SKIP                           08300000
         NI   MSW,X'CF'           TURN OFF X SW & LEFT PARAN SW         08320000
*                                 A PERIOD INDICATES                    08340000
*                                   THE END OF AN EXHIBIT VERBS RANGE.  08360000
MG2      TM    MSW,X'2'            IS 88 SWITCH ON                      08380000
         BZ    MERGE               OFF.  RETURN                         08400000
         CLI   4(P1),C')'          IS THE CHARACTER A RIGHT PAREN       08420000
         BNE   MERGE                                                    08440000
         NI    MSW,X'FD'                                                08460000
         B     T883                                                     08480000
HART1    TM    MSW,X'10'           IS EXHIBIT SW ON                     08500000
         BZ    MG2                 NO                                   08520000
HART3    XI    MSW,X'30'           TURN EXHIBIT SW OFF BUT INDICATE     08540000
         B     MG2                 BY TURNING LEFT PARAM SW ON          08560000
HART2    TM    MSW,X'20'           IS LEFT PARAM SW ON                  08580000
         BZ    MG2                 NO                                   08600000
         B     HART3               RESET EXHIBIT & LEFT PARAM SWS       08620000
CPR      CLC   3(,P1),10(C1)                                            08640000
CPR2     CLC   3(,P1),10(C2)                                            08660000
MG5      NI    MSW,X'F7'           CLEAR WRITE SWITCH                   08680000
MG5A     BAL   L1,CPUTC                                                 08700000
         B     MERGE                                                    08720000
DIAG     BAL   L1,PDIAGC           COMMON DIAGNOSTIC ROUTINE            08740000
         DC    X'10'               INDICATES ONE INSERTION WORD         08760000
D1       DC    X'0'                ROUTINES MOVE IN CODE BYTE BEFORE    08780000
         LA    0,WERD              WORK AREA,, ADR OF SRC               08800000
         LA    0,WERD+3            ADR OF WORD IN WORK AREA AFTER SRC   08820000
         L     C1,HOLD             LOAD POINTER TO ATRIBUTE             08840000
         LA    P1,WERD             POINT P1 TO WORK AREA                08860000
         MVC   4(8,P1),0(C1)       MOVE ATRIB IN FRONT OF SRC IN WRK AR 08880000
         OI    4(P1),X'70'         SET ERROR MAJOR CODE IN ATTRIBUTE    08900000
         MVI   3(P1),X'8'          SET LENGTH FOR ATRIBUTE              08920000
         NI    0(P1),X'01'         CLEAR FLAGS                          08940000
         BAL   L1,CPUTC            OUTPUT ERROR ATRIBUTE                08960000
         B     MERGE               GO HANDLE NEXT WORD                  08980000
*      ***********************                                          09000000
*      ***  HASH ROUTINE   ***                                          09020000
*      ***********************                                          09040000
RWORD    EQU   10                                                       09060000
RNDX     EQU   11                                                       09080000
RQUT     EQU   12                                                       09100000
RADD     EQU   13                                                       09120000
RFOUR    EQU   14                                                       09140000
RCNT     EQU   15                                                       09160000
LOAD     DC    F'0'                                                     09180000
         DC    F'0'                                                     09200000
         DC    F'0'                                                     09220000
         DC    F'4'                                                     09240000
PRIME    DC    F'251'                                                   09260000
HASH     LM    RNDX,RFOUR,LOAD                                          09280000
         BCTR  RCNT,0                                                   09300000
LOOP     AL    RADD,0(RNDX,RWORD)                                       09320000
         BXLE  RNDX,RFOUR,LOOP                                          09340000
         D     RQUT,PRIME                                               09360000
         AR    RQUT,RQUT                                                09380000
         AL    RQUT,HASHAD                                              09400000
         ST    RQUT,HSHDBG             STORE RESULT FOR DEBUGING ONLY   09420000
         BCR   15,L1                                                    09440000
HSHDBG   DC    F'0'                    DEBUGING USE ONLY                09460000
         CIOPC PMG,A                                                    09480000
*            *******************************                            09500000
*            *******************************                            09520000
*            *******                 *******                            09540000
*            *******     GETWORD     *******                            09560000
*            *******                 *******                            09580000
*            *******************************                            09600000
*            *******************************                            09620000
*      **************************                                       09640000
*      ***  AUDIT  FUNCTION  ****                                       09660000
*      **************************                                       09680000
GETWRD   ST    L1,LINK             SAVE LINK ADDRESS FOR RETURN         09700000
FSW      BC    15,FIRST            BRANCH FIRST TIME ONLY. THEN NO-OP   09720000
         LM    W3,C1,STOR          LOAD PERM. REGS                      09740000
AUDIT    EQU   *                   CONSTRUCT SRC FOR CURRENT WORD       09760000
         IC    W1,FLAGS            LOAD CODE FLAGS                      09780000
         SLL   W1,4                SHIFT TO MAKE ROOM FOR POSITION NO.  09800000
         N     C0,TRNC                                                  09820000
         OR    W1,C0               OR IN POSITION NUMBER                09840000
         SLL   W1,12               SHIFT TO MAKE ROOM FOR SEQUENCE NO.  09860000
         OR    W1,C5               OR IN SEQUENCE NUMBER                09880000
         ST    W1,HOLD1            STORE IN WORK AREA                   09900000
         TM    SWITCH,X'1'                                              09920000
         BO    AUD5                                                     09940000
         LA    W1,4(P1,C4)                                              09960000
         C     W1,WRDLIM                                                09980000
         BNL   AUD7                                                     10000000
AUD5     MVC   0(3,P1),HOLD1+1     MOVE TO SRC POSITION                 10020000
         STC   C4,3(P1)            STORE LENGTH IN SRC                  10040000
*                                                                 22061 10042000
*                                                                 22061 10044000
*                                                                 22061 10046000
*                                                                 22061 10048000
*                                                                 22061 10050000
*                                                                 22061 10052000
*                                                                 22061 10054000
*                                                                 22061 10056000
*                                                                 22061 10058000
         EX    C4,INST1           MOVE NEXT WORD TO WORD AREA           10060000
         CH    C4,THIRTY           IS WORD TOO LONG                     10080000
         BNH   AUD6                IF NOT SKIP                          10100000
         BAL   L1,PDIAGC           DIAGNOSE WORD GREATER THAN 30 BYTES. 10120000
         DC    X'1005'                                                  10140000
         LA    0,0(P1)                                                  10160000
         LA    0,3(P1)                                                  10180000
         MVI   3(P1),X'1E'         TRUNCATE LENGTH TO MAX OF 30         10200000
         LA    C4,30               LOAD MAXIMUM LENGTH                  10220000
AUD6     LA    W1,4(C4,P1)                                              10240000
         MVC   0(4,W1),ZERO                                             10260000
         AH    C0,ONE              BUMP POSITION ON CARD COUNTER        10280000
         TM    FLAGS,X'0E'         WORD FLAGS ALL ZERO                  10300000
         BC    4,AUD1              IF NO THEN BR.                       10320000
         CH    C4,TWO              IS NEXT WORD LENGTH TWO              10340000
         BE    AUD2                THEN GO CHECK                        10360000
*      **************************                                       10380000
*      ***  SEARCH FUNCTION  ****                                       10400000
*      **************************                                       10420000
SCH1     SR    C4,C4               RESTORE LENGTH                       10440000
         MVI   FLAGS,X'80'         RESTORE FLAGS                        10460000
         B     SCH                                                      10480000
BUMP     LA    C1,1(C1)            BUMP POINTER TO NXT POS ON CARD      10500000
SCH      CLR   C1,W3               OFF CARD {                           10520000
         BH    READ                YES. GO READ                         10540000
         CLI   0(C1),C' '          IS THIS A BLANK                      10560000
         BE    BUMP                YES. GO BUMP REG                     10580000
         LR    C3,C1               STORE BEG. ADR                       10600000
         CLI   0(C1),X'7F'                                              10620000
         BL    SCH12                                                    10640000
         TM    NOTESW,X'4'   1ST TIME THRU MEANS STILL IN          4632 10641017
         BO    NOTNOTE1      PARAGRAPH NAME RTN                    4632 10642017
         CLC   0(5,C1),NOTE  NOTE STMT                             4632 10643017
         BE    YESNOTE                                             4632 10644017
         CLC   0(5,C1),NOTE1 'NOTE.'                               4632 10645017
         BE    YESNOTE                                             4632 10646017
         CLC   0(5,C1),NOTE2 'NOTE,'                               4632 10647017
         BE    YESNOTE                                             4632 10648017
         CLC   0(5,C1),NOTE3 'NOTE '                               4632 10649017
         BE    YESNOTE                                             8101 10649220
         CLC   0(4,C1),NOTE4                                       8101 10649420
         BE    YESNOTE                                             8101 10649620
         BNE   NOTNOTE       NO                                    4632 10650017
YESNOTE  EQU   *                                                   4632 10651017
         TM    NOTESW,X'01'  IS NOTE 1ST IN PARAGRAPH              4632 10652017
         BO    NOTEPAR             YES                            22061 10653000
         OI    NOTESW,X'2'   NO, READ UNITL NEXT PRIOD             4632 10654017
         B     NEXTPERD                                            4632 10655017
NOTEPAR  OI    NOTESW,X'08'        IS IT A NOTE PARAGRAPH         22061 10655200
         NI    NOTESW,X'FE'        TURN OFF NEW PARAGRAPH SWITCH  22061 10655400
         B     READ                                               22061 10655600
NOTNOTE  EQU   *                                                   4632 10656017
         NI    NOTESW,X'FE'  TURN OFF IF NOTE NOT 1ST IN PARA      4632 10657017
NOTNOTE1 NI    NOTESW,X'F9' TURN OFF FIRST TIME, PERIOD SWITCH    22061 10658000
         CLC   3(8,P1),NCLUDE      SHOULD C1 POINT AT A QUOTE           10660000
         BNE   DEF                 FOR THE START OF A LIBRARY NAME      10680000
         MVI   3(P1),X'00'         STOP EQUAL COMPARE 2ND TIME          10700000
         B    NCBAD                                                     10720000
NEXTPERD CLR   C1,W3               IS IT IN COL 72                22061 10721000
         BE    CKPERD              YES                            22061 10722000
         LA    C1,1(C1)            NOT IN COL 72                  22061 10723000
         CLR   C1,W3               IS IT OFF CARD                 22061 10724000
         BH    READ                YES, READ PHYSICAL CARD        22061 10725000
         CLC   0(2,C1),NOTEPERD    IS THIS A PERIOD-BLANK         22061 10726000
         BNE   NEXTPERD            NO, CONTINUE SEARCHING         22061 10727000
PERDEND  NI    NOTESW,X'FD'        YES                            22061 10728000
         OI    MSW,X'40'     PERIOD FOUND SW                       4632 10734017
         B     BUMP          RETURN TO MAIN ROUTINE                4632 10736017
CKPERD   CLC   0(1,C1),NOTEPERD    IS COL 72 A PERIOD             22061 10737000
         BNE   READ                NO, READ CARD                  22061 10738000
         B     PERDEND             YES, PERIOD FOUND              22061 10739000
*      **************************                                       10740000
*      ***  DEFINE FUNCTION  ****                                       10760000
*      **************************                                       10780000
DEF      LR    W1,W3                                                    10800000
         SR    W1,C1                                                    10820000
         BM    DEF6                BR. ON MINUS                         10840000
         SR    C2,C2               CLEAR RESULT REG FOR TRT INSTRUCTION 10860000
         EX    W1,INST2            TRT                                  10880000
         BC    8,DEF9              BR. ON CC0                           10900000
         CH    C2,THIRTY           SPECIAL TEST CHAR TO SEE IF IN       10920000
         BE    BADNAM              INCLUDE LIBRARY NAME MODE.           10940000
         TM    SWITCH,X'02'        LIT SWITCH ON                        10960000
         BC    1,DEF3              YES. BR.                             10980000
         CH    C2,ONE              DELIMITER BYTE A BLANK               11000000
         BE    OUT                                                      11020000
         CH    C2,THREE            DELIMITER BYTE A RT PAREN/SEMICOLON  11040000
         BE    OUT                                                      11060000
         L    L1,CCOMM                                                  11080000
         CLI   UPOIN(L1),X'6B'     IS SPECIAL EUROPEAN SYSTEM IN AFFECT 11100000
         BE    INPTED              I.E., COMMAS FOR DECIMAL POINTS      11120000
         CH    C2,FOUR             DELIMITER BYTE A COMMA               11140000
         BNE   DEF8                                                     11160000
         CLR   C1,W3               IS COMMA IN COL. 72                  11180000
         BE    OUT                                                      11200000
         MVI   MESAGE+1,X'0A'                                           11220000
         BAL   W2,TSTBLK           SEE IF FOLLOWED BY A BLANK           11240000
         B     OUT                                                      11260000
DEF8     CH    C2,TWO              DELIMITER BYTE A PERIOD              11280000
         BNE   DEF4                ANYTHING ELSE IS UNPRINTABLE         11300000
         CLR   C1,W3               IS PERIOD IN COL. 72                 11320000
         BE    OUT1                IF YES IT CAN'T BE IMBEDDED WD. 4484 11340015
IMBED    CLI   1(C1),C' '          ELSE CHK NXT POS FOR BLANK           11360000
         BNE   DEF5                IF NOT BLANK, THEN THE PERIOD IS     11380000
*                                   IMBEDDED IN A WORD. WE ASSUME IT TO 11400000
*                                   BE A LITERAL WITH DEC. PT.          11420000
OUT1     OI    MSW,X'40'           SET PERIOD SW ON                4484 11430015
         B     OUT                 IF BLANK THEN THE PERIOD IS A        11440000
*                                   DELINEATOR. GO EXIT.                11460000
INPTED   CH    C2,TWO              DELIMITER BYTE A PERIOD              11480000
         BNE   TSTCOM                                                   11500000
         CLR   C1,W3               IS PERIOD IN COL. 72                 11520000
         BE    OUT1              IF YES IT MUST BE END OF WROD     4484 11540015
         MVI   MESAGE+1,X'04'                                           11560000
         BAL   W2,TSTBLK           SEE IF FOLLOWED BY A BLANK           11580000
         B     OUT                                                      11600000
TSTCOM   CH    C2,FOUR             DELIMITER BYTE A COMMA(DEC. PT.)     11620000
         BNE   DEF4                                                     11640000
         CLI   1(C1),C' '              IS IT FOLLOWED BY A BLANK   3117 11650015
         BNE   DEF5                    NO                          3117 11660015
         B     OUT                                                 3117 11670015
TSTBLK   CLI   1(C1),C' '          SYNTAX REQUIRES A BLANK AFTER A      11680000
         BNE   NOBLK               COMMA, SEMICOLON, RIGHT PAREN        11700000
         CLI   0(C1),C'.'                                          4484 11708015
         BNE   TSTPRD                                              4484 11716015
         OI    MSW,X'40'           SET PERIOD SW ON                4484 11724015
TSTPRD   BR    W2                                                  4484 11732015
NOBLK    TM    MSW,X'80'           ARE WE OPERATING BETWIX PARENS       11740000
         BO    DAGCHK                                                   11760000
NOBLK1   MVC   HOLDIT(2),WERD      KEEP SRC CODE OF CURRENT WORD        11780000
         NI    WERD,X'FE'          CLEAR 1ST BIT OF POSIT NUM.          11800000
         NI    WERD+1,X'0F'        CLEAR REST OF POSIT. NUM.            11820000
         BAL   L1,PDIAGC                                                11840000
MESAGE   DC    X'0000'                                                  11860000
         LA    0,WERD                                                   11880000
         MVC   WERD(2),HOLDIT      RESTORE SRC CODE TO ORIGINAL         11900000
         BR    W2                                                       11920000
DAGCHK   TM    COUNTR,X'01'        HAS COMMA W/ NO BLANK FOLLOWING      11940000
         BO    STOPDG              ALREADY BEEN DIAGNOSTED              11960000
         OI    COUNTR,X'01'        NO--SET SWITCH FOR NEXT TIME         11980000
         B     NOBLK1                                                   12000000
STOPDG   NI    COUNTR,X'00'        AFTER 2ND ATTEMP TO DIAGNOSE THIS    12020000
         BR    W2                  CONDITION,RESET COUNTER SO NEXT      12040000
*                                  VALID DIAGNOSTIC OF IT CAN BE PUT.   12060000
*      **************************                                       12080000
*      ***  LITERAL CONTROL  ****                                       12100000
*      **************************                                       12120000
CON      NI    SWITCH,X'FD'        CLEAR LIT SWITCH                     12140000
         LR    W1,C1               LOAD CARD POINT                      12160000
         SR    W1,C3               SUBTRACT BEG. ADR.                   12180000
         LR    S1,C4               LOAD OLD TOT. LENGTH, WHICH IS ZERO  12200000
*                             UNLESS LIT. HAS BEEN CONTINUED            12220000
         AR    S1,W1               CALC NEW TOT. LENGTH                 12240000
         LR    W2,S1               STORE NEW TOT.                       12260000
         SH    S1,LIMIT            SUBTRACT 120 FROM TOTAL LENGTH       12280000
         BC    12,CON1             IF MINUS OR ZERO ITS OK              12300000
         BAL   L1,PDIAGC           DIAGNOSE LITERAL OVER 120 BYTES      12320000
         DC    X'0001'                                                  12340000
         LA    0,WERD                                                   12360000
         OI    SWITCH,X'04'        SET OUTSWITCH                        12380000
         SR    W1,S1               REDUCE LENGTH FOR MOVE BY TOT-120    12400000
         LH    W2,LIMIT            SET TOTAL LENGTH TO 120              12420000
         TM    SWITCH,X'08'        TEST 'SWITCH                         12440000
         BC    1,CON1              ON THEN BR.                          12460000
         SR    C1,S1               ELSE REDUCE TRT TRT REG BY TOT-120   12480000
CON1     LA    S2,4(C4,P1)         S2 GETS WORD AREA + OLD LENGTH + 4   12500000
         C     W1,ZERO             WAS 120 BYTE OF LIT IN COL72 OF      12520000
*                                  PREVIOUS CARD,,, IF SO               12540000
         BE    BYPASS              MOVE NO MORE OF INVALID LIT TO       12560000
*                                  OUTPUT AREA.                         12580000
         BCTR  W1,0                REDUCE LENGTH REG FOR MOVE           12600000
         EX    W1,INST3            MOVE TO WORD AREA                    12620000
         LA    W1,1(0,W1)          RESTORE LENGTH REG                   12640000
BYPASS   LR    C4,W2               LOAD NEW TOTAL                       12660000
         TM    SWITCH,X'04'        TEST OUT SWITCH                      12680000
         BC    8,CONT4                                                  12700000
         NI    SWITCH,X'FB'        TURN OFF OUTSWITCH                   12720000
CON12    STC   C4,3(0,P1)                                               12740000
         TM    MSW,X'4'            IS LIB. NAME SWITCH ON               12760000
         BO    CON14               IF YES SKIP PUT AND TURN OFF TWO SW. 12780000
         BAL   L1,CPUTC                                                 12800000
CON13    LA    C1,1(C1)            BUMP POINTER PAST TERMINAL '         12820000
         TM    SWITCH,X'08'        TEST 'SWITCH                         12840000
         BC    8,CON3              BR IF OFF-MEANS OVER 120 W/O '       12860000
CON2     NI    SWITCH,X'F1'                                             12880000
         MVI   TABLE+C' ',X'1'                                          12900000
         MVI   TABLE+C'.',X'2'                                          12920000
         MVI   TABLE+C',',X'4'                                          12940000
         MVI   TABLE+C';',X'3'                                          12960000
         MVI   TABLE+C')',X'3'                                          12980000
         MVI   TABLE+C'''',X'0'                                         13000000
         B     SCH1                                                     13020000
CON14    NI    SWITCH,X'FE'        TURN OFF TWO SWITCH                  13040000
         B     CON13                                                    13060000
* HERE WE LOOK FOR FIRST BLANK IF LIT EXCEEDED                          13080000
CON3     CLR   C1,W3               OFF CARD{                            13100000
         BH    CON2                YES. GO TO CON2                      13120000
         CLI   0(C1),C' '          IS THIS A BLANK                      13140000
         BE    CON2                YES. GO TO CON2                      13160000
         LA    C1,1(C1)            BUMP POINTER TO NXT POS ON CARD      13180000
         B     CON3                                                     13200000
CONT4    OI    SWITCH,X'10'        SET CON SWITCH                       13220000
         B     READ                                                     13240000
CON5     NI    SWITCH,X'EF'        TURN OF CON SWITCH                   13260000
         NI    MSW,X'BF'           SET PERIOD SWITCH OFF           4484 13270015
         LR    W1,C1               STORE MARGIN A POS. FOR LATER TESTS  13280000
CON6     CLI   0(C1),C''''         IS THIS THE CONTINUATION QUOTE       13300000
         BE    CON7                                                     13320000
         CLI   0(C1),C' '          IS THIS A BLANK                      13340000
         BC    7,CON8              NO. BR.                              13360000
         LA    C1,1(C1)            BUMP POINTER                         13380000
         CLR   C1,W3               OFF CARD{                            13400000
         BH    CON8                YES. BR.                             13420000
         B     CON6                                                     13440000
CON7     LA    C1,1(C1)            BUMP POINTER PAST INITIAL '          13460000
         OI    SWITCH,X'02'        SET LIT. SWITCH                      13480000
         LR    C3,C1               STORE BEG. ADR                       13500000
         AH    C0,ONE              BUMP POSITION-ON-CARD COUNTER        13520000
         LA    W1,4(W1)            SET W1 TO MARGIN B                   13540000
         CLR   C1,W1               IS TRT REG LESS THAN MARGIN B        13560000
         BH    DEF                 EQAL OR HI OK                        13580000
         BAL   L1,PDIAGC           DIAGNOSE CONTINUED LIT BEFORE COL 12 13600000
         DC    X'0002'                                                  13620000
         LA    0,WERD                                                   13640000
         B     DEF                                                      13660000
CON8     LA    W1,4(W1)            SET W1 TO MARGIN B                   13680000
         BAL   L1,PDIAGC           DIAGNOSE MISSING ' OR IMPROPER       13700000
         DC    X'0003'             CONTINUATION                         13720000
         LA    0,WERD                                                   13740000
         CLR   C1,W1                                                    13760000
         BC    10,CON9                                                  13780000
         OI    FLAGS,X'82'                                              13800000
CON9     OI    SWITCH,X'08'        SET ' SWITCH                         13820000
         BCTR  C1,0                                                     13840000
         B     CON12                                                    13860000
*      **************************                                       13880000
*      ****  READ  FUNCTION  ****                                       13900000
*      **************************                                       13920000
READ     BAL   L1,CIPT             GET NEXT CARD                        13940000
READ1    L     C1,INPUT            LOAD ITS ADR IN C1                   13960000
         LA    W3,71(0,C1)         SET 72ADR                            13980000
         LA    C5,1(C5)            BUMP CARD COUNT                      14000000
         L     L1,CCOMM           GET ADDRESS OF COMMON AREA       000E 14006018
         STH   C5,UCNTS(L1)       BUMP COUNT BY 1 FOR NO OF SOURCE 000E 14012018
         LA    C0,1                SET POSITION ON CARD COUNTER TO 1    14020000
         L     W2,LIST             LOAD ADR OF NEXT PRINT BUFFER        14040000
         MVI   0(W2),C' '          CARRIAGE CONTROL SINGLE SPACE        14060000
         LH    W1,CLNS                                                  14080000
         BCT   W1,READ2            COUNT SPECIFIED NO. OF LINES/PAGE    14100000
         MVI   0(W2),C'1'                                               14120000
         LH    W1,CLNCT                                                 14140000
READ2    STH   W1,CLNS             STORE COUNT OF REMAINING LINES       14160000
         LA    W2,1(W2)                                                 14180000
         CVD   C5,CVD              CONVERT ASSIGNED SEQUENCE NO.        14200000
         MVC   0(17,W2),EDMX       LOAD EDIT MASK                       14220000
         ED    8(6,W2),CVD+5       EDIT ASSIGNED SEQUENCE NO. TO PRINT  14240000
         TM    SWITCH,X'20'        IS THIS RECORD FROM LIBRARY CALL     14260000
         BZ    READ3               IF NO SKIP                           14280000
         MVI   15(W2),C'*'         ELSE MOVE IN LIBRARY FLAG            14300000
READ3    MVC   17(72,W2),0(C1)     MOVE IN CARD COLS. 1-72              14320000
         MVI   90(W2),C' '         BLANK PRINT POS. 91                  14340000
         MVC   91(8,W2),72(C1)     MOVE IN CARD COL. 73-80              14360000
         CLC   0(6,C1),BLANK       IS SOURCE SEQUENCE FIELD BLANK       14380000
         BE    READ5               IF YES DON'T CHECK SOURCE SEQUENCE   14400000
         CLC   0(6,C1),SEQ         COMP. TO PREV. SOURCE SEQ. FIELD     14420000
         BH    READ4               IF HIGH SOURCE SEQUENCE CHECKS       14440000
         MVI   9(W2),C'S'          MOVE IN SEQUENCE ERROR FLAG          14460000
READ4    MVC   SEQ(6),0(C1)        STORE SOURCE SEQ. FOR NEXT CHECK     14480000
READ5    BAL   L1,CPRINT           FREE CURRENT READ BUF AND GET NEXT   14500000
*      ***************************                                      14520000
*      ***  CHEK, FIRST + OUT ****                                      14540000
*      ***************************                                      14560000
       CLC     7(65,C1),BLANKS     IS THIS CARD BLANK              4484 14566015
       BE      READ                                                4484 14572015
         LA    C1,7(C1)            LOAD MARGIN A ADR                    14580000
         TM    SWITCH,X'10'        CON SW. ON                           14600000
         BC    1,CON5                                                   14620000
         CLC   0(4,C1),BLANK       ENTIRE MARGIN A FIELD BLANK          14640000
         BNE   CHK2                NO. GO SET MARGIN A PREFIX           14660000
*                                                                 22061 14661000
*                                                                 22061 14662000
         TM    NOTESW,X'08'        ARE WE IN A NOTE PARAGRAPH     22061 14663000
         BO    READ          YES, GET NEXT CARD                    4632 14664017
         TM    NOTESW,X'2'   ARE WE IN NOTE SENTENCE               4632 14665017
         BO    NEXTPERD                                            4632 14666017
CHK2B    EQU   *                                                   4632 14667017
*                                                                 22061 14670000
*                                                                 22061 14673000
*                                                                 22061 14676000
         LA    C1,4(0,C1)          ELSE SET TRT REG TO MARGINB          14680000
         NI    MSW,X'BF'           SET PERIOD SWITCH OFF           4484 14690015
         B     SCH                                                      14700000
CHK2     EQU   *                                                   4632 14702017
         TM    NOTESW,X'08'        IF ON AT THIS POINT THEN END OF22061 14704000
         BZ    CHK2A         NOTE PARAGRAPH   (NO)                 4632 14706017
         OI    MSW,X'40'     YES, TURN ON PERIOD SW                4632 14708017
CHK2A    OI    FLAGS,X'82'   SET MARGIN A PREFIX                   4632 14710017
         OI    NOTESW,X'5'   FOUND START OF NEW PARAGRAPH  X'1'    4632 14712017
*                                 1ST TIME THRU SW X'4'            4632 14714017
         NI    NOTESW,X'F7'  TURN OFF NOTE ON PARA CARD SW         4632 14716017
         TM    MSW,X'40'     IS PRECEDING STATEMENT HAS PERIOD     4484 14725015
         BC    1,SCH         YES                                   4484 14730015
       TM      SW2,X'80'   IS THE 1ST TIME IN PROCED. DIV.?        4484 14735015
         BC    1,CHK3        YES                                   4484 14740015
         OI    SW2,X'01'   NO, & PERIOD NOT FOUND IN LAST ST'MENT  4484 14745015
CHK3     NI    SW2,X'7F'     TURN 1ST TIME SWITCH OFF              4484 14750015
         B     SCH                                                 4484 14755015
FIRST    NI    FSW+1,X'0F'         TURN OFF FIRST SW                    14760000
         OI    SW2,X'80'     1ST TIME IN PROCEDURE DIVISION.       4484 14770015
         L     W1,CCOMM            POINT TO COMMON AREA                 14780000
         LH    C5,UISEQ(W1)        GET ASSIGNED SEQUENCE NO FROM COMM   14800000
         MVC   SEQ(6),USSEQ(W1)    GET PREVIOUS SOURCE SEQUENCE NO      14820000
         B     READ1                                                    14840000
OUT      LR    C4,C1               LOAD CARD POINT                      14860000
         SLR   C4,C3               SUBTRACT BEG. ADR TO GIVE LENGTH     14880000
         TM    SWITCH,X'01'        TWO SWITCH ON                        14900000
         BC    8,EXIT                                                   14920000
         NI    SWITCH,X'FE'                                             14940000
         B     AUDIT                                                    14960000
EXIT     STM   W3,C1,STOR                                               14980000
         L     L1,LINK             RESTORE LINK REG.                    15000000
         BCR   15,L1                                                    15020000
*      ***********************                                          15040000
*      ***  MISCELLANEOUS  ***                                          15060000
*      ***********************                                          15080000
INST1    MVC   4(,P1),0(C3)                                             15100000
INST2    TRT   0(0,C1),TABLE                                            15120000
INST3    MVC   0(,S2),0(C3)                                             15140000
AUD1     TM    FLAGS,X'84'         ALPHA LITERAL +                      15160000
         BC    1,AUD3              BR. IF YES                           15180000
*                             IF NOT SHOULD BE MARGIN A NAME            15200000
*                             OR NUMERIC W/ DECIMAL                     15220000
         BAL   L1,CPUTC                                                 15240000
         TM    FLAGS,X'88'       IS IT A NUM. W/DEC.?              4484 15241015
         BC    1,AUD4        YES                                   4484 15242015
         TM    SW2,X'01'     IS NO PERIOD SWITCH ON                4484 15243015
         BC    8,AUD4      PERIOD IN LAST STATEMENT                4484 15244015
         MVI   MESAGE+1,X'41'  PERIOD MISSING ERROR MESSAGE        4484 15245015
         BAL   W2,NOBLK1                                           4484 15246015
         NI    MSW,X'BF'          TURN OFF PERIOD SW.              4484 15247015
         NI    SW2,X'FE'                                           4484 15248015
         OI    WERD,X'FE'          RESET POSITION BIT ON           4484 15249015
       OI      WERD+1,X'0F'                                        4484 15250015
AUD4     OI    SWITCH,X'1'         SET TWO SWITCH                       15260000
         B     SCH1                                                     15280000
AUD2     CLC   0(2,C3),AST         IS THIS EXPONENTIATION               15300000
         BNE   SCH1                                                     15320000
         MVI   4(P1),X'59'         IF  ** MOVE HEX 59 TO WORD AREA      15340000
         MVI   3(P1),X'1'          SET LENGTH TO 1                      15360000
         BAL   L1,CPUTC                                                 15380000
         B     AUD4                                                     15400000
AUD3     OI    SWITCH,X'3'         SET LIT SWITCH + TWO SWITCH          15420000
         SR    C4,C4              CLEAR LENGTH COUNTER                  15440000
         MVI   TABLE+C' ',X'0'                                          15460000
         MVI   TABLE+C'.',X'0'                                          15480000
         MVI   TABLE+C',',X'0'                                          15500000
         MVI   TABLE+C';',X'0'                                          15520000
         MVI   TABLE+C')',X'0'                                          15540000
         MVI   TABLE+C'''',C''''                                        15560000
         TM    MSW,X'04'           IF IN INCLUDE LIBRARY NAME MODE      15580000
         BZ    DEF                 THE TRT SCAN MUST BE STOPPED BY A    15600000
         MVI   TABLE+C' ',X'1E'    QUOTE OR A BLANK.                    15620000
         MVI   FLAGS,X'80'                                              15640000
         B     DEF                                                      15660000
AUD7     LA    P1,WERD                                                  15680000
         BAL   L1,QL1                                                   15700000
         SR    S1,S1                                                    15720000
         BCTR  C3,0                                                     15740000
         STC   C4,0(C3)                                                 15760000
         BAL   L1,PDIAGC                                                15780000
         DC    X'202F'                                                  15800000
         LA    0,WERD                                                   15820000
         LA    0,WERD+3                                                 15840000
         LA    0,0(C3)                                                  15860000
         LA    C3,1(C3)                                                 15880000
         B     AUD5                                                     15900000
SCH12    CLI   0(C1),C''''         IS THIS A QUOTE                      15920000
         BE    SCH2                                                     15940000
         CLC   3(8,P1),NCLUDE      IF INCLUDE LIB NAME MODE, LIB NAME   15960000
         BNE   SCH10               MUST START AND END WITH A QUOTE      15980000
         MVI   3(P1),X'00'        (STOP EQUAL COMPARE 2ND TIME)         16000000
         B    NCBAD                                                     16020000
SCH10    L    L1,CCOMM                                                  16040000
         CLI   UPOIN(L1),X'6B'     IS SPECIAL EUROPEAN SYSTEM IN EFFECT 16060000
         BE    INVPRT              I.E., COMMAS FOR DECIMAL POINTS.     16080000
         CLI   0(C1),C','          DELIMITER BYTE A COMMA               16100000
         BNE   SCH11                                                    16120000
         CLR   C1,W3               IS COMMA IN COL. 72                  16140000
         BNE   SCH4                NO--                                 16160000
         LA    C1,1(C1)            YES--GO FOR NEXT CARD                16180000
         B     SCH                                                      16200000
SCH11    CLI   0(C1),C'.'          DELIMITER BYTE A PERIOD              16220000
         BE    SCH5                                                     16240000
SCH6     CLI   0(C1),C';'          IS IT A SEMICOLON                    16260000
         BE    SCH4                IF YES SKIP IT.                      16280000
         CLI   0(C1),C'('          IS THIS A LEFT PAREN                 16300000
         BE    SCH8                                                     16320000
         CLI   0(C1),C')'          IS THIS A RIGHT PAREN                16340000
         BNE   DEF                                                      16360000
         NI    MSW,X'7F'           TURN OFF BETWIX PAREN SWITCH         16380000
         CLI   1(C1),C'.'                                               16400000
         BE    PRDSW                                               4484 16420015
         CLI   1(C1),C','                                               16440000
         BE    SCH3                                                     16460000
         CLI   1(C1),C')'                                               16480000
         BE    SCH3                                                     16500000
         CLR   C1,W3               RIGHT PAREN IN COL. 72               16520000
         BE    SCH3                                                     16540000
         MVI   MESAGE+1,X'0A'                                           16560000
         BAL   W2,TSTBLK           SEE IF FOLLOWED BY A BLANK           16580000
SCH3     LA    C1,1(C1)            BUMP POINTER TO NXT POS              16600000
         B     OUT                 AND GO OUTPUT                        16620000
SCH8     OI    MSW,X'80'           TURN ON BETWIX PAREN SWITCH          16640000
         B     SCH3                                                     16660000
SCH4     MVI   MESAGE+1,X'0A'                                           16680000
         BAL   W2,TSTBLK           SEE IF FOLLOWED BY A BLANK           16700000
         LA    C1,1(C1)            BUMP POINTER TO SKIP PAST COMMA      16720000
         AH    C0,ONE              BUMP POSITION-ON-CARD COUNTER        16740000
         B     SCH                 AND GO LOOK FOR NEXT WORD            16760000
SCH5     CLR   C1,W3               IS PERIOD IN COL 72                  16780000
         BE    PRDSW           IF YES, IT CANT BE IMBEDDED         4484 16800015
SCH7     CLI   1(C1),C' '          ELSE CHK NEXT POSIT FOR BLANK        16820000
         BNE   DEF5                IF NOT BLANK THIS IS ASSUMED TO BE A 16840000
*                                   NUMERIC LIT WITH LEADING DEC. POINT 16860000
         B     PRDSW                       ELSE TREATED AS PUNCT.  4484 16880015
SCH9     CLI   1(C1),C' '          INVERTED PRINT EDIT MODE, COMMAS     16900000
         BNE   DEF5                IF NOT FOLLOWED BY A BLANK WILL      16920000
         LA    C1,1(C1)            BE CONSIDERED AS DECIMAL POINTS.     16940000
         AH    C0,ONE              IF FOLLOWED BY A BLANK,              16960000
         B    SCH                  THEY  ARE DROPPED                    16980000
PRDSW    OI    MSW,X'40'           TURN PERIOD SW ON               4484 16986015
         B     SCH3                                                4484 16992015
SCH2     OI    FLAGS,X'84'                                              17000000
         LA    C1,1(C1)            BUMP POINTER                         17020000
         LR    C3,C1                                                    17040000
DEF2     LA    C1,1(C1)            BUMP POINTER                         17060000
DEF6     TM    SWITCH,X'2'         TEST LIT  SWITCH                     17080000
         BC    1,CON                                                    17100000
         B     OUT                                                      17120000
DEF3     CLI   0(C1),C''''         IS THIS A QUOTE                      17140000
         BE    DEF7                                                     17160000
DEF5     OI    FLAGS,X'88'                                              17180000
DEF4     LA    C1,1(C1)            BUMP POINTER PAST DEC. POINT         17200000
         B     DEF                                                      17220000
DEF7     OI    SWITCH,X'C'         SET OUTSWITCH SET   'SWITCH          17240000
         B     CON                                                      17260000
DEF9     LR    C1,W3               SET CARD POINT TO COL. 72            17280000
         B     DEF2                                                     17300000
INVPRT   CLI   0(C1),C'.'          DELIMITER BYTE A PERIOD              17320000
         BNE   INVCOM                                                   17340000
         CLR   C1,W3               IS PERIOD IN COL. 72                 17360000
         BE    PRDSW                         IT MUST END OF WORD   4484 17380015
         MVI   MESAGE+1,X'04'                                           17400000
         BAL   W2,TSTBLK           SEE IF FOLLOWED BY A BLANK           17420000
         B     SCH3                                                     17440000
INVCOM   CLI   0(C1),C','          DELIMITER BYTE A COMMA (DEC.PT.)     17460000
         BNE   SCH6                                                     17480000
         B     SCH9                SEE IF COMMA IS DELIMITER/DEC.PT.    17500000
ENDCD    TM    SWITCH,X'01'        TEST TWO SWITCH                      17520000
         BO    LEEV               BR TO END PHASE                  4479 17540015
         MVC   AUDIT(4),ENDWRD     ELSE SET UP TO RETURN AFTER          17560000
*                                 MERGING LAST WORD                     17580000
         OI    FLAGS,X'84'         SET LIT FLAG SO MERGE WONT TEST N. W 17600000
         B     EXIT                                                     17620000
LEEV     LA    P1,PERIOD           SETUP TO PUT OUT A PERIOD  AT END    17680000
         BAL   L1,CPUTC            OF PROGRAM.                          17700000
         BAL   L1,CCLOSE                                                17720000
         DC    X'00000200'                                              17740000
         B     CEXIT                                                    17760000
ENDWRD   B     LEEV                                                4479 17820015
         EJECT                                                     4632 17850017
*                                                                       17880000
*                                                                       17900000
*        *******************************************************        17920000
*        *******************************************************        17940000
*        *****                                             *****        17960000
*        *****  SPECIAL DIAGNOSTIC ROUTINE FOR PMG & SMG   *****        17980000
*        *****                                             *****        18000000
*        *******************************************************        18020000
*        *******************************************************        18040000
*                                                                       18060000
*                                                                       18080000
*        THIS ROUTINE IS SETUP TO STOP THE MERGE PHASES FROM            18100000
*        OUTPUTTING THEIR DIAGNOSTICS ON FILEA BUT RATHER               18120000
*        OUTPUTTING THEM ON FILEC AS INPUT FOR THE SYNTAX PHASE         18140000
*        THAT FOLLOWS. THE SYNTAX PHASE WILL SENSE THESE                18160000
*        DIAGNOSTICS BY THE CODE 8D IN A DUMMY SRCF PREPARED            18180000
*        BY THE MERGE PHASE. THE SYNTAX PHASE WILL OUTPUT THEM          18200000
*        ON FILEA FOR THE MERGE PHASE.                                  18220000
*        IF THE SYNTAX PHASE SENSES ONE OF THE SPECIAL 8D CODES         18240000
*        ON AN INPUT RECORD WHILE IT KNOWS IT IS IN THE 'NOTE'          18260000
*        MODE, IT WILL DROP THE RECORD AND GO ON.                       18280000
*        ALL THIS IS DONE SO THAT DIAGNOSTICS GENERATED BY THE          18300000
*        MERGE PHASE ON ANYTHING WITHIN A NOTE  STATEMENT OR            18320000
*        PARAGRAPH WILL NOT BE PUT OUT ON THE DIAGNOSTIC LISTING.       18340000
*                                                                       18360000
*                                                                       18380000
PDIAGC   ST    9,TABLE+8                                                18400000
         STM   0,1,TABLE                                                18420000
         LH    0,0(L1)             ERROR MESSAGE NUMBER TO REG.         18440000
         LA    L1,2(L1)            BUMP PTR TO GET ADDR OF SRC          18460000
         STH   0,DGSRC+4           ERROR NUM TO RECORD BUILD AREA       18480000
         NI    DGSRC+4,X'0F'       CLEAR OUT TRLR COUNT BITS            18500000
         SRL   0,12                HOLD TRAILER COUNT                   18520000
         MVI   DGSRC,X'86'                                              18540000
         STH   0,TRLNUM            SAVE NUM. OF TRAILERS                18560000
         EX    0,0(L1)             GET ADDR OF SRC                      18580000
         LA    L1,4(L1)            ADDR OF POSSIBLE TRAILER             18600000
         ST    L1,TABLE+12         SAVE RETURN                          18620000
         LR    1,0                 SET WRK PTR TO SRC                   18640000
         MVC   DGSRC+1(2),1(1)     PUT POSIT-SEQ TO RECORD BUILD AREA   18660000
         TM    0(1),X'01'          IS HI-ORDER BIT OF POSIT ON          18680000
         BC    8,CLEAR             NO,                                  18700000
         OI    DGSRC,X'01'         YES, SET IT ON IN RECORD BUILD AREA  18720000
CLEAR    LA    9,SPSRC             SET OUTPUT PTR TO DUMMY SRC          18740000
         BAL   L1,CPUTC            PUT OUT ERROR NUM. RECORD            18760000
         L     L1,TABLE+12         SETUP RETURN TO MAIN PROG            18780000
         LH    1,TRLNUM            NUM OF TRAILERS TO REG.              18800000
         LTR   1,1                 ARE THERE ANY TRAILERS               18820000
         BC    8,DGEXIT            NO, RETURN TO MAIN PROG.             18840000
         NI    DGSRC,X'E5'       PUT TRAILER CODE IN RECORD BUILD AREA  18860000
         OI    DGSRC,X'E4'         W/OUT UPSET OF HI-ORDER POSIT. BIT   18880000
TRLOOP   EX    0,0(L1)             POINT TO LGTH/WORD TO BE TRAILER     18900000
         STH   1,TRLNUM            DECREMENTED TRAILER COUNT IF MORE    18920000
*                                  THAN ONE TRAILER IS TO BE USED       18940000
         LA    L1,4(L1)            BUMP TO NEXT TRAILER OR RETURN       18960000
         ST    L1,TABLE+12         SAVE RETURN TO MAIN PROG.            18980000
         LR    9,0                 WRK PTR TO LENGTH OF TRAILER WORD    19000000
         SH    9,HALF7             BACK UP PTR TO ALLOCATE SPACE FOR    19020000
*                                  DUMMY SRC AND REAL SRC               19040000
         MVC   TABLE+16(7),0(9)    SAVE INFO IN BYTES TO BE CLOBBERED   19060000
         SR    L1,L1                                                    19080000
         IC    L1,7(9)             TAKE LENGTH OF TRAILER WORD AND      19100000
         LA    L1,4(L1)            ADD 4 TO IT TO GET RECORD LENGTH     19120000
         MVC   0(7,9),SPSRC        FOR CIOP. OVER LAY W/ DUMMY/REAL SRC 19140000
         STC   L1,3(9)             PLUG RECORD LGTH IN INPUT AREA       19160000
         BAL   L1,CPUTC                                                 19180000
         MVC   0(7,9),TABLE+16     RESTORE CLOBBERED BYTES IN PROG.     19200000
         L     L1,TABLE+12         RESTORE PTR TO MAIN PROG.            19220000
         LH    1,TRLNUM            NUM OF TRAILERS LEFT TO WRK REG.     19240000
         BCT   1,TRLOOP            DECREMENT AND CHK IF 0--YES--DONE    19260000
DGEXIT   LM    0,1,TABLE           RESTORE REGS. AND                    19280000
         L     9,TABLE+8           RETURN TO  MAIN PROG.                19300000
         MVI   TABLE,X'00'         RESTORE TRT TABLE                    19320000
         MVC   TABLE+1(23),TABLE   DIAG. RT. USED 24 BYTES              19340000
         BR    L1                                                       19360000
*                                                                       19380000
*                                                                       19400000
         DC    0F'0'               NEXT 3 CARDS MUST BE TOGETHER        19420000
SPSRC    DC    X'8D000006'    1.   DUMMY SRC FOR DIAGNOSTICS            19440000
DGSRC    DC    X'00000002'    2.   REAL SRC FOR DIAGNOSTICS             19460000
         DC    X'0000'        3.   AREA FOR DIAG. NUMBER                19480000
TRLNUM   DC    H'0'                                                     19500000
HALF7    DC    H'7'                                                     19520000
CDGWK    DS    F                                                        19540000
*                                                                       19560000
*                                                                       19580000
*      *********************************                                19600000
*      ***  TRANSLATE + TEST TABLE  ****                                19620000
*      *********************************                                19640000
         DC    0F'0'                                                    19660000
TABLE    DC    100X'0'             MUST BE ON FULL WORD BOUNDRY         19680000
         DC    156X'0'                                                  19700000
RESTRT   EQU   *                                                        19720000
         ORG   TABLE+C' '          BLANK                                19740000
         DC    X'1'                                                     19760000
         ORG   TABLE+C'.'          PERIOD                               19780000
         DC    X'2'                                                     19800000
         ORG   TABLE+C')'          RIGHT PAREN                          19820000
         DC    X'3'                                                     19840000
         ORG   TABLE+C','          COMMA                                19860000
         DC    X'4'                                                     19880000
         ORG   TABLE+C';'          SEMI-COLON                           19900000
         DC    X'3'                                                     19920000
         ORG   RESTRT                                                   19940000
*      *************************                                        19960000
*      ***  MERGE LITERALS   ***                                        19980000
*      *************************                                        20000000
NCLUDE   DC    X'7'                                                     20020000
         DC    C'INCLUDE'                                               20040000
THEN     DC    X'4'                'THEN' IS USED AS PUNCTUATION IN SOU 20060000
         DC    C'THEN'             IT IS DROPPED FROM OUTPUT LIKE COMMA 20080000
XIBIT    DC    X'7'                                                     20100000
         DC    C'EXHIBIT'                                               20120000
TRACE    DC    X'5'                                                     20140000
         DC    C'TRACE'                                                 20160000
WRITE    DC    X'5'                CONSTANT TO CHECK FOR WRITE VERB     20180000
         DC    C'WRITE'                                                 20200000
REWRIT   DC    X'7'                                                     20220000
         DC    C'REWRITE'                                               20240000
OF       DC    C'OF'                                                    20260000
IN       DC    C'IN'                                                    20280000
AST      DC    C'**'                                                    20300000
MSW      DC    X'0'                SWITCHES FOR MERGE PHASE             20320000
* POS 0-7 ARE THE BITS NUMBERED FROM RIGHT TO LEFT                      20340000
* POS 0 - FOUND SWITCH.  INDICATES THAT A MATCHING HIERARCHY HAS BEEN   20360000
*            FOUND FOR A QUALIFIED NAME,  AND WE ARE NOW CHECKING FOR   20380000
*            ADDITIONAL MATCHES, IN ORDER TO DIAGNOS AMBIGUITY OF       20400000
*            QUALIFICATION.                                             20420000
* POS 1 - 88 SWITCH.  ON WHILE WE MERGE THE SUBSCRIPTS OF A SUBSCRIPTED 20440000
*            CONDITION NAME. INDICATES THAT AFTER LOCATING A RIGHT HAND 20460000
*            PAREN, WE RETURN TO THE 88 ROUTINE TO MERGE THE EQUAL      20480000
*            OPERATOR AND THE CONDITION.                                20500000
* POS 2 - LIBRARY NAME SWITCH - ON WHEN DOING GETWORD FOR LIB. NAME     20520000
* POS 4 - X SWITCH. ON WHILE HANDLING AN EXHIBIT VERB.  INDICATES       20540000
*            THAT WE ARE TO MERGE THE DATA NAMES, AS WELL AS THEIR      20560000
*            ATTRIBUTES.                                                20580000
*  POS 5  LEFT PARAN SW INDICATES A LEFT PARAN HAS BEEN FOUND           20600000
*        FOLLOWING AN EXHIBIT STATEMENT.  THIS IS TO BYPASS             20620000
*        PUTTING OUT THE DATA-NAME FOR THE SUBSCRIPTS.                  20640000
* POS 6   PERIOD NOT FOUND SWITCH - ON WHEN FOUND                  4484 20650015
* POS 7 - LEFT RAREN FOUND SWITCH---ON WHEN FOUND--.                    20660000
SWITCH   DC    X'1'                GETWORD SWITCHES                     20680000
* POSITIONS 0-7 ARE THE BITS NUMBERED FROM RIGHT TO LEFT                20700000
* POS 0 - TWO SWITCH. ON IF NEXT WORD WAS IRRELEVANT TO MERGE, SO THAT  20720000
*         WE WANT TO GET TWO WORDS BEFORE RETURNING.   INITIALY ON.     20740000
* POS 1 - LIT SWITCH. ON IF WE ARE WORKING ON A LITERAL. TRT TABLE WILL 20760000
*         BE SET UP FOR LITERALS ETC.                                   20780000
* POS 2 - OUTSWITCH. ON WHEN WE ARE READY TO PUT A LITERAL, EITHOR      20800000
*         DUE TO A RIGHT ' OR EXCESSIVE LENGTH.                         20820000
* POS 3 - ' SWITCH. ON WHEN A RIGHT ' HAS BEEN FOUND FOR A LITERAL.     20840000
* POS 4 - CON SWITCH. ON WHILE WE READ A CARD TO CONTINUE A LITERAL.    20860000
* POS 5 - LIBRARY SWITCH. ON WHEN INCLUDING                             20880000
* POS 6 - BUFFER SWITCH. USED TO CONTROL TWO INPUT BUFFERS.             20900000
* POS 7 - SEG SWITCH. ON IF ATTRIBUTE TABLE IS SEGMENTED.               20920000
BLANKS DC      65C' '                                              4484 20925015
SW1    DC      X'00'                                               4484 20930015
SW2    DC      X'00'                                               4484 20935015
ONE      DC    H'1'                                                     20940000
TWO      DC    H'2'                                                     20960000
THREE    DC    H'3'                                                     20980000
FOUR     DC    H'4'                                                     21000000
THIRTY   DC    H'30'                                                    21020000
LIMIT    DC    H'120'              MAXIMUM LENGTH OF CONTINUED LITERALS 21040000
HOLDIT   DC    H'0'                                                     21060000
TRNC     DC    F'31'               MASK TO TRUNCATE POS TO MAX 31       21080000
FLAGS    DC    X'80'                                                    21100000
PERIOD   DC    X'800000014B'       SPECIAL RECORD FOR END OF PROGRAM .  21120000
B88      DC    F'1'                                                     21140000
         DC    CL1'='                                                   21160000
G88      DC    X'00000008'         HOLD AREA FOR CONDITION NAME ATTRIB. 21180000
         DC    8X'0'                                                    21200000
COUNTR   DC    X'00'                                                    21220000
BSE      DC    F'0'                                                     21240000
HASHAD   DC    A(HSH+4)                                                 21260000
HOLD     DC    2F'0'               WORK AREA                            21280000
HOLD1    EQU   HOLD+4                                                   21300000
WRDLIM   DC    AL4(WERD+300)                                            21320000
LINK     DC    F'0'                HOLD AREA FOR LINK TO GETWORD        21340000
STOR     DC    6F'0'               REG STORAGE AREA FOR GETWORD         21360000
HALF     DC    F'0'                FOR LOADING UP POINTS. THE FIRST TWO 21380000
*                                 BYTES MUST REMAIN ZERO                21400000
         DC    0D'0'                                                    21420000
WERD     DC    300X'0'             WORK AREA FOR QUALIFICATION          21440000
ZERO     DC    F'0'                                                     21460000
CVD      DC    D'0'                USED FOR CONVERSION OF ASSIGNED SEG. 21480000
BLANK    EQU   *                   USE EDIT MASK FOR CONSTANT BLANKS    21500000
EDMX     DC    C'         '        ED. MASK FOR ASSIGNED SEQ NO ON LIST 21520000
         DC    X'2020202120'       MORE OF EDIT MASK                    21540000
         DC    C'   '              LAST OF EDIT MASK                    21560000
NCSEQ    DC    6C' '               STORE SEQ FIELD HERE FOR INCLUDE     21580000
SEQ      DC    6C' '               HOLD AREA FOR SOURCE SEQ. NO.        21600000
RSEQ     DC    6C' '               RESTORE SEQ FIELD FOR INCLUDE        21620000
         DC    0H'0'               PUT HASH TABLE ON HALF WORD BOUND    21640000
HSH      DC    506X'0'             AREA FOR HASH TABLE                  21660000
NOTESW   DC    X'0'                                                4632 21662017
*                       X'01' FOUND START OF NEW PARAGRAPH         4632 21664017
*                       X'02' NOTE IN MIDDLE OF PARAGRAPH          4632 21666017
NOTE     DC    C'NOTE '                                            4632 21668017
NOTE1    DC    C'NOTE.'                                            4632 21670017
NOTE2    DC    C'NOTE,'                                            4632 21672017
NOTE3    DC    C'NOTE '                                            4632 21674017
NOTE4    DC    C'NOTE'                                             8101 21675020
NOTEPERD DC    C'. '                                               4632 21676017
COMM     EQU   CCOMM                                                    21680000
         CIOPL PMG                                                      21700000
         END   CETPMG                                                   21720000
