         TITLE 'IECTATEN - BTAM LOCAL 3270 FIRST LEVEL ATTN RTN'        00600021
IECTATEN CSECT                                                          01200021
* STATUS- CHANGE LEVEL 000                                              01800021
*                                                                       02400021
* FUNCTION-HANDLE ALL ATTENTION INTERRUPTS FOR LOCAL 3270 DEVICES IN    03000021
*    OS/BTAM.  SCHEDULE THE SECOND LEVEL ATTENTION RTN. (IGG019PG) IF   03600021
*    A READ IS TO BE STARTED.  UPDATE ATTENTION INFORMATION FOR THE     04200021
*    BTAM LINE GROUP.                                                   04800021
*                                                                       05400021
* ENTRY POINT- THE ROUTINE IS ENTERED AT IECTATEN FROM THE I/O INTER-   06000021
*    RUPT SUPERVISOR WHENEVER ATTENTION STATUS OCCURS FROM A LOCAL 3270 06600021
*    DEVICE.                                                            07200021
*                                                                       07800021
* INPUT- REGISTERS 7, 10, AND 14 ARE ESTABLISHED BY IOS                 08400021
*    REGISTER  7 - THE ADDRESS OF THE UCB FOR THE DEVICE                09000021
*    REGISTER 10 - ADDRESS OF THE ENTRY POINT OF AEE2                   09600021
*    REGISTER 14 - RETURN POINT ADDRESS                                 10200021
*                                                                       10800021
* OUTPUT- UPDATED ATTENTION FLAGS AND COUNT IN THE LINE GROUP'S UCB'S.  11400021
*    AN INITIALIZED IQE IF THE SECOND LEVEL ATTENTION RTN IS SCHEDULED. 12000021
*                                                                       12600021
* EXTERNAL REFERENCES- ASYNCHRONOUS EXIT EFFECTOR, STAGE 2 (AEE2)       13200021
*                                                                       13800021
* EXITS,NORMAL- RETURN TO IOS WITH ATTENTION INFORMATION UPDATED        14400021
*                                                                       15000021
* EXITS,ERROR- RETURN TO IOS WITHOUT UPDATING ATTENTION INFORMATION     15600021
*                                                                       16200021
* TABLES/WORK AREAS- NONE                                               16800021
*                                                                       17400021
* ATTRIBUTES- NUCLEUS RESIDENT, DISABLED, SUPERVISOR PROTECT KEY,       18000021
*    READ ONLY.                                                         18600021
*                                                                       19200021
* CHARACTER CODE DEPENDENCY- N/A                                        19800021
*                                                                       20400021
* NOTES- THIS ROUTINES LOGS ATTENTION INTERRUPTS RECEIVED FROM LOCAL    21000021
*    3270 DEVICES ON OPEN BTAM LINE GROUPS.  IF AN OUTSTANDING READ     21600021
*    INITIAL EXISTS FOR THE LINE GROUP AND THE DEVICE IS ABLE TO        22200021
*    PROCESS READ INITIALS, THE SECOND LEVEL ATTENTION ROUTINE IS       22800021
*    SCHEDULED USING AEE2 TO START THE READ.  ATTENTION INFORMATION     23400021
*    IN THE LINE GROUP'S UCB'S IS UPDATED AS REQUIRED.                  24000021
*                                                                       24600021
         EJECT                                                          25200021
*/*IECTATEN: CHART */                                                   25220021
*/* HEADER                                                              25240021
*/*BTAM FIRST LEVEL ATTENTION ROUTINE FOR 3270 DEVICES              */  25260021
*/* E ENTRY FROM IOS */                                                 25280021
*/* M SAVE REGS AND ESTABLISH ADDRESSABILITY */                         25300021
*/* D (YES,,NO,RTNTOIOS) IS DEVICE A 3270 DEVICE? */                    25320021
*/* D (YES,,NO,RTNTOIOS) ATTN HANDLING IRB ADDRESS NON-ZERO? */         25340021
*/* D (YES,,NO,FLGERROR) DE AND/OR ATTN ONLY STATUS? */                 25360021
*/* D (YES,PROCATTN,NO,) ATTN STATUS PRESENTED ? */                     25410021
*/* D (YES,,NO,RTNTOIOS) DE STATUS PRESENTED ? */                       25412021
*/*OPENCHK: D (YES,RTNTOIOS,NO,) DEVICE COME READY ALREADY ? */         25414021
*/* D (YES,CHKREADY,NO,) READY IRB PRESENT ? */                         25416021
*/* D (YES,FLAGRDY,NO,RTNTOIOS) OPEN IN PROGRESS ? */                   25418021
*/*FLAGRDY: P (,RTNTOIOS) FLAG READY DURING OPEN */                     25418421
*/*CHKREADY: D (YES,FLAGRDY,NO,) OPEN IN PROGRESS ? */                  25418821
*/* D (YES,,NO,RTNTOIOS) DEVICE NOT READY ? */                          25419221
*/* D (YES,RTNTOIOS,NO,) I/O QUEUED ? */                                25419621
*/* P TURN ON THE DEVICE CAME READY FLAG */                             25419721
*/* P OBTAIN AN IQE AND PUT RLN AND DEB ADDRESS IN PARM */              25419821
*/* L INVOKE AEE2 TO SCHEDULE READY PROCESSING */                       25419921
*/* P (,RTN2IOS) TURN OFF DEVICE NOT READY FLAG */                      25426621
*/*PROCATTN: D (NO,,YES,RTNTOIOS) I/O OPERATION QUEUED FOR THIS DVC? */ 25428621
*/*ACPTATN: D (NO,,YES,SETATNFL) SKIP FLAG ON? */                       25433321
*/*CHKRLN: M OBTAIN ADDRESS OF MASTER UCB */                            25440021
*/*RDTIPND: D (NO,,YES,SCHEDIQE) READ INITIAL PENDING? */               25460021
*/* D (NO,,YES,RTNTOIOS) ATTENTION FLAG ALREADY ON? */                  25480021
*/* P INCREMENT ATTENTION COUNT IN MASTER UCB BY 1 */                   25500021
*/*SETATNFL: P SET ATTENTION FLAG IN GCB */                             25520021
*/*RTNTOIOS: P RESTORE IOS'S REGISTERS */                               25540021
*/* R RETURN TO IOS */                                                  25560021
*/*FLGERROR: P (,RTNTOIOS) SET IOB INTERCEPT FLAG IN UCB */             25580021
*/*SCHEDIQE: M GET IQE FROM IRB QUEUE */                                25600021
*/* P STORE UCB ADDRESS IN IQE */                                       25620021
*/* L INVOKE AEE2 TO SCHEDULE 2ND LEVEL ATTN RTN */                     25640021
*/* P (,RTNTOIOS) SET READ INITIAL PENDING FLAG OFF */                  25660021
*/*IECTATEN: END */                                                     25680021
         EJECT                                                          25700021
PARMREG  EQU   1                    PARAMETER REGISTER                  25800021
AEEREG   EQU   10                   ADDRESS OF AEE2                     26400021
SAVEREG  EQU   13                   ADDRESS OF SAVE AREA                27000021
RTNREG   EQU   14                   RETURN POINT REGISTER               27600021
EPREG    EQU   15                   ENTRY POINT REGISTER                28200021
*                                                                       28800021
BASEREG  EQU   11                   BASE REGISTER FOR ATTENTION RTN     29400021
IRBREG   EQU   9                    POINTER TO IRB                      30000021
MSTREG   EQU   8                    BASE REGISTER FOR MASTER UCB        30600021
UCBREG   EQU   7                    BASE REGISTER FOR DEVICE UCB        31200021
IQEREG   EQU   6                    POINTER TO IQE                      31800021
DEBREG   EQU   4                    ADDR OF DEB FROM MSTRUCB  SB A57064 31850021
*                                                                       32400021
WORK1    EQU   2                    WORK REGISTER                       33000021
WORK2    EQU   3                    WORK REGISTER                       33600021
R12      EQU   12                                                       33900021
*                                                                       34200021
ALLON    EQU   X'FF'                ONE BYTE MASK-ALL BITS ON           34800021
CSWAD    EQU   64                   ADDRESS OF CHANNEL STATUS WORD      35400021
STAT1    EQU   4                    DISPLACEMENT TO 1ST CSW STATUS BYTE 36000021
STAT2    EQU   5                    DISPLACEMENT TO 2ND CSW STATUS BYTE 36600021
ATNSTAT  EQU   X'80'                ATTENTION STATUS                    37200021
DESTAT   EQU   X'04'                DEVICE END STATUS                   37800021
CUESTAT  EQU   X'20'                CONTROL UNIT END STATUS      A60886 37850021
IQEPARAM EQU   4                    DISPLACEMENT TO IQEPARAM            38400021
IQELINK  EQU   0                  DISP TO LINK FIELD IN IQE      A68754 38450021
RBNEXAV  EQU   96                   DISPLACEMENT TO IRB POINTER TO IQE  39000021
DVCBSY   EQU   X'80'                UCB DEVICE BUSY FLAG                39600021
DVCNTRDY EQU   X'40'                UCB DEVICE NOT READY FLAG           40200021
IOBNTCPT EQU   X'10'                UCB IOB INTERCEPT FLAG              40800021
GRPHCDVC EQU   X'10'                GRAPHICS DEVICE CLASS               41400021
DVC3277  EQU   X'09'                DEVICE TYPE FOR 3277 DISPLAY        42000021
DVC3284  EQU   X'0A'                DEVICE TYPE FOR 3284 PRINTER        42600021
DVC3286  EQU   X'0B'                DEVICE TYPE FOR 3286 PRINTER        43200021
IQELNGTH EQU   16                  LENGTH OF AN IQE           SB A57064 43250021
*                                                                       43800021
ATTN     EQU   X'01'                ATTENTION FLAG                      44400021
DEERR    EQU   X'40'               DEVICE END PLUS ERROR      SB A57064 44402021
IGG019UP EQU   X'10'               USING BTAM'S READY ROUT    SB A57064 44404021
LINERDY  EQU   X'01'               MTR FLAG FOR READY IN GROUPSB A57064 44410021
OPENFAIL EQU   X'02'               OPEN FAILED FOR DEVICE     SB A57064 44450021
OPENINIT EQU   X'80'               OPEN IN PROGRESS FLAG      SB A57064 44500021
OPENRDY  EQU   X'40'               DEV INTERRUPT DURING OPEN  SB A57064 44550021
SKIP     EQU   X'02'                SKIP FLAG                           45000021
READTI   EQU   X'04'                READ INITIAL PENDING FLAG           45600021
READY    EQU   X'20'               GRAF FLAG READY            SB A57064 45650021
RDYNDONE EQU   X'04'               PROCESSING READY           SB A57064 45700021
RLN1     EQU   X'01'                RLN FOR RLN 1                       46200021
POST     EQU   X'20'               UCB POST FLAG                        46500021
ONE      EQU   1                                                        46600021
TWO      EQU   2                  CONSTANT TWO                   A68753 46650021
FOUR     EQU   4                                                        46700021
         EJECT                                                          46800021
*              ENTRY CODE & ADDRESSABILITY                              47400021
         USING *,EPREG             TEMPORARY ADDRESSABILITY             48000021
         B     SAVEREGS            BRANCH AROUND ID                     48600021
         DC    AL1(8)              LENGTH OF ID                         49200021
         DC    CL8'IECTATEN'       MODULE IDENTIFIER                    49800021
         DS    0H                                                       50400021
SAVEREGS STM   RTNREG,R12,SAVE     SAVE IOS'S REGISTERS                 51000021
         DROP  EPREG               DROP ADDRESSABILITY                  51600021
         BALR  BASEREG,0            ESTABLISH ADDRESSABILITY FOR        52200021
         USING *,BASEREG            ATTENTION RTN CSECT                 52800021
         USING UCB,UCBREG           ESTABLISH ADDRESSABILITY FOR UCB    53400021
*              VALIDATE DEVICE                                          54000021
CHKTYPE  CLI   UCBDVCLS,GRPHCDVC    GRAPHICS DEVICE CLASS IN UCB        54600021
         BNE   RTNTOIOS             NO, RETURN TO IOS                   55200021
         CLI   UCBUNTYP,DVC3277    IS DEVICE 3270 DEVICE                55800021
         BL    RTNTOIOS            NO, RETURN TO IOS                    56400021
         CLI   UCBUNTYP,DVC3286    MAYBE, CHECK FURTHER                 57000021
         BH    RTNTOIOS            NO, RETURN TO IOS                    57600021
*              CHECK OPEN STATUS                                        58200021
OPENCHK1 EQU   *                   CHECK OPEN COMPLETED       SB A57064 59200021
         L     IRBREG,UCBIRB       GET ADDRESS OF ATTEN IRB   SB A57064 59250021
         LA    IRBREG,0(IRBREG)    CLEAR GRAF FLAGS           SB A57064 59300021
         LTR   IRBREG,IRBREG        IRB ADDR ESTABLISHED BY OPEN        59400021
         BZ    RTNTOIOS            NO, IGNORE ATTN               A68753 59450021
         TM    UCBFL1,POST        VALID RQE?                     A68753 59500021
         BNO   CHKCSW             NO,ASYNCHRONOUS                A68753 59550021
*              EXIT CODE                                                60600021
RTNTOIOS LM    RTNREG,R12,SAVE     RESTORE IOS'S REGISTERS              61200021
         BR    RTNREG              RETURN TO IOS                        61800021
RTN2IOS  NI    UCBFL1,X'FF'-X'C8'  TURN OFF BUSY,NOT READY,CU BUSY      61900021
         LM    RTNREG,R12,SAVE     RESTORE REGS                         62000021
         B     4(RTNREG)           RETURN                               62100021
*                                  ASYNCHRONOUS READY         SB A57064 62150021
CHKREADY EQU   *                   READY QUEUE HAS BEEN       SB A57064 62200021
*                                  INITIALIZED                SB A57064 62250021
         TM    UCBGRAF,OPENFAIL    DID OPEN FOR DEVICE FAIL ? SB A57064 62360021
         BO    CHKFUTH             NO, RETURN TO IOS          SB A57064 62370021
         TM    UCBGCB,DEERR        DE WITH ERROR ?            SB A57064 62372021
         BO    FLGERCMP            YES, SET ERROR             SB A57064 62374021
         B     RTNTOIOS            NO, RETURN                 SB A57064 62374421
CHKFUTH  EQU   *                   CHECK FUTHER               SB A57064 62376021
         OI    UCBGRAF,READY       SET READY FLAG             SB A57064 62399721
         L     IQEREG,RBNEXAV(IRBREG) GET ADDR OF READY QUEUE SB A57064 62469921
         MVC   RBNEXAV(FOUR,IRBREG),0(IQEREG) CHAIN NEXT IQE  SB A57064 62471921
         XC    0(FOUR,IQEREG),0(IQEREG) REMOVE IQE FROM CHAIN SB A57064 62473921
         SR    WORK1,WORK1         CLEAR EVEN REGISTER        SB A57064 62479921
         IC    WORK2,UCBRLN        PICK UP RLN OF THIS DEVICE SB A57064 62489921
         CLI   UCBRLN,RLN1         IS THIS THE MASTER UCB ?   SB A57064 62490321
         BE    MSTADDOK            YES, USE THE ADDRESS       SB A57064 62490721
         L     MSTREG,UCBCTLNK     NO, GET ADDR OF MASTER UCB SB A57064 62491121
         LA    MSTREG,0(MSTREG)    CLEAR THE HIGH BYTE        SB A57064 62491221
         B     MSTUCBOK            GO CHECK THE READ TI BITS  SB A57064 62491521
MSTADDOK EQU   *                   SET UP TO CHECK MASTER UCB SB A57064 62491621
         LR    MSTREG,UCBREG       PICK UP MASTER UCB ADD     SB A57064 62491721
MSTUCBOK EQU   *                   MSTREG CONTAINS ADDRESS    SB A57064 62491821
         USING MSTRUCB,MSTREG      MASTER UCB ADDRESSABILITY  SB A57064 62491921
         TM    MTRGRAF,IGG019UP    USING BTAMS ?              SB A57064 62492021
         BNO   NOSETRDY            NO, DON'T SET LINERDY      SB A57064 62492121
         OI    MTRGRAF,LINERDY     INDICATE DEVICE READY      SB A57064 62492321
         B     LNRDYSET            BYPASS TURN OFF            SB A57064 62492721
NOSETRDY EQU   *                   TURN OFF MTR LINE READY    SB A57064 62493121
         NI    MTRGRAF,ALLON-LINERDY TURN OFF LINE READY      SB A57064 62493521
LNRDYSET EQU   *                   MTR GRAF FLAGS SET         SB A57064 62493621
         L     DEBREG,MTRDEBAD     GET DEB ADDRESS FOR GROUP  SB A57064 62493921
         DROP  MSTREG              DON'T NEED MASTER          SB A57064 62495921
         LA    DEBREG,0(DEBREG)    CLEAR THE HIGH BYTE        SB A57064 62496321
         SLL   WORK2,24            PUT IN HIGH BYTE           SB A57064 62497921
         OR    DEBREG,WORK2        PUT RLN IN PARM            SB A57064 62498321
         ST    DEBREG,IQEPARAM(IQEREG) STORE RLN/DEBADDR      SB A57064 62549821
         LNR   PARMREG,IQEREG      PARM = COMPLEMENT OF       SB A57064 62579821
*                                  IQE ADDRESS                SB A57064 62589821
         LR    EPREG,AEEREG        ENTRY POINT = AEE2         SB A57064 62591821
         BALR  RTNREG,EPREG        GO TO AEE2 TO SCHEDULE     SB A57064 62593821
*                                  USER PROVIDED ASYNCHRONOUS SB A57064 62595821
*                                  DEVICE READY ROUTINE       SB A57064 62597821
         NI    UCBGRAF,ALLON-OPENFAIL TURN OFF OPEN FAIL FLG  SB A57064 62598221
         TM    UCBGCB,DEERR        ERROR WITH DE STAT ?       SB A57064 62598321
         BO    FLGERCMP            YES, SET ERROR             SB A57064 62598421
         B     RTN2IOS             RETURN TO IOS+4            SB A57064 62598621
FLAGRDY  EQU   *                   DEVICE INTERRUPT IN OPEN   SB A57064 62599021
         OI    UCBGRAF,OPENRDY     SET FLAG INT DURING OPEN   SB A57064 62599421
         TM    UCBGCB,DEERR        ERROR WITH DE STAT ?       SB A57064 62649421
         BO    FLGERCMP            YES, SET ERROR             SB A57064 62659421
         B     RTNTOIOS            RETURN TO IOS              SB A57064 62699421
*              CHECK CSW STATUS OTHER THAN ATTN, DE AND CUE      A60886 62749421
CHKCSW   TM    CSWAD+STAT1,ALLON-ATNSTAT-DESTAT-CUESTAT          A60886 63000021
         BZ    OTHRSTS              NO, CHECK FURTHER                   63600021
FLGERROR OI    UCBFL1,IOBNTCPT      TURN IOB INTERCEPT FLAG ON          64200021
         SR    WORK1,WORK1        CLEAR REG                      A68753 64210021
         ST    WORK1,UCBLTS       ZERO STATUS AND SENSE          A68753 64220021
*        NOTE: IOS SAVES STATUS IN UCBLTS IF ASYN ERROR          A68753 64230021
         MVC   UCBLTS(TWO),CSWAD+STAT1   SAVE STATUS IN UCB      A68753 64240021
         TM    CSWAD+STAT1,DESTAT  DEVICE END ?               SB A57064 64250021
         BNO   PROCATTN           SINCE ERROR, TRY TO SCHEDULE   A68753 64300021
*        2ND LEVEL SO USER CAN BE MADE AWARE OF IT               A68753 64302021
         OI    UCBGCB,DEERR        SET DE WITH ERROR          SB A57064 64310021
         TM    UCBGRAF,OPENFAIL    NOT PREVIOUSLY READY ?     SB A57064 64350021
         BO    OPENCHK             YES, PROCESS READY         SB A57064 64400021
FLGERCMP EQU   *                   RETURN                     SB A57064 64450021
         NI    UCBGCB,ALLON-DEERR TURN OFF DE W ERROR         SB A57064 64500021
         B     RTN2IOS             RETURN TO IOS+4                      64800021
OTHRSTS  TM    CSWAD+STAT2,ALLON    ERROR STATUS IN BYTE2               65400021
         BNZ   FLGERROR             YES, FLAG ERROR IN UCB              66000021
         TM    CSWAD+STAT1,ATNSTAT  ATTENTION STATUS ON                 66600021
         BO    PROCATTN            YES, GO PROCESS IT         SB A57064 67200021
         TM    CSWAD+STAT1,DESTAT  DEVICE END STATUS ?        SB A57064 67210021
         BZ    RTNTOIOS            NO, RETURN TO IOS          SB A57064 67220021
OPENCHK  EQU   *                   SEE IF OPEN IN PROGRESS,   SB A57064 67250021
*                                  OR IF OPEN COMPLETE        SB A57064 67300021
         TM    UCBGRAF,OPENRDY+READY UCB READY ALREADY        SB A57064 67310021
         BZ    NXTCHK              NO, CHECK FURTHER          SB A57064 67320021
         TM    UCBGCB,DEERR        ERROR STAT ?               SB A57064 67322021
         BO    FLGERCMP            YES, SET ERROR             SB A57064 67324021
         B     RTNTOIOS            NO, RETURN                 SB A57064 67326021
NXTCHK   EQU   *                   CHECK FURTHER              SB A57064 67328021
         TM    UCBGRAF,OPENINIT    IS OPEN IN PROGRESS ?      SB A57064 67330021
         BO    FLAGRDY             YES, FLAG INT DURING OPEN  SB A57064 67340021
         L     IRBREG,UCBRDYQ      GET ADDRESS OF READY IRB   SB A57064 67350021
         LA    IRBREG,0(IRBREG)    CLEAR HIGH BYTE FOR TEST   SB A57064 67400021
         LTR   IRBREG,IRBREG       READY QUEUE INITIALIZED ?  SB A57064 67450021
         BNZ   CHKREADY            YES, SEE IF NEED SCHEDULE  SB A57064 67500021
         TM    UCBGCB,DEERR        ERROR WITH STAT ?          SB A57064 67550021
         BO    FLGERCMP            YES, SET ERROR             SB A57064 67600021
         B     RTNTOIOS            RETURN TO IOS              SB A57064 67800021
*              YES, PROCESS ATTENTION                                   68400021
PROCATTN EQU   *                   PROCESS THE ATTENTION      SB A57064 68450021
ACPTATN  TM    UCBGCB,SKIP          SKIP FLAG ON                        69000021
         BZ    CHKRLN               NO, CHECK FOR PENDING READ          69600021
SETATNFL OI    UCBGCB,ATTN          SET ATTENTION FLAG IN GCB           70200021
         B     RTN2IOS             RETURN TO IOS+4                      70800021
*                                                                       71400021
CHKRLN   CLI   UCBRLN,RLN1          UCB RLN 1 FOR LINE GROUP            72000021
         BE    RLNISONE             YES, UCB = MASTER UCB               72600021
         L     MSTREG,UCBCTLNK      NO, GET ADDRESS OF MASTER UCB       73200021
         USING MSTRUCB,MSTREG       & ESTABLISH ADDRESSABILITY          73800021
*                                                                       74400021
RDTIPND  EQU   *                   CHECK STATUS OF UCB        SB A57064 74450021
         TM    MTRGRAF,RDYNDONE    PROCESSING READY ?         SB A57064 74500021
         BO    NOSCHED             YES, DON'T SCHEDULE        SB A57064 74550021
         TM    MTRGCB,READTI        READ INITIAL PENDING                75000021
         BO    SCHEDIQE             YES, SCHEDULE 2ND LEVEL ATTN RTN    75600021
NOSCHED  EQU   *                   WON'T SCHEDULE             SB A57064 75650021
         TM    UCBGCB,ATTN          IF ATTENTION FLAG ALREADY ON,       76200021
         BO    RTN2IOS             RETURN TO IOS+4                      76800021
         SR    WORK1,WORK1                                              77400021
         IC    WORK1,MTRATNCT       INCREMENT ATTENTION COUNT IN        78000021
         LA    WORK1,ONE(WORK1)    MASTER UCB BY 1                      78600021
         STC   WORK1,MTRATNCT                                           79200021
         B     SETATNFL             SET ATTENTION FLAG IN GCB           79800021
*              SCHEDULE 2ND LEVEL ATTENTION ROUTINE                     80400021
SCHEDIQE L     IQEREG,RBNEXAV(IRBREG) GET ADDRESS OF IQE                81000021
         ST    UCBREG,IQEPARAM(IQEREG) STORE ADDRESS OF UCB IN IQE      81600021
         MVC   RBNEXAV(FOUR,IRBREG),IQELINK(IQEREG)  UNCHAIN     A68754 81650021
*                                 FIRST AVAILABLE IQE            A68754 81700021
         LNR   PARMREG,IQEREG       PARM = COMPLEMENT OF IQE ADDRESS    82800021
         LR    EPREG,AEEREG         EP = AEE2                           83400021
         BALR  RTNREG,EPREG         GO TO AEE2 TO SCHEDULE IQE          84000021
         NI    MTRGCB,ALLON-READTI  TURN READ PENDING FLAG OFF          84600021
         B     RTN2IOS             RETURN TO IOS+4                      85200021
RLNISONE LR    MSTREG,UCBREG        TRANSFER UCB ADDRESS TO MASTER      85800021
         B     RDTIPND              UCB BASE AND CHECK FOR PENDING READ 86400021
*                                                                       87000021
SAVE     DC    15F'0'              REGISTER SAVE AREA                   87600021
         EJECT                                                          88200021
         IECTUCBX                                                       88800021
UCBLTS   EQU   UCB+20             STATUS AND SENSE               A68753 88850021
         END                                                            89400021
