*(                                                                      00003017
*2801                                                              8101 00009020
*)                                                                      00015017
*   IBM SYSTEM/360 OPERATING SYSTEM                                   * 00020000
*   COBOL(E) 360S-CO-503                                              * 00040000
*   MODULE IEPSMG00                                                   * 00060000
 TITLE 'IEPSMG00--REPLACES DATA-NAMES WITH DESCRIPT. ATTRIBUTE'         00080000
*STATUS:  CHANGE LEVEL 10                                             * 00100000
*FUNCTION/OPERATION-                                                  * 00120000
*   READS PROCEDURE DIVISION SOURCE CARDS, LISTS THEM, CHECKS SEQUENCE* 00140000
*   AND COMPRESSES THEM INTO A UNIFORM INTERNAL FORMAT. DATA DIVISION * 00160000
*   GENERATED ATTRIBUTES ARE SUBSTITUTED FOR DATA-NAMES, QUALIFICATION* 00180000
*   IS RESOLVED AND ALL INFORMATION NEEDED TO HANDLE FILE-NAMES, 88S, * 00200000
*   AND SUBSCRIPTING IS INCLUDED SO THAT NO SUBSEQUENT PHASE NEED     * 00220000
*   REFER TO ANY DATA DIVISION GENERATED INFORMATION OTHER THAN THAT  * 00240000
*   INCLUDED IN THE OUTPUT OF THIS MERGE PHASE.                       * 00260000
*ENTRY POINTS-                                                        * 00280000
*        CETSMG      CALLING SEQUENCE-          LA    CR15,CPHADR     * 00300000
*                                               SVC   6               * 00320000
*                                       CPHLN   DC    CL8'IEPSMG00    * 00340000
*                                       CPHADR  DC    A(CPHLN)        * 00360000
*INPUT-                                                               * 00380000
*   INPUT IS FROM THE IPT DEVICE ASSIGNED. THE CARD IMAGE IS READ INTO* 00400000
*   THE INPUT AREA WITH REGISTER 1 POINTING TO IT. THIS REGISTER SCANS* 00420000
*   THE AREA ONE WORD AT A TIME NORMALLY BEING STOPPED BY A BLANK.    * 00440000
*   REGISTER 13 HOLDS THE BEGINNING ADDRESS OF THE CURRENT WORD FOR   * 00460000
*   CALCULATIONS THAT WILL BE DONE ON THE WORD, BASICLY GETTING ITS   * 00480000
*   LENGTH.                                                           * 00500000
*OUTPUT-                                                              * 00520000
*   EACH BRANCH TO CPUTA PUTS OUT A RECORD IN THE FOLLOWING FORMAT ON * 00540000
*   FILEA.                                                            * 00560000
*        4 BYTE SRC PLUS WORD OR ATTRIBUTE OF DATA-NAME               * 00580000
*        IF QUALIFIED, SUCH A RECORD GOES OUT FOR EACH QUALIFIED NAME.* 00600000
*        IF A DIAGNOSTIC CONDITION OCCURS, THE RECORD IS PREPARED WITH* 00620000
*        A DUMMY SRC WITH CODE '8D' AND PUTOUT ON FILEC FOR OUTPUTTING* 00640000
*        BY PSYN1.                                                    * 00660000
*EXTERNAL ROUTINES:                                                   * 00680000
*        IJJCPD1   CP LOGIC MODULE.                                   * 00700000
*        IJFWZNZZ  MAGNETIC TAPE LOGIC MODULE.                        * 00720000
*        IJGWZNZZ  SEQUENTIAL DISK LOGIC MODULE.                      * 00740000
*EXITS NORMAL-                                                        * 00760000
*   CEXIT- AT CONCLUSION OF THIS PHASE A BRANCH TO THIS LABEL CAUSES  * 00780000
*          THE NEXT PHASE TO BE FETCHED.                              * 00800000
*EXITS ERROR- N/A                                                     * 00820000
*TABLE/WORK AREAS-                                                    * 00840000
*   HSHTBL- HASH TABLE FOR FINDING DATA-NAME ATTRIBUTES IN ATTRIBUTE  * 00860000
*           TABLE. 506 BYTES LONG                                     * 00880000
*   ATTRIBUTE TABLE- CORE REMAINING BETWEEN A CALCULATED END OF PHASE * 00900000
*           ADDRESS (CCORAD) AND THE BEGINNING ADDRESS OF THE I/O     * 00920000
*           BUFFERS.                                                  * 00940000
*   SEGMENT POINTER TABLE- 150 BYTE TABLE TO GIVE THE POINTER TO CALL * 00960000
*        IN SEGMENTED ATTRIBUTE TABLES.                               * 00980000
*ATTRIBUTES- N/A                                                      * 01000000
*NOTES-                                                               * 01020000
*   1-   BECAUSE THIS PHASE DOES NOT HAVE THE CAPABILITY TO KNOW ABOUT* 01040000
*        A NOTE PARAGRAPH/STATEMENT, IT WILL DIAGNOSE CONDITIONS OR   * 01060000
*        WORDS THAT WOULD BE INVALID IN A PROCEDURE DIVISION STATEMENT* 01080000
*        FOR THIS REASON, ALL DIAGNOSTICS GENERATED BY THE MERGE PHASE* 01100000
*        ARE SENT TO PSYN1 WHERE THEY CAN BE SCREENED.                * 01120000
*   2-   THE ABILITY TO READ INPUT FROM A SOURCE STATEMENT LIBRARY IN * 01140000
*        CONJUNCTION WITH AN INCLUDE VERB IS IMPLIMENTED IN THIS PHASE* 01160000
*   3-   IF SMG HAS BEEN FETCHED, IT MEANS THAT ENOUGH CORE WAS NOT   * 01180000
*        AVAILABLE TO HOLD THE HASH TABLE AND THE COMPLETE ATTRIBUTE  * 01200000
*        TABLE AT ONE TIME. THE BLD PHASE HAS EARLIER DETERMINED THIS * 01220000
*        AND HAS SET UP THE SEGMENT POINTER TABLE AND MAX. ATTRIBUTE  * 01240000
*        TABLE LENGTH. IT HAS ALSO BUILT THE TABLES AND STORED THEM ON* 01260000
*        AN EXTERNAL I/O DEVICE FROM WHICH SMG WILL CALL THEM IN.     * 01280000
*                                                                       01300000
*                                                                       01320000
         CIOP  PHASE=SMG,ENTRY=PMGBEG,OUTREG=9,EOFIPT=ENDCD,           C01340000
               NFLIB=NCBAD,EOFLIB=NCEND                                 01360000
PMGBEG   L     W2,CCOMM                                                 01380000
         OI    USEGS(W2),X'40'    TURN ON SEG SW IN AREA FOR STAT I000E 01390018
XSEG     EQU   X'40'               POSITION IN USWCH FOR SEGMENTED TABL 01400000
XTRC     EQU   X'80'               POSITION IN USWCH FOR TRACE SWITCH   01420000
         BAL   L1,COPEN                                                 01440000
         DC    X'0'                                                     01460000
         DC    X'0'                                                     01480000
         DC    X'20'                                                    01500000
         DC    X'0'                EXPLICIT SLACK BYTE FOR IMA          01520000
         LA    P1,HSH              POINT TO HASH TABLE AREA             01540000
         BAL   L1,CREAD                                                 01560000
         L     P1,CCORAD           POINT TO TABLE CORE                  01580000
         TM    USWCH(W2),XSEG      IS TABLE SEGMENTED                   01600000
         BZ    PRE1                IF NO SKIP                           01620000
         LA    P1,USTSZ+4(P1)      ELSE BUMP PAST SEG TABLE AREA        01640000
PRE1     ST    P1,TABAD            AND STORE ADR OF ATTRIB. TABLE PREFI 01660000
         BAL   L1,CREAD                                                 01680000
         LA    P1,4(P1)            LOAD ACTUAL ADR OF ATTRIBUTE TABLE   01700000
         ST    P1,BSE              AND STORE IT                         01720000
         TM    USWCH(W2),XSEG      IS TABLE SEGMENTED                   01740000
         BZ    MERGE               IF NO SKIP                           01760000
         OI    SWITCH,X'80'        ELSE SET SEG SWITCH                  01780000
         L     P1,CCORAD           POINT TO SEG TABLE AREA IN FRONT     01800000
         MVC   0(4,P1),USGTB(W2)   MOVE NOTEWORD TO F.W. BOUND          01820000
         LR    W1,P1               POINT TO NOTEWORD                    01840000
         BAL   L1,CREAD            GO READ SEGMENT TABLE                01860000
         LA    P1,4(P1)            POINT TO ENTRY FOR FIRST SEG         01880000
         ST    P1,INSEG            STORE POINTER TO LOADED SEG ENTRY    01900000
*            ****************************                               01920000
*            ****************************                               01940000
*            *******               ******                               01960000
*            *******     MERGE     ******                               01980000
*            *******               ******                               02000000
*            ****************************                               02020000
*            ****************************                               02040000
*                    GETWORD                                            02060000
*          THE PMRG GETWORD IS A ROUTINE WHICH HANDLES THE READING,     02080000
*    LISTING, AND SCAN FUNCTIONS FOR THE PMRG PHASE.  A DESCRIPTION     02100000
*    OF ITS OPERATION FOLLOWS.                                          02120000
*          A BAL TO GETWORD WILL CAUSE THE NEXT SOURCE WORD TO BE       02140000
*    PLACED IN A WORK AREA, AND THE POSITION AND LENGTH OF THE          02160000
*    FOLLOWING WORD TO BE PLACED IN REGISTERS.  PMRG CAN THEN ALWAYS    02180000
*    EXAMINE TWO WORDS OF SOURCE.                                       02200000
*          THERE ARE CERTAIN WORDS IT IS CONVENIENT FOR GETWORD TO      02220000
*    RECOGNIZE AND OUTPUT WITHOUT RETURNING TO PMRG.  THESE ARE ALPHA   02240000
*    OR NUMERIC WITH DECIMAL LITERALS, AND THE OPERATOR ** . THE WORDS  02260000
*    ,OF, AND ,IN, ALSO ARE OF INTEREST  TO PMRG ONLY AS NEXT WORDS,    02280000
*    AND SO ARE SKIPPED BY GETWORD.                                     02300000
*          TO FIND THE BEGINNING OF A WORD, POSITIONS ARE EXAMINED      02320000
*    UNTIL A NON-BLANK IS FOUND. THIS POSITION IS EXAMINED FOR ,(,  ,   02340000
*    WHICH IS TREATED AS A SEPARATE WORD, OR ,', , WHICH INDICATES A    02360000
*    LITERAL, AND IS NOT TREATED UNTIL THE NEXT TIME.                   02380000
*          OTHERWISE A TRT IS DONE, STARTING AT THIS POSITION, WHICH IS 02400000
*    STOPPED BY . , ) OR BLANK. IF IT IS A . WE THEN CHECK IF THE NEXT  02420000
*    POSITION IS NON-BLANK, IN WHICH CASE IT IS A NUMERIC WITH DECIMAL  02440000
*    LITERAL.  OTHERWISE  WE GO AND CALCULATE ITS LENGTH, LOAD ITS      02460000
*    ADDRESS IN A REGISTER FOR PMRG, AND EXIT, UNLESS TWO WORDS WERE    02480000
*    CALLED FOR BY THE TWO SWITCH. QV.                                  02500000
*          ON THE NEXT ENTRY WE EXAMINE THE WORD WE JUST CALLED THE     02520000
*    NEXT WORD. IF IT WAS A NUMERIC W/DECIMAL LITERAL OR THE OPERATOR   02540000
*    ** WE OUTPUT DIRECTLY AND SET THE ,TWO SWITCH, WHICH TELLS US TO   02560000
*    GET TWO WORDS BEFORE RETURNING.  IF IT WAS ,OF, OR ,IN, WE         02580000
*    SIMPLY SET THE TWO SWITCH, EFFECTIVELY SKIPPING THE WORD. IF IT    02600000
*    WAS THE START OF AN ALPHA LITERAL, WE SET THE TWO SWITCH, AND      02620000
*    HANDLE IT COMPLETELY, INCLUDING POSSIBLE CONTINUATIONS, AND OUTPUT 02640000
*    IT.                                                                02660000
*          IF IT WAS NONE OF THESE, WE MOVE THE WORD TO A WORK AREA AND 02680000
*    GET THE NEXT WORD.                                                 02700000
*      **********************                                           02720000
*      ***  CENTRAL PATH  ***                                           02740000
*      **********************                                           02760000
MERGE    LA    P1,WERD             RESTORE P1                           02780000
         BAL   L1,GETWRD           GO GET ANOTHER WORD                  02800000
MRGIN    CLI   3(P1),X'7'          IS LENGTH LESS THAN SEVEN            02820000
         BNH   MG                  IF NOT HI GO CHECK FOR SPECIAL NAMES 02840000
MRG1     LA    W1,4(0,P1)          SET UP FOR HASH, WORD ADR IN W1      02860000
         SR    C5,C5                                                    02880000
         IC    C5,3(P1)            C5 GETS BYTE COUNT FOR HASH          02900000
         STM   C3,C4,HOLD                                               02920000
         BAL   L1,HASH                                                  02940000
         LM    C3,C4,HOLD                                               02960000
         MVC   CHLOAD+2(2),0(W3)   MOVE HASH TABLE ENTRY FOR LOADING    02980000
         BAL   L1,CHAIN            SEE IF NAME IS ON TABLE              03000000
         C     C2,ZERO             WAS NAME FOUND                       03020000
         BE    MG5                 C2 EQUAL ZERO MEANS NAME NOT FOUND   03040000
         MVC   HOLD3(4),CHSTR                                           03060000
         MVC   OUTP(3),WERD        MOVE PREFIX TO OUTPUT AREA           03080000
         MVI   OUTP+3,X'8'         SET LENGTH TO 8                      03100000
         NI    OUTP,X'1'           CLEAR FLAGS                          03120000
         TM    MSW,X'10'           TEST X SW.                           03140000
         BZ    MRG3                IF NO BR.                            03160000
         BAL   L1,CPUTC            ELSE CPUT WORD FOR EXHIBIT           03180000
MRG3     CH    C4,TWO              IS NEXT WORD LENGTH TWO              03200000
         BE    QUAL                YES. GO SEE IF QUALIFIED             03220000
AMB      TM    OUT+4,X'80'         IS THERE A CHAIN POINTER             03240000
         BO    AMB1                IF HAS ONE SEE IF NAME AMBIGUOUS     03260000
FLNM     TM    OUT,X'F0'           TEST MAJOR CODE                      03280000
         BZ    FLNM1               ALL ZEROS  MEANS FILE OR REC NAME    03300000
T88      IC    W1,OUT+4            LOAD LEVEL AND MBS                   03320000
         LA    W3,3                PUT MASK IN REG                      03340000
         NR    W3,W1               GET MBS IN W3                        03360000
         TM    OUT+4,X'40'         TEST 88 SWITCH                       03380000
         BO    T881                BRANCH IF ON                         03400000
         LA    P1,OUTP             SET OUTPUT POINTER TO ATTRIBUTE      03420000
         BAL   L1,CPUTC            AND GO OUTPUT IT                     03440000
         NI    MSW,X'F7'           CLEAR WRITE SWITCH                   03460000
         C     W3,ZERO             SUBSCRIPTED {                        03480000
         BE    MERGE               NO. RETURN                           03500000
*      ************************                                         03520000
*      ***  SUBSCRIPTING   ****                                         03540000
*      ************************                                         03560000
         LA    C2,OUT              POINT TO ORIG. ATTRIBUTE             03580000
SUB1     TM    5(C2),X'20'         TEST O BIT                           03600000
         BZ    SUB2                NOT ONE GO CHECK UP POINT            03620000
         BAL   L1,PAT              GO OUTPUT ATTRIBUTE POINTED TO BY C2 03640000
         IC    W1,4(C2)            GET LEVEL AND MBS                    03660000
         LA    W3,3                PUT MASK IN REG                      03680000
         NR    W3,W1               GET MBS ONLY IN REG                  03700000
         BCT   W3,SUB2             W3, HAS MBS                          03720000
         B     MERGE                                                    03740000
SUB2     BAL   L1,UPPT2            LOAD UP POINTER                      03760000
         C     C2,LOAD             IS UP POINTER ZERO                   03780000
         BNE   SUB1                IF NOT THEN LOOP                     03800000
         BAL   L1,PDIAGC           DIAGNOSE SUBSCRIPTED NAME WITH       03820000
         DC    X'100C'             INSUFFICIENT UP POINTERS.            03840000
         LA    0,WERD                                                   03860000
         LA    0,WERD+3                                                 03880000
         B     MERGE                                                    03900000
*      ************************                                         03920000
*      ***  QUALIFICATION   ***                                         03940000
*      ************************                                         03960000
QUAL     CLC   0(2,C3),OF          N.W. OF                              03980000
         BE    QUAL1               YES THEN ITS QUALIFIED               04000000
         CLC   0(2,C3),IN          N.W. IN                              04020000
         BNE   AMB                 NO. NOT QUALIFIED SO RETURN          04040000
QUAL1    NI    MSW,X'FE'           TURN OFF FOUND SWITCH                04060000
         SR    S1,S1               CLEAR REG FOR QUALIFIER COUNT        04080000
QUAL2    BAL   L1,QL1              BUMP POINTER TO NXT WORD IN WORK ARE 04100000
         OI    SWITCH,X'01'        SET TWO SWITCH TO BYPASS THE OF OR I 04120000
         BAL   L1,GETWRD           GETWRD                               04140000
         LA    S1,1(S1)            BUMP QUALIFIER COUNT                 04160000
         TM    MSW,X'10'           TEST X SW.                           04180000
         BZ    QUAL2A              IF OFF SKIP                          04200000
         BAL   L1,CPUTC            ELSE CPUTC WORD FOR EXHIBIT VERB     04220000
QUAL2A   CH    C4,TWO              IS NEXT WORD LENGTH TWO              04240000
         BE    QL2                 YES.GO SEE IF MORE QUALIFIERS        04260000
*                                  WHEN QUAL3 IS REACHED ALL QUALIFIERS 04280000
*                                  ARE STACKED IN THE WORD AREA, WITH   04300000
*                                  PREFIXES, AND S1 IS THEIR NUMBER.    04320000
QUAL3    LA    P1,WERD             POINT P1 TO QUALIFIED NAME           04340000
QUAL4    LA    C2,OUT              POINT UPPOINT REG TO CURRENT ATRIBUT 04360000
         LA    S2,0                SET COUNT TO ZERO                    04380000
QL10     BAL   L1,QL1              BUMP POINTER TO NXT WORD IN WORK ARE 04400000
QL7      BAL   L1,UPPT2            LOAD UP POINTER FROM C2              04420000
         C     C2,LOAD             IS UP POINTER ZERO                   04440000
         BE    QL4                 IF YES GO LOOK AT NEXT CHAIN.        04460000
         IC    W1,3(P1)            LOAD LENGTH FOR COMPARE              04480000
         EX    W1,CPR              COMPARE LENGTH AND NAME              04500000
         BNE   QL7                 UNEQUAL. GET NEXT UPPOINTER          04520000
         LA    S2,1(S2)            BUMP COUNT                           04540000
         CLR   S1,S2               WAS THAT LAST QUALIFIER              04560000
         BNE   QL10                                                     04580000
         TM    MSW,X'01'           TEST FOUND SWITCH                    04600000
         BO    QL3                                                      04620000
         OI    MSW,X'01'           SET  FOUND SWITCH                    04640000
         MVC   QSAVE(10),OUT       SAVE ATRIB. WHICH MATCHED HIERARCHY  04660000
QL4      LA    P1,WERD             RESET P1 TO POINT TO QUALIFIED NAME  04680000
         BAL   L1,CHAIN            LOAD CHAIN POINTER                   04700000
         C     C2,ZERO             C2 EQUAL ZERO MEANS NAME NOT FOUND   04720000
         BNE   QUAL4               BR. IF NAME FOUND                    04740000
         TM    MSW,X'01'           TEST FOUND SWITCH                    04760000
         BO    QL6                 BR. IF ON                            04780000
         MVI   D1,X'7'             UNDEFINED HIERARCHY DIAGNOSTIC       04800000
         B     DIAG                GO TO COMMON DIAGNOSTIC ROUTINE      04820000
QL6      MVC   OUT(10),QSAVE       RESTORE ATRIB. WHICH MATCHED         04840000
         B     FLNM                GO TO FILE NAME ROUTINE              04860000
QL1      LA    W1,0                CLEAR WORK REG.                      04880000
         IC    W1,3(P1)            LOAD BYTE COUNT                      04900000
         LA    P1,4(P1,W1)         BUMP P1 TO NEXT QUALIFIER POSITION   04920000
         BR    L1                  RETURN                               04940000
QL2      CLC   0(2,C3),OF                                               04960000
         BE    QUAL2                                                    04980000
         CLC   0(2,C3),IN                                               05000000
         BE    QUAL2                                                    05020000
         B     QUAL3                                                    05040000
QL3      MVI   D1,X'8'             AMBIGUOUS HIERARCHY DIAGNOSTIC       05060000
         B     DIAG                GO TO COMMON DIAGNOSTIC ROUTINE      05080000
*                                  END UP HERE IF  NO UP POINTER        05100000
*      ********************                                             05120000
*      ***  AMBIGUITY   ***                                             05140000
*      ********************                                             05160000
AMB1     MVC   QSAVE(10),OUT       SAVE ORIGINAL ATRIBUTE               05180000
         BAL   L1,CHAIN            SEE IF THERES A SYNONYM              05200000
         MVC   OUT(10),QSAVE       RESTORE ORIGINAL ATRIBUTE            05220000
         MVC   CHSTR(4),HOLD3                                           05240000
         C     C2,ZERO             C2 EQUAL ZERO MEANS NAME NOT FOUND   05260000
         BE    FLNM                IF EQ. THERES NO AMBIGUITY           05280000
         MVI   D1,X'6'             AMBIGUOUS NAME DIAGNOSTIC            05300000
         B     DIAG                GO TO COMMON DIAGNOSTIC ROUTINE      05320000
*      ********************                                             05340000
*      ***  FILE NAME   ***                                             05360000
*      ********************                                             05380000
FLNM1    CLI   OUT,X'0D'           MINOR CODE FD                        05400000
         BNE   RCNM                NO. CHECK FOR REC NAME               05420000
       TM    MSW,X'8'             WRITE FILE-NAME...               7637 05422013
       BZ    FLNM4                NO                               7637 05424013
       BAL   L1,PDIAGC            YES, ISSUE MESSAGE               7637 05426013
       DC    X'21BC'              NUMBER 444, EXPECT 2 TRAILERS    7637 05428013
       LA    0,WERD               POS/SEQ                          7637 05430013
       LA    0,WRITE              CLAUSE    (TRAILER 1)            7637 05432013
       LA    0,WERD+3             FILE-NAME    (TRAILER 2)         7637 05434013
FLNM4  EQU   *                    ACCEPT AS IS                     7637 05436013
         LA    P1,OUTP             SET OUTPUT POINTER TO ATTRIBUTE      05440000
         BAL   L1,CPUTC            AND GO OUTPUT IT                     05460000
         NI    MSW,X'F7'           CLEAR WRITE SWITCH                   05480000
         SR    W2,W2                                                    05500000
         L     C2,CHSTR            LOAD CURRENT REL. ADR                05520000
         IC    W2,WERD+3           LOAD BYTE COUNT OF CURRENT NAME      05540000
         LA    C2,11(W2,C2)        BUMP TO REL. ADR OF NEXT ENTRY       05560000
         TM    OUT+4,X'80'         TEST FOR PRESENCE OF CHAIN POINTER   05580000
         BZ    FLNM2               IF NONE SKIP                         05600000
         LA    C2,2(C2)            ELSE ADJUST FOR CHAIN POINTER        05620000
FLNM2    TM    SWITCH,X'80'        IS TABLE SEGMENTED                   05640000
         BZ    FLNM3               IF NO SKIP                           05660000
         BAL   L1,ITER             ELSE GET PROPER SEG                  05680000
FLNM3    A     C2,BSE              ADD TABLE ADR TO DISPLACEMENT        05700000
         BAL   L1,PAT              GO OUTPUT ATTRIBUTE POINTED TO BY C2 05720000
         B     MERGE                                                    05740000
*      **********************                                           05760000
*      ***  RECORD NAME   ***                                           05780000
*      **********************                                           05800000
RCNM     TM    OUT+4,X'4'          TEST LEVEL 1 SWITCH                  05820000
         BZ    T88                 IF OFF NOT RECORD, SO RETURN         05840000
         TM    MSW,X'8'            TEST WRITE SWITCH                    05860000
         BZ    RCNM1               IF OFF ITS NOT FOR A WRITE VERB      05880000
         BAL   L1,UPPT             LOAD UP POINTER                      05900000
         C     C2,LOAD             IS UP POINTER ZERO                   05920000
         BE    RCNM4               YES. GO FLAG ERROR                   05940000
         BAL   L1,PAT              GO OUTPUT ATTRIBUTE POINTED TO BY C2 05960000
RCNM1    LA    P1,OUTP             SET OUTPUT POINTER TO ATTRIBUTE      05980000
         BAL   L1,CPUTC            AND GO OUTPUT IT                     06000000
         NI    MSW,X'F7'           CLEAR WRITE SWITCH                   06020000
         B     MERGE                                                    06040000
RCNM4    MVI   D1,X'0D'            RECORD NAME W/O UP POINTER DIAGNOSTI 06060000
         B     DIAG                GO TO COMMON DIAGNOSTIC ROUTINE      06080000
*      ******************                                               06100000
*      ***     88 S   ***                                               06120000
*      ******************                                               06140000
T881     BAL   L1,UPPT             LOAD UP POINTER                      06160000
         C     C2,LOAD             IS UP POINTER ZERO                   06180000
         BE    T884                YES. GO FLAG ERROR                   06200000
         MVC   G88(3),0(P1)        MOVE IN ORIGINAL PREFIX              06220000
         MVC   G88+4(8),OUT        STORE CONDITION NAME ATTRIBUTE       06240000
         MVC   B88(3),G88          PUT PREFIX ON OPERATOR               06260000
         NI    G88,X'01'           CLEAR FLAGS                          06280000
         BAL   L1,PAT              GO OUTPUT ATTRIBUTE POINTED TO BY C2 06300000
         TM    4(C2),X'03'         IS CONDITION NAME POINTING TO A      06320000
*                                 SUBSCRIPTED NAME.                     06340000
         BC    5,T885              IF YES GO SET SWITCH AND HANDLE THE  06360000
*                                 SUBSCRIPTING BEFORE OUTPUTTING REST   06380000
*                                   OF 88 INFORMATION                   06400000
T883     LA    P1,B88              POINT TO OPERATOR                    06420000
         BAL   L1,CPUTC                                                 06440000
         LA    P1,G88                                                   06460000
         BAL   L1,CPUTC            OUTPUT CONDITION ATTRIBUTE           06480000
         B     MERGE                                                    06500000
T884     MVI   D1,X'10'            88 W/O UP POINTER DIAGNOSTIC         06520000
         B     DIAG                GO TO COMMON DIAGNOSTIC ROUTINE      06540000
T885     OI    MSW,X'02'           SET  88 SWITCH                       06560000
         B     SUB1                GO DO SUBSCRIPTING ROUTINE BEFORE 88 06580000
*        *****************************                                  06600000
*        *********  CHAIN ROUTINE  ***                                  06620000
*        *****************************                                  06640000
*        W3 IS  LINK REG                                                06660000
*        P1  I S NAME AND PREFIX ADR                                    06680000
*        C1 IS  ADR OF OLD ATTRIBUTE                                    06700000
*        AND W ILL EITHOR HAVE ADR OF NEW ATTRIBUTE                     06720000
*        IF ON E IS FOUND OR WILL BE SET TO ZERO                        06740000
CHAIN    L     C2,CHLOAD           LOAD CHAIN POINT THAT WAS STORED     06760000
         CH    C2,CHLOAD           IS IT ZERO                           06780000
         BCR   8,L1                IF YES RETURN                        06800000
         ST    C2,CHSTR            ELSE STORE CURRENT REL. ADR.         06820000
         TM    SWITCH,X'80'        IS TABLE SEGMENTED                   06840000
         BZ    CHAIN2              IF NOT SKIP                          06860000
         ST    L1,LINK             ELSE STORE LINK                      06880000
         BAL   L1,ITER             AND GET PROPER SEG IN CORE           06900000
         L     L1,LINK             RESTORE LINK                         06920000
CHAIN2   A     C2,BSE              ADD TABLE BASE TO REL. ADR.          06940000
         TM    4(C2),X'80'         IS THERE A CHAIN POINT               06960000
         BZ    DEAD                IF NOT THEN BRANCH TO SO INDICATE    06980000
         LA    W2,0                ELSE ZERO A WORK REG                 07000000
         IC    W2,10(C2)           LOAD BYTE COUNT OF CURRENT NAME      07020000
         LA    W2,11(W2,C2)        POINT W2 TO CHAIN POINTER            07040000
         MVC   CHLOAD+2(2),0(W2)   STORE CHAIN  POINTER FOR NEXT CHAIN  07060000
CHAIN3   IC    C5,3(P1)            LOAD BYTE COUNT OF SOURCE NAME       07080000
         EX    C5,CPR              COMPARE TABLE NAME TO SOURCE NAME    07100000
         BNE   CHAIN               UNEQ. THEN GET NEXT NAME ON CHAIN    07120000
         MVC   OUT(10),0(C2)       ELSE STORE ATTRIBUTE                 07140000
         BR    L1                  AND EXIT                             07160000
DEAD     MVC   CHLOAD+2(2),CHLOAD  ZERO HOLD AREA FOR CHAIN POINTER     07180000
         B     CHAIN3              AND GO CHECK CURRENT ENTRY           07200000
*      ************************                                         07220000
*      ***  MISCELLANEOUS   ***                                         07240000
*      ************************                                         07260000
UPPT2    MVC   HALF+2(2),8(C2)     MOVE C2 UP POINT FOR LOADING         07280000
         B     UPX                 AND GO TO NORMAL UP POINT            07300000
UPPT     MVC   HALF+2(2),OUT+8     MOVE CURRENT UP POINTER FOR LOADING  07320000
UPX      L     C2,HALF             LOAD UP POINT                        07340000
         CH    C2,HALF             IS IT ZERO                           07360000
         BCR   8,L1                IF YES RETURN                        07380000
         TM    SWITCH,X'80'        IS TABLE SEGMENTED                   07400000
         BZ    UP2                 IF YES SKIP                          07420000
         ST    L1,LINK             ELSE STORE LINK ADR                  07440000
         BAL   L1,ITER             GO ASSURE THAT PROPER SEG IS LOADED  07460000
         L     L1,LINK             RESTORE LINK                         07480000
UP2      A     C2,BSE              ADD TABLE BASE TO RELATIVE ADR       07500000
         BR    L1                  RETURN                               07520000
PAT      MVC   WERD+4(8),0(C2)     MOVE ATRIB. POINTED TO BY C2 IN      07540000
*                                   FRONT OF PREFIX IN WORK AREA.       07560000
         MVI   WERD+3,X'8'         MOVE IN BYTE COUNT                   07580000
         NI    WERD,X'1'           CLEAR FLAGS                          07600000
         NI    MSW,X'F7'           CLEAR WRITE SWITCH                   07620000
         LA    P1,WERD             POINT OUTPUT REG TO WERD             07640000
         ST    L1,LINK             STORE RETURN ADR                     07660000
         BAL   L1,CPUTC            GO OUTPUT ATTRIBUTE                  07680000
         L     L1,LINK             OAD RETURN ADR                       07700000
         BR    L1                  AND RETURN                           07720000
MG       CLI   3(P1),X'1'          LENGTH OF ONE                        07740000
         BE    MG1                                                      07760000
         CLI   3(P1),X'00'                                              07780000
         BE    MERGE                                                    07800000
         CLC   3(5,P1),THEN        IS THIS THE WORD THEN                07820000
         BE    MERGE               IF YES SKIP IT                       07840000
         CLC   3(6,P1),WRITE       IS THIS A WRITE VERB                 07860000
         BE    WRT                 IF YES GO SET SWITCH                 07880000
         CLC   3(8,P1),REWRIT      IS THIS A REWRITE VERB               07900000
         BE    WRT                 IF YES, GO SET SWT                   07920000
         CLC   3(8,P1),NCLUDE      IS THIS AN INCLUDE VERB              07940000
         BE    NCLD     IF YES, GO SET UP FOR A LIBRARY CALL       4632 07960017
         CLC   3(8,P1),XIBIT       IS THIS AN EXHIBIT VERB              07980000
         BE    XBT                 IF YES GO SET SWITCH FOR EXTRA OUTPU 08000000
         CLC   3(6,P1),TRACE       IS THIS A TRACE VERB                 08020000
         BE    TRC                                                 000B 08022016
         SR    C5,C5                                               000B 08024016
         IC    C5,3(P1)                                            000B 08026016
         LR    W1,C5                                               000B 08028016
         IC    C5,FINDTB-2(C5)   C5 HAS ADDR OF DICT ENTRY         000B 08030016
         LA    C5,FINDTB(C5)                                       000B 08032016
         SH    W1,ONE                                              000B 08034016
COMPREWD EX    W1,COMPAR                                           000B 08036016
         BE    MG5                                                 000B 08038016
         LA    C5,1(C5,W1)        BUMP POINTER TO NEXT WORD        000B 08040016
         CLI   0(C5),X'FF'                                         000B 08042016
         BNE   COMPREWD                                            000B 08044016
         B     MRG1            BRANCH TO HASH TABLE                000B 08046016
COMPAR   CLC   0(0,C5),4(P1)            WORD COMPARE               000B 08048016
TRC      L     W1,CCOMM            LOAD ADR. OF COMM AREA               08060000
         OI    USWCH(W1),XTRC      SET TRACE SWITCH IN COMM REGION      08080000
         B     MG5                 AND GO OUTPUT                        08100000
WRT      OI    MSW,X'8'            SET WRITE SWITCH SO THAT WE OUTPUT   08120000
         B     MG5A                                                     08140000
NCLD     TM    MSW,X'4'            ARE WE ALREADY IN LIBRARY MODE.      08160000
         BZ    NC3                 NO--                                 08180000
         BAL   L1,PDIAGC           YES--DIAGNOSE INCLUDE W/IN LIBRARY   08200000
         DC    X'0017'                                                  08220000
         LA    0,WERD                                                   08240000
         B     MERGE                                                    08260000
NC3      OI    MSW,X'4'                 SET LIBRARY NAME SWITCH         08280000
         BAL   L1,GETWRD           GET LIBRARY NAME                     08300000
         NI    MSW,X'FB'           TURN OFF LIBRARY NAME SWITCH         08320000
         CLI   0(C3),C'.'          IS NEXT WORD PERIOD                  08340000
         BE    NC1                 IF YES OK                            08360000
         BAL   L1,PDIAGC           ELSE DIAGNOSE                        08380000
         DC    X'1018'             NO PERIOD AFTER MEMBER NAME          08400000
         LA    0,WERD                                                   08420000
         LA    0,WERD+3                                                 08440000
NC1      CLI   WERD+3,X'08'        IS LIBRARY NAME TOO LONG--OVER  8 CH 08460000
         BH    NCBAD               YES--DIAGNOSE AND GET NEXT CARD      08480000
         BAL   L1,CFIND            LOCATE ENTRY                         08500000
         L     C5,STOR+12          LOAD SEQ NO (ASSIGNED)               08520000
         OI    SWITCH,X'21'        SET TWO SWITCH AND LIB SWITCH        08540000
         MVC   NCSEQ(12),SEQ       STORE AND RESET SOURCE SEQ NO        08560000
NC2      LA    L1,MRGIN            LOAD RETURN ADR                      08580000
         ST    L1,LINK                                                  08600000
         B     READ                GO GETWORD                           08620000
BADNAM   NI    SWITCH,X'E1'                                             08640000
         MVI   TABLE+C' ',X'1'                                          08660000
         MVI   TABLE+C'.',X'2'                                          08680000
         MVI   TABLE+C',',X'4'                                          08700000
         MVI   TABLE+C';',X'3'                                          08720000
         MVI   TABLE+C')',X'3'                                          08740000
         MVI   TABLE+C'''',X'0'                                         08760000
NCBAD    BAL   L1,PDIAGC           DIAGNOSE UNFOUND MEMBER NAME         08780000
         DC    X'0020'                                                  08800000
         LA    0,WERD                                                   08820000
         OI    SWITCH,X'01'                                             08840000
NCEND    NI    SWITCH,X'DF'        TURN OFF LIB SWITCH                  08860000
         MVC   SEQ(4),NCSEQ        RESTORE SEQ FIELD FROM SOURCE        08880000
         NI    MSW,X'FB'           TURN OFF LIBRARY NAME SWITCH         08900000
         B     NC2                 READ NEXT CARD                       08920000
XBT      OI    MSW,X'10'           SET EXHIBIT SWITCH                   08940000
         NI   MSW,X'DF'           TURN OFF LEFT PARAN SW FOR EXHIBIT    08960000
         B     MG5                 AND GO OUTPUT                        08980000
MG1      CLI   4(P1),X'7F'         OPERATOR OR PUNCTUATION {            09000000
         BH    MRG1                NO. THEN RETURN                      09020000
         BAL   L1,CPUTC            OUTPUT OPERATOR                      09040000
         CLI   4(P1),C'('          LEFT PARAM                           09060000
         BE    HART1               YES                                  09080000
         CLI   4(P1),C')'          RIGHT PARAM                          09100000
         BE    HART2               YES                                  09120000
         CLI   4(P1),C'.'          IS IT A PERIOD                       09140000
         BNE   MG2                 IF NO SKIP                           09160000
         NI   MSW,X'CF'           TURN OFF X SW & LEFT PARAN SW         09180000
*                                 A PERIOD INDICATES                    09200000
*                                   THE END OF AN EXHIBIT VERBS RANGE.  09220000
MG2      TM    MSW,X'2'            IS 88 SWITCH ON                      09240000
         BZ    MERGE               OFF.  RETURN                         09260000
         CLI   4(P1),C')'          IS THE CHARACTER A RIGHT PAREN       09280000
         BNE   MERGE                                                    09300000
         NI    MSW,X'FD'                                                09320000
         B     T883                                                     09340000
HART1    TM    MSW,X'10'           IS EXHIBIT SW ON                     09360000
         BZ    MG2                 NO                                   09380000
HART3    XI    MSW,X'30'           TURN EXHIBIT SW OFF BUT INDICATE     09400000
         B     MG2                 BY TURNING LEFT PARAM SW ON          09420000
HART2    TM    MSW,X'20'           IS LEFT PARAM SW ON                  09440000
         BZ    MG2                 NO                                   09460000
         B     HART3               RESET EXHIBIT & LEFT PARAM SWS       09480000
CPR      CLC   3(,P1),10(C2)                                            09500000
MG5      NI    MSW,X'F7'           CLEAR WRITE SWITCH                   09520000
MG5A     BAL   L1,CPUTC                                                 09540000
         B     MERGE                                                    09560000
DIAG     BAL   L1,PDIAGC           COMMON DIAGNOSTIC ROUTINE            09580000
         DC    X'10'               INDICATES ONE INSERTION WORD         09600000
D1       DC    X'0'                ROUTINES MOVE IN CODE BYTE BEFORE    09620000
         LA    0,WERD              WORK AREA,, ADR OF SRC               09640000
         LA    0,WERD+3            ADR OF WORD IN WORK AREA AFTER SRC   09660000
         LA    P1,OUTP             SET OUTPUT REG TO PROPER AREA        09680000
         OI    OUT,X'70'           SET ERROR MAJOR CODE IN ATTRIBUTE    09700000
         BAL   L1,CPUTC            OUTPUT ERROR ATRIBUTE                09720000
         B     MERGE               GO HANDLE NEXT WORD                  09740000
*      ***********************                                          09760000
*      ***  HASH ROUTINE   ***                                          09780000
*      ***********************                                          09800000
RWORD    EQU   10                                                       09820000
RNDX     EQU   11                                                       09840000
RQUT     EQU   12                                                       09860000
RADD     EQU   13                                                       09880000
RFOUR    EQU   14                                                       09900000
RCNT     EQU   15                                                       09920000
LOAD     DC    F'0'                                                     09940000
         DC    F'0'                                                     09960000
         DC    F'0'                                                     09980000
         DC    F'4'                                                     10000000
PRIME    DC    F'251'                                                   10020000
HASH     LM    RNDX,RFOUR,LOAD                                          10040000
         BCTR  RCNT,0                                                   10060000
LOOP     AL    RADD,0(RNDX,RWORD)                                       10080000
         BXLE  RNDX,RFOUR,LOOP                                          10100000
         D     RQUT,PRIME                                               10120000
         AR    RQUT,RQUT                                                10140000
         AL    RQUT,HASHAD                                              10160000
         ST    RQUT,HSHDBG             STORE RESULT FOR DEBUGING ONLY   10180000
         BCR   15,L1                                                    10200000
HSHDBG   DC    F'0'                    DEBUGING USE ONLY                10220000
ITER     STM   L1,W1,HOLD                                               10240000
         L     W1,INSEG            W1 POINTS TO ENTRY FOR CURRENT SEG   10260000
         MVC   HALF+2(2),10(W1)    LO(I+1) TO FW FIELD                  10280000
         C     C2,HALF             COMPARE A TO LO(I+1)                 10300000
         BNL   IT3                 IF HI WANT HIGHER SEG THAN IS NOW    10320000
*                                  LOADED IN CORE.                      10340000
         MVC   HALF+2(2),4(W1)     LO(I) TO FW FIELD                    10360000
         S     C2,HALF             CALC  A - LO(I)                      10380000
         BM    IT5                 IF MINUS WANT LOWER SEG THAN IS NOW  10400000
*                                  LOADED IN CORE                       10420000
IT2      LA    C2,1(C2)            C2 IS A - LO(I) + 1                  10440000
         LM    L1,W1,HOLD                                               10460000
         BR    L1                                                       10480000
IT3      LA    W1,6(W1)            BUMP LO TABLE INDEX TO NEXT ENTRY    10500000
         MVC   HALF+2(2),10(W1)    LO(I+1) TO FW BOUND                  10520000
         C     C2,HALF             COMPARE A TO LO(I+1)                 10540000
         BNL   IT3                 LOOP TILL HIGH, AT WHICH TIME W1 WIL 10560000
*                                  POINT TO ENTRY FOR CORRECT SEGMENT   10580000
IT4      MVC   HALF+2(2),4(W1)     LO(I) TO FW BOUND                    10600000
         S     C2,HALF             CALC  A - LO(I)                      10620000
         ST    W1,INSEG            STORE POINTER TO CURRENT SEG         10640000
         L     P1,TABAD            POINT TO SEGMENT INPUT AREA          10660000
         BAL   L1,CREAD            GO READ CORRECT SEGMENT              10680000
         B     IT2                                                      10700000
IT5      A     C2,HALF             RESTORE A                            10720000
IT6      SH    W1,SIX              REDUCE TABLE POINTER                 10740000
         MVC   HALF+2(2),4(W1)     LO(I) TO FW                          10760000
         C     C2,HALF             COMPARE A TO LO(I)                   10780000
         BL    IT6                 LOOP TILL HI OR EQ, AT WHICH TIME    10800000
*                                  W1 POINTS TO ENTRY FOR CORRECT SEG.  10820000
         B     IT4                                                      10840000
         CIOPC SMG,A                                                    10860000
*            *******************************                            10880000
*            *******************************                            10900000
*            *******                 *******                            10920000
*            *******     GETWORD     *******                            10940000
*            *******                 *******                            10960000
*            *******************************                            10980000
*            *******************************                            11000000
*      **************************                                       11020000
*      ***  AUDIT  FUNCTION  ****                                       11040000
*      **************************                                       11060000
GETWRD   ST    L1,LINK             SAVE LINK ADDRESS FOR RETURN         11080000
FSW      BC    15,FIRST            BRANCH FIRST TIME ONLY. THEN NO-OP   11100000
         LM    W3,C1,STOR          LOAD PERM. REGS                      11120000
AUDIT    EQU   *                   CONSTRUCT SRC FOR CURRENT WORD       11140000
         IC    W1,FLAGS            LOAD CODE FLAGS                      11160000
         SLL   W1,4                SHIFT TO MAKE ROOM FOR POSITION NO.  11180000
         N     C0,TRNC                                                  11200000
         OR    W1,C0               OR IN POSITION NUMBER                11220000
         SLL   W1,12               SHIFT TO MAKE ROOM FOR SEQUENCE NO.  11240000
         OR    W1,C5               OR IN SEQUENCE NUMBER                11260000
         ST    W1,HOLD1            STORE IN WORK AREA                   11280000
         TM    SWITCH,X'1'                                              11300000
         BO    AUD5                                                     11320000
         LA    W1,4(P1,C4)                                              11340000
         C     W1,WRDLIM                                                11360000
         BNL   AUD7                                                     11380000
AUD5     MVC   0(3,P1),HOLD1+1                                          11400000
         STC   C4,3(P1)            STORE LENGTH IN SRC                  11420000
*                                                                 22061 11422000
*                                                                 22061 11424000
*                                                                 22061 11426000
*                                                                 22061 11428000
*                                                                 22061 11430000
*                                                                 22061 11432000
*                                                                 22061 11434000
*                                                                 22061 11436000
*                                                                 22061 11438000
         EX    C4,INST1            MOVE NEXT WORD TO WORD AREA          11440000
         CH    C4,THIRTY           IS WORD TOO LONG                     11460000
         BNH   AUD6                IF NOT SKIP                          11480000
         BAL   L1,PDIAGC           DIAGNOSE WORD GREATER THAN 30 BYTES. 11500000
         DC    X'1005'                                                  11520000
         LA    0,0(P1)                                                  11540000
         LA    0,3(P1)                                                  11560000
         MVI   3(P1),X'1E'         TRUNCATE LENGTH TO MAX OF 30         11580000
         LA    C4,30               LOAD MAXIMUM LENGTH                  11600000
AUD6     LA    W1,4(C4,P1)                                              11620000
         MVC   0(4,W1),ZERO                                             11640000
         AH    C0,ONE              BUMP POSITION ON CARD COUNTER        11660000
         TM    FLAGS,X'0E'         WORD FLAGS ALL ZERO                  11680000
         BC    4,AUD1              IF NO THEN BR.                       11700000
         CH    C4,TWO              IS NEXT WORD LENGTH TWO              11720000
         BE    AUD2                THEN GO CHECK                        11740000
*      **************************                                       11760000
*      ***  SEARCH FUNCTION  ****                                       11780000
*      **************************                                       11800000
SCH1     SR    C4,C4               RESTORE LENGTH                       11820000
         MVI   FLAGS,X'80'         RESTORE FLAGS                        11840000
         B     SCH                                                      11860000
BUMP     LA    C1,1(C1)            BUMP POINTER TO NXT POS ON CARD      11880000
SCH      CLR   C1,W3               OFF CARD {                           11900000
         BH    READ                YES. GO READ                         11920000
         CLI   0(C1),C' '          IS THIS A BLANK                      11940000
         BE    BUMP                YES. GO BUMP REG                     11960000
         LR    C3,C1               STORE BEG. ADR                       11980000
         CLI   0(C1),X'7F'                                              12000000
         BL    SCH12                                                    12020000
         TM    NOTESW,X'4'   1ST TIME THRU MEANS STILL IN          4632 12021017
         BO    NOTNOTE1      PARAGRAPH NAME RTN                    4632 12022017
         CLC   0(5,C1),NOTE  NOTE STMT                             4632 12023017
         BE    YESNOTE                                             4632 12024017
         CLC   0(5,C1),NOTE1 'NOTE.'                               4632 12025017
         BE    YESNOTE                                             4632 12026017
         CLC   0(5,C1),NOTE2 'NOTE,'                               4632 12027017
         BE    YESNOTE                                             4632 12028017
         CLC   0(5,C1),NOTE3 'NOTE '                               4632 12029017
         BE    YESNOTE                                             8101 12029220
         CLC   0(4,C1),NOTE4                                       8101 12029420
         BE    YESNOTE                                             8101 12029620
         BNE   NOTNOTE       NO                                    4632 12030017
YESNOTE  EQU   *                                                   4632 12031017
         TM    NOTESW,X'01'  IS NOTE 1ST IN PARAGRAPH              4632 12032017
         BO    NOTEPAR             YES, READ UNTIL NEXT PARAGRAPH 22061 12033000
         OI    NOTESW,X'2'   NO, READ UNITL NEXT PRIOD             4632 12034017
         B     NEXTPERD                                            4632 12035017
NOTEPAR  OI    NOTESW,X'08'        A NOTE PARAGRAPH               22061 12035200
         NI    NOTESW,X'FE'        TURN OFF NEW PARAGRAPH SWITCH  22061 12035400
         B     READ                                               22061 12035600
NOTNOTE  EQU   *                                                   4632 12036017
         NI    NOTESW,X'FE'  TURN OFF IF NOTE NOT 1ST IN PARA      4632 12037017
NOTNOTE1 NI    NOTESW,X'F9'                                       22061 12038000
         CLC   3(8,P1),NCLUDE      SHOULD C1 POINT AT A QUOTE           12040000
         BNE   DEF                 FOR THE START OF A LIBRARY NAME      12060000
         MVI   3(P1),X'00'         STOP EQUAL COMPARE 2ND TIME          12080000
         B    NCBAD                                                     12100000
NEXTPERD CLR   C1,W3               IS IT IN COL 72                22061 12101000
         BE    CKPERD              YES                            22061 12102000
         LA    C1,1(C1)            NOT IN COL 72                  22061 12103000
         CLR   C1,W3         OFF CARD                              4632 12104017
         BH    READ          YES, READ PHYSICAL CARD               4632 12106017
         CLC   0(2,C1),NOTEPERD        IS THIS A PERIOD-BLANK      4632 12108017
         BNE   NEXTPERD      NO, CONTINUE SEARCH                   4632 12110017
PERDEND  NI    NOTESW,X'FD'        YES                            22061 12112000
         OI    MSW,X'40'     PERIOD FOUND SW                       4632 12114017
         B     BUMP          RETURN TO MAIN ROUTINE                4632 12116017
CKPERD   CLC   0(1,C1),NOTEPERD    IS COL 72 A PERIOD             22061 12117000
         BNE   READ                NO, READ A CARD                22061 12118000
         B     PERDEND             YES, PERIOD FOUND              22061 12119000
*      **************************                                       12120000
*      ***  DEFINE FUNCTION  ****                                       12140000
*      **************************                                       12160000
DEF      LR    W1,W3                                                    12180000
         SR    W1,C1                                                    12200000
         BM    DEF6                BR. ON MINUS                         12220000
         LA    C2,0                ZERO THE RESULT REG FOR TRT INSTR.   12240000
         EX    W1,INST2            TRT                                  12260000
         BC    8,DEF9              BR. ON CC0                           12280000
         CH    C2,THIRTY           SPECIAL TEST CHAR TO SEE IF IN       12300000
         BE    BADNAM              INCLUDE LIBRARY NAME MODE AND NAME   12320000
*                                  SCAN STOPPED BY A BLANK              12340000
         TM    SWITCH,X'02'        LIT SWITCH ON                        12360000
         BC    1,DEF3              YES. BR.                             12380000
         CH    C2,ONE              DELIMITER BYTE A BLANK               12400000
         BE    FINE                                                     12420000
         CH    C2,THREE            DELIMITER BYTE A RT PAREN/SEMICOLON  12440000
         BE    FINE                                                     12460000
         L    L1,CCOMM                                                  12480000
         CLI   UPOIN(L1),X'6B'     IF IN INVERTED PRINT EDIT MODE       12500000
         BE    INPTED              CHECK COMMAS FOR DECIMAL POINTS      12520000
         CH    C2,FOUR             DELIMITER BYTE A COMMA               12540000
         BNE   DEF8                                                     12560000
         CLR   C1,W3               IS COMMA IN COL. 72                  12580000
         BE    FINE                                                     12600000
         MVI   MESAGE+1,X'0A'                                           12620000
         BAL   W2,TSTBLK           SEE IF FOLLOWED BY A BLANK           12640000
         B     FINE                                                     12660000
DEF8     CH    C2,TWO              DELIMITER BYTE A PERIOD              12680000
         BNE   DEF4                ANYTHING ELSE IS UNPRINTABLE         12700000
         CLR   C1,W3               IS PERIOD IN COL. 72                 12720000
         BE    FINE1               IF YES IT CAN'T BE IMBEDDED WD. 4484 12740015
IMBED    CLI   1(C1),C' '          ELSE CHK NXT POS FOR BLANK           12760000
         BNE   DEF5                IF NOT BLANK, THEN THE PERIOD IS     12780000
*                                   IMBEDDED IN A WORD. WE ASSUME IT TO 12800000
*                                   BE A LITERAL WITH DEC. PT.          12820000
FINE1    OI    MSW,X'40'           SET PERIOD SW ON                4484 12830015
         B     FINE                IF BLANK THEN THE PERIOD IS A        12840000
*                                   DELINEATOR. GO EXIT.                12860000
INPTED   CH    C2,TWO              DELIMITER BYTE A PERIOD              12880000
         BNE   TSTCOM                                                   12900000
         CLR   C1,W3               IS PERIOD IN COL. 72                 12920000
         BE    FINE1             IF YES IT MUST BE END OF WROD     4484 12940015
         MVI   MESAGE+1,X'04'                                           12960000
         BAL   W2,TSTBLK           SEE IF FOLLOWED BY A BLANK           12980000
         B     FINE                                                     13000000
TSTCOM   CH    C2,FOUR             DELIMITER BYTE A COMMA(DEC. PT.)     13020000
         BNE   DEF4                                                     13040000
         CLI   1(C1),C' '              IS IT FOLLOWED BY A BLANK   4484 13050015
         BNE   DEF5                    NO                          4484 13060015
         B     OUT                                                 4484 13070015
TSTBLK   CLI   1(C1),C' '          SYNTAX REQUIRES A BLANK AFTER A      13080000
         BNE   NOBLK               COMMA, SEMICOLON, RIGHT PAREN AND    13100000
         CLI   0(C1),C'.'                                          4484 13108015
         BNE   TSTPRD                                              4484 13116015
         OI    MSW,X'40'           SET PERIOD SW ON                4484 13124015
TSTPRD   BR    W2                                                  4484 13132015
NOBLK    TM    MSW,X'80'           ARE WE OPERATING BETWIX PARENS       13140000
         BO    DAGCHK                                                   13160000
NOBLK1   MVC   HOLDIT(2),WERD      KEEP SRC CODE OF CURRENT WORD        13180000
         NI    WERD,X'FE'          CLEAR 1ST BIT OF POSIT NUM.          13200000
         NI    WERD+1,X'0F'        CLEAR REST OF POSIT. NUM.            13220000
         BAL   L1,PDIAGC                                                13240000
MESAGE   DC    X'0000'                                                  13260000
         LA    0,WERD                                                   13280000
         MVC   WERD(2),HOLDIT      RESTORE SRC CODE TO ORIGINAL         13300000
         BR    W2                                                       13320000
DAGCHK   TM    COUNTR,X'01'        HAS COMMA W/ NO BLANK FOLLOWING      13340000
         BO    STOPDG              ALREADY BEEN DIAGNOSTED              13360000
         OI    COUNTR,X'01'        NO--SET SWITCH FOR NEXT TIME         13380000
         B     NOBLK1                                                   13400000
STOPDG   NI    COUNTR,X'00'        AFTER 2ND ATTEMP TO DIAGNOSE THIS    13420000
         BR    W2                  CONDITION,RESET COUNTER SO NEXT      13440000
*                                  VALID DIAGNOSTIC OF IT CAN BE PUT.   13460000
*      **************************                                       13480000
*      ***  LITERAL CONTROL  ****                                       13500000
*      **************************                                       13520000
CON      NI    SWITCH,X'FD'        CLEAR LIT SWITCH                     13540000
         LR    W1,C1               LOAD CARD POINT                      13560000
         SR    W1,C3               SUBTRACT BEG. ADR.                   13580000
         LR    S1,C4               LOAD OLD TOT. LENGTH, WHICH IS ZERO  13600000
*                             UNLESS LIT. HAS BEEN CONTINUED            13620000
         AR    S1,W1               CALC NEW TOT. LENGTH                 13640000
         LR    W2,S1               STORE NEW TOT.                       13660000
         SH    S1,LIMIT            SUBTRACT 120 FROM TOTAL LENGTH       13680000
         BC    12,CON1             IF MINUS OR ZERO ITS OK              13700000
         BAL   L1,PDIAGC           DIAGNOSE LITERAL OVER 120 BYTES      13720000
         DC    X'0001'                                                  13740000
         LA    0,WERD                                                   13760000
         OI    SWITCH,X'04'        SET OUTSWITCH                        13780000
         SR    W1,S1               REDUCE LENGTH FOR MOVE BY TOT-120    13800000
         LH    W2,LIMIT            SET TOTAL LENGTH TO 120              13820000
         TM    SWITCH,X'08'        TEST 'SWITCH                         13840000
         BC    1,CON1              ON THEN BR.                          13860000
         SR    C1,S1               ELSE REDUCE TRT TRT REG BY TOT-120   13880000
CON1     LA    S2,4(C4,P1)         S2 GETS WORD AREA + OLD LENGTH + 4   13900000
         C     W1,ZERO             WAS 120 BYTE OF LIT IN COL72 OF      13920000
*                                  PREVIOUS CARD,,, IF SO               13940000
         BE    BYPASS              MOVE NO MORE OF INVALID LIT TO       13960000
*                                  OUTPUT AREA.                         13980000
         BCTR  W1,0                REDUCE LENGTH REG FOR MOVE           14000000
         EX    W1,INST3            MOVE TO WORD AREA                    14020000
         LA    W1,1(0,W1)          RESTORE LENGTH REG                   14040000
BYPASS   LR    C4,W2               LOAD NEW TOTAL                       14060000
         TM    SWITCH,X'04'        TEST OUT SWITCH                      14080000
         BZ    CONT4               BR. IF OFF-MEANS CONTINUATION        14100000
         NI    SWITCH,X'FB'        TURN OFF OUTSWITCH                   14120000
CON12    STC   C4,3(0,P1)                                               14140000
         TM    MSW,X'4'            IS LIB. NAME SWITCH ON               14160000
         BO    CON14               IF YES SKIP PUT AND TURN OFF TWO SW. 14180000
         BAL   L1,CPUTC                                                 14200000
CON13    LA    C1,1(C1)            BUMP POINTER PAST TERMINAL '         14220000
         TM    SWITCH,X'08'        TEST 'SWITCH                         14240000
         BC    8,CON3              BR IF OFF-MEANS OVER 120 W/O '       14260000
CON2     NI    SWITCH,X'F1'                                             14280000
         MVI   TABLE+C' ',X'1'                                          14300000
         MVI   TABLE+C'.',X'2'                                          14320000
         MVI   TABLE+C',',X'4'                                          14340000
         MVI   TABLE+C';',X'3'                                          14360000
         MVI   TABLE+C')',X'3'                                          14380000
         MVI   TABLE+C'''',X'0'                                         14400000
         B     SCH1                                                     14420000
CON14    NI    SWITCH,X'FE'        TURN OFF TWO SWITCH                  14440000
         B     CON13                                                    14460000
* HERE WE LOOK FOR FIRST BLANK IF LIT EXCEEDED                          14480000
CON3     CLR   C1,W3               OFF CARD{                            14500000
         BH    CON2                YES. GO TO CON2                      14520000
         CLI   0(C1),C' '          IS THIS A BLANK                      14540000
         BE    CON2                YES. GO TO CON2                      14560000
         LA    C1,1(C1)            BUMP POINTER TO NXT POS ON CARD      14580000
         B     CON3                                                     14600000
CONT4    OI    SWITCH,X'FE'        TURN OFF CON SWITCH                  14620000
         B     READ                                                     14640000
CON5     NI    SWITCH,X'EF'        TURN OF CON SWITCH                   14660000
         NI    MSW,X'BF'           SET PERIOD SWITCH OFF           4484 14670015
         LR    W1,C1               STORE MARGIN A POS. FOR LATER TESTS  14680000
CON6     CLI   0(C1),C''''         IS THIS THE CONTINUATION QUOTE       14700000
         BE    CON7                                                     14720000
         CLI   0(C1),C' '          IS THIS A BLANK                      14740000
         BC    7,CON8              NO. BR.                              14760000
         LA    C1,1(C1)            BUMP POINTER                         14780000
         CLR   C1,W3               OFF CARD{                            14800000
         BH    CON8                YES. BR.                             14820000
         B     CON6                                                     14840000
CON7     LA    C1,1(C1)            BUMP POINTER PAST INITIAL '          14860000
         OI    SWITCH,X'02'        SET LIT. SWITCH                      14880000
         LR    C3,C1               STORE BEG. ADR                       14900000
         AH    C0,ONE              BUMP POSITION-ON-CARD COUNTER        14920000
         LA    W1,4(W1)            SET W1 TO MARGIN B                   14940000
         CLR   C1,W1               IS TRT REG LESS THAN MARGIN B        14960000
         BH    DEF                 EQAL OR HI OK                        14980000
         BAL   L1,PDIAGC           DIAGNOSE CONTINUED LIT BEFORE COL 12 15000000
         DC    X'0002'                                                  15020000
         LA    0,WERD                                                   15040000
         B     DEF                                                      15060000
CON8     LA    W1,4(W1)            SET W1 TO MARGIN B                   15080000
         BAL   L1,PDIAGC           DIAGNOSE MISSING ' OR IMPROPER       15100000
         DC    X'0003'             CONTINUATION                         15120000
         LA    0,WERD                                                   15140000
         CLR   C1,W1                                                    15160000
         BC    10,CON9                                                  15180000
         OI    FLAGS,X'82'                                              15200000
CON9     OI    SWITCH,X'08'        SET ' SWITCH                         15220000
         BCTR  C1,0                                                     15240000
         B     CON12                                                    15260000
*      **************************                                       15280000
*      ****  READ  FUNCTION  ****                                       15300000
*      **************************                                       15320000
READ     BAL   L1,CIPT             GET NEXT CARD                        15340000
READ1    L     C1,INPUT            LOAD ITS ADR IN C1                   15360000
         LA    W3,71(0,C1)         SET 72ADR                            15380000
         LA    C5,1(C5)            BUMP CARD COUNT                      15400000
         L     L1,CCOMM           GET ADDRESS OF COMMON AREA       000E 15406018
         STH   C5,UCNTS(L1)       BUMP CT OF SOURCE RECS FOR STAT  000E 15412018
         LA    C0,1                SET POSITION-ON-CARD COUNTER TO 1    15420000
         L     W2,LIST             LOAD ADR OF NEXT PRINT BUFFER        15440000
         MVI   0(W2),C' '          CARRIAGE CONTROL SINGLE SPACE        15460000
         LH    W1,CLNS                                                  15480000
         BCT   W1,CCNTRL                                                15500000
         MVI   0(W2),C'1'                                               15520000
         LH    W1,CLNCT                                                 15540000
CCNTRL   STH   W1,CLNS                                                  15560000
         LA    W2,1(W2)                                                 15580000
         CVD   C5,CVD              CONVERT ASSIGNED SEQUENCE NO.        15600000
         MVC   0(17,W2),EDMX       LOAD EDIT MASK                       15620000
         ED    8(6,W2),CVD+5       EDIT ASSIGNED SEQUENCE NO. TO PRINT  15640000
         MVC   17(72,W2),0(C1)     MOVE IN CARD COL. 1-72               15660000
         MVI   90(W2),C' '         BLANK PRINT POS. 91                  15680000
         MVC   91(8,W2),72(C1)     MOVE IN CARD COL. 73-80              15700000
         CLC   0(6,C1),BLANK       IS SOURCE SEQUENCE FIELD BLANK       15720000
         BE    PRINT               IF YES DONT CHK SEQ                  15740000
         CLC   0(6,C1),SEQ         COMP. TO PREV. SOURCE SEQ. FIELD     15760000
         BH    R5                                                       15780000
         MVI   9(W2),C'S'          MOVE IN SEQUENCE ERROR FLAG          15800000
R5       MVC   SEQ(6),0(C1)        STORE SOURCE SEQUENCE FIELD          15820000
PRINT    BAL   L1,CPRINT           PRINT LINE                           15840000
*      ***************************                                      15860000
*      ***  CHEK, FIRST + OUT ****                                      15880000
*      ***************************                                      15900000
       CLC     7(65,C1),BLANKS     IS THIS CARD BLANK              4484 15906015
       BE      READ                                                4484 15912015
         LA    C1,7(C1)            LOAD MARGIN A ADR                    15920000
         TM    SWITCH,X'10'        CON SW. ON                           15940000
         BC    1,CON5                                                   15960000
         CLC   0(4,C1),BLANK       ENTIRE MARGIN A FIELD BLANK          15980000
         BNE   CHK2                NO. GO SET MARGIN A PREFIX           16000000
*                                                                 22061 16001000
*                                                                 22061 16002000
         TM    NOTESW,X'08'        ARE WE IN A NOTE PARAGRAPH     22061 16003000
         BO    READ          YES, GET NEXT CARD                    4632 16004017
         TM    NOTESW,X'2'   ARE WE IN NOTE SENTENCE               4632 16005017
         BO    NEXTPERD                                            4632 16006017
CHK2B    EQU   *                                                   4632 16007017
*                                                                 22061 16010000
*                                                                 22061 16013000
*                                                                 22061 16016000
         LA    C1,4(0,C1)          ELSE SET TRT REG TO MARGINB          16020000
         NI    MSW,X'BF'           SET PERIOD SWITCH OFF           4484 16030015
         B     SCH                                                      16040000
CHK2     EQU   *                                                   4632 16042017
         TM    NOTESW,X'08'        IF ON AT THIS POINT THEN END OF22061 16044000
         BZ    CHK2A         NOTE PARAGRAPH   (NO)                 4632 16046017
         OI    MSW,X'40'     YES, TURN ON PERIOD SW                4632 16048017
CHK2A    OI    FLAGS,X'82'   SET MARGIN A PREFIX                   4632 16050017
         OI    NOTESW,X'5'   FOUND START OF NEW PARAGRAPH  X'1'    4632 16052017
*                                 1ST TIME THRU SW X'4'            4632 16054017
         NI    NOTESW,X'F7'        TURN OFF NOTE PARAGRAPH SWITCH 22061 16059000
         TM    MSW,X'40'     IS PRECEDING STATEMENT HAS PERIOD     4484 16065015
         BC    1,SCH         YES                                   4484 16070015
       TM      SW2,X'80'   IS THE 1ST TIME IN PROCED. DIV.?        4484 16075015
         BC    1,CHK3        YES                                   4484 16080015
         OI    SW2,X'01'   NO, & PERIOD NOT FOUND IN LAST ST'MENT  4484 16085015
CHK3     NI    SW2,X'7F'     TURN 1ST TIME SWITCH OFF              4484 16090015
         B     SCH                                                 4484 16095015
FIRST    NI    FSW+1,X'0F'         TURN OFF FIRST SW                    16100000
         OI    SW2,X'80'     1ST TIME IN PROCEDURE DIVISION.       4484 16110015
         L     W1,CCOMM            POINT TO COMMON AREA                 16120000
         LH    C5,UISEQ(W1)        GET ASSIGNED SEQUENCE NO FROM COMM   16140000
         MVC   SEQ(6),USSEQ(W1)    GET PREVIOUS SOURCE SEQUENCE NO      16160000
         B     READ1                                                    16180000
FINE     LR    C4,C1               LOAD CARD POINTER                    16200000
         SLR   C4,C3               SUBTRACT BEG. ADR TO GIVE LENGTH     16220000
         TM    SWITCH,X'01'        TWO SWITCH ON                        16240000
         BC    8,EXIT                                                   16260000
         NI    SWITCH,X'FE'                                             16280000
         B     AUDIT                                                    16300000
EXIT     STM   W3,C1,STOR                                               16320000
         L     L1,LINK             RESTORE LINK REG.                    16340000
         BCR   15,L1                                                    16360000
*      ***********************                                          16380000
*      ***  MISCELLANEOUS  ***                                          16400000
*      ***********************                                          16420000
INST1    MVC   4(,P1),0(C3)                                             16440000
INST2    TRT   0(0,C1),TABLE                                            16460000
INST3    MVC   0(,S2),0(C3)                                             16480000
AUD1     TM    FLAGS,X'84'         ALPHA LITERAL +                      16500000
         BC    1,AUD3              BR. IF YES                           16520000
*                             IF NOT SHOULD BE MARGIN A NAME            16540000
*                             OR NUMERIC W/ DECIMAL                     16560000
         BAL   L1,CPUTC                                                 16580000
         TM    FLAGS,X'88'       IS IT A NUM. W/DEC.?              4484 16581015
         BC    1,AUD4        YES                                   4484 16582015
         TM    SW2,X'01'     IS NO PERIOD SWITCH ON                4484 16583015
         BC    8,AUD4      PERIOD IN LAST STATEMENT                4484 16584015
         MVI   MESAGE+1,X'41'  PERIOD MISSING ERROR MESSAGE        4484 16585015
         BAL   W2,NOBLK1                                           4484 16586015
         NI    MSW,X'BF'          TURN OFF PERIOD SW.              4484 16587015
         NI    SW2,X'FE'                                           4484 16588015
         OI    WERD,X'FE'          RESET POSITION BIT ON           4484 16589015
         OI    WERD+1,X'0F'                                        4484 16590015
AUD4     OI    SWITCH,X'1'         SET TWO SWITCH                       16600000
         B     SCH1                                                     16620000
AUD2     EQU   *                                                        16640000
         CLC   0(2,C3),AST                                              16660000
         BNE   SCH1                                                     16680000
         MVI   4(P1),X'59'         IF  ** MOVE HEX 59 TO WORD AREA      16700000
         MVI   3(P1),X'1'          SET LENGTH TO 1                      16720000
         BAL   L1,CPUTC                                                 16740000
         B     AUD4                                                     16760000
AUD3     OI    SWITCH,X'3'         SET LIT SWITCH + TWO SWITCH          16780000
         SR    C4,C4              CLEAR LENGTH COUNTER                  16800000
         MVI   TABLE+C' ',X'0'                                          16820000
         MVI   TABLE+C'.',X'0'                                          16840000
         MVI   TABLE+C',',X'0'                                          16860000
         MVI   TABLE+C';',X'0'                                          16880000
         MVI   TABLE+C')',X'0'                                          16900000
         MVI   TABLE+C'''',C''''                                        16920000
         TM    MSW,X'04'           IF IN INCLUDE LIBRARY NAME MODE      16940000
         BZ    DEF                 THE TRT SCAN MUST BE STOPPED BY A    16960000
         MVI   TABLE+C' ',X'1E'    QUOTE OR A BLANK,TO PREVENT          16980000
*                                  INDEFINITE SCANNING ON AN INVALID    17000000
*                                  LIBRARY NAME TERMINATION IN USING    17020000
*                                  THE LITERAL ROUTINE                  17040000
         MVI   FLAGS,X'80'                                              17060000
         B     DEF                                                      17080000
AUD7     LA    P1,WERD                                                  17100000
         BAL   L1,QL1                                                   17120000
         SR    S1,S1                                                    17140000
         BCTR  C3,0                                                     17160000
         STC   C4,0(C3)                                                 17180000
         BAL   L1,PDIAGC                                                17200000
         DC    X'202F'                                                  17220000
         LA    0,WERD                                                   17240000
         LA    0,WERD+3                                                 17260000
         LA    0,0(C3)                                                  17280000
         LA    C3,1(C3)                                                 17300000
        B     AUD5                                                      17320000
SCH12    CLI   0(C1),C''''         IS THIS A QUOTE                      17340000
         BE    SCH2                                                     17360000
         CLC   3(8,P1),NCLUDE      IF INCLUDE LIB NAME MODE, LIB NAME   17380000
         BNE   SCH10               MUST START WITH A QUOTE              17400000
         MVI   3(P1),X'00'        (STOP EQUAL COMPARE 2ND TIME)         17420000
         B    NCBAD                                                     17440000
SCH10    L    L1,CCOMM                                                  17460000
         CLI   UPOIN(L1),X'6B'     IS SPECIAL EUROPEAN SYSTEM IN EFFECT 17480000
         BE    INVPRT              I.E., COMMAS FOR DECIMAL POINTS.     17500000
         CLI   0(C1),C','          DELIMITER BYTE A COMMA               17520000
         BNE   SCH11                                                    17540000
         CLR   C1,W3               IS COMMA IN COL. 72                  17560000
         BNE   SCH4                NO--                                 17580000
         LA    C1,1(C1)            YES--GO FOR NEXT CARD                17600000
         B     SCH                                                      17620000
SCH11    CLI   0(C1),C'.'          DELIMITER BYTE A PERIOD              17640000
         BE    SCH5                                                     17660000
SCH6     CLI   0(C1),C';'          IS IT A SEMICOLON                    17680000
         BE    SCH4                IF YES SKIP IT.                      17700000
         CLI   0(C1),C'('          IS THIS A LEFT PAREN                 17720000
         BE    SCH8                                                     17740000
         CLI   0(C1),C')'          IS THIS A RIGHT PAREN                17760000
         BNE   DEF                                                      17780000
         NI    MSW,X'7F'           TURN OFF BETWIX PAREN SWITCH         17800000
         CLI   1(C1),C'.'                                               17820000
         BE    PRDSW                                               4484 17840015
         CLI   1(C1),C','                                               17860000
         BE    SCH3                                                     17880000
         CLI   1(C1),C')'                                               17900000
         BE    SCH3                                                     17920000
         CLR   C1,W3               RIGHT PAREN IN COL. 72               17940000
         BE    SCH3                                                     17960000
         MVI   MESAGE+1,X'0A'                                           17980000
         BAL   W2,TSTBLK           SEE IF FOLLOWED BY A BLANK           18000000
SCH3     LA    C1,1(C1)            BUMP POINTER TO NXT POS              18020000
         B     FINE                AND EXIT                             18040000
SCH8     OI    MSW,X'80'           TURN ON BETWIX PAREN SWITCH          18060000
         B     SCH3                                                     18080000
SCH4     MVI   MESAGE+1,X'0A'                                           18100000
         BAL   W2,TSTBLK           SEE IF FOLLOWED BY A BLANK           18120000
         LA    C1,1(C1)            BUMP POINTER TO SKIP PAST COMMA      18140000
         AH    C0,ONE              BUMP POSITION-ON-CARD COUNTER        18160000
         B     SCH                 AND GO LOOK FOR NEXT WORD            18180000
SCH5     CLR   C1,W3               IS PERIOD IN COL 72                  18200000
         BE    PRDSW         IF YES IT CANT BE IMBEDDED            4484 18220015
SCH7     CLI   1(C1),C' '          ELSE CHK NEXT POSIT FOR BLANK        18240000
         BNE   DEF5                IF NOT BLANK THIS IS ASSUMED TO BE A 18260000
*                                   NUMERIC LIT WITH LEADING DEC. POINT 18280000
         B     PRDSW                       ELSE TREATED AS PUNCT.  4484 18300015
SCH9     CLI   1(C1),C' '          INVERTED PRINT EDIT MODE, COMMAS     18320000
         BNE   DEF5                IF NOT FOLLOWED BY A BLANK WILL      18340000
         LA    C1,1(C1)            BE CONSIDERED AS DECIMAL POINTS.     18360000
         AH    C0,ONE              IF FOLLOWED BY A BLANK,              18380000
         B    SCH                  THEY  ARE DROPPED                    18400000
PRDSW    OI    MSW,X'40'           TURN PERIOD SW ON               4484 18406015
         B     SCH3                                                4484 18412015
SCH2     OI    FLAGS,X'84'                                              18420000
         LA    C1,1(C1)            BUMP POINTER                         18440000
         LR    C3,C1                                                    18460000
DEF2     LA    C1,1(C1)            BUMP POINTER                         18480000
DEF6     TM    SWITCH,X'2'         TEST LIT  SWITCH                     18500000
         BC    1,CON                                                    18520000
         B     FINE                ELSE EXIT                            18540000
DEF3     CLI   0(C1),C''''         IS THIS A QUOTE                      18560000
         BE    DEF7                                                     18580000
DEF5     OI    FLAGS,X'88'                                              18600000
DEF4     LA    C1,1(C1)            BUMP POINTER PAST DEC. POINT         18620000
         B     DEF                                                      18640000
DEF7     OI    SWITCH,X'C'         SET OUTSWITCH SET   'SWITCH          18660000
         B     CON                                                      18680000
DEF9     LR    C1,W3               SET CARD POINT TO COL. 72            18700000
         B     DEF2                                                     18720000
INVPRT   CLI   0(C1),C'.'          DELIMITER BYTE A PERIOD              18740000
         BNE   INVCOM                                                   18760000
         CLR   C1,W3               IS PERIOD IN COL. 72                 18780000
         BE    PRDSW                         IT MUST END OF WORD   4484 18800015
         MVI   MESAGE+1,X'04'                                           18820000
         BAL   W2,TSTBLK           SEE IF FOLLOWED BY A BLANK           18840000
         B     SCH3                                                     18860000
INVCOM   CLI   0(C1),C','          DELIMITER BYTE A COMMA (DEC.PT.)     18880000
         BNE   SCH6                                                     18900000
         B     SCH9                SEE IF COMMA IS DELIMITER/DEC.PT.    18920000
ENDCD    TM    SWITCH,X'01'        TEST TWO SWITCH                      18940000
         BO    LEEV               BR TO END PHASE                  4479 18960015
         MVC   AUDIT(4),ENDWRD     ELSE SET UP TO RETURN AFTER          18980000
*                                 MERGING LAST WORD                     19000000
         OI    FLAGS,X'84'         SET LIT FLAG SO MERGE WONT TEST N. W 19020000
         B     EXIT                                                     19040000
LEEV     LA    P1,PERIOD           SETUP TO PUT OUT A PERIOD  AT END    19120000
         BAL   L1,CPUTC            OF PROGRAM.                          19140000
         BAL   L1,CCLOSE                                                19160000
         DC    X'00000200'                                              19180000
         TM    SWITCH,SSEG         IS TABLE SEGMENTED                   19200000
         BZ    LEEV1               IF NO SKIP                           19220000
         L     P1,CCORAD           POINT TO TABLE AREA                  19240000
         LA    W1,4(P1)            POINT TO NOTEWORD FOR SEGMENT 1      19260000
         LA    P1,USTSZ+4(P1)                                           19280000
         BAL   L1,CREAD            GO READ SEGMENT 1                    19300000
LEEV1    B     CEXIT               EXIT FROM PHASE                      19320000
ENDWRD   B     LEEV                                                4479 19380015
         EJECT                                                     4632 19410017
*                                                                       19440000
*                                                                       19460000
*        *******************************************************        19480000
*        *******************************************************        19500000
*        *****                                             *****        19520000
*        *****  SPECIAL DIAGNOSTIC ROUTINE FOR PMG & SMG   *****        19540000
*        *****                                             *****        19560000
*        *******************************************************        19580000
*        *******************************************************        19600000
*                                                                       19620000
*                                                                       19640000
*        THIS ROUTINE IS SETUP TO STOP THE MERGE PHASES FROM            19660000
*        OUTPUTTING THEIR DIAGNOSTICS ON FILEA BUT RATHER               19680000
*        OUTPUTTING THEM ON FILEC AS INPUT FOR THE SYNTAX PHASE         19700000
*        THAT FOLLOWS. THE SYNTAX PHASE WILL SENSE THESE                19720000
*        DIAGNOSTICS BY THE CODE 8D IN A DUMMY SRCF PREPARED            19740000
*        BY THE MERGE PHASE. THE SYNTAX PHASE WILL OUTPUT THEM          19760000
*        ON FILEA FOR THE MERGE PHASE.                                  19780000
*        IF THE SYNTAX PHASE SENSES ONE OF THE SPECIAL 8D CODES         19800000
*        ON AN INPUT RECORD WHILE IT KNOWS IT IS IN THE 'NOTE'          19820000
*        MODE, IT WILL DROP THE RECORD AND GO ON.                       19840000
*        ALL THIS IS DONE SO THAT DIAGNOSTICS GENERATED BY THE          19860000
*        MERGE PHASE ON ANYTHING WITHIN A NOTE  STATEMENT OR            19880000
*        PARAGRAPH WILL NOT BE PUT OUT ON THE DIAGNOSTIC LISTING.       19900000
*                                                                       19920000
*                                                                       19940000
PDIAGC   ST    9,TABLE+8                                                19960000
         STM   0,1,TABLE                                                19980000
         LH    0,0(L1)             ERROR MESSAGE NUMBER TO REG.         20000000
         LA    L1,2(L1)            BUMP PTR TO GET ADDR OF SRC          20020000
         STH   0,DGSRC+4           ERROR NUM TO RECORD BUILD AREA       20040000
         NI    DGSRC+4,X'0F'       CLEAR OUT TRLR COUNT BITS            20060000
         SRL   0,12                HOLD TRAILER COUNT                   20080000
         MVI   DGSRC,X'86'                                              20100000
         STH   0,TRLNUM            SAVE NUM. OF TRAILERS                20120000
         EX    0,0(L1)             GET ADDR OF SRC                      20140000
         LA    L1,4(L1)            ADDR OF POSSIBLE TRAILER             20160000
         ST    L1,TABLE+12         SAVE RETURN                          20180000
         LR    1,0                 SET WRK PTR TO SRC                   20200000
         MVC   DGSRC+1(2),1(1)     PUT POSIT-SEQ TO RECORD BUILD AREA   20220000
         TM    0(1),X'01'          IS HI-ORDER BIT OF POSIT ON          20240000
         BC    8,CLEAR             NO,                                  20260000
         OI    DGSRC,X'01'         YES, SET IT ON IN RECORD BUILD AREA  20280000
CLEAR    LA    9,SPSRC             SET OUTPUT PTR TO DUMMY SRC          20300000
         BAL   L1,CPUTC            PUT OUT ERROR NUM. RECORD            20320000
         L     L1,TABLE+12         SETUP RETURN TO MAIN PROG            20340000
         LH    1,TRLNUM            NUM OF TRAILERS TO REG.              20360000
         LTR   1,1                 ARE THERE ANY TRAILERS               20380000
         BC    8,DGEXIT            NO, RETURN TO MAIN PROG.             20400000
         NI    DGSRC,X'E5'       PUT TRAILER CODE IN RECORD BUILD AREA  20420000
         OI    DGSRC,X'E4'         W/OUT UPSET OF HI-ORDER POSIT. BIT   20440000
TRLOOP   EX    0,0(L1)             POINT TO LGTH/WORD TO BE TRAILER     20460000
         STH   1,TRLNUM            DECREMENTED TRAILER COUNT IF MORE    20480000
*                                  THAN ONE TRAILER IS TO BE USED       20500000
         LA    L1,4(L1)            BUMP TO NEXT TRAILER OR RETURN       20520000
         ST    L1,TABLE+12         SAVE RETURN TO MAIN PROG.            20540000
         LR    9,0                 WRK PTR TO LENGTH OF TRAILER WORD    20560000
         SH    9,HALF7             BACK UP PTR TO ALLOCATE SPACE FOR    20580000
*                                  DUMMY SRC AND REAL SRC               20600000
         MVC   TABLE+16(7),0(9)    SAVE INFO IN BYTES TO BE CLOBBERED   20620000
         SR    L1,L1                                                    20640000
         IC    L1,7(9)             TAKE LENGTH OF TRAILER WORD AND      20660000
         LA    L1,4(L1)            ADD 4 TO IT TO GET RECORD LENGTH     20680000
         MVC   0(7,9),SPSRC        FOR CIOP. OVER LAY W/ DUMMY/REAL SRC 20700000
         STC   L1,3(9)             PLUG RECORD LGTH IN INPUT AREA       20720000
         BAL   L1,CPUTC                                                 20740000
         MVC   0(7,9),TABLE+16     RESTORE CLOBBERED BYTES IN PROG.     20760000
         L     L1,TABLE+12         RESTORE PTR TO MAIN PROG.            20780000
         LH    1,TRLNUM            NUM OF TRAILERS LEFT TO WRK REG.     20800000
         BCT   1,TRLOOP            DECREMENT AND CHK IF 0--YES--DONE    20820000
DGEXIT   LM    0,1,TABLE           RESTORE REGS. AND                    20840000
         L     9,TABLE+8           RETURN TO  MAIN PROG.                20860000
         MVI   TABLE,X'00'         RESTORE TRT TABLE                    20880000
         MVC   TABLE+1(23),TABLE   DIAG. RT. USED 24 BYTES              20900000
         BR    L1                                                       20920000
*                                                                       20940000
*                                                                       20960000
         DC    0F'0'               NEXT 3 CARDS MUST BE TOGETHER        20980000
SPSRC    DC    X'8D000006'    1.   DUMMY SRC FOR DIAGNOSTICS            21000000
DGSRC    DC    X'00000002'    2.   REAL SRC FOR DIAGNOSTICS             21020000
         DC    X'0000'        3.   AREA FOR DIAG. NUMBER                21040000
TRLNUM   DC    H'0'                                                     21060000
HALF7    DC    H'7'                                                     21080000
CDGWK    DS    F                                                        21100000
*         **************************************                   000B 21100516
*      ** RESERVED WORD TABLE ****                                 000B 21101016
*      ******************                                          000B 21101516
FINDTB   DC    AL1(RESL2-FINDTB)                                   000B 21102016
         DC    AL1(RESL3-FINDTB)                                   000B 21102516
         DC    AL1(RESL4-FINDTB)                                   000B 21103016
         DC    AL1(RESL5-FINDTB)                                   000B 21103516
         DC    AL1(RESL6-FINDTB)                                   000B 21104016
         DC    AL1(RESL7-FINDTB)                                   000B 21104516
RESL2    DC    C'IF'              RESERVED WORDS OF LENGTH TWO     000B 21105016
         DC    C'GO'                                               000B 21105516
         DC    C'TO'                                               000B 21106016
         DC    C'OR'                                               000B 21106516
         DC    C'AT'                                               000B 21107016
         DC    X'FF'                                               000B 21107516
RESL3    DC    C'AND'             RESERVED WORDS OF LENGTH THREE   000B 21108016
         DC    C'ADD'                                              000B 21108516
         DC    C'END'                                              000B 21109016
         DC    C'NOT'                                              000B 21109516
         DC    X'FF'             INDICATES  END OF DICT LIST       000B 21110016
RESL4    DC    C'MOVE'            RESERVED WORDS OF LENGTH FOUR    000B 21110516
         DC    C'LESS'                                             000B 21111016
         DC    C'THAN'                                             000B 21111516
         DC    C'ELSE'                                             000B 21112016
         DC    C'THRU'                                             000B 21112516
         DC    C'FROM'                                             000B 21113016
         DC    C'EXIT'                                             000B 21113516
         DC    C'READ'                                             000B 21114016
         DC    X'FF'             INDICATES  END OF                 000B 21114516
RESL5    DC    C'EQUAL'           RESERVED WORDS OF LENGTH FIVE    000B 21115016
         DC    X'FF'             INDICATES  END O                  000B 21115516
RESL6    DC    C'DIVIDE'          RESERVED WORDS OF LENGTH SIX     000B 21116016
         DC    X'FF'             INDICATES  END O                  000B 21116516
RESL7    DC    C'PERFORM'                                          000B 21117016
         DC    C'DISPLAY'                                          000B 21117516
         DC    C'COMPUTE'                                          000B 21118016
         DC    C'ROUNDED'                                          000B 21118516
         DC    C'GREATER'                                          000B 21119016
         DC    X'FF'                                               000B 21119516
*                                                                       21120000
*                                                                       21140000
*      *********************************                                21160000
*      ***  TRANSLATE + TEST TABLE  ****                                21180000
*      *********************************                                21200000
         DC    0F'0'                                                    21220000
TABLE    DC    100X'0'             MUST BE ON FULL WORD BOUNDRY         21240000
         DC    156X'0'                                                  21260000
RESTRT   EQU   *                                                        21280000
         ORG   TABLE+C' '                                               21300000
         DC    X'1'                                                     21320000
         ORG   TABLE+C'.'                                               21340000
         DC    X'2'                                                     21360000
         ORG   TABLE+C')'                                               21380000
         DC    X'3'                                                     21400000
         ORG   TABLE+C','                                               21420000
         DC    X'4'                                                     21440000
         ORG   TABLE+C';'                                               21460000
         DC    X'3'                                                     21480000
         ORG   RESTRT                                                   21500000
*      *************************                                        21520000
*      ***  MERGE LITERALS   ***                                        21540000
*      *************************                                        21560000
NCLUDE   DC    X'7'                                                     21580000
         DC    C'INCLUDE'                                               21600000
THEN     DC    X'4'                'THEN' IS USED AS PUNCTUATION IN SOU 21620000
         DC    C'THEN'             IT IS DROPPED FROM OUTPUT LIKE COMMA 21640000
XIBIT    DC    X'7'                                                     21660000
         DC    C'EXHIBIT'                                               21680000
TRACE    DC    X'5'                                                     21700000
         DC    C'TRACE'                                                 21720000
WRITE    DC    X'5'                CONSTANT TO CHECK FOR WRITE VERB     21740000
         DC    C'WRITE'                                                 21760000
REWRIT   DC    X'7'                                                     21780000
         DC    C'REWRITE'                                               21800000
OF       DC    C'OF'                                                    21820000
IN       DC    C'IN'                                                    21840000
AST      DC    C'**'                                                    21860000
MSW      DC    X'0'                SWITCHES FOR MERGE PHASE             21880000
* POS 0-7 ARE THE BITS NUMBERED FROM RIGHT TO LEFT                      21900000
* POS 0 - FOUND SWITCH.  INDICATES THAT A MATCHING HIERARCHY HAS BEEN   21920000
*            FOUND FOR A QUALIFIED NAME,  AND WE ARE NOW CHECKING FOR   21940000
*            ADDITIONAL MATCHES, IN ORDER TO DIAGNOS AMBIGUITY OF       21960000
*            QUALIFICATION.                                             21980000
* POS 1 - 88 SWITCH.  ON WHILE WE MERGE THE SUBSCRIPTS OF A SUBSCRIPTED 22000000
*            CONDITION NAME. INDICATES THAT AFTER LOCATING A RIGHT HAND 22020000
*            PAREN, WE RETURN TO THE 88 ROUTINE TO MERGE THE EQUAL      22040000
*            OPERATOR AND THE CONDITION.                                22060000
* POS 2 - LIBRARY NAME SWITCH - ON WHEN DOING GETWORD FOR LIB. NAME     22080000
* POS 4 - X SWITCH. ON WHILE HANDLING AN EXHIBIT VERB.  INDICATES       22100000
*            THAT WE ARE TO MERGE THE DATA NAMES, AS WELL AS THEIR      22120000
*            ATTRIBUTES.                                                22140000
*  POS 5  LEFT PARAN SW INDICATES A LEFT PARAN HAS BEEN FOUND           22160000
*        FOLLOWING AN EXHIBIT STATEMENT.  THIS IS TO BYPASS             22180000
*        PUTTING OUT THE DATA-NAME FOR THE SUBSCRIPTS.                  22200000
* POS 6 - PERIOD FOUND SWITCH - ON WHEN FOUND                      4484 22210015
* POS 7 - LEFT RAREN FOUND SWITCH---ON WHEN FOUND--.                    22220000
SWITCH   DC    X'1'                GETWORD SWITCHES                     22240000
* POSITIONS 0-7 ARE THE BITS NUMBERED FROM RIGHT TO LEFT                22260000
* POS 0 - TWO SWITCH. ON IF NEXT WORD WAS IRRELEVANT TO MERGE, SO THAT  22280000
*         WE WANT TO GET TWO WORDS BEFORE RETURNING.   INITIALY ON.     22300000
* POS 1 - LIT SWITCH. ON IF WE ARE WORKING ON A LITERAL. TRT TABLE WILL 22320000
*         BE SET UP FOR LITERALS ETC.                                   22340000
* POS 2 - OUTSWITCH. ON WHEN WE ARE READY TO PUT A LITERAL, EITHOR      22360000
*         DUE TO A RIGHT ' OR EXCESSIVE LENGTH.                         22380000
* POS 3 - ' SWITCH. ON WHEN A RIGHT ' HAS BEEN FOUND FOR A LITERAL.     22400000
* POS 4 - CON SWITCH. ON WHILE WE READ A CARD TO CONTINUE A LITERAL.    22420000
* POS 5 - LIBRARY SWITCH. ON WHEN INCLUDING                             22440000
* POS 6 - BUFFER SWITCH. USED TO CONTROL TWO INPUT BUFFERS.             22460000
BLANKS DC      65C' '                                              4484 22465015
SW1    DC      X'00'                                               4484 22470015
SW2    DC      X'00'                                               4484 22475015
SSEG     EQU   X'80'               ON IF TABLE IS SEGMENTED             22480000
TRNC     DC    F'31'               MASK TO TRUNCATE POS TO MAX 31       22500000
FLAGS    DC    X'80'                                                    22520000
PERIOD   DC    X'800000014B'       SPECIAL RECORD FOR END OF PROGRAM .  22540000
B88      DC    F'1'                                                     22560000
         DC    CL1'='                                                   22580000
G88      DS    CL3                 HOLD AREA FOR ATTRIBUTE OF CONDITION 22600000
         DC    X'8'                NAME.                                22620000
         DS    CL8                                                      22640000
COUNTR   DC    X'00'                                                    22660000
ONE      DC    H'1'                                                     22680000
TWO      DC    H'2'                                                     22700000
THREE    DC    H'3'                                                     22720000
FOUR     DC    H'4'                                                     22740000
SIX      DC    H'6'                                                     22760000
THIRTY   DC    H'30'                                                    22780000
LIMIT    DC    H'120'              MAXIMUM LENGTH OF CONTINUED LITERALS 22800000
HOLDIT   DC    H'0'                                                     22820000
BSE      DC    F'0'                                                     22840000
HASHAD   DC    A(HSH+4)                                                 22860000
HOLD     DS    F                   HOLD + HOLD1 MUST BE CONTIGUOUS      22880000
HOLD1    DS    F                                                        22900000
HOLD2    DC    F'0'                                                     22920000
HOLD3    DC    F'0'                                                     22940000
WRDLIM   DC    AL4(WERD+300)                                            22960000
LINK     DS    F                   HOLD AREA FOR LINK ADR TO GETWORD    22980000
LINK1    DS    F                   STORE LINK FOR ITERATION ROUTINE     23000000
STOR     DS    6F                                                       23020000
CHLOAD   DC    F'0'                USED TO STORE CHAIN POINTER. FIRST   23040000
*                                 TWO BYTES MUST REMAIN ZERO.           23060000
TABAD    DC    F'0'                                                     23080000
CHSTR    DS    F                   STORE CURRENT RELATIVE ADRES         23100000
HALF     DC    F'0'                FOR LOADING UP POINTS. THE FIRST TWO 23120000
*                                 BYTES MUST REMAIN ZERO                23140000
OUTP     DS    CL4                 AREA FOR PREFIX, IN FRONT OF ATRIB.  23160000
OUT      DS    CL10                AREA TO SAVE ATRIBUTE AND UP POINTER 23180000
QSAVE    DS    CL10                AREA TO STORE ATRIBUTE               23200000
WERD     DS    CL150               WORK AREA 300 POSITIONS LONG FOR     23220000
         DS    CL150               CONTINUED LITERALS, NAMES, + QUALS.  23240000
ZERO     DC    F'0'                                                     23260000
CVD      DS    D                   USED FOR CONVERSION OF ASSIGNED SEQ  23280000
BLANK    EQU   *                   USE EDIT MASK FOR CONSTANT BLANKS    23300000
EDMX     DC    C'         '        ED. MASK FOR ASSIGNED SEQ NO ON LIST 23320000
         DC    X'2020202120'       MORE OF EDIT MASK                    23340000
         DC    C'   '              LAST OF EDIT MASK                    23360000
NCSEQ    DC    6C' '               STORE SEQ FIELD HERE FOR INCLUDE     23380000
SEQ      DC    6C' '               HOLD AREA FOR SOURCE SEQ. NO.        23400000
RSEQ     DC    6C' '               RESTORE SEQ FIELD FOR INCLUDE        23420000
         DC    0H'0'               PUT HASH TABLE ON HALF WORD BOUND    23440000
HSH      DS    2CL253                                                   23460000
NOTESW   DC    X'0'                                                4632 23462017
*                       X'01' FOUND START OF NEW PARAGRAPH         4632 23464017
*                       X'02' NOTE IN MIDDLE OF PARAGRAPH          4632 23466017
NOTE     DC    C'NOTE '                                            4632 23468017
NOTE1    DC    C'NOTE.'                                            4632 23470017
NOTE2    DC    C'NOTE,'                                            4632 23472017
NOTE3    DC    C'NOTE '                                            4632 23474017
NOTE4    DC    C'NOTE'                                             8101 23475020
NOTEPERD DC    C'. '                                               4632 23476017
INSEG    DS    F                   POINTER TO ENTRY FOR CURRENT SEG     23480000
COMM     EQU   CCOMM                                                    23500000
         CIOPL SMG                                                      23520000
         END   CETSMG                                                   23540000
